src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     ;; IR1-CONVERT-MAYBE-PREDICATE requires DEST to be CIF, so the
  39     ;; order of the following two forms is important
  40     (setf (continuation-dest pred) node)
  41     (ir1-convert start pred test)
  42     (link-node-to-previous-continuation node pred)
  43     (use-continuation node dummy-cont)
  44
  45     (let ((start-block (continuation-block pred)))
  46       (setf (block-last start-block) node)
  47       (continuation-starts-block cont)
  48
  49       (link-blocks start-block then-block)
  50       (link-blocks start-block else-block))
  51
  52     (ir1-convert then-cont cont then)
  53     (ir1-convert else-cont cont else)))
  54 \f
  55 ;;;; BLOCK and TAGBODY
  56
  57 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  58 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  59 ;;;; node.
  60
  61 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  62 ;;; body in the modified environment. We make CONT start a block now,
  63 ;;; since if it was done later, the block would be in the wrong
  64 ;;; environment.
  65 (def-ir1-translator block ((name &rest forms) start cont)
  66   #!+sb-doc
  67   "Block Name Form*
  68   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  69   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  70   result of Value-Form."
  71   (unless (symbolp name)
  72     (compiler-error "The block name ~S is not a symbol." name))
  73   (continuation-starts-block cont)
  74   (let* ((dummy (make-continuation))
  75          (entry (make-entry))
  76          (cleanup (make-cleanup :kind :block
  77                                 :mess-up entry)))
  78     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  79     (setf (entry-cleanup entry) cleanup)
  80     (link-node-to-previous-continuation entry start)
  81     (use-continuation entry dummy)
  82
  83     (let* ((env-entry (list entry cont))
  84            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  85                                   :cleanup cleanup)))
  86       (push env-entry (continuation-lexenv-uses cont))
  87       (ir1-convert-progn-body dummy cont forms))))
  88
  89 (def-ir1-translator return-from ((name &optional value) start cont)
  90   #!+sb-doc
  91   "Return-From Block-Name Value-Form
  92   Evaluate the Value-Form, returning its values from the lexically enclosing
  93   BLOCK Block-Name. This is constrained to be used only within the dynamic
  94   extent of the BLOCK."
  95   ;; CMU CL comment:
  96   ;;   We make CONT start a block just so that it will have a block
  97   ;;   assigned. People assume that when they pass a continuation into
  98   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  99   ;; KLUDGE: Note that this block is basically fictitious. In the code
 100   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 101   ;; it's the block which answers the question "which block is
 102   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 103   ;; dead code and so doesn't really have a block at all. The existence
 104   ;; of this block, and that way that it doesn't explicitly say
 105   ;; "I'm actually nowhere at all" makes some logic (e.g.
 106   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 107   ;; to get rid of it, perhaps using a special placeholder value
 108   ;; to indicate the orphanedness of the code.
 109   (continuation-starts-block cont)
 110   (let* ((found (or (lexenv-find name blocks)
 111                     (compiler-error "return for unknown block: ~S" name)))
 112          (value-cont (make-continuation))
 113          (entry (first found))
 114          (exit (make-exit :entry entry
 115                           :value value-cont)))
 116     (push exit (entry-exits entry))
 117     (setf (continuation-dest value-cont) exit)
 118     (ir1-convert start value-cont value)
 119     (link-node-to-previous-continuation exit value-cont)
 120     (let ((home-lambda (continuation-home-lambda-or-null start)))
 121       (when home-lambda
 122         (push entry (lambda-calls-or-closes home-lambda))))
 123     (use-continuation exit (second found))))
 124
 125 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 126 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 127 ;;; tagbody into segments of non-tag statements, and explicitly
 128 ;;; represent the drop-through with a GO. The first segment has a
 129 ;;; dummy NIL tag, since it represents code before the first tag. The
 130 ;;; last segment (which may also be the first segment) ends in NIL
 131 ;;; rather than a GO.
 132 (defun parse-tagbody (body)
 133   (declare (list body))
 134   (collect ((segments))
 135     (let ((current (cons nil body)))
 136       (loop
 137         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 138           (unless tag-pos
 139             (segments `(,@current nil))
 140             (return))
 141           (let ((tag (elt current tag-pos)))
 142             (when (assoc tag (segments))
 143               (compiler-error
 144                "The tag ~S appears more than once in the tagbody."
 145                tag))
 146             (unless (or (symbolp tag) (integerp tag))
 147               (compiler-error "~S is not a legal tagbody statement." tag))
 148             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 149           (setq current (nthcdr tag-pos current)))))
 150     (segments)))
 151
 152 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 153 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 154 ;;; Finally, convert each segment with the precomputed Start and Cont
 155 ;;; values.
 156 (def-ir1-translator tagbody ((&rest statements) start cont)
 157   #!+sb-doc
 158   "Tagbody {Tag | Statement}*
 159   Define tags for used with GO. The Statements are evaluated in order
 160   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 161   defined Tag within the lexical scope of the form, then control is transferred
 162   to the next statement following that tag. A Tag must an integer or a
 163   symbol. A statement must be a list. Other objects are illegal within the
 164   body."
 165   (continuation-starts-block cont)
 166   (let* ((dummy (make-continuation))
 167          (entry (make-entry))
 168          (segments (parse-tagbody statements))
 169          (cleanup (make-cleanup :kind :tagbody
 170                                 :mess-up entry)))
 171     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 172     (setf (entry-cleanup entry) cleanup)
 173     (link-node-to-previous-continuation entry start)
 174     (use-continuation entry dummy)
 175
 176     (collect ((tags)
 177               (starts)
 178               (conts))
 179       (starts dummy)
 180       (dolist (segment (rest segments))
 181         (let* ((tag-cont (make-continuation))
 182                (tag (list (car segment) entry tag-cont)))
 183           (conts tag-cont)
 184           (starts tag-cont)
 185           (continuation-starts-block tag-cont)
 186           (tags tag)
 187           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 188       (conts cont)
 189
 190       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 191         (mapc (lambda (segment start cont)
 192                 (ir1-convert-progn-body start cont (rest segment)))
 193               segments (starts) (conts))))))
 194
 195 ;;; Emit an EXIT node without any value.
 196 (def-ir1-translator go ((tag) start cont)
 197   #!+sb-doc
 198   "Go Tag
 199   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 200   is constrained to be used only within the dynamic extent of the TAGBODY."
 201   (continuation-starts-block cont)
 202   (let* ((found (or (lexenv-find tag tags :test #'eql)
 203                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 204                                     tag)))
 205          (entry (first found))
 206          (exit (make-exit :entry entry)))
 207     (push exit (entry-exits entry))
 208     (link-node-to-previous-continuation exit start)
 209     (let ((home-lambda (continuation-home-lambda-or-null start)))
 210       (when home-lambda
 211         (push entry (lambda-calls-or-closes home-lambda))))
 212     (use-continuation exit (second found))))
 213 \f
 214 ;;;; translators for compiler-magic special forms
 215
 216 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 217 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 218 ;;; so that they're never seen at this level.)
 219 ;;;
 220 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 221 ;;; of non-top-level EVAL-WHENs is very simple:
 222 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 223 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 224 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 225 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 226 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 227 ;;;   form; otherwise, the forms in the body are ignored.
 228 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 229   #!+sb-doc
 230   "EVAL-WHEN (Situation*) Form*
 231   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 232   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 233   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 234     (declare (ignore ct lt))
 235     (ir1-convert-progn-body start cont (and e forms)))
 236   (values))
 237
 238 ;;; common logic for MACROLET and SYMBOL-MACROLET
 239 ;;;
 240 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 241 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 242 ;;; call FUN (with no arguments).
 243 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 244                                        definitionize-keyword
 245                                        definitions
 246                                        fun)
 247   (declare (type function definitionize-fun fun))
 248   (declare (type (member :vars :funs) definitionize-keyword))
 249   (declare (type list definitions))
 250   (unless (= (length definitions)
 251              (length (remove-duplicates definitions :key #'first)))
 252     (compiler-style-warn "duplicate definitions in ~S" definitions))
 253   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 254          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 255     (funcall fun definitionize-keyword processed-definitions)))
 256
 257 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 258 ;;; call FUN (with no arguments).
 259 ;;;
 260 ;;; This is split off from the IR1 convert method so that it can be
 261 ;;; shared by the special-case top level MACROLET processing code, and
 262 ;;; further split so that the special-case MACROLET processing code in
 263 ;;; EVAL can likewise make use of it.
 264 (defmacro macrolet-definitionize-fun (context lexenv)
 265   (flet ((make-error-form (control &rest args)
 266            (ecase context
 267              (:compile `(compiler-error ,control ,@args))
 268              (:eval `(error 'simple-program-error
 269                       :format-control ,control
 270                       :format-arguments (list ,@args))))))
 271     `(lambda (definition)
 272       (unless (list-of-length-at-least-p definition 2)
 273         ,(make-error-form "The list ~S is too short to be a legal local macro definition." 'definition))
 274       (destructuring-bind (name arglist &body body) definition
 275         (unless (symbolp name)
 276           ,(make-error-form "The local macro name ~S is not a symbol." 'name))
 277         (unless (listp arglist)
 278           ,(make-error-form "The local macro argument list ~S is not a list." 'arglist))
 279         (let ((whole (gensym "WHOLE"))
 280               (environment (gensym "ENVIRONMENT")))
 281           (multiple-value-bind (body local-decls)
 282               (parse-defmacro arglist whole body name 'macrolet
 283                               :environment environment)
 284             `(,name macro .
 285               ,(compile-in-lexenv
 286                 nil
 287                 `(lambda (,whole ,environment)
 288                   ,@local-decls
 289                   (block ,name ,body))
 290                 ,lexenv))))))))
 291
 292 (defun funcall-in-macrolet-lexenv (definitions fun)
 293   (%funcall-in-foomacrolet-lexenv
 294    (macrolet-definitionize-fun :compile (make-restricted-lexenv *lexenv*))
 295    :funs
 296    definitions
 297    fun))
 298
 299 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 300   #!+sb-doc
 301   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 302   Evaluate the Body-Forms in an environment with the specified local macros
 303   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 304   destructuring lambda list, and the Forms evaluate to the expansion.."
 305   (funcall-in-macrolet-lexenv
 306    definitions
 307    (lambda (&key funs)
 308      (declare (ignore funs))
 309      (ir1-translate-locally body start cont))))
 310
 311 (defmacro symbol-macrolet-definitionize-fun (context)
 312   (flet ((make-error-form (control &rest args)
 313            (ecase context
 314              (:compile `(compiler-error ,control ,@args))
 315              (:eval `(error 'simple-program-error
 316                       :format-control ,control
 317                       :format-arguments (list ,@args))))))
 318     `(lambda (definition)
 319       (unless (proper-list-of-length-p definition 2)
 320        ,(make-error-form "malformed symbol/expansion pair: ~S" 'definition))
 321      (destructuring-bind (name expansion) definition
 322        (unless (symbolp name)
 323          ,(make-error-form
 324            "The local symbol macro name ~S is not a symbol."
 325            'name))
 326        (let ((kind (info :variable :kind name)))
 327          (when (member kind '(:special :constant))
 328            ,(make-error-form
 329              "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 330              'kind 'name)))
 331        `(,name . (MACRO . ,expansion))))))1
 332
 333 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 334   (%funcall-in-foomacrolet-lexenv
 335    (symbol-macrolet-definitionize-fun :compile)
 336    :vars
 337    definitions
 338    fun))
 339
 340 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 341   #!+sb-doc
 342   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 343   Define the Names as symbol macros with the given Expansions. Within the
 344   body, references to a Name will effectively be replaced with the Expansion."
 345   (funcall-in-symbol-macrolet-lexenv
 346    macrobindings
 347    (lambda (&key vars)
 348      (ir1-translate-locally body start cont :vars vars))))
 349 \f
 350 ;;;; %PRIMITIVE
 351 ;;;;
 352 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 353 ;;;; into a funny function.
 354
 355 ;;; Carefully evaluate a list of forms, returning a list of the results.
 356 (defun eval-info-args (args)
 357   (declare (list args))
 358   (handler-case (mapcar #'eval args)
 359     (error (condition)
 360       (compiler-error "Lisp error during evaluation of info args:~%~A"
 361                       condition))))
 362
 363 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 364 ;;; the template, the second is a list of the results of any
 365 ;;; codegen-info args, and the remaining arguments are the runtime
 366 ;;; arguments.
 367 ;;;
 368 ;;; We do various error checking now so that we don't bomb out with
 369 ;;; a fatal error during IR2 conversion.
 370 ;;;
 371 ;;; KLUDGE: It's confusing having multiple names floating around for
 372 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 373 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 374 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 375 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 376 ;;; VOP or %VOP.. -- WHN 2001-06-11
 377 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 378 (def-ir1-translator %primitive ((name &rest args) start cont)
 379   (declare (type symbol name))
 380   (let* ((template (or (gethash name *backend-template-names*)
 381                        (bug "undefined primitive ~A" name)))
 382          (required (length (template-arg-types template)))
 383          (info (template-info-arg-count template))
 384          (min (+ required info))
 385          (nargs (length args)))
 386     (if (template-more-args-type template)
 387         (when (< nargs min)
 388           (bug "Primitive ~A was called with ~R argument~:P, ~
 389                 but wants at least ~R."
 390                name
 391                nargs
 392                min))
 393         (unless (= nargs min)
 394           (bug "Primitive ~A was called with ~R argument~:P, ~
 395                 but wants exactly ~R."
 396                name
 397                nargs
 398                min)))
 399
 400     (when (eq (template-result-types template) :conditional)
 401       (bug "%PRIMITIVE was used with a conditional template."))
 402
 403     (when (template-more-results-type template)
 404       (bug "%PRIMITIVE was used with an unknown values template."))
 405
 406     (ir1-convert start
 407                  cont
 408                  `(%%primitive ',template
 409                                ',(eval-info-args
 410                                   (subseq args required min))
 411                                ,@(subseq args 0 required)
 412                                ,@(subseq args min)))))
 413 \f
 414 ;;;; QUOTE
 415
 416 (def-ir1-translator quote ((thing) start cont)
 417   #!+sb-doc
 418   "QUOTE Value
 419   Return Value without evaluating it."
 420   (reference-constant start cont thing))
 421 \f
 422 ;;;; FUNCTION and NAMED-LAMBDA
 423
 424 (def-ir1-translator function ((thing) start cont)
 425   #!+sb-doc
 426   "FUNCTION Name
 427   Return the lexically apparent definition of the function Name. Name may also
 428   be a lambda expression."
 429   (if (consp thing)
 430       (case (car thing)
 431         ((lambda named-lambda instance-lambda lambda-with-lexenv)
 432          (reference-leaf start
 433                          cont
 434                          (ir1-convert-lambdalike
 435                           thing
 436                           :debug-name (debug-namify "#'~S" thing)
 437                           :allow-debug-catch-tag t)))
 438         ((setf sb!pcl::class-predicate sb!pcl::slot-accessor)
 439          (let ((var (find-lexically-apparent-fun
 440                      thing "as the argument to FUNCTION")))
 441            (reference-leaf start cont var)))
 442         (t
 443          (compiler-error "~S is not a legal function name." thing)))
 444       (let ((var (find-lexically-apparent-fun
 445                   thing "as the argument to FUNCTION")))
 446         (reference-leaf start cont var))))
 447 \f
 448 ;;;; FUNCALL
 449
 450 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 451 ;;; (not symbols). %FUNCALL is used directly in some places where the
 452 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 453 (deftransform funcall ((function &rest args) * *)
 454   (let ((arg-names (make-gensym-list (length args))))
 455     `(lambda (function ,@arg-names)
 456        (%funcall ,(if (csubtypep (continuation-type function)
 457                                  (specifier-type 'function))
 458                       'function
 459                       '(%coerce-callable-to-fun function))
 460                  ,@arg-names))))
 461
 462 (def-ir1-translator %funcall ((function &rest args) start cont)
 463   (let ((fun-cont (make-continuation)))
 464     (ir1-convert start fun-cont function)
 465     (assert-continuation-type fun-cont (specifier-type 'function)
 466                               (lexenv-policy *lexenv*))
 467     (ir1-convert-combination-args fun-cont cont args)))
 468
 469 ;;; This source transform exists to reduce the amount of work for the
 470 ;;; compiler. If the called function is a FUNCTION form, then convert
 471 ;;; directly to %FUNCALL, instead of waiting around for type
 472 ;;; inference.
 473 (define-source-transform funcall (function &rest args)
 474   (if (and (consp function) (eq (car function) 'function))
 475       `(%funcall ,function ,@args)
 476       (values nil t)))
 477
 478 (deftransform %coerce-callable-to-fun ((thing) (function) *
 479                                        :important t)
 480   "optimize away possible call to FDEFINITION at runtime"
 481   'thing)
 482 \f
 483 ;;;; LET and LET*
 484 ;;;;
 485 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 486 ;;;; any pervasive declarations also affect the evaluation of the
 487 ;;;; arguments.)
 488
 489 ;;; Given a list of binding specifiers in the style of LET, return:
 490 ;;;  1. The list of var structures for the variables bound.
 491 ;;;  2. The initial value form for each variable.
 492 ;;;
 493 ;;; The variable names are checked for legality and globally special
 494 ;;; variables are marked as such. Context is the name of the form, for
 495 ;;; error reporting purposes.
 496 (declaim (ftype (function (list symbol) (values list list))
 497                 extract-let-vars))
 498 (defun extract-let-vars (bindings context)
 499   (collect ((vars)
 500             (vals)
 501             (names))
 502     (flet ((get-var (name)
 503              (varify-lambda-arg name
 504                                 (if (eq context 'let*)
 505                                     nil
 506                                     (names)))))
 507       (dolist (spec bindings)
 508         (cond ((atom spec)
 509                (let ((var (get-var spec)))
 510                  (vars var)
 511                  (names spec)
 512                  (vals nil)))
 513               (t
 514                (unless (proper-list-of-length-p spec 1 2)
 515                  (compiler-error "The ~S binding spec ~S is malformed."
 516                                  context
 517                                  spec))
 518                (let* ((name (first spec))
 519                       (var (get-var name)))
 520                  (vars var)
 521                  (names name)
 522                  (vals (second spec)))))))
 523
 524     (values (vars) (vals))))
 525
 526 (def-ir1-translator let ((bindings &body body)
 527                          start cont)
 528   #!+sb-doc
 529   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 530   During evaluation of the Forms, bind the Vars to the result of evaluating the
 531   Value forms. The variables are bound in parallel after all of the Values are
 532   evaluated."
 533   (multiple-value-bind (forms decls) (parse-body body nil)
 534     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 535       (let ((fun-cont (make-continuation)))
 536         (let* ((*lexenv* (process-decls decls vars nil cont))
 537                (fun (ir1-convert-lambda-body
 538                      forms vars
 539                      :debug-name (debug-namify "LET ~S" bindings))))
 540           (reference-leaf start fun-cont fun))
 541         (ir1-convert-combination-args fun-cont cont values)))))
 542
 543 (def-ir1-translator let* ((bindings &body body)
 544                           start cont)
 545   #!+sb-doc
 546   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 547   Similar to LET, but the variables are bound sequentially, allowing each Value
 548   form to reference any of the previous Vars."
 549   (multiple-value-bind (forms decls) (parse-body body nil)
 550     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 551       (let ((*lexenv* (process-decls decls vars nil cont)))
 552         (ir1-convert-aux-bindings start cont forms vars values)))))
 553
 554 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 555 ;;; and SYMBOL-MACROLET
 556 ;;;
 557 ;;; Note that all these things need to preserve toplevel-formness,
 558 ;;; but we don't need to worry about that within an IR1 translator,
 559 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 560 ;;; forms before we hit the IR1 transform level.
 561 (defun ir1-translate-locally (body start cont &key vars funs)
 562   (declare (type list body) (type continuation start cont))
 563   (multiple-value-bind (forms decls) (parse-body body nil)
 564     (let ((*lexenv* (process-decls decls vars funs cont)))
 565       (ir1-convert-aux-bindings start cont forms nil nil))))
 566
 567 (def-ir1-translator locally ((&body body) start cont)
 568   #!+sb-doc
 569   "LOCALLY Declaration* Form*
 570   Sequentially evaluate the Forms in a lexical environment where the
 571   the Declarations have effect. If LOCALLY is a top level form, then
 572   the Forms are also processed as top level forms."
 573   (ir1-translate-locally body start cont))
 574 \f
 575 ;;;; FLET and LABELS
 576
 577 ;;; Given a list of local function specifications in the style of
 578 ;;; FLET, return lists of the function names and of the lambdas which
 579 ;;; are their definitions.
 580 ;;;
 581 ;;; The function names are checked for legality. CONTEXT is the name
 582 ;;; of the form, for error reporting.
 583 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 584 (defun extract-flet-vars (definitions context)
 585   (collect ((names)
 586             (defs))
 587     (dolist (def definitions)
 588       (when (or (atom def) (< (length def) 2))
 589         (compiler-error "The ~S definition spec ~S is malformed." context def))
 590
 591       (let ((name (first def)))
 592         (check-fun-name name)
 593         (names name)
 594         (multiple-value-bind (forms decls) (parse-body (cddr def))
 595           (defs `(lambda ,(second def)
 596                    ,@decls
 597                    (block ,(fun-name-block-name name)
 598                      . ,forms))))))
 599     (values (names) (defs))))
 600
 601 (def-ir1-translator flet ((definitions &body body)
 602                           start cont)
 603   #!+sb-doc
 604   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 605   Evaluate the Body-Forms with some local function definitions. The bindings
 606   do not enclose the definitions; any use of Name in the Forms will refer to
 607   the lexically apparent function definition in the enclosing environment."
 608   (multiple-value-bind (forms decls) (parse-body body nil)
 609     (multiple-value-bind (names defs)
 610         (extract-flet-vars definitions 'flet)
 611       (let* ((fvars (mapcar (lambda (n d)
 612                               (ir1-convert-lambda d
 613                                                   :source-name n
 614                                                   :debug-name (debug-namify
 615                                                                "FLET ~S" n)
 616                                                   :allow-debug-catch-tag t))
 617                             names defs))
 618              (*lexenv* (make-lexenv
 619                         :default (process-decls decls nil fvars cont)
 620                         :funs (pairlis names fvars))))
 621         (ir1-convert-progn-body start cont forms)))))
 622
 623 (def-ir1-translator labels ((definitions &body body) start cont)
 624   #!+sb-doc
 625   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 626   Evaluate the Body-Forms with some local function definitions. The bindings
 627   enclose the new definitions, so the defined functions can call themselves or
 628   each other."
 629   (multiple-value-bind (forms decls) (parse-body body nil)
 630     (multiple-value-bind (names defs)
 631         (extract-flet-vars definitions 'labels)
 632       (let* (;; dummy LABELS functions, to be used as placeholders
 633              ;; during construction of real LABELS functions
 634              (placeholder-funs (mapcar (lambda (name)
 635                                          (make-functional
 636                                           :%source-name name
 637                                           :%debug-name (debug-namify
 638                                                         "LABELS placeholder ~S"
 639                                                         name)))
 640                                        names))
 641              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 642              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 643              ;; the real LABELS functions, compiled in a LEXENV which
 644              ;; includes the dummy LABELS functions
 645              (real-funs
 646               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 647                 (mapcar (lambda (name def)
 648                           (ir1-convert-lambda def
 649                                               :source-name name
 650                                               :debug-name (debug-namify
 651                                                            "LABELS ~S" name)
 652                                               :allow-debug-catch-tag t))
 653                         names defs))))
 654
 655         ;; Modify all the references to the dummy function leaves so
 656         ;; that they point to the real function leaves.
 657         (loop for real-fun in real-funs and
 658               placeholder-cons in placeholder-fenv do
 659               (substitute-leaf real-fun (cdr placeholder-cons))
 660               (setf (cdr placeholder-cons) real-fun))
 661
 662         ;; Voila.
 663         (let ((*lexenv* (make-lexenv
 664                          :default (process-decls decls nil real-funs cont)
 665                          ;; Use a proper FENV here (not the
 666                          ;; placeholder used earlier) so that if the
 667                          ;; lexical environment is used for inline
 668                          ;; expansion we'll get the right functions.
 669                          :funs (pairlis names real-funs))))
 670           (ir1-convert-progn-body start cont forms))))))
 671 \f
 672 ;;;; the THE special operator, and friends
 673
 674 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 675 ;;; continuation that the assertion applies to, TYPE is the type
 676 ;;; specifier and LEXENV is the current lexical environment. NAME is
 677 ;;; the name of the declaration we are doing, for use in error
 678 ;;; messages.
 679 ;;;
 680 ;;; This is somewhat involved, since a type assertion may only be made
 681 ;;; on a continuation, not on a node. We can't just set the
 682 ;;; continuation asserted type and let it go at that, since there may
 683 ;;; be parallel THE's for the same continuation, i.e.
 684 ;;;     (if ...
 685 ;;;      (the foo ...)
 686 ;;;      (the bar ...))
 687 ;;;
 688 ;;; In this case, our representation can do no better than the union
 689 ;;; of these assertions. And if there is a branch with no assertion,
 690 ;;; we have nothing at all. We really need to recognize scoping, since
 691 ;;; we need to be able to discern between parallel assertions (which
 692 ;;; we union) and nested ones (which we intersect).
 693 ;;;
 694 ;;; We represent the scoping by throwing our innermost (intersected)
 695 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 696 ;;; intersect our assertions together. If CONT has no uses yet, we
 697 ;;; have not yet bottomed out on the first COND branch; in this case
 698 ;;; we optimistically assume that this type will be the one we end up
 699 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 700 ;;; than the type that we have the first time we bottom out. Later
 701 ;;; THE's (or the absence thereof) can only weaken this result.
 702 ;;;
 703 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 704 ;;; across COND branches. We can't do it here, since we don't know how
 705 ;;; many branches there are going to be.
 706 (defun ir1ize-the-or-values (type cont lexenv place)
 707   (declare (type continuation cont) (type lexenv lexenv))
 708   (let* ((atype (if (typep type 'ctype) type (compiler-values-specifier-type type)))
 709          (old-atype (or (lexenv-find cont type-restrictions)
 710                         *wild-type*))
 711          (old-ctype (or (lexenv-find cont weakend-type-restrictions)
 712                         *wild-type*))
 713          (intersects (values-types-equal-or-intersect old-atype atype))
 714          (new-atype (values-type-intersection old-atype atype))
 715          (new-ctype (values-type-intersection
 716                      old-ctype (maybe-weaken-check atype (lexenv-policy lexenv)))))
 717     (when (null (find-uses cont))
 718       (setf (continuation-asserted-type cont) new-atype)
 719       (setf (continuation-type-to-check cont) new-ctype))
 720     (when (and (not intersects)
 721                ;; FIXME: Is it really right to look at *LEXENV* here,
 722                ;; instead of looking at the LEXENV argument? Why?
 723                (not (policy *lexenv*
 724                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 725       (compiler-warn
 726        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 727        (type-specifier atype)
 728        place
 729        (type-specifier old-atype)))
 730     (make-lexenv :type-restrictions `((,cont . ,new-atype))
 731                  :weakend-type-restrictions `((,cont . ,new-ctype))
 732                  :default lexenv)))
 733
 734 ;;; Assert that FORM evaluates to the specified type (which may be a
 735 ;;; VALUES type).
 736 ;;;
 737 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 738 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 739 ;;; values. Check that SBCL doesn't have this problem.
 740 (def-ir1-translator the ((type value) start cont)
 741   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 742                                           "in THE declaration")
 743     (ir1-convert start cont value)))
 744
 745 ;;; This is like the THE special form, except that it believes
 746 ;;; whatever you tell it. It will never generate a type check, but
 747 ;;; will cause a warning if the compiler can prove the assertion is
 748 ;;; wrong.
 749 ;;;
 750 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 751 ;;; its uses's types, setting it won't work. Instead we must intersect
 752 ;;; the type with the uses's DERIVED-TYPE.
 753 (def-ir1-translator truly-the ((type value) start cont)
 754   #!+sb-doc
 755   (declare (inline member))
 756   (let ((type (compiler-values-specifier-type type))
 757         (old (find-uses cont)))
 758     (ir1-convert start cont value)
 759     (do-uses (use cont)
 760       (unless (member use old :test #'eq)
 761         (derive-node-type use type)))))
 762 \f
 763 ;;;; SETQ
 764
 765 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 766 ;;; look at the global information. If the name is for a constant,
 767 ;;; then error out.
 768 (def-ir1-translator setq ((&whole source &rest things) start cont)
 769   (let ((len (length things)))
 770     (when (oddp len)
 771       (compiler-error "odd number of args to SETQ: ~S" source))
 772     (if (= len 2)
 773         (let* ((name (first things))
 774                (leaf (or (lexenv-find name vars)
 775                          (find-free-var name))))
 776           (etypecase leaf
 777             (leaf
 778              (when (constant-p leaf)
 779                (compiler-error "~S is a constant and thus can't be set." name))
 780              (when (lambda-var-p leaf)
 781                (let ((home-lambda (continuation-home-lambda-or-null start)))
 782                  (when home-lambda
 783                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 784                (when (lambda-var-ignorep leaf)
 785                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 786                  ;; requires that this be a STYLE-WARNING, not a full warning.
 787                  (compiler-style-warn
 788                   "~S is being set even though it was declared to be ignored."
 789                   name)))
 790              (setq-var start cont leaf (second things)))
 791             (cons
 792              (aver (eq (car leaf) 'MACRO))
 793              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 794             (heap-alien-info
 795              (ir1-convert start cont
 796                           `(%set-heap-alien ',leaf ,(second things))))))
 797         (collect ((sets))
 798           (do ((thing things (cddr thing)))
 799               ((endp thing)
 800                (ir1-convert-progn-body start cont (sets)))
 801             (sets `(setq ,(first thing) ,(second thing))))))))
 802
 803 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 804 ;;; This should only need to be called in SETQ.
 805 (defun setq-var (start cont var value)
 806   (declare (type continuation start cont) (type basic-var var))
 807   (let ((dest (make-continuation)))
 808     (ir1-convert start dest value)
 809     (assert-continuation-type dest
 810                               (or (lexenv-find var type-restrictions)
 811                                   (leaf-type var))
 812                               (lexenv-policy *lexenv*))
 813     (let ((res (make-set :var var :value dest)))
 814       (setf (continuation-dest dest) res)
 815       (setf (leaf-ever-used var) t)
 816       (push res (basic-var-sets var))
 817       (link-node-to-previous-continuation res dest)
 818       (use-continuation res cont))))
 819 \f
 820 ;;;; CATCH, THROW and UNWIND-PROTECT
 821
 822 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 823 ;;; since as as far as IR1 is concerned, it has no interesting
 824 ;;; properties other than receiving multiple-values.
 825 (def-ir1-translator throw ((tag result) start cont)
 826   #!+sb-doc
 827   "Throw Tag Form
 828   Do a non-local exit, return the values of Form from the CATCH whose tag
 829   evaluates to the same thing as Tag."
 830   (ir1-convert start cont
 831                `(multiple-value-call #'%throw ,tag ,result)))
 832
 833 ;;; This is a special special form used to instantiate a cleanup as
 834 ;;; the current cleanup within the body. KIND is the kind of cleanup
 835 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 836 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 837 ;;; and introduce the cleanup into the lexical environment. We
 838 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 839 ;;; cleanup, since this inner cleanup is the interesting one.
 840 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 841   (let ((dummy (make-continuation))
 842         (dummy2 (make-continuation)))
 843     (ir1-convert start dummy mess-up)
 844     (let* ((mess-node (continuation-use dummy))
 845            (cleanup (make-cleanup :kind kind
 846                                   :mess-up mess-node))
 847            (old-cup (lexenv-cleanup *lexenv*))
 848            (*lexenv* (make-lexenv :cleanup cleanup)))
 849       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 850       (ir1-convert dummy dummy2 '(%cleanup-point))
 851       (ir1-convert-progn-body dummy2 cont body))))
 852
 853 ;;; This is a special special form that makes an "escape function"
 854 ;;; which returns unknown values from named block. We convert the
 855 ;;; function, set its kind to :ESCAPE, and then reference it. The
 856 ;;; :ESCAPE kind indicates that this function's purpose is to
 857 ;;; represent a non-local control transfer, and that it might not
 858 ;;; actually have to be compiled.
 859 ;;;
 860 ;;; Note that environment analysis replaces references to escape
 861 ;;; functions with references to the corresponding NLX-INFO structure.
 862 (def-ir1-translator %escape-fun ((tag) start cont)
 863   (let ((fun (ir1-convert-lambda
 864               `(lambda ()
 865                  (return-from ,tag (%unknown-values)))
 866               :debug-name (debug-namify "escape function for ~S" tag))))
 867     (setf (functional-kind fun) :escape)
 868     (reference-leaf start cont fun)))
 869
 870 ;;; Yet another special special form. This one looks up a local
 871 ;;; function and smashes it to a :CLEANUP function, as well as
 872 ;;; referencing it.
 873 (def-ir1-translator %cleanup-fun ((name) start cont)
 874   (let ((fun (lexenv-find name funs)))
 875     (aver (lambda-p fun))
 876     (setf (functional-kind fun) :cleanup)
 877     (reference-leaf start cont fun)))
 878
 879 ;;; We represent the possibility of the control transfer by making an
 880 ;;; "escape function" that does a lexical exit, and instantiate the
 881 ;;; cleanup using %WITHIN-CLEANUP.
 882 (def-ir1-translator catch ((tag &body body) start cont)
 883   #!+sb-doc
 884   "Catch Tag Form*
 885   Evaluates Tag and instantiates it as a catcher while the body forms are
 886   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 887   scope of the body, then control will be transferred to the end of the body
 888   and the thrown values will be returned."
 889   (ir1-convert
 890    start cont
 891    (let ((exit-block (gensym "EXIT-BLOCK-")))
 892      `(block ,exit-block
 893         (%within-cleanup
 894             :catch
 895             (%catch (%escape-fun ,exit-block) ,tag)
 896           ,@body)))))
 897
 898 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 899 ;;; cleanup forms into a local function so that they can be referenced
 900 ;;; both in the case where we are unwound and in any local exits. We
 901 ;;; use %CLEANUP-FUN on this to indicate that reference by
 902 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 903 ;;; an XEP.
 904 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 905   #!+sb-doc
 906   "Unwind-Protect Protected Cleanup*
 907   Evaluate the form Protected, returning its values. The cleanup forms are
 908   evaluated whenever the dynamic scope of the Protected form is exited (either
 909   due to normal completion or a non-local exit such as THROW)."
 910   (ir1-convert
 911    start cont
 912    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 913          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 914          (exit-tag (gensym "EXIT-TAG-"))
 915          (next (gensym "NEXT"))
 916          (start (gensym "START"))
 917          (count (gensym "COUNT")))
 918      `(flet ((,cleanup-fun () ,@cleanup nil))
 919         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 920         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 921         ;; and something can be done to make %ESCAPE-FUN have
 922         ;; dynamic extent too.
 923         (block ,drop-thru-tag
 924           (multiple-value-bind (,next ,start ,count)
 925               (block ,exit-tag
 926                 (%within-cleanup
 927                     :unwind-protect
 928                     (%unwind-protect (%escape-fun ,exit-tag)
 929                                      (%cleanup-fun ,cleanup-fun))
 930                   (return-from ,drop-thru-tag ,protected)))
 931             (,cleanup-fun)
 932             (%continue-unwind ,next ,start ,count)))))))
 933 \f
 934 ;;;; multiple-value stuff
 935
 936 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 937 ;;; MV-COMBINATION.
 938 ;;;
 939 ;;; If there are no arguments, then we convert to a normal
 940 ;;; combination, ensuring that a MV-COMBINATION always has at least
 941 ;;; one argument. This can be regarded as an optimization, but it is
 942 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 943 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 944   #!+sb-doc
 945   "MULTIPLE-VALUE-CALL Function Values-Form*
 946   Call Function, passing all the values of each Values-Form as arguments,
 947   values from the first Values-Form making up the first argument, etc."
 948   (let* ((fun-cont (make-continuation))
 949          (node (if args
 950                    (make-mv-combination fun-cont)
 951                    (make-combination fun-cont))))
 952     (ir1-convert start fun-cont
 953                  (if (and (consp fun) (eq (car fun) 'function))
 954                      fun
 955                      `(%coerce-callable-to-fun ,fun)))
 956     (setf (continuation-dest fun-cont) node)
 957     (collect ((arg-conts))
 958       (let ((this-start fun-cont))
 959         (dolist (arg args)
 960           (let ((this-cont (make-continuation node)))
 961             (ir1-convert this-start this-cont arg)
 962             (setq this-start this-cont)
 963             (arg-conts this-cont)))
 964         (link-node-to-previous-continuation node this-start)
 965         (use-continuation node cont)
 966         (setf (basic-combination-args node) (arg-conts))))))
 967
 968 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 969 ;;; the result code use result continuation (CONT), but transfer
 970 ;;; control to the evaluation of the body. In other words, the result
 971 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 972 ;;; the result.
 973 ;;;
 974 ;;; In order to get the control flow right, we convert the result with
 975 ;;; a dummy result continuation, then convert all the uses of the
 976 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 977 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 978 ;;; that they are consistent. Note that this doesn't amount to
 979 ;;; changing the exit target, since the control destination of an exit
 980 ;;; is determined by the block successor; we are just indicating the
 981 ;;; continuation that the result is delivered to.
 982 ;;;
 983 ;;; We then convert the body, using another dummy continuation in its
 984 ;;; own block as the result. After we are done converting the body, we
 985 ;;; move all predecessors of the dummy end block to CONT's block.
 986 ;;;
 987 ;;; Note that we both exploit and maintain the invariant that the CONT
 988 ;;; to an IR1 convert method either has no block or starts the block
 989 ;;; that control should transfer to after completion for the form.
 990 ;;; Nested MV-PROG1's work because during conversion of the result
 991 ;;; form, we use dummy continuation whose block is the true control
 992 ;;; destination.
 993 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
 994   #!+sb-doc
 995   "MULTIPLE-VALUE-PROG1 Values-Form Form*
 996   Evaluate Values-Form and then the Forms, but return all the values of
 997   Values-Form."
 998   (continuation-starts-block cont)
 999   (let* ((dummy-result (make-continuation))
1000          (dummy-start (make-continuation))
1001          (cont-block (continuation-block cont)))
1002     (continuation-starts-block dummy-start)
1003     (ir1-convert start dummy-start result)
1004
1005     (with-continuation-type-assertion
1006         ;; FIXME: policy
1007         (cont (continuation-asserted-type dummy-start)
1008               "of the first form")
1009       (substitute-continuation-uses cont dummy-start))
1010
1011     (continuation-starts-block dummy-result)
1012     (ir1-convert-progn-body dummy-start dummy-result forms)
1013     (let ((end-block (continuation-block dummy-result)))
1014       (dolist (pred (block-pred end-block))
1015         (unlink-blocks pred end-block)
1016         (link-blocks pred cont-block))
1017       (aver (not (continuation-dest dummy-result)))
1018       (delete-continuation dummy-result)
1019       (remove-from-dfo end-block))))
1020 \f
1021 ;;;; interface to defining macros
1022
1023 ;;; Old CMUCL comment:
1024 ;;;
1025 ;;;   Return a new source path with any stuff intervening between the
1026 ;;;   current path and the first form beginning with NAME stripped
1027 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1028 ;;;   prevent annoying error messages.
1029 ;;;
1030 ;;; Now that we have implementations of DEFmumble macros in terms of
1031 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1032 ;;; worth figuring out why it was used, and maybe doing analogous
1033 ;;; munging to the functions created in the expanders for the macros.
1034 (defun revert-source-path (name)
1035   (do ((path *current-path* (cdr path)))
1036       ((null path) *current-path*)
1037     (let ((first (first path)))
1038       (when (or (eq first name)
1039                 (eq first 'original-source-start))
1040         (return path)))))