src/compiler/ir1-translators.lisp

   1 ;;;; the usual place for DEF-IR1-TRANSLATOR forms (and their
   2 ;;;; close personal friends)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; special forms for control
  16
  17 (def-ir1-translator progn ((&rest forms) start cont)
  18   #!+sb-doc
  19   "Progn Form*
  20   Evaluates each Form in order, returning the values of the last form. With no
  21   forms, returns NIL."
  22   (ir1-convert-progn-body start cont forms))
  23
  24 (def-ir1-translator if ((test then &optional else) start cont)
  25   #!+sb-doc
  26   "If Predicate Then [Else]
  27   If Predicate evaluates to non-null, evaluate Then and returns its values,
  28   otherwise evaluate Else and return its values. Else defaults to NIL."
  29   (let* ((pred (make-continuation))
  30          (then-cont (make-continuation))
  31          (then-block (continuation-starts-block then-cont))
  32          (else-cont (make-continuation))
  33          (else-block (continuation-starts-block else-cont))
  34          (dummy-cont (make-continuation))
  35          (node (make-if :test pred
  36                         :consequent then-block
  37                         :alternative else-block)))
  38     (setf (continuation-dest pred) node)
  39     (ir1-convert start pred test)
  40     (link-node-to-previous-continuation node pred)
  41     (use-continuation node dummy-cont)
  42
  43     (let ((start-block (continuation-block pred)))
  44       (setf (block-last start-block) node)
  45       (continuation-starts-block cont)
  46
  47       (link-blocks start-block then-block)
  48       (link-blocks start-block else-block))
  49
  50     (ir1-convert then-cont cont then)
  51     (ir1-convert else-cont cont else)))
  52 \f
  53 ;;;; BLOCK and TAGBODY
  54
  55 ;;;; We make an ENTRY node to mark the start and a :ENTRY cleanup to
  56 ;;;; mark its extent. When doing GO or RETURN-FROM, we emit an EXIT
  57 ;;;; node.
  58
  59 ;;; Make a :ENTRY cleanup and emit an ENTRY node, then convert the
  60 ;;; body in the modified environment. We make CONT start a block now,
  61 ;;; since if it was done later, the block would be in the wrong
  62 ;;; environment.
  63 (def-ir1-translator block ((name &rest forms) start cont)
  64   #!+sb-doc
  65   "Block Name Form*
  66   Evaluate the Forms as a PROGN. Within the lexical scope of the body,
  67   (RETURN-FROM Name Value-Form) can be used to exit the form, returning the
  68   result of Value-Form."
  69   (unless (symbolp name)
  70     (compiler-error "The block name ~S is not a symbol." name))
  71   (continuation-starts-block cont)
  72   (let* ((dummy (make-continuation))
  73          (entry (make-entry))
  74          (cleanup (make-cleanup :kind :block
  75                                 :mess-up entry)))
  76     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
  77     (setf (entry-cleanup entry) cleanup)
  78     (link-node-to-previous-continuation entry start)
  79     (use-continuation entry dummy)
  80
  81     (let* ((env-entry (list entry cont))
  82            (*lexenv* (make-lexenv :blocks (list (cons name env-entry))
  83                                   :cleanup cleanup)))
  84       (push env-entry (continuation-lexenv-uses cont))
  85       (ir1-convert-progn-body dummy cont forms))))
  86
  87 (def-ir1-translator return-from ((name &optional value) start cont)
  88   #!+sb-doc
  89   "Return-From Block-Name Value-Form
  90   Evaluate the Value-Form, returning its values from the lexically enclosing
  91   BLOCK Block-Name. This is constrained to be used only within the dynamic
  92   extent of the BLOCK."
  93   ;; CMU CL comment:
  94   ;;   We make CONT start a block just so that it will have a block
  95   ;;   assigned. People assume that when they pass a continuation into
  96   ;;   IR1-CONVERT as CONT, it will have a block when it is done.
  97   ;; KLUDGE: Note that this block is basically fictitious. In the code
  98   ;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
  99   ;; it's the block which answers the question "which block is
 100   ;; the (SETQ X 3) in?" when the right answer is that (SETQ X 3) is
 101   ;; dead code and so doesn't really have a block at all. The existence
 102   ;; of this block, and that way that it doesn't explicitly say
 103   ;; "I'm actually nowhere at all" makes some logic (e.g.
 104   ;; BLOCK-HOME-LAMBDA-OR-NULL) more obscure, and it might be better
 105   ;; to get rid of it, perhaps using a special placeholder value
 106   ;; to indicate the orphanedness of the code.
 107   (continuation-starts-block cont)
 108   (let* ((found (or (lexenv-find name blocks)
 109                     (compiler-error "return for unknown block: ~S" name)))
 110          (value-cont (make-continuation))
 111          (entry (first found))
 112          (exit (make-exit :entry entry
 113                           :value value-cont)))
 114     (push exit (entry-exits entry))
 115     (setf (continuation-dest value-cont) exit)
 116     (ir1-convert start value-cont value)
 117     (link-node-to-previous-continuation exit value-cont)
 118     (let ((home-lambda (continuation-home-lambda-or-null start)))
 119       (when home-lambda
 120         (push entry (lambda-calls-or-closes home-lambda))))
 121     (use-continuation exit (second found))))
 122
 123 ;;; Return a list of the segments of a TAGBODY. Each segment looks
 124 ;;; like (<tag> <form>* (go <next tag>)). That is, we break up the
 125 ;;; tagbody into segments of non-tag statements, and explicitly
 126 ;;; represent the drop-through with a GO. The first segment has a
 127 ;;; dummy NIL tag, since it represents code before the first tag. The
 128 ;;; last segment (which may also be the first segment) ends in NIL
 129 ;;; rather than a GO.
 130 (defun parse-tagbody (body)
 131   (declare (list body))
 132   (collect ((segments))
 133     (let ((current (cons nil body)))
 134       (loop
 135         (let ((tag-pos (position-if (complement #'listp) current :start 1)))
 136           (unless tag-pos
 137             (segments `(,@current nil))
 138             (return))
 139           (let ((tag (elt current tag-pos)))
 140             (when (assoc tag (segments))
 141               (compiler-error
 142                "The tag ~S appears more than once in the tagbody."
 143                tag))
 144             (unless (or (symbolp tag) (integerp tag))
 145               (compiler-error "~S is not a legal tagbody statement." tag))
 146             (segments `(,@(subseq current 0 tag-pos) (go ,tag))))
 147           (setq current (nthcdr tag-pos current)))))
 148     (segments)))
 149
 150 ;;; Set up the cleanup, emitting the entry node. Then make a block for
 151 ;;; each tag, building up the tag list for LEXENV-TAGS as we go.
 152 ;;; Finally, convert each segment with the precomputed Start and Cont
 153 ;;; values.
 154 (def-ir1-translator tagbody ((&rest statements) start cont)
 155   #!+sb-doc
 156   "Tagbody {Tag | Statement}*
 157   Define tags for used with GO. The Statements are evaluated in order
 158   (skipping Tags) and NIL is returned. If a statement contains a GO to a
 159   defined Tag within the lexical scope of the form, then control is transferred
 160   to the next statement following that tag. A Tag must an integer or a
 161   symbol. A statement must be a list. Other objects are illegal within the
 162   body."
 163   (continuation-starts-block cont)
 164   (let* ((dummy (make-continuation))
 165          (entry (make-entry))
 166          (segments (parse-tagbody statements))
 167          (cleanup (make-cleanup :kind :tagbody
 168                                 :mess-up entry)))
 169     (push entry (lambda-entries (lexenv-lambda *lexenv*)))
 170     (setf (entry-cleanup entry) cleanup)
 171     (link-node-to-previous-continuation entry start)
 172     (use-continuation entry dummy)
 173
 174     (collect ((tags)
 175               (starts)
 176               (conts))
 177       (starts dummy)
 178       (dolist (segment (rest segments))
 179         (let* ((tag-cont (make-continuation))
 180                (tag (list (car segment) entry tag-cont)))
 181           (conts tag-cont)
 182           (starts tag-cont)
 183           (continuation-starts-block tag-cont)
 184           (tags tag)
 185           (push (cdr tag) (continuation-lexenv-uses tag-cont))))
 186       (conts cont)
 187
 188       (let ((*lexenv* (make-lexenv :cleanup cleanup :tags (tags))))
 189         (mapc (lambda (segment start cont)
 190                 (ir1-convert-progn-body start cont (rest segment)))
 191               segments (starts) (conts))))))
 192
 193 ;;; Emit an EXIT node without any value.
 194 (def-ir1-translator go ((tag) start cont)
 195   #!+sb-doc
 196   "Go Tag
 197   Transfer control to the named Tag in the lexically enclosing TAGBODY. This
 198   is constrained to be used only within the dynamic extent of the TAGBODY."
 199   (continuation-starts-block cont)
 200   (let* ((found (or (lexenv-find tag tags :test #'eql)
 201                     (compiler-error "attempt to GO to nonexistent tag: ~S"
 202                                     tag)))
 203          (entry (first found))
 204          (exit (make-exit :entry entry)))
 205     (push exit (entry-exits entry))
 206     (link-node-to-previous-continuation exit start)
 207     (let ((home-lambda (continuation-home-lambda-or-null start)))
 208       (when home-lambda
 209         (push entry (lambda-calls-or-closes home-lambda))))
 210     (use-continuation exit (second found))))
 211 \f
 212 ;;;; translators for compiler-magic special forms
 213
 214 ;;; This handles EVAL-WHEN in non-top-level forms. (EVAL-WHENs in top
 215 ;;; level forms are picked off and handled by PROCESS-TOPLEVEL-FORM,
 216 ;;; so that they're never seen at this level.)
 217 ;;;
 218 ;;; ANSI "3.2.3.1 Processing of Top Level Forms" says that processing
 219 ;;; of non-top-level EVAL-WHENs is very simple:
 220 ;;;   EVAL-WHEN forms cause compile-time evaluation only at top level.
 221 ;;;   Both :COMPILE-TOPLEVEL and :LOAD-TOPLEVEL situation specifications
 222 ;;;   are ignored for non-top-level forms. For non-top-level forms, an
 223 ;;;   eval-when specifying the :EXECUTE situation is treated as an
 224 ;;;   implicit PROGN including the forms in the body of the EVAL-WHEN
 225 ;;;   form; otherwise, the forms in the body are ignored.
 226 (def-ir1-translator eval-when ((situations &rest forms) start cont)
 227   #!+sb-doc
 228   "EVAL-WHEN (Situation*) Form*
 229   Evaluate the Forms in the specified Situations (any of :COMPILE-TOPLEVEL,
 230   :LOAD-TOPLEVEL, or :EXECUTE, or (deprecated) COMPILE, LOAD, or EVAL)."
 231   (multiple-value-bind (ct lt e) (parse-eval-when-situations situations)
 232     (declare (ignore ct lt))
 233     (ir1-convert-progn-body start cont (and e forms)))
 234   (values))
 235
 236 ;;; common logic for MACROLET and SYMBOL-MACROLET
 237 ;;;
 238 ;;; Call DEFINITIONIZE-FUN on each element of DEFINITIONS to find its
 239 ;;; in-lexenv representation, stuff the results into *LEXENV*, and
 240 ;;; call FUN (with no arguments).
 241 (defun %funcall-in-foomacrolet-lexenv (definitionize-fun
 242                                        definitionize-keyword
 243                                        definitions
 244                                        fun)
 245   (declare (type function definitionize-fun fun))
 246   (declare (type (member :vars :funs) definitionize-keyword))
 247   (declare (type list definitions))
 248   (unless (= (length definitions)
 249              (length (remove-duplicates definitions :key #'first)))
 250     (compiler-style-warn "duplicate definitions in ~S" definitions))
 251   (let* ((processed-definitions (mapcar definitionize-fun definitions))
 252          (*lexenv* (make-lexenv definitionize-keyword processed-definitions)))
 253     (funcall fun definitionize-keyword processed-definitions)))
 254
 255 ;;; Tweak LEXENV to include the DEFINITIONS from a MACROLET, then
 256 ;;; call FUN (with no arguments).
 257 ;;;
 258 ;;; This is split off from the IR1 convert method so that it can be
 259 ;;; shared by the special-case top level MACROLET processing code, and
 260 ;;; further split so that the special-case MACROLET processing code in
 261 ;;; EVAL can likewise make use of it.
 262 (defmacro macrolet-definitionize-fun (context lexenv)
 263   (flet ((make-error-form (control &rest args)
 264            (ecase context
 265              (:compile `(compiler-error ,control ,@args))
 266              (:eval `(error 'simple-program-error
 267                       :format-control ,control
 268                       :format-arguments (list ,@args))))))
 269     `(lambda (definition)
 270       (unless (list-of-length-at-least-p definition 2)
 271         ,(make-error-form "The list ~S is too short to be a legal local macro definition." 'definition))
 272       (destructuring-bind (name arglist &body body) definition
 273         (unless (symbolp name)
 274           ,(make-error-form "The local macro name ~S is not a symbol." 'name))
 275         (unless (listp arglist)
 276           ,(make-error-form "The local macro argument list ~S is not a list." 'arglist))
 277         (let ((whole (gensym "WHOLE"))
 278               (environment (gensym "ENVIRONMENT")))
 279           (multiple-value-bind (body local-decls)
 280               (parse-defmacro arglist whole body name 'macrolet
 281                               :environment environment)
 282             `(,name macro .
 283               ,(compile-in-lexenv
 284                 nil
 285                 `(lambda (,whole ,environment)
 286                   ,@local-decls
 287                   (block ,name ,body))
 288                 ,lexenv))))))))
 289
 290 (defun funcall-in-macrolet-lexenv (definitions fun)
 291   (%funcall-in-foomacrolet-lexenv
 292    (macrolet-definitionize-fun :compile (make-restricted-lexenv *lexenv*))
 293    :funs
 294    definitions
 295    fun))
 296
 297 (def-ir1-translator macrolet ((definitions &rest body) start cont)
 298   #!+sb-doc
 299   "MACROLET ({(Name Lambda-List Form*)}*) Body-Form*
 300   Evaluate the Body-Forms in an environment with the specified local macros
 301   defined. Name is the local macro name, Lambda-List is the DEFMACRO style
 302   destructuring lambda list, and the Forms evaluate to the expansion.."
 303   (funcall-in-macrolet-lexenv
 304    definitions
 305    (lambda (&key funs)
 306      (declare (ignore funs))
 307      (ir1-translate-locally body start cont))))
 308
 309 (defmacro symbol-macrolet-definitionize-fun (context)
 310   (flet ((make-error-form (control &rest args)
 311            (ecase context
 312              (:compile `(compiler-error ,control ,@args))
 313              (:eval `(error 'simple-program-error
 314                       :format-control ,control
 315                       :format-arguments (list ,@args))))))
 316     `(lambda (definition)
 317       (unless (proper-list-of-length-p definition 2)
 318        ,(make-error-form "malformed symbol/expansion pair: ~S" 'definition))
 319      (destructuring-bind (name expansion) definition
 320        (unless (symbolp name)
 321          ,(make-error-form
 322            "The local symbol macro name ~S is not a symbol."
 323            'name))
 324        (let ((kind (info :variable :kind name)))
 325          (when (member kind '(:special :constant))
 326            ,(make-error-form
 327              "Attempt to bind a ~(~A~) variable with SYMBOL-MACROLET: ~S"
 328              'kind 'name)))
 329        `(,name . (MACRO . ,expansion))))))1
 330
 331 (defun funcall-in-symbol-macrolet-lexenv (definitions fun)
 332   (%funcall-in-foomacrolet-lexenv
 333    (symbol-macrolet-definitionize-fun :compile)
 334    :vars
 335    definitions
 336    fun))
 337
 338 (def-ir1-translator symbol-macrolet ((macrobindings &body body) start cont)
 339   #!+sb-doc
 340   "SYMBOL-MACROLET ({(Name Expansion)}*) Decl* Form*
 341   Define the Names as symbol macros with the given Expansions. Within the
 342   body, references to a Name will effectively be replaced with the Expansion."
 343   (funcall-in-symbol-macrolet-lexenv
 344    macrobindings
 345    (lambda (&key vars)
 346      (ir1-translate-locally body start cont :vars vars))))
 347
 348 ;;; not really a special form, but..
 349 (def-ir1-translator declare ((&rest stuff) start cont)
 350   (declare (ignore stuff))
 351   ;; We ignore START and CONT too, but we can't use DECLARE IGNORE to
 352   ;; tell the compiler about it here, because the DEF-IR1-TRANSLATOR
 353   ;; macro would put the DECLARE in the wrong place, so..
 354   start cont
 355   (compiler-error "misplaced declaration"))
 356 \f
 357 ;;;; %PRIMITIVE
 358 ;;;;
 359 ;;;; Uses of %PRIMITIVE are either expanded into Lisp code or turned
 360 ;;;; into a funny function.
 361
 362 ;;; Carefully evaluate a list of forms, returning a list of the results.
 363 (defun eval-info-args (args)
 364   (declare (list args))
 365   (handler-case (mapcar #'eval args)
 366     (error (condition)
 367       (compiler-error "Lisp error during evaluation of info args:~%~A"
 368                       condition))))
 369
 370 ;;; Convert to the %%PRIMITIVE funny function. The first argument is
 371 ;;; the template, the second is a list of the results of any
 372 ;;; codegen-info args, and the remaining arguments are the runtime
 373 ;;; arguments.
 374 ;;;
 375 ;;; We do various error checking now so that we don't bomb out with
 376 ;;; a fatal error during IR2 conversion.
 377 ;;;
 378 ;;; KLUDGE: It's confusing having multiple names floating around for
 379 ;;; nearly the same concept: PRIMITIVE, TEMPLATE, VOP. Now that CMU
 380 ;;; CL's *PRIMITIVE-TRANSLATORS* stuff is gone, we could call
 381 ;;; primitives VOPs, rename TEMPLATE to VOP-TEMPLATE, rename
 382 ;;; BACKEND-TEMPLATE-NAMES to BACKEND-VOPS, and rename %PRIMITIVE to
 383 ;;; VOP or %VOP.. -- WHN 2001-06-11
 384 ;;; FIXME: Look at doing this ^, it doesn't look too hard actually.
 385 (def-ir1-translator %primitive ((name &rest args) start cont)
 386   (declare (type symbol name))
 387   (let* ((template (or (gethash name *backend-template-names*)
 388                        (bug "undefined primitive ~A" name)))
 389          (required (length (template-arg-types template)))
 390          (info (template-info-arg-count template))
 391          (min (+ required info))
 392          (nargs (length args)))
 393     (if (template-more-args-type template)
 394         (when (< nargs min)
 395           (bug "Primitive ~A was called with ~R argument~:P, ~
 396                 but wants at least ~R."
 397                name
 398                nargs
 399                min))
 400         (unless (= nargs min)
 401           (bug "Primitive ~A was called with ~R argument~:P, ~
 402                 but wants exactly ~R."
 403                name
 404                nargs
 405                min)))
 406
 407     (when (eq (template-result-types template) :conditional)
 408       (bug "%PRIMITIVE was used with a conditional template."))
 409
 410     (when (template-more-results-type template)
 411       (bug "%PRIMITIVE was used with an unknown values template."))
 412
 413     (ir1-convert start
 414                  cont
 415                  `(%%primitive ',template
 416                                ',(eval-info-args
 417                                   (subseq args required min))
 418                                ,@(subseq args 0 required)
 419                                ,@(subseq args min)))))
 420 \f
 421 ;;;; QUOTE
 422
 423 (def-ir1-translator quote ((thing) start cont)
 424   #!+sb-doc
 425   "QUOTE Value
 426   Return Value without evaluating it."
 427   (reference-constant start cont thing))
 428 \f
 429 ;;;; FUNCTION and NAMED-LAMBDA
 430
 431 (def-ir1-translator function ((thing) start cont)
 432   #!+sb-doc
 433   "FUNCTION Name
 434   Return the lexically apparent definition of the function Name. Name may also
 435   be a lambda expression."
 436   (if (consp thing)
 437       (case (car thing)
 438         ((lambda named-lambda instance-lambda lambda-with-lexenv)
 439          (reference-leaf start
 440                          cont
 441                          (ir1-convert-lambdalike
 442                           thing
 443                           :debug-name (debug-namify "#'~S" thing)
 444                           :allow-debug-catch-tag t)))
 445         ((setf)
 446          (let ((var (find-lexically-apparent-fun
 447                      thing "as the argument to FUNCTION")))
 448            (reference-leaf start cont var)))
 449         (t
 450          (compiler-error "~S is not a legal function name." thing)))
 451       (let ((var (find-lexically-apparent-fun
 452                   thing "as the argument to FUNCTION")))
 453         (reference-leaf start cont var))))
 454 \f
 455 ;;;; FUNCALL
 456
 457 ;;; FUNCALL is implemented on %FUNCALL, which can only call functions
 458 ;;; (not symbols). %FUNCALL is used directly in some places where the
 459 ;;; call should always be open-coded even if FUNCALL is :NOTINLINE.
 460 (deftransform funcall ((function &rest args) * *)
 461   (let ((arg-names (make-gensym-list (length args))))
 462     `(lambda (function ,@arg-names)
 463        (%funcall ,(if (csubtypep (continuation-type function)
 464                                  (specifier-type 'function))
 465                       'function
 466                       '(%coerce-callable-to-fun function))
 467                  ,@arg-names))))
 468
 469 (def-ir1-translator %funcall ((function &rest args) start cont)
 470   (let ((fun-cont (make-continuation)))
 471     (ir1-convert start fun-cont function)
 472     (assert-continuation-type fun-cont (specifier-type 'function)
 473                               (lexenv-policy *lexenv*))
 474     (ir1-convert-combination-args fun-cont cont args)))
 475
 476 ;;; This source transform exists to reduce the amount of work for the
 477 ;;; compiler. If the called function is a FUNCTION form, then convert
 478 ;;; directly to %FUNCALL, instead of waiting around for type
 479 ;;; inference.
 480 (define-source-transform funcall (function &rest args)
 481   (if (and (consp function) (eq (car function) 'function))
 482       `(%funcall ,function ,@args)
 483       (values nil t)))
 484
 485 (deftransform %coerce-callable-to-fun ((thing) (function) *
 486                                        :important t)
 487   "optimize away possible call to FDEFINITION at runtime"
 488   'thing)
 489 \f
 490 ;;;; LET and LET*
 491 ;;;;
 492 ;;;; (LET and LET* can't be implemented as macros due to the fact that
 493 ;;;; any pervasive declarations also affect the evaluation of the
 494 ;;;; arguments.)
 495
 496 ;;; Given a list of binding specifiers in the style of LET, return:
 497 ;;;  1. The list of var structures for the variables bound.
 498 ;;;  2. The initial value form for each variable.
 499 ;;;
 500 ;;; The variable names are checked for legality and globally special
 501 ;;; variables are marked as such. Context is the name of the form, for
 502 ;;; error reporting purposes.
 503 (declaim (ftype (function (list symbol) (values list list))
 504                 extract-let-vars))
 505 (defun extract-let-vars (bindings context)
 506   (collect ((vars)
 507             (vals)
 508             (names))
 509     (flet ((get-var (name)
 510              (varify-lambda-arg name
 511                                 (if (eq context 'let*)
 512                                     nil
 513                                     (names)))))
 514       (dolist (spec bindings)
 515         (cond ((atom spec)
 516                (let ((var (get-var spec)))
 517                  (vars var)
 518                  (names spec)
 519                  (vals nil)))
 520               (t
 521                (unless (proper-list-of-length-p spec 1 2)
 522                  (compiler-error "The ~S binding spec ~S is malformed."
 523                                  context
 524                                  spec))
 525                (let* ((name (first spec))
 526                       (var (get-var name)))
 527                  (vars var)
 528                  (names name)
 529                  (vals (second spec)))))))
 530
 531     (values (vars) (vals))))
 532
 533 (def-ir1-translator let ((bindings &body body)
 534                          start cont)
 535   #!+sb-doc
 536   "LET ({(Var [Value]) | Var}*) Declaration* Form*
 537   During evaluation of the Forms, bind the Vars to the result of evaluating the
 538   Value forms. The variables are bound in parallel after all of the Values are
 539   evaluated."
 540   (multiple-value-bind (forms decls) (parse-body body nil)
 541     (multiple-value-bind (vars values) (extract-let-vars bindings 'let)
 542       (let ((fun-cont (make-continuation)))
 543         (let* ((*lexenv* (process-decls decls vars nil cont))
 544                (fun (ir1-convert-lambda-body
 545                      forms vars
 546                      :debug-name (debug-namify "LET ~S" bindings))))
 547           (reference-leaf start fun-cont fun))
 548         (ir1-convert-combination-args fun-cont cont values)))))
 549
 550 (def-ir1-translator let* ((bindings &body body)
 551                           start cont)
 552   #!+sb-doc
 553   "LET* ({(Var [Value]) | Var}*) Declaration* Form*
 554   Similar to LET, but the variables are bound sequentially, allowing each Value
 555   form to reference any of the previous Vars."
 556   (multiple-value-bind (forms decls) (parse-body body nil)
 557     (multiple-value-bind (vars values) (extract-let-vars bindings 'let*)
 558       (let ((*lexenv* (process-decls decls vars nil cont)))
 559         (ir1-convert-aux-bindings start cont forms vars values)))))
 560
 561 ;;; logic shared between IR1 translators for LOCALLY, MACROLET,
 562 ;;; and SYMBOL-MACROLET
 563 ;;;
 564 ;;; Note that all these things need to preserve toplevel-formness,
 565 ;;; but we don't need to worry about that within an IR1 translator,
 566 ;;; since toplevel-formness is picked off by PROCESS-TOPLEVEL-FOO
 567 ;;; forms before we hit the IR1 transform level.
 568 (defun ir1-translate-locally (body start cont &key vars funs)
 569   (declare (type list body) (type continuation start cont))
 570   (multiple-value-bind (forms decls) (parse-body body nil)
 571     (let ((*lexenv* (process-decls decls vars funs cont)))
 572       (ir1-convert-aux-bindings start cont forms nil nil))))
 573
 574 (def-ir1-translator locally ((&body body) start cont)
 575   #!+sb-doc
 576   "LOCALLY Declaration* Form*
 577   Sequentially evaluate the Forms in a lexical environment where the
 578   the Declarations have effect. If LOCALLY is a top level form, then
 579   the Forms are also processed as top level forms."
 580   (ir1-translate-locally body start cont))
 581 \f
 582 ;;;; FLET and LABELS
 583
 584 ;;; Given a list of local function specifications in the style of
 585 ;;; FLET, return lists of the function names and of the lambdas which
 586 ;;; are their definitions.
 587 ;;;
 588 ;;; The function names are checked for legality. CONTEXT is the name
 589 ;;; of the form, for error reporting.
 590 (declaim (ftype (function (list symbol) (values list list)) extract-flet-vars))
 591 (defun extract-flet-vars (definitions context)
 592   (collect ((names)
 593             (defs))
 594     (dolist (def definitions)
 595       (when (or (atom def) (< (length def) 2))
 596         (compiler-error "The ~S definition spec ~S is malformed." context def))
 597
 598       (let ((name (first def)))
 599         (check-fun-name name)
 600         (names name)
 601         (multiple-value-bind (forms decls) (parse-body (cddr def))
 602           (defs `(lambda ,(second def)
 603                    ,@decls
 604                    (block ,(fun-name-block-name name)
 605                      . ,forms))))))
 606     (values (names) (defs))))
 607
 608 (def-ir1-translator flet ((definitions &body body)
 609                           start cont)
 610   #!+sb-doc
 611   "FLET ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 612   Evaluate the Body-Forms with some local function definitions. The bindings
 613   do not enclose the definitions; any use of Name in the Forms will refer to
 614   the lexically apparent function definition in the enclosing environment."
 615   (multiple-value-bind (forms decls) (parse-body body nil)
 616     (multiple-value-bind (names defs)
 617         (extract-flet-vars definitions 'flet)
 618       (let* ((fvars (mapcar (lambda (n d)
 619                               (ir1-convert-lambda d
 620                                                   :source-name n
 621                                                   :debug-name (debug-namify
 622                                                                "FLET ~S" n)
 623                                                   :allow-debug-catch-tag t))
 624                             names defs))
 625              (*lexenv* (make-lexenv
 626                         :default (process-decls decls nil fvars cont)
 627                         :funs (pairlis names fvars))))
 628         (ir1-convert-progn-body start cont forms)))))
 629
 630 (def-ir1-translator labels ((definitions &body body) start cont)
 631   #!+sb-doc
 632   "LABELS ({(Name Lambda-List Declaration* Form*)}*) Declaration* Body-Form*
 633   Evaluate the Body-Forms with some local function definitions. The bindings
 634   enclose the new definitions, so the defined functions can call themselves or
 635   each other."
 636   (multiple-value-bind (forms decls) (parse-body body nil)
 637     (multiple-value-bind (names defs)
 638         (extract-flet-vars definitions 'labels)
 639       (let* (;; dummy LABELS functions, to be used as placeholders
 640              ;; during construction of real LABELS functions
 641              (placeholder-funs (mapcar (lambda (name)
 642                                          (make-functional
 643                                           :%source-name name
 644                                           :%debug-name (debug-namify
 645                                                         "LABELS placeholder ~S"
 646                                                         name)))
 647                                        names))
 648              ;; (like PAIRLIS but guaranteed to preserve ordering:)
 649              (placeholder-fenv (mapcar #'cons names placeholder-funs))
 650              ;; the real LABELS functions, compiled in a LEXENV which
 651              ;; includes the dummy LABELS functions
 652              (real-funs
 653               (let ((*lexenv* (make-lexenv :funs placeholder-fenv)))
 654                 (mapcar (lambda (name def)
 655                           (ir1-convert-lambda def
 656                                               :source-name name
 657                                               :debug-name (debug-namify
 658                                                            "LABELS ~S" name)
 659                                               :allow-debug-catch-tag t))
 660                         names defs))))
 661
 662         ;; Modify all the references to the dummy function leaves so
 663         ;; that they point to the real function leaves.
 664         (loop for real-fun in real-funs and
 665               placeholder-cons in placeholder-fenv do
 666               (substitute-leaf real-fun (cdr placeholder-cons))
 667               (setf (cdr placeholder-cons) real-fun))
 668
 669         ;; Voila.
 670         (let ((*lexenv* (make-lexenv
 671                          :default (process-decls decls nil real-funs cont)
 672                          ;; Use a proper FENV here (not the
 673                          ;; placeholder used earlier) so that if the
 674                          ;; lexical environment is used for inline
 675                          ;; expansion we'll get the right functions.
 676                          :funs (pairlis names real-funs))))
 677           (ir1-convert-progn-body start cont forms))))))
 678 \f
 679 ;;;; the THE special operator, and friends
 680
 681 ;;; Do stuff to recognize a THE or VALUES declaration. CONT is the
 682 ;;; continuation that the assertion applies to, TYPE is the type
 683 ;;; specifier and LEXENV is the current lexical environment. NAME is
 684 ;;; the name of the declaration we are doing, for use in error
 685 ;;; messages.
 686 ;;;
 687 ;;; This is somewhat involved, since a type assertion may only be made
 688 ;;; on a continuation, not on a node. We can't just set the
 689 ;;; continuation asserted type and let it go at that, since there may
 690 ;;; be parallel THE's for the same continuation, i.e.
 691 ;;;     (if ...
 692 ;;;      (the foo ...)
 693 ;;;      (the bar ...))
 694 ;;;
 695 ;;; In this case, our representation can do no better than the union
 696 ;;; of these assertions. And if there is a branch with no assertion,
 697 ;;; we have nothing at all. We really need to recognize scoping, since
 698 ;;; we need to be able to discern between parallel assertions (which
 699 ;;; we union) and nested ones (which we intersect).
 700 ;;;
 701 ;;; We represent the scoping by throwing our innermost (intersected)
 702 ;;; assertion on CONT into the TYPE-RESTRICTIONS. As we go down, we
 703 ;;; intersect our assertions together. If CONT has no uses yet, we
 704 ;;; have not yet bottomed out on the first COND branch; in this case
 705 ;;; we optimistically assume that this type will be the one we end up
 706 ;;; with, and set the ASSERTED-TYPE to it. We can never get better
 707 ;;; than the type that we have the first time we bottom out. Later
 708 ;;; THE's (or the absence thereof) can only weaken this result.
 709 ;;;
 710 ;;; We make this work by getting USE-CONTINUATION to do the unioning
 711 ;;; across COND branches. We can't do it here, since we don't know how
 712 ;;; many branches there are going to be.
 713 (defun ir1ize-the-or-values (type cont lexenv place)
 714   (declare (type continuation cont) (type lexenv lexenv))
 715   (let* ((atype (if (typep type 'ctype) type (compiler-values-specifier-type type)))
 716          (old-atype (or (lexenv-find cont type-restrictions)
 717                         *wild-type*))
 718          (old-ctype (or (lexenv-find cont weakend-type-restrictions)
 719                         *wild-type*))
 720          (intersects (values-types-equal-or-intersect old-atype atype))
 721          (new-atype (values-type-intersection old-atype atype))
 722          (new-ctype (values-type-intersection
 723                      old-ctype (maybe-weaken-check atype (lexenv-policy lexenv)))))
 724     (when (null (find-uses cont))
 725       (setf (continuation-asserted-type cont) new-atype)
 726       (setf (continuation-type-to-check cont) new-ctype))
 727     (when (and (not intersects)
 728                ;; FIXME: Is it really right to look at *LEXENV* here,
 729                ;; instead of looking at the LEXENV argument? Why?
 730                (not (policy *lexenv*
 731                             (= inhibit-warnings 3)))) ;FIXME: really OK to suppress?
 732       (compiler-warn
 733        "The type ~S ~A conflicts with an enclosing assertion:~%   ~S"
 734        (type-specifier atype)
 735        place
 736        (type-specifier old-atype)))
 737     (make-lexenv :type-restrictions `((,cont . ,new-atype))
 738                  :weakend-type-restrictions `((,cont . ,new-ctype))
 739                  :default lexenv)))
 740
 741 ;;; Assert that FORM evaluates to the specified type (which may be a
 742 ;;; VALUES type).
 743 ;;;
 744 ;;; FIXME: In a version of CMU CL that I used at Cadabra ca. 20000101,
 745 ;;; this didn't seem to expand into an assertion, at least for ALIEN
 746 ;;; values. Check that SBCL doesn't have this problem.
 747 (def-ir1-translator the ((type value) start cont)
 748   (with-continuation-type-assertion (cont (compiler-values-specifier-type type)
 749                                           "in THE declaration")
 750     (ir1-convert start cont value)))
 751
 752 ;;; This is like the THE special form, except that it believes
 753 ;;; whatever you tell it. It will never generate a type check, but
 754 ;;; will cause a warning if the compiler can prove the assertion is
 755 ;;; wrong.
 756 ;;;
 757 ;;; Since the CONTINUATION-DERIVED-TYPE is computed as the union of
 758 ;;; its uses's types, setting it won't work. Instead we must intersect
 759 ;;; the type with the uses's DERIVED-TYPE.
 760 (def-ir1-translator truly-the ((type value) start cont)
 761   #!+sb-doc
 762   (declare (inline member))
 763   (let ((type (compiler-values-specifier-type type))
 764         (old (find-uses cont)))
 765     (ir1-convert start cont value)
 766     (do-uses (use cont)
 767       (unless (member use old :test #'eq)
 768         (derive-node-type use type)))))
 769 \f
 770 ;;;; SETQ
 771
 772 ;;; If there is a definition in LEXENV-VARS, just set that, otherwise
 773 ;;; look at the global information. If the name is for a constant,
 774 ;;; then error out.
 775 (def-ir1-translator setq ((&whole source &rest things) start cont)
 776   (let ((len (length things)))
 777     (when (oddp len)
 778       (compiler-error "odd number of args to SETQ: ~S" source))
 779     (if (= len 2)
 780         (let* ((name (first things))
 781                (leaf (or (lexenv-find name vars)
 782                          (find-free-var name))))
 783           (etypecase leaf
 784             (leaf
 785              (when (constant-p leaf)
 786                (compiler-error "~S is a constant and thus can't be set." name))
 787              (when (lambda-var-p leaf)
 788                (let ((home-lambda (continuation-home-lambda-or-null start)))
 789                  (when home-lambda
 790                    (pushnew leaf (lambda-calls-or-closes home-lambda))))
 791                (when (lambda-var-ignorep leaf)
 792                  ;; ANSI's definition of "Declaration IGNORE, IGNORABLE"
 793                  ;; requires that this be a STYLE-WARNING, not a full warning.
 794                  (compiler-style-warn
 795                   "~S is being set even though it was declared to be ignored."
 796                   name)))
 797              (setq-var start cont leaf (second things)))
 798             (cons
 799              (aver (eq (car leaf) 'MACRO))
 800              (ir1-convert start cont `(setf ,(cdr leaf) ,(second things))))
 801             (heap-alien-info
 802              (ir1-convert start cont
 803                           `(%set-heap-alien ',leaf ,(second things))))))
 804         (collect ((sets))
 805           (do ((thing things (cddr thing)))
 806               ((endp thing)
 807                (ir1-convert-progn-body start cont (sets)))
 808             (sets `(setq ,(first thing) ,(second thing))))))))
 809
 810 ;;; This is kind of like REFERENCE-LEAF, but we generate a SET node.
 811 ;;; This should only need to be called in SETQ.
 812 (defun setq-var (start cont var value)
 813   (declare (type continuation start cont) (type basic-var var))
 814   (let ((dest (make-continuation)))
 815     (ir1-convert start dest value)
 816     (assert-continuation-type dest (leaf-type var) (lexenv-policy *lexenv*))
 817     (let ((res (make-set :var var :value dest)))
 818       (setf (continuation-dest dest) res)
 819       (setf (leaf-ever-used var) t)
 820       (push res (basic-var-sets var))
 821       (link-node-to-previous-continuation res dest)
 822       (use-continuation res cont))))
 823 \f
 824 ;;;; CATCH, THROW and UNWIND-PROTECT
 825
 826 ;;; We turn THROW into a MULTIPLE-VALUE-CALL of a magical function,
 827 ;;; since as as far as IR1 is concerned, it has no interesting
 828 ;;; properties other than receiving multiple-values.
 829 (def-ir1-translator throw ((tag result) start cont)
 830   #!+sb-doc
 831   "Throw Tag Form
 832   Do a non-local exit, return the values of Form from the CATCH whose tag
 833   evaluates to the same thing as Tag."
 834   (ir1-convert start cont
 835                `(multiple-value-call #'%throw ,tag ,result)))
 836
 837 ;;; This is a special special form used to instantiate a cleanup as
 838 ;;; the current cleanup within the body. KIND is the kind of cleanup
 839 ;;; to make, and MESS-UP is a form that does the mess-up action. We
 840 ;;; make the MESS-UP be the USE of the MESS-UP form's continuation,
 841 ;;; and introduce the cleanup into the lexical environment. We
 842 ;;; back-patch the ENTRY-CLEANUP for the current cleanup to be the new
 843 ;;; cleanup, since this inner cleanup is the interesting one.
 844 (def-ir1-translator %within-cleanup ((kind mess-up &body body) start cont)
 845   (let ((dummy (make-continuation))
 846         (dummy2 (make-continuation)))
 847     (ir1-convert start dummy mess-up)
 848     (let* ((mess-node (continuation-use dummy))
 849            (cleanup (make-cleanup :kind kind
 850                                   :mess-up mess-node))
 851            (old-cup (lexenv-cleanup *lexenv*))
 852            (*lexenv* (make-lexenv :cleanup cleanup)))
 853       (setf (entry-cleanup (cleanup-mess-up old-cup)) cleanup)
 854       (ir1-convert dummy dummy2 '(%cleanup-point))
 855       (ir1-convert-progn-body dummy2 cont body))))
 856
 857 ;;; This is a special special form that makes an "escape function"
 858 ;;; which returns unknown values from named block. We convert the
 859 ;;; function, set its kind to :ESCAPE, and then reference it. The
 860 ;;; :ESCAPE kind indicates that this function's purpose is to
 861 ;;; represent a non-local control transfer, and that it might not
 862 ;;; actually have to be compiled.
 863 ;;;
 864 ;;; Note that environment analysis replaces references to escape
 865 ;;; functions with references to the corresponding NLX-INFO structure.
 866 (def-ir1-translator %escape-fun ((tag) start cont)
 867   (let ((fun (ir1-convert-lambda
 868               `(lambda ()
 869                  (return-from ,tag (%unknown-values)))
 870               :debug-name (debug-namify "escape function for ~S" tag))))
 871     (setf (functional-kind fun) :escape)
 872     (reference-leaf start cont fun)))
 873
 874 ;;; Yet another special special form. This one looks up a local
 875 ;;; function and smashes it to a :CLEANUP function, as well as
 876 ;;; referencing it.
 877 (def-ir1-translator %cleanup-fun ((name) start cont)
 878   (let ((fun (lexenv-find name funs)))
 879     (aver (lambda-p fun))
 880     (setf (functional-kind fun) :cleanup)
 881     (reference-leaf start cont fun)))
 882
 883 ;;; We represent the possibility of the control transfer by making an
 884 ;;; "escape function" that does a lexical exit, and instantiate the
 885 ;;; cleanup using %WITHIN-CLEANUP.
 886 (def-ir1-translator catch ((tag &body body) start cont)
 887   #!+sb-doc
 888   "Catch Tag Form*
 889   Evaluates Tag and instantiates it as a catcher while the body forms are
 890   evaluated in an implicit PROGN. If a THROW is done to Tag within the dynamic
 891   scope of the body, then control will be transferred to the end of the body
 892   and the thrown values will be returned."
 893   (ir1-convert
 894    start cont
 895    (let ((exit-block (gensym "EXIT-BLOCK-")))
 896      `(block ,exit-block
 897         (%within-cleanup
 898             :catch
 899             (%catch (%escape-fun ,exit-block) ,tag)
 900           ,@body)))))
 901
 902 ;;; UNWIND-PROTECT is similar to CATCH, but hairier. We make the
 903 ;;; cleanup forms into a local function so that they can be referenced
 904 ;;; both in the case where we are unwound and in any local exits. We
 905 ;;; use %CLEANUP-FUN on this to indicate that reference by
 906 ;;; %UNWIND-PROTECT isn't "real", and thus doesn't cause creation of
 907 ;;; an XEP.
 908 (def-ir1-translator unwind-protect ((protected &body cleanup) start cont)
 909   #!+sb-doc
 910   "Unwind-Protect Protected Cleanup*
 911   Evaluate the form Protected, returning its values. The cleanup forms are
 912   evaluated whenever the dynamic scope of the Protected form is exited (either
 913   due to normal completion or a non-local exit such as THROW)."
 914   (ir1-convert
 915    start cont
 916    (let ((cleanup-fun (gensym "CLEANUP-FUN-"))
 917          (drop-thru-tag (gensym "DROP-THRU-TAG-"))
 918          (exit-tag (gensym "EXIT-TAG-"))
 919          (next (gensym "NEXT"))
 920          (start (gensym "START"))
 921          (count (gensym "COUNT")))
 922      `(flet ((,cleanup-fun () ,@cleanup nil))
 923         ;; FIXME: If we ever get DYNAMIC-EXTENT working, then
 924         ;; ,CLEANUP-FUN should probably be declared DYNAMIC-EXTENT,
 925         ;; and something can be done to make %ESCAPE-FUN have
 926         ;; dynamic extent too.
 927         (block ,drop-thru-tag
 928           (multiple-value-bind (,next ,start ,count)
 929               (block ,exit-tag
 930                 (%within-cleanup
 931                     :unwind-protect
 932                     (%unwind-protect (%escape-fun ,exit-tag)
 933                                      (%cleanup-fun ,cleanup-fun))
 934                   (return-from ,drop-thru-tag ,protected)))
 935             (,cleanup-fun)
 936             (%continue-unwind ,next ,start ,count)))))))
 937 \f
 938 ;;;; multiple-value stuff
 939
 940 ;;; If there are arguments, MULTIPLE-VALUE-CALL turns into an
 941 ;;; MV-COMBINATION.
 942 ;;;
 943 ;;; If there are no arguments, then we convert to a normal
 944 ;;; combination, ensuring that a MV-COMBINATION always has at least
 945 ;;; one argument. This can be regarded as an optimization, but it is
 946 ;;; more important for simplifying compilation of MV-COMBINATIONS.
 947 (def-ir1-translator multiple-value-call ((fun &rest args) start cont)
 948   #!+sb-doc
 949   "MULTIPLE-VALUE-CALL Function Values-Form*
 950   Call Function, passing all the values of each Values-Form as arguments,
 951   values from the first Values-Form making up the first argument, etc."
 952   (let* ((fun-cont (make-continuation))
 953          (node (if args
 954                    (make-mv-combination fun-cont)
 955                    (make-combination fun-cont))))
 956     (ir1-convert start fun-cont
 957                  (if (and (consp fun) (eq (car fun) 'function))
 958                      fun
 959                      `(%coerce-callable-to-fun ,fun)))
 960     (setf (continuation-dest fun-cont) node)
 961     (assert-continuation-type fun-cont
 962                               (specifier-type '(or function symbol))
 963                               (lexenv-policy *lexenv*))
 964     (collect ((arg-conts))
 965       (let ((this-start fun-cont))
 966         (dolist (arg args)
 967           (let ((this-cont (make-continuation node)))
 968             (ir1-convert this-start this-cont arg)
 969             (setq this-start this-cont)
 970             (arg-conts this-cont)))
 971         (link-node-to-previous-continuation node this-start)
 972         (use-continuation node cont)
 973         (setf (basic-combination-args node) (arg-conts))))))
 974
 975 ;;; MULTIPLE-VALUE-PROG1 is represented implicitly in IR1 by having a
 976 ;;; the result code use result continuation (CONT), but transfer
 977 ;;; control to the evaluation of the body. In other words, the result
 978 ;;; continuation isn't IMMEDIATELY-USED-P by the nodes that compute
 979 ;;; the result.
 980 ;;;
 981 ;;; In order to get the control flow right, we convert the result with
 982 ;;; a dummy result continuation, then convert all the uses of the
 983 ;;; dummy to be uses of CONT. If a use is an EXIT, then we also
 984 ;;; substitute CONT for the dummy in the corresponding ENTRY node so
 985 ;;; that they are consistent. Note that this doesn't amount to
 986 ;;; changing the exit target, since the control destination of an exit
 987 ;;; is determined by the block successor; we are just indicating the
 988 ;;; continuation that the result is delivered to.
 989 ;;;
 990 ;;; We then convert the body, using another dummy continuation in its
 991 ;;; own block as the result. After we are done converting the body, we
 992 ;;; move all predecessors of the dummy end block to CONT's block.
 993 ;;;
 994 ;;; Note that we both exploit and maintain the invariant that the CONT
 995 ;;; to an IR1 convert method either has no block or starts the block
 996 ;;; that control should transfer to after completion for the form.
 997 ;;; Nested MV-PROG1's work because during conversion of the result
 998 ;;; form, we use dummy continuation whose block is the true control
 999 ;;; destination.
1000 (def-ir1-translator multiple-value-prog1 ((result &rest forms) start cont)
1001   #!+sb-doc
1002   "MULTIPLE-VALUE-PROG1 Values-Form Form*
1003   Evaluate Values-Form and then the Forms, but return all the values of
1004   Values-Form."
1005   (continuation-starts-block cont)
1006   (let* ((dummy-result (make-continuation))
1007          (dummy-start (make-continuation))
1008          (cont-block (continuation-block cont)))
1009     (continuation-starts-block dummy-start)
1010     (ir1-convert start dummy-start result)
1011
1012     (with-continuation-type-assertion
1013         ;; FIXME: policy
1014         (cont (continuation-asserted-type dummy-start)
1015               "of the first form")
1016       (substitute-continuation-uses cont dummy-start))
1017
1018     (continuation-starts-block dummy-result)
1019     (ir1-convert-progn-body dummy-start dummy-result forms)
1020     (let ((end-block (continuation-block dummy-result)))
1021       (dolist (pred (block-pred end-block))
1022         (unlink-blocks pred end-block)
1023         (link-blocks pred cont-block))
1024       (aver (not (continuation-dest dummy-result)))
1025       (delete-continuation dummy-result)
1026       (remove-from-dfo end-block))))
1027 \f
1028 ;;;; interface to defining macros
1029
1030 ;;; Old CMUCL comment:
1031 ;;;
1032 ;;;   Return a new source path with any stuff intervening between the
1033 ;;;   current path and the first form beginning with NAME stripped
1034 ;;;   off.  This is used to hide the guts of DEFmumble macros to
1035 ;;;   prevent annoying error messages.
1036 ;;;
1037 ;;; Now that we have implementations of DEFmumble macros in terms of
1038 ;;; EVAL-WHEN, this function is no longer used.  However, it might be
1039 ;;; worth figuring out why it was used, and maybe doing analogous
1040 ;;; munging to the functions created in the expanders for the macros.
1041 (defun revert-source-path (name)
1042   (do ((path *current-path* (cdr path)))
1043       ((null path) *current-path*)
1044     (let ((first (first path)))
1045       (when (or (eq first name)
1046                 (eq first 'original-source-start))
1047         (return path)))))