src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     ;; IR1-CONVERT-MAYBE-PREDICATE requires DEST to be CIF, so the
  39     ;; order of the following two forms is important
  40     (setf (continuation-dest pred) node)
  41     (ir1-convert start pred test)
  42     (link-node-to-previous-continuation node pred)
  43     (use-continuation node dummy-cont)
  44
  45     (let ((start-block (continuation-block pred)))
  46       (setf (block-last start-block) node)
  47       (continuation-starts-block cont)
  48
  49       (link-blocks start-block then-block)
  50       (link-blocks start-block else-block))
  51
  52     (ir1-convert then-cont cont then)
  53     (ir1-convert else-cont cont else)))
  54 \f
  55 ;;;; BLOCK and TAGBODY
  56
  57 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  58 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  59 ;;;; node.
  60
  61 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  62 ;;; body in the modified environment. We make CONT start a block now,
  63 ;;; since if it was done later, the block would be in the wrong
  64 ;;; environment.
  65 (def-ir1-translator block ((name &rest forms) start cont)
  66   #!+sb-doc
  67   "Block Name Form*
  68   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  69   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  70   result of Value-Form."
  71   (unless (symbolp name)
  72     (compiler-error "The block name ~S is not a symbol." name))
  73   (continuation-starts-block cont)
  74   (let* ((dummy (make-continuation))
  75          (entry (make-entry))
  76          (cleanup (make-cleanup :kind :block
  77                                 :mess-up entry)))
  78     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  79     (setf (entry-cleanup entry) cleanup)
  80     (link-node-to-previous-continuation entry start)
  81     (use-continuation entry dummy)
  82
  83     (let* ((env-entry (list entry cont))
  84            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  85                                   :cleanup cleanup)))
  86       (push env-entry (continuation-lexenv-uses cont))
  87       (ir1-convert-progn-body dummy cont forms))))
  88
  89 (def-ir1-translator return-from ((name &optional value) start cont)
  90   #!+sb-doc
  91   "Return-From Block-Name Value-Form
  92   Evaluate the Value-Form, returning its values from the lexically enclosing
  93   BLOCK Block-Name. This is constrained to be used only within the dynamic
  94   extent of the BLOCK."
  95   ;; CMU CL comment:
  96   ;;   We make CONT start a block just so that it will have a block
  97   ;;   assigned. People assume that when they pass a continuation into
  98   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  99   ;; KLUDGE: Note that this block is basically fictitious. In the code
 100   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 101   ;; it's the block which answers the question "which block is
 102   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 103   ;; dead code and so doesn't really have a block at all. The existence
 104   ;; of this block, and that way that it doesn't explicitly say
 105   ;; "I'm actually nowhere at all" makes some logic (e.g.
 106   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 107   ;; to get rid of it, perhaps using a special placeholder value
 108   ;; to indicate the orphanedness of the code.
 109   (continuation-starts-block cont)
 110   (let* ((found (or (lexenv-find name blocks)
 111                     (compiler-error "return for unknown block: ~S" name)))
 112          (value-cont (make-continuation))
 113          (entry (first found))
 114          (exit (make-exit :entry entry
 115                           :value value-cont)))
 116     (push exit (entry-exits entry))
 117     (setf (continuation-dest value-cont) exit)
 118     (ir1-convert start value-cont value)
 119     (link-node-to-previous-continuation exit value-cont)
 120     (let ((home-lambda (continuation-home-lambda-or-null start)))
 121       (when home-lambda
 122         (push entry (lambda-calls-or-closes home-lambda))))
 123     (use-continuation exit (second found))))
 124
 125 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 126 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 127 ;;; tagbody into segments of non-tag statements, and explicitly
 128 ;;; represent the drop-through with a GO. The first segment has a
 129 ;;; dummy NIL tag, since it represents code before the first tag. The
 130 ;;; last segment (which may also be the first segment) ends in NIL
 131 ;;; rather than a GO.
 132 (defun parse-tagbody (body)
 133   (declare (list body))
 134   (collect ((segments))
 135     (let ((current (cons nil body)))
 136       (loop
 137         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 138           (unless tag-pos
 139             (segments `(,@current nil))
 140             (return))
 141           (let ((tag (elt current tag-pos)))
 142             (when (assoc tag (segments))
 143               (compiler-error
 144                "The tag ~S appears more than once in the tagbody."
 145                tag))
 146             (unless (or (symbolp tag) (integerp tag))
 147               (compiler-error "~S is not a legal tagbody statement." tag))
 148             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 149           (setq current (nthcdr tag-pos current)))))
 150     (segments)))
 151
 152 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 153 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 154 ;;; Finally, convert each segment with the precomputed Start and Cont
 155 ;;; values.
 156 (def-ir1-translator tagbody ((&rest statements) start cont)
 157   #!+sb-doc
 158   "Tagbody {Tag | Statement}*
 159   Define tags for used with GO. The Statements are evaluated in order
 160   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 161   defined Tag within the lexical scope of the form, then control is transferred
 162   to the next statement following that tag. A Tag must an integer or a
 163   symbol. A statement must be a list. Other objects are illegal within the
 164   body."
 165   (continuation-starts-block cont)
 166   (let* ((dummy (make-continuation))
 167          (entry (make-entry))
 168          (segments (parse-tagbody statements))
 169          (cleanup (make-cleanup :kind :tagbody
 170                                 :mess-up entry)))
 171     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 172     (setf (entry-cleanup entry) cleanup)
 173     (link-node-to-previous-continuation entry start)
 174     (use-continuation entry dummy)
 175
 176     (collect ((tags)
 177               (starts)
 178               (conts))
 179       (starts dummy)
 180       (dolist (segment (rest segments))
 181         (let* ((tag-cont (make-continuation))
 182                (tag (list (car segment) entry tag-cont)))
 183           (conts tag-cont)
 184           (starts tag-cont)
 185           (continuation-starts-block tag-cont)
 186           (tags tag)
 187           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 188       (conts cont)
 189
 190       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 191         (mapc (lambda (segment start cont)
 192                 (ir1-convert-progn-body start cont (rest segment)))
 193               segments (starts) (conts))))))
 194
 195 ;;; Emit an EXIT node without any value.
 196 (def-ir1-translator go ((tag) start cont)
 197   #!+sb-doc
 198   "Go Tag
 199   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 200   is constrained to be used only within the dynamic extent of the TAGBODY."
 201   (continuation-starts-block cont)
 202   (let* ((found (or (lexenv-find tag tags :test #'eql)
 203                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 204                                     tag)))
 205          (entry (first found))
 206          (exit (make-exit :entry entry)))
 207     (push exit (entry-exits entry))
 208     (link-node-to-previous-continuation exit start)
 209     (let ((home-lambda (continuation-home-lambda-or-null start)))
 210       (when home-lambda
 211         (push entry (lambda-calls-or-closes home-lambda))))
 212     (use-continuation exit (second found))))
 213 \f
 214 ;;;; translators for compiler-magic special forms
 215
 216 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 217 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 218 ;;; so that they're never seen at this level.)
 219 ;;;
 220 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 221 ;;; of non-top-level EVAL-WHENs is very simple:
 222 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 223 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 224 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 225 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 226 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 227 ;;;   form; otherwise, the forms in the body are ignored.
 228 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 229   #!+sb-doc
 230   "EVAL-WHEN (Situation*) Form*
 231   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 232   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 233   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 234     (declare (ignore ct lt))
 235     (ir1-convert-progn-body start cont (and e forms)))
 236   (values))
 237
 238 ;;; common logic for MACROLET and SYMBOL-MACROLET
 239 ;;;
 240 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 241 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 242 ;;; call FUN (with no arguments).
 243 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 244                                        definitionize-keyword
 245                                        definitions
 246                                        fun)
 247   (declare (type function definitionize-fun fun))
 248   (declare (type (member :vars :funs) definitionize-keyword))
 249   (declare (type list definitions))
 250   (unless (= (length definitions)
 251              (length (remove-duplicates definitions :key #'first)))
 252     (compiler-style-warn "duplicate definitions in ~S" definitions))
 253   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 254          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 255     (funcall fun definitionize-keyword processed-definitions)))
 256
 257 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 258 ;;; call FUN (with no arguments).
 259 ;;;
 260 ;;; This is split off from the IR1 convert method so that it can be
 261 ;;; shared by the special-case top level MACROLET processing code, and
 262 ;;; further split so that the special-case MACROLET processing code in
 263 ;;; EVAL can likewise make use of it.
 264 (defmacro macrolet-definitionize-fun (context lexenv)
 265   (flet ((make-error-form (control &rest args)
 266            (ecase context
 267              (:compile `(compiler-error ,control ,@args))
 268              (:eval `(error 'simple-program-error
 269                       :format-control ,control
 270                       :format-arguments (list ,@args))))))
 271     `(lambda (definition)
 272       (unless (list-of-length-at-least-p definition 2)
 273         ,(make-error-form
 274           "The list ~S is too short to be a legal local macro definition."
 275           'definition))
 276       (destructuring-bind (name arglist &body body) definition
 277         (unless (symbolp name)
 278           ,(make-error-form "The local macro name ~S is not a symbol." 'name))
 279         (unless (listp arglist)
 280           ,(make-error-form
 281             "The local macro argument list ~S is not a list."
 282             'arglist))
 283         (with-unique-names (whole environment)
 284           (multiple-value-bind (body local-decls)
 285               (parse-defmacro arglist whole body name 'macrolet
 286                               :environment environment)
 287             `(,name macro .
 288               ,(compile-in-lexenv
 289                 nil
 290                 `(lambda (,whole ,environment)
 291                   ,@local-decls
 292                   (block ,name ,body))
 293                 ,lexenv))))))))
 294
 295 (defun funcall-in-macrolet-lexenv (definitions fun)
 296   (%funcall-in-foomacrolet-lexenv
 297    (macrolet-definitionize-fun :compile (make-restricted-lexenv *lexenv*))
 298    :funs
 299    definitions
 300    fun))
 301
 302 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 303   #!+sb-doc
 304   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 305   Evaluate the Body-Forms in an environment with the specified local macros
 306   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 307   destructuring lambda list, and the Forms evaluate to the expansion.."
 308   (funcall-in-macrolet-lexenv
 309    definitions
 310    (lambda (&key funs)
 311      (declare (ignore funs))
 312      (ir1-translate-locally body start cont))))
 313
 314 (defmacro symbol-macrolet-definitionize-fun (context)
 315   (flet ((make-error-form (control &rest args)
 316            (ecase context
 317              (:compile `(compiler-error ,control ,@args))
 318              (:eval `(error 'simple-program-error
 319                       :format-control ,control
 320                       :format-arguments (list ,@args))))))
 321     `(lambda (definition)
 322       (unless (proper-list-of-length-p definition 2)
 323        ,(make-error-form "malformed symbol/expansion pair: ~S" 'definition))
 324      (destructuring-bind (name expansion) definition
 325        (unless (symbolp name)
 326          ,(make-error-form
 327            "The local symbol macro name ~S is not a symbol."
 328            'name))
 329        (let ((kind (info :variable :kind name)))
 330          (when (member kind '(:special :constant))
 331            ,(make-error-form
 332              "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 333              'kind 'name)))
 334        `(,name . (MACRO . ,expansion))))))1
 335
 336 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 337   (%funcall-in-foomacrolet-lexenv
 338    (symbol-macrolet-definitionize-fun :compile)
 339    :vars
 340    definitions
 341    fun))
 342
 343 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 344   #!+sb-doc
 345   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 346   Define the Names as symbol macros with the given Expansions. Within the
 347   body, references to a Name will effectively be replaced with the Expansion."
 348   (funcall-in-symbol-macrolet-lexenv
 349    macrobindings
 350    (lambda (&key vars)
 351      (ir1-translate-locally body start cont :vars vars))))
 352 \f
 353 ;;;; %PRIMITIVE
 354 ;;;;
 355 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 356 ;;;; into a funny function.
 357
 358 ;;; Carefully evaluate a list of forms, returning a list of the results.
 359 (defun eval-info-args (args)
 360   (declare (list args))
 361   (handler-case (mapcar #'eval args)
 362     (error (condition)
 363       (compiler-error "Lisp error during evaluation of info args:~%~A"
 364                       condition))))
 365
 366 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 367 ;;; the template, the second is a list of the results of any
 368 ;;; codegen-info args, and the remaining arguments are the runtime
 369 ;;; arguments.
 370 ;;;
 371 ;;; We do various error checking now so that we don't bomb out with
 372 ;;; a fatal error during IR2 conversion.
 373 ;;;
 374 ;;; KLUDGE: It's confusing having multiple names floating around for
 375 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 376 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 377 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 378 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 379 ;;; VOP or %VOP.. -- WHN 2001-06-11
 380 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 381 (def-ir1-translator %primitive ((name &rest args) start cont)
 382   (declare (type symbol name))
 383   (let* ((template (or (gethash name *backend-template-names*)
 384                        (bug "undefined primitive ~A" name)))
 385          (required (length (template-arg-types template)))
 386          (info (template-info-arg-count template))
 387          (min (+ required info))
 388          (nargs (length args)))
 389     (if (template-more-args-type template)
 390         (when (< nargs min)
 391           (bug "Primitive ~A was called with ~R argument~:P, ~
 392                 but wants at least ~R."
 393                name
 394                nargs
 395                min))
 396         (unless (= nargs min)
 397           (bug "Primitive ~A was called with ~R argument~:P, ~
 398                 but wants exactly ~R."
 399                name
 400                nargs
 401                min)))
 402
 403     (when (eq (template-result-types template) :conditional)
 404       (bug "%PRIMITIVE was used with a conditional template."))
 405
 406     (when (template-more-results-type template)
 407       (bug "%PRIMITIVE was used with an unknown values template."))
 408
 409     (ir1-convert start
 410                  cont
 411                  `(%%primitive ',template
 412                                ',(eval-info-args
 413                                   (subseq args required min))
 414                                ,@(subseq args 0 required)
 415                                ,@(subseq args min)))))
 416 \f
 417 ;;;; QUOTE
 418
 419 (def-ir1-translator quote ((thing) start cont)
 420   #!+sb-doc
 421   "QUOTE Value
 422   Return Value without evaluating it."
 423   (reference-constant start cont thing))
 424 \f
 425 ;;;; FUNCTION and NAMED-LAMBDA
 426
 427 (def-ir1-translator function ((thing) start cont)
 428   #!+sb-doc
 429   "FUNCTION Name
 430   Return the lexically apparent definition of the function Name. Name may also
 431   be a lambda expression."
 432   (if (consp thing)
 433       (cond
 434         ((member (car thing)
 435                  '(lambda named-lambda instance-lambda lambda-with-lexenv))
 436          (reference-leaf start
 437                          cont
 438                          (ir1-convert-lambdalike
 439                           thing
 440                           :debug-name (debug-namify "#'~S" thing)
 441                           :allow-debug-catch-tag t)))
 442         ((legal-fun-name-p thing)
 443          (let ((var (find-lexically-apparent-fun
 444                      thing "as the argument to FUNCTION")))
 445            (reference-leaf start cont var)))
 446         (t
 447          (compiler-error "~S is not a legal function name." thing)))
 448       (let ((var (find-lexically-apparent-fun
 449                   thing "as the argument to FUNCTION")))
 450         (reference-leaf start cont var))))
 451 \f
 452 ;;;; FUNCALL
 453
 454 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 455 ;;; (not symbols). %FUNCALL is used directly in some places where the
 456 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 457 (deftransform funcall ((function &rest args) * *)
 458   (let ((arg-names (make-gensym-list (length args))))
 459     `(lambda (function ,@arg-names)
 460        (%funcall ,(if (csubtypep (continuation-type function)
 461                                  (specifier-type 'function))
 462                       'function
 463                       '(%coerce-callable-to-fun function))
 464                  ,@arg-names))))
 465
 466 (def-ir1-translator %funcall ((function &rest args) start cont)
 467   (let ((fun-cont (make-continuation)))
 468     (ir1-convert start fun-cont function)
 469     (assert-continuation-type fun-cont (specifier-type 'function)
 470                               (lexenv-policy *lexenv*))
 471     (ir1-convert-combination-args fun-cont cont args)))
 472
 473 ;;; This source transform exists to reduce the amount of work for the
 474 ;;; compiler. If the called function is a FUNCTION form, then convert
 475 ;;; directly to %FUNCALL, instead of waiting around for type
 476 ;;; inference.
 477 (define-source-transform funcall (function &rest args)
 478   (if (and (consp function) (eq (car function) 'function))
 479       `(%funcall ,function ,@args)
 480       (values nil t)))
 481
 482 (deftransform %coerce-callable-to-fun ((thing) (function) *
 483                                        :important t)
 484   "optimize away possible call to FDEFINITION at runtime"
 485   'thing)
 486 \f
 487 ;;;; LET and LET*
 488 ;;;;
 489 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 490 ;;;; any pervasive declarations also affect the evaluation of the
 491 ;;;; arguments.)
 492
 493 ;;; Given a list of binding specifiers in the style of LET, return:
 494 ;;;  1. The list of var structures for the variables bound.
 495 ;;;  2. The initial value form for each variable.
 496 ;;;
 497 ;;; The variable names are checked for legality and globally special
 498 ;;; variables are marked as such. Context is the name of the form, for
 499 ;;; error reporting purposes.
 500 (declaim (ftype (function (list symbol) (values list list))
 501                 extract-let-vars))
 502 (defun extract-let-vars (bindings context)
 503   (collect ((vars)
 504             (vals)
 505             (names))
 506     (flet ((get-var (name)
 507              (varify-lambda-arg name
 508                                 (if (eq context 'let*)
 509                                     nil
 510                                     (names)))))
 511       (dolist (spec bindings)
 512         (cond ((atom spec)
 513                (let ((var (get-var spec)))
 514                  (vars var)
 515                  (names spec)
 516                  (vals nil)))
 517               (t
 518                (unless (proper-list-of-length-p spec 1 2)
 519                  (compiler-error "The ~S binding spec ~S is malformed."
 520                                  context
 521                                  spec))
 522                (let* ((name (first spec))
 523                       (var (get-var name)))
 524                  (vars var)
 525                  (names name)
 526                  (vals (second spec)))))))
 527
 528     (values (vars) (vals))))
 529
 530 (def-ir1-translator let ((bindings &body body)
 531                          start cont)
 532   #!+sb-doc
 533   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 534   During evaluation of the Forms, bind the Vars to the result of evaluating the
 535   Value forms. The variables are bound in parallel after all of the Values are
 536   evaluated."
 537   (if (null bindings)
 538       (ir1-translate-locally  body start cont)
 539       (multiple-value-bind (forms decls) (parse-body body nil)
 540         (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 541           (let ((fun-cont (make-continuation)))
 542             (let* ((*lexenv* (process-decls decls vars nil cont))
 543                    (fun (ir1-convert-lambda-body
 544                          forms vars
 545                          :debug-name (debug-namify "LET ~S" bindings))))
 546               (reference-leaf start fun-cont fun))
 547             (ir1-convert-combination-args fun-cont cont values))))))
 548
 549 (def-ir1-translator let* ((bindings &body body)
 550                           start cont)
 551   #!+sb-doc
 552   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 553   Similar to LET, but the variables are bound sequentially, allowing each Value
 554   form to reference any of the previous Vars."
 555   (multiple-value-bind (forms decls) (parse-body body nil)
 556     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 557       (let ((*lexenv* (process-decls decls vars nil cont)))
 558         (ir1-convert-aux-bindings start cont forms vars values)))))
 559
 560 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 561 ;;; and SYMBOL-MACROLET
 562 ;;;
 563 ;;; Note that all these things need to preserve toplevel-formness,
 564 ;;; but we don't need to worry about that within an IR1 translator,
 565 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 566 ;;; forms before we hit the IR1 transform level.
 567 (defun ir1-translate-locally (body start cont &key vars funs)
 568   (declare (type list body) (type continuation start cont))
 569   (multiple-value-bind (forms decls) (parse-body body nil)
 570     (let ((*lexenv* (process-decls decls vars funs cont)))
 571       (ir1-convert-aux-bindings start cont forms nil nil))))
 572
 573 (def-ir1-translator locally ((&body body) start cont)
 574   #!+sb-doc
 575   "LOCALLY Declaration* Form*
 576   Sequentially evaluate the Forms in a lexical environment where the
 577   the Declarations have effect. If LOCALLY is a top level form, then
 578   the Forms are also processed as top level forms."
 579   (ir1-translate-locally body start cont))
 580 \f
 581 ;;;; FLET and LABELS
 582
 583 ;;; Given a list of local function specifications in the style of
 584 ;;; FLET, return lists of the function names and of the lambdas which
 585 ;;; are their definitions.
 586 ;;;
 587 ;;; The function names are checked for legality. CONTEXT is the name
 588 ;;; of the form, for error reporting.
 589 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 590 (defun extract-flet-vars (definitions context)
 591   (collect ((names)
 592             (defs))
 593     (dolist (def definitions)
 594       (when (or (atom def) (< (length def) 2))
 595         (compiler-error "The ~S definition spec ~S is malformed." context def))
 596
 597       (let ((name (first def)))
 598         (check-fun-name name)
 599         (names name)
 600         (multiple-value-bind (forms decls) (parse-body (cddr def))
 601           (defs `(lambda ,(second def)
 602                    ,@decls
 603                    (block ,(fun-name-block-name name)
 604                      . ,forms))))))
 605     (values (names) (defs))))
 606
 607 (def-ir1-translator flet ((definitions &body body)
 608                           start cont)
 609   #!+sb-doc
 610   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 611   Evaluate the Body-Forms with some local function definitions. The bindings
 612   do not enclose the definitions; any use of Name in the Forms will refer to
 613   the lexically apparent function definition in the enclosing environment."
 614   (multiple-value-bind (forms decls) (parse-body body nil)
 615     (multiple-value-bind (names defs)
 616         (extract-flet-vars definitions 'flet)
 617       (let* ((fvars (mapcar (lambda (n d)
 618                               (ir1-convert-lambda d
 619                                                   :source-name n
 620                                                   :debug-name (debug-namify
 621                                                                "FLET ~S" n)
 622                                                   :allow-debug-catch-tag t))
 623                             names defs))
 624              (*lexenv* (make-lexenv
 625                         :default (process-decls decls nil fvars cont)
 626                         :funs (pairlis names fvars))))
 627         (ir1-convert-progn-body start cont forms)))))
 628
 629 (def-ir1-translator labels ((definitions &body body) start cont)
 630   #!+sb-doc
 631   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 632   Evaluate the Body-Forms with some local function definitions. The bindings
 633   enclose the new definitions, so the defined functions can call themselves or
 634   each other."
 635   (multiple-value-bind (forms decls) (parse-body body nil)
 636     (multiple-value-bind (names defs)
 637         (extract-flet-vars definitions 'labels)
 638       (let* (;; dummy LABELS functions, to be used as placeholders
 639              ;; during construction of real LABELS functions
 640              (placeholder-funs (mapcar (lambda (name)
 641                                          (make-functional
 642                                           :%source-name name
 643                                           :%debug-name (debug-namify
 644                                                         "LABELS placeholder ~S"
 645                                                         name)))
 646                                        names))
 647              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 648              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 649              ;; the real LABELS functions, compiled in a LEXENV which
 650              ;; includes the dummy LABELS functions
 651              (real-funs
 652               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 653                 (mapcar (lambda (name def)
 654                           (ir1-convert-lambda def
 655                                               :source-name name
 656                                               :debug-name (debug-namify
 657                                                            "LABELS ~S" name)
 658                                               :allow-debug-catch-tag t))
 659                         names defs))))
 660
 661         ;; Modify all the references to the dummy function leaves so
 662         ;; that they point to the real function leaves.
 663         (loop for real-fun in real-funs and
 664               placeholder-cons in placeholder-fenv do
 665               (substitute-leaf real-fun (cdr placeholder-cons))
 666               (setf (cdr placeholder-cons) real-fun))
 667
 668         ;; Voila.
 669         (let ((*lexenv* (make-lexenv
 670                          :default (process-decls decls nil real-funs cont)
 671                          ;; Use a proper FENV here (not the
 672                          ;; placeholder used earlier) so that if the
 673                          ;; lexical environment is used for inline
 674                          ;; expansion we'll get the right functions.
 675                          :funs (pairlis names real-funs))))
 676           (ir1-convert-progn-body start cont forms))))))
 677 \f
 678 ;;;; the THE special operator, and friends
 679
 680 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 681 ;;; continuation that the assertion applies to, TYPE is the type
 682 ;;; specifier and LEXENV is the current lexical environment. NAME is
 683 ;;; the name of the declaration we are doing, for use in error
 684 ;;; messages.
 685 ;;;
 686 ;;; This is somewhat involved, since a type assertion may only be made
 687 ;;; on a continuation, not on a node. We can't just set the
 688 ;;; continuation asserted type and let it go at that, since there may
 689 ;;; be parallel THE's for the same continuation, i.e.
 690 ;;;     (if ...
 691 ;;;      (the foo ...)
 692 ;;;      (the bar ...))
 693 ;;;
 694 ;;; In this case, our representation can do no better than the union
 695 ;;; of these assertions. And if there is a branch with no assertion,
 696 ;;; we have nothing at all. We really need to recognize scoping, since
 697 ;;; we need to be able to discern between parallel assertions (which
 698 ;;; we union) and nested ones (which we intersect).
 699 ;;;
 700 ;;; We represent the scoping by throwing our innermost (intersected)
 701 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 702 ;;; intersect our assertions together. If CONT has no uses yet, we
 703 ;;; have not yet bottomed out on the first COND branch; in this case
 704 ;;; we optimistically assume that this type will be the one we end up
 705 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 706 ;;; than the type that we have the first time we bottom out. Later
 707 ;;; THE's (or the absence thereof) can only weaken this result.
 708 ;;;
 709 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 710 ;;; across COND branches. We can't do it here, since we don't know how
 711 ;;; many branches there are going to be.
 712 (defun ir1ize-the-or-values (type cont lexenv place)
 713   (declare (type continuation cont) (type lexenv lexenv))
 714   (let* ((atype (if (typep type 'ctype)
 715                     type
 716                     (compiler-values-specifier-type type)))
 717          (old-atype (or (lexenv-find cont type-restrictions)
 718                         *wild-type*))
 719          (old-ctype (or (lexenv-find cont weakend-type-restrictions)
 720                         *wild-type*))
 721          (intersects (values-types-equal-or-intersect old-atype atype))
 722          (new-atype (values-type-intersection old-atype atype))
 723          (new-ctype (values-type-intersection
 724                      old-ctype
 725                      (maybe-weaken-check atype (lexenv-policy lexenv)))))
 726     (when (null (find-uses cont))
 727       (setf (continuation-asserted-type cont) new-atype)
 728       (setf (continuation-type-to-check cont) new-ctype))
 729     (when (and (not intersects)
 730                ;; FIXME: Is it really right to look at *LEXENV* here,
 731                ;; instead of looking at the LEXENV argument? Why?
 732                (not (policy *lexenv*
 733                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 734       (compiler-warn
 735        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 736        (type-specifier atype)
 737        place
 738        (type-specifier old-atype)))
 739     (make-lexenv :type-restrictions `((,cont . ,new-atype))
 740                  :weakend-type-restrictions `((,cont . ,new-ctype))
 741                  :default lexenv)))
 742
 743 ;;; Assert that FORM evaluates to the specified type (which may be a
 744 ;;; VALUES type).
 745 ;;;
 746 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 747 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 748 ;;; values. Check that SBCL doesn't have this problem.
 749 (def-ir1-translator the ((type value) start cont)
 750   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 751                                           "in THE declaration")
 752     (ir1-convert start cont value)))
 753
 754 ;;; This is like the THE special form, except that it believes
 755 ;;; whatever you tell it. It will never generate a type check, but
 756 ;;; will cause a warning if the compiler can prove the assertion is
 757 ;;; wrong.
 758 ;;;
 759 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 760 ;;; its uses's types, setting it won't work. Instead we must intersect
 761 ;;; the type with the uses's DERIVED-TYPE.
 762 (def-ir1-translator truly-the ((type value) start cont)
 763   #!+sb-doc
 764   (declare (inline member))
 765   (let ((type (compiler-values-specifier-type type))
 766         (old (find-uses cont)))
 767     (ir1-convert start cont value)
 768     (do-uses (use cont)
 769       (unless (member use old :test #'eq)
 770         (derive-node-type use type)))))
 771 \f
 772 ;;;; SETQ
 773
 774 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 775 ;;; look at the global information. If the name is for a constant,
 776 ;;; then error out.
 777 (def-ir1-translator setq ((&whole source &rest things) start cont)
 778   (let ((len (length things)))
 779     (when (oddp len)
 780       (compiler-error "odd number of args to SETQ: ~S" source))
 781     (if (= len 2)
 782         (let* ((name (first things))
 783                (leaf (or (lexenv-find name vars)
 784                          (find-free-var name))))
 785           (etypecase leaf
 786             (leaf
 787              (when (constant-p leaf)
 788                (compiler-error "~S is a constant and thus can't be set." name))
 789              (when (lambda-var-p leaf)
 790                (let ((home-lambda (continuation-home-lambda-or-null start)))
 791                  (when home-lambda
 792                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 793                (when (lambda-var-ignorep leaf)
 794                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 795                  ;; requires that this be a STYLE-WARNING, not a full warning.
 796                  (compiler-style-warn
 797                   "~S is being set even though it was declared to be ignored."
 798                   name)))
 799              (setq-var start cont leaf (second things)))
 800             (cons
 801              (aver (eq (car leaf) 'MACRO))
 802              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 803             (heap-alien-info
 804              (ir1-convert start cont
 805                           `(%set-heap-alien ',leaf ,(second things))))))
 806         (collect ((sets))
 807           (do ((thing things (cddr thing)))
 808               ((endp thing)
 809                (ir1-convert-progn-body start cont (sets)))
 810             (sets `(setq ,(first thing) ,(second thing))))))))
 811
 812 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 813 ;;; This should only need to be called in SETQ.
 814 (defun setq-var (start cont var value)
 815   (declare (type continuation start cont) (type basic-var var))
 816   (let ((dest (make-continuation)))
 817     (ir1-convert start dest value)
 818     (assert-continuation-type dest
 819                               (or (lexenv-find var type-restrictions)
 820                                   (leaf-type var))
 821                               (lexenv-policy *lexenv*))
 822     (let ((res (make-set :var var :value dest)))
 823       (setf (continuation-dest dest) res)
 824       (setf (leaf-ever-used var) t)
 825       (push res (basic-var-sets var))
 826       (link-node-to-previous-continuation res dest)
 827       (use-continuation res cont))))
 828 \f
 829 ;;;; CATCH, THROW and UNWIND-PROTECT
 830
 831 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 832 ;;; since as as far as IR1 is concerned, it has no interesting
 833 ;;; properties other than receiving multiple-values.
 834 (def-ir1-translator throw ((tag result) start cont)
 835   #!+sb-doc
 836   "Throw Tag Form
 837   Do a non-local exit, return the values of Form from the CATCH whose tag
 838   evaluates to the same thing as Tag."
 839   (ir1-convert start cont
 840                `(multiple-value-call #'%throw ,tag ,result)))
 841
 842 ;;; This is a special special form used to instantiate a cleanup as
 843 ;;; the current cleanup within the body. KIND is the kind of cleanup
 844 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 845 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 846 ;;; and introduce the cleanup into the lexical environment. We
 847 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 848 ;;; cleanup, since this inner cleanup is the interesting one.
 849 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 850   (let ((dummy (make-continuation))
 851         (dummy2 (make-continuation)))
 852     (ir1-convert start dummy mess-up)
 853     (let* ((mess-node (continuation-use dummy))
 854            (cleanup (make-cleanup :kind kind
 855                                   :mess-up mess-node))
 856            (old-cup (lexenv-cleanup *lexenv*))
 857            (*lexenv* (make-lexenv :cleanup cleanup)))
 858       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 859       (ir1-convert dummy dummy2 '(%cleanup-point))
 860       (ir1-convert-progn-body dummy2 cont body))))
 861
 862 ;;; This is a special special form that makes an "escape function"
 863 ;;; which returns unknown values from named block. We convert the
 864 ;;; function, set its kind to :ESCAPE, and then reference it. The
 865 ;;; :ESCAPE kind indicates that this function's purpose is to
 866 ;;; represent a non-local control transfer, and that it might not
 867 ;;; actually have to be compiled.
 868 ;;;
 869 ;;; Note that environment analysis replaces references to escape
 870 ;;; functions with references to the corresponding NLX-INFO structure.
 871 (def-ir1-translator %escape-fun ((tag) start cont)
 872   (let ((fun (ir1-convert-lambda
 873               `(lambda ()
 874                  (return-from ,tag (%unknown-values)))
 875               :debug-name (debug-namify "escape function for ~S" tag))))
 876     (setf (functional-kind fun) :escape)
 877     (reference-leaf start cont fun)))
 878
 879 ;;; Yet another special special form. This one looks up a local
 880 ;;; function and smashes it to a :CLEANUP function, as well as
 881 ;;; referencing it.
 882 (def-ir1-translator %cleanup-fun ((name) start cont)
 883   (let ((fun (lexenv-find name funs)))
 884     (aver (lambda-p fun))
 885     (setf (functional-kind fun) :cleanup)
 886     (reference-leaf start cont fun)))
 887
 888 (def-ir1-translator catch ((tag &body body) start cont)
 889   #!+sb-doc
 890   "Catch Tag Form*
 891   Evaluate TAG and instantiate it as a catcher while the body forms are
 892   evaluated in an implicit PROGN. If a THROW is done to TAG within the dynamic
 893   scope of the body, then control will be transferred to the end of the body
 894   and the thrown values will be returned."
 895   ;; We represent the possibility of the control transfer by making an
 896   ;; "escape function" that does a lexical exit, and instantiate the
 897   ;; cleanup using %WITHIN-CLEANUP.
 898   (ir1-convert
 899    start cont
 900    (with-unique-names (exit-block)
 901      `(block ,exit-block
 902         (%within-cleanup
 903             :catch
 904             (%catch (%escape-fun ,exit-block) ,tag)
 905           ,@body)))))
 906
 907 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 908   #!+sb-doc
 909   "Unwind-Protect Protected Cleanup*
 910   Evaluate the form PROTECTED, returning its values. The CLEANUP forms are
 911   evaluated whenever the dynamic scope of the PROTECTED form is exited (either
 912   due to normal completion or a non-local exit such as THROW)."
 913   ;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 914   ;; cleanup forms into a local function so that they can be referenced
 915   ;; both in the case where we are unwound and in any local exits. We
 916   ;; use %CLEANUP-FUN on this to indicate that reference by
 917   ;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 918   ;; an XEP.
 919   (ir1-convert
 920    start cont
 921    (with-unique-names (cleanup-fun drop-thru-tag exit-tag next start count)
 922      `(flet ((,cleanup-fun () ,@cleanup nil))
 923         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 924         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 925         ;; and something can be done to make %ESCAPE-FUN have
 926         ;; dynamic extent too.
 927         (block ,drop-thru-tag
 928           (multiple-value-bind (,next ,start ,count)
 929               (block ,exit-tag
 930                 (%within-cleanup
 931                     :unwind-protect
 932                     (%unwind-protect (%escape-fun ,exit-tag)
 933                                      (%cleanup-fun ,cleanup-fun))
 934                   (return-from ,drop-thru-tag ,protected)))
 935             (,cleanup-fun)
 936             (%continue-unwind ,next ,start ,count)))))))
 937 \f
 938 ;;;; multiple-value stuff
 939
 940 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 941   #!+sb-doc
 942   "MULTIPLE-VALUE-CALL Function Values-Form*
 943   Call FUNCTION, passing all the values of each VALUES-FORM as arguments,
 944   values from the first VALUES-FORM making up the first argument, etc."
 945   (let* ((fun-cont (make-continuation))
 946          (node (if args
 947                    ;; If there are arguments, MULTIPLE-VALUE-CALL
 948                    ;; turns into an MV-COMBINATION.
 949                    (make-mv-combination fun-cont)
 950                    ;; If there are no arguments, then we convert to a
 951                    ;; normal combination, ensuring that a MV-COMBINATION
 952                    ;; always has at least one argument. This can be
 953                    ;; regarded as an optimization, but it is more
 954                    ;; important for simplifying compilation of
 955                    ;; MV-COMBINATIONS.
 956                    (make-combination fun-cont))))
 957     (ir1-convert start fun-cont
 958                  (if (and (consp fun) (eq (car fun) 'function))
 959                      fun
 960                      `(%coerce-callable-to-fun ,fun)))
 961     (setf (continuation-dest fun-cont) node)
 962     (collect ((arg-conts))
 963       (let ((this-start fun-cont))
 964         (dolist (arg args)
 965           (let ((this-cont (make-continuation node)))
 966             (ir1-convert this-start this-cont arg)
 967             (setq this-start this-cont)
 968             (arg-conts this-cont)))
 969         (link-node-to-previous-continuation node this-start)
 970         (use-continuation node cont)
 971         (setf (basic-combination-args node) (arg-conts))))))
 972
 973 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 974 ;;; the result code use result continuation (CONT), but transfer
 975 ;;; control to the evaluation of the body. In other words, the result
 976 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 977 ;;; the result.
 978 ;;;
 979 ;;; In order to get the control flow right, we convert the result with
 980 ;;; a dummy result continuation, then convert all the uses of the
 981 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 982 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 983 ;;; that they are consistent. Note that this doesn't amount to
 984 ;;; changing the exit target, since the control destination of an exit
 985 ;;; is determined by the block successor; we are just indicating the
 986 ;;; continuation that the result is delivered to.
 987 ;;;
 988 ;;; We then convert the body, using another dummy continuation in its
 989 ;;; own block as the result. After we are done converting the body, we
 990 ;;; move all predecessors of the dummy end block to CONT's block.
 991 ;;;
 992 ;;; Note that we both exploit and maintain the invariant that the CONT
 993 ;;; to an IR1 convert method either has no block or starts the block
 994 ;;; that control should transfer to after completion for the form.
 995 ;;; Nested MV-PROG1's work because during conversion of the result
 996 ;;; form, we use dummy continuation whose block is the true control
 997 ;;; destination.
 998 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
 999   #!+sb-doc
1000   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1001   Evaluate Values-Form and then the Forms, but return all the values of
1002   Values-Form."
1003   (continuation-starts-block cont)
1004   (let* ((dummy-result (make-continuation))
1005          (dummy-start (make-continuation))
1006          (cont-block (continuation-block cont)))
1007     (continuation-starts-block dummy-start)
1008     (ir1-convert start dummy-start result)
1009
1010     (with-continuation-type-assertion
1011         ;; FIXME: policy
1012         (cont (continuation-asserted-type dummy-start)
1013               "of the first form")
1014       (substitute-continuation-uses cont dummy-start))
1015
1016     (continuation-starts-block dummy-result)
1017     (ir1-convert-progn-body dummy-start dummy-result forms)
1018     (let ((end-block (continuation-block dummy-result)))
1019       (dolist (pred (block-pred end-block))
1020         (unlink-blocks pred end-block)
1021         (link-blocks pred cont-block))
1022       (aver (not (continuation-dest dummy-result)))
1023       (delete-continuation dummy-result)
1024       (remove-from-dfo end-block))))
1025 \f
1026 ;;;; interface to defining macros
1027
1028 ;;; Old CMUCL comment:
1029 ;;;
1030 ;;;   Return a new source path with any stuff intervening between the
1031 ;;;   current path and the first form beginning with NAME stripped
1032 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1033 ;;;   prevent annoying error messages.
1034 ;;;
1035 ;;; Now that we have implementations of DEFmumble macros in terms of
1036 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1037 ;;; worth figuring out why it was used, and maybe doing analogous
1038 ;;; munging to the functions created in the expanders for the macros.
1039 (defun revert-source-path (name)
1040   (do ((path *current-path* (cdr path)))
1041       ((null path) *current-path*)
1042     (let ((first (first path)))
1043       (when (or (eq first name)
1044                 (eq first 'original-source-start))
1045         (return path)))))