src/compiler/gtn.lisp

   1 ;;;; This file contains the GTN pass in the compiler. GTN allocates
   2 ;;;; the TNs that hold the values of lexical variables and determines
   3 ;;;; the calling conventions and passing locations used in function
   4 ;;;; calls.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 ;;; We make a pass over the component's environments, assigning argument
  18 ;;; passing locations and return conventions and TNs for local variables.
  19 (defun gtn-analyze (component)
  20   (setf (component-info component) (make-ir2-component))
  21   (let ((funs (component-lambdas component)))
  22     (dolist (fun funs)
  23       (assign-ir2-physenv fun)
  24       (assign-return-locations fun)
  25       (assign-ir2-nlx-info fun)
  26       (assign-lambda-var-tns fun nil)
  27       (dolist (let (lambda-lets fun))
  28         (assign-lambda-var-tns let t))))
  29
  30   (values))
  31
  32 ;;; We have to allocate the home TNs for variables before we can call
  33 ;;; ASSIGN-IR2-PHYSENV so that we can close over TNs that haven't
  34 ;;; had their home environment assigned yet. Here we evaluate the
  35 ;;; DEBUG-INFO/SPEED tradeoff to determine how variables are
  36 ;;; allocated. If SPEED is 3, then all variables are subject to
  37 ;;; lifetime analysis. Otherwise, only LET-P variables are allocated
  38 ;;; normally, and that can be inhibited by DEBUG-INFO = 3.
  39 (defun assign-lambda-var-tns (fun let-p)
  40   (declare (type clambda fun))
  41   (dolist (var (lambda-vars fun))
  42     (when (leaf-refs var)
  43       (let* ((type (if (lambda-var-indirect var)
  44                        *backend-t-primitive-type*
  45                        (primitive-type (leaf-type var))))
  46              (temp (make-normal-tn type))
  47              (node (lambda-bind fun))
  48              (res (if (or (and let-p (policy node (< debug 3)))
  49                           (policy node (zerop debug))
  50                           (policy node (= speed 3)))
  51                       temp
  52                       (physenv-debug-live-tn temp (lambda-physenv fun)))))
  53         (setf (tn-leaf res) var)
  54         (setf (leaf-info var) res))))
  55   (values))
  56
  57 ;;; Give CLAMBDA an IR2-PHYSENV structure. (And in order to
  58 ;;; properly initialize the new structure, we make the TNs which hold
  59 ;;; environment values and the old-FP/return-PC.)
  60 (defun assign-ir2-physenv (clambda)
  61   (declare (type clambda clambda))
  62   (let ((lambda-physenv (lambda-physenv clambda))
  63         (reversed-ir2-physenv-alist nil))
  64     ;; FIXME: should be MAPCAR, not DOLIST
  65     (dolist (thing (physenv-closure lambda-physenv))
  66       (let ((ptype (etypecase thing
  67                      (lambda-var
  68                       (if (lambda-var-indirect thing)
  69                           *backend-t-primitive-type*
  70                           (primitive-type (leaf-type thing))))
  71                      (nlx-info *backend-t-primitive-type*))))
  72         (push (cons thing (make-normal-tn ptype))
  73               reversed-ir2-physenv-alist)))
  74
  75     (let ((res (make-ir2-physenv
  76                 :closure (nreverse reversed-ir2-physenv-alist)
  77                 :return-pc-pass (make-return-pc-passing-location
  78                                  (xep-p clambda)))))
  79       (setf (physenv-info lambda-physenv) res)
  80       (setf (ir2-physenv-old-fp res)
  81             (make-old-fp-save-location lambda-physenv))
  82       (setf (ir2-physenv-return-pc res)
  83             (make-return-pc-save-location lambda-physenv))))
  84
  85   (values))
  86
  87 ;;; Return true if FUN's result is used in a tail-recursive full
  88 ;;; call. We only consider explicit :FULL calls. It is assumed that
  89 ;;; known calls are never part of a tail-recursive loop, so we don't
  90 ;;; need to enforce tail-recursion. In any case, we don't know which
  91 ;;; known calls will actually be full calls until after LTN.
  92 (defun has-full-call-use (fun)
  93   (declare (type clambda fun))
  94   (let ((return (lambda-return fun)))
  95     (and return
  96          (do-uses (use (return-result return) nil)
  97            (when (and (node-tail-p use)
  98                       (basic-combination-p use)
  99                       (eq (basic-combination-kind use) :full))
 100              (return t))))))
 101
 102 ;;; Return true if we should use the standard (unknown) return
 103 ;;; convention for a TAIL-SET. We use the standard return convention
 104 ;;; when:
 105 ;;; -- We must use the standard convention to preserve tail-recursion,
 106 ;;;    since the TAIL-SET contains both an XEP and a TR full call.
 107 ;;; -- It appears to be more efficient to use the standard convention,
 108 ;;;    since there are no non-TR local calls that could benefit from
 109 ;;;    a non-standard convention.
 110 (defun use-standard-returns (tails)
 111   (declare (type tail-set tails))
 112   (let ((funs (tail-set-funs tails)))
 113     (or (and (find-if #'xep-p funs)
 114              (find-if #'has-full-call-use funs))
 115         (block punt
 116           (dolist (fun funs t)
 117             (dolist (ref (leaf-refs fun))
 118               (let* ((lvar (node-lvar ref))
 119                      (dest (and lvar (lvar-dest lvar))))
 120                 (when (and (basic-combination-p dest)
 121                            (not (node-tail-p dest))
 122                            (eq (basic-combination-fun dest) lvar)
 123                            (eq (basic-combination-kind dest) :local))
 124                   (return-from punt nil)))))))))
 125
 126 ;;; If policy indicates, give an efficiency note about our inability to
 127 ;;; use the known return convention. We try to find a function in the
 128 ;;; tail set with non-constant return values to use as context. If
 129 ;;; there is no such function, then be more vague.
 130 (defun return-value-efficiency-note (tails)
 131   (declare (type tail-set tails))
 132   (let ((funs (tail-set-funs tails)))
 133     (when (policy (lambda-bind (first funs))
 134                   (> (max speed space)
 135                      inhibit-warnings))
 136       (dolist (fun funs
 137                    (let ((*compiler-error-context* (lambda-bind (first funs))))
 138                      (compiler-notify
 139                       "Return value count mismatch prevents known return ~
 140                        from these functions:~
 141                        ~{~%  ~A~}"
 142                       (mapcar #'leaf-source-name
 143                               (remove-if-not #'leaf-has-source-name-p funs)))))
 144         (let ((ret (lambda-return fun)))
 145           (when ret
 146             (let ((rtype (return-result-type ret)))
 147               (multiple-value-bind (ignore count) (values-types rtype)
 148                 (declare (ignore ignore))
 149                 (when (eq count :unknown)
 150                   (let ((*compiler-error-context* (lambda-bind fun)))
 151                     (compiler-notify
 152                      "Return type not fixed values, so can't use known return ~
 153                       convention:~%  ~S"
 154                      (type-specifier rtype)))
 155                   (return)))))))))
 156   (values))
 157
 158 ;;; Return a RETURN-INFO structure describing how we should return
 159 ;;; from functions in the specified tail set. We use the unknown
 160 ;;; values convention if the number of values is unknown, or if it is
 161 ;;; a good idea for some other reason. Otherwise we allocate passing
 162 ;;; locations for a fixed number of values.
 163 (defun return-info-for-set (tails)
 164   (declare (type tail-set tails))
 165   (multiple-value-bind (types count) (values-types (tail-set-type tails))
 166     (let ((ptypes (mapcar #'primitive-type types))
 167           (use-standard (use-standard-returns tails)))
 168       (when (and (eq count :unknown) (not use-standard)
 169                  (not (eq (tail-set-type tails) *empty-type*)))
 170         (return-value-efficiency-note tails))
 171       (if (or (eq count :unknown) use-standard)
 172           (make-return-info :kind :unknown
 173                             :count count
 174                             :types ptypes)
 175           (make-return-info :kind :fixed
 176                             :count count
 177                             :types ptypes
 178                             :locations (mapcar #'make-normal-tn ptypes))))))
 179
 180 ;;; If TAIL-SET doesn't have any INFO, then make a RETURN-INFO for it.
 181 ;;; If we choose a return convention other than :UNKNOWN, and this
 182 ;;; environment is for an XEP, then break tail recursion on the XEP
 183 ;;; calls, since we must always use unknown values when returning from
 184 ;;; an XEP.
 185 (defun assign-return-locations (fun)
 186   (declare (type clambda fun))
 187   (let* ((tails (lambda-tail-set fun))
 188          (returns (or (tail-set-info tails)
 189                       (setf (tail-set-info tails)
 190                             (return-info-for-set tails))))
 191          (return (lambda-return fun)))
 192     (when (and return
 193                (not (eq (return-info-kind returns) :unknown))
 194                (xep-p fun))
 195       (do-uses (use (return-result return))
 196         (setf (node-tail-p use) nil))))
 197   (values))
 198
 199 ;;; Make an IR2-NLX-INFO structure for each NLX entry point recorded.
 200 ;;; We call a VM supplied function to make the SAVE-SP restricted on
 201 ;;; the stack. The NLX-ENTRY VOP's :FORCE-TO-STACK SAVE-P value
 202 ;;; doesn't do this, since the SP is an argument to the VOP, and thus
 203 ;;; isn't live afterwards.
 204 (defun assign-ir2-nlx-info (fun)
 205   (declare (type clambda fun))
 206   (let ((physenv (lambda-physenv fun)))
 207     (dolist (nlx (physenv-nlx-info physenv))
 208       (setf (nlx-info-info nlx)
 209             (make-ir2-nlx-info
 210              :home (when (member (cleanup-kind (nlx-info-cleanup nlx))
 211                                  '(:block :tagbody))
 212                      (make-normal-tn *backend-t-primitive-type*))
 213              :save-sp (make-nlx-sp-tn physenv)))))
 214   (values))