src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; control special forms
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     (setf (continuation-dest pred) node)
  39     (ir1-convert start pred test)
  40     (link-node-to-previous-continuation node pred)
  41     (use-continuation node dummy-cont)
  42
  43     (let ((start-block (continuation-block pred)))
  44       (setf (block-last start-block) node)
  45       (continuation-starts-block cont)
  46
  47       (link-blocks start-block then-block)
  48       (link-blocks start-block else-block))
  49
  50     (ir1-convert then-cont cont then)
  51     (ir1-convert else-cont cont else)))
  52 \f
  53 ;;;; BLOCK and TAGBODY
  54
  55 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  56 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  57 ;;;; node.
  58
  59 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  60 ;;; body in the modified environment. We make CONT start a block now,
  61 ;;; since if it was done later, the block would be in the wrong
  62 ;;; environment.
  63 (def-ir1-translator block ((name &rest forms) start cont)
  64   #!+sb-doc
  65   "Block Name Form*
  66   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  67   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  68   result of Value-Form."
  69   (unless (symbolp name)
  70     (compiler-error "The block name ~S is not a symbol." name))
  71   (continuation-starts-block cont)
  72   (let* ((dummy (make-continuation))
  73          (entry (make-entry))
  74          (cleanup (make-cleanup :kind :block
  75                                 :mess-up entry)))
  76     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  77     (setf (entry-cleanup entry) cleanup)
  78     (link-node-to-previous-continuation entry start)
  79     (use-continuation entry dummy)
  80
  81     (let* ((env-entry (list entry cont))
  82            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  83                                   :cleanup cleanup)))
  84       (push env-entry (continuation-lexenv-uses cont))
  85       (ir1-convert-progn-body dummy cont forms))))
  86
  87
  88 (def-ir1-translator return-from ((name &optional value) start cont)
  89   #!+sb-doc
  90   "Return-From Block-Name Value-Form
  91   Evaluate the Value-Form, returning its values from the lexically enclosing
  92   BLOCK Block-Name. This is constrained to be used only within the dynamic
  93   extent of the BLOCK."
  94   ;; CMU CL comment:
  95   ;;   We make CONT start a block just so that it will have a block
  96   ;;   assigned. People assume that when they pass a continuation into
  97   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  98   ;; KLUDGE: Note that this block is basically fictitious. In the code
  99   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 100   ;; it's the block which answers the question "which block is
 101   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 102   ;; dead code and so doesn't really have a block at all. The existence
 103   ;; of this block, and that way that it doesn't explicitly say
 104   ;; "I'm actually nowhere at all" makes some logic (e.g.
 105   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 106   ;; to get rid of it, perhaps using a special placeholder value
 107   ;; to indicate the orphanedness of the code.
 108   (continuation-starts-block cont)
 109   (let* ((found (or (lexenv-find name blocks)
 110                     (compiler-error "return for unknown block: ~S" name)))
 111          (value-cont (make-continuation))
 112          (entry (first found))
 113          (exit (make-exit :entry entry
 114                           :value value-cont)))
 115     (push exit (entry-exits entry))
 116     (setf (continuation-dest value-cont) exit)
 117     (ir1-convert start value-cont value)
 118     (link-node-to-previous-continuation exit value-cont)
 119     (let ((home-lambda (continuation-home-lambda-or-null start)))
 120       (when home-lambda
 121         (push entry (lambda-calls-or-closes home-lambda))))
 122     (use-continuation exit (second found))))
 123
 124 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 125 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 126 ;;; tagbody into segments of non-tag statements, and explicitly
 127 ;;; represent the drop-through with a GO. The first segment has a
 128 ;;; dummy NIL tag, since it represents code before the first tag. The
 129 ;;; last segment (which may also be the first segment) ends in NIL
 130 ;;; rather than a GO.
 131 (defun parse-tagbody (body)
 132   (declare (list body))
 133   (collect ((segments))
 134     (let ((current (cons nil body)))
 135       (loop
 136         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 137           (unless tag-pos
 138             (segments `(,@current nil))
 139             (return))
 140           (let ((tag (elt current tag-pos)))
 141             (when (assoc tag (segments))
 142               (compiler-error
 143                "The tag ~S appears more than once in the tagbody."
 144                tag))
 145             (unless (or (symbolp tag) (integerp tag))
 146               (compiler-error "~S is not a legal tagbody statement." tag))
 147             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 148           (setq current (nthcdr tag-pos current)))))
 149     (segments)))
 150
 151 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 152 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 153 ;;; Finally, convert each segment with the precomputed Start and Cont
 154 ;;; values.
 155 (def-ir1-translator tagbody ((&rest statements) start cont)
 156   #!+sb-doc
 157   "Tagbody {Tag | Statement}*
 158   Define tags for used with GO. The Statements are evaluated in order
 159   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 160   defined Tag within the lexical scope of the form, then control is transferred
 161   to the next statement following that tag. A Tag must an integer or a
 162   symbol. A statement must be a list. Other objects are illegal within the
 163   body."
 164   (continuation-starts-block cont)
 165   (let* ((dummy (make-continuation))
 166          (entry (make-entry))
 167          (segments (parse-tagbody statements))
 168          (cleanup (make-cleanup :kind :tagbody
 169                                 :mess-up entry)))
 170     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 171     (setf (entry-cleanup entry) cleanup)
 172     (link-node-to-previous-continuation entry start)
 173     (use-continuation entry dummy)
 174
 175     (collect ((tags)
 176               (starts)
 177               (conts))
 178       (starts dummy)
 179       (dolist (segment (rest segments))
 180         (let* ((tag-cont (make-continuation))
 181                (tag (list (car segment) entry tag-cont)))
 182           (conts tag-cont)
 183           (starts tag-cont)
 184           (continuation-starts-block tag-cont)
 185           (tags tag)
 186           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 187       (conts cont)
 188
 189       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 190         (mapc (lambda (segment start cont)
 191                 (ir1-convert-progn-body start cont (rest segment)))
 192               segments (starts) (conts))))))
 193
 194 ;;; Emit an EXIT node without any value.
 195 (def-ir1-translator go ((tag) start cont)
 196   #!+sb-doc
 197   "Go Tag
 198   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 199   is constrained to be used only within the dynamic extent of the TAGBODY."
 200   (continuation-starts-block cont)
 201   (let* ((found (or (lexenv-find tag tags :test #'eql)
 202                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 203                                     tag)))
 204          (entry (first found))
 205          (exit (make-exit :entry entry)))
 206     (push exit (entry-exits entry))
 207     (link-node-to-previous-continuation exit start)
 208     (let ((home-lambda (continuation-home-lambda-or-null start)))
 209       (when home-lambda
 210         (push entry (lambda-calls-or-closes home-lambda))))
 211     (use-continuation exit (second found))))
 212 \f
 213 ;;;; translators for compiler-magic special forms
 214
 215 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 216 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 217 ;;; so that they're never seen at this level.)
 218 ;;;
 219 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 220 ;;; of non-top-level EVAL-WHENs is very simple:
 221 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 222 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 223 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 224 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 225 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 226 ;;;   form; otherwise, the forms in the body are ignored.
 227 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 228   #!+sb-doc
 229   "EVAL-WHEN (Situation*) Form*
 230   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 231   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 232   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 233     (declare (ignore ct lt))
 234     (ir1-convert-progn-body start cont (and e forms)))
 235   (values))
 236
 237 ;;; common logic for MACROLET and SYMBOL-MACROLET
 238 ;;;
 239 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 240 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 241 ;;; call FUN (with no arguments).
 242 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 243                                        definitionize-keyword
 244                                        definitions
 245                                        fun)
 246   (declare (type function definitionize-fun fun))
 247   (declare (type (member :vars :funs) definitionize-keyword))
 248   (declare (type list definitions))
 249   (unless (= (length definitions)
 250              (length (remove-duplicates definitions :key #'first)))
 251     (compiler-style-warn "duplicate definitions in ~S" definitions))
 252   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 253          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 254     (funcall fun)))
 255
 256 ;;; Tweak *LEXENV* to include the DEFINITIONS from a MACROLET, then
 257 ;;; call FUN (with no arguments).
 258 ;;;
 259 ;;; This is split off from the IR1 convert method so that it can be
 260 ;;; shared by the special-case top level MACROLET processing code.
 261 (defun funcall-in-macrolet-lexenv (definitions fun)
 262   (%funcall-in-foomacrolet-lexenv
 263    (lambda (definition)
 264      (unless (list-of-length-at-least-p definition 2)
 265        (compiler-error
 266         "The list ~S is too short to be a legal local macro definition."
 267         definition))
 268      (destructuring-bind (name arglist &body body) definition
 269        (unless (symbolp name)
 270          (compiler-error "The local macro name ~S is not a symbol." name))
 271        (let ((whole (gensym "WHOLE"))
 272              (environment (gensym "ENVIRONMENT")))
 273          (multiple-value-bind (body local-decls)
 274              (parse-defmacro arglist whole body name 'macrolet
 275                              :environment environment)
 276            `(,name macro .
 277                    ,(compile nil
 278                              `(lambda (,whole ,environment)
 279                                 ,@local-decls
 280                                 (block ,name ,body))))))))
 281    :funs
 282    definitions
 283    fun))
 284
 285 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 286   #!+sb-doc
 287   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 288   Evaluate the Body-Forms in an environment with the specified local macros
 289   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 290   destructuring lambda list, and the Forms evaluate to the expansion. The
 291   Forms are evaluated in the null environment."
 292   (funcall-in-macrolet-lexenv definitions
 293                               (lambda ()
 294                                 (ir1-translate-locally body start cont))))
 295
 296 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 297   (%funcall-in-foomacrolet-lexenv
 298    (lambda (definition)
 299      (unless (proper-list-of-length-p definition 2)
 300        (compiler-error "malformed symbol/expansion pair: ~S" definition))
 301      (destructuring-bind (name expansion) definition
 302        (unless (symbolp name)
 303          (compiler-error
 304           "The local symbol macro name ~S is not a symbol."
 305           name))
 306        `(,name . (MACRO . ,expansion))))
 307    :vars
 308    definitions
 309    fun))
 310
 311 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 312   #!+sb-doc
 313   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 314   Define the Names as symbol macros with the given Expansions. Within the
 315   body, references to a Name will effectively be replaced with the Expansion."
 316   (funcall-in-symbol-macrolet-lexenv
 317    macrobindings
 318    (lambda ()
 319      (ir1-translate-locally body start cont))))
 320
 321 ;;; not really a special form, but..
 322 (def-ir1-translator declare ((&rest stuff) start cont)
 323   (declare (ignore stuff))
 324   ;; We ignore START and CONT too, but we can't use DECLARE IGNORE to
 325   ;; tell the compiler about it here, because the DEF-IR1-TRANSLATOR
 326   ;; macro would put the DECLARE in the wrong place, so..
 327   start cont
 328   (compiler-error "misplaced declaration"))
 329 \f
 330 ;;;; %PRIMITIVE
 331 ;;;;
 332 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 333 ;;;; into a funny function.
 334
 335 ;;; Carefully evaluate a list of forms, returning a list of the results.
 336 (defun eval-info-args (args)
 337   (declare (list args))
 338   (handler-case (mapcar #'eval args)
 339     (error (condition)
 340       (compiler-error "Lisp error during evaluation of info args:~%~A"
 341                       condition))))
 342
 343 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 344 ;;; the template, the second is a list of the results of any
 345 ;;; codegen-info args, and the remaining arguments are the runtime
 346 ;;; arguments.
 347 ;;;
 348 ;;; We do various error checking now so that we don't bomb out with
 349 ;;; a fatal error during IR2 conversion.
 350 ;;;
 351 ;;; KLUDGE: It's confusing having multiple names floating around for
 352 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 353 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 354 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 355 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 356 ;;; VOP or %VOP.. -- WHN 2001-06-11
 357 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 358 (def-ir1-translator %primitive ((name &rest args) start cont)
 359   (unless (symbolp name)
 360     (compiler-error "internal error: Primitive name ~S is not a symbol." name))
 361   (let* ((template (or (gethash name *backend-template-names*)
 362                        (compiler-error
 363                         "internal error: Primitive name ~A is not defined."
 364                         name)))
 365          (required (length (template-arg-types template)))
 366          (info (template-info-arg-count template))
 367          (min (+ required info))
 368          (nargs (length args)))
 369     (if (template-more-args-type template)
 370         (when (< nargs min)
 371           (compiler-error "internal error: Primitive ~A was called ~
 372                            with ~R argument~:P, ~
 373                            but wants at least ~R."
 374                           name
 375                           nargs
 376                           min))
 377         (unless (= nargs min)
 378           (compiler-error "internal error: Primitive ~A was called ~
 379                            with ~R argument~:P, ~
 380                            but wants exactly ~R."
 381                           name
 382                           nargs
 383                           min)))
 384
 385     (when (eq (template-result-types template) :conditional)
 386       (compiler-error
 387        "%PRIMITIVE was used with a conditional template."))
 388
 389     (when (template-more-results-type template)
 390       (compiler-error
 391        "%PRIMITIVE was used with an unknown values template."))
 392
 393     (ir1-convert start
 394                  cont
 395                  `(%%primitive ',template
 396                                ',(eval-info-args
 397                                   (subseq args required min))
 398                                ,@(subseq args 0 required)
 399                                ,@(subseq args min)))))
 400 \f
 401 ;;;; QUOTE
 402
 403 (def-ir1-translator quote ((thing) start cont)
 404   #!+sb-doc
 405   "QUOTE Value
 406   Return Value without evaluating it."
 407   (reference-constant start cont thing))
 408 \f
 409 ;;;; FUNCTION and NAMED-LAMBDA
 410
 411 (def-ir1-translator function ((thing) start cont)
 412   #!+sb-doc
 413   "FUNCTION Name
 414   Return the lexically apparent definition of the function Name. Name may also
 415   be a lambda expression."
 416   (if (consp thing)
 417       (case (car thing)
 418         ((lambda)
 419          (reference-leaf start
 420                          cont
 421                          (ir1-convert-lambda thing
 422                                              :debug-name (debug-namify
 423                                                           "#'~S" thing))))
 424         ((setf)
 425          (let ((var (find-lexically-apparent-fun
 426                      thing "as the argument to FUNCTION")))
 427            (reference-leaf start cont var)))
 428         ((instance-lambda)
 429          (let ((res (ir1-convert-lambda `(lambda ,@(cdr thing))
 430                                         :debug-name (debug-namify "#'~S"
 431                                                                   thing))))
 432            (setf (getf (functional-plist res) :fin-function) t)
 433            (reference-leaf start cont res)))
 434         (t
 435          (compiler-error "~S is not a legal function name." thing)))
 436       (let ((var (find-lexically-apparent-fun
 437                   thing "as the argument to FUNCTION")))
 438         (reference-leaf start cont var))))
 439
 440 ;;; `(NAMED-LAMBDA ,NAME ,@REST) is like `(FUNCTION (LAMBDA ,@REST)),
 441 ;;; except that the value of NAME is passed to the compiler for use in
 442 ;;; creation of debug information for the resulting function.
 443 ;;;
 444 ;;; NAME can be a legal function name or some arbitrary other thing.
 445 ;;;
 446 ;;; If NAME is a legal function name, then the caller should be
 447 ;;; planning to set (FDEFINITION NAME) to the created function.
 448 ;;; (Otherwise the debug names will be inconsistent and thus
 449 ;;; unnecessarily confusing.)
 450 ;;;
 451 ;;; Arbitrary other things are appropriate for naming things which are
 452 ;;; not the FDEFINITION of NAME. E.g.
 453 ;;;   NAME = (:FLET FOO BAR)
 454 ;;; for the FLET function in
 455 ;;;   (DEFUN BAR (X)
 456 ;;;     (FLET ((FOO (Y) (+ X Y)))
 457 ;;;       FOO))
 458 ;;; or
 459 ;;;   NAME = (:METHOD PRINT-OBJECT :AROUND (STARSHIP T))
 460 ;;; for the function used to implement
 461 ;;;   (DEFMETHOD PRINT-OBJECT :AROUND ((SS STARSHIP) STREAM) ...).
 462 (def-ir1-translator named-lambda ((name &rest rest) start cont)
 463   (reference-leaf start
 464                   cont
 465                   (if (legal-fun-name-p name)
 466                       (ir1-convert-lambda `(lambda ,@rest)
 467                                           :source-name name)
 468                       (ir1-convert-lambda `(lambda ,@rest)
 469                                           :debug-name name))))
 470 \f
 471 ;;;; FUNCALL
 472
 473 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 474 ;;; (not symbols). %FUNCALL is used directly in some places where the
 475 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 476 (deftransform funcall ((function &rest args) * * :when :both)
 477   (let ((arg-names (make-gensym-list (length args))))
 478     `(lambda (function ,@arg-names)
 479        (%funcall ,(if (csubtypep (continuation-type function)
 480                                  (specifier-type 'function))
 481                       'function
 482                       '(%coerce-callable-to-fun function))
 483                  ,@arg-names))))
 484
 485 (def-ir1-translator %funcall ((function &rest args) start cont)
 486   (let ((fun-cont (make-continuation)))
 487     (ir1-convert start fun-cont function)
 488     (assert-continuation-type fun-cont (specifier-type 'function))
 489     (ir1-convert-combination-args fun-cont cont args)))
 490
 491 ;;; This source transform exists to reduce the amount of work for the
 492 ;;; compiler. If the called function is a FUNCTION form, then convert
 493 ;;; directly to %FUNCALL, instead of waiting around for type
 494 ;;; inference.
 495 (define-source-transform funcall (function &rest args)
 496   (if (and (consp function) (eq (car function) 'function))
 497       `(%funcall ,function ,@args)
 498       (values nil t)))
 499
 500 (deftransform %coerce-callable-to-fun ((thing) (function) *
 501                                        :when :both
 502                                        :important t)
 503   "optimize away possible call to FDEFINITION at runtime"
 504   'thing)
 505 \f
 506 ;;;; LET and LET*
 507 ;;;;
 508 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 509 ;;;; any pervasive declarations also affect the evaluation of the
 510 ;;;; arguments.)
 511
 512 ;;; Given a list of binding specifiers in the style of Let, return:
 513 ;;;  1. The list of var structures for the variables bound.
 514 ;;;  2. The initial value form for each variable.
 515 ;;;
 516 ;;; The variable names are checked for legality and globally special
 517 ;;; variables are marked as such. Context is the name of the form, for
 518 ;;; error reporting purposes.
 519 (declaim (ftype (function (list symbol) (values list list list))
 520                 extract-let-vars))
 521 (defun extract-let-vars (bindings context)
 522   (collect ((vars)
 523             (vals)
 524             (names))
 525     (flet ((get-var (name)
 526              (varify-lambda-arg name
 527                                 (if (eq context 'let*)
 528                                     nil
 529                                     (names)))))
 530       (dolist (spec bindings)
 531         (cond ((atom spec)
 532                (let ((var (get-var spec)))
 533                  (vars var)
 534                  (names (cons spec var))
 535                  (vals nil)))
 536               (t
 537                (unless (proper-list-of-length-p spec 1 2)
 538                  (compiler-error "The ~S binding spec ~S is malformed."
 539                                  context
 540                                  spec))
 541                (let* ((name (first spec))
 542                       (var (get-var name)))
 543                  (vars var)
 544                  (names name)
 545                  (vals (second spec)))))))
 546
 547     (values (vars) (vals) (names))))
 548
 549 (def-ir1-translator let ((bindings &body body)
 550                          start cont)
 551   #!+sb-doc
 552   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 553   During evaluation of the Forms, bind the Vars to the result of evaluating the
 554   Value forms. The variables are bound in parallel after all of the Values are
 555   evaluated."
 556   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 557     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 558       (let* ((*lexenv* (process-decls decls vars nil cont))
 559              (fun-cont (make-continuation))
 560              (fun (ir1-convert-lambda-body
 561                    forms vars :debug-name (debug-namify "LET ~S" bindings))))
 562         (reference-leaf start fun-cont fun)
 563         (ir1-convert-combination-args fun-cont cont values)))))
 564
 565 (def-ir1-translator let* ((bindings &body body)
 566                           start cont)
 567   #!+sb-doc
 568   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 569   Similar to LET, but the variables are bound sequentially, allowing each Value
 570   form to reference any of the previous Vars."
 571   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 572     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 573       (let ((*lexenv* (process-decls decls vars nil cont)))
 574         (ir1-convert-aux-bindings start cont forms vars values)))))
 575
 576 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 577 ;;; and SYMBOL-MACROLET
 578 ;;;
 579 ;;; Note that all these things need to preserve toplevel-formness,
 580 ;;; but we don't need to worry about that within an IR1 translator,
 581 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 582 ;;; forms before we hit the IR1 transform level.
 583 (defun ir1-translate-locally (body start cont)
 584   (declare (type list body) (type continuation start cont))
 585   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 586     (let ((*lexenv* (process-decls decls nil nil cont)))
 587       (ir1-convert-aux-bindings start cont forms nil nil))))
 588
 589 (def-ir1-translator locally ((&body body) start cont)
 590   #!+sb-doc
 591   "LOCALLY Declaration* Form*
 592   Sequentially evaluate the Forms in a lexical environment where the
 593   the Declarations have effect. If LOCALLY is a top level form, then
 594   the Forms are also processed as top level forms."
 595   (ir1-translate-locally body start cont))
 596 \f
 597 ;;;; FLET and LABELS
 598
 599 ;;; Given a list of local function specifications in the style of
 600 ;;; FLET, return lists of the function names and of the lambdas which
 601 ;;; are their definitions.
 602 ;;;
 603 ;;; The function names are checked for legality. CONTEXT is the name
 604 ;;; of the form, for error reporting.
 605 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 606 (defun extract-flet-vars (definitions context)
 607   (collect ((names)
 608             (defs))
 609     (dolist (def definitions)
 610       (when (or (atom def) (< (length def) 2))
 611         (compiler-error "The ~S definition spec ~S is malformed." context def))
 612
 613       (let ((name (first def)))
 614         (check-fun-name name)
 615         (names name)
 616         (multiple-value-bind (forms decls) (sb!sys:parse-body (cddr def))
 617           (defs `(lambda ,(second def)
 618                    ,@decls
 619                    (block ,(fun-name-block-name name)
 620                      . ,forms))))))
 621     (values (names) (defs))))
 622
 623 (def-ir1-translator flet ((definitions &body body)
 624                           start cont)
 625   #!+sb-doc
 626   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 627   Evaluate the Body-Forms with some local function definitions. The bindings
 628   do not enclose the definitions; any use of Name in the Forms will refer to
 629   the lexically apparent function definition in the enclosing environment."
 630   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 631     (multiple-value-bind (names defs)
 632         (extract-flet-vars definitions 'flet)
 633       (let* ((fvars (mapcar (lambda (n d)
 634                               (ir1-convert-lambda d
 635                                                   :source-name n
 636                                                   :debug-name (debug-namify
 637                                                                "FLET ~S" n)))
 638                             names defs))
 639              (*lexenv* (make-lexenv
 640                         :default (process-decls decls nil fvars cont)
 641                         :funs (pairlis names fvars))))
 642         (ir1-convert-progn-body start cont forms)))))
 643
 644 (def-ir1-translator labels ((definitions &body body) start cont)
 645   #!+sb-doc
 646   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 647   Evaluate the Body-Forms with some local function definitions. The bindings
 648   enclose the new definitions, so the defined functions can call themselves or
 649   each other."
 650   (multiple-value-bind (forms decls) (sb!sys:parse-body body nil)
 651     (multiple-value-bind (names defs)
 652         (extract-flet-vars definitions 'labels)
 653       (let* (;; dummy LABELS functions, to be used as placeholders
 654              ;; during construction of real LABELS functions
 655              (placeholder-funs (mapcar (lambda (name)
 656                                          (make-functional
 657                                           :%source-name name
 658                                           :%debug-name (debug-namify
 659                                                         "LABELS placeholder ~S"
 660                                                         name)))
 661                                        names))
 662              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 663              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 664              ;; the real LABELS functions, compiled in a LEXENV which
 665              ;; includes the dummy LABELS functions
 666              (real-funs
 667               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 668                 (mapcar (lambda (name def)
 669                           (ir1-convert-lambda def
 670                                               :source-name name
 671                                               :debug-name (debug-namify
 672                                                            "LABELS ~S" name)))
 673                         names defs))))
 674
 675         ;; Modify all the references to the dummy function leaves so
 676         ;; that they point to the real function leaves.
 677         (loop for real-fun in real-funs and
 678               placeholder-cons in placeholder-fenv do
 679               (substitute-leaf real-fun (cdr placeholder-cons))
 680               (setf (cdr placeholder-cons) real-fun))
 681
 682         ;; Voila.
 683         (let ((*lexenv* (make-lexenv
 684                          :default (process-decls decls nil real-funs cont)
 685                          ;; Use a proper FENV here (not the
 686                          ;; placeholder used earlier) so that if the
 687                          ;; lexical environment is used for inline
 688                          ;; expansion we'll get the right functions.
 689                          :funs (pairlis names real-funs))))
 690           (ir1-convert-progn-body start cont forms))))))
 691 \f
 692 ;;;; the THE special operator, and friends
 693
 694 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 695 ;;; continuation that the assertion applies to, TYPE is the type
 696 ;;; specifier and LEXENV is the current lexical environment. NAME is
 697 ;;; the name of the declaration we are doing, for use in error
 698 ;;; messages.
 699 ;;;
 700 ;;; This is somewhat involved, since a type assertion may only be made
 701 ;;; on a continuation, not on a node. We can't just set the
 702 ;;; continuation asserted type and let it go at that, since there may
 703 ;;; be parallel THE's for the same continuation, i.e.
 704 ;;;     (if ...
 705 ;;;      (the foo ...)
 706 ;;;      (the bar ...))
 707 ;;;
 708 ;;; In this case, our representation can do no better than the union
 709 ;;; of these assertions. And if there is a branch with no assertion,
 710 ;;; we have nothing at all. We really need to recognize scoping, since
 711 ;;; we need to be able to discern between parallel assertions (which
 712 ;;; we union) and nested ones (which we intersect).
 713 ;;;
 714 ;;; We represent the scoping by throwing our innermost (intersected)
 715 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 716 ;;; intersect our assertions together. If CONT has no uses yet, we
 717 ;;; have not yet bottomed out on the first COND branch; in this case
 718 ;;; we optimistically assume that this type will be the one we end up
 719 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 720 ;;; than the type that we have the first time we bottom out. Later
 721 ;;; THE's (or the absence thereof) can only weaken this result.
 722 ;;;
 723 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 724 ;;; across COND branches. We can't do it here, since we don't know how
 725 ;;; many branches there are going to be.
 726 (defun ir1ize-the-or-values (type cont lexenv name)
 727   (declare (type continuation cont) (type lexenv lexenv))
 728   (let* ((ctype (values-specifier-type type))
 729          (old-type (or (lexenv-find cont type-restrictions)
 730                        *wild-type*))
 731          (intersects (values-types-equal-or-intersect old-type ctype))
 732          (int (values-type-intersection old-type ctype))
 733          (new (if intersects int old-type)))
 734     (when (null (find-uses cont))
 735       (setf (continuation-asserted-type cont) new))
 736     (when (and (not intersects)
 737                (not (policy *lexenv*
 738                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 739       (compiler-warn
 740        "The type ~S in ~S declaration conflicts with an ~
 741         enclosing assertion:~%   ~S"
 742        (type-specifier ctype)
 743        name
 744        (type-specifier old-type)))
 745     (make-lexenv :type-restrictions `((,cont . ,new))
 746                  :default lexenv)))
 747
 748 ;;; Assert that FORM evaluates to the specified type (which may be a
 749 ;;; VALUES type).
 750 ;;;
 751 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 752 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 753 ;;; values. Check that SBCL doesn't have this problem.
 754 (def-ir1-translator the ((type value) start cont)
 755   (let ((*lexenv* (ir1ize-the-or-values type cont *lexenv* 'the)))
 756     (ir1-convert start cont value)))
 757
 758 ;;; This is like the THE special form, except that it believes
 759 ;;; whatever you tell it. It will never generate a type check, but
 760 ;;; will cause a warning if the compiler can prove the assertion is
 761 ;;; wrong.
 762 ;;;
 763 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 764 ;;; its uses's types, setting it won't work. Instead we must intersect
 765 ;;; the type with the uses's DERIVED-TYPE.
 766 (def-ir1-translator truly-the ((type value) start cont)
 767   #!+sb-doc
 768   (declare (inline member))
 769   (let ((type (values-specifier-type type))
 770         (old (find-uses cont)))
 771     (ir1-convert start cont value)
 772     (do-uses (use cont)
 773       (unless (member use old :test #'eq)
 774         (derive-node-type use type)))))
 775 \f
 776 ;;;; SETQ
 777
 778 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 779 ;;; look at the global information. If the name is for a constant,
 780 ;;; then error out.
 781 (def-ir1-translator setq ((&whole source &rest things) start cont)
 782   (let ((len (length things)))
 783     (when (oddp len)
 784       (compiler-error "odd number of args to SETQ: ~S" source))
 785     (if (= len 2)
 786         (let* ((name (first things))
 787                (leaf (or (lexenv-find name vars)
 788                          (find-free-var name))))
 789           (etypecase leaf
 790             (leaf
 791              (when (constant-p leaf)
 792                (compiler-error "~S is a constant and thus can't be set." name))
 793              (when (lambda-var-p leaf)
 794                (let ((home-lambda (continuation-home-lambda-or-null start)))
 795                  (when home-lambda
 796                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 797                (when (lambda-var-ignorep leaf)
 798                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 799                  ;; requires that this be a STYLE-WARNING, not a full warning.
 800                  (compiler-style-warn
 801                   "~S is being set even though it was declared to be ignored."
 802                   name)))
 803              (setq-var start cont leaf (second things)))
 804             (cons
 805              (aver (eq (car leaf) 'MACRO))
 806              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 807             (heap-alien-info
 808              (ir1-convert start cont
 809                           `(%set-heap-alien ',leaf ,(second things))))))
 810         (collect ((sets))
 811           (do ((thing things (cddr thing)))
 812               ((endp thing)
 813                (ir1-convert-progn-body start cont (sets)))
 814             (sets `(setq ,(first thing) ,(second thing))))))))
 815
 816 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 817 ;;; This should only need to be called in SETQ.
 818 (defun setq-var (start cont var value)
 819   (declare (type continuation start cont) (type basic-var var))
 820   (let ((dest (make-continuation)))
 821     (setf (continuation-asserted-type dest) (leaf-type var))
 822     (ir1-convert start dest value)
 823     (let ((res (make-set :var var :value dest)))
 824       (setf (continuation-dest dest) res)
 825       (setf (leaf-ever-used var) t)
 826       (push res (basic-var-sets var))
 827       (link-node-to-previous-continuation res dest)
 828       (use-continuation res cont))))
 829 \f
 830 ;;;; CATCH, THROW and UNWIND-PROTECT
 831
 832 ;;; We turn THROW into a multiple-value-call of a magical function,
 833 ;;; since as as far as IR1 is concerned, it has no interesting
 834 ;;; properties other than receiving multiple-values.
 835 (def-ir1-translator throw ((tag result) start cont)
 836   #!+sb-doc
 837   "Throw Tag Form
 838   Do a non-local exit, return the values of Form from the CATCH whose tag
 839   evaluates to the same thing as Tag."
 840   (ir1-convert start cont
 841                `(multiple-value-call #'%throw ,tag ,result)))
 842
 843 ;;; This is a special special form used to instantiate a cleanup as
 844 ;;; the current cleanup within the body. KIND is the kind of cleanup
 845 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 846 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 847 ;;; and introduce the cleanup into the lexical environment. We
 848 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 849 ;;; cleanup, since this inner cleanup is the interesting one.
 850 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 851   (let ((dummy (make-continuation))
 852         (dummy2 (make-continuation)))
 853     (ir1-convert start dummy mess-up)
 854     (let* ((mess-node (continuation-use dummy))
 855            (cleanup (make-cleanup :kind kind
 856                                   :mess-up mess-node))
 857            (old-cup (lexenv-cleanup *lexenv*))
 858            (*lexenv* (make-lexenv :cleanup cleanup)))
 859       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 860       (ir1-convert dummy dummy2 '(%cleanup-point))
 861       (ir1-convert-progn-body dummy2 cont body))))
 862
 863 ;;; This is a special special form that makes an "escape function"
 864 ;;; which returns unknown values from named block. We convert the
 865 ;;; function, set its kind to :ESCAPE, and then reference it. The
 866 ;;; :ESCAPE kind indicates that this function's purpose is to
 867 ;;; represent a non-local control transfer, and that it might not
 868 ;;; actually have to be compiled.
 869 ;;;
 870 ;;; Note that environment analysis replaces references to escape
 871 ;;; functions with references to the corresponding NLX-INFO structure.
 872 (def-ir1-translator %escape-fun ((tag) start cont)
 873   (let ((fun (ir1-convert-lambda
 874               `(lambda ()
 875                  (return-from ,tag (%unknown-values)))
 876               :debug-name (debug-namify "escape function for ~S" tag))))
 877     (setf (functional-kind fun) :escape)
 878     (reference-leaf start cont fun)))
 879
 880 ;;; Yet another special special form. This one looks up a local
 881 ;;; function and smashes it to a :CLEANUP function, as well as
 882 ;;; referencing it.
 883 (def-ir1-translator %cleanup-fun ((name) start cont)
 884   (let ((fun (lexenv-find name funs)))
 885     (aver (lambda-p fun))
 886     (setf (functional-kind fun) :cleanup)
 887     (reference-leaf start cont fun)))
 888
 889 ;;; We represent the possibility of the control transfer by making an
 890 ;;; "escape function" that does a lexical exit, and instantiate the
 891 ;;; cleanup using %WITHIN-CLEANUP.
 892 (def-ir1-translator catch ((tag &body body) start cont)
 893   #!+sb-doc
 894   "Catch Tag Form*
 895   Evaluates Tag and instantiates it as a catcher while the body forms are
 896   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 897   scope of the body, then control will be transferred to the end of the body
 898   and the thrown values will be returned."
 899   (ir1-convert
 900    start cont
 901    (let ((exit-block (gensym "EXIT-BLOCK-")))
 902      `(block ,exit-block
 903         (%within-cleanup
 904             :catch
 905             (%catch (%escape-fun ,exit-block) ,tag)
 906           ,@body)))))
 907
 908 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 909 ;;; cleanup forms into a local function so that they can be referenced
 910 ;;; both in the case where we are unwound and in any local exits. We
 911 ;;; use %CLEANUP-FUN on this to indicate that reference by
 912 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 913 ;;; an XEP.
 914 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 915   #!+sb-doc
 916   "Unwind-Protect Protected Cleanup*
 917   Evaluate the form Protected, returning its values. The cleanup forms are
 918   evaluated whenever the dynamic scope of the Protected form is exited (either
 919   due to normal completion or a non-local exit such as THROW)."
 920   (ir1-convert
 921    start cont
 922    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 923          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 924          (exit-tag (gensym "EXIT-TAG-"))
 925          (next (gensym "NEXT"))
 926          (start (gensym "START"))
 927          (count (gensym "COUNT")))
 928      `(flet ((,cleanup-fun () ,@cleanup nil))
 929         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 930         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 931         ;; and something can be done to make %ESCAPE-FUN have
 932         ;; dynamic extent too.
 933         (block ,drop-thru-tag
 934           (multiple-value-bind (,next ,start ,count)
 935               (block ,exit-tag
 936                 (%within-cleanup
 937                     :unwind-protect
 938                     (%unwind-protect (%escape-fun ,exit-tag)
 939                                      (%cleanup-fun ,cleanup-fun))
 940                   (return-from ,drop-thru-tag ,protected)))
 941             (,cleanup-fun)
 942             (%continue-unwind ,next ,start ,count)))))))
 943 \f
 944 ;;;; multiple-value stuff
 945
 946 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 947 ;;; MV-COMBINATION.
 948 ;;;
 949 ;;; If there are no arguments, then we convert to a normal
 950 ;;; combination, ensuring that a MV-COMBINATION always has at least
 951 ;;; one argument. This can be regarded as an optimization, but it is
 952 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 953 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 954   #!+sb-doc
 955   "MULTIPLE-VALUE-CALL Function Values-Form*
 956   Call Function, passing all the values of each Values-Form as arguments,
 957   values from the first Values-Form making up the first argument, etc."
 958   (let* ((fun-cont (make-continuation))
 959          (node (if args
 960                    (make-mv-combination fun-cont)
 961                    (make-combination fun-cont))))
 962     (ir1-convert start fun-cont
 963                  (if (and (consp fun) (eq (car fun) 'function))
 964                      fun
 965                      `(%coerce-callable-to-fun ,fun)))
 966     (setf (continuation-dest fun-cont) node)
 967     (assert-continuation-type fun-cont
 968                               (specifier-type '(or function symbol)))
 969     (collect ((arg-conts))
 970       (let ((this-start fun-cont))
 971         (dolist (arg args)
 972           (let ((this-cont (make-continuation node)))
 973             (ir1-convert this-start this-cont arg)
 974             (setq this-start this-cont)
 975             (arg-conts this-cont)))
 976         (link-node-to-previous-continuation node this-start)
 977         (use-continuation node cont)
 978         (setf (basic-combination-args node) (arg-conts))))))
 979
 980 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 981 ;;; the result code use result continuation (CONT), but transfer
 982 ;;; control to the evaluation of the body. In other words, the result
 983 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 984 ;;; the result.
 985 ;;;
 986 ;;; In order to get the control flow right, we convert the result with
 987 ;;; a dummy result continuation, then convert all the uses of the
 988 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 989 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 990 ;;; that they are consistent. Note that this doesn't amount to
 991 ;;; changing the exit target, since the control destination of an exit
 992 ;;; is determined by the block successor; we are just indicating the
 993 ;;; continuation that the result is delivered to.
 994 ;;;
 995 ;;; We then convert the body, using another dummy continuation in its
 996 ;;; own block as the result. After we are done converting the body, we
 997 ;;; move all predecessors of the dummy end block to CONT's block.
 998 ;;;
 999 ;;; Note that we both exploit and maintain the invariant that the CONT
1000 ;;; to an IR1 convert method either has no block or starts the block
1001 ;;; that control should transfer to after completion for the form.
1002 ;;; Nested MV-PROG1's work because during conversion of the result
1003 ;;; form, we use dummy continuation whose block is the true control
1004 ;;; destination.
1005 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
1006   #!+sb-doc
1007   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1008   Evaluate Values-Form and then the Forms, but return all the values of
1009   Values-Form."
1010   (continuation-starts-block cont)
1011   (let* ((dummy-result (make-continuation))
1012          (dummy-start (make-continuation))
1013          (cont-block (continuation-block cont)))
1014     (continuation-starts-block dummy-start)
1015     (ir1-convert start dummy-start result)
1016
1017     (substitute-continuation-uses cont dummy-start)
1018
1019     (continuation-starts-block dummy-result)
1020     (ir1-convert-progn-body dummy-start dummy-result forms)
1021     (let ((end-block (continuation-block dummy-result)))
1022       (dolist (pred (block-pred end-block))
1023         (unlink-blocks pred end-block)
1024         (link-blocks pred cont-block))
1025       (aver (not (continuation-dest dummy-result)))
1026       (delete-continuation dummy-result)
1027       (remove-from-dfo end-block))))
1028 \f
1029 ;;;; interface to defining macros
1030
1031 ;;;; FIXME:
1032 ;;;;   classic CMU CL comment:
1033 ;;;;     DEFMACRO and DEFUN expand into calls to %DEFxxx functions
1034 ;;;;     so that we get a chance to see what is going on. We define
1035 ;;;;     IR1 translators for these functions which look at the
1036 ;;;;     definition and then generate a call to the %%DEFxxx function.
1037 ;;;; Alas, this implementation doesn't do the right thing for
1038 ;;;; non-toplevel uses of these forms, so this should probably
1039 ;;;; be changed to use EVAL-WHEN instead.
1040
1041 ;;; Return a new source path with any stuff intervening between the
1042 ;;; current path and the first form beginning with NAME stripped off.
1043 ;;; This is used to hide the guts of DEFmumble macros to prevent
1044 ;;; annoying error messages.
1045 (defun revert-source-path (name)
1046   (do ((path *current-path* (cdr path)))
1047       ((null path) *current-path*)
1048     (let ((first (first path)))
1049       (when (or (eq first name)
1050                 (eq first 'original-source-start))
1051         (return path)))))
1052
1053 ;;; Warn about incompatible or illegal definitions and add the macro
1054 ;;; to the compiler environment.
1055 ;;;
1056 ;;; Someday we could check for macro arguments being incompatibly
1057 ;;; redefined. Doing this right will involve finding the old macro
1058 ;;; lambda-list and comparing it with the new one.
1059 (def-ir1-translator %defmacro ((qname qdef lambda-list doc) start cont
1060                                :kind :function)
1061   (let (;; QNAME is typically a quoted name. I think the idea is to
1062         ;; let %DEFMACRO work as an ordinary function when
1063         ;; interpreting. Whatever the reason the quote is there, we
1064         ;; don't want it any more. -- WHN 19990603
1065         (name (eval qname))
1066         ;; QDEF should be a sharp-quoted definition. We don't want to
1067         ;; make a function of it just yet, so we just drop the
1068         ;; sharp-quote.
1069         (def (progn
1070                (aver (eq 'function (first qdef)))
1071                (aver (proper-list-of-length-p qdef 2))
1072                (second qdef))))
1073
1074     (/show "doing IR1 translator for %DEFMACRO" name)
1075
1076     (unless (symbolp name)
1077       (compiler-error "The macro name ~S is not a symbol." name))
1078
1079     (ecase (info :function :kind name)
1080       ((nil))
1081       (:function
1082        (remhash name *free-funs*)
1083        (undefine-fun-name name)
1084        (compiler-warn
1085         "~S is being redefined as a macro when it was ~
1086          previously ~(~A~) to be a function."
1087         name
1088         (info :function :where-from name)))
1089       (:macro)
1090       (:special-form
1091        (compiler-error "The special form ~S can't be redefined as a macro."
1092                        name)))
1093
1094     (setf (info :function :kind name) :macro
1095           (info :function :where-from name) :defined
1096           (info :function :macro-function name) (coerce def 'function))
1097
1098     (let* ((*current-path* (revert-source-path 'defmacro))
1099            (fun (ir1-convert-lambda def
1100                                     :debug-name (debug-namify "DEFMACRO ~S"
1101                                                               name))))
1102       (setf (functional-arg-documentation fun) (eval lambda-list))
1103
1104       (ir1-convert start cont `(%%defmacro ',name ,fun ,doc)))
1105
1106     (when sb!xc:*compile-print*
1107       ;; FIXME: It would be nice to convert this, and the other places
1108       ;; which create compiler diagnostic output prefixed by
1109       ;; semicolons, to use some common utility which automatically
1110       ;; prefixes all its output with semicolons. (The addition of
1111       ;; semicolon prefixes was introduced ca. sbcl-0.6.8.10 as the
1112       ;; "MNA compiler message patch", and implemented by modifying a
1113       ;; bunch of output statements on a case-by-case basis, which
1114       ;; seems unnecessarily error-prone and unclear, scattering
1115       ;; implicit information about output style throughout the
1116       ;; system.) Starting by rewriting COMPILER-MUMBLE to add
1117       ;; semicolon prefixes would be a good start, and perhaps also:
1118       ;;   * Add semicolon prefixes for "FOO assembled" messages emitted
1119       ;;     when e.g. src/assembly/x86/assem-rtns.lisp is processed.
1120       ;;   * At least some debugger output messages deserve semicolon
1121       ;;     prefixes too:
1122       ;;     ** restarts table
1123       ;;     ** "Within the debugger, you can type HELP for help."
1124       (compiler-mumble "~&; converted ~S~%" name))))
1125
1126 (def-ir1-translator %define-compiler-macro ((name def lambda-list doc)
1127                                             start cont
1128                                             :kind :function)
1129   (let ((name (eval name))
1130         (def (second def))) ; We don't want to make a function just yet...
1131
1132     (when (eq (info :function :kind name) :special-form)
1133       (compiler-error "attempt to define a compiler-macro for special form ~S"
1134                       name))
1135
1136     (setf (info :function :compiler-macro-function name)
1137           (coerce def 'function))
1138
1139     (let* ((*current-path* (revert-source-path 'define-compiler-macro))
1140            (fun (ir1-convert-lambda def
1141                                     :debug-name (debug-namify
1142                                                  "DEFINE-COMPILER-MACRO ~S"
1143                                                  name))))
1144       (setf (functional-arg-documentation fun) (eval lambda-list))
1145
1146       (ir1-convert start cont `(%%define-compiler-macro ',name ,fun ,doc)))
1147
1148     (when sb!xc:*compile-print*
1149       (compiler-mumble "~&; converted ~S~%" name))))