src/compiler/generic/vm-array.lisp

   1 ;;;; this file centralizes information about the array types
   2 ;;;; implemented by the system, where previously such information was
   3 ;;;; spread over several files.
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!VM")
  15
  16 (defstruct (specialized-array-element-type-properties
  17             (:conc-name saetp-)
  18             (:constructor
  19              !make-saetp
  20              (specifier
  21               initial-element-default
  22               n-bits
  23               primitive-type-name
  24               &key (n-pad-elements 0) complex-typecode
  25               &aux (typecode
  26                     (eval (symbolicate primitive-type-name "-WIDETAG")))))
  27             (:copier nil))
  28   ;; the element specifier, e.g. BASE-CHAR or (UNSIGNED-BYTE 4)
  29   (specifier (missing-arg) :type type-specifier :read-only t)
  30   ;; the element type, e.g. #<BUILT-IN-CLASS BASE-CHAR (sealed)> or
  31   ;; #<SB-KERNEL:NUMERIC-TYPE (UNSIGNED-BYTE 4)>
  32   (ctype nil :type (or ctype null))
  33   ;; what we get when the low-level vector-creation logic zeroes all
  34   ;; the bits (which also serves as the default value of MAKE-ARRAY's
  35   ;; :INITIAL-ELEMENT keyword)
  36   (initial-element-default (missing-arg) :read-only t)
  37   ;; how many bits per element
  38   (n-bits (missing-arg) :type index :read-only t)
  39   ;; the low-level type code (aka "widetag")
  40   (typecode (missing-arg) :type index :read-only t)
  41   ;; if an integer, a typecode corresponding to a complex vector
  42   ;; specialized on this element type.
  43   (complex-typecode nil :type (or index null) :read-only t)
  44   ;; the name of the primitive type of data vectors specialized on
  45   ;; this type
  46   (primitive-type-name (missing-arg) :type symbol :read-only t)
  47   ;; the number of extra elements we use at the end of the array for
  48   ;; low level hackery (e.g., one element for arrays of BASE-CHAR,
  49   ;; which is used for a fixed #\NULL so that when we call out to C
  50   ;; we don't need to cons a new copy)
  51   (n-pad-elements (missing-arg) :type index :read-only t))
  52
  53 (defparameter *specialized-array-element-type-properties*
  54   (map 'simple-vector
  55        (lambda (args)
  56          (apply #'!make-saetp args))
  57        `(;; Erm.  Yeah.  There aren't a lot of things that make sense
  58          ;; for an initial element for (ARRAY NIL). -- CSR, 2002-03-07
  59          (nil #:mu 0 simple-array-nil
  60               :complex-typecode #.sb!vm:complex-vector-nil-widetag)
  61          (base-char ,(code-char 0) 8 simple-base-string
  62                     ;; (SIMPLE-BASE-STRINGs are stored with an extra
  63                     ;; trailing #\NULL for convenience in calling out
  64                     ;; to C.)
  65                     :n-pad-elements 1
  66                     :complex-typecode #.sb!vm:complex-base-string-widetag)
  67          (single-float 0.0f0 32 simple-array-single-float)
  68          (double-float 0.0d0 64 simple-array-double-float)
  69          #!+long-float
  70          (long-float 0.0l0 #!+x86 96 #!+sparc 128 simple-array-long-float)
  71          (bit 0 1 simple-bit-vector
  72               :complex-typecode #.sb!vm:complex-bit-vector-widetag)
  73          ;; KLUDGE: The fact that these UNSIGNED-BYTE entries come
  74          ;; before their SIGNED-BYTE partners is significant in the
  75          ;; implementation of the compiler; some of the cross-compiler
  76          ;; code (see e.g. COERCE-TO-SMALLEST-ELTYPE in
  77          ;; src/compiler/debug-dump.lisp) attempts to create an array
  78          ;; specialized on (UNSIGNED-BYTE FOO), where FOO could be 7;
  79          ;; (UNSIGNED-BYTE 7) is SUBTYPEP (SIGNED-BYTE 8), so if we're
  80          ;; not careful we could get the wrong specialized array when
  81          ;; we try to FIND-IF, below. -- CSR, 2002-07-08
  82          ((unsigned-byte 2) 0 2 simple-array-unsigned-byte-2)
  83          ((unsigned-byte 4) 0 4 simple-array-unsigned-byte-4)
  84          ((unsigned-byte 8) 0 8 simple-array-unsigned-byte-8)
  85          ((unsigned-byte 16) 0 16 simple-array-unsigned-byte-16)
  86          ((unsigned-byte 32) 0 32 simple-array-unsigned-byte-32)
  87          ((signed-byte 8) 0 8 simple-array-signed-byte-8)
  88          ((signed-byte 16) 0 16 simple-array-signed-byte-16)
  89          ;; KLUDGE: See the comment in PRIMITIVE-TYPE-AUX,
  90          ;; compiler/generic/primtype.lisp, for why this is FIXNUM and
  91          ;; not (SIGNED-BYTE 30)
  92          (fixnum 0 32 simple-array-signed-byte-30)
  93          ((signed-byte 32) 0 32 simple-array-signed-byte-32)
  94          ((complex single-float) #C(0.0f0 0.0f0) 64
  95           simple-array-complex-single-float)
  96          ((complex double-float) #C(0.0d0 0.0d0) 128
  97           simple-array-complex-double-float)
  98          #!+long-float
  99          ((complex long-float) #C(0.0l0 0.0l0) #!+x86 192 #!+sparc 256
 100           simple-array-complex-long-float)
 101          (t 0 32 simple-vector))))
 102
 103 (defvar sb!kernel::*specialized-array-element-types*
 104   (map 'list
 105        #'saetp-specifier
 106        *specialized-array-element-type-properties*))
 107
 108 #-sb-xc-host
 109 (defun !vm-type-cold-init ()
 110   (setf sb!kernel::*specialized-array-element-types*
 111         '#.sb!kernel::*specialized-array-element-types*))
 112
 113 (defvar *simple-array-primitive-types*
 114   (map 'list
 115        (lambda (saetp)
 116          (cons (saetp-specifier saetp)
 117                (saetp-primitive-type-name saetp)))
 118        *specialized-array-element-type-properties*)
 119   #!+sb-doc
 120   "An alist for mapping simple array element types to their
 121 corresponding primitive types.")