src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     (setf (continuation-dest pred) node)
  39     (ir1-convert start pred test)
  40     (link-node-to-previous-continuation node pred)
  41     (use-continuation node dummy-cont)
  42
  43     (let ((start-block (continuation-block pred)))
  44       (setf (block-last start-block) node)
  45       (continuation-starts-block cont)
  46
  47       (link-blocks start-block then-block)
  48       (link-blocks start-block else-block))
  49
  50     (ir1-convert then-cont cont then)
  51     (ir1-convert else-cont cont else)))
  52 \f
  53 ;;;; BLOCK and TAGBODY
  54
  55 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  56 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  57 ;;;; node.
  58
  59 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  60 ;;; body in the modified environment. We make CONT start a block now,
  61 ;;; since if it was done later, the block would be in the wrong
  62 ;;; environment.
  63 (def-ir1-translator block ((name &rest forms) start cont)
  64   #!+sb-doc
  65   "Block Name Form*
  66   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  67   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  68   result of Value-Form."
  69   (unless (symbolp name)
  70     (compiler-error "The block name ~S is not a symbol." name))
  71   (continuation-starts-block cont)
  72   (let* ((dummy (make-continuation))
  73          (entry (make-entry))
  74          (cleanup (make-cleanup :kind :block
  75                                 :mess-up entry)))
  76     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  77     (setf (entry-cleanup entry) cleanup)
  78     (link-node-to-previous-continuation entry start)
  79     (use-continuation entry dummy)
  80
  81     (let* ((env-entry (list entry cont))
  82            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  83                                   :cleanup cleanup)))
  84       (push env-entry (continuation-lexenv-uses cont))
  85       (ir1-convert-progn-body dummy cont forms))))
  86
  87 (def-ir1-translator return-from ((name &optional value) start cont)
  88   #!+sb-doc
  89   "Return-From Block-Name Value-Form
  90   Evaluate the Value-Form, returning its values from the lexically enclosing
  91   BLOCK Block-Name. This is constrained to be used only within the dynamic
  92   extent of the BLOCK."
  93   ;; CMU CL comment:
  94   ;;   We make CONT start a block just so that it will have a block
  95   ;;   assigned. People assume that when they pass a continuation into
  96   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  97   ;; KLUDGE: Note that this block is basically fictitious. In the code
  98   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
  99   ;; it's the block which answers the question "which block is
 100   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 101   ;; dead code and so doesn't really have a block at all. The existence
 102   ;; of this block, and that way that it doesn't explicitly say
 103   ;; "I'm actually nowhere at all" makes some logic (e.g.
 104   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 105   ;; to get rid of it, perhaps using a special placeholder value
 106   ;; to indicate the orphanedness of the code.
 107   (continuation-starts-block cont)
 108   (let* ((found (or (lexenv-find name blocks)
 109                     (compiler-error "return for unknown block: ~S" name)))
 110          (value-cont (make-continuation))
 111          (entry (first found))
 112          (exit (make-exit :entry entry
 113                           :value value-cont)))
 114     (push exit (entry-exits entry))
 115     (setf (continuation-dest value-cont) exit)
 116     (ir1-convert start value-cont value)
 117     (link-node-to-previous-continuation exit value-cont)
 118     (let ((home-lambda (continuation-home-lambda-or-null start)))
 119       (when home-lambda
 120         (push entry (lambda-calls-or-closes home-lambda))))
 121     (use-continuation exit (second found))))
 122
 123 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 124 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 125 ;;; tagbody into segments of non-tag statements, and explicitly
 126 ;;; represent the drop-through with a GO. The first segment has a
 127 ;;; dummy NIL tag, since it represents code before the first tag. The
 128 ;;; last segment (which may also be the first segment) ends in NIL
 129 ;;; rather than a GO.
 130 (defun parse-tagbody (body)
 131   (declare (list body))
 132   (collect ((segments))
 133     (let ((current (cons nil body)))
 134       (loop
 135         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 136           (unless tag-pos
 137             (segments `(,@current nil))
 138             (return))
 139           (let ((tag (elt current tag-pos)))
 140             (when (assoc tag (segments))
 141               (compiler-error
 142                "The tag ~S appears more than once in the tagbody."
 143                tag))
 144             (unless (or (symbolp tag) (integerp tag))
 145               (compiler-error "~S is not a legal tagbody statement." tag))
 146             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 147           (setq current (nthcdr tag-pos current)))))
 148     (segments)))
 149
 150 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 151 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 152 ;;; Finally, convert each segment with the precomputed Start and Cont
 153 ;;; values.
 154 (def-ir1-translator tagbody ((&rest statements) start cont)
 155   #!+sb-doc
 156   "Tagbody {Tag | Statement}*
 157   Define tags for used with GO. The Statements are evaluated in order
 158   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 159   defined Tag within the lexical scope of the form, then control is transferred
 160   to the next statement following that tag. A Tag must an integer or a
 161   symbol. A statement must be a list. Other objects are illegal within the
 162   body."
 163   (continuation-starts-block cont)
 164   (let* ((dummy (make-continuation))
 165          (entry (make-entry))
 166          (segments (parse-tagbody statements))
 167          (cleanup (make-cleanup :kind :tagbody
 168                                 :mess-up entry)))
 169     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 170     (setf (entry-cleanup entry) cleanup)
 171     (link-node-to-previous-continuation entry start)
 172     (use-continuation entry dummy)
 173
 174     (collect ((tags)
 175               (starts)
 176               (conts))
 177       (starts dummy)
 178       (dolist (segment (rest segments))
 179         (let* ((tag-cont (make-continuation))
 180                (tag (list (car segment) entry tag-cont)))
 181           (conts tag-cont)
 182           (starts tag-cont)
 183           (continuation-starts-block tag-cont)
 184           (tags tag)
 185           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 186       (conts cont)
 187
 188       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 189         (mapc (lambda (segment start cont)
 190                 (ir1-convert-progn-body start cont (rest segment)))
 191               segments (starts) (conts))))))
 192
 193 ;;; Emit an EXIT node without any value.
 194 (def-ir1-translator go ((tag) start cont)
 195   #!+sb-doc
 196   "Go Tag
 197   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 198   is constrained to be used only within the dynamic extent of the TAGBODY."
 199   (continuation-starts-block cont)
 200   (let* ((found (or (lexenv-find tag tags :test #'eql)
 201                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 202                                     tag)))
 203          (entry (first found))
 204          (exit (make-exit :entry entry)))
 205     (push exit (entry-exits entry))
 206     (link-node-to-previous-continuation exit start)
 207     (let ((home-lambda (continuation-home-lambda-or-null start)))
 208       (when home-lambda
 209         (push entry (lambda-calls-or-closes home-lambda))))
 210     (use-continuation exit (second found))))
 211 \f
 212 ;;;; translators for compiler-magic special forms
 213
 214 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 215 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 216 ;;; so that they're never seen at this level.)
 217 ;;;
 218 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 219 ;;; of non-top-level EVAL-WHENs is very simple:
 220 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 221 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 222 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 223 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 224 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 225 ;;;   form; otherwise, the forms in the body are ignored.
 226 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 227   #!+sb-doc
 228   "EVAL-WHEN (Situation*) Form*
 229   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 230   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 231   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 232     (declare (ignore ct lt))
 233     (ir1-convert-progn-body start cont (and e forms)))
 234   (values))
 235
 236 ;;; common logic for MACROLET and SYMBOL-MACROLET
 237 ;;;
 238 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 239 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 240 ;;; call FUN (with no arguments).
 241 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 242                                        definitionize-keyword
 243                                        definitions
 244                                        fun)
 245   (declare (type function definitionize-fun fun))
 246   (declare (type (member :vars :funs) definitionize-keyword))
 247   (declare (type list definitions))
 248   (unless (= (length definitions)
 249              (length (remove-duplicates definitions :key #'first)))
 250     (compiler-style-warn "duplicate definitions in ~S" definitions))
 251   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 252          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 253     (funcall fun definitionize-keyword processed-definitions)))
 254
 255 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 256 ;;; call FUN (with no arguments).
 257 ;;;
 258 ;;; This is split off from the IR1 convert method so that it can be
 259 ;;; shared by the special-case top level MACROLET processing code, and
 260 ;;; further split so that the special-case MACROLET processing code in
 261 ;;; EVAL can likewise make use of it.
 262 (defmacro macrolet-definitionize-fun (context lexenv)
 263   (flet ((make-error-form (control &rest args)
 264            (ecase context
 265              (:compile `(compiler-error ,control ,@args))
 266              (:eval `(error 'simple-program-error
 267                       :format-control ,control
 268                       :format-arguments (list ,@args))))))
 269     `(lambda (definition)
 270       (unless (list-of-length-at-least-p definition 2)
 271         ,(make-error-form "The list ~S is too short to be a legal local macro definition." 'definition))
 272       (destructuring-bind (name arglist &body body) definition
 273         (unless (symbolp name)
 274           ,(make-error-form "The local macro name ~S is not a symbol." 'name))
 275         (unless (listp arglist)
 276           ,(make-error-form "The local macro argument list ~S is not a list." 'arglist))
 277         (let ((whole (gensym "WHOLE"))
 278               (environment (gensym "ENVIRONMENT")))
 279           (multiple-value-bind (body local-decls)
 280               (parse-defmacro arglist whole body name 'macrolet
 281                               :environment environment)
 282             `(,name macro .
 283               ,(compile-in-lexenv
 284                 nil
 285                 `(lambda (,whole ,environment)
 286                   ,@local-decls
 287                   (block ,name ,body))
 288                 ,lexenv))))))))
 289
 290 (defun funcall-in-macrolet-lexenv (definitions fun)
 291   (%funcall-in-foomacrolet-lexenv
 292    (macrolet-definitionize-fun :compile (make-restricted-lexenv *lexenv*))
 293    :funs
 294    definitions
 295    fun))
 296
 297 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 298   #!+sb-doc
 299   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 300   Evaluate the Body-Forms in an environment with the specified local macros
 301   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 302   destructuring lambda list, and the Forms evaluate to the expansion.."
 303   (funcall-in-macrolet-lexenv
 304    definitions
 305    (lambda (&key funs)
 306      (declare (ignore funs))
 307      (ir1-translate-locally body start cont))))
 308
 309 (defmacro symbol-macrolet-definitionize-fun (context)
 310   (flet ((make-error-form (control &rest args)
 311            (ecase context
 312              (:compile `(compiler-error ,control ,@args))
 313              (:eval `(error 'simple-program-error
 314                       :format-control ,control
 315                       :format-arguments (list ,@args))))))
 316     `(lambda (definition)
 317       (unless (proper-list-of-length-p definition 2)
 318        ,(make-error-form "malformed symbol/expansion pair: ~S" 'definition))
 319      (destructuring-bind (name expansion) definition
 320        (unless (symbolp name)
 321          ,(make-error-form
 322            "The local symbol macro name ~S is not a symbol."
 323            'name))
 324        (let ((kind (info :variable :kind name)))
 325          (when (member kind '(:special :constant))
 326            ,(make-error-form
 327              "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 328              'kind 'name)))
 329        `(,name . (MACRO . ,expansion))))))1
 330
 331 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 332   (%funcall-in-foomacrolet-lexenv
 333    (symbol-macrolet-definitionize-fun :compile)
 334    :vars
 335    definitions
 336    fun))
 337
 338 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 339   #!+sb-doc
 340   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 341   Define the Names as symbol macros with the given Expansions. Within the
 342   body, references to a Name will effectively be replaced with the Expansion."
 343   (funcall-in-symbol-macrolet-lexenv
 344    macrobindings
 345    (lambda (&key vars)
 346      (ir1-translate-locally body start cont :vars vars))))
 347
 348 ;;; not really a special form, but..
 349 (def-ir1-translator declare ((&rest stuff) start cont)
 350   (declare (ignore stuff))
 351   ;; We ignore START and CONT too, but we can't use DECLARE IGNORE to
 352   ;; tell the compiler about it here, because the DEF-IR1-TRANSLATOR
 353   ;; macro would put the DECLARE in the wrong place, so..
 354   start cont
 355   (compiler-error "misplaced declaration"))
 356 \f
 357 ;;;; %PRIMITIVE
 358 ;;;;
 359 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 360 ;;;; into a funny function.
 361
 362 ;;; Carefully evaluate a list of forms, returning a list of the results.
 363 (defun eval-info-args (args)
 364   (declare (list args))
 365   (handler-case (mapcar #'eval args)
 366     (error (condition)
 367       (compiler-error "Lisp error during evaluation of info args:~%~A"
 368                       condition))))
 369
 370 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 371 ;;; the template, the second is a list of the results of any
 372 ;;; codegen-info args, and the remaining arguments are the runtime
 373 ;;; arguments.
 374 ;;;
 375 ;;; We do various error checking now so that we don't bomb out with
 376 ;;; a fatal error during IR2 conversion.
 377 ;;;
 378 ;;; KLUDGE: It's confusing having multiple names floating around for
 379 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 380 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 381 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 382 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 383 ;;; VOP or %VOP.. -- WHN 2001-06-11
 384 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 385 (def-ir1-translator %primitive ((name &rest args) start cont)
 386   (declare (type symbol name))
 387   (let* ((template (or (gethash name *backend-template-names*)
 388                        (bug "undefined primitive ~A" name)))
 389          (required (length (template-arg-types template)))
 390          (info (template-info-arg-count template))
 391          (min (+ required info))
 392          (nargs (length args)))
 393     (if (template-more-args-type template)
 394         (when (< nargs min)
 395           (bug "Primitive ~A was called with ~R argument~:P, ~
 396                 but wants at least ~R."
 397                name
 398                nargs
 399                min))
 400         (unless (= nargs min)
 401           (bug "Primitive ~A was called with ~R argument~:P, ~
 402                 but wants exactly ~R."
 403                name
 404                nargs
 405                min)))
 406
 407     (when (eq (template-result-types template) :conditional)
 408       (bug "%PRIMITIVE was used with a conditional template."))
 409
 410     (when (template-more-results-type template)
 411       (bug "%PRIMITIVE was used with an unknown values template."))
 412
 413     (ir1-convert start
 414                  cont
 415                  `(%%primitive ',template
 416                                ',(eval-info-args
 417                                   (subseq args required min))
 418                                ,@(subseq args 0 required)
 419                                ,@(subseq args min)))))
 420 \f
 421 ;;;; QUOTE
 422
 423 (def-ir1-translator quote ((thing) start cont)
 424   #!+sb-doc
 425   "QUOTE Value
 426   Return Value without evaluating it."
 427   (reference-constant start cont thing))
 428 \f
 429 ;;;; FUNCTION and NAMED-LAMBDA
 430
 431 (def-ir1-translator function ((thing) start cont)
 432   #!+sb-doc
 433   "FUNCTION Name
 434   Return the lexically apparent definition of the function Name. Name may also
 435   be a lambda expression."
 436   (if (consp thing)
 437       (case (car thing)
 438         ((lambda)
 439          (reference-leaf start
 440                          cont
 441                          (ir1-convert-lambda thing
 442                                              :debug-name (debug-namify
 443                                                           "#'~S" thing))))
 444         ((setf)
 445          (let ((var (find-lexically-apparent-fun
 446                      thing "as the argument to FUNCTION")))
 447            (reference-leaf start cont var)))
 448         ((instance-lambda)
 449          (let ((res (ir1-convert-lambda `(lambda ,@(cdr thing))
 450                                         :debug-name (debug-namify "#'~S"
 451                                                                   thing))))
 452            (setf (getf (functional-plist res) :fin-function) t)
 453            (reference-leaf start cont res)))
 454         (t
 455          (compiler-error "~S is not a legal function name." thing)))
 456       (let ((var (find-lexically-apparent-fun
 457                   thing "as the argument to FUNCTION")))
 458         (reference-leaf start cont var))))
 459
 460 ;;; `(NAMED-LAMBDA ,NAME ,@REST) is like `(FUNCTION (LAMBDA ,@REST)),
 461 ;;; except that the value of NAME is passed to the compiler for use in
 462 ;;; creation of debug information for the resulting function.
 463 ;;;
 464 ;;; NAME can be a legal function name or some arbitrary other thing.
 465 ;;;
 466 ;;; If NAME is a legal function name, then the caller should be
 467 ;;; planning to set (FDEFINITION NAME) to the created function.
 468 ;;; (Otherwise the debug names will be inconsistent and thus
 469 ;;; unnecessarily confusing.)
 470 ;;;
 471 ;;; Arbitrary other things are appropriate for naming things which are
 472 ;;; not the FDEFINITION of NAME. E.g.
 473 ;;;   NAME = (:FLET FOO BAR)
 474 ;;; for the FLET function in
 475 ;;;   (DEFUN BAR (X)
 476 ;;;     (FLET ((FOO (Y) (+ X Y)))
 477 ;;;       FOO))
 478 ;;; or
 479 ;;;   NAME = (:METHOD PRINT-OBJECT :AROUND (STARSHIP T))
 480 ;;; for the function used to implement
 481 ;;;   (DEFMETHOD PRINT-OBJECT :AROUND ((SS STARSHIP) STREAM) ...).
 482 (def-ir1-translator named-lambda ((name &rest rest) start cont)
 483   (let* ((fun (if (legal-fun-name-p name)
 484                   (ir1-convert-lambda `(lambda ,@rest)
 485                                       :source-name name)
 486                   (ir1-convert-lambda `(lambda ,@rest)
 487                                       :debug-name name)))
 488          (leaf (reference-leaf start cont fun)))
 489     (when (legal-fun-name-p name)
 490       (assert-global-function-definition-type name fun))
 491     leaf))
 492 \f
 493 ;;;; FUNCALL
 494
 495 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 496 ;;; (not symbols). %FUNCALL is used directly in some places where the
 497 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 498 (deftransform funcall ((function &rest args) * *)
 499   (let ((arg-names (make-gensym-list (length args))))
 500     `(lambda (function ,@arg-names)
 501        (%funcall ,(if (csubtypep (continuation-type function)
 502                                  (specifier-type 'function))
 503                       'function
 504                       '(%coerce-callable-to-fun function))
 505                  ,@arg-names))))
 506
 507 (def-ir1-translator %funcall ((function &rest args) start cont)
 508   (let ((fun-cont (make-continuation)))
 509     (ir1-convert start fun-cont function)
 510     (assert-continuation-type fun-cont (specifier-type 'function)
 511                               (lexenv-policy *lexenv*))
 512     (ir1-convert-combination-args fun-cont cont args)))
 513
 514 ;;; This source transform exists to reduce the amount of work for the
 515 ;;; compiler. If the called function is a FUNCTION form, then convert
 516 ;;; directly to %FUNCALL, instead of waiting around for type
 517 ;;; inference.
 518 (define-source-transform funcall (function &rest args)
 519   (if (and (consp function) (eq (car function) 'function))
 520       `(%funcall ,function ,@args)
 521       (values nil t)))
 522
 523 (deftransform %coerce-callable-to-fun ((thing) (function) *
 524                                        :important t)
 525   "optimize away possible call to FDEFINITION at runtime"
 526   'thing)
 527 \f
 528 ;;;; LET and LET*
 529 ;;;;
 530 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 531 ;;;; any pervasive declarations also affect the evaluation of the
 532 ;;;; arguments.)
 533
 534 ;;; Given a list of binding specifiers in the style of LET, return:
 535 ;;;  1. The list of var structures for the variables bound.
 536 ;;;  2. The initial value form for each variable.
 537 ;;;
 538 ;;; The variable names are checked for legality and globally special
 539 ;;; variables are marked as such. Context is the name of the form, for
 540 ;;; error reporting purposes.
 541 (declaim (ftype (function (list symbol) (values list list))
 542                 extract-let-vars))
 543 (defun extract-let-vars (bindings context)
 544   (collect ((vars)
 545             (vals)
 546             (names))
 547     (flet ((get-var (name)
 548              (varify-lambda-arg name
 549                                 (if (eq context 'let*)
 550                                     nil
 551                                     (names)))))
 552       (dolist (spec bindings)
 553         (cond ((atom spec)
 554                (let ((var (get-var spec)))
 555                  (vars var)
 556                  (names spec)
 557                  (vals nil)))
 558               (t
 559                (unless (proper-list-of-length-p spec 1 2)
 560                  (compiler-error "The ~S binding spec ~S is malformed."
 561                                  context
 562                                  spec))
 563                (let* ((name (first spec))
 564                       (var (get-var name)))
 565                  (vars var)
 566                  (names name)
 567                  (vals (second spec)))))))
 568
 569     (values (vars) (vals))))
 570
 571 (def-ir1-translator let ((bindings &body body)
 572                          start cont)
 573   #!+sb-doc
 574   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 575   During evaluation of the Forms, bind the Vars to the result of evaluating the
 576   Value forms. The variables are bound in parallel after all of the Values are
 577   evaluated."
 578   (multiple-value-bind (forms decls) (parse-body body nil)
 579     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 580       (let ((fun-cont (make-continuation)))
 581         (let* ((*lexenv* (process-decls decls vars nil cont))
 582                (fun (ir1-convert-lambda-body
 583                      forms vars
 584                      :debug-name (debug-namify "LET ~S" bindings))))
 585           (reference-leaf start fun-cont fun))
 586         (ir1-convert-combination-args fun-cont cont values)))))
 587
 588 (def-ir1-translator let* ((bindings &body body)
 589                           start cont)
 590   #!+sb-doc
 591   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 592   Similar to LET, but the variables are bound sequentially, allowing each Value
 593   form to reference any of the previous Vars."
 594   (multiple-value-bind (forms decls) (parse-body body nil)
 595     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 596       (let ((*lexenv* (process-decls decls vars nil cont)))
 597         (ir1-convert-aux-bindings start cont forms vars values)))))
 598
 599 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 600 ;;; and SYMBOL-MACROLET
 601 ;;;
 602 ;;; Note that all these things need to preserve toplevel-formness,
 603 ;;; but we don't need to worry about that within an IR1 translator,
 604 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 605 ;;; forms before we hit the IR1 transform level.
 606 (defun ir1-translate-locally (body start cont &key vars funs)
 607   (declare (type list body) (type continuation start cont))
 608   (multiple-value-bind (forms decls) (parse-body body nil)
 609     (let ((*lexenv* (process-decls decls vars funs cont)))
 610       (ir1-convert-aux-bindings start cont forms nil nil))))
 611
 612 (def-ir1-translator locally ((&body body) start cont)
 613   #!+sb-doc
 614   "LOCALLY Declaration* Form*
 615   Sequentially evaluate the Forms in a lexical environment where the
 616   the Declarations have effect. If LOCALLY is a top level form, then
 617   the Forms are also processed as top level forms."
 618   (ir1-translate-locally body start cont))
 619 \f
 620 ;;;; FLET and LABELS
 621
 622 ;;; Given a list of local function specifications in the style of
 623 ;;; FLET, return lists of the function names and of the lambdas which
 624 ;;; are their definitions.
 625 ;;;
 626 ;;; The function names are checked for legality. CONTEXT is the name
 627 ;;; of the form, for error reporting.
 628 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 629 (defun extract-flet-vars (definitions context)
 630   (collect ((names)
 631             (defs))
 632     (dolist (def definitions)
 633       (when (or (atom def) (< (length def) 2))
 634         (compiler-error "The ~S definition spec ~S is malformed." context def))
 635
 636       (let ((name (first def)))
 637         (check-fun-name name)
 638         (names name)
 639         (multiple-value-bind (forms decls) (parse-body (cddr def))
 640           (defs `(lambda ,(second def)
 641                    ,@decls
 642                    (block ,(fun-name-block-name name)
 643                      . ,forms))))))
 644     (values (names) (defs))))
 645
 646 (def-ir1-translator flet ((definitions &body body)
 647                           start cont)
 648   #!+sb-doc
 649   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 650   Evaluate the Body-Forms with some local function definitions. The bindings
 651   do not enclose the definitions; any use of Name in the Forms will refer to
 652   the lexically apparent function definition in the enclosing environment."
 653   (multiple-value-bind (forms decls) (parse-body body nil)
 654     (multiple-value-bind (names defs)
 655         (extract-flet-vars definitions 'flet)
 656       (let* ((fvars (mapcar (lambda (n d)
 657                               (ir1-convert-lambda d
 658                                                   :source-name n
 659                                                   :debug-name (debug-namify
 660                                                                "FLET ~S" n)))
 661                             names defs))
 662              (*lexenv* (make-lexenv
 663                         :default (process-decls decls nil fvars cont)
 664                         :funs (pairlis names fvars))))
 665         (ir1-convert-progn-body start cont forms)))))
 666
 667 (def-ir1-translator labels ((definitions &body body) start cont)
 668   #!+sb-doc
 669   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 670   Evaluate the Body-Forms with some local function definitions. The bindings
 671   enclose the new definitions, so the defined functions can call themselves or
 672   each other."
 673   (multiple-value-bind (forms decls) (parse-body body nil)
 674     (multiple-value-bind (names defs)
 675         (extract-flet-vars definitions 'labels)
 676       (let* (;; dummy LABELS functions, to be used as placeholders
 677              ;; during construction of real LABELS functions
 678              (placeholder-funs (mapcar (lambda (name)
 679                                          (make-functional
 680                                           :%source-name name
 681                                           :%debug-name (debug-namify
 682                                                         "LABELS placeholder ~S"
 683                                                         name)))
 684                                        names))
 685              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 686              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 687              ;; the real LABELS functions, compiled in a LEXENV which
 688              ;; includes the dummy LABELS functions
 689              (real-funs
 690               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 691                 (mapcar (lambda (name def)
 692                           (ir1-convert-lambda def
 693                                               :source-name name
 694                                               :debug-name (debug-namify
 695                                                            "LABELS ~S" name)))
 696                         names defs))))
 697
 698         ;; Modify all the references to the dummy function leaves so
 699         ;; that they point to the real function leaves.
 700         (loop for real-fun in real-funs and
 701               placeholder-cons in placeholder-fenv do
 702               (substitute-leaf real-fun (cdr placeholder-cons))
 703               (setf (cdr placeholder-cons) real-fun))
 704
 705         ;; Voila.
 706         (let ((*lexenv* (make-lexenv
 707                          :default (process-decls decls nil real-funs cont)
 708                          ;; Use a proper FENV here (not the
 709                          ;; placeholder used earlier) so that if the
 710                          ;; lexical environment is used for inline
 711                          ;; expansion we'll get the right functions.
 712                          :funs (pairlis names real-funs))))
 713           (ir1-convert-progn-body start cont forms))))))
 714 \f
 715 ;;;; the THE special operator, and friends
 716
 717 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 718 ;;; continuation that the assertion applies to, TYPE is the type
 719 ;;; specifier and LEXENV is the current lexical environment. NAME is
 720 ;;; the name of the declaration we are doing, for use in error
 721 ;;; messages.
 722 ;;;
 723 ;;; This is somewhat involved, since a type assertion may only be made
 724 ;;; on a continuation, not on a node. We can't just set the
 725 ;;; continuation asserted type and let it go at that, since there may
 726 ;;; be parallel THE's for the same continuation, i.e.
 727 ;;;     (if ...
 728 ;;;      (the foo ...)
 729 ;;;      (the bar ...))
 730 ;;;
 731 ;;; In this case, our representation can do no better than the union
 732 ;;; of these assertions. And if there is a branch with no assertion,
 733 ;;; we have nothing at all. We really need to recognize scoping, since
 734 ;;; we need to be able to discern between parallel assertions (which
 735 ;;; we union) and nested ones (which we intersect).
 736 ;;;
 737 ;;; We represent the scoping by throwing our innermost (intersected)
 738 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 739 ;;; intersect our assertions together. If CONT has no uses yet, we
 740 ;;; have not yet bottomed out on the first COND branch; in this case
 741 ;;; we optimistically assume that this type will be the one we end up
 742 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 743 ;;; than the type that we have the first time we bottom out. Later
 744 ;;; THE's (or the absence thereof) can only weaken this result.
 745 ;;;
 746 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 747 ;;; across COND branches. We can't do it here, since we don't know how
 748 ;;; many branches there are going to be.
 749 (defun ir1ize-the-or-values (type cont lexenv place)
 750   (declare (type continuation cont) (type lexenv lexenv))
 751   (let* ((atype (if (typep type 'ctype) type (compiler-values-specifier-type type)))
 752          (old-atype (or (lexenv-find cont type-restrictions)
 753                         *wild-type*))
 754          (old-ctype (or (lexenv-find cont weakend-type-restrictions)
 755                         *wild-type*))
 756          (intersects (values-types-equal-or-intersect old-atype atype))
 757          (new-atype (values-type-intersection old-atype atype))
 758          (new-ctype (values-type-intersection
 759                      old-ctype (maybe-weaken-check atype (lexenv-policy lexenv)))))
 760     (when (null (find-uses cont))
 761       (setf (continuation-asserted-type cont) new-atype)
 762       (setf (continuation-type-to-check cont) new-ctype))
 763     (when (and (not intersects)
 764                ;; FIXME: Is it really right to look at *LEXENV* here,
 765                ;; instead of looking at the LEXENV argument? Why?
 766                (not (policy *lexenv*
 767                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 768       (compiler-warn
 769        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 770        (type-specifier atype)
 771        place
 772        (type-specifier old-atype)))
 773     (make-lexenv :type-restrictions `((,cont . ,new-atype))
 774                  :weakend-type-restrictions `((,cont . ,new-ctype))
 775                  :default lexenv)))
 776
 777 ;;; Assert that FORM evaluates to the specified type (which may be a
 778 ;;; VALUES type).
 779 ;;;
 780 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 781 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 782 ;;; values. Check that SBCL doesn't have this problem.
 783 (def-ir1-translator the ((type value) start cont)
 784   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 785                                           "in THE declaration")
 786     (ir1-convert start cont value)))
 787
 788 ;;; This is like the THE special form, except that it believes
 789 ;;; whatever you tell it. It will never generate a type check, but
 790 ;;; will cause a warning if the compiler can prove the assertion is
 791 ;;; wrong.
 792 ;;;
 793 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 794 ;;; its uses's types, setting it won't work. Instead we must intersect
 795 ;;; the type with the uses's DERIVED-TYPE.
 796 (def-ir1-translator truly-the ((type value) start cont)
 797   #!+sb-doc
 798   (declare (inline member))
 799   (let ((type (compiler-values-specifier-type type))
 800         (old (find-uses cont)))
 801     (ir1-convert start cont value)
 802     (do-uses (use cont)
 803       (unless (member use old :test #'eq)
 804         (derive-node-type use type)))))
 805 \f
 806 ;;;; SETQ
 807
 808 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 809 ;;; look at the global information. If the name is for a constant,
 810 ;;; then error out.
 811 (def-ir1-translator setq ((&whole source &rest things) start cont)
 812   (let ((len (length things)))
 813     (when (oddp len)
 814       (compiler-error "odd number of args to SETQ: ~S" source))
 815     (if (= len 2)
 816         (let* ((name (first things))
 817                (leaf (or (lexenv-find name vars)
 818                          (find-free-var name))))
 819           (etypecase leaf
 820             (leaf
 821              (when (constant-p leaf)
 822                (compiler-error "~S is a constant and thus can't be set." name))
 823              (when (lambda-var-p leaf)
 824                (let ((home-lambda (continuation-home-lambda-or-null start)))
 825                  (when home-lambda
 826                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 827                (when (lambda-var-ignorep leaf)
 828                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 829                  ;; requires that this be a STYLE-WARNING, not a full warning.
 830                  (compiler-style-warn
 831                   "~S is being set even though it was declared to be ignored."
 832                   name)))
 833              (setq-var start cont leaf (second things)))
 834             (cons
 835              (aver (eq (car leaf) 'MACRO))
 836              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 837             (heap-alien-info
 838              (ir1-convert start cont
 839                           `(%set-heap-alien ',leaf ,(second things))))))
 840         (collect ((sets))
 841           (do ((thing things (cddr thing)))
 842               ((endp thing)
 843                (ir1-convert-progn-body start cont (sets)))
 844             (sets `(setq ,(first thing) ,(second thing))))))))
 845
 846 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 847 ;;; This should only need to be called in SETQ.
 848 (defun setq-var (start cont var value)
 849   (declare (type continuation start cont) (type basic-var var))
 850   (let ((dest (make-continuation)))
 851     (ir1-convert start dest value)
 852     (assert-continuation-type dest (leaf-type var) (lexenv-policy *lexenv*))
 853     (let ((res (make-set :var var :value dest)))
 854       (setf (continuation-dest dest) res)
 855       (setf (leaf-ever-used var) t)
 856       (push res (basic-var-sets var))
 857       (link-node-to-previous-continuation res dest)
 858       (use-continuation res cont))))
 859 \f
 860 ;;;; CATCH, THROW and UNWIND-PROTECT
 861
 862 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 863 ;;; since as as far as IR1 is concerned, it has no interesting
 864 ;;; properties other than receiving multiple-values.
 865 (def-ir1-translator throw ((tag result) start cont)
 866   #!+sb-doc
 867   "Throw Tag Form
 868   Do a non-local exit, return the values of Form from the CATCH whose tag
 869   evaluates to the same thing as Tag."
 870   (ir1-convert start cont
 871                `(multiple-value-call #'%throw ,tag ,result)))
 872
 873 ;;; This is a special special form used to instantiate a cleanup as
 874 ;;; the current cleanup within the body. KIND is the kind of cleanup
 875 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 876 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 877 ;;; and introduce the cleanup into the lexical environment. We
 878 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 879 ;;; cleanup, since this inner cleanup is the interesting one.
 880 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 881   (let ((dummy (make-continuation))
 882         (dummy2 (make-continuation)))
 883     (ir1-convert start dummy mess-up)
 884     (let* ((mess-node (continuation-use dummy))
 885            (cleanup (make-cleanup :kind kind
 886                                   :mess-up mess-node))
 887            (old-cup (lexenv-cleanup *lexenv*))
 888            (*lexenv* (make-lexenv :cleanup cleanup)))
 889       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 890       (ir1-convert dummy dummy2 '(%cleanup-point))
 891       (ir1-convert-progn-body dummy2 cont body))))
 892
 893 ;;; This is a special special form that makes an "escape function"
 894 ;;; which returns unknown values from named block. We convert the
 895 ;;; function, set its kind to :ESCAPE, and then reference it. The
 896 ;;; :ESCAPE kind indicates that this function's purpose is to
 897 ;;; represent a non-local control transfer, and that it might not
 898 ;;; actually have to be compiled.
 899 ;;;
 900 ;;; Note that environment analysis replaces references to escape
 901 ;;; functions with references to the corresponding NLX-INFO structure.
 902 (def-ir1-translator %escape-fun ((tag) start cont)
 903   (let ((fun (ir1-convert-lambda
 904               `(lambda ()
 905                  (return-from ,tag (%unknown-values)))
 906               :debug-name (debug-namify "escape function for ~S" tag))))
 907     (setf (functional-kind fun) :escape)
 908     (reference-leaf start cont fun)))
 909
 910 ;;; Yet another special special form. This one looks up a local
 911 ;;; function and smashes it to a :CLEANUP function, as well as
 912 ;;; referencing it.
 913 (def-ir1-translator %cleanup-fun ((name) start cont)
 914   (let ((fun (lexenv-find name funs)))
 915     (aver (lambda-p fun))
 916     (setf (functional-kind fun) :cleanup)
 917     (reference-leaf start cont fun)))
 918
 919 ;;; We represent the possibility of the control transfer by making an
 920 ;;; "escape function" that does a lexical exit, and instantiate the
 921 ;;; cleanup using %WITHIN-CLEANUP.
 922 (def-ir1-translator catch ((tag &body body) start cont)
 923   #!+sb-doc
 924   "Catch Tag Form*
 925   Evaluates Tag and instantiates it as a catcher while the body forms are
 926   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 927   scope of the body, then control will be transferred to the end of the body
 928   and the thrown values will be returned."
 929   (ir1-convert
 930    start cont
 931    (let ((exit-block (gensym "EXIT-BLOCK-")))
 932      `(block ,exit-block
 933         (%within-cleanup
 934             :catch
 935             (%catch (%escape-fun ,exit-block) ,tag)
 936           ,@body)))))
 937
 938 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 939 ;;; cleanup forms into a local function so that they can be referenced
 940 ;;; both in the case where we are unwound and in any local exits. We
 941 ;;; use %CLEANUP-FUN on this to indicate that reference by
 942 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 943 ;;; an XEP.
 944 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 945   #!+sb-doc
 946   "Unwind-Protect Protected Cleanup*
 947   Evaluate the form Protected, returning its values. The cleanup forms are
 948   evaluated whenever the dynamic scope of the Protected form is exited (either
 949   due to normal completion or a non-local exit such as THROW)."
 950   (ir1-convert
 951    start cont
 952    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 953          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 954          (exit-tag (gensym "EXIT-TAG-"))
 955          (next (gensym "NEXT"))
 956          (start (gensym "START"))
 957          (count (gensym "COUNT")))
 958      `(flet ((,cleanup-fun () ,@cleanup nil))
 959         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 960         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 961         ;; and something can be done to make %ESCAPE-FUN have
 962         ;; dynamic extent too.
 963         (block ,drop-thru-tag
 964           (multiple-value-bind (,next ,start ,count)
 965               (block ,exit-tag
 966                 (%within-cleanup
 967                     :unwind-protect
 968                     (%unwind-protect (%escape-fun ,exit-tag)
 969                                      (%cleanup-fun ,cleanup-fun))
 970                   (return-from ,drop-thru-tag ,protected)))
 971             (,cleanup-fun)
 972             (%continue-unwind ,next ,start ,count)))))))
 973 \f
 974 ;;;; multiple-value stuff
 975
 976 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 977 ;;; MV-COMBINATION.
 978 ;;;
 979 ;;; If there are no arguments, then we convert to a normal
 980 ;;; combination, ensuring that a MV-COMBINATION always has at least
 981 ;;; one argument. This can be regarded as an optimization, but it is
 982 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 983 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 984   #!+sb-doc
 985   "MULTIPLE-VALUE-CALL Function Values-Form*
 986   Call Function, passing all the values of each Values-Form as arguments,
 987   values from the first Values-Form making up the first argument, etc."
 988   (let* ((fun-cont (make-continuation))
 989          (node (if args
 990                    (make-mv-combination fun-cont)
 991                    (make-combination fun-cont))))
 992     (ir1-convert start fun-cont
 993                  (if (and (consp fun) (eq (car fun) 'function))
 994                      fun
 995                      `(%coerce-callable-to-fun ,fun)))
 996     (setf (continuation-dest fun-cont) node)
 997     (assert-continuation-type fun-cont
 998                               (specifier-type '(or function symbol))
 999                               (lexenv-policy *lexenv*))
1000     (collect ((arg-conts))
1001       (let ((this-start fun-cont))
1002         (dolist (arg args)
1003           (let ((this-cont (make-continuation node)))
1004             (ir1-convert this-start this-cont arg)
1005             (setq this-start this-cont)
1006             (arg-conts this-cont)))
1007         (link-node-to-previous-continuation node this-start)
1008         (use-continuation node cont)
1009         (setf (basic-combination-args node) (arg-conts))))))
1010
1011 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
1012 ;;; the result code use result continuation (CONT), but transfer
1013 ;;; control to the evaluation of the body. In other words, the result
1014 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
1015 ;;; the result.
1016 ;;;
1017 ;;; In order to get the control flow right, we convert the result with
1018 ;;; a dummy result continuation, then convert all the uses of the
1019 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
1020 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
1021 ;;; that they are consistent. Note that this doesn't amount to
1022 ;;; changing the exit target, since the control destination of an exit
1023 ;;; is determined by the block successor; we are just indicating the
1024 ;;; continuation that the result is delivered to.
1025 ;;;
1026 ;;; We then convert the body, using another dummy continuation in its
1027 ;;; own block as the result. After we are done converting the body, we
1028 ;;; move all predecessors of the dummy end block to CONT's block.
1029 ;;;
1030 ;;; Note that we both exploit and maintain the invariant that the CONT
1031 ;;; to an IR1 convert method either has no block or starts the block
1032 ;;; that control should transfer to after completion for the form.
1033 ;;; Nested MV-PROG1's work because during conversion of the result
1034 ;;; form, we use dummy continuation whose block is the true control
1035 ;;; destination.
1036 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
1037   #!+sb-doc
1038   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1039   Evaluate Values-Form and then the Forms, but return all the values of
1040   Values-Form."
1041   (continuation-starts-block cont)
1042   (let* ((dummy-result (make-continuation))
1043          (dummy-start (make-continuation))
1044          (cont-block (continuation-block cont)))
1045     (continuation-starts-block dummy-start)
1046     (ir1-convert start dummy-start result)
1047
1048     (with-continuation-type-assertion
1049         ;; FIXME: policy
1050         (cont (continuation-asserted-type dummy-start)
1051               "of the first form")
1052       (substitute-continuation-uses cont dummy-start))
1053
1054     (continuation-starts-block dummy-result)
1055     (ir1-convert-progn-body dummy-start dummy-result forms)
1056     (let ((end-block (continuation-block dummy-result)))
1057       (dolist (pred (block-pred end-block))
1058         (unlink-blocks pred end-block)
1059         (link-blocks pred cont-block))
1060       (aver (not (continuation-dest dummy-result)))
1061       (delete-continuation dummy-result)
1062       (remove-from-dfo end-block))))
1063 \f
1064 ;;;; interface to defining macros
1065
1066 ;;; Old CMUCL comment:
1067 ;;;
1068 ;;;   Return a new source path with any stuff intervening between the
1069 ;;;   current path and the first form beginning with NAME stripped
1070 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1071 ;;;   prevent annoying error messages.
1072 ;;;
1073 ;;; Now that we have implementations of DEFmumble macros in terms of
1074 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1075 ;;; worth figuring out why it was used, and maybe doing analogous
1076 ;;; munging to the functions created in the expanders for the macros.
1077 (defun revert-source-path (name)
1078   (do ((path *current-path* (cdr path)))
1079       ((null path) *current-path*)
1080     (let ((first (first path)))
1081       (when (or (eq first name)
1082                 (eq first 'original-source-start))
1083         (return path)))))