src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     (setf (continuation-dest pred) node)
  39     (ir1-convert start pred test)
  40     (link-node-to-previous-continuation node pred)
  41     (use-continuation node dummy-cont)
  42
  43     (let ((start-block (continuation-block pred)))
  44       (setf (block-last start-block) node)
  45       (continuation-starts-block cont)
  46
  47       (link-blocks start-block then-block)
  48       (link-blocks start-block else-block))
  49
  50     (ir1-convert then-cont cont then)
  51     (ir1-convert else-cont cont else)))
  52 \f
  53 ;;;; BLOCK and TAGBODY
  54
  55 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  56 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  57 ;;;; node.
  58
  59 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  60 ;;; body in the modified environment. We make CONT start a block now,
  61 ;;; since if it was done later, the block would be in the wrong
  62 ;;; environment.
  63 (def-ir1-translator block ((name &rest forms) start cont)
  64   #!+sb-doc
  65   "Block Name Form*
  66   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  67   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  68   result of Value-Form."
  69   (unless (symbolp name)
  70     (compiler-error "The block name ~S is not a symbol." name))
  71   (continuation-starts-block cont)
  72   (let* ((dummy (make-continuation))
  73          (entry (make-entry))
  74          (cleanup (make-cleanup :kind :block
  75                                 :mess-up entry)))
  76     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  77     (setf (entry-cleanup entry) cleanup)
  78     (link-node-to-previous-continuation entry start)
  79     (use-continuation entry dummy)
  80
  81     (let* ((env-entry (list entry cont))
  82            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  83                                   :cleanup cleanup)))
  84       (push env-entry (continuation-lexenv-uses cont))
  85       (ir1-convert-progn-body dummy cont forms))))
  86
  87 (def-ir1-translator return-from ((name &optional value) start cont)
  88   #!+sb-doc
  89   "Return-From Block-Name Value-Form
  90   Evaluate the Value-Form, returning its values from the lexically enclosing
  91   BLOCK Block-Name. This is constrained to be used only within the dynamic
  92   extent of the BLOCK."
  93   ;; CMU CL comment:
  94   ;;   We make CONT start a block just so that it will have a block
  95   ;;   assigned. People assume that when they pass a continuation into
  96   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  97   ;; KLUDGE: Note that this block is basically fictitious. In the code
  98   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
  99   ;; it's the block which answers the question "which block is
 100   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 101   ;; dead code and so doesn't really have a block at all. The existence
 102   ;; of this block, and that way that it doesn't explicitly say
 103   ;; "I'm actually nowhere at all" makes some logic (e.g.
 104   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 105   ;; to get rid of it, perhaps using a special placeholder value
 106   ;; to indicate the orphanedness of the code.
 107   (continuation-starts-block cont)
 108   (let* ((found (or (lexenv-find name blocks)
 109                     (compiler-error "return for unknown block: ~S" name)))
 110          (value-cont (make-continuation))
 111          (entry (first found))
 112          (exit (make-exit :entry entry
 113                           :value value-cont)))
 114     (push exit (entry-exits entry))
 115     (setf (continuation-dest value-cont) exit)
 116     (ir1-convert start value-cont value)
 117     (link-node-to-previous-continuation exit value-cont)
 118     (let ((home-lambda (continuation-home-lambda-or-null start)))
 119       (when home-lambda
 120         (push entry (lambda-calls-or-closes home-lambda))))
 121     (use-continuation exit (second found))))
 122
 123 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 124 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 125 ;;; tagbody into segments of non-tag statements, and explicitly
 126 ;;; represent the drop-through with a GO. The first segment has a
 127 ;;; dummy NIL tag, since it represents code before the first tag. The
 128 ;;; last segment (which may also be the first segment) ends in NIL
 129 ;;; rather than a GO.
 130 (defun parse-tagbody (body)
 131   (declare (list body))
 132   (collect ((segments))
 133     (let ((current (cons nil body)))
 134       (loop
 135         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 136           (unless tag-pos
 137             (segments `(,@current nil))
 138             (return))
 139           (let ((tag (elt current tag-pos)))
 140             (when (assoc tag (segments))
 141               (compiler-error
 142                "The tag ~S appears more than once in the tagbody."
 143                tag))
 144             (unless (or (symbolp tag) (integerp tag))
 145               (compiler-error "~S is not a legal tagbody statement." tag))
 146             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 147           (setq current (nthcdr tag-pos current)))))
 148     (segments)))
 149
 150 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 151 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 152 ;;; Finally, convert each segment with the precomputed Start and Cont
 153 ;;; values.
 154 (def-ir1-translator tagbody ((&rest statements) start cont)
 155   #!+sb-doc
 156   "Tagbody {Tag | Statement}*
 157   Define tags for used with GO. The Statements are evaluated in order
 158   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 159   defined Tag within the lexical scope of the form, then control is transferred
 160   to the next statement following that tag. A Tag must an integer or a
 161   symbol. A statement must be a list. Other objects are illegal within the
 162   body."
 163   (continuation-starts-block cont)
 164   (let* ((dummy (make-continuation))
 165          (entry (make-entry))
 166          (segments (parse-tagbody statements))
 167          (cleanup (make-cleanup :kind :tagbody
 168                                 :mess-up entry)))
 169     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 170     (setf (entry-cleanup entry) cleanup)
 171     (link-node-to-previous-continuation entry start)
 172     (use-continuation entry dummy)
 173
 174     (collect ((tags)
 175               (starts)
 176               (conts))
 177       (starts dummy)
 178       (dolist (segment (rest segments))
 179         (let* ((tag-cont (make-continuation))
 180                (tag (list (car segment) entry tag-cont)))
 181           (conts tag-cont)
 182           (starts tag-cont)
 183           (continuation-starts-block tag-cont)
 184           (tags tag)
 185           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 186       (conts cont)
 187
 188       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 189         (mapc (lambda (segment start cont)
 190                 (ir1-convert-progn-body start cont (rest segment)))
 191               segments (starts) (conts))))))
 192
 193 ;;; Emit an EXIT node without any value.
 194 (def-ir1-translator go ((tag) start cont)
 195   #!+sb-doc
 196   "Go Tag
 197   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 198   is constrained to be used only within the dynamic extent of the TAGBODY."
 199   (continuation-starts-block cont)
 200   (let* ((found (or (lexenv-find tag tags :test #'eql)
 201                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 202                                     tag)))
 203          (entry (first found))
 204          (exit (make-exit :entry entry)))
 205     (push exit (entry-exits entry))
 206     (link-node-to-previous-continuation exit start)
 207     (let ((home-lambda (continuation-home-lambda-or-null start)))
 208       (when home-lambda
 209         (push entry (lambda-calls-or-closes home-lambda))))
 210     (use-continuation exit (second found))))
 211 \f
 212 ;;;; translators for compiler-magic special forms
 213
 214 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 215 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 216 ;;; so that they're never seen at this level.)
 217 ;;;
 218 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 219 ;;; of non-top-level EVAL-WHENs is very simple:
 220 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 221 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 222 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 223 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 224 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 225 ;;;   form; otherwise, the forms in the body are ignored.
 226 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 227   #!+sb-doc
 228   "EVAL-WHEN (Situation*) Form*
 229   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 230   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 231   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 232     (declare (ignore ct lt))
 233     (ir1-convert-progn-body start cont (and e forms)))
 234   (values))
 235
 236 ;;; common logic for MACROLET and SYMBOL-MACROLET
 237 ;;;
 238 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 239 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 240 ;;; call FUN (with no arguments).
 241 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 242                                        definitionize-keyword
 243                                        definitions
 244                                        fun)
 245   (declare (type function definitionize-fun fun))
 246   (declare (type (member :vars :funs) definitionize-keyword))
 247   (declare (type list definitions))
 248   (unless (= (length definitions)
 249              (length (remove-duplicates definitions :key #'first)))
 250     (compiler-style-warn "duplicate definitions in ~S" definitions))
 251   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 252          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 253     (funcall fun definitionize-keyword processed-definitions)))
 254
 255 ;;; Tweak *LEXENV* to include the DEFINITIONS from a MACROLET, then
 256 ;;; call FUN (with no arguments).
 257 ;;;
 258 ;;; This is split off from the IR1 convert method so that it can be
 259 ;;; shared by the special-case top level MACROLET processing code.
 260 (defun funcall-in-macrolet-lexenv (definitions fun)
 261   (%funcall-in-foomacrolet-lexenv
 262    (lambda (definition)
 263      (unless (list-of-length-at-least-p definition 2)
 264        (compiler-error
 265         "The list ~S is too short to be a legal local macro definition."
 266         definition))
 267      (destructuring-bind (name arglist &body body) definition
 268        (unless (symbolp name)
 269          (compiler-error "The local macro name ~S is not a symbol." name))
 270        (unless (listp arglist)
 271          (compiler-error "The local macro argument list ~S is not a list." arglist))
 272        (let ((whole (gensym "WHOLE"))
 273              (environment (gensym "ENVIRONMENT")))
 274          (multiple-value-bind (body local-decls)
 275              (parse-defmacro arglist whole body name 'macrolet
 276                              :environment environment)
 277            `(,name macro .
 278                    ,(compile-in-lexenv
 279                      nil
 280                      `(lambda (,whole ,environment)
 281                         ,@local-decls
 282                         (block ,name ,body))
 283                      (make-restricted-lexenv *lexenv*)))))))
 284    :funs
 285    definitions
 286    fun))
 287
 288 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 289   #!+sb-doc
 290   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 291   Evaluate the Body-Forms in an environment with the specified local macros
 292   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 293   destructuring lambda list, and the Forms evaluate to the expansion. The
 294   Forms are evaluated in the null environment."
 295   (funcall-in-macrolet-lexenv
 296    definitions
 297    (lambda (&key funs)
 298      (declare (ignore funs))
 299      (ir1-translate-locally body start cont))))
 300
 301 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 302   (%funcall-in-foomacrolet-lexenv
 303    (lambda (definition)
 304      (unless (proper-list-of-length-p definition 2)
 305        (compiler-error "malformed symbol/expansion pair: ~S" definition))
 306      (destructuring-bind (name expansion) definition
 307        (unless (symbolp name)
 308          (compiler-error
 309           "The local symbol macro name ~S is not a symbol."
 310           name))
 311        (let ((kind (info :variable :kind name)))
 312          (when (member kind '(:special :constant))
 313            (compiler-error "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S" kind name)))
 314        `(,name . (MACRO . ,expansion))))
 315    :vars
 316    definitions
 317    fun))
 318
 319 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 320   #!+sb-doc
 321   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 322   Define the Names as symbol macros with the given Expansions. Within the
 323   body, references to a Name will effectively be replaced with the Expansion."
 324   (funcall-in-symbol-macrolet-lexenv
 325    macrobindings
 326    (lambda (&key vars)
 327      (ir1-translate-locally body start cont :vars vars))))
 328
 329 ;;; not really a special form, but..
 330 (def-ir1-translator declare ((&rest stuff) start cont)
 331   (declare (ignore stuff))
 332   ;; We ignore START and CONT too, but we can't use DECLARE IGNORE to
 333   ;; tell the compiler about it here, because the DEF-IR1-TRANSLATOR
 334   ;; macro would put the DECLARE in the wrong place, so..
 335   start cont
 336   (compiler-error "misplaced declaration"))
 337 \f
 338 ;;;; %PRIMITIVE
 339 ;;;;
 340 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 341 ;;;; into a funny function.
 342
 343 ;;; Carefully evaluate a list of forms, returning a list of the results.
 344 (defun eval-info-args (args)
 345   (declare (list args))
 346   (handler-case (mapcar #'eval args)
 347     (error (condition)
 348       (compiler-error "Lisp error during evaluation of info args:~%~A"
 349                       condition))))
 350
 351 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 352 ;;; the template, the second is a list of the results of any
 353 ;;; codegen-info args, and the remaining arguments are the runtime
 354 ;;; arguments.
 355 ;;;
 356 ;;; We do various error checking now so that we don't bomb out with
 357 ;;; a fatal error during IR2 conversion.
 358 ;;;
 359 ;;; KLUDGE: It's confusing having multiple names floating around for
 360 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 361 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 362 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 363 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 364 ;;; VOP or %VOP.. -- WHN 2001-06-11
 365 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 366 (def-ir1-translator %primitive ((name &rest args) start cont)
 367   (declare (type symbol name))
 368   (let* ((template (or (gethash name *backend-template-names*)
 369                        (bug "undefined primitive ~A" name)))
 370          (required (length (template-arg-types template)))
 371          (info (template-info-arg-count template))
 372          (min (+ required info))
 373          (nargs (length args)))
 374     (if (template-more-args-type template)
 375         (when (< nargs min)
 376           (bug "Primitive ~A was called with ~R argument~:P, ~
 377                 but wants at least ~R."
 378                name
 379                nargs
 380                min))
 381         (unless (= nargs min)
 382           (bug "Primitive ~A was called with ~R argument~:P, ~
 383                 but wants exactly ~R."
 384                name
 385                nargs
 386                min)))
 387
 388     (when (eq (template-result-types template) :conditional)
 389       (bug "%PRIMITIVE was used with a conditional template."))
 390
 391     (when (template-more-results-type template)
 392       (bug "%PRIMITIVE was used with an unknown values template."))
 393
 394     (ir1-convert start
 395                  cont
 396                  `(%%primitive ',template
 397                                ',(eval-info-args
 398                                   (subseq args required min))
 399                                ,@(subseq args 0 required)
 400                                ,@(subseq args min)))))
 401 \f
 402 ;;;; QUOTE
 403
 404 (def-ir1-translator quote ((thing) start cont)
 405   #!+sb-doc
 406   "QUOTE Value
 407   Return Value without evaluating it."
 408   (reference-constant start cont thing))
 409 \f
 410 ;;;; FUNCTION and NAMED-LAMBDA
 411
 412 (def-ir1-translator function ((thing) start cont)
 413   #!+sb-doc
 414   "FUNCTION Name
 415   Return the lexically apparent definition of the function Name. Name may also
 416   be a lambda expression."
 417   (if (consp thing)
 418       (case (car thing)
 419         ((lambda)
 420          (reference-leaf start
 421                          cont
 422                          (ir1-convert-lambda thing
 423                                              :debug-name (debug-namify
 424                                                           "#'~S" thing))))
 425         ((setf)
 426          (let ((var (find-lexically-apparent-fun
 427                      thing "as the argument to FUNCTION")))
 428            (reference-leaf start cont var)))
 429         ((instance-lambda)
 430          (let ((res (ir1-convert-lambda `(lambda ,@(cdr thing))
 431                                         :debug-name (debug-namify "#'~S"
 432                                                                   thing))))
 433            (setf (getf (functional-plist res) :fin-function) t)
 434            (reference-leaf start cont res)))
 435         (t
 436          (compiler-error "~S is not a legal function name." thing)))
 437       (let ((var (find-lexically-apparent-fun
 438                   thing "as the argument to FUNCTION")))
 439         (reference-leaf start cont var))))
 440
 441 ;;; `(NAMED-LAMBDA ,NAME ,@REST) is like `(FUNCTION (LAMBDA ,@REST)),
 442 ;;; except that the value of NAME is passed to the compiler for use in
 443 ;;; creation of debug information for the resulting function.
 444 ;;;
 445 ;;; NAME can be a legal function name or some arbitrary other thing.
 446 ;;;
 447 ;;; If NAME is a legal function name, then the caller should be
 448 ;;; planning to set (FDEFINITION NAME) to the created function.
 449 ;;; (Otherwise the debug names will be inconsistent and thus
 450 ;;; unnecessarily confusing.)
 451 ;;;
 452 ;;; Arbitrary other things are appropriate for naming things which are
 453 ;;; not the FDEFINITION of NAME. E.g.
 454 ;;;   NAME = (:FLET FOO BAR)
 455 ;;; for the FLET function in
 456 ;;;   (DEFUN BAR (X)
 457 ;;;     (FLET ((FOO (Y) (+ X Y)))
 458 ;;;       FOO))
 459 ;;; or
 460 ;;;   NAME = (:METHOD PRINT-OBJECT :AROUND (STARSHIP T))
 461 ;;; for the function used to implement
 462 ;;;   (DEFMETHOD PRINT-OBJECT :AROUND ((SS STARSHIP) STREAM) ...).
 463 (def-ir1-translator named-lambda ((name &rest rest) start cont)
 464   (reference-leaf start
 465                   cont
 466                   (if (legal-fun-name-p name)
 467                       (ir1-convert-lambda `(lambda ,@rest)
 468                                           :source-name name)
 469                       (ir1-convert-lambda `(lambda ,@rest)
 470                                           :debug-name name))))
 471 \f
 472 ;;;; FUNCALL
 473
 474 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 475 ;;; (not symbols). %FUNCALL is used directly in some places where the
 476 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 477 (deftransform funcall ((function &rest args) * *)
 478   (let ((arg-names (make-gensym-list (length args))))
 479     `(lambda (function ,@arg-names)
 480        (%funcall ,(if (csubtypep (continuation-type function)
 481                                  (specifier-type 'function))
 482                       'function
 483                       '(%coerce-callable-to-fun function))
 484                  ,@arg-names))))
 485
 486 (def-ir1-translator %funcall ((function &rest args) start cont)
 487   (let ((fun-cont (make-continuation)))
 488     (ir1-convert start fun-cont function)
 489     (assert-continuation-type fun-cont (specifier-type 'function))
 490     (ir1-convert-combination-args fun-cont cont args)))
 491
 492 ;;; This source transform exists to reduce the amount of work for the
 493 ;;; compiler. If the called function is a FUNCTION form, then convert
 494 ;;; directly to %FUNCALL, instead of waiting around for type
 495 ;;; inference.
 496 (define-source-transform funcall (function &rest args)
 497   (if (and (consp function) (eq (car function) 'function))
 498       `(%funcall ,function ,@args)
 499       (values nil t)))
 500
 501 (deftransform %coerce-callable-to-fun ((thing) (function) *
 502                                        :important t)
 503   "optimize away possible call to FDEFINITION at runtime"
 504   'thing)
 505 \f
 506 ;;;; LET and LET*
 507 ;;;;
 508 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 509 ;;;; any pervasive declarations also affect the evaluation of the
 510 ;;;; arguments.)
 511
 512 ;;; Given a list of binding specifiers in the style of LET, return:
 513 ;;;  1. The list of var structures for the variables bound.
 514 ;;;  2. The initial value form for each variable.
 515 ;;;
 516 ;;; The variable names are checked for legality and globally special
 517 ;;; variables are marked as such. Context is the name of the form, for
 518 ;;; error reporting purposes.
 519 (declaim (ftype (function (list symbol) (values list list))
 520                 extract-let-vars))
 521 (defun extract-let-vars (bindings context)
 522   (collect ((vars)
 523             (vals)
 524             (names))
 525     (flet ((get-var (name)
 526              (varify-lambda-arg name
 527                                 (if (eq context 'let*)
 528                                     nil
 529                                     (names)))))
 530       (dolist (spec bindings)
 531         (cond ((atom spec)
 532                (let ((var (get-var spec)))
 533                  (vars var)
 534                  (names spec)
 535                  (vals nil)))
 536               (t
 537                (unless (proper-list-of-length-p spec 1 2)
 538                  (compiler-error "The ~S binding spec ~S is malformed."
 539                                  context
 540                                  spec))
 541                (let* ((name (first spec))
 542                       (var (get-var name)))
 543                  (vars var)
 544                  (names name)
 545                  (vals (second spec)))))))
 546
 547     (values (vars) (vals))))
 548
 549 (def-ir1-translator let ((bindings &body body)
 550                          start cont)
 551   #!+sb-doc
 552   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 553   During evaluation of the Forms, bind the Vars to the result of evaluating the
 554   Value forms. The variables are bound in parallel after all of the Values are
 555   evaluated."
 556   (multiple-value-bind (forms decls) (parse-body body nil)
 557     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 558       (let ((fun-cont (make-continuation)))
 559         (let* ((*lexenv* (process-decls decls vars nil cont))
 560                (fun (ir1-convert-lambda-body
 561                      forms vars
 562                      :debug-name (debug-namify "LET ~S" bindings))))
 563           (reference-leaf start fun-cont fun))
 564         (ir1-convert-combination-args fun-cont cont values)))))
 565
 566 (def-ir1-translator let* ((bindings &body body)
 567                           start cont)
 568   #!+sb-doc
 569   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 570   Similar to LET, but the variables are bound sequentially, allowing each Value
 571   form to reference any of the previous Vars."
 572   (multiple-value-bind (forms decls) (parse-body body nil)
 573     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 574       (let ((*lexenv* (process-decls decls vars nil cont)))
 575         (ir1-convert-aux-bindings start cont forms vars values)))))
 576
 577 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 578 ;;; and SYMBOL-MACROLET
 579 ;;;
 580 ;;; Note that all these things need to preserve toplevel-formness,
 581 ;;; but we don't need to worry about that within an IR1 translator,
 582 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 583 ;;; forms before we hit the IR1 transform level.
 584 (defun ir1-translate-locally (body start cont &key vars funs)
 585   (declare (type list body) (type continuation start cont))
 586   (multiple-value-bind (forms decls) (parse-body body nil)
 587     (let ((*lexenv* (process-decls decls vars funs cont)))
 588       (ir1-convert-aux-bindings start cont forms nil nil))))
 589
 590 (def-ir1-translator locally ((&body body) start cont)
 591   #!+sb-doc
 592   "LOCALLY Declaration* Form*
 593   Sequentially evaluate the Forms in a lexical environment where the
 594   the Declarations have effect. If LOCALLY is a top level form, then
 595   the Forms are also processed as top level forms."
 596   (ir1-translate-locally body start cont))
 597 \f
 598 ;;;; FLET and LABELS
 599
 600 ;;; Given a list of local function specifications in the style of
 601 ;;; FLET, return lists of the function names and of the lambdas which
 602 ;;; are their definitions.
 603 ;;;
 604 ;;; The function names are checked for legality. CONTEXT is the name
 605 ;;; of the form, for error reporting.
 606 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 607 (defun extract-flet-vars (definitions context)
 608   (collect ((names)
 609             (defs))
 610     (dolist (def definitions)
 611       (when (or (atom def) (< (length def) 2))
 612         (compiler-error "The ~S definition spec ~S is malformed." context def))
 613
 614       (let ((name (first def)))
 615         (check-fun-name name)
 616         (names name)
 617         (multiple-value-bind (forms decls) (parse-body (cddr def))
 618           (defs `(lambda ,(second def)
 619                    ,@decls
 620                    (block ,(fun-name-block-name name)
 621                      . ,forms))))))
 622     (values (names) (defs))))
 623
 624 (def-ir1-translator flet ((definitions &body body)
 625                           start cont)
 626   #!+sb-doc
 627   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 628   Evaluate the Body-Forms with some local function definitions. The bindings
 629   do not enclose the definitions; any use of Name in the Forms will refer to
 630   the lexically apparent function definition in the enclosing environment."
 631   (multiple-value-bind (forms decls) (parse-body body nil)
 632     (multiple-value-bind (names defs)
 633         (extract-flet-vars definitions 'flet)
 634       (let* ((fvars (mapcar (lambda (n d)
 635                               (ir1-convert-lambda d
 636                                                   :source-name n
 637                                                   :debug-name (debug-namify
 638                                                                "FLET ~S" n)))
 639                             names defs))
 640              (*lexenv* (make-lexenv
 641                         :default (process-decls decls nil fvars cont)
 642                         :funs (pairlis names fvars))))
 643         (ir1-convert-progn-body start cont forms)))))
 644
 645 (def-ir1-translator labels ((definitions &body body) start cont)
 646   #!+sb-doc
 647   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 648   Evaluate the Body-Forms with some local function definitions. The bindings
 649   enclose the new definitions, so the defined functions can call themselves or
 650   each other."
 651   (multiple-value-bind (forms decls) (parse-body body nil)
 652     (multiple-value-bind (names defs)
 653         (extract-flet-vars definitions 'labels)
 654       (let* (;; dummy LABELS functions, to be used as placeholders
 655              ;; during construction of real LABELS functions
 656              (placeholder-funs (mapcar (lambda (name)
 657                                          (make-functional
 658                                           :%source-name name
 659                                           :%debug-name (debug-namify
 660                                                         "LABELS placeholder ~S"
 661                                                         name)))
 662                                        names))
 663              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 664              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 665              ;; the real LABELS functions, compiled in a LEXENV which
 666              ;; includes the dummy LABELS functions
 667              (real-funs
 668               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 669                 (mapcar (lambda (name def)
 670                           (ir1-convert-lambda def
 671                                               :source-name name
 672                                               :debug-name (debug-namify
 673                                                            "LABELS ~S" name)))
 674                         names defs))))
 675
 676         ;; Modify all the references to the dummy function leaves so
 677         ;; that they point to the real function leaves.
 678         (loop for real-fun in real-funs and
 679               placeholder-cons in placeholder-fenv do
 680               (substitute-leaf real-fun (cdr placeholder-cons))
 681               (setf (cdr placeholder-cons) real-fun))
 682
 683         ;; Voila.
 684         (let ((*lexenv* (make-lexenv
 685                          :default (process-decls decls nil real-funs cont)
 686                          ;; Use a proper FENV here (not the
 687                          ;; placeholder used earlier) so that if the
 688                          ;; lexical environment is used for inline
 689                          ;; expansion we'll get the right functions.
 690                          :funs (pairlis names real-funs))))
 691           (ir1-convert-progn-body start cont forms))))))
 692 \f
 693 ;;;; the THE special operator, and friends
 694
 695 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 696 ;;; continuation that the assertion applies to, TYPE is the type
 697 ;;; specifier and LEXENV is the current lexical environment. NAME is
 698 ;;; the name of the declaration we are doing, for use in error
 699 ;;; messages.
 700 ;;;
 701 ;;; This is somewhat involved, since a type assertion may only be made
 702 ;;; on a continuation, not on a node. We can't just set the
 703 ;;; continuation asserted type and let it go at that, since there may
 704 ;;; be parallel THE's for the same continuation, i.e.
 705 ;;;     (if ...
 706 ;;;      (the foo ...)
 707 ;;;      (the bar ...))
 708 ;;;
 709 ;;; In this case, our representation can do no better than the union
 710 ;;; of these assertions. And if there is a branch with no assertion,
 711 ;;; we have nothing at all. We really need to recognize scoping, since
 712 ;;; we need to be able to discern between parallel assertions (which
 713 ;;; we union) and nested ones (which we intersect).
 714 ;;;
 715 ;;; We represent the scoping by throwing our innermost (intersected)
 716 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 717 ;;; intersect our assertions together. If CONT has no uses yet, we
 718 ;;; have not yet bottomed out on the first COND branch; in this case
 719 ;;; we optimistically assume that this type will be the one we end up
 720 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 721 ;;; than the type that we have the first time we bottom out. Later
 722 ;;; THE's (or the absence thereof) can only weaken this result.
 723 ;;;
 724 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 725 ;;; across COND branches. We can't do it here, since we don't know how
 726 ;;; many branches there are going to be.
 727 (defun ir1ize-the-or-values (type cont lexenv place)
 728   (declare (type continuation cont) (type lexenv lexenv))
 729   (let* ((ctype (if (typep type 'ctype) type (compiler-values-specifier-type type)))
 730          (old-type (or (lexenv-find cont type-restrictions)
 731                        *wild-type*))
 732          (intersects (values-types-equal-or-intersect old-type ctype))
 733          (new (values-type-intersection old-type ctype)))
 734     (when (null (find-uses cont))
 735       (setf (continuation-asserted-type cont) new))
 736     (when (and (not intersects)
 737                ;; FIXME: Is it really right to look at *LEXENV* here,
 738                ;; instead of looking at the LEXENV argument? Why?
 739                (not (policy *lexenv*
 740                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 741       (compiler-warn
 742        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 743        (type-specifier ctype)
 744        place
 745        (type-specifier old-type)))
 746     (make-lexenv :type-restrictions `((,cont . ,new))
 747                  :default lexenv)))
 748
 749 ;;; Assert that FORM evaluates to the specified type (which may be a
 750 ;;; VALUES type).
 751 ;;;
 752 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 753 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 754 ;;; values. Check that SBCL doesn't have this problem.
 755 (def-ir1-translator the ((type value) start cont)
 756   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 757                                           "in THE declaration")
 758     (ir1-convert start cont value)))
 759
 760 ;;; This is like the THE special form, except that it believes
 761 ;;; whatever you tell it. It will never generate a type check, but
 762 ;;; will cause a warning if the compiler can prove the assertion is
 763 ;;; wrong.
 764 ;;;
 765 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 766 ;;; its uses's types, setting it won't work. Instead we must intersect
 767 ;;; the type with the uses's DERIVED-TYPE.
 768 (def-ir1-translator truly-the ((type value) start cont)
 769   #!+sb-doc
 770   (declare (inline member))
 771   (let ((type (compiler-values-specifier-type type))
 772         (old (find-uses cont)))
 773     (ir1-convert start cont value)
 774     (do-uses (use cont)
 775       (unless (member use old :test #'eq)
 776         (derive-node-type use type)))))
 777 \f
 778 ;;;; SETQ
 779
 780 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 781 ;;; look at the global information. If the name is for a constant,
 782 ;;; then error out.
 783 (def-ir1-translator setq ((&whole source &rest things) start cont)
 784   (let ((len (length things)))
 785     (when (oddp len)
 786       (compiler-error "odd number of args to SETQ: ~S" source))
 787     (if (= len 2)
 788         (let* ((name (first things))
 789                (leaf (or (lexenv-find name vars)
 790                          (find-free-var name))))
 791           (etypecase leaf
 792             (leaf
 793              (when (constant-p leaf)
 794                (compiler-error "~S is a constant and thus can't be set." name))
 795              (when (lambda-var-p leaf)
 796                (let ((home-lambda (continuation-home-lambda-or-null start)))
 797                  (when home-lambda
 798                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 799                (when (lambda-var-ignorep leaf)
 800                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 801                  ;; requires that this be a STYLE-WARNING, not a full warning.
 802                  (compiler-style-warn
 803                   "~S is being set even though it was declared to be ignored."
 804                   name)))
 805              (setq-var start cont leaf (second things)))
 806             (cons
 807              (aver (eq (car leaf) 'MACRO))
 808              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 809             (heap-alien-info
 810              (ir1-convert start cont
 811                           `(%set-heap-alien ',leaf ,(second things))))))
 812         (collect ((sets))
 813           (do ((thing things (cddr thing)))
 814               ((endp thing)
 815                (ir1-convert-progn-body start cont (sets)))
 816             (sets `(setq ,(first thing) ,(second thing))))))))
 817
 818 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 819 ;;; This should only need to be called in SETQ.
 820 (defun setq-var (start cont var value)
 821   (declare (type continuation start cont) (type basic-var var))
 822   (let ((dest (make-continuation)))
 823     (setf (continuation-asserted-type dest) (leaf-type var))
 824     (ir1-convert start dest value)
 825     (let ((res (make-set :var var :value dest)))
 826       (setf (continuation-dest dest) res)
 827       (setf (leaf-ever-used var) t)
 828       (push res (basic-var-sets var))
 829       (link-node-to-previous-continuation res dest)
 830       (use-continuation res cont))))
 831 \f
 832 ;;;; CATCH, THROW and UNWIND-PROTECT
 833
 834 ;;; We turn THROW into a multiple-value-call of a magical function,
 835 ;;; since as as far as IR1 is concerned, it has no interesting
 836 ;;; properties other than receiving multiple-values.
 837 (def-ir1-translator throw ((tag result) start cont)
 838   #!+sb-doc
 839   "Throw Tag Form
 840   Do a non-local exit, return the values of Form from the CATCH whose tag
 841   evaluates to the same thing as Tag."
 842   (ir1-convert start cont
 843                `(multiple-value-call #'%throw ,tag ,result)))
 844
 845 ;;; This is a special special form used to instantiate a cleanup as
 846 ;;; the current cleanup within the body. KIND is the kind of cleanup
 847 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 848 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 849 ;;; and introduce the cleanup into the lexical environment. We
 850 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 851 ;;; cleanup, since this inner cleanup is the interesting one.
 852 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 853   (let ((dummy (make-continuation))
 854         (dummy2 (make-continuation)))
 855     (ir1-convert start dummy mess-up)
 856     (let* ((mess-node (continuation-use dummy))
 857            (cleanup (make-cleanup :kind kind
 858                                   :mess-up mess-node))
 859            (old-cup (lexenv-cleanup *lexenv*))
 860            (*lexenv* (make-lexenv :cleanup cleanup)))
 861       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 862       (ir1-convert dummy dummy2 '(%cleanup-point))
 863       (ir1-convert-progn-body dummy2 cont body))))
 864
 865 ;;; This is a special special form that makes an "escape function"
 866 ;;; which returns unknown values from named block. We convert the
 867 ;;; function, set its kind to :ESCAPE, and then reference it. The
 868 ;;; :ESCAPE kind indicates that this function's purpose is to
 869 ;;; represent a non-local control transfer, and that it might not
 870 ;;; actually have to be compiled.
 871 ;;;
 872 ;;; Note that environment analysis replaces references to escape
 873 ;;; functions with references to the corresponding NLX-INFO structure.
 874 (def-ir1-translator %escape-fun ((tag) start cont)
 875   (let ((fun (ir1-convert-lambda
 876               `(lambda ()
 877                  (return-from ,tag (%unknown-values)))
 878               :debug-name (debug-namify "escape function for ~S" tag))))
 879     (setf (functional-kind fun) :escape)
 880     (reference-leaf start cont fun)))
 881
 882 ;;; Yet another special special form. This one looks up a local
 883 ;;; function and smashes it to a :CLEANUP function, as well as
 884 ;;; referencing it.
 885 (def-ir1-translator %cleanup-fun ((name) start cont)
 886   (let ((fun (lexenv-find name funs)))
 887     (aver (lambda-p fun))
 888     (setf (functional-kind fun) :cleanup)
 889     (reference-leaf start cont fun)))
 890
 891 ;;; We represent the possibility of the control transfer by making an
 892 ;;; "escape function" that does a lexical exit, and instantiate the
 893 ;;; cleanup using %WITHIN-CLEANUP.
 894 (def-ir1-translator catch ((tag &body body) start cont)
 895   #!+sb-doc
 896   "Catch Tag Form*
 897   Evaluates Tag and instantiates it as a catcher while the body forms are
 898   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 899   scope of the body, then control will be transferred to the end of the body
 900   and the thrown values will be returned."
 901   (ir1-convert
 902    start cont
 903    (let ((exit-block (gensym "EXIT-BLOCK-")))
 904      `(block ,exit-block
 905         (%within-cleanup
 906             :catch
 907             (%catch (%escape-fun ,exit-block) ,tag)
 908           ,@body)))))
 909
 910 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 911 ;;; cleanup forms into a local function so that they can be referenced
 912 ;;; both in the case where we are unwound and in any local exits. We
 913 ;;; use %CLEANUP-FUN on this to indicate that reference by
 914 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 915 ;;; an XEP.
 916 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 917   #!+sb-doc
 918   "Unwind-Protect Protected Cleanup*
 919   Evaluate the form Protected, returning its values. The cleanup forms are
 920   evaluated whenever the dynamic scope of the Protected form is exited (either
 921   due to normal completion or a non-local exit such as THROW)."
 922   (ir1-convert
 923    start cont
 924    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 925          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 926          (exit-tag (gensym "EXIT-TAG-"))
 927          (next (gensym "NEXT"))
 928          (start (gensym "START"))
 929          (count (gensym "COUNT")))
 930      `(flet ((,cleanup-fun () ,@cleanup nil))
 931         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 932         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 933         ;; and something can be done to make %ESCAPE-FUN have
 934         ;; dynamic extent too.
 935         (block ,drop-thru-tag
 936           (multiple-value-bind (,next ,start ,count)
 937               (block ,exit-tag
 938                 (%within-cleanup
 939                     :unwind-protect
 940                     (%unwind-protect (%escape-fun ,exit-tag)
 941                                      (%cleanup-fun ,cleanup-fun))
 942                   (return-from ,drop-thru-tag ,protected)))
 943             (,cleanup-fun)
 944             (%continue-unwind ,next ,start ,count)))))))
 945 \f
 946 ;;;; multiple-value stuff
 947
 948 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 949 ;;; MV-COMBINATION.
 950 ;;;
 951 ;;; If there are no arguments, then we convert to a normal
 952 ;;; combination, ensuring that a MV-COMBINATION always has at least
 953 ;;; one argument. This can be regarded as an optimization, but it is
 954 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 955 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 956   #!+sb-doc
 957   "MULTIPLE-VALUE-CALL Function Values-Form*
 958   Call Function, passing all the values of each Values-Form as arguments,
 959   values from the first Values-Form making up the first argument, etc."
 960   (let* ((fun-cont (make-continuation))
 961          (node (if args
 962                    (make-mv-combination fun-cont)
 963                    (make-combination fun-cont))))
 964     (ir1-convert start fun-cont
 965                  (if (and (consp fun) (eq (car fun) 'function))
 966                      fun
 967                      `(%coerce-callable-to-fun ,fun)))
 968     (setf (continuation-dest fun-cont) node)
 969     (assert-continuation-type fun-cont
 970                               (specifier-type '(or function symbol)))
 971     (collect ((arg-conts))
 972       (let ((this-start fun-cont))
 973         (dolist (arg args)
 974           (let ((this-cont (make-continuation node)))
 975             (ir1-convert this-start this-cont arg)
 976             (setq this-start this-cont)
 977             (arg-conts this-cont)))
 978         (link-node-to-previous-continuation node this-start)
 979         (use-continuation node cont)
 980         (setf (basic-combination-args node) (arg-conts))))))
 981
 982 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 983 ;;; the result code use result continuation (CONT), but transfer
 984 ;;; control to the evaluation of the body. In other words, the result
 985 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 986 ;;; the result.
 987 ;;;
 988 ;;; In order to get the control flow right, we convert the result with
 989 ;;; a dummy result continuation, then convert all the uses of the
 990 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 991 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 992 ;;; that they are consistent. Note that this doesn't amount to
 993 ;;; changing the exit target, since the control destination of an exit
 994 ;;; is determined by the block successor; we are just indicating the
 995 ;;; continuation that the result is delivered to.
 996 ;;;
 997 ;;; We then convert the body, using another dummy continuation in its
 998 ;;; own block as the result. After we are done converting the body, we
 999 ;;; move all predecessors of the dummy end block to CONT's block.
1000 ;;;
1001 ;;; Note that we both exploit and maintain the invariant that the CONT
1002 ;;; to an IR1 convert method either has no block or starts the block
1003 ;;; that control should transfer to after completion for the form.
1004 ;;; Nested MV-PROG1's work because during conversion of the result
1005 ;;; form, we use dummy continuation whose block is the true control
1006 ;;; destination.
1007 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
1008   #!+sb-doc
1009   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1010   Evaluate Values-Form and then the Forms, but return all the values of
1011   Values-Form."
1012   (continuation-starts-block cont)
1013   (let* ((dummy-result (make-continuation))
1014          (dummy-start (make-continuation))
1015          (cont-block (continuation-block cont)))
1016     (continuation-starts-block dummy-start)
1017     (ir1-convert start dummy-start result)
1018
1019     (with-continuation-type-assertion
1020         (cont (continuation-asserted-type dummy-start)
1021               "of the first form")
1022       (substitute-continuation-uses cont dummy-start))
1023
1024     (continuation-starts-block dummy-result)
1025     (ir1-convert-progn-body dummy-start dummy-result forms)
1026     (let ((end-block (continuation-block dummy-result)))
1027       (dolist (pred (block-pred end-block))
1028         (unlink-blocks pred end-block)
1029         (link-blocks pred cont-block))
1030       (aver (not (continuation-dest dummy-result)))
1031       (delete-continuation dummy-result)
1032       (remove-from-dfo end-block))))
1033 \f
1034 ;;;; interface to defining macros
1035
1036 ;;;; FIXME:
1037 ;;;;   classic CMU CL comment:
1038 ;;;;     DEFMACRO and DEFUN expand into calls to %DEFxxx functions
1039 ;;;;     so that we get a chance to see what is going on. We define
1040 ;;;;     IR1 translators for these functions which look at the
1041 ;;;;     definition and then generate a call to the %%DEFxxx function.
1042 ;;;; Alas, this implementation doesn't do the right thing for
1043 ;;;; non-toplevel uses of these forms, so this should probably
1044 ;;;; be changed to use EVAL-WHEN instead.
1045
1046 ;;; Return a new source path with any stuff intervening between the
1047 ;;; current path and the first form beginning with NAME stripped off.
1048 ;;; This is used to hide the guts of DEFmumble macros to prevent
1049 ;;; annoying error messages.
1050 (defun revert-source-path (name)
1051   (do ((path *current-path* (cdr path)))
1052       ((null path) *current-path*)
1053     (let ((first (first path)))
1054       (when (or (eq first name)
1055                 (eq first 'original-source-start))
1056         (return path)))))
1057
1058 (def-ir1-translator %define-compiler-macro ((name def lambda-list doc)
1059                                             start cont
1060                                             :kind :function)
1061   (let ((name (eval name))
1062         (def (second def))) ; We don't want to make a function just yet...
1063
1064     (when (eq (info :function :kind name) :special-form)
1065       (compiler-error "attempt to define a compiler-macro for special form ~S"
1066                       name))
1067
1068     (setf (info :function :compiler-macro-function name)
1069           (coerce def 'function))
1070
1071     (let* ((*current-path* (revert-source-path 'define-compiler-macro))
1072            (fun (ir1-convert-lambda def
1073                                     :debug-name (debug-namify
1074                                                  "DEFINE-COMPILER-MACRO ~S"
1075                                                  name))))
1076       (setf (functional-arg-documentation fun) (eval lambda-list))
1077
1078       (ir1-convert start cont `(%%define-compiler-macro ',name ,fun ,doc)))
1079
1080     (when sb!xc:*compile-print*
1081       (compiler-mumble "~&; converted ~S~%" name))))