src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for an LVAR whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-lvar-p (thing)
  24   (declare (type (or lvar null) thing))
  25   (and (lvar-p thing)
  26        (let ((use (principal-lvar-use thing)))
  27          (and (ref-p use) (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for an LVAR whose only use is a constant
  30 ;;; node.
  31 (declaim (ftype (function (lvar) t) lvar-value))
  32 (defun lvar-value (lvar)
  33   (let ((use (principal-lvar-use lvar)))
  34     (constant-value (ref-leaf use))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Our best guess for the type of this lvar's value. Note that this
  39 ;;; may be VALUES or FUNCTION type, which cannot be passed as an
  40 ;;; argument to the normal type operations. See LVAR-TYPE.
  41 ;;;
  42 ;;; The result value is cached in the LVAR-%DERIVED-TYPE slot. If the
  43 ;;; slot is true, just return that value, otherwise recompute and
  44 ;;; stash the value there.
  45 #!-sb-fluid (declaim (inline lvar-derived-type))
  46 (defun lvar-derived-type (lvar)
  47   (declare (type lvar lvar))
  48   (or (lvar-%derived-type lvar)
  49       (setf (lvar-%derived-type lvar)
  50             (%lvar-derived-type lvar))))
  51 (defun %lvar-derived-type (lvar)
  52   (declare (type lvar lvar))
  53   (let ((uses (lvar-uses lvar)))
  54     (cond ((null uses) *empty-type*)
  55           ((listp uses)
  56            (do ((res (node-derived-type (first uses))
  57                      (values-type-union (node-derived-type (first current))
  58                                         res))
  59                 (current (rest uses) (rest current)))
  60                ((null current) res)))
  61           (t
  62            (node-derived-type (lvar-uses lvar))))))
  63
  64 ;;; Return the derived type for LVAR's first value. This is guaranteed
  65 ;;; not to be a VALUES or FUNCTION type.
  66 (declaim (ftype (sfunction (lvar) ctype) lvar-type))
  67 (defun lvar-type (lvar)
  68   (single-value-type (lvar-derived-type lvar)))
  69
  70 ;;; If LVAR is an argument of a function, return a type which the
  71 ;;; function checks LVAR for.
  72 #!-sb-fluid (declaim (inline lvar-externally-checkable-type))
  73 (defun lvar-externally-checkable-type (lvar)
  74   (or (lvar-%externally-checkable-type lvar)
  75       (%lvar-%externally-checkable-type lvar)))
  76 (defun %lvar-%externally-checkable-type (lvar)
  77   (declare (type lvar lvar))
  78   (let ((dest (lvar-dest lvar)))
  79     (if (not (and dest (combination-p dest)))
  80         ;; TODO: MV-COMBINATION
  81         (setf (lvar-%externally-checkable-type lvar) *wild-type*)
  82         (let* ((fun (combination-fun dest))
  83                (args (combination-args dest))
  84                (fun-type (lvar-type fun)))
  85           (setf (lvar-%externally-checkable-type fun) *wild-type*)
  86           (if (or (not (call-full-like-p dest))
  87                   (not (fun-type-p fun-type))
  88                   ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
  89                   (fun-type-wild-args fun-type))
  90               (dolist (arg args)
  91                 (when arg
  92                   (setf (lvar-%externally-checkable-type arg)
  93                         *wild-type*)))
  94               (map-combination-args-and-types
  95                (lambda (arg type)
  96                  (setf (lvar-%externally-checkable-type arg)
  97                        (acond ((lvar-%externally-checkable-type arg)
  98                                (values-type-intersection
  99                                 it (coerce-to-values type)))
 100                               (t (coerce-to-values type)))))
 101                dest)))))
 102   (lvar-%externally-checkable-type lvar))
 103 #!-sb-fluid(declaim (inline flush-lvar-externally-checkable-type))
 104 (defun flush-lvar-externally-checkable-type (lvar)
 105   (declare (type lvar lvar))
 106   (setf (lvar-%externally-checkable-type lvar) nil))
 107 \f
 108 ;;;; interface routines used by optimizers
 109
 110 ;;; This function is called by optimizers to indicate that something
 111 ;;; interesting has happened to the value of LVAR. Optimizers must
 112 ;;; make sure that they don't call for reoptimization when nothing has
 113 ;;; happened, since optimization will fail to terminate.
 114 ;;;
 115 ;;; We clear any cached type for the lvar and set the reoptimize flags
 116 ;;; on everything in sight.
 117 (defun reoptimize-lvar (lvar)
 118   (declare (type (or lvar null) lvar))
 119   (when lvar
 120     (setf (lvar-%derived-type lvar) nil)
 121     (let ((dest (lvar-dest lvar)))
 122       (when dest
 123         (setf (lvar-reoptimize lvar) t)
 124         (setf (node-reoptimize dest) t)
 125         (binding* (;; Since this may be called during IR1 conversion,
 126                    ;; PREV may be missing.
 127                    (prev (node-prev dest) :exit-if-null)
 128                    (block (ctran-block prev))
 129                    (component (block-component block)))
 130           (when (typep dest 'cif)
 131             (setf (block-test-modified block) t))
 132           (setf (block-reoptimize block) t)
 133           (setf (component-reoptimize component) t))))
 134     (do-uses (node lvar)
 135       (setf (block-type-check (node-block node)) t)))
 136   (values))
 137
 138 (defun reoptimize-lvar-uses (lvar)
 139   (declare (type lvar lvar))
 140   (do-uses (use lvar)
 141     (setf (node-reoptimize use) t)
 142     (setf (block-reoptimize (node-block use)) t)
 143     (setf (component-reoptimize (node-component use)) t)))
 144
 145 ;;; Annotate NODE to indicate that its result has been proven to be
 146 ;;; TYPEP to RTYPE. After IR1 conversion has happened, this is the
 147 ;;; only correct way to supply information discovered about a node's
 148 ;;; type. If you screw with the NODE-DERIVED-TYPE directly, then
 149 ;;; information may be lost and reoptimization may not happen.
 150 ;;;
 151 ;;; What we do is intersect RTYPE with NODE's DERIVED-TYPE. If the
 152 ;;; intersection is different from the old type, then we do a
 153 ;;; REOPTIMIZE-LVAR on the NODE-LVAR.
 154 (defun derive-node-type (node rtype)
 155   (declare (type valued-node node) (type ctype rtype))
 156   (let ((node-type (node-derived-type node)))
 157     (unless (eq node-type rtype)
 158       (let ((int (values-type-intersection node-type rtype))
 159             (lvar (node-lvar node)))
 160         (when (type/= node-type int)
 161           (when (and *check-consistency*
 162                      (eq int *empty-type*)
 163                      (not (eq rtype *empty-type*)))
 164             (let ((*compiler-error-context* node))
 165               (compiler-warn
 166                "New inferred type ~S conflicts with old type:~
 167                 ~%  ~S~%*** possible internal error? Please report this."
 168                (type-specifier rtype) (type-specifier node-type))))
 169           (setf (node-derived-type node) int)
 170           ;; If the new type consists of only one object, replace the
 171           ;; node with a constant reference.
 172           (when (and (ref-p node)
 173                      (lambda-var-p (ref-leaf node)))
 174             (let ((type (single-value-type int)))
 175               (when (and (member-type-p type)
 176                          (null (rest (member-type-members type))))
 177                 (change-ref-leaf node (find-constant
 178                                        (first (member-type-members type)))))))
 179           (reoptimize-lvar lvar)))))
 180   (values))
 181
 182 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 183 ;;; error for LVAR's value not to be TYPEP to TYPE. We implement it
 184 ;;; splitting off DEST a new CAST node; old LVAR will deliver values
 185 ;;; to CAST. If we improve the assertion, we set TYPE-CHECK and
 186 ;;; TYPE-ASSERTED to guarantee that the new assertion will be checked.
 187 (defun assert-lvar-type (lvar type policy)
 188   (declare (type lvar lvar) (type ctype type))
 189   (unless (values-subtypep (lvar-derived-type lvar) type)
 190     (let* ((dest (lvar-dest lvar))
 191            (ctran (node-prev dest)))
 192       (with-ir1-environment-from-node dest
 193         (let* ((cast (make-cast lvar type policy))
 194                (internal-lvar (make-lvar))
 195                (internal-ctran (make-ctran)))
 196           (setf (ctran-next ctran) cast
 197                 (node-prev cast) ctran)
 198           (use-continuation cast internal-ctran internal-lvar)
 199           (link-node-to-previous-ctran dest internal-ctran)
 200           (substitute-lvar internal-lvar lvar)
 201           (setf (lvar-dest lvar) cast)
 202           (reoptimize-lvar lvar)
 203           (when (return-p dest)
 204             (node-ends-block cast))
 205           (setf (block-attributep (block-flags (node-block cast))
 206                                   type-check type-asserted)
 207                 t))))))
 208
 209 \f
 210 ;;;; IR1-OPTIMIZE
 211
 212 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 213 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 214 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 215 ;;; we are done, then another iteration would be beneficial.
 216 (defun ir1-optimize (component)
 217   (declare (type component component))
 218   (setf (component-reoptimize component) nil)
 219   (loop with block = (block-next (component-head component))
 220         with tail = (component-tail component)
 221         for last-block = block
 222         until (eq block tail)
 223         do (cond
 224              ;; We delete blocks when there is either no predecessor or the
 225              ;; block is in a lambda that has been deleted. These blocks
 226              ;; would eventually be deleted by DFO recomputation, but doing
 227              ;; it here immediately makes the effect available to IR1
 228              ;; optimization.
 229              ((or (block-delete-p block)
 230                   (null (block-pred block)))
 231               (delete-block-lazily block)
 232               (setq block (clean-component component block)))
 233              ((eq (functional-kind (block-home-lambda block)) :deleted)
 234               ;; Preserve the BLOCK-SUCC invariant that almost every block has
 235               ;; one successor (and a block with DELETE-P set is an acceptable
 236               ;; exception).
 237               (mark-for-deletion block)
 238               (setq block (clean-component component block)))
 239              (t
 240               (loop
 241                  (let ((succ (block-succ block)))
 242                    (unless (singleton-p succ)
 243                      (return)))
 244
 245                  (let ((last (block-last block)))
 246                    (typecase last
 247                      (cif
 248                       (flush-dest (if-test last))
 249                       (when (unlink-node last)
 250                         (return)))
 251                      (exit
 252                       (when (maybe-delete-exit last)
 253                         (return)))))
 254
 255                  (unless (join-successor-if-possible block)
 256                    (return)))
 257
 258               (when (and (block-reoptimize block) (block-component block))
 259                 (aver (not (block-delete-p block)))
 260                 (ir1-optimize-block block))
 261
 262               (cond ((and (block-delete-p block) (block-component block))
 263                      (setq block (clean-component component block)))
 264                     ((and (block-flush-p block) (block-component block))
 265                      (flush-dead-code block)))))
 266         do (when (eq block last-block)
 267              (setq block (block-next block))))
 268
 269   (values))
 270
 271 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 272 ;;; flags.
 273 ;;;
 274 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 275 ;;; still be set upon return from this function, meaning that further
 276 ;;; optimization is wanted (as a consequence of optimizations we did).
 277 (defun ir1-optimize-block (block)
 278   (declare (type cblock block))
 279   ;; We clear the node and block REOPTIMIZE flags before doing the
 280   ;; optimization, not after. This ensures that the node or block will
 281   ;; be reoptimized if necessary.
 282   (setf (block-reoptimize block) nil)
 283   (do-nodes (node nil block :restart-p t)
 284     (when (node-reoptimize node)
 285       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 286       (setf (node-reoptimize node) nil)
 287       (typecase node
 288         (ref)
 289         (combination
 290          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 291          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 292          ;; any argument changes.
 293          (ir1-optimize-combination node))
 294         (cif
 295          (ir1-optimize-if node))
 296         (creturn
 297          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 298          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 299          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 300          ;; CMU CL comments
 301          (setf (node-reoptimize node) t)
 302          (ir1-optimize-return node))
 303         (mv-combination
 304          (ir1-optimize-mv-combination node))
 305         (exit
 306          ;; With an EXIT, we derive the node's type from the VALUE's
 307          ;; type.
 308          (let ((value (exit-value node)))
 309            (when value
 310              (derive-node-type node (lvar-derived-type value)))))
 311         (cset
 312          (ir1-optimize-set node))
 313         (cast
 314          (ir1-optimize-cast node)))))
 315
 316   (values))
 317
 318 ;;; Try to join with a successor block. If we succeed, we return true,
 319 ;;; otherwise false.
 320 (defun join-successor-if-possible (block)
 321   (declare (type cblock block))
 322   (let ((next (first (block-succ block))))
 323     (when (block-start next)  ; NEXT is not an END-OF-COMPONENT marker
 324       (cond ( ;; We cannot combine with a successor block if:
 325              (or
 326               ;; the successor has more than one predecessor;
 327               (rest (block-pred next))
 328               ;; the successor is the current block (infinite loop);
 329               (eq next block)
 330               ;; the next block has a different cleanup, and thus
 331               ;; we may want to insert cleanup code between the
 332               ;; two blocks at some point;
 333               (not (eq (block-end-cleanup block)
 334                        (block-start-cleanup next)))
 335               ;; the next block has a different home lambda, and
 336               ;; thus the control transfer is a non-local exit.
 337               (not (eq (block-home-lambda block)
 338                        (block-home-lambda next)))
 339               ;; Stack analysis phase wants ENTRY to start a block...
 340               (entry-p (block-start-node next))
 341               (let ((last (block-last block)))
 342                 (and (valued-node-p last)
 343                      (awhen (node-lvar last)
 344                        (or
 345                         ;; ... and a DX-allocator to end a block.
 346                         (lvar-dynamic-extent it)
 347                         ;; FIXME: This is a partial workaround for bug 303.
 348                         (consp (lvar-uses it)))))))
 349              nil)
 350             (t
 351              (join-blocks block next)
 352              t)))))
 353
 354 ;;; Join together two blocks. The code in BLOCK2 is moved into BLOCK1
 355 ;;; and BLOCK2 is deleted from the DFO. We combine the optimize flags
 356 ;;; for the two blocks so that any indicated optimization gets done.
 357 (defun join-blocks (block1 block2)
 358   (declare (type cblock block1 block2))
 359   (let* ((last1 (block-last block1))
 360          (last2 (block-last block2))
 361          (succ (block-succ block2))
 362          (start2 (block-start block2)))
 363     (do ((ctran start2 (node-next (ctran-next ctran))))
 364         ((not ctran))
 365       (setf (ctran-block ctran) block1))
 366
 367     (unlink-blocks block1 block2)
 368     (dolist (block succ)
 369       (unlink-blocks block2 block)
 370       (link-blocks block1 block))
 371
 372     (setf (ctran-kind start2) :inside-block)
 373     (setf (node-next last1) start2)
 374     (setf (ctran-use start2) last1)
 375     (setf (block-last block1) last2))
 376
 377   (setf (block-flags block1)
 378         (attributes-union (block-flags block1)
 379                           (block-flags block2)
 380                           (block-attributes type-asserted test-modified)))
 381
 382   (let ((next (block-next block2))
 383         (prev (block-prev block2)))
 384     (setf (block-next prev) next)
 385     (setf (block-prev next) prev))
 386
 387   (values))
 388
 389 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 390 ;;; side effects. We can delete sets of lexical variables when the set
 391 ;;; variable has no references.
 392 (defun flush-dead-code (block)
 393   (declare (type cblock block))
 394   (setf (block-flush-p block) nil)
 395   (do-nodes-backwards (node lvar block :restart-p t)
 396     (unless lvar
 397       (typecase node
 398         (ref
 399          (delete-ref node)
 400          (unlink-node node))
 401         (combination
 402          (let ((kind (combination-kind node))
 403                (info (combination-fun-info node)))
 404            (when (and (eq kind :known) (fun-info-p info))
 405              (let ((attr (fun-info-attributes info)))
 406                (when (and (not (ir1-attributep attr call))
 407                           ;; ### For now, don't delete potentially
 408                           ;; flushable calls when they have the CALL
 409                           ;; attribute. Someday we should look at the
 410                           ;; functional args to determine if they have
 411                           ;; any side effects.
 412                           (if (policy node (= safety 3))
 413                               (ir1-attributep attr flushable)
 414                               (ir1-attributep attr unsafely-flushable)))
 415                  (flush-combination node))))))
 416         (mv-combination
 417          (when (eq (basic-combination-kind node) :local)
 418            (let ((fun (combination-lambda node)))
 419              (when (dolist (var (lambda-vars fun) t)
 420                      (when (or (leaf-refs var)
 421                                (lambda-var-sets var))
 422                        (return nil)))
 423                (flush-dest (first (basic-combination-args node)))
 424                (delete-let fun)))))
 425         (exit
 426          (let ((value (exit-value node)))
 427            (when value
 428              (flush-dest value)
 429              (setf (exit-value node) nil))))
 430         (cset
 431          (let ((var (set-var node)))
 432            (when (and (lambda-var-p var)
 433                       (null (leaf-refs var)))
 434              (flush-dest (set-value node))
 435              (setf (basic-var-sets var)
 436                    (delq node (basic-var-sets var)))
 437              (unlink-node node))))
 438         (cast
 439          (unless (cast-type-check node)
 440            (flush-dest (cast-value node))
 441            (unlink-node node))))))
 442
 443   (values))
 444 \f
 445 ;;;; local call return type propagation
 446
 447 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 448 ;;; flag set. It iterates over the uses of the RESULT, looking for
 449 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 450 ;;; call, then we union its type together with the types of other such
 451 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 452 ;;; type with the RESULT's asserted type. We can make this
 453 ;;; intersection now (potentially before type checking) because this
 454 ;;; assertion on the result will eventually be checked (if
 455 ;;; appropriate.)
 456 ;;;
 457 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 458 ;;; combination, which may change the succesor of the call to be the
 459 ;;; called function, and if so, checks if the call can become an
 460 ;;; assignment. If we convert to an assignment, we abort, since the
 461 ;;; RETURN has been deleted.
 462 (defun find-result-type (node)
 463   (declare (type creturn node))
 464   (let ((result (return-result node)))
 465     (collect ((use-union *empty-type* values-type-union))
 466       (do-uses (use result)
 467         (let ((use-home (node-home-lambda use)))
 468           (cond ((or (eq (functional-kind use-home) :deleted)
 469                      (block-delete-p (node-block use))))
 470                 ((and (basic-combination-p use)
 471                       (eq (basic-combination-kind use) :local))
 472                  (aver (eq (lambda-tail-set use-home)
 473                            (lambda-tail-set (combination-lambda use))))
 474                  (when (combination-p use)
 475                    (when (nth-value 1 (maybe-convert-tail-local-call use))
 476                      (return-from find-result-type t))))
 477                 (t
 478                  (use-union (node-derived-type use))))))
 479       (let ((int
 480              ;; (values-type-intersection
 481              ;; (continuation-asserted-type result) ; FIXME -- APD, 2002-01-26
 482              (use-union)
 483               ;; )
 484               ))
 485         (setf (return-result-type node) int))))
 486   nil)
 487
 488 ;;; Do stuff to realize that something has changed about the value
 489 ;;; delivered to a return node. Since we consider the return values of
 490 ;;; all functions in the tail set to be equivalent, this amounts to
 491 ;;; bringing the entire tail set up to date. We iterate over the
 492 ;;; returns for all the functions in the tail set, reanalyzing them
 493 ;;; all (not treating NODE specially.)
 494 ;;;
 495 ;;; When we are done, we check whether the new type is different from
 496 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 497 ;;; all the lvars for references to functions in the tail set. This
 498 ;;; will cause IR1-OPTIMIZE-COMBINATION to derive the new type as the
 499 ;;; results of the calls.
 500 (defun ir1-optimize-return (node)
 501   (declare (type creturn node))
 502   (tagbody
 503    :restart
 504      (let* ((tails (lambda-tail-set (return-lambda node)))
 505             (funs (tail-set-funs tails)))
 506        (collect ((res *empty-type* values-type-union))
 507                 (dolist (fun funs)
 508                   (let ((return (lambda-return fun)))
 509                     (when return
 510                       (when (node-reoptimize return)
 511                         (setf (node-reoptimize return) nil)
 512                         (when (find-result-type return)
 513                           (go :restart)))
 514                       (res (return-result-type return)))))
 515
 516                 (when (type/= (res) (tail-set-type tails))
 517                   (setf (tail-set-type tails) (res))
 518                   (dolist (fun (tail-set-funs tails))
 519                     (dolist (ref (leaf-refs fun))
 520                       (reoptimize-lvar (node-lvar ref))))))))
 521
 522   (values))
 523 \f
 524 ;;;; IF optimization
 525
 526 ;;; If the test has multiple uses, replicate the node when possible.
 527 ;;; Also check whether the predicate is known to be true or false,
 528 ;;; deleting the IF node in favor of the appropriate branch when this
 529 ;;; is the case.
 530 (defun ir1-optimize-if (node)
 531   (declare (type cif node))
 532   (let ((test (if-test node))
 533         (block (node-block node)))
 534
 535     (when (and (eq (block-start-node block) node)
 536                (listp (lvar-uses test)))
 537       (do-uses (use test)
 538         (when (immediately-used-p test use)
 539           (convert-if-if use node)
 540           (when (not (listp (lvar-uses test))) (return)))))
 541
 542     (let* ((type (lvar-type test))
 543            (victim
 544             (cond ((constant-lvar-p test)
 545                    (if (lvar-value test)
 546                        (if-alternative node)
 547                        (if-consequent node)))
 548                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 549                    (if-alternative node))
 550                   ((type= type (specifier-type 'null))
 551                    (if-consequent node)))))
 552       (when victim
 553         (flush-dest test)
 554         (when (rest (block-succ block))
 555           (unlink-blocks block victim))
 556         (setf (component-reanalyze (node-component node)) t)
 557         (unlink-node node))))
 558   (values))
 559
 560 ;;; Create a new copy of an IF node that tests the value of the node
 561 ;;; USE. The test must have >1 use, and must be immediately used by
 562 ;;; USE. NODE must be the only node in its block (implying that
 563 ;;; block-start = if-test).
 564 ;;;
 565 ;;; This optimization has an effect semantically similar to the
 566 ;;; source-to-source transformation:
 567 ;;;    (IF (IF A B C) D E) ==>
 568 ;;;    (IF A (IF B D E) (IF C D E))
 569 ;;;
 570 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 571 ;;; node so that dead code deletion notes will definitely not consider
 572 ;;; either node to be part of the original source. One node might
 573 ;;; become unreachable, resulting in a spurious note.
 574 (defun convert-if-if (use node)
 575   (declare (type node use) (type cif node))
 576   (with-ir1-environment-from-node node
 577     (let* ((block (node-block node))
 578            (test (if-test node))
 579            (cblock (if-consequent node))
 580            (ablock (if-alternative node))
 581            (use-block (node-block use))
 582            (new-ctran (make-ctran))
 583            (new-lvar (make-lvar))
 584            (new-node (make-if :test new-lvar
 585                               :consequent cblock
 586                               :alternative ablock))
 587            (new-block (ctran-starts-block new-ctran)))
 588       (link-node-to-previous-ctran new-node new-ctran)
 589       (setf (lvar-dest new-lvar) new-node)
 590       (setf (block-last new-block) new-node)
 591
 592       (unlink-blocks use-block block)
 593       (%delete-lvar-use use)
 594       (add-lvar-use use new-lvar)
 595       (link-blocks use-block new-block)
 596
 597       (link-blocks new-block cblock)
 598       (link-blocks new-block ablock)
 599
 600       (push "<IF Duplication>" (node-source-path node))
 601       (push "<IF Duplication>" (node-source-path new-node))
 602
 603       (reoptimize-lvar test)
 604       (reoptimize-lvar new-lvar)
 605       (setf (component-reanalyze *current-component*) t)))
 606   (values))
 607 \f
 608 ;;;; exit IR1 optimization
 609
 610 ;;; This function attempts to delete an exit node, returning true if
 611 ;;; it deletes the block as a consequence:
 612 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 613 ;;;    anything, since there is nothing to be done.
 614 ;;; -- If the exit node and its ENTRY have the same home lambda then
 615 ;;;    we know the exit is local, and can delete the exit. We change
 616 ;;;    uses of the Exit-Value to be uses of the original lvar,
 617 ;;;    then unlink the node. If the exit is to a TR context, then we
 618 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 619 ;;;    their value to this exit.
 620 ;;; -- If there is no value (as in a GO), then we skip the value
 621 ;;;    semantics.
 622 ;;;
 623 ;;; This function is also called by environment analysis, since it
 624 ;;; wants all exits to be optimized even if normal optimization was
 625 ;;; omitted.
 626 (defun maybe-delete-exit (node)
 627   (declare (type exit node))
 628   (let ((value (exit-value node))
 629         (entry (exit-entry node)))
 630     (when (and entry
 631                (eq (node-home-lambda node) (node-home-lambda entry)))
 632       (setf (entry-exits entry) (delq node (entry-exits entry)))
 633       (if value
 634           (delete-filter node (node-lvar node) value)
 635           (unlink-node node)))))
 636
 637 \f
 638 ;;;; combination IR1 optimization
 639
 640 ;;; Report as we try each transform?
 641 #!+sb-show
 642 (defvar *show-transforms-p* nil)
 643
 644 ;;; Do IR1 optimizations on a COMBINATION node.
 645 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 646 (defun ir1-optimize-combination (node)
 647   (when (lvar-reoptimize (basic-combination-fun node))
 648     (propagate-fun-change node)
 649     (maybe-terminate-block node nil))
 650   (let ((args (basic-combination-args node))
 651         (kind (basic-combination-kind node))
 652         (info (basic-combination-fun-info node)))
 653     (ecase kind
 654       (:local
 655        (let ((fun (combination-lambda node)))
 656          (if (eq (functional-kind fun) :let)
 657              (propagate-let-args node fun)
 658              (propagate-local-call-args node fun))))
 659       (:error
 660        (dolist (arg args)
 661          (when arg
 662            (setf (lvar-reoptimize arg) nil))))
 663       (:full
 664        (dolist (arg args)
 665          (when arg
 666            (setf (lvar-reoptimize arg) nil)))
 667        (when info
 668          (let ((fun (fun-info-derive-type info)))
 669            (when fun
 670              (let ((res (funcall fun node)))
 671                (when res
 672                  (derive-node-type node (coerce-to-values res))
 673                  (maybe-terminate-block node nil)))))))
 674       (:known
 675        (aver info)
 676        (dolist (arg args)
 677          (when arg
 678            (setf (lvar-reoptimize arg) nil)))
 679
 680        (let ((attr (fun-info-attributes info)))
 681          (when (and (ir1-attributep attr foldable)
 682                     ;; KLUDGE: The next test could be made more sensitive,
 683                     ;; only suppressing constant-folding of functions with
 684                     ;; CALL attributes when they're actually passed
 685                     ;; function arguments. -- WHN 19990918
 686                     (not (ir1-attributep attr call))
 687                     (every #'constant-lvar-p args)
 688                     (node-lvar node)
 689                     ;; Even if the function is foldable in principle,
 690                     ;; it might be one of our low-level
 691                     ;; implementation-specific functions. Such
 692                     ;; functions don't necessarily exist at runtime on
 693                     ;; a plain vanilla ANSI Common Lisp
 694                     ;; cross-compilation host, in which case the
 695                     ;; cross-compiler can't fold it because the
 696                     ;; cross-compiler doesn't know how to evaluate it.
 697                     #+sb-xc-host
 698                     (or (fboundp (combination-fun-source-name node))
 699                         (progn (format t ";;; !!! Unbound fun: (~S~{ ~S~})~%"
 700                                        (combination-fun-source-name node)
 701                                        (mapcar #'lvar-value args))
 702                                nil)))
 703            (constant-fold-call node)
 704            (return-from ir1-optimize-combination)))
 705
 706        (let ((fun (fun-info-derive-type info)))
 707          (when fun
 708            (let ((res (funcall fun node)))
 709              (when res
 710                (derive-node-type node (coerce-to-values res))
 711                (maybe-terminate-block node nil)))))
 712
 713        (let ((fun (fun-info-optimizer info)))
 714          (unless (and fun (funcall fun node))
 715            (dolist (x (fun-info-transforms info))
 716              #!+sb-show
 717              (when *show-transforms-p*
 718                (let* ((lvar (basic-combination-fun node))
 719                       (fname (lvar-fun-name lvar t)))
 720                  (/show "trying transform" x (transform-function x) "for" fname)))
 721              (unless (ir1-transform node x)
 722                #!+sb-show
 723                (when *show-transforms-p*
 724                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 725                (return))))))))
 726
 727   (values))
 728
 729 ;;; If NODE doesn't return (i.e. return type is NIL), then terminate
 730 ;;; the block there, and link it to the component tail.
 731 ;;;
 732 ;;; Except when called during IR1 convertion, we delete the
 733 ;;; continuation if it has no other uses. (If it does have other uses,
 734 ;;; we reoptimize.)
 735 ;;;
 736 ;;; Termination on the basis of a continuation type is
 737 ;;; inhibited when:
 738 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 739 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 740 ;;;    weakening.) FIXME: Now THE assertions are not weakened, but new
 741 ;;;    uses can(?) be added later. -- APD, 2003-07-17
 742 ;;;
 743 ;;; Why do we need to consider LVAR type? -- APD, 2003-07-30
 744 (defun maybe-terminate-block (node ir1-converting-not-optimizing-p)
 745   (declare (type (or basic-combination cast) node))
 746   (let* ((block (node-block node))
 747          (lvar (node-lvar node))
 748          (ctran (node-next node))
 749          (tail (component-tail (block-component block)))
 750          (succ (first (block-succ block))))
 751     (declare (ignore lvar))
 752     (unless (or (and (eq node (block-last block)) (eq succ tail))
 753                 (block-delete-p block))
 754       (when (eq (node-derived-type node) *empty-type*)
 755         (cond (ir1-converting-not-optimizing-p
 756                (cond
 757                  ((block-last block)
 758                   (aver (eq (block-last block) node)))
 759                  (t
 760                   (setf (block-last block) node)
 761                   (setf (ctran-use ctran) nil)
 762                   (setf (ctran-kind ctran) :unused)
 763                   (setf (ctran-block ctran) nil)
 764                   (setf (node-next node) nil)
 765                   (link-blocks block (ctran-starts-block ctran)))))
 766               (t
 767                (node-ends-block node)))
 768
 769         (unlink-blocks block (first (block-succ block)))
 770         (setf (component-reanalyze (block-component block)) t)
 771         (aver (not (block-succ block)))
 772         (link-blocks block tail)
 773         (if ir1-converting-not-optimizing-p
 774             (%delete-lvar-use node)
 775             (delete-lvar-use node))
 776         t))))
 777
 778 ;;; This is called both by IR1 conversion and IR1 optimization when
 779 ;;; they have verified the type signature for the call, and are
 780 ;;; wondering if something should be done to special-case the call. If
 781 ;;; CALL is a call to a global function, then see whether it defined
 782 ;;; or known:
 783 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 784 ;;;    the expansion and change the call to call it. Expansion is
 785 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 786 ;;;    true, we never expand, since this function has already been
 787 ;;;    converted. Local call analysis will duplicate the definition
 788 ;;;    if necessary. We claim that the parent form is LABELS for
 789 ;;;    context declarations, since we don't want it to be considered
 790 ;;;    a real global function.
 791 ;;; -- If it is a known function, mark it as such by setting the KIND.
 792 ;;;
 793 ;;; We return the leaf referenced (NIL if not a leaf) and the
 794 ;;; FUN-INFO assigned.
 795 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 796   (declare (type combination call))
 797   (let* ((ref (lvar-uses (basic-combination-fun call)))
 798          (leaf (when (ref-p ref) (ref-leaf ref)))
 799          (inlinep (if (defined-fun-p leaf)
 800                       (defined-fun-inlinep leaf)
 801                       :no-chance)))
 802     (cond
 803      ((eq inlinep :notinline)
 804       (let ((info (info :function :info (leaf-source-name leaf))))
 805         (when info
 806           (setf (basic-combination-fun-info call) info))
 807         (values nil nil)))
 808      ((not (and (global-var-p leaf)
 809                 (eq (global-var-kind leaf) :global-function)))
 810       (values leaf nil))
 811      ((and (ecase inlinep
 812              (:inline t)
 813              (:no-chance nil)
 814              ((nil :maybe-inline) (policy call (zerop space))))
 815            (defined-fun-p leaf)
 816            (defined-fun-inline-expansion leaf)
 817            (let ((fun (defined-fun-functional leaf)))
 818              (or (not fun)
 819                  (and (eq inlinep :inline) (functional-kind fun))))
 820            (inline-expansion-ok call))
 821       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 822              ;; called semi-inlining? A more descriptive name would
 823              ;; be nice. -- WHN 2002-01-07
 824              (frob ()
 825                (let ((res (ir1-convert-lambda-for-defun
 826                            (defined-fun-inline-expansion leaf)
 827                            leaf t
 828                            #'ir1-convert-inline-lambda)))
 829                  (setf (defined-fun-functional leaf) res)
 830                  (change-ref-leaf ref res))))
 831         (if ir1-converting-not-optimizing-p
 832             (frob)
 833             (with-ir1-environment-from-node call
 834               (frob)
 835               (locall-analyze-component *current-component*))))
 836
 837       (values (ref-leaf (lvar-uses (basic-combination-fun call)))
 838               nil))
 839      (t
 840       (let ((info (info :function :info (leaf-source-name leaf))))
 841         (if info
 842             (values leaf
 843                     (progn
 844                       (setf (basic-combination-kind call) :known)
 845                       (setf (basic-combination-fun-info call) info)))
 846             (values leaf nil)))))))
 847
 848 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 849 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 850 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 851 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 852 ;;; syntax check, arg/result type processing, but still call
 853 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 854 ;;; and that checking is done by local call analysis.
 855 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 856   (declare (type combination call) (type ctype type))
 857   (cond ((not (fun-type-p type))
 858          (aver (multiple-value-bind (val win)
 859                    (csubtypep type (specifier-type 'function))
 860                  (or val (not win))))
 861          (recognize-known-call call ir1-converting-not-optimizing-p))
 862         ((valid-fun-use call type
 863                         :argument-test #'always-subtypep
 864                         :result-test nil
 865                         ;; KLUDGE: Common Lisp is such a dynamic
 866                         ;; language that all we can do here in
 867                         ;; general is issue a STYLE-WARNING. It
 868                         ;; would be nice to issue a full WARNING
 869                         ;; in the special case of of type
 870                         ;; mismatches within a compilation unit
 871                         ;; (as in section 3.2.2.3 of the spec)
 872                         ;; but at least as of sbcl-0.6.11, we
 873                         ;; don't keep track of whether the
 874                         ;; mismatched data came from the same
 875                         ;; compilation unit, so we can't do that.
 876                         ;; -- WHN 2001-02-11
 877                         ;;
 878                         ;; FIXME: Actually, I think we could
 879                         ;; issue a full WARNING if the call
 880                         ;; violates a DECLAIM FTYPE.
 881                         :lossage-fun #'compiler-style-warn
 882                         :unwinnage-fun #'compiler-notify)
 883          (assert-call-type call type)
 884          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 885          (recognize-known-call call ir1-converting-not-optimizing-p))
 886         (t
 887          (setf (combination-kind call) :error)
 888          (values nil nil))))
 889
 890 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 891 ;;; changed. If the call is local, we try to LET-convert it, and
 892 ;;; derive the result type. If it is a :FULL call, we validate it
 893 ;;; against the type, which recognizes known calls, does inline
 894 ;;; expansion, etc. If a call to a predicate in a non-conditional
 895 ;;; position or to a function with a source transform, then we
 896 ;;; reconvert the form to give IR1 another chance.
 897 (defun propagate-fun-change (call)
 898   (declare (type combination call))
 899   (let ((*compiler-error-context* call)
 900         (fun-lvar (basic-combination-fun call)))
 901     (setf (lvar-reoptimize fun-lvar) nil)
 902     (case (combination-kind call)
 903       (:local
 904        (let ((fun (combination-lambda call)))
 905          (maybe-let-convert fun)
 906          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 907            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 908       (:full
 909        (multiple-value-bind (leaf info)
 910            (validate-call-type call (lvar-type fun-lvar) nil)
 911          (cond ((functional-p leaf)
 912                 (convert-call-if-possible
 913                  (lvar-uses (basic-combination-fun call))
 914                  call))
 915                ((not leaf))
 916                ((and (global-var-p leaf)
 917                      (eq (global-var-kind leaf) :global-function)
 918                      (leaf-has-source-name-p leaf)
 919                      (or (info :function :source-transform (leaf-source-name leaf))
 920                          (and info
 921                               (ir1-attributep (fun-info-attributes info)
 922                                               predicate)
 923                               (let ((lvar (node-lvar call)))
 924                                 (and lvar (not (if-p (lvar-dest lvar))))))))
 925                 (let ((name (leaf-source-name leaf))
 926                       (dummies (make-gensym-list
 927                                 (length (combination-args call)))))
 928                   (transform-call call
 929                                   `(lambda ,dummies
 930                                      (,@(if (symbolp name)
 931                                             `(,name)
 932                                             `(funcall #',name))
 933                                         ,@dummies))
 934                                   (leaf-source-name leaf)))))))))
 935   (values))
 936 \f
 937 ;;;; known function optimization
 938
 939 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
 940 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
 941 ;;; replace it, otherwise add a new one.
 942 (defun record-optimization-failure (node transform args)
 943   (declare (type combination node) (type transform transform)
 944            (type (or fun-type list) args))
 945   (let* ((table (component-failed-optimizations *component-being-compiled*))
 946          (found (assoc transform (gethash node table))))
 947     (if found
 948         (setf (cdr found) args)
 949         (push (cons transform args) (gethash node table))))
 950   (values))
 951
 952 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
 953 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
 954 ;;; doing the transform for some reason and FLAME is true, then we
 955 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
 956 ;;; finalize to pick up. We return true if the transform failed, and
 957 ;;; thus further transformation should be attempted. We return false
 958 ;;; if either the transform succeeded or was aborted.
 959 (defun ir1-transform (node transform)
 960   (declare (type combination node) (type transform transform))
 961   (let* ((type (transform-type transform))
 962          (fun (transform-function transform))
 963          (constrained (fun-type-p type))
 964          (table (component-failed-optimizations *component-being-compiled*))
 965          (flame (if (transform-important transform)
 966                     (policy node (>= speed inhibit-warnings))
 967                     (policy node (> speed inhibit-warnings))))
 968          (*compiler-error-context* node))
 969     (cond ((or (not constrained)
 970                (valid-fun-use node type))
 971            (multiple-value-bind (severity args)
 972                (catch 'give-up-ir1-transform
 973                  (transform-call node
 974                                  (funcall fun node)
 975                                  (combination-fun-source-name node))
 976                  (values :none nil))
 977              (ecase severity
 978                (:none
 979                 (remhash node table)
 980                 nil)
 981                (:aborted
 982                 (setf (combination-kind node) :error)
 983                 (when args
 984                   (apply #'warn args))
 985                 (remhash node table)
 986                 nil)
 987                (:failure
 988                 (if args
 989                     (when flame
 990                       (record-optimization-failure node transform args))
 991                     (setf (gethash node table)
 992                           (remove transform (gethash node table) :key #'car)))
 993                 t)
 994                (:delayed
 995                  (remhash node table)
 996                  nil))))
 997           ((and flame
 998                 (valid-fun-use node
 999                                type
1000                                :argument-test #'types-equal-or-intersect
1001                                :result-test #'values-types-equal-or-intersect))
1002            (record-optimization-failure node transform type)
1003            t)
1004           (t
1005            t))))
1006
1007 ;;; When we don't like an IR1 transform, we throw the severity/reason
1008 ;;; and args.
1009 ;;;
1010 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1011 ;;; aborting this attempt to transform the call, but admitting the
1012 ;;; possibility that this or some other transform will later succeed.
1013 ;;; If arguments are supplied, they are format arguments for an
1014 ;;; efficiency note.
1015 ;;;
1016 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1017 ;;; force a normal call to the function at run time. No further
1018 ;;; optimizations will be attempted.
1019 ;;;
1020 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1021 ;;; delay the transform on the node until later. REASONS specifies
1022 ;;; when the transform will be later retried. The :OPTIMIZE reason
1023 ;;; causes the transform to be delayed until after the current IR1
1024 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1025 ;;; be delayed until after constraint propagation.
1026 ;;;
1027 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1028 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1029 ;;; do CASE operations on the various REASON values, it might be a
1030 ;;; good idea to go OO, representing the reasons by objects, using
1031 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1032 ;;; SIGNAL instead of THROW.
1033 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1034 (defun give-up-ir1-transform (&rest args)
1035   (throw 'give-up-ir1-transform (values :failure args)))
1036 (defun abort-ir1-transform (&rest args)
1037   (throw 'give-up-ir1-transform (values :aborted args)))
1038 (defun delay-ir1-transform (node &rest reasons)
1039   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1040     (cond ((not assoc)
1041             (setf *delayed-ir1-transforms*
1042                     (acons node reasons *delayed-ir1-transforms*))
1043             (throw 'give-up-ir1-transform :delayed))
1044           ((cdr assoc)
1045             (dolist (reason reasons)
1046               (pushnew reason (cdr assoc)))
1047             (throw 'give-up-ir1-transform :delayed)))))
1048
1049 ;;; Clear any delayed transform with no reasons - these should have
1050 ;;; been tried in the last pass. Then remove the reason from the
1051 ;;; delayed transform reasons, and if any become empty then set
1052 ;;; reoptimize flags for the node. Return true if any transforms are
1053 ;;; to be retried.
1054 (defun retry-delayed-ir1-transforms (reason)
1055   (setf *delayed-ir1-transforms*
1056         (remove-if-not #'cdr *delayed-ir1-transforms*))
1057   (let ((reoptimize nil))
1058     (dolist (assoc *delayed-ir1-transforms*)
1059       (let ((reasons (remove reason (cdr assoc))))
1060         (setf (cdr assoc) reasons)
1061         (unless reasons
1062           (let ((node (car assoc)))
1063             (unless (node-deleted node)
1064               (setf reoptimize t)
1065               (setf (node-reoptimize node) t)
1066               (let ((block (node-block node)))
1067                 (setf (block-reoptimize block) t)
1068                 (setf (component-reoptimize (block-component block)) t)))))))
1069     reoptimize))
1070
1071 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1072 ;;; environment, and then install it as the function for the call
1073 ;;; NODE. We do local call analysis so that the new function is
1074 ;;; integrated into the control flow.
1075 ;;;
1076 ;;; We require the original function source name in order to generate
1077 ;;; a meaningful debug name for the lambda we set up. (It'd be
1078 ;;; possible to do this starting from debug names as well as source
1079 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1080 ;;; generality, since source names are always known to our callers.)
1081 (defun transform-call (call res source-name)
1082   (declare (type combination call) (list res))
1083   (aver (and (legal-fun-name-p source-name)
1084              (not (eql source-name '.anonymous.))))
1085   (node-ends-block call)
1086   (with-ir1-environment-from-node call
1087     (with-component-last-block (*current-component*
1088                                 (block-next (node-block call)))
1089       (let ((new-fun (ir1-convert-inline-lambda
1090                       res
1091                       :debug-name (debug-namify "LAMBDA-inlined "
1092                                                 source-name
1093                                                 "<unknown function>")))
1094             (ref (lvar-use (combination-fun call))))
1095         (change-ref-leaf ref new-fun)
1096         (setf (combination-kind call) :full)
1097         (locall-analyze-component *current-component*))))
1098   (values))
1099
1100 ;;; Replace a call to a foldable function of constant arguments with
1101 ;;; the result of evaluating the form. If there is an error during the
1102 ;;; evaluation, we give a warning and leave the call alone, making the
1103 ;;; call a :ERROR call.
1104 ;;;
1105 ;;; If there is more than one value, then we transform the call into a
1106 ;;; VALUES form.
1107 (defun constant-fold-call (call)
1108   (let ((args (mapcar #'lvar-value (combination-args call)))
1109         (fun-name (combination-fun-source-name call)))
1110     (multiple-value-bind (values win)
1111         (careful-call fun-name
1112                       args
1113                       call
1114                       ;; Note: CMU CL had COMPILER-WARN here, and that
1115                       ;; seems more natural, but it's probably not.
1116                       ;;
1117                       ;; It's especially not while bug 173 exists:
1118                       ;; Expressions like
1119                       ;;   (COND (END
1120                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1121                       ;;            ...))
1122                       ;; can cause constant-folding TYPE-ERRORs (in
1123                       ;; #'<=) when END can be proved to be NIL, even
1124                       ;; though the code is perfectly legal and safe
1125                       ;; because a NIL value of END means that the
1126                       ;; #'<= will never be executed.
1127                       ;;
1128                       ;; Moreover, even without bug 173,
1129                       ;; quite-possibly-valid code like
1130                       ;;   (COND ((NONINLINED-PREDICATE END)
1131                       ;;          (UNLESS (<= END SIZE))
1132                       ;;            ...))
1133                       ;; (where NONINLINED-PREDICATE is something the
1134                       ;; compiler can't do at compile time, but which
1135                       ;; turns out to make the #'<= expression
1136                       ;; unreachable when END=NIL) could cause errors
1137                       ;; when the compiler tries to constant-fold (<=
1138                       ;; END SIZE).
1139                       ;;
1140                       ;; So, with or without bug 173, it'd be
1141                       ;; unnecessarily evil to do a full
1142                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1143                       ;; from COMPILE-FILE) for legal code, so we we
1144                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1145                       #'compiler-style-warn
1146                       "constant folding")
1147       (cond ((not win)
1148              (setf (combination-kind call) :error))
1149             ((and (proper-list-of-length-p values 1))
1150              (with-ir1-environment-from-node call
1151                (let* ((lvar (node-lvar call))
1152                       (prev (node-prev call))
1153                       (intermediate-ctran (make-ctran)))
1154                  (%delete-lvar-use call)
1155                  (setf (ctran-next prev) nil)
1156                  (setf (node-prev call) nil)
1157                  (reference-constant prev intermediate-ctran lvar
1158                                      (first values))
1159                  (link-node-to-previous-ctran call intermediate-ctran)
1160                  (reoptimize-lvar lvar)
1161                  (flush-combination call))))
1162             (t (let ((dummies (make-gensym-list (length args))))
1163                  (transform-call
1164                   call
1165                   `(lambda ,dummies
1166                      (declare (ignore ,@dummies))
1167                      (values ,@(mapcar (lambda (x) `',x) values)))
1168                   fun-name))))))
1169   (values))
1170 \f
1171 ;;;; local call optimization
1172
1173 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1174 ;;; the leaf type is a function type, then just leave it alone, since
1175 ;;; TYPE is never going to be more specific than that (and
1176 ;;; TYPE-INTERSECTION would choke.)
1177 (defun propagate-to-refs (leaf type)
1178   (declare (type leaf leaf) (type ctype type))
1179   (let ((var-type (leaf-type leaf)))
1180     (unless (fun-type-p var-type)
1181       (let ((int (type-approx-intersection2 var-type type)))
1182         (when (type/= int var-type)
1183           (setf (leaf-type leaf) int)
1184           (dolist (ref (leaf-refs leaf))
1185             (derive-node-type ref (make-single-value-type int))
1186             ;; KLUDGE: LET var substitution
1187             (let* ((lvar (node-lvar ref)))
1188               (when (and lvar (combination-p (lvar-dest lvar)))
1189                 (reoptimize-lvar lvar))))))
1190       (values))))
1191
1192 ;;; Iteration variable: exactly one SETQ of the form:
1193 ;;;
1194 ;;; (let ((var initial))
1195 ;;;   ...
1196 ;;;   (setq var (+ var step))
1197 ;;;   ...)
1198 (defun maybe-infer-iteration-var-type (var initial-type)
1199   (binding* ((sets (lambda-var-sets var) :exit-if-null)
1200              (set (first sets))
1201              (() (null (rest sets)) :exit-if-null)
1202              (set-use (principal-lvar-use (set-value set)))
1203              (() (and (combination-p set-use)
1204                       (eq (combination-kind set-use) :known)
1205                       (fun-info-p (combination-fun-info set-use))
1206                       (not (node-to-be-deleted-p set-use))
1207                       (eq (combination-fun-source-name set-use) '+))
1208                :exit-if-null)
1209              (+-args (basic-combination-args set-use))
1210              (() (and (proper-list-of-length-p +-args 2 2)
1211                       (let ((first (principal-lvar-use
1212                                     (first +-args))))
1213                         (and (ref-p first)
1214                              (eq (ref-leaf first) var))))
1215                :exit-if-null)
1216              (step-type (lvar-type (second +-args)))
1217              (set-type (lvar-type (set-value set))))
1218     (when (and (numeric-type-p initial-type)
1219                (numeric-type-p step-type)
1220                (numeric-type-equal initial-type step-type))
1221       (multiple-value-bind (low high)
1222           (cond ((csubtypep step-type (specifier-type '(real 0 *)))
1223                  (values (numeric-type-low initial-type)
1224                          (when (and (numeric-type-p set-type)
1225                                     (numeric-type-equal set-type initial-type))
1226                            (numeric-type-high set-type))))
1227                 ((csubtypep step-type (specifier-type '(real * 0)))
1228                  (values (when (and (numeric-type-p set-type)
1229                                     (numeric-type-equal set-type initial-type))
1230                            (numeric-type-low set-type))
1231                          (numeric-type-high initial-type)))
1232                 (t
1233                  (values nil nil)))
1234         (modified-numeric-type initial-type
1235                                :low low
1236                                :high high
1237                                :enumerable nil)))))
1238 (deftransform + ((x y) * * :result result)
1239   "check for iteration variable reoptimization"
1240   (let ((dest (principal-lvar-end result))
1241         (use (principal-lvar-use x)))
1242     (when (and (ref-p use)
1243                (set-p dest)
1244                (eq (ref-leaf use)
1245                    (set-var dest)))
1246       (reoptimize-lvar (set-value dest))))
1247   (give-up-ir1-transform))
1248
1249 ;;; Figure out the type of a LET variable that has sets. We compute
1250 ;;; the union of the INITIAL-TYPE and the types of all the set
1251 ;;; values and to a PROPAGATE-TO-REFS with this type.
1252 (defun propagate-from-sets (var initial-type)
1253   (collect ((res initial-type type-union))
1254     (dolist (set (basic-var-sets var))
1255       (let ((type (lvar-type (set-value set))))
1256         (res type)
1257         (when (node-reoptimize set)
1258           (derive-node-type set (make-single-value-type type))
1259           (setf (node-reoptimize set) nil))))
1260     (let ((res (res)))
1261       (awhen (maybe-infer-iteration-var-type var initial-type)
1262         (setq res it))
1263       (propagate-to-refs var res)))
1264   (values))
1265
1266 ;;; If a LET variable, find the initial value's type and do
1267 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1268 ;;; type.
1269 (defun ir1-optimize-set (node)
1270   (declare (type cset node))
1271   (let ((var (set-var node)))
1272     (when (and (lambda-var-p var) (leaf-refs var))
1273       (let ((home (lambda-var-home var)))
1274         (when (eq (functional-kind home) :let)
1275           (let* ((initial-value (let-var-initial-value var))
1276                  (initial-type (lvar-type initial-value)))
1277             (setf (lvar-reoptimize initial-value) nil)
1278             (propagate-from-sets var initial-type))))))
1279
1280   (derive-node-type node (make-single-value-type
1281                           (lvar-type (set-value node))))
1282   (values))
1283
1284 ;;; Return true if the value of REF will always be the same (and is
1285 ;;; thus legal to substitute.)
1286 (defun constant-reference-p (ref)
1287   (declare (type ref ref))
1288   (let ((leaf (ref-leaf ref)))
1289     (typecase leaf
1290       ((or constant functional) t)
1291       (lambda-var
1292        (null (lambda-var-sets leaf)))
1293       (defined-fun
1294        (not (eq (defined-fun-inlinep leaf) :notinline)))
1295       (global-var
1296        (case (global-var-kind leaf)
1297          (:global-function
1298           (let ((name (leaf-source-name leaf)))
1299             (or #-sb-xc-host
1300                 (eq (symbol-package (fun-name-block-name name))
1301                     *cl-package*)
1302                 (info :function :info name)))))))))
1303
1304 ;;; If we have a non-set LET var with a single use, then (if possible)
1305 ;;; replace the variable reference's LVAR with the arg lvar.
1306 ;;;
1307 ;;; We change the REF to be a reference to NIL with unused value, and
1308 ;;; let it be flushed as dead code. A side effect of this substitution
1309 ;;; is to delete the variable.
1310 (defun substitute-single-use-lvar (arg var)
1311   (declare (type lvar arg) (type lambda-var var))
1312   (binding* ((ref (first (leaf-refs var)))
1313              (lvar (node-lvar ref) :exit-if-null)
1314              (dest (lvar-dest lvar)))
1315     (when (and
1316            ;; Think about (LET ((A ...)) (IF ... A ...)): two
1317            ;; LVAR-USEs should not be met on one path. Another problem
1318            ;; is with dynamic-extent.
1319            (eq (lvar-uses lvar) ref)
1320            (typecase dest
1321              ;; we should not change lifetime of unknown values lvars
1322              (cast
1323               (and (type-single-value-p (lvar-derived-type arg))
1324                    (multiple-value-bind (pdest pprev)
1325                        (principal-lvar-end lvar)
1326                      (declare (ignore pdest))
1327                      (lvar-single-value-p pprev))))
1328              (mv-combination
1329               (or (eq (basic-combination-fun dest) lvar)
1330                   (and (eq (basic-combination-kind dest) :local)
1331                        (type-single-value-p (lvar-derived-type arg)))))
1332              ((or creturn exit)
1333               ;; While CRETURN and EXIT nodes may be known-values,
1334               ;; they have their own complications, such as
1335               ;; substitution into CRETURN may create new tail calls.
1336               nil)
1337              (t
1338               (aver (lvar-single-value-p lvar))
1339               t))
1340            (eq (node-home-lambda ref)
1341                (lambda-home (lambda-var-home var))))
1342       (setf (node-derived-type ref) *wild-type*)
1343       (substitute-lvar-uses lvar arg
1344                             ;; Really it is (EQ (LVAR-USES LVAR) REF):
1345                             t)
1346       (delete-lvar-use ref)
1347       (change-ref-leaf ref (find-constant nil))
1348       (delete-ref ref)
1349       (unlink-node ref)
1350       (reoptimize-lvar lvar)
1351       t)))
1352
1353 ;;; Delete a LET, removing the call and bind nodes, and warning about
1354 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1355 ;;; along right away and delete the REF and then the lambda, since we
1356 ;;; flush the FUN lvar.
1357 (defun delete-let (clambda)
1358   (declare (type clambda clambda))
1359   (aver (functional-letlike-p clambda))
1360   (note-unreferenced-vars clambda)
1361   (let ((call (let-combination clambda)))
1362     (flush-dest (basic-combination-fun call))
1363     (unlink-node call)
1364     (unlink-node (lambda-bind clambda))
1365     (setf (lambda-bind clambda) nil))
1366   (setf (functional-kind clambda) :zombie)
1367   (let ((home (lambda-home clambda)))
1368     (setf (lambda-lets home) (delete clambda (lambda-lets home))))
1369   (values))
1370
1371 ;;; This function is called when one of the arguments to a LET
1372 ;;; changes. We look at each changed argument. If the corresponding
1373 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1374 ;;; consider substituting for the variable, and also propagate
1375 ;;; derived-type information for the arg to all the VAR's refs.
1376 ;;;
1377 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1378 ;;; subtype of the argument's leaf type. This prevents type checking
1379 ;;; from being defeated, and also ensures that the best representation
1380 ;;; for the variable can be used.
1381 ;;;
1382 ;;; Substitution of individual references is inhibited if the
1383 ;;; reference is in a different component from the home. This can only
1384 ;;; happen with closures over top level lambda vars. In such cases,
1385 ;;; the references may have already been compiled, and thus can't be
1386 ;;; retroactively modified.
1387 ;;;
1388 ;;; If all of the variables are deleted (have no references) when we
1389 ;;; are done, then we delete the LET.
1390 ;;;
1391 ;;; Note that we are responsible for clearing the LVAR-REOPTIMIZE
1392 ;;; flags.
1393 (defun propagate-let-args (call fun)
1394   (declare (type combination call) (type clambda fun))
1395   (loop for arg in (combination-args call)
1396         and var in (lambda-vars fun) do
1397     (when (and arg (lvar-reoptimize arg))
1398       (setf (lvar-reoptimize arg) nil)
1399       (cond
1400         ((lambda-var-sets var)
1401          (propagate-from-sets var (lvar-type arg)))
1402         ((let ((use (lvar-uses arg)))
1403            (when (ref-p use)
1404              (let ((leaf (ref-leaf use)))
1405                (when (and (constant-reference-p use)
1406                           (csubtypep (leaf-type leaf)
1407                                      ;; (NODE-DERIVED-TYPE USE) would
1408                                      ;; be better -- APD, 2003-05-15
1409                                      (leaf-type var)))
1410                  (propagate-to-refs var (lvar-type arg))
1411                  (let ((use-component (node-component use)))
1412                    (prog1 (substitute-leaf-if
1413                            (lambda (ref)
1414                              (cond ((eq (node-component ref) use-component)
1415                                     t)
1416                                    (t
1417                                     (aver (lambda-toplevelish-p (lambda-home fun)))
1418                                     nil)))
1419                            leaf var)))
1420                  t)))))
1421         ((and (null (rest (leaf-refs var)))
1422               (substitute-single-use-lvar arg var)))
1423         (t
1424          (propagate-to-refs var (lvar-type arg))))))
1425
1426   (when (every #'not (combination-args call))
1427     (delete-let fun))
1428
1429   (values))
1430
1431 ;;; This function is called when one of the args to a non-LET local
1432 ;;; call changes. For each changed argument corresponding to an unset
1433 ;;; variable, we compute the union of the types across all calls and
1434 ;;; propagate this type information to the var's refs.
1435 ;;;
1436 ;;; If the function has an XEP, then we don't do anything, since we
1437 ;;; won't discover anything.
1438 ;;;
1439 ;;; We can clear the LVAR-REOPTIMIZE flags for arguments in all calls
1440 ;;; corresponding to changed arguments in CALL, since the only use in
1441 ;;; IR1 optimization of the REOPTIMIZE flag for local call args is
1442 ;;; right here.
1443 (defun propagate-local-call-args (call fun)
1444   (declare (type combination call) (type clambda fun))
1445
1446   (unless (or (functional-entry-fun fun)
1447               (lambda-optional-dispatch fun))
1448     (let* ((vars (lambda-vars fun))
1449            (union (mapcar (lambda (arg var)
1450                             (when (and arg
1451                                        (lvar-reoptimize arg)
1452                                        (null (basic-var-sets var)))
1453                               (lvar-type arg)))
1454                           (basic-combination-args call)
1455                           vars))
1456            (this-ref (lvar-use (basic-combination-fun call))))
1457
1458       (dolist (arg (basic-combination-args call))
1459         (when arg
1460           (setf (lvar-reoptimize arg) nil)))
1461
1462       (dolist (ref (leaf-refs fun))
1463         (let ((dest (node-dest ref)))
1464           (unless (or (eq ref this-ref) (not dest))
1465             (setq union
1466                   (mapcar (lambda (this-arg old)
1467                             (when old
1468                               (setf (lvar-reoptimize this-arg) nil)
1469                               (type-union (lvar-type this-arg) old)))
1470                           (basic-combination-args dest)
1471                           union)))))
1472
1473       (loop for var in vars
1474             and type in union
1475             when type do (propagate-to-refs var type))))
1476
1477   (values))
1478 \f
1479 ;;;; multiple values optimization
1480
1481 ;;; Do stuff to notice a change to a MV combination node. There are
1482 ;;; two main branches here:
1483 ;;;  -- If the call is local, then it is already a MV let, or should
1484 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1485 ;;;     be converted to :MV-LETs, there can be a window when the call
1486 ;;;     is local, but has not been LET converted yet. This is because
1487 ;;;     the entry-point lambdas may have stray references (in other
1488 ;;;     entry points) that have not been deleted yet.
1489 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1490 ;;;     combination optimization: we propagate return type information and
1491 ;;;     notice non-returning calls. We also have an optimization
1492 ;;;     which tries to convert MV-CALLs into MV-binds.
1493 (defun ir1-optimize-mv-combination (node)
1494   (ecase (basic-combination-kind node)
1495     (:local
1496      (let ((fun-lvar (basic-combination-fun node)))
1497        (when (lvar-reoptimize fun-lvar)
1498          (setf (lvar-reoptimize fun-lvar) nil)
1499          (maybe-let-convert (combination-lambda node))))
1500      (setf (lvar-reoptimize (first (basic-combination-args node))) nil)
1501      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1502        (unless (convert-mv-bind-to-let node)
1503          (ir1-optimize-mv-bind node))))
1504     (:full
1505      (let* ((fun (basic-combination-fun node))
1506             (fun-changed (lvar-reoptimize fun))
1507             (args (basic-combination-args node)))
1508        (when fun-changed
1509          (setf (lvar-reoptimize fun) nil)
1510          (let ((type (lvar-type fun)))
1511            (when (fun-type-p type)
1512              (derive-node-type node (fun-type-returns type))))
1513          (maybe-terminate-block node nil)
1514          (let ((use (lvar-uses fun)))
1515            (when (and (ref-p use) (functional-p (ref-leaf use)))
1516              (convert-call-if-possible use node)
1517              (when (eq (basic-combination-kind node) :local)
1518                (maybe-let-convert (ref-leaf use))))))
1519        (unless (or (eq (basic-combination-kind node) :local)
1520                    (eq (lvar-fun-name fun) '%throw))
1521          (ir1-optimize-mv-call node))
1522        (dolist (arg args)
1523          (setf (lvar-reoptimize arg) nil))))
1524     (:error))
1525   (values))
1526
1527 ;;; Propagate derived type info from the values lvar to the vars.
1528 (defun ir1-optimize-mv-bind (node)
1529   (declare (type mv-combination node))
1530   (let* ((arg (first (basic-combination-args node)))
1531          (vars (lambda-vars (combination-lambda node)))
1532          (n-vars (length vars))
1533          (types (values-type-in (lvar-derived-type arg)
1534                                 n-vars)))
1535     (loop for var in vars
1536           and type in types
1537           do (if (basic-var-sets var)
1538                  (propagate-from-sets var type)
1539                  (propagate-to-refs var type)))
1540     (setf (lvar-reoptimize arg) nil))
1541   (values))
1542
1543 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1544 ;;; this if:
1545 ;;; -- The call has only one argument, and
1546 ;;; -- The function has a known fixed number of arguments, or
1547 ;;; -- The argument yields a known fixed number of values.
1548 ;;;
1549 ;;; What we do is change the function in the MV-CALL to be a lambda
1550 ;;; that "looks like an MV bind", which allows
1551 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1552 ;;; converted (the next time around.) This new lambda just calls the
1553 ;;; actual function with the MV-BIND variables as arguments. Note that
1554 ;;; this new MV bind is not let-converted immediately, as there are
1555 ;;; going to be stray references from the entry-point functions until
1556 ;;; they get deleted.
1557 ;;;
1558 ;;; In order to avoid loss of argument count checking, we only do the
1559 ;;; transformation according to a known number of expected argument if
1560 ;;; safety is unimportant. We can always convert if we know the number
1561 ;;; of actual values, since the normal call that we build will still
1562 ;;; do any appropriate argument count checking.
1563 ;;;
1564 ;;; We only attempt the transformation if the called function is a
1565 ;;; constant reference. This allows us to just splice the leaf into
1566 ;;; the new function, instead of trying to somehow bind the function
1567 ;;; expression. The leaf must be constant because we are evaluating it
1568 ;;; again in a different place. This also has the effect of squelching
1569 ;;; multiple warnings when there is an argument count error.
1570 (defun ir1-optimize-mv-call (node)
1571   (let ((fun (basic-combination-fun node))
1572         (*compiler-error-context* node)
1573         (ref (lvar-uses (basic-combination-fun node)))
1574         (args (basic-combination-args node)))
1575
1576     (unless (and (ref-p ref) (constant-reference-p ref)
1577                  (singleton-p args))
1578       (return-from ir1-optimize-mv-call))
1579
1580     (multiple-value-bind (min max)
1581         (fun-type-nargs (lvar-type fun))
1582       (let ((total-nvals
1583              (multiple-value-bind (types nvals)
1584                  (values-types (lvar-derived-type (first args)))
1585                (declare (ignore types))
1586                (if (eq nvals :unknown) nil nvals))))
1587
1588         (when total-nvals
1589           (when (and min (< total-nvals min))
1590             (compiler-warn
1591              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1592              at least ~R."
1593              total-nvals min)
1594             (setf (basic-combination-kind node) :error)
1595             (return-from ir1-optimize-mv-call))
1596           (when (and max (> total-nvals max))
1597             (compiler-warn
1598              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1599              at most ~R."
1600              total-nvals max)
1601             (setf (basic-combination-kind node) :error)
1602             (return-from ir1-optimize-mv-call)))
1603
1604         (let ((count (cond (total-nvals)
1605                            ((and (policy node (zerop verify-arg-count))
1606                                  (eql min max))
1607                             min)
1608                            (t nil))))
1609           (when count
1610             (with-ir1-environment-from-node node
1611               (let* ((dums (make-gensym-list count))
1612                      (ignore (gensym))
1613                      (fun (ir1-convert-lambda
1614                            `(lambda (&optional ,@dums &rest ,ignore)
1615                               (declare (ignore ,ignore))
1616                               (funcall ,(ref-leaf ref) ,@dums)))))
1617                 (change-ref-leaf ref fun)
1618                 (aver (eq (basic-combination-kind node) :full))
1619                 (locall-analyze-component *current-component*)
1620                 (aver (eq (basic-combination-kind node) :local)))))))))
1621   (values))
1622
1623 ;;; If we see:
1624 ;;;    (multiple-value-bind
1625 ;;;     (x y)
1626 ;;;     (values xx yy)
1627 ;;;      ...)
1628 ;;; Convert to:
1629 ;;;    (let ((x xx)
1630 ;;;       (y yy))
1631 ;;;      ...)
1632 ;;;
1633 ;;; What we actually do is convert the VALUES combination into a
1634 ;;; normal LET combination calling the original :MV-LET lambda. If
1635 ;;; there are extra args to VALUES, discard the corresponding
1636 ;;; lvars. If there are insufficient args, insert references to NIL.
1637 (defun convert-mv-bind-to-let (call)
1638   (declare (type mv-combination call))
1639   (let* ((arg (first (basic-combination-args call)))
1640          (use (lvar-uses arg)))
1641     (when (and (combination-p use)
1642                (eq (lvar-fun-name (combination-fun use))
1643                    'values))
1644       (let* ((fun (combination-lambda call))
1645              (vars (lambda-vars fun))
1646              (vals (combination-args use))
1647              (nvars (length vars))
1648              (nvals (length vals)))
1649         (cond ((> nvals nvars)
1650                (mapc #'flush-dest (subseq vals nvars))
1651                (setq vals (subseq vals 0 nvars)))
1652               ((< nvals nvars)
1653                (with-ir1-environment-from-node use
1654                  (let ((node-prev (node-prev use)))
1655                    (setf (node-prev use) nil)
1656                    (setf (ctran-next node-prev) nil)
1657                    (collect ((res vals))
1658                      (loop for count below (- nvars nvals)
1659                            for prev = node-prev then ctran
1660                            for ctran = (make-ctran)
1661                            and lvar = (make-lvar use)
1662                            do (reference-constant prev ctran lvar nil)
1663                               (res lvar)
1664                            finally (link-node-to-previous-ctran
1665                                     use ctran))
1666                      (setq vals (res)))))))
1667         (setf (combination-args use) vals)
1668         (flush-dest (combination-fun use))
1669         (let ((fun-lvar (basic-combination-fun call)))
1670           (setf (lvar-dest fun-lvar) use)
1671           (setf (combination-fun use) fun-lvar)
1672           (flush-lvar-externally-checkable-type fun-lvar))
1673         (setf (combination-kind use) :local)
1674         (setf (functional-kind fun) :let)
1675         (flush-dest (first (basic-combination-args call)))
1676         (unlink-node call)
1677         (when vals
1678           (reoptimize-lvar (first vals)))
1679         (propagate-to-args use fun)
1680         (reoptimize-call use))
1681       t)))
1682
1683 ;;; If we see:
1684 ;;;    (values-list (list x y z))
1685 ;;;
1686 ;;; Convert to:
1687 ;;;    (values x y z)
1688 ;;;
1689 ;;; In implementation, this is somewhat similar to
1690 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1691 ;;; args of the VALUES-LIST call, flushing the old argument lvar
1692 ;;; (allowing the LIST to be flushed.)
1693 ;;;
1694 ;;; FIXME: Thus we lose possible type assertions on (LIST ...).
1695 (defoptimizer (values-list optimizer) ((list) node)
1696   (let ((use (lvar-uses list)))
1697     (when (and (combination-p use)
1698                (eq (lvar-fun-name (combination-fun use))
1699                    'list))
1700
1701       ;; FIXME: VALUES might not satisfy an assertion on NODE-LVAR.
1702       (change-ref-leaf (lvar-uses (combination-fun node))
1703                        (find-free-fun 'values "in a strange place"))
1704       (setf (combination-kind node) :full)
1705       (let ((args (combination-args use)))
1706         (dolist (arg args)
1707           (setf (lvar-dest arg) node)
1708           (flush-lvar-externally-checkable-type arg))
1709         (setf (combination-args use) nil)
1710         (flush-dest list)
1711         (setf (combination-args node) args))
1712       t)))
1713
1714 ;;; If VALUES appears in a non-MV context, then effectively convert it
1715 ;;; to a PROG1. This allows the computation of the additional values
1716 ;;; to become dead code.
1717 (deftransform values ((&rest vals) * * :node node)
1718   (unless (lvar-single-value-p (node-lvar node))
1719     (give-up-ir1-transform))
1720   (setf (node-derived-type node)
1721         (make-short-values-type (list (single-value-type
1722                                        (node-derived-type node)))))
1723   (principal-lvar-single-valuify (node-lvar node))
1724   (if vals
1725       (let ((dummies (make-gensym-list (length (cdr vals)))))
1726         `(lambda (val ,@dummies)
1727            (declare (ignore ,@dummies))
1728            val))
1729       nil))
1730
1731 ;;; TODO:
1732 ;;; - CAST chains;
1733 (defun ir1-optimize-cast (cast &optional do-not-optimize)
1734   (declare (type cast cast))
1735   (let ((value (cast-value cast))
1736         (atype (cast-asserted-type cast)))
1737     (when (not do-not-optimize)
1738       (let ((lvar (node-lvar cast)))
1739         (when (values-subtypep (lvar-derived-type value)
1740                                (cast-asserted-type cast))
1741           (delete-filter cast lvar value)
1742           (when lvar
1743             (reoptimize-lvar lvar)
1744             (when (lvar-single-value-p lvar)
1745               (note-single-valuified-lvar lvar)))
1746           (return-from ir1-optimize-cast t))
1747
1748         (when (and (listp (lvar-uses value))
1749                    lvar)
1750           ;; Pathwise removing of CAST
1751           (let ((ctran (node-next cast))
1752                 (dest (lvar-dest lvar))
1753                 next-block)
1754             (collect ((merges))
1755               (do-uses (use value)
1756                 (when (and (values-subtypep (node-derived-type use) atype)
1757                            (immediately-used-p value use))
1758                   (unless next-block
1759                     (when ctran (ensure-block-start ctran))
1760                     (setq next-block (first (block-succ (node-block cast))))
1761                     (ensure-block-start (node-prev cast))
1762                     (reoptimize-lvar lvar)
1763                     (setf (lvar-%derived-type value) nil))
1764                   (%delete-lvar-use use)
1765                   (add-lvar-use use lvar)
1766                   (unlink-blocks (node-block use) (node-block cast))
1767                   (link-blocks (node-block use) next-block)
1768                   (when (and (return-p dest)
1769                              (basic-combination-p use)
1770                              (eq (basic-combination-kind use) :local))
1771                     (merges use))))
1772               (dolist (use (merges))
1773                 (merge-tail-sets use)))))))
1774
1775     (let* ((value-type (lvar-derived-type value))
1776            (int (values-type-intersection value-type atype)))
1777       (derive-node-type cast int)
1778       (when (eq int *empty-type*)
1779         (unless (eq value-type *empty-type*)
1780
1781           ;; FIXME: Do it in one step.
1782           (filter-lvar
1783            value
1784            (if (cast-single-value-p cast)
1785                `(list 'dummy)
1786                `(multiple-value-call #'list 'dummy)))
1787           (filter-lvar
1788            (cast-value cast)
1789            ;; FIXME: Derived type.
1790            `(%compile-time-type-error 'dummy
1791                                       ',(type-specifier atype)
1792                                       ',(type-specifier value-type)))
1793           ;; KLUDGE: FILTER-LVAR does not work for non-returning
1794           ;; functions, so we declare the return type of
1795           ;; %COMPILE-TIME-TYPE-ERROR to be * and derive the real type
1796           ;; here.
1797           (setq value (cast-value cast))
1798           (derive-node-type (lvar-uses value) *empty-type*)
1799           (maybe-terminate-block (lvar-uses value) nil)
1800           ;; FIXME: Is it necessary?
1801           (aver (null (block-pred (node-block cast))))
1802           (delete-block-lazily (node-block cast))
1803           (return-from ir1-optimize-cast)))
1804       (when (eq (node-derived-type cast) *empty-type*)
1805         (maybe-terminate-block cast nil))
1806
1807       (when (and (cast-%type-check cast)
1808                  (values-subtypep value-type
1809                                   (cast-type-to-check cast)))
1810         (setf (cast-%type-check cast) nil))))
1811
1812   (unless do-not-optimize
1813     (setf (node-reoptimize cast) nil)))