src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start next result)
  18   #!+sb-doc
  19   "PROGN form*
  20
  21 Evaluates each FORM in order, returning the values of the last form. With no
  22 forms, returns NIL."
  23   (ir1-convert-progn-body start next result forms))
  24
  25 (def-ir1-translator if ((test then &optional else) start next result)
  26   #!+sb-doc
  27   "IF predicate then [else]
  28
  29 If PREDICATE evaluates to false, evaluate THEN and return its values,
  30 otherwise evaluate ELSE and return its values. ELSE defaults to NIL."
  31   (let* ((pred-ctran (make-ctran))
  32          (pred-lvar (make-lvar))
  33          (then-ctran (make-ctran))
  34          (then-block (ctran-starts-block then-ctran))
  35          (else-ctran (make-ctran))
  36          (else-block (ctran-starts-block else-ctran))
  37          (maybe-instrument *instrument-if-for-code-coverage*)
  38          (*instrument-if-for-code-coverage* t)
  39          (node (make-if :test pred-lvar
  40                         :consequent then-block
  41                         :alternative else-block)))
  42     ;; IR1-CONVERT-MAYBE-PREDICATE requires DEST to be CIF, so the
  43     ;; order of the following two forms is important
  44     (setf (lvar-dest pred-lvar) node)
  45     (ir1-convert start pred-ctran pred-lvar test)
  46     (link-node-to-previous-ctran node pred-ctran)
  47
  48     (let ((start-block (ctran-block pred-ctran)))
  49       (setf (block-last start-block) node)
  50       (ctran-starts-block next)
  51
  52       (link-blocks start-block then-block)
  53       (link-blocks start-block else-block))
  54
  55     (let ((path (best-sub-source-path test)))
  56       (ir1-convert (if (and path maybe-instrument)
  57                        (let ((*current-path* path))
  58                          (instrument-coverage then-ctran :then test))
  59                        then-ctran)
  60                    next result then)
  61       (ir1-convert (if (and path maybe-instrument)
  62                        (let ((*current-path* path))
  63                          (instrument-coverage else-ctran :else test))
  64                        else-ctran)
  65                    next result else))))
  66
  67 ;;; To get even remotely sensible results for branch coverage
  68 ;;; tracking, we need good source paths. If the macroexpansions
  69 ;;; interfere enough the TEST of the conditional doesn't actually have
  70 ;;; an original source location (e.g. (UNLESS FOO ...) -> (IF (NOT
  71 ;;; FOO) ...). Look through the form, and try to find some subform
  72 ;;; that has one.
  73 (defun best-sub-source-path (form)
  74   (if (policy *lexenv* (= store-coverage-data 0))
  75       nil
  76       (labels ((sub (form)
  77                  (or (get-source-path form)
  78                      (and (consp form)
  79                           (some #'sub form)))))
  80         (or (sub form)))))
  81 \f
  82 ;;;; BLOCK and TAGBODY
  83
  84 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  85 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  86 ;;;; node.
  87
  88 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  89 ;;; body in the modified environment. We make NEXT start a block now,
  90 ;;; since if it was done later, the block would be in the wrong
  91 ;;; environment.
  92 (def-ir1-translator block ((name &rest forms) start next result)
  93   #!+sb-doc
  94   "BLOCK name form*
  95
  96 Evaluate the FORMS as a PROGN. Within the lexical scope of the body,
  97 RETURN-FROM can be used to exit the form."
  98   (unless (symbolp name)
  99     (compiler-error "The block name ~S is not a symbol." name))
 100   (start-block start)
 101   (ctran-starts-block next)
 102   (let* ((dummy (make-ctran))
 103          (entry (make-entry))
 104          (cleanup (make-cleanup :kind :block
 105                                 :mess-up entry)))
 106     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 107     (setf (entry-cleanup entry) cleanup)
 108     (link-node-to-previous-ctran entry start)
 109     (use-ctran entry dummy)
 110
 111     (let* ((env-entry (list entry next result))
 112            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
 113                                   :cleanup cleanup)))
 114       (ir1-convert-progn-body dummy next result forms))))
 115
 116 (def-ir1-translator return-from ((name &optional value) start next result)
 117   #!+sb-doc
 118   "RETURN-FROM block-name value-form
 119
 120 Evaluate the VALUE-FORM, returning its values from the lexically enclosing
 121 block BLOCK-NAME. This is constrained to be used only within the dynamic
 122 extent of the block."
 123   ;; old comment:
 124   ;;   We make NEXT start a block just so that it will have a block
 125   ;;   assigned. People assume that when they pass a ctran into
 126   ;;   IR1-CONVERT as NEXT, it will have a block when it is done.
 127   ;; KLUDGE: Note that this block is basically fictitious. In the code
 128   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 129   ;; it's the block which answers the question "which block is
 130   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 131   ;; dead code and so doesn't really have a block at all. The existence
 132   ;; of this block, and that way that it doesn't explicitly say
 133   ;; "I'm actually nowhere at all" makes some logic (e.g.
 134   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 135   ;; to get rid of it, perhaps using a special placeholder value
 136   ;; to indicate the orphanedness of the code.
 137   (declare (ignore result))
 138   (ctran-starts-block next)
 139   (let* ((found (or (lexenv-find name blocks)
 140                     (compiler-error "return for unknown block: ~S" name)))
 141          (exit-ctran (second found))
 142          (value-ctran (make-ctran))
 143          (value-lvar (make-lvar))
 144          (entry (first found))
 145          (exit (make-exit :entry entry
 146                           :value value-lvar)))
 147     (when (ctran-deleted-p exit-ctran)
 148       (throw 'locall-already-let-converted exit-ctran))
 149     (push exit (entry-exits entry))
 150     (setf (lvar-dest value-lvar) exit)
 151     (ir1-convert start value-ctran value-lvar value)
 152     (link-node-to-previous-ctran exit value-ctran)
 153     (let ((home-lambda (ctran-home-lambda-or-null start)))
 154       (when home-lambda
 155         (sset-adjoin entry (lambda-calls-or-closes home-lambda))))
 156     (use-continuation exit exit-ctran (third found))))
 157
 158 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 159 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 160 ;;; tagbody into segments of non-tag statements, and explicitly
 161 ;;; represent the drop-through with a GO. The first segment has a
 162 ;;; dummy NIL tag, since it represents code before the first tag. Note
 163 ;;; however that NIL may appear as the tag of an inner segment. The
 164 ;;; last segment (which may also be the first segment) ends in NIL
 165 ;;; rather than a GO.
 166 (defun parse-tagbody (body)
 167   (declare (list body))
 168   (collect ((tags)
 169             (segments))
 170     (let ((current body))
 171       (loop
 172        (let ((next-segment (member-if #'atom current)))
 173          (unless next-segment
 174            (segments `(,@current nil))
 175            (return))
 176          (let ((tag (car next-segment)))
 177            (when (member tag (tags))
 178              (compiler-error
 179               "The tag ~S appears more than once in a tagbody."
 180               tag))
 181            (unless (or (symbolp tag) (integerp tag))
 182              (compiler-error "~S is not a legal go tag." tag))
 183            (tags tag)
 184            (segments `(,@(ldiff current next-segment) (go ,tag))))
 185          (setq current (rest next-segment))))
 186       (mapcar #'cons (cons nil (tags)) (segments)))))
 187
 188 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 189 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 190 ;;; Finally, convert each segment with the precomputed Start and Cont
 191 ;;; values.
 192 (def-ir1-translator tagbody ((&rest statements) start next result)
 193   #!+sb-doc
 194   "TAGBODY {tag | statement}*
 195
 196 Define tags for use with GO. The STATEMENTS are evaluated in order ,skipping
 197 TAGS, and NIL is returned. If a statement contains a GO to a defined TAG
 198 within the lexical scope of the form, then control is transferred to the next
 199 statement following that tag. A TAG must an integer or a symbol. A STATEMENT
 200 must be a list. Other objects are illegal within the body."
 201   (start-block start)
 202   (ctran-starts-block next)
 203   (let* ((dummy (make-ctran))
 204          (entry (make-entry))
 205          (segments (parse-tagbody statements))
 206          (cleanup (make-cleanup :kind :tagbody
 207                                 :mess-up entry)))
 208     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 209     (setf (entry-cleanup entry) cleanup)
 210     (link-node-to-previous-ctran entry start)
 211     (use-ctran entry dummy)
 212
 213     (collect ((tags)
 214               (starts)
 215               (ctrans))
 216       (starts dummy)
 217       (dolist (segment (rest segments))
 218         (let* ((tag-ctran (make-ctran))
 219                (tag (list (car segment) entry tag-ctran)))
 220           (ctrans tag-ctran)
 221           (starts tag-ctran)
 222           (ctran-starts-block tag-ctran)
 223           (tags tag)))
 224       (ctrans next)
 225
 226       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 227         (mapc (lambda (segment start end)
 228                 (ir1-convert-progn-body start end
 229                                         (when (eq end next) result)
 230                                         (rest segment)))
 231               segments (starts) (ctrans))))))
 232
 233 ;;; Emit an EXIT node without any value.
 234 (def-ir1-translator go ((tag) start next result)
 235   #!+sb-doc
 236   "GO tag
 237
 238 Transfer control to the named TAG in the lexically enclosing TAGBODY. This is
 239 constrained to be used only within the dynamic extent of the TAGBODY."
 240   (ctran-starts-block next)
 241   (let* ((found (or (lexenv-find tag tags :test #'eql)
 242                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 243                                     tag)))
 244          (entry (first found))
 245          (exit (make-exit :entry entry)))
 246     (push exit (entry-exits entry))
 247     (link-node-to-previous-ctran exit start)
 248     (let ((home-lambda (ctran-home-lambda-or-null start)))
 249       (when home-lambda
 250         (sset-adjoin entry (lambda-calls-or-closes home-lambda))))
 251     (use-ctran exit (second found))))
 252 \f
 253 ;;;; translators for compiler-magic special forms
 254
 255 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 256 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 257 ;;; so that they're never seen at this level.)
 258 ;;;
 259 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 260 ;;; of non-top-level EVAL-WHENs is very simple:
 261 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 262 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 263 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 264 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 265 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 266 ;;;   form; otherwise, the forms in the body are ignored.
 267 (def-ir1-translator eval-when ((situations &rest forms) start next result)
 268   #!+sb-doc
 269   "EVAL-WHEN (situation*) form*
 270
 271 Evaluate the FORMS in the specified SITUATIONS (any of :COMPILE-TOPLEVEL,
 272 :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 273   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 274     (declare (ignore ct lt))
 275     (ir1-convert-progn-body start next result (and e forms)))
 276   (values))
 277
 278 ;;; common logic for MACROLET and SYMBOL-MACROLET
 279 ;;;
 280 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 281 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 282 ;;; call FUN (with no arguments).
 283 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 284                                        definitionize-keyword
 285                                        definitions
 286                                        fun)
 287   (declare (type function definitionize-fun fun))
 288   (declare (type (member :vars :funs) definitionize-keyword))
 289   (declare (type list definitions))
 290   (unless (= (length definitions)
 291              (length (remove-duplicates definitions :key #'first)))
 292     (compiler-style-warn "duplicate definitions in ~S" definitions))
 293   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 294          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 295     ;; I wonder how much of an compiler performance penalty this
 296     ;; non-constant keyword is.
 297     (funcall fun definitionize-keyword processed-definitions)))
 298
 299 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 300 ;;; call FUN (with no arguments).
 301 ;;;
 302 ;;; This is split off from the IR1 convert method so that it can be
 303 ;;; shared by the special-case top level MACROLET processing code, and
 304 ;;; further split so that the special-case MACROLET processing code in
 305 ;;; EVAL can likewise make use of it.
 306 (defun macrolet-definitionize-fun (context lexenv)
 307   (flet ((fail (control &rest args)
 308            (ecase context
 309              (:compile (apply #'compiler-error control args))
 310              (:eval (error 'simple-program-error
 311                            :format-control control
 312                            :format-arguments args)))))
 313     (lambda (definition)
 314       (unless (list-of-length-at-least-p definition 2)
 315         (fail "The list ~S is too short to be a legal local macro definition."
 316               definition))
 317       (destructuring-bind (name arglist &body body) definition
 318         (unless (symbolp name)
 319           (fail "The local macro name ~S is not a symbol." name))
 320         (when (fboundp name)
 321           (program-assert-symbol-home-package-unlocked
 322            context name "binding ~A as a local macro"))
 323         (unless (listp arglist)
 324           (fail "The local macro argument list ~S is not a list."
 325                 arglist))
 326         (with-unique-names (whole environment)
 327           (multiple-value-bind (body local-decls)
 328               (parse-defmacro arglist whole body name 'macrolet
 329                               :environment environment)
 330             `(,name macro .
 331                     ,(compile-in-lexenv
 332                       nil
 333                       `(lambda (,whole ,environment)
 334                          ,@local-decls
 335                          ,body)
 336                       lexenv))))))))
 337
 338 (defun funcall-in-macrolet-lexenv (definitions fun context)
 339   (%funcall-in-foomacrolet-lexenv
 340    (macrolet-definitionize-fun context (make-restricted-lexenv *lexenv*))
 341    :funs
 342    definitions
 343    fun))
 344
 345 (def-ir1-translator macrolet ((definitions &rest body) start next result)
 346   #!+sb-doc
 347   "MACROLET ({(name lambda-list form*)}*) body-form*
 348
 349 Evaluate the BODY-FORMS in an environment with the specified local macros
 350 defined. Name is the local macro name, LAMBDA-LIST is a DEFMACRO style
 351 destructuring lambda list, and the FORMS evaluate to the expansion."
 352   (funcall-in-macrolet-lexenv
 353    definitions
 354    (lambda (&key funs)
 355      (declare (ignore funs))
 356      (ir1-translate-locally body start next result))
 357    :compile))
 358
 359 (defun symbol-macrolet-definitionize-fun (context)
 360   (flet ((fail (control &rest args)
 361            (ecase context
 362              (:compile (apply #'compiler-error control args))
 363              (:eval (error 'simple-program-error
 364                            :format-control control
 365                            :format-arguments args)))))
 366     (lambda (definition)
 367       (unless (proper-list-of-length-p definition 2)
 368         (fail "malformed symbol/expansion pair: ~S" definition))
 369       (destructuring-bind (name expansion) definition
 370         (unless (symbolp name)
 371           (fail "The local symbol macro name ~S is not a symbol." name))
 372         (when (or (boundp name) (eq (info :variable :kind name) :macro))
 373           (program-assert-symbol-home-package-unlocked
 374            context name "binding ~A as a local symbol-macro"))
 375         (let ((kind (info :variable :kind name)))
 376           (when (member kind '(:special :constant :global))
 377             (fail "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 378                   kind name)))
 379         ;; A magical cons that MACROEXPAND-1 understands.
 380         `(,name . (macro . ,expansion))))))
 381
 382 (defun funcall-in-symbol-macrolet-lexenv (definitions fun context)
 383   (%funcall-in-foomacrolet-lexenv
 384    (symbol-macrolet-definitionize-fun context)
 385    :vars
 386    definitions
 387    fun))
 388
 389 (def-ir1-translator symbol-macrolet
 390     ((macrobindings &body body) start next result)
 391   #!+sb-doc
 392   "SYMBOL-MACROLET ({(name expansion)}*) decl* form*
 393
 394 Define the NAMES as symbol macros with the given EXPANSIONS. Within the
 395 body, references to a NAME will effectively be replaced with the EXPANSION."
 396   (funcall-in-symbol-macrolet-lexenv
 397    macrobindings
 398    (lambda (&key vars)
 399      (ir1-translate-locally body start next result :vars vars))
 400    :compile))
 401 \f
 402 ;;;; %PRIMITIVE
 403 ;;;;
 404 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 405 ;;;; into a funny function.
 406
 407 ;;; Carefully evaluate a list of forms, returning a list of the results.
 408 (defun eval-info-args (args)
 409   (declare (list args))
 410   (handler-case (mapcar #'eval args)
 411     (error (condition)
 412       (compiler-error "Lisp error during evaluation of info args:~%~A"
 413                       condition))))
 414
 415 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 416 ;;; the template, the second is a list of the results of any
 417 ;;; codegen-info args, and the remaining arguments are the runtime
 418 ;;; arguments.
 419 ;;;
 420 ;;; We do various error checking now so that we don't bomb out with
 421 ;;; a fatal error during IR2 conversion.
 422 ;;;
 423 ;;; KLUDGE: It's confusing having multiple names floating around for
 424 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 425 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 426 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 427 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 428 ;;; VOP or %VOP.. -- WHN 2001-06-11
 429 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 430 (def-ir1-translator %primitive ((name &rest args) start next result)
 431   (declare (type symbol name))
 432   (let* ((template (or (gethash name *backend-template-names*)
 433                        (bug "undefined primitive ~A" name)))
 434          (required (length (template-arg-types template)))
 435          (info (template-info-arg-count template))
 436          (min (+ required info))
 437          (nargs (length args)))
 438     (if (template-more-args-type template)
 439         (when (< nargs min)
 440           (bug "Primitive ~A was called with ~R argument~:P, ~
 441                 but wants at least ~R."
 442                name
 443                nargs
 444                min))
 445         (unless (= nargs min)
 446           (bug "Primitive ~A was called with ~R argument~:P, ~
 447                 but wants exactly ~R."
 448                name
 449                nargs
 450                min)))
 451
 452     (when (template-conditional-p template)
 453       (bug "%PRIMITIVE was used with a conditional template."))
 454
 455     (when (template-more-results-type template)
 456       (bug "%PRIMITIVE was used with an unknown values template."))
 457
 458     (ir1-convert start next result
 459                  `(%%primitive ',template
 460                                ',(eval-info-args
 461                                   (subseq args required min))
 462                                ,@(subseq args 0 required)
 463                                ,@(subseq args min)))))
 464 \f
 465 ;;;; QUOTE
 466
 467 (def-ir1-translator quote ((thing) start next result)
 468   #!+sb-doc
 469   "QUOTE value
 470
 471 Return VALUE without evaluating it."
 472   (reference-constant start next result thing))
 473 \f
 474 ;;;; FUNCTION and NAMED-LAMBDA
 475 (defun name-lambdalike (thing)
 476   (ecase (car thing)
 477     ((named-lambda)
 478      (or (second thing)
 479          `(lambda ,(third thing))))
 480     ((lambda instance-lambda)
 481      `(lambda ,(second thing)))
 482     ((lambda-with-lexenv)
 483      `(lambda ,(fifth thing)))))
 484
 485 (defun fun-name-leaf (thing)
 486   (if (consp thing)
 487       (cond
 488         ((member (car thing)
 489                  '(lambda named-lambda instance-lambda lambda-with-lexenv))
 490          (values (ir1-convert-lambdalike
 491                   thing
 492                   :debug-name (name-lambdalike thing))
 493                  t))
 494         ((legal-fun-name-p thing)
 495          (values (find-lexically-apparent-fun
 496                   thing "as the argument to FUNCTION")
 497                  nil))
 498         (t
 499          (compiler-error "~S is not a legal function name." thing)))
 500       (values (find-lexically-apparent-fun
 501                thing "as the argument to FUNCTION")
 502               nil)))
 503
 504 (def-ir1-translator %%allocate-closures ((&rest leaves) start next result)
 505   (aver (eq result 'nil))
 506   (let ((lambdas leaves))
 507     (ir1-convert start next result `(%allocate-closures ',lambdas))
 508     (let ((allocator (node-dest (ctran-next start))))
 509       (dolist (lambda lambdas)
 510         (setf (functional-allocator lambda) allocator)))))
 511
 512 (defmacro with-fun-name-leaf ((leaf thing start &key global-function) &body body)
 513   `(multiple-value-bind (,leaf allocate-p)
 514        (if ,global-function
 515            (find-global-fun ,thing t)
 516            (fun-name-leaf ,thing))
 517      (if allocate-p
 518          (let ((.new-start. (make-ctran)))
 519            (ir1-convert ,start .new-start. nil `(%%allocate-closures ,leaf))
 520            (let ((,start .new-start.))
 521              ,@body))
 522          (locally
 523              ,@body))))
 524
 525 (def-ir1-translator function ((thing) start next result)
 526   #!+sb-doc
 527   "FUNCTION name
 528
 529 Return the lexically apparent definition of the function NAME. NAME may also
 530 be a lambda expression."
 531   (with-fun-name-leaf (leaf thing start)
 532     (reference-leaf start next result leaf)))
 533
 534 ;;; Like FUNCTION, but ignores local definitions and inline
 535 ;;; expansions, and doesn't nag about undefined functions.
 536 ;;; Used for optimizing things like (FUNCALL 'FOO).
 537 (def-ir1-translator global-function ((thing) start next result)
 538   (with-fun-name-leaf (leaf thing start :global-function t)
 539     (reference-leaf start next result leaf)))
 540
 541 (defun constant-global-fun-name (thing)
 542   (let ((constantp (sb!xc:constantp thing)))
 543     (when constantp
 544       (let ((name (constant-form-value thing)))
 545         (when (legal-fun-name-p name)
 546           name)))))
 547
 548 (defun lvar-constant-global-fun-name (lvar)
 549   (when (constant-lvar-p lvar)
 550     (let ((name (lvar-value lvar)))
 551       (when (legal-fun-name-p name)
 552         name))))
 553
 554 (defun ensure-source-fun-form (source &optional give-up)
 555   (let ((op (when (consp source) (car source))))
 556     (cond ((eq op '%coerce-callable-to-fun)
 557            (ensure-source-fun-form (second source)))
 558           ((member op '(function global-function lambda named-lambda))
 559            (values source nil))
 560           (t
 561            (let ((cname (constant-global-fun-name source)))
 562              (if cname
 563                  (values `(global-function ,cname) nil)
 564                  (values `(%coerce-callable-to-fun ,source) give-up)))))))
 565
 566 (defun ensure-lvar-fun-form (lvar lvar-name &optional give-up)
 567   (aver (and lvar-name (symbolp lvar-name)))
 568   (if (csubtypep (lvar-type lvar) (specifier-type 'function))
 569       lvar-name
 570       (let ((cname (lvar-constant-global-fun-name lvar)))
 571         (cond (cname
 572                `(global-function ,cname))
 573               (give-up
 574                (give-up-ir1-transform give-up))
 575               (t
 576                `(%coerce-callable-to-fun ,lvar-name))))))
 577 \f
 578 ;;;; FUNCALL
 579
 580 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 581 ;;; (not symbols). %FUNCALL is used directly in some places where the
 582 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 583 (deftransform funcall ((function &rest args) * *)
 584   (let ((arg-names (make-gensym-list (length args))))
 585     `(lambda (function ,@arg-names)
 586        (declare (ignorable function))
 587        `(%funcall ,(ensure-lvar-fun-form function 'function) ,@arg-names))))
 588
 589 (def-ir1-translator %funcall ((function &rest args) start next result)
 590   (let ((op (when (consp function) (car function))))
 591     (cond ((eq op 'function)
 592            (with-fun-name-leaf (leaf (second function) start)
 593              (ir1-convert start next result `(,leaf ,@args))))
 594           ((eq op 'global-function)
 595            (with-fun-name-leaf (leaf (second function) start :global-function t)
 596              (ir1-convert start next result `(,leaf ,@args))))
 597           (t
 598            (let ((ctran (make-ctran))
 599                  (fun-lvar (make-lvar)))
 600              (ir1-convert start ctran fun-lvar `(the function ,function))
 601              (ir1-convert-combination-args fun-lvar ctran next result args))))))
 602
 603 ;;; This source transform exists to reduce the amount of work for the
 604 ;;; compiler. If the called function is a FUNCTION form, then convert
 605 ;;; directly to %FUNCALL, instead of waiting around for type
 606 ;;; inference.
 607 (define-source-transform funcall (function &rest args)
 608   `(%funcall ,(ensure-source-fun-form function) ,@args))
 609
 610 (deftransform %coerce-callable-to-fun ((thing) * *)
 611   (ensure-lvar-fun-form thing 'thing "optimize away possible call to FDEFINITION at runtime"))
 612
 613 (define-source-transform %coerce-callable-to-fun (thing)
 614   (ensure-source-fun-form thing t))
 615 \f
 616 ;;;; LET and LET*
 617 ;;;;
 618 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 619 ;;;; any pervasive declarations also affect the evaluation of the
 620 ;;;; arguments.)
 621
 622 ;;; Given a list of binding specifiers in the style of LET, return:
 623 ;;;  1. The list of var structures for the variables bound.
 624 ;;;  2. The initial value form for each variable.
 625 ;;;
 626 ;;; The variable names are checked for legality and globally special
 627 ;;; variables are marked as such. Context is the name of the form, for
 628 ;;; error reporting purposes.
 629 (declaim (ftype (function (list symbol) (values list list))
 630                 extract-let-vars))
 631 (defun extract-let-vars (bindings context)
 632   (collect ((vars)
 633             (vals)
 634             (names))
 635     (flet ((get-var (name)
 636              (varify-lambda-arg name
 637                                 (if (eq context 'let*)
 638                                     nil
 639                                     (names)))))
 640       (dolist (spec bindings)
 641         (cond ((atom spec)
 642                (let ((var (get-var spec)))
 643                  (vars var)
 644                  (names spec)
 645                  (vals nil)))
 646               (t
 647                (unless (proper-list-of-length-p spec 1 2)
 648                  (compiler-error "The ~S binding spec ~S is malformed."
 649                                  context
 650                                  spec))
 651                (let* ((name (first spec))
 652                       (var (get-var name)))
 653                  (vars var)
 654                  (names name)
 655                  (vals (second spec)))))))
 656     (dolist (name (names))
 657       (when (eq (info :variable :kind name) :macro)
 658         (program-assert-symbol-home-package-unlocked
 659          :compile name "lexically binding symbol-macro ~A")))
 660     (values (vars) (vals))))
 661
 662 (def-ir1-translator let ((bindings &body body) start next result)
 663   #!+sb-doc
 664   "LET ({(var [value]) | var}*) declaration* form*
 665
 666 During evaluation of the FORMS, bind the VARS to the result of evaluating the
 667 VALUE forms. The variables are bound in parallel after all of the VALUES forms
 668 have been evaluated."
 669   (cond ((null bindings)
 670          (ir1-translate-locally body start next result))
 671         ((listp bindings)
 672          (multiple-value-bind (forms decls)
 673              (parse-body body :doc-string-allowed nil)
 674            (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 675              (binding* ((ctran (make-ctran))
 676                         (fun-lvar (make-lvar))
 677                         ((next result)
 678                          (processing-decls (decls vars nil next result
 679                                                   post-binding-lexenv)
 680                            (let ((fun (ir1-convert-lambda-body
 681                                        forms
 682                                        vars
 683                                        :post-binding-lexenv post-binding-lexenv
 684                                        :debug-name (debug-name 'let bindings))))
 685                              (reference-leaf start ctran fun-lvar fun))
 686                            (values next result))))
 687                (ir1-convert-combination-args fun-lvar ctran next result values)))))
 688         (t
 689          (compiler-error "Malformed LET bindings: ~S." bindings))))
 690
 691 (def-ir1-translator let* ((bindings &body body)
 692                           start next result)
 693   #!+sb-doc
 694   "LET* ({(var [value]) | var}*) declaration* form*
 695
 696 Similar to LET, but the variables are bound sequentially, allowing each VALUE
 697 form to reference any of the previous VARS."
 698   (if (listp bindings)
 699       (multiple-value-bind (forms decls)
 700           (parse-body body :doc-string-allowed nil)
 701         (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 702           (processing-decls (decls vars nil next result post-binding-lexenv)
 703             (ir1-convert-aux-bindings start
 704                                       next
 705                                       result
 706                                       forms
 707                                       vars
 708                                       values
 709                                       post-binding-lexenv))))
 710       (compiler-error "Malformed LET* bindings: ~S." bindings)))
 711
 712 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 713 ;;; and SYMBOL-MACROLET
 714 ;;;
 715 ;;; Note that all these things need to preserve toplevel-formness,
 716 ;;; but we don't need to worry about that within an IR1 translator,
 717 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 718 ;;; forms before we hit the IR1 transform level.
 719 (defun ir1-translate-locally (body start next result &key vars funs)
 720   (declare (type ctran start next) (type (or lvar null) result)
 721            (type list body))
 722   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
 723     (processing-decls (decls vars funs next result)
 724       (ir1-convert-progn-body start next result forms))))
 725
 726 (def-ir1-translator locally ((&body body) start next result)
 727   #!+sb-doc
 728   "LOCALLY declaration* form*
 729
 730 Sequentially evaluate the FORMS in a lexical environment where the
 731 DECLARATIONS have effect. If LOCALLY is a top level form, then the FORMS are
 732 also processed as top level forms."
 733   (ir1-translate-locally body start next result))
 734 \f
 735 ;;;; FLET and LABELS
 736
 737 ;;; Given a list of local function specifications in the style of
 738 ;;; FLET, return lists of the function names and of the lambdas which
 739 ;;; are their definitions.
 740 ;;;
 741 ;;; The function names are checked for legality. CONTEXT is the name
 742 ;;; of the form, for error reporting.
 743 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 744 (defun extract-flet-vars (definitions context)
 745   (collect ((names)
 746             (defs))
 747     (dolist (def definitions)
 748       (when (or (atom def) (< (length def) 2))
 749         (compiler-error "The ~S definition spec ~S is malformed." context def))
 750
 751       (let ((name (first def)))
 752         (check-fun-name name)
 753         (when (fboundp name)
 754           (program-assert-symbol-home-package-unlocked
 755            :compile name "binding ~A as a local function"))
 756         (names name)
 757         (multiple-value-bind (forms decls) (parse-body (cddr def))
 758           (defs `(lambda ,(second def)
 759                    ,@decls
 760                    (block ,(fun-name-block-name name)
 761                      . ,forms))))))
 762     (values (names) (defs))))
 763
 764 (defun ir1-convert-fbindings (start next result funs body)
 765   (let ((ctran (make-ctran))
 766         (dx-p (find-if #'leaf-dynamic-extent funs)))
 767     (when dx-p
 768       (ctran-starts-block ctran)
 769       (ctran-starts-block next))
 770     (ir1-convert start ctran nil `(%%allocate-closures ,@funs))
 771     (cond (dx-p
 772            (let* ((dummy (make-ctran))
 773                   (entry (make-entry))
 774                   (cleanup (make-cleanup :kind :dynamic-extent
 775                                          :mess-up entry
 776                                          :info (list (node-dest
 777                                                       (ctran-next start))))))
 778              (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 779              (setf (entry-cleanup entry) cleanup)
 780              (link-node-to-previous-ctran entry ctran)
 781              (use-ctran entry dummy)
 782
 783              (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 784                (ir1-convert-progn-body dummy next result body))))
 785           (t (ir1-convert-progn-body ctran next result body)))))
 786
 787 (def-ir1-translator flet ((definitions &body body)
 788                           start next result)
 789   #!+sb-doc
 790   "FLET ({(name lambda-list declaration* form*)}*) declaration* body-form*
 791
 792 Evaluate the BODY-FORMS with local function definitions. The bindings do
 793 not enclose the definitions; any use of NAME in the FORMS will refer to the
 794 lexically apparent function definition in the enclosing environment."
 795   (multiple-value-bind (forms decls)
 796       (parse-body body :doc-string-allowed nil)
 797     (multiple-value-bind (names defs)
 798         (extract-flet-vars definitions 'flet)
 799       (let ((fvars (mapcar (lambda (n d)
 800                              (ir1-convert-lambda d
 801                                                  :source-name n
 802                                                  :maybe-add-debug-catch t
 803                                                  :debug-name (debug-name 'flet n)))
 804                            names defs)))
 805         (processing-decls (decls nil fvars next result)
 806           (let ((*lexenv* (make-lexenv :funs (pairlis names fvars))))
 807             (ir1-convert-fbindings start next result fvars forms)))))))
 808
 809 (def-ir1-translator labels ((definitions &body body) start next result)
 810   #!+sb-doc
 811   "LABELS ({(name lambda-list declaration* form*)}*) declaration* body-form*
 812
 813 Evaluate the BODY-FORMS with local function definitions. The bindings enclose
 814 the new definitions, so the defined functions can call themselves or each
 815 other."
 816   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
 817     (multiple-value-bind (names defs)
 818         (extract-flet-vars definitions 'labels)
 819       (let* (;; dummy LABELS functions, to be used as placeholders
 820              ;; during construction of real LABELS functions
 821              (placeholder-funs (mapcar (lambda (name)
 822                                          (make-functional
 823                                           :%source-name name
 824                                           :%debug-name (debug-name
 825                                                         'labels-placeholder
 826                                                         name)))
 827                                        names))
 828              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 829              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 830              ;; the real LABELS functions, compiled in a LEXENV which
 831              ;; includes the dummy LABELS functions
 832              (real-funs
 833               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 834                 (mapcar (lambda (name def)
 835                           (ir1-convert-lambda def
 836                                               :source-name name
 837                                               :maybe-add-debug-catch t
 838                                               :debug-name (debug-name 'labels name)))
 839                         names defs))))
 840
 841         ;; Modify all the references to the dummy function leaves so
 842         ;; that they point to the real function leaves.
 843         (loop for real-fun in real-funs and
 844               placeholder-cons in placeholder-fenv do
 845               (substitute-leaf real-fun (cdr placeholder-cons))
 846               (setf (cdr placeholder-cons) real-fun))
 847
 848         ;; Voila.
 849         (processing-decls (decls nil real-funs next result)
 850           (let ((*lexenv* (make-lexenv
 851                            ;; Use a proper FENV here (not the
 852                            ;; placeholder used earlier) so that if the
 853                            ;; lexical environment is used for inline
 854                            ;; expansion we'll get the right functions.
 855                            :funs (pairlis names real-funs))))
 856             (ir1-convert-fbindings start next result real-funs forms)))))))
 857
 858 \f
 859 ;;;; the THE special operator, and friends
 860
 861 ;;; A logic shared among THE and TRULY-THE.
 862 (defun the-in-policy (type value policy start next result)
 863   (let ((type (if (ctype-p type) type
 864                    (compiler-values-specifier-type type))))
 865     (cond ((or (eq type *wild-type*)
 866                (eq type *universal-type*)
 867                (and (leaf-p value)
 868                     (values-subtypep (make-single-value-type (leaf-type value))
 869                                      type))
 870                (and (sb!xc:constantp value)
 871                     (ctypep (constant-form-value value)
 872                             (single-value-type type))))
 873            (ir1-convert start next result value))
 874           (t (let ((value-ctran (make-ctran))
 875                    (value-lvar (make-lvar)))
 876                (ir1-convert start value-ctran value-lvar value)
 877                (let ((cast (make-cast value-lvar type policy)))
 878                  (link-node-to-previous-ctran cast value-ctran)
 879                  (setf (lvar-dest value-lvar) cast)
 880                  (use-continuation cast next result)))))))
 881
 882 ;;; Assert that FORM evaluates to the specified type (which may be a
 883 ;;; VALUES type). TYPE may be a type specifier or (as a hack) a CTYPE.
 884 (def-ir1-translator the ((value-type form) start next result)
 885   #!+sb-doc
 886   "Specifies that the values returned by FORM conform to the VALUE-TYPE.
 887
 888 CLHS specifies that the consequences are undefined if any result is
 889 not of the declared type, but SBCL treats declarations as assertions
 890 as long as SAFETY is at least 2, in which case incorrect type
 891 information will result in a runtime type-error instead of leading to
 892 eg. heap corruption. This is however expressly non-portable: use
 893 CHECK-TYPE instead of THE to catch type-errors at runtime. THE is best
 894 considered an optimization tool to inform the compiler about types it
 895 is unable to derive from other declared types."
 896   (the-in-policy value-type form (lexenv-policy *lexenv*) start next result))
 897
 898 ;;; This is like the THE special form, except that it believes
 899 ;;; whatever you tell it. It will never generate a type check, but
 900 ;;; will cause a warning if the compiler can prove the assertion is
 901 ;;; wrong.
 902 (def-ir1-translator truly-the ((value-type form) start next result)
 903   #!+sb-doc
 904   "Specifies that the values returned by FORM conform to the
 905 VALUE-TYPE, and causes the compiler to trust this information
 906 unconditionally.
 907
 908 Consequences are undefined if any result is not of the declared type
 909 -- typical symptoms including memory corruptions. Use with great
 910 care."
 911   (the-in-policy value-type form '((type-check . 0)) start next result))
 912 \f
 913 ;;;; SETQ
 914
 915 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 916 ;;; look at the global information. If the name is for a constant,
 917 ;;; then error out.
 918 (def-ir1-translator setq ((&whole source &rest things) start next result)
 919   (let ((len (length things)))
 920     (when (oddp len)
 921       (compiler-error "odd number of args to SETQ: ~S" source))
 922     (if (= len 2)
 923         (let* ((name (first things))
 924                (value-form (second things))
 925                (leaf (or (lexenv-find name vars) (find-free-var name))))
 926           (etypecase leaf
 927             (leaf
 928              (when (constant-p leaf)
 929                (compiler-error "~S is a constant and thus can't be set." name))
 930              (when (lambda-var-p leaf)
 931                (let ((home-lambda (ctran-home-lambda-or-null start)))
 932                  (when home-lambda
 933                    (sset-adjoin leaf (lambda-calls-or-closes home-lambda))))
 934                (when (lambda-var-ignorep leaf)
 935                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 936                  ;; requires that this be a STYLE-WARNING, not a full warning.
 937                  (compiler-style-warn
 938                   "~S is being set even though it was declared to be ignored."
 939                   name)))
 940              (if (and (global-var-p leaf) (eq :unknown (global-var-kind leaf)))
 941                  ;; For undefined variables go through SET, so that we can catch
 942                  ;; constant modifications.
 943                  (ir1-convert start next result `(set ',name ,value-form))
 944                  (setq-var start next result leaf value-form)))
 945             (cons
 946              (aver (eq (car leaf) 'macro))
 947              ;; FIXME: [Free] type declaration. -- APD, 2002-01-26
 948              (ir1-convert start next result
 949                           `(setf ,(cdr leaf) ,(second things))))
 950             (heap-alien-info
 951              (ir1-convert start next result
 952                           `(%set-heap-alien ',leaf ,(second things))))))
 953         (collect ((sets))
 954           (do ((thing things (cddr thing)))
 955               ((endp thing)
 956                (ir1-convert-progn-body start next result (sets)))
 957             (sets `(setq ,(first thing) ,(second thing))))))))
 958
 959 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 960 ;;; This should only need to be called in SETQ.
 961 (defun setq-var (start next result var value)
 962   (declare (type ctran start next) (type (or lvar null) result)
 963            (type basic-var var))
 964   (let ((dest-ctran (make-ctran))
 965         (dest-lvar (make-lvar))
 966         (type (or (lexenv-find var type-restrictions)
 967                   (leaf-type var))))
 968     (ir1-convert start dest-ctran dest-lvar `(the ,type ,value))
 969     (let ((res (make-set :var var :value dest-lvar)))
 970       (setf (lvar-dest dest-lvar) res)
 971       (setf (leaf-ever-used var) t)
 972       (push res (basic-var-sets var))
 973       (link-node-to-previous-ctran res dest-ctran)
 974       (use-continuation res next result))))
 975 \f
 976 ;;;; CATCH, THROW and UNWIND-PROTECT
 977
 978 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 979 ;;; since as as far as IR1 is concerned, it has no interesting
 980 ;;; properties other than receiving multiple-values.
 981 (def-ir1-translator throw ((tag result) start next result-lvar)
 982   #!+sb-doc
 983   "THROW tag form
 984
 985 Do a non-local exit, return the values of FORM from the CATCH whose tag is EQ
 986 to TAG."
 987   (ir1-convert start next result-lvar
 988                `(multiple-value-call #'%throw ,tag ,result)))
 989
 990 ;;; This is a special special form used to instantiate a cleanup as
 991 ;;; the current cleanup within the body. KIND is the kind of cleanup
 992 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 993 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 994 ;;; and introduce the cleanup into the lexical environment. We
 995 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 996 ;;; cleanup, since this inner cleanup is the interesting one.
 997 (def-ir1-translator %within-cleanup
 998     ((kind mess-up &body body) start next result)
 999   (let ((dummy (make-ctran))
1000         (dummy2 (make-ctran)))
1001     (ir1-convert start dummy nil mess-up)
1002     (let* ((mess-node (ctran-use dummy))
1003            (cleanup (make-cleanup :kind kind
1004                                   :mess-up mess-node))
1005            (old-cup (lexenv-cleanup *lexenv*))
1006            (*lexenv* (make-lexenv :cleanup cleanup)))
1007       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
1008       (ir1-convert dummy dummy2 nil '(%cleanup-point))
1009       (ir1-convert-progn-body dummy2 next result body))))
1010
1011 ;;; This is a special special form that makes an "escape function"
1012 ;;; which returns unknown values from named block. We convert the
1013 ;;; function, set its kind to :ESCAPE, and then reference it. The
1014 ;;; :ESCAPE kind indicates that this function's purpose is to
1015 ;;; represent a non-local control transfer, and that it might not
1016 ;;; actually have to be compiled.
1017 ;;;
1018 ;;; Note that environment analysis replaces references to escape
1019 ;;; functions with references to the corresponding NLX-INFO structure.
1020 (def-ir1-translator %escape-fun ((tag) start next result)
1021   (let ((fun (let ((*allow-instrumenting* nil))
1022                (ir1-convert-lambda
1023                 `(lambda ()
1024                    (return-from ,tag (%unknown-values)))
1025                 :debug-name (debug-name 'escape-fun tag))))
1026         (ctran (make-ctran)))
1027     (setf (functional-kind fun) :escape)
1028     (ir1-convert start ctran nil `(%%allocate-closures ,fun))
1029     (reference-leaf ctran next result fun)))
1030
1031 ;;; Yet another special special form. This one looks up a local
1032 ;;; function and smashes it to a :CLEANUP function, as well as
1033 ;;; referencing it.
1034 (def-ir1-translator %cleanup-fun ((name) start next result)
1035   ;; FIXME: Should this not be :TEST #'EQUAL? What happens to
1036   ;; (SETF FOO) here?
1037   (let ((fun (lexenv-find name funs)))
1038     (aver (lambda-p fun))
1039     (setf (functional-kind fun) :cleanup)
1040     (reference-leaf start next result fun)))
1041
1042 (def-ir1-translator catch ((tag &body body) start next result)
1043   #!+sb-doc
1044   "CATCH tag form*
1045
1046 Evaluate TAG and instantiate it as a catcher while the body forms are
1047 evaluated in an implicit PROGN. If a THROW is done to TAG within the dynamic
1048 scope of the body, then control will be transferred to the end of the body and
1049 the thrown values will be returned."
1050   ;; We represent the possibility of the control transfer by making an
1051   ;; "escape function" that does a lexical exit, and instantiate the
1052   ;; cleanup using %WITHIN-CLEANUP.
1053   (ir1-convert
1054    start next result
1055    (with-unique-names (exit-block)
1056      `(block ,exit-block
1057         (%within-cleanup
1058          :catch (%catch (%escape-fun ,exit-block) ,tag)
1059          ,@body)))))
1060
1061 (def-ir1-translator unwind-protect
1062     ((protected &body cleanup) start next result)
1063   #!+sb-doc
1064   "UNWIND-PROTECT protected cleanup*
1065
1066 Evaluate the form PROTECTED, returning its values. The CLEANUP forms are
1067 evaluated whenever the dynamic scope of the PROTECTED form is exited (either
1068 due to normal completion or a non-local exit such as THROW)."
1069   ;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
1070   ;; cleanup forms into a local function so that they can be referenced
1071   ;; both in the case where we are unwound and in any local exits. We
1072   ;; use %CLEANUP-FUN on this to indicate that reference by
1073   ;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
1074   ;; an XEP.
1075   (ir1-convert
1076    start next result
1077    (with-unique-names (cleanup-fun drop-thru-tag exit-tag next start count)
1078      `(flet ((,cleanup-fun ()
1079                ,@cleanup
1080                nil))
1081         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
1082         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
1083         ;; and something can be done to make %ESCAPE-FUN have
1084         ;; dynamic extent too.
1085         (block ,drop-thru-tag
1086           (multiple-value-bind (,next ,start ,count)
1087               (block ,exit-tag
1088                 (%within-cleanup
1089                     :unwind-protect
1090                     (%unwind-protect (%escape-fun ,exit-tag)
1091                                      (%cleanup-fun ,cleanup-fun))
1092                   (return-from ,drop-thru-tag ,protected)))
1093             (declare (optimize (insert-debug-catch 0)))
1094             (,cleanup-fun)
1095             (%continue-unwind ,next ,start ,count)))))))
1096 \f
1097 ;;;; multiple-value stuff
1098
1099 (def-ir1-translator multiple-value-call ((fun &rest args) start next result)
1100   #!+sb-doc
1101   "MULTIPLE-VALUE-CALL function values-form*
1102
1103 Call FUNCTION, passing all the values of each VALUES-FORM as arguments,
1104 values from the first VALUES-FORM making up the first argument, etc."
1105   (let* ((ctran (make-ctran))
1106          (fun-lvar (make-lvar))
1107          (node (if args
1108                    ;; If there are arguments, MULTIPLE-VALUE-CALL
1109                    ;; turns into an MV-COMBINATION.
1110                    (make-mv-combination fun-lvar)
1111                    ;; If there are no arguments, then we convert to a
1112                    ;; normal combination, ensuring that a MV-COMBINATION
1113                    ;; always has at least one argument. This can be
1114                    ;; regarded as an optimization, but it is more
1115                    ;; important for simplifying compilation of
1116                    ;; MV-COMBINATIONS.
1117                    (make-combination fun-lvar))))
1118     (ir1-convert start ctran fun-lvar (ensure-source-fun-form fun))
1119     (setf (lvar-dest fun-lvar) node)
1120     (collect ((arg-lvars))
1121       (let ((this-start ctran))
1122         (dolist (arg args)
1123           (let ((this-ctran (make-ctran))
1124                 (this-lvar (make-lvar node)))
1125             (ir1-convert this-start this-ctran this-lvar arg)
1126             (setq this-start this-ctran)
1127             (arg-lvars this-lvar)))
1128         (link-node-to-previous-ctran node this-start)
1129         (use-continuation node next result)
1130         (setf (basic-combination-args node) (arg-lvars))))))
1131
1132 (def-ir1-translator multiple-value-prog1
1133     ((values-form &rest forms) start next result)
1134   #!+sb-doc
1135   "MULTIPLE-VALUE-PROG1 values-form form*
1136
1137 Evaluate VALUES-FORM and then the FORMS, but return all the values of
1138 VALUES-FORM."
1139   (let ((dummy (make-ctran)))
1140     (ctran-starts-block dummy)
1141     (ir1-convert start dummy result values-form)
1142     (ir1-convert-progn-body dummy next nil forms)))
1143 \f
1144 ;;;; interface to defining macros
1145
1146 ;;; Old CMUCL comment:
1147 ;;;
1148 ;;;   Return a new source path with any stuff intervening between the
1149 ;;;   current path and the first form beginning with NAME stripped
1150 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1151 ;;;   prevent annoying error messages.
1152 ;;;
1153 ;;; Now that we have implementations of DEFmumble macros in terms of
1154 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1155 ;;; worth figuring out why it was used, and maybe doing analogous
1156 ;;; munging to the functions created in the expanders for the macros.
1157 (defun revert-source-path (name)
1158   (do ((path *current-path* (cdr path)))
1159       ((null path) *current-path*)
1160     (let ((first (first path)))
1161       (when (or (eq first name)
1162                 (eq first 'original-source-start))
1163         (return path)))))