src/compiler/info-functions.lisp

   1 ;;;; miscellaneous functions which use INFO
   2 ;;;;
   3 ;;;; (In CMU CL, these were in globaldb.lisp. They've been moved here
   4 ;;;; because references to INFO can't be compiled correctly until
   5 ;;;; globaldb initialization is complete, and the SBCL technique for
   6 ;;;; initializing the global database in the cross-compiler isn't
   7 ;;;; completed until load time.)
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!C")
  19 \f
  20 ;;;; internal utilities defined in terms of INFO
  21
  22 ;;; Check that NAME is a valid function name, returning the name if
  23 ;;; OK, and signalling an error if not. In addition to checking for
  24 ;;; basic well-formedness, we also check that symbol names are not NIL
  25 ;;; or the name of a special form.
  26 (defun check-fun-name (name)
  27   (typecase name
  28     (list
  29      (unless (legal-fun-name-p name)
  30        (compiler-error "illegal function name: ~S" name)))
  31     (symbol
  32      (when (eq (info :function :kind name) :special-form)
  33        (compiler-error "Special form is an illegal function name: ~S" name)))
  34     (t
  35      (compiler-error "illegal function name: ~S" name)))
  36   (values))
  37
  38 ;;; Record a new function definition, and check its legality.
  39 (defun proclaim-as-fun-name (name)
  40
  41   ;; legal name?
  42   (check-fun-name name)
  43
  44   ;; scrubbing old data I: possible collision with old definition
  45   (when (fboundp name)
  46     (ecase (info :function :kind name)
  47       (:function) ; happy case
  48       ((nil)) ; another happy case
  49       (:macro ; maybe-not-so-good case
  50        (compiler-style-warn "~S was previously defined as a macro." name)
  51        (setf (info :function :where-from name) :assumed)
  52        (clear-info :function :macro-function name))))
  53
  54   ;; scrubbing old data II: dangling forward references
  55   ;;
  56   ;; (This could happen if someone executes PROCLAIM FTYPE at
  57   ;; macroexpansion time, which is bad style, or at compile time, e.g.
  58   ;; in EVAL-WHEN (:COMPILE) inside something like DEFSTRUCT, in which
  59   ;; case it's reasonable style. Either way, NAME is no longer a free
  60   ;; function.)
  61   (when (boundp '*free-funs*) ; when compiling
  62     (remhash name *free-funs*))
  63
  64   ;; recording the ordinary case
  65   (setf (info :function :kind name) :function)
  66   (note-if-setf-fun-and-macro name)
  67
  68   (values))
  69
  70 ;;; This is called to do something about SETF functions that overlap
  71 ;;; with SETF macros. Perhaps we should interact with the user to see
  72 ;;; whether the macro should be blown away, but for now just give a
  73 ;;; warning. Due to the weak semantics of the (SETF FUNCTION) name, we
  74 ;;; can't assume that they aren't just naming a function (SETF FOO)
  75 ;;; for the heck of it. NAME is already known to be well-formed.
  76 (defun note-if-setf-fun-and-macro (name)
  77   (when (consp name)
  78     (when (or (info :setf :inverse name)
  79               (info :setf :expander name))
  80       (compiler-style-warn
  81        "defining as a SETF function a name that already has a SETF macro:~
  82        ~%  ~S"
  83        name)))
  84   (values))
  85
  86 ;;; Make NAME no longer be a function name: clear everything back to
  87 ;;; the default.
  88 (defun undefine-fun-name (name)
  89   (when name
  90     (macrolet ((frob (type &optional val)
  91                  `(unless (eq (info :function ,type name) ,val)
  92                     (setf (info :function ,type name) ,val))))
  93       (frob :info)
  94       (frob :type (specifier-type 'function))
  95       (frob :where-from :assumed)
  96       (frob :inlinep)
  97       (frob :kind)
  98       (frob :inline-expansion-designator)
  99       (frob :source-transform)
 100       (frob :assumed-type)))
 101   (values))
 102
 103 ;;; part of what happens with DEFUN, also with some PCL stuff: Make
 104 ;;; NAME known to be a function definition.
 105 (defun become-defined-fun-name (name)
 106   (proclaim-as-fun-name name)
 107   (when (eq (info :function :where-from name) :assumed)
 108     (setf (info :function :where-from name) :defined)
 109     (if (info :function :assumed-type name)
 110         (setf (info :function :assumed-type name) nil))))
 111
 112 ;;; Decode any raw (INFO :FUNCTION :INLINE-EXPANSION-DESIGNATOR FUN-NAME)
 113 ;;; value into a lambda expression, or return NIL if there is none.
 114 (declaim (ftype (function ((or symbol cons)) list) fun-name-inline-expansion))
 115 (defun fun-name-inline-expansion (fun-name)
 116   (let ((info (info :function :inline-expansion-designator fun-name)))
 117     (if (functionp info)
 118         (funcall info)
 119         info)))
 120 \f
 121 ;;;; ANSI Common Lisp functions which are defined in terms of the info
 122 ;;;; database
 123
 124 (defun sb!xc:constantp (object &optional environment)
 125   #!+sb-doc
 126   "True of any Lisp object that has a constant value: types that eval to
 127   themselves, keywords, constants, and list whose car is QUOTE."
 128   ;; FIXME: Someday it would be nice to make the code recognize foldable
 129   ;; functions and call itself recursively on their arguments, so that
 130   ;; more of the examples in the ANSI CL definition are recognized.
 131   ;; (e.g. (+ 3 2), (SQRT PI), and (LENGTH '(A B C)))
 132   (declare (ignore environment))
 133   (typecase object
 134     ;; (Note that the following test on INFO catches KEYWORDs as well as
 135     ;; explicitly DEFCONSTANT symbols.)
 136     (symbol (eq (info :variable :kind object) :constant))
 137     (list (and (eq (car object) 'quote)
 138                (consp (cdr object))))
 139     (t t)))
 140
 141 (defun constant-form-value (form)
 142   (typecase form
 143     (symbol (info :variable :constant-value form))
 144     ((cons (eql quote) cons)
 145      (second form))
 146     (t form)))
 147
 148 (declaim (ftype (function (symbol &optional (or null sb!c::lexenv))) sb!xc:macro-function))
 149 (defun sb!xc:macro-function (symbol &optional env)
 150   #!+sb-doc
 151   "If SYMBOL names a macro in ENV, returns the expansion function,
 152    else returns NIL. If ENV is unspecified or NIL, use the global
 153    environment only."
 154   (declare (symbol symbol))
 155   (let* ((fenv (when env (sb!c::lexenv-funs env)))
 156          (local-def (cdr (assoc symbol fenv))))
 157     (cond (local-def
 158            (if (and (consp local-def) (eq (car local-def) 'MACRO))
 159                (cdr local-def)
 160                nil))
 161           ((eq (info :function :kind symbol) :macro)
 162            (values (info :function :macro-function symbol)))
 163           (t
 164            nil))))
 165
 166 ;;; Note: Technically there could be an ENV optional argument to SETF
 167 ;;; MACRO-FUNCTION, but since ANSI says that the consequences of
 168 ;;; supplying that optional argument are undefined, we don't allow it.
 169 ;;; (Thus our implementation of this unspecified behavior is to
 170 ;;; complain that the wrong number of arguments was supplied. Since
 171 ;;; the behavior is unspecified, this is conforming.:-)
 172 (defun (setf sb!xc:macro-function) (function symbol)
 173   (declare (symbol symbol) (type function function))
 174   (when (eq (info :function :kind symbol) :special-form)
 175     (error "~S names a special form." symbol))
 176   (setf (info :function :kind symbol) :macro)
 177   (setf (info :function :macro-function symbol) function)
 178   ;; This is a nice thing to have in the target SBCL, but in the
 179   ;; cross-compilation host it's not nice to mess with
 180   ;; (SYMBOL-FUNCTION FOO) where FOO might be a symbol in the
 181   ;; cross-compilation host's COMMON-LISP package.
 182   #-sb-xc-host
 183   (setf (symbol-function symbol)
 184         (lambda (&rest args)
 185           (declare (ignore args))
 186           ;; (ANSI specification of FUNCALL says that this should be
 187           ;; an error of type UNDEFINED-FUNCTION, not just SIMPLE-ERROR.)
 188           (error 'undefined-function :name symbol)))
 189   function)
 190
 191 (defun sb!xc:compiler-macro-function (name &optional env)
 192   #!+sb-doc
 193   "If NAME names a compiler-macro in ENV, return the expansion function, else
 194    return NIL. Can be set with SETF when ENV is NIL."
 195   (declare (ignore env))
 196   (legal-fun-name-or-type-error name)
 197   ;; Note: CMU CL used to return NIL here when a NOTINLINE declaration
 198   ;; was in force. That's fairly logical, given the specified effect
 199   ;; of NOTINLINE declarations on compiler-macro expansion. However,
 200   ;; (1) it doesn't seem to be consistent with the ANSI spec for
 201   ;; COMPILER-MACRO-FUNCTION, and (2) it would give surprising
 202   ;; behavior for (SETF (COMPILER-MACRO-FUNCTION FOO) ...) in the
 203   ;; presence of a (PROCLAIM '(NOTINLINE FOO)). So we don't do it.
 204   (values (info :function :compiler-macro-function name)))
 205 (defun (setf sb!xc:compiler-macro-function) (function name &optional env)
 206   (declare (type (or symbol list) name)
 207            (type (or function null) function))
 208   (when env
 209     ;; ANSI says this operation is undefined.
 210     (error "can't SETF COMPILER-MACRO-FUNCTION when ENV is non-NIL"))
 211   (when (eq (info :function :kind name) :special-form)
 212     (error "~S names a special form." name))
 213   (setf (info :function :compiler-macro-function name) function)
 214   function)
 215 \f
 216 ;;;; a subset of DOCUMENTATION functionality for bootstrapping
 217
 218 ;;; FDOCUMENTATION is like DOCUMENTATION, but with less functionality,
 219 ;;; and implemented with DEFUN instead of DEFGENERIC so that it can
 220 ;;; run before CLOS is set up. Supported DOC-TYPE values are
 221 ;;;   FUNCTION
 222 ;;;   SETF
 223 ;;;   STRUCTURE
 224 ;;;   T
 225 ;;;   TYPE
 226 ;;;   VARIABLE
 227 ;;; FIXME: Other types end up in INFO :RANDOM-DOCUMENTATION :STUFF. I
 228 ;;; should add some code to monitor this and make sure that nothing is
 229 ;;; unintentionally being sent to never never land this way.
 230 ;;; FIXME: Rename FDOCUMENTATION to BDOCUMENTATION, by analogy with
 231 ;;; DEF!STRUCT and DEF!MACRO and so forth. And consider simply saving
 232 ;;; all the BDOCUMENTATION entries in a *BDOCUMENTATION* hash table
 233 ;;; and slamming them into PCL once PCL gets going.
 234 (defun fdocumentation (x doc-type)
 235   (flet ((try-cmucl-random-doc (x doc-type)
 236            (declare (symbol doc-type))
 237            (cdr (assoc doc-type
 238                        (values (info :random-documentation :stuff x))))))
 239     (case doc-type
 240       (variable
 241        (typecase x
 242          (symbol (values (info :variable :documentation x)))))
 243       (function
 244        (cond ((functionp x)
 245               (%fun-doc x))
 246              ((legal-fun-name-p x)
 247               ;; FIXME: Is it really right to make
 248               ;; (DOCUMENTATION '(SETF FOO) 'FUNCTION) equivalent to
 249               ;; (DOCUMENTATION 'FOO 'FUNCTION)? That's what CMU CL
 250               ;; did, so we do it, but I'm not sure it's what ANSI wants.
 251               (values (info :function :documentation
 252                             (fun-name-block-name x))))))
 253       (structure
 254        (typecase x
 255          (symbol (when (eq (info :type :kind x) :instance)
 256                    (values (info :type :documentation x))))))
 257       (type
 258        (typecase x
 259          (structure-class (values (info :type :documentation (class-name x))))
 260          (t (and (typep x 'symbol) (values (info :type :documentation x))))))
 261       (setf (info :setf :documentation x))
 262       ((t)
 263        (typecase x
 264          (function (%fun-doc x))
 265          (package (package-doc-string x))
 266          (structure-class (values (info :type :documentation (class-name x))))
 267          (symbol (try-cmucl-random-doc x doc-type))))
 268       (t
 269        (typecase x
 270          ;; FIXME: This code comes from CMU CL, but
 271          ;; TRY-CMUCL-RANDOM-DOC doesn't seem to be defined anywhere
 272          ;; in CMU CL. Perhaps it could be defined by analogy with the
 273          ;; corresponding SETF FDOCUMENTATION code.
 274          (symbol (try-cmucl-random-doc x doc-type)))))))
 275 (defun (setf fdocumentation) (string name doc-type)
 276   ;; FIXME: I think it should be possible to set documentation for
 277   ;; things (e.g. compiler macros) named (SETF FOO). fndb.lisp
 278   ;; declares DOC-TYPE to be a SYMBOL, which contradicts that. What
 279   ;; should be done?
 280   (case doc-type
 281     (variable (setf (info :variable :documentation name) string))
 282     (function (setf (info :function :documentation name) string))
 283     (structure (if (eq (info :type :kind name) :instance)
 284                    (setf (info :type :documentation name) string)
 285                    (error "~S is not the name of a structure type." name)))
 286     (type (setf (info :type :documentation name) string))
 287     (setf (setf (info :setf :documentation name) string))
 288     (t
 289      (let ((pair (assoc doc-type (info :random-documentation :stuff name))))
 290        (if pair
 291            (setf (cdr pair) string)
 292            (push (cons doc-type string)
 293                  (info :random-documentation :stuff name))))))
 294   string)