src/compiler/ir1opt.lisp

   1 ;;;; This file implements the IR1 optimization phase of the compiler.
   2 ;;;; IR1 optimization is a grab-bag of optimizations that don't make
   3 ;;;; major changes to the block-level control flow and don't use flow
   4 ;;;; analysis. These optimizations can mostly be classified as
   5 ;;;; "meta-evaluation", but there is a sizable top-down component as
   6 ;;;; well.
   7
   8 ;;;; This software is part of the SBCL system. See the README file for
   9 ;;;; more information.
  10 ;;;;
  11 ;;;; This software is derived from the CMU CL system, which was
  12 ;;;; written at Carnegie Mellon University and released into the
  13 ;;;; public domain. The software is in the public domain and is
  14 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  15 ;;;; files for more information.
  16
  17 (in-package "SB!C")
  18 \f
  19 ;;;; interface for obtaining results of constant folding
  20
  21 ;;; Return true for an LVAR whose sole use is a reference to a
  22 ;;; constant leaf.
  23 (defun constant-lvar-p (thing)
  24   (declare (type (or lvar null) thing))
  25   (and (lvar-p thing)
  26        (let ((use (principal-lvar-use thing)))
  27          (and (ref-p use) (constant-p (ref-leaf use))))))
  28
  29 ;;; Return the constant value for an LVAR whose only use is a constant
  30 ;;; node.
  31 (declaim (ftype (function (lvar) t) lvar-value))
  32 (defun lvar-value (lvar)
  33   (let ((use (principal-lvar-use lvar)))
  34     (constant-value (ref-leaf use))))
  35 \f
  36 ;;;; interface for obtaining results of type inference
  37
  38 ;;; Our best guess for the type of this lvar's value. Note that this
  39 ;;; may be VALUES or FUNCTION type, which cannot be passed as an
  40 ;;; argument to the normal type operations. See LVAR-TYPE.
  41 ;;;
  42 ;;; The result value is cached in the LVAR-%DERIVED-TYPE slot. If the
  43 ;;; slot is true, just return that value, otherwise recompute and
  44 ;;; stash the value there.
  45 #!-sb-fluid (declaim (inline lvar-derived-type))
  46 (defun lvar-derived-type (lvar)
  47   (declare (type lvar lvar))
  48   (or (lvar-%derived-type lvar)
  49       (setf (lvar-%derived-type lvar)
  50             (%lvar-derived-type lvar))))
  51 (defun %lvar-derived-type (lvar)
  52   (declare (type lvar lvar))
  53   (let ((uses (lvar-uses lvar)))
  54     (cond ((null uses) *empty-type*)
  55           ((listp uses)
  56            (do ((res (node-derived-type (first uses))
  57                      (values-type-union (node-derived-type (first current))
  58                                         res))
  59                 (current (rest uses) (rest current)))
  60                ((null current) res)))
  61           (t
  62            (node-derived-type (lvar-uses lvar))))))
  63
  64 ;;; Return the derived type for LVAR's first value. This is guaranteed
  65 ;;; not to be a VALUES or FUNCTION type.
  66 (declaim (ftype (sfunction (lvar) ctype) lvar-type))
  67 (defun lvar-type (lvar)
  68   (single-value-type (lvar-derived-type lvar)))
  69
  70 ;;; If LVAR is an argument of a function, return a type which the
  71 ;;; function checks LVAR for.
  72 #!-sb-fluid (declaim (inline lvar-externally-checkable-type))
  73 (defun lvar-externally-checkable-type (lvar)
  74   (or (lvar-%externally-checkable-type lvar)
  75       (%lvar-%externally-checkable-type lvar)))
  76 (defun %lvar-%externally-checkable-type (lvar)
  77   (declare (type lvar lvar))
  78   (let ((dest (lvar-dest lvar)))
  79     (if (not (and dest (combination-p dest)))
  80         ;; TODO: MV-COMBINATION
  81         (setf (lvar-%externally-checkable-type lvar) *wild-type*)
  82         (let* ((fun (combination-fun dest))
  83                (args (combination-args dest))
  84                (fun-type (lvar-type fun)))
  85           (setf (lvar-%externally-checkable-type fun) *wild-type*)
  86           (if (or (not (call-full-like-p dest))
  87                   (not (fun-type-p fun-type))
  88                   ;; FUN-TYPE might be (AND FUNCTION (SATISFIES ...)).
  89                   (fun-type-wild-args fun-type))
  90               (dolist (arg args)
  91                 (when arg
  92                   (setf (lvar-%externally-checkable-type arg)
  93                         *wild-type*)))
  94               (map-combination-args-and-types
  95                (lambda (arg type)
  96                  (setf (lvar-%externally-checkable-type arg)
  97                        (acond ((lvar-%externally-checkable-type arg)
  98                                (values-type-intersection
  99                                 it (coerce-to-values type)))
 100                               (t (coerce-to-values type)))))
 101                dest)))))
 102   (lvar-%externally-checkable-type lvar))
 103 #!-sb-fluid(declaim (inline flush-lvar-externally-checkable-type))
 104 (defun flush-lvar-externally-checkable-type (lvar)
 105   (declare (type lvar lvar))
 106   (setf (lvar-%externally-checkable-type lvar) nil))
 107 \f
 108 ;;;; interface routines used by optimizers
 109
 110 ;;; This function is called by optimizers to indicate that something
 111 ;;; interesting has happened to the value of LVAR. Optimizers must
 112 ;;; make sure that they don't call for reoptimization when nothing has
 113 ;;; happened, since optimization will fail to terminate.
 114 ;;;
 115 ;;; We clear any cached type for the lvar and set the reoptimize flags
 116 ;;; on everything in sight.
 117 (defun reoptimize-lvar (lvar)
 118   (declare (type (or lvar null) lvar))
 119   (when lvar
 120     (setf (lvar-%derived-type lvar) nil)
 121     (let ((dest (lvar-dest lvar)))
 122       (when dest
 123         (setf (lvar-reoptimize lvar) t)
 124         (setf (node-reoptimize dest) t)
 125         (binding* (;; Since this may be called during IR1 conversion,
 126                    ;; PREV may be missing.
 127                    (prev (node-prev dest) :exit-if-null)
 128                    (block (ctran-block prev))
 129                    (component (block-component block)))
 130           (when (typep dest 'cif)
 131             (setf (block-test-modified block) t))
 132           (setf (block-reoptimize block) t)
 133           (setf (component-reoptimize component) t))))
 134     (do-uses (node lvar)
 135       (setf (block-type-check (node-block node)) t)))
 136   (values))
 137
 138 (defun reoptimize-lvar-uses (lvar)
 139   (declare (type lvar lvar))
 140   (do-uses (use lvar)
 141     (setf (node-reoptimize use) t)
 142     (setf (block-reoptimize (node-block use)) t)
 143     (setf (component-reoptimize (node-component use)) t)))
 144
 145 ;;; Annotate NODE to indicate that its result has been proven to be
 146 ;;; TYPEP to RTYPE. After IR1 conversion has happened, this is the
 147 ;;; only correct way to supply information discovered about a node's
 148 ;;; type. If you screw with the NODE-DERIVED-TYPE directly, then
 149 ;;; information may be lost and reoptimization may not happen.
 150 ;;;
 151 ;;; What we do is intersect RTYPE with NODE's DERIVED-TYPE. If the
 152 ;;; intersection is different from the old type, then we do a
 153 ;;; REOPTIMIZE-LVAR on the NODE-LVAR.
 154 (defun derive-node-type (node rtype)
 155   (declare (type valued-node node) (type ctype rtype))
 156   (let ((node-type (node-derived-type node)))
 157     (unless (eq node-type rtype)
 158       (let ((int (values-type-intersection node-type rtype))
 159             (lvar (node-lvar node)))
 160         (when (type/= node-type int)
 161           (when (and *check-consistency*
 162                      (eq int *empty-type*)
 163                      (not (eq rtype *empty-type*)))
 164             (let ((*compiler-error-context* node))
 165               (compiler-warn
 166                "New inferred type ~S conflicts with old type:~
 167                 ~%  ~S~%*** possible internal error? Please report this."
 168                (type-specifier rtype) (type-specifier node-type))))
 169           (setf (node-derived-type node) int)
 170           ;; If the new type consists of only one object, replace the
 171           ;; node with a constant reference.
 172           (when (and (ref-p node)
 173                      (lambda-var-p (ref-leaf node)))
 174             (let ((type (single-value-type int)))
 175               (when (and (member-type-p type)
 176                          (null (rest (member-type-members type))))
 177                 (change-ref-leaf node (find-constant
 178                                        (first (member-type-members type)))))))
 179           (reoptimize-lvar lvar)))))
 180   (values))
 181
 182 ;;; This is similar to DERIVE-NODE-TYPE, but asserts that it is an
 183 ;;; error for LVAR's value not to be TYPEP to TYPE. We implement it
 184 ;;; splitting off DEST a new CAST node; old LVAR will deliver values
 185 ;;; to CAST. If we improve the assertion, we set TYPE-CHECK and
 186 ;;; TYPE-ASSERTED to guarantee that the new assertion will be checked.
 187 (defun assert-lvar-type (lvar type policy)
 188   (declare (type lvar lvar) (type ctype type))
 189   (unless (values-subtypep (lvar-derived-type lvar) type)
 190     (let* ((dest (lvar-dest lvar))
 191            (ctran (node-prev dest)))
 192       (with-ir1-environment-from-node dest
 193         (let* ((cast (make-cast lvar type policy))
 194                (internal-lvar (make-lvar))
 195                (internal-ctran (make-ctran)))
 196           (setf (ctran-next ctran) cast
 197                 (node-prev cast) ctran)
 198           (use-continuation cast internal-ctran internal-lvar)
 199           (link-node-to-previous-ctran dest internal-ctran)
 200           (substitute-lvar internal-lvar lvar)
 201           (setf (lvar-dest lvar) cast)
 202           (reoptimize-lvar lvar)
 203           (when (return-p dest)
 204             (node-ends-block cast))
 205           (setf (block-attributep (block-flags (node-block cast))
 206                                   type-check type-asserted)
 207                 t))))))
 208
 209 \f
 210 ;;;; IR1-OPTIMIZE
 211
 212 ;;; Do one forward pass over COMPONENT, deleting unreachable blocks
 213 ;;; and doing IR1 optimizations. We can ignore all blocks that don't
 214 ;;; have the REOPTIMIZE flag set. If COMPONENT-REOPTIMIZE is true when
 215 ;;; we are done, then another iteration would be beneficial.
 216 (defun ir1-optimize (component)
 217   (declare (type component component))
 218   (setf (component-reoptimize component) nil)
 219   (loop with block = (block-next (component-head component))
 220         with tail = (component-tail component)
 221         for last-block = block
 222         until (eq block tail)
 223         do (cond
 224              ;; We delete blocks when there is either no predecessor or the
 225              ;; block is in a lambda that has been deleted. These blocks
 226              ;; would eventually be deleted by DFO recomputation, but doing
 227              ;; it here immediately makes the effect available to IR1
 228              ;; optimization.
 229              ((or (block-delete-p block)
 230                   (null (block-pred block)))
 231               (delete-block-lazily block)
 232               (setq block (clean-component component block)))
 233              ((eq (functional-kind (block-home-lambda block)) :deleted)
 234               ;; Preserve the BLOCK-SUCC invariant that almost every block has
 235               ;; one successor (and a block with DELETE-P set is an acceptable
 236               ;; exception).
 237               (mark-for-deletion block)
 238               (setq block (clean-component component block)))
 239              (t
 240               (loop
 241                  (let ((succ (block-succ block)))
 242                    (unless (singleton-p succ)
 243                      (return)))
 244
 245                  (let ((last (block-last block)))
 246                    (typecase last
 247                      (cif
 248                       (flush-dest (if-test last))
 249                       (when (unlink-node last)
 250                         (return)))
 251                      (exit
 252                       (when (maybe-delete-exit last)
 253                         (return)))))
 254
 255                  (unless (join-successor-if-possible block)
 256                    (return)))
 257
 258               (when (and (block-reoptimize block) (block-component block))
 259                 (aver (not (block-delete-p block)))
 260                 (ir1-optimize-block block))
 261
 262               (cond ((and (block-delete-p block) (block-component block))
 263                      (setq block (clean-component component block)))
 264                     ((and (block-flush-p block) (block-component block))
 265                      (flush-dead-code block)))))
 266         do (when (eq block last-block)
 267              (setq block (block-next block))))
 268
 269   (values))
 270
 271 ;;; Loop over the nodes in BLOCK, acting on (and clearing) REOPTIMIZE
 272 ;;; flags.
 273 ;;;
 274 ;;; Note that although they are cleared here, REOPTIMIZE flags might
 275 ;;; still be set upon return from this function, meaning that further
 276 ;;; optimization is wanted (as a consequence of optimizations we did).
 277 (defun ir1-optimize-block (block)
 278   (declare (type cblock block))
 279   ;; We clear the node and block REOPTIMIZE flags before doing the
 280   ;; optimization, not after. This ensures that the node or block will
 281   ;; be reoptimized if necessary.
 282   (setf (block-reoptimize block) nil)
 283   (do-nodes (node nil block :restart-p t)
 284     (when (node-reoptimize node)
 285       ;; As above, we clear the node REOPTIMIZE flag before optimizing.
 286       (setf (node-reoptimize node) nil)
 287       (typecase node
 288         (ref)
 289         (combination
 290          ;; With a COMBINATION, we call PROPAGATE-FUN-CHANGE whenever
 291          ;; the function changes, and call IR1-OPTIMIZE-COMBINATION if
 292          ;; any argument changes.
 293          (ir1-optimize-combination node))
 294         (cif
 295          (ir1-optimize-if node))
 296         (creturn
 297          ;; KLUDGE: We leave the NODE-OPTIMIZE flag set going into
 298          ;; IR1-OPTIMIZE-RETURN, since IR1-OPTIMIZE-RETURN wants to
 299          ;; clear the flag itself. -- WHN 2002-02-02, quoting original
 300          ;; CMU CL comments
 301          (setf (node-reoptimize node) t)
 302          (ir1-optimize-return node))
 303         (mv-combination
 304          (ir1-optimize-mv-combination node))
 305         (exit
 306          ;; With an EXIT, we derive the node's type from the VALUE's
 307          ;; type.
 308          (let ((value (exit-value node)))
 309            (when value
 310              (derive-node-type node (lvar-derived-type value)))))
 311         (cset
 312          (ir1-optimize-set node))
 313         (cast
 314          (ir1-optimize-cast node)))))
 315
 316   (values))
 317
 318 ;;; Try to join with a successor block. If we succeed, we return true,
 319 ;;; otherwise false.
 320 (defun join-successor-if-possible (block)
 321   (declare (type cblock block))
 322   (let ((next (first (block-succ block))))
 323     (when (block-start next)  ; NEXT is not an END-OF-COMPONENT marker
 324       (cond ( ;; We cannot combine with a successor block if:
 325              (or
 326               ;; The successor has more than one predecessor.
 327               (rest (block-pred next))
 328               ;; The successor is the current block (infinite loop).
 329               (eq next block)
 330               ;; The next block has a different cleanup, and thus
 331               ;; we may want to insert cleanup code between the
 332               ;; two blocks at some point.
 333               (not (eq (block-end-cleanup block)
 334                        (block-start-cleanup next)))
 335               ;; The next block has a different home lambda, and
 336               ;; thus the control transfer is a non-local exit.
 337               (not (eq (block-home-lambda block)
 338                        (block-home-lambda next))))
 339              nil)
 340             (t
 341              (join-blocks block next)
 342              t)))))
 343
 344 ;;; Join together two blocks. The code in BLOCK2 is moved into BLOCK1
 345 ;;; and BLOCK2 is deleted from the DFO. We combine the optimize flags
 346 ;;; for the two blocks so that any indicated optimization gets done.
 347 (defun join-blocks (block1 block2)
 348   (declare (type cblock block1 block2))
 349   (let* ((last1 (block-last block1))
 350          (last2 (block-last block2))
 351          (succ (block-succ block2))
 352          (start2 (block-start block2)))
 353     (do ((ctran start2 (node-next (ctran-next ctran))))
 354         ((not ctran))
 355       (setf (ctran-block ctran) block1))
 356
 357     (unlink-blocks block1 block2)
 358     (dolist (block succ)
 359       (unlink-blocks block2 block)
 360       (link-blocks block1 block))
 361
 362     (setf (ctran-kind start2) :inside-block)
 363     (setf (node-next last1) start2)
 364     (setf (ctran-use start2) last1)
 365     (setf (block-last block1) last2))
 366
 367   (setf (block-flags block1)
 368         (attributes-union (block-flags block1)
 369                           (block-flags block2)
 370                           (block-attributes type-asserted test-modified)))
 371
 372   (let ((next (block-next block2))
 373         (prev (block-prev block2)))
 374     (setf (block-next prev) next)
 375     (setf (block-prev next) prev))
 376
 377   (values))
 378
 379 ;;; Delete any nodes in BLOCK whose value is unused and which have no
 380 ;;; side effects. We can delete sets of lexical variables when the set
 381 ;;; variable has no references.
 382 (defun flush-dead-code (block)
 383   (declare (type cblock block))
 384   (setf (block-flush-p block) nil)
 385   (do-nodes-backwards (node lvar block :restart-p t)
 386     (unless lvar
 387       (typecase node
 388         (ref
 389          (delete-ref node)
 390          (unlink-node node))
 391         (combination
 392          (let ((info (combination-kind node)))
 393            (when (fun-info-p info)
 394              (let ((attr (fun-info-attributes info)))
 395                (when (and (not (ir1-attributep attr call))
 396                           ;; ### For now, don't delete potentially
 397                           ;; flushable calls when they have the CALL
 398                           ;; attribute. Someday we should look at the
 399                           ;; functional args to determine if they have
 400                           ;; any side effects.
 401                           (if (policy node (= safety 3))
 402                               (ir1-attributep attr flushable)
 403                               (ir1-attributep attr unsafely-flushable)))
 404                  (flush-combination node))))))
 405         (mv-combination
 406          (when (eq (basic-combination-kind node) :local)
 407            (let ((fun (combination-lambda node)))
 408              (when (dolist (var (lambda-vars fun) t)
 409                      (when (or (leaf-refs var)
 410                                (lambda-var-sets var))
 411                        (return nil)))
 412                (flush-dest (first (basic-combination-args node)))
 413                (delete-let fun)))))
 414         (exit
 415          (let ((value (exit-value node)))
 416            (when value
 417              (flush-dest value)
 418              (setf (exit-value node) nil))))
 419         (cset
 420          (let ((var (set-var node)))
 421            (when (and (lambda-var-p var)
 422                       (null (leaf-refs var)))
 423              (flush-dest (set-value node))
 424              (setf (basic-var-sets var)
 425                    (delq node (basic-var-sets var)))
 426              (unlink-node node))))
 427         (cast
 428          (unless (cast-type-check node)
 429            (flush-dest (cast-value node))
 430            (unlink-node node))))))
 431
 432   (values))
 433 \f
 434 ;;;; local call return type propagation
 435
 436 ;;; This function is called on RETURN nodes that have their REOPTIMIZE
 437 ;;; flag set. It iterates over the uses of the RESULT, looking for
 438 ;;; interesting stuff to update the TAIL-SET. If a use isn't a local
 439 ;;; call, then we union its type together with the types of other such
 440 ;;; uses. We assign to the RETURN-RESULT-TYPE the intersection of this
 441 ;;; type with the RESULT's asserted type. We can make this
 442 ;;; intersection now (potentially before type checking) because this
 443 ;;; assertion on the result will eventually be checked (if
 444 ;;; appropriate.)
 445 ;;;
 446 ;;; We call MAYBE-CONVERT-TAIL-LOCAL-CALL on each local non-MV
 447 ;;; combination, which may change the succesor of the call to be the
 448 ;;; called function, and if so, checks if the call can become an
 449 ;;; assignment. If we convert to an assignment, we abort, since the
 450 ;;; RETURN has been deleted.
 451 (defun find-result-type (node)
 452   (declare (type creturn node))
 453   (let ((result (return-result node)))
 454     (collect ((use-union *empty-type* values-type-union))
 455       (do-uses (use result)
 456         (let ((use-home (node-home-lambda use)))
 457           (cond ((or (eq (functional-kind use-home) :deleted)
 458                      (block-delete-p (node-block use))))
 459                 ((and (basic-combination-p use)
 460                       (eq (basic-combination-kind use) :local))
 461                  (aver (eq (lambda-tail-set use-home)
 462                            (lambda-tail-set (combination-lambda use))))
 463                  (when (combination-p use)
 464                    (when (nth-value 1 (maybe-convert-tail-local-call use))
 465                      (return-from find-result-type t))))
 466                 (t
 467                  (use-union (node-derived-type use))))))
 468       (let ((int
 469              ;; (values-type-intersection
 470              ;; (continuation-asserted-type result) ; FIXME -- APD, 2002-01-26
 471              (use-union)
 472               ;; )
 473               ))
 474         (setf (return-result-type node) int))))
 475   nil)
 476
 477 ;;; Do stuff to realize that something has changed about the value
 478 ;;; delivered to a return node. Since we consider the return values of
 479 ;;; all functions in the tail set to be equivalent, this amounts to
 480 ;;; bringing the entire tail set up to date. We iterate over the
 481 ;;; returns for all the functions in the tail set, reanalyzing them
 482 ;;; all (not treating NODE specially.)
 483 ;;;
 484 ;;; When we are done, we check whether the new type is different from
 485 ;;; the old TAIL-SET-TYPE. If so, we set the type and also reoptimize
 486 ;;; all the lvars for references to functions in the tail set. This
 487 ;;; will cause IR1-OPTIMIZE-COMBINATION to derive the new type as the
 488 ;;; results of the calls.
 489 (defun ir1-optimize-return (node)
 490   (declare (type creturn node))
 491   (tagbody
 492    :restart
 493      (let* ((tails (lambda-tail-set (return-lambda node)))
 494             (funs (tail-set-funs tails)))
 495        (collect ((res *empty-type* values-type-union))
 496                 (dolist (fun funs)
 497                   (let ((return (lambda-return fun)))
 498                     (when return
 499                       (when (node-reoptimize return)
 500                         (setf (node-reoptimize return) nil)
 501                         (when (find-result-type return)
 502                           (go :restart)))
 503                       (res (return-result-type return)))))
 504
 505                 (when (type/= (res) (tail-set-type tails))
 506                   (setf (tail-set-type tails) (res))
 507                   (dolist (fun (tail-set-funs tails))
 508                     (dolist (ref (leaf-refs fun))
 509                       (reoptimize-lvar (node-lvar ref))))))))
 510
 511   (values))
 512 \f
 513 ;;;; IF optimization
 514
 515 ;;; If the test has multiple uses, replicate the node when possible.
 516 ;;; Also check whether the predicate is known to be true or false,
 517 ;;; deleting the IF node in favor of the appropriate branch when this
 518 ;;; is the case.
 519 (defun ir1-optimize-if (node)
 520   (declare (type cif node))
 521   (let ((test (if-test node))
 522         (block (node-block node)))
 523
 524     (when (and (eq (block-start-node block) node)
 525                (listp (lvar-uses test)))
 526       (do-uses (use test)
 527         (when (immediately-used-p test use)
 528           (convert-if-if use node)
 529           (when (not (listp (lvar-uses test))) (return)))))
 530
 531     (let* ((type (lvar-type test))
 532            (victim
 533             (cond ((constant-lvar-p test)
 534                    (if (lvar-value test)
 535                        (if-alternative node)
 536                        (if-consequent node)))
 537                   ((not (types-equal-or-intersect type (specifier-type 'null)))
 538                    (if-alternative node))
 539                   ((type= type (specifier-type 'null))
 540                    (if-consequent node)))))
 541       (when victim
 542         (flush-dest test)
 543         (when (rest (block-succ block))
 544           (unlink-blocks block victim))
 545         (setf (component-reanalyze (node-component node)) t)
 546         (unlink-node node))))
 547   (values))
 548
 549 ;;; Create a new copy of an IF node that tests the value of the node
 550 ;;; USE. The test must have >1 use, and must be immediately used by
 551 ;;; USE. NODE must be the only node in its block (implying that
 552 ;;; block-start = if-test).
 553 ;;;
 554 ;;; This optimization has an effect semantically similar to the
 555 ;;; source-to-source transformation:
 556 ;;;    (IF (IF A B C) D E) ==>
 557 ;;;    (IF A (IF B D E) (IF C D E))
 558 ;;;
 559 ;;; We clobber the NODE-SOURCE-PATH of both the original and the new
 560 ;;; node so that dead code deletion notes will definitely not consider
 561 ;;; either node to be part of the original source. One node might
 562 ;;; become unreachable, resulting in a spurious note.
 563 (defun convert-if-if (use node)
 564   (declare (type node use) (type cif node))
 565   (with-ir1-environment-from-node node
 566     (let* ((block (node-block node))
 567            (test (if-test node))
 568            (cblock (if-consequent node))
 569            (ablock (if-alternative node))
 570            (use-block (node-block use))
 571            (new-ctran (make-ctran))
 572            (new-lvar (make-lvar))
 573            (new-node (make-if :test new-lvar
 574                               :consequent cblock
 575                               :alternative ablock))
 576            (new-block (ctran-starts-block new-ctran)))
 577       (link-node-to-previous-ctran new-node new-ctran)
 578       (setf (lvar-dest new-lvar) new-node)
 579       (setf (block-last new-block) new-node)
 580
 581       (unlink-blocks use-block block)
 582       (%delete-lvar-use use)
 583       (add-lvar-use use new-lvar)
 584       (link-blocks use-block new-block)
 585
 586       (link-blocks new-block cblock)
 587       (link-blocks new-block ablock)
 588
 589       (push "<IF Duplication>" (node-source-path node))
 590       (push "<IF Duplication>" (node-source-path new-node))
 591
 592       (reoptimize-lvar test)
 593       (reoptimize-lvar new-lvar)
 594       (setf (component-reanalyze *current-component*) t)))
 595   (values))
 596 \f
 597 ;;;; exit IR1 optimization
 598
 599 ;;; This function attempts to delete an exit node, returning true if
 600 ;;; it deletes the block as a consequence:
 601 ;;; -- If the exit is degenerate (has no ENTRY), then we don't do
 602 ;;;    anything, since there is nothing to be done.
 603 ;;; -- If the exit node and its ENTRY have the same home lambda then
 604 ;;;    we know the exit is local, and can delete the exit. We change
 605 ;;;    uses of the Exit-Value to be uses of the original lvar,
 606 ;;;    then unlink the node. If the exit is to a TR context, then we
 607 ;;;    must do MERGE-TAIL-SETS on any local calls which delivered
 608 ;;;    their value to this exit.
 609 ;;; -- If there is no value (as in a GO), then we skip the value
 610 ;;;    semantics.
 611 ;;;
 612 ;;; This function is also called by environment analysis, since it
 613 ;;; wants all exits to be optimized even if normal optimization was
 614 ;;; omitted.
 615 (defun maybe-delete-exit (node)
 616   (declare (type exit node))
 617   (let ((value (exit-value node))
 618         (entry (exit-entry node)))
 619     (when (and entry
 620                (eq (node-home-lambda node) (node-home-lambda entry)))
 621       (setf (entry-exits entry) (delq node (entry-exits entry)))
 622       (if value
 623           (delete-filter node (node-lvar node) value)
 624           (unlink-node node)))))
 625
 626 \f
 627 ;;;; combination IR1 optimization
 628
 629 ;;; Report as we try each transform?
 630 #!+sb-show
 631 (defvar *show-transforms-p* nil)
 632
 633 ;;; Do IR1 optimizations on a COMBINATION node.
 634 (declaim (ftype (function (combination) (values)) ir1-optimize-combination))
 635 (defun ir1-optimize-combination (node)
 636   (when (lvar-reoptimize (basic-combination-fun node))
 637     (propagate-fun-change node)
 638     (maybe-terminate-block node nil))
 639   (let ((args (basic-combination-args node))
 640         (kind (basic-combination-kind node)))
 641     (case kind
 642       (:local
 643        (let ((fun (combination-lambda node)))
 644          (if (eq (functional-kind fun) :let)
 645              (propagate-let-args node fun)
 646              (propagate-local-call-args node fun))))
 647       ((:full :error)
 648        (dolist (arg args)
 649          (when arg
 650            (setf (lvar-reoptimize arg) nil))))
 651       (t
 652        (dolist (arg args)
 653          (when arg
 654            (setf (lvar-reoptimize arg) nil)))
 655
 656        (let ((attr (fun-info-attributes kind)))
 657          (when (and (ir1-attributep attr foldable)
 658                     ;; KLUDGE: The next test could be made more sensitive,
 659                     ;; only suppressing constant-folding of functions with
 660                     ;; CALL attributes when they're actually passed
 661                     ;; function arguments. -- WHN 19990918
 662                     (not (ir1-attributep attr call))
 663                     (every #'constant-lvar-p args)
 664                     (node-lvar node)
 665                     ;; Even if the function is foldable in principle,
 666                     ;; it might be one of our low-level
 667                     ;; implementation-specific functions. Such
 668                     ;; functions don't necessarily exist at runtime on
 669                     ;; a plain vanilla ANSI Common Lisp
 670                     ;; cross-compilation host, in which case the
 671                     ;; cross-compiler can't fold it because the
 672                     ;; cross-compiler doesn't know how to evaluate it.
 673                     #+sb-xc-host
 674                     (or (fboundp (combination-fun-source-name node))
 675                         (progn (format t ";;; !!! Unbound fun: (~S~{ ~S~})~%"
 676                                        (combination-fun-source-name node)
 677                                        (mapcar #'lvar-value args))
 678                                nil)))
 679            (constant-fold-call node)
 680            (return-from ir1-optimize-combination)))
 681
 682        (let ((fun (fun-info-derive-type kind)))
 683          (when fun
 684            (let ((res (funcall fun node)))
 685              (when res
 686                (derive-node-type node (coerce-to-values res))
 687                (maybe-terminate-block node nil)))))
 688
 689        (let ((fun (fun-info-optimizer kind)))
 690          (unless (and fun (funcall fun node))
 691            (dolist (x (fun-info-transforms kind))
 692              #!+sb-show
 693              (when *show-transforms-p*
 694                (let* ((lvar (basic-combination-fun node))
 695                       (fname (lvar-fun-name lvar t)))
 696                  (/show "trying transform" x (transform-function x) "for" fname)))
 697              (unless (ir1-transform node x)
 698                #!+sb-show
 699                (when *show-transforms-p*
 700                  (/show "quitting because IR1-TRANSFORM result was NIL"))
 701                (return))))))))
 702
 703   (values))
 704
 705 ;;; If NODE doesn't return (i.e. return type is NIL), then terminate
 706 ;;; the block there, and link it to the component tail.
 707 ;;;
 708 ;;; Except when called during IR1 convertion, we delete the
 709 ;;; continuation if it has no other uses. (If it does have other uses,
 710 ;;; we reoptimize.)
 711 ;;;
 712 ;;; Termination on the basis of a continuation type is
 713 ;;; inhibited when:
 714 ;;; -- The continuation is deleted (hence the assertion is spurious), or
 715 ;;; -- We are in IR1 conversion (where THE assertions are subject to
 716 ;;;    weakening.) FIXME: Now THE assertions are not weakened, but new
 717 ;;;    uses can(?) be added later. -- APD, 2003-07-17
 718 ;;;
 719 ;;; Why do we need to consider LVAR type? -- APD, 2003-07-30
 720 (defun maybe-terminate-block (node ir1-converting-not-optimizing-p)
 721   (declare (type (or basic-combination cast) node))
 722   (let* ((block (node-block node))
 723          (lvar (node-lvar node))
 724          (ctran (node-next node))
 725          (tail (component-tail (block-component block)))
 726          (succ (first (block-succ block))))
 727     (unless (or (and (eq node (block-last block)) (eq succ tail))
 728                 (block-delete-p block))
 729       (when (eq (node-derived-type node) *empty-type*)
 730         (cond (ir1-converting-not-optimizing-p
 731                (cond
 732                  ((block-last block)
 733                   (aver (eq (block-last block) node)))
 734                  (t
 735                   (setf (block-last block) node)
 736                   (setf (ctran-use ctran) nil)
 737                   (setf (ctran-kind ctran) :unused)
 738                   (setf (ctran-block ctran) nil)
 739                   (setf (node-next node) nil)
 740                   (link-blocks block (ctran-starts-block ctran)))))
 741               (t
 742                (node-ends-block node)))
 743
 744         (unlink-blocks block (first (block-succ block)))
 745         (setf (component-reanalyze (block-component block)) t)
 746         (aver (not (block-succ block)))
 747         (link-blocks block tail)
 748         (if ir1-converting-not-optimizing-p
 749             (%delete-lvar-use node)
 750             (delete-lvar-use node))
 751         t))))
 752
 753 ;;; This is called both by IR1 conversion and IR1 optimization when
 754 ;;; they have verified the type signature for the call, and are
 755 ;;; wondering if something should be done to special-case the call. If
 756 ;;; CALL is a call to a global function, then see whether it defined
 757 ;;; or known:
 758 ;;; -- If a DEFINED-FUN should be inline expanded, then convert
 759 ;;;    the expansion and change the call to call it. Expansion is
 760 ;;;    enabled if :INLINE or if SPACE=0. If the FUNCTIONAL slot is
 761 ;;;    true, we never expand, since this function has already been
 762 ;;;    converted. Local call analysis will duplicate the definition
 763 ;;;    if necessary. We claim that the parent form is LABELS for
 764 ;;;    context declarations, since we don't want it to be considered
 765 ;;;    a real global function.
 766 ;;; -- If it is a known function, mark it as such by setting the KIND.
 767 ;;;
 768 ;;; We return the leaf referenced (NIL if not a leaf) and the
 769 ;;; FUN-INFO assigned.
 770 (defun recognize-known-call (call ir1-converting-not-optimizing-p)
 771   (declare (type combination call))
 772   (let* ((ref (lvar-uses (basic-combination-fun call)))
 773          (leaf (when (ref-p ref) (ref-leaf ref)))
 774          (inlinep (if (defined-fun-p leaf)
 775                       (defined-fun-inlinep leaf)
 776                       :no-chance)))
 777     (cond
 778      ((eq inlinep :notinline) (values nil nil))
 779      ((not (and (global-var-p leaf)
 780                 (eq (global-var-kind leaf) :global-function)))
 781       (values leaf nil))
 782      ((and (ecase inlinep
 783              (:inline t)
 784              (:no-chance nil)
 785              ((nil :maybe-inline) (policy call (zerop space))))
 786            (defined-fun-p leaf)
 787            (defined-fun-inline-expansion leaf)
 788            (let ((fun (defined-fun-functional leaf)))
 789              (or (not fun)
 790                  (and (eq inlinep :inline) (functional-kind fun))))
 791            (inline-expansion-ok call))
 792       (flet (;; FIXME: Is this what the old CMU CL internal documentation
 793              ;; called semi-inlining? A more descriptive name would
 794              ;; be nice. -- WHN 2002-01-07
 795              (frob ()
 796                (let ((res (ir1-convert-lambda-for-defun
 797                            (defined-fun-inline-expansion leaf)
 798                            leaf t
 799                            #'ir1-convert-inline-lambda)))
 800                  (setf (defined-fun-functional leaf) res)
 801                  (change-ref-leaf ref res))))
 802         (if ir1-converting-not-optimizing-p
 803             (frob)
 804             (with-ir1-environment-from-node call
 805               (frob)
 806               (locall-analyze-component *current-component*))))
 807
 808       (values (ref-leaf (lvar-uses (basic-combination-fun call)))
 809               nil))
 810      (t
 811       (let ((info (info :function :info (leaf-source-name leaf))))
 812         (if info
 813             (values leaf (setf (basic-combination-kind call) info))
 814             (values leaf nil)))))))
 815
 816 ;;; Check whether CALL satisfies TYPE. If so, apply the type to the
 817 ;;; call, and do MAYBE-TERMINATE-BLOCK and return the values of
 818 ;;; RECOGNIZE-KNOWN-CALL. If an error, set the combination kind and
 819 ;;; return NIL, NIL. If the type is just FUNCTION, then skip the
 820 ;;; syntax check, arg/result type processing, but still call
 821 ;;; RECOGNIZE-KNOWN-CALL, since the call might be to a known lambda,
 822 ;;; and that checking is done by local call analysis.
 823 (defun validate-call-type (call type ir1-converting-not-optimizing-p)
 824   (declare (type combination call) (type ctype type))
 825   (cond ((not (fun-type-p type))
 826          (aver (multiple-value-bind (val win)
 827                    (csubtypep type (specifier-type 'function))
 828                  (or val (not win))))
 829          (recognize-known-call call ir1-converting-not-optimizing-p))
 830         ((valid-fun-use call type
 831                         :argument-test #'always-subtypep
 832                         :result-test #'always-subtypep
 833                         ;; KLUDGE: Common Lisp is such a dynamic
 834                         ;; language that all we can do here in
 835                         ;; general is issue a STYLE-WARNING. It
 836                         ;; would be nice to issue a full WARNING
 837                         ;; in the special case of of type
 838                         ;; mismatches within a compilation unit
 839                         ;; (as in section 3.2.2.3 of the spec)
 840                         ;; but at least as of sbcl-0.6.11, we
 841                         ;; don't keep track of whether the
 842                         ;; mismatched data came from the same
 843                         ;; compilation unit, so we can't do that.
 844                         ;; -- WHN 2001-02-11
 845                         ;;
 846                         ;; FIXME: Actually, I think we could
 847                         ;; issue a full WARNING if the call
 848                         ;; violates a DECLAIM FTYPE.
 849                         :lossage-fun #'compiler-style-warn
 850                         :unwinnage-fun #'compiler-notify)
 851          (assert-call-type call type)
 852          (maybe-terminate-block call ir1-converting-not-optimizing-p)
 853          (recognize-known-call call ir1-converting-not-optimizing-p))
 854         (t
 855          (setf (combination-kind call) :error)
 856          (values nil nil))))
 857
 858 ;;; This is called by IR1-OPTIMIZE when the function for a call has
 859 ;;; changed. If the call is local, we try to LET-convert it, and
 860 ;;; derive the result type. If it is a :FULL call, we validate it
 861 ;;; against the type, which recognizes known calls, does inline
 862 ;;; expansion, etc. If a call to a predicate in a non-conditional
 863 ;;; position or to a function with a source transform, then we
 864 ;;; reconvert the form to give IR1 another chance.
 865 (defun propagate-fun-change (call)
 866   (declare (type combination call))
 867   (let ((*compiler-error-context* call)
 868         (fun-lvar (basic-combination-fun call)))
 869     (setf (lvar-reoptimize fun-lvar) nil)
 870     (case (combination-kind call)
 871       (:local
 872        (let ((fun (combination-lambda call)))
 873          (maybe-let-convert fun)
 874          (unless (member (functional-kind fun) '(:let :assignment :deleted))
 875            (derive-node-type call (tail-set-type (lambda-tail-set fun))))))
 876       (:full
 877        (multiple-value-bind (leaf info)
 878            (validate-call-type call (lvar-type fun-lvar) nil)
 879          (cond ((functional-p leaf)
 880                 (convert-call-if-possible
 881                  (lvar-uses (basic-combination-fun call))
 882                  call))
 883                ((not leaf))
 884                ((and (leaf-has-source-name-p leaf)
 885                      (or (info :function :source-transform (leaf-source-name leaf))
 886                          (and info
 887                               (ir1-attributep (fun-info-attributes info)
 888                                               predicate)
 889                               (let ((lvar (node-lvar call)))
 890                                 (and lvar (not (if-p (lvar-dest lvar))))))))
 891                 (let ((name (leaf-source-name leaf))
 892                       (dummies (make-gensym-list
 893                                 (length (combination-args call)))))
 894                   (transform-call call
 895                                   `(lambda ,dummies
 896                                      (,@(if (symbolp name)
 897                                             `(,name)
 898                                             `(funcall #',name))
 899                                         ,@dummies))
 900                                   (leaf-source-name leaf)))))))))
 901   (values))
 902 \f
 903 ;;;; known function optimization
 904
 905 ;;; Add a failed optimization note to FAILED-OPTIMZATIONS for NODE,
 906 ;;; FUN and ARGS. If there is already a note for NODE and TRANSFORM,
 907 ;;; replace it, otherwise add a new one.
 908 (defun record-optimization-failure (node transform args)
 909   (declare (type combination node) (type transform transform)
 910            (type (or fun-type list) args))
 911   (let* ((table (component-failed-optimizations *component-being-compiled*))
 912          (found (assoc transform (gethash node table))))
 913     (if found
 914         (setf (cdr found) args)
 915         (push (cons transform args) (gethash node table))))
 916   (values))
 917
 918 ;;; Attempt to transform NODE using TRANSFORM-FUNCTION, subject to the
 919 ;;; call type constraint TRANSFORM-TYPE. If we are inhibited from
 920 ;;; doing the transform for some reason and FLAME is true, then we
 921 ;;; make a note of the message in FAILED-OPTIMIZATIONS for IR1
 922 ;;; finalize to pick up. We return true if the transform failed, and
 923 ;;; thus further transformation should be attempted. We return false
 924 ;;; if either the transform succeeded or was aborted.
 925 (defun ir1-transform (node transform)
 926   (declare (type combination node) (type transform transform))
 927   (let* ((type (transform-type transform))
 928          (fun (transform-function transform))
 929          (constrained (fun-type-p type))
 930          (table (component-failed-optimizations *component-being-compiled*))
 931          (flame (if (transform-important transform)
 932                     (policy node (>= speed inhibit-warnings))
 933                     (policy node (> speed inhibit-warnings))))
 934          (*compiler-error-context* node))
 935     (cond ((or (not constrained)
 936                (valid-fun-use node type))
 937            (multiple-value-bind (severity args)
 938                (catch 'give-up-ir1-transform
 939                  (transform-call node
 940                                  (funcall fun node)
 941                                  (combination-fun-source-name node))
 942                  (values :none nil))
 943              (ecase severity
 944                (:none
 945                 (remhash node table)
 946                 nil)
 947                (:aborted
 948                 (setf (combination-kind node) :error)
 949                 (when args
 950                   (apply #'compiler-warn args))
 951                 (remhash node table)
 952                 nil)
 953                (:failure
 954                 (if args
 955                     (when flame
 956                       (record-optimization-failure node transform args))
 957                     (setf (gethash node table)
 958                           (remove transform (gethash node table) :key #'car)))
 959                 t)
 960                (:delayed
 961                  (remhash node table)
 962                  nil))))
 963           ((and flame
 964                 (valid-fun-use node
 965                                type
 966                                :argument-test #'types-equal-or-intersect
 967                                :result-test #'values-types-equal-or-intersect))
 968            (record-optimization-failure node transform type)
 969            t)
 970           (t
 971            t))))
 972
 973 ;;; When we don't like an IR1 transform, we throw the severity/reason
 974 ;;; and args.
 975 ;;;
 976 ;;; GIVE-UP-IR1-TRANSFORM is used to throw out of an IR1 transform,
 977 ;;; aborting this attempt to transform the call, but admitting the
 978 ;;; possibility that this or some other transform will later succeed.
 979 ;;; If arguments are supplied, they are format arguments for an
 980 ;;; efficiency note.
 981 ;;;
 982 ;;; ABORT-IR1-TRANSFORM is used to throw out of an IR1 transform and
 983 ;;; force a normal call to the function at run time. No further
 984 ;;; optimizations will be attempted.
 985 ;;;
 986 ;;; DELAY-IR1-TRANSFORM is used to throw out of an IR1 transform, and
 987 ;;; delay the transform on the node until later. REASONS specifies
 988 ;;; when the transform will be later retried. The :OPTIMIZE reason
 989 ;;; causes the transform to be delayed until after the current IR1
 990 ;;; optimization pass. The :CONSTRAINT reason causes the transform to
 991 ;;; be delayed until after constraint propagation.
 992 ;;;
 993 ;;; FIXME: Now (0.6.11.44) that there are 4 variants of this (GIVE-UP,
 994 ;;; ABORT, DELAY/:OPTIMIZE, DELAY/:CONSTRAINT) and we're starting to
 995 ;;; do CASE operations on the various REASON values, it might be a
 996 ;;; good idea to go OO, representing the reasons by objects, using
 997 ;;; CLOS methods on the objects instead of CASE, and (possibly) using
 998 ;;; SIGNAL instead of THROW.
 999 (declaim (ftype (function (&rest t) nil) give-up-ir1-transform))
1000 (defun give-up-ir1-transform (&rest args)
1001   (throw 'give-up-ir1-transform (values :failure args)))
1002 (defun abort-ir1-transform (&rest args)
1003   (throw 'give-up-ir1-transform (values :aborted args)))
1004 (defun delay-ir1-transform (node &rest reasons)
1005   (let ((assoc (assoc node *delayed-ir1-transforms*)))
1006     (cond ((not assoc)
1007             (setf *delayed-ir1-transforms*
1008                     (acons node reasons *delayed-ir1-transforms*))
1009             (throw 'give-up-ir1-transform :delayed))
1010           ((cdr assoc)
1011             (dolist (reason reasons)
1012               (pushnew reason (cdr assoc)))
1013             (throw 'give-up-ir1-transform :delayed)))))
1014
1015 ;;; Clear any delayed transform with no reasons - these should have
1016 ;;; been tried in the last pass. Then remove the reason from the
1017 ;;; delayed transform reasons, and if any become empty then set
1018 ;;; reoptimize flags for the node. Return true if any transforms are
1019 ;;; to be retried.
1020 (defun retry-delayed-ir1-transforms (reason)
1021   (setf *delayed-ir1-transforms*
1022         (remove-if-not #'cdr *delayed-ir1-transforms*))
1023   (let ((reoptimize nil))
1024     (dolist (assoc *delayed-ir1-transforms*)
1025       (let ((reasons (remove reason (cdr assoc))))
1026         (setf (cdr assoc) reasons)
1027         (unless reasons
1028           (let ((node (car assoc)))
1029             (unless (node-deleted node)
1030               (setf reoptimize t)
1031               (setf (node-reoptimize node) t)
1032               (let ((block (node-block node)))
1033                 (setf (block-reoptimize block) t)
1034                 (setf (component-reoptimize (block-component block)) t)))))))
1035     reoptimize))
1036
1037 ;;; Take the lambda-expression RES, IR1 convert it in the proper
1038 ;;; environment, and then install it as the function for the call
1039 ;;; NODE. We do local call analysis so that the new function is
1040 ;;; integrated into the control flow.
1041 ;;;
1042 ;;; We require the original function source name in order to generate
1043 ;;; a meaningful debug name for the lambda we set up. (It'd be
1044 ;;; possible to do this starting from debug names as well as source
1045 ;;; names, but as of sbcl-0.7.1.5, there was no need for this
1046 ;;; generality, since source names are always known to our callers.)
1047 (defun transform-call (call res source-name)
1048   (declare (type combination call) (list res))
1049   (aver (and (legal-fun-name-p source-name)
1050              (not (eql source-name '.anonymous.))))
1051   (node-ends-block call)
1052   (with-ir1-environment-from-node call
1053     (with-component-last-block (*current-component*
1054                                 (block-next (node-block call)))
1055       (let ((new-fun (ir1-convert-inline-lambda
1056                       res
1057                       :debug-name (debug-namify "LAMBDA-inlined ~A"
1058                                                 (as-debug-name
1059                                                  source-name
1060                                                  "<unknown function>"))))
1061             (ref (lvar-use (combination-fun call))))
1062         (change-ref-leaf ref new-fun)
1063         (setf (combination-kind call) :full)
1064         (locall-analyze-component *current-component*))))
1065   (values))
1066
1067 ;;; Replace a call to a foldable function of constant arguments with
1068 ;;; the result of evaluating the form. If there is an error during the
1069 ;;; evaluation, we give a warning and leave the call alone, making the
1070 ;;; call a :ERROR call.
1071 ;;;
1072 ;;; If there is more than one value, then we transform the call into a
1073 ;;; VALUES form.
1074 (defun constant-fold-call (call)
1075   (let ((args (mapcar #'lvar-value (combination-args call)))
1076         (fun-name (combination-fun-source-name call)))
1077     (multiple-value-bind (values win)
1078         (careful-call fun-name
1079                       args
1080                       call
1081                       ;; Note: CMU CL had COMPILER-WARN here, and that
1082                       ;; seems more natural, but it's probably not.
1083                       ;;
1084                       ;; It's especially not while bug 173 exists:
1085                       ;; Expressions like
1086                       ;;   (COND (END
1087                       ;;          (UNLESS (OR UNSAFE? (<= END SIZE)))
1088                       ;;            ...))
1089                       ;; can cause constant-folding TYPE-ERRORs (in
1090                       ;; #'<=) when END can be proved to be NIL, even
1091                       ;; though the code is perfectly legal and safe
1092                       ;; because a NIL value of END means that the
1093                       ;; #'<= will never be executed.
1094                       ;;
1095                       ;; Moreover, even without bug 173,
1096                       ;; quite-possibly-valid code like
1097                       ;;   (COND ((NONINLINED-PREDICATE END)
1098                       ;;          (UNLESS (<= END SIZE))
1099                       ;;            ...))
1100                       ;; (where NONINLINED-PREDICATE is something the
1101                       ;; compiler can't do at compile time, but which
1102                       ;; turns out to make the #'<= expression
1103                       ;; unreachable when END=NIL) could cause errors
1104                       ;; when the compiler tries to constant-fold (<=
1105                       ;; END SIZE).
1106                       ;;
1107                       ;; So, with or without bug 173, it'd be
1108                       ;; unnecessarily evil to do a full
1109                       ;; COMPILER-WARNING (and thus return FAILURE-P=T
1110                       ;; from COMPILE-FILE) for legal code, so we we
1111                       ;; use a wimpier COMPILE-STYLE-WARNING instead.
1112                       #'compiler-style-warn
1113                       "constant folding")
1114       (cond ((not win)
1115              (setf (combination-kind call) :error))
1116             ((and (proper-list-of-length-p values 1))
1117              (with-ir1-environment-from-node call
1118                (let* ((lvar (node-lvar call))
1119                       (prev (node-prev call))
1120                       (intermediate-ctran (make-ctran)))
1121                  (%delete-lvar-use call)
1122                  (setf (ctran-next prev) nil)
1123                  (setf (node-prev call) nil)
1124                  (reference-constant prev intermediate-ctran lvar
1125                                      (first values))
1126                  (link-node-to-previous-ctran call intermediate-ctran)
1127                  (reoptimize-lvar lvar)
1128                  (flush-combination call))))
1129             (t (let ((dummies (make-gensym-list (length args))))
1130                  (transform-call
1131                   call
1132                   `(lambda ,dummies
1133                      (declare (ignore ,@dummies))
1134                      (values ,@(mapcar (lambda (x) `',x) values)))
1135                   fun-name))))))
1136   (values))
1137 \f
1138 ;;;; local call optimization
1139
1140 ;;; Propagate TYPE to LEAF and its REFS, marking things changed. If
1141 ;;; the leaf type is a function type, then just leave it alone, since
1142 ;;; TYPE is never going to be more specific than that (and
1143 ;;; TYPE-INTERSECTION would choke.)
1144 (defun propagate-to-refs (leaf type)
1145   (declare (type leaf leaf) (type ctype type))
1146   (let ((var-type (leaf-type leaf)))
1147     (unless (fun-type-p var-type)
1148       (let ((int (type-approx-intersection2 var-type type)))
1149         (when (type/= int var-type)
1150           (setf (leaf-type leaf) int)
1151           (dolist (ref (leaf-refs leaf))
1152             (derive-node-type ref (make-single-value-type int))
1153             ;; KLUDGE: LET var substitution
1154             (let* ((lvar (node-lvar ref)))
1155               (when (and lvar (combination-p (lvar-dest lvar)))
1156                 (reoptimize-lvar lvar))))))
1157       (values))))
1158
1159 ;;; Iteration variable: exactly one SETQ of the form:
1160 ;;;
1161 ;;; (let ((var initial))
1162 ;;;   ...
1163 ;;;   (setq var (+ var step))
1164 ;;;   ...)
1165 (defun maybe-infer-iteration-var-type (var initial-type)
1166   (binding* ((sets (lambda-var-sets var) :exit-if-null)
1167              (set (first sets))
1168              (() (null (rest sets)) :exit-if-null)
1169              (set-use (principal-lvar-use (set-value set)))
1170              (() (and (combination-p set-use)
1171                       (fun-info-p (combination-kind set-use))
1172                       (not (node-to-be-deleted-p set-use))
1173                       (eq (combination-fun-source-name set-use) '+))
1174                :exit-if-null)
1175              (+-args (basic-combination-args set-use))
1176              (() (and (proper-list-of-length-p +-args 2 2)
1177                       (let ((first (principal-lvar-use
1178                                     (first +-args))))
1179                         (and (ref-p first)
1180                              (eq (ref-leaf first) var))))
1181                :exit-if-null)
1182              (step-type (lvar-type (second +-args)))
1183              (set-type (lvar-type (set-value set))))
1184     (when (and (numeric-type-p initial-type)
1185                (numeric-type-p step-type)
1186                (numeric-type-equal initial-type step-type))
1187       (multiple-value-bind (low high)
1188           (cond ((csubtypep step-type (specifier-type '(real 0 *)))
1189                  (values (numeric-type-low initial-type)
1190                          (when (and (numeric-type-p set-type)
1191                                     (numeric-type-equal set-type initial-type))
1192                            (numeric-type-high set-type))))
1193                 ((csubtypep step-type (specifier-type '(real * 0)))
1194                  (values (when (and (numeric-type-p set-type)
1195                                     (numeric-type-equal set-type initial-type))
1196                            (numeric-type-low set-type))
1197                          (numeric-type-high initial-type)))
1198                 (t
1199                  (values nil nil)))
1200         (modified-numeric-type initial-type
1201                                :low low
1202                                :high high
1203                                :enumerable nil)))))
1204 (deftransform + ((x y) * * :result result)
1205   "check for iteration variable reoptimization"
1206   (let ((dest (principal-lvar-end result))
1207         (use (principal-lvar-use x)))
1208     (when (and (ref-p use)
1209                (set-p dest)
1210                (eq (ref-leaf use)
1211                    (set-var dest)))
1212       (reoptimize-lvar (set-value dest))))
1213   (give-up-ir1-transform))
1214
1215 ;;; Figure out the type of a LET variable that has sets. We compute
1216 ;;; the union of the INITIAL-TYPE and the types of all the set
1217 ;;; values and to a PROPAGATE-TO-REFS with this type.
1218 (defun propagate-from-sets (var initial-type)
1219   (collect ((res initial-type type-union))
1220     (dolist (set (basic-var-sets var))
1221       (let ((type (lvar-type (set-value set))))
1222         (res type)
1223         (when (node-reoptimize set)
1224           (derive-node-type set (make-single-value-type type))
1225           (setf (node-reoptimize set) nil))))
1226     (let ((res (res)))
1227       (awhen (maybe-infer-iteration-var-type var initial-type)
1228         (setq res it))
1229       (propagate-to-refs var res)))
1230   (values))
1231
1232 ;;; If a LET variable, find the initial value's type and do
1233 ;;; PROPAGATE-FROM-SETS. We also derive the VALUE's type as the node's
1234 ;;; type.
1235 (defun ir1-optimize-set (node)
1236   (declare (type cset node))
1237   (let ((var (set-var node)))
1238     (when (and (lambda-var-p var) (leaf-refs var))
1239       (let ((home (lambda-var-home var)))
1240         (when (eq (functional-kind home) :let)
1241           (let* ((initial-value (let-var-initial-value var))
1242                  (initial-type (lvar-type initial-value)))
1243             (setf (lvar-reoptimize initial-value) nil)
1244             (propagate-from-sets var initial-type))))))
1245
1246   (derive-node-type node (make-single-value-type
1247                           (lvar-type (set-value node))))
1248   (values))
1249
1250 ;;; Return true if the value of REF will always be the same (and is
1251 ;;; thus legal to substitute.)
1252 (defun constant-reference-p (ref)
1253   (declare (type ref ref))
1254   (let ((leaf (ref-leaf ref)))
1255     (typecase leaf
1256       ((or constant functional) t)
1257       (lambda-var
1258        (null (lambda-var-sets leaf)))
1259       (defined-fun
1260        (not (eq (defined-fun-inlinep leaf) :notinline)))
1261       (global-var
1262        (case (global-var-kind leaf)
1263          (:global-function
1264           (let ((name (leaf-source-name leaf)))
1265             (or #-sb-xc-host
1266                 (eq (symbol-package (fun-name-block-name name))
1267                     *cl-package*)
1268                 (info :function :info name)))))))))
1269
1270 ;;; If we have a non-set LET var with a single use, then (if possible)
1271 ;;; replace the variable reference's LVAR with the arg lvar.
1272 ;;;
1273 ;;; We change the REF to be a reference to NIL with unused value, and
1274 ;;; let it be flushed as dead code. A side effect of this substitution
1275 ;;; is to delete the variable.
1276 (defun substitute-single-use-lvar (arg var)
1277   (declare (type lvar arg) (type lambda-var var))
1278   (binding* ((ref (first (leaf-refs var)))
1279              (lvar (node-lvar ref) :exit-if-null)
1280              (dest (lvar-dest lvar)))
1281     (when (and
1282            ;; Think about (LET ((A ...)) (IF ... A ...)): two
1283            ;; LVAR-USEs should not be met on one path.
1284            (eq (lvar-uses lvar) ref)
1285            (typecase dest
1286              ;; we should not change lifetime of unknown values lvars
1287              (cast
1288               (and (type-single-value-p (lvar-derived-type arg))
1289                    (multiple-value-bind (pdest pprev)
1290                        (principal-lvar-end lvar)
1291                      (declare (ignore pdest))
1292                      (lvar-single-value-p pprev))))
1293              (mv-combination
1294               (or (eq (basic-combination-fun dest) lvar)
1295                   (and (eq (basic-combination-kind dest) :local)
1296                        (type-single-value-p (lvar-derived-type arg)))))
1297              ((or creturn exit)
1298               ;; While CRETURN and EXIT nodes may be known-values,
1299               ;; they have their own complications, such as
1300               ;; substitution into CRETURN may create new tail calls.
1301               nil)
1302              (t
1303               (aver (lvar-single-value-p lvar))
1304               t))
1305            (eq (node-home-lambda ref)
1306                (lambda-home (lambda-var-home var))))
1307       (setf (node-derived-type ref) *wild-type*)
1308       (substitute-lvar-uses lvar arg)
1309       (delete-lvar-use ref)
1310       (change-ref-leaf ref (find-constant nil))
1311       (delete-ref ref)
1312       (unlink-node ref)
1313       (reoptimize-lvar lvar)
1314       t)))
1315
1316 ;;; Delete a LET, removing the call and bind nodes, and warning about
1317 ;;; any unreferenced variables. Note that FLUSH-DEAD-CODE will come
1318 ;;; along right away and delete the REF and then the lambda, since we
1319 ;;; flush the FUN lvar.
1320 (defun delete-let (clambda)
1321   (declare (type clambda clambda))
1322   (aver (functional-letlike-p clambda))
1323   (note-unreferenced-vars clambda)
1324   (let ((call (let-combination clambda)))
1325     (flush-dest (basic-combination-fun call))
1326     (unlink-node call)
1327     (unlink-node (lambda-bind clambda))
1328     (setf (lambda-bind clambda) nil))
1329   (values))
1330
1331 ;;; This function is called when one of the arguments to a LET
1332 ;;; changes. We look at each changed argument. If the corresponding
1333 ;;; variable is set, then we call PROPAGATE-FROM-SETS. Otherwise, we
1334 ;;; consider substituting for the variable, and also propagate
1335 ;;; derived-type information for the arg to all the VAR's refs.
1336 ;;;
1337 ;;; Substitution is inhibited when the arg leaf's derived type isn't a
1338 ;;; subtype of the argument's leaf type. This prevents type checking
1339 ;;; from being defeated, and also ensures that the best representation
1340 ;;; for the variable can be used.
1341 ;;;
1342 ;;; Substitution of individual references is inhibited if the
1343 ;;; reference is in a different component from the home. This can only
1344 ;;; happen with closures over top level lambda vars. In such cases,
1345 ;;; the references may have already been compiled, and thus can't be
1346 ;;; retroactively modified.
1347 ;;;
1348 ;;; If all of the variables are deleted (have no references) when we
1349 ;;; are done, then we delete the LET.
1350 ;;;
1351 ;;; Note that we are responsible for clearing the LVAR-REOPTIMIZE
1352 ;;; flags.
1353 (defun propagate-let-args (call fun)
1354   (declare (type combination call) (type clambda fun))
1355   (loop for arg in (combination-args call)
1356         and var in (lambda-vars fun) do
1357     (when (and arg (lvar-reoptimize arg))
1358       (setf (lvar-reoptimize arg) nil)
1359       (cond
1360         ((lambda-var-sets var)
1361          (propagate-from-sets var (lvar-type arg)))
1362         ((let ((use (lvar-uses arg)))
1363            (when (ref-p use)
1364              (let ((leaf (ref-leaf use)))
1365                (when (and (constant-reference-p use)
1366                           (csubtypep (leaf-type leaf)
1367                                      ;; (NODE-DERIVED-TYPE USE) would
1368                                      ;; be better -- APD, 2003-05-15
1369                                      (leaf-type var)))
1370                  (propagate-to-refs var (lvar-type arg))
1371                  (let ((use-component (node-component use)))
1372                    (prog1 (substitute-leaf-if
1373                            (lambda (ref)
1374                              (cond ((eq (node-component ref) use-component)
1375                                     t)
1376                                    (t
1377                                     (aver (lambda-toplevelish-p (lambda-home fun)))
1378                                     nil)))
1379                            leaf var)))
1380                  t)))))
1381         ((and (null (rest (leaf-refs var)))
1382               (substitute-single-use-lvar arg var)))
1383         (t
1384          (propagate-to-refs var (lvar-type arg))))))
1385
1386   (when (every #'not (combination-args call))
1387     (delete-let fun))
1388
1389   (values))
1390
1391 ;;; This function is called when one of the args to a non-LET local
1392 ;;; call changes. For each changed argument corresponding to an unset
1393 ;;; variable, we compute the union of the types across all calls and
1394 ;;; propagate this type information to the var's refs.
1395 ;;;
1396 ;;; If the function has an XEP, then we don't do anything, since we
1397 ;;; won't discover anything.
1398 ;;;
1399 ;;; We can clear the LVAR-REOPTIMIZE flags for arguments in all calls
1400 ;;; corresponding to changed arguments in CALL, since the only use in
1401 ;;; IR1 optimization of the REOPTIMIZE flag for local call args is
1402 ;;; right here.
1403 (defun propagate-local-call-args (call fun)
1404   (declare (type combination call) (type clambda fun))
1405
1406   (unless (or (functional-entry-fun fun)
1407               (lambda-optional-dispatch fun))
1408     (let* ((vars (lambda-vars fun))
1409            (union (mapcar (lambda (arg var)
1410                             (when (and arg
1411                                        (lvar-reoptimize arg)
1412                                        (null (basic-var-sets var)))
1413                               (lvar-type arg)))
1414                           (basic-combination-args call)
1415                           vars))
1416            (this-ref (lvar-use (basic-combination-fun call))))
1417
1418       (dolist (arg (basic-combination-args call))
1419         (when arg
1420           (setf (lvar-reoptimize arg) nil)))
1421
1422       (dolist (ref (leaf-refs fun))
1423         (let ((dest (node-dest ref)))
1424           (unless (or (eq ref this-ref) (not dest))
1425             (setq union
1426                   (mapcar (lambda (this-arg old)
1427                             (when old
1428                               (setf (lvar-reoptimize this-arg) nil)
1429                               (type-union (lvar-type this-arg) old)))
1430                           (basic-combination-args dest)
1431                           union)))))
1432
1433       (loop for var in vars
1434             and type in union
1435             when type do (propagate-to-refs var type))))
1436
1437   (values))
1438 \f
1439 ;;;; multiple values optimization
1440
1441 ;;; Do stuff to notice a change to a MV combination node. There are
1442 ;;; two main branches here:
1443 ;;;  -- If the call is local, then it is already a MV let, or should
1444 ;;;     become one. Note that although all :LOCAL MV calls must eventually
1445 ;;;     be converted to :MV-LETs, there can be a window when the call
1446 ;;;     is local, but has not been LET converted yet. This is because
1447 ;;;     the entry-point lambdas may have stray references (in other
1448 ;;;     entry points) that have not been deleted yet.
1449 ;;;  -- The call is full. This case is somewhat similar to the non-MV
1450 ;;;     combination optimization: we propagate return type information and
1451 ;;;     notice non-returning calls. We also have an optimization
1452 ;;;     which tries to convert MV-CALLs into MV-binds.
1453 (defun ir1-optimize-mv-combination (node)
1454   (ecase (basic-combination-kind node)
1455     (:local
1456      (let ((fun-lvar (basic-combination-fun node)))
1457        (when (lvar-reoptimize fun-lvar)
1458          (setf (lvar-reoptimize fun-lvar) nil)
1459          (maybe-let-convert (combination-lambda node))))
1460      (setf (lvar-reoptimize (first (basic-combination-args node))) nil)
1461      (when (eq (functional-kind (combination-lambda node)) :mv-let)
1462        (unless (convert-mv-bind-to-let node)
1463          (ir1-optimize-mv-bind node))))
1464     (:full
1465      (let* ((fun (basic-combination-fun node))
1466             (fun-changed (lvar-reoptimize fun))
1467             (args (basic-combination-args node)))
1468        (when fun-changed
1469          (setf (lvar-reoptimize fun) nil)
1470          (let ((type (lvar-type fun)))
1471            (when (fun-type-p type)
1472              (derive-node-type node (fun-type-returns type))))
1473          (maybe-terminate-block node nil)
1474          (let ((use (lvar-uses fun)))
1475            (when (and (ref-p use) (functional-p (ref-leaf use)))
1476              (convert-call-if-possible use node)
1477              (when (eq (basic-combination-kind node) :local)
1478                (maybe-let-convert (ref-leaf use))))))
1479        (unless (or (eq (basic-combination-kind node) :local)
1480                    (eq (lvar-fun-name fun) '%throw))
1481          (ir1-optimize-mv-call node))
1482        (dolist (arg args)
1483          (setf (lvar-reoptimize arg) nil))))
1484     (:error))
1485   (values))
1486
1487 ;;; Propagate derived type info from the values lvar to the vars.
1488 (defun ir1-optimize-mv-bind (node)
1489   (declare (type mv-combination node))
1490   (let* ((arg (first (basic-combination-args node)))
1491          (vars (lambda-vars (combination-lambda node)))
1492          (n-vars (length vars))
1493          (types (values-type-in (lvar-derived-type arg)
1494                                 n-vars)))
1495     (loop for var in vars
1496           and type in types
1497           do (if (basic-var-sets var)
1498                  (propagate-from-sets var type)
1499                  (propagate-to-refs var type)))
1500     (setf (lvar-reoptimize arg) nil))
1501   (values))
1502
1503 ;;; If possible, convert a general MV call to an MV-BIND. We can do
1504 ;;; this if:
1505 ;;; -- The call has only one argument, and
1506 ;;; -- The function has a known fixed number of arguments, or
1507 ;;; -- The argument yields a known fixed number of values.
1508 ;;;
1509 ;;; What we do is change the function in the MV-CALL to be a lambda
1510 ;;; that "looks like an MV bind", which allows
1511 ;;; IR1-OPTIMIZE-MV-COMBINATION to notice that this call can be
1512 ;;; converted (the next time around.) This new lambda just calls the
1513 ;;; actual function with the MV-BIND variables as arguments. Note that
1514 ;;; this new MV bind is not let-converted immediately, as there are
1515 ;;; going to be stray references from the entry-point functions until
1516 ;;; they get deleted.
1517 ;;;
1518 ;;; In order to avoid loss of argument count checking, we only do the
1519 ;;; transformation according to a known number of expected argument if
1520 ;;; safety is unimportant. We can always convert if we know the number
1521 ;;; of actual values, since the normal call that we build will still
1522 ;;; do any appropriate argument count checking.
1523 ;;;
1524 ;;; We only attempt the transformation if the called function is a
1525 ;;; constant reference. This allows us to just splice the leaf into
1526 ;;; the new function, instead of trying to somehow bind the function
1527 ;;; expression. The leaf must be constant because we are evaluating it
1528 ;;; again in a different place. This also has the effect of squelching
1529 ;;; multiple warnings when there is an argument count error.
1530 (defun ir1-optimize-mv-call (node)
1531   (let ((fun (basic-combination-fun node))
1532         (*compiler-error-context* node)
1533         (ref (lvar-uses (basic-combination-fun node)))
1534         (args (basic-combination-args node)))
1535
1536     (unless (and (ref-p ref) (constant-reference-p ref)
1537                  (singleton-p args))
1538       (return-from ir1-optimize-mv-call))
1539
1540     (multiple-value-bind (min max)
1541         (fun-type-nargs (lvar-type fun))
1542       (let ((total-nvals
1543              (multiple-value-bind (types nvals)
1544                  (values-types (lvar-derived-type (first args)))
1545                (declare (ignore types))
1546                (if (eq nvals :unknown) nil nvals))))
1547
1548         (when total-nvals
1549           (when (and min (< total-nvals min))
1550             (compiler-warn
1551              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1552              at least ~R."
1553              total-nvals min)
1554             (setf (basic-combination-kind node) :error)
1555             (return-from ir1-optimize-mv-call))
1556           (when (and max (> total-nvals max))
1557             (compiler-warn
1558              "MULTIPLE-VALUE-CALL with ~R values when the function expects ~
1559              at most ~R."
1560              total-nvals max)
1561             (setf (basic-combination-kind node) :error)
1562             (return-from ir1-optimize-mv-call)))
1563
1564         (let ((count (cond (total-nvals)
1565                            ((and (policy node (zerop verify-arg-count))
1566                                  (eql min max))
1567                             min)
1568                            (t nil))))
1569           (when count
1570             (with-ir1-environment-from-node node
1571               (let* ((dums (make-gensym-list count))
1572                      (ignore (gensym))
1573                      (fun (ir1-convert-lambda
1574                            `(lambda (&optional ,@dums &rest ,ignore)
1575                               (declare (ignore ,ignore))
1576                               (funcall ,(ref-leaf ref) ,@dums)))))
1577                 (change-ref-leaf ref fun)
1578                 (aver (eq (basic-combination-kind node) :full))
1579                 (locall-analyze-component *current-component*)
1580                 (aver (eq (basic-combination-kind node) :local)))))))))
1581   (values))
1582
1583 ;;; If we see:
1584 ;;;    (multiple-value-bind
1585 ;;;     (x y)
1586 ;;;     (values xx yy)
1587 ;;;      ...)
1588 ;;; Convert to:
1589 ;;;    (let ((x xx)
1590 ;;;       (y yy))
1591 ;;;      ...)
1592 ;;;
1593 ;;; What we actually do is convert the VALUES combination into a
1594 ;;; normal LET combination calling the original :MV-LET lambda. If
1595 ;;; there are extra args to VALUES, discard the corresponding
1596 ;;; lvars. If there are insufficient args, insert references to NIL.
1597 (defun convert-mv-bind-to-let (call)
1598   (declare (type mv-combination call))
1599   (let* ((arg (first (basic-combination-args call)))
1600          (use (lvar-uses arg)))
1601     (when (and (combination-p use)
1602                (eq (lvar-fun-name (combination-fun use))
1603                    'values))
1604       (let* ((fun (combination-lambda call))
1605              (vars (lambda-vars fun))
1606              (vals (combination-args use))
1607              (nvars (length vars))
1608              (nvals (length vals)))
1609         (cond ((> nvals nvars)
1610                (mapc #'flush-dest (subseq vals nvars))
1611                (setq vals (subseq vals 0 nvars)))
1612               ((< nvals nvars)
1613                (with-ir1-environment-from-node use
1614                  (let ((node-prev (node-prev use)))
1615                    (setf (node-prev use) nil)
1616                    (setf (ctran-next node-prev) nil)
1617                    (collect ((res vals))
1618                      (loop for count below (- nvars nvals)
1619                            for prev = node-prev then ctran
1620                            for ctran = (make-ctran)
1621                            and lvar = (make-lvar use)
1622                            do (reference-constant prev ctran lvar nil)
1623                               (res lvar)
1624                            finally (link-node-to-previous-ctran
1625                                     use ctran))
1626                      (setq vals (res)))))))
1627         (setf (combination-args use) vals)
1628         (flush-dest (combination-fun use))
1629         (let ((fun-lvar (basic-combination-fun call)))
1630           (setf (lvar-dest fun-lvar) use)
1631           (setf (combination-fun use) fun-lvar)
1632           (flush-lvar-externally-checkable-type fun-lvar))
1633         (setf (combination-kind use) :local)
1634         (setf (functional-kind fun) :let)
1635         (flush-dest (first (basic-combination-args call)))
1636         (unlink-node call)
1637         (when vals
1638           (reoptimize-lvar (first vals)))
1639         (propagate-to-args use fun)
1640         (reoptimize-call use))
1641       t)))
1642
1643 ;;; If we see:
1644 ;;;    (values-list (list x y z))
1645 ;;;
1646 ;;; Convert to:
1647 ;;;    (values x y z)
1648 ;;;
1649 ;;; In implementation, this is somewhat similar to
1650 ;;; CONVERT-MV-BIND-TO-LET. We grab the args of LIST and make them
1651 ;;; args of the VALUES-LIST call, flushing the old argument lvar
1652 ;;; (allowing the LIST to be flushed.)
1653 ;;;
1654 ;;; FIXME: Thus we lose possible type assertions on (LIST ...).
1655 (defoptimizer (values-list optimizer) ((list) node)
1656   (let ((use (lvar-uses list)))
1657     (when (and (combination-p use)
1658                (eq (lvar-fun-name (combination-fun use))
1659                    'list))
1660
1661       ;; FIXME: VALUES might not satisfy an assertion on NODE-LVAR.
1662       (change-ref-leaf (lvar-uses (combination-fun node))
1663                        (find-free-fun 'values "in a strange place"))
1664       (setf (combination-kind node) :full)
1665       (let ((args (combination-args use)))
1666         (dolist (arg args)
1667           (setf (lvar-dest arg) node)
1668           (flush-lvar-externally-checkable-type arg))
1669         (setf (combination-args use) nil)
1670         (flush-dest list)
1671         (setf (combination-args node) args))
1672       t)))
1673
1674 ;;; If VALUES appears in a non-MV context, then effectively convert it
1675 ;;; to a PROG1. This allows the computation of the additional values
1676 ;;; to become dead code.
1677 (deftransform values ((&rest vals) * * :node node)
1678   (unless (lvar-single-value-p (node-lvar node))
1679     (give-up-ir1-transform))
1680   (setf (node-derived-type node) *wild-type*)
1681   (principal-lvar-single-valuify (node-lvar node))
1682   (if vals
1683       (let ((dummies (make-gensym-list (length (cdr vals)))))
1684         `(lambda (val ,@dummies)
1685            (declare (ignore ,@dummies))
1686            val))
1687       nil))
1688
1689 ;;; TODO:
1690 ;;; - CAST chains;
1691 (defun ir1-optimize-cast (cast &optional do-not-optimize)
1692   (declare (type cast cast))
1693   (let ((value (cast-value cast))
1694         (atype (cast-asserted-type cast)))
1695     (when (not do-not-optimize)
1696       (let ((lvar (node-lvar cast)))
1697         (when (values-subtypep (lvar-derived-type value)
1698                                (cast-asserted-type cast))
1699           (delete-filter cast lvar value)
1700           (when lvar
1701             (reoptimize-lvar lvar)
1702             (when (lvar-single-value-p lvar)
1703               (note-single-valuified-lvar lvar)))
1704           (return-from ir1-optimize-cast t))
1705
1706         (when (and (listp (lvar-uses value))
1707                    lvar)
1708           ;; Pathwise removing of CAST
1709           (let ((ctran (node-next cast))
1710                 (dest (lvar-dest lvar))
1711                 next-block)
1712             (collect ((merges))
1713               (do-uses (use value)
1714                 (when (and (values-subtypep (node-derived-type use) atype)
1715                            (immediately-used-p value use))
1716                   (unless next-block
1717                     (when ctran (ensure-block-start ctran))
1718                     (setq next-block (first (block-succ (node-block cast)))))
1719                   (%delete-lvar-use use)
1720                   (add-lvar-use use lvar)
1721                   (unlink-blocks (node-block use) (node-block cast))
1722                   (link-blocks (node-block use) next-block)
1723                   (when (and (return-p dest)
1724                              (basic-combination-p use)
1725                              (eq (basic-combination-kind use) :local))
1726                     (merges use))))
1727               (dolist (use (merges))
1728                 (merge-tail-sets use)))))))
1729
1730     (let* ((value-type (lvar-derived-type value))
1731            (int (values-type-intersection value-type atype)))
1732       (derive-node-type cast int)
1733       (when (eq int *empty-type*)
1734         (unless (eq value-type *empty-type*)
1735
1736           ;; FIXME: Do it in one step.
1737           (filter-lvar
1738            value
1739            `(multiple-value-call #'list 'dummy))
1740           (filter-lvar
1741            (cast-value cast)
1742            ;; FIXME: Derived type.
1743            `(%compile-time-type-error 'dummy
1744                                       ',(type-specifier atype)
1745                                       ',(type-specifier value-type)))
1746           ;; KLUDGE: FILTER-LVAR does not work for non-returning
1747           ;; functions, so we declare the return type of
1748           ;; %COMPILE-TIME-TYPE-ERROR to be * and derive the real type
1749           ;; here.
1750           (setq value (cast-value cast))
1751           (derive-node-type (lvar-uses value) *empty-type*)
1752           (maybe-terminate-block (lvar-uses value) nil)
1753           ;; FIXME: Is it necessary?
1754           (aver (null (block-pred (node-block cast))))
1755           (delete-block-lazily (node-block cast))
1756           (return-from ir1-optimize-cast)))
1757       (when (eq (node-derived-type cast) *empty-type*)
1758         (maybe-terminate-block cast nil))
1759
1760       (when (and (cast-%type-check cast)
1761                  (values-subtypep value-type
1762                                   (cast-type-to-check cast)))
1763         (setf (cast-%type-check cast) nil))))
1764
1765   (unless do-not-optimize
1766     (setf (node-reoptimize cast) nil)))