src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     (setf (continuation-dest pred) node)
  39     (ir1-convert start pred test)
  40     (link-node-to-previous-continuation node pred)
  41     (use-continuation node dummy-cont)
  42
  43     (let ((start-block (continuation-block pred)))
  44       (setf (block-last start-block) node)
  45       (continuation-starts-block cont)
  46
  47       (link-blocks start-block then-block)
  48       (link-blocks start-block else-block))
  49
  50     (ir1-convert then-cont cont then)
  51     (ir1-convert else-cont cont else)))
  52 \f
  53 ;;;; BLOCK and TAGBODY
  54
  55 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  56 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  57 ;;;; node.
  58
  59 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  60 ;;; body in the modified environment. We make CONT start a block now,
  61 ;;; since if it was done later, the block would be in the wrong
  62 ;;; environment.
  63 (def-ir1-translator block ((name &rest forms) start cont)
  64   #!+sb-doc
  65   "Block Name Form*
  66   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  67   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  68   result of Value-Form."
  69   (unless (symbolp name)
  70     (compiler-error "The block name ~S is not a symbol." name))
  71   (continuation-starts-block cont)
  72   (let* ((dummy (make-continuation))
  73          (entry (make-entry))
  74          (cleanup (make-cleanup :kind :block
  75                                 :mess-up entry)))
  76     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  77     (setf (entry-cleanup entry) cleanup)
  78     (link-node-to-previous-continuation entry start)
  79     (use-continuation entry dummy)
  80
  81     (let* ((env-entry (list entry cont))
  82            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  83                                   :cleanup cleanup)))
  84       (push env-entry (continuation-lexenv-uses cont))
  85       (ir1-convert-progn-body dummy cont forms))))
  86
  87 (def-ir1-translator return-from ((name &optional value) start cont)
  88   #!+sb-doc
  89   "Return-From Block-Name Value-Form
  90   Evaluate the Value-Form, returning its values from the lexically enclosing
  91   BLOCK Block-Name. This is constrained to be used only within the dynamic
  92   extent of the BLOCK."
  93   ;; CMU CL comment:
  94   ;;   We make CONT start a block just so that it will have a block
  95   ;;   assigned. People assume that when they pass a continuation into
  96   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  97   ;; KLUDGE: Note that this block is basically fictitious. In the code
  98   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
  99   ;; it's the block which answers the question "which block is
 100   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 101   ;; dead code and so doesn't really have a block at all. The existence
 102   ;; of this block, and that way that it doesn't explicitly say
 103   ;; "I'm actually nowhere at all" makes some logic (e.g.
 104   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 105   ;; to get rid of it, perhaps using a special placeholder value
 106   ;; to indicate the orphanedness of the code.
 107   (continuation-starts-block cont)
 108   (let* ((found (or (lexenv-find name blocks)
 109                     (compiler-error "return for unknown block: ~S" name)))
 110          (value-cont (make-continuation))
 111          (entry (first found))
 112          (exit (make-exit :entry entry
 113                           :value value-cont)))
 114     (push exit (entry-exits entry))
 115     (setf (continuation-dest value-cont) exit)
 116     (ir1-convert start value-cont value)
 117     (link-node-to-previous-continuation exit value-cont)
 118     (let ((home-lambda (continuation-home-lambda-or-null start)))
 119       (when home-lambda
 120         (push entry (lambda-calls-or-closes home-lambda))))
 121     (use-continuation exit (second found))))
 122
 123 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 124 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 125 ;;; tagbody into segments of non-tag statements, and explicitly
 126 ;;; represent the drop-through with a GO. The first segment has a
 127 ;;; dummy NIL tag, since it represents code before the first tag. The
 128 ;;; last segment (which may also be the first segment) ends in NIL
 129 ;;; rather than a GO.
 130 (defun parse-tagbody (body)
 131   (declare (list body))
 132   (collect ((segments))
 133     (let ((current (cons nil body)))
 134       (loop
 135         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 136           (unless tag-pos
 137             (segments `(,@current nil))
 138             (return))
 139           (let ((tag (elt current tag-pos)))
 140             (when (assoc tag (segments))
 141               (compiler-error
 142                "The tag ~S appears more than once in the tagbody."
 143                tag))
 144             (unless (or (symbolp tag) (integerp tag))
 145               (compiler-error "~S is not a legal tagbody statement." tag))
 146             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 147           (setq current (nthcdr tag-pos current)))))
 148     (segments)))
 149
 150 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 151 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 152 ;;; Finally, convert each segment with the precomputed Start and Cont
 153 ;;; values.
 154 (def-ir1-translator tagbody ((&rest statements) start cont)
 155   #!+sb-doc
 156   "Tagbody {Tag | Statement}*
 157   Define tags for used with GO. The Statements are evaluated in order
 158   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 159   defined Tag within the lexical scope of the form, then control is transferred
 160   to the next statement following that tag. A Tag must an integer or a
 161   symbol. A statement must be a list. Other objects are illegal within the
 162   body."
 163   (continuation-starts-block cont)
 164   (let* ((dummy (make-continuation))
 165          (entry (make-entry))
 166          (segments (parse-tagbody statements))
 167          (cleanup (make-cleanup :kind :tagbody
 168                                 :mess-up entry)))
 169     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 170     (setf (entry-cleanup entry) cleanup)
 171     (link-node-to-previous-continuation entry start)
 172     (use-continuation entry dummy)
 173
 174     (collect ((tags)
 175               (starts)
 176               (conts))
 177       (starts dummy)
 178       (dolist (segment (rest segments))
 179         (let* ((tag-cont (make-continuation))
 180                (tag (list (car segment) entry tag-cont)))
 181           (conts tag-cont)
 182           (starts tag-cont)
 183           (continuation-starts-block tag-cont)
 184           (tags tag)
 185           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 186       (conts cont)
 187
 188       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 189         (mapc (lambda (segment start cont)
 190                 (ir1-convert-progn-body start cont (rest segment)))
 191               segments (starts) (conts))))))
 192
 193 ;;; Emit an EXIT node without any value.
 194 (def-ir1-translator go ((tag) start cont)
 195   #!+sb-doc
 196   "Go Tag
 197   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 198   is constrained to be used only within the dynamic extent of the TAGBODY."
 199   (continuation-starts-block cont)
 200   (let* ((found (or (lexenv-find tag tags :test #'eql)
 201                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 202                                     tag)))
 203          (entry (first found))
 204          (exit (make-exit :entry entry)))
 205     (push exit (entry-exits entry))
 206     (link-node-to-previous-continuation exit start)
 207     (let ((home-lambda (continuation-home-lambda-or-null start)))
 208       (when home-lambda
 209         (push entry (lambda-calls-or-closes home-lambda))))
 210     (use-continuation exit (second found))))
 211 \f
 212 ;;;; translators for compiler-magic special forms
 213
 214 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 215 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 216 ;;; so that they're never seen at this level.)
 217 ;;;
 218 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 219 ;;; of non-top-level EVAL-WHENs is very simple:
 220 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 221 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 222 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 223 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 224 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 225 ;;;   form; otherwise, the forms in the body are ignored.
 226 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 227   #!+sb-doc
 228   "EVAL-WHEN (Situation*) Form*
 229   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 230   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 231   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 232     (declare (ignore ct lt))
 233     (ir1-convert-progn-body start cont (and e forms)))
 234   (values))
 235
 236 ;;; common logic for MACROLET and SYMBOL-MACROLET
 237 ;;;
 238 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 239 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 240 ;;; call FUN (with no arguments).
 241 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 242                                        definitionize-keyword
 243                                        definitions
 244                                        fun)
 245   (declare (type function definitionize-fun fun))
 246   (declare (type (member :vars :funs) definitionize-keyword))
 247   (declare (type list definitions))
 248   (unless (= (length definitions)
 249              (length (remove-duplicates definitions :key #'first)))
 250     (compiler-style-warn "duplicate definitions in ~S" definitions))
 251   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 252          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 253     (funcall fun)))
 254
 255 ;;; Tweak *LEXENV* to include the DEFINITIONS from a MACROLET, then
 256 ;;; call FUN (with no arguments).
 257 ;;;
 258 ;;; This is split off from the IR1 convert method so that it can be
 259 ;;; shared by the special-case top level MACROLET processing code.
 260 (defun funcall-in-macrolet-lexenv (definitions fun)
 261   (%funcall-in-foomacrolet-lexenv
 262    (lambda (definition)
 263      (unless (list-of-length-at-least-p definition 2)
 264        (compiler-error
 265         "The list ~S is too short to be a legal local macro definition."
 266         definition))
 267      (destructuring-bind (name arglist &body body) definition
 268        (unless (symbolp name)
 269          (compiler-error "The local macro name ~S is not a symbol." name))
 270        (let ((whole (gensym "WHOLE"))
 271              (environment (gensym "ENVIRONMENT")))
 272          (multiple-value-bind (body local-decls)
 273              (parse-defmacro arglist whole body name 'macrolet
 274                              :environment environment)
 275            `(,name macro .
 276                    ,(compile nil
 277                              `(lambda (,whole ,environment)
 278                                 ,@local-decls
 279                                 (block ,name ,body))))))))
 280    :funs
 281    definitions
 282    fun))
 283
 284 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 285   #!+sb-doc
 286   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 287   Evaluate the Body-Forms in an environment with the specified local macros
 288   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 289   destructuring lambda list, and the Forms evaluate to the expansion. The
 290   Forms are evaluated in the null environment."
 291   (funcall-in-macrolet-lexenv definitions
 292                               (lambda ()
 293                                 (ir1-translate-locally body start cont))))
 294
 295 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 296   (%funcall-in-foomacrolet-lexenv
 297    (lambda (definition)
 298      (unless (proper-list-of-length-p definition 2)
 299        (compiler-error "malformed symbol/expansion pair: ~S" definition))
 300      (destructuring-bind (name expansion) definition
 301        (unless (symbolp name)
 302          (compiler-error
 303           "The local symbol macro name ~S is not a symbol."
 304           name))
 305        `(,name . (MACRO . ,expansion))))
 306    :vars
 307    definitions
 308    fun))
 309
 310 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 311   #!+sb-doc
 312   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 313   Define the Names as symbol macros with the given Expansions. Within the
 314   body, references to a Name will effectively be replaced with the Expansion."
 315   (funcall-in-symbol-macrolet-lexenv
 316    macrobindings
 317    (lambda ()
 318      (ir1-translate-locally body start cont))))
 319
 320 ;;; not really a special form, but..
 321 (def-ir1-translator declare ((&rest stuff) start cont)
 322   (declare (ignore stuff))
 323   ;; We ignore START and CONT too, but we can't use DECLARE IGNORE to
 324   ;; tell the compiler about it here, because the DEF-IR1-TRANSLATOR
 325   ;; macro would put the DECLARE in the wrong place, so..
 326   start cont
 327   (compiler-error "misplaced declaration"))
 328 \f
 329 ;;;; %PRIMITIVE
 330 ;;;;
 331 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 332 ;;;; into a funny function.
 333
 334 ;;; Carefully evaluate a list of forms, returning a list of the results.
 335 (defun eval-info-args (args)
 336   (declare (list args))
 337   (handler-case (mapcar #'eval args)
 338     (error (condition)
 339       (compiler-error "Lisp error during evaluation of info args:~%~A"
 340                       condition))))
 341
 342 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 343 ;;; the template, the second is a list of the results of any
 344 ;;; codegen-info args, and the remaining arguments are the runtime
 345 ;;; arguments.
 346 ;;;
 347 ;;; We do various error checking now so that we don't bomb out with
 348 ;;; a fatal error during IR2 conversion.
 349 ;;;
 350 ;;; KLUDGE: It's confusing having multiple names floating around for
 351 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 352 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 353 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 354 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 355 ;;; VOP or %VOP.. -- WHN 2001-06-11
 356 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 357 (def-ir1-translator %primitive ((name &rest args) start cont)
 358   (declare (type symbol name))
 359   (let* ((template (or (gethash name *backend-template-names*)
 360                        (bug "undefined primitive ~A" name)))
 361          (required (length (template-arg-types template)))
 362          (info (template-info-arg-count template))
 363          (min (+ required info))
 364          (nargs (length args)))
 365     (if (template-more-args-type template)
 366         (when (< nargs min)
 367           (bug "Primitive ~A was called with ~R argument~:P, ~
 368                 but wants at least ~R."
 369                name
 370                nargs
 371                min))
 372         (unless (= nargs min)
 373           (bug "Primitive ~A was called with ~R argument~:P, ~
 374                 but wants exactly ~R."
 375                name
 376                nargs
 377                min)))
 378
 379     (when (eq (template-result-types template) :conditional)
 380       (bug "%PRIMITIVE was used with a conditional template."))
 381
 382     (when (template-more-results-type template)
 383       (bug "%PRIMITIVE was used with an unknown values template."))
 384
 385     (ir1-convert start
 386                  cont
 387                  `(%%primitive ',template
 388                                ',(eval-info-args
 389                                   (subseq args required min))
 390                                ,@(subseq args 0 required)
 391                                ,@(subseq args min)))))
 392 \f
 393 ;;;; QUOTE
 394
 395 (def-ir1-translator quote ((thing) start cont)
 396   #!+sb-doc
 397   "QUOTE Value
 398   Return Value without evaluating it."
 399   (reference-constant start cont thing))
 400 \f
 401 ;;;; FUNCTION and NAMED-LAMBDA
 402
 403 (def-ir1-translator function ((thing) start cont)
 404   #!+sb-doc
 405   "FUNCTION Name
 406   Return the lexically apparent definition of the function Name. Name may also
 407   be a lambda expression."
 408   (if (consp thing)
 409       (case (car thing)
 410         ((lambda)
 411          (reference-leaf start
 412                          cont
 413                          (ir1-convert-lambda thing
 414                                              :debug-name (debug-namify
 415                                                           "#'~S" thing))))
 416         ((setf)
 417          (let ((var (find-lexically-apparent-fun
 418                      thing "as the argument to FUNCTION")))
 419            (reference-leaf start cont var)))
 420         ((instance-lambda)
 421          (let ((res (ir1-convert-lambda `(lambda ,@(cdr thing))
 422                                         :debug-name (debug-namify "#'~S"
 423                                                                   thing))))
 424            (setf (getf (functional-plist res) :fin-function) t)
 425            (reference-leaf start cont res)))
 426         (t
 427          (compiler-error "~S is not a legal function name." thing)))
 428       (let ((var (find-lexically-apparent-fun
 429                   thing "as the argument to FUNCTION")))
 430         (reference-leaf start cont var))))
 431
 432 ;;; `(NAMED-LAMBDA ,NAME ,@REST) is like `(FUNCTION (LAMBDA ,@REST)),
 433 ;;; except that the value of NAME is passed to the compiler for use in
 434 ;;; creation of debug information for the resulting function.
 435 ;;;
 436 ;;; NAME can be a legal function name or some arbitrary other thing.
 437 ;;;
 438 ;;; If NAME is a legal function name, then the caller should be
 439 ;;; planning to set (FDEFINITION NAME) to the created function.
 440 ;;; (Otherwise the debug names will be inconsistent and thus
 441 ;;; unnecessarily confusing.)
 442 ;;;
 443 ;;; Arbitrary other things are appropriate for naming things which are
 444 ;;; not the FDEFINITION of NAME. E.g.
 445 ;;;   NAME = (:FLET FOO BAR)
 446 ;;; for the FLET function in
 447 ;;;   (DEFUN BAR (X)
 448 ;;;     (FLET ((FOO (Y) (+ X Y)))
 449 ;;;       FOO))
 450 ;;; or
 451 ;;;   NAME = (:METHOD PRINT-OBJECT :AROUND (STARSHIP T))
 452 ;;; for the function used to implement
 453 ;;;   (DEFMETHOD PRINT-OBJECT :AROUND ((SS STARSHIP) STREAM) ...).
 454 (def-ir1-translator named-lambda ((name &rest rest) start cont)
 455   (reference-leaf start
 456                   cont
 457                   (if (legal-fun-name-p name)
 458                       (ir1-convert-lambda `(lambda ,@rest)
 459                                           :source-name name)
 460                       (ir1-convert-lambda `(lambda ,@rest)
 461                                           :debug-name name))))
 462 \f
 463 ;;;; FUNCALL
 464
 465 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 466 ;;; (not symbols). %FUNCALL is used directly in some places where the
 467 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 468 (deftransform funcall ((function &rest args) * *)
 469   (let ((arg-names (make-gensym-list (length args))))
 470     `(lambda (function ,@arg-names)
 471        (%funcall ,(if (csubtypep (continuation-type function)
 472                                  (specifier-type 'function))
 473                       'function
 474                       '(%coerce-callable-to-fun function))
 475                  ,@arg-names))))
 476
 477 (def-ir1-translator %funcall ((function &rest args) start cont)
 478   (let ((fun-cont (make-continuation)))
 479     (ir1-convert start fun-cont function)
 480     (assert-continuation-type fun-cont (specifier-type 'function))
 481     (ir1-convert-combination-args fun-cont cont args)))
 482
 483 ;;; This source transform exists to reduce the amount of work for the
 484 ;;; compiler. If the called function is a FUNCTION form, then convert
 485 ;;; directly to %FUNCALL, instead of waiting around for type
 486 ;;; inference.
 487 (define-source-transform funcall (function &rest args)
 488   (if (and (consp function) (eq (car function) 'function))
 489       `(%funcall ,function ,@args)
 490       (values nil t)))
 491
 492 (deftransform %coerce-callable-to-fun ((thing) (function) *
 493                                        :important t)
 494   "optimize away possible call to FDEFINITION at runtime"
 495   'thing)
 496 \f
 497 ;;;; LET and LET*
 498 ;;;;
 499 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 500 ;;;; any pervasive declarations also affect the evaluation of the
 501 ;;;; arguments.)
 502
 503 ;;; Given a list of binding specifiers in the style of LET, return:
 504 ;;;  1. The list of var structures for the variables bound.
 505 ;;;  2. The initial value form for each variable.
 506 ;;;
 507 ;;; The variable names are checked for legality and globally special
 508 ;;; variables are marked as such. Context is the name of the form, for
 509 ;;; error reporting purposes.
 510 (declaim (ftype (function (list symbol) (values list list))
 511                 extract-let-vars))
 512 (defun extract-let-vars (bindings context)
 513   (collect ((vars)
 514             (vals)
 515             (names))
 516     (flet ((get-var (name)
 517              (varify-lambda-arg name
 518                                 (if (eq context 'let*)
 519                                     nil
 520                                     (names)))))
 521       (dolist (spec bindings)
 522         (cond ((atom spec)
 523                (let ((var (get-var spec)))
 524                  (vars var)
 525                  (names spec)
 526                  (vals nil)))
 527               (t
 528                (unless (proper-list-of-length-p spec 1 2)
 529                  (compiler-error "The ~S binding spec ~S is malformed."
 530                                  context
 531                                  spec))
 532                (let* ((name (first spec))
 533                       (var (get-var name)))
 534                  (vars var)
 535                  (names name)
 536                  (vals (second spec)))))))
 537
 538     (values (vars) (vals))))
 539
 540 (def-ir1-translator let ((bindings &body body)
 541                          start cont)
 542   #!+sb-doc
 543   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 544   During evaluation of the Forms, bind the Vars to the result of evaluating the
 545   Value forms. The variables are bound in parallel after all of the Values are
 546   evaluated."
 547   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 548     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 549       (let ((fun-cont (make-continuation)))
 550         (let* ((*lexenv* (process-decls decls vars nil cont))
 551                (fun (ir1-convert-lambda-body
 552                      forms vars
 553                      :debug-name (debug-namify "LET ~S" bindings))))
 554           (reference-leaf start fun-cont fun))
 555         (ir1-convert-combination-args fun-cont cont values)))))
 556
 557 (def-ir1-translator let* ((bindings &body body)
 558                           start cont)
 559   #!+sb-doc
 560   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 561   Similar to LET, but the variables are bound sequentially, allowing each Value
 562   form to reference any of the previous Vars."
 563   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 564     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 565       (let ((*lexenv* (process-decls decls vars nil cont)))
 566         (ir1-convert-aux-bindings start cont forms vars values)))))
 567
 568 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 569 ;;; and SYMBOL-MACROLET
 570 ;;;
 571 ;;; Note that all these things need to preserve toplevel-formness,
 572 ;;; but we don't need to worry about that within an IR1 translator,
 573 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 574 ;;; forms before we hit the IR1 transform level.
 575 (defun ir1-translate-locally (body start cont)
 576   (declare (type list body) (type continuation start cont))
 577   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 578     (let ((*lexenv* (process-decls decls nil nil cont)))
 579       (ir1-convert-aux-bindings start cont forms nil nil))))
 580
 581 (def-ir1-translator locally ((&body body) start cont)
 582   #!+sb-doc
 583   "LOCALLY Declaration* Form*
 584   Sequentially evaluate the Forms in a lexical environment where the
 585   the Declarations have effect. If LOCALLY is a top level form, then
 586   the Forms are also processed as top level forms."
 587   (ir1-translate-locally body start cont))
 588 \f
 589 ;;;; FLET and LABELS
 590
 591 ;;; Given a list of local function specifications in the style of
 592 ;;; FLET, return lists of the function names and of the lambdas which
 593 ;;; are their definitions.
 594 ;;;
 595 ;;; The function names are checked for legality. CONTEXT is the name
 596 ;;; of the form, for error reporting.
 597 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 598 (defun extract-flet-vars (definitions context)
 599   (collect ((names)
 600             (defs))
 601     (dolist (def definitions)
 602       (when (or (atom def) (< (length def) 2))
 603         (compiler-error "The ~S definition spec ~S is malformed." context def))
 604
 605       (let ((name (first def)))
 606         (check-fun-name name)
 607         (names name)
 608         (multiple-value-bind (forms decls) (sb!sys:parse-body (cddr def))
 609           (defs `(lambda ,(second def)
 610                    ,@decls
 611                    (block ,(fun-name-block-name name)
 612                      . ,forms))))))
 613     (values (names) (defs))))
 614
 615 (def-ir1-translator flet ((definitions &body body)
 616                           start cont)
 617   #!+sb-doc
 618   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 619   Evaluate the Body-Forms with some local function definitions. The bindings
 620   do not enclose the definitions; any use of Name in the Forms will refer to
 621   the lexically apparent function definition in the enclosing environment."
 622   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 623     (multiple-value-bind (names defs)
 624         (extract-flet-vars definitions 'flet)
 625       (let* ((fvars (mapcar (lambda (n d)
 626                               (ir1-convert-lambda d
 627                                                   :source-name n
 628                                                   :debug-name (debug-namify
 629                                                                "FLET ~S" n)))
 630                             names defs))
 631              (*lexenv* (make-lexenv
 632                         :default (process-decls decls nil fvars cont)
 633                         :funs (pairlis names fvars))))
 634         (ir1-convert-progn-body start cont forms)))))
 635
 636 (def-ir1-translator labels ((definitions &body body) start cont)
 637   #!+sb-doc
 638   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 639   Evaluate the Body-Forms with some local function definitions. The bindings
 640   enclose the new definitions, so the defined functions can call themselves or
 641   each other."
 642   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 643     (multiple-value-bind (names defs)
 644         (extract-flet-vars definitions 'labels)
 645       (let* (;; dummy LABELS functions, to be used as placeholders
 646              ;; during construction of real LABELS functions
 647              (placeholder-funs (mapcar (lambda (name)
 648                                          (make-functional
 649                                           :%source-name name
 650                                           :%debug-name (debug-namify
 651                                                         "LABELS placeholder ~S"
 652                                                         name)))
 653                                        names))
 654              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 655              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 656              ;; the real LABELS functions, compiled in a LEXENV which
 657              ;; includes the dummy LABELS functions
 658              (real-funs
 659               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 660                 (mapcar (lambda (name def)
 661                           (ir1-convert-lambda def
 662                                               :source-name name
 663                                               :debug-name (debug-namify
 664                                                            "LABELS ~S" name)))
 665                         names defs))))
 666
 667         ;; Modify all the references to the dummy function leaves so
 668         ;; that they point to the real function leaves.
 669         (loop for real-fun in real-funs and
 670               placeholder-cons in placeholder-fenv do
 671               (substitute-leaf real-fun (cdr placeholder-cons))
 672               (setf (cdr placeholder-cons) real-fun))
 673
 674         ;; Voila.
 675         (let ((*lexenv* (make-lexenv
 676                          :default (process-decls decls nil real-funs cont)
 677                          ;; Use a proper FENV here (not the
 678                          ;; placeholder used earlier) so that if the
 679                          ;; lexical environment is used for inline
 680                          ;; expansion we'll get the right functions.
 681                          :funs (pairlis names real-funs))))
 682           (ir1-convert-progn-body start cont forms))))))
 683 \f
 684 ;;;; the THE special operator, and friends
 685
 686 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 687 ;;; continuation that the assertion applies to, TYPE is the type
 688 ;;; specifier and LEXENV is the current lexical environment. NAME is
 689 ;;; the name of the declaration we are doing, for use in error
 690 ;;; messages.
 691 ;;;
 692 ;;; This is somewhat involved, since a type assertion may only be made
 693 ;;; on a continuation, not on a node. We can't just set the
 694 ;;; continuation asserted type and let it go at that, since there may
 695 ;;; be parallel THE's for the same continuation, i.e.
 696 ;;;     (if ...
 697 ;;;      (the foo ...)
 698 ;;;      (the bar ...))
 699 ;;;
 700 ;;; In this case, our representation can do no better than the union
 701 ;;; of these assertions. And if there is a branch with no assertion,
 702 ;;; we have nothing at all. We really need to recognize scoping, since
 703 ;;; we need to be able to discern between parallel assertions (which
 704 ;;; we union) and nested ones (which we intersect).
 705 ;;;
 706 ;;; We represent the scoping by throwing our innermost (intersected)
 707 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 708 ;;; intersect our assertions together. If CONT has no uses yet, we
 709 ;;; have not yet bottomed out on the first COND branch; in this case
 710 ;;; we optimistically assume that this type will be the one we end up
 711 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 712 ;;; than the type that we have the first time we bottom out. Later
 713 ;;; THE's (or the absence thereof) can only weaken this result.
 714 ;;;
 715 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 716 ;;; across COND branches. We can't do it here, since we don't know how
 717 ;;; many branches there are going to be.
 718 (defun ir1ize-the-or-values (type cont lexenv name)
 719   (declare (type continuation cont) (type lexenv lexenv))
 720   (let* ((ctype (values-specifier-type type))
 721          (old-type (or (lexenv-find cont type-restrictions)
 722                        *wild-type*))
 723          (intersects (values-types-equal-or-intersect old-type ctype))
 724          (int (values-type-intersection old-type ctype))
 725          (new (if intersects int old-type)))
 726     (when (null (find-uses cont))
 727       (setf (continuation-asserted-type cont) new))
 728     (when (and (not intersects)
 729                (not (policy *lexenv*
 730                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 731       (compiler-warn
 732        "The type ~S in ~S declaration conflicts with an ~
 733         enclosing assertion:~%   ~S"
 734        (type-specifier ctype)
 735        name
 736        (type-specifier old-type)))
 737     (make-lexenv :type-restrictions `((,cont . ,new))
 738                  :default lexenv)))
 739
 740 ;;; Assert that FORM evaluates to the specified type (which may be a
 741 ;;; VALUES type).
 742 ;;;
 743 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 744 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 745 ;;; values. Check that SBCL doesn't have this problem.
 746 (def-ir1-translator the ((type value) start cont)
 747   (let ((*lexenv* (ir1ize-the-or-values type cont *lexenv* 'the)))
 748     (ir1-convert start cont value)))
 749
 750 ;;; This is like the THE special form, except that it believes
 751 ;;; whatever you tell it. It will never generate a type check, but
 752 ;;; will cause a warning if the compiler can prove the assertion is
 753 ;;; wrong.
 754 ;;;
 755 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 756 ;;; its uses's types, setting it won't work. Instead we must intersect
 757 ;;; the type with the uses's DERIVED-TYPE.
 758 (def-ir1-translator truly-the ((type value) start cont)
 759   #!+sb-doc
 760   (declare (inline member))
 761   (let ((type (values-specifier-type type))
 762         (old (find-uses cont)))
 763     (ir1-convert start cont value)
 764     (do-uses (use cont)
 765       (unless (member use old :test #'eq)
 766         (derive-node-type use type)))))
 767 \f
 768 ;;;; SETQ
 769
 770 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 771 ;;; look at the global information. If the name is for a constant,
 772 ;;; then error out.
 773 (def-ir1-translator setq ((&whole source &rest things) start cont)
 774   (let ((len (length things)))
 775     (when (oddp len)
 776       (compiler-error "odd number of args to SETQ: ~S" source))
 777     (if (= len 2)
 778         (let* ((name (first things))
 779                (leaf (or (lexenv-find name vars)
 780                          (find-free-var name))))
 781           (etypecase leaf
 782             (leaf
 783              (when (constant-p leaf)
 784                (compiler-error "~S is a constant and thus can't be set." name))
 785              (when (lambda-var-p leaf)
 786                (let ((home-lambda (continuation-home-lambda-or-null start)))
 787                  (when home-lambda
 788                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 789                (when (lambda-var-ignorep leaf)
 790                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 791                  ;; requires that this be a STYLE-WARNING, not a full warning.
 792                  (compiler-style-warn
 793                   "~S is being set even though it was declared to be ignored."
 794                   name)))
 795              (setq-var start cont leaf (second things)))
 796             (cons
 797              (aver (eq (car leaf) 'MACRO))
 798              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 799             (heap-alien-info
 800              (ir1-convert start cont
 801                           `(%set-heap-alien ',leaf ,(second things))))))
 802         (collect ((sets))
 803           (do ((thing things (cddr thing)))
 804               ((endp thing)
 805                (ir1-convert-progn-body start cont (sets)))
 806             (sets `(setq ,(first thing) ,(second thing))))))))
 807
 808 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 809 ;;; This should only need to be called in SETQ.
 810 (defun setq-var (start cont var value)
 811   (declare (type continuation start cont) (type basic-var var))
 812   (let ((dest (make-continuation)))
 813     (setf (continuation-asserted-type dest) (leaf-type var))
 814     (ir1-convert start dest value)
 815     (let ((res (make-set :var var :value dest)))
 816       (setf (continuation-dest dest) res)
 817       (setf (leaf-ever-used var) t)
 818       (push res (basic-var-sets var))
 819       (link-node-to-previous-continuation res dest)
 820       (use-continuation res cont))))
 821 \f
 822 ;;;; CATCH, THROW and UNWIND-PROTECT
 823
 824 ;;; We turn THROW into a multiple-value-call of a magical function,
 825 ;;; since as as far as IR1 is concerned, it has no interesting
 826 ;;; properties other than receiving multiple-values.
 827 (def-ir1-translator throw ((tag result) start cont)
 828   #!+sb-doc
 829   "Throw Tag Form
 830   Do a non-local exit, return the values of Form from the CATCH whose tag
 831   evaluates to the same thing as Tag."
 832   (ir1-convert start cont
 833                `(multiple-value-call #'%throw ,tag ,result)))
 834
 835 ;;; This is a special special form used to instantiate a cleanup as
 836 ;;; the current cleanup within the body. KIND is the kind of cleanup
 837 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 838 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 839 ;;; and introduce the cleanup into the lexical environment. We
 840 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 841 ;;; cleanup, since this inner cleanup is the interesting one.
 842 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 843   (let ((dummy (make-continuation))
 844         (dummy2 (make-continuation)))
 845     (ir1-convert start dummy mess-up)
 846     (let* ((mess-node (continuation-use dummy))
 847            (cleanup (make-cleanup :kind kind
 848                                   :mess-up mess-node))
 849            (old-cup (lexenv-cleanup *lexenv*))
 850            (*lexenv* (make-lexenv :cleanup cleanup)))
 851       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 852       (ir1-convert dummy dummy2 '(%cleanup-point))
 853       (ir1-convert-progn-body dummy2 cont body))))
 854
 855 ;;; This is a special special form that makes an "escape function"
 856 ;;; which returns unknown values from named block. We convert the
 857 ;;; function, set its kind to :ESCAPE, and then reference it. The
 858 ;;; :ESCAPE kind indicates that this function's purpose is to
 859 ;;; represent a non-local control transfer, and that it might not
 860 ;;; actually have to be compiled.
 861 ;;;
 862 ;;; Note that environment analysis replaces references to escape
 863 ;;; functions with references to the corresponding NLX-INFO structure.
 864 (def-ir1-translator %escape-fun ((tag) start cont)
 865   (let ((fun (ir1-convert-lambda
 866               `(lambda ()
 867                  (return-from ,tag (%unknown-values)))
 868               :debug-name (debug-namify "escape function for ~S" tag))))
 869     (setf (functional-kind fun) :escape)
 870     (reference-leaf start cont fun)))
 871
 872 ;;; Yet another special special form. This one looks up a local
 873 ;;; function and smashes it to a :CLEANUP function, as well as
 874 ;;; referencing it.
 875 (def-ir1-translator %cleanup-fun ((name) start cont)
 876   (let ((fun (lexenv-find name funs)))
 877     (aver (lambda-p fun))
 878     (setf (functional-kind fun) :cleanup)
 879     (reference-leaf start cont fun)))
 880
 881 ;;; We represent the possibility of the control transfer by making an
 882 ;;; "escape function" that does a lexical exit, and instantiate the
 883 ;;; cleanup using %WITHIN-CLEANUP.
 884 (def-ir1-translator catch ((tag &body body) start cont)
 885   #!+sb-doc
 886   "Catch Tag Form*
 887   Evaluates Tag and instantiates it as a catcher while the body forms are
 888   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 889   scope of the body, then control will be transferred to the end of the body
 890   and the thrown values will be returned."
 891   (ir1-convert
 892    start cont
 893    (let ((exit-block (gensym "EXIT-BLOCK-")))
 894      `(block ,exit-block
 895         (%within-cleanup
 896             :catch
 897             (%catch (%escape-fun ,exit-block) ,tag)
 898           ,@body)))))
 899
 900 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 901 ;;; cleanup forms into a local function so that they can be referenced
 902 ;;; both in the case where we are unwound and in any local exits. We
 903 ;;; use %CLEANUP-FUN on this to indicate that reference by
 904 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 905 ;;; an XEP.
 906 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 907   #!+sb-doc
 908   "Unwind-Protect Protected Cleanup*
 909   Evaluate the form Protected, returning its values. The cleanup forms are
 910   evaluated whenever the dynamic scope of the Protected form is exited (either
 911   due to normal completion or a non-local exit such as THROW)."
 912   (ir1-convert
 913    start cont
 914    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 915          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 916          (exit-tag (gensym "EXIT-TAG-"))
 917          (next (gensym "NEXT"))
 918          (start (gensym "START"))
 919          (count (gensym "COUNT")))
 920      `(flet ((,cleanup-fun () ,@cleanup nil))
 921         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 922         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 923         ;; and something can be done to make %ESCAPE-FUN have
 924         ;; dynamic extent too.
 925         (block ,drop-thru-tag
 926           (multiple-value-bind (,next ,start ,count)
 927               (block ,exit-tag
 928                 (%within-cleanup
 929                     :unwind-protect
 930                     (%unwind-protect (%escape-fun ,exit-tag)
 931                                      (%cleanup-fun ,cleanup-fun))
 932                   (return-from ,drop-thru-tag ,protected)))
 933             (,cleanup-fun)
 934             (%continue-unwind ,next ,start ,count)))))))
 935 \f
 936 ;;;; multiple-value stuff
 937
 938 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 939 ;;; MV-COMBINATION.
 940 ;;;
 941 ;;; If there are no arguments, then we convert to a normal
 942 ;;; combination, ensuring that a MV-COMBINATION always has at least
 943 ;;; one argument. This can be regarded as an optimization, but it is
 944 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 945 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 946   #!+sb-doc
 947   "MULTIPLE-VALUE-CALL Function Values-Form*
 948   Call Function, passing all the values of each Values-Form as arguments,
 949   values from the first Values-Form making up the first argument, etc."
 950   (let* ((fun-cont (make-continuation))
 951          (node (if args
 952                    (make-mv-combination fun-cont)
 953                    (make-combination fun-cont))))
 954     (ir1-convert start fun-cont
 955                  (if (and (consp fun) (eq (car fun) 'function))
 956                      fun
 957                      `(%coerce-callable-to-fun ,fun)))
 958     (setf (continuation-dest fun-cont) node)
 959     (assert-continuation-type fun-cont
 960                               (specifier-type '(or function symbol)))
 961     (collect ((arg-conts))
 962       (let ((this-start fun-cont))
 963         (dolist (arg args)
 964           (let ((this-cont (make-continuation node)))
 965             (ir1-convert this-start this-cont arg)
 966             (setq this-start this-cont)
 967             (arg-conts this-cont)))
 968         (link-node-to-previous-continuation node this-start)
 969         (use-continuation node cont)
 970         (setf (basic-combination-args node) (arg-conts))))))
 971
 972 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 973 ;;; the result code use result continuation (CONT), but transfer
 974 ;;; control to the evaluation of the body. In other words, the result
 975 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 976 ;;; the result.
 977 ;;;
 978 ;;; In order to get the control flow right, we convert the result with
 979 ;;; a dummy result continuation, then convert all the uses of the
 980 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 981 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 982 ;;; that they are consistent. Note that this doesn't amount to
 983 ;;; changing the exit target, since the control destination of an exit
 984 ;;; is determined by the block successor; we are just indicating the
 985 ;;; continuation that the result is delivered to.
 986 ;;;
 987 ;;; We then convert the body, using another dummy continuation in its
 988 ;;; own block as the result. After we are done converting the body, we
 989 ;;; move all predecessors of the dummy end block to CONT's block.
 990 ;;;
 991 ;;; Note that we both exploit and maintain the invariant that the CONT
 992 ;;; to an IR1 convert method either has no block or starts the block
 993 ;;; that control should transfer to after completion for the form.
 994 ;;; Nested MV-PROG1's work because during conversion of the result
 995 ;;; form, we use dummy continuation whose block is the true control
 996 ;;; destination.
 997 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
 998   #!+sb-doc
 999   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1000   Evaluate Values-Form and then the Forms, but return all the values of
1001   Values-Form."
1002   (continuation-starts-block cont)
1003   (let* ((dummy-result (make-continuation))
1004          (dummy-start (make-continuation))
1005          (cont-block (continuation-block cont)))
1006     (continuation-starts-block dummy-start)
1007     (ir1-convert start dummy-start result)
1008
1009     (substitute-continuation-uses cont dummy-start)
1010
1011     (continuation-starts-block dummy-result)
1012     (ir1-convert-progn-body dummy-start dummy-result forms)
1013     (let ((end-block (continuation-block dummy-result)))
1014       (dolist (pred (block-pred end-block))
1015         (unlink-blocks pred end-block)
1016         (link-blocks pred cont-block))
1017       (aver (not (continuation-dest dummy-result)))
1018       (delete-continuation dummy-result)
1019       (remove-from-dfo end-block))))
1020 \f
1021 ;;;; interface to defining macros
1022
1023 ;;;; FIXME:
1024 ;;;;   classic CMU CL comment:
1025 ;;;;     DEFMACRO and DEFUN expand into calls to %DEFxxx functions
1026 ;;;;     so that we get a chance to see what is going on. We define
1027 ;;;;     IR1 translators for these functions which look at the
1028 ;;;;     definition and then generate a call to the %%DEFxxx function.
1029 ;;;; Alas, this implementation doesn't do the right thing for
1030 ;;;; non-toplevel uses of these forms, so this should probably
1031 ;;;; be changed to use EVAL-WHEN instead.
1032
1033 ;;; Return a new source path with any stuff intervening between the
1034 ;;; current path and the first form beginning with NAME stripped off.
1035 ;;; This is used to hide the guts of DEFmumble macros to prevent
1036 ;;; annoying error messages.
1037 (defun revert-source-path (name)
1038   (do ((path *current-path* (cdr path)))
1039       ((null path) *current-path*)
1040     (let ((first (first path)))
1041       (when (or (eq first name)
1042                 (eq first 'original-source-start))
1043         (return path)))))
1044
1045 ;;; Warn about incompatible or illegal definitions and add the macro
1046 ;;; to the compiler environment.
1047 ;;;
1048 ;;; Someday we could check for macro arguments being incompatibly
1049 ;;; redefined. Doing this right will involve finding the old macro
1050 ;;; lambda-list and comparing it with the new one.
1051 (def-ir1-translator %defmacro ((qname qdef lambda-list doc) start cont
1052                                :kind :function)
1053   (let (;; QNAME is typically a quoted name. I think the idea is to
1054         ;; let %DEFMACRO work as an ordinary function when
1055         ;; interpreting. Whatever the reason the quote is there, we
1056         ;; don't want it any more. -- WHN 19990603
1057         (name (eval qname))
1058         ;; QDEF should be a sharp-quoted definition. We don't want to
1059         ;; make a function of it just yet, so we just drop the
1060         ;; sharp-quote.
1061         (def (progn
1062                (aver (eq 'function (first qdef)))
1063                (aver (proper-list-of-length-p qdef 2))
1064                (second qdef))))
1065
1066     (/show "doing IR1 translator for %DEFMACRO" name)
1067
1068     (unless (symbolp name)
1069       (compiler-error "The macro name ~S is not a symbol." name))
1070
1071     (ecase (info :function :kind name)
1072       ((nil))
1073       (:function
1074        (remhash name *free-funs*)
1075        (undefine-fun-name name)
1076        (compiler-warn
1077         "~S is being redefined as a macro when it was ~
1078          previously ~(~A~) to be a function."
1079         name
1080         (info :function :where-from name)))
1081       (:macro)
1082       (:special-form
1083        (compiler-error "The special form ~S can't be redefined as a macro."
1084                        name)))
1085
1086     (setf (info :function :kind name) :macro
1087           (info :function :where-from name) :defined
1088           (info :function :macro-function name) (coerce def 'function))
1089
1090     (let* ((*current-path* (revert-source-path 'defmacro))
1091            (fun (ir1-convert-lambda def
1092                                     :debug-name (debug-namify "DEFMACRO ~S"
1093                                                               name))))
1094       (setf (functional-arg-documentation fun) (eval lambda-list))
1095
1096       (ir1-convert start cont `(%%defmacro ',name ,fun ,doc)))
1097
1098     (when sb!xc:*compile-print*
1099       ;; FIXME: It would be nice to convert this, and the other places
1100       ;; which create compiler diagnostic output prefixed by
1101       ;; semicolons, to use some common utility which automatically
1102       ;; prefixes all its output with semicolons. (The addition of
1103       ;; semicolon prefixes was introduced ca. sbcl-0.6.8.10 as the
1104       ;; "MNA compiler message patch", and implemented by modifying a
1105       ;; bunch of output statements on a case-by-case basis, which
1106       ;; seems unnecessarily error-prone and unclear, scattering
1107       ;; implicit information about output style throughout the
1108       ;; system.) Starting by rewriting COMPILER-MUMBLE to add
1109       ;; semicolon prefixes would be a good start, and perhaps also:
1110       ;;   * Add semicolon prefixes for "FOO assembled" messages emitted
1111       ;;     when e.g. src/assembly/x86/assem-rtns.lisp is processed.
1112       ;;   * At least some debugger output messages deserve semicolon
1113       ;;     prefixes too:
1114       ;;     ** restarts table
1115       ;;     ** "Within the debugger, you can type HELP for help."
1116       (compiler-mumble "~&; converted ~S~%" name))))
1117
1118 (def-ir1-translator %define-compiler-macro ((name def lambda-list doc)
1119                                             start cont
1120                                             :kind :function)
1121   (let ((name (eval name))
1122         (def (second def))) ; We don't want to make a function just yet...
1123
1124     (when (eq (info :function :kind name) :special-form)
1125       (compiler-error "attempt to define a compiler-macro for special form ~S"
1126                       name))
1127
1128     (setf (info :function :compiler-macro-function name)
1129           (coerce def 'function))
1130
1131     (let* ((*current-path* (revert-source-path 'define-compiler-macro))
1132            (fun (ir1-convert-lambda def
1133                                     :debug-name (debug-namify
1134                                                  "DEFINE-COMPILER-MACRO ~S"
1135                                                  name))))
1136       (setf (functional-arg-documentation fun) (eval lambda-list))
1137
1138       (ir1-convert start cont `(%%define-compiler-macro ',name ,fun ,doc)))
1139
1140     (when sb!xc:*compile-print*
1141       (compiler-mumble "~&; converted ~S~%" name))))