src/compiler/info-functions.lisp

   1 ;;;; miscellaneous functions which use INFO
   2 ;;;;
   3 ;;;; (In CMU CL, these were in globaldb.lisp. They've been moved here
   4 ;;;; because references to INFO can't be compiled correctly until
   5 ;;;; globaldb initialization is complete, and the SBCL technique for
   6 ;;;; initializing the global database in the cross-compiler isn't
   7 ;;;; completed until load time.)
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!C")
  19 \f
  20 ;;;; internal utilities defined in terms of INFO
  21
  22 ;;; Check that NAME is a valid function name, returning the name if
  23 ;;; OK, and signalling an error if not. In addition to checking for
  24 ;;; basic well-formedness, we also check that symbol names are not NIL
  25 ;;; or the name of a special form.
  26 (defun check-fun-name (name)
  27   (typecase name
  28     (list
  29      (unless (legal-fun-name-p name)
  30        (compiler-error "illegal function name: ~S" name)))
  31     (symbol
  32      (when (eq (info :function :kind name) :special-form)
  33        (compiler-error "Special form is an illegal function name: ~S" name)))
  34     (t
  35      (compiler-error "illegal function name: ~S" name)))
  36   (values))
  37
  38 ;;; Record a new function definition, and check its legality.
  39 (defun proclaim-as-fun-name (name)
  40
  41   ;; legal name?
  42   (check-fun-name name)
  43
  44
  45   ;; KLUDGE: This can happen when eg. compiling a NAMED-LAMBDA, and isn't
  46   ;; guarded against elsewhere -- so we want to assert package locks here. The
  47   ;; reason we do it only when stomping on existing stuff is because we want
  48   ;; to keep
  49   ;;   (WITHOUT-PACKAGE-LOCKS (DEFUN LOCKED:FOO ...))
  50   ;; viable, which requires no compile-time violations in the harmless cases.
  51   (with-single-package-locked-error ()
  52     (flet ((assert-it ()
  53              (assert-symbol-home-package-unlocked name "proclaiming ~S as a function")))
  54
  55       (let ((kind (info :function :kind name)))
  56         ;; scrubbing old data I: possible collision with a macro
  57         (when (and (fboundp name) (eq :macro kind))
  58           (assert-it)
  59           (compiler-style-warn "~S was previously defined as a macro." name)
  60           (setf (info :function :where-from name) :assumed)
  61           (clear-info :function :macro-function name))
  62
  63         (unless (eq :function kind)
  64           (assert-it)
  65           (setf (info :function :kind name) :function)))))
  66
  67   ;; scrubbing old data II: dangling forward references
  68   ;;
  69   ;; (This could happen if someone executes PROCLAIM FTYPE at
  70   ;; macroexpansion time, which is bad style, or at compile time, e.g.
  71   ;; in EVAL-WHEN (:COMPILE) inside something like DEFSTRUCT, in which
  72   ;; case it's reasonable style. Either way, NAME is no longer a free
  73   ;; function.)
  74   (when (boundp '*free-funs*)       ; when compiling
  75     (remhash name *free-funs*))
  76
  77   (note-if-setf-fun-and-macro name)
  78
  79   (values))
  80
  81 ;;; This is called to do something about SETF functions that overlap
  82 ;;; with SETF macros. Perhaps we should interact with the user to see
  83 ;;; whether the macro should be blown away, but for now just give a
  84 ;;; warning. Due to the weak semantics of the (SETF FUNCTION) name, we
  85 ;;; can't assume that they aren't just naming a function (SETF FOO)
  86 ;;; for the heck of it. NAME is already known to be well-formed.
  87 (defun note-if-setf-fun-and-macro (name)
  88   (when (consp name)
  89     (when (or (info :setf :inverse name)
  90               (info :setf :expander name))
  91       (compiler-style-warn
  92        "defining as a SETF function a name that already has a SETF macro:~
  93        ~%  ~S"
  94        name)))
  95   (values))
  96
  97 ;;; Make NAME no longer be a function name: clear everything back to
  98 ;;; the default.
  99 (defun undefine-fun-name (name)
 100   (when name
 101     (macrolet ((frob (type &optional val)
 102                  `(unless (eq (info :function ,type name) ,val)
 103                     (setf (info :function ,type name) ,val))))
 104       (frob :info)
 105       (frob :type (specifier-type 'function))
 106       (frob :where-from :assumed)
 107       (frob :inlinep)
 108       (frob :kind)
 109       (frob :macro-function)
 110       (frob :inline-expansion-designator)
 111       (frob :source-transform)
 112       (frob :structure-accessor)
 113       (frob :assumed-type)))
 114   (values))
 115
 116 ;;; part of what happens with DEFUN, also with some PCL stuff: Make
 117 ;;; NAME known to be a function definition.
 118 (defun become-defined-fun-name (name)
 119   (proclaim-as-fun-name name)
 120   (when (eq (info :function :where-from name) :assumed)
 121     (setf (info :function :where-from name) :defined)
 122     (if (info :function :assumed-type name)
 123         (setf (info :function :assumed-type name) nil))))
 124
 125 ;;; Decode any raw (INFO :FUNCTION :INLINE-EXPANSION-DESIGNATOR FUN-NAME)
 126 ;;; value into a lambda expression, or return NIL if there is none.
 127 (declaim (ftype (function ((or symbol cons)) list) fun-name-inline-expansion))
 128 (defun fun-name-inline-expansion (fun-name)
 129   (let ((info (info :function :inline-expansion-designator fun-name)))
 130     (if (functionp info)
 131         (funcall info)
 132         info)))
 133 \f
 134 ;;;; ANSI Common Lisp functions which are defined in terms of the info
 135 ;;;; database
 136
 137 (defun sb!xc:macro-function (symbol &optional env)
 138   #!+sb-doc
 139   "If SYMBOL names a macro in ENV, returns the expansion function,
 140 else returns NIL. If ENV is unspecified or NIL, use the global environment
 141 only."
 142   (declare (symbol symbol))
 143   (let* ((fenv (when env (lexenv-funs env)))
 144          (local-def (cdr (assoc symbol fenv))))
 145     (if local-def
 146         (if (and (consp local-def) (eq (car local-def) 'macro))
 147             (cdr local-def)
 148             nil)
 149         (values (info :function :macro-function symbol)))))
 150
 151 (defun (setf sb!xc:macro-function) (function symbol &optional environment)
 152   (declare (symbol symbol) (type function function))
 153   (when environment
 154     ;; Note: Technically there could be an ENV optional argument to SETF
 155     ;; MACRO-FUNCTION, but since ANSI says that the consequences of
 156     ;; supplying a non-nil one are undefined, we don't allow it.
 157     ;; (Thus our implementation of this unspecified behavior is to
 158     ;; complain. SInce the behavior is unspecified, this is conforming.:-)
 159     (error "Non-NIL environment argument in SETF of MACRO-FUNCTION ~S: ~S"
 160            symbol environment))
 161   (when (eq (info :function :kind symbol) :special-form)
 162     (error "~S names a special form." symbol))
 163   (with-single-package-locked-error (:symbol symbol "setting the macro-function of ~S")
 164     (setf (info :function :kind symbol) :macro)
 165     (setf (info :function :macro-function symbol) function)
 166     ;; This is a nice thing to have in the target SBCL, but in the
 167     ;; cross-compilation host it's not nice to mess with
 168     ;; (SYMBOL-FUNCTION FOO) where FOO might be a symbol in the
 169     ;; cross-compilation host's COMMON-LISP package.
 170     #-sb-xc-host
 171     (setf (symbol-function symbol)
 172           (lambda (&rest args)
 173             (declare (ignore args))
 174             ;; (ANSI specification of FUNCALL says that this should be
 175             ;; an error of type UNDEFINED-FUNCTION, not just SIMPLE-ERROR.)
 176             (error 'undefined-function :name symbol))))
 177   function)
 178
 179 (defun fun-locally-defined-p (name env)
 180   (and env
 181        (let ((fun (cdr (assoc name (lexenv-funs env) :test #'equal))))
 182          (and fun (not (global-var-p fun))))))
 183
 184 (defun sb!xc:compiler-macro-function (name &optional env)
 185   #!+sb-doc
 186   "If NAME names a compiler-macro in ENV, return the expansion function, else
 187 return NIL. Can be set with SETF when ENV is NIL."
 188   (legal-fun-name-or-type-error name)
 189   ;; CLHS 3.2.2.1: Creating a lexical binding for the function name
 190   ;; not only creates a new local function or macro definition, but
 191   ;; also shadows[2] the compiler macro.
 192   (unless (fun-locally-defined-p name env)
 193     ;; Note: CMU CL used to return NIL here when a NOTINLINE
 194     ;; declaration was in force. That's fairly logical, given the
 195     ;; specified effect of NOTINLINE declarations on compiler-macro
 196     ;; expansion. However, (1) it doesn't seem to be consistent with
 197     ;; the ANSI spec for COMPILER-MACRO-FUNCTION, and (2) it would
 198     ;; give surprising behavior for (SETF (COMPILER-MACRO-FUNCTION
 199     ;; FOO) ...) in the presence of a (PROCLAIM '(NOTINLINE FOO)). So
 200     ;; we don't do it.
 201     (values (info :function :compiler-macro-function name))))
 202
 203 (defun (setf sb!xc:compiler-macro-function) (function name &optional env)
 204   (declare (type (or symbol list) name)
 205            (type (or function null) function))
 206   (when env
 207     ;; ANSI says this operation is undefined.
 208     (error "can't SETF COMPILER-MACRO-FUNCTION when ENV is non-NIL"))
 209   (when (eq (info :function :kind name) :special-form)
 210     (error "~S names a special form." name))
 211   (with-single-package-locked-error
 212       (:symbol name "setting the compiler-macro-function of ~A")
 213     (setf (info :function :compiler-macro-function name) function)
 214     function))
 215 \f
 216 ;;;; a subset of DOCUMENTATION functionality for bootstrapping
 217
 218 ;;; FDOCUMENTATION is like DOCUMENTATION, but with less functionality,
 219 ;;; and implemented with DEFUN instead of DEFGENERIC so that it can
 220 ;;; run before CLOS is set up. Supported DOC-TYPE values are
 221 ;;;   FUNCTION
 222 ;;;   SETF
 223 ;;;   STRUCTURE
 224 ;;;   T
 225 ;;;   TYPE
 226 ;;;   VARIABLE
 227 ;;; FIXME: Other types end up in INFO :RANDOM-DOCUMENTATION :STUFF. I
 228 ;;; should add some code to monitor this and make sure that nothing is
 229 ;;; unintentionally being sent to never never land this way.
 230 ;;; FIXME: Rename FDOCUMENTATION to BDOCUMENTATION, by analogy with
 231 ;;; DEF!STRUCT and DEF!MACRO and so forth. And consider simply saving
 232 ;;; all the BDOCUMENTATION entries in a *BDOCUMENTATION* hash table
 233 ;;; and slamming them into PCL once PCL gets going.
 234 (defun fdocumentation (x doc-type)
 235   (case doc-type
 236     (variable
 237      (typecase x
 238        (symbol (values (info :variable :documentation x)))))
 239     ;; FUNCTION is not used at the momemnt, just here for symmetry.
 240     (function
 241      (cond ((functionp x)
 242             (%fun-doc x))
 243            ((and (legal-fun-name-p x) (fboundp x))
 244             (%fun-doc (or (and (symbolp x) (macro-function x))
 245                           (fdefinition x))))))
 246     (structure
 247      (typecase x
 248        (symbol (cond
 249                  ((eq (info :type :kind x) :instance)
 250                   (values (info :type :documentation x)))
 251                  ((info :typed-structure :info x)
 252                   (values (info :typed-structure :documentation x)))))))
 253     (type
 254      (typecase x
 255        (structure-class (values (info :type :documentation (class-name x))))
 256        (t (and (typep x 'symbol) (values (info :type :documentation x))))))
 257     (setf (values (info :setf :documentation x)))
 258     ((t)
 259      (typecase x
 260        (function (%fun-doc x))
 261        (package (package-doc-string x))
 262        (structure-class (values (info :type :documentation (class-name x))))
 263        ((or symbol cons)
 264         (random-documentation x doc-type))))
 265     (t
 266      (when (typep x '(or symbol cons))
 267        (random-documentation x doc-type)))))
 268
 269 (defun (setf fdocumentation) (string name doc-type)
 270   (declare (type (or null string) string))
 271   (case doc-type
 272     (variable (setf (info :variable :documentation name) string))
 273     (function
 274      ;; KLUDGE: FDEFINITION isn't ready early enough during cold-init, so
 275      ;; special case for symbols.
 276      (if (symbolp name)
 277          (setf (%fun-doc (symbol-function name)) string)
 278          (when (legal-fun-name-p name)
 279            (setf (%fun-doc (fdefinition name)) string))))
 280     (structure (cond
 281                  ((eq (info :type :kind name) :instance)
 282                   (setf (info :type :documentation name) string))
 283                  ((info :typed-structure :info name)
 284                   (setf (info :typed-structure :documentation name) string))))
 285     (type (setf (info :type :documentation name) string))
 286     (setf (setf (info :setf :documentation name) string))
 287     (t
 288      (when (typep name '(or symbol cons))
 289        (setf (random-documentation name doc-type) string))))
 290   string)
 291
 292 (defun random-documentation (name type)
 293   (cdr (assoc type (info :random-documentation :stuff name))))
 294
 295 (defun (setf random-documentation) (new-value name type)
 296   (let ((pair (assoc type (info :random-documentation :stuff name))))
 297     (if pair
 298         (setf (cdr pair) new-value)
 299         (push (cons type new-value)
 300               (info :random-documentation :stuff name))))
 301   new-value)