src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for a CONTINUATION whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-continuation-p (thing)
  24   (and (continuation-p thing)
  25        (let ((use (continuation-use thing)))
  26          (and (ref-p use)
  27               (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for a continuation whose only use is a
  30 ;;; constant node.
  31 (declaim (ftype (function (continuation) t) continuation-value))
  32 (defun continuation-value (cont)
  33   (aver (constant-continuation-p cont))
  34   (constant-value (ref-leaf (continuation-use cont))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Return a (possibly values) type that describes what we have proven
  39 ;;; about the type of Cont without taking any type assertions into
  40 ;;; consideration. This is just the union of the NODE-DERIVED-TYPE of
  41 ;;; all the uses. Most often people use CONTINUATION-DERIVED-TYPE or
  42 ;;; CONTINUATION-TYPE instead of using this function directly.
  43 (defun continuation-proven-type (cont)
  44   (declare (type continuation cont))
  45   (ecase (continuation-kind cont)
  46     ((:block-start :deleted-block-start)
  47      (let ((uses (block-start-uses (continuation-block cont))))
  48        (if uses
  49            (do ((res (node-derived-type (first uses))
  50                      (values-type-union (node-derived-type (first current))
  51                                         res))
  52                 (current (rest uses) (rest current)))
  53                ((null current) res))
  54            *empty-type*)))
  55     (:inside-block
  56      (node-derived-type (continuation-use cont)))))
  57
  58 ;;; Our best guess for the type of this continuation's value. Note
  59 ;;; that this may be VALUES or FUNCTION type, which cannot be passed
  60 ;;; as an argument to the normal type operations. See
  61 ;;; CONTINUATION-TYPE. This may be called on deleted continuations,
  62 ;;; always returning *.
  63 ;;;
  64 ;;; What we do is call CONTINUATION-PROVEN-TYPE and check whether the
  65 ;;; result is a subtype of the assertion. If so, return the proven
  66 ;;; type and set TYPE-CHECK to nil. Otherwise, return the intersection
  67 ;;; of the asserted and proven types, and set TYPE-CHECK T. If
  68 ;;; TYPE-CHECK already has a non-null value, then preserve it. Only in
  69 ;;; the somewhat unusual circumstance of a newly discovered assertion
  70 ;;; will we change TYPE-CHECK from NIL to T.
  71 ;;;
  72 ;;; The result value is cached in the CONTINUATION-%DERIVED-TYPE slot.
  73 ;;; If the slot is true, just return that value, otherwise recompute
  74 ;;; and stash the value there.
  75 #!-sb-fluid (declaim (inline continuation-derived-type))
  76 (defun continuation-derived-type (cont)
  77   (declare (type continuation cont))
  78   (or (continuation-%derived-type cont)
  79       (%continuation-derived-type cont)))
  80 (defun %continuation-derived-type (cont)
  81   (declare (type continuation cont))
  82   (let ((proven (continuation-proven-type cont))
  83         (asserted (continuation-asserted-type cont)))
  84     (cond ((values-subtypep proven asserted)
  85            (setf (continuation-%type-check cont) nil)
  86            (setf (continuation-%derived-type cont) proven))
  87           ((and (values-subtypep proven (specifier-type 'function))
  88                 (values-subtypep asserted (specifier-type 'function)))
  89            ;; It's physically impossible for a runtime type check to
  90            ;; distinguish between the various subtypes of FUNCTION, so
  91            ;; it'd be pointless to do more type checks here.
  92            (setf (continuation-%type-check cont) nil)
  93            (setf (continuation-%derived-type cont)
  94                  ;; FIXME: This should depend on optimization
  95                  ;; policy. This is for SPEED > SAFETY:
  96                  #+nil (values-type-intersection asserted proven)
  97                  ;; and this is for SAFETY >= SPEED:
  98                  #-nil proven))
  99           (t
 100            (unless (or (continuation-%type-check cont)
 101                        (not (continuation-dest cont))
 102                        (eq asserted *universal-type*))
 103              (setf (continuation-%type-check cont) t))
 104
 105            (setf (continuation-%derived-type cont)
 106                  (values-type-intersection asserted proven))))))
 107
 108 ;;; Call CONTINUATION-DERIVED-TYPE to make sure the slot is up to
 109 ;;; date, then return it.
 110 #!-sb-fluid (declaim (inline continuation-type-check))
 111 (defun continuation-type-check (cont)
 112   (declare (type continuation cont))
 113   (continuation-derived-type cont)
 114   (continuation-%type-check cont))
 115
 116 ;;; Return the derived type for CONT's first value. This is guaranteed
 117 ;;; not to be a VALUES or FUNCTION type.
 118 (declaim (ftype (function (continuation) ctype) continuation-type))
 119 (defun continuation-type (cont)
 120   (single-value-type (continuation-derived-type cont)))
 121
 122 ;;; If CONT is an argument of a function, return a type which the
 123 ;;; function checks CONT for.
 124 #!-sb-fluid (declaim (inline continuation-externally-checkable-type))
 125 (defun continuation-externally-checkable-type (cont)
 126   (or (continuation-%externally-checkable-type cont)
 127       (%continuation-%externally-checkable-type cont)))
 128 (defun %continuation-%externally-checkable-type (cont)
 129   (declare (type continuation cont))
 130   (let ((dest (continuation-dest cont)))
 131       (if (not (and dest (combination-p dest)))
 132           ;; TODO: MV-COMBINATION
 133           (setf (continuation-%externally-checkable-type cont) *wild-type*)
 134           (let* ((fun (combination-fun dest))
 135                  (args (combination-args dest))
 136                  (fun-type (continuation-type fun)))
 137             (if (or (not (fun-type-p fun-type))
 138                     ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
 139                     (fun-type-wild-args fun-type))
 140                 (progn (dolist (arg args)
 141                          (when arg
 142                            (setf (continuation-%externally-checkable-type arg)
 143                                  *wild-type*)))
 144                        *wild-type*)
 145                 (let* ((arg-types (append (fun-type-required fun-type)
 146                                           (fun-type-optional fun-type)
 147                                           (let ((rest (list (or (fun-type-rest fun-type)
 148                                                                 *wild-type*))))
 149                                             (setf (cdr rest) rest)))))
 150                   ;; TODO: &KEY
 151                   (loop
 152                      for arg of-type continuation in args
 153                      and type of-type ctype in arg-types
 154                      do (when arg
 155                           (setf (continuation-%externally-checkable-type arg)
 156                                 type)))
 157                   (continuation-%externally-checkable-type cont)))))))
 158 \f
 159 ;;;; interface routines used by optimizers
 160
 161 ;;; This function is called by optimizers to indicate that something
 162 ;;; interesting has happened to the value of Cont. Optimizers must
 163 ;;; make sure that they don't call for reoptimization when nothing has
 164 ;;; happened, since optimization will fail to terminate.
 165 ;;;
 166 ;;; We clear any cached type for the continuation and set the
 167 ;;; reoptimize flags on everything in sight, unless the continuation
 168 ;;; is deleted (in which case we do nothing.)
 169 ;;;
 170 ;;; Since this can get called during IR1 conversion, we have to be
 171 ;;; careful not to fly into space when the Dest's Prev is missing.
 172 (defun reoptimize-continuation (cont)
 173   (declare (type continuation cont))
 174   (unless (member (continuation-kind cont) '(:deleted :unused))
 175     (setf (continuation-%derived-type cont) nil)
 176     (let ((dest (continuation-dest cont)))
 177       (when dest
 178         (setf (continuation-reoptimize cont) t)
 179         (setf (node-reoptimize dest) t)
 180         (let ((prev (node-prev dest)))
 181           (when prev
 182             (let* ((block (continuation-block prev))
 183                    (component (block-component block)))
 184               (when (typep dest 'cif)
 185                 (setf (block-test-modified block) t))
 186               (setf (block-reoptimize block) t)
 187               (setf (component-reoptimize component) t))))))
 188     (do-uses (node cont)
 189       (setf (block-type-check (node-block node)) t)))
 190   (values))
 191
 192 ;;; Annotate NODE to indicate that its result has been proven to be
 193 ;;; TYPEP to RTYPE. After IR1 conversion has happened, this is the
 194 ;;; only correct way to supply information discovered about a node's
 195 ;;; type. If you screw with the NODE-DERIVED-TYPE directly, then
 196 ;;; information may be lost and reoptimization may not happen.
 197 ;;;
 198 ;;; What we do is intersect RTYPE with NODE's DERIVED-TYPE. If the
 199 ;;; intersection is different from the old type, then we do a
 200 ;;; REOPTIMIZE-CONTINUATION on the NODE-CONT.
 201 (defun derive-node-type (node rtype)
 202   (declare (type node node) (type ctype rtype))
 203   (let ((node-type (node-derived-type node)))
 204     (unless (eq node-type rtype)
 205       (let ((int (values-type-intersection node-type rtype)))
 206         (when (type/= node-type int)
 207           (when (and *check-consistency*
 208                      (eq int *empty-type*)
 209                      (not (eq rtype *empty-type*)))
 210             (let ((*compiler-error-context* node))
 211               (compiler-warn
 212                "New inferred type ~S conflicts with old type:~
 213                 ~%  ~S~%*** possible internal error? Please report this."
 214                (type-specifier rtype) (type-specifier node-type))))
 215           (setf (node-derived-type node) int)
 216           (reoptimize-continuation (node-cont node))))))
 217   (values))
 218
 219 (defun set-continuation-type-assertion (cont atype ctype)
 220   (declare (type continuation cont) (type ctype atype ctype))
 221   (when (eq atype *wild-type*)
 222     (return-from set-continuation-type-assertion))
 223   (let* ((old-atype (continuation-asserted-type cont))
 224          (old-ctype (continuation-type-to-check cont))
 225          (new-atype (values-type-intersection old-atype atype))
 226          (new-ctype (values-type-intersection old-ctype ctype)))
 227     (when (or (type/= old-atype new-atype)
 228               (type/= old-ctype new-ctype))
 229       (setf (continuation-asserted-type cont) new-atype)
 230       (setf (continuation-type-to-check cont) new-ctype)
 231       (do-uses (node cont)
 232         (setf (block-attributep (block-flags (node-block node))
 233                                 type-check type-asserted)
 234               t))
 235       (reoptimize-continuation cont)))
 236   (values))
 237
 238 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 239 ;;; error for CONT's value not to be TYPEP to TYPE. If we improve the
 240 ;;; assertion, we set TYPE-CHECK and TYPE-ASSERTED to guarantee that
 241 ;;; the new assertion will be checked.
 242 (defun assert-continuation-type (cont type policy)
 243   (declare (type continuation cont) (type ctype type))
 244   (when (eq type *wild-type*)
 245     (return-from assert-continuation-type))
 246   (set-continuation-type-assertion cont type (maybe-weaken-check type policy)))
 247
 248 ;;; Assert that CALL is to a function of the specified TYPE. It is
 249 ;;; assumed that the call is legal and has only constants in the
 250 ;;; keyword positions.
 251 (defun assert-call-type (call type)
 252   (declare (type combination call) (type fun-type type))
 253   (derive-node-type call (fun-type-returns type))
 254   (let ((args (combination-args call))
 255         (policy (lexenv-policy (node-lexenv call))))
 256     (dolist (req (fun-type-required type))
 257       (when (null args) (return-from assert-call-type))
 258       (let ((arg (pop args)))
 259         (assert-continuation-type arg req policy)))
 260     (dolist (opt (fun-type-optional type))
 261       (when (null args) (return-from assert-call-type))
 262       (let ((arg (pop args)))
 263         (assert-continuation-type arg opt policy)))
 264
 265     (let ((rest (fun-type-rest type)))
 266       (when rest
 267         (dolist (arg args)
 268           (assert-continuation-type arg rest policy))))
 269
 270     (dolist (key (fun-type-keywords type))
 271       (let ((name (key-info-name key)))
 272         (do ((arg args (cddr arg)))
 273             ((null arg))
 274           (when (eq (continuation-value (first arg)) name)
 275             (assert-continuation-type
 276              (second arg) (key-info-type key)
 277              policy))))))
 278   (values))
 279 \f
 280 ;;;; IR1-OPTIMIZE
 281
 282 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 283 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 284 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 285 ;;; we are done, then another iteration would be beneficial.
 286 (defun ir1-optimize (component)
 287   (declare (type component component))
 288   (setf (component-reoptimize component) nil)
 289   (do-blocks (block component)
 290     (cond
 291      ((or (block-delete-p block)
 292           (null (block-pred block)))
 293       (delete-block block))
 294      ((eq (functional-kind (block-home-lambda block)) :deleted)
 295       ;; Preserve the BLOCK-SUCC invariant that almost every block has
 296       ;; one successor (and a block with DELETE-P set is an acceptable
 297       ;; exception).
 298       (labels ((mark-blocks (block)
 299                  (dolist (pred (block-pred block))
 300                    (unless (or (block-delete-p pred)
 301                                (eq (component-head (block-component pred))
 302                                    pred))
 303                      (setf (block-delete-p pred) t)
 304                      (mark-blocks pred)))))
 305         (mark-blocks block)
 306         (delete-block block)))
 307      (t
 308       (loop
 309         (let ((succ (block-succ block)))
 310           (unless (and succ (null (rest succ)))
 311             (return)))
 312
 313         (let ((last (block-last block)))
 314           (typecase last
 315             (cif
 316              (flush-dest (if-test last))
 317              (when (unlink-node last)
 318                (return)))
 319             (exit
 320              (when (maybe-delete-exit last)
 321                (return)))))
 322
 323         (unless (join-successor-if-possible block)
 324           (return)))
 325
 326       (when (and (block-reoptimize block) (block-component block))
 327         (aver (not (block-delete-p block)))
 328         (ir1-optimize-block block))
 329
 330       ;; We delete blocks when there is either no predecessor or the
 331       ;; block is in a lambda that has been deleted. These blocks
 332       ;; would eventually be deleted by DFO recomputation, but doing
 333       ;; it here immediately makes the effect available to IR1
 334       ;; optimization.
 335       (when (and (block-flush-p block) (block-component block))
 336         (aver (not (block-delete-p block)))
 337         (flush-dead-code block)))))
 338
 339   (values))
 340
 341 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 342 ;;; flags.
 343 ;;;
 344 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 345 ;;; still be set upon return from this function, meaning that further
 346 ;;; optimization is wanted (as a consequence of optimizations we did).
 347 (defun ir1-optimize-block (block)
 348   (declare (type cblock block))
 349   ;; We clear the node and block REOPTIMIZE flags before doing the
 350   ;; optimization, not after. This ensures that the node or block will
 351   ;; be reoptimized if necessary.
 352   (setf (block-reoptimize block) nil)
 353   (do-nodes (node cont block :restart-p t)
 354     (when (node-reoptimize node)
 355       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 356       (setf (node-reoptimize node) nil)
 357       (typecase node
 358         (ref)
 359         (combination
 360          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 361          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 362          ;; any argument changes.
 363          (ir1-optimize-combination node))
 364         (cif
 365          (ir1-optimize-if node))
 366         (creturn
 367          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 368          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 369          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 370          ;; CMU CL comments
 371          (setf (node-reoptimize node) t)
 372          (ir1-optimize-return node))
 373         (mv-combination
 374          (ir1-optimize-mv-combination node))
 375         (exit
 376          ;; With an EXIT, we derive the node's type from the VALUE's
 377          ;; type. We don't propagate CONT's assertion to the VALUE,
 378          ;; since if we did, this would move the checking of CONT's
 379          ;; assertion to the exit. This wouldn't work with CATCH and
 380          ;; UWP, where the EXIT node is just a placeholder for the
 381          ;; actual unknown exit.
 382          (let ((value (exit-value node)))
 383            (when value
 384              (derive-node-type node (continuation-derived-type value)))))
 385         (cset
 386          (ir1-optimize-set node)))))
 387   (values))
 388
 389 ;;; Try to join with a successor block. If we succeed, we return true,
 390 ;;; otherwise false.
 391 (defun join-successor-if-possible (block)
 392   (declare (type cblock block))
 393   (let ((next (first (block-succ block))))
 394     (when (block-start next)
 395       (let* ((last (block-last block))
 396              (last-cont (node-cont last))
 397              (next-cont (block-start next)))
 398         (cond (;; We cannot combine with a successor block if:
 399                (or
 400                 ;; The successor has more than one predecessor.
 401                 (rest (block-pred next))
 402                 ;; The last node's CONT is also used somewhere else.
 403                 (not (eq (continuation-use last-cont) last))
 404                 ;; The successor is the current block (infinite loop).
 405                 (eq next block)
 406                 ;; The next block has a different cleanup, and thus
 407                 ;; we may want to insert cleanup code between the
 408                 ;; two blocks at some point.
 409                 (not (eq (block-end-cleanup block)
 410                          (block-start-cleanup next)))
 411                 ;; The next block has a different home lambda, and
 412                 ;; thus the control transfer is a non-local exit.
 413                 (not (eq (block-home-lambda block)
 414                          (block-home-lambda next))))
 415                nil)
 416               ;; Joining is easy when the successor's START
 417               ;; continuation is the same from our LAST's CONT.
 418               ((eq last-cont next-cont)
 419                (join-blocks block next)
 420                t)
 421               ;; If they differ, then we can still join when the last
 422               ;; continuation has no next and the next continuation
 423               ;; has no uses.
 424               ((and (null (block-start-uses next))
 425                     (eq (continuation-kind last-cont) :inside-block))
 426                ;; In this case, we replace the next
 427                ;; continuation with the last before joining the blocks.
 428                (let ((next-node (continuation-next next-cont)))
 429                  ;; If NEXT-CONT does have a dest, it must be
 430                  ;; unreachable, since there are no USES.
 431                  ;; DELETE-CONTINUATION will mark the dest block as
 432                  ;; DELETE-P [and also this block, unless it is no
 433                  ;; longer backward reachable from the dest block.]
 434                  (delete-continuation next-cont)
 435                  (setf (node-prev next-node) last-cont)
 436                  (setf (continuation-next last-cont) next-node)
 437                  (setf (block-start next) last-cont)
 438                  (join-blocks block next))
 439                t)
 440               (t
 441                nil))))))
 442
 443 ;;; Join together two blocks which have the same ending/starting
 444 ;;; continuation. The code in BLOCK2 is moved into BLOCK1 and BLOCK2
 445 ;;; is deleted from the DFO. We combine the optimize flags for the two
 446 ;;; blocks so that any indicated optimization gets done.
 447 (defun join-blocks (block1 block2)
 448   (declare (type cblock block1 block2))
 449   (let* ((last (block-last block2))
 450          (last-cont (node-cont last))
 451          (succ (block-succ block2))
 452          (start2 (block-start block2)))
 453     (do ((cont start2 (node-cont (continuation-next cont))))
 454         ((eq cont last-cont)
 455          (when (eq (continuation-kind last-cont) :inside-block)
 456            (setf (continuation-block last-cont) block1)))
 457       (setf (continuation-block cont) block1))
 458
 459     (unlink-blocks block1 block2)
 460     (dolist (block succ)
 461       (unlink-blocks block2 block)
 462       (link-blocks block1 block))
 463
 464     (setf (block-last block1) last)
 465     (setf (continuation-kind start2) :inside-block))
 466
 467   (setf (block-flags block1)
 468         (attributes-union (block-flags block1)
 469                           (block-flags block2)
 470                           (block-attributes type-asserted test-modified)))
 471
 472   (let ((next (block-next block2))
 473         (prev (block-prev block2)))
 474     (setf (block-next prev) next)
 475     (setf (block-prev next) prev))
 476
 477   (values))
 478
 479 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 480 ;;; side effects. We can delete sets of lexical variables when the set
 481 ;;; variable has no references.
 482 (defun flush-dead-code (block)
 483   (declare (type cblock block))
 484   (do-nodes-backwards (node cont block)
 485     (unless (continuation-dest cont)
 486       (typecase node
 487         (ref
 488          (delete-ref node)
 489          (unlink-node node))
 490         (combination
 491          (let ((info (combination-kind node)))
 492            (when (fun-info-p info)
 493              (let ((attr (fun-info-attributes info)))
 494                (when (and (not (ir1-attributep attr call))
 495                           ;; ### For now, don't delete potentially
 496                           ;; flushable calls when they have the CALL
 497                           ;; attribute. Someday we should look at the
 498                           ;; functional args to determine if they have
 499                           ;; any side effects.
 500                           (if (policy node (= safety 3))
 501                               (and (ir1-attributep attr flushable)
 502                                    (every (lambda (arg)
 503                                             ;; FIXME: when bug 203
 504                                             ;; will be fixed, remove
 505                                             ;; this check
 506                                             (member (continuation-type-check arg)
 507                                                     '(nil :deleted)))
 508                                           (basic-combination-args node))
 509                                    (valid-fun-use node
 510                                                   (info :function :type
 511                                                         (leaf-source-name (ref-leaf (continuation-use (basic-combination-fun node)))))
 512                                                   :result-test #'always-subtypep
 513                                                   :lossage-fun nil
 514                                                   :unwinnage-fun nil))
 515                               (ir1-attributep attr unsafely-flushable)))
 516                  (flush-dest (combination-fun node))
 517                  (dolist (arg (combination-args node))
 518                    (flush-dest arg))
 519                  (unlink-node node))))))
 520         (mv-combination
 521          (when (eq (basic-combination-kind node) :local)
 522            (let ((fun (combination-lambda node)))
 523              (when (dolist (var (lambda-vars fun) t)
 524                      (when (or (leaf-refs var)
 525                                (lambda-var-sets var))
 526                        (return nil)))
 527                (flush-dest (first (basic-combination-args node)))
 528                (delete-let fun)))))
 529         (exit
 530          (let ((value (exit-value node)))
 531            (when value
 532              (flush-dest value)
 533              (setf (exit-value node) nil))))
 534         (cset
 535          (let ((var (set-var node)))
 536            (when (and (lambda-var-p var)
 537                       (null (leaf-refs var)))
 538              (flush-dest (set-value node))
 539              (setf (basic-var-sets var)
 540                    (delete node (basic-var-sets var)))
 541              (unlink-node node)))))))
 542
 543   (setf (block-flush-p block) nil)
 544   (values))
 545 \f
 546 ;;;; local call return type propagation
 547
 548 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 549 ;;; flag set. It iterates over the uses of the RESULT, looking for
 550 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 551 ;;; call, then we union its type together with the types of other such
 552 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 553 ;;; type with the RESULT's asserted type. We can make this
 554 ;;; intersection now (potentially before type checking) because this
 555 ;;; assertion on the result will eventually be checked (if
 556 ;;; appropriate.)
 557 ;;;
 558 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 559 ;;; combination, which may change the succesor of the call to be the
 560 ;;; called function, and if so, checks if the call can become an
 561 ;;; assignment. If we convert to an assignment, we abort, since the
 562 ;;; RETURN has been deleted.
 563 (defun find-result-type (node)
 564   (declare (type creturn node))
 565   (let ((result (return-result node)))
 566     (collect ((use-union *empty-type* values-type-union))
 567       (do-uses (use result)
 568         (cond ((and (basic-combination-p use)
 569                     (eq (basic-combination-kind use) :local))
 570                (aver (eq (lambda-tail-set (node-home-lambda use))
 571                          (lambda-tail-set (combination-lambda use))))
 572                (when (combination-p use)
 573                  (when (nth-value 1 (maybe-convert-tail-local-call use))
 574                    (return-from find-result-type (values)))))
 575               (t
 576                (use-union (node-derived-type use)))))
 577       (let ((int (values-type-intersection
 578                   (continuation-asserted-type result)
 579                   (use-union))))
 580         (setf (return-result-type node) int))))
 581   (values))
 582
 583 ;;; Do stuff to realize that something has changed about the value
 584 ;;; delivered to a return node. Since we consider the return values of
 585 ;;; all functions in the tail set to be equivalent, this amounts to
 586 ;;; bringing the entire tail set up to date. We iterate over the
 587 ;;; returns for all the functions in the tail set, reanalyzing them
 588 ;;; all (not treating Node specially.)
 589 ;;;
 590 ;;; When we are done, we check whether the new type is different from
 591 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 592 ;;; all the continuations for references to functions in the tail set.
 593 ;;; This will cause IR1-OPTIMIZE-COMBINATION to derive the new type as
 594 ;;; the results of the calls.
 595 (defun ir1-optimize-return (node)
 596   (declare (type creturn node))
 597   (let* ((tails (lambda-tail-set (return-lambda node)))
 598          (funs (tail-set-funs tails)))
 599     (collect ((res *empty-type* values-type-union))
 600       (dolist (fun funs)
 601         (let ((return (lambda-return fun)))
 602           (when return
 603             (when (node-reoptimize return)
 604               (setf (node-reoptimize return) nil)
 605               (find-result-type return))
 606             (res (return-result-type return)))))
 607
 608       (when (type/= (res) (tail-set-type tails))
 609         (setf (tail-set-type tails) (res))
 610         (dolist (fun (tail-set-funs tails))
 611           (dolist (ref (leaf-refs fun))
 612             (reoptimize-continuation (node-cont ref)))))))
 613
 614   (values))
 615 \f
 616 ;;;; IF optimization
 617
 618 ;;; If the test has multiple uses, replicate the node when possible.
 619 ;;; Also check whether the predicate is known to be true or false,
 620 ;;; deleting the IF node in favor of the appropriate branch when this
 621 ;;; is the case.
 622 (defun ir1-optimize-if (node)
 623   (declare (type cif node))
 624   (let ((test (if-test node))
 625         (block (node-block node)))
 626
 627     (when (and (eq (block-start block) test)
 628                (eq (continuation-next test) node)
 629                (rest (block-start-uses block)))
 630       (do-uses (use test)
 631         (when (immediately-used-p test use)
 632           (convert-if-if use node)
 633           (when (continuation-use test) (return)))))
 634
 635     (let* ((type (continuation-type test))
 636            (victim
 637             (cond ((constant-continuation-p test)
 638                    (if (continuation-value test)
 639                        (if-alternative node)
 640                        (if-consequent node)))
 641                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 642                    (if-alternative node))
 643                   ((type= type (specifier-type 'null))
 644                    (if-consequent node)))))
 645       (when victim
 646         (flush-dest test)
 647         (when (rest (block-succ block))
 648           (unlink-blocks block victim))
 649         (setf (component-reanalyze (node-component node)) t)
 650         (unlink-node node))))
 651   (values))
 652
 653 ;;; Create a new copy of an IF node that tests the value of the node
 654 ;;; USE. The test must have >1 use, and must be immediately used by
 655 ;;; USE. NODE must be the only node in its block (implying that
 656 ;;; block-start = if-test).
 657 ;;;
 658 ;;; This optimization has an effect semantically similar to the
 659 ;;; source-to-source transformation:
 660 ;;;    (IF (IF A B C) D E) ==>
 661 ;;;    (IF A (IF B D E) (IF C D E))
 662 ;;;
 663 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 664 ;;; node so that dead code deletion notes will definitely not consider
 665 ;;; either node to be part of the original source. One node might
 666 ;;; become unreachable, resulting in a spurious note.
 667 (defun convert-if-if (use node)
 668   (declare (type node use) (type cif node))
 669   (with-ir1-environment-from-node node
 670     (let* ((block (node-block node))
 671            (test (if-test node))
 672            (cblock (if-consequent node))
 673            (ablock (if-alternative node))
 674            (use-block (node-block use))
 675            (dummy-cont (make-continuation))
 676            (new-cont (make-continuation))
 677            (new-node (make-if :test new-cont
 678                               :consequent cblock
 679                               :alternative ablock))
 680            (new-block (continuation-starts-block new-cont)))
 681       (link-node-to-previous-continuation new-node new-cont)
 682       (setf (continuation-dest new-cont) new-node)
 683       (setf (continuation-%externally-checkable-type new-cont) nil)
 684       (add-continuation-use new-node dummy-cont)
 685       (setf (block-last new-block) new-node)
 686
 687       (unlink-blocks use-block block)
 688       (delete-continuation-use use)
 689       (add-continuation-use use new-cont)
 690       (link-blocks use-block new-block)
 691
 692       (link-blocks new-block cblock)
 693       (link-blocks new-block ablock)
 694
 695       (push "<IF Duplication>" (node-source-path node))
 696       (push "<IF Duplication>" (node-source-path new-node))
 697
 698       (reoptimize-continuation test)
 699       (reoptimize-continuation new-cont)
 700       (setf (component-reanalyze *current-component*) t)))
 701   (values))
 702 \f
 703 ;;;; exit IR1 optimization
 704
 705 ;;; This function attempts to delete an exit node, returning true if
 706 ;;; it deletes the block as a consequence:
 707 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 708 ;;;    anything, since there is nothing to be done.
 709 ;;; -- If the exit node and its ENTRY have the same home lambda then
 710 ;;;    we know the exit is local, and can delete the exit. We change
 711 ;;;    uses of the Exit-Value to be uses of the original continuation,
 712 ;;;    then unlink the node. If the exit is to a TR context, then we
 713 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 714 ;;;    their value to this exit.
 715 ;;; -- If there is no value (as in a GO), then we skip the value
 716 ;;;    semantics.
 717 ;;;
 718 ;;; This function is also called by environment analysis, since it
 719 ;;; wants all exits to be optimized even if normal optimization was
 720 ;;; omitted.
 721 (defun maybe-delete-exit (node)
 722   (declare (type exit node))
 723   (let ((value (exit-value node))
 724         (entry (exit-entry node))
 725         (cont (node-cont node)))
 726     (when (and entry
 727                (eq (node-home-lambda node) (node-home-lambda entry)))
 728       (setf (entry-exits entry) (delete node (entry-exits entry)))
 729       (prog1
 730           (unlink-node node)
 731         (when value
 732           (collect ((merges))
 733             (when (return-p (continuation-dest cont))
 734               (do-uses (use value)
 735                 (when (and (basic-combination-p use)
 736                            (eq (basic-combination-kind use) :local))
 737                   (merges use))))
 738             (substitute-continuation-uses cont value)
 739             (dolist (merge (merges))
 740               (merge-tail-sets merge))))))))
 741 \f
 742 ;;;; combination IR1 optimization
 743
 744 ;;; Report as we try each transform?
 745 #!+sb-show
 746 (defvar *show-transforms-p* nil)
 747
 748 ;;; Do IR1 optimizations on a COMBINATION node.
 749 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 750 (defun ir1-optimize-combination (node)
 751   (when (continuation-reoptimize (basic-combination-fun node))
 752     (propagate-fun-change node))
 753   (let ((args (basic-combination-args node))
 754         (kind (basic-combination-kind node)))
 755     (case kind
 756       (:local
 757        (let ((fun (combination-lambda node)))
 758          (if (eq (functional-kind fun) :let)
 759              (propagate-let-args node fun)
 760              (propagate-local-call-args node fun))))
 761       ((:full :error)
 762        (dolist (arg args)
 763          (when arg
 764            (setf (continuation-reoptimize arg) nil))))
 765       (t
 766        (dolist (arg args)
 767          (when arg
 768            (setf (continuation-reoptimize arg) nil)))
 769
 770        (let ((attr (fun-info-attributes kind)))
 771          (when (and (ir1-attributep attr foldable)
 772                     ;; KLUDGE: The next test could be made more sensitive,
 773                     ;; only suppressing constant-folding of functions with
 774                     ;; CALL attributes when they're actually passed
 775                     ;; function arguments. -- WHN 19990918
 776                     (not (ir1-attributep attr call))
 777                     (every #'constant-continuation-p args)
 778                     (continuation-dest (node-cont node))
 779                     ;; Even if the function is foldable in principle,
 780                     ;; it might be one of our low-level
 781                     ;; implementation-specific functions. Such
 782                     ;; functions don't necessarily exist at runtime on
 783                     ;; a plain vanilla ANSI Common Lisp
 784                     ;; cross-compilation host, in which case the
 785                     ;; cross-compiler can't fold it because the
 786                     ;; cross-compiler doesn't know how to evaluate it.
 787                     #+sb-xc-host
 788                     (fboundp (combination-fun-source-name node)))
 789            (constant-fold-call node)
 790            (return-from ir1-optimize-combination)))
 791
 792        (let ((fun (fun-info-derive-type kind)))
 793          (when fun
 794            (let ((res (funcall fun node)))
 795              (when res
 796                (derive-node-type node res)
 797                (maybe-terminate-block node nil)))))
 798
 799        (let ((fun (fun-info-optimizer kind)))
 800          (unless (and fun (funcall fun node))
 801            (dolist (x (fun-info-transforms kind))
 802              #!+sb-show
 803              (when *show-transforms-p*
 804                (let* ((cont (basic-combination-fun node))
 805                       (fname (continuation-fun-name cont t)))
 806                  (/show "trying transform" x (transform-function x) "for" fname)))
 807              (unless (ir1-transform node x)
 808                #!+sb-show
 809                (when *show-transforms-p*
 810                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 811                (return))))))))
 812
 813   (values))
 814
 815 ;;; If CALL is to a function that doesn't return (i.e. return type is
 816 ;;; NIL), then terminate the block there, and link it to the component
 817 ;;; tail. We also change the call's CONT to be a dummy continuation to
 818 ;;; prevent the use from confusing things.
 819 ;;;
 820 ;;; Except when called during IR1 [FIXME: What does this mean? Except
 821 ;;; during IR1 conversion? What about IR1 optimization?], we delete
 822 ;;; the continuation if it has no other uses. (If it does have other
 823 ;;; uses, we reoptimize.)
 824 ;;;
 825 ;;; Termination on the basis of a continuation type assertion is
 826 ;;; inhibited when:
 827 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 828 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 829 ;;;    weakening.)
 830 (defun maybe-terminate-block (call ir1-converting-not-optimizing-p)
 831   (declare (type basic-combination call))
 832   (let* ((block (node-block call))
 833          (cont (node-cont call))
 834          (tail (component-tail (block-component block)))
 835          (succ (first (block-succ block))))
 836     (unless (or (and (eq call (block-last block)) (eq succ tail))
 837                 (block-delete-p block))
 838       (when (or (and (eq (continuation-asserted-type cont) *empty-type*)
 839                      (not (or ir1-converting-not-optimizing-p
 840                               (eq (continuation-kind cont) :deleted))))
 841                 (eq (node-derived-type call) *empty-type*))
 842         (cond (ir1-converting-not-optimizing-p
 843                (delete-continuation-use call)
 844                (cond
 845                 ((block-last block)
 846                  (aver (and (eq (block-last block) call)
 847                             (eq (continuation-kind cont) :block-start))))
 848                 (t
 849                  (setf (block-last block) call)
 850                  (link-blocks block (continuation-starts-block cont)))))
 851               (t
 852                (node-ends-block call)
 853                (delete-continuation-use call)
 854                (if (eq (continuation-kind cont) :unused)
 855                    (delete-continuation cont)
 856                    (reoptimize-continuation cont))))
 857
 858         (unlink-blocks block (first (block-succ block)))
 859         (setf (component-reanalyze (block-component block)) t)
 860         (aver (not (block-succ block)))
 861         (link-blocks block tail)
 862         (add-continuation-use call (make-continuation))
 863         t))))
 864
 865 ;;; This is called both by IR1 conversion and IR1 optimization when
 866 ;;; they have verified the type signature for the call, and are
 867 ;;; wondering if something should be done to special-case the call. If
 868 ;;; CALL is a call to a global function, then see whether it defined
 869 ;;; or known:
 870 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 871 ;;;    the expansion and change the call to call it. Expansion is
 872 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 873 ;;;    true, we never expand, since this function has already been
 874 ;;;    converted. Local call analysis will duplicate the definition
 875 ;;;    if necessary. We claim that the parent form is LABELS for
 876 ;;;    context declarations, since we don't want it to be considered
 877 ;;;    a real global function.
 878 ;;; -- If it is a known function, mark it as such by setting the KIND.
 879 ;;;
 880 ;;; We return the leaf referenced (NIL if not a leaf) and the
 881 ;;; FUN-INFO assigned.
 882 ;;;
 883 ;;; FIXME: The IR1-CONVERTING-NOT-OPTIMIZING-P argument is what the
 884 ;;; old CMU CL code called IR1-P, without explanation. My (WHN
 885 ;;; 2002-01-09) tentative understanding of it is that we can call this
 886 ;;; operation either in initial IR1 conversion or in later IR1
 887 ;;; optimization, and it tells which is which. But it would be good
 888 ;;; for someone who really understands it to check whether this is
 889 ;;; really right.
 890 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 891   (declare (type combination call))
 892   (let* ((ref (continuation-use (basic-combination-fun call)))
 893          (leaf (when (ref-p ref) (ref-leaf ref)))
 894          (inlinep (if (defined-fun-p leaf)
 895                       (defined-fun-inlinep leaf)
 896                       :no-chance)))
 897     (cond
 898      ((eq inlinep :notinline) (values nil nil))
 899      ((not (and (global-var-p leaf)
 900                 (eq (global-var-kind leaf) :global-function)))
 901       (values leaf nil))
 902      ((and (ecase inlinep
 903              (:inline t)
 904              (:no-chance nil)
 905              ((nil :maybe-inline) (policy call (zerop space))))
 906            (defined-fun-p leaf)
 907            (defined-fun-inline-expansion leaf)
 908            (let ((fun (defined-fun-functional leaf)))
 909              (or (not fun)
 910                  (and (eq inlinep :inline) (functional-kind fun))))
 911            (inline-expansion-ok call))
 912       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 913              ;; called semi-inlining? A more descriptive name would
 914              ;; be nice. -- WHN 2002-01-07
 915              (frob ()
 916                (let ((res (ir1-convert-lambda-for-defun
 917                            (defined-fun-inline-expansion leaf)
 918                            leaf t
 919                            #'ir1-convert-inline-lambda)))
 920                  (setf (defined-fun-functional leaf) res)
 921                  (change-ref-leaf ref res))))
 922         (if ir1-converting-not-optimizing-p
 923             (frob)
 924             (with-ir1-environment-from-node call
 925               (frob)
 926               (locall-analyze-component *current-component*))))
 927
 928       (values (ref-leaf (continuation-use (basic-combination-fun call)))
 929               nil))
 930      (t
 931       (let ((info (info :function :info (leaf-source-name leaf))))
 932         (if info
 933             (values leaf (setf (basic-combination-kind call) info))
 934             (values leaf nil)))))))
 935
 936 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 937 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 938 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 939 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 940 ;;; syntax check, arg/result type processing, but still call
 941 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 942 ;;; and that checking is done by local call analysis.
 943 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 944   (declare (type combination call) (type ctype type))
 945   (cond ((not (fun-type-p type))
 946          (aver (multiple-value-bind (val win)
 947                    (csubtypep type (specifier-type 'function))
 948                  (or val (not win))))
 949          (recognize-known-call call ir1-converting-not-optimizing-p))
 950         ((valid-fun-use call type
 951                         :argument-test #'always-subtypep
 952                         :result-test #'always-subtypep
 953                         ;; KLUDGE: Common Lisp is such a dynamic
 954                         ;; language that all we can do here in
 955                         ;; general is issue a STYLE-WARNING. It
 956                         ;; would be nice to issue a full WARNING
 957                         ;; in the special case of of type
 958                         ;; mismatches within a compilation unit
 959                         ;; (as in section 3.2.2.3 of the spec)
 960                         ;; but at least as of sbcl-0.6.11, we
 961                         ;; don't keep track of whether the
 962                         ;; mismatched data came from the same
 963                         ;; compilation unit, so we can't do that.
 964                         ;; -- WHN 2001-02-11
 965                         ;;
 966                         ;; FIXME: Actually, I think we could
 967                         ;; issue a full WARNING if the call
 968                         ;; violates a DECLAIM FTYPE.
 969                         :lossage-fun #'compiler-style-warn
 970                         :unwinnage-fun #'compiler-note)
 971          (assert-call-type call type)
 972          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 973          (recognize-known-call call ir1-converting-not-optimizing-p))
 974         (t
 975          (setf (combination-kind call) :error)
 976          (values nil nil))))
 977
 978 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 979 ;;; changed. If the call is local, we try to LET-convert it, and
 980 ;;; derive the result type. If it is a :FULL call, we validate it
 981 ;;; against the type, which recognizes known calls, does inline
 982 ;;; expansion, etc. If a call to a predicate in a non-conditional
 983 ;;; position or to a function with a source transform, then we
 984 ;;; reconvert the form to give IR1 another chance.
 985 (defun propagate-fun-change (call)
 986   (declare (type combination call))
 987   (let ((*compiler-error-context* call)
 988         (fun-cont (basic-combination-fun call)))
 989     (setf (continuation-reoptimize fun-cont) nil)
 990     (case (combination-kind call)
 991       (:local
 992        (let ((fun (combination-lambda call)))
 993          (maybe-let-convert fun)
 994          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 995            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 996       (:full
 997        (multiple-value-bind (leaf info)
 998            (validate-call-type call (continuation-type fun-cont) nil)
 999          (cond ((functional-p leaf)
1000                 (convert-call-if-possible
1001                  (continuation-use (basic-combination-fun call))
1002                  call))
1003                ((not leaf))
1004                ((and (leaf-has-source-name-p leaf)
1005                      (or (info :function :source-transform (leaf-source-name leaf))
1006                          (and info
1007                               (ir1-attributep (fun-info-attributes info)
1008                                               predicate)
1009                               (let ((dest (continuation-dest (node-cont call))))
1010                                 (and dest (not (if-p dest)))))))
1011                 ;; FIXME: This SYMBOLP is part of a literal
1012                 ;; translation of a test in the old CMU CL
1013                 ;; source, and it's not quite clear what
1014                 ;; the old source meant. Did it mean "has a
1015                 ;; valid name"? Or did it mean "is an
1016                 ;; ordinary function name, not a SETF
1017                 ;; function"? Either way, the old CMU CL
1018                 ;; code probably didn't deal with SETF
1019                 ;; functions correctly, and neither does
1020                 ;; this new SBCL code, and that should be fixed.
1021                 (when (symbolp (leaf-source-name leaf))
1022                   (let ((dummies (make-gensym-list
1023                                   (length (combination-args call)))))
1024                     (transform-call call
1025                                     `(lambda ,dummies
1026                                       (,(leaf-source-name leaf)
1027                                        ,@dummies))
1028                                     (leaf-source-name leaf))))))))))
1029   (values))
1030 \f
1031 ;;;; known function optimization
1032
1033 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
1034 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
1035 ;;; replace it, otherwise add a new one.
1036 (defun record-optimization-failure (node transform args)
1037   (declare (type combination node) (type transform transform)
1038            (type (or fun-type list) args))
1039   (let* ((table (component-failed-optimizations *component-being-compiled*))
1040          (found (assoc transform (gethash node table))))
1041     (if found
1042         (setf (cdr found) args)
1043         (push (cons transform args) (gethash node table))))
1044   (values))
1045
1046 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
1047 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
1048 ;;; doing the transform for some reason and FLAME is true, then we
1049 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
1050 ;;; finalize to pick up. We return true if the transform failed, and
1051 ;;; thus further transformation should be attempted. We return false
1052 ;;; if either the transform succeeded or was aborted.
1053 (defun ir1-transform (node transform)
1054   (declare (type combination node) (type transform transform))
1055   (let* ((type (transform-type transform))
1056          (fun (transform-function transform))
1057          (constrained (fun-type-p type))
1058          (table (component-failed-optimizations *component-being-compiled*))
1059          (flame (if (transform-important transform)
1060                     (policy node (>= speed inhibit-warnings))
1061                     (policy node (> speed inhibit-warnings))))
1062          (*compiler-error-context* node))
1063     (cond ((or (not constrained)
1064                (valid-fun-use node type :strict-result t))
1065            (multiple-value-bind (severity args)
1066                (catch 'give-up-ir1-transform
1067                  (transform-call node
1068                                  (funcall fun node)
1069                                  (combination-fun-source-name node))
1070                  (values :none nil))
1071              (ecase severity
1072                (:none
1073                 (remhash node table)
1074                 nil)
1075                (:aborted
1076                 (setf (combination-kind node) :error)
1077                 (when args
1078                   (apply #'compiler-warn args))
1079                 (remhash node table)
1080                 nil)
1081                (:failure
1082                 (if args
1083                     (when flame
1084                       (record-optimization-failure node transform args))
1085                     (setf (gethash node table)
1086                           (remove transform (gethash node table) :key #'car)))
1087                 t)
1088                (:delayed
1089                  (remhash node table)
1090                  nil))))
1091           ((and flame
1092                 (valid-fun-use node
1093                                type
1094                                :argument-test #'types-equal-or-intersect
1095                                :result-test #'values-types-equal-or-intersect))
1096            (record-optimization-failure node transform type)
1097            t)
1098           (t
1099            t))))
1100
1101 ;;; When we don't like an IR1 transform, we throw the severity/reason
1102 ;;; and args.
1103 ;;;
1104 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
1105 ;;; aborting this attempt to transform the call, but admitting the
1106 ;;; possibility that this or some other transform will later succeed.
1107 ;;; If arguments are supplied, they are format arguments for an
1108 ;;; efficiency note.
1109 ;;;
1110 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
1111 ;;; force a normal call to the function at run time. No further
1112 ;;; optimizations will be attempted.
1113 ;;;
1114 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
1115 ;;; delay the transform on the node until later. REASONS specifies
1116 ;;; when the transform will be later retried. The :OPTIMIZE reason
1117 ;;; causes the transform to be delayed until after the current IR1
1118 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
1119 ;;; be delayed until after constraint propagation.
1120 ;;;
1121 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
1122 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
1123 ;;; do CASE operations on the various REASON values, it might be a
1124 ;;; good idea to go OO, representing the reasons by objects, using
1125 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
1126 ;;; SIGNAL instead of THROW.
1127 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1128 (defun give-up-ir1-transform (&rest args)
1129   (throw 'give-up-ir1-transform (values :failure args)))
1130 (defun abort-ir1-transform (&rest args)
1131   (throw 'give-up-ir1-transform (values :aborted args)))
1132 (defun delay-ir1-transform (node &rest reasons)
1133   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1134     (cond ((not assoc)
1135             (setf *delayed-ir1-transforms*
1136                     (acons node reasons *delayed-ir1-transforms*))
1137             (throw 'give-up-ir1-transform :delayed))
1138           ((cdr assoc)
1139             (dolist (reason reasons)
1140               (pushnew reason (cdr assoc)))
1141             (throw 'give-up-ir1-transform :delayed)))))
1142
1143 ;;; Clear any delayed transform with no reasons - these should have
1144 ;;; been tried in the last pass. Then remove the reason from the
1145 ;;; delayed transform reasons, and if any become empty then set
1146 ;;; reoptimize flags for the node. Return true if any transforms are
1147 ;;; to be retried.
1148 (defun retry-delayed-ir1-transforms (reason)
1149   (setf *delayed-ir1-transforms*
1150         (remove-if-not #'cdr *delayed-ir1-transforms*))
1151   (let ((reoptimize nil))
1152     (dolist (assoc *delayed-ir1-transforms*)
1153       (let ((reasons (remove reason (cdr assoc))))
1154         (setf (cdr assoc) reasons)
1155         (unless reasons
1156           (let ((node (car assoc)))
1157             (unless (node-deleted node)
1158               (setf reoptimize t)
1159               (setf (node-reoptimize node) t)
1160               (let ((block (node-block node)))
1161                 (setf (block-reoptimize block) t)
1162                 (setf (component-reoptimize (block-component block)) t)))))))
1163     reoptimize))
1164
1165 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1166 ;;; environment, and then install it as the function for the call
1167 ;;; NODE. We do local call analysis so that the new function is
1168 ;;; integrated into the control flow.
1169 ;;;
1170 ;;; We require the original function source name in order to generate
1171 ;;; a meaningful debug name for the lambda we set up. (It'd be
1172 ;;; possible to do this starting from debug names as well as source
1173 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1174 ;;; generality, since source names are always known to our callers.)
1175 (defun transform-call (node res source-name)
1176   (declare (type combination node) (list res))
1177   (aver (and (legal-fun-name-p source-name)
1178              (not (eql source-name '.anonymous.))))
1179   (with-ir1-environment-from-node node
1180       (let ((new-fun (ir1-convert-inline-lambda
1181                       res
1182                       :debug-name (debug-namify "LAMBDA-inlined ~A"
1183                                                 (as-debug-name
1184                                                  source-name
1185                                                  "<unknown function>"))))
1186             (ref (continuation-use (combination-fun node))))
1187         (change-ref-leaf ref new-fun)
1188         (setf (combination-kind node) :full)
1189         (locall-analyze-component *current-component*)))
1190   (values))
1191
1192 ;;; Replace a call to a foldable function of constant arguments with
1193 ;;; the result of evaluating the form. We insert the resulting
1194 ;;; constant node after the call, stealing the call's continuation. We
1195 ;;; give the call a continuation with no DEST, which should cause it
1196 ;;; and its arguments to go away. If there is an error during the
1197 ;;; evaluation, we give a warning and leave the call alone, making the
1198 ;;; call a :ERROR call.
1199 ;;;
1200 ;;; If there is more than one value, then we transform the call into a
1201 ;;; VALUES form.
1202 (defun constant-fold-call (call)
1203   (let ((args (mapcar #'continuation-value (combination-args call)))
1204         (fun-name (combination-fun-source-name call)))
1205     (multiple-value-bind (values win)
1206         (careful-call fun-name
1207                       args
1208                       call
1209                       ;; Note: CMU CL had COMPILER-WARN here, and that
1210                       ;; seems more natural, but it's probably not.
1211                       ;;
1212                       ;; It's especially not while bug 173 exists:
1213                       ;; Expressions like
1214                       ;;   (COND (END
1215                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1216                       ;;            ...))
1217                       ;; can cause constant-folding TYPE-ERRORs (in
1218                       ;; #'<=) when END can be proved to be NIL, even
1219                       ;; though the code is perfectly legal and safe
1220                       ;; because a NIL value of END means that the
1221                       ;; #'<= will never be executed.
1222                       ;;
1223                       ;; Moreover, even without bug 173,
1224                       ;; quite-possibly-valid code like
1225                       ;;   (COND ((NONINLINED-PREDICATE END)
1226                       ;;          (UNLESS (<= END SIZE))
1227                       ;;            ...))
1228                       ;; (where NONINLINED-PREDICATE is something the
1229                       ;; compiler can't do at compile time, but which
1230                       ;; turns out to make the #'<= expression
1231                       ;; unreachable when END=NIL) could cause errors
1232                       ;; when the compiler tries to constant-fold (<=
1233                       ;; END SIZE).
1234                       ;;
1235                       ;; So, with or without bug 173, it'd be
1236                       ;; unnecessarily evil to do a full
1237                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1238                       ;; from COMPILE-FILE) for legal code, so we we
1239                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1240                       #'compiler-style-warn
1241                       "constant folding")
1242       (if (not win)
1243           (setf (combination-kind call) :error)
1244           (let ((dummies (make-gensym-list (length args))))
1245             (transform-call
1246              call
1247              `(lambda ,dummies
1248                 (declare (ignore ,@dummies))
1249                 (values ,@(mapcar (lambda (x) `',x) values)))
1250              fun-name)))))
1251   (values))
1252 \f
1253 ;;;; local call optimization
1254
1255 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1256 ;;; the leaf type is a function type, then just leave it alone, since
1257 ;;; TYPE is never going to be more specific than that (and
1258 ;;; TYPE-INTERSECTION would choke.)
1259 (defun propagate-to-refs (leaf type)
1260   (declare (type leaf leaf) (type ctype type))
1261   (let ((var-type (leaf-type leaf)))
1262     (unless (fun-type-p var-type)
1263       (let ((int (type-approx-intersection2 var-type type)))
1264         (when (type/= int var-type)
1265           (setf (leaf-type leaf) int)
1266           (dolist (ref (leaf-refs leaf))
1267             (derive-node-type ref int))))
1268       (values))))
1269
1270 ;;; Figure out the type of a LET variable that has sets. We compute
1271 ;;; the union of the initial value Type and the types of all the set
1272 ;;; values and to a PROPAGATE-TO-REFS with this type.
1273 (defun propagate-from-sets (var type)
1274   (collect ((res type type-union))
1275     (dolist (set (basic-var-sets var))
1276       (res (continuation-type (set-value set)))
1277       (setf (node-reoptimize set) nil))
1278     (propagate-to-refs var (res)))
1279   (values))
1280
1281 ;;; If a LET variable, find the initial value's type and do
1282 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1283 ;;; type.
1284 (defun ir1-optimize-set (node)
1285   (declare (type cset node))
1286   (let ((var (set-var node)))
1287     (when (and (lambda-var-p var) (leaf-refs var))
1288       (let ((home (lambda-var-home var)))
1289         (when (eq (functional-kind home) :let)
1290           (let ((iv (let-var-initial-value var)))
1291             (setf (continuation-reoptimize iv) nil)
1292             (propagate-from-sets var (continuation-type iv)))))))
1293
1294   (derive-node-type node (continuation-type (set-value node)))
1295   (values))
1296
1297 ;;; Return true if the value of REF will always be the same (and is
1298 ;;; thus legal to substitute.)
1299 (defun constant-reference-p (ref)
1300   (declare (type ref ref))
1301   (let ((leaf (ref-leaf ref)))
1302     (typecase leaf
1303       ((or constant functional) t)
1304       (lambda-var
1305        (null (lambda-var-sets leaf)))
1306       (defined-fun
1307        (not (eq (defined-fun-inlinep leaf) :notinline)))
1308       (global-var
1309        (case (global-var-kind leaf)
1310          (:global-function t))))))
1311
1312 ;;; If we have a non-set LET var with a single use, then (if possible)
1313 ;;; replace the variable reference's CONT with the arg continuation.
1314 ;;; This is inhibited when:
1315 ;;; -- CONT has other uses, or
1316 ;;; -- CONT receives multiple values, or
1317 ;;; -- the reference is in a different environment from the variable, or
1318 ;;; -- either continuation has a funky TYPE-CHECK annotation.
1319 ;;; -- the continuations have incompatible assertions, so the new asserted type
1320 ;;;    would be NIL.
1321 ;;; -- the var's DEST has a different policy than the ARG's (think safety).
1322 ;;;
1323 ;;; We change the REF to be a reference to NIL with unused value, and
1324 ;;; let it be flushed as dead code. A side effect of this substitution
1325 ;;; is to delete the variable.
1326 (defun substitute-single-use-continuation (arg var)
1327   (declare (type continuation arg) (type lambda-var var))
1328   (let* ((ref (first (leaf-refs var)))
1329          (cont (node-cont ref))
1330          (cont-atype (continuation-asserted-type cont))
1331          (cont-ctype (continuation-type-to-check cont))
1332          (dest (continuation-dest cont)))
1333     (when (and (eq (continuation-use cont) ref)
1334                dest
1335                (not (typep dest '(or creturn exit mv-combination)))
1336                (eq (node-home-lambda ref)
1337                    (lambda-home (lambda-var-home var)))
1338                (member (continuation-type-check arg) '(t nil))
1339                (member (continuation-type-check cont) '(t nil))
1340                (not (eq (values-type-intersection
1341                          cont-atype
1342                          (continuation-asserted-type arg))
1343                         *empty-type*))
1344                (eq (lexenv-policy (node-lexenv dest))
1345                    (lexenv-policy (node-lexenv (continuation-dest arg)))))
1346       (aver (member (continuation-kind arg)
1347                     '(:block-start :deleted-block-start :inside-block)))
1348       (set-continuation-type-assertion arg cont-atype cont-ctype)
1349       (setf (node-derived-type ref) *wild-type*)
1350       (change-ref-leaf ref (find-constant nil))
1351       (substitute-continuation arg cont)
1352       (reoptimize-continuation arg)
1353       t)))
1354
1355 ;;; Delete a LET, removing the call and bind nodes, and warning about
1356 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1357 ;;; along right away and delete the REF and then the lambda, since we
1358 ;;; flush the FUN continuation.
1359 (defun delete-let (clambda)
1360   (declare (type clambda clambda))
1361   (aver (functional-letlike-p clambda))
1362   (note-unreferenced-vars clambda)
1363   (let ((call (let-combination clambda)))
1364     (flush-dest (basic-combination-fun call))
1365     (unlink-node call)
1366     (unlink-node (lambda-bind clambda))
1367     (setf (lambda-bind clambda) nil))
1368   (values))
1369
1370 ;;; This function is called when one of the arguments to a LET
1371 ;;; changes. We look at each changed argument. If the corresponding
1372 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1373 ;;; consider substituting for the variable, and also propagate
1374 ;;; derived-type information for the arg to all the VAR's refs.
1375 ;;;
1376 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1377 ;;; subtype of the argument's asserted type. This prevents type
1378 ;;; checking from being defeated, and also ensures that the best
1379 ;;; representation for the variable can be used.
1380 ;;;
1381 ;;; Substitution of individual references is inhibited if the
1382 ;;; reference is in a different component from the home. This can only
1383 ;;; happen with closures over top level lambda vars. In such cases,
1384 ;;; the references may have already been compiled, and thus can't be
1385 ;;; retroactively modified.
1386 ;;;
1387 ;;; If all of the variables are deleted (have no references) when we
1388 ;;; are done, then we delete the LET.
1389 ;;;
1390 ;;; Note that we are responsible for clearing the
1391 ;;; CONTINUATION-REOPTIMIZE flags.
1392 (defun propagate-let-args (call fun)
1393   (declare (type combination call) (type clambda fun))
1394   (loop for arg in (combination-args call)
1395         and var in (lambda-vars fun) do
1396     (when (and arg (continuation-reoptimize arg))
1397       (setf (continuation-reoptimize arg) nil)
1398       (cond
1399        ((lambda-var-sets var)
1400         (propagate-from-sets var (continuation-type arg)))
1401        ((let ((use (continuation-use arg)))
1402           (when (ref-p use)
1403             (let ((leaf (ref-leaf use)))
1404               (when (and (constant-reference-p use)
1405                          (values-subtypep (leaf-type leaf)
1406                                           (continuation-asserted-type arg)))
1407                 (propagate-to-refs var (continuation-type arg))
1408                 (let ((use-component (node-component use)))
1409                   (substitute-leaf-if
1410                    (lambda (ref)
1411                      (cond ((eq (node-component ref) use-component)
1412                             t)
1413                            (t
1414                             (aver (lambda-toplevelish-p (lambda-home fun)))
1415                             nil)))
1416                    leaf var))
1417                 t)))))
1418        ((and (null (rest (leaf-refs var)))
1419              (substitute-single-use-continuation arg var)))
1420        (t
1421         (propagate-to-refs var (continuation-type arg))))))
1422
1423   (when (every #'null (combination-args call))
1424     (delete-let fun))
1425
1426   (values))
1427
1428 ;;; This function is called when one of the args to a non-LET local
1429 ;;; call changes. For each changed argument corresponding to an unset
1430 ;;; variable, we compute the union of the types across all calls and
1431 ;;; propagate this type information to the var's refs.
1432 ;;;
1433 ;;; If the function has an XEP, then we don't do anything, since we
1434 ;;; won't discover anything.
1435 ;;;
1436 ;;; We can clear the Continuation-Reoptimize flags for arguments in
1437 ;;; all calls corresponding to changed arguments in Call, since the
1438 ;;; only use in IR1 optimization of the Reoptimize flag for local call
1439 ;;; args is right here.
1440 (defun propagate-local-call-args (call fun)
1441   (declare (type combination call) (type clambda fun))
1442
1443   (unless (or (functional-entry-fun fun)
1444               (lambda-optional-dispatch fun))
1445     (let* ((vars (lambda-vars fun))
1446            (union (mapcar (lambda (arg var)
1447                             (when (and arg
1448                                        (continuation-reoptimize arg)
1449                                        (null (basic-var-sets var)))
1450                               (continuation-type arg)))
1451                           (basic-combination-args call)
1452                           vars))
1453            (this-ref (continuation-use (basic-combination-fun call))))
1454
1455       (dolist (arg (basic-combination-args call))
1456         (when arg
1457           (setf (continuation-reoptimize arg) nil)))
1458
1459       (dolist (ref (leaf-refs fun))
1460         (let ((dest (continuation-dest (node-cont ref))))
1461           (unless (or (eq ref this-ref) (not dest))
1462             (setq union
1463                   (mapcar (lambda (this-arg old)
1464                             (when old
1465                               (setf (continuation-reoptimize this-arg) nil)
1466                               (type-union (continuation-type this-arg) old)))
1467                           (basic-combination-args dest)
1468                           union)))))
1469
1470       (mapc (lambda (var type)
1471               (when type
1472                 (propagate-to-refs var type)))
1473             vars union)))
1474
1475   (values))
1476 \f
1477 ;;;; multiple values optimization
1478
1479 ;;; Do stuff to notice a change to a MV combination node. There are
1480 ;;; two main branches here:
1481 ;;;  -- If the call is local, then it is already a MV let, or should
1482 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1483 ;;;     be converted to :MV-LETs, there can be a window when the call
1484 ;;;     is local, but has not been LET converted yet. This is because
1485 ;;;     the entry-point lambdas may have stray references (in other
1486 ;;;     entry points) that have not been deleted yet.
1487 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1488 ;;;     combination optimization: we propagate return type information and
1489 ;;;     notice non-returning calls. We also have an optimization
1490 ;;;     which tries to convert MV-CALLs into MV-binds.
1491 (defun ir1-optimize-mv-combination (node)
1492   (ecase (basic-combination-kind node)
1493     (:local
1494      (let ((fun-cont (basic-combination-fun node)))
1495        (when (continuation-reoptimize fun-cont)
1496          (setf (continuation-reoptimize fun-cont) nil)
1497          (maybe-let-convert (combination-lambda node))))
1498      (setf (continuation-reoptimize (first (basic-combination-args node))) nil)
1499      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1500        (unless (convert-mv-bind-to-let node)
1501          (ir1-optimize-mv-bind node))))
1502     (:full
1503      (let* ((fun (basic-combination-fun node))
1504             (fun-changed (continuation-reoptimize fun))
1505             (args (basic-combination-args node)))
1506        (when fun-changed
1507          (setf (continuation-reoptimize fun) nil)
1508          (let ((type (continuation-type fun)))
1509            (when (fun-type-p type)
1510              (derive-node-type node (fun-type-returns type))))
1511          (maybe-terminate-block node nil)
1512          (let ((use (continuation-use fun)))
1513            (when (and (ref-p use) (functional-p (ref-leaf use)))
1514              (convert-call-if-possible use node)
1515              (when (eq (basic-combination-kind node) :local)
1516                (maybe-let-convert (ref-leaf use))))))
1517        (unless (or (eq (basic-combination-kind node) :local)
1518                    (eq (continuation-fun-name fun) '%throw))
1519          (ir1-optimize-mv-call node))
1520        (dolist (arg args)
1521          (setf (continuation-reoptimize arg) nil))))
1522     (:error))
1523   (values))
1524
1525 ;;; Propagate derived type info from the values continuation to the
1526 ;;; vars.
1527 (defun ir1-optimize-mv-bind (node)
1528   (declare (type mv-combination node))
1529   (let ((arg (first (basic-combination-args node)))
1530         (vars (lambda-vars (combination-lambda node))))
1531     (multiple-value-bind (types nvals)
1532         (values-types (continuation-derived-type arg))
1533       (unless (eq nvals :unknown)
1534         (mapc (lambda (var type)
1535                 (if (basic-var-sets var)
1536                     (propagate-from-sets var type)
1537                     (propagate-to-refs var type)))
1538               vars
1539                 (append types
1540                         (make-list (max (- (length vars) nvals) 0)
1541                                    :initial-element (specifier-type 'null))))))
1542     (setf (continuation-reoptimize arg) nil))
1543   (values))
1544
1545 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1546 ;;; this if:
1547 ;;; -- The call has only one argument, and
1548 ;;; -- The function has a known fixed number of arguments, or
1549 ;;; -- The argument yields a known fixed number of values.
1550 ;;;
1551 ;;; What we do is change the function in the MV-CALL to be a lambda
1552 ;;; that "looks like an MV bind", which allows
1553 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1554 ;;; converted (the next time around.) This new lambda just calls the
1555 ;;; actual function with the MV-BIND variables as arguments. Note that
1556 ;;; this new MV bind is not let-converted immediately, as there are
1557 ;;; going to be stray references from the entry-point functions until
1558 ;;; they get deleted.
1559 ;;;
1560 ;;; In order to avoid loss of argument count checking, we only do the
1561 ;;; transformation according to a known number of expected argument if
1562 ;;; safety is unimportant. We can always convert if we know the number
1563 ;;; of actual values, since the normal call that we build will still
1564 ;;; do any appropriate argument count checking.
1565 ;;;
1566 ;;; We only attempt the transformation if the called function is a
1567 ;;; constant reference. This allows us to just splice the leaf into
1568 ;;; the new function, instead of trying to somehow bind the function
1569 ;;; expression. The leaf must be constant because we are evaluating it
1570 ;;; again in a different place. This also has the effect of squelching
1571 ;;; multiple warnings when there is an argument count error.
1572 (defun ir1-optimize-mv-call (node)
1573   (let ((fun (basic-combination-fun node))
1574         (*compiler-error-context* node)
1575         (ref (continuation-use (basic-combination-fun node)))
1576         (args (basic-combination-args node)))
1577
1578     (unless (and (ref-p ref) (constant-reference-p ref)
1579                  args (null (rest args)))
1580       (return-from ir1-optimize-mv-call))
1581
1582     (multiple-value-bind (min max)
1583         (fun-type-nargs (continuation-type fun))
1584       (let ((total-nvals
1585              (multiple-value-bind (types nvals)
1586                  (values-types (continuation-derived-type (first args)))
1587                (declare (ignore types))
1588                (if (eq nvals :unknown) nil nvals))))
1589
1590         (when total-nvals
1591           (when (and min (< total-nvals min))
1592             (compiler-warn
1593              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1594              at least ~R."
1595              total-nvals min)
1596             (setf (basic-combination-kind node) :error)
1597             (return-from ir1-optimize-mv-call))
1598           (when (and max (> total-nvals max))
1599             (compiler-warn
1600              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1601              at most ~R."
1602              total-nvals max)
1603             (setf (basic-combination-kind node) :error)
1604             (return-from ir1-optimize-mv-call)))
1605
1606         (let ((count (cond (total-nvals)
1607                            ((and (policy node (zerop safety))
1608                                  (eql min max))
1609                             min)
1610                            (t nil))))
1611           (when count
1612             (with-ir1-environment-from-node node
1613               (let* ((dums (make-gensym-list count))
1614                      (ignore (gensym))
1615                      (fun (ir1-convert-lambda
1616                            `(lambda (&optional ,@dums &rest ,ignore)
1617                               (declare (ignore ,ignore))
1618                               (funcall ,(ref-leaf ref) ,@dums)))))
1619                 (change-ref-leaf ref fun)
1620                 (aver (eq (basic-combination-kind node) :full))
1621                 (locall-analyze-component *current-component*)
1622                 (aver (eq (basic-combination-kind node) :local)))))))))
1623   (values))
1624
1625 ;;; If we see:
1626 ;;;    (multiple-value-bind
1627 ;;;     (x y)
1628 ;;;     (values xx yy)
1629 ;;;      ...)
1630 ;;; Convert to:
1631 ;;;    (let ((x xx)
1632 ;;;       (y yy))
1633 ;;;      ...)
1634 ;;;
1635 ;;; What we actually do is convert the VALUES combination into a
1636 ;;; normal LET combination calling the original :MV-LET lambda. If
1637 ;;; there are extra args to VALUES, discard the corresponding
1638 ;;; continuations. If there are insufficient args, insert references
1639 ;;; to NIL.
1640 (defun convert-mv-bind-to-let (call)
1641   (declare (type mv-combination call))
1642   (let* ((arg (first (basic-combination-args call)))
1643          (use (continuation-use arg)))
1644     (when (and (combination-p use)
1645                (eq (continuation-fun-name (combination-fun use))
1646                    'values))
1647       (let* ((fun (combination-lambda call))
1648              (vars (lambda-vars fun))
1649              (vals (combination-args use))
1650              (nvars (length vars))
1651              (nvals (length vals)))
1652         (cond ((> nvals nvars)
1653                (mapc #'flush-dest (subseq vals nvars))
1654                (setq vals (subseq vals 0 nvars)))
1655               ((< nvals nvars)
1656                (with-ir1-environment-from-node use
1657                  (let ((node-prev (node-prev use)))
1658                    (setf (node-prev use) nil)
1659                    (setf (continuation-next node-prev) nil)
1660                    (collect ((res vals))
1661                      (loop as cont = (make-continuation use)
1662                            and prev = node-prev then cont
1663                            repeat (- nvars nvals)
1664                            do (reference-constant prev cont nil)
1665                               (res cont))
1666                      (setq vals (res)))
1667                    (link-node-to-previous-continuation use
1668                                                        (car (last vals)))))))
1669         (setf (combination-args use) vals)
1670         (flush-dest (combination-fun use))
1671         (let ((fun-cont (basic-combination-fun call)))
1672           (setf (continuation-dest fun-cont) use)
1673           (setf (combination-fun use) fun-cont)
1674           (setf (continuation-%externally-checkable-type fun-cont) nil))
1675         (setf (combination-kind use) :local)
1676         (setf (functional-kind fun) :let)
1677         (flush-dest (first (basic-combination-args call)))
1678         (unlink-node call)
1679         (when vals
1680           (reoptimize-continuation (first vals)))
1681         (propagate-to-args use fun))
1682       t)))
1683
1684 ;;; If we see:
1685 ;;;    (values-list (list x y z))
1686 ;;;
1687 ;;; Convert to:
1688 ;;;    (values x y z)
1689 ;;;
1690 ;;; In implementation, this is somewhat similar to
1691 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1692 ;;; args of the VALUES-LIST call, flushing the old argument
1693 ;;; continuation (allowing the LIST to be flushed.)
1694 (defoptimizer (values-list optimizer) ((list) node)
1695   (let ((use (continuation-use list)))
1696     (when (and (combination-p use)
1697                (eq (continuation-fun-name (combination-fun use))
1698                    'list))
1699       (change-ref-leaf (continuation-use (combination-fun node))
1700                        (find-free-fun 'values "in a strange place"))
1701       (setf (combination-kind node) :full)
1702       (let ((args (combination-args use)))
1703         (dolist (arg args)
1704           (setf (continuation-dest arg) node)
1705           (setf (continuation-%externally-checkable-type arg) nil))
1706         (setf (combination-args use) nil)
1707         (flush-dest list)
1708         (setf (combination-args node) args))
1709       t)))
1710
1711 ;;; If VALUES appears in a non-MV context, then effectively convert it
1712 ;;; to a PROG1. This allows the computation of the additional values
1713 ;;; to become dead code.
1714 (deftransform values ((&rest vals) * * :node node)
1715   (when (typep (continuation-dest (node-cont node))
1716                '(or creturn exit mv-combination))
1717     (give-up-ir1-transform))
1718   (setf (node-derived-type node) *wild-type*)
1719   (if vals
1720       (let ((dummies (make-gensym-list (length (cdr vals)))))
1721         `(lambda (val ,@dummies)
1722            (declare (ignore ,@dummies))
1723            val))
1724       nil))