src/compiler/ir1report.lisp

   1 ;;;; machinery for reporting errors/warnings/notes/whatnot from
   2 ;;;; the compiler
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; compiler error context determination
  16
  17 (declaim (special *current-path*))
  18
  19 ;;; We bind print level and length when printing out messages so that
  20 ;;; we don't dump huge amounts of garbage.
  21 ;;;
  22 ;;; FIXME: It's not possible to get the defaults right for everyone.
  23 ;;; So: Should these variables be in the SB-EXT package? Or should we
  24 ;;; just get rid of them completely and just use the bare
  25 ;;; CL:*PRINT-FOO* variables instead?
  26 (declaim (type (or unsigned-byte null)
  27                *compiler-error-print-level*
  28                *compiler-error-print-length*
  29                *compiler-error-print-lines*))
  30 (defvar *compiler-error-print-level* 5
  31   #!+sb-doc
  32   "the value for *PRINT-LEVEL* when printing compiler error messages")
  33 (defvar *compiler-error-print-length* 10
  34   #!+sb-doc
  35   "the value for *PRINT-LENGTH* when printing compiler error messages")
  36 (defvar *compiler-error-print-lines* 12
  37   #!+sb-doc
  38   "the value for *PRINT-LINES* when printing compiler error messages")
  39
  40 (defvar *enclosing-source-cutoff* 1
  41   #!+sb-doc
  42   "The maximum number of enclosing non-original source forms (i.e. from
  43   macroexpansion) that we print in full. For additional enclosing forms, we
  44   print only the CAR.")
  45 (declaim (type unsigned-byte *enclosing-source-cutoff*))
  46
  47 ;;; We separate the determination of compiler error contexts from the
  48 ;;; actual signalling of those errors by objectifying the error
  49 ;;; context. This allows postponement of the determination of how (and
  50 ;;; if) to signal the error.
  51 ;;;
  52 ;;; We take care not to reference any of the IR1 so that pending
  53 ;;; potential error messages won't prevent the IR1 from being GC'd. To
  54 ;;; this end, we convert source forms to strings so that source forms
  55 ;;; that contain IR1 references (e.g. %DEFUN) don't hold onto the IR.
  56 (defstruct (compiler-error-context
  57             #-no-ansi-print-object
  58             (:print-object (lambda (x stream)
  59                              (print-unreadable-object (x stream :type t))))
  60             (:copier nil))
  61   ;; a list of the stringified CARs of the enclosing non-original source forms
  62   ;; exceeding the *enclosing-source-cutoff*
  63   (enclosing-source nil :type list)
  64   ;; a list of stringified enclosing non-original source forms
  65   (source nil :type list)
  66   ;; the stringified form in the original source that expanded into SOURCE
  67   (original-source (missing-arg) :type simple-string)
  68   ;; a list of prefixes of "interesting" forms that enclose original-source
  69   (context nil :type list)
  70   ;; the FILE-INFO-NAME for the relevant FILE-INFO
  71   (file-name (missing-arg) :type (or pathname (member :lisp :stream)))
  72   ;; the file position at which the top level form starts, if applicable
  73   (file-position nil :type (or index null))
  74   ;; the original source part of the source path
  75   (original-source-path nil :type list))
  76
  77 ;;; If true, this is the node which is used as context in compiler warning
  78 ;;; messages.
  79 (declaim (type (or null compiler-error-context node) *compiler-error-context*))
  80 (defvar *compiler-error-context* nil)
  81
  82 ;;; a hashtable mapping macro names to source context parsers. Each parser
  83 ;;; function returns the source-context list for that form.
  84 (defvar *source-context-methods* (make-hash-table))
  85
  86 ;;; documentation originally from cmu-user.tex:
  87 ;;;   This macro defines how to extract an abbreviated source context from
  88 ;;;   the \var{name}d form when it appears in the compiler input.
  89 ;;;   \var{lambda-list} is a \code{defmacro} style lambda-list used to
  90 ;;;   parse the arguments. The \var{body} should return a list of
  91 ;;;   subforms that can be printed on about one line. There are
  92 ;;;   predefined methods for \code{defstruct}, \code{defmethod}, etc. If
  93 ;;;   no method is defined, then the first two subforms are returned.
  94 ;;;   Note that this facility implicitly determines the string name
  95 ;;;   associated with anonymous functions.
  96 ;;; So even though SBCL itself only uses this macro within this file,
  97 ;;; it's a reasonable thing to put in SB-EXT in case some dedicated
  98 ;;; user wants to do some heavy tweaking to make SBCL give more
  99 ;;; informative output about his code.
 100 (defmacro define-source-context (name lambda-list &body body)
 101   #!+sb-doc
 102   "DEFINE-SOURCE-CONTEXT Name Lambda-List Form*
 103    This macro defines how to extract an abbreviated source context from the
 104    Named form when it appears in the compiler input. Lambda-List is a DEFMACRO
 105    style lambda-list used to parse the arguments. The Body should return a
 106    list of subforms suitable for a \"~{~S ~}\" format string."
 107   (let ((n-whole (gensym)))
 108     `(setf (gethash ',name *source-context-methods*)
 109            (lambda (,n-whole)
 110              (destructuring-bind ,lambda-list ,n-whole ,@body)))))
 111
 112 (defmacro def-source-context (&rest rest)
 113   (deprecation-warning 'def-source-context 'define-source-context)
 114   `(define-source-context ,@rest))
 115
 116 (define-source-context defstruct (name-or-options &rest slots)
 117   (declare (ignore slots))
 118   `(defstruct ,(if (consp name-or-options)
 119                    (car name-or-options)
 120                    name-or-options)))
 121
 122 (define-source-context function (thing)
 123   (if (and (consp thing) (eq (first thing) 'lambda) (consp (rest thing)))
 124       `(lambda ,(second thing))
 125       `(function ,thing)))
 126
 127 ;;; Return the first two elements of FORM if FORM is a list. Take the
 128 ;;; CAR of the second form if appropriate.
 129 (defun source-form-context (form)
 130   (cond ((atom form) nil)
 131         ((>= (length form) 2)
 132          (let* ((context-fun-default (lambda (x)
 133                                        (declare (ignore x))
 134                                        (list (first form) (second form))))
 135                 (context-fun (gethash (first form)
 136                                       *source-context-methods*
 137                                       context-fun-default)))
 138            (declare (type function context-fun))
 139            (funcall context-fun (rest form))))
 140         (t
 141          form)))
 142
 143 ;;; Given a source path, return the original source form and a
 144 ;;; description of the interesting aspects of the context in which it
 145 ;;; appeared. The context is a list of lists, one sublist per context
 146 ;;; form. The sublist is a list of some of the initial subforms of the
 147 ;;; context form.
 148 ;;;
 149 ;;; For now, we use the first two subforms of each interesting form. A
 150 ;;; form is interesting if the first element is a symbol beginning
 151 ;;; with "DEF" and it is not the source form. If there is no
 152 ;;; DEF-mumble, then we use the outermost containing form. If the
 153 ;;; second subform is a list, then in some cases we return the CAR of
 154 ;;; that form rather than the whole form (i.e. don't show DEFSTRUCT
 155 ;;; options, etc.)
 156 (defun find-original-source (path)
 157   (declare (list path))
 158   (let* ((rpath (reverse (source-path-original-source path)))
 159          (tlf (first rpath))
 160          (root (find-source-root tlf *source-info*)))
 161     (collect ((context))
 162       (let ((form root)
 163             (current (rest rpath)))
 164         (loop
 165           (when (atom form)
 166             (aver (null current))
 167             (return))
 168           (let ((head (first form)))
 169             (when (symbolp head)
 170               (let ((name (symbol-name head)))
 171                 (when (and (>= (length name) 3) (string= name "DEF" :end1 3))
 172                   (context (source-form-context form))))))
 173           (when (null current) (return))
 174           (setq form (nth (pop current) form)))
 175
 176         (cond ((context)
 177                (values form (context)))
 178               ((and path root)
 179                (let ((c (source-form-context root)))
 180                  (values form (if c (list c) nil))))
 181               (t
 182                (values '(unable to locate source)
 183                        '((some strange place)))))))))
 184
 185 ;;; Convert a source form to a string, suitably formatted for use in
 186 ;;; compiler warnings.
 187 (defun stringify-form (form &optional (pretty t))
 188   (with-standard-io-syntax
 189    (let ((*print-readably* nil)
 190          (*print-pretty* pretty)
 191          (*print-level* *compiler-error-print-level*)
 192          (*print-length* *compiler-error-print-length*)
 193          (*print-lines* *compiler-error-print-lines*))
 194      (if pretty
 195          (format nil "~<~@;  ~S~:>" (list form))
 196          (prin1-to-string form)))))
 197
 198 ;;; Return a COMPILER-ERROR-CONTEXT structure describing the current
 199 ;;; error context, or NIL if we can't figure anything out. ARGS is a
 200 ;;; list of things that are going to be printed out in the error
 201 ;;; message, and can thus be blown off when they appear in the source
 202 ;;; context.
 203 (defun find-error-context (args)
 204   (let ((context *compiler-error-context*))
 205     (if (compiler-error-context-p context)
 206         context
 207         (let ((path (or (and (boundp '*current-path*) *current-path*)
 208                         (if context
 209                             (node-source-path context)
 210                             nil))))
 211           (when (and *source-info* path)
 212             (multiple-value-bind (form src-context) (find-original-source path)
 213               (collect ((full nil cons)
 214                         (short nil cons))
 215                 (let ((forms (source-path-forms path))
 216                       (n 0))
 217                   (dolist (src (if (member (first forms) args)
 218                                    (rest forms)
 219                                    forms))
 220                     (if (>= n *enclosing-source-cutoff*)
 221                         (short (stringify-form (if (consp src)
 222                                                    (car src)
 223                                                    src)
 224                                                nil))
 225                         (full (stringify-form src)))
 226                     (incf n)))
 227
 228                 (let* ((tlf (source-path-tlf-number path))
 229                        (file-info (source-info-file-info *source-info*)))
 230                   (make-compiler-error-context
 231                    :enclosing-source (short)
 232                    :source (full)
 233                    :original-source (stringify-form form)
 234                    :context src-context
 235                    :file-name (file-info-name file-info)
 236                    :file-position
 237                    (multiple-value-bind (ignore pos)
 238                        (find-source-root tlf *source-info*)
 239                      (declare (ignore ignore))
 240                      pos)
 241                    :original-source-path
 242                    (source-path-original-source path))))))))))
 243 \f
 244 ;;;; printing error messages
 245
 246 ;;; We save the context information that we printed out most recently
 247 ;;; so that we don't print it out redundantly.
 248
 249 ;;; The last COMPILER-ERROR-CONTEXT that we printed.
 250 (defvar *last-error-context* nil)
 251 (declaim (type (or compiler-error-context null) *last-error-context*))
 252
 253 ;;; The format string and args for the last error we printed.
 254 (defvar *last-format-string* nil)
 255 (defvar *last-format-args* nil)
 256 (declaim (type (or string null) *last-format-string*))
 257 (declaim (type list *last-format-args*))
 258
 259 ;;; The number of times that the last error message has been emitted,
 260 ;;; so that we can compress duplicate error messages.
 261 (defvar *last-message-count* 0)
 262 (declaim (type index *last-message-count*))
 263
 264 ;;; If the last message was given more than once, then print out an
 265 ;;; indication of how many times it was repeated. We reset the message
 266 ;;; count when we are done.
 267 (defun note-message-repeats (&optional (terpri t))
 268   (cond ((= *last-message-count* 1)
 269          (when terpri (terpri *error-output*)))
 270         ((> *last-message-count* 1)
 271           (format *error-output* "~&; [Last message occurs ~W times.]~2%"
 272                  *last-message-count*)))
 273   (setq *last-message-count* 0))
 274
 275 ;;; Print out the message, with appropriate context if we can find it.
 276 ;;; If the context is different from the context of the last message
 277 ;;; we printed, then we print the context. If the original source is
 278 ;;; different from the source we are working on, then we print the
 279 ;;; current source in addition to the original source.
 280 ;;;
 281 ;;; We suppress printing of messages identical to the previous, but
 282 ;;; record the number of times that the message is repeated.
 283 (defun print-compiler-message (format-string format-args)
 284
 285   (declare (type simple-string format-string))
 286   (declare (type list format-args))
 287
 288   (let ((stream *error-output*)
 289         (context (find-error-context format-args)))
 290     (cond
 291      (context
 292       (let ((file (compiler-error-context-file-name context))
 293             (in (compiler-error-context-context context))
 294             (form (compiler-error-context-original-source context))
 295             (enclosing (compiler-error-context-enclosing-source context))
 296             (source (compiler-error-context-source context))
 297             (last *last-error-context*))
 298
 299         (unless (and last
 300                      (equal file (compiler-error-context-file-name last)))
 301           (when (pathnamep file)
 302             (note-message-repeats)
 303             (setq last nil)
 304             (format stream "~2&; file: ~A~%" (namestring file))))
 305
 306         (unless (and last
 307                      (equal in (compiler-error-context-context last)))
 308           (note-message-repeats)
 309           (setq last nil)
 310           (format stream "~&")
 311           (pprint-logical-block (stream nil :per-line-prefix "; ")
 312             (format stream "in:~{~<~%    ~4:;~{ ~S~}~>~^ =>~}" in))
 313           (format stream "~%"))
 314
 315
 316         (unless (and last
 317                      (string= form
 318                               (compiler-error-context-original-source last)))
 319           (note-message-repeats)
 320           (setq last nil)
 321           (format stream "~&")
 322           (pprint-logical-block (stream nil :per-line-prefix "; ")
 323             (format stream "  ~A" form))
 324           (format stream "~&"))
 325
 326         (unless (and last
 327                      (equal enclosing
 328                             (compiler-error-context-enclosing-source last)))
 329           (when enclosing
 330             (note-message-repeats)
 331             (setq last nil)
 332             (format stream "~&; --> ~{~<~%; --> ~1:;~A~> ~}~%" enclosing)))
 333
 334         (unless (and last
 335                      (equal source (compiler-error-context-source last)))
 336           (setq *last-format-string* nil)
 337           (when source
 338             (note-message-repeats)
 339             (dolist (src source)
 340               (format stream "~&")
 341               (write-string "; ==>" stream)
 342               (format stream "~&")
 343               (pprint-logical-block (stream nil :per-line-prefix "; ")
 344                 (write-string src stream)))))))
 345      (t
 346        (format stream "~&")
 347       (note-message-repeats)
 348       (setq *last-format-string* nil)
 349        (format stream "~&")))
 350
 351     (setq *last-error-context* context)
 352
 353     ;; FIXME: this testing for effective equality of compiler messages
 354     ;; is ugly, and really ought to be done at a higher level.
 355     (unless (and (equal format-string *last-format-string*)
 356                  (tree-equal format-args *last-format-args*))
 357       (note-message-repeats nil)
 358       (setq *last-format-string* format-string)
 359       (setq *last-format-args* format-args)
 360       (let ((*print-level*  *compiler-error-print-level*)
 361             (*print-length* *compiler-error-print-length*)
 362             (*print-lines*  *compiler-error-print-lines*))
 363         (format stream "~&")
 364         (pprint-logical-block (stream nil :per-line-prefix "; ")
 365           (format stream "~&~?" format-string format-args))
 366         (format stream "~&"))))
 367
 368   (incf *last-message-count*)
 369   (values))
 370
 371 (defun print-compiler-condition (condition)
 372   (declare (type condition condition))
 373   (let (;; These different classes of conditions have different
 374         ;; effects on the return codes of COMPILE-FILE, so it's nice
 375         ;; for users to be able to pick them out by lexical search
 376         ;; through the output.
 377         (what (etypecase condition
 378                 (style-warning 'style-warning)
 379                 (warning 'warning)
 380                 ((or error compiler-error) 'error))))
 381     (multiple-value-bind (format-string format-args)
 382         (if (typep condition 'simple-condition)
 383             (values (simple-condition-format-control condition)
 384                     (simple-condition-format-arguments condition))
 385             (values "~A"
 386                     (list (with-output-to-string (s)
 387                             (princ condition s)))))
 388       (print-compiler-message
 389        (format nil "caught ~S:~%  ~A" what format-string)
 390        format-args)))
 391   (values))
 392
 393 ;;; The act of signalling one of these beasts must not cause WARNINGSP
 394 ;;; (or FAILUREP) to be set from COMPILE or COMPILE-FILE, so we can't
 395 ;;; inherit from WARNING or STYLE-WARNING.
 396 ;;;
 397 ;;; FIXME: the handling of compiler-notes could be unified with
 398 ;;; warnings and style-warnings (see the various handler functions
 399 ;;; below).
 400 (define-condition compiler-note (condition) ()
 401   (:documentation
 402    "Root of the hierarchy of conditions representing information discovered
 403 by the compiler that the user might wish to know, but which does not merit
 404 a STYLE-WARNING (or any more serious condition)."))
 405 (define-condition simple-compiler-note (simple-condition compiler-note) ())
 406 (define-condition code-deletion-note (simple-compiler-note) ()
 407   (:documentation
 408    "A condition type signalled when the compiler deletes code that the user
 409 has written, having proved that it is unreachable."))
 410
 411 (defun compiler-notify (datum &rest args)
 412   (unless (if *compiler-error-context*
 413               (policy *compiler-error-context* (= inhibit-warnings 3))
 414               (policy *lexenv* (= inhibit-warnings 3)))
 415     (let ((condition
 416            (coerce-to-condition datum args
 417                                 'simple-compiler-note 'compiler-notify)))
 418       (restart-case
 419           (signal condition)
 420         (muffle-warning ()
 421           (return-from compiler-notify (values))))
 422       (incf *compiler-note-count*)
 423       (multiple-value-bind (format-string format-args)
 424           (if (typep condition 'simple-condition)
 425               (values (simple-condition-format-control condition)
 426                       (simple-condition-format-arguments condition))
 427               (values "~A"
 428                       (list (with-output-to-string (s)
 429                               (princ condition s)))))
 430         (print-compiler-message (format nil "note: ~A" format-string)
 431                                 format-args))))
 432   (values))
 433
 434 ;;; Issue a note when we might or might not be in the compiler.
 435 (defun maybe-compiler-notify (&rest rest)
 436   (if (boundp '*lexenv*) ; if we're in the compiler
 437       (apply #'compiler-notify rest)
 438       (progn
 439         (let ((condition
 440                (coerce-to-condition (car rest) (cdr rest)
 441                                     'simple-compiler-note
 442                                     'maybe-compiler-notify)))
 443           (restart-case
 444               (signal condition)
 445             (muffle-warning ()
 446               (return-from maybe-compiler-notify (values))))
 447           (let ((stream *error-output*))
 448             (pprint-logical-block (stream nil :per-line-prefix ";")
 449               (format stream " note: ~3I~_")
 450               (pprint-logical-block (stream nil)
 451                 (format stream "~A" condition)))
 452             ;; (outside logical block, no per-line-prefix)
 453             (fresh-line stream)))
 454         (values))))
 455
 456 ;;; The politically correct way to print out progress messages and
 457 ;;; such like. We clear the current error context so that we know that
 458 ;;; it needs to be reprinted, and we also FORCE-OUTPUT so that the
 459 ;;; message gets seen right away.
 460 (declaim (ftype (function (string &rest t) (values)) compiler-mumble))
 461 (defun compiler-mumble (format-string &rest format-args)
 462   (note-message-repeats)
 463   (setq *last-error-context* nil)
 464   (apply #'format *error-output* format-string format-args)
 465   (force-output *error-output*)
 466   (values))
 467
 468 ;;; Return a string that somehow names the code in COMPONENT. We use
 469 ;;; the source path for the bind node for an arbitrary entry point to
 470 ;;; find the source context, then return that as a string.
 471 (declaim (ftype (function (component) simple-string) find-component-name))
 472 (defun find-component-name (component)
 473   (let ((ep (first (block-succ (component-head component)))))
 474     (aver ep) ; else no entry points??
 475     (multiple-value-bind (form context)
 476         (find-original-source
 477          (node-source-path (block-start-node ep)))
 478       (declare (ignore form))
 479       (let ((*print-level* 2)
 480             (*print-pretty* nil))
 481         (format nil "~{~{~S~^ ~}~^ => ~}" context)))))
 482 \f
 483 ;;;; condition system interface
 484
 485 ;;; Keep track of how many times each kind of condition happens.
 486 (defvar *compiler-error-count*)
 487 (defvar *compiler-warning-count*)
 488 (defvar *compiler-style-warning-count*)
 489 (defvar *compiler-note-count*)
 490
 491 ;;; Keep track of whether any surrounding COMPILE or COMPILE-FILE call
 492 ;;; should return WARNINGS-P or FAILURE-P.
 493 (defvar *failure-p*)
 494 (defvar *warnings-p*)
 495
 496 ;;; condition handlers established by the compiler. We re-signal the
 497 ;;; condition, then if it isn't handled, we increment our warning
 498 ;;; counter and print the error message.
 499 (defun compiler-error-handler (condition)
 500   (signal condition)
 501   (incf *compiler-error-count*)
 502   (setf *warnings-p* t
 503         *failure-p* t)
 504   (print-compiler-condition condition)
 505   (continue condition))
 506 (defun compiler-warning-handler (condition)
 507   (signal condition)
 508   (incf *compiler-warning-count*)
 509   (setf *warnings-p* t
 510         *failure-p* t)
 511   (print-compiler-condition condition)
 512   (muffle-warning condition))
 513 (defun compiler-style-warning-handler (condition)
 514   (signal condition)
 515   (incf *compiler-style-warning-count*)
 516   (setf *warnings-p* t)
 517   (print-compiler-condition condition)
 518   (muffle-warning condition))
 519 \f
 520 ;;;; undefined warnings
 521
 522 (defvar *undefined-warning-limit* 3
 523   #!+sb-doc
 524   "If non-null, then an upper limit on the number of unknown function or type
 525   warnings that the compiler will print for any given name in a single
 526   compilation. This prevents excessive amounts of output when the real
 527   problem is a missing definition (as opposed to a typo in the use.)")
 528
 529 ;;; Make an entry in the *UNDEFINED-WARNINGS* describing a reference
 530 ;;; to NAME of the specified KIND. If we have exceeded the warning
 531 ;;; limit, then just increment the count, otherwise note the current
 532 ;;; error context.
 533 ;;;
 534 ;;; Undefined types are noted by a condition handler in
 535 ;;; WITH-COMPILATION-UNIT, which can potentially be invoked outside
 536 ;;; the compiler, hence the BOUNDP check.
 537 (defun note-undefined-reference (name kind)
 538   (unless (and
 539            ;; Check for boundness so we don't blow up if we're called
 540            ;; when IR1 conversion isn't going on.
 541            (boundp '*lexenv*)
 542            ;; FIXME: I'm pretty sure the INHIBIT-WARNINGS test below
 543            ;; isn't a good idea; we should have INHIBIT-WARNINGS
 544            ;; affect compiler notes, not STYLE-WARNINGs. And I'm not
 545            ;; sure what the BOUNDP '*LEXENV* test above is for; it's
 546            ;; likely a good idea, but it probably deserves an
 547            ;; explanatory comment.
 548            (policy *lexenv* (= inhibit-warnings 3)))
 549     (let* ((found (dolist (warning *undefined-warnings* nil)
 550                     (when (and (equal (undefined-warning-name warning) name)
 551                                (eq (undefined-warning-kind warning) kind))
 552                       (return warning))))
 553            (res (or found
 554                     (make-undefined-warning :name name :kind kind))))
 555       (unless found (push res *undefined-warnings*))
 556       (when (or (not *undefined-warning-limit*)
 557                 (< (undefined-warning-count res) *undefined-warning-limit*))
 558         (push (find-error-context (list name))
 559               (undefined-warning-warnings res)))
 560       (incf (undefined-warning-count res))))
 561   (values))