src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     ;; IR1-CONVERT-MAYBE-PREDICATE requires DEST to be CIF, so the
  39     ;; order of the following two forms is important
  40     (setf (continuation-dest pred) node)
  41     (ir1-convert start pred test)
  42     (link-node-to-previous-continuation node pred)
  43     (use-continuation node dummy-cont)
  44
  45     (let ((start-block (continuation-block pred)))
  46       (setf (block-last start-block) node)
  47       (continuation-starts-block cont)
  48
  49       (link-blocks start-block then-block)
  50       (link-blocks start-block else-block))
  51
  52     (ir1-convert then-cont cont then)
  53     (ir1-convert else-cont cont else)))
  54 \f
  55 ;;;; BLOCK and TAGBODY
  56
  57 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  58 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  59 ;;;; node.
  60
  61 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  62 ;;; body in the modified environment. We make CONT start a block now,
  63 ;;; since if it was done later, the block would be in the wrong
  64 ;;; environment.
  65 (def-ir1-translator block ((name &rest forms) start cont)
  66   #!+sb-doc
  67   "Block Name Form*
  68   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  69   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  70   result of Value-Form."
  71   (unless (symbolp name)
  72     (compiler-error "The block name ~S is not a symbol." name))
  73   (continuation-starts-block cont)
  74   (let* ((dummy (make-continuation))
  75          (entry (make-entry))
  76          (cleanup (make-cleanup :kind :block
  77                                 :mess-up entry)))
  78     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  79     (setf (entry-cleanup entry) cleanup)
  80     (link-node-to-previous-continuation entry start)
  81     (use-continuation entry dummy)
  82
  83     (let* ((env-entry (list entry cont))
  84            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  85                                   :cleanup cleanup)))
  86       (push env-entry (continuation-lexenv-uses cont))
  87       (ir1-convert-progn-body dummy cont forms))))
  88
  89 (def-ir1-translator return-from ((name &optional value) start cont)
  90   #!+sb-doc
  91   "Return-From Block-Name Value-Form
  92   Evaluate the Value-Form, returning its values from the lexically enclosing
  93   BLOCK Block-Name. This is constrained to be used only within the dynamic
  94   extent of the BLOCK."
  95   ;; CMU CL comment:
  96   ;;   We make CONT start a block just so that it will have a block
  97   ;;   assigned. People assume that when they pass a continuation into
  98   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  99   ;; KLUDGE: Note that this block is basically fictitious. In the code
 100   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 101   ;; it's the block which answers the question "which block is
 102   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 103   ;; dead code and so doesn't really have a block at all. The existence
 104   ;; of this block, and that way that it doesn't explicitly say
 105   ;; "I'm actually nowhere at all" makes some logic (e.g.
 106   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 107   ;; to get rid of it, perhaps using a special placeholder value
 108   ;; to indicate the orphanedness of the code.
 109   (continuation-starts-block cont)
 110   (let* ((found (or (lexenv-find name blocks)
 111                     (compiler-error "return for unknown block: ~S" name)))
 112          (value-cont (make-continuation))
 113          (entry (first found))
 114          (exit (make-exit :entry entry
 115                           :value value-cont)))
 116     (push exit (entry-exits entry))
 117     (setf (continuation-dest value-cont) exit)
 118     (ir1-convert start value-cont value)
 119     (link-node-to-previous-continuation exit value-cont)
 120     (let ((home-lambda (continuation-home-lambda-or-null start)))
 121       (when home-lambda
 122         (push entry (lambda-calls-or-closes home-lambda))))
 123     (use-continuation exit (second found))))
 124
 125 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 126 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 127 ;;; tagbody into segments of non-tag statements, and explicitly
 128 ;;; represent the drop-through with a GO. The first segment has a
 129 ;;; dummy NIL tag, since it represents code before the first tag. The
 130 ;;; last segment (which may also be the first segment) ends in NIL
 131 ;;; rather than a GO.
 132 (defun parse-tagbody (body)
 133   (declare (list body))
 134   (collect ((segments))
 135     (let ((current (cons nil body)))
 136       (loop
 137         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 138           (unless tag-pos
 139             (segments `(,@current nil))
 140             (return))
 141           (let ((tag (elt current tag-pos)))
 142             (when (assoc tag (segments))
 143               (compiler-error
 144                "The tag ~S appears more than once in the tagbody."
 145                tag))
 146             (unless (or (symbolp tag) (integerp tag))
 147               (compiler-error "~S is not a legal tagbody statement." tag))
 148             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 149           (setq current (nthcdr tag-pos current)))))
 150     (segments)))
 151
 152 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 153 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 154 ;;; Finally, convert each segment with the precomputed Start and Cont
 155 ;;; values.
 156 (def-ir1-translator tagbody ((&rest statements) start cont)
 157   #!+sb-doc
 158   "Tagbody {Tag | Statement}*
 159   Define tags for used with GO. The Statements are evaluated in order
 160   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 161   defined Tag within the lexical scope of the form, then control is transferred
 162   to the next statement following that tag. A Tag must an integer or a
 163   symbol. A statement must be a list. Other objects are illegal within the
 164   body."
 165   (continuation-starts-block cont)
 166   (let* ((dummy (make-continuation))
 167          (entry (make-entry))
 168          (segments (parse-tagbody statements))
 169          (cleanup (make-cleanup :kind :tagbody
 170                                 :mess-up entry)))
 171     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 172     (setf (entry-cleanup entry) cleanup)
 173     (link-node-to-previous-continuation entry start)
 174     (use-continuation entry dummy)
 175
 176     (collect ((tags)
 177               (starts)
 178               (conts))
 179       (starts dummy)
 180       (dolist (segment (rest segments))
 181         (let* ((tag-cont (make-continuation))
 182                (tag (list (car segment) entry tag-cont)))
 183           (conts tag-cont)
 184           (starts tag-cont)
 185           (continuation-starts-block tag-cont)
 186           (tags tag)
 187           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 188       (conts cont)
 189
 190       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 191         (mapc (lambda (segment start cont)
 192                 (ir1-convert-progn-body start cont (rest segment)))
 193               segments (starts) (conts))))))
 194
 195 ;;; Emit an EXIT node without any value.
 196 (def-ir1-translator go ((tag) start cont)
 197   #!+sb-doc
 198   "Go Tag
 199   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 200   is constrained to be used only within the dynamic extent of the TAGBODY."
 201   (continuation-starts-block cont)
 202   (let* ((found (or (lexenv-find tag tags :test #'eql)
 203                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 204                                     tag)))
 205          (entry (first found))
 206          (exit (make-exit :entry entry)))
 207     (push exit (entry-exits entry))
 208     (link-node-to-previous-continuation exit start)
 209     (let ((home-lambda (continuation-home-lambda-or-null start)))
 210       (when home-lambda
 211         (push entry (lambda-calls-or-closes home-lambda))))
 212     (use-continuation exit (second found))))
 213 \f
 214 ;;;; translators for compiler-magic special forms
 215
 216 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 217 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 218 ;;; so that they're never seen at this level.)
 219 ;;;
 220 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 221 ;;; of non-top-level EVAL-WHENs is very simple:
 222 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 223 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 224 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 225 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 226 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 227 ;;;   form; otherwise, the forms in the body are ignored.
 228 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 229   #!+sb-doc
 230   "EVAL-WHEN (Situation*) Form*
 231   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 232   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 233   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 234     (declare (ignore ct lt))
 235     (ir1-convert-progn-body start cont (and e forms)))
 236   (values))
 237
 238 ;;; common logic for MACROLET and SYMBOL-MACROLET
 239 ;;;
 240 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 241 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 242 ;;; call FUN (with no arguments).
 243 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 244                                        definitionize-keyword
 245                                        definitions
 246                                        fun)
 247   (declare (type function definitionize-fun fun))
 248   (declare (type (member :vars :funs) definitionize-keyword))
 249   (declare (type list definitions))
 250   (unless (= (length definitions)
 251              (length (remove-duplicates definitions :key #'first)))
 252     (compiler-style-warn "duplicate definitions in ~S" definitions))
 253   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 254          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 255     (funcall fun definitionize-keyword processed-definitions)))
 256
 257 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 258 ;;; call FUN (with no arguments).
 259 ;;;
 260 ;;; This is split off from the IR1 convert method so that it can be
 261 ;;; shared by the special-case top level MACROLET processing code, and
 262 ;;; further split so that the special-case MACROLET processing code in
 263 ;;; EVAL can likewise make use of it.
 264 (defmacro macrolet-definitionize-fun (context lexenv)
 265   (flet ((make-error-form (control &rest args)
 266            (ecase context
 267              (:compile `(compiler-error ,control ,@args))
 268              (:eval `(error 'simple-program-error
 269                       :format-control ,control
 270                       :format-arguments (list ,@args))))))
 271     `(lambda (definition)
 272       (unless (list-of-length-at-least-p definition 2)
 273         ,(make-error-form
 274           "The list ~S is too short to be a legal local macro definition."
 275           'definition))
 276       (destructuring-bind (name arglist &body body) definition
 277         (unless (symbolp name)
 278           ,(make-error-form "The local macro name ~S is not a symbol." 'name))
 279         (unless (listp arglist)
 280           ,(make-error-form
 281             "The local macro argument list ~S is not a list."
 282             'arglist))
 283         (with-unique-names (whole environment)
 284           (multiple-value-bind (body local-decls)
 285               (parse-defmacro arglist whole body name 'macrolet
 286                               :environment environment)
 287             `(,name macro .
 288               ,(compile-in-lexenv
 289                 nil
 290                 `(lambda (,whole ,environment)
 291                   ,@local-decls
 292                   (block ,name ,body))
 293                 ,lexenv))))))))
 294
 295 (defun funcall-in-macrolet-lexenv (definitions fun)
 296   (%funcall-in-foomacrolet-lexenv
 297    (macrolet-definitionize-fun :compile (make-restricted-lexenv *lexenv*))
 298    :funs
 299    definitions
 300    fun))
 301
 302 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 303   #!+sb-doc
 304   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 305   Evaluate the Body-Forms in an environment with the specified local macros
 306   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 307   destructuring lambda list, and the Forms evaluate to the expansion.."
 308   (funcall-in-macrolet-lexenv
 309    definitions
 310    (lambda (&key funs)
 311      (declare (ignore funs))
 312      (ir1-translate-locally body start cont))))
 313
 314 (defmacro symbol-macrolet-definitionize-fun (context)
 315   (flet ((make-error-form (control &rest args)
 316            (ecase context
 317              (:compile `(compiler-error ,control ,@args))
 318              (:eval `(error 'simple-program-error
 319                       :format-control ,control
 320                       :format-arguments (list ,@args))))))
 321     `(lambda (definition)
 322       (unless (proper-list-of-length-p definition 2)
 323        ,(make-error-form "malformed symbol/expansion pair: ~S" 'definition))
 324      (destructuring-bind (name expansion) definition
 325        (unless (symbolp name)
 326          ,(make-error-form
 327            "The local symbol macro name ~S is not a symbol."
 328            'name))
 329        (let ((kind (info :variable :kind name)))
 330          (when (member kind '(:special :constant))
 331            ,(make-error-form
 332              "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 333              'kind 'name)))
 334        `(,name . (MACRO . ,expansion))))))1
 335
 336 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 337   (%funcall-in-foomacrolet-lexenv
 338    (symbol-macrolet-definitionize-fun :compile)
 339    :vars
 340    definitions
 341    fun))
 342
 343 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 344   #!+sb-doc
 345   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 346   Define the Names as symbol macros with the given Expansions. Within the
 347   body, references to a Name will effectively be replaced with the Expansion."
 348   (funcall-in-symbol-macrolet-lexenv
 349    macrobindings
 350    (lambda (&key vars)
 351      (ir1-translate-locally body start cont :vars vars))))
 352 \f
 353 ;;;; %PRIMITIVE
 354 ;;;;
 355 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 356 ;;;; into a funny function.
 357
 358 ;;; Carefully evaluate a list of forms, returning a list of the results.
 359 (defun eval-info-args (args)
 360   (declare (list args))
 361   (handler-case (mapcar #'eval args)
 362     (error (condition)
 363       (compiler-error "Lisp error during evaluation of info args:~%~A"
 364                       condition))))
 365
 366 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 367 ;;; the template, the second is a list of the results of any
 368 ;;; codegen-info args, and the remaining arguments are the runtime
 369 ;;; arguments.
 370 ;;;
 371 ;;; We do various error checking now so that we don't bomb out with
 372 ;;; a fatal error during IR2 conversion.
 373 ;;;
 374 ;;; KLUDGE: It's confusing having multiple names floating around for
 375 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 376 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 377 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 378 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 379 ;;; VOP or %VOP.. -- WHN 2001-06-11
 380 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 381 (def-ir1-translator %primitive ((name &rest args) start cont)
 382   (declare (type symbol name))
 383   (let* ((template (or (gethash name *backend-template-names*)
 384                        (bug "undefined primitive ~A" name)))
 385          (required (length (template-arg-types template)))
 386          (info (template-info-arg-count template))
 387          (min (+ required info))
 388          (nargs (length args)))
 389     (if (template-more-args-type template)
 390         (when (< nargs min)
 391           (bug "Primitive ~A was called with ~R argument~:P, ~
 392                 but wants at least ~R."
 393                name
 394                nargs
 395                min))
 396         (unless (= nargs min)
 397           (bug "Primitive ~A was called with ~R argument~:P, ~
 398                 but wants exactly ~R."
 399                name
 400                nargs
 401                min)))
 402
 403     (when (eq (template-result-types template) :conditional)
 404       (bug "%PRIMITIVE was used with a conditional template."))
 405
 406     (when (template-more-results-type template)
 407       (bug "%PRIMITIVE was used with an unknown values template."))
 408
 409     (ir1-convert start
 410                  cont
 411                  `(%%primitive ',template
 412                                ',(eval-info-args
 413                                   (subseq args required min))
 414                                ,@(subseq args 0 required)
 415                                ,@(subseq args min)))))
 416 \f
 417 ;;;; QUOTE
 418
 419 (def-ir1-translator quote ((thing) start cont)
 420   #!+sb-doc
 421   "QUOTE Value
 422   Return Value without evaluating it."
 423   (reference-constant start cont thing))
 424 \f
 425 ;;;; FUNCTION and NAMED-LAMBDA
 426
 427 (def-ir1-translator function ((thing) start cont)
 428   #!+sb-doc
 429   "FUNCTION Name
 430   Return the lexically apparent definition of the function Name. Name may also
 431   be a lambda expression."
 432   (if (consp thing)
 433       (case (car thing)
 434         ((lambda named-lambda instance-lambda lambda-with-lexenv)
 435          (reference-leaf start
 436                          cont
 437                          (ir1-convert-lambdalike
 438                           thing
 439                           :debug-name (debug-namify "#'~S" thing)
 440                           :allow-debug-catch-tag t)))
 441         ((setf sb!pcl::class-predicate sb!pcl::slot-accessor)
 442          (let ((var (find-lexically-apparent-fun
 443                      thing "as the argument to FUNCTION")))
 444            (reference-leaf start cont var)))
 445         (t
 446          (compiler-error "~S is not a legal function name." thing)))
 447       (let ((var (find-lexically-apparent-fun
 448                   thing "as the argument to FUNCTION")))
 449         (reference-leaf start cont var))))
 450 \f
 451 ;;;; FUNCALL
 452
 453 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 454 ;;; (not symbols). %FUNCALL is used directly in some places where the
 455 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 456 (deftransform funcall ((function &rest args) * *)
 457   (let ((arg-names (make-gensym-list (length args))))
 458     `(lambda (function ,@arg-names)
 459        (%funcall ,(if (csubtypep (continuation-type function)
 460                                  (specifier-type 'function))
 461                       'function
 462                       '(%coerce-callable-to-fun function))
 463                  ,@arg-names))))
 464
 465 (def-ir1-translator %funcall ((function &rest args) start cont)
 466   (let ((fun-cont (make-continuation)))
 467     (ir1-convert start fun-cont function)
 468     (assert-continuation-type fun-cont (specifier-type 'function)
 469                               (lexenv-policy *lexenv*))
 470     (ir1-convert-combination-args fun-cont cont args)))
 471
 472 ;;; This source transform exists to reduce the amount of work for the
 473 ;;; compiler. If the called function is a FUNCTION form, then convert
 474 ;;; directly to %FUNCALL, instead of waiting around for type
 475 ;;; inference.
 476 (define-source-transform funcall (function &rest args)
 477   (if (and (consp function) (eq (car function) 'function))
 478       `(%funcall ,function ,@args)
 479       (values nil t)))
 480
 481 (deftransform %coerce-callable-to-fun ((thing) (function) *
 482                                        :important t)
 483   "optimize away possible call to FDEFINITION at runtime"
 484   'thing)
 485 \f
 486 ;;;; LET and LET*
 487 ;;;;
 488 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 489 ;;;; any pervasive declarations also affect the evaluation of the
 490 ;;;; arguments.)
 491
 492 ;;; Given a list of binding specifiers in the style of LET, return:
 493 ;;;  1. The list of var structures for the variables bound.
 494 ;;;  2. The initial value form for each variable.
 495 ;;;
 496 ;;; The variable names are checked for legality and globally special
 497 ;;; variables are marked as such. Context is the name of the form, for
 498 ;;; error reporting purposes.
 499 (declaim (ftype (function (list symbol) (values list list))
 500                 extract-let-vars))
 501 (defun extract-let-vars (bindings context)
 502   (collect ((vars)
 503             (vals)
 504             (names))
 505     (flet ((get-var (name)
 506              (varify-lambda-arg name
 507                                 (if (eq context 'let*)
 508                                     nil
 509                                     (names)))))
 510       (dolist (spec bindings)
 511         (cond ((atom spec)
 512                (let ((var (get-var spec)))
 513                  (vars var)
 514                  (names spec)
 515                  (vals nil)))
 516               (t
 517                (unless (proper-list-of-length-p spec 1 2)
 518                  (compiler-error "The ~S binding spec ~S is malformed."
 519                                  context
 520                                  spec))
 521                (let* ((name (first spec))
 522                       (var (get-var name)))
 523                  (vars var)
 524                  (names name)
 525                  (vals (second spec)))))))
 526
 527     (values (vars) (vals))))
 528
 529 (def-ir1-translator let ((bindings &body body)
 530                          start cont)
 531   #!+sb-doc
 532   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 533   During evaluation of the Forms, bind the Vars to the result of evaluating the
 534   Value forms. The variables are bound in parallel after all of the Values are
 535   evaluated."
 536   (if (null bindings)
 537       (ir1-translate-locally  body start cont)
 538       (multiple-value-bind (forms decls) (parse-body body nil)
 539         (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 540           (let ((fun-cont (make-continuation)))
 541             (let* ((*lexenv* (process-decls decls vars nil cont))
 542                    (fun (ir1-convert-lambda-body
 543                          forms vars
 544                          :debug-name (debug-namify "LET ~S" bindings))))
 545               (reference-leaf start fun-cont fun))
 546             (ir1-convert-combination-args fun-cont cont values))))))
 547
 548 (def-ir1-translator let* ((bindings &body body)
 549                           start cont)
 550   #!+sb-doc
 551   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 552   Similar to LET, but the variables are bound sequentially, allowing each Value
 553   form to reference any of the previous Vars."
 554   (multiple-value-bind (forms decls) (parse-body body nil)
 555     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 556       (let ((*lexenv* (process-decls decls vars nil cont)))
 557         (ir1-convert-aux-bindings start cont forms vars values)))))
 558
 559 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 560 ;;; and SYMBOL-MACROLET
 561 ;;;
 562 ;;; Note that all these things need to preserve toplevel-formness,
 563 ;;; but we don't need to worry about that within an IR1 translator,
 564 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 565 ;;; forms before we hit the IR1 transform level.
 566 (defun ir1-translate-locally (body start cont &key vars funs)
 567   (declare (type list body) (type continuation start cont))
 568   (multiple-value-bind (forms decls) (parse-body body nil)
 569     (let ((*lexenv* (process-decls decls vars funs cont)))
 570       (ir1-convert-aux-bindings start cont forms nil nil))))
 571
 572 (def-ir1-translator locally ((&body body) start cont)
 573   #!+sb-doc
 574   "LOCALLY Declaration* Form*
 575   Sequentially evaluate the Forms in a lexical environment where the
 576   the Declarations have effect. If LOCALLY is a top level form, then
 577   the Forms are also processed as top level forms."
 578   (ir1-translate-locally body start cont))
 579 \f
 580 ;;;; FLET and LABELS
 581
 582 ;;; Given a list of local function specifications in the style of
 583 ;;; FLET, return lists of the function names and of the lambdas which
 584 ;;; are their definitions.
 585 ;;;
 586 ;;; The function names are checked for legality. CONTEXT is the name
 587 ;;; of the form, for error reporting.
 588 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 589 (defun extract-flet-vars (definitions context)
 590   (collect ((names)
 591             (defs))
 592     (dolist (def definitions)
 593       (when (or (atom def) (< (length def) 2))
 594         (compiler-error "The ~S definition spec ~S is malformed." context def))
 595
 596       (let ((name (first def)))
 597         (check-fun-name name)
 598         (names name)
 599         (multiple-value-bind (forms decls) (parse-body (cddr def))
 600           (defs `(lambda ,(second def)
 601                    ,@decls
 602                    (block ,(fun-name-block-name name)
 603                      . ,forms))))))
 604     (values (names) (defs))))
 605
 606 (def-ir1-translator flet ((definitions &body body)
 607                           start cont)
 608   #!+sb-doc
 609   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 610   Evaluate the Body-Forms with some local function definitions. The bindings
 611   do not enclose the definitions; any use of Name in the Forms will refer to
 612   the lexically apparent function definition in the enclosing environment."
 613   (multiple-value-bind (forms decls) (parse-body body nil)
 614     (multiple-value-bind (names defs)
 615         (extract-flet-vars definitions 'flet)
 616       (let* ((fvars (mapcar (lambda (n d)
 617                               (ir1-convert-lambda d
 618                                                   :source-name n
 619                                                   :debug-name (debug-namify
 620                                                                "FLET ~S" n)
 621                                                   :allow-debug-catch-tag t))
 622                             names defs))
 623              (*lexenv* (make-lexenv
 624                         :default (process-decls decls nil fvars cont)
 625                         :funs (pairlis names fvars))))
 626         (ir1-convert-progn-body start cont forms)))))
 627
 628 (def-ir1-translator labels ((definitions &body body) start cont)
 629   #!+sb-doc
 630   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 631   Evaluate the Body-Forms with some local function definitions. The bindings
 632   enclose the new definitions, so the defined functions can call themselves or
 633   each other."
 634   (multiple-value-bind (forms decls) (parse-body body nil)
 635     (multiple-value-bind (names defs)
 636         (extract-flet-vars definitions 'labels)
 637       (let* (;; dummy LABELS functions, to be used as placeholders
 638              ;; during construction of real LABELS functions
 639              (placeholder-funs (mapcar (lambda (name)
 640                                          (make-functional
 641                                           :%source-name name
 642                                           :%debug-name (debug-namify
 643                                                         "LABELS placeholder ~S"
 644                                                         name)))
 645                                        names))
 646              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 647              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 648              ;; the real LABELS functions, compiled in a LEXENV which
 649              ;; includes the dummy LABELS functions
 650              (real-funs
 651               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 652                 (mapcar (lambda (name def)
 653                           (ir1-convert-lambda def
 654                                               :source-name name
 655                                               :debug-name (debug-namify
 656                                                            "LABELS ~S" name)
 657                                               :allow-debug-catch-tag t))
 658                         names defs))))
 659
 660         ;; Modify all the references to the dummy function leaves so
 661         ;; that they point to the real function leaves.
 662         (loop for real-fun in real-funs and
 663               placeholder-cons in placeholder-fenv do
 664               (substitute-leaf real-fun (cdr placeholder-cons))
 665               (setf (cdr placeholder-cons) real-fun))
 666
 667         ;; Voila.
 668         (let ((*lexenv* (make-lexenv
 669                          :default (process-decls decls nil real-funs cont)
 670                          ;; Use a proper FENV here (not the
 671                          ;; placeholder used earlier) so that if the
 672                          ;; lexical environment is used for inline
 673                          ;; expansion we'll get the right functions.
 674                          :funs (pairlis names real-funs))))
 675           (ir1-convert-progn-body start cont forms))))))
 676 \f
 677 ;;;; the THE special operator, and friends
 678
 679 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 680 ;;; continuation that the assertion applies to, TYPE is the type
 681 ;;; specifier and LEXENV is the current lexical environment. NAME is
 682 ;;; the name of the declaration we are doing, for use in error
 683 ;;; messages.
 684 ;;;
 685 ;;; This is somewhat involved, since a type assertion may only be made
 686 ;;; on a continuation, not on a node. We can't just set the
 687 ;;; continuation asserted type and let it go at that, since there may
 688 ;;; be parallel THE's for the same continuation, i.e.
 689 ;;;     (if ...
 690 ;;;      (the foo ...)
 691 ;;;      (the bar ...))
 692 ;;;
 693 ;;; In this case, our representation can do no better than the union
 694 ;;; of these assertions. And if there is a branch with no assertion,
 695 ;;; we have nothing at all. We really need to recognize scoping, since
 696 ;;; we need to be able to discern between parallel assertions (which
 697 ;;; we union) and nested ones (which we intersect).
 698 ;;;
 699 ;;; We represent the scoping by throwing our innermost (intersected)
 700 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 701 ;;; intersect our assertions together. If CONT has no uses yet, we
 702 ;;; have not yet bottomed out on the first COND branch; in this case
 703 ;;; we optimistically assume that this type will be the one we end up
 704 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 705 ;;; than the type that we have the first time we bottom out. Later
 706 ;;; THE's (or the absence thereof) can only weaken this result.
 707 ;;;
 708 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 709 ;;; across COND branches. We can't do it here, since we don't know how
 710 ;;; many branches there are going to be.
 711 (defun ir1ize-the-or-values (type cont lexenv place)
 712   (declare (type continuation cont) (type lexenv lexenv))
 713   (let* ((atype (if (typep type 'ctype)
 714                     type
 715                     (compiler-values-specifier-type type)))
 716          (old-atype (or (lexenv-find cont type-restrictions)
 717                         *wild-type*))
 718          (old-ctype (or (lexenv-find cont weakend-type-restrictions)
 719                         *wild-type*))
 720          (intersects (values-types-equal-or-intersect old-atype atype))
 721          (new-atype (values-type-intersection old-atype atype))
 722          (new-ctype (values-type-intersection
 723                      old-ctype
 724                      (maybe-weaken-check atype (lexenv-policy lexenv)))))
 725     (when (null (find-uses cont))
 726       (setf (continuation-asserted-type cont) new-atype)
 727       (setf (continuation-type-to-check cont) new-ctype))
 728     (when (and (not intersects)
 729                ;; FIXME: Is it really right to look at *LEXENV* here,
 730                ;; instead of looking at the LEXENV argument? Why?
 731                (not (policy *lexenv*
 732                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 733       (compiler-warn
 734        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 735        (type-specifier atype)
 736        place
 737        (type-specifier old-atype)))
 738     (make-lexenv :type-restrictions `((,cont . ,new-atype))
 739                  :weakend-type-restrictions `((,cont . ,new-ctype))
 740                  :default lexenv)))
 741
 742 ;;; Assert that FORM evaluates to the specified type (which may be a
 743 ;;; VALUES type).
 744 ;;;
 745 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 746 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 747 ;;; values. Check that SBCL doesn't have this problem.
 748 (def-ir1-translator the ((type value) start cont)
 749   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 750                                           "in THE declaration")
 751     (ir1-convert start cont value)))
 752
 753 ;;; This is like the THE special form, except that it believes
 754 ;;; whatever you tell it. It will never generate a type check, but
 755 ;;; will cause a warning if the compiler can prove the assertion is
 756 ;;; wrong.
 757 ;;;
 758 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 759 ;;; its uses's types, setting it won't work. Instead we must intersect
 760 ;;; the type with the uses's DERIVED-TYPE.
 761 (def-ir1-translator truly-the ((type value) start cont)
 762   #!+sb-doc
 763   (declare (inline member))
 764   (let ((type (compiler-values-specifier-type type))
 765         (old (find-uses cont)))
 766     (ir1-convert start cont value)
 767     (do-uses (use cont)
 768       (unless (member use old :test #'eq)
 769         (derive-node-type use type)))))
 770 \f
 771 ;;;; SETQ
 772
 773 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 774 ;;; look at the global information. If the name is for a constant,
 775 ;;; then error out.
 776 (def-ir1-translator setq ((&whole source &rest things) start cont)
 777   (let ((len (length things)))
 778     (when (oddp len)
 779       (compiler-error "odd number of args to SETQ: ~S" source))
 780     (if (= len 2)
 781         (let* ((name (first things))
 782                (leaf (or (lexenv-find name vars)
 783                          (find-free-var name))))
 784           (etypecase leaf
 785             (leaf
 786              (when (constant-p leaf)
 787                (compiler-error "~S is a constant and thus can't be set." name))
 788              (when (lambda-var-p leaf)
 789                (let ((home-lambda (continuation-home-lambda-or-null start)))
 790                  (when home-lambda
 791                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 792                (when (lambda-var-ignorep leaf)
 793                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 794                  ;; requires that this be a STYLE-WARNING, not a full warning.
 795                  (compiler-style-warn
 796                   "~S is being set even though it was declared to be ignored."
 797                   name)))
 798              (setq-var start cont leaf (second things)))
 799             (cons
 800              (aver (eq (car leaf) 'MACRO))
 801              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 802             (heap-alien-info
 803              (ir1-convert start cont
 804                           `(%set-heap-alien ',leaf ,(second things))))))
 805         (collect ((sets))
 806           (do ((thing things (cddr thing)))
 807               ((endp thing)
 808                (ir1-convert-progn-body start cont (sets)))
 809             (sets `(setq ,(first thing) ,(second thing))))))))
 810
 811 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 812 ;;; This should only need to be called in SETQ.
 813 (defun setq-var (start cont var value)
 814   (declare (type continuation start cont) (type basic-var var))
 815   (let ((dest (make-continuation)))
 816     (ir1-convert start dest value)
 817     (assert-continuation-type dest
 818                               (or (lexenv-find var type-restrictions)
 819                                   (leaf-type var))
 820                               (lexenv-policy *lexenv*))
 821     (let ((res (make-set :var var :value dest)))
 822       (setf (continuation-dest dest) res)
 823       (setf (leaf-ever-used var) t)
 824       (push res (basic-var-sets var))
 825       (link-node-to-previous-continuation res dest)
 826       (use-continuation res cont))))
 827 \f
 828 ;;;; CATCH, THROW and UNWIND-PROTECT
 829
 830 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 831 ;;; since as as far as IR1 is concerned, it has no interesting
 832 ;;; properties other than receiving multiple-values.
 833 (def-ir1-translator throw ((tag result) start cont)
 834   #!+sb-doc
 835   "Throw Tag Form
 836   Do a non-local exit, return the values of Form from the CATCH whose tag
 837   evaluates to the same thing as Tag."
 838   (ir1-convert start cont
 839                `(multiple-value-call #'%throw ,tag ,result)))
 840
 841 ;;; This is a special special form used to instantiate a cleanup as
 842 ;;; the current cleanup within the body. KIND is the kind of cleanup
 843 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 844 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 845 ;;; and introduce the cleanup into the lexical environment. We
 846 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 847 ;;; cleanup, since this inner cleanup is the interesting one.
 848 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 849   (let ((dummy (make-continuation))
 850         (dummy2 (make-continuation)))
 851     (ir1-convert start dummy mess-up)
 852     (let* ((mess-node (continuation-use dummy))
 853            (cleanup (make-cleanup :kind kind
 854                                   :mess-up mess-node))
 855            (old-cup (lexenv-cleanup *lexenv*))
 856            (*lexenv* (make-lexenv :cleanup cleanup)))
 857       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 858       (ir1-convert dummy dummy2 '(%cleanup-point))
 859       (ir1-convert-progn-body dummy2 cont body))))
 860
 861 ;;; This is a special special form that makes an "escape function"
 862 ;;; which returns unknown values from named block. We convert the
 863 ;;; function, set its kind to :ESCAPE, and then reference it. The
 864 ;;; :ESCAPE kind indicates that this function's purpose is to
 865 ;;; represent a non-local control transfer, and that it might not
 866 ;;; actually have to be compiled.
 867 ;;;
 868 ;;; Note that environment analysis replaces references to escape
 869 ;;; functions with references to the corresponding NLX-INFO structure.
 870 (def-ir1-translator %escape-fun ((tag) start cont)
 871   (let ((fun (ir1-convert-lambda
 872               `(lambda ()
 873                  (return-from ,tag (%unknown-values)))
 874               :debug-name (debug-namify "escape function for ~S" tag))))
 875     (setf (functional-kind fun) :escape)
 876     (reference-leaf start cont fun)))
 877
 878 ;;; Yet another special special form. This one looks up a local
 879 ;;; function and smashes it to a :CLEANUP function, as well as
 880 ;;; referencing it.
 881 (def-ir1-translator %cleanup-fun ((name) start cont)
 882   (let ((fun (lexenv-find name funs)))
 883     (aver (lambda-p fun))
 884     (setf (functional-kind fun) :cleanup)
 885     (reference-leaf start cont fun)))
 886
 887 (def-ir1-translator catch ((tag &body body) start cont)
 888   #!+sb-doc
 889   "Catch Tag Form*
 890   Evaluate TAG and instantiate it as a catcher while the body forms are
 891   evaluated in an implicit PROGN. If a THROW is done to TAG within the dynamic
 892   scope of the body, then control will be transferred to the end of the body
 893   and the thrown values will be returned."
 894   ;; We represent the possibility of the control transfer by making an
 895   ;; "escape function" that does a lexical exit, and instantiate the
 896   ;; cleanup using %WITHIN-CLEANUP.
 897   (ir1-convert
 898    start cont
 899    (with-unique-names (exit-block)
 900      `(block ,exit-block
 901         (%within-cleanup
 902             :catch
 903             (%catch (%escape-fun ,exit-block) ,tag)
 904           ,@body)))))
 905
 906 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 907   #!+sb-doc
 908   "Unwind-Protect Protected Cleanup*
 909   Evaluate the form PROTECTED, returning its values. The CLEANUP forms are
 910   evaluated whenever the dynamic scope of the PROTECTED form is exited (either
 911   due to normal completion or a non-local exit such as THROW)."
 912   ;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 913   ;; cleanup forms into a local function so that they can be referenced
 914   ;; both in the case where we are unwound and in any local exits. We
 915   ;; use %CLEANUP-FUN on this to indicate that reference by
 916   ;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 917   ;; an XEP.
 918   (ir1-convert
 919    start cont
 920    (with-unique-names (cleanup-fun drop-thru-tag exit-tag next start count)
 921      `(flet ((,cleanup-fun () ,@cleanup nil))
 922         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 923         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 924         ;; and something can be done to make %ESCAPE-FUN have
 925         ;; dynamic extent too.
 926         (block ,drop-thru-tag
 927           (multiple-value-bind (,next ,start ,count)
 928               (block ,exit-tag
 929                 (%within-cleanup
 930                     :unwind-protect
 931                     (%unwind-protect (%escape-fun ,exit-tag)
 932                                      (%cleanup-fun ,cleanup-fun))
 933                   (return-from ,drop-thru-tag ,protected)))
 934             (,cleanup-fun)
 935             (%continue-unwind ,next ,start ,count)))))))
 936 \f
 937 ;;;; multiple-value stuff
 938
 939 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 940   #!+sb-doc
 941   "MULTIPLE-VALUE-CALL Function Values-Form*
 942   Call FUNCTION, passing all the values of each VALUES-FORM as arguments,
 943   values from the first VALUES-FORM making up the first argument, etc."
 944   (let* ((fun-cont (make-continuation))
 945          (node (if args
 946                    ;; If there are arguments, MULTIPLE-VALUE-CALL
 947                    ;; turns into an MV-COMBINATION.
 948                    (make-mv-combination fun-cont)
 949                    ;; If there are no arguments, then we convert to a
 950                    ;; normal combination, ensuring that a MV-COMBINATION
 951                    ;; always has at least one argument. This can be
 952                    ;; regarded as an optimization, but it is more
 953                    ;; important for simplifying compilation of
 954                    ;; MV-COMBINATIONS.
 955                    (make-combination fun-cont))))
 956     (ir1-convert start fun-cont
 957                  (if (and (consp fun) (eq (car fun) 'function))
 958                      fun
 959                      `(%coerce-callable-to-fun ,fun)))
 960     (setf (continuation-dest fun-cont) node)
 961     (collect ((arg-conts))
 962       (let ((this-start fun-cont))
 963         (dolist (arg args)
 964           (let ((this-cont (make-continuation node)))
 965             (ir1-convert this-start this-cont arg)
 966             (setq this-start this-cont)
 967             (arg-conts this-cont)))
 968         (link-node-to-previous-continuation node this-start)
 969         (use-continuation node cont)
 970         (setf (basic-combination-args node) (arg-conts))))))
 971
 972 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 973 ;;; the result code use result continuation (CONT), but transfer
 974 ;;; control to the evaluation of the body. In other words, the result
 975 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 976 ;;; the result.
 977 ;;;
 978 ;;; In order to get the control flow right, we convert the result with
 979 ;;; a dummy result continuation, then convert all the uses of the
 980 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 981 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 982 ;;; that they are consistent. Note that this doesn't amount to
 983 ;;; changing the exit target, since the control destination of an exit
 984 ;;; is determined by the block successor; we are just indicating the
 985 ;;; continuation that the result is delivered to.
 986 ;;;
 987 ;;; We then convert the body, using another dummy continuation in its
 988 ;;; own block as the result. After we are done converting the body, we
 989 ;;; move all predecessors of the dummy end block to CONT's block.
 990 ;;;
 991 ;;; Note that we both exploit and maintain the invariant that the CONT
 992 ;;; to an IR1 convert method either has no block or starts the block
 993 ;;; that control should transfer to after completion for the form.
 994 ;;; Nested MV-PROG1's work because during conversion of the result
 995 ;;; form, we use dummy continuation whose block is the true control
 996 ;;; destination.
 997 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
 998   #!+sb-doc
 999   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1000   Evaluate Values-Form and then the Forms, but return all the values of
1001   Values-Form."
1002   (continuation-starts-block cont)
1003   (let* ((dummy-result (make-continuation))
1004          (dummy-start (make-continuation))
1005          (cont-block (continuation-block cont)))
1006     (continuation-starts-block dummy-start)
1007     (ir1-convert start dummy-start result)
1008
1009     (with-continuation-type-assertion
1010         ;; FIXME: policy
1011         (cont (continuation-asserted-type dummy-start)
1012               "of the first form")
1013       (substitute-continuation-uses cont dummy-start))
1014
1015     (continuation-starts-block dummy-result)
1016     (ir1-convert-progn-body dummy-start dummy-result forms)
1017     (let ((end-block (continuation-block dummy-result)))
1018       (dolist (pred (block-pred end-block))
1019         (unlink-blocks pred end-block)
1020         (link-blocks pred cont-block))
1021       (aver (not (continuation-dest dummy-result)))
1022       (delete-continuation dummy-result)
1023       (remove-from-dfo end-block))))
1024 \f
1025 ;;;; interface to defining macros
1026
1027 ;;; Old CMUCL comment:
1028 ;;;
1029 ;;;   Return a new source path with any stuff intervening between the
1030 ;;;   current path and the first form beginning with NAME stripped
1031 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1032 ;;;   prevent annoying error messages.
1033 ;;;
1034 ;;; Now that we have implementations of DEFmumble macros in terms of
1035 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1036 ;;; worth figuring out why it was used, and maybe doing analogous
1037 ;;; munging to the functions created in the expanders for the macros.
1038 (defun revert-source-path (name)
1039   (do ((path *current-path* (cdr path)))
1040       ((null path) *current-path*)
1041     (let ((first (first path)))
1042       (when (or (eq first name)
1043                 (eq first 'original-source-start))
1044         (return path)))))