src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for an LVAR whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-lvar-p (thing)
  24   (declare (type (or lvar null) thing))
  25   (and (lvar-p thing)
  26        (let ((use (principal-lvar-use thing)))
  27          (and (ref-p use) (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for an LVAR whose only use is a constant
  30 ;;; node.
  31 (declaim (ftype (function (lvar) t) lvar-value))
  32 (defun lvar-value (lvar)
  33   (let ((use (principal-lvar-use lvar)))
  34     (constant-value (ref-leaf use))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Our best guess for the type of this lvar's value. Note that this
  39 ;;; may be VALUES or FUNCTION type, which cannot be passed as an
  40 ;;; argument to the normal type operations. See LVAR-TYPE.
  41 ;;;
  42 ;;; The result value is cached in the LVAR-%DERIVED-TYPE slot. If the
  43 ;;; slot is true, just return that value, otherwise recompute and
  44 ;;; stash the value there.
  45 #!-sb-fluid (declaim (inline lvar-derived-type))
  46 (defun lvar-derived-type (lvar)
  47   (declare (type lvar lvar))
  48   (or (lvar-%derived-type lvar)
  49       (setf (lvar-%derived-type lvar)
  50             (%lvar-derived-type lvar))))
  51 (defun %lvar-derived-type (lvar)
  52   (declare (type lvar lvar))
  53   (let ((uses (lvar-uses lvar)))
  54     (cond ((null uses) *empty-type*)
  55           ((listp uses)
  56            (do ((res (node-derived-type (first uses))
  57                      (values-type-union (node-derived-type (first current))
  58                                         res))
  59                 (current (rest uses) (rest current)))
  60                ((null current) res)))
  61           (t
  62            (node-derived-type (lvar-uses lvar))))))
  63
  64 ;;; Return the derived type for LVAR's first value. This is guaranteed
  65 ;;; not to be a VALUES or FUNCTION type.
  66 (declaim (ftype (sfunction (lvar) ctype) lvar-type))
  67 (defun lvar-type (lvar)
  68   (single-value-type (lvar-derived-type lvar)))
  69
  70 ;;; If LVAR is an argument of a function, return a type which the
  71 ;;; function checks LVAR for.
  72 #!-sb-fluid (declaim (inline lvar-externally-checkable-type))
  73 (defun lvar-externally-checkable-type (lvar)
  74   (or (lvar-%externally-checkable-type lvar)
  75       (%lvar-%externally-checkable-type lvar)))
  76 (defun %lvar-%externally-checkable-type (lvar)
  77   (declare (type lvar lvar))
  78   (let ((dest (lvar-dest lvar)))
  79     (if (not (and dest (combination-p dest)))
  80         ;; TODO: MV-COMBINATION
  81         (setf (lvar-%externally-checkable-type lvar) *wild-type*)
  82         (let* ((fun (combination-fun dest))
  83                (args (combination-args dest))
  84                (fun-type (lvar-type fun)))
  85           (setf (lvar-%externally-checkable-type fun) *wild-type*)
  86           (if (or (not (call-full-like-p dest))
  87                   (not (fun-type-p fun-type))
  88                   ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
  89                   (fun-type-wild-args fun-type))
  90               (dolist (arg args)
  91                 (when arg
  92                   (setf (lvar-%externally-checkable-type arg)
  93                         *wild-type*)))
  94               (map-combination-args-and-types
  95                (lambda (arg type)
  96                  (setf (lvar-%externally-checkable-type arg)
  97                        (acond ((lvar-%externally-checkable-type arg)
  98                                (values-type-intersection
  99                                 it (coerce-to-values type)))
 100                               (t (coerce-to-values type)))))
 101                dest)))))
 102   (lvar-%externally-checkable-type lvar))
 103 #!-sb-fluid(declaim (inline flush-lvar-externally-checkable-type))
 104 (defun flush-lvar-externally-checkable-type (lvar)
 105   (declare (type lvar lvar))
 106   (setf (lvar-%externally-checkable-type lvar) nil))
 107 \f
 108 ;;;; interface routines used by optimizers
 109
 110 ;;; This function is called by optimizers to indicate that something
 111 ;;; interesting has happened to the value of LVAR. Optimizers must
 112 ;;; make sure that they don't call for reoptimization when nothing has
 113 ;;; happened, since optimization will fail to terminate.
 114 ;;;
 115 ;;; We clear any cached type for the lvar and set the reoptimize flags
 116 ;;; on everything in sight.
 117 (defun reoptimize-lvar (lvar)
 118   (declare (type (or lvar null) lvar))
 119   (when lvar
 120     (setf (lvar-%derived-type lvar) nil)
 121     (let ((dest (lvar-dest lvar)))
 122       (when dest
 123         (setf (lvar-reoptimize lvar) t)
 124         (setf (node-reoptimize dest) t)
 125         (binding* (;; Since this may be called during IR1 conversion,
 126                    ;; PREV may be missing.
 127                    (prev (node-prev dest) :exit-if-null)
 128                    (block (ctran-block prev))
 129                    (component (block-component block)))
 130           (when (typep dest 'cif)
 131             (setf (block-test-modified block) t))
 132           (setf (block-reoptimize block) t)
 133           (setf (component-reoptimize component) t))))
 134     (do-uses (node lvar)
 135       (setf (block-type-check (node-block node)) t)))
 136   (values))
 137
 138 (defun reoptimize-lvar-uses (lvar)
 139   (declare (type lvar lvar))
 140   (do-uses (use lvar)
 141     (setf (node-reoptimize use) t)
 142     (setf (block-reoptimize (node-block use)) t)
 143     (setf (component-reoptimize (node-component use)) t)))
 144
 145 ;;; Annotate NODE to indicate that its result has been proven to be
 146 ;;; TYPEP to RTYPE. After IR1 conversion has happened, this is the
 147 ;;; only correct way to supply information discovered about a node's
 148 ;;; type. If you screw with the NODE-DERIVED-TYPE directly, then
 149 ;;; information may be lost and reoptimization may not happen.
 150 ;;;
 151 ;;; What we do is intersect RTYPE with NODE's DERIVED-TYPE. If the
 152 ;;; intersection is different from the old type, then we do a
 153 ;;; REOPTIMIZE-LVAR on the NODE-LVAR.
 154 (defun derive-node-type (node rtype)
 155   (declare (type valued-node node) (type ctype rtype))
 156   (let ((node-type (node-derived-type node)))
 157     (unless (eq node-type rtype)
 158       (let ((int (values-type-intersection node-type rtype))
 159             (lvar (node-lvar node)))
 160         (when (type/= node-type int)
 161           (when (and *check-consistency*
 162                      (eq int *empty-type*)
 163                      (not (eq rtype *empty-type*)))
 164             (let ((*compiler-error-context* node))
 165               (compiler-warn
 166                "New inferred type ~S conflicts with old type:~
 167                 ~%  ~S~%*** possible internal error? Please report this."
 168                (type-specifier rtype) (type-specifier node-type))))
 169           (setf (node-derived-type node) int)
 170           ;; If the new type consists of only one object, replace the
 171           ;; node with a constant reference.
 172           (when (and (ref-p node)
 173                      (lambda-var-p (ref-leaf node)))
 174             (let ((type (single-value-type int)))
 175               (when (and (member-type-p type)
 176                          (null (rest (member-type-members type))))
 177                 (change-ref-leaf node (find-constant
 178                                        (first (member-type-members type)))))))
 179           (reoptimize-lvar lvar)))))
 180   (values))
 181
 182 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 183 ;;; error for LVAR's value not to be TYPEP to TYPE. We implement it
 184 ;;; splitting off DEST a new CAST node; old LVAR will deliver values
 185 ;;; to CAST. If we improve the assertion, we set TYPE-CHECK and
 186 ;;; TYPE-ASSERTED to guarantee that the new assertion will be checked.
 187 (defun assert-lvar-type (lvar type policy)
 188   (declare (type lvar lvar) (type ctype type))
 189   (unless (values-subtypep (lvar-derived-type lvar) type)
 190     (let* ((dest (lvar-dest lvar))
 191            (ctran (node-prev dest)))
 192       (with-ir1-environment-from-node dest
 193         (let* ((cast (make-cast lvar type policy))
 194                (internal-lvar (make-lvar))
 195                (internal-ctran (make-ctran)))
 196           (setf (ctran-next ctran) cast
 197                 (node-prev cast) ctran)
 198           (use-continuation cast internal-ctran internal-lvar)
 199           (link-node-to-previous-ctran dest internal-ctran)
 200           (substitute-lvar internal-lvar lvar)
 201           (setf (lvar-dest lvar) cast)
 202           (reoptimize-lvar lvar)
 203           (when (return-p dest)
 204             (node-ends-block cast))
 205           (setf (block-attributep (block-flags (node-block cast))
 206                                   type-check type-asserted)
 207                 t))))))
 208
 209 \f
 210 ;;;; IR1-OPTIMIZE
 211
 212 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 213 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 214 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 215 ;;; we are done, then another iteration would be beneficial.
 216 (defun ir1-optimize (component)
 217   (declare (type component component))
 218   (setf (component-reoptimize component) nil)
 219   (loop with block = (block-next (component-head component))
 220         with tail = (component-tail component)
 221         for last-block = block
 222         until (eq block tail)
 223         do (cond
 224              ;; We delete blocks when there is either no predecessor or the
 225              ;; block is in a lambda that has been deleted. These blocks
 226              ;; would eventually be deleted by DFO recomputation, but doing
 227              ;; it here immediately makes the effect available to IR1
 228              ;; optimization.
 229              ((or (block-delete-p block)
 230                   (null (block-pred block)))
 231               (delete-block-lazily block)
 232               (setq block (clean-component component block)))
 233              ((eq (functional-kind (block-home-lambda block)) :deleted)
 234               ;; Preserve the BLOCK-SUCC invariant that almost every block has
 235               ;; one successor (and a block with DELETE-P set is an acceptable
 236               ;; exception).
 237               (mark-for-deletion block)
 238               (setq block (clean-component component block)))
 239              (t
 240               (loop
 241                  (let ((succ (block-succ block)))
 242                    (unless (singleton-p succ)
 243                      (return)))
 244
 245                  (let ((last (block-last block)))
 246                    (typecase last
 247                      (cif
 248                       (flush-dest (if-test last))
 249                       (when (unlink-node last)
 250                         (return)))
 251                      (exit
 252                       (when (maybe-delete-exit last)
 253                         (return)))))
 254
 255                  (unless (join-successor-if-possible block)
 256                    (return)))
 257
 258               (when (and (block-reoptimize block) (block-component block))
 259                 (aver (not (block-delete-p block)))
 260                 (ir1-optimize-block block))
 261
 262               (cond ((and (block-delete-p block) (block-component block))
 263                      (setq block (clean-component component block)))
 264                     ((and (block-flush-p block) (block-component block))
 265                      (flush-dead-code block)))))
 266         do (when (eq block last-block)
 267              (setq block (block-next block))))
 268
 269   (values))
 270
 271 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 272 ;;; flags.
 273 ;;;
 274 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 275 ;;; still be set upon return from this function, meaning that further
 276 ;;; optimization is wanted (as a consequence of optimizations we did).
 277 (defun ir1-optimize-block (block)
 278   (declare (type cblock block))
 279   ;; We clear the node and block REOPTIMIZE flags before doing the
 280   ;; optimization, not after. This ensures that the node or block will
 281   ;; be reoptimized if necessary.
 282   (setf (block-reoptimize block) nil)
 283   (do-nodes (node nil block :restart-p t)
 284     (when (node-reoptimize node)
 285       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 286       (setf (node-reoptimize node) nil)
 287       (typecase node
 288         (ref)
 289         (combination
 290          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 291          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 292          ;; any argument changes.
 293          (ir1-optimize-combination node))
 294         (cif
 295          (ir1-optimize-if node))
 296         (creturn
 297          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 298          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 299          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 300          ;; CMU CL comments
 301          (setf (node-reoptimize node) t)
 302          (ir1-optimize-return node))
 303         (mv-combination
 304          (ir1-optimize-mv-combination node))
 305         (exit
 306          ;; With an EXIT, we derive the node's type from the VALUE's
 307          ;; type.
 308          (let ((value (exit-value node)))
 309            (when value
 310              (derive-node-type node (lvar-derived-type value)))))
 311         (cset
 312          (ir1-optimize-set node))
 313         (cast
 314          (ir1-optimize-cast node)))))
 315
 316   (values))
 317
 318 ;;; Try to join with a successor block. If we succeed, we return true,
 319 ;;; otherwise false.
 320 (defun join-successor-if-possible (block)
 321   (declare (type cblock block))
 322   (let ((next (first (block-succ block))))
 323     (when (block-start next)  ; NEXT is not an END-OF-COMPONENT marker
 324       (cond ( ;; We cannot combine with a successor block if:
 325              (or
 326               ;; the successor has more than one predecessor;
 327               (rest (block-pred next))
 328               ;; the successor is the current block (infinite loop);
 329               (eq next block)
 330               ;; the next block has a different cleanup, and thus
 331               ;; we may want to insert cleanup code between the
 332               ;; two blocks at some point;
 333               (not (eq (block-end-cleanup block)
 334                        (block-start-cleanup next)))
 335               ;; the next block has a different home lambda, and
 336               ;; thus the control transfer is a non-local exit.
 337               (not (eq (block-home-lambda block)
 338                        (block-home-lambda next)))
 339               ;; Stack analysis phase wants ENTRY to start a block.
 340               (entry-p (block-start-node next))
 341               (let ((last (block-last block)))
 342                 (and (valued-node-p last)
 343                      (awhen (node-lvar last)
 344                        (consp (lvar-uses it))))))
 345              nil)
 346             (t
 347              (join-blocks block next)
 348              t)))))
 349
 350 ;;; Join together two blocks. The code in BLOCK2 is moved into BLOCK1
 351 ;;; and BLOCK2 is deleted from the DFO. We combine the optimize flags
 352 ;;; for the two blocks so that any indicated optimization gets done.
 353 (defun join-blocks (block1 block2)
 354   (declare (type cblock block1 block2))
 355   (let* ((last1 (block-last block1))
 356          (last2 (block-last block2))
 357          (succ (block-succ block2))
 358          (start2 (block-start block2)))
 359     (do ((ctran start2 (node-next (ctran-next ctran))))
 360         ((not ctran))
 361       (setf (ctran-block ctran) block1))
 362
 363     (unlink-blocks block1 block2)
 364     (dolist (block succ)
 365       (unlink-blocks block2 block)
 366       (link-blocks block1 block))
 367
 368     (setf (ctran-kind start2) :inside-block)
 369     (setf (node-next last1) start2)
 370     (setf (ctran-use start2) last1)
 371     (setf (block-last block1) last2))
 372
 373   (setf (block-flags block1)
 374         (attributes-union (block-flags block1)
 375                           (block-flags block2)
 376                           (block-attributes type-asserted test-modified)))
 377
 378   (let ((next (block-next block2))
 379         (prev (block-prev block2)))
 380     (setf (block-next prev) next)
 381     (setf (block-prev next) prev))
 382
 383   (values))
 384
 385 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 386 ;;; side effects. We can delete sets of lexical variables when the set
 387 ;;; variable has no references.
 388 (defun flush-dead-code (block)
 389   (declare (type cblock block))
 390   (setf (block-flush-p block) nil)
 391   (do-nodes-backwards (node lvar block :restart-p t)
 392     (unless lvar
 393       (typecase node
 394         (ref
 395          (delete-ref node)
 396          (unlink-node node))
 397         (combination
 398          (let ((kind (combination-kind node))
 399                (info (combination-fun-info node)))
 400            (when (and (eq kind :known) (fun-info-p info))
 401              (let ((attr (fun-info-attributes info)))
 402                (when (and (not (ir1-attributep attr call))
 403                           ;; ### For now, don't delete potentially
 404                           ;; flushable calls when they have the CALL
 405                           ;; attribute. Someday we should look at the
 406                           ;; functional args to determine if they have
 407                           ;; any side effects.
 408                           (if (policy node (= safety 3))
 409                               (ir1-attributep attr flushable)
 410                               (ir1-attributep attr unsafely-flushable)))
 411                  (flush-combination node))))))
 412         (mv-combination
 413          (when (eq (basic-combination-kind node) :local)
 414            (let ((fun (combination-lambda node)))
 415              (when (dolist (var (lambda-vars fun) t)
 416                      (when (or (leaf-refs var)
 417                                (lambda-var-sets var))
 418                        (return nil)))
 419                (flush-dest (first (basic-combination-args node)))
 420                (delete-let fun)))))
 421         (exit
 422          (let ((value (exit-value node)))
 423            (when value
 424              (flush-dest value)
 425              (setf (exit-value node) nil))))
 426         (cset
 427          (let ((var (set-var node)))
 428            (when (and (lambda-var-p var)
 429                       (null (leaf-refs var)))
 430              (flush-dest (set-value node))
 431              (setf (basic-var-sets var)
 432                    (delq node (basic-var-sets var)))
 433              (unlink-node node))))
 434         (cast
 435          (unless (cast-type-check node)
 436            (flush-dest (cast-value node))
 437            (unlink-node node))))))
 438
 439   (values))
 440 \f
 441 ;;;; local call return type propagation
 442
 443 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 444 ;;; flag set. It iterates over the uses of the RESULT, looking for
 445 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 446 ;;; call, then we union its type together with the types of other such
 447 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 448 ;;; type with the RESULT's asserted type. We can make this
 449 ;;; intersection now (potentially before type checking) because this
 450 ;;; assertion on the result will eventually be checked (if
 451 ;;; appropriate.)
 452 ;;;
 453 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 454 ;;; combination, which may change the succesor of the call to be the
 455 ;;; called function, and if so, checks if the call can become an
 456 ;;; assignment. If we convert to an assignment, we abort, since the
 457 ;;; RETURN has been deleted.
 458 (defun find-result-type (node)
 459   (declare (type creturn node))
 460   (let ((result (return-result node)))
 461     (collect ((use-union *empty-type* values-type-union))
 462       (do-uses (use result)
 463         (let ((use-home (node-home-lambda use)))
 464           (cond ((or (eq (functional-kind use-home) :deleted)
 465                      (block-delete-p (node-block use))))
 466                 ((and (basic-combination-p use)
 467                       (eq (basic-combination-kind use) :local))
 468                  (aver (eq (lambda-tail-set use-home)
 469                            (lambda-tail-set (combination-lambda use))))
 470                  (when (combination-p use)
 471                    (when (nth-value 1 (maybe-convert-tail-local-call use))
 472                      (return-from find-result-type t))))
 473                 (t
 474                  (use-union (node-derived-type use))))))
 475       (let ((int
 476              ;; (values-type-intersection
 477              ;; (continuation-asserted-type result) ; FIXME -- APD, 2002-01-26
 478              (use-union)
 479               ;; )
 480               ))
 481         (setf (return-result-type node) int))))
 482   nil)
 483
 484 ;;; Do stuff to realize that something has changed about the value
 485 ;;; delivered to a return node. Since we consider the return values of
 486 ;;; all functions in the tail set to be equivalent, this amounts to
 487 ;;; bringing the entire tail set up to date. We iterate over the
 488 ;;; returns for all the functions in the tail set, reanalyzing them
 489 ;;; all (not treating NODE specially.)
 490 ;;;
 491 ;;; When we are done, we check whether the new type is different from
 492 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 493 ;;; all the lvars for references to functions in the tail set. This
 494 ;;; will cause IR1-OPTIMIZE-COMBINATION to derive the new type as the
 495 ;;; results of the calls.
 496 (defun ir1-optimize-return (node)
 497   (declare (type creturn node))
 498   (tagbody
 499    :restart
 500      (let* ((tails (lambda-tail-set (return-lambda node)))
 501             (funs (tail-set-funs tails)))
 502        (collect ((res *empty-type* values-type-union))
 503                 (dolist (fun funs)
 504                   (let ((return (lambda-return fun)))
 505                     (when return
 506                       (when (node-reoptimize return)
 507                         (setf (node-reoptimize return) nil)
 508                         (when (find-result-type return)
 509                           (go :restart)))
 510                       (res (return-result-type return)))))
 511
 512                 (when (type/= (res) (tail-set-type tails))
 513                   (setf (tail-set-type tails) (res))
 514                   (dolist (fun (tail-set-funs tails))
 515                     (dolist (ref (leaf-refs fun))
 516                       (reoptimize-lvar (node-lvar ref))))))))
 517
 518   (values))
 519 \f
 520 ;;;; IF optimization
 521
 522 ;;; If the test has multiple uses, replicate the node when possible.
 523 ;;; Also check whether the predicate is known to be true or false,
 524 ;;; deleting the IF node in favor of the appropriate branch when this
 525 ;;; is the case.
 526 (defun ir1-optimize-if (node)
 527   (declare (type cif node))
 528   (let ((test (if-test node))
 529         (block (node-block node)))
 530
 531     (when (and (eq (block-start-node block) node)
 532                (listp (lvar-uses test)))
 533       (do-uses (use test)
 534         (when (immediately-used-p test use)
 535           (convert-if-if use node)
 536           (when (not (listp (lvar-uses test))) (return)))))
 537
 538     (let* ((type (lvar-type test))
 539            (victim
 540             (cond ((constant-lvar-p test)
 541                    (if (lvar-value test)
 542                        (if-alternative node)
 543                        (if-consequent node)))
 544                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 545                    (if-alternative node))
 546                   ((type= type (specifier-type 'null))
 547                    (if-consequent node)))))
 548       (when victim
 549         (flush-dest test)
 550         (when (rest (block-succ block))
 551           (unlink-blocks block victim))
 552         (setf (component-reanalyze (node-component node)) t)
 553         (unlink-node node))))
 554   (values))
 555
 556 ;;; Create a new copy of an IF node that tests the value of the node
 557 ;;; USE. The test must have >1 use, and must be immediately used by
 558 ;;; USE. NODE must be the only node in its block (implying that
 559 ;;; block-start = if-test).
 560 ;;;
 561 ;;; This optimization has an effect semantically similar to the
 562 ;;; source-to-source transformation:
 563 ;;;    (IF (IF A B C) D E) ==>
 564 ;;;    (IF A (IF B D E) (IF C D E))
 565 ;;;
 566 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 567 ;;; node so that dead code deletion notes will definitely not consider
 568 ;;; either node to be part of the original source. One node might
 569 ;;; become unreachable, resulting in a spurious note.
 570 (defun convert-if-if (use node)
 571   (declare (type node use) (type cif node))
 572   (with-ir1-environment-from-node node
 573     (let* ((block (node-block node))
 574            (test (if-test node))
 575            (cblock (if-consequent node))
 576            (ablock (if-alternative node))
 577            (use-block (node-block use))
 578            (new-ctran (make-ctran))
 579            (new-lvar (make-lvar))
 580            (new-node (make-if :test new-lvar
 581                               :consequent cblock
 582                               :alternative ablock))
 583            (new-block (ctran-starts-block new-ctran)))
 584       (link-node-to-previous-ctran new-node new-ctran)
 585       (setf (lvar-dest new-lvar) new-node)
 586       (setf (block-last new-block) new-node)
 587
 588       (unlink-blocks use-block block)
 589       (%delete-lvar-use use)
 590       (add-lvar-use use new-lvar)
 591       (link-blocks use-block new-block)
 592
 593       (link-blocks new-block cblock)
 594       (link-blocks new-block ablock)
 595
 596       (push "<IF Duplication>" (node-source-path node))
 597       (push "<IF Duplication>" (node-source-path new-node))
 598
 599       (reoptimize-lvar test)
 600       (reoptimize-lvar new-lvar)
 601       (setf (component-reanalyze *current-component*) t)))
 602   (values))
 603 \f
 604 ;;;; exit IR1 optimization
 605
 606 ;;; This function attempts to delete an exit node, returning true if
 607 ;;; it deletes the block as a consequence:
 608 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 609 ;;;    anything, since there is nothing to be done.
 610 ;;; -- If the exit node and its ENTRY have the same home lambda then
 611 ;;;    we know the exit is local, and can delete the exit. We change
 612 ;;;    uses of the Exit-Value to be uses of the original lvar,
 613 ;;;    then unlink the node. If the exit is to a TR context, then we
 614 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 615 ;;;    their value to this exit.
 616 ;;; -- If there is no value (as in a GO), then we skip the value
 617 ;;;    semantics.
 618 ;;;
 619 ;;; This function is also called by environment analysis, since it
 620 ;;; wants all exits to be optimized even if normal optimization was
 621 ;;; omitted.
 622 (defun maybe-delete-exit (node)
 623   (declare (type exit node))
 624   (let ((value (exit-value node))
 625         (entry (exit-entry node)))
 626     (when (and entry
 627                (eq (node-home-lambda node) (node-home-lambda entry)))
 628       (setf (entry-exits entry) (delq node (entry-exits entry)))
 629       (if value
 630           (delete-filter node (node-lvar node) value)
 631           (unlink-node node)))))
 632
 633 \f
 634 ;;;; combination IR1 optimization
 635
 636 ;;; Report as we try each transform?
 637 #!+sb-show
 638 (defvar *show-transforms-p* nil)
 639
 640 ;;; Do IR1 optimizations on a COMBINATION node.
 641 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 642 (defun ir1-optimize-combination (node)
 643   (when (lvar-reoptimize (basic-combination-fun node))
 644     (propagate-fun-change node)
 645     (maybe-terminate-block node nil))
 646   (let ((args (basic-combination-args node))
 647         (kind (basic-combination-kind node))
 648         (info (basic-combination-fun-info node)))
 649     (ecase kind
 650       (:local
 651        (let ((fun (combination-lambda node)))
 652          (if (eq (functional-kind fun) :let)
 653              (propagate-let-args node fun)
 654              (propagate-local-call-args node fun))))
 655       (:error
 656        (dolist (arg args)
 657          (when arg
 658            (setf (lvar-reoptimize arg) nil))))
 659       (:full
 660        (dolist (arg args)
 661          (when arg
 662            (setf (lvar-reoptimize arg) nil)))
 663        (when info
 664          (let ((fun (fun-info-derive-type info)))
 665            (when fun
 666              (let ((res (funcall fun node)))
 667                (when res
 668                  (derive-node-type node (coerce-to-values res))
 669                  (maybe-terminate-block node nil)))))))
 670       (:known
 671        (aver info)
 672        (dolist (arg args)
 673          (when arg
 674            (setf (lvar-reoptimize arg) nil)))
 675
 676        (let ((attr (fun-info-attributes info)))
 677          (when (and (ir1-attributep attr foldable)
 678                     ;; KLUDGE: The next test could be made more sensitive,
 679                     ;; only suppressing constant-folding of functions with
 680                     ;; CALL attributes when they're actually passed
 681                     ;; function arguments. -- WHN 19990918
 682                     (not (ir1-attributep attr call))
 683                     (every #'constant-lvar-p args)
 684                     (node-lvar node)
 685                     ;; Even if the function is foldable in principle,
 686                     ;; it might be one of our low-level
 687                     ;; implementation-specific functions. Such
 688                     ;; functions don't necessarily exist at runtime on
 689                     ;; a plain vanilla ANSI Common Lisp
 690                     ;; cross-compilation host, in which case the
 691                     ;; cross-compiler can't fold it because the
 692                     ;; cross-compiler doesn't know how to evaluate it.
 693                     #+sb-xc-host
 694                     (or (fboundp (combination-fun-source-name node))
 695                         (progn (format t ";;; !!! Unbound fun: (~S~{ ~S~})~%"
 696                                        (combination-fun-source-name node)
 697                                        (mapcar #'lvar-value args))
 698                                nil)))
 699            (constant-fold-call node)
 700            (return-from ir1-optimize-combination)))
 701
 702        (let ((fun (fun-info-derive-type info)))
 703          (when fun
 704            (let ((res (funcall fun node)))
 705              (when res
 706                (derive-node-type node (coerce-to-values res))
 707                (maybe-terminate-block node nil)))))
 708
 709        (let ((fun (fun-info-optimizer info)))
 710          (unless (and fun (funcall fun node))
 711            (dolist (x (fun-info-transforms info))
 712              #!+sb-show
 713              (when *show-transforms-p*
 714                (let* ((lvar (basic-combination-fun node))
 715                       (fname (lvar-fun-name lvar t)))
 716                  (/show "trying transform" x (transform-function x) "for" fname)))
 717              (unless (ir1-transform node x)
 718                #!+sb-show
 719                (when *show-transforms-p*
 720                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 721                (return))))))))
 722
 723   (values))
 724
 725 ;;; If NODE doesn't return (i.e. return type is NIL), then terminate
 726 ;;; the block there, and link it to the component tail.
 727 ;;;
 728 ;;; Except when called during IR1 convertion, we delete the
 729 ;;; continuation if it has no other uses. (If it does have other uses,
 730 ;;; we reoptimize.)
 731 ;;;
 732 ;;; Termination on the basis of a continuation type is
 733 ;;; inhibited when:
 734 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 735 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 736 ;;;    weakening.) FIXME: Now THE assertions are not weakened, but new
 737 ;;;    uses can(?) be added later. -- APD, 2003-07-17
 738 ;;;
 739 ;;; Why do we need to consider LVAR type? -- APD, 2003-07-30
 740 (defun maybe-terminate-block (node ir1-converting-not-optimizing-p)
 741   (declare (type (or basic-combination cast) node))
 742   (let* ((block (node-block node))
 743          (lvar (node-lvar node))
 744          (ctran (node-next node))
 745          (tail (component-tail (block-component block)))
 746          (succ (first (block-succ block))))
 747     (declare (ignore lvar))
 748     (unless (or (and (eq node (block-last block)) (eq succ tail))
 749                 (block-delete-p block))
 750       (when (eq (node-derived-type node) *empty-type*)
 751         (cond (ir1-converting-not-optimizing-p
 752                (cond
 753                  ((block-last block)
 754                   (aver (eq (block-last block) node)))
 755                  (t
 756                   (setf (block-last block) node)
 757                   (setf (ctran-use ctran) nil)
 758                   (setf (ctran-kind ctran) :unused)
 759                   (setf (ctran-block ctran) nil)
 760                   (setf (node-next node) nil)
 761                   (link-blocks block (ctran-starts-block ctran)))))
 762               (t
 763                (node-ends-block node)))
 764
 765         (unlink-blocks block (first (block-succ block)))
 766         (setf (component-reanalyze (block-component block)) t)
 767         (aver (not (block-succ block)))
 768         (link-blocks block tail)
 769         (if ir1-converting-not-optimizing-p
 770             (%delete-lvar-use node)
 771             (delete-lvar-use node))
 772         t))))
 773
 774 ;;; This is called both by IR1 conversion and IR1 optimization when
 775 ;;; they have verified the type signature for the call, and are
 776 ;;; wondering if something should be done to special-case the call. If
 777 ;;; CALL is a call to a global function, then see whether it defined
 778 ;;; or known:
 779 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 780 ;;;    the expansion and change the call to call it. Expansion is
 781 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 782 ;;;    true, we never expand, since this function has already been
 783 ;;;    converted. Local call analysis will duplicate the definition
 784 ;;;    if necessary. We claim that the parent form is LABELS for
 785 ;;;    context declarations, since we don't want it to be considered
 786 ;;;    a real global function.
 787 ;;; -- If it is a known function, mark it as such by setting the KIND.
 788 ;;;
 789 ;;; We return the leaf referenced (NIL if not a leaf) and the
 790 ;;; FUN-INFO assigned.
 791 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 792   (declare (type combination call))
 793   (let* ((ref (lvar-uses (basic-combination-fun call)))
 794          (leaf (when (ref-p ref) (ref-leaf ref)))
 795          (inlinep (if (defined-fun-p leaf)
 796                       (defined-fun-inlinep leaf)
 797                       :no-chance)))
 798     (cond
 799      ((eq inlinep :notinline)
 800       (let ((info (info :function :info (leaf-source-name leaf))))
 801         (when info
 802           (setf (basic-combination-fun-info call) info))
 803         (values nil nil)))
 804      ((not (and (global-var-p leaf)
 805                 (eq (global-var-kind leaf) :global-function)))
 806       (values leaf nil))
 807      ((and (ecase inlinep
 808              (:inline t)
 809              (:no-chance nil)
 810              ((nil :maybe-inline) (policy call (zerop space))))
 811            (defined-fun-p leaf)
 812            (defined-fun-inline-expansion leaf)
 813            (let ((fun (defined-fun-functional leaf)))
 814              (or (not fun)
 815                  (and (eq inlinep :inline) (functional-kind fun))))
 816            (inline-expansion-ok call))
 817       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 818              ;; called semi-inlining? A more descriptive name would
 819              ;; be nice. -- WHN 2002-01-07
 820              (frob ()
 821                (let ((res (ir1-convert-lambda-for-defun
 822                            (defined-fun-inline-expansion leaf)
 823                            leaf t
 824                            #'ir1-convert-inline-lambda)))
 825                  (setf (defined-fun-functional leaf) res)
 826                  (change-ref-leaf ref res))))
 827         (if ir1-converting-not-optimizing-p
 828             (frob)
 829             (with-ir1-environment-from-node call
 830               (frob)
 831               (locall-analyze-component *current-component*))))
 832
 833       (values (ref-leaf (lvar-uses (basic-combination-fun call)))
 834               nil))
 835      (t
 836       (let ((info (info :function :info (leaf-source-name leaf))))
 837         (if info
 838             (values leaf
 839                     (progn
 840                       (setf (basic-combination-kind call) :known)
 841                       (setf (basic-combination-fun-info call) info)))
 842             (values leaf nil)))))))
 843
 844 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 845 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 846 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 847 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 848 ;;; syntax check, arg/result type processing, but still call
 849 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 850 ;;; and that checking is done by local call analysis.
 851 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 852   (declare (type combination call) (type ctype type))
 853   (cond ((not (fun-type-p type))
 854          (aver (multiple-value-bind (val win)
 855                    (csubtypep type (specifier-type 'function))
 856                  (or val (not win))))
 857          (recognize-known-call call ir1-converting-not-optimizing-p))
 858         ((valid-fun-use call type
 859                         :argument-test #'always-subtypep
 860                         :result-test nil
 861                         ;; KLUDGE: Common Lisp is such a dynamic
 862                         ;; language that all we can do here in
 863                         ;; general is issue a STYLE-WARNING. It
 864                         ;; would be nice to issue a full WARNING
 865                         ;; in the special case of of type
 866                         ;; mismatches within a compilation unit
 867                         ;; (as in section 3.2.2.3 of the spec)
 868                         ;; but at least as of sbcl-0.6.11, we
 869                         ;; don't keep track of whether the
 870                         ;; mismatched data came from the same
 871                         ;; compilation unit, so we can't do that.
 872                         ;; -- WHN 2001-02-11
 873                         ;;
 874                         ;; FIXME: Actually, I think we could
 875                         ;; issue a full WARNING if the call
 876                         ;; violates a DECLAIM FTYPE.
 877                         :lossage-fun #'compiler-style-warn
 878                         :unwinnage-fun #'compiler-notify)
 879          (assert-call-type call type)
 880          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 881          (recognize-known-call call ir1-converting-not-optimizing-p))
 882         (t
 883          (setf (combination-kind call) :error)
 884          (values nil nil))))
 885
 886 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 887 ;;; changed. If the call is local, we try to LET-convert it, and
 888 ;;; derive the result type. If it is a :FULL call, we validate it
 889 ;;; against the type, which recognizes known calls, does inline
 890 ;;; expansion, etc. If a call to a predicate in a non-conditional
 891 ;;; position or to a function with a source transform, then we
 892 ;;; reconvert the form to give IR1 another chance.
 893 (defun propagate-fun-change (call)
 894   (declare (type combination call))
 895   (let ((*compiler-error-context* call)
 896         (fun-lvar (basic-combination-fun call)))
 897     (setf (lvar-reoptimize fun-lvar) nil)
 898     (case (combination-kind call)
 899       (:local
 900        (let ((fun (combination-lambda call)))
 901          (maybe-let-convert fun)
 902          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 903            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 904       (:full
 905        (multiple-value-bind (leaf info)
 906            (validate-call-type call (lvar-type fun-lvar) nil)
 907          (cond ((functional-p leaf)
 908                 (convert-call-if-possible
 909                  (lvar-uses (basic-combination-fun call))
 910                  call))
 911                ((not leaf))
 912                ((and (global-var-p leaf)
 913                      (eq (global-var-kind leaf) :global-function)
 914                      (leaf-has-source-name-p leaf)
 915                      (or (info :function :source-transform (leaf-source-name leaf))
 916                          (and info
 917                               (ir1-attributep (fun-info-attributes info)
 918                                               predicate)
 919                               (let ((lvar (node-lvar call)))
 920                                 (and lvar (not (if-p (lvar-dest lvar))))))))
 921                 (let ((name (leaf-source-name leaf))
 922                       (dummies (make-gensym-list
 923                                 (length (combination-args call)))))
 924                   (transform-call call
 925                                   `(lambda ,dummies
 926                                      (,@(if (symbolp name)
 927                                             `(,name)
 928                                             `(funcall #',name))
 929                                         ,@dummies))
 930                                   (leaf-source-name leaf)))))))))
 931   (values))
 932 \f
 933 ;;;; known function optimization
 934
 935 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
 936 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
 937 ;;; replace it, otherwise add a new one.
 938 (defun record-optimization-failure (node transform args)
 939   (declare (type combination node) (type transform transform)
 940            (type (or fun-type list) args))
 941   (let* ((table (component-failed-optimizations *component-being-compiled*))
 942          (found (assoc transform (gethash node table))))
 943     (if found
 944         (setf (cdr found) args)
 945         (push (cons transform args) (gethash node table))))
 946   (values))
 947
 948 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
 949 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
 950 ;;; doing the transform for some reason and FLAME is true, then we
 951 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
 952 ;;; finalize to pick up. We return true if the transform failed, and
 953 ;;; thus further transformation should be attempted. We return false
 954 ;;; if either the transform succeeded or was aborted.
 955 (defun ir1-transform (node transform)
 956   (declare (type combination node) (type transform transform))
 957   (let* ((type (transform-type transform))
 958          (fun (transform-function transform))
 959          (constrained (fun-type-p type))
 960          (table (component-failed-optimizations *component-being-compiled*))
 961          (flame (if (transform-important transform)
 962                     (policy node (>= speed inhibit-warnings))
 963                     (policy node (> speed inhibit-warnings))))
 964          (*compiler-error-context* node))
 965     (cond ((or (not constrained)
 966                (valid-fun-use node type))
 967            (multiple-value-bind (severity args)
 968                (catch 'give-up-ir1-transform
 969                  (transform-call node
 970                                  (funcall fun node)
 971                                  (combination-fun-source-name node))
 972                  (values :none nil))
 973              (ecase severity
 974                (:none
 975                 (remhash node table)
 976                 nil)
 977                (:aborted
 978                 (setf (combination-kind node) :error)
 979                 (when args
 980                   (apply #'warn args))
 981                 (remhash node table)
 982                 nil)
 983                (:failure
 984                 (if args
 985                     (when flame
 986                       (record-optimization-failure node transform args))
 987                     (setf (gethash node table)
 988                           (remove transform (gethash node table) :key #'car)))
 989                 t)
 990                (:delayed
 991                  (remhash node table)
 992                  nil))))
 993           ((and flame
 994                 (valid-fun-use node
 995                                type
 996                                :argument-test #'types-equal-or-intersect
 997                                :result-test #'values-types-equal-or-intersect))
 998            (record-optimization-failure node transform type)
 999            t)
1000           (t
1001            t))))
1002
1003 ;;; When we don't like an IR1 transform, we throw the severity/reason
1004 ;;; and args.
1005 ;;;
1006 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1007 ;;; aborting this attempt to transform the call, but admitting the
1008 ;;; possibility that this or some other transform will later succeed.
1009 ;;; If arguments are supplied, they are format arguments for an
1010 ;;; efficiency note.
1011 ;;;
1012 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1013 ;;; force a normal call to the function at run time. No further
1014 ;;; optimizations will be attempted.
1015 ;;;
1016 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1017 ;;; delay the transform on the node until later. REASONS specifies
1018 ;;; when the transform will be later retried. The :OPTIMIZE reason
1019 ;;; causes the transform to be delayed until after the current IR1
1020 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1021 ;;; be delayed until after constraint propagation.
1022 ;;;
1023 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1024 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1025 ;;; do CASE operations on the various REASON values, it might be a
1026 ;;; good idea to go OO, representing the reasons by objects, using
1027 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1028 ;;; SIGNAL instead of THROW.
1029 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1030 (defun give-up-ir1-transform (&rest args)
1031   (throw 'give-up-ir1-transform (values :failure args)))
1032 (defun abort-ir1-transform (&rest args)
1033   (throw 'give-up-ir1-transform (values :aborted args)))
1034 (defun delay-ir1-transform (node &rest reasons)
1035   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1036     (cond ((not assoc)
1037             (setf *delayed-ir1-transforms*
1038                     (acons node reasons *delayed-ir1-transforms*))
1039             (throw 'give-up-ir1-transform :delayed))
1040           ((cdr assoc)
1041             (dolist (reason reasons)
1042               (pushnew reason (cdr assoc)))
1043             (throw 'give-up-ir1-transform :delayed)))))
1044
1045 ;;; Clear any delayed transform with no reasons - these should have
1046 ;;; been tried in the last pass. Then remove the reason from the
1047 ;;; delayed transform reasons, and if any become empty then set
1048 ;;; reoptimize flags for the node. Return true if any transforms are
1049 ;;; to be retried.
1050 (defun retry-delayed-ir1-transforms (reason)
1051   (setf *delayed-ir1-transforms*
1052         (remove-if-not #'cdr *delayed-ir1-transforms*))
1053   (let ((reoptimize nil))
1054     (dolist (assoc *delayed-ir1-transforms*)
1055       (let ((reasons (remove reason (cdr assoc))))
1056         (setf (cdr assoc) reasons)
1057         (unless reasons
1058           (let ((node (car assoc)))
1059             (unless (node-deleted node)
1060               (setf reoptimize t)
1061               (setf (node-reoptimize node) t)
1062               (let ((block (node-block node)))
1063                 (setf (block-reoptimize block) t)
1064                 (setf (component-reoptimize (block-component block)) t)))))))
1065     reoptimize))
1066
1067 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1068 ;;; environment, and then install it as the function for the call
1069 ;;; NODE. We do local call analysis so that the new function is
1070 ;;; integrated into the control flow.
1071 ;;;
1072 ;;; We require the original function source name in order to generate
1073 ;;; a meaningful debug name for the lambda we set up. (It'd be
1074 ;;; possible to do this starting from debug names as well as source
1075 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1076 ;;; generality, since source names are always known to our callers.)
1077 (defun transform-call (call res source-name)
1078   (declare (type combination call) (list res))
1079   (aver (and (legal-fun-name-p source-name)
1080              (not (eql source-name '.anonymous.))))
1081   (node-ends-block call)
1082   (with-ir1-environment-from-node call
1083     (with-component-last-block (*current-component*
1084                                 (block-next (node-block call)))
1085       (let ((new-fun (ir1-convert-inline-lambda
1086                       res
1087                       :debug-name (debug-namify "LAMBDA-inlined "
1088                                                 source-name
1089                                                 "<unknown function>")))
1090             (ref (lvar-use (combination-fun call))))
1091         (change-ref-leaf ref new-fun)
1092         (setf (combination-kind call) :full)
1093         (locall-analyze-component *current-component*))))
1094   (values))
1095
1096 ;;; Replace a call to a foldable function of constant arguments with
1097 ;;; the result of evaluating the form. If there is an error during the
1098 ;;; evaluation, we give a warning and leave the call alone, making the
1099 ;;; call a :ERROR call.
1100 ;;;
1101 ;;; If there is more than one value, then we transform the call into a
1102 ;;; VALUES form.
1103 (defun constant-fold-call (call)
1104   (let ((args (mapcar #'lvar-value (combination-args call)))
1105         (fun-name (combination-fun-source-name call)))
1106     (multiple-value-bind (values win)
1107         (careful-call fun-name
1108                       args
1109                       call
1110                       ;; Note: CMU CL had COMPILER-WARN here, and that
1111                       ;; seems more natural, but it's probably not.
1112                       ;;
1113                       ;; It's especially not while bug 173 exists:
1114                       ;; Expressions like
1115                       ;;   (COND (END
1116                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1117                       ;;            ...))
1118                       ;; can cause constant-folding TYPE-ERRORs (in
1119                       ;; #'<=) when END can be proved to be NIL, even
1120                       ;; though the code is perfectly legal and safe
1121                       ;; because a NIL value of END means that the
1122                       ;; #'<= will never be executed.
1123                       ;;
1124                       ;; Moreover, even without bug 173,
1125                       ;; quite-possibly-valid code like
1126                       ;;   (COND ((NONINLINED-PREDICATE END)
1127                       ;;          (UNLESS (<= END SIZE))
1128                       ;;            ...))
1129                       ;; (where NONINLINED-PREDICATE is something the
1130                       ;; compiler can't do at compile time, but which
1131                       ;; turns out to make the #'<= expression
1132                       ;; unreachable when END=NIL) could cause errors
1133                       ;; when the compiler tries to constant-fold (<=
1134                       ;; END SIZE).
1135                       ;;
1136                       ;; So, with or without bug 173, it'd be
1137                       ;; unnecessarily evil to do a full
1138                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1139                       ;; from COMPILE-FILE) for legal code, so we we
1140                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1141                       #'compiler-style-warn
1142                       "constant folding")
1143       (cond ((not win)
1144              (setf (combination-kind call) :error))
1145             ((and (proper-list-of-length-p values 1))
1146              (with-ir1-environment-from-node call
1147                (let* ((lvar (node-lvar call))
1148                       (prev (node-prev call))
1149                       (intermediate-ctran (make-ctran)))
1150                  (%delete-lvar-use call)
1151                  (setf (ctran-next prev) nil)
1152                  (setf (node-prev call) nil)
1153                  (reference-constant prev intermediate-ctran lvar
1154                                      (first values))
1155                  (link-node-to-previous-ctran call intermediate-ctran)
1156                  (reoptimize-lvar lvar)
1157                  (flush-combination call))))
1158             (t (let ((dummies (make-gensym-list (length args))))
1159                  (transform-call
1160                   call
1161                   `(lambda ,dummies
1162                      (declare (ignore ,@dummies))
1163                      (values ,@(mapcar (lambda (x) `',x) values)))
1164                   fun-name))))))
1165   (values))
1166 \f
1167 ;;;; local call optimization
1168
1169 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1170 ;;; the leaf type is a function type, then just leave it alone, since
1171 ;;; TYPE is never going to be more specific than that (and
1172 ;;; TYPE-INTERSECTION would choke.)
1173 (defun propagate-to-refs (leaf type)
1174   (declare (type leaf leaf) (type ctype type))
1175   (let ((var-type (leaf-type leaf)))
1176     (unless (fun-type-p var-type)
1177       (let ((int (type-approx-intersection2 var-type type)))
1178         (when (type/= int var-type)
1179           (setf (leaf-type leaf) int)
1180           (dolist (ref (leaf-refs leaf))
1181             (derive-node-type ref (make-single-value-type int))
1182             ;; KLUDGE: LET var substitution
1183             (let* ((lvar (node-lvar ref)))
1184               (when (and lvar (combination-p (lvar-dest lvar)))
1185                 (reoptimize-lvar lvar))))))
1186       (values))))
1187
1188 ;;; Iteration variable: exactly one SETQ of the form:
1189 ;;;
1190 ;;; (let ((var initial))
1191 ;;;   ...
1192 ;;;   (setq var (+ var step))
1193 ;;;   ...)
1194 (defun maybe-infer-iteration-var-type (var initial-type)
1195   (binding* ((sets (lambda-var-sets var) :exit-if-null)
1196              (set (first sets))
1197              (() (null (rest sets)) :exit-if-null)
1198              (set-use (principal-lvar-use (set-value set)))
1199              (() (and (combination-p set-use)
1200                       (eq (combination-kind set-use) :known)
1201                       (fun-info-p (combination-fun-info set-use))
1202                       (not (node-to-be-deleted-p set-use))
1203                       (eq (combination-fun-source-name set-use) '+))
1204                :exit-if-null)
1205              (+-args (basic-combination-args set-use))
1206              (() (and (proper-list-of-length-p +-args 2 2)
1207                       (let ((first (principal-lvar-use
1208                                     (first +-args))))
1209                         (and (ref-p first)
1210                              (eq (ref-leaf first) var))))
1211                :exit-if-null)
1212              (step-type (lvar-type (second +-args)))
1213              (set-type (lvar-type (set-value set))))
1214     (when (and (numeric-type-p initial-type)
1215                (numeric-type-p step-type)
1216                (numeric-type-equal initial-type step-type))
1217       (multiple-value-bind (low high)
1218           (cond ((csubtypep step-type (specifier-type '(real 0 *)))
1219                  (values (numeric-type-low initial-type)
1220                          (when (and (numeric-type-p set-type)
1221                                     (numeric-type-equal set-type initial-type))
1222                            (numeric-type-high set-type))))
1223                 ((csubtypep step-type (specifier-type '(real * 0)))
1224                  (values (when (and (numeric-type-p set-type)
1225                                     (numeric-type-equal set-type initial-type))
1226                            (numeric-type-low set-type))
1227                          (numeric-type-high initial-type)))
1228                 (t
1229                  (values nil nil)))
1230         (modified-numeric-type initial-type
1231                                :low low
1232                                :high high
1233                                :enumerable nil)))))
1234 (deftransform + ((x y) * * :result result)
1235   "check for iteration variable reoptimization"
1236   (let ((dest (principal-lvar-end result))
1237         (use (principal-lvar-use x)))
1238     (when (and (ref-p use)
1239                (set-p dest)
1240                (eq (ref-leaf use)
1241                    (set-var dest)))
1242       (reoptimize-lvar (set-value dest))))
1243   (give-up-ir1-transform))
1244
1245 ;;; Figure out the type of a LET variable that has sets. We compute
1246 ;;; the union of the INITIAL-TYPE and the types of all the set
1247 ;;; values and to a PROPAGATE-TO-REFS with this type.
1248 (defun propagate-from-sets (var initial-type)
1249   (collect ((res initial-type type-union))
1250     (dolist (set (basic-var-sets var))
1251       (let ((type (lvar-type (set-value set))))
1252         (res type)
1253         (when (node-reoptimize set)
1254           (derive-node-type set (make-single-value-type type))
1255           (setf (node-reoptimize set) nil))))
1256     (let ((res (res)))
1257       (awhen (maybe-infer-iteration-var-type var initial-type)
1258         (setq res it))
1259       (propagate-to-refs var res)))
1260   (values))
1261
1262 ;;; If a LET variable, find the initial value's type and do
1263 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1264 ;;; type.
1265 (defun ir1-optimize-set (node)
1266   (declare (type cset node))
1267   (let ((var (set-var node)))
1268     (when (and (lambda-var-p var) (leaf-refs var))
1269       (let ((home (lambda-var-home var)))
1270         (when (eq (functional-kind home) :let)
1271           (let* ((initial-value (let-var-initial-value var))
1272                  (initial-type (lvar-type initial-value)))
1273             (setf (lvar-reoptimize initial-value) nil)
1274             (propagate-from-sets var initial-type))))))
1275
1276   (derive-node-type node (make-single-value-type
1277                           (lvar-type (set-value node))))
1278   (values))
1279
1280 ;;; Return true if the value of REF will always be the same (and is
1281 ;;; thus legal to substitute.)
1282 (defun constant-reference-p (ref)
1283   (declare (type ref ref))
1284   (let ((leaf (ref-leaf ref)))
1285     (typecase leaf
1286       ((or constant functional) t)
1287       (lambda-var
1288        (null (lambda-var-sets leaf)))
1289       (defined-fun
1290        (not (eq (defined-fun-inlinep leaf) :notinline)))
1291       (global-var
1292        (case (global-var-kind leaf)
1293          (:global-function
1294           (let ((name (leaf-source-name leaf)))
1295             (or #-sb-xc-host
1296                 (eq (symbol-package (fun-name-block-name name))
1297                     *cl-package*)
1298                 (info :function :info name)))))))))
1299
1300 ;;; If we have a non-set LET var with a single use, then (if possible)
1301 ;;; replace the variable reference's LVAR with the arg lvar.
1302 ;;;
1303 ;;; We change the REF to be a reference to NIL with unused value, and
1304 ;;; let it be flushed as dead code. A side effect of this substitution
1305 ;;; is to delete the variable.
1306 (defun substitute-single-use-lvar (arg var)
1307   (declare (type lvar arg) (type lambda-var var))
1308   (binding* ((ref (first (leaf-refs var)))
1309              (lvar (node-lvar ref) :exit-if-null)
1310              (dest (lvar-dest lvar)))
1311     (when (and
1312            ;; Think about (LET ((A ...)) (IF ... A ...)): two
1313            ;; LVAR-USEs should not be met on one path.
1314            (eq (lvar-uses lvar) ref)
1315            (typecase dest
1316              ;; we should not change lifetime of unknown values lvars
1317              (cast
1318               (and (type-single-value-p (lvar-derived-type arg))
1319                    (multiple-value-bind (pdest pprev)
1320                        (principal-lvar-end lvar)
1321                      (declare (ignore pdest))
1322                      (lvar-single-value-p pprev))))
1323              (mv-combination
1324               (or (eq (basic-combination-fun dest) lvar)
1325                   (and (eq (basic-combination-kind dest) :local)
1326                        (type-single-value-p (lvar-derived-type arg)))))
1327              ((or creturn exit)
1328               ;; While CRETURN and EXIT nodes may be known-values,
1329               ;; they have their own complications, such as
1330               ;; substitution into CRETURN may create new tail calls.
1331               nil)
1332              (t
1333               (aver (lvar-single-value-p lvar))
1334               t))
1335            (eq (node-home-lambda ref)
1336                (lambda-home (lambda-var-home var))))
1337       (setf (node-derived-type ref) *wild-type*)
1338       (substitute-lvar-uses lvar arg)
1339       (delete-lvar-use ref)
1340       (change-ref-leaf ref (find-constant nil))
1341       (delete-ref ref)
1342       (unlink-node ref)
1343       (reoptimize-lvar lvar)
1344       t)))
1345
1346 ;;; Delete a LET, removing the call and bind nodes, and warning about
1347 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1348 ;;; along right away and delete the REF and then the lambda, since we
1349 ;;; flush the FUN lvar.
1350 (defun delete-let (clambda)
1351   (declare (type clambda clambda))
1352   (aver (functional-letlike-p clambda))
1353   (note-unreferenced-vars clambda)
1354   (let ((call (let-combination clambda)))
1355     (flush-dest (basic-combination-fun call))
1356     (unlink-node call)
1357     (unlink-node (lambda-bind clambda))
1358     (setf (lambda-bind clambda) nil))
1359   (setf (functional-kind clambda) :zombie)
1360   (let ((home (lambda-home clambda)))
1361     (setf (lambda-lets home) (delete clambda (lambda-lets home))))
1362   (values))
1363
1364 ;;; This function is called when one of the arguments to a LET
1365 ;;; changes. We look at each changed argument. If the corresponding
1366 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1367 ;;; consider substituting for the variable, and also propagate
1368 ;;; derived-type information for the arg to all the VAR's refs.
1369 ;;;
1370 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1371 ;;; subtype of the argument's leaf type. This prevents type checking
1372 ;;; from being defeated, and also ensures that the best representation
1373 ;;; for the variable can be used.
1374 ;;;
1375 ;;; Substitution of individual references is inhibited if the
1376 ;;; reference is in a different component from the home. This can only
1377 ;;; happen with closures over top level lambda vars. In such cases,
1378 ;;; the references may have already been compiled, and thus can't be
1379 ;;; retroactively modified.
1380 ;;;
1381 ;;; If all of the variables are deleted (have no references) when we
1382 ;;; are done, then we delete the LET.
1383 ;;;
1384 ;;; Note that we are responsible for clearing the LVAR-REOPTIMIZE
1385 ;;; flags.
1386 (defun propagate-let-args (call fun)
1387   (declare (type combination call) (type clambda fun))
1388   (loop for arg in (combination-args call)
1389         and var in (lambda-vars fun) do
1390     (when (and arg (lvar-reoptimize arg))
1391       (setf (lvar-reoptimize arg) nil)
1392       (cond
1393         ((lambda-var-sets var)
1394          (propagate-from-sets var (lvar-type arg)))
1395         ((let ((use (lvar-uses arg)))
1396            (when (ref-p use)
1397              (let ((leaf (ref-leaf use)))
1398                (when (and (constant-reference-p use)
1399                           (csubtypep (leaf-type leaf)
1400                                      ;; (NODE-DERIVED-TYPE USE) would
1401                                      ;; be better -- APD, 2003-05-15
1402                                      (leaf-type var)))
1403                  (propagate-to-refs var (lvar-type arg))
1404                  (let ((use-component (node-component use)))
1405                    (prog1 (substitute-leaf-if
1406                            (lambda (ref)
1407                              (cond ((eq (node-component ref) use-component)
1408                                     t)
1409                                    (t
1410                                     (aver (lambda-toplevelish-p (lambda-home fun)))
1411                                     nil)))
1412                            leaf var)))
1413                  t)))))
1414         ((and (null (rest (leaf-refs var)))
1415               (substitute-single-use-lvar arg var)))
1416         (t
1417          (propagate-to-refs var (lvar-type arg))))))
1418
1419   (when (every #'not (combination-args call))
1420     (delete-let fun))
1421
1422   (values))
1423
1424 ;;; This function is called when one of the args to a non-LET local
1425 ;;; call changes. For each changed argument corresponding to an unset
1426 ;;; variable, we compute the union of the types across all calls and
1427 ;;; propagate this type information to the var's refs.
1428 ;;;
1429 ;;; If the function has an XEP, then we don't do anything, since we
1430 ;;; won't discover anything.
1431 ;;;
1432 ;;; We can clear the LVAR-REOPTIMIZE flags for arguments in all calls
1433 ;;; corresponding to changed arguments in CALL, since the only use in
1434 ;;; IR1 optimization of the REOPTIMIZE flag for local call args is
1435 ;;; right here.
1436 (defun propagate-local-call-args (call fun)
1437   (declare (type combination call) (type clambda fun))
1438
1439   (unless (or (functional-entry-fun fun)
1440               (lambda-optional-dispatch fun))
1441     (let* ((vars (lambda-vars fun))
1442            (union (mapcar (lambda (arg var)
1443                             (when (and arg
1444                                        (lvar-reoptimize arg)
1445                                        (null (basic-var-sets var)))
1446                               (lvar-type arg)))
1447                           (basic-combination-args call)
1448                           vars))
1449            (this-ref (lvar-use (basic-combination-fun call))))
1450
1451       (dolist (arg (basic-combination-args call))
1452         (when arg
1453           (setf (lvar-reoptimize arg) nil)))
1454
1455       (dolist (ref (leaf-refs fun))
1456         (let ((dest (node-dest ref)))
1457           (unless (or (eq ref this-ref) (not dest))
1458             (setq union
1459                   (mapcar (lambda (this-arg old)
1460                             (when old
1461                               (setf (lvar-reoptimize this-arg) nil)
1462                               (type-union (lvar-type this-arg) old)))
1463                           (basic-combination-args dest)
1464                           union)))))
1465
1466       (loop for var in vars
1467             and type in union
1468             when type do (propagate-to-refs var type))))
1469
1470   (values))
1471 \f
1472 ;;;; multiple values optimization
1473
1474 ;;; Do stuff to notice a change to a MV combination node. There are
1475 ;;; two main branches here:
1476 ;;;  -- If the call is local, then it is already a MV let, or should
1477 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1478 ;;;     be converted to :MV-LETs, there can be a window when the call
1479 ;;;     is local, but has not been LET converted yet. This is because
1480 ;;;     the entry-point lambdas may have stray references (in other
1481 ;;;     entry points) that have not been deleted yet.
1482 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1483 ;;;     combination optimization: we propagate return type information and
1484 ;;;     notice non-returning calls. We also have an optimization
1485 ;;;     which tries to convert MV-CALLs into MV-binds.
1486 (defun ir1-optimize-mv-combination (node)
1487   (ecase (basic-combination-kind node)
1488     (:local
1489      (let ((fun-lvar (basic-combination-fun node)))
1490        (when (lvar-reoptimize fun-lvar)
1491          (setf (lvar-reoptimize fun-lvar) nil)
1492          (maybe-let-convert (combination-lambda node))))
1493      (setf (lvar-reoptimize (first (basic-combination-args node))) nil)
1494      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1495        (unless (convert-mv-bind-to-let node)
1496          (ir1-optimize-mv-bind node))))
1497     (:full
1498      (let* ((fun (basic-combination-fun node))
1499             (fun-changed (lvar-reoptimize fun))
1500             (args (basic-combination-args node)))
1501        (when fun-changed
1502          (setf (lvar-reoptimize fun) nil)
1503          (let ((type (lvar-type fun)))
1504            (when (fun-type-p type)
1505              (derive-node-type node (fun-type-returns type))))
1506          (maybe-terminate-block node nil)
1507          (let ((use (lvar-uses fun)))
1508            (when (and (ref-p use) (functional-p (ref-leaf use)))
1509              (convert-call-if-possible use node)
1510              (when (eq (basic-combination-kind node) :local)
1511                (maybe-let-convert (ref-leaf use))))))
1512        (unless (or (eq (basic-combination-kind node) :local)
1513                    (eq (lvar-fun-name fun) '%throw))
1514          (ir1-optimize-mv-call node))
1515        (dolist (arg args)
1516          (setf (lvar-reoptimize arg) nil))))
1517     (:error))
1518   (values))
1519
1520 ;;; Propagate derived type info from the values lvar to the vars.
1521 (defun ir1-optimize-mv-bind (node)
1522   (declare (type mv-combination node))
1523   (let* ((arg (first (basic-combination-args node)))
1524          (vars (lambda-vars (combination-lambda node)))
1525          (n-vars (length vars))
1526          (types (values-type-in (lvar-derived-type arg)
1527                                 n-vars)))
1528     (loop for var in vars
1529           and type in types
1530           do (if (basic-var-sets var)
1531                  (propagate-from-sets var type)
1532                  (propagate-to-refs var type)))
1533     (setf (lvar-reoptimize arg) nil))
1534   (values))
1535
1536 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1537 ;;; this if:
1538 ;;; -- The call has only one argument, and
1539 ;;; -- The function has a known fixed number of arguments, or
1540 ;;; -- The argument yields a known fixed number of values.
1541 ;;;
1542 ;;; What we do is change the function in the MV-CALL to be a lambda
1543 ;;; that "looks like an MV bind", which allows
1544 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1545 ;;; converted (the next time around.) This new lambda just calls the
1546 ;;; actual function with the MV-BIND variables as arguments. Note that
1547 ;;; this new MV bind is not let-converted immediately, as there are
1548 ;;; going to be stray references from the entry-point functions until
1549 ;;; they get deleted.
1550 ;;;
1551 ;;; In order to avoid loss of argument count checking, we only do the
1552 ;;; transformation according to a known number of expected argument if
1553 ;;; safety is unimportant. We can always convert if we know the number
1554 ;;; of actual values, since the normal call that we build will still
1555 ;;; do any appropriate argument count checking.
1556 ;;;
1557 ;;; We only attempt the transformation if the called function is a
1558 ;;; constant reference. This allows us to just splice the leaf into
1559 ;;; the new function, instead of trying to somehow bind the function
1560 ;;; expression. The leaf must be constant because we are evaluating it
1561 ;;; again in a different place. This also has the effect of squelching
1562 ;;; multiple warnings when there is an argument count error.
1563 (defun ir1-optimize-mv-call (node)
1564   (let ((fun (basic-combination-fun node))
1565         (*compiler-error-context* node)
1566         (ref (lvar-uses (basic-combination-fun node)))
1567         (args (basic-combination-args node)))
1568
1569     (unless (and (ref-p ref) (constant-reference-p ref)
1570                  (singleton-p args))
1571       (return-from ir1-optimize-mv-call))
1572
1573     (multiple-value-bind (min max)
1574         (fun-type-nargs (lvar-type fun))
1575       (let ((total-nvals
1576              (multiple-value-bind (types nvals)
1577                  (values-types (lvar-derived-type (first args)))
1578                (declare (ignore types))
1579                (if (eq nvals :unknown) nil nvals))))
1580
1581         (when total-nvals
1582           (when (and min (< total-nvals min))
1583             (compiler-warn
1584              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1585              at least ~R."
1586              total-nvals min)
1587             (setf (basic-combination-kind node) :error)
1588             (return-from ir1-optimize-mv-call))
1589           (when (and max (> total-nvals max))
1590             (compiler-warn
1591              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1592              at most ~R."
1593              total-nvals max)
1594             (setf (basic-combination-kind node) :error)
1595             (return-from ir1-optimize-mv-call)))
1596
1597         (let ((count (cond (total-nvals)
1598                            ((and (policy node (zerop verify-arg-count))
1599                                  (eql min max))
1600                             min)
1601                            (t nil))))
1602           (when count
1603             (with-ir1-environment-from-node node
1604               (let* ((dums (make-gensym-list count))
1605                      (ignore (gensym))
1606                      (fun (ir1-convert-lambda
1607                            `(lambda (&optional ,@dums &rest ,ignore)
1608                               (declare (ignore ,ignore))
1609                               (funcall ,(ref-leaf ref) ,@dums)))))
1610                 (change-ref-leaf ref fun)
1611                 (aver (eq (basic-combination-kind node) :full))
1612                 (locall-analyze-component *current-component*)
1613                 (aver (eq (basic-combination-kind node) :local)))))))))
1614   (values))
1615
1616 ;;; If we see:
1617 ;;;    (multiple-value-bind
1618 ;;;     (x y)
1619 ;;;     (values xx yy)
1620 ;;;      ...)
1621 ;;; Convert to:
1622 ;;;    (let ((x xx)
1623 ;;;       (y yy))
1624 ;;;      ...)
1625 ;;;
1626 ;;; What we actually do is convert the VALUES combination into a
1627 ;;; normal LET combination calling the original :MV-LET lambda. If
1628 ;;; there are extra args to VALUES, discard the corresponding
1629 ;;; lvars. If there are insufficient args, insert references to NIL.
1630 (defun convert-mv-bind-to-let (call)
1631   (declare (type mv-combination call))
1632   (let* ((arg (first (basic-combination-args call)))
1633          (use (lvar-uses arg)))
1634     (when (and (combination-p use)
1635                (eq (lvar-fun-name (combination-fun use))
1636                    'values))
1637       (let* ((fun (combination-lambda call))
1638              (vars (lambda-vars fun))
1639              (vals (combination-args use))
1640              (nvars (length vars))
1641              (nvals (length vals)))
1642         (cond ((> nvals nvars)
1643                (mapc #'flush-dest (subseq vals nvars))
1644                (setq vals (subseq vals 0 nvars)))
1645               ((< nvals nvars)
1646                (with-ir1-environment-from-node use
1647                  (let ((node-prev (node-prev use)))
1648                    (setf (node-prev use) nil)
1649                    (setf (ctran-next node-prev) nil)
1650                    (collect ((res vals))
1651                      (loop for count below (- nvars nvals)
1652                            for prev = node-prev then ctran
1653                            for ctran = (make-ctran)
1654                            and lvar = (make-lvar use)
1655                            do (reference-constant prev ctran lvar nil)
1656                               (res lvar)
1657                            finally (link-node-to-previous-ctran
1658                                     use ctran))
1659                      (setq vals (res)))))))
1660         (setf (combination-args use) vals)
1661         (flush-dest (combination-fun use))
1662         (let ((fun-lvar (basic-combination-fun call)))
1663           (setf (lvar-dest fun-lvar) use)
1664           (setf (combination-fun use) fun-lvar)
1665           (flush-lvar-externally-checkable-type fun-lvar))
1666         (setf (combination-kind use) :local)
1667         (setf (functional-kind fun) :let)
1668         (flush-dest (first (basic-combination-args call)))
1669         (unlink-node call)
1670         (when vals
1671           (reoptimize-lvar (first vals)))
1672         (propagate-to-args use fun)
1673         (reoptimize-call use))
1674       t)))
1675
1676 ;;; If we see:
1677 ;;;    (values-list (list x y z))
1678 ;;;
1679 ;;; Convert to:
1680 ;;;    (values x y z)
1681 ;;;
1682 ;;; In implementation, this is somewhat similar to
1683 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1684 ;;; args of the VALUES-LIST call, flushing the old argument lvar
1685 ;;; (allowing the LIST to be flushed.)
1686 ;;;
1687 ;;; FIXME: Thus we lose possible type assertions on (LIST ...).
1688 (defoptimizer (values-list optimizer) ((list) node)
1689   (let ((use (lvar-uses list)))
1690     (when (and (combination-p use)
1691                (eq (lvar-fun-name (combination-fun use))
1692                    'list))
1693
1694       ;; FIXME: VALUES might not satisfy an assertion on NODE-LVAR.
1695       (change-ref-leaf (lvar-uses (combination-fun node))
1696                        (find-free-fun 'values "in a strange place"))
1697       (setf (combination-kind node) :full)
1698       (let ((args (combination-args use)))
1699         (dolist (arg args)
1700           (setf (lvar-dest arg) node)
1701           (flush-lvar-externally-checkable-type arg))
1702         (setf (combination-args use) nil)
1703         (flush-dest list)
1704         (setf (combination-args node) args))
1705       t)))
1706
1707 ;;; If VALUES appears in a non-MV context, then effectively convert it
1708 ;;; to a PROG1. This allows the computation of the additional values
1709 ;;; to become dead code.
1710 (deftransform values ((&rest vals) * * :node node)
1711   (unless (lvar-single-value-p (node-lvar node))
1712     (give-up-ir1-transform))
1713   (setf (node-derived-type node)
1714         (make-short-values-type (list (single-value-type
1715                                        (node-derived-type node)))))
1716   (principal-lvar-single-valuify (node-lvar node))
1717   (if vals
1718       (let ((dummies (make-gensym-list (length (cdr vals)))))
1719         `(lambda (val ,@dummies)
1720            (declare (ignore ,@dummies))
1721            val))
1722       nil))
1723
1724 ;;; TODO:
1725 ;;; - CAST chains;
1726 (defun ir1-optimize-cast (cast &optional do-not-optimize)
1727   (declare (type cast cast))
1728   (let ((value (cast-value cast))
1729         (atype (cast-asserted-type cast)))
1730     (when (not do-not-optimize)
1731       (let ((lvar (node-lvar cast)))
1732         (when (values-subtypep (lvar-derived-type value)
1733                                (cast-asserted-type cast))
1734           (delete-filter cast lvar value)
1735           (when lvar
1736             (reoptimize-lvar lvar)
1737             (when (lvar-single-value-p lvar)
1738               (note-single-valuified-lvar lvar)))
1739           (return-from ir1-optimize-cast t))
1740
1741         (when (and (listp (lvar-uses value))
1742                    lvar)
1743           ;; Pathwise removing of CAST
1744           (let ((ctran (node-next cast))
1745                 (dest (lvar-dest lvar))
1746                 next-block)
1747             (collect ((merges))
1748               (do-uses (use value)
1749                 (when (and (values-subtypep (node-derived-type use) atype)
1750                            (immediately-used-p value use))
1751                   (unless next-block
1752                     (when ctran (ensure-block-start ctran))
1753                     (setq next-block (first (block-succ (node-block cast))))
1754                     (ensure-block-start (node-prev cast))
1755                     (reoptimize-lvar lvar)
1756                     (setf (lvar-%derived-type value) nil))
1757                   (%delete-lvar-use use)
1758                   (add-lvar-use use lvar)
1759                   (unlink-blocks (node-block use) (node-block cast))
1760                   (link-blocks (node-block use) next-block)
1761                   (when (and (return-p dest)
1762                              (basic-combination-p use)
1763                              (eq (basic-combination-kind use) :local))
1764                     (merges use))))
1765               (dolist (use (merges))
1766                 (merge-tail-sets use)))))))
1767
1768     (let* ((value-type (lvar-derived-type value))
1769            (int (values-type-intersection value-type atype)))
1770       (derive-node-type cast int)
1771       (when (eq int *empty-type*)
1772         (unless (eq value-type *empty-type*)
1773
1774           ;; FIXME: Do it in one step.
1775           (filter-lvar
1776            value
1777            (if (cast-single-value-p cast)
1778                `(list 'dummy)
1779                `(multiple-value-call #'list 'dummy)))
1780           (filter-lvar
1781            (cast-value cast)
1782            ;; FIXME: Derived type.
1783            `(%compile-time-type-error 'dummy
1784                                       ',(type-specifier atype)
1785                                       ',(type-specifier value-type)))
1786           ;; KLUDGE: FILTER-LVAR does not work for non-returning
1787           ;; functions, so we declare the return type of
1788           ;; %COMPILE-TIME-TYPE-ERROR to be * and derive the real type
1789           ;; here.
1790           (setq value (cast-value cast))
1791           (derive-node-type (lvar-uses value) *empty-type*)
1792           (maybe-terminate-block (lvar-uses value) nil)
1793           ;; FIXME: Is it necessary?
1794           (aver (null (block-pred (node-block cast))))
1795           (delete-block-lazily (node-block cast))
1796           (return-from ir1-optimize-cast)))
1797       (when (eq (node-derived-type cast) *empty-type*)
1798         (maybe-terminate-block cast nil))
1799
1800       (when (and (cast-%type-check cast)
1801                  (values-subtypep value-type
1802                                   (cast-type-to-check cast)))
1803         (setf (cast-%type-check cast) nil))))
1804
1805   (unless do-not-optimize
1806     (setf (node-reoptimize cast) nil)))