src/compiler/info-functions.lisp

   1 ;;;; miscellaneous functions which use INFO
   2 ;;;;
   3 ;;;; (In CMU CL, these were in globaldb.lisp. They've been moved here
   4 ;;;; because references to INFO can't be compiled correctly until
   5 ;;;; globaldb initialization is complete, and the SBCL technique for
   6 ;;;; initializing the global database in the cross-compiler isn't
   7 ;;;; completed until load time.)
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!C")
  19 \f
  20 ;;;; internal utilities defined in terms of INFO
  21
  22 ;;; Check that NAME is a valid function name, returning the name if
  23 ;;; OK, and signalling an error if not. In addition to checking for
  24 ;;; basic well-formedness, we also check that symbol names are not NIL
  25 ;;; or the name of a special form.
  26 (defun check-fun-name (name)
  27   (typecase name
  28     (list
  29      (unless (legal-fun-name-p name)
  30        (compiler-error "illegal function name: ~S" name)))
  31     (symbol
  32      (when (eq (info :function :kind name) :special-form)
  33        (compiler-error "Special form is an illegal function name: ~S" name)))
  34     (t
  35      (compiler-error "illegal function name: ~S" name)))
  36   (values))
  37
  38 ;;; Record a new function definition, and check its legality.
  39 (defun proclaim-as-fun-name (name)
  40
  41   ;; legal name?
  42   (check-fun-name name)
  43
  44   ;; scrubbing old data I: possible collision with old definition
  45   (when (fboundp name)
  46     (ecase (info :function :kind name)
  47       (:function) ; happy case
  48       ((nil)) ; another happy case
  49       (:macro ; maybe-not-so-good case
  50        (compiler-style-warn "~S was previously defined as a macro." name)
  51        (setf (info :function :where-from name) :assumed)
  52        (clear-info :function :macro-function name))))
  53
  54   ;; scrubbing old data II: dangling forward references
  55   ;;
  56   ;; (This could happen if someone executes PROCLAIM FTYPE at
  57   ;; macroexpansion time, which is bad style, or at compile time, e.g.
  58   ;; in EVAL-WHEN (:COMPILE) inside something like DEFSTRUCT, in which
  59   ;; case it's reasonable style. Either way, NAME is no longer a free
  60   ;; function.)
  61   (when (boundp '*free-funs*) ; when compiling
  62     (remhash name *free-funs*))
  63
  64   ;; recording the ordinary case
  65   (setf (info :function :kind name) :function)
  66   (note-if-setf-fun-and-macro name)
  67
  68   (values))
  69
  70 ;;; This is called to do something about SETF functions that overlap
  71 ;;; with SETF macros. Perhaps we should interact with the user to see
  72 ;;; whether the macro should be blown away, but for now just give a
  73 ;;; warning. Due to the weak semantics of the (SETF FUNCTION) name, we
  74 ;;; can't assume that they aren't just naming a function (SETF FOO)
  75 ;;; for the heck of it. NAME is already known to be well-formed.
  76 (defun note-if-setf-fun-and-macro (name)
  77   (when (consp name)
  78     (when (or (info :setf :inverse name)
  79               (info :setf :expander name))
  80       (compiler-style-warn
  81        "defining as a SETF function a name that already has a SETF macro:~
  82        ~%  ~S"
  83        name)))
  84   (values))
  85
  86 ;;; Make NAME no longer be a function name: clear everything back to
  87 ;;; the default.
  88 (defun undefine-fun-name (name)
  89   (when name
  90     (macrolet ((frob (type &optional val)
  91                  `(unless (eq (info :function ,type name) ,val)
  92                     (setf (info :function ,type name) ,val))))
  93       (frob :info)
  94       (frob :type (specifier-type 'function))
  95       (frob :where-from :assumed)
  96       (frob :inlinep)
  97       (frob :kind)
  98       (frob :inline-expansion-designator)
  99       (frob :source-transform)
 100       (frob :assumed-type)))
 101   (values))
 102
 103 ;;; part of what happens with DEFUN, also with some PCL stuff: Make
 104 ;;; NAME known to be a function definition.
 105 (defun become-defined-fun-name (name)
 106   (proclaim-as-fun-name name)
 107   (when (eq (info :function :where-from name) :assumed)
 108     (setf (info :function :where-from name) :defined)
 109     (if (info :function :assumed-type name)
 110         (setf (info :function :assumed-type name) nil))))
 111
 112 ;;; Decode any raw (INFO :FUNCTION :INLINE-EXPANSION-DESIGNATOR FUN-NAME)
 113 ;;; value into a lambda expression, or return NIL if there is none.
 114 (declaim (ftype (function ((or symbol cons)) list) fun-name-inline-expansion))
 115 (defun fun-name-inline-expansion (fun-name)
 116   (let ((info (info :function :inline-expansion-designator fun-name)))
 117     (if (functionp info)
 118         (funcall info)
 119         info)))
 120 \f
 121 ;;;; ANSI Common Lisp functions which are defined in terms of the info
 122 ;;;; database
 123
 124 (defun sb!xc:constantp (object &optional environment)
 125   #!+sb-doc
 126   "True of any Lisp object that has a constant value: types that eval to
 127   themselves, keywords, constants, and list whose car is QUOTE."
 128   ;; FIXME: Someday it would be nice to make the code recognize foldable
 129   ;; functions and call itself recursively on their arguments, so that
 130   ;; more of the examples in the ANSI CL definition are recognized.
 131   ;; (e.g. (+ 3 2), (SQRT PI), and (LENGTH '(A B C)))
 132   (declare (ignore environment))
 133   (typecase object
 134     ;; (Note that the following test on INFO catches KEYWORDs as well as
 135     ;; explicitly DEFCONSTANT symbols.)
 136     (symbol (eq (info :variable :kind object) :constant))
 137     (list (eq (car object) 'quote))
 138     (t t)))
 139
 140 (declaim (ftype (function (symbol &optional (or null sb!c::lexenv))) sb!xc:macro-function))
 141 (defun sb!xc:macro-function (symbol &optional env)
 142   #!+sb-doc
 143   "If SYMBOL names a macro in ENV, returns the expansion function,
 144    else returns NIL. If ENV is unspecified or NIL, use the global
 145    environment only."
 146   (declare (symbol symbol))
 147   (let* ((fenv (when env (sb!c::lexenv-funs env)))
 148          (local-def (cdr (assoc symbol fenv))))
 149     (cond (local-def
 150            (if (and (consp local-def) (eq (car local-def) 'MACRO))
 151                (cdr local-def)
 152                nil))
 153           ((eq (info :function :kind symbol) :macro)
 154            (values (info :function :macro-function symbol)))
 155           (t
 156            nil))))
 157
 158 ;;; Note: Technically there could be an ENV optional argument to SETF
 159 ;;; MACRO-FUNCTION, but since ANSI says that the consequences of
 160 ;;; supplying that optional argument are undefined, we don't allow it.
 161 ;;; (Thus our implementation of this unspecified behavior is to
 162 ;;; complain that the wrong number of arguments was supplied. Since
 163 ;;; the behavior is unspecified, this is conforming.:-)
 164 (defun (setf sb!xc:macro-function) (function symbol)
 165   (declare (symbol symbol) (type function function))
 166   (when (eq (info :function :kind symbol) :special-form)
 167     (error "~S names a special form." symbol))
 168   (setf (info :function :kind symbol) :macro)
 169   (setf (info :function :macro-function symbol) function)
 170   ;; This is a nice thing to have in the target SBCL, but in the
 171   ;; cross-compilation host it's not nice to mess with
 172   ;; (SYMBOL-FUNCTION FOO) where FOO might be a symbol in the
 173   ;; cross-compilation host's COMMON-LISP package.
 174   #-sb-xc-host
 175   (setf (symbol-function symbol)
 176         (lambda (&rest args)
 177           (declare (ignore args))
 178           ;; (ANSI specification of FUNCALL says that this should be
 179           ;; an error of type UNDEFINED-FUNCTION, not just SIMPLE-ERROR.)
 180           (error 'undefined-function :name symbol)))
 181   function)
 182
 183 (defun sb!xc:compiler-macro-function (name &optional env)
 184   #!+sb-doc
 185   "If NAME names a compiler-macro in ENV, return the expansion function, else
 186    return NIL. Can be set with SETF when ENV is NIL."
 187   (declare (ignore env))
 188   (legal-fun-name-or-type-error name)
 189   ;; Note: CMU CL used to return NIL here when a NOTINLINE declaration
 190   ;; was in force. That's fairly logical, given the specified effect
 191   ;; of NOTINLINE declarations on compiler-macro expansion. However,
 192   ;; (1) it doesn't seem to be consistent with the ANSI spec for
 193   ;; COMPILER-MACRO-FUNCTION, and (2) it would give surprising
 194   ;; behavior for (SETF (COMPILER-MACRO-FUNCTION FOO) ...) in the
 195   ;; presence of a (PROCLAIM '(NOTINLINE FOO)). So we don't do it.
 196   (values (info :function :compiler-macro-function name)))
 197 (defun (setf sb!xc:compiler-macro-function) (function name &optional env)
 198   (declare (type (or symbol list) name)
 199            (type (or function null) function))
 200   (when env
 201     ;; ANSI says this operation is undefined.
 202     (error "can't SETF COMPILER-MACRO-FUNCTION when ENV is non-NIL"))
 203   (when (eq (info :function :kind name) :special-form)
 204     (error "~S names a special form." name))
 205   (setf (info :function :compiler-macro-function name) function)
 206   function)
 207 \f
 208 ;;;; a subset of DOCUMENTATION functionality for bootstrapping
 209
 210 ;;; FDOCUMENTATION is like DOCUMENTATION, but with less functionality,
 211 ;;; and implemented with DEFUN instead of DEFGENERIC so that it can
 212 ;;; run before CLOS is set up. Supported DOC-TYPE values are
 213 ;;;   FUNCTION
 214 ;;;   SETF
 215 ;;;   STRUCTURE
 216 ;;;   T
 217 ;;;   TYPE
 218 ;;;   VARIABLE
 219 ;;; FIXME: Other types end up in INFO :RANDOM-DOCUMENTATION :STUFF. I
 220 ;;; should add some code to monitor this and make sure that nothing is
 221 ;;; unintentionally being sent to never never land this way.
 222 ;;; FIXME: Rename FDOCUMENTATION to BDOCUMENTATION, by analogy with
 223 ;;; DEF!STRUCT and DEF!MACRO and so forth. And consider simply saving
 224 ;;; all the BDOCUMENTATION entries in a *BDOCUMENTATION* hash table
 225 ;;; and slamming them into PCL once PCL gets going.
 226 (defun fdocumentation (x doc-type)
 227   (flet ((try-cmucl-random-doc (x doc-type)
 228            (declare (symbol doc-type))
 229            (cdr (assoc doc-type
 230                        (values (info :random-documentation :stuff x))))))
 231     (case doc-type
 232       (variable
 233        (typecase x
 234          (symbol (values (info :variable :documentation x)))))
 235       (function
 236        (cond ((functionp x)
 237               (%fun-doc x))
 238              ((legal-fun-name-p x)
 239               ;; FIXME: Is it really right to make
 240               ;; (DOCUMENTATION '(SETF FOO) 'FUNCTION) equivalent to
 241               ;; (DOCUMENTATION 'FOO 'FUNCTION)? That's what CMU CL
 242               ;; did, so we do it, but I'm not sure it's what ANSI wants.
 243               (values (info :function :documentation
 244                             (fun-name-block-name x))))))
 245       (structure
 246        (typecase x
 247          (symbol (when (eq (info :type :kind x) :instance)
 248                    (values (info :type :documentation x))))))
 249       (type
 250        (typecase x
 251          (structure-class (values (info :type :documentation (class-name x))))
 252          (t (and (typep x 'symbol) (values (info :type :documentation x))))))
 253       (setf (info :setf :documentation x))
 254       ((t)
 255        (typecase x
 256          (function (%fun-doc x))
 257          (package (package-doc-string x))
 258          (structure-class (values (info :type :documentation (class-name x))))
 259          (symbol (try-cmucl-random-doc x doc-type))))
 260       (t
 261        (typecase x
 262          ;; FIXME: This code comes from CMU CL, but
 263          ;; TRY-CMUCL-RANDOM-DOC doesn't seem to be defined anywhere
 264          ;; in CMU CL. Perhaps it could be defined by analogy with the
 265          ;; corresponding SETF FDOCUMENTATION code.
 266          (symbol (try-cmucl-random-doc x doc-type)))))))
 267 (defun (setf fdocumentation) (string name doc-type)
 268   ;; FIXME: I think it should be possible to set documentation for
 269   ;; things (e.g. compiler macros) named (SETF FOO). fndb.lisp
 270   ;; declares DOC-TYPE to be a SYMBOL, which contradicts that. What
 271   ;; should be done?
 272   (case doc-type
 273     (variable (setf (info :variable :documentation name) string))
 274     (function (setf (info :function :documentation name) string))
 275     (structure (if (eq (info :type :kind name) :instance)
 276                    (setf (info :type :documentation name) string)
 277                    (error "~S is not the name of a structure type." name)))
 278     (type (setf (info :type :documentation name) string))
 279     (setf (setf (info :setf :documentation name) string))
 280     (t
 281      (let ((pair (assoc doc-type (info :random-documentation :stuff name))))
 282        (if pair
 283            (setf (cdr pair) string)
 284            (push (cons doc-type string)
 285                  (info :random-documentation :stuff name))))))
 286   string)