src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for an LVAR whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-lvar-p (thing)
  24   (declare (type (or lvar null) thing))
  25   (and (lvar-p thing)
  26        (let ((use (principal-lvar-use thing)))
  27          (and (ref-p use) (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for an LVAR whose only use is a constant
  30 ;;; node.
  31 (declaim (ftype (function (lvar) t) lvar-value))
  32 (defun lvar-value (lvar)
  33   (let ((use (principal-lvar-use lvar)))
  34     (constant-value (ref-leaf use))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Our best guess for the type of this lvar's value. Note that this
  39 ;;; may be VALUES or FUNCTION type, which cannot be passed as an
  40 ;;; argument to the normal type operations. See LVAR-TYPE.
  41 ;;;
  42 ;;; The result value is cached in the LVAR-%DERIVED-TYPE slot. If the
  43 ;;; slot is true, just return that value, otherwise recompute and
  44 ;;; stash the value there.
  45 #!-sb-fluid (declaim (inline lvar-derived-type))
  46 (defun lvar-derived-type (lvar)
  47   (declare (type lvar lvar))
  48   (or (lvar-%derived-type lvar)
  49       (setf (lvar-%derived-type lvar)
  50             (%lvar-derived-type lvar))))
  51 (defun %lvar-derived-type (lvar)
  52   (declare (type lvar lvar))
  53   (let ((uses (lvar-uses lvar)))
  54     (cond ((null uses) *empty-type*)
  55           ((listp uses)
  56            (do ((res (node-derived-type (first uses))
  57                      (values-type-union (node-derived-type (first current))
  58                                         res))
  59                 (current (rest uses) (rest current)))
  60                ((null current) res)))
  61           (t
  62            (node-derived-type (lvar-uses lvar))))))
  63
  64 ;;; Return the derived type for LVAR's first value. This is guaranteed
  65 ;;; not to be a VALUES or FUNCTION type.
  66 (declaim (ftype (sfunction (lvar) ctype) lvar-type))
  67 (defun lvar-type (lvar)
  68   (single-value-type (lvar-derived-type lvar)))
  69
  70 ;;; If LVAR is an argument of a function, return a type which the
  71 ;;; function checks LVAR for.
  72 #!-sb-fluid (declaim (inline lvar-externally-checkable-type))
  73 (defun lvar-externally-checkable-type (lvar)
  74   (or (lvar-%externally-checkable-type lvar)
  75       (%lvar-%externally-checkable-type lvar)))
  76 (defun %lvar-%externally-checkable-type (lvar)
  77   (declare (type lvar lvar))
  78   (let ((dest (lvar-dest lvar)))
  79     (if (not (and dest (combination-p dest)))
  80         ;; TODO: MV-COMBINATION
  81         (setf (lvar-%externally-checkable-type lvar) *wild-type*)
  82         (let* ((fun (combination-fun dest))
  83                (args (combination-args dest))
  84                (fun-type (lvar-type fun)))
  85           (setf (lvar-%externally-checkable-type fun) *wild-type*)
  86           (if (or (not (call-full-like-p dest))
  87                   (not (fun-type-p fun-type))
  88                   ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
  89                   (fun-type-wild-args fun-type))
  90               (dolist (arg args)
  91                 (when arg
  92                   (setf (lvar-%externally-checkable-type arg)
  93                         *wild-type*)))
  94               (map-combination-args-and-types
  95                (lambda (arg type)
  96                  (setf (lvar-%externally-checkable-type arg)
  97                        (acond ((lvar-%externally-checkable-type arg)
  98                                (values-type-intersection
  99                                 it (coerce-to-values type)))
 100                               (t (coerce-to-values type)))))
 101                dest)))))
 102   (lvar-%externally-checkable-type lvar))
 103 #!-sb-fluid(declaim (inline flush-lvar-externally-checkable-type))
 104 (defun flush-lvar-externally-checkable-type (lvar)
 105   (declare (type lvar lvar))
 106   (setf (lvar-%externally-checkable-type lvar) nil))
 107 \f
 108 ;;;; interface routines used by optimizers
 109
 110 ;;; This function is called by optimizers to indicate that something
 111 ;;; interesting has happened to the value of LVAR. Optimizers must
 112 ;;; make sure that they don't call for reoptimization when nothing has
 113 ;;; happened, since optimization will fail to terminate.
 114 ;;;
 115 ;;; We clear any cached type for the lvar and set the reoptimize flags
 116 ;;; on everything in sight.
 117 (defun reoptimize-lvar (lvar)
 118   (declare (type (or lvar null) lvar))
 119   (when lvar
 120     (setf (lvar-%derived-type lvar) nil)
 121     (let ((dest (lvar-dest lvar)))
 122       (when dest
 123         (setf (lvar-reoptimize lvar) t)
 124         (setf (node-reoptimize dest) t)
 125         (binding* (;; Since this may be called during IR1 conversion,
 126                    ;; PREV may be missing.
 127                    (prev (node-prev dest) :exit-if-null)
 128                    (block (ctran-block prev))
 129                    (component (block-component block)))
 130           (when (typep dest 'cif)
 131             (setf (block-test-modified block) t))
 132           (setf (block-reoptimize block) t)
 133           (setf (component-reoptimize component) t))))
 134     (do-uses (node lvar)
 135       (setf (block-type-check (node-block node)) t)))
 136   (values))
 137
 138 (defun reoptimize-lvar-uses (lvar)
 139   (declare (type lvar lvar))
 140   (do-uses (use lvar)
 141     (setf (node-reoptimize use) t)
 142     (setf (block-reoptimize (node-block use)) t)
 143     (setf (component-reoptimize (node-component use)) t)))
 144
 145 ;;; Annotate NODE to indicate that its result has been proven to be
 146 ;;; TYPEP to RTYPE. After IR1 conversion has happened, this is the
 147 ;;; only correct way to supply information discovered about a node's
 148 ;;; type. If you screw with the NODE-DERIVED-TYPE directly, then
 149 ;;; information may be lost and reoptimization may not happen.
 150 ;;;
 151 ;;; What we do is intersect RTYPE with NODE's DERIVED-TYPE. If the
 152 ;;; intersection is different from the old type, then we do a
 153 ;;; REOPTIMIZE-LVAR on the NODE-LVAR.
 154 (defun derive-node-type (node rtype)
 155   (declare (type valued-node node) (type ctype rtype))
 156   (let ((node-type (node-derived-type node)))
 157     (unless (eq node-type rtype)
 158       (let ((int (values-type-intersection node-type rtype))
 159             (lvar (node-lvar node)))
 160         (when (type/= node-type int)
 161           (when (and *check-consistency*
 162                      (eq int *empty-type*)
 163                      (not (eq rtype *empty-type*)))
 164             (let ((*compiler-error-context* node))
 165               (compiler-warn
 166                "New inferred type ~S conflicts with old type:~
 167                 ~%  ~S~%*** possible internal error? Please report this."
 168                (type-specifier rtype) (type-specifier node-type))))
 169           (setf (node-derived-type node) int)
 170           ;; If the new type consists of only one object, replace the
 171           ;; node with a constant reference.
 172           (when (and (ref-p node)
 173                      (lambda-var-p (ref-leaf node)))
 174             (let ((type (single-value-type int)))
 175               (when (and (member-type-p type)
 176                          (null (rest (member-type-members type))))
 177                 (change-ref-leaf node (find-constant
 178                                        (first (member-type-members type)))))))
 179           (reoptimize-lvar lvar)))))
 180   (values))
 181
 182 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 183 ;;; error for LVAR's value not to be TYPEP to TYPE. We implement it
 184 ;;; splitting off DEST a new CAST node; old LVAR will deliver values
 185 ;;; to CAST. If we improve the assertion, we set TYPE-CHECK and
 186 ;;; TYPE-ASSERTED to guarantee that the new assertion will be checked.
 187 (defun assert-lvar-type (lvar type policy)
 188   (declare (type lvar lvar) (type ctype type))
 189   (unless (values-subtypep (lvar-derived-type lvar) type)
 190     (let* ((dest (lvar-dest lvar))
 191            (ctran (node-prev dest)))
 192       (with-ir1-environment-from-node dest
 193         (let* ((cast (make-cast lvar type policy))
 194                (internal-lvar (make-lvar))
 195                (internal-ctran (make-ctran)))
 196           (setf (ctran-next ctran) cast
 197                 (node-prev cast) ctran)
 198           (use-continuation cast internal-ctran internal-lvar)
 199           (link-node-to-previous-ctran dest internal-ctran)
 200           (substitute-lvar internal-lvar lvar)
 201           (setf (lvar-dest lvar) cast)
 202           (reoptimize-lvar lvar)
 203           (when (return-p dest)
 204             (node-ends-block cast))
 205           (setf (block-attributep (block-flags (node-block cast))
 206                                   type-check type-asserted)
 207                 t))))))
 208
 209 \f
 210 ;;;; IR1-OPTIMIZE
 211
 212 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 213 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 214 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 215 ;;; we are done, then another iteration would be beneficial.
 216 (defun ir1-optimize (component)
 217   (declare (type component component))
 218   (setf (component-reoptimize component) nil)
 219   (loop with block = (block-next (component-head component))
 220         with tail = (component-tail component)
 221         for last-block = block
 222         until (eq block tail)
 223         do (cond
 224              ;; We delete blocks when there is either no predecessor or the
 225              ;; block is in a lambda that has been deleted. These blocks
 226              ;; would eventually be deleted by DFO recomputation, but doing
 227              ;; it here immediately makes the effect available to IR1
 228              ;; optimization.
 229              ((or (block-delete-p block)
 230                   (null (block-pred block)))
 231               (delete-block-lazily block)
 232               (setq block (clean-component component block)))
 233              ((eq (functional-kind (block-home-lambda block)) :deleted)
 234               ;; Preserve the BLOCK-SUCC invariant that almost every block has
 235               ;; one successor (and a block with DELETE-P set is an acceptable
 236               ;; exception).
 237               (mark-for-deletion block)
 238               (setq block (clean-component component block)))
 239              (t
 240               (loop
 241                  (let ((succ (block-succ block)))
 242                    (unless (singleton-p succ)
 243                      (return)))
 244
 245                  (let ((last (block-last block)))
 246                    (typecase last
 247                      (cif
 248                       (flush-dest (if-test last))
 249                       (when (unlink-node last)
 250                         (return)))
 251                      (exit
 252                       (when (maybe-delete-exit last)
 253                         (return)))))
 254
 255                  (unless (join-successor-if-possible block)
 256                    (return)))
 257
 258               (when (and (block-reoptimize block) (block-component block))
 259                 (aver (not (block-delete-p block)))
 260                 (ir1-optimize-block block))
 261
 262               (cond ((and (block-delete-p block) (block-component block))
 263                      (setq block (clean-component component block)))
 264                     ((and (block-flush-p block) (block-component block))
 265                      (flush-dead-code block)))))
 266         do (when (eq block last-block)
 267              (setq block (block-next block))))
 268
 269   (values))
 270
 271 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 272 ;;; flags.
 273 ;;;
 274 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 275 ;;; still be set upon return from this function, meaning that further
 276 ;;; optimization is wanted (as a consequence of optimizations we did).
 277 (defun ir1-optimize-block (block)
 278   (declare (type cblock block))
 279   ;; We clear the node and block REOPTIMIZE flags before doing the
 280   ;; optimization, not after. This ensures that the node or block will
 281   ;; be reoptimized if necessary.
 282   (setf (block-reoptimize block) nil)
 283   (do-nodes (node nil block :restart-p t)
 284     (when (node-reoptimize node)
 285       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 286       (setf (node-reoptimize node) nil)
 287       (typecase node
 288         (ref)
 289         (combination
 290          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 291          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 292          ;; any argument changes.
 293          (ir1-optimize-combination node))
 294         (cif
 295          (ir1-optimize-if node))
 296         (creturn
 297          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 298          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 299          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 300          ;; CMU CL comments
 301          (setf (node-reoptimize node) t)
 302          (ir1-optimize-return node))
 303         (mv-combination
 304          (ir1-optimize-mv-combination node))
 305         (exit
 306          ;; With an EXIT, we derive the node's type from the VALUE's
 307          ;; type.
 308          (let ((value (exit-value node)))
 309            (when value
 310              (derive-node-type node (lvar-derived-type value)))))
 311         (cset
 312          (ir1-optimize-set node))
 313         (cast
 314          (ir1-optimize-cast node)))))
 315
 316   (values))
 317
 318 ;;; Try to join with a successor block. If we succeed, we return true,
 319 ;;; otherwise false.
 320 (defun join-successor-if-possible (block)
 321   (declare (type cblock block))
 322   (let ((next (first (block-succ block))))
 323     (when (block-start next)  ; NEXT is not an END-OF-COMPONENT marker
 324       (cond ( ;; We cannot combine with a successor block if:
 325              (or
 326               ;; the successor has more than one predecessor;
 327               (rest (block-pred next))
 328               ;; the successor is the current block (infinite loop);
 329               (eq next block)
 330               ;; the next block has a different cleanup, and thus
 331               ;; we may want to insert cleanup code between the
 332               ;; two blocks at some point;
 333               (not (eq (block-end-cleanup block)
 334                        (block-start-cleanup next)))
 335               ;; the next block has a different home lambda, and
 336               ;; thus the control transfer is a non-local exit.
 337               (not (eq (block-home-lambda block)
 338                        (block-home-lambda next)))
 339               ;; Stack analysis phase wants ENTRY to start a block...
 340               (entry-p (block-start-node next))
 341               (let ((last (block-last block)))
 342                 (and (valued-node-p last)
 343                      (awhen (node-lvar last)
 344                        (or
 345                         ;; ... and a DX-allocator to end a block.
 346                         (lvar-dynamic-extent it)
 347                         ;; FIXME: This is a partial workaround for bug 303.
 348                         (consp (lvar-uses it)))))))
 349              nil)
 350             (t
 351              (join-blocks block next)
 352              t)))))
 353
 354 ;;; Join together two blocks. The code in BLOCK2 is moved into BLOCK1
 355 ;;; and BLOCK2 is deleted from the DFO. We combine the optimize flags
 356 ;;; for the two blocks so that any indicated optimization gets done.
 357 (defun join-blocks (block1 block2)
 358   (declare (type cblock block1 block2))
 359   (let* ((last1 (block-last block1))
 360          (last2 (block-last block2))
 361          (succ (block-succ block2))
 362          (start2 (block-start block2)))
 363     (do ((ctran start2 (node-next (ctran-next ctran))))
 364         ((not ctran))
 365       (setf (ctran-block ctran) block1))
 366
 367     (unlink-blocks block1 block2)
 368     (dolist (block succ)
 369       (unlink-blocks block2 block)
 370       (link-blocks block1 block))
 371
 372     (setf (ctran-kind start2) :inside-block)
 373     (setf (node-next last1) start2)
 374     (setf (ctran-use start2) last1)
 375     (setf (block-last block1) last2))
 376
 377   (setf (block-flags block1)
 378         (attributes-union (block-flags block1)
 379                           (block-flags block2)
 380                           (block-attributes type-asserted test-modified)))
 381
 382   (let ((next (block-next block2))
 383         (prev (block-prev block2)))
 384     (setf (block-next prev) next)
 385     (setf (block-prev next) prev))
 386
 387   (values))
 388
 389 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 390 ;;; side effects. We can delete sets of lexical variables when the set
 391 ;;; variable has no references.
 392 (defun flush-dead-code (block)
 393   (declare (type cblock block))
 394   (setf (block-flush-p block) nil)
 395   (do-nodes-backwards (node lvar block :restart-p t)
 396     (unless lvar
 397       (typecase node
 398         (ref
 399          (delete-ref node)
 400          (unlink-node node))
 401         (combination
 402          (let ((kind (combination-kind node))
 403                (info (combination-fun-info node)))
 404            (when (and (eq kind :known) (fun-info-p info))
 405              (let ((attr (fun-info-attributes info)))
 406                (when (and (not (ir1-attributep attr call))
 407                           ;; ### For now, don't delete potentially
 408                           ;; flushable calls when they have the CALL
 409                           ;; attribute. Someday we should look at the
 410                           ;; functional args to determine if they have
 411                           ;; any side effects.
 412                           (if (policy node (= safety 3))
 413                               (ir1-attributep attr flushable)
 414                               (ir1-attributep attr unsafely-flushable)))
 415                  (flush-combination node))))))
 416         (mv-combination
 417          (when (eq (basic-combination-kind node) :local)
 418            (let ((fun (combination-lambda node)))
 419              (when (dolist (var (lambda-vars fun) t)
 420                      (when (or (leaf-refs var)
 421                                (lambda-var-sets var))
 422                        (return nil)))
 423                (flush-dest (first (basic-combination-args node)))
 424                (delete-let fun)))))
 425         (exit
 426          (let ((value (exit-value node)))
 427            (when value
 428              (flush-dest value)
 429              (setf (exit-value node) nil))))
 430         (cset
 431          (let ((var (set-var node)))
 432            (when (and (lambda-var-p var)
 433                       (null (leaf-refs var)))
 434              (flush-dest (set-value node))
 435              (setf (basic-var-sets var)
 436                    (delq node (basic-var-sets var)))
 437              (unlink-node node))))
 438         (cast
 439          (unless (cast-type-check node)
 440            (flush-dest (cast-value node))
 441            (unlink-node node))))))
 442
 443   (values))
 444 \f
 445 ;;;; local call return type propagation
 446
 447 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 448 ;;; flag set. It iterates over the uses of the RESULT, looking for
 449 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 450 ;;; call, then we union its type together with the types of other such
 451 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 452 ;;; type with the RESULT's asserted type. We can make this
 453 ;;; intersection now (potentially before type checking) because this
 454 ;;; assertion on the result will eventually be checked (if
 455 ;;; appropriate.)
 456 ;;;
 457 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 458 ;;; combination, which may change the succesor of the call to be the
 459 ;;; called function, and if so, checks if the call can become an
 460 ;;; assignment. If we convert to an assignment, we abort, since the
 461 ;;; RETURN has been deleted.
 462 (defun find-result-type (node)
 463   (declare (type creturn node))
 464   (let ((result (return-result node)))
 465     (collect ((use-union *empty-type* values-type-union))
 466       (do-uses (use result)
 467         (let ((use-home (node-home-lambda use)))
 468           (cond ((or (eq (functional-kind use-home) :deleted)
 469                      (block-delete-p (node-block use))))
 470                 ((and (basic-combination-p use)
 471                       (eq (basic-combination-kind use) :local))
 472                  (aver (eq (lambda-tail-set use-home)
 473                            (lambda-tail-set (combination-lambda use))))
 474                  (when (combination-p use)
 475                    (when (nth-value 1 (maybe-convert-tail-local-call use))
 476                      (return-from find-result-type t))))
 477                 (t
 478                  (use-union (node-derived-type use))))))
 479       (let ((int
 480              ;; (values-type-intersection
 481              ;; (continuation-asserted-type result) ; FIXME -- APD, 2002-01-26
 482              (use-union)
 483               ;; )
 484               ))
 485         (setf (return-result-type node) int))))
 486   nil)
 487
 488 ;;; Do stuff to realize that something has changed about the value
 489 ;;; delivered to a return node. Since we consider the return values of
 490 ;;; all functions in the tail set to be equivalent, this amounts to
 491 ;;; bringing the entire tail set up to date. We iterate over the
 492 ;;; returns for all the functions in the tail set, reanalyzing them
 493 ;;; all (not treating NODE specially.)
 494 ;;;
 495 ;;; When we are done, we check whether the new type is different from
 496 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 497 ;;; all the lvars for references to functions in the tail set. This
 498 ;;; will cause IR1-OPTIMIZE-COMBINATION to derive the new type as the
 499 ;;; results of the calls.
 500 (defun ir1-optimize-return (node)
 501   (declare (type creturn node))
 502   (tagbody
 503    :restart
 504      (let* ((tails (lambda-tail-set (return-lambda node)))
 505             (funs (tail-set-funs tails)))
 506        (collect ((res *empty-type* values-type-union))
 507                 (dolist (fun funs)
 508                   (let ((return (lambda-return fun)))
 509                     (when return
 510                       (when (node-reoptimize return)
 511                         (setf (node-reoptimize return) nil)
 512                         (when (find-result-type return)
 513                           (go :restart)))
 514                       (res (return-result-type return)))))
 515
 516                 (when (type/= (res) (tail-set-type tails))
 517                   (setf (tail-set-type tails) (res))
 518                   (dolist (fun (tail-set-funs tails))
 519                     (dolist (ref (leaf-refs fun))
 520                       (reoptimize-lvar (node-lvar ref))))))))
 521
 522   (values))
 523 \f
 524 ;;;; IF optimization
 525
 526 ;;; If the test has multiple uses, replicate the node when possible.
 527 ;;; Also check whether the predicate is known to be true or false,
 528 ;;; deleting the IF node in favor of the appropriate branch when this
 529 ;;; is the case.
 530 (defun ir1-optimize-if (node)
 531   (declare (type cif node))
 532   (let ((test (if-test node))
 533         (block (node-block node)))
 534
 535     (when (and (eq (block-start-node block) node)
 536                (listp (lvar-uses test)))
 537       (do-uses (use test)
 538         (when (immediately-used-p test use)
 539           (convert-if-if use node)
 540           (when (not (listp (lvar-uses test))) (return)))))
 541
 542     (let* ((type (lvar-type test))
 543            (victim
 544             (cond ((constant-lvar-p test)
 545                    (if (lvar-value test)
 546                        (if-alternative node)
 547                        (if-consequent node)))
 548                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 549                    (if-alternative node))
 550                   ((type= type (specifier-type 'null))
 551                    (if-consequent node)))))
 552       (when victim
 553         (flush-dest test)
 554         (when (rest (block-succ block))
 555           (unlink-blocks block victim))
 556         (setf (component-reanalyze (node-component node)) t)
 557         (unlink-node node))))
 558   (values))
 559
 560 ;;; Create a new copy of an IF node that tests the value of the node
 561 ;;; USE. The test must have >1 use, and must be immediately used by
 562 ;;; USE. NODE must be the only node in its block (implying that
 563 ;;; block-start = if-test).
 564 ;;;
 565 ;;; This optimization has an effect semantically similar to the
 566 ;;; source-to-source transformation:
 567 ;;;    (IF (IF A B C) D E) ==>
 568 ;;;    (IF A (IF B D E) (IF C D E))
 569 ;;;
 570 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 571 ;;; node so that dead code deletion notes will definitely not consider
 572 ;;; either node to be part of the original source. One node might
 573 ;;; become unreachable, resulting in a spurious note.
 574 (defun convert-if-if (use node)
 575   (declare (type node use) (type cif node))
 576   (with-ir1-environment-from-node node
 577     (let* ((block (node-block node))
 578            (test (if-test node))
 579            (cblock (if-consequent node))
 580            (ablock (if-alternative node))
 581            (use-block (node-block use))
 582            (new-ctran (make-ctran))
 583            (new-lvar (make-lvar))
 584            (new-node (make-if :test new-lvar
 585                               :consequent cblock
 586                               :alternative ablock))
 587            (new-block (ctran-starts-block new-ctran)))
 588       (link-node-to-previous-ctran new-node new-ctran)
 589       (setf (lvar-dest new-lvar) new-node)
 590       (setf (block-last new-block) new-node)
 591
 592       (unlink-blocks use-block block)
 593       (%delete-lvar-use use)
 594       (add-lvar-use use new-lvar)
 595       (link-blocks use-block new-block)
 596
 597       (link-blocks new-block cblock)
 598       (link-blocks new-block ablock)
 599
 600       (push "<IF Duplication>" (node-source-path node))
 601       (push "<IF Duplication>" (node-source-path new-node))
 602
 603       (reoptimize-lvar test)
 604       (reoptimize-lvar new-lvar)
 605       (setf (component-reanalyze *current-component*) t)))
 606   (values))
 607 \f
 608 ;;;; exit IR1 optimization
 609
 610 ;;; This function attempts to delete an exit node, returning true if
 611 ;;; it deletes the block as a consequence:
 612 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 613 ;;;    anything, since there is nothing to be done.
 614 ;;; -- If the exit node and its ENTRY have the same home lambda then
 615 ;;;    we know the exit is local, and can delete the exit. We change
 616 ;;;    uses of the Exit-Value to be uses of the original lvar,
 617 ;;;    then unlink the node. If the exit is to a TR context, then we
 618 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 619 ;;;    their value to this exit.
 620 ;;; -- If there is no value (as in a GO), then we skip the value
 621 ;;;    semantics.
 622 ;;;
 623 ;;; This function is also called by environment analysis, since it
 624 ;;; wants all exits to be optimized even if normal optimization was
 625 ;;; omitted.
 626 (defun maybe-delete-exit (node)
 627   (declare (type exit node))
 628   (let ((value (exit-value node))
 629         (entry (exit-entry node)))
 630     (when (and entry
 631                (eq (node-home-lambda node) (node-home-lambda entry)))
 632       (setf (entry-exits entry) (delq node (entry-exits entry)))
 633       (if value
 634           (delete-filter node (node-lvar node) value)
 635           (unlink-node node)))))
 636
 637 \f
 638 ;;;; combination IR1 optimization
 639
 640 ;;; Report as we try each transform?
 641 #!+sb-show
 642 (defvar *show-transforms-p* nil)
 643
 644 ;;; Do IR1 optimizations on a COMBINATION node.
 645 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 646 (defun ir1-optimize-combination (node)
 647   (when (lvar-reoptimize (basic-combination-fun node))
 648     (propagate-fun-change node)
 649     (maybe-terminate-block node nil))
 650   (let ((args (basic-combination-args node))
 651         (kind (basic-combination-kind node))
 652         (info (basic-combination-fun-info node)))
 653     (ecase kind
 654       (:local
 655        (let ((fun (combination-lambda node)))
 656          (if (eq (functional-kind fun) :let)
 657              (propagate-let-args node fun)
 658              (propagate-local-call-args node fun))))
 659       (:error
 660        (dolist (arg args)
 661          (when arg
 662            (setf (lvar-reoptimize arg) nil))))
 663       (:full
 664        (dolist (arg args)
 665          (when arg
 666            (setf (lvar-reoptimize arg) nil)))
 667        (when info
 668          (let ((fun (fun-info-derive-type info)))
 669            (when fun
 670              (let ((res (funcall fun node)))
 671                (when res
 672                  (derive-node-type node (coerce-to-values res))
 673                  (maybe-terminate-block node nil)))))))
 674       (:known
 675        (aver info)
 676        (dolist (arg args)
 677          (when arg
 678            (setf (lvar-reoptimize arg) nil)))
 679
 680        (let ((attr (fun-info-attributes info)))
 681          (when (and (ir1-attributep attr foldable)
 682                     ;; KLUDGE: The next test could be made more sensitive,
 683                     ;; only suppressing constant-folding of functions with
 684                     ;; CALL attributes when they're actually passed
 685                     ;; function arguments. -- WHN 19990918
 686                     (not (ir1-attributep attr call))
 687                     (every #'constant-lvar-p args)
 688                     (node-lvar node)
 689                     ;; Even if the function is foldable in principle,
 690                     ;; it might be one of our low-level
 691                     ;; implementation-specific functions. Such
 692                     ;; functions don't necessarily exist at runtime on
 693                     ;; a plain vanilla ANSI Common Lisp
 694                     ;; cross-compilation host, in which case the
 695                     ;; cross-compiler can't fold it because the
 696                     ;; cross-compiler doesn't know how to evaluate it.
 697                     #+sb-xc-host
 698                     (or (fboundp (combination-fun-source-name node))
 699                         (progn (format t ";;; !!! Unbound fun: (~S~{ ~S~})~%"
 700                                        (combination-fun-source-name node)
 701                                        (mapcar #'lvar-value args))
 702                                nil)))
 703            (constant-fold-call node)
 704            (return-from ir1-optimize-combination)))
 705
 706        (let ((fun (fun-info-derive-type info)))
 707          (when fun
 708            (let ((res (funcall fun node)))
 709              (when res
 710                (derive-node-type node (coerce-to-values res))
 711                (maybe-terminate-block node nil)))))
 712
 713        (let ((fun (fun-info-optimizer info)))
 714          (unless (and fun (funcall fun node))
 715            (dolist (x (fun-info-transforms info))
 716              #!+sb-show
 717              (when *show-transforms-p*
 718                (let* ((lvar (basic-combination-fun node))
 719                       (fname (lvar-fun-name lvar t)))
 720                  (/show "trying transform" x (transform-function x) "for" fname)))
 721              (unless (ir1-transform node x)
 722                #!+sb-show
 723                (when *show-transforms-p*
 724                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 725                (return))))))))
 726
 727   (values))
 728
 729 ;;; If NODE doesn't return (i.e. return type is NIL), then terminate
 730 ;;; the block there, and link it to the component tail.
 731 ;;;
 732 ;;; Except when called during IR1 convertion, we delete the
 733 ;;; continuation if it has no other uses. (If it does have other uses,
 734 ;;; we reoptimize.)
 735 ;;;
 736 ;;; Termination on the basis of a continuation type is
 737 ;;; inhibited when:
 738 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 739 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 740 ;;;    weakening.) FIXME: Now THE assertions are not weakened, but new
 741 ;;;    uses can(?) be added later. -- APD, 2003-07-17
 742 ;;;
 743 ;;; Why do we need to consider LVAR type? -- APD, 2003-07-30
 744 (defun maybe-terminate-block (node ir1-converting-not-optimizing-p)
 745   (declare (type (or basic-combination cast) node))
 746   (let* ((block (node-block node))
 747          (lvar (node-lvar node))
 748          (ctran (node-next node))
 749          (tail (component-tail (block-component block)))
 750          (succ (first (block-succ block))))
 751     (declare (ignore lvar))
 752     (unless (or (and (eq node (block-last block)) (eq succ tail))
 753                 (block-delete-p block))
 754       (when (eq (node-derived-type node) *empty-type*)
 755         (cond (ir1-converting-not-optimizing-p
 756                (cond
 757                  ((block-last block)
 758                   (aver (eq (block-last block) node)))
 759                  (t
 760                   (setf (block-last block) node)
 761                   (setf (ctran-use ctran) nil)
 762                   (setf (ctran-kind ctran) :unused)
 763                   (setf (ctran-block ctran) nil)
 764                   (setf (node-next node) nil)
 765                   (link-blocks block (ctran-starts-block ctran)))))
 766               (t
 767                (node-ends-block node)))
 768
 769         (unlink-blocks block (first (block-succ block)))
 770         (setf (component-reanalyze (block-component block)) t)
 771         (aver (not (block-succ block)))
 772         (link-blocks block tail)
 773         (if ir1-converting-not-optimizing-p
 774             (%delete-lvar-use node)
 775             (delete-lvar-use node))
 776         t))))
 777
 778 ;;; This is called both by IR1 conversion and IR1 optimization when
 779 ;;; they have verified the type signature for the call, and are
 780 ;;; wondering if something should be done to special-case the call. If
 781 ;;; CALL is a call to a global function, then see whether it defined
 782 ;;; or known:
 783 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 784 ;;;    the expansion and change the call to call it. Expansion is
 785 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 786 ;;;    true, we never expand, since this function has already been
 787 ;;;    converted. Local call analysis will duplicate the definition
 788 ;;;    if necessary. We claim that the parent form is LABELS for
 789 ;;;    context declarations, since we don't want it to be considered
 790 ;;;    a real global function.
 791 ;;; -- If it is a known function, mark it as such by setting the KIND.
 792 ;;;
 793 ;;; We return the leaf referenced (NIL if not a leaf) and the
 794 ;;; FUN-INFO assigned.
 795 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 796   (declare (type combination call))
 797   (let* ((ref (lvar-uses (basic-combination-fun call)))
 798          (leaf (when (ref-p ref) (ref-leaf ref)))
 799          (inlinep (if (defined-fun-p leaf)
 800                       (defined-fun-inlinep leaf)
 801                       :no-chance)))
 802     (cond
 803      ((eq inlinep :notinline)
 804       (let ((info (info :function :info (leaf-source-name leaf))))
 805         (when info
 806           (setf (basic-combination-fun-info call) info))
 807         (values nil nil)))
 808      ((not (and (global-var-p leaf)
 809                 (eq (global-var-kind leaf) :global-function)))
 810       (values leaf nil))
 811      ((and (ecase inlinep
 812              (:inline t)
 813              (:no-chance nil)
 814              ((nil :maybe-inline) (policy call (zerop space))))
 815            (defined-fun-p leaf)
 816            (defined-fun-inline-expansion leaf)
 817            (let ((fun (defined-fun-functional leaf)))
 818              (or (not fun)
 819                  (and (eq inlinep :inline) (functional-kind fun))))
 820            (inline-expansion-ok call))
 821       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 822              ;; called semi-inlining? A more descriptive name would
 823              ;; be nice. -- WHN 2002-01-07
 824              (frob ()
 825                (let ((res (let ((*allow-instrumenting* t))
 826                             (ir1-convert-lambda-for-defun
 827                              (defined-fun-inline-expansion leaf)
 828                              leaf t
 829                              #'ir1-convert-inline-lambda))))
 830                  (setf (defined-fun-functional leaf) res)
 831                  (change-ref-leaf ref res))))
 832         (if ir1-converting-not-optimizing-p
 833             (frob)
 834             (with-ir1-environment-from-node call
 835               (frob)
 836               (locall-analyze-component *current-component*))))
 837
 838       (values (ref-leaf (lvar-uses (basic-combination-fun call)))
 839               nil))
 840      (t
 841       (let ((info (info :function :info (leaf-source-name leaf))))
 842         (if info
 843             (values leaf
 844                     (progn
 845                       (setf (basic-combination-kind call) :known)
 846                       (setf (basic-combination-fun-info call) info)))
 847             (values leaf nil)))))))
 848
 849 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 850 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 851 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 852 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 853 ;;; syntax check, arg/result type processing, but still call
 854 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 855 ;;; and that checking is done by local call analysis.
 856 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 857   (declare (type combination call) (type ctype type))
 858   (cond ((not (fun-type-p type))
 859          (aver (multiple-value-bind (val win)
 860                    (csubtypep type (specifier-type 'function))
 861                  (or val (not win))))
 862          (recognize-known-call call ir1-converting-not-optimizing-p))
 863         ((valid-fun-use call type
 864                         :argument-test #'always-subtypep
 865                         :result-test nil
 866                         ;; KLUDGE: Common Lisp is such a dynamic
 867                         ;; language that all we can do here in
 868                         ;; general is issue a STYLE-WARNING. It
 869                         ;; would be nice to issue a full WARNING
 870                         ;; in the special case of of type
 871                         ;; mismatches within a compilation unit
 872                         ;; (as in section 3.2.2.3 of the spec)
 873                         ;; but at least as of sbcl-0.6.11, we
 874                         ;; don't keep track of whether the
 875                         ;; mismatched data came from the same
 876                         ;; compilation unit, so we can't do that.
 877                         ;; -- WHN 2001-02-11
 878                         ;;
 879                         ;; FIXME: Actually, I think we could
 880                         ;; issue a full WARNING if the call
 881                         ;; violates a DECLAIM FTYPE.
 882                         :lossage-fun #'compiler-style-warn
 883                         :unwinnage-fun #'compiler-notify)
 884          (assert-call-type call type)
 885          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 886          (recognize-known-call call ir1-converting-not-optimizing-p))
 887         (t
 888          (setf (combination-kind call) :error)
 889          (values nil nil))))
 890
 891 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 892 ;;; changed. If the call is local, we try to LET-convert it, and
 893 ;;; derive the result type. If it is a :FULL call, we validate it
 894 ;;; against the type, which recognizes known calls, does inline
 895 ;;; expansion, etc. If a call to a predicate in a non-conditional
 896 ;;; position or to a function with a source transform, then we
 897 ;;; reconvert the form to give IR1 another chance.
 898 (defun propagate-fun-change (call)
 899   (declare (type combination call))
 900   (let ((*compiler-error-context* call)
 901         (fun-lvar (basic-combination-fun call)))
 902     (setf (lvar-reoptimize fun-lvar) nil)
 903     (case (combination-kind call)
 904       (:local
 905        (let ((fun (combination-lambda call)))
 906          (maybe-let-convert fun)
 907          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 908            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 909       (:full
 910        (multiple-value-bind (leaf info)
 911            (validate-call-type call (lvar-type fun-lvar) nil)
 912          (cond ((functional-p leaf)
 913                 (convert-call-if-possible
 914                  (lvar-uses (basic-combination-fun call))
 915                  call))
 916                ((not leaf))
 917                ((and (global-var-p leaf)
 918                      (eq (global-var-kind leaf) :global-function)
 919                      (leaf-has-source-name-p leaf)
 920                      (or (info :function :source-transform (leaf-source-name leaf))
 921                          (and info
 922                               (ir1-attributep (fun-info-attributes info)
 923                                               predicate)
 924                               (let ((lvar (node-lvar call)))
 925                                 (and lvar (not (if-p (lvar-dest lvar))))))))
 926                 (let ((name (leaf-source-name leaf))
 927                       (dummies (make-gensym-list
 928                                 (length (combination-args call)))))
 929                   (transform-call call
 930                                   `(lambda ,dummies
 931                                      (,@(if (symbolp name)
 932                                             `(,name)
 933                                             `(funcall #',name))
 934                                         ,@dummies))
 935                                   (leaf-source-name leaf)))))))))
 936   (values))
 937 \f
 938 ;;;; known function optimization
 939
 940 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
 941 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
 942 ;;; replace it, otherwise add a new one.
 943 (defun record-optimization-failure (node transform args)
 944   (declare (type combination node) (type transform transform)
 945            (type (or fun-type list) args))
 946   (let* ((table (component-failed-optimizations *component-being-compiled*))
 947          (found (assoc transform (gethash node table))))
 948     (if found
 949         (setf (cdr found) args)
 950         (push (cons transform args) (gethash node table))))
 951   (values))
 952
 953 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
 954 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
 955 ;;; doing the transform for some reason and FLAME is true, then we
 956 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
 957 ;;; finalize to pick up. We return true if the transform failed, and
 958 ;;; thus further transformation should be attempted. We return false
 959 ;;; if either the transform succeeded or was aborted.
 960 (defun ir1-transform (node transform)
 961   (declare (type combination node) (type transform transform))
 962   (let* ((type (transform-type transform))
 963          (fun (transform-function transform))
 964          (constrained (fun-type-p type))
 965          (table (component-failed-optimizations *component-being-compiled*))
 966          (flame (if (transform-important transform)
 967                     (policy node (>= speed inhibit-warnings))
 968                     (policy node (> speed inhibit-warnings))))
 969          (*compiler-error-context* node))
 970     (cond ((or (not constrained)
 971                (valid-fun-use node type))
 972            (multiple-value-bind (severity args)
 973                (catch 'give-up-ir1-transform
 974                  (transform-call node
 975                                  (funcall fun node)
 976                                  (combination-fun-source-name node))
 977                  (values :none nil))
 978              (ecase severity
 979                (:none
 980                 (remhash node table)
 981                 nil)
 982                (:aborted
 983                 (setf (combination-kind node) :error)
 984                 (when args
 985                   (apply #'warn args))
 986                 (remhash node table)
 987                 nil)
 988                (:failure
 989                 (if args
 990                     (when flame
 991                       (record-optimization-failure node transform args))
 992                     (setf (gethash node table)
 993                           (remove transform (gethash node table) :key #'car)))
 994                 t)
 995                (:delayed
 996                  (remhash node table)
 997                  nil))))
 998           ((and flame
 999                 (valid-fun-use node
1000                                type
1001                                :argument-test #'types-equal-or-intersect
1002                                :result-test #'values-types-equal-or-intersect))
1003            (record-optimization-failure node transform type)
1004            t)
1005           (t
1006            t))))
1007
1008 ;;; When we don't like an IR1 transform, we throw the severity/reason
1009 ;;; and args.
1010 ;;;
1011 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1012 ;;; aborting this attempt to transform the call, but admitting the
1013 ;;; possibility that this or some other transform will later succeed.
1014 ;;; If arguments are supplied, they are format arguments for an
1015 ;;; efficiency note.
1016 ;;;
1017 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1018 ;;; force a normal call to the function at run time. No further
1019 ;;; optimizations will be attempted.
1020 ;;;
1021 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1022 ;;; delay the transform on the node until later. REASONS specifies
1023 ;;; when the transform will be later retried. The :OPTIMIZE reason
1024 ;;; causes the transform to be delayed until after the current IR1
1025 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1026 ;;; be delayed until after constraint propagation.
1027 ;;;
1028 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1029 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1030 ;;; do CASE operations on the various REASON values, it might be a
1031 ;;; good idea to go OO, representing the reasons by objects, using
1032 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1033 ;;; SIGNAL instead of THROW.
1034 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1035 (defun give-up-ir1-transform (&rest args)
1036   (throw 'give-up-ir1-transform (values :failure args)))
1037 (defun abort-ir1-transform (&rest args)
1038   (throw 'give-up-ir1-transform (values :aborted args)))
1039 (defun delay-ir1-transform (node &rest reasons)
1040   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1041     (cond ((not assoc)
1042             (setf *delayed-ir1-transforms*
1043                     (acons node reasons *delayed-ir1-transforms*))
1044             (throw 'give-up-ir1-transform :delayed))
1045           ((cdr assoc)
1046             (dolist (reason reasons)
1047               (pushnew reason (cdr assoc)))
1048             (throw 'give-up-ir1-transform :delayed)))))
1049
1050 ;;; Clear any delayed transform with no reasons - these should have
1051 ;;; been tried in the last pass. Then remove the reason from the
1052 ;;; delayed transform reasons, and if any become empty then set
1053 ;;; reoptimize flags for the node. Return true if any transforms are
1054 ;;; to be retried.
1055 (defun retry-delayed-ir1-transforms (reason)
1056   (setf *delayed-ir1-transforms*
1057         (remove-if-not #'cdr *delayed-ir1-transforms*))
1058   (let ((reoptimize nil))
1059     (dolist (assoc *delayed-ir1-transforms*)
1060       (let ((reasons (remove reason (cdr assoc))))
1061         (setf (cdr assoc) reasons)
1062         (unless reasons
1063           (let ((node (car assoc)))
1064             (unless (node-deleted node)
1065               (setf reoptimize t)
1066               (setf (node-reoptimize node) t)
1067               (let ((block (node-block node)))
1068                 (setf (block-reoptimize block) t)
1069                 (setf (component-reoptimize (block-component block)) t)))))))
1070     reoptimize))
1071
1072 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1073 ;;; environment, and then install it as the function for the call
1074 ;;; NODE. We do local call analysis so that the new function is
1075 ;;; integrated into the control flow.
1076 ;;;
1077 ;;; We require the original function source name in order to generate
1078 ;;; a meaningful debug name for the lambda we set up. (It'd be
1079 ;;; possible to do this starting from debug names as well as source
1080 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1081 ;;; generality, since source names are always known to our callers.)
1082 (defun transform-call (call res source-name)
1083   (declare (type combination call) (list res))
1084   (aver (and (legal-fun-name-p source-name)
1085              (not (eql source-name '.anonymous.))))
1086   (node-ends-block call)
1087   (with-ir1-environment-from-node call
1088     (with-component-last-block (*current-component*
1089                                 (block-next (node-block call)))
1090       (let ((new-fun (ir1-convert-inline-lambda
1091                       res
1092                       :debug-name (debug-namify "LAMBDA-inlined "
1093                                                 source-name
1094                                                 "<unknown function>")))
1095             (ref (lvar-use (combination-fun call))))
1096         (change-ref-leaf ref new-fun)
1097         (setf (combination-kind call) :full)
1098         (locall-analyze-component *current-component*))))
1099   (values))
1100
1101 ;;; Replace a call to a foldable function of constant arguments with
1102 ;;; the result of evaluating the form. If there is an error during the
1103 ;;; evaluation, we give a warning and leave the call alone, making the
1104 ;;; call a :ERROR call.
1105 ;;;
1106 ;;; If there is more than one value, then we transform the call into a
1107 ;;; VALUES form.
1108 (defun constant-fold-call (call)
1109   (let ((args (mapcar #'lvar-value (combination-args call)))
1110         (fun-name (combination-fun-source-name call)))
1111     (multiple-value-bind (values win)
1112         (careful-call fun-name
1113                       args
1114                       call
1115                       ;; Note: CMU CL had COMPILER-WARN here, and that
1116                       ;; seems more natural, but it's probably not.
1117                       ;;
1118                       ;; It's especially not while bug 173 exists:
1119                       ;; Expressions like
1120                       ;;   (COND (END
1121                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1122                       ;;            ...))
1123                       ;; can cause constant-folding TYPE-ERRORs (in
1124                       ;; #'<=) when END can be proved to be NIL, even
1125                       ;; though the code is perfectly legal and safe
1126                       ;; because a NIL value of END means that the
1127                       ;; #'<= will never be executed.
1128                       ;;
1129                       ;; Moreover, even without bug 173,
1130                       ;; quite-possibly-valid code like
1131                       ;;   (COND ((NONINLINED-PREDICATE END)
1132                       ;;          (UNLESS (<= END SIZE))
1133                       ;;            ...))
1134                       ;; (where NONINLINED-PREDICATE is something the
1135                       ;; compiler can't do at compile time, but which
1136                       ;; turns out to make the #'<= expression
1137                       ;; unreachable when END=NIL) could cause errors
1138                       ;; when the compiler tries to constant-fold (<=
1139                       ;; END SIZE).
1140                       ;;
1141                       ;; So, with or without bug 173, it'd be
1142                       ;; unnecessarily evil to do a full
1143                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1144                       ;; from COMPILE-FILE) for legal code, so we we
1145                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1146                       #'compiler-style-warn
1147                       "constant folding")
1148       (cond ((not win)
1149              (setf (combination-kind call) :error))
1150             ((and (proper-list-of-length-p values 1))
1151              (with-ir1-environment-from-node call
1152                (let* ((lvar (node-lvar call))
1153                       (prev (node-prev call))
1154                       (intermediate-ctran (make-ctran)))
1155                  (%delete-lvar-use call)
1156                  (setf (ctran-next prev) nil)
1157                  (setf (node-prev call) nil)
1158                  (reference-constant prev intermediate-ctran lvar
1159                                      (first values))
1160                  (link-node-to-previous-ctran call intermediate-ctran)
1161                  (reoptimize-lvar lvar)
1162                  (flush-combination call))))
1163             (t (let ((dummies (make-gensym-list (length args))))
1164                  (transform-call
1165                   call
1166                   `(lambda ,dummies
1167                      (declare (ignore ,@dummies))
1168                      (values ,@(mapcar (lambda (x) `',x) values)))
1169                   fun-name))))))
1170   (values))
1171 \f
1172 ;;;; local call optimization
1173
1174 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1175 ;;; the leaf type is a function type, then just leave it alone, since
1176 ;;; TYPE is never going to be more specific than that (and
1177 ;;; TYPE-INTERSECTION would choke.)
1178 (defun propagate-to-refs (leaf type)
1179   (declare (type leaf leaf) (type ctype type))
1180   (let ((var-type (leaf-type leaf)))
1181     (unless (fun-type-p var-type)
1182       (let ((int (type-approx-intersection2 var-type type)))
1183         (when (type/= int var-type)
1184           (setf (leaf-type leaf) int)
1185           (dolist (ref (leaf-refs leaf))
1186             (derive-node-type ref (make-single-value-type int))
1187             ;; KLUDGE: LET var substitution
1188             (let* ((lvar (node-lvar ref)))
1189               (when (and lvar (combination-p (lvar-dest lvar)))
1190                 (reoptimize-lvar lvar))))))
1191       (values))))
1192
1193 ;;; Iteration variable: exactly one SETQ of the form:
1194 ;;;
1195 ;;; (let ((var initial))
1196 ;;;   ...
1197 ;;;   (setq var (+ var step))
1198 ;;;   ...)
1199 (defun maybe-infer-iteration-var-type (var initial-type)
1200   (binding* ((sets (lambda-var-sets var) :exit-if-null)
1201              (set (first sets))
1202              (() (null (rest sets)) :exit-if-null)
1203              (set-use (principal-lvar-use (set-value set)))
1204              (() (and (combination-p set-use)
1205                       (eq (combination-kind set-use) :known)
1206                       (fun-info-p (combination-fun-info set-use))
1207                       (not (node-to-be-deleted-p set-use))
1208                       (eq (combination-fun-source-name set-use) '+))
1209                :exit-if-null)
1210              (+-args (basic-combination-args set-use))
1211              (() (and (proper-list-of-length-p +-args 2 2)
1212                       (let ((first (principal-lvar-use
1213                                     (first +-args))))
1214                         (and (ref-p first)
1215                              (eq (ref-leaf first) var))))
1216                :exit-if-null)
1217              (step-type (lvar-type (second +-args)))
1218              (set-type (lvar-type (set-value set))))
1219     (when (and (numeric-type-p initial-type)
1220                (numeric-type-p step-type)
1221                (numeric-type-equal initial-type step-type))
1222       (multiple-value-bind (low high)
1223           (cond ((csubtypep step-type (specifier-type '(real 0 *)))
1224                  (values (numeric-type-low initial-type)
1225                          (when (and (numeric-type-p set-type)
1226                                     (numeric-type-equal set-type initial-type))
1227                            (numeric-type-high set-type))))
1228                 ((csubtypep step-type (specifier-type '(real * 0)))
1229                  (values (when (and (numeric-type-p set-type)
1230                                     (numeric-type-equal set-type initial-type))
1231                            (numeric-type-low set-type))
1232                          (numeric-type-high initial-type)))
1233                 (t
1234                  (values nil nil)))
1235         (modified-numeric-type initial-type
1236                                :low low
1237                                :high high
1238                                :enumerable nil)))))
1239 (deftransform + ((x y) * * :result result)
1240   "check for iteration variable reoptimization"
1241   (let ((dest (principal-lvar-end result))
1242         (use (principal-lvar-use x)))
1243     (when (and (ref-p use)
1244                (set-p dest)
1245                (eq (ref-leaf use)
1246                    (set-var dest)))
1247       (reoptimize-lvar (set-value dest))))
1248   (give-up-ir1-transform))
1249
1250 ;;; Figure out the type of a LET variable that has sets. We compute
1251 ;;; the union of the INITIAL-TYPE and the types of all the set
1252 ;;; values and to a PROPAGATE-TO-REFS with this type.
1253 (defun propagate-from-sets (var initial-type)
1254   (collect ((res initial-type type-union))
1255     (dolist (set (basic-var-sets var))
1256       (let ((type (lvar-type (set-value set))))
1257         (res type)
1258         (when (node-reoptimize set)
1259           (derive-node-type set (make-single-value-type type))
1260           (setf (node-reoptimize set) nil))))
1261     (let ((res (res)))
1262       (awhen (maybe-infer-iteration-var-type var initial-type)
1263         (setq res it))
1264       (propagate-to-refs var res)))
1265   (values))
1266
1267 ;;; If a LET variable, find the initial value's type and do
1268 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1269 ;;; type.
1270 (defun ir1-optimize-set (node)
1271   (declare (type cset node))
1272   (let ((var (set-var node)))
1273     (when (and (lambda-var-p var) (leaf-refs var))
1274       (let ((home (lambda-var-home var)))
1275         (when (eq (functional-kind home) :let)
1276           (let* ((initial-value (let-var-initial-value var))
1277                  (initial-type (lvar-type initial-value)))
1278             (setf (lvar-reoptimize initial-value) nil)
1279             (propagate-from-sets var initial-type))))))
1280
1281   (derive-node-type node (make-single-value-type
1282                           (lvar-type (set-value node))))
1283   (values))
1284
1285 ;;; Return true if the value of REF will always be the same (and is
1286 ;;; thus legal to substitute.)
1287 (defun constant-reference-p (ref)
1288   (declare (type ref ref))
1289   (let ((leaf (ref-leaf ref)))
1290     (typecase leaf
1291       ((or constant functional) t)
1292       (lambda-var
1293        (null (lambda-var-sets leaf)))
1294       (defined-fun
1295        (not (eq (defined-fun-inlinep leaf) :notinline)))
1296       (global-var
1297        (case (global-var-kind leaf)
1298          (:global-function
1299           (let ((name (leaf-source-name leaf)))
1300             (or #-sb-xc-host
1301                 (eq (symbol-package (fun-name-block-name name))
1302                     *cl-package*)
1303                 (info :function :info name)))))))))
1304
1305 ;;; If we have a non-set LET var with a single use, then (if possible)
1306 ;;; replace the variable reference's LVAR with the arg lvar.
1307 ;;;
1308 ;;; We change the REF to be a reference to NIL with unused value, and
1309 ;;; let it be flushed as dead code. A side effect of this substitution
1310 ;;; is to delete the variable.
1311 (defun substitute-single-use-lvar (arg var)
1312   (declare (type lvar arg) (type lambda-var var))
1313   (binding* ((ref (first (leaf-refs var)))
1314              (lvar (node-lvar ref) :exit-if-null)
1315              (dest (lvar-dest lvar)))
1316     (when (and
1317            ;; Think about (LET ((A ...)) (IF ... A ...)): two
1318            ;; LVAR-USEs should not be met on one path. Another problem
1319            ;; is with dynamic-extent.
1320            (eq (lvar-uses lvar) ref)
1321            (typecase dest
1322              ;; we should not change lifetime of unknown values lvars
1323              (cast
1324               (and (type-single-value-p (lvar-derived-type arg))
1325                    (multiple-value-bind (pdest pprev)
1326                        (principal-lvar-end lvar)
1327                      (declare (ignore pdest))
1328                      (lvar-single-value-p pprev))))
1329              (mv-combination
1330               (or (eq (basic-combination-fun dest) lvar)
1331                   (and (eq (basic-combination-kind dest) :local)
1332                        (type-single-value-p (lvar-derived-type arg)))))
1333              ((or creturn exit)
1334               ;; While CRETURN and EXIT nodes may be known-values,
1335               ;; they have their own complications, such as
1336               ;; substitution into CRETURN may create new tail calls.
1337               nil)
1338              (t
1339               (aver (lvar-single-value-p lvar))
1340               t))
1341            (eq (node-home-lambda ref)
1342                (lambda-home (lambda-var-home var))))
1343       (setf (node-derived-type ref) *wild-type*)
1344       (substitute-lvar-uses lvar arg
1345                             ;; Really it is (EQ (LVAR-USES LVAR) REF):
1346                             t)
1347       (delete-lvar-use ref)
1348       (change-ref-leaf ref (find-constant nil))
1349       (delete-ref ref)
1350       (unlink-node ref)
1351       (reoptimize-lvar lvar)
1352       t)))
1353
1354 ;;; Delete a LET, removing the call and bind nodes, and warning about
1355 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1356 ;;; along right away and delete the REF and then the lambda, since we
1357 ;;; flush the FUN lvar.
1358 (defun delete-let (clambda)
1359   (declare (type clambda clambda))
1360   (aver (functional-letlike-p clambda))
1361   (note-unreferenced-vars clambda)
1362   (let ((call (let-combination clambda)))
1363     (flush-dest (basic-combination-fun call))
1364     (unlink-node call)
1365     (unlink-node (lambda-bind clambda))
1366     (setf (lambda-bind clambda) nil))
1367   (setf (functional-kind clambda) :zombie)
1368   (let ((home (lambda-home clambda)))
1369     (setf (lambda-lets home) (delete clambda (lambda-lets home))))
1370   (values))
1371
1372 ;;; This function is called when one of the arguments to a LET
1373 ;;; changes. We look at each changed argument. If the corresponding
1374 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1375 ;;; consider substituting for the variable, and also propagate
1376 ;;; derived-type information for the arg to all the VAR's refs.
1377 ;;;
1378 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1379 ;;; subtype of the argument's leaf type. This prevents type checking
1380 ;;; from being defeated, and also ensures that the best representation
1381 ;;; for the variable can be used.
1382 ;;;
1383 ;;; Substitution of individual references is inhibited if the
1384 ;;; reference is in a different component from the home. This can only
1385 ;;; happen with closures over top level lambda vars. In such cases,
1386 ;;; the references may have already been compiled, and thus can't be
1387 ;;; retroactively modified.
1388 ;;;
1389 ;;; If all of the variables are deleted (have no references) when we
1390 ;;; are done, then we delete the LET.
1391 ;;;
1392 ;;; Note that we are responsible for clearing the LVAR-REOPTIMIZE
1393 ;;; flags.
1394 (defun propagate-let-args (call fun)
1395   (declare (type combination call) (type clambda fun))
1396   (loop for arg in (combination-args call)
1397         and var in (lambda-vars fun) do
1398     (when (and arg (lvar-reoptimize arg))
1399       (setf (lvar-reoptimize arg) nil)
1400       (cond
1401         ((lambda-var-sets var)
1402          (propagate-from-sets var (lvar-type arg)))
1403         ((let ((use (lvar-uses arg)))
1404            (when (ref-p use)
1405              (let ((leaf (ref-leaf use)))
1406                (when (and (constant-reference-p use)
1407                           (csubtypep (leaf-type leaf)
1408                                      ;; (NODE-DERIVED-TYPE USE) would
1409                                      ;; be better -- APD, 2003-05-15
1410                                      (leaf-type var)))
1411                  (propagate-to-refs var (lvar-type arg))
1412                  (let ((use-component (node-component use)))
1413                    (prog1 (substitute-leaf-if
1414                            (lambda (ref)
1415                              (cond ((eq (node-component ref) use-component)
1416                                     t)
1417                                    (t
1418                                     (aver (lambda-toplevelish-p (lambda-home fun)))
1419                                     nil)))
1420                            leaf var)))
1421                  t)))))
1422         ((and (null (rest (leaf-refs var)))
1423               (substitute-single-use-lvar arg var)))
1424         (t
1425          (propagate-to-refs var (lvar-type arg))))))
1426
1427   (when (every #'not (combination-args call))
1428     (delete-let fun))
1429
1430   (values))
1431
1432 ;;; This function is called when one of the args to a non-LET local
1433 ;;; call changes. For each changed argument corresponding to an unset
1434 ;;; variable, we compute the union of the types across all calls and
1435 ;;; propagate this type information to the var's refs.
1436 ;;;
1437 ;;; If the function has an XEP, then we don't do anything, since we
1438 ;;; won't discover anything.
1439 ;;;
1440 ;;; We can clear the LVAR-REOPTIMIZE flags for arguments in all calls
1441 ;;; corresponding to changed arguments in CALL, since the only use in
1442 ;;; IR1 optimization of the REOPTIMIZE flag for local call args is
1443 ;;; right here.
1444 (defun propagate-local-call-args (call fun)
1445   (declare (type combination call) (type clambda fun))
1446
1447   (unless (or (functional-entry-fun fun)
1448               (lambda-optional-dispatch fun))
1449     (let* ((vars (lambda-vars fun))
1450            (union (mapcar (lambda (arg var)
1451                             (when (and arg
1452                                        (lvar-reoptimize arg)
1453                                        (null (basic-var-sets var)))
1454                               (lvar-type arg)))
1455                           (basic-combination-args call)
1456                           vars))
1457            (this-ref (lvar-use (basic-combination-fun call))))
1458
1459       (dolist (arg (basic-combination-args call))
1460         (when arg
1461           (setf (lvar-reoptimize arg) nil)))
1462
1463       (dolist (ref (leaf-refs fun))
1464         (let ((dest (node-dest ref)))
1465           (unless (or (eq ref this-ref) (not dest))
1466             (setq union
1467                   (mapcar (lambda (this-arg old)
1468                             (when old
1469                               (setf (lvar-reoptimize this-arg) nil)
1470                               (type-union (lvar-type this-arg) old)))
1471                           (basic-combination-args dest)
1472                           union)))))
1473
1474       (loop for var in vars
1475             and type in union
1476             when type do (propagate-to-refs var type))))
1477
1478   (values))
1479 \f
1480 ;;;; multiple values optimization
1481
1482 ;;; Do stuff to notice a change to a MV combination node. There are
1483 ;;; two main branches here:
1484 ;;;  -- If the call is local, then it is already a MV let, or should
1485 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1486 ;;;     be converted to :MV-LETs, there can be a window when the call
1487 ;;;     is local, but has not been LET converted yet. This is because
1488 ;;;     the entry-point lambdas may have stray references (in other
1489 ;;;     entry points) that have not been deleted yet.
1490 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1491 ;;;     combination optimization: we propagate return type information and
1492 ;;;     notice non-returning calls. We also have an optimization
1493 ;;;     which tries to convert MV-CALLs into MV-binds.
1494 (defun ir1-optimize-mv-combination (node)
1495   (ecase (basic-combination-kind node)
1496     (:local
1497      (let ((fun-lvar (basic-combination-fun node)))
1498        (when (lvar-reoptimize fun-lvar)
1499          (setf (lvar-reoptimize fun-lvar) nil)
1500          (maybe-let-convert (combination-lambda node))))
1501      (setf (lvar-reoptimize (first (basic-combination-args node))) nil)
1502      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1503        (unless (convert-mv-bind-to-let node)
1504          (ir1-optimize-mv-bind node))))
1505     (:full
1506      (let* ((fun (basic-combination-fun node))
1507             (fun-changed (lvar-reoptimize fun))
1508             (args (basic-combination-args node)))
1509        (when fun-changed
1510          (setf (lvar-reoptimize fun) nil)
1511          (let ((type (lvar-type fun)))
1512            (when (fun-type-p type)
1513              (derive-node-type node (fun-type-returns type))))
1514          (maybe-terminate-block node nil)
1515          (let ((use (lvar-uses fun)))
1516            (when (and (ref-p use) (functional-p (ref-leaf use)))
1517              (convert-call-if-possible use node)
1518              (when (eq (basic-combination-kind node) :local)
1519                (maybe-let-convert (ref-leaf use))))))
1520        (unless (or (eq (basic-combination-kind node) :local)
1521                    (eq (lvar-fun-name fun) '%throw))
1522          (ir1-optimize-mv-call node))
1523        (dolist (arg args)
1524          (setf (lvar-reoptimize arg) nil))))
1525     (:error))
1526   (values))
1527
1528 ;;; Propagate derived type info from the values lvar to the vars.
1529 (defun ir1-optimize-mv-bind (node)
1530   (declare (type mv-combination node))
1531   (let* ((arg (first (basic-combination-args node)))
1532          (vars (lambda-vars (combination-lambda node)))
1533          (n-vars (length vars))
1534          (types (values-type-in (lvar-derived-type arg)
1535                                 n-vars)))
1536     (loop for var in vars
1537           and type in types
1538           do (if (basic-var-sets var)
1539                  (propagate-from-sets var type)
1540                  (propagate-to-refs var type)))
1541     (setf (lvar-reoptimize arg) nil))
1542   (values))
1543
1544 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1545 ;;; this if:
1546 ;;; -- The call has only one argument, and
1547 ;;; -- The function has a known fixed number of arguments, or
1548 ;;; -- The argument yields a known fixed number of values.
1549 ;;;
1550 ;;; What we do is change the function in the MV-CALL to be a lambda
1551 ;;; that "looks like an MV bind", which allows
1552 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1553 ;;; converted (the next time around.) This new lambda just calls the
1554 ;;; actual function with the MV-BIND variables as arguments. Note that
1555 ;;; this new MV bind is not let-converted immediately, as there are
1556 ;;; going to be stray references from the entry-point functions until
1557 ;;; they get deleted.
1558 ;;;
1559 ;;; In order to avoid loss of argument count checking, we only do the
1560 ;;; transformation according to a known number of expected argument if
1561 ;;; safety is unimportant. We can always convert if we know the number
1562 ;;; of actual values, since the normal call that we build will still
1563 ;;; do any appropriate argument count checking.
1564 ;;;
1565 ;;; We only attempt the transformation if the called function is a
1566 ;;; constant reference. This allows us to just splice the leaf into
1567 ;;; the new function, instead of trying to somehow bind the function
1568 ;;; expression. The leaf must be constant because we are evaluating it
1569 ;;; again in a different place. This also has the effect of squelching
1570 ;;; multiple warnings when there is an argument count error.
1571 (defun ir1-optimize-mv-call (node)
1572   (let ((fun (basic-combination-fun node))
1573         (*compiler-error-context* node)
1574         (ref (lvar-uses (basic-combination-fun node)))
1575         (args (basic-combination-args node)))
1576
1577     (unless (and (ref-p ref) (constant-reference-p ref)
1578                  (singleton-p args))
1579       (return-from ir1-optimize-mv-call))
1580
1581     (multiple-value-bind (min max)
1582         (fun-type-nargs (lvar-type fun))
1583       (let ((total-nvals
1584              (multiple-value-bind (types nvals)
1585                  (values-types (lvar-derived-type (first args)))
1586                (declare (ignore types))
1587                (if (eq nvals :unknown) nil nvals))))
1588
1589         (when total-nvals
1590           (when (and min (< total-nvals min))
1591             (compiler-warn
1592              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1593               at least ~R."
1594              total-nvals min)
1595             (setf (basic-combination-kind node) :error)
1596             (return-from ir1-optimize-mv-call))
1597           (when (and max (> total-nvals max))
1598             (compiler-warn
1599              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1600               at most ~R."
1601              total-nvals max)
1602             (setf (basic-combination-kind node) :error)
1603             (return-from ir1-optimize-mv-call)))
1604
1605         (let ((count (cond (total-nvals)
1606                            ((and (policy node (zerop verify-arg-count))
1607                                  (eql min max))
1608                             min)
1609                            (t nil))))
1610           (when count
1611             (with-ir1-environment-from-node node
1612               (let* ((dums (make-gensym-list count))
1613                      (ignore (gensym))
1614                      (fun (ir1-convert-lambda
1615                            `(lambda (&optional ,@dums &rest ,ignore)
1616                               (declare (ignore ,ignore))
1617                               (funcall ,(ref-leaf ref) ,@dums)))))
1618                 (change-ref-leaf ref fun)
1619                 (aver (eq (basic-combination-kind node) :full))
1620                 (locall-analyze-component *current-component*)
1621                 (aver (eq (basic-combination-kind node) :local)))))))))
1622   (values))
1623
1624 ;;; If we see:
1625 ;;;    (multiple-value-bind
1626 ;;;     (x y)
1627 ;;;     (values xx yy)
1628 ;;;      ...)
1629 ;;; Convert to:
1630 ;;;    (let ((x xx)
1631 ;;;       (y yy))
1632 ;;;      ...)
1633 ;;;
1634 ;;; What we actually do is convert the VALUES combination into a
1635 ;;; normal LET combination calling the original :MV-LET lambda. If
1636 ;;; there are extra args to VALUES, discard the corresponding
1637 ;;; lvars. If there are insufficient args, insert references to NIL.
1638 (defun convert-mv-bind-to-let (call)
1639   (declare (type mv-combination call))
1640   (let* ((arg (first (basic-combination-args call)))
1641          (use (lvar-uses arg)))
1642     (when (and (combination-p use)
1643                (eq (lvar-fun-name (combination-fun use))
1644                    'values))
1645       (let* ((fun (combination-lambda call))
1646              (vars (lambda-vars fun))
1647              (vals (combination-args use))
1648              (nvars (length vars))
1649              (nvals (length vals)))
1650         (cond ((> nvals nvars)
1651                (mapc #'flush-dest (subseq vals nvars))
1652                (setq vals (subseq vals 0 nvars)))
1653               ((< nvals nvars)
1654                (with-ir1-environment-from-node use
1655                  (let ((node-prev (node-prev use)))
1656                    (setf (node-prev use) nil)
1657                    (setf (ctran-next node-prev) nil)
1658                    (collect ((res vals))
1659                      (loop for count below (- nvars nvals)
1660                            for prev = node-prev then ctran
1661                            for ctran = (make-ctran)
1662                            and lvar = (make-lvar use)
1663                            do (reference-constant prev ctran lvar nil)
1664                               (res lvar)
1665                            finally (link-node-to-previous-ctran
1666                                     use ctran))
1667                      (setq vals (res)))))))
1668         (setf (combination-args use) vals)
1669         (flush-dest (combination-fun use))
1670         (let ((fun-lvar (basic-combination-fun call)))
1671           (setf (lvar-dest fun-lvar) use)
1672           (setf (combination-fun use) fun-lvar)
1673           (flush-lvar-externally-checkable-type fun-lvar))
1674         (setf (combination-kind use) :local)
1675         (setf (functional-kind fun) :let)
1676         (flush-dest (first (basic-combination-args call)))
1677         (unlink-node call)
1678         (when vals
1679           (reoptimize-lvar (first vals)))
1680         (propagate-to-args use fun)
1681         (reoptimize-call use))
1682       t)))
1683
1684 ;;; If we see:
1685 ;;;    (values-list (list x y z))
1686 ;;;
1687 ;;; Convert to:
1688 ;;;    (values x y z)
1689 ;;;
1690 ;;; In implementation, this is somewhat similar to
1691 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1692 ;;; args of the VALUES-LIST call, flushing the old argument lvar
1693 ;;; (allowing the LIST to be flushed.)
1694 ;;;
1695 ;;; FIXME: Thus we lose possible type assertions on (LIST ...).
1696 (defoptimizer (values-list optimizer) ((list) node)
1697   (let ((use (lvar-uses list)))
1698     (when (and (combination-p use)
1699                (eq (lvar-fun-name (combination-fun use))
1700                    'list))
1701
1702       ;; FIXME: VALUES might not satisfy an assertion on NODE-LVAR.
1703       (change-ref-leaf (lvar-uses (combination-fun node))
1704                        (find-free-fun 'values "in a strange place"))
1705       (setf (combination-kind node) :full)
1706       (let ((args (combination-args use)))
1707         (dolist (arg args)
1708           (setf (lvar-dest arg) node)
1709           (flush-lvar-externally-checkable-type arg))
1710         (setf (combination-args use) nil)
1711         (flush-dest list)
1712         (setf (combination-args node) args))
1713       t)))
1714
1715 ;;; If VALUES appears in a non-MV context, then effectively convert it
1716 ;;; to a PROG1. This allows the computation of the additional values
1717 ;;; to become dead code.
1718 (deftransform values ((&rest vals) * * :node node)
1719   (unless (lvar-single-value-p (node-lvar node))
1720     (give-up-ir1-transform))
1721   (setf (node-derived-type node)
1722         (make-short-values-type (list (single-value-type
1723                                        (node-derived-type node)))))
1724   (principal-lvar-single-valuify (node-lvar node))
1725   (if vals
1726       (let ((dummies (make-gensym-list (length (cdr vals)))))
1727         `(lambda (val ,@dummies)
1728            (declare (ignore ,@dummies))
1729            val))
1730       nil))
1731
1732 ;;; TODO:
1733 ;;; - CAST chains;
1734 (defun ir1-optimize-cast (cast &optional do-not-optimize)
1735   (declare (type cast cast))
1736   (let ((value (cast-value cast))
1737         (atype (cast-asserted-type cast)))
1738     (when (not do-not-optimize)
1739       (let ((lvar (node-lvar cast)))
1740         (when (values-subtypep (lvar-derived-type value)
1741                                (cast-asserted-type cast))
1742           (delete-filter cast lvar value)
1743           (when lvar
1744             (reoptimize-lvar lvar)
1745             (when (lvar-single-value-p lvar)
1746               (note-single-valuified-lvar lvar)))
1747           (return-from ir1-optimize-cast t))
1748
1749         (when (and (listp (lvar-uses value))
1750                    lvar)
1751           ;; Pathwise removing of CAST
1752           (let ((ctran (node-next cast))
1753                 (dest (lvar-dest lvar))
1754                 next-block)
1755             (collect ((merges))
1756               (do-uses (use value)
1757                 (when (and (values-subtypep (node-derived-type use) atype)
1758                            (immediately-used-p value use))
1759                   (unless next-block
1760                     (when ctran (ensure-block-start ctran))
1761                     (setq next-block (first (block-succ (node-block cast))))
1762                     (ensure-block-start (node-prev cast))
1763                     (reoptimize-lvar lvar)
1764                     (setf (lvar-%derived-type value) nil))
1765                   (%delete-lvar-use use)
1766                   (add-lvar-use use lvar)
1767                   (unlink-blocks (node-block use) (node-block cast))
1768                   (link-blocks (node-block use) next-block)
1769                   (when (and (return-p dest)
1770                              (basic-combination-p use)
1771                              (eq (basic-combination-kind use) :local))
1772                     (merges use))))
1773               (dolist (use (merges))
1774                 (merge-tail-sets use)))))))
1775
1776     (let* ((value-type (lvar-derived-type value))
1777            (int (values-type-intersection value-type atype)))
1778       (derive-node-type cast int)
1779       (when (eq int *empty-type*)
1780         (unless (eq value-type *empty-type*)
1781
1782           ;; FIXME: Do it in one step.
1783           (filter-lvar
1784            value
1785            (if (cast-single-value-p cast)
1786                `(list 'dummy)
1787                `(multiple-value-call #'list 'dummy)))
1788           (filter-lvar
1789            (cast-value cast)
1790            ;; FIXME: Derived type.
1791            `(%compile-time-type-error 'dummy
1792                                       ',(type-specifier atype)
1793                                       ',(type-specifier value-type)))
1794           ;; KLUDGE: FILTER-LVAR does not work for non-returning
1795           ;; functions, so we declare the return type of
1796           ;; %COMPILE-TIME-TYPE-ERROR to be * and derive the real type
1797           ;; here.
1798           (setq value (cast-value cast))
1799           (derive-node-type (lvar-uses value) *empty-type*)
1800           (maybe-terminate-block (lvar-uses value) nil)
1801           ;; FIXME: Is it necessary?
1802           (aver (null (block-pred (node-block cast))))
1803           (delete-block-lazily (node-block cast))
1804           (return-from ir1-optimize-cast)))
1805       (when (eq (node-derived-type cast) *empty-type*)
1806         (maybe-terminate-block cast nil))
1807
1808       (when (and (cast-%type-check cast)
1809                  (values-subtypep value-type
1810                                   (cast-type-to-check cast)))
1811         (setf (cast-%type-check cast) nil))))
1812
1813   (unless do-not-optimize
1814     (setf (node-reoptimize cast) nil)))