src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for a CONTINUATION whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-continuation-p (thing)
  24   (and (continuation-p thing)
  25        (let ((use (continuation-use thing)))
  26          (and (ref-p use)
  27               (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for a continuation whose only use is a
  30 ;;; constant node.
  31 (declaim (ftype (function (continuation) t) continuation-value))
  32 (defun continuation-value (cont)
  33   (aver (constant-continuation-p cont))
  34   (constant-value (ref-leaf (continuation-use cont))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Return a (possibly values) type that describes what we have proven
  39 ;;; about the type of Cont without taking any type assertions into
  40 ;;; consideration. This is just the union of the NODE-DERIVED-TYPE of
  41 ;;; all the uses. Most often people use CONTINUATION-DERIVED-TYPE or
  42 ;;; CONTINUATION-TYPE instead of using this function directly.
  43 (defun continuation-proven-type (cont)
  44   (declare (type continuation cont))
  45   (ecase (continuation-kind cont)
  46     ((:block-start :deleted-block-start)
  47      (let ((uses (block-start-uses (continuation-block cont))))
  48        (if uses
  49            (do ((res (node-derived-type (first uses))
  50                      (values-type-union (node-derived-type (first current))
  51                                         res))
  52                 (current (rest uses) (rest current)))
  53                ((null current) res))
  54            *empty-type*)))
  55     (:inside-block
  56      (node-derived-type (continuation-use cont)))))
  57
  58 ;;; Our best guess for the type of this continuation's value. Note
  59 ;;; that this may be VALUES or FUNCTION type, which cannot be passed
  60 ;;; as an argument to the normal type operations. See
  61 ;;; CONTINUATION-TYPE. This may be called on deleted continuations,
  62 ;;; always returning *.
  63 ;;;
  64 ;;; What we do is call CONTINUATION-PROVEN-TYPE and check whether the
  65 ;;; result is a subtype of the assertion. If so, return the proven
  66 ;;; type and set TYPE-CHECK to nil. Otherwise, return the intersection
  67 ;;; of the asserted and proven types, and set TYPE-CHECK T. If
  68 ;;; TYPE-CHECK already has a non-null value, then preserve it. Only in
  69 ;;; the somewhat unusual circumstance of a newly discovered assertion
  70 ;;; will we change TYPE-CHECK from NIL to T.
  71 ;;;
  72 ;;; The result value is cached in the CONTINUATION-%DERIVED-TYPE slot.
  73 ;;; If the slot is true, just return that value, otherwise recompute
  74 ;;; and stash the value there.
  75 #!-sb-fluid (declaim (inline continuation-derived-type))
  76 (defun continuation-derived-type (cont)
  77   (declare (type continuation cont))
  78   (or (continuation-%derived-type cont)
  79       (%continuation-derived-type cont)))
  80 (defun %continuation-derived-type (cont)
  81   (declare (type continuation cont))
  82   (let ((proven (continuation-proven-type cont))
  83         (asserted (continuation-asserted-type cont)))
  84     (cond ((values-subtypep proven asserted)
  85            (setf (continuation-%type-check cont) nil)
  86            (setf (continuation-%derived-type cont) proven))
  87           ((and (values-subtypep proven (specifier-type 'function))
  88                 (values-subtypep asserted (specifier-type 'function)))
  89            ;; It's physically impossible for a runtime type check to
  90            ;; distinguish between the various subtypes of FUNCTION, so
  91            ;; it'd be pointless to do more type checks here.
  92            (setf (continuation-%type-check cont) nil)
  93            (setf (continuation-%derived-type cont)
  94                  ;; FIXME: This should depend on optimization
  95                  ;; policy. This is for SPEED > SAFETY:
  96                  #+nil (values-type-intersection asserted proven)
  97                  ;; and this is for SAFETY >= SPEED:
  98                  #-nil proven))
  99           (t
 100            (unless (or (continuation-%type-check cont)
 101                        (not (continuation-dest cont))
 102                        (eq asserted *universal-type*))
 103              (setf (continuation-%type-check cont) t))
 104
 105            (setf (continuation-%derived-type cont)
 106                  (values-type-intersection asserted proven))))))
 107
 108 ;;; Call CONTINUATION-DERIVED-TYPE to make sure the slot is up to
 109 ;;; date, then return it.
 110 #!-sb-fluid (declaim (inline continuation-type-check))
 111 (defun continuation-type-check (cont)
 112   (declare (type continuation cont))
 113   (continuation-derived-type cont)
 114   (continuation-%type-check cont))
 115
 116 ;;; Return the derived type for CONT's first value. This is guaranteed
 117 ;;; not to be a VALUES or FUNCTION type.
 118 (declaim (ftype (function (continuation) ctype) continuation-type))
 119 (defun continuation-type (cont)
 120   (single-value-type (continuation-derived-type cont)))
 121 \f
 122 ;;;; interface routines used by optimizers
 123
 124 ;;; This function is called by optimizers to indicate that something
 125 ;;; interesting has happened to the value of Cont. Optimizers must
 126 ;;; make sure that they don't call for reoptimization when nothing has
 127 ;;; happened, since optimization will fail to terminate.
 128 ;;;
 129 ;;; We clear any cached type for the continuation and set the
 130 ;;; reoptimize flags on everything in sight, unless the continuation
 131 ;;; is deleted (in which case we do nothing.)
 132 ;;;
 133 ;;; Since this can get called during IR1 conversion, we have to be
 134 ;;; careful not to fly into space when the Dest's Prev is missing.
 135 (defun reoptimize-continuation (cont)
 136   (declare (type continuation cont))
 137   (unless (member (continuation-kind cont) '(:deleted :unused))
 138     (setf (continuation-%derived-type cont) nil)
 139     (let ((dest (continuation-dest cont)))
 140       (when dest
 141         (setf (continuation-reoptimize cont) t)
 142         (setf (node-reoptimize dest) t)
 143         (let ((prev (node-prev dest)))
 144           (when prev
 145             (let* ((block (continuation-block prev))
 146                    (component (block-component block)))
 147               (when (typep dest 'cif)
 148                 (setf (block-test-modified block) t))
 149               (setf (block-reoptimize block) t)
 150               (setf (component-reoptimize component) t))))))
 151     (do-uses (node cont)
 152       (setf (block-type-check (node-block node)) t)))
 153   (values))
 154
 155 ;;; Annotate Node to indicate that its result has been proven to be
 156 ;;; typep to RType. After IR1 conversion has happened, this is the
 157 ;;; only correct way to supply information discovered about a node's
 158 ;;; type. If you screw with the Node-Derived-Type directly, then
 159 ;;; information may be lost and reoptimization may not happen.
 160 ;;;
 161 ;;; What we do is intersect Rtype with Node's Derived-Type. If the
 162 ;;; intersection is different from the old type, then we do a
 163 ;;; Reoptimize-Continuation on the Node-Cont.
 164 (defun derive-node-type (node rtype)
 165   (declare (type node node) (type ctype rtype))
 166   (let ((node-type (node-derived-type node)))
 167     (unless (eq node-type rtype)
 168       (let ((int (values-type-intersection node-type rtype)))
 169         (when (type/= node-type int)
 170           (when (and *check-consistency*
 171                      (eq int *empty-type*)
 172                      (not (eq rtype *empty-type*)))
 173             (let ((*compiler-error-context* node))
 174               (compiler-warn
 175                "New inferred type ~S conflicts with old type:~
 176                 ~%  ~S~%*** possible internal error? Please report this."
 177                (type-specifier rtype) (type-specifier node-type))))
 178           (setf (node-derived-type node) int)
 179           (reoptimize-continuation (node-cont node))))))
 180   (values))
 181
 182 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 183 ;;; error for CONT's value not to be TYPEP to TYPE. If we improve the
 184 ;;; assertion, we set TYPE-CHECK and TYPE-ASSERTED to guarantee that
 185 ;;; the new assertion will be checked.
 186 (defun assert-continuation-type (cont type)
 187   (declare (type continuation cont) (type ctype type))
 188   (let ((cont-type (continuation-asserted-type cont)))
 189     (unless (eq cont-type type)
 190       (let ((int (values-type-intersection cont-type type)))
 191         (when (type/= cont-type int)
 192           (setf (continuation-asserted-type cont) int)
 193           (do-uses (node cont)
 194             (setf (block-attributep (block-flags (node-block node))
 195                                     type-check type-asserted)
 196                   t))
 197           (reoptimize-continuation cont)))))
 198   (values))
 199
 200 ;;; Assert that CALL is to a function of the specified TYPE. It is
 201 ;;; assumed that the call is legal and has only constants in the
 202 ;;; keyword positions.
 203 (defun assert-call-type (call type)
 204   (declare (type combination call) (type fun-type type))
 205   (derive-node-type call (fun-type-returns type))
 206   (let ((args (combination-args call)))
 207     (dolist (req (fun-type-required type))
 208       (when (null args) (return-from assert-call-type))
 209       (let ((arg (pop args)))
 210         (assert-continuation-type arg req)))
 211     (dolist (opt (fun-type-optional type))
 212       (when (null args) (return-from assert-call-type))
 213       (let ((arg (pop args)))
 214         (assert-continuation-type arg opt)))
 215
 216     (let ((rest (fun-type-rest type)))
 217       (when rest
 218         (dolist (arg args)
 219           (assert-continuation-type arg rest))))
 220
 221     (dolist (key (fun-type-keywords type))
 222       (let ((name (key-info-name key)))
 223         (do ((arg args (cddr arg)))
 224             ((null arg))
 225           (when (eq (continuation-value (first arg)) name)
 226             (assert-continuation-type
 227              (second arg) (key-info-type key)))))))
 228   (values))
 229 \f
 230 ;;;; IR1-OPTIMIZE
 231
 232 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 233 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 234 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 235 ;;; we are done, then another iteration would be beneficial.
 236 (defun ir1-optimize (component)
 237   (declare (type component component))
 238   (setf (component-reoptimize component) nil)
 239   (do-blocks (block component)
 240     (cond
 241      ((or (block-delete-p block)
 242           (null (block-pred block)))
 243       (delete-block block))
 244      ((eq (functional-kind (block-home-lambda block)) :deleted)
 245       ;; Preserve the BLOCK-SUCC invariant that almost every block has
 246       ;; one successor (and a block with DELETE-P set is an acceptable
 247       ;; exception).
 248       (labels ((mark-blocks (block)
 249                  (dolist (pred (block-pred block))
 250                    (when (and (not (block-delete-p pred))
 251                               (eq (functional-kind (block-home-lambda pred))
 252                                   :deleted))
 253                      (setf (block-delete-p pred) t)
 254                      (mark-blocks pred)))))
 255         (mark-blocks block)
 256         (delete-block block)))
 257      (t
 258       (loop
 259         (let ((succ (block-succ block)))
 260           (unless (and succ (null (rest succ)))
 261             (return)))
 262
 263         (let ((last (block-last block)))
 264           (typecase last
 265             (cif
 266              (flush-dest (if-test last))
 267              (when (unlink-node last)
 268                (return)))
 269             (exit
 270              (when (maybe-delete-exit last)
 271                (return)))))
 272
 273         (unless (join-successor-if-possible block)
 274           (return)))
 275
 276       (when (and (block-reoptimize block) (block-component block))
 277         (aver (not (block-delete-p block)))
 278         (ir1-optimize-block block))
 279
 280       ;; We delete blocks when there is either no predecessor or the
 281       ;; block is in a lambda that has been deleted. These blocks
 282       ;; would eventually be deleted by DFO recomputation, but doing
 283       ;; it here immediately makes the effect available to IR1
 284       ;; optimization.
 285       (when (and (block-flush-p block) (block-component block))
 286         (aver (not (block-delete-p block)))
 287         (flush-dead-code block)))))
 288
 289   (values))
 290
 291 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 292 ;;; flags.
 293 ;;;
 294 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 295 ;;; still be set upon return from this function, meaning that further
 296 ;;; optimization is wanted (as a consequence of optimizations we did).
 297 (defun ir1-optimize-block (block)
 298   (declare (type cblock block))
 299   ;; We clear the node and block REOPTIMIZE flags before doing the
 300   ;; optimization, not after. This ensures that the node or block will
 301   ;; be reoptimized if necessary.
 302   (setf (block-reoptimize block) nil)
 303   (do-nodes (node cont block :restart-p t)
 304     (when (node-reoptimize node)
 305       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 306       (setf (node-reoptimize node) nil)
 307       (typecase node
 308         (ref)
 309         (combination
 310          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 311          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 312          ;; any argument changes.
 313          (ir1-optimize-combination node))
 314         (cif
 315          (ir1-optimize-if node))
 316         (creturn
 317          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 318          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 319          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 320          ;; CMU CL comments
 321          (setf (node-reoptimize node) t)
 322          (ir1-optimize-return node))
 323         (mv-combination
 324          (ir1-optimize-mv-combination node))
 325         (exit
 326          ;; With an EXIT, we derive the node's type from the VALUE's
 327          ;; type. We don't propagate CONT's assertion to the VALUE,
 328          ;; since if we did, this would move the checking of CONT's
 329          ;; assertion to the exit. This wouldn't work with CATCH and
 330          ;; UWP, where the EXIT node is just a placeholder for the
 331          ;; actual unknown exit.
 332          (let ((value (exit-value node)))
 333            (when value
 334              (derive-node-type node (continuation-derived-type value)))))
 335         (cset
 336          (ir1-optimize-set node)))))
 337   (values))
 338
 339 ;;; Try to join with a successor block. If we succeed, we return true,
 340 ;;; otherwise false.
 341 (defun join-successor-if-possible (block)
 342   (declare (type cblock block))
 343   (let ((next (first (block-succ block))))
 344     (when (block-start next)
 345       (let* ((last (block-last block))
 346              (last-cont (node-cont last))
 347              (next-cont (block-start next)))
 348         (cond (;; We cannot combine with a successor block if:
 349                (or
 350                 ;; The successor has more than one predecessor.
 351                 (rest (block-pred next))
 352                 ;; The last node's CONT is also used somewhere else.
 353                 (not (eq (continuation-use last-cont) last))
 354                 ;; The successor is the current block (infinite loop).
 355                 (eq next block)
 356                 ;; The next block has a different cleanup, and thus
 357                 ;; we may want to insert cleanup code between the
 358                 ;; two blocks at some point.
 359                 (not (eq (block-end-cleanup block)
 360                          (block-start-cleanup next)))
 361                 ;; The next block has a different home lambda, and
 362                 ;; thus the control transfer is a non-local exit.
 363                 (not (eq (block-home-lambda block)
 364                          (block-home-lambda next))))
 365                nil)
 366               ;; Joining is easy when the successor's START
 367               ;; continuation is the same from our LAST's CONT.
 368               ((eq last-cont next-cont)
 369                (join-blocks block next)
 370                t)
 371               ;; If they differ, then we can still join when the last
 372               ;; continuation has no next and the next continuation
 373               ;; has no uses.
 374               ((and (null (block-start-uses next))
 375                     (eq (continuation-kind last-cont) :inside-block))
 376                ;; In this case, we replace the next
 377                ;; continuation with the last before joining the blocks.
 378                (let ((next-node (continuation-next next-cont)))
 379                  ;; If NEXT-CONT does have a dest, it must be
 380                  ;; unreachable, since there are no USES.
 381                  ;; DELETE-CONTINUATION will mark the dest block as
 382                  ;; DELETE-P [and also this block, unless it is no
 383                  ;; longer backward reachable from the dest block.]
 384                  (delete-continuation next-cont)
 385                  (setf (node-prev next-node) last-cont)
 386                  (setf (continuation-next last-cont) next-node)
 387                  (setf (block-start next) last-cont)
 388                  (join-blocks block next))
 389                t)
 390               (t
 391                nil))))))
 392
 393 ;;; Join together two blocks which have the same ending/starting
 394 ;;; continuation. The code in BLOCK2 is moved into BLOCK1 and BLOCK2
 395 ;;; is deleted from the DFO. We combine the optimize flags for the two
 396 ;;; blocks so that any indicated optimization gets done.
 397 (defun join-blocks (block1 block2)
 398   (declare (type cblock block1 block2))
 399   (let* ((last (block-last block2))
 400          (last-cont (node-cont last))
 401          (succ (block-succ block2))
 402          (start2 (block-start block2)))
 403     (do ((cont start2 (node-cont (continuation-next cont))))
 404         ((eq cont last-cont)
 405          (when (eq (continuation-kind last-cont) :inside-block)
 406            (setf (continuation-block last-cont) block1)))
 407       (setf (continuation-block cont) block1))
 408
 409     (unlink-blocks block1 block2)
 410     (dolist (block succ)
 411       (unlink-blocks block2 block)
 412       (link-blocks block1 block))
 413
 414     (setf (block-last block1) last)
 415     (setf (continuation-kind start2) :inside-block))
 416
 417   (setf (block-flags block1)
 418         (attributes-union (block-flags block1)
 419                           (block-flags block2)
 420                           (block-attributes type-asserted test-modified)))
 421
 422   (let ((next (block-next block2))
 423         (prev (block-prev block2)))
 424     (setf (block-next prev) next)
 425     (setf (block-prev next) prev))
 426
 427   (values))
 428
 429 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 430 ;;; side effects. We can delete sets of lexical variables when the set
 431 ;;; variable has no references.
 432 (defun flush-dead-code (block)
 433   (declare (type cblock block))
 434   (do-nodes-backwards (node cont block)
 435     (unless (continuation-dest cont)
 436       (typecase node
 437         (ref
 438          (delete-ref node)
 439          (unlink-node node))
 440         (combination
 441          (let ((info (combination-kind node)))
 442            (when (fun-info-p info)
 443              (let ((attr (fun-info-attributes info)))
 444                (when (and (ir1-attributep attr flushable)
 445                           ;; ### For now, don't delete potentially
 446                           ;; flushable calls when they have the CALL
 447                           ;; attribute. Someday we should look at the
 448                           ;; functional args to determine if they have
 449                           ;; any side effects.
 450                           (not (ir1-attributep attr call)))
 451                  (flush-dest (combination-fun node))
 452                  (dolist (arg (combination-args node))
 453                    (flush-dest arg))
 454                  (unlink-node node))))))
 455         (mv-combination
 456          (when (eq (basic-combination-kind node) :local)
 457            (let ((fun (combination-lambda node)))
 458              (when (dolist (var (lambda-vars fun) t)
 459                      (when (or (leaf-refs var)
 460                                (lambda-var-sets var))
 461                        (return nil)))
 462                (flush-dest (first (basic-combination-args node)))
 463                (delete-let fun)))))
 464         (exit
 465          (let ((value (exit-value node)))
 466            (when value
 467              (flush-dest value)
 468              (setf (exit-value node) nil))))
 469         (cset
 470          (let ((var (set-var node)))
 471            (when (and (lambda-var-p var)
 472                       (null (leaf-refs var)))
 473              (flush-dest (set-value node))
 474              (setf (basic-var-sets var)
 475                    (delete node (basic-var-sets var)))
 476              (unlink-node node)))))))
 477
 478   (setf (block-flush-p block) nil)
 479   (values))
 480 \f
 481 ;;;; local call return type propagation
 482
 483 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 484 ;;; flag set. It iterates over the uses of the RESULT, looking for
 485 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 486 ;;; call, then we union its type together with the types of other such
 487 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 488 ;;; type with the RESULT's asserted type. We can make this
 489 ;;; intersection now (potentially before type checking) because this
 490 ;;; assertion on the result will eventually be checked (if
 491 ;;; appropriate.)
 492 ;;;
 493 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 494 ;;; combination, which may change the succesor of the call to be the
 495 ;;; called function, and if so, checks if the call can become an
 496 ;;; assignment. If we convert to an assignment, we abort, since the
 497 ;;; RETURN has been deleted.
 498 (defun find-result-type (node)
 499   (declare (type creturn node))
 500   (let ((result (return-result node)))
 501     (collect ((use-union *empty-type* values-type-union))
 502       (do-uses (use result)
 503         (cond ((and (basic-combination-p use)
 504                     (eq (basic-combination-kind use) :local))
 505                (aver (eq (lambda-tail-set (node-home-lambda use))
 506                          (lambda-tail-set (combination-lambda use))))
 507                (when (combination-p use)
 508                  (when (nth-value 1 (maybe-convert-tail-local-call use))
 509                    (return-from find-result-type (values)))))
 510               (t
 511                (use-union (node-derived-type use)))))
 512       (let ((int (values-type-intersection
 513                   (continuation-asserted-type result)
 514                   (use-union))))
 515         (setf (return-result-type node) int))))
 516   (values))
 517
 518 ;;; Do stuff to realize that something has changed about the value
 519 ;;; delivered to a return node. Since we consider the return values of
 520 ;;; all functions in the tail set to be equivalent, this amounts to
 521 ;;; bringing the entire tail set up to date. We iterate over the
 522 ;;; returns for all the functions in the tail set, reanalyzing them
 523 ;;; all (not treating Node specially.)
 524 ;;;
 525 ;;; When we are done, we check whether the new type is different from
 526 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 527 ;;; all the continuations for references to functions in the tail set.
 528 ;;; This will cause IR1-OPTIMIZE-COMBINATION to derive the new type as
 529 ;;; the results of the calls.
 530 (defun ir1-optimize-return (node)
 531   (declare (type creturn node))
 532   (let* ((tails (lambda-tail-set (return-lambda node)))
 533          (funs (tail-set-funs tails)))
 534     (collect ((res *empty-type* values-type-union))
 535       (dolist (fun funs)
 536         (let ((return (lambda-return fun)))
 537           (when return
 538             (when (node-reoptimize return)
 539               (setf (node-reoptimize return) nil)
 540               (find-result-type return))
 541             (res (return-result-type return)))))
 542
 543       (when (type/= (res) (tail-set-type tails))
 544         (setf (tail-set-type tails) (res))
 545         (dolist (fun (tail-set-funs tails))
 546           (dolist (ref (leaf-refs fun))
 547             (reoptimize-continuation (node-cont ref)))))))
 548
 549   (values))
 550 \f
 551 ;;;; IF optimization
 552
 553 ;;; If the test has multiple uses, replicate the node when possible.
 554 ;;; Also check whether the predicate is known to be true or false,
 555 ;;; deleting the IF node in favor of the appropriate branch when this
 556 ;;; is the case.
 557 (defun ir1-optimize-if (node)
 558   (declare (type cif node))
 559   (let ((test (if-test node))
 560         (block (node-block node)))
 561
 562     (when (and (eq (block-start block) test)
 563                (eq (continuation-next test) node)
 564                (rest (block-start-uses block)))
 565       (do-uses (use test)
 566         (when (immediately-used-p test use)
 567           (convert-if-if use node)
 568           (when (continuation-use test) (return)))))
 569
 570     (let* ((type (continuation-type test))
 571            (victim
 572             (cond ((constant-continuation-p test)
 573                    (if (continuation-value test)
 574                        (if-alternative node)
 575                        (if-consequent node)))
 576                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 577                    (if-alternative node))
 578                   ((type= type (specifier-type 'null))
 579                    (if-consequent node)))))
 580       (when victim
 581         (flush-dest test)
 582         (when (rest (block-succ block))
 583           (unlink-blocks block victim))
 584         (setf (component-reanalyze (node-component node)) t)
 585         (unlink-node node))))
 586   (values))
 587
 588 ;;; Create a new copy of an IF node that tests the value of the node
 589 ;;; USE. The test must have >1 use, and must be immediately used by
 590 ;;; USE. NODE must be the only node in its block (implying that
 591 ;;; block-start = if-test).
 592 ;;;
 593 ;;; This optimization has an effect semantically similar to the
 594 ;;; source-to-source transformation:
 595 ;;;    (IF (IF A B C) D E) ==>
 596 ;;;    (IF A (IF B D E) (IF C D E))
 597 ;;;
 598 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 599 ;;; node so that dead code deletion notes will definitely not consider
 600 ;;; either node to be part of the original source. One node might
 601 ;;; become unreachable, resulting in a spurious note.
 602 (defun convert-if-if (use node)
 603   (declare (type node use) (type cif node))
 604   (with-ir1-environment-from-node node
 605     (let* ((block (node-block node))
 606            (test (if-test node))
 607            (cblock (if-consequent node))
 608            (ablock (if-alternative node))
 609            (use-block (node-block use))
 610            (dummy-cont (make-continuation))
 611            (new-cont (make-continuation))
 612            (new-node (make-if :test new-cont
 613                               :consequent cblock
 614                               :alternative ablock))
 615            (new-block (continuation-starts-block new-cont)))
 616       (link-node-to-previous-continuation new-node new-cont)
 617       (setf (continuation-dest new-cont) new-node)
 618       (add-continuation-use new-node dummy-cont)
 619       (setf (block-last new-block) new-node)
 620
 621       (unlink-blocks use-block block)
 622       (delete-continuation-use use)
 623       (add-continuation-use use new-cont)
 624       (link-blocks use-block new-block)
 625
 626       (link-blocks new-block cblock)
 627       (link-blocks new-block ablock)
 628
 629       (push "<IF Duplication>" (node-source-path node))
 630       (push "<IF Duplication>" (node-source-path new-node))
 631
 632       (reoptimize-continuation test)
 633       (reoptimize-continuation new-cont)
 634       (setf (component-reanalyze *current-component*) t)))
 635   (values))
 636 \f
 637 ;;;; exit IR1 optimization
 638
 639 ;;; This function attempts to delete an exit node, returning true if
 640 ;;; it deletes the block as a consequence:
 641 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 642 ;;;    anything, since there is nothing to be done.
 643 ;;; -- If the exit node and its ENTRY have the same home lambda then
 644 ;;;    we know the exit is local, and can delete the exit. We change
 645 ;;;    uses of the Exit-Value to be uses of the original continuation,
 646 ;;;    then unlink the node. If the exit is to a TR context, then we
 647 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 648 ;;;    their value to this exit.
 649 ;;; -- If there is no value (as in a GO), then we skip the value
 650 ;;;    semantics.
 651 ;;;
 652 ;;; This function is also called by environment analysis, since it
 653 ;;; wants all exits to be optimized even if normal optimization was
 654 ;;; omitted.
 655 (defun maybe-delete-exit (node)
 656   (declare (type exit node))
 657   (let ((value (exit-value node))
 658         (entry (exit-entry node))
 659         (cont (node-cont node)))
 660     (when (and entry
 661                (eq (node-home-lambda node) (node-home-lambda entry)))
 662       (setf (entry-exits entry) (delete node (entry-exits entry)))
 663       (prog1
 664           (unlink-node node)
 665         (when value
 666           (collect ((merges))
 667             (when (return-p (continuation-dest cont))
 668               (do-uses (use value)
 669                 (when (and (basic-combination-p use)
 670                            (eq (basic-combination-kind use) :local))
 671                   (merges use))))
 672             (substitute-continuation-uses cont value)
 673             (dolist (merge (merges))
 674               (merge-tail-sets merge))))))))
 675 \f
 676 ;;;; combination IR1 optimization
 677
 678 ;;; Report as we try each transform?
 679 #!+sb-show
 680 (defvar *show-transforms-p* nil)
 681
 682 ;;; Do IR1 optimizations on a COMBINATION node.
 683 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 684 (defun ir1-optimize-combination (node)
 685   (when (continuation-reoptimize (basic-combination-fun node))
 686     (propagate-fun-change node))
 687   (let ((args (basic-combination-args node))
 688         (kind (basic-combination-kind node)))
 689     (case kind
 690       (:local
 691        (let ((fun (combination-lambda node)))
 692          (if (eq (functional-kind fun) :let)
 693              (propagate-let-args node fun)
 694              (propagate-local-call-args node fun))))
 695       ((:full :error)
 696        (dolist (arg args)
 697          (when arg
 698            (setf (continuation-reoptimize arg) nil))))
 699       (t
 700        (dolist (arg args)
 701          (when arg
 702            (setf (continuation-reoptimize arg) nil)))
 703
 704        (let ((attr (fun-info-attributes kind)))
 705          (when (and (ir1-attributep attr foldable)
 706                     ;; KLUDGE: The next test could be made more sensitive,
 707                     ;; only suppressing constant-folding of functions with
 708                     ;; CALL attributes when they're actually passed
 709                     ;; function arguments. -- WHN 19990918
 710                     (not (ir1-attributep attr call))
 711                     (every #'constant-continuation-p args)
 712                     (continuation-dest (node-cont node))
 713                     ;; Even if the function is foldable in principle,
 714                     ;; it might be one of our low-level
 715                     ;; implementation-specific functions. Such
 716                     ;; functions don't necessarily exist at runtime on
 717                     ;; a plain vanilla ANSI Common Lisp
 718                     ;; cross-compilation host, in which case the
 719                     ;; cross-compiler can't fold it because the
 720                     ;; cross-compiler doesn't know how to evaluate it.
 721                     #+sb-xc-host
 722                     (fboundp (combination-fun-source-name node)))
 723            (constant-fold-call node)
 724            (return-from ir1-optimize-combination)))
 725
 726        (let ((fun (fun-info-derive-type kind)))
 727          (when fun
 728            (let ((res (funcall fun node)))
 729              (when res
 730                (derive-node-type node res)
 731                (maybe-terminate-block node nil)))))
 732
 733        (let ((fun (fun-info-optimizer kind)))
 734          (unless (and fun (funcall fun node))
 735            (dolist (x (fun-info-transforms kind))
 736              #!+sb-show
 737              (when *show-transforms-p*
 738                (let* ((cont (basic-combination-fun node))
 739                       (fname (continuation-fun-name cont t)))
 740                  (/show "trying transform" x (transform-function x) "for" fname)))
 741              (unless (ir1-transform node x)
 742                #!+sb-show
 743                (when *show-transforms-p*
 744                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 745                (return))))))))
 746
 747   (values))
 748
 749 ;;; If CALL is to a function that doesn't return (i.e. return type is
 750 ;;; NIL), then terminate the block there, and link it to the component
 751 ;;; tail. We also change the call's CONT to be a dummy continuation to
 752 ;;; prevent the use from confusing things.
 753 ;;;
 754 ;;; Except when called during IR1 [FIXME: What does this mean? Except
 755 ;;; during IR1 conversion? What about IR1 optimization?], we delete
 756 ;;; the continuation if it has no other uses. (If it does have other
 757 ;;; uses, we reoptimize.)
 758 ;;;
 759 ;;; Termination on the basis of a continuation type assertion is
 760 ;;; inhibited when:
 761 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 762 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 763 ;;;    weakening.)
 764 (defun maybe-terminate-block (call ir1-converting-not-optimizing-p)
 765   (declare (type basic-combination call))
 766   (let* ((block (node-block call))
 767          (cont (node-cont call))
 768          (tail (component-tail (block-component block)))
 769          (succ (first (block-succ block))))
 770     (unless (or (and (eq call (block-last block)) (eq succ tail))
 771                 (block-delete-p block))
 772       (when (or (and (eq (continuation-asserted-type cont) *empty-type*)
 773                      (not (or ir1-converting-not-optimizing-p
 774                               (eq (continuation-kind cont) :deleted))))
 775                 (eq (node-derived-type call) *empty-type*))
 776         (cond (ir1-converting-not-optimizing-p
 777                (delete-continuation-use call)
 778                (cond
 779                 ((block-last block)
 780                  (aver (and (eq (block-last block) call)
 781                             (eq (continuation-kind cont) :block-start))))
 782                 (t
 783                  (setf (block-last block) call)
 784                  (link-blocks block (continuation-starts-block cont)))))
 785               (t
 786                (node-ends-block call)
 787                (delete-continuation-use call)
 788                (if (eq (continuation-kind cont) :unused)
 789                    (delete-continuation cont)
 790                    (reoptimize-continuation cont))))
 791
 792         (unlink-blocks block (first (block-succ block)))
 793         (setf (component-reanalyze (block-component block)) t)
 794         (aver (not (block-succ block)))
 795         (link-blocks block tail)
 796         (add-continuation-use call (make-continuation))
 797         t))))
 798
 799 ;;; This is called both by IR1 conversion and IR1 optimization when
 800 ;;; they have verified the type signature for the call, and are
 801 ;;; wondering if something should be done to special-case the call. If
 802 ;;; CALL is a call to a global function, then see whether it defined
 803 ;;; or known:
 804 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 805 ;;;    the expansion and change the call to call it. Expansion is
 806 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 807 ;;;    true, we never expand, since this function has already been
 808 ;;;    converted. Local call analysis will duplicate the definition
 809 ;;;    if necessary. We claim that the parent form is LABELS for
 810 ;;;    context declarations, since we don't want it to be considered
 811 ;;;    a real global function.
 812 ;;; -- If it is a known function, mark it as such by setting the KIND.
 813 ;;;
 814 ;;; We return the leaf referenced (NIL if not a leaf) and the
 815 ;;; FUN-INFO assigned.
 816 ;;;
 817 ;;; FIXME: The IR1-CONVERTING-NOT-OPTIMIZING-P argument is what the
 818 ;;; old CMU CL code called IR1-P, without explanation. My (WHN
 819 ;;; 2002-01-09) tentative understanding of it is that we can call this
 820 ;;; operation either in initial IR1 conversion or in later IR1
 821 ;;; optimization, and it tells which is which. But it would be good
 822 ;;; for someone who really understands it to check whether this is
 823 ;;; really right.
 824 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 825   (declare (type combination call))
 826   (let* ((ref (continuation-use (basic-combination-fun call)))
 827          (leaf (when (ref-p ref) (ref-leaf ref)))
 828          (inlinep (if (defined-fun-p leaf)
 829                       (defined-fun-inlinep leaf)
 830                       :no-chance)))
 831     (cond
 832      ((eq inlinep :notinline) (values nil nil))
 833      ((not (and (global-var-p leaf)
 834                 (eq (global-var-kind leaf) :global-function)))
 835       (values leaf nil))
 836      ((and (ecase inlinep
 837              (:inline t)
 838              (:no-chance nil)
 839              ((nil :maybe-inline) (policy call (zerop space))))
 840            (defined-fun-p leaf)
 841            (defined-fun-inline-expansion leaf)
 842            (let ((fun (defined-fun-functional leaf)))
 843              (or (not fun)
 844                  (and (eq inlinep :inline) (functional-kind fun))))
 845            (inline-expansion-ok call))
 846       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 847              ;; called semi-inlining? A more descriptive name would
 848              ;; be nice. -- WHN 2002-01-07
 849              (frob ()
 850                (let ((res (ir1-convert-lambda-for-defun
 851                            (defined-fun-inline-expansion leaf)
 852                            leaf t
 853                            #'ir1-convert-inline-lambda)))
 854                  (setf (defined-fun-functional leaf) res)
 855                  (change-ref-leaf ref res))))
 856         (if ir1-converting-not-optimizing-p
 857             (frob)
 858             (with-ir1-environment-from-node call
 859               (frob)
 860               (locall-analyze-component *current-component*))))
 861
 862       (values (ref-leaf (continuation-use (basic-combination-fun call)))
 863               nil))
 864      (t
 865       (let ((info (info :function :info (leaf-source-name leaf))))
 866         (if info
 867             (values leaf (setf (basic-combination-kind call) info))
 868             (values leaf nil)))))))
 869
 870 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 871 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 872 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 873 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 874 ;;; syntax check, arg/result type processing, but still call
 875 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 876 ;;; and that checking is done by local call analysis.
 877 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 878   (declare (type combination call) (type ctype type))
 879   (cond ((not (fun-type-p type))
 880          (aver (multiple-value-bind (val win)
 881                    (csubtypep type (specifier-type 'function))
 882                  (or val (not win))))
 883          (recognize-known-call call ir1-converting-not-optimizing-p))
 884         ((valid-fun-use call type
 885                         :argument-test #'always-subtypep
 886                         :result-test #'always-subtypep
 887                         ;; KLUDGE: Common Lisp is such a dynamic
 888                         ;; language that all we can do here in
 889                         ;; general is issue a STYLE-WARNING. It
 890                         ;; would be nice to issue a full WARNING
 891                         ;; in the special case of of type
 892                         ;; mismatches within a compilation unit
 893                         ;; (as in section 3.2.2.3 of the spec)
 894                         ;; but at least as of sbcl-0.6.11, we
 895                         ;; don't keep track of whether the
 896                         ;; mismatched data came from the same
 897                         ;; compilation unit, so we can't do that.
 898                         ;; -- WHN 2001-02-11
 899                         ;;
 900                         ;; FIXME: Actually, I think we could
 901                         ;; issue a full WARNING if the call
 902                         ;; violates a DECLAIM FTYPE.
 903                         :lossage-fun #'compiler-style-warn
 904                         :unwinnage-fun #'compiler-note)
 905          (assert-call-type call type)
 906          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 907          (recognize-known-call call ir1-converting-not-optimizing-p))
 908         (t
 909          (setf (combination-kind call) :error)
 910          (values nil nil))))
 911
 912 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 913 ;;; changed. If the call is local, we try to LET-convert it, and
 914 ;;; derive the result type. If it is a :FULL call, we validate it
 915 ;;; against the type, which recognizes known calls, does inline
 916 ;;; expansion, etc. If a call to a predicate in a non-conditional
 917 ;;; position or to a function with a source transform, then we
 918 ;;; reconvert the form to give IR1 another chance.
 919 (defun propagate-fun-change (call)
 920   (declare (type combination call))
 921   (let ((*compiler-error-context* call)
 922         (fun-cont (basic-combination-fun call)))
 923     (setf (continuation-reoptimize fun-cont) nil)
 924     (case (combination-kind call)
 925       (:local
 926        (let ((fun (combination-lambda call)))
 927          (maybe-let-convert fun)
 928          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 929            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 930       (:full
 931        (multiple-value-bind (leaf info)
 932            (validate-call-type call (continuation-type fun-cont) nil)
 933          (cond ((functional-p leaf)
 934                 (convert-call-if-possible
 935                  (continuation-use (basic-combination-fun call))
 936                  call))
 937                ((not leaf))
 938                ((or (info :function :source-transform (leaf-source-name leaf))
 939                     (and info
 940                          (ir1-attributep (fun-info-attributes info)
 941                                          predicate)
 942                          (let ((dest (continuation-dest (node-cont call))))
 943                            (and dest (not (if-p dest))))))
 944                 (when (and (leaf-has-source-name-p leaf)
 945                            ;; FIXME: This SYMBOLP is part of a literal
 946                            ;; translation of a test in the old CMU CL
 947                            ;; source, and it's not quite clear what
 948                            ;; the old source meant. Did it mean "has a
 949                            ;; valid name"? Or did it mean "is an
 950                            ;; ordinary function name, not a SETF
 951                            ;; function"? Either way, the old CMU CL
 952                            ;; code probably didn't deal with SETF
 953                            ;; functions correctly, and neither does
 954                            ;; this new SBCL code, and that should be fixed.
 955                            (symbolp (leaf-source-name leaf)))
 956                   (let ((dummies (make-gensym-list (length
 957                                                     (combination-args call)))))
 958                     (transform-call call
 959                                     `(lambda ,dummies
 960                                        (,(leaf-source-name leaf)
 961                                         ,@dummies))
 962                                     (leaf-source-name leaf))))))))))
 963   (values))
 964 \f
 965 ;;;; known function optimization
 966
 967 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
 968 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
 969 ;;; replace it, otherwise add a new one.
 970 (defun record-optimization-failure (node transform args)
 971   (declare (type combination node) (type transform transform)
 972            (type (or fun-type list) args))
 973   (let* ((table (component-failed-optimizations *component-being-compiled*))
 974          (found (assoc transform (gethash node table))))
 975     (if found
 976         (setf (cdr found) args)
 977         (push (cons transform args) (gethash node table))))
 978   (values))
 979
 980 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
 981 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
 982 ;;; doing the transform for some reason and FLAME is true, then we
 983 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
 984 ;;; finalize to pick up. We return true if the transform failed, and
 985 ;;; thus further transformation should be attempted. We return false
 986 ;;; if either the transform succeeded or was aborted.
 987 (defun ir1-transform (node transform)
 988   (declare (type combination node) (type transform transform))
 989   (let* ((type (transform-type transform))
 990          (fun (transform-function transform))
 991          (constrained (fun-type-p type))
 992          (table (component-failed-optimizations *component-being-compiled*))
 993          (flame (if (transform-important transform)
 994                     (policy node (>= speed inhibit-warnings))
 995                     (policy node (> speed inhibit-warnings))))
 996          (*compiler-error-context* node))
 997     (cond ((or (not constrained)
 998                (valid-fun-use node type :strict-result t))
 999            (multiple-value-bind (severity args)
1000                (catch 'give-up-ir1-transform
1001                  (transform-call node
1002                                  (funcall fun node)
1003                                  (combination-fun-source-name node))
1004                  (values :none nil))
1005              (ecase severity
1006                (:none
1007                 (remhash node table)
1008                 nil)
1009                (:aborted
1010                 (setf (combination-kind node) :error)
1011                 (when args
1012                   (apply #'compiler-warn args))
1013                 (remhash node table)
1014                 nil)
1015                (:failure
1016                 (if args
1017                     (when flame
1018                       (record-optimization-failure node transform args))
1019                     (setf (gethash node table)
1020                           (remove transform (gethash node table) :key #'car)))
1021                 t)
1022                (:delayed
1023                  (remhash node table)
1024                  nil))))
1025           ((and flame
1026                 (valid-fun-use node
1027                                type
1028                                :argument-test #'types-equal-or-intersect
1029                                :result-test #'values-types-equal-or-intersect))
1030            (record-optimization-failure node transform type)
1031            t)
1032           (t
1033            t))))
1034
1035 ;;; When we don't like an IR1 transform, we throw the severity/reason
1036 ;;; and args.
1037 ;;;
1038 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1039 ;;; aborting this attempt to transform the call, but admitting the
1040 ;;; possibility that this or some other transform will later succeed.
1041 ;;; If arguments are supplied, they are format arguments for an
1042 ;;; efficiency note.
1043 ;;;
1044 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1045 ;;; force a normal call to the function at run time. No further
1046 ;;; optimizations will be attempted.
1047 ;;;
1048 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1049 ;;; delay the transform on the node until later. REASONS specifies
1050 ;;; when the transform will be later retried. The :OPTIMIZE reason
1051 ;;; causes the transform to be delayed until after the current IR1
1052 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1053 ;;; be delayed until after constraint propagation.
1054 ;;;
1055 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1056 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1057 ;;; do CASE operations on the various REASON values, it might be a
1058 ;;; good idea to go OO, representing the reasons by objects, using
1059 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1060 ;;; SIGNAL instead of THROW.
1061 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1062 (defun give-up-ir1-transform (&rest args)
1063   (throw 'give-up-ir1-transform (values :failure args)))
1064 (defun abort-ir1-transform (&rest args)
1065   (throw 'give-up-ir1-transform (values :aborted args)))
1066 (defun delay-ir1-transform (node &rest reasons)
1067   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1068     (cond ((not assoc)
1069             (setf *delayed-ir1-transforms*
1070                     (acons node reasons *delayed-ir1-transforms*))
1071             (throw 'give-up-ir1-transform :delayed))
1072           ((cdr assoc)
1073             (dolist (reason reasons)
1074               (pushnew reason (cdr assoc)))
1075             (throw 'give-up-ir1-transform :delayed)))))
1076
1077 ;;; Clear any delayed transform with no reasons - these should have
1078 ;;; been tried in the last pass. Then remove the reason from the
1079 ;;; delayed transform reasons, and if any become empty then set
1080 ;;; reoptimize flags for the node. Return true if any transforms are
1081 ;;; to be retried.
1082 (defun retry-delayed-ir1-transforms (reason)
1083   (setf *delayed-ir1-transforms*
1084         (remove-if-not #'cdr *delayed-ir1-transforms*))
1085   (let ((reoptimize nil))
1086     (dolist (assoc *delayed-ir1-transforms*)
1087       (let ((reasons (remove reason (cdr assoc))))
1088         (setf (cdr assoc) reasons)
1089         (unless reasons
1090           (let ((node (car assoc)))
1091             (unless (node-deleted node)
1092               (setf reoptimize t)
1093               (setf (node-reoptimize node) t)
1094               (let ((block (node-block node)))
1095                 (setf (block-reoptimize block) t)
1096                 (setf (component-reoptimize (block-component block)) t)))))))
1097     reoptimize))
1098
1099 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1100 ;;; environment, and then install it as the function for the call
1101 ;;; NODE. We do local call analysis so that the new function is
1102 ;;; integrated into the control flow.
1103 ;;;
1104 ;;; We require the original function source name in order to generate
1105 ;;; a meaningful debug name for the lambda we set up. (It'd be
1106 ;;; possible to do this starting from debug names as well as source
1107 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1108 ;;; generality, since source names are always known to our callers.)
1109 (defun transform-call (node res source-name)
1110   (declare (type combination node) (list res))
1111   (aver (and (legal-fun-name-p source-name)
1112              (not (eql source-name '.anonymous.))))
1113   (with-ir1-environment-from-node node
1114       (let ((new-fun (ir1-convert-inline-lambda
1115                       res
1116                       :debug-name (debug-namify "LAMBDA-inlined ~A"
1117                                                 (as-debug-name
1118                                                  source-name
1119                                                  "<unknown function>"))))
1120             (ref (continuation-use (combination-fun node))))
1121         (change-ref-leaf ref new-fun)
1122         (setf (combination-kind node) :full)
1123         (locall-analyze-component *current-component*)))
1124   (values))
1125
1126 ;;; Replace a call to a foldable function of constant arguments with
1127 ;;; the result of evaluating the form. We insert the resulting
1128 ;;; constant node after the call, stealing the call's continuation. We
1129 ;;; give the call a continuation with no DEST, which should cause it
1130 ;;; and its arguments to go away. If there is an error during the
1131 ;;; evaluation, we give a warning and leave the call alone, making the
1132 ;;; call a :ERROR call.
1133 ;;;
1134 ;;; If there is more than one value, then we transform the call into a
1135 ;;; VALUES form.
1136 (defun constant-fold-call (call)
1137   (let ((args (mapcar #'continuation-value (combination-args call)))
1138         (fun-name (combination-fun-source-name call)))
1139     (multiple-value-bind (values win)
1140         (careful-call fun-name
1141                       args
1142                       call
1143                       ;; Note: CMU CL had COMPILER-WARN here, and that
1144                       ;; seems more natural, but it's probably not.
1145                       ;;
1146                       ;; It's especially not while bug 173 exists:
1147                       ;; Expressions like
1148                       ;;   (COND (END
1149                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1150                       ;;            ...))
1151                       ;; can cause constant-folding TYPE-ERRORs (in
1152                       ;; #'<=) when END can be proved to be NIL, even
1153                       ;; though the code is perfectly legal and safe
1154                       ;; because a NIL value of END means that the
1155                       ;; #'<= will never be executed.
1156                       ;;
1157                       ;; Moreover, even without bug 173,
1158                       ;; quite-possibly-valid code like
1159                       ;;   (COND ((NONINLINED-PREDICATE END)
1160                       ;;          (UNLESS (<= END SIZE))
1161                       ;;            ...))
1162                       ;; (where NONINLINED-PREDICATE is something the
1163                       ;; compiler can't do at compile time, but which
1164                       ;; turns out to make the #'<= expression
1165                       ;; unreachable when END=NIL) could cause errors
1166                       ;; when the compiler tries to constant-fold (<=
1167                       ;; END SIZE).
1168                       ;;
1169                       ;; So, with or without bug 173, it'd be
1170                       ;; unnecessarily evil to do a full
1171                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1172                       ;; from COMPILE-FILE) for legal code, so we we
1173                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1174                       #'compiler-style-warn
1175                       "constant folding")
1176       (if (not win)
1177           (setf (combination-kind call) :error)
1178           (let ((dummies (make-gensym-list (length args))))
1179             (transform-call
1180              call
1181              `(lambda ,dummies
1182                 (declare (ignore ,@dummies))
1183                 (values ,@(mapcar (lambda (x) `',x) values)))
1184              fun-name)))))
1185   (values))
1186 \f
1187 ;;;; local call optimization
1188
1189 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1190 ;;; the leaf type is a function type, then just leave it alone, since
1191 ;;; TYPE is never going to be more specific than that (and
1192 ;;; TYPE-INTERSECTION would choke.)
1193 (defun propagate-to-refs (leaf type)
1194   (declare (type leaf leaf) (type ctype type))
1195   (let ((var-type (leaf-type leaf)))
1196     (unless (fun-type-p var-type)
1197       (let ((int (type-approx-intersection2 var-type type)))
1198         (when (type/= int var-type)
1199           (setf (leaf-type leaf) int)
1200           (dolist (ref (leaf-refs leaf))
1201             (derive-node-type ref int))))
1202       (values))))
1203
1204 ;;; Figure out the type of a LET variable that has sets. We compute
1205 ;;; the union of the initial value Type and the types of all the set
1206 ;;; values and to a PROPAGATE-TO-REFS with this type.
1207 (defun propagate-from-sets (var type)
1208   (collect ((res type type-union))
1209     (dolist (set (basic-var-sets var))
1210       (res (continuation-type (set-value set)))
1211       (setf (node-reoptimize set) nil))
1212     (propagate-to-refs var (res)))
1213   (values))
1214
1215 ;;; If a LET variable, find the initial value's type and do
1216 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1217 ;;; type.
1218 (defun ir1-optimize-set (node)
1219   (declare (type cset node))
1220   (let ((var (set-var node)))
1221     (when (and (lambda-var-p var) (leaf-refs var))
1222       (let ((home (lambda-var-home var)))
1223         (when (eq (functional-kind home) :let)
1224           (let ((iv (let-var-initial-value var)))
1225             (setf (continuation-reoptimize iv) nil)
1226             (propagate-from-sets var (continuation-type iv)))))))
1227
1228   (derive-node-type node (continuation-type (set-value node)))
1229   (values))
1230
1231 ;;; Return true if the value of Ref will always be the same (and is
1232 ;;; thus legal to substitute.)
1233 (defun constant-reference-p (ref)
1234   (declare (type ref ref))
1235   (let ((leaf (ref-leaf ref)))
1236     (typecase leaf
1237       ((or constant functional) t)
1238       (lambda-var
1239        (null (lambda-var-sets leaf)))
1240       (defined-fun
1241        (not (eq (defined-fun-inlinep leaf) :notinline)))
1242       (global-var
1243        (case (global-var-kind leaf)
1244          (:global-function t))))))
1245
1246 ;;; If we have a non-set LET var with a single use, then (if possible)
1247 ;;; replace the variable reference's CONT with the arg continuation.
1248 ;;; This is inhibited when:
1249 ;;; -- CONT has other uses, or
1250 ;;; -- CONT receives multiple values, or
1251 ;;; -- the reference is in a different environment from the variable, or
1252 ;;; -- either continuation has a funky TYPE-CHECK annotation.
1253 ;;; -- the continuations have incompatible assertions, so the new asserted type
1254 ;;;    would be NIL.
1255 ;;; -- the var's DEST has a different policy than the ARG's (think safety).
1256 ;;;
1257 ;;; We change the REF to be a reference to NIL with unused value, and
1258 ;;; let it be flushed as dead code. A side effect of this substitution
1259 ;;; is to delete the variable.
1260 (defun substitute-single-use-continuation (arg var)
1261   (declare (type continuation arg) (type lambda-var var))
1262   (let* ((ref (first (leaf-refs var)))
1263          (cont (node-cont ref))
1264          (cont-atype (continuation-asserted-type cont))
1265          (dest (continuation-dest cont)))
1266     (when (and (eq (continuation-use cont) ref)
1267                dest
1268                (not (typep dest '(or creturn exit mv-combination)))
1269                (eq (node-home-lambda ref)
1270                    (lambda-home (lambda-var-home var)))
1271                (member (continuation-type-check arg) '(t nil))
1272                (member (continuation-type-check cont) '(t nil))
1273                (not (eq (values-type-intersection
1274                          cont-atype
1275                          (continuation-asserted-type arg))
1276                         *empty-type*))
1277                (eq (lexenv-policy (node-lexenv dest))
1278                    (lexenv-policy (node-lexenv (continuation-dest arg)))))
1279       (aver (member (continuation-kind arg)
1280                     '(:block-start :deleted-block-start :inside-block)))
1281       (assert-continuation-type arg cont-atype)
1282       (setf (node-derived-type ref) *wild-type*)
1283       (change-ref-leaf ref (find-constant nil))
1284       (substitute-continuation arg cont)
1285       (reoptimize-continuation arg)
1286       t)))
1287
1288 ;;; Delete a LET, removing the call and bind nodes, and warning about
1289 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1290 ;;; along right away and delete the REF and then the lambda, since we
1291 ;;; flush the FUN continuation.
1292 (defun delete-let (clambda)
1293   (declare (type clambda clambda))
1294   (aver (functional-letlike-p clambda))
1295   (note-unreferenced-vars clambda)
1296   (let ((call (let-combination clambda)))
1297     (flush-dest (basic-combination-fun call))
1298     (unlink-node call)
1299     (unlink-node (lambda-bind clambda))
1300     (setf (lambda-bind clambda) nil))
1301   (values))
1302
1303 ;;; This function is called when one of the arguments to a LET
1304 ;;; changes. We look at each changed argument. If the corresponding
1305 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1306 ;;; consider substituting for the variable, and also propagate
1307 ;;; derived-type information for the arg to all the VAR's refs.
1308 ;;;
1309 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1310 ;;; subtype of the argument's asserted type. This prevents type
1311 ;;; checking from being defeated, and also ensures that the best
1312 ;;; representation for the variable can be used.
1313 ;;;
1314 ;;; Substitution of individual references is inhibited if the
1315 ;;; reference is in a different component from the home. This can only
1316 ;;; happen with closures over top level lambda vars. In such cases,
1317 ;;; the references may have already been compiled, and thus can't be
1318 ;;; retroactively modified.
1319 ;;;
1320 ;;; If all of the variables are deleted (have no references) when we
1321 ;;; are done, then we delete the LET.
1322 ;;;
1323 ;;; Note that we are responsible for clearing the
1324 ;;; CONTINUATION-REOPTIMIZE flags.
1325 (defun propagate-let-args (call fun)
1326   (declare (type combination call) (type clambda fun))
1327   (loop for arg in (combination-args call)
1328         and var in (lambda-vars fun) do
1329     (when (and arg (continuation-reoptimize arg))
1330       (setf (continuation-reoptimize arg) nil)
1331       (cond
1332        ((lambda-var-sets var)
1333         (propagate-from-sets var (continuation-type arg)))
1334        ((let ((use (continuation-use arg)))
1335           (when (ref-p use)
1336             (let ((leaf (ref-leaf use)))
1337               (when (and (constant-reference-p use)
1338                          (values-subtypep (leaf-type leaf)
1339                                           (continuation-asserted-type arg)))
1340                 (propagate-to-refs var (continuation-type arg))
1341                 (let ((use-component (node-component use)))
1342                   (substitute-leaf-if
1343                    (lambda (ref)
1344                      (cond ((eq (node-component ref) use-component)
1345                             t)
1346                            (t
1347                             (aver (lambda-toplevelish-p (lambda-home fun)))
1348                             nil)))
1349                    leaf var))
1350                 t)))))
1351        ((and (null (rest (leaf-refs var)))
1352              (substitute-single-use-continuation arg var)))
1353        (t
1354         (propagate-to-refs var (continuation-type arg))))))
1355
1356   (when (every #'null (combination-args call))
1357     (delete-let fun))
1358
1359   (values))
1360
1361 ;;; This function is called when one of the args to a non-LET local
1362 ;;; call changes. For each changed argument corresponding to an unset
1363 ;;; variable, we compute the union of the types across all calls and
1364 ;;; propagate this type information to the var's refs.
1365 ;;;
1366 ;;; If the function has an XEP, then we don't do anything, since we
1367 ;;; won't discover anything.
1368 ;;;
1369 ;;; We can clear the Continuation-Reoptimize flags for arguments in
1370 ;;; all calls corresponding to changed arguments in Call, since the
1371 ;;; only use in IR1 optimization of the Reoptimize flag for local call
1372 ;;; args is right here.
1373 (defun propagate-local-call-args (call fun)
1374   (declare (type combination call) (type clambda fun))
1375
1376   (unless (or (functional-entry-fun fun)
1377               (lambda-optional-dispatch fun))
1378     (let* ((vars (lambda-vars fun))
1379            (union (mapcar (lambda (arg var)
1380                             (when (and arg
1381                                        (continuation-reoptimize arg)
1382                                        (null (basic-var-sets var)))
1383                               (continuation-type arg)))
1384                           (basic-combination-args call)
1385                           vars))
1386            (this-ref (continuation-use (basic-combination-fun call))))
1387
1388       (dolist (arg (basic-combination-args call))
1389         (when arg
1390           (setf (continuation-reoptimize arg) nil)))
1391
1392       (dolist (ref (leaf-refs fun))
1393         (let ((dest (continuation-dest (node-cont ref))))
1394           (unless (or (eq ref this-ref) (not dest))
1395             (setq union
1396                   (mapcar (lambda (this-arg old)
1397                             (when old
1398                               (setf (continuation-reoptimize this-arg) nil)
1399                               (type-union (continuation-type this-arg) old)))
1400                           (basic-combination-args dest)
1401                           union)))))
1402
1403       (mapc (lambda (var type)
1404               (when type
1405                 (propagate-to-refs var type)))
1406             vars union)))
1407
1408   (values))
1409 \f
1410 ;;;; multiple values optimization
1411
1412 ;;; Do stuff to notice a change to a MV combination node. There are
1413 ;;; two main branches here:
1414 ;;;  -- If the call is local, then it is already a MV let, or should
1415 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1416 ;;;     be converted to :MV-LETs, there can be a window when the call
1417 ;;;     is local, but has not been LET converted yet. This is because
1418 ;;;     the entry-point lambdas may have stray references (in other
1419 ;;;     entry points) that have not been deleted yet.
1420 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1421 ;;;     combination optimization: we propagate return type information and
1422 ;;;     notice non-returning calls. We also have an optimization
1423 ;;;     which tries to convert MV-CALLs into MV-binds.
1424 (defun ir1-optimize-mv-combination (node)
1425   (ecase (basic-combination-kind node)
1426     (:local
1427      (let ((fun-cont (basic-combination-fun node)))
1428        (when (continuation-reoptimize fun-cont)
1429          (setf (continuation-reoptimize fun-cont) nil)
1430          (maybe-let-convert (combination-lambda node))))
1431      (setf (continuation-reoptimize (first (basic-combination-args node))) nil)
1432      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1433        (unless (convert-mv-bind-to-let node)
1434          (ir1-optimize-mv-bind node))))
1435     (:full
1436      (let* ((fun (basic-combination-fun node))
1437             (fun-changed (continuation-reoptimize fun))
1438             (args (basic-combination-args node)))
1439        (when fun-changed
1440          (setf (continuation-reoptimize fun) nil)
1441          (let ((type (continuation-type fun)))
1442            (when (fun-type-p type)
1443              (derive-node-type node (fun-type-returns type))))
1444          (maybe-terminate-block node nil)
1445          (let ((use (continuation-use fun)))
1446            (when (and (ref-p use) (functional-p (ref-leaf use)))
1447              (convert-call-if-possible use node)
1448              (when (eq (basic-combination-kind node) :local)
1449                (maybe-let-convert (ref-leaf use))))))
1450        (unless (or (eq (basic-combination-kind node) :local)
1451                    (eq (continuation-fun-name fun) '%throw))
1452          (ir1-optimize-mv-call node))
1453        (dolist (arg args)
1454          (setf (continuation-reoptimize arg) nil))))
1455     (:error))
1456   (values))
1457
1458 ;;; Propagate derived type info from the values continuation to the
1459 ;;; vars.
1460 (defun ir1-optimize-mv-bind (node)
1461   (declare (type mv-combination node))
1462   (let ((arg (first (basic-combination-args node)))
1463         (vars (lambda-vars (combination-lambda node))))
1464     (multiple-value-bind (types nvals)
1465         (values-types (continuation-derived-type arg))
1466       (unless (eq nvals :unknown)
1467         (mapc (lambda (var type)
1468                 (if (basic-var-sets var)
1469                     (propagate-from-sets var type)
1470                     (propagate-to-refs var type)))
1471               vars
1472                 (append types
1473                         (make-list (max (- (length vars) nvals) 0)
1474                                    :initial-element (specifier-type 'null))))))
1475     (setf (continuation-reoptimize arg) nil))
1476   (values))
1477
1478 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1479 ;;; this if:
1480 ;;; -- The call has only one argument, and
1481 ;;; -- The function has a known fixed number of arguments, or
1482 ;;; -- The argument yields a known fixed number of values.
1483 ;;;
1484 ;;; What we do is change the function in the MV-CALL to be a lambda
1485 ;;; that "looks like an MV bind", which allows
1486 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1487 ;;; converted (the next time around.) This new lambda just calls the
1488 ;;; actual function with the MV-BIND variables as arguments. Note that
1489 ;;; this new MV bind is not let-converted immediately, as there are
1490 ;;; going to be stray references from the entry-point functions until
1491 ;;; they get deleted.
1492 ;;;
1493 ;;; In order to avoid loss of argument count checking, we only do the
1494 ;;; transformation according to a known number of expected argument if
1495 ;;; safety is unimportant. We can always convert if we know the number
1496 ;;; of actual values, since the normal call that we build will still
1497 ;;; do any appropriate argument count checking.
1498 ;;;
1499 ;;; We only attempt the transformation if the called function is a
1500 ;;; constant reference. This allows us to just splice the leaf into
1501 ;;; the new function, instead of trying to somehow bind the function
1502 ;;; expression. The leaf must be constant because we are evaluating it
1503 ;;; again in a different place. This also has the effect of squelching
1504 ;;; multiple warnings when there is an argument count error.
1505 (defun ir1-optimize-mv-call (node)
1506   (let ((fun (basic-combination-fun node))
1507         (*compiler-error-context* node)
1508         (ref (continuation-use (basic-combination-fun node)))
1509         (args (basic-combination-args node)))
1510
1511     (unless (and (ref-p ref) (constant-reference-p ref)
1512                  args (null (rest args)))
1513       (return-from ir1-optimize-mv-call))
1514
1515     (multiple-value-bind (min max)
1516         (fun-type-nargs (continuation-type fun))
1517       (let ((total-nvals
1518              (multiple-value-bind (types nvals)
1519                  (values-types (continuation-derived-type (first args)))
1520                (declare (ignore types))
1521                (if (eq nvals :unknown) nil nvals))))
1522
1523         (when total-nvals
1524           (when (and min (< total-nvals min))
1525             (compiler-warn
1526              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1527              at least ~R."
1528              total-nvals min)
1529             (setf (basic-combination-kind node) :error)
1530             (return-from ir1-optimize-mv-call))
1531           (when (and max (> total-nvals max))
1532             (compiler-warn
1533              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1534              at most ~R."
1535              total-nvals max)
1536             (setf (basic-combination-kind node) :error)
1537             (return-from ir1-optimize-mv-call)))
1538
1539         (let ((count (cond (total-nvals)
1540                            ((and (policy node (zerop safety))
1541                                  (eql min max))
1542                             min)
1543                            (t nil))))
1544           (when count
1545             (with-ir1-environment-from-node node
1546               (let* ((dums (make-gensym-list count))
1547                      (ignore (gensym))
1548                      (fun (ir1-convert-lambda
1549                            `(lambda (&optional ,@dums &rest ,ignore)
1550                               (declare (ignore ,ignore))
1551                               (funcall ,(ref-leaf ref) ,@dums)))))
1552                 (change-ref-leaf ref fun)
1553                 (aver (eq (basic-combination-kind node) :full))
1554                 (locall-analyze-component *current-component*)
1555                 (aver (eq (basic-combination-kind node) :local)))))))))
1556   (values))
1557
1558 ;;; If we see:
1559 ;;;    (multiple-value-bind
1560 ;;;     (x y)
1561 ;;;     (values xx yy)
1562 ;;;      ...)
1563 ;;; Convert to:
1564 ;;;    (let ((x xx)
1565 ;;;       (y yy))
1566 ;;;      ...)
1567 ;;;
1568 ;;; What we actually do is convert the VALUES combination into a
1569 ;;; normal LET combination calling the original :MV-LET lambda. If
1570 ;;; there are extra args to VALUES, discard the corresponding
1571 ;;; continuations. If there are insufficient args, insert references
1572 ;;; to NIL.
1573 (defun convert-mv-bind-to-let (call)
1574   (declare (type mv-combination call))
1575   (let* ((arg (first (basic-combination-args call)))
1576          (use (continuation-use arg)))
1577     (when (and (combination-p use)
1578                (eq (continuation-fun-name (combination-fun use))
1579                    'values))
1580       (let* ((fun (combination-lambda call))
1581              (vars (lambda-vars fun))
1582              (vals (combination-args use))
1583              (nvars (length vars))
1584              (nvals (length vals)))
1585         (cond ((> nvals nvars)
1586                (mapc #'flush-dest (subseq vals nvars))
1587                (setq vals (subseq vals 0 nvars)))
1588               ((< nvals nvars)
1589                (with-ir1-environment-from-node use
1590                  (let ((node-prev (node-prev use)))
1591                    (setf (node-prev use) nil)
1592                    (setf (continuation-next node-prev) nil)
1593                    (collect ((res vals))
1594                      (loop as cont = (make-continuation use)
1595                            and prev = node-prev then cont
1596                            repeat (- nvars nvals)
1597                            do (reference-constant prev cont nil)
1598                               (res cont))
1599                      (setq vals (res)))
1600                    (link-node-to-previous-continuation use
1601                                                        (car (last vals)))))))
1602         (setf (combination-args use) vals)
1603         (flush-dest (combination-fun use))
1604         (let ((fun-cont (basic-combination-fun call)))
1605           (setf (continuation-dest fun-cont) use)
1606           (setf (combination-fun use) fun-cont))
1607         (setf (combination-kind use) :local)
1608         (setf (functional-kind fun) :let)
1609         (flush-dest (first (basic-combination-args call)))
1610         (unlink-node call)
1611         (when vals
1612           (reoptimize-continuation (first vals)))
1613         (propagate-to-args use fun))
1614       t)))
1615
1616 ;;; If we see:
1617 ;;;    (values-list (list x y z))
1618 ;;;
1619 ;;; Convert to:
1620 ;;;    (values x y z)
1621 ;;;
1622 ;;; In implementation, this is somewhat similar to
1623 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1624 ;;; args of the VALUES-LIST call, flushing the old argument
1625 ;;; continuation (allowing the LIST to be flushed.)
1626 (defoptimizer (values-list optimizer) ((list) node)
1627   (let ((use (continuation-use list)))
1628     (when (and (combination-p use)
1629                (eq (continuation-fun-name (combination-fun use))
1630                    'list))
1631       (change-ref-leaf (continuation-use (combination-fun node))
1632                        (find-free-fun 'values "in a strange place"))
1633       (setf (combination-kind node) :full)
1634       (let ((args (combination-args use)))
1635         (dolist (arg args)
1636           (setf (continuation-dest arg) node))
1637         (setf (combination-args use) nil)
1638         (flush-dest list)
1639         (setf (combination-args node) args))
1640       t)))
1641
1642 ;;; If VALUES appears in a non-MV context, then effectively convert it
1643 ;;; to a PROG1. This allows the computation of the additional values
1644 ;;; to become dead code.
1645 (deftransform values ((&rest vals) * * :node node)
1646   (when (typep (continuation-dest (node-cont node))
1647                '(or creturn exit mv-combination))
1648     (give-up-ir1-transform))
1649   (setf (node-derived-type node) *wild-type*)
1650   (if vals
1651       (let ((dummies (make-gensym-list (length (cdr vals)))))
1652         `(lambda (val ,@dummies)
1653            (declare (ignore ,@dummies))
1654            val))
1655       nil))