0.8.16.37: fixed #351
[sbcl.git] / src / compiler / ir1-translators.lisp
1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
2 ;;;; close personal friends)
3
4 ;;;; This software is part of the SBCL system. See the README file for
5 ;;;; more information.
6 ;;;;
7 ;;;; This software is derived from the CMU CL system, which was
8 ;;;; written at Carnegie Mellon University and released into the
9 ;;;; public domain. The software is in the public domain and is
10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
11 ;;;; files for more information.
12
13 (in-package "SB!C")
14 \f
15 ;;;; special forms for control
16
17 (def-ir1-translator progn ((&rest forms) start next result)
18   #!+sb-doc
19   "Progn Form*
20   Evaluates each Form in order, returning the values of the last form. With no
21   forms, returns NIL."
22   (ir1-convert-progn-body start next result forms))
23
24 (def-ir1-translator if ((test then &optional else) start next result)
25   #!+sb-doc
26   "If Predicate Then [Else]
27   If Predicate evaluates to non-null, evaluate Then and returns its values,
28   otherwise evaluate Else and return its values. Else defaults to NIL."
29   (let* ((pred-ctran (make-ctran))
30          (pred-lvar (make-lvar))
31          (then-ctran (make-ctran))
32          (then-block (ctran-starts-block then-ctran))
33          (else-ctran (make-ctran))
34          (else-block (ctran-starts-block else-ctran))
35          (node (make-if :test pred-lvar
36                         :consequent then-block
37                         :alternative else-block)))
38     ;; IR1-CONVERT-MAYBE-PREDICATE requires DEST to be CIF, so the
39     ;; order of the following two forms is important
40     (setf (lvar-dest pred-lvar) node)
41     (ir1-convert start pred-ctran pred-lvar test)
42     (link-node-to-previous-ctran node pred-ctran)
43
44     (let ((start-block (ctran-block pred-ctran)))
45       (setf (block-last start-block) node)
46       (ctran-starts-block next)
47
48       (link-blocks start-block then-block)
49       (link-blocks start-block else-block))
50
51     (ir1-convert then-ctran next result then)
52     (ir1-convert else-ctran next result else)))
53 \f
54 ;;;; BLOCK and TAGBODY
55
56 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
57 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
58 ;;;; node.
59
60 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
61 ;;; body in the modified environment. We make NEXT start a block now,
62 ;;; since if it was done later, the block would be in the wrong
63 ;;; environment.
64 (def-ir1-translator block ((name &rest forms) start next result)
65   #!+sb-doc
66   "Block Name Form*
67   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
68   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
69   result of Value-Form."
70   (unless (symbolp name)
71     (compiler-error "The block name ~S is not a symbol." name))
72   (start-block start)
73   (ctran-starts-block next)
74   (let* ((dummy (make-ctran))
75          (entry (make-entry))
76          (cleanup (make-cleanup :kind :block
77                                 :mess-up entry)))
78     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
79     (setf (entry-cleanup entry) cleanup)
80     (link-node-to-previous-ctran entry start)
81     (use-ctran entry dummy)
82
83     (let* ((env-entry (list entry next result))
84            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
85                                   :cleanup cleanup)))
86       (ir1-convert-progn-body dummy next result forms))))
87
88 (def-ir1-translator return-from ((name &optional value) start next result)
89   #!+sb-doc
90   "Return-From Block-Name Value-Form
91   Evaluate the Value-Form, returning its values from the lexically enclosing
92   BLOCK Block-Name. This is constrained to be used only within the dynamic
93   extent of the BLOCK."
94   ;; old comment:
95   ;;   We make NEXT start a block just so that it will have a block
96   ;;   assigned. People assume that when they pass a ctran into
97   ;;   IR1-CONVERT as NEXT, it will have a block when it is done.
98   ;; KLUDGE: Note that this block is basically fictitious. In the code
99   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
100   ;; it's the block which answers the question "which block is
101   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
102   ;; dead code and so doesn't really have a block at all. The existence
103   ;; of this block, and that way that it doesn't explicitly say
104   ;; "I'm actually nowhere at all" makes some logic (e.g.
105   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
106   ;; to get rid of it, perhaps using a special placeholder value
107   ;; to indicate the orphanedness of the code.
108   (declare (ignore result))
109   (ctran-starts-block next)
110   (let* ((found (or (lexenv-find name blocks)
111                     (compiler-error "return for unknown block: ~S" name)))
112          (value-ctran (make-ctran))
113          (value-lvar (make-lvar))
114          (entry (first found))
115          (exit (make-exit :entry entry
116                           :value value-lvar)))
117     (push exit (entry-exits entry))
118     (setf (lvar-dest value-lvar) exit)
119     (ir1-convert start value-ctran value-lvar value)
120     (link-node-to-previous-ctran exit value-ctran)
121     (let ((home-lambda (ctran-home-lambda-or-null start)))
122       (when home-lambda
123         (push entry (lambda-calls-or-closes home-lambda))))
124     (use-continuation exit (second found) (third found))))
125
126 ;;; Return a list of the segments of a TAGBODY. Each segment looks
127 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
128 ;;; tagbody into segments of non-tag statements, and explicitly
129 ;;; represent the drop-through with a GO. The first segment has a
130 ;;; dummy NIL tag, since it represents code before the first tag. The
131 ;;; last segment (which may also be the first segment) ends in NIL
132 ;;; rather than a GO.
133 (defun parse-tagbody (body)
134   (declare (list body))
135   (collect ((segments))
136     (let ((current (cons nil body)))
137       (loop
138         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
139           (unless tag-pos
140             (segments `(,@current nil))
141             (return))
142           (let ((tag (elt current tag-pos)))
143             (when (assoc tag (segments))
144               (compiler-error
145                "The tag ~S appears more than once in the tagbody."
146                tag))
147             (unless (or (symbolp tag) (integerp tag))
148               (compiler-error "~S is not a legal tagbody statement." tag))
149             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
150           (setq current (nthcdr tag-pos current)))))
151     (segments)))
152
153 ;;; Set up the cleanup, emitting the entry node. Then make a block for
154 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
155 ;;; Finally, convert each segment with the precomputed Start and Cont
156 ;;; values.
157 (def-ir1-translator tagbody ((&rest statements) start next result)
158   #!+sb-doc
159   "Tagbody {Tag | Statement}*
160   Define tags for used with GO. The Statements are evaluated in order
161   (skipping Tags) and NIL is returned. If a statement contains a GO to a
162   defined Tag within the lexical scope of the form, then control is transferred
163   to the next statement following that tag. A Tag must an integer or a
164   symbol. A statement must be a list. Other objects are illegal within the
165   body."
166   (start-block start)
167   (ctran-starts-block next)
168   (let* ((dummy (make-ctran))
169          (entry (make-entry))
170          (segments (parse-tagbody statements))
171          (cleanup (make-cleanup :kind :tagbody
172                                 :mess-up entry)))
173     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
174     (setf (entry-cleanup entry) cleanup)
175     (link-node-to-previous-ctran entry start)
176     (use-ctran entry dummy)
177
178     (collect ((tags)
179               (starts)
180               (ctrans))
181       (starts dummy)
182       (dolist (segment (rest segments))
183         (let* ((tag-ctran (make-ctran))
184                (tag (list (car segment) entry tag-ctran)))
185           (ctrans tag-ctran)
186           (starts tag-ctran)
187           (ctran-starts-block tag-ctran)
188           (tags tag)))
189       (ctrans next)
190
191       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
192         (mapc (lambda (segment start end)
193                 (ir1-convert-progn-body start end
194                                         (when (eq end next) result)
195                                         (rest segment)))
196               segments (starts) (ctrans))))))
197
198 ;;; Emit an EXIT node without any value.
199 (def-ir1-translator go ((tag) start next result)
200   #!+sb-doc
201   "Go Tag
202   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
203   is constrained to be used only within the dynamic extent of the TAGBODY."
204   (ctran-starts-block next)
205   (let* ((found (or (lexenv-find tag tags :test #'eql)
206                     (compiler-error "attempt to GO to nonexistent tag: ~S"
207                                     tag)))
208          (entry (first found))
209          (exit (make-exit :entry entry)))
210     (push exit (entry-exits entry))
211     (link-node-to-previous-ctran exit start)
212     (let ((home-lambda (ctran-home-lambda-or-null start)))
213       (when home-lambda
214         (push entry (lambda-calls-or-closes home-lambda))))
215     (use-ctran exit (second found))))
216 \f
217 ;;;; translators for compiler-magic special forms
218
219 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
220 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
221 ;;; so that they're never seen at this level.)
222 ;;;
223 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
224 ;;; of non-top-level EVAL-WHENs is very simple:
225 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
226 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
227 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
228 ;;;   eval-when specifying the :EXECUTE situation is treated as an
229 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
230 ;;;   form; otherwise, the forms in the body are ignored.
231 (def-ir1-translator eval-when ((situations &rest forms) start next result)
232   #!+sb-doc
233   "EVAL-WHEN (Situation*) Form*
234   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
235   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
236   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
237     (declare (ignore ct lt))
238     (ir1-convert-progn-body start next result (and e forms)))
239   (values))
240
241 ;;; common logic for MACROLET and SYMBOL-MACROLET
242 ;;;
243 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
244 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
245 ;;; call FUN (with no arguments).
246 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
247                                        definitionize-keyword
248                                        definitions
249                                        fun)
250   (declare (type function definitionize-fun fun))
251   (declare (type (member :vars :funs) definitionize-keyword))
252   (declare (type list definitions))
253   (unless (= (length definitions)
254              (length (remove-duplicates definitions :key #'first)))
255     (compiler-style-warn "duplicate definitions in ~S" definitions))
256   (let* ((processed-definitions (mapcar definitionize-fun definitions))
257          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
258     ;; I wonder how much of an compiler performance penalty this
259     ;; non-constant keyword is.
260     (funcall fun definitionize-keyword processed-definitions)))
261
262 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
263 ;;; call FUN (with no arguments).
264 ;;;
265 ;;; This is split off from the IR1 convert method so that it can be
266 ;;; shared by the special-case top level MACROLET processing code, and
267 ;;; further split so that the special-case MACROLET processing code in
268 ;;; EVAL can likewise make use of it.
269 (defun macrolet-definitionize-fun (context lexenv)
270   (flet ((fail (control &rest args)
271            (ecase context
272              (:compile (apply #'compiler-error control args))
273              (:eval (error 'simple-program-error
274                            :format-control control
275                            :format-arguments args)))))
276     (lambda (definition)
277       (unless (list-of-length-at-least-p definition 2)
278         (fail "The list ~S is too short to be a legal local macro definition."
279               definition))
280       (destructuring-bind (name arglist &body body) definition
281         (unless (symbolp name)
282           (fail "The local macro name ~S is not a symbol." name))
283         (when (fboundp name)
284           (compiler-assert-symbol-home-package-unlocked
285            name "binding ~A as a local macro"))
286         (unless (listp arglist)
287           (fail "The local macro argument list ~S is not a list."
288                 arglist))
289         (with-unique-names (whole environment)
290           (multiple-value-bind (body local-decls)
291               (parse-defmacro arglist whole body name 'macrolet
292                               :environment environment)
293             `(,name macro .
294                     ,(compile-in-lexenv
295                       nil
296                       `(lambda (,whole ,environment)
297                          ,@local-decls
298                          ,body)
299                       lexenv))))))))
300
301 (defun funcall-in-macrolet-lexenv (definitions fun context)
302   (%funcall-in-foomacrolet-lexenv
303    (macrolet-definitionize-fun context (make-restricted-lexenv *lexenv*))
304    :funs
305    definitions
306    fun))
307
308 (def-ir1-translator macrolet ((definitions &rest body) start next result)
309   #!+sb-doc
310   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
311   Evaluate the Body-Forms in an environment with the specified local macros
312   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
313   destructuring lambda list, and the Forms evaluate to the expansion.."
314   (funcall-in-macrolet-lexenv
315    definitions
316    (lambda (&key funs)
317      (declare (ignore funs))
318      (ir1-translate-locally body start next result))
319    :compile))
320
321 (defun symbol-macrolet-definitionize-fun (context)
322   (flet ((fail (control &rest args)
323            (ecase context
324              (:compile (apply #'compiler-error control args))
325              (:eval (error 'simple-program-error
326                            :format-control control
327                            :format-arguments args)))))
328     (lambda (definition)
329       (unless (proper-list-of-length-p definition 2)
330         (fail "malformed symbol/expansion pair: ~S" definition))
331       (destructuring-bind (name expansion) definition
332         (unless (symbolp name)
333           (fail "The local symbol macro name ~S is not a symbol." name))
334         (when (or (boundp name) (eq (info :variable :kind name) :macro))
335           (compiler-assert-symbol-home-package-unlocked
336            name "binding ~A as a local symbol-macro"))
337         (let ((kind (info :variable :kind name)))
338           (when (member kind '(:special :constant))
339             (fail "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
340                   kind name)))
341         ;; A magical cons that MACROEXPAND-1 understands.
342         `(,name . (MACRO . ,expansion))))))
343
344 (defun funcall-in-symbol-macrolet-lexenv (definitions fun context)
345   (%funcall-in-foomacrolet-lexenv
346    (symbol-macrolet-definitionize-fun context)
347    :vars
348    definitions
349    fun))
350
351 (def-ir1-translator symbol-macrolet
352     ((macrobindings &body body) start next result)
353   #!+sb-doc
354   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
355   Define the Names as symbol macros with the given Expansions. Within the
356   body, references to a Name will effectively be replaced with the Expansion."
357   (funcall-in-symbol-macrolet-lexenv
358    macrobindings
359    (lambda (&key vars)
360      (ir1-translate-locally body start next result :vars vars))
361    :compile))
362 \f
363 ;;;; %PRIMITIVE
364 ;;;;
365 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
366 ;;;; into a funny function.
367
368 ;;; Carefully evaluate a list of forms, returning a list of the results.
369 (defun eval-info-args (args)
370   (declare (list args))
371   (handler-case (mapcar #'eval args)
372     (error (condition)
373       (compiler-error "Lisp error during evaluation of info args:~%~A"
374                       condition))))
375
376 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
377 ;;; the template, the second is a list of the results of any
378 ;;; codegen-info args, and the remaining arguments are the runtime
379 ;;; arguments.
380 ;;;
381 ;;; We do various error checking now so that we don't bomb out with
382 ;;; a fatal error during IR2 conversion.
383 ;;;
384 ;;; KLUDGE: It's confusing having multiple names floating around for
385 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
386 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
387 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
388 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
389 ;;; VOP or %VOP.. -- WHN 2001-06-11
390 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
391 (def-ir1-translator %primitive ((name &rest args) start next result)
392   (declare (type symbol name))
393   (let* ((template (or (gethash name *backend-template-names*)
394                        (bug "undefined primitive ~A" name)))
395          (required (length (template-arg-types template)))
396          (info (template-info-arg-count template))
397          (min (+ required info))
398          (nargs (length args)))
399     (if (template-more-args-type template)
400         (when (< nargs min)
401           (bug "Primitive ~A was called with ~R argument~:P, ~
402                 but wants at least ~R."
403                name
404                nargs
405                min))
406         (unless (= nargs min)
407           (bug "Primitive ~A was called with ~R argument~:P, ~
408                 but wants exactly ~R."
409                name
410                nargs
411                min)))
412
413     (when (eq (template-result-types template) :conditional)
414       (bug "%PRIMITIVE was used with a conditional template."))
415
416     (when (template-more-results-type template)
417       (bug "%PRIMITIVE was used with an unknown values template."))
418
419     (ir1-convert start next result
420                  `(%%primitive ',template
421                                ',(eval-info-args
422                                   (subseq args required min))
423                                ,@(subseq args 0 required)
424                                ,@(subseq args min)))))
425 \f
426 ;;;; QUOTE
427
428 (def-ir1-translator quote ((thing) start next result)
429   #!+sb-doc
430   "QUOTE Value
431   Return Value without evaluating it."
432   (reference-constant start next result thing))
433 \f
434 ;;;; FUNCTION and NAMED-LAMBDA
435 (defun fun-name-leaf (thing)
436   (if (consp thing)
437       (cond
438         ((member (car thing)
439                  '(lambda named-lambda instance-lambda lambda-with-lexenv))
440          (ir1-convert-lambdalike
441                           thing
442                           :debug-name (debug-namify "#'" thing)))
443         ((legal-fun-name-p thing)
444          (find-lexically-apparent-fun
445                      thing "as the argument to FUNCTION"))
446         (t
447          (compiler-error "~S is not a legal function name." thing)))
448       (find-lexically-apparent-fun
449        thing "as the argument to FUNCTION")))
450
451 (def-ir1-translator function ((thing) start next result)
452   #!+sb-doc
453   "FUNCTION Name
454   Return the lexically apparent definition of the function Name. Name may also
455   be a lambda expression."
456   (reference-leaf start next result (fun-name-leaf thing)))
457 \f
458 ;;;; FUNCALL
459
460 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
461 ;;; (not symbols). %FUNCALL is used directly in some places where the
462 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
463 (deftransform funcall ((function &rest args) * *)
464   (let ((arg-names (make-gensym-list (length args))))
465     `(lambda (function ,@arg-names)
466        (%funcall ,(if (csubtypep (lvar-type function)
467                                  (specifier-type 'function))
468                       'function
469                       '(%coerce-callable-to-fun function))
470                  ,@arg-names))))
471
472 (def-ir1-translator %funcall ((function &rest args) start next result)
473   (if (and (consp function) (eq (car function) 'function))
474       (ir1-convert start next result
475                    `(,(fun-name-leaf (second function)) ,@args))
476       (let ((ctran (make-ctran))
477             (fun-lvar (make-lvar)))
478         (ir1-convert start ctran fun-lvar `(the function ,function))
479         (ir1-convert-combination-args fun-lvar ctran next result args))))
480
481 ;;; This source transform exists to reduce the amount of work for the
482 ;;; compiler. If the called function is a FUNCTION form, then convert
483 ;;; directly to %FUNCALL, instead of waiting around for type
484 ;;; inference.
485 (define-source-transform funcall (function &rest args)
486   (if (and (consp function) (eq (car function) 'function))
487       `(%funcall ,function ,@args)
488       (values nil t)))
489
490 (deftransform %coerce-callable-to-fun ((thing) (function) *)
491   "optimize away possible call to FDEFINITION at runtime"
492   'thing)
493 \f
494 ;;;; LET and LET*
495 ;;;;
496 ;;;; (LET and LET* can't be implemented as macros due to the fact that
497 ;;;; any pervasive declarations also affect the evaluation of the
498 ;;;; arguments.)
499
500 ;;; Given a list of binding specifiers in the style of LET, return:
501 ;;;  1. The list of var structures for the variables bound.
502 ;;;  2. The initial value form for each variable.
503 ;;;
504 ;;; The variable names are checked for legality and globally special
505 ;;; variables are marked as such. Context is the name of the form, for
506 ;;; error reporting purposes.
507 (declaim (ftype (function (list symbol) (values list list))
508                 extract-let-vars))
509 (defun extract-let-vars (bindings context)
510   (collect ((vars)
511             (vals)
512             (names))
513     (flet ((get-var (name)
514              (varify-lambda-arg name
515                                 (if (eq context 'let*)
516                                     nil
517                                     (names)))))
518       (dolist (spec bindings)
519         (cond ((atom spec)
520                (let ((var (get-var spec)))
521                  (vars var)
522                  (names spec)
523                  (vals nil)))
524               (t
525                (unless (proper-list-of-length-p spec 1 2)
526                  (compiler-error "The ~S binding spec ~S is malformed."
527                                  context
528                                  spec))
529                (let* ((name (first spec))
530                       (var (get-var name)))
531                  (vars var)
532                  (names name)
533                  (vals (second spec)))))))
534     (dolist (name (names))
535       (when (eq (info :variable :kind name) :macro)
536         (compiler-assert-symbol-home-package-unlocked
537          name "lexically binding symbol-macro ~A")))
538     (values (vars) (vals))))
539
540 (def-ir1-translator let ((bindings &body body) start next result)
541   #!+sb-doc
542   "LET ({(Var [Value]) | Var}*) Declaration* Form*
543   During evaluation of the Forms, bind the Vars to the result of evaluating the
544   Value forms. The variables are bound in parallel after all of the Values are
545   evaluated."
546   (cond ((null bindings)
547          (ir1-translate-locally body start next result))
548         ((listp bindings)
549          (multiple-value-bind (forms decls)
550              (parse-body body :doc-string-allowed nil)
551            (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
552              (binding* ((ctran (make-ctran))
553                         (fun-lvar (make-lvar))
554                         ((next result)
555                          (processing-decls (decls vars nil next result)
556                                            (let ((fun (ir1-convert-lambda-body
557                                                        forms
558                                                        vars
559                                                        :debug-name (debug-namify "LET S"
560                                                                                  bindings))))
561                                              (reference-leaf start ctran fun-lvar fun))
562                                            (values next result))))
563                        (ir1-convert-combination-args fun-lvar ctran next result values)))))
564         (t
565          (compiler-error "Malformed LET bindings: ~S." bindings))))
566
567 (def-ir1-translator let* ((bindings &body body)
568                           start next result)
569   #!+sb-doc
570   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
571   Similar to LET, but the variables are bound sequentially, allowing each Value
572   form to reference any of the previous Vars."
573   (if (listp bindings)
574       (multiple-value-bind (forms decls)
575           (parse-body body :doc-string-allowed nil)
576         (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
577           (processing-decls (decls vars nil start next)
578                             (ir1-convert-aux-bindings start 
579                                                       next 
580                                                       result
581                                                       forms
582                                                       vars 
583                                                       values))))
584       (compiler-error "Malformed LET* bindings: ~S." bindings)))
585   
586 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
587 ;;; and SYMBOL-MACROLET
588 ;;;
589 ;;; Note that all these things need to preserve toplevel-formness,
590 ;;; but we don't need to worry about that within an IR1 translator,
591 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
592 ;;; forms before we hit the IR1 transform level.
593 (defun ir1-translate-locally (body start next result &key vars funs)
594   (declare (type ctran start next) (type (or lvar null) result)
595            (type list body))
596   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
597     (processing-decls (decls vars funs next result)
598       (ir1-convert-progn-body start next result forms))))
599
600 (def-ir1-translator locally ((&body body) start next result)
601   #!+sb-doc
602   "LOCALLY Declaration* Form*
603   Sequentially evaluate the Forms in a lexical environment where the
604   the Declarations have effect. If LOCALLY is a top level form, then
605   the Forms are also processed as top level forms."
606   (ir1-translate-locally body start next result))
607 \f
608 ;;;; FLET and LABELS
609
610 ;;; Given a list of local function specifications in the style of
611 ;;; FLET, return lists of the function names and of the lambdas which
612 ;;; are their definitions.
613 ;;;
614 ;;; The function names are checked for legality. CONTEXT is the name
615 ;;; of the form, for error reporting.
616 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
617 (defun extract-flet-vars (definitions context)
618   (collect ((names)
619             (defs))
620     (dolist (def definitions)
621       (when (or (atom def) (< (length def) 2))
622         (compiler-error "The ~S definition spec ~S is malformed." context def))
623
624       (let ((name (first def)))
625         (check-fun-name name)
626         (when (fboundp name)
627           (compiler-assert-symbol-home-package-unlocked
628            name "binding ~A as a local function"))
629         (names name)
630         (multiple-value-bind (forms decls) (parse-body (cddr def))
631           (defs `(lambda ,(second def)
632                    ,@decls
633                    (block ,(fun-name-block-name name)
634                      . ,forms))))))
635     (values (names) (defs))))
636
637 (def-ir1-translator flet ((definitions &body body)
638                           start next result)
639   #!+sb-doc
640   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
641   Evaluate the Body-Forms with some local function definitions. The bindings
642   do not enclose the definitions; any use of Name in the Forms will refer to
643   the lexically apparent function definition in the enclosing environment."
644   (multiple-value-bind (forms decls)
645       (parse-body body :doc-string-allowed nil)
646     (multiple-value-bind (names defs)
647         (extract-flet-vars definitions 'flet)
648       (let ((fvars (mapcar (lambda (n d)
649                              (ir1-convert-lambda d
650                                                  :source-name n
651                                                  :debug-name (debug-namify
652                                                               "FLET " n)))
653                            names defs)))
654         (processing-decls (decls nil fvars next result)
655           (let ((*lexenv* (make-lexenv :funs (pairlis names fvars))))
656             (ir1-convert-progn-body start 
657                                     next 
658                                     result
659                                     forms)))))))
660
661 (def-ir1-translator labels ((definitions &body body) start next result)
662   #!+sb-doc
663   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
664   Evaluate the Body-Forms with some local function definitions. The bindings
665   enclose the new definitions, so the defined functions can call themselves or
666   each other."
667   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
668     (multiple-value-bind (names defs)
669         (extract-flet-vars definitions 'labels)
670       (let* (;; dummy LABELS functions, to be used as placeholders
671              ;; during construction of real LABELS functions
672              (placeholder-funs (mapcar (lambda (name)
673                                          (make-functional
674                                           :%source-name name
675                                           :%debug-name (debug-namify
676                                                         "LABELS placeholder "
677                                                         name)))
678                                        names))
679              ;; (like PAIRLIS but guaranteed to preserve ordering:)
680              (placeholder-fenv (mapcar #'cons names placeholder-funs))
681              ;; the real LABELS functions, compiled in a LEXENV which
682              ;; includes the dummy LABELS functions
683              (real-funs
684               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
685                 (mapcar (lambda (name def)
686                           (ir1-convert-lambda def
687                                               :source-name name
688                                               :debug-name (debug-namify
689                                                            "LABELS " name)))
690                         names defs))))
691         
692         ;; Modify all the references to the dummy function leaves so
693         ;; that they point to the real function leaves.
694         (loop for real-fun in real-funs and
695               placeholder-cons in placeholder-fenv do
696               (substitute-leaf real-fun (cdr placeholder-cons))
697               (setf (cdr placeholder-cons) real-fun))
698         
699         ;; Voila.
700         (processing-decls (decls nil real-funs next result)
701           (let ((*lexenv* (make-lexenv
702                            ;; Use a proper FENV here (not the
703                            ;; placeholder used earlier) so that if the
704                            ;; lexical environment is used for inline
705                            ;; expansion we'll get the right functions.
706                            :funs (pairlis names real-funs))))
707             (ir1-convert-progn-body start 
708                                     next 
709                                     result
710                                     forms)))))))
711
712 \f
713 ;;;; the THE special operator, and friends
714
715 ;;; A logic shared among THE and TRULY-THE.
716 (defun the-in-policy (type value policy start next result)
717   (let ((type (if (ctype-p type) type
718                    (compiler-values-specifier-type type))))
719     (cond ((or (eq type *wild-type*)
720                (eq type *universal-type*)
721                (and (leaf-p value)
722                     (values-subtypep (make-single-value-type (leaf-type value))
723                                      type))
724                (and (sb!xc:constantp value)
725                     (ctypep (constant-form-value value)
726                             (single-value-type type))))
727            (ir1-convert start next result value))
728           (t (let ((value-ctran (make-ctran))
729                    (value-lvar (make-lvar)))
730                (ir1-convert start value-ctran value-lvar value)
731                (let ((cast (make-cast value-lvar type policy)))
732                  (link-node-to-previous-ctran cast value-ctran)
733                  (setf (lvar-dest value-lvar) cast)
734                  (use-continuation cast next result)))))))
735
736 ;;; Assert that FORM evaluates to the specified type (which may be a
737 ;;; VALUES type). TYPE may be a type specifier or (as a hack) a CTYPE.
738 (def-ir1-translator the ((type value) start next result)
739   (the-in-policy type value (lexenv-policy *lexenv*) start next result))
740
741 ;;; This is like the THE special form, except that it believes
742 ;;; whatever you tell it. It will never generate a type check, but
743 ;;; will cause a warning if the compiler can prove the assertion is
744 ;;; wrong.
745 (def-ir1-translator truly-the ((type value) start next result)
746   #!+sb-doc
747   ""
748   #-nil
749   (let ((type (coerce-to-values (compiler-values-specifier-type type)))
750         (old (when result (find-uses result))))
751     (ir1-convert start next result value)
752     (when result
753       (do-uses (use result)
754         (unless (memq use old)
755           (derive-node-type use type)))))
756   #+nil
757   (the-in-policy type value '((type-check . 0)) start cont))
758 \f
759 ;;;; SETQ
760
761 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
762 ;;; look at the global information. If the name is for a constant,
763 ;;; then error out.
764 (def-ir1-translator setq ((&whole source &rest things) start next result)
765   (let ((len (length things)))
766     (when (oddp len)
767       (compiler-error "odd number of args to SETQ: ~S" source))
768     (if (= len 2)
769         (let* ((name (first things))
770                (leaf (or (lexenv-find name vars)
771                          (find-free-var name))))
772           (etypecase leaf
773             (leaf
774              (when (constant-p leaf)
775                (compiler-error "~S is a constant and thus can't be set." name))
776              (when (lambda-var-p leaf)
777                (let ((home-lambda (ctran-home-lambda-or-null start)))
778                  (when home-lambda
779                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
780                (when (lambda-var-ignorep leaf)
781                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
782                  ;; requires that this be a STYLE-WARNING, not a full warning.
783                  (compiler-style-warn
784                   "~S is being set even though it was declared to be ignored."
785                   name)))
786              (setq-var start next result leaf (second things)))
787             (cons
788              (aver (eq (car leaf) 'MACRO))
789              ;; FIXME: [Free] type declaration. -- APD, 2002-01-26
790              (ir1-convert start next result
791                           `(setf ,(cdr leaf) ,(second things))))
792             (heap-alien-info
793              (ir1-convert start next result
794                           `(%set-heap-alien ',leaf ,(second things))))))
795         (collect ((sets))
796           (do ((thing things (cddr thing)))
797               ((endp thing)
798                (ir1-convert-progn-body start next result (sets)))
799             (sets `(setq ,(first thing) ,(second thing))))))))
800
801 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
802 ;;; This should only need to be called in SETQ.
803 (defun setq-var (start next result var value)
804   (declare (type ctran start next) (type (or lvar null) result)
805            (type basic-var var))
806   (let ((dest-ctran (make-ctran))
807         (dest-lvar (make-lvar))
808         (type (or (lexenv-find var type-restrictions)
809                   (leaf-type var))))
810     (ir1-convert start dest-ctran dest-lvar `(the ,type ,value))
811     (let ((res (make-set :var var :value dest-lvar)))
812       (setf (lvar-dest dest-lvar) res)
813       (setf (leaf-ever-used var) t)
814       (push res (basic-var-sets var))
815       (link-node-to-previous-ctran res dest-ctran)
816       (use-continuation res next result))))
817 \f
818 ;;;; CATCH, THROW and UNWIND-PROTECT
819
820 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
821 ;;; since as as far as IR1 is concerned, it has no interesting
822 ;;; properties other than receiving multiple-values.
823 (def-ir1-translator throw ((tag result) start next result-lvar)
824   #!+sb-doc
825   "Throw Tag Form
826   Do a non-local exit, return the values of Form from the CATCH whose tag
827   evaluates to the same thing as Tag."
828   (ir1-convert start next result-lvar
829                `(multiple-value-call #'%throw ,tag ,result)))
830
831 ;;; This is a special special form used to instantiate a cleanup as
832 ;;; the current cleanup within the body. KIND is the kind of cleanup
833 ;;; to make, and MESS-UP is a form that does the mess-up action. We
834 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
835 ;;; and introduce the cleanup into the lexical environment. We
836 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
837 ;;; cleanup, since this inner cleanup is the interesting one.
838 (def-ir1-translator %within-cleanup
839     ((kind mess-up &body body) start next result)
840   (let ((dummy (make-ctran))
841         (dummy2 (make-ctran)))
842     (ir1-convert start dummy nil mess-up)
843     (let* ((mess-node (ctran-use dummy))
844            (cleanup (make-cleanup :kind kind
845                                   :mess-up mess-node))
846            (old-cup (lexenv-cleanup *lexenv*))
847            (*lexenv* (make-lexenv :cleanup cleanup)))
848       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
849       (ir1-convert dummy dummy2 nil '(%cleanup-point))
850       (ir1-convert-progn-body dummy2 next result body))))
851
852 ;;; This is a special special form that makes an "escape function"
853 ;;; which returns unknown values from named block. We convert the
854 ;;; function, set its kind to :ESCAPE, and then reference it. The
855 ;;; :ESCAPE kind indicates that this function's purpose is to
856 ;;; represent a non-local control transfer, and that it might not
857 ;;; actually have to be compiled.
858 ;;;
859 ;;; Note that environment analysis replaces references to escape
860 ;;; functions with references to the corresponding NLX-INFO structure.
861 (def-ir1-translator %escape-fun ((tag) start next result)
862   (let ((fun (let ((*allow-instrumenting* nil))
863                (ir1-convert-lambda
864                 `(lambda ()
865                    (return-from ,tag (%unknown-values)))
866                 :debug-name (debug-namify "escape function for " tag)))))
867     (setf (functional-kind fun) :escape)
868     (reference-leaf start next result fun)))
869
870 ;;; Yet another special special form. This one looks up a local
871 ;;; function and smashes it to a :CLEANUP function, as well as
872 ;;; referencing it.
873 (def-ir1-translator %cleanup-fun ((name) start next result)
874   (let ((fun (lexenv-find name funs)))
875     (aver (lambda-p fun))
876     (setf (functional-kind fun) :cleanup)
877     (reference-leaf start next result fun)))
878
879 (def-ir1-translator catch ((tag &body body) start next result)
880   #!+sb-doc
881   "Catch Tag Form*
882   Evaluate TAG and instantiate it as a catcher while the body forms are
883   evaluated in an implicit PROGN. If a THROW is done to TAG within the dynamic
884   scope of the body, then control will be transferred to the end of the body
885   and the thrown values will be returned."
886   ;; We represent the possibility of the control transfer by making an
887   ;; "escape function" that does a lexical exit, and instantiate the
888   ;; cleanup using %WITHIN-CLEANUP.
889   (ir1-convert
890    start next result
891    (with-unique-names (exit-block)
892      `(block ,exit-block
893         (%within-cleanup
894          :catch (%catch (%escape-fun ,exit-block) ,tag)
895          ,@body)))))
896
897 (def-ir1-translator unwind-protect
898     ((protected &body cleanup) start next result)
899   #!+sb-doc
900   "Unwind-Protect Protected Cleanup*
901   Evaluate the form PROTECTED, returning its values. The CLEANUP forms are
902   evaluated whenever the dynamic scope of the PROTECTED form is exited (either
903   due to normal completion or a non-local exit such as THROW)."
904   ;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
905   ;; cleanup forms into a local function so that they can be referenced
906   ;; both in the case where we are unwound and in any local exits. We
907   ;; use %CLEANUP-FUN on this to indicate that reference by
908   ;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
909   ;; an XEP.
910   (ir1-convert
911    start next result
912    (with-unique-names (cleanup-fun drop-thru-tag exit-tag next start count)
913      `(flet ((,cleanup-fun () ,@cleanup nil))
914         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
915         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
916         ;; and something can be done to make %ESCAPE-FUN have
917         ;; dynamic extent too.
918         (block ,drop-thru-tag
919           (multiple-value-bind (,next ,start ,count)
920               (block ,exit-tag
921                 (%within-cleanup
922                     :unwind-protect
923                     (%unwind-protect (%escape-fun ,exit-tag)
924                                      (%cleanup-fun ,cleanup-fun))
925                   (return-from ,drop-thru-tag ,protected)))
926             (,cleanup-fun)
927             (%continue-unwind ,next ,start ,count)))))))
928 \f
929 ;;;; multiple-value stuff
930
931 (def-ir1-translator multiple-value-call ((fun &rest args) start next result)
932   #!+sb-doc
933   "MULTIPLE-VALUE-CALL Function Values-Form*
934   Call FUNCTION, passing all the values of each VALUES-FORM as arguments,
935   values from the first VALUES-FORM making up the first argument, etc."
936   (let* ((ctran (make-ctran))
937          (fun-lvar (make-lvar))
938          (node (if args
939                    ;; If there are arguments, MULTIPLE-VALUE-CALL
940                    ;; turns into an MV-COMBINATION.
941                    (make-mv-combination fun-lvar)
942                    ;; If there are no arguments, then we convert to a
943                    ;; normal combination, ensuring that a MV-COMBINATION
944                    ;; always has at least one argument. This can be
945                    ;; regarded as an optimization, but it is more
946                    ;; important for simplifying compilation of
947                    ;; MV-COMBINATIONS.
948                    (make-combination fun-lvar))))
949     (ir1-convert start ctran fun-lvar
950                  (if (and (consp fun) (eq (car fun) 'function))
951                      fun
952                      `(%coerce-callable-to-fun ,fun)))
953     (setf (lvar-dest fun-lvar) node)
954     (collect ((arg-lvars))
955       (let ((this-start ctran))
956         (dolist (arg args)
957           (let ((this-ctran (make-ctran))
958                 (this-lvar (make-lvar node)))
959             (ir1-convert this-start this-ctran this-lvar arg)
960             (setq this-start this-ctran)
961             (arg-lvars this-lvar)))
962         (link-node-to-previous-ctran node this-start)
963         (use-continuation node next result)
964         (setf (basic-combination-args node) (arg-lvars))))))
965
966 (def-ir1-translator multiple-value-prog1
967     ((values-form &rest forms) start next result)
968   #!+sb-doc
969   "MULTIPLE-VALUE-PROG1 Values-Form Form*
970   Evaluate Values-Form and then the Forms, but return all the values of
971   Values-Form."
972   (let ((dummy (make-ctran)))
973     (ctran-starts-block dummy)
974     (ir1-convert start dummy result values-form)
975     (ir1-convert-progn-body dummy next nil forms)))
976 \f
977 ;;;; interface to defining macros
978
979 ;;; Old CMUCL comment:
980 ;;;
981 ;;;   Return a new source path with any stuff intervening between the
982 ;;;   current path and the first form beginning with NAME stripped
983 ;;;   off.  This is used to hide the guts of DEFmumble macros to
984 ;;;   prevent annoying error messages.
985 ;;;
986 ;;; Now that we have implementations of DEFmumble macros in terms of
987 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
988 ;;; worth figuring out why it was used, and maybe doing analogous
989 ;;; munging to the functions created in the expanders for the macros.
990 (defun revert-source-path (name)
991   (do ((path *current-path* (cdr path)))
992       ((null path) *current-path*)
993     (let ((first (first path)))
994       (when (or (eq first name)
995                 (eq first 'original-source-start))
996         (return path)))))