src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for a CONTINUATION whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-continuation-p (thing)
  24   (and (continuation-p thing)
  25        (let ((use (continuation-use thing)))
  26          (and (ref-p use)
  27               (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for a continuation whose only use is a
  30 ;;; constant node.
  31 (declaim (ftype (function (continuation) t) continuation-value))
  32 (defun continuation-value (cont)
  33   (aver (constant-continuation-p cont))
  34   (constant-value (ref-leaf (continuation-use cont))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Return a (possibly values) type that describes what we have proven
  39 ;;; about the type of Cont without taking any type assertions into
  40 ;;; consideration. This is just the union of the NODE-DERIVED-TYPE of
  41 ;;; all the uses. Most often people use CONTINUATION-DERIVED-TYPE or
  42 ;;; CONTINUATION-TYPE instead of using this function directly.
  43 (defun continuation-proven-type (cont)
  44   (declare (type continuation cont))
  45   (ecase (continuation-kind cont)
  46     ((:block-start :deleted-block-start)
  47      (let ((uses (block-start-uses (continuation-block cont))))
  48        (if uses
  49            (do ((res (node-derived-type (first uses))
  50                      (values-type-union (node-derived-type (first current))
  51                                         res))
  52                 (current (rest uses) (rest current)))
  53                ((null current) res))
  54            *empty-type*)))
  55     (:inside-block
  56      (node-derived-type (continuation-use cont)))))
  57
  58 ;;; Our best guess for the type of this continuation's value. Note
  59 ;;; that this may be VALUES or FUNCTION type, which cannot be passed
  60 ;;; as an argument to the normal type operations. See
  61 ;;; CONTINUATION-TYPE. This may be called on deleted continuations,
  62 ;;; always returning *.
  63 ;;;
  64 ;;; What we do is call CONTINUATION-PROVEN-TYPE and check whether the
  65 ;;; result is a subtype of the assertion. If so, return the proven
  66 ;;; type and set TYPE-CHECK to nil. Otherwise, return the intersection
  67 ;;; of the asserted and proven types, and set TYPE-CHECK T. If
  68 ;;; TYPE-CHECK already has a non-null value, then preserve it. Only in
  69 ;;; the somewhat unusual circumstance of a newly discovered assertion
  70 ;;; will we change TYPE-CHECK from NIL to T.
  71 ;;;
  72 ;;; The result value is cached in the CONTINUATION-%DERIVED-TYPE slot.
  73 ;;; If the slot is true, just return that value, otherwise recompute
  74 ;;; and stash the value there.
  75 #!-sb-fluid (declaim (inline continuation-derived-type))
  76 (defun continuation-derived-type (cont)
  77   (declare (type continuation cont))
  78   (or (continuation-%derived-type cont)
  79       (%continuation-derived-type cont)))
  80 (defun %continuation-derived-type (cont)
  81   (declare (type continuation cont))
  82   (let ((proven (continuation-proven-type cont))
  83         (asserted (continuation-asserted-type cont)))
  84     (cond ((values-subtypep proven asserted)
  85            (setf (continuation-%type-check cont) nil)
  86            (setf (continuation-%derived-type cont) proven))
  87           ((and (values-subtypep proven (specifier-type 'function))
  88                 (values-subtypep asserted (specifier-type 'function)))
  89            ;; It's physically impossible for a runtime type check to
  90            ;; distinguish between the various subtypes of FUNCTION, so
  91            ;; it'd be pointless to do more type checks here.
  92            (setf (continuation-%type-check cont) nil)
  93            (setf (continuation-%derived-type cont)
  94                  ;; FIXME: This should depend on optimization
  95                  ;; policy. This is for SPEED > SAFETY:
  96                  #+nil (values-type-intersection asserted proven)
  97                  ;; and this is for SAFETY >= SPEED:
  98                  #-nil proven))
  99           (t
 100            (unless (or (continuation-%type-check cont)
 101                        (not (continuation-dest cont))
 102                        (eq asserted *universal-type*))
 103              (setf (continuation-%type-check cont) t))
 104
 105            (setf (continuation-%derived-type cont)
 106                  (values-type-intersection asserted proven))))))
 107
 108 ;;; Call CONTINUATION-DERIVED-TYPE to make sure the slot is up to
 109 ;;; date, then return it.
 110 #!-sb-fluid (declaim (inline continuation-type-check))
 111 (defun continuation-type-check (cont)
 112   (declare (type continuation cont))
 113   (continuation-derived-type cont)
 114   (continuation-%type-check cont))
 115
 116 ;;; Return the derived type for CONT's first value. This is guaranteed
 117 ;;; not to be a VALUES or FUNCTION type.
 118 (declaim (ftype (function (continuation) ctype) continuation-type))
 119 (defun continuation-type (cont)
 120   (single-value-type (continuation-derived-type cont)))
 121
 122 ;;; If CONT is an argument of a function, return a type which the
 123 ;;; function checks CONT for.
 124 #!-sb-fluid (declaim (inline continuation-externally-checkable-type))
 125 (defun continuation-externally-checkable-type (cont)
 126   (or (continuation-%externally-checkable-type cont)
 127       (%continuation-%externally-checkable-type cont)))
 128 (defun %continuation-%externally-checkable-type (cont)
 129   (declare (type continuation cont))
 130   (let ((dest (continuation-dest cont)))
 131       (if (not (and dest (combination-p dest)))
 132           ;; TODO: MV-COMBINATION
 133           (setf (continuation-%externally-checkable-type cont) *wild-type*)
 134           (let* ((fun (combination-fun dest))
 135                  (args (combination-args dest))
 136                  (fun-type (continuation-type fun)))
 137             (if (or (not (fun-type-p fun-type))
 138                     ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
 139                     (fun-type-wild-args fun-type))
 140                 (progn (dolist (arg args)
 141                          (setf (continuation-%externally-checkable-type arg)
 142                                *wild-type*))
 143                        *wild-type*)
 144                 (let* ((arg-types (append (fun-type-required fun-type)
 145                                           (fun-type-optional fun-type)
 146                                           (let ((rest (list (or (fun-type-rest fun-type)
 147                                                                 *wild-type*))))
 148                                             (setf (cdr rest) rest)))))
 149                   ;; TODO: &KEY
 150                   (loop
 151                      for arg of-type continuation in args
 152                      and type of-type ctype in arg-types
 153                      do (setf (continuation-%externally-checkable-type arg)
 154                               type))
 155                   (continuation-%externally-checkable-type cont)))))))
 156 \f
 157 ;;;; interface routines used by optimizers
 158
 159 ;;; This function is called by optimizers to indicate that something
 160 ;;; interesting has happened to the value of Cont. Optimizers must
 161 ;;; make sure that they don't call for reoptimization when nothing has
 162 ;;; happened, since optimization will fail to terminate.
 163 ;;;
 164 ;;; We clear any cached type for the continuation and set the
 165 ;;; reoptimize flags on everything in sight, unless the continuation
 166 ;;; is deleted (in which case we do nothing.)
 167 ;;;
 168 ;;; Since this can get called during IR1 conversion, we have to be
 169 ;;; careful not to fly into space when the Dest's Prev is missing.
 170 (defun reoptimize-continuation (cont)
 171   (declare (type continuation cont))
 172   (unless (member (continuation-kind cont) '(:deleted :unused))
 173     (setf (continuation-%derived-type cont) nil)
 174     (let ((dest (continuation-dest cont)))
 175       (when dest
 176         (setf (continuation-reoptimize cont) t)
 177         (setf (node-reoptimize dest) t)
 178         (let ((prev (node-prev dest)))
 179           (when prev
 180             (let* ((block (continuation-block prev))
 181                    (component (block-component block)))
 182               (when (typep dest 'cif)
 183                 (setf (block-test-modified block) t))
 184               (setf (block-reoptimize block) t)
 185               (setf (component-reoptimize component) t))))))
 186     (do-uses (node cont)
 187       (setf (block-type-check (node-block node)) t)))
 188   (values))
 189
 190 ;;; Annotate Node to indicate that its result has been proven to be
 191 ;;; typep to RType. After IR1 conversion has happened, this is the
 192 ;;; only correct way to supply information discovered about a node's
 193 ;;; type. If you screw with the Node-Derived-Type directly, then
 194 ;;; information may be lost and reoptimization may not happen.
 195 ;;;
 196 ;;; What we do is intersect Rtype with Node's Derived-Type. If the
 197 ;;; intersection is different from the old type, then we do a
 198 ;;; Reoptimize-Continuation on the Node-Cont.
 199 (defun derive-node-type (node rtype)
 200   (declare (type node node) (type ctype rtype))
 201   (let ((node-type (node-derived-type node)))
 202     (unless (eq node-type rtype)
 203       (let ((int (values-type-intersection node-type rtype)))
 204         (when (type/= node-type int)
 205           (when (and *check-consistency*
 206                      (eq int *empty-type*)
 207                      (not (eq rtype *empty-type*)))
 208             (let ((*compiler-error-context* node))
 209               (compiler-warn
 210                "New inferred type ~S conflicts with old type:~
 211                 ~%  ~S~%*** possible internal error? Please report this."
 212                (type-specifier rtype) (type-specifier node-type))))
 213           (setf (node-derived-type node) int)
 214           (reoptimize-continuation (node-cont node))))))
 215   (values))
 216
 217 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 218 ;;; error for CONT's value not to be TYPEP to TYPE. If we improve the
 219 ;;; assertion, we set TYPE-CHECK and TYPE-ASSERTED to guarantee that
 220 ;;; the new assertion will be checked.
 221 (defun assert-continuation-type (cont type)
 222   (declare (type continuation cont) (type ctype type))
 223   (let ((cont-type (continuation-asserted-type cont)))
 224     (unless (eq cont-type type)
 225       (let ((int (values-type-intersection cont-type type)))
 226         (when (type/= cont-type int)
 227           (setf (continuation-asserted-type cont) int)
 228           (do-uses (node cont)
 229             (setf (block-attributep (block-flags (node-block node))
 230                                     type-check type-asserted)
 231                   t))
 232           (reoptimize-continuation cont)))))
 233   (values))
 234
 235 ;;; Assert that CALL is to a function of the specified TYPE. It is
 236 ;;; assumed that the call is legal and has only constants in the
 237 ;;; keyword positions.
 238 (defun assert-call-type (call type)
 239   (declare (type combination call) (type fun-type type))
 240   (derive-node-type call (fun-type-returns type))
 241   (let ((args (combination-args call)))
 242     (dolist (req (fun-type-required type))
 243       (when (null args) (return-from assert-call-type))
 244       (let ((arg (pop args)))
 245         (assert-continuation-type arg req)))
 246     (dolist (opt (fun-type-optional type))
 247       (when (null args) (return-from assert-call-type))
 248       (let ((arg (pop args)))
 249         (assert-continuation-type arg opt)))
 250
 251     (let ((rest (fun-type-rest type)))
 252       (when rest
 253         (dolist (arg args)
 254           (assert-continuation-type arg rest))))
 255
 256     (dolist (key (fun-type-keywords type))
 257       (let ((name (key-info-name key)))
 258         (do ((arg args (cddr arg)))
 259             ((null arg))
 260           (when (eq (continuation-value (first arg)) name)
 261             (assert-continuation-type
 262              (second arg) (key-info-type key)))))))
 263   (values))
 264 \f
 265 ;;;; IR1-OPTIMIZE
 266
 267 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 268 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 269 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 270 ;;; we are done, then another iteration would be beneficial.
 271 (defun ir1-optimize (component)
 272   (declare (type component component))
 273   (setf (component-reoptimize component) nil)
 274   (do-blocks (block component)
 275     (cond
 276      ((or (block-delete-p block)
 277           (null (block-pred block)))
 278       (delete-block block))
 279      ((eq (functional-kind (block-home-lambda block)) :deleted)
 280       ;; Preserve the BLOCK-SUCC invariant that almost every block has
 281       ;; one successor (and a block with DELETE-P set is an acceptable
 282       ;; exception).
 283       (labels ((mark-blocks (block)
 284                  (dolist (pred (block-pred block))
 285                    (when (and (not (block-delete-p pred))
 286                               (eq (functional-kind (block-home-lambda pred))
 287                                   :deleted))
 288                      (setf (block-delete-p pred) t)
 289                      (mark-blocks pred)))))
 290         (mark-blocks block)
 291         (delete-block block)))
 292      (t
 293       (loop
 294         (let ((succ (block-succ block)))
 295           (unless (and succ (null (rest succ)))
 296             (return)))
 297
 298         (let ((last (block-last block)))
 299           (typecase last
 300             (cif
 301              (flush-dest (if-test last))
 302              (when (unlink-node last)
 303                (return)))
 304             (exit
 305              (when (maybe-delete-exit last)
 306                (return)))))
 307
 308         (unless (join-successor-if-possible block)
 309           (return)))
 310
 311       (when (and (block-reoptimize block) (block-component block))
 312         (aver (not (block-delete-p block)))
 313         (ir1-optimize-block block))
 314
 315       ;; We delete blocks when there is either no predecessor or the
 316       ;; block is in a lambda that has been deleted. These blocks
 317       ;; would eventually be deleted by DFO recomputation, but doing
 318       ;; it here immediately makes the effect available to IR1
 319       ;; optimization.
 320       (when (and (block-flush-p block) (block-component block))
 321         (aver (not (block-delete-p block)))
 322         (flush-dead-code block)))))
 323
 324   (values))
 325
 326 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 327 ;;; flags.
 328 ;;;
 329 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 330 ;;; still be set upon return from this function, meaning that further
 331 ;;; optimization is wanted (as a consequence of optimizations we did).
 332 (defun ir1-optimize-block (block)
 333   (declare (type cblock block))
 334   ;; We clear the node and block REOPTIMIZE flags before doing the
 335   ;; optimization, not after. This ensures that the node or block will
 336   ;; be reoptimized if necessary.
 337   (setf (block-reoptimize block) nil)
 338   (do-nodes (node cont block :restart-p t)
 339     (when (node-reoptimize node)
 340       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 341       (setf (node-reoptimize node) nil)
 342       (typecase node
 343         (ref)
 344         (combination
 345          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 346          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 347          ;; any argument changes.
 348          (ir1-optimize-combination node))
 349         (cif
 350          (ir1-optimize-if node))
 351         (creturn
 352          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 353          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 354          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 355          ;; CMU CL comments
 356          (setf (node-reoptimize node) t)
 357          (ir1-optimize-return node))
 358         (mv-combination
 359          (ir1-optimize-mv-combination node))
 360         (exit
 361          ;; With an EXIT, we derive the node's type from the VALUE's
 362          ;; type. We don't propagate CONT's assertion to the VALUE,
 363          ;; since if we did, this would move the checking of CONT's
 364          ;; assertion to the exit. This wouldn't work with CATCH and
 365          ;; UWP, where the EXIT node is just a placeholder for the
 366          ;; actual unknown exit.
 367          (let ((value (exit-value node)))
 368            (when value
 369              (derive-node-type node (continuation-derived-type value)))))
 370         (cset
 371          (ir1-optimize-set node)))))
 372   (values))
 373
 374 ;;; Try to join with a successor block. If we succeed, we return true,
 375 ;;; otherwise false.
 376 (defun join-successor-if-possible (block)
 377   (declare (type cblock block))
 378   (let ((next (first (block-succ block))))
 379     (when (block-start next)
 380       (let* ((last (block-last block))
 381              (last-cont (node-cont last))
 382              (next-cont (block-start next)))
 383         (cond (;; We cannot combine with a successor block if:
 384                (or
 385                 ;; The successor has more than one predecessor.
 386                 (rest (block-pred next))
 387                 ;; The last node's CONT is also used somewhere else.
 388                 (not (eq (continuation-use last-cont) last))
 389                 ;; The successor is the current block (infinite loop).
 390                 (eq next block)
 391                 ;; The next block has a different cleanup, and thus
 392                 ;; we may want to insert cleanup code between the
 393                 ;; two blocks at some point.
 394                 (not (eq (block-end-cleanup block)
 395                          (block-start-cleanup next)))
 396                 ;; The next block has a different home lambda, and
 397                 ;; thus the control transfer is a non-local exit.
 398                 (not (eq (block-home-lambda block)
 399                          (block-home-lambda next))))
 400                nil)
 401               ;; Joining is easy when the successor's START
 402               ;; continuation is the same from our LAST's CONT.
 403               ((eq last-cont next-cont)
 404                (join-blocks block next)
 405                t)
 406               ;; If they differ, then we can still join when the last
 407               ;; continuation has no next and the next continuation
 408               ;; has no uses.
 409               ((and (null (block-start-uses next))
 410                     (eq (continuation-kind last-cont) :inside-block))
 411                ;; In this case, we replace the next
 412                ;; continuation with the last before joining the blocks.
 413                (let ((next-node (continuation-next next-cont)))
 414                  ;; If NEXT-CONT does have a dest, it must be
 415                  ;; unreachable, since there are no USES.
 416                  ;; DELETE-CONTINUATION will mark the dest block as
 417                  ;; DELETE-P [and also this block, unless it is no
 418                  ;; longer backward reachable from the dest block.]
 419                  (delete-continuation next-cont)
 420                  (setf (node-prev next-node) last-cont)
 421                  (setf (continuation-next last-cont) next-node)
 422                  (setf (block-start next) last-cont)
 423                  (join-blocks block next))
 424                t)
 425               (t
 426                nil))))))
 427
 428 ;;; Join together two blocks which have the same ending/starting
 429 ;;; continuation. The code in BLOCK2 is moved into BLOCK1 and BLOCK2
 430 ;;; is deleted from the DFO. We combine the optimize flags for the two
 431 ;;; blocks so that any indicated optimization gets done.
 432 (defun join-blocks (block1 block2)
 433   (declare (type cblock block1 block2))
 434   (let* ((last (block-last block2))
 435          (last-cont (node-cont last))
 436          (succ (block-succ block2))
 437          (start2 (block-start block2)))
 438     (do ((cont start2 (node-cont (continuation-next cont))))
 439         ((eq cont last-cont)
 440          (when (eq (continuation-kind last-cont) :inside-block)
 441            (setf (continuation-block last-cont) block1)))
 442       (setf (continuation-block cont) block1))
 443
 444     (unlink-blocks block1 block2)
 445     (dolist (block succ)
 446       (unlink-blocks block2 block)
 447       (link-blocks block1 block))
 448
 449     (setf (block-last block1) last)
 450     (setf (continuation-kind start2) :inside-block))
 451
 452   (setf (block-flags block1)
 453         (attributes-union (block-flags block1)
 454                           (block-flags block2)
 455                           (block-attributes type-asserted test-modified)))
 456
 457   (let ((next (block-next block2))
 458         (prev (block-prev block2)))
 459     (setf (block-next prev) next)
 460     (setf (block-prev next) prev))
 461
 462   (values))
 463
 464 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 465 ;;; side effects. We can delete sets of lexical variables when the set
 466 ;;; variable has no references.
 467 (defun flush-dead-code (block)
 468   (declare (type cblock block))
 469   (do-nodes-backwards (node cont block)
 470     (unless (continuation-dest cont)
 471       (typecase node
 472         (ref
 473          (delete-ref node)
 474          (unlink-node node))
 475         (combination
 476          (let ((info (combination-kind node)))
 477            (when (fun-info-p info)
 478              (let ((attr (fun-info-attributes info)))
 479                (when (and (not (ir1-attributep attr call))
 480                           ;; ### For now, don't delete potentially
 481                           ;; flushable calls when they have the CALL
 482                           ;; attribute. Someday we should look at the
 483                           ;; functional args to determine if they have
 484                           ;; any side effects.
 485                           (if (policy node (= safety 3))
 486                               (and (ir1-attributep attr flushable)
 487                                    (every (lambda (arg)
 488                                             ;; FIXME: when bug 203
 489                                             ;; will be fixed, remove
 490                                             ;; this check
 491                                             (member (continuation-type-check arg)
 492                                                     '(nil :deleted)))
 493                                           (basic-combination-args node))
 494                                    (valid-fun-use node
 495                                                   (info :function :type
 496                                                         (leaf-source-name (ref-leaf (continuation-use (basic-combination-fun node)))))
 497                                                   :result-test #'always-subtypep
 498                                                   :lossage-fun nil
 499                                                   :unwinnage-fun nil))
 500                               (ir1-attributep attr unsafely-flushable)))
 501                  (flush-dest (combination-fun node))
 502                  (dolist (arg (combination-args node))
 503                    (flush-dest arg))
 504                  (unlink-node node))))))
 505         (mv-combination
 506          (when (eq (basic-combination-kind node) :local)
 507            (let ((fun (combination-lambda node)))
 508              (when (dolist (var (lambda-vars fun) t)
 509                      (when (or (leaf-refs var)
 510                                (lambda-var-sets var))
 511                        (return nil)))
 512                (flush-dest (first (basic-combination-args node)))
 513                (delete-let fun)))))
 514         (exit
 515          (let ((value (exit-value node)))
 516            (when value
 517              (flush-dest value)
 518              (setf (exit-value node) nil))))
 519         (cset
 520          (let ((var (set-var node)))
 521            (when (and (lambda-var-p var)
 522                       (null (leaf-refs var)))
 523              (flush-dest (set-value node))
 524              (setf (basic-var-sets var)
 525                    (delete node (basic-var-sets var)))
 526              (unlink-node node)))))))
 527
 528   (setf (block-flush-p block) nil)
 529   (values))
 530 \f
 531 ;;;; local call return type propagation
 532
 533 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 534 ;;; flag set. It iterates over the uses of the RESULT, looking for
 535 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 536 ;;; call, then we union its type together with the types of other such
 537 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 538 ;;; type with the RESULT's asserted type. We can make this
 539 ;;; intersection now (potentially before type checking) because this
 540 ;;; assertion on the result will eventually be checked (if
 541 ;;; appropriate.)
 542 ;;;
 543 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 544 ;;; combination, which may change the succesor of the call to be the
 545 ;;; called function, and if so, checks if the call can become an
 546 ;;; assignment. If we convert to an assignment, we abort, since the
 547 ;;; RETURN has been deleted.
 548 (defun find-result-type (node)
 549   (declare (type creturn node))
 550   (let ((result (return-result node)))
 551     (collect ((use-union *empty-type* values-type-union))
 552       (do-uses (use result)
 553         (cond ((and (basic-combination-p use)
 554                     (eq (basic-combination-kind use) :local))
 555                (aver (eq (lambda-tail-set (node-home-lambda use))
 556                          (lambda-tail-set (combination-lambda use))))
 557                (when (combination-p use)
 558                  (when (nth-value 1 (maybe-convert-tail-local-call use))
 559                    (return-from find-result-type (values)))))
 560               (t
 561                (use-union (node-derived-type use)))))
 562       (let ((int (values-type-intersection
 563                   (continuation-asserted-type result)
 564                   (use-union))))
 565         (setf (return-result-type node) int))))
 566   (values))
 567
 568 ;;; Do stuff to realize that something has changed about the value
 569 ;;; delivered to a return node. Since we consider the return values of
 570 ;;; all functions in the tail set to be equivalent, this amounts to
 571 ;;; bringing the entire tail set up to date. We iterate over the
 572 ;;; returns for all the functions in the tail set, reanalyzing them
 573 ;;; all (not treating Node specially.)
 574 ;;;
 575 ;;; When we are done, we check whether the new type is different from
 576 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 577 ;;; all the continuations for references to functions in the tail set.
 578 ;;; This will cause IR1-OPTIMIZE-COMBINATION to derive the new type as
 579 ;;; the results of the calls.
 580 (defun ir1-optimize-return (node)
 581   (declare (type creturn node))
 582   (let* ((tails (lambda-tail-set (return-lambda node)))
 583          (funs (tail-set-funs tails)))
 584     (collect ((res *empty-type* values-type-union))
 585       (dolist (fun funs)
 586         (let ((return (lambda-return fun)))
 587           (when return
 588             (when (node-reoptimize return)
 589               (setf (node-reoptimize return) nil)
 590               (find-result-type return))
 591             (res (return-result-type return)))))
 592
 593       (when (type/= (res) (tail-set-type tails))
 594         (setf (tail-set-type tails) (res))
 595         (dolist (fun (tail-set-funs tails))
 596           (dolist (ref (leaf-refs fun))
 597             (reoptimize-continuation (node-cont ref)))))))
 598
 599   (values))
 600 \f
 601 ;;;; IF optimization
 602
 603 ;;; If the test has multiple uses, replicate the node when possible.
 604 ;;; Also check whether the predicate is known to be true or false,
 605 ;;; deleting the IF node in favor of the appropriate branch when this
 606 ;;; is the case.
 607 (defun ir1-optimize-if (node)
 608   (declare (type cif node))
 609   (let ((test (if-test node))
 610         (block (node-block node)))
 611
 612     (when (and (eq (block-start block) test)
 613                (eq (continuation-next test) node)
 614                (rest (block-start-uses block)))
 615       (do-uses (use test)
 616         (when (immediately-used-p test use)
 617           (convert-if-if use node)
 618           (when (continuation-use test) (return)))))
 619
 620     (let* ((type (continuation-type test))
 621            (victim
 622             (cond ((constant-continuation-p test)
 623                    (if (continuation-value test)
 624                        (if-alternative node)
 625                        (if-consequent node)))
 626                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 627                    (if-alternative node))
 628                   ((type= type (specifier-type 'null))
 629                    (if-consequent node)))))
 630       (when victim
 631         (flush-dest test)
 632         (when (rest (block-succ block))
 633           (unlink-blocks block victim))
 634         (setf (component-reanalyze (node-component node)) t)
 635         (unlink-node node))))
 636   (values))
 637
 638 ;;; Create a new copy of an IF node that tests the value of the node
 639 ;;; USE. The test must have >1 use, and must be immediately used by
 640 ;;; USE. NODE must be the only node in its block (implying that
 641 ;;; block-start = if-test).
 642 ;;;
 643 ;;; This optimization has an effect semantically similar to the
 644 ;;; source-to-source transformation:
 645 ;;;    (IF (IF A B C) D E) ==>
 646 ;;;    (IF A (IF B D E) (IF C D E))
 647 ;;;
 648 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 649 ;;; node so that dead code deletion notes will definitely not consider
 650 ;;; either node to be part of the original source. One node might
 651 ;;; become unreachable, resulting in a spurious note.
 652 (defun convert-if-if (use node)
 653   (declare (type node use) (type cif node))
 654   (with-ir1-environment-from-node node
 655     (let* ((block (node-block node))
 656            (test (if-test node))
 657            (cblock (if-consequent node))
 658            (ablock (if-alternative node))
 659            (use-block (node-block use))
 660            (dummy-cont (make-continuation))
 661            (new-cont (make-continuation))
 662            (new-node (make-if :test new-cont
 663                               :consequent cblock
 664                               :alternative ablock))
 665            (new-block (continuation-starts-block new-cont)))
 666       (link-node-to-previous-continuation new-node new-cont)
 667       (setf (continuation-dest new-cont) new-node)
 668       (setf (continuation-%externally-checkable-type new-cont) nil)
 669       (add-continuation-use new-node dummy-cont)
 670       (setf (block-last new-block) new-node)
 671
 672       (unlink-blocks use-block block)
 673       (delete-continuation-use use)
 674       (add-continuation-use use new-cont)
 675       (link-blocks use-block new-block)
 676
 677       (link-blocks new-block cblock)
 678       (link-blocks new-block ablock)
 679
 680       (push "<IF Duplication>" (node-source-path node))
 681       (push "<IF Duplication>" (node-source-path new-node))
 682
 683       (reoptimize-continuation test)
 684       (reoptimize-continuation new-cont)
 685       (setf (component-reanalyze *current-component*) t)))
 686   (values))
 687 \f
 688 ;;;; exit IR1 optimization
 689
 690 ;;; This function attempts to delete an exit node, returning true if
 691 ;;; it deletes the block as a consequence:
 692 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 693 ;;;    anything, since there is nothing to be done.
 694 ;;; -- If the exit node and its ENTRY have the same home lambda then
 695 ;;;    we know the exit is local, and can delete the exit. We change
 696 ;;;    uses of the Exit-Value to be uses of the original continuation,
 697 ;;;    then unlink the node. If the exit is to a TR context, then we
 698 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 699 ;;;    their value to this exit.
 700 ;;; -- If there is no value (as in a GO), then we skip the value
 701 ;;;    semantics.
 702 ;;;
 703 ;;; This function is also called by environment analysis, since it
 704 ;;; wants all exits to be optimized even if normal optimization was
 705 ;;; omitted.
 706 (defun maybe-delete-exit (node)
 707   (declare (type exit node))
 708   (let ((value (exit-value node))
 709         (entry (exit-entry node))
 710         (cont (node-cont node)))
 711     (when (and entry
 712                (eq (node-home-lambda node) (node-home-lambda entry)))
 713       (setf (entry-exits entry) (delete node (entry-exits entry)))
 714       (prog1
 715           (unlink-node node)
 716         (when value
 717           (collect ((merges))
 718             (when (return-p (continuation-dest cont))
 719               (do-uses (use value)
 720                 (when (and (basic-combination-p use)
 721                            (eq (basic-combination-kind use) :local))
 722                   (merges use))))
 723             (substitute-continuation-uses cont value)
 724             (dolist (merge (merges))
 725               (merge-tail-sets merge))))))))
 726 \f
 727 ;;;; combination IR1 optimization
 728
 729 ;;; Report as we try each transform?
 730 #!+sb-show
 731 (defvar *show-transforms-p* nil)
 732
 733 ;;; Do IR1 optimizations on a COMBINATION node.
 734 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 735 (defun ir1-optimize-combination (node)
 736   (when (continuation-reoptimize (basic-combination-fun node))
 737     (propagate-fun-change node))
 738   (let ((args (basic-combination-args node))
 739         (kind (basic-combination-kind node)))
 740     (case kind
 741       (:local
 742        (let ((fun (combination-lambda node)))
 743          (if (eq (functional-kind fun) :let)
 744              (propagate-let-args node fun)
 745              (propagate-local-call-args node fun))))
 746       ((:full :error)
 747        (dolist (arg args)
 748          (when arg
 749            (setf (continuation-reoptimize arg) nil))))
 750       (t
 751        (dolist (arg args)
 752          (when arg
 753            (setf (continuation-reoptimize arg) nil)))
 754
 755        (let ((attr (fun-info-attributes kind)))
 756          (when (and (ir1-attributep attr foldable)
 757                     ;; KLUDGE: The next test could be made more sensitive,
 758                     ;; only suppressing constant-folding of functions with
 759                     ;; CALL attributes when they're actually passed
 760                     ;; function arguments. -- WHN 19990918
 761                     (not (ir1-attributep attr call))
 762                     (every #'constant-continuation-p args)
 763                     (continuation-dest (node-cont node))
 764                     ;; Even if the function is foldable in principle,
 765                     ;; it might be one of our low-level
 766                     ;; implementation-specific functions. Such
 767                     ;; functions don't necessarily exist at runtime on
 768                     ;; a plain vanilla ANSI Common Lisp
 769                     ;; cross-compilation host, in which case the
 770                     ;; cross-compiler can't fold it because the
 771                     ;; cross-compiler doesn't know how to evaluate it.
 772                     #+sb-xc-host
 773                     (fboundp (combination-fun-source-name node)))
 774            (constant-fold-call node)
 775            (return-from ir1-optimize-combination)))
 776
 777        (let ((fun (fun-info-derive-type kind)))
 778          (when fun
 779            (let ((res (funcall fun node)))
 780              (when res
 781                (derive-node-type node res)
 782                (maybe-terminate-block node nil)))))
 783
 784        (let ((fun (fun-info-optimizer kind)))
 785          (unless (and fun (funcall fun node))
 786            (dolist (x (fun-info-transforms kind))
 787              #!+sb-show
 788              (when *show-transforms-p*
 789                (let* ((cont (basic-combination-fun node))
 790                       (fname (continuation-fun-name cont t)))
 791                  (/show "trying transform" x (transform-function x) "for" fname)))
 792              (unless (ir1-transform node x)
 793                #!+sb-show
 794                (when *show-transforms-p*
 795                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 796                (return))))))))
 797
 798   (values))
 799
 800 ;;; If CALL is to a function that doesn't return (i.e. return type is
 801 ;;; NIL), then terminate the block there, and link it to the component
 802 ;;; tail. We also change the call's CONT to be a dummy continuation to
 803 ;;; prevent the use from confusing things.
 804 ;;;
 805 ;;; Except when called during IR1 [FIXME: What does this mean? Except
 806 ;;; during IR1 conversion? What about IR1 optimization?], we delete
 807 ;;; the continuation if it has no other uses. (If it does have other
 808 ;;; uses, we reoptimize.)
 809 ;;;
 810 ;;; Termination on the basis of a continuation type assertion is
 811 ;;; inhibited when:
 812 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 813 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 814 ;;;    weakening.)
 815 (defun maybe-terminate-block (call ir1-converting-not-optimizing-p)
 816   (declare (type basic-combination call))
 817   (let* ((block (node-block call))
 818          (cont (node-cont call))
 819          (tail (component-tail (block-component block)))
 820          (succ (first (block-succ block))))
 821     (unless (or (and (eq call (block-last block)) (eq succ tail))
 822                 (block-delete-p block))
 823       (when (or (and (eq (continuation-asserted-type cont) *empty-type*)
 824                      (not (or ir1-converting-not-optimizing-p
 825                               (eq (continuation-kind cont) :deleted))))
 826                 (eq (node-derived-type call) *empty-type*))
 827         (cond (ir1-converting-not-optimizing-p
 828                (delete-continuation-use call)
 829                (cond
 830                 ((block-last block)
 831                  (aver (and (eq (block-last block) call)
 832                             (eq (continuation-kind cont) :block-start))))
 833                 (t
 834                  (setf (block-last block) call)
 835                  (link-blocks block (continuation-starts-block cont)))))
 836               (t
 837                (node-ends-block call)
 838                (delete-continuation-use call)
 839                (if (eq (continuation-kind cont) :unused)
 840                    (delete-continuation cont)
 841                    (reoptimize-continuation cont))))
 842
 843         (unlink-blocks block (first (block-succ block)))
 844         (setf (component-reanalyze (block-component block)) t)
 845         (aver (not (block-succ block)))
 846         (link-blocks block tail)
 847         (add-continuation-use call (make-continuation))
 848         t))))
 849
 850 ;;; This is called both by IR1 conversion and IR1 optimization when
 851 ;;; they have verified the type signature for the call, and are
 852 ;;; wondering if something should be done to special-case the call. If
 853 ;;; CALL is a call to a global function, then see whether it defined
 854 ;;; or known:
 855 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 856 ;;;    the expansion and change the call to call it. Expansion is
 857 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 858 ;;;    true, we never expand, since this function has already been
 859 ;;;    converted. Local call analysis will duplicate the definition
 860 ;;;    if necessary. We claim that the parent form is LABELS for
 861 ;;;    context declarations, since we don't want it to be considered
 862 ;;;    a real global function.
 863 ;;; -- If it is a known function, mark it as such by setting the KIND.
 864 ;;;
 865 ;;; We return the leaf referenced (NIL if not a leaf) and the
 866 ;;; FUN-INFO assigned.
 867 ;;;
 868 ;;; FIXME: The IR1-CONVERTING-NOT-OPTIMIZING-P argument is what the
 869 ;;; old CMU CL code called IR1-P, without explanation. My (WHN
 870 ;;; 2002-01-09) tentative understanding of it is that we can call this
 871 ;;; operation either in initial IR1 conversion or in later IR1
 872 ;;; optimization, and it tells which is which. But it would be good
 873 ;;; for someone who really understands it to check whether this is
 874 ;;; really right.
 875 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 876   (declare (type combination call))
 877   (let* ((ref (continuation-use (basic-combination-fun call)))
 878          (leaf (when (ref-p ref) (ref-leaf ref)))
 879          (inlinep (if (defined-fun-p leaf)
 880                       (defined-fun-inlinep leaf)
 881                       :no-chance)))
 882     (cond
 883      ((eq inlinep :notinline) (values nil nil))
 884      ((not (and (global-var-p leaf)
 885                 (eq (global-var-kind leaf) :global-function)))
 886       (values leaf nil))
 887      ((and (ecase inlinep
 888              (:inline t)
 889              (:no-chance nil)
 890              ((nil :maybe-inline) (policy call (zerop space))))
 891            (defined-fun-p leaf)
 892            (defined-fun-inline-expansion leaf)
 893            (let ((fun (defined-fun-functional leaf)))
 894              (or (not fun)
 895                  (and (eq inlinep :inline) (functional-kind fun))))
 896            (inline-expansion-ok call))
 897       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 898              ;; called semi-inlining? A more descriptive name would
 899              ;; be nice. -- WHN 2002-01-07
 900              (frob ()
 901                (let ((res (ir1-convert-lambda-for-defun
 902                            (defined-fun-inline-expansion leaf)
 903                            leaf t
 904                            #'ir1-convert-inline-lambda)))
 905                  (setf (defined-fun-functional leaf) res)
 906                  (change-ref-leaf ref res))))
 907         (if ir1-converting-not-optimizing-p
 908             (frob)
 909             (with-ir1-environment-from-node call
 910               (frob)
 911               (locall-analyze-component *current-component*))))
 912
 913       (values (ref-leaf (continuation-use (basic-combination-fun call)))
 914               nil))
 915      (t
 916       (let ((info (info :function :info (leaf-source-name leaf))))
 917         (if info
 918             (values leaf (setf (basic-combination-kind call) info))
 919             (values leaf nil)))))))
 920
 921 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 922 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 923 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 924 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 925 ;;; syntax check, arg/result type processing, but still call
 926 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 927 ;;; and that checking is done by local call analysis.
 928 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 929   (declare (type combination call) (type ctype type))
 930   (cond ((not (fun-type-p type))
 931          (aver (multiple-value-bind (val win)
 932                    (csubtypep type (specifier-type 'function))
 933                  (or val (not win))))
 934          (recognize-known-call call ir1-converting-not-optimizing-p))
 935         ((valid-fun-use call type
 936                         :argument-test #'always-subtypep
 937                         :result-test #'always-subtypep
 938                         ;; KLUDGE: Common Lisp is such a dynamic
 939                         ;; language that all we can do here in
 940                         ;; general is issue a STYLE-WARNING. It
 941                         ;; would be nice to issue a full WARNING
 942                         ;; in the special case of of type
 943                         ;; mismatches within a compilation unit
 944                         ;; (as in section 3.2.2.3 of the spec)
 945                         ;; but at least as of sbcl-0.6.11, we
 946                         ;; don't keep track of whether the
 947                         ;; mismatched data came from the same
 948                         ;; compilation unit, so we can't do that.
 949                         ;; -- WHN 2001-02-11
 950                         ;;
 951                         ;; FIXME: Actually, I think we could
 952                         ;; issue a full WARNING if the call
 953                         ;; violates a DECLAIM FTYPE.
 954                         :lossage-fun #'compiler-style-warn
 955                         :unwinnage-fun #'compiler-note)
 956          (assert-call-type call type)
 957          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 958          (recognize-known-call call ir1-converting-not-optimizing-p))
 959         (t
 960          (setf (combination-kind call) :error)
 961          (values nil nil))))
 962
 963 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 964 ;;; changed. If the call is local, we try to LET-convert it, and
 965 ;;; derive the result type. If it is a :FULL call, we validate it
 966 ;;; against the type, which recognizes known calls, does inline
 967 ;;; expansion, etc. If a call to a predicate in a non-conditional
 968 ;;; position or to a function with a source transform, then we
 969 ;;; reconvert the form to give IR1 another chance.
 970 (defun propagate-fun-change (call)
 971   (declare (type combination call))
 972   (let ((*compiler-error-context* call)
 973         (fun-cont (basic-combination-fun call)))
 974     (setf (continuation-reoptimize fun-cont) nil)
 975     (case (combination-kind call)
 976       (:local
 977        (let ((fun (combination-lambda call)))
 978          (maybe-let-convert fun)
 979          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 980            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 981       (:full
 982        (multiple-value-bind (leaf info)
 983            (validate-call-type call (continuation-type fun-cont) nil)
 984          (cond ((functional-p leaf)
 985                 (convert-call-if-possible
 986                  (continuation-use (basic-combination-fun call))
 987                  call))
 988                ((not leaf))
 989                ((and (leaf-has-source-name-p leaf)
 990                      (or (info :function :source-transform (leaf-source-name leaf))
 991                          (and info
 992                               (ir1-attributep (fun-info-attributes info)
 993                                               predicate)
 994                               (let ((dest (continuation-dest (node-cont call))))
 995                                 (and dest (not (if-p dest)))))))
 996                 ;; FIXME: This SYMBOLP is part of a literal
 997                 ;; translation of a test in the old CMU CL
 998                 ;; source, and it's not quite clear what
 999                 ;; the old source meant. Did it mean "has a
1000                 ;; valid name"? Or did it mean "is an
1001                 ;; ordinary function name, not a SETF
1002                 ;; function"? Either way, the old CMU CL
1003                 ;; code probably didn't deal with SETF
1004                 ;; functions correctly, and neither does
1005                 ;; this new SBCL code, and that should be fixed.
1006                 (when (symbolp (leaf-source-name leaf))
1007                   (let ((dummies (make-gensym-list
1008                                   (length (combination-args call)))))
1009                     (transform-call call
1010                                     `(lambda ,dummies
1011                                       (,(leaf-source-name leaf)
1012                                        ,@dummies))
1013                                     (leaf-source-name leaf))))))))))
1014   (values))
1015 \f
1016 ;;;; known function optimization
1017
1018 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
1019 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
1020 ;;; replace it, otherwise add a new one.
1021 (defun record-optimization-failure (node transform args)
1022   (declare (type combination node) (type transform transform)
1023            (type (or fun-type list) args))
1024   (let* ((table (component-failed-optimizations *component-being-compiled*))
1025          (found (assoc transform (gethash node table))))
1026     (if found
1027         (setf (cdr found) args)
1028         (push (cons transform args) (gethash node table))))
1029   (values))
1030
1031 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
1032 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
1033 ;;; doing the transform for some reason and FLAME is true, then we
1034 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
1035 ;;; finalize to pick up. We return true if the transform failed, and
1036 ;;; thus further transformation should be attempted. We return false
1037 ;;; if either the transform succeeded or was aborted.
1038 (defun ir1-transform (node transform)
1039   (declare (type combination node) (type transform transform))
1040   (let* ((type (transform-type transform))
1041          (fun (transform-function transform))
1042          (constrained (fun-type-p type))
1043          (table (component-failed-optimizations *component-being-compiled*))
1044          (flame (if (transform-important transform)
1045                     (policy node (>= speed inhibit-warnings))
1046                     (policy node (> speed inhibit-warnings))))
1047          (*compiler-error-context* node))
1048     (cond ((or (not constrained)
1049                (valid-fun-use node type :strict-result t))
1050            (multiple-value-bind (severity args)
1051                (catch 'give-up-ir1-transform
1052                  (transform-call node
1053                                  (funcall fun node)
1054                                  (combination-fun-source-name node))
1055                  (values :none nil))
1056              (ecase severity
1057                (:none
1058                 (remhash node table)
1059                 nil)
1060                (:aborted
1061                 (setf (combination-kind node) :error)
1062                 (when args
1063                   (apply #'compiler-warn args))
1064                 (remhash node table)
1065                 nil)
1066                (:failure
1067                 (if args
1068                     (when flame
1069                       (record-optimization-failure node transform args))
1070                     (setf (gethash node table)
1071                           (remove transform (gethash node table) :key #'car)))
1072                 t)
1073                (:delayed
1074                  (remhash node table)
1075                  nil))))
1076           ((and flame
1077                 (valid-fun-use node
1078                                type
1079                                :argument-test #'types-equal-or-intersect
1080                                :result-test #'values-types-equal-or-intersect))
1081            (record-optimization-failure node transform type)
1082            t)
1083           (t
1084            t))))
1085
1086 ;;; When we don't like an IR1 transform, we throw the severity/reason
1087 ;;; and args.
1088 ;;;
1089 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1090 ;;; aborting this attempt to transform the call, but admitting the
1091 ;;; possibility that this or some other transform will later succeed.
1092 ;;; If arguments are supplied, they are format arguments for an
1093 ;;; efficiency note.
1094 ;;;
1095 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1096 ;;; force a normal call to the function at run time. No further
1097 ;;; optimizations will be attempted.
1098 ;;;
1099 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1100 ;;; delay the transform on the node until later. REASONS specifies
1101 ;;; when the transform will be later retried. The :OPTIMIZE reason
1102 ;;; causes the transform to be delayed until after the current IR1
1103 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1104 ;;; be delayed until after constraint propagation.
1105 ;;;
1106 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1107 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1108 ;;; do CASE operations on the various REASON values, it might be a
1109 ;;; good idea to go OO, representing the reasons by objects, using
1110 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1111 ;;; SIGNAL instead of THROW.
1112 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1113 (defun give-up-ir1-transform (&rest args)
1114   (throw 'give-up-ir1-transform (values :failure args)))
1115 (defun abort-ir1-transform (&rest args)
1116   (throw 'give-up-ir1-transform (values :aborted args)))
1117 (defun delay-ir1-transform (node &rest reasons)
1118   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1119     (cond ((not assoc)
1120             (setf *delayed-ir1-transforms*
1121                     (acons node reasons *delayed-ir1-transforms*))
1122             (throw 'give-up-ir1-transform :delayed))
1123           ((cdr assoc)
1124             (dolist (reason reasons)
1125               (pushnew reason (cdr assoc)))
1126             (throw 'give-up-ir1-transform :delayed)))))
1127
1128 ;;; Clear any delayed transform with no reasons - these should have
1129 ;;; been tried in the last pass. Then remove the reason from the
1130 ;;; delayed transform reasons, and if any become empty then set
1131 ;;; reoptimize flags for the node. Return true if any transforms are
1132 ;;; to be retried.
1133 (defun retry-delayed-ir1-transforms (reason)
1134   (setf *delayed-ir1-transforms*
1135         (remove-if-not #'cdr *delayed-ir1-transforms*))
1136   (let ((reoptimize nil))
1137     (dolist (assoc *delayed-ir1-transforms*)
1138       (let ((reasons (remove reason (cdr assoc))))
1139         (setf (cdr assoc) reasons)
1140         (unless reasons
1141           (let ((node (car assoc)))
1142             (unless (node-deleted node)
1143               (setf reoptimize t)
1144               (setf (node-reoptimize node) t)
1145               (let ((block (node-block node)))
1146                 (setf (block-reoptimize block) t)
1147                 (setf (component-reoptimize (block-component block)) t)))))))
1148     reoptimize))
1149
1150 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1151 ;;; environment, and then install it as the function for the call
1152 ;;; NODE. We do local call analysis so that the new function is
1153 ;;; integrated into the control flow.
1154 ;;;
1155 ;;; We require the original function source name in order to generate
1156 ;;; a meaningful debug name for the lambda we set up. (It'd be
1157 ;;; possible to do this starting from debug names as well as source
1158 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1159 ;;; generality, since source names are always known to our callers.)
1160 (defun transform-call (node res source-name)
1161   (declare (type combination node) (list res))
1162   (aver (and (legal-fun-name-p source-name)
1163              (not (eql source-name '.anonymous.))))
1164   (with-ir1-environment-from-node node
1165       (let ((new-fun (ir1-convert-inline-lambda
1166                       res
1167                       :debug-name (debug-namify "LAMBDA-inlined ~A"
1168                                                 (as-debug-name
1169                                                  source-name
1170                                                  "<unknown function>"))))
1171             (ref (continuation-use (combination-fun node))))
1172         (change-ref-leaf ref new-fun)
1173         (setf (combination-kind node) :full)
1174         (locall-analyze-component *current-component*)))
1175   (values))
1176
1177 ;;; Replace a call to a foldable function of constant arguments with
1178 ;;; the result of evaluating the form. We insert the resulting
1179 ;;; constant node after the call, stealing the call's continuation. We
1180 ;;; give the call a continuation with no DEST, which should cause it
1181 ;;; and its arguments to go away. If there is an error during the
1182 ;;; evaluation, we give a warning and leave the call alone, making the
1183 ;;; call a :ERROR call.
1184 ;;;
1185 ;;; If there is more than one value, then we transform the call into a
1186 ;;; VALUES form.
1187 (defun constant-fold-call (call)
1188   (let ((args (mapcar #'continuation-value (combination-args call)))
1189         (fun-name (combination-fun-source-name call)))
1190     (multiple-value-bind (values win)
1191         (careful-call fun-name
1192                       args
1193                       call
1194                       ;; Note: CMU CL had COMPILER-WARN here, and that
1195                       ;; seems more natural, but it's probably not.
1196                       ;;
1197                       ;; It's especially not while bug 173 exists:
1198                       ;; Expressions like
1199                       ;;   (COND (END
1200                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1201                       ;;            ...))
1202                       ;; can cause constant-folding TYPE-ERRORs (in
1203                       ;; #'<=) when END can be proved to be NIL, even
1204                       ;; though the code is perfectly legal and safe
1205                       ;; because a NIL value of END means that the
1206                       ;; #'<= will never be executed.
1207                       ;;
1208                       ;; Moreover, even without bug 173,
1209                       ;; quite-possibly-valid code like
1210                       ;;   (COND ((NONINLINED-PREDICATE END)
1211                       ;;          (UNLESS (<= END SIZE))
1212                       ;;            ...))
1213                       ;; (where NONINLINED-PREDICATE is something the
1214                       ;; compiler can't do at compile time, but which
1215                       ;; turns out to make the #'<= expression
1216                       ;; unreachable when END=NIL) could cause errors
1217                       ;; when the compiler tries to constant-fold (<=
1218                       ;; END SIZE).
1219                       ;;
1220                       ;; So, with or without bug 173, it'd be
1221                       ;; unnecessarily evil to do a full
1222                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1223                       ;; from COMPILE-FILE) for legal code, so we we
1224                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1225                       #'compiler-style-warn
1226                       "constant folding")
1227       (if (not win)
1228           (setf (combination-kind call) :error)
1229           (let ((dummies (make-gensym-list (length args))))
1230             (transform-call
1231              call
1232              `(lambda ,dummies
1233                 (declare (ignore ,@dummies))
1234                 (values ,@(mapcar (lambda (x) `',x) values)))
1235              fun-name)))))
1236   (values))
1237 \f
1238 ;;;; local call optimization
1239
1240 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1241 ;;; the leaf type is a function type, then just leave it alone, since
1242 ;;; TYPE is never going to be more specific than that (and
1243 ;;; TYPE-INTERSECTION would choke.)
1244 (defun propagate-to-refs (leaf type)
1245   (declare (type leaf leaf) (type ctype type))
1246   (let ((var-type (leaf-type leaf)))
1247     (unless (fun-type-p var-type)
1248       (let ((int (type-approx-intersection2 var-type type)))
1249         (when (type/= int var-type)
1250           (setf (leaf-type leaf) int)
1251           (dolist (ref (leaf-refs leaf))
1252             (derive-node-type ref int))))
1253       (values))))
1254
1255 ;;; Figure out the type of a LET variable that has sets. We compute
1256 ;;; the union of the initial value Type and the types of all the set
1257 ;;; values and to a PROPAGATE-TO-REFS with this type.
1258 (defun propagate-from-sets (var type)
1259   (collect ((res type type-union))
1260     (dolist (set (basic-var-sets var))
1261       (res (continuation-type (set-value set)))
1262       (setf (node-reoptimize set) nil))
1263     (propagate-to-refs var (res)))
1264   (values))
1265
1266 ;;; If a LET variable, find the initial value's type and do
1267 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1268 ;;; type.
1269 (defun ir1-optimize-set (node)
1270   (declare (type cset node))
1271   (let ((var (set-var node)))
1272     (when (and (lambda-var-p var) (leaf-refs var))
1273       (let ((home (lambda-var-home var)))
1274         (when (eq (functional-kind home) :let)
1275           (let ((iv (let-var-initial-value var)))
1276             (setf (continuation-reoptimize iv) nil)
1277             (propagate-from-sets var (continuation-type iv)))))))
1278
1279   (derive-node-type node (continuation-type (set-value node)))
1280   (values))
1281
1282 ;;; Return true if the value of REF will always be the same (and is
1283 ;;; thus legal to substitute.)
1284 (defun constant-reference-p (ref)
1285   (declare (type ref ref))
1286   (let ((leaf (ref-leaf ref)))
1287     (typecase leaf
1288       ((or constant functional) t)
1289       (lambda-var
1290        (null (lambda-var-sets leaf)))
1291       (defined-fun
1292        (not (eq (defined-fun-inlinep leaf) :notinline)))
1293       (global-var
1294        (case (global-var-kind leaf)
1295          (:global-function t))))))
1296
1297 ;;; If we have a non-set LET var with a single use, then (if possible)
1298 ;;; replace the variable reference's CONT with the arg continuation.
1299 ;;; This is inhibited when:
1300 ;;; -- CONT has other uses, or
1301 ;;; -- CONT receives multiple values, or
1302 ;;; -- the reference is in a different environment from the variable, or
1303 ;;; -- either continuation has a funky TYPE-CHECK annotation.
1304 ;;; -- the continuations have incompatible assertions, so the new asserted type
1305 ;;;    would be NIL.
1306 ;;; -- the var's DEST has a different policy than the ARG's (think safety).
1307 ;;;
1308 ;;; We change the REF to be a reference to NIL with unused value, and
1309 ;;; let it be flushed as dead code. A side effect of this substitution
1310 ;;; is to delete the variable.
1311 (defun substitute-single-use-continuation (arg var)
1312   (declare (type continuation arg) (type lambda-var var))
1313   (let* ((ref (first (leaf-refs var)))
1314          (cont (node-cont ref))
1315          (cont-atype (continuation-asserted-type cont))
1316          (dest (continuation-dest cont)))
1317     (when (and (eq (continuation-use cont) ref)
1318                dest
1319                (not (typep dest '(or creturn exit mv-combination)))
1320                (eq (node-home-lambda ref)
1321                    (lambda-home (lambda-var-home var)))
1322                (member (continuation-type-check arg) '(t nil))
1323                (member (continuation-type-check cont) '(t nil))
1324                (not (eq (values-type-intersection
1325                          cont-atype
1326                          (continuation-asserted-type arg))
1327                         *empty-type*))
1328                (eq (lexenv-policy (node-lexenv dest))
1329                    (lexenv-policy (node-lexenv (continuation-dest arg)))))
1330       (aver (member (continuation-kind arg)
1331                     '(:block-start :deleted-block-start :inside-block)))
1332       (assert-continuation-type arg cont-atype)
1333       (setf (node-derived-type ref) *wild-type*)
1334       (change-ref-leaf ref (find-constant nil))
1335       (substitute-continuation arg cont)
1336       (reoptimize-continuation arg)
1337       t)))
1338
1339 ;;; Delete a LET, removing the call and bind nodes, and warning about
1340 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1341 ;;; along right away and delete the REF and then the lambda, since we
1342 ;;; flush the FUN continuation.
1343 (defun delete-let (clambda)
1344   (declare (type clambda clambda))
1345   (aver (functional-letlike-p clambda))
1346   (note-unreferenced-vars clambda)
1347   (let ((call (let-combination clambda)))
1348     (flush-dest (basic-combination-fun call))
1349     (unlink-node call)
1350     (unlink-node (lambda-bind clambda))
1351     (setf (lambda-bind clambda) nil))
1352   (values))
1353
1354 ;;; This function is called when one of the arguments to a LET
1355 ;;; changes. We look at each changed argument. If the corresponding
1356 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1357 ;;; consider substituting for the variable, and also propagate
1358 ;;; derived-type information for the arg to all the VAR's refs.
1359 ;;;
1360 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1361 ;;; subtype of the argument's asserted type. This prevents type
1362 ;;; checking from being defeated, and also ensures that the best
1363 ;;; representation for the variable can be used.
1364 ;;;
1365 ;;; Substitution of individual references is inhibited if the
1366 ;;; reference is in a different component from the home. This can only
1367 ;;; happen with closures over top level lambda vars. In such cases,
1368 ;;; the references may have already been compiled, and thus can't be
1369 ;;; retroactively modified.
1370 ;;;
1371 ;;; If all of the variables are deleted (have no references) when we
1372 ;;; are done, then we delete the LET.
1373 ;;;
1374 ;;; Note that we are responsible for clearing the
1375 ;;; CONTINUATION-REOPTIMIZE flags.
1376 (defun propagate-let-args (call fun)
1377   (declare (type combination call) (type clambda fun))
1378   (loop for arg in (combination-args call)
1379         and var in (lambda-vars fun) do
1380     (when (and arg (continuation-reoptimize arg))
1381       (setf (continuation-reoptimize arg) nil)
1382       (cond
1383        ((lambda-var-sets var)
1384         (propagate-from-sets var (continuation-type arg)))
1385        ((let ((use (continuation-use arg)))
1386           (when (ref-p use)
1387             (let ((leaf (ref-leaf use)))
1388               (when (and (constant-reference-p use)
1389                          (values-subtypep (leaf-type leaf)
1390                                           (continuation-asserted-type arg)))
1391                 (propagate-to-refs var (continuation-type arg))
1392                 (let ((use-component (node-component use)))
1393                   (substitute-leaf-if
1394                    (lambda (ref)
1395                      (cond ((eq (node-component ref) use-component)
1396                             t)
1397                            (t
1398                             (aver (lambda-toplevelish-p (lambda-home fun)))
1399                             nil)))
1400                    leaf var))
1401                 t)))))
1402        ((and (null (rest (leaf-refs var)))
1403              (substitute-single-use-continuation arg var)))
1404        (t
1405         (propagate-to-refs var (continuation-type arg))))))
1406
1407   (when (every #'null (combination-args call))
1408     (delete-let fun))
1409
1410   (values))
1411
1412 ;;; This function is called when one of the args to a non-LET local
1413 ;;; call changes. For each changed argument corresponding to an unset
1414 ;;; variable, we compute the union of the types across all calls and
1415 ;;; propagate this type information to the var's refs.
1416 ;;;
1417 ;;; If the function has an XEP, then we don't do anything, since we
1418 ;;; won't discover anything.
1419 ;;;
1420 ;;; We can clear the Continuation-Reoptimize flags for arguments in
1421 ;;; all calls corresponding to changed arguments in Call, since the
1422 ;;; only use in IR1 optimization of the Reoptimize flag for local call
1423 ;;; args is right here.
1424 (defun propagate-local-call-args (call fun)
1425   (declare (type combination call) (type clambda fun))
1426
1427   (unless (or (functional-entry-fun fun)
1428               (lambda-optional-dispatch fun))
1429     (let* ((vars (lambda-vars fun))
1430            (union (mapcar (lambda (arg var)
1431                             (when (and arg
1432                                        (continuation-reoptimize arg)
1433                                        (null (basic-var-sets var)))
1434                               (continuation-type arg)))
1435                           (basic-combination-args call)
1436                           vars))
1437            (this-ref (continuation-use (basic-combination-fun call))))
1438
1439       (dolist (arg (basic-combination-args call))
1440         (when arg
1441           (setf (continuation-reoptimize arg) nil)))
1442
1443       (dolist (ref (leaf-refs fun))
1444         (let ((dest (continuation-dest (node-cont ref))))
1445           (unless (or (eq ref this-ref) (not dest))
1446             (setq union
1447                   (mapcar (lambda (this-arg old)
1448                             (when old
1449                               (setf (continuation-reoptimize this-arg) nil)
1450                               (type-union (continuation-type this-arg) old)))
1451                           (basic-combination-args dest)
1452                           union)))))
1453
1454       (mapc (lambda (var type)
1455               (when type
1456                 (propagate-to-refs var type)))
1457             vars union)))
1458
1459   (values))
1460 \f
1461 ;;;; multiple values optimization
1462
1463 ;;; Do stuff to notice a change to a MV combination node. There are
1464 ;;; two main branches here:
1465 ;;;  -- If the call is local, then it is already a MV let, or should
1466 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1467 ;;;     be converted to :MV-LETs, there can be a window when the call
1468 ;;;     is local, but has not been LET converted yet. This is because
1469 ;;;     the entry-point lambdas may have stray references (in other
1470 ;;;     entry points) that have not been deleted yet.
1471 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1472 ;;;     combination optimization: we propagate return type information and
1473 ;;;     notice non-returning calls. We also have an optimization
1474 ;;;     which tries to convert MV-CALLs into MV-binds.
1475 (defun ir1-optimize-mv-combination (node)
1476   (ecase (basic-combination-kind node)
1477     (:local
1478      (let ((fun-cont (basic-combination-fun node)))
1479        (when (continuation-reoptimize fun-cont)
1480          (setf (continuation-reoptimize fun-cont) nil)
1481          (maybe-let-convert (combination-lambda node))))
1482      (setf (continuation-reoptimize (first (basic-combination-args node))) nil)
1483      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1484        (unless (convert-mv-bind-to-let node)
1485          (ir1-optimize-mv-bind node))))
1486     (:full
1487      (let* ((fun (basic-combination-fun node))
1488             (fun-changed (continuation-reoptimize fun))
1489             (args (basic-combination-args node)))
1490        (when fun-changed
1491          (setf (continuation-reoptimize fun) nil)
1492          (let ((type (continuation-type fun)))
1493            (when (fun-type-p type)
1494              (derive-node-type node (fun-type-returns type))))
1495          (maybe-terminate-block node nil)
1496          (let ((use (continuation-use fun)))
1497            (when (and (ref-p use) (functional-p (ref-leaf use)))
1498              (convert-call-if-possible use node)
1499              (when (eq (basic-combination-kind node) :local)
1500                (maybe-let-convert (ref-leaf use))))))
1501        (unless (or (eq (basic-combination-kind node) :local)
1502                    (eq (continuation-fun-name fun) '%throw))
1503          (ir1-optimize-mv-call node))
1504        (dolist (arg args)
1505          (setf (continuation-reoptimize arg) nil))))
1506     (:error))
1507   (values))
1508
1509 ;;; Propagate derived type info from the values continuation to the
1510 ;;; vars.
1511 (defun ir1-optimize-mv-bind (node)
1512   (declare (type mv-combination node))
1513   (let ((arg (first (basic-combination-args node)))
1514         (vars (lambda-vars (combination-lambda node))))
1515     (multiple-value-bind (types nvals)
1516         (values-types (continuation-derived-type arg))
1517       (unless (eq nvals :unknown)
1518         (mapc (lambda (var type)
1519                 (if (basic-var-sets var)
1520                     (propagate-from-sets var type)
1521                     (propagate-to-refs var type)))
1522               vars
1523                 (append types
1524                         (make-list (max (- (length vars) nvals) 0)
1525                                    :initial-element (specifier-type 'null))))))
1526     (setf (continuation-reoptimize arg) nil))
1527   (values))
1528
1529 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1530 ;;; this if:
1531 ;;; -- The call has only one argument, and
1532 ;;; -- The function has a known fixed number of arguments, or
1533 ;;; -- The argument yields a known fixed number of values.
1534 ;;;
1535 ;;; What we do is change the function in the MV-CALL to be a lambda
1536 ;;; that "looks like an MV bind", which allows
1537 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1538 ;;; converted (the next time around.) This new lambda just calls the
1539 ;;; actual function with the MV-BIND variables as arguments. Note that
1540 ;;; this new MV bind is not let-converted immediately, as there are
1541 ;;; going to be stray references from the entry-point functions until
1542 ;;; they get deleted.
1543 ;;;
1544 ;;; In order to avoid loss of argument count checking, we only do the
1545 ;;; transformation according to a known number of expected argument if
1546 ;;; safety is unimportant. We can always convert if we know the number
1547 ;;; of actual values, since the normal call that we build will still
1548 ;;; do any appropriate argument count checking.
1549 ;;;
1550 ;;; We only attempt the transformation if the called function is a
1551 ;;; constant reference. This allows us to just splice the leaf into
1552 ;;; the new function, instead of trying to somehow bind the function
1553 ;;; expression. The leaf must be constant because we are evaluating it
1554 ;;; again in a different place. This also has the effect of squelching
1555 ;;; multiple warnings when there is an argument count error.
1556 (defun ir1-optimize-mv-call (node)
1557   (let ((fun (basic-combination-fun node))
1558         (*compiler-error-context* node)
1559         (ref (continuation-use (basic-combination-fun node)))
1560         (args (basic-combination-args node)))
1561
1562     (unless (and (ref-p ref) (constant-reference-p ref)
1563                  args (null (rest args)))
1564       (return-from ir1-optimize-mv-call))
1565
1566     (multiple-value-bind (min max)
1567         (fun-type-nargs (continuation-type fun))
1568       (let ((total-nvals
1569              (multiple-value-bind (types nvals)
1570                  (values-types (continuation-derived-type (first args)))
1571                (declare (ignore types))
1572                (if (eq nvals :unknown) nil nvals))))
1573
1574         (when total-nvals
1575           (when (and min (< total-nvals min))
1576             (compiler-warn
1577              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1578              at least ~R."
1579              total-nvals min)
1580             (setf (basic-combination-kind node) :error)
1581             (return-from ir1-optimize-mv-call))
1582           (when (and max (> total-nvals max))
1583             (compiler-warn
1584              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1585              at most ~R."
1586              total-nvals max)
1587             (setf (basic-combination-kind node) :error)
1588             (return-from ir1-optimize-mv-call)))
1589
1590         (let ((count (cond (total-nvals)
1591                            ((and (policy node (zerop safety))
1592                                  (eql min max))
1593                             min)
1594                            (t nil))))
1595           (when count
1596             (with-ir1-environment-from-node node
1597               (let* ((dums (make-gensym-list count))
1598                      (ignore (gensym))
1599                      (fun (ir1-convert-lambda
1600                            `(lambda (&optional ,@dums &rest ,ignore)
1601                               (declare (ignore ,ignore))
1602                               (funcall ,(ref-leaf ref) ,@dums)))))
1603                 (change-ref-leaf ref fun)
1604                 (aver (eq (basic-combination-kind node) :full))
1605                 (locall-analyze-component *current-component*)
1606                 (aver (eq (basic-combination-kind node) :local)))))))))
1607   (values))
1608
1609 ;;; If we see:
1610 ;;;    (multiple-value-bind
1611 ;;;     (x y)
1612 ;;;     (values xx yy)
1613 ;;;      ...)
1614 ;;; Convert to:
1615 ;;;    (let ((x xx)
1616 ;;;       (y yy))
1617 ;;;      ...)
1618 ;;;
1619 ;;; What we actually do is convert the VALUES combination into a
1620 ;;; normal LET combination calling the original :MV-LET lambda. If
1621 ;;; there are extra args to VALUES, discard the corresponding
1622 ;;; continuations. If there are insufficient args, insert references
1623 ;;; to NIL.
1624 (defun convert-mv-bind-to-let (call)
1625   (declare (type mv-combination call))
1626   (let* ((arg (first (basic-combination-args call)))
1627          (use (continuation-use arg)))
1628     (when (and (combination-p use)
1629                (eq (continuation-fun-name (combination-fun use))
1630                    'values))
1631       (let* ((fun (combination-lambda call))
1632              (vars (lambda-vars fun))
1633              (vals (combination-args use))
1634              (nvars (length vars))
1635              (nvals (length vals)))
1636         (cond ((> nvals nvars)
1637                (mapc #'flush-dest (subseq vals nvars))
1638                (setq vals (subseq vals 0 nvars)))
1639               ((< nvals nvars)
1640                (with-ir1-environment-from-node use
1641                  (let ((node-prev (node-prev use)))
1642                    (setf (node-prev use) nil)
1643                    (setf (continuation-next node-prev) nil)
1644                    (collect ((res vals))
1645                      (loop as cont = (make-continuation use)
1646                            and prev = node-prev then cont
1647                            repeat (- nvars nvals)
1648                            do (reference-constant prev cont nil)
1649                               (res cont))
1650                      (setq vals (res)))
1651                    (link-node-to-previous-continuation use
1652                                                        (car (last vals)))))))
1653         (setf (combination-args use) vals)
1654         (flush-dest (combination-fun use))
1655         (let ((fun-cont (basic-combination-fun call)))
1656           (setf (continuation-dest fun-cont) use)
1657           (setf (combination-fun use) fun-cont)
1658           (setf (continuation-%externally-checkable-type fun-cont) nil))
1659         (setf (combination-kind use) :local)
1660         (setf (functional-kind fun) :let)
1661         (flush-dest (first (basic-combination-args call)))
1662         (unlink-node call)
1663         (when vals
1664           (reoptimize-continuation (first vals)))
1665         (propagate-to-args use fun))
1666       t)))
1667
1668 ;;; If we see:
1669 ;;;    (values-list (list x y z))
1670 ;;;
1671 ;;; Convert to:
1672 ;;;    (values x y z)
1673 ;;;
1674 ;;; In implementation, this is somewhat similar to
1675 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1676 ;;; args of the VALUES-LIST call, flushing the old argument
1677 ;;; continuation (allowing the LIST to be flushed.)
1678 (defoptimizer (values-list optimizer) ((list) node)
1679   (let ((use (continuation-use list)))
1680     (when (and (combination-p use)
1681                (eq (continuation-fun-name (combination-fun use))
1682                    'list))
1683       (change-ref-leaf (continuation-use (combination-fun node))
1684                        (find-free-fun 'values "in a strange place"))
1685       (setf (combination-kind node) :full)
1686       (let ((args (combination-args use)))
1687         (dolist (arg args)
1688           (setf (continuation-dest arg) node)
1689           (setf (continuation-%externally-checkable-type arg) nil))
1690         (setf (combination-args use) nil)
1691         (flush-dest list)
1692         (setf (combination-args node) args))
1693       t)))
1694
1695 ;;; If VALUES appears in a non-MV context, then effectively convert it
1696 ;;; to a PROG1. This allows the computation of the additional values
1697 ;;; to become dead code.
1698 (deftransform values ((&rest vals) * * :node node)
1699   (when (typep (continuation-dest (node-cont node))
1700                '(or creturn exit mv-combination))
1701     (give-up-ir1-transform))
1702   (setf (node-derived-type node) *wild-type*)
1703   (if vals
1704       (let ((dummies (make-gensym-list (length (cdr vals)))))
1705         `(lambda (val ,@dummies)
1706            (declare (ignore ,@dummies))
1707            val))
1708       nil))