src/compiler/globaldb.lisp

   1 ;;;; This file provides a functional interface to global information
   2 ;;;; about named things in the system. Information is considered to be
   3 ;;;; global if it must persist between invocations of the compiler. The
   4 ;;;; use of a functional interface eliminates the need for the compiler
   5 ;;;; to worry about the actual representation. This is important, since
   6 ;;;; the information may well have several representations.
   7 ;;;;
   8 ;;;; The database contains arbitrary Lisp values, addressed by a
   9 ;;;; combination of Name, Class and Type. The Name is a EQUAL-thing
  10 ;;;; which is the name of the thing we are recording information
  11 ;;;; about. Class is the kind of object involved. Typical classes are
  12 ;;;; :FUNCTION, :VARIABLE, :TYPE, ... A Type names a particular piece
  13 ;;;; of information within a given class. Class and Type are keywords,
  14 ;;;; and are compared with EQ.
  15
  16 ;;;; This software is part of the SBCL system. See the README file for
  17 ;;;; more information.
  18 ;;;;
  19 ;;;; This software is derived from the CMU CL system, which was
  20 ;;;; written at Carnegie Mellon University and released into the
  21 ;;;; public domain. The software is in the public domain and is
  22 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  23 ;;;; files for more information.
  24
  25 (in-package "SB!C")
  26
  27 (!begin-collecting-cold-init-forms)
  28 #!+sb-show (!cold-init-forms (/show0 "early in globaldb.lisp cold init"))
  29
  30 ;;; The DEFVAR for this appears later.
  31 ;;; FIXME: centralize
  32 (declaim (special *universal-type*))
  33
  34 ;;; This is sorta semantically equivalent to SXHASH, but optimized for
  35 ;;; legal function names. Note: semantically equivalent does *not*
  36 ;;; mean that it always returns the same value as SXHASH, just that it
  37 ;;; satisfies the formal definition of SXHASH. The ``sorta'' is
  38 ;;; because SYMBOL-HASH will not necessarily return the same value in
  39 ;;; different lisp images.
  40 ;;;
  41 ;;; Why optimize? We want to avoid the fully-general TYPECASE in ordinary
  42 ;;; SXHASH, because
  43 ;;;   1. This hash function has to run when we're initializing the globaldb,
  44 ;;;      so it has to run before the type system is initialized, and it's
  45 ;;;      easier to make it do this if we don't try to do a general TYPECASE.
  46 ;;;   2. This function is in a potential bottleneck for the compiler,
  47 ;;;      and avoiding the general TYPECASE lets us improve performance
  48 ;;;      because
  49 ;;;     2a. the general TYPECASE is intrinsically slow, and
  50 ;;;     2b. the general TYPECASE is too big for us to easily afford
  51 ;;;         to inline it, so it brings with it a full function call.
  52 ;;;
  53 ;;; Why not specialize instead of optimize? (I.e. why fall through to
  54 ;;; general SXHASH as a last resort?) Because the INFO database is used
  55 ;;; to hold all manner of things, e.g. (INFO :TYPE :BUILTIN ..)
  56 ;;; which is called on values like (UNSIGNED-BYTE 29). Falling through
  57 ;;; to SXHASH lets us support all manner of things (as long as they
  58 ;;; aren't used too early in cold boot for SXHASH to run).
  59 #!-sb-fluid (declaim (inline globaldb-sxhashoid))
  60 (defun globaldb-sxhashoid (x)
  61   (cond #-sb-xc-host ; (SYMBOL-HASH doesn't exist on cross-compilation host.)
  62         ((symbolp x)
  63          (symbol-hash x))
  64         #-sb-xc-host ; (SYMBOL-HASH doesn't exist on cross-compilation host.)
  65         ((and (listp x)
  66               (eq (first x) 'setf)
  67               (let ((rest (rest x)))
  68                 (and (symbolp (car rest))
  69                      (null (cdr rest)))))
  70          (logxor (symbol-hash (second x))
  71                  110680597))
  72         (t (sxhash x))))
  73
  74 ;;; Given any non-negative integer, return a prime number >= to it.
  75 ;;;
  76 ;;; FIXME: This logic should be shared with ALMOST-PRIMIFY in
  77 ;;; hash-table.lisp. Perhaps the merged logic should be
  78 ;;; PRIMIFY-HASH-TABLE-SIZE, implemented as a lookup table of primes
  79 ;;; after integral powers of two:
  80 ;;;    #(17 37 67 131 ..)
  81 ;;; (Or, if that's too coarse, after half-integral powers of two.) By
  82 ;;; thus getting rid of any need for primality testing at runtime, we
  83 ;;; could punt POSITIVE-PRIMEP, too.
  84 (defun primify (x)
  85   (declare (type unsigned-byte x))
  86   (do ((n (logior x 1) (+ n 2)))
  87       ((positive-primep n) n)))
  88 \f
  89 ;;;; info classes, info types, and type numbers, part I: what's needed
  90 ;;;; not only at compile time but also at run time
  91
  92 ;;;; Note: This section is a blast from the past, a little trip down
  93 ;;;; memory lane to revisit the weird host/target interactions of the
  94 ;;;; CMU CL build process. Because of the way that the cross-compiler
  95 ;;;; and target compiler share stuff here, if you change anything in
  96 ;;;; here, you'd be well-advised to nuke all your fasl files and
  97 ;;;; restart compilation from the very beginning of the bootstrap
  98 ;;;; process.
  99
 100 ;;; At run time, we represent the type of info that we want by a small
 101 ;;; non-negative integer.
 102 (defconstant type-number-bits 6)
 103 (deftype type-number () `(unsigned-byte ,type-number-bits))
 104
 105 ;;; Why do we suppress the :COMPILE-TOPLEVEL situation here when we're
 106 ;;; running the cross-compiler? The cross-compiler (which was built
 107 ;;; from these sources) has its version of these data and functions
 108 ;;; defined in the same places we'd be defining into. We're happy with
 109 ;;; its version, since it was compiled from the same sources, so
 110 ;;; there's no point in overwriting its nice compiled version of this
 111 ;;; stuff with our interpreted version. (And any time we're *not*
 112 ;;; happy with its version, perhaps because we've been editing the
 113 ;;; sources partway through bootstrapping, tch tch, overwriting its
 114 ;;; version with our version would be unlikely to help, because that
 115 ;;; would make the cross-compiler very confused.)
 116 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 117
 118 (defstruct (class-info
 119             (:constructor make-class-info (name))
 120             #-no-ansi-print-object
 121             (:print-object (lambda (x s)
 122                              (print-unreadable-object (x s :type t)
 123                                (prin1 (class-info-name x)))))
 124             (:copier nil))
 125   ;; name of this class
 126   (name nil :type keyword :read-only t)
 127   ;; list of Type-Info structures for each type in this class
 128   (types () :type list))
 129
 130 ;;; a map from type numbers to TYPE-INFO objects. There is one type
 131 ;;; number for each defined CLASS/TYPE pair.
 132 ;;;
 133 ;;; We build its value at build-the-cross-compiler time (with calls to
 134 ;;; DEFINE-INFO-TYPE), then generate code to recreate the compile time
 135 ;;; value, and arrange for that code to be called in cold load.
 136 ;;; KLUDGE: We don't try to reset its value when cross-compiling the
 137 ;;; compiler, since that creates too many bootstrapping problems,
 138 ;;; instead just reusing the built-in-the-cross-compiler version,
 139 ;;; which is theoretically a little bit ugly but pretty safe in
 140 ;;; practice because the cross-compiler is as close to the target
 141 ;;; compiler as we can make it, i.e. identical in most ways, including
 142 ;;; this one. -- WHN 2001-08-19
 143 (defvar *info-types*)
 144 (declaim (type simple-vector *info-types*))
 145 #-sb-xc ; as per KLUDGE note above
 146 (eval-when (:compile-toplevel :execute)
 147   (setf *info-types*
 148         (make-array (ash 1 type-number-bits) :initial-element nil)))
 149
 150 (defstruct (type-info
 151             #-no-ansi-print-object
 152             (:print-object (lambda (x s)
 153                              (print-unreadable-object (x s)
 154                                (format s
 155                                        "~S ~S, Number = ~D"
 156                                        (class-info-name (type-info-class x))
 157                                        (type-info-name x)
 158                                        (type-info-number x)))))
 159             (:copier nil))
 160   ;; the name of this type
 161   (name (required-argument) :type keyword)
 162   ;; this type's class
 163   (class (required-argument) :type class-info)
 164   ;; a number that uniquely identifies this type (and implicitly its class)
 165   (number (required-argument) :type type-number)
 166   ;; a type specifier which info of this type must satisfy
 167   (type nil :type t)
 168   ;; a function called when there is no information of this type
 169   (default (lambda () (error "type not defined yet")) :type function))
 170
 171 ;;; a map from class names to CLASS-INFO structures
 172 ;;;
 173 ;;; We build the value for this at compile time (with calls to
 174 ;;; DEFINE-INFO-CLASS), then generate code to recreate the compile time
 175 ;;; value, and arrange for that code to be called in cold load.
 176 ;;; KLUDGE: Just as for *INFO-TYPES*, we don't try to rebuild this
 177 ;;; when cross-compiling, but instead just reuse the cross-compiler's
 178 ;;; version for the target compiler. -- WHN 2001-08-19
 179 (defvar *info-classes*)
 180 (declaim (hash-table *info-classes*))
 181 #-sb-xc ; as per KLUDGE note above
 182 (eval-when (:compile-toplevel :execute)
 183   (setf *info-classes* (make-hash-table)))
 184
 185 ;;; If NAME is the name of a type in CLASS, then return the TYPE-INFO,
 186 ;;; otherwise NIL.
 187 (defun find-type-info (name class)
 188   (declare (type keyword name) (type class-info class))
 189   (dolist (type (class-info-types class) nil)
 190     (when (eq (type-info-name type) name)
 191       (return type))))
 192
 193 ;;; Return the info structure for an info class or type, or die trying.
 194 (declaim (ftype (function (keyword) class-info) class-info-or-lose))
 195 (defun class-info-or-lose (class)
 196   (declare (type keyword class))
 197   #+sb-xc (/noshow0 "entering CLASS-INFO-OR-LOSE, CLASS=..")
 198   #+sb-xc (/nohexstr class)
 199   (prog1
 200       (or (gethash class *info-classes*)
 201           (error "~S is not a defined info class." class))
 202     #+sb-xc (/noshow0 "returning from CLASS-INFO-OR-LOSE")))
 203 (declaim (ftype (function (keyword keyword) type-info) type-info-or-lose))
 204 (defun type-info-or-lose (class type)
 205   #+sb-xc (/noshow0 "entering TYPE-INFO-OR-LOSE, CLASS,TYPE=..")
 206   #+sb-xc (/nohexstr class)
 207   #+sb-xc (/nohexstr type)
 208   (prog1
 209       (or (find-type-info type (class-info-or-lose class))
 210           (error "~S is not a defined info type." type))
 211     #+sb-xc (/noshow0 "returning from TYPE-INFO-OR-LOSE")))
 212
 213 ) ; EVAL-WHEN
 214 \f
 215 ;;;; info classes, info types, and type numbers, part II: what's
 216 ;;;; needed only at compile time, not at run time
 217
 218 ;;; FIXME: Perhaps this stuff (the definition of DEFINE-INFO-CLASS
 219 ;;; and the calls to it) could/should go in a separate file,
 220 ;;; perhaps info-classes.lisp?
 221
 222 (eval-when (:compile-toplevel :execute)
 223
 224 ;;; Set up the data structures to support an info class.
 225 ;;;
 226 ;;; comment from CMU CL:
 227 ;;;   We make sure that the class exists at compile time so that
 228 ;;;   macros can use it, but we don't actually store the init function
 229 ;;;   until load time so that we don't break the running compiler.
 230 ;;; KLUDGE: I don't think that's the way it is any more, but I haven't
 231 ;;; looked into it enough to write a better comment. -- WHN 2001-03-06
 232 (#+sb-xc-host defmacro
 233  #-sb-xc-host sb!xc:defmacro
 234      define-info-class (class)
 235   (declare (type keyword class))
 236   `(progn
 237      ;; (We don't need to evaluate this at load time, compile time is
 238      ;; enough. There's special logic elsewhere which deals with cold
 239      ;; load initialization by inspecting the info class data
 240      ;; structures at compile time and generating code to recreate
 241      ;; those data structures.)
 242      (eval-when (:compile-toplevel :execute)
 243        (unless (gethash ,class *info-classes*)
 244          (setf (gethash ,class *info-classes*) (make-class-info ,class))))
 245      ,class))
 246
 247 ;;; Find a type number not already in use by looking for a null entry
 248 ;;; in *INFO-TYPES*.
 249 (defun find-unused-type-number ()
 250   (or (position nil *info-types*)
 251       (error "no more INFO type numbers available")))
 252
 253 ;;; a list of forms for initializing the DEFAULT slots of TYPE-INFO
 254 ;;; objects, accumulated during compilation and eventually converted
 255 ;;; into a function to be called at cold load time after the
 256 ;;; appropriate TYPE-INFO objects have been created
 257 ;;;
 258 ;;; Note: This is quite similar to the !COLD-INIT-FORMS machinery, but
 259 ;;; we can't conveniently use the ordinary !COLD-INIT-FORMS machinery
 260 ;;; here. The problem is that the natural order in which the
 261 ;;; default-slot-initialization forms are generated relative to the
 262 ;;; order in which the TYPE-INFO-creation forms are generated doesn't
 263 ;;; match the relative order in which the forms need to be executed at
 264 ;;; cold load time.
 265 (defparameter *reversed-type-info-init-forms* nil)
 266
 267 ;;; Define a new type of global information for CLASS. TYPE is the
 268 ;;; name of the type, DEFAULT is the value for that type when it
 269 ;;; hasn't been set, and TYPE-SPEC is a type specifier which values of
 270 ;;; the type must satisfy. The default expression is evaluated each
 271 ;;; time the information is needed, with NAME bound to the name for
 272 ;;; which the information is being looked up.
 273 ;;;
 274 ;;; The main thing we do is determine the type's number. We need to do
 275 ;;; this at macroexpansion time, since both the COMPILE and LOAD time
 276 ;;; calls to %DEFINE-INFO-TYPE must use the same type number.
 277 (#+sb-xc-host defmacro
 278  #-sb-xc-host sb!xc:defmacro
 279     define-info-type (&key (class (required-argument))
 280                            (type (required-argument))
 281                            (type-spec (required-argument))
 282                            default)
 283   (declare (type keyword class type))
 284   `(progn
 285      (eval-when (:compile-toplevel :execute)
 286        ;; At compile time, ensure that the type number exists. It will
 287        ;; need to be forced to exist at cold load time, too, but
 288        ;; that's not handled here; it's handled by later code which
 289        ;; looks at the compile time state and generates code to
 290        ;; replicate it at cold load time.
 291        (let* ((class-info (class-info-or-lose ',class))
 292               (old-type-info (find-type-info ',type class-info)))
 293          (unless old-type-info
 294            (let* ((new-type-number (find-unused-type-number))
 295                   (new-type-info
 296                    (make-type-info :name ',type
 297                                    :class class-info
 298                                    :number new-type-number)))
 299              (setf (aref *info-types* new-type-number) new-type-info)
 300              (push new-type-info (class-info-types class-info)))))
 301        ;; Arrange for TYPE-INFO-DEFAULT and TYPE-INFO-TYPE to be set
 302        ;; at cold load time. (They can't very well be set at
 303        ;; cross-compile time, since they differ between the
 304        ;; cross-compiler and the target. The DEFAULT slot values
 305        ;; differ because they're compiled closures, and the TYPE slot
 306        ;; values differ in the use of SB!XC symbols instead of CL
 307        ;; symbols.)
 308        (push `(let ((type-info (type-info-or-lose ,',class ,',type)))
 309                 (setf (type-info-default type-info)
 310                        ;; FIXME: This code is sort of nasty. It would
 311                        ;; be cleaner if DEFAULT accepted a real
 312                        ;; function, instead of accepting a statement
 313                        ;; which will be turned into a lambda assuming
 314                        ;; that the argument name is NAME. It might
 315                        ;; even be more microefficient, too, since many
 316                        ;; DEFAULTs could be implemented as (CONSTANTLY
 317                        ;; NIL) instead of full-blown (LAMBDA (X) NIL).
 318                        (lambda (name)
 319                          (declare (ignorable name))
 320                          ,',default))
 321                 (setf (type-info-type type-info) ',',type-spec))
 322              *reversed-type-info-init-forms*))
 323      ',type))
 324
 325 ) ; EVAL-WHEN
 326 \f
 327 ;;;; generic info environments
 328
 329 ;;; Note: the CACHE-NAME slot is deliberately not shared for
 330 ;;; bootstrapping reasons. If we access with accessors for the exact
 331 ;;; type, then the inline type check will win. If the inline check
 332 ;;; didn't win, we would try to use the type system before it was
 333 ;;; properly initialized.
 334 (defstruct (info-env (:constructor nil)
 335                      (:copier nil))
 336   ;; some string describing what is in this environment, for
 337   ;; printing/debugging purposes only
 338   (name (required-argument) :type string))
 339 (def!method print-object ((x info-env) stream)
 340   (print-unreadable-object (x stream :type t)
 341     (prin1 (info-env-name x) stream)))
 342 \f
 343 ;;;; generic interfaces
 344
 345 ;;; FIXME: used only in this file, needn't be in runtime
 346 (defmacro do-info ((env &key (name (gensym)) (class (gensym)) (type (gensym))
 347                         (type-number (gensym)) (value (gensym)) known-volatile)
 348                    &body body)
 349   #!+sb-doc
 350   "DO-INFO (Env &Key Name Class Type Value) Form*
 351   Iterate over all the values stored in the Info-Env Env. Name is bound to
 352   the entry's name, Class and Type are bound to the class and type
 353   (represented as keywords), and Value is bound to the entry's value."
 354   (once-only ((n-env env))
 355     (if known-volatile
 356         (do-volatile-info name class type type-number value n-env body)
 357         `(if (typep ,n-env 'volatile-info-env)
 358              ,(do-volatile-info name class type type-number value n-env body)
 359              ,(do-compact-info name class type type-number value
 360                                n-env body)))))
 361
 362 (eval-when (:compile-toplevel :load-toplevel :execute)
 363
 364 ;;; Return code to iterate over a compact info environment.
 365 (defun do-compact-info (name-var class-var type-var type-number-var value-var
 366                                  n-env body)
 367   (let ((n-index (gensym))
 368         (n-type (gensym))
 369         (punt (gensym)))
 370     (once-only ((n-table `(compact-info-env-table ,n-env))
 371                 (n-entries-index `(compact-info-env-index ,n-env))
 372                 (n-entries `(compact-info-env-entries ,n-env))
 373                 (n-entries-info `(compact-info-env-entries-info ,n-env))
 374                 (n-info-types '*info-types*))
 375       `(dotimes (,n-index (length ,n-table))
 376          (declare (type index ,n-index))
 377          (block ,PUNT
 378            (let ((,name-var (svref ,n-table ,n-index)))
 379              (unless (eql ,name-var 0)
 380                (do-anonymous ((,n-type (aref ,n-entries-index ,n-index)
 381                                        (1+ ,n-type)))
 382                              (nil)
 383                  (declare (type index ,n-type))
 384                  ,(once-only ((n-info `(aref ,n-entries-info ,n-type)))
 385                     `(let ((,type-number-var
 386                             (logand ,n-info compact-info-entry-type-mask)))
 387                        ,(once-only ((n-type-info
 388                                      `(svref ,n-info-types
 389                                              ,type-number-var)))
 390                           `(let ((,type-var (type-info-name ,n-type-info))
 391                                  (,class-var (class-info-name
 392                                               (type-info-class ,n-type-info)))
 393                                  (,value-var (svref ,n-entries ,n-type)))
 394                              (declare (ignorable ,type-var ,class-var
 395                                                  ,value-var))
 396                              ,@body
 397                              (unless (zerop (logand ,n-info
 398                                                     compact-info-entry-last))
 399                                (return-from ,PUNT))))))))))))))
 400
 401 ;;; Return code to iterate over a volatile info environment.
 402 (defun do-volatile-info (name-var class-var type-var type-number-var value-var
 403                                   n-env body)
 404   (let ((n-index (gensym)) (n-names (gensym)) (n-types (gensym)))
 405     (once-only ((n-table `(volatile-info-env-table ,n-env))
 406                 (n-info-types '*info-types*))
 407       `(dotimes (,n-index (length ,n-table))
 408          (declare (type index ,n-index))
 409          (do-anonymous ((,n-names (svref ,n-table ,n-index)
 410                                   (cdr ,n-names)))
 411                        ((null ,n-names))
 412            (let ((,name-var (caar ,n-names)))
 413              (declare (ignorable ,name-var))
 414              (do-anonymous ((,n-types (cdar ,n-names) (cdr ,n-types)))
 415                            ((null ,n-types))
 416                (let ((,type-number-var (caar ,n-types)))
 417                  ,(once-only ((n-type `(svref ,n-info-types
 418                                               ,type-number-var)))
 419                     `(let ((,type-var (type-info-name ,n-type))
 420                            (,class-var (class-info-name
 421                                         (type-info-class ,n-type)))
 422                            (,value-var (cdar ,n-types)))
 423                        (declare (ignorable ,type-var ,class-var ,value-var))
 424                        ,@body))))))))))
 425
 426 ) ; EVAL-WHEN
 427 \f
 428 ;;;; INFO cache
 429
 430 ;;;; We use a hash cache to cache name X type => value for the current
 431 ;;;; value of *INFO-ENVIRONMENT*. This is in addition to the
 432 ;;;; per-environment caching of name => types.
 433
 434 ;;; The value of *INFO-ENVIRONMENT* that has cached values.
 435 ;;; *INFO-ENVIRONMENT* should never be destructively modified, so if
 436 ;;; it is EQ to this, then the cache is valid.
 437 (defvar *cached-info-environment*)
 438 (!cold-init-forms
 439   (setf *cached-info-environment* nil))
 440
 441 ;;; the hash function used for the INFO cache
 442 #!-sb-fluid (declaim (inline info-cache-hash))
 443 (defun info-cache-hash (name type)
 444   (logand
 445     (the fixnum
 446          (logxor (globaldb-sxhashoid name)
 447                  (ash (the fixnum type) 7)))
 448     #x3FF))
 449
 450 (!cold-init-forms
 451   (/show0 "before initialization of INFO hash cache"))
 452 (define-hash-cache info ((name eq) (type eq))
 453   :values 2
 454   :hash-function info-cache-hash
 455   :hash-bits 10
 456   :default (values nil :empty)
 457   :init-wrapper !cold-init-forms)
 458 (!cold-init-forms
 459   (/show0 "clearing INFO hash cache")
 460   (info-cache-clear)
 461   (/show0 "done clearing INFO hash cache"))
 462
 463 ;;; If the info cache is invalid, then clear it.
 464 #!-sb-fluid (declaim (inline clear-invalid-info-cache))
 465 (defun clear-invalid-info-cache ()
 466   ;; Unless the cache is valid..
 467   (unless (eq *info-environment* *cached-info-environment*)
 468     (;; In the target Lisp, this should be done without interrupts,
 469      ;; but in the host Lisp when cross-compiling, we don't need to
 470      ;; sweat it, since no affected-by-GC hashes should be used when
 471      ;; running under the host Lisp (since that's non-portable) and
 472      ;; since only one thread should be used when running under the
 473      ;; host Lisp (because multiple threads are non-portable too).
 474      #-sb-xc-host without-interrupts
 475      #+sb-xc-host progn
 476       (info-cache-clear)
 477       (setq *cached-info-environment* *info-environment*))))
 478 \f
 479 ;;;; compact info environments
 480
 481 ;;; The upper limit on the size of the ENTRIES vector in a COMPACT-INFO-ENV.
 482 (defconstant compact-info-env-entries-bits 16)
 483 (deftype compact-info-entries-index () `(unsigned-byte ,compact-info-env-entries-bits))
 484
 485 ;;; the type of the values in COMPACT-INFO-ENTRIES-INFO
 486 (deftype compact-info-entry () `(unsigned-byte ,(1+ type-number-bits)))
 487
 488 ;;; This is an open hashtable with rehashing. Since modification is
 489 ;;; not allowed, we don't have to worry about deleted entries. We
 490 ;;; indirect through a parallel vector to find the index in the
 491 ;;; ENTRIES at which the entries for a given name starts.
 492 (defstruct (compact-info-env (:include info-env)
 493                              #-sb-xc-host (:pure :substructure)
 494                              (:copier nil))
 495   ;; If this value is EQ to the name we want to look up, then the
 496   ;; cache hit function can be called instead of the lookup function.
 497   (cache-name 0)
 498   ;; The index in ENTRIES for the CACHE-NAME, or NIL if that name has
 499   ;; no entries.
 500   (cache-index nil :type (or compact-info-entries-index null))
 501   ;; hashtable of the names in this environment. If a bucket is
 502   ;; unused, it is 0.
 503   (table (required-argument) :type simple-vector)
 504   ;; an indirection vector parallel to TABLE, translating indices in
 505   ;; TABLE to the start of the ENTRIES for that name. Unused entries
 506   ;; are undefined.
 507   (index (required-argument)
 508          :type (simple-array compact-info-entries-index (*)))
 509   ;; a vector contining in contiguous ranges the values of for all the
 510   ;; types of info for each name.
 511   (entries (required-argument) :type simple-vector)
 512   ;; a vector parallel to ENTRIES, indicating the type number for the
 513   ;; value stored in that location and whether this location is the
 514   ;; last type of info stored for this name. The type number is in the
 515   ;; low TYPE-NUMBER-BITS bits, and the next bit is set if this is the
 516   ;; last entry.
 517   (entries-info (required-argument)
 518                 :type (simple-array compact-info-entry (*))))
 519
 520 (defconstant compact-info-entry-type-mask (ldb (byte type-number-bits 0) -1))
 521 (defconstant compact-info-entry-last (ash 1 type-number-bits))
 522
 523 ;;; Return the value of the type corresponding to NUMBER for the
 524 ;;; currently cached name in ENV.
 525 #!-sb-fluid (declaim (inline compact-info-cache-hit))
 526 (defun compact-info-cache-hit (env number)
 527   (declare (type compact-info-env env) (type type-number number))
 528   (let ((entries-info (compact-info-env-entries-info env))
 529         (index (compact-info-env-cache-index env)))
 530     (if index
 531         (do ((index index (1+ index)))
 532             (nil)
 533           (declare (type index index))
 534           (let ((info (aref entries-info index)))
 535             (when (= (logand info compact-info-entry-type-mask) number)
 536               (return (values (svref (compact-info-env-entries env) index)
 537                               t)))
 538             (unless (zerop (logand compact-info-entry-last info))
 539               (return (values nil nil)))))
 540         (values nil nil))))
 541
 542 ;;; Encache NAME in the compact environment ENV. HASH is the
 543 ;;; GLOBALDB-SXHASHOID of NAME.
 544 (defun compact-info-lookup (env name hash)
 545   (declare (type compact-info-env env) (type index hash))
 546   (let* ((table (compact-info-env-table env))
 547          (len (length table))
 548          (len-2 (- len 2))
 549          (hash2 (- len-2 (rem hash len-2))))
 550     (declare (type index len-2 hash2))
 551     (macrolet ((lookup (test)
 552                  `(do ((probe (rem hash len)
 553                               (let ((new (+ probe hash2)))
 554                                 (declare (type index new))
 555                                 ;; same as (MOD NEW LEN), but faster.
 556                                 (if (>= new len)
 557                                     (the index (- new len))
 558                                     new))))
 559                       (nil)
 560                     (let ((entry (svref table probe)))
 561                       (when (eql entry 0)
 562                         (return nil))
 563                       (when (,test entry name)
 564                         (return (aref (compact-info-env-index env)
 565                                       probe)))))))
 566       (setf (compact-info-env-cache-index env)
 567             (if (symbolp name)
 568                 (lookup eq)
 569                 (lookup equal)))
 570       (setf (compact-info-env-cache-name env) name)))
 571
 572   (values))
 573
 574 ;;; the exact density (modulo rounding) of the hashtable in a compact
 575 ;;; info environment in names/bucket
 576 (defconstant compact-info-environment-density 65)
 577
 578 ;;; Return a new compact info environment that holds the same
 579 ;;; information as ENV.
 580 (defun compact-info-environment (env &key (name (info-env-name env)))
 581   (let ((name-count 0)
 582         (prev-name 0)
 583         (entry-count 0))
 584     (/show0 "before COLLECT in COMPACT-INFO-ENVIRONMENT")
 585
 586     ;; Iterate over the environment once to find out how many names
 587     ;; and entries it has, then build the result. This code assumes
 588     ;; that all the entries for a name well be iterated over
 589     ;; contiguously, which holds true for the implementation of
 590     ;; iteration over both kinds of environments.
 591     (collect ((names))
 592
 593       (/show0 "at head of COLLECT in COMPACT-INFO-ENVIRONMENT")
 594       (let ((types ()))
 595         (do-info (env :name name :type-number num :value value)
 596           (/noshow0 "at head of DO-INFO in COMPACT-INFO-ENVIRONMENT")
 597           (unless (eq name prev-name)
 598             (/noshow0 "not (EQ NAME PREV-NAME) case")
 599             (incf name-count)
 600             (unless (eql prev-name 0)
 601               (names (cons prev-name types)))
 602             (setq prev-name name)
 603             (setq types ()))
 604           (incf entry-count)
 605           (push (cons num value) types))
 606         (unless (eql prev-name 0)
 607           (/show0 "not (EQL PREV-NAME 0) case")
 608           (names (cons prev-name types))))
 609
 610       ;; Now that we know how big the environment is, we can build
 611       ;; a table to represent it.
 612       ;;
 613       ;; When building the table, we sort the entries by pointer
 614       ;; comparison in an attempt to preserve any VM locality present
 615       ;; in the original load order, rather than randomizing with the
 616       ;; original hash function.
 617       (/show0 "about to make/sort vectors in COMPACT-INFO-ENVIRONMENT")
 618       (let* ((table-size (primify
 619                           (+ (truncate (* name-count 100)
 620                                        compact-info-environment-density)
 621                              3)))
 622              (table (make-array table-size :initial-element 0))
 623              (index (make-array table-size
 624                                 :element-type 'compact-info-entries-index))
 625              (entries (make-array entry-count))
 626              (entries-info (make-array entry-count
 627                                        :element-type 'compact-info-entry))
 628              (sorted (sort (names)
 629                            #+sb-xc-host #'<
 630                            ;; (This MAKE-FIXNUM hack implements
 631                            ;; pointer comparison, as explained above.)
 632                            #-sb-xc-host (lambda (x y)
 633                                           (< (%primitive make-fixnum x)
 634                                              (%primitive make-fixnum y))))))
 635         (/show0 "done making/sorting vectors in COMPACT-INFO-ENVIRONMENT")
 636         (let ((entries-idx 0))
 637           (dolist (types sorted)
 638             (let* ((name (first types))
 639                    (hash (globaldb-sxhashoid name))
 640                    (len-2 (- table-size 2))
 641                    (hash2 (- len-2 (rem hash len-2))))
 642               (do ((probe (rem hash table-size)
 643                           (rem (+ probe hash2) table-size)))
 644                   (nil)
 645                 (let ((entry (svref table probe)))
 646                   (when (eql entry 0)
 647                     (setf (svref table probe) name)
 648                     (setf (aref index probe) entries-idx)
 649                     (return))
 650                   (aver (not (equal entry name))))))
 651
 652             (unless (zerop entries-idx)
 653               (setf (aref entries-info (1- entries-idx))
 654                     (logior (aref entries-info (1- entries-idx))
 655                             compact-info-entry-last)))
 656
 657             (loop for (num . value) in (rest types) do
 658               (setf (aref entries-info entries-idx) num)
 659               (setf (aref entries entries-idx) value)
 660               (incf entries-idx)))
 661           (/show0 "done w/ DOLIST (TYPES SORTED) in COMPACT-INFO-ENVIRONMENT")
 662
 663           (unless (zerop entry-count)
 664             (/show0 "nonZEROP ENTRY-COUNT")
 665             (setf (aref entries-info (1- entry-count))
 666                   (logior (aref entries-info (1- entry-count))
 667                           compact-info-entry-last)))
 668
 669           (/show0 "falling through to MAKE-COMPACT-INFO-ENV")
 670           (make-compact-info-env :name name
 671                                  :table table
 672                                  :index index
 673                                  :entries entries
 674                                  :entries-info entries-info))))))
 675 \f
 676 ;;;; volatile environments
 677
 678 ;;; This is a closed hashtable, with the bucket being computed by
 679 ;;; taking the GLOBALDB-SXHASHOID of the NAME modulo the table size.
 680 (defstruct (volatile-info-env (:include info-env)
 681                               (:copier nil))
 682   ;; If this value is EQ to the name we want to look up, then the
 683   ;; cache hit function can be called instead of the lookup function.
 684   (cache-name 0)
 685   ;; the alist translating type numbers to values for the currently
 686   ;; cached name
 687   (cache-types nil :type list)
 688   ;; vector of alists of alists of the form:
 689   ;;    ((Name . ((Type-Number . Value) ...) ...)
 690   (table (required-argument) :type simple-vector)
 691   ;; the number of distinct names currently in this table. Each name
 692   ;; may have multiple entries, since there can be many types of info.
 693   (count 0 :type index)
 694   ;; the number of names at which we should grow the table and rehash
 695   (threshold 0 :type index))
 696
 697 ;;; Just like COMPACT-INFO-CACHE-HIT, only do it on a volatile environment.
 698 #!-sb-fluid (declaim (inline volatile-info-cache-hit))
 699 (defun volatile-info-cache-hit (env number)
 700   (declare (type volatile-info-env env) (type type-number number))
 701   (dolist (type (volatile-info-env-cache-types env) (values nil nil))
 702     (when (eql (car type) number)
 703       (return (values (cdr type) t)))))
 704
 705 ;;; Just like COMPACT-INFO-LOOKUP, only do it on a volatile environment.
 706 (defun volatile-info-lookup (env name hash)
 707   (declare (type volatile-info-env env) (type index hash))
 708   (let ((table (volatile-info-env-table env)))
 709     (macrolet ((lookup (test)
 710                  `(dolist (entry (svref table (mod hash (length table))) ())
 711                     (when (,test (car entry) name)
 712                       (return (cdr entry))))))
 713       (setf (volatile-info-env-cache-types env)
 714             (if (symbolp name)
 715                 (lookup eq)
 716                 (lookup equal)))
 717       (setf (volatile-info-env-cache-name env) name)))
 718
 719   (values))
 720
 721 ;;; Given a volatile environment Env, bind Table-Var the environment's table
 722 ;;; and Index-Var to the index of Name's bucket in the table. We also flush
 723 ;;; the cache so that things will be consistent if body modifies something.
 724 (eval-when (:compile-toplevel :execute)
 725   (#+sb-xc-host cl:defmacro
 726    #-sb-xc-host sb!xc:defmacro
 727       with-info-bucket ((table-var index-var name env) &body body)
 728     (once-only ((n-name name)
 729                 (n-env env))
 730       `(progn
 731          (setf (volatile-info-env-cache-name ,n-env) 0)
 732          (let* ((,table-var (volatile-info-env-table ,n-env))
 733                 (,index-var (mod (globaldb-sxhashoid ,n-name)
 734                                  (length ,table-var))))
 735            ,@body)))))
 736
 737 ;;; Get the info environment that we use for write/modification operations.
 738 ;;; This is always the first environment in the list, and must be a
 739 ;;; VOLATILE-INFO-ENV.
 740 #!-sb-fluid (declaim (inline get-write-info-env))
 741 (defun get-write-info-env (&optional (env-list *info-environment*))
 742   (let ((env (car env-list)))
 743     (unless env
 744       (error "no info environment?"))
 745     (unless (typep env 'volatile-info-env)
 746       (error "cannot modify this environment: ~S" env))
 747     (the volatile-info-env env)))
 748
 749 ;;; If Name is already present in the table, then just create or
 750 ;;; modify the specified type. Otherwise, add the new name and type,
 751 ;;; checking for rehashing.
 752 ;;;
 753 ;;; We rehash by making a new larger environment, copying all of the
 754 ;;; entries into it, then clobbering the old environment with the new
 755 ;;; environment's table. We clear the old table to prevent it from
 756 ;;; holding onto garbage if it is statically allocated.
 757 ;;;
 758 ;;; We return the new value so that this can be conveniently used in a
 759 ;;; SETF function.
 760 (defun set-info-value (name0 type new-value
 761                              &optional (env (get-write-info-env)))
 762   (declare (type type-number type) (type volatile-info-env env)
 763            (inline assoc))
 764   (let ((name (uncross name0)))
 765     (when (eql name 0)
 766       (error "0 is not a legal INFO name."))
 767     ;; We don't enter the value in the cache because we don't know that this
 768     ;; info-environment is part of *cached-info-environment*.
 769     (info-cache-enter name type nil :empty)
 770     (with-info-bucket (table index name env)
 771       (let ((types (if (symbolp name)
 772                        (assoc name (svref table index) :test #'eq)
 773                        (assoc name (svref table index) :test #'equal))))
 774         (cond
 775          (types
 776           (let ((value (assoc type (cdr types))))
 777             (if value
 778                 (setf (cdr value) new-value)
 779                 (push (cons type new-value) (cdr types)))))
 780          (t
 781           (push (cons name (list (cons type new-value)))
 782                 (svref table index))
 783
 784           (let ((count (incf (volatile-info-env-count env))))
 785             (when (>= count (volatile-info-env-threshold env))
 786               (let ((new (make-info-environment :size (* count 2))))
 787                 (do-info (env :name entry-name :type-number entry-num
 788                               :value entry-val :known-volatile t)
 789                          (set-info-value entry-name entry-num entry-val new))
 790                 (fill (volatile-info-env-table env) nil)
 791                 (setf (volatile-info-env-table env)
 792                       (volatile-info-env-table new))
 793                 (setf (volatile-info-env-threshold env)
 794                       (volatile-info-env-threshold new)))))))))
 795     new-value))
 796
 797 ;;; FIXME: It should be possible to eliminate the hairy compiler macros below
 798 ;;; by declaring INFO and (SETF INFO) inline and making a simple compiler macro
 799 ;;; for TYPE-INFO-OR-LOSE. (If we didn't worry about efficiency of the
 800 ;;; cross-compiler, we could even do it by just making TYPE-INFO-OR-LOSE
 801 ;;; foldable.)
 802
 803 ;;; INFO is the standard way to access the database. It's settable.
 804 ;;;
 805 ;;; Return the information of the specified TYPE and CLASS for NAME.
 806 ;;; The second value returned is true if there is any such information
 807 ;;; recorded. If there is no information, the first value returned is
 808 ;;; the default and the second value returned is NIL.
 809 (defun info (class type name &optional (env-list nil env-list-p))
 810   ;; FIXME: At some point check systematically to make sure that the
 811   ;; system doesn't do any full calls to INFO or (SETF INFO), or at
 812   ;; least none in any inner loops.
 813   (let ((info (type-info-or-lose class type)))
 814     (if env-list-p
 815         (get-info-value name (type-info-number info) env-list)
 816         (get-info-value name (type-info-number info)))))
 817 #!-sb-fluid
 818 (define-compiler-macro info
 819   (&whole whole class type name &optional (env-list nil env-list-p))
 820   ;; Constant CLASS and TYPE is an overwhelmingly common special case,
 821   ;; and we can implement it much more efficiently than the general case.
 822   (if (and (constantp class) (constantp type))
 823       (let ((info (type-info-or-lose class type))
 824             (value (gensym "VALUE"))
 825             (foundp (gensym "FOUNDP")))
 826         `(multiple-value-bind (,value ,foundp)
 827              (get-info-value ,name
 828                              ,(type-info-number info)
 829                              ,@(when env-list-p `(,env-list)))
 830            (declare (type ,(type-info-type info) ,value))
 831            (values ,value ,foundp)))
 832       whole))
 833 (defun (setf info) (new-value
 834                     class
 835                     type
 836                     name
 837                     &optional (env-list nil env-list-p))
 838   (let* ((info (type-info-or-lose class type))
 839          (tin (type-info-number info)))
 840     (if env-list-p
 841       (set-info-value name
 842                       tin
 843                       new-value
 844                       (get-write-info-env env-list))
 845       (set-info-value name
 846                       tin
 847                       new-value)))
 848   new-value)
 849 ;;; FIXME: We'd like to do this, but Python doesn't support
 850 ;;; compiler macros and it's hard to change it so that it does.
 851 ;;; It might make more sense to just convert INFO :FOO :BAR into
 852 ;;; an ordinary function, so that instead of calling INFO :FOO :BAR
 853 ;;; you call e.g. INFO%FOO%BAR. Then dynamic linking could be handled
 854 ;;; by the ordinary Lisp mechanisms and we wouldn't have to maintain
 855 ;;; all this cruft..
 856 #|
 857 #!-sb-fluid
 858 (progn
 859   (define-compiler-macro (setf info) (&whole whole
 860                                       new-value
 861                                       class
 862                                       type
 863                                       name
 864                                       &optional (env-list nil env-list-p))
 865     ;; Constant CLASS and TYPE is an overwhelmingly common special case, and we
 866     ;; can resolve it much more efficiently than the general case.
 867     (if (and (constantp class) (constantp type))
 868         (let* ((info (type-info-or-lose class type))
 869                (tin (type-info-number info)))
 870           (if env-list-p
 871               `(set-info-value ,name
 872                                ,tin
 873                                ,new-value
 874                                (get-write-info-env ,env-list))
 875               `(set-info-value ,name
 876                                ,tin
 877                                ,new-value)))
 878         whole)))
 879 |#
 880
 881 ;;; the maximum density of the hashtable in a volatile env (in
 882 ;;; names/bucket)
 883 ;;;
 884 ;;; FIXME: actually seems to be measured in percent, should be
 885 ;;; converted to be measured in names/bucket
 886 (defconstant volatile-info-environment-density 50)
 887
 888 ;;; Make a new volatile environment of the specified size.
 889 (defun make-info-environment (&key (size 42) (name "Unknown"))
 890   (declare (type (integer 1) size))
 891   (let ((table-size (primify (truncate (* size 100)
 892                                        volatile-info-environment-density))))
 893     (make-volatile-info-env :name name
 894                             :table (make-array table-size :initial-element nil)
 895                             :threshold size)))
 896
 897 ;;; Clear the information of the specified TYPE and CLASS for NAME in
 898 ;;; the current environment, allowing any inherited info to become
 899 ;;; visible. We return true if there was any info.
 900 (defun clear-info (class type name)
 901   #!+sb-doc
 902   (let ((info (type-info-or-lose class type)))
 903     (clear-info-value name (type-info-number info))))
 904 #!-sb-fluid
 905 (define-compiler-macro clear-info (&whole whole class type name)
 906   ;; Constant CLASS and TYPE is an overwhelmingly common special case, and
 907   ;; we can resolve it much more efficiently than the general case.
 908   (if (and (keywordp class) (keywordp type))
 909     (let ((info (type-info-or-lose class type)))
 910       `(clear-info-value ,name ,(type-info-number info)))
 911     whole))
 912 (defun clear-info-value (name type)
 913   (declare (type type-number type) (inline assoc))
 914   (clear-invalid-info-cache)
 915   (info-cache-enter name type nil :empty)
 916   (with-info-bucket (table index name (get-write-info-env))
 917     (let ((types (assoc name (svref table index) :test #'equal)))
 918       (when (and types
 919                  (assoc type (cdr types)))
 920         (setf (cdr types)
 921               (delete type (cdr types) :key #'car))
 922         t))))
 923 \f
 924 ;;;; *INFO-ENVIRONMENT*
 925
 926 ;;; We do info access relative to the current *INFO-ENVIRONMENT*, a
 927 ;;; list of INFO-ENVIRONMENT structures.
 928 (defvar *info-environment*)
 929 (declaim (type list *info-environment*))
 930 (!cold-init-forms
 931   (setq *info-environment*
 932         (list (make-info-environment :name "initial global")))
 933   (/show0 "done setting *INFO-ENVIRONMENT*"))
 934 ;;; FIXME: should perhaps be *INFO-ENV-LIST*. And rename
 935 ;;; all FOO-INFO-ENVIRONMENT-BAR stuff to FOO-INFO-ENV-BAR.
 936 \f
 937 ;;;; GET-INFO-VALUE
 938
 939 ;;; Check whether the name and type is in our cache, if so return it.
 940 ;;; Otherwise, search for the value and encache it.
 941 ;;;
 942 ;;; Return the value from the first environment which has it defined,
 943 ;;; or return the default if none does. We have a cache for the last
 944 ;;; name looked up in each environment. We don't compute the hash
 945 ;;; until the first time the cache misses. When the cache does miss,
 946 ;;; we invalidate it before calling the lookup routine to eliminate
 947 ;;; the possibility of the cache being partially updated if the lookup
 948 ;;; is interrupted.
 949 (defun get-info-value (name0 type &optional (env-list nil env-list-p))
 950   (declare (type type-number type))
 951   ;; sanity check: If we have screwed up initialization somehow, then
 952   ;; *INFO-TYPES* could still be uninitialized at the time we try to
 953   ;; get an info value, and then we'd be out of luck. (This happened,
 954   ;; and was confusing to debug, when rewriting EVAL-WHEN in
 955   ;; sbcl-0.pre7.x.)
 956   (aver (aref *info-types* type))
 957   (let ((name (uncross name0)))
 958     (flet ((lookup-ignoring-global-cache (env-list)
 959              (let ((hash nil))
 960                (dolist (env env-list
 961                             (multiple-value-bind (val winp)
 962                                 (funcall (type-info-default
 963                                           (svref *info-types* type))
 964                                          name)
 965                               (values val winp)))
 966                  (macrolet ((frob (lookup cache slot)
 967                               `(progn
 968                                  (unless (eq name (,slot env))
 969                                    (unless hash
 970                                      (setq hash (globaldb-sxhashoid name)))
 971                                    (setf (,slot env) 0)
 972                                    (,lookup env name hash))
 973                                  (multiple-value-bind (value winp)
 974                                      (,cache env type)
 975                                    (when winp (return (values value t)))))))
 976                    (etypecase env
 977                      (volatile-info-env (frob
 978                                          volatile-info-lookup
 979                                          volatile-info-cache-hit
 980                                          volatile-info-env-cache-name))
 981                      (compact-info-env (frob
 982                                         compact-info-lookup
 983                                         compact-info-cache-hit
 984                                         compact-info-env-cache-name))))))))
 985       (cond (env-list-p
 986              (lookup-ignoring-global-cache env-list))
 987             (t
 988              (clear-invalid-info-cache)
 989              (multiple-value-bind (val winp) (info-cache-lookup name type)
 990                (if (eq winp :empty)
 991                    (multiple-value-bind (val winp)
 992                        (lookup-ignoring-global-cache *info-environment*)
 993                      (info-cache-enter name type val winp)
 994                      (values val winp))
 995                    (values val winp))))))))
 996 \f
 997 ;;;; definitions for function information
 998
 999 (define-info-class :function)
1000
1001 ;;; the kind of functional object being described. If null, NAME isn't
1002 ;;; a known functional object.
1003 (define-info-type
1004   :class :function
1005   :type :kind
1006   :type-spec (member nil :function :macro :special-form)
1007   ;; I'm a little confused what the correct behavior of this default
1008   ;; is. It's not clear how to generalize the FBOUNDP expression to
1009   ;; the cross-compiler. As far as I can tell, NIL is a safe default
1010   ;; -- it might keep the compiler from making some valid
1011   ;; optimization, but it shouldn't produce incorrect code. -- WHN
1012   ;; 19990330
1013   :default
1014   #+sb-xc-host nil
1015   #-sb-xc-host (if (fboundp name) :function nil))
1016
1017 ;;; The type specifier for this function.
1018 (define-info-type
1019   :class :function
1020   :type :type
1021   :type-spec ctype
1022   ;; Again (as in DEFINE-INFO-TYPE :CLASS :FUNCTION :TYPE :KIND) it's
1023   ;; not clear how to generalize the FBOUNDP expression to the
1024   ;; cross-compiler. -- WHN 19990330
1025   :default
1026   #+sb-xc-host (specifier-type 'function)
1027   #-sb-xc-host (if (fboundp name)
1028                    (extract-fun-type (fdefinition name))
1029                    (specifier-type 'function)))
1030
1031 ;;; the ASSUMED-TYPE for this function, if we have to infer the type
1032 ;;; due to not having a declaration or definition
1033 (define-info-type
1034   :class :function
1035   :type :assumed-type
1036   ;; FIXME: The type-spec really should be
1037   ;;   (or approximate-fun-type null)).
1038   ;; It was changed to T as a hopefully-temporary hack while getting
1039   ;; cold init problems untangled.
1040   :type-spec t)
1041
1042 ;;; where this information came from:
1043 ;;;    :ASSUMED  = from uses of the object
1044 ;;;    :DEFINED  = from examination of the definition
1045 ;;;    :DECLARED = from a declaration
1046 ;;; :DEFINED trumps :ASSUMED, and :DECLARED trumps :DEFINED.
1047 ;;; :DEFINED and :ASSUMED are useful for issuing compile-time warnings,
1048 ;;; and :DECLARED is useful for ANSIly specializing code which
1049 ;;; implements the function, or which uses the function's return values.
1050 (define-info-type
1051   :class :function
1052   :type :where-from
1053   :type-spec (member :declared :assumed :defined)
1054   :default
1055   ;; Again (as in DEFINE-INFO-TYPE :CLASS :FUNCTION :TYPE :KIND) it's
1056   ;; not clear how to generalize the FBOUNDP expression to the
1057   ;; cross-compiler. -- WHN 19990606
1058   #+sb-xc-host :assumed
1059   #-sb-xc-host (if (fboundp name) :defined :assumed))
1060
1061 ;;; something which can be decoded into the inline expansion of the
1062 ;;; function, or NIL if there is none
1063 ;;;
1064 ;;; To inline a function, we want a lambda expression, e.g.
1065 ;;; '(LAMBDA (X) (+ X 1)). That can be encoded here in one of two
1066 ;;; ways.
1067 ;;;   * The value in INFO can be the lambda expression itself, e.g.
1068 ;;;       (SETF (INFO :FUNCTION :INLINE-EXPANSION-DESIGNATOR 'FOO)
1069 ;;;             '(LAMBDA (X) (+ X 1)))
1070 ;;;     This is the ordinary way, the natural way of representing e.g.
1071 ;;;       (DECLAIM (INLINE FOO))
1072 ;;;       (DEFUN FOO (X) (+ X 1))
1073 ;;;   * The value in INFO can be a closure which returns the lambda
1074 ;;;     expression, e.g.
1075 ;;;       (SETF (INFO :FUNCTION :INLINE-EXPANSION-DESIGNATOR 'BAR-LEFT-CHILD)
1076 ;;;             (LAMBDA ()
1077 ;;;               '(LAMBDA (BAR) (BAR-REF BAR 3))))
1078 ;;;     This twisty way of storing values is supported in order to
1079 ;;;     allow structure slot accessors, and perhaps later other
1080 ;;;     stereotyped functions, to be represented compactly.
1081 (define-info-type
1082   :class :function
1083   :type :inline-expansion-designator
1084   :type-spec (or list function)
1085   :default nil)
1086
1087 ;;; This specifies whether this function may be expanded inline. If
1088 ;;; null, we don't care.
1089 (define-info-type
1090   :class :function
1091   :type :inlinep
1092   :type-spec inlinep
1093   :default nil)
1094
1095 ;;; a macro-like function which transforms a call to this function
1096 ;;; into some other Lisp form. This expansion is inhibited if inline
1097 ;;; expansion is inhibited
1098 (define-info-type
1099   :class :function
1100   :type :source-transform
1101   :type-spec (or function null))
1102
1103 ;;; the macroexpansion function for this macro
1104 (define-info-type
1105   :class :function
1106   :type :macro-function
1107   :type-spec (or function null)
1108   :default nil)
1109
1110 ;;; the compiler-macroexpansion function for this macro
1111 (define-info-type
1112   :class :function
1113   :type :compiler-macro-function
1114   :type-spec (or function null)
1115   :default nil)
1116
1117 ;;; a function which converts this special form into IR1
1118 (define-info-type
1119   :class :function
1120   :type :ir1-convert
1121   :type-spec (or function null))
1122
1123 ;;; a function which gets a chance to do stuff to the IR1 for any call
1124 ;;; to this function.
1125 (define-info-type
1126   :class :function
1127   :type :ir1-transform
1128   :type-spec (or function null))
1129
1130 ;;; If a function is "known" to the compiler, then this is a
1131 ;;; FUNCTION-INFO structure containing the info used to special-case
1132 ;;; compilation.
1133 (define-info-type
1134   :class :function
1135   :type :info
1136   :type-spec (or function-info null)
1137   :default nil)
1138
1139 (define-info-type
1140   :class :function
1141   :type :documentation
1142   :type-spec (or string null)
1143   :default nil)
1144
1145 (define-info-type
1146   :class :function
1147   :type :definition
1148   :type-spec t
1149   :default nil)
1150 \f
1151 ;;;; definitions for other miscellaneous information
1152
1153 (define-info-class :variable)
1154
1155 ;;; the kind of variable-like thing described
1156 (define-info-type
1157   :class :variable
1158   :type :kind
1159   :type-spec (member :special :constant :global :alien)
1160   :default (if (symbol-self-evaluating-p name)
1161                :constant
1162                :global))
1163
1164 ;;; the declared type for this variable
1165 (define-info-type
1166   :class :variable
1167   :type :type
1168   :type-spec ctype
1169   :default *universal-type*)
1170
1171 ;;; where this type and kind information came from
1172 (define-info-type
1173   :class :variable
1174   :type :where-from
1175   :type-spec (member :declared :assumed :defined)
1176   :default :assumed)
1177
1178 ;;; the Lisp object which is the value of this constant, if known
1179 (define-info-type
1180   :class :variable
1181   :type :constant-value
1182   :type-spec t
1183   ;; CMU CL used to return two values for (INFO :VARIABLE :CONSTANT-VALUE ..).
1184   ;; Now we don't: it was the last remaining multiple-value return from
1185   ;; the INFO system, and bringing it down to one value lets us simplify
1186   ;; things, especially simplifying the declaration of return types.
1187   ;; Software which used to check the second value (for "is it defined
1188   ;; as a constant?") should check (EQL (INFO :VARIABLE :KIND ..) :CONSTANT)
1189   ;; instead.
1190   :default (if (symbol-self-evaluating-p name)
1191                name
1192                (error "internal error: constant lookup of nonconstant ~S"
1193                       name)))
1194
1195 (define-info-type
1196   :class :variable
1197   :type :alien-info
1198   :type-spec (or heap-alien-info null)
1199   :default nil)
1200
1201 (define-info-type
1202   :class :variable
1203   :type :documentation
1204   :type-spec (or string null)
1205   :default nil)
1206
1207 (define-info-class :type)
1208
1209 ;;; the kind of type described. We return :INSTANCE for standard types
1210 ;;; that are implemented as structures.
1211 (define-info-type
1212   :class :type
1213   :type :kind
1214   :type-spec (member :primitive :defined :instance nil)
1215   :default nil)
1216
1217 ;;; the expander function for a defined type
1218 (define-info-type
1219   :class :type
1220   :type :expander
1221   :type-spec (or function null)
1222   :default nil)
1223
1224 (define-info-type
1225   :class :type
1226   :type :documentation
1227   :type-spec (or string null))
1228
1229 ;;; function that parses type specifiers into CTYPE structures
1230 (define-info-type
1231   :class :type
1232   :type :translator
1233   :type-spec (or function null)
1234   :default nil)
1235
1236 ;;; If true, then the type coresponding to this name. Note that if
1237 ;;; this is a built-in class with a translation, then this is the
1238 ;;; translation, not the class object. This info type keeps track of
1239 ;;; various atomic types (NIL etc.) and also serves as a cache to
1240 ;;; ensure that common standard types (atomic and otherwise) are only
1241 ;;; consed once.
1242 (define-info-type
1243   :class :type
1244   :type :builtin
1245   :type-spec (or ctype null)
1246   :default nil)
1247
1248 ;;; If this is a class name, then the value is a cons (NAME . CLASS),
1249 ;;; where CLASS may be null if the class hasn't been defined yet. Note
1250 ;;; that for built-in classes, the kind may be :PRIMITIVE and not
1251 ;;; :INSTANCE. The the name is in the cons so that we can signal a
1252 ;;; meaningful error if we only have the cons.
1253 (define-info-type
1254   :class :type
1255   :type :class
1256   :type-spec (or sb!kernel::class-cell null)
1257   :default nil)
1258
1259 ;;; layout for this type being used by the compiler
1260 (define-info-type
1261   :class :type
1262   :type :compiler-layout
1263   :type-spec (or layout null)
1264   :default (let ((class (sb!xc:find-class name nil)))
1265              (when class (class-layout class))))
1266
1267 (define-info-class :typed-structure)
1268 (define-info-type
1269   :class :typed-structure
1270   :type :info
1271   :type-spec t
1272   :default nil)
1273
1274 (define-info-class :declaration)
1275 (define-info-type
1276   :class :declaration
1277   :type :recognized
1278   :type-spec boolean)
1279
1280 (define-info-class :alien-type)
1281 (define-info-type
1282   :class :alien-type
1283   :type :kind
1284   :type-spec (member :primitive :defined :unknown)
1285   :default :unknown)
1286 (define-info-type
1287   :class :alien-type
1288   :type :translator
1289   :type-spec (or function null)
1290   :default nil)
1291 (define-info-type
1292   :class :alien-type
1293   :type :definition
1294   :type-spec (or alien-type null)
1295   :default nil)
1296 (define-info-type
1297   :class :alien-type
1298   :type :struct
1299   :type-spec (or alien-type null)
1300   :default nil)
1301 (define-info-type
1302   :class :alien-type
1303   :type :union
1304   :type-spec (or alien-type null)
1305   :default nil)
1306 (define-info-type
1307   :class :alien-type
1308   :type :enum
1309   :type-spec (or alien-type null)
1310   :default nil)
1311
1312 (define-info-class :setf)
1313
1314 (define-info-type
1315   :class :setf
1316   :type :inverse
1317   :type-spec (or symbol null)
1318   :default nil)
1319
1320 (define-info-type
1321   :class :setf
1322   :type :documentation
1323   :type-spec (or string null)
1324   :default nil)
1325
1326 (define-info-type
1327   :class :setf
1328   :type :expander
1329   :type-spec (or function null)
1330   :default nil)
1331
1332 ;;; This is used for storing miscellaneous documentation types. The
1333 ;;; stuff is an alist translating documentation kinds to values.
1334 (define-info-class :random-documentation)
1335 (define-info-type
1336   :class :random-documentation
1337   :type :stuff
1338   :type-spec list
1339   :default ())
1340
1341 #!-sb-fluid (declaim (freeze-type info-env))
1342 \f
1343 ;;; Now that we have finished initializing *INFO-CLASSES* and
1344 ;;; *INFO-TYPES* (at compile time), generate code to set them at cold
1345 ;;; load time to the same state they have currently.
1346 (!cold-init-forms
1347   (/show0 "beginning *INFO-CLASSES* init, calling MAKE-HASH-TABLE")
1348   (setf *info-classes*
1349         (make-hash-table :size #.(hash-table-size *info-classes*)))
1350   (/show0 "done with MAKE-HASH-TABLE in *INFO-CLASSES* init")
1351   (dolist (class-info-name '#.(let ((result nil))
1352                                 (maphash (lambda (key value)
1353                                            (declare (ignore value))
1354                                            (push key result))
1355                                          *info-classes*)
1356                                 result))
1357     (let ((class-info (make-class-info class-info-name)))
1358       (setf (gethash class-info-name *info-classes*)
1359             class-info)))
1360   (/show0 "done with *INFO-CLASSES* initialization")
1361   (/show0 "beginning *INFO-TYPES* initialization")
1362   (setf *info-types*
1363         (map 'vector
1364              (lambda (x)
1365                (/show0 "in LAMBDA (X), X=..")
1366                (/hexstr x)
1367                (when x
1368                  (let* ((class-info (class-info-or-lose (second x)))
1369                         (type-info (make-type-info :name (first x)
1370                                                    :class class-info
1371                                                    :number (third x)
1372                                                    :type (fourth x))))
1373                    (/show0 "got CLASS-INFO in LAMBDA (X)")
1374                    (push type-info (class-info-types class-info))
1375                    type-info)))
1376              '#.(map 'list
1377                      (lambda (info-type)
1378                        (when info-type
1379                          (list (type-info-name info-type)
1380                                (class-info-name (type-info-class info-type))
1381                                (type-info-number info-type)
1382                                (type-info-type info-type))))
1383                      *info-types*)))
1384   (/show0 "done with *INFO-TYPES* initialization"))
1385
1386 ;;; At cold load time, after the INFO-TYPE objects have been created,
1387 ;;; we can set their DEFAULT and TYPE slots.
1388 (macrolet ((frob ()
1389              `(!cold-init-forms
1390                 ,@(reverse *reversed-type-info-init-forms*))))
1391   (frob))
1392 \f
1393 ;;;; a hack for detecting
1394 ;;;;   (DEFUN FOO (X Y)
1395 ;;;;     ..
1396 ;;;;     (SETF (BAR A FFH) 12) ; compiles to a call to #'(SETF BAR)
1397 ;;;;     ..)
1398 ;;;;   (DEFSETF BAR SET-BAR) ; can't influence previous compilation
1399 ;;;;
1400 ;;;; KLUDGE: Arguably it should be another class/type combination in
1401 ;;;; the globaldb. However, IMHO the whole globaldb/fdefinition
1402 ;;;; treatment of SETF functions is a mess which ought to be
1403 ;;;; rewritten, and I'm not inclined to mess with it short of that. So
1404 ;;;; I just put this bag on the side of it instead..
1405
1406 ;;; true for symbols FOO which have been assumed to have '(SETF FOO)
1407 ;;; bound to a function
1408 (defvar *setf-assumed-fboundp*)
1409 (!cold-init-forms (setf *setf-assumed-fboundp* (make-hash-table)))
1410 \f
1411 (!defun-from-collected-cold-init-forms !globaldb-cold-init)