src/compiler/ir1report.lisp

   1 ;;;; machinery for reporting errors/warnings/notes/whatnot from
   2 ;;;; the compiler
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; compiler error context determination
  16
  17 (declaim (special *current-path*))
  18
  19 ;;; We bind print level and length when printing out messages so that
  20 ;;; we don't dump huge amounts of garbage.
  21 ;;;
  22 ;;; FIXME: It's not possible to get the defaults right for everyone.
  23 ;;; So: Should these variables be in the SB-EXT package? Or should we
  24 ;;; just get rid of them completely and just use the bare
  25 ;;; CL:*PRINT-FOO* variables instead?
  26 (declaim (type (or unsigned-byte null)
  27                *compiler-error-print-level*
  28                *compiler-error-print-length*
  29                *compiler-error-print-lines*))
  30 (defvar *compiler-error-print-level* 5
  31   #!+sb-doc
  32   "the value for *PRINT-LEVEL* when printing compiler error messages")
  33 (defvar *compiler-error-print-length* 10
  34   #!+sb-doc
  35   "the value for *PRINT-LENGTH* when printing compiler error messages")
  36 (defvar *compiler-error-print-lines* 12
  37   #!+sb-doc
  38   "the value for *PRINT-LINES* when printing compiler error messages")
  39
  40 (defvar *enclosing-source-cutoff* 1
  41   #!+sb-doc
  42   "The maximum number of enclosing non-original source forms (i.e. from
  43   macroexpansion) that we print in full. For additional enclosing forms, we
  44   print only the CAR.")
  45 (declaim (type unsigned-byte *enclosing-source-cutoff*))
  46
  47 ;;; We separate the determination of compiler error contexts from the
  48 ;;; actual signalling of those errors by objectifying the error
  49 ;;; context. This allows postponement of the determination of how (and
  50 ;;; if) to signal the error.
  51 ;;;
  52 ;;; We take care not to reference any of the IR1 so that pending
  53 ;;; potential error messages won't prevent the IR1 from being GC'd. To
  54 ;;; this end, we convert source forms to strings so that source forms
  55 ;;; that contain IR1 references (e.g. %DEFUN) don't hold onto the IR.
  56 (defstruct (compiler-error-context
  57             #-no-ansi-print-object
  58             (:print-object (lambda (x stream)
  59                              (print-unreadable-object (x stream :type t))))
  60             (:copier nil))
  61   ;; a list of the stringified CARs of the enclosing non-original source forms
  62   ;; exceeding the *enclosing-source-cutoff*
  63   (enclosing-source nil :type list)
  64   ;; a list of stringified enclosing non-original source forms
  65   (source nil :type list)
  66   ;; the stringified form in the original source that expanded into SOURCE
  67   (original-source (missing-arg) :type simple-string)
  68   ;; a list of prefixes of "interesting" forms that enclose original-source
  69   (context nil :type list)
  70   ;; the FILE-INFO-NAME for the relevant FILE-INFO
  71   (file-name (missing-arg) :type (or pathname (member :lisp :stream)))
  72   ;; the file position at which the top level form starts, if applicable
  73   (file-position nil :type (or index null))
  74   ;; the original source part of the source path
  75   (original-source-path nil :type list))
  76
  77 ;;; If true, this is the node which is used as context in compiler warning
  78 ;;; messages.
  79 (declaim (type (or null compiler-error-context node) *compiler-error-context*))
  80 (defvar *compiler-error-context* nil)
  81
  82 ;;; a hashtable mapping macro names to source context parsers. Each parser
  83 ;;; function returns the source-context list for that form.
  84 (defvar *source-context-methods* (make-hash-table))
  85
  86 ;;; documentation originally from cmu-user.tex:
  87 ;;;   This macro defines how to extract an abbreviated source context from
  88 ;;;   the \var{name}d form when it appears in the compiler input.
  89 ;;;   \var{lambda-list} is a \code{defmacro} style lambda-list used to
  90 ;;;   parse the arguments. The \var{body} should return a list of
  91 ;;;   subforms that can be printed on about one line. There are
  92 ;;;   predefined methods for \code{defstruct}, \code{defmethod}, etc. If
  93 ;;;   no method is defined, then the first two subforms are returned.
  94 ;;;   Note that this facility implicitly determines the string name
  95 ;;;   associated with anonymous functions.
  96 ;;; So even though SBCL itself only uses this macro within this file,
  97 ;;; it's a reasonable thing to put in SB-EXT in case some dedicated
  98 ;;; user wants to do some heavy tweaking to make SBCL give more
  99 ;;; informative output about his code.
 100 (defmacro define-source-context (name lambda-list &body body)
 101   #!+sb-doc
 102   "DEFINE-SOURCE-CONTEXT Name Lambda-List Form*
 103    This macro defines how to extract an abbreviated source context from the
 104    Named form when it appears in the compiler input. Lambda-List is a DEFMACRO
 105    style lambda-list used to parse the arguments. The Body should return a
 106    list of subforms suitable for a \"~{~S ~}\" format string."
 107   (let ((n-whole (gensym)))
 108     `(setf (gethash ',name *source-context-methods*)
 109            #'(lambda (,n-whole)
 110                (destructuring-bind ,lambda-list ,n-whole ,@body)))))
 111
 112 (defmacro def-source-context (&rest rest)
 113   (deprecation-warning 'def-source-context 'define-source-context)
 114   `(define-source-context ,@rest))
 115
 116 (define-source-context defstruct (name-or-options &rest slots)
 117   (declare (ignore slots))
 118   `(defstruct ,(if (consp name-or-options)
 119                    (car name-or-options)
 120                    name-or-options)))
 121
 122 (define-source-context function (thing)
 123   (if (and (consp thing) (eq (first thing) 'lambda) (consp (rest thing)))
 124       `(lambda ,(second thing))
 125       `(function ,thing)))
 126
 127 ;;; Return the first two elements of FORM if FORM is a list. Take the
 128 ;;; CAR of the second form if appropriate.
 129 (defun source-form-context (form)
 130   (cond ((atom form) nil)
 131         ((>= (length form) 2)
 132          (funcall (gethash (first form) *source-context-methods*
 133                            #'(lambda (x)
 134                                (declare (ignore x))
 135                                (list (first form) (second form))))
 136                   (rest form)))
 137         (t
 138          form)))
 139
 140 ;;; Given a source path, return the original source form and a
 141 ;;; description of the interesting aspects of the context in which it
 142 ;;; appeared. The context is a list of lists, one sublist per context
 143 ;;; form. The sublist is a list of some of the initial subforms of the
 144 ;;; context form.
 145 ;;;
 146 ;;; For now, we use the first two subforms of each interesting form. A
 147 ;;; form is interesting if the first element is a symbol beginning
 148 ;;; with "DEF" and it is not the source form. If there is no
 149 ;;; DEF-mumble, then we use the outermost containing form. If the
 150 ;;; second subform is a list, then in some cases we return the CAR of
 151 ;;; that form rather than the whole form (i.e. don't show DEFSTRUCT
 152 ;;; options, etc.)
 153 (defun find-original-source (path)
 154   (declare (list path))
 155   (let* ((rpath (reverse (source-path-original-source path)))
 156          (tlf (first rpath))
 157          (root (find-source-root tlf *source-info*)))
 158     (collect ((context))
 159       (let ((form root)
 160             (current (rest rpath)))
 161         (loop
 162           (when (atom form)
 163             (aver (null current))
 164             (return))
 165           (let ((head (first form)))
 166             (when (symbolp head)
 167               (let ((name (symbol-name head)))
 168                 (when (and (>= (length name) 3) (string= name "DEF" :end1 3))
 169                   (context (source-form-context form))))))
 170           (when (null current) (return))
 171           (setq form (nth (pop current) form)))
 172
 173         (cond ((context)
 174                (values form (context)))
 175               ((and path root)
 176                (let ((c (source-form-context root)))
 177                  (values form (if c (list c) nil))))
 178               (t
 179                (values '(unable to locate source)
 180                        '((some strange place)))))))))
 181
 182 ;;; Convert a source form to a string, suitably formatted for use in
 183 ;;; compiler warnings.
 184 (defun stringify-form (form &optional (pretty t))
 185   (with-standard-io-syntax
 186    (let ((*print-readably* nil)
 187          (*print-pretty* pretty)
 188          (*print-level* *compiler-error-print-level*)
 189          (*print-length* *compiler-error-print-length*)
 190          (*print-lines* *compiler-error-print-lines*))
 191      (if pretty
 192          (format nil "~<~@;  ~S~:>" (list form))
 193          (prin1-to-string form)))))
 194
 195 ;;; shorthand for creating debug names from source names or other
 196 ;;; stems, e.g.
 197 ;;;   (DEBUG-NAMIFY "FLET ~S" SOURCE-NAME)
 198 ;;;   (DEBUG-NAMIFY "top level form ~S" FORM)
 199 ;;;
 200 ;;; FIXME: This function seems to have a lot in common with
 201 ;;; STRINGIFY-FORM, and perhaps there's some way to merge the two
 202 ;;; functions.
 203 (defun debug-namify (format-string &rest format-arguments)
 204   (with-standard-io-syntax
 205    (let ((*print-readably* nil)
 206          (*package* *cl-package*)
 207          (*print-length* 3)
 208          (*print-level* 2))
 209      (apply #'format nil format-string format-arguments))))
 210
 211 ;;; Return a COMPILER-ERROR-CONTEXT structure describing the current
 212 ;;; error context, or NIL if we can't figure anything out. ARGS is a
 213 ;;; list of things that are going to be printed out in the error
 214 ;;; message, and can thus be blown off when they appear in the source
 215 ;;; context.
 216 (defun find-error-context (args)
 217   (let ((context *compiler-error-context*))
 218     (if (compiler-error-context-p context)
 219         context
 220         (let ((path (or (and (boundp '*current-path*) *current-path*)
 221                         (if context
 222                             (node-source-path context)
 223                             nil))))
 224           (when (and *source-info* path)
 225             (multiple-value-bind (form src-context) (find-original-source path)
 226               (collect ((full nil cons)
 227                         (short nil cons))
 228                 (let ((forms (source-path-forms path))
 229                       (n 0))
 230                   (dolist (src (if (member (first forms) args)
 231                                    (rest forms)
 232                                    forms))
 233                     (if (>= n *enclosing-source-cutoff*)
 234                         (short (stringify-form (if (consp src)
 235                                                    (car src)
 236                                                    src)
 237                                                nil))
 238                         (full (stringify-form src)))
 239                     (incf n)))
 240
 241                 (let* ((tlf (source-path-tlf-number path))
 242                        (file-info (source-info-file-info *source-info*)))
 243                   (make-compiler-error-context
 244                    :enclosing-source (short)
 245                    :source (full)
 246                    :original-source (stringify-form form)
 247                    :context src-context
 248                    :file-name (file-info-name file-info)
 249                    :file-position
 250                    (multiple-value-bind (ignore pos)
 251                        (find-source-root tlf *source-info*)
 252                      (declare (ignore ignore))
 253                      pos)
 254                    :original-source-path
 255                    (source-path-original-source path))))))))))
 256 \f
 257 ;;;; printing error messages
 258
 259 ;;; We save the context information that we printed out most recently
 260 ;;; so that we don't print it out redundantly.
 261
 262 ;;; The last COMPILER-ERROR-CONTEXT that we printed.
 263 (defvar *last-error-context* nil)
 264 (declaim (type (or compiler-error-context null) *last-error-context*))
 265
 266 ;;; The format string and args for the last error we printed.
 267 (defvar *last-format-string* nil)
 268 (defvar *last-format-args* nil)
 269 (declaim (type (or string null) *last-format-string*))
 270 (declaim (type list *last-format-args*))
 271
 272 ;;; The number of times that the last error message has been emitted,
 273 ;;; so that we can compress duplicate error messages.
 274 (defvar *last-message-count* 0)
 275 (declaim (type index *last-message-count*))
 276
 277 ;;; If the last message was given more than once, then print out an
 278 ;;; indication of how many times it was repeated. We reset the message
 279 ;;; count when we are done.
 280 (defun note-message-repeats (&optional (terpri t))
 281   (cond ((= *last-message-count* 1)
 282          (when terpri (terpri *error-output*)))
 283         ((> *last-message-count* 1)
 284           (format *error-output* "~&; [Last message occurs ~W times.]~2%"
 285                  *last-message-count*)))
 286   (setq *last-message-count* 0))
 287
 288 ;;; Print out the message, with appropriate context if we can find it.
 289 ;;; If the context is different from the context of the last message
 290 ;;; we printed, then we print the context. If the original source is
 291 ;;; different from the source we are working on, then we print the
 292 ;;; current source in addition to the original source.
 293 ;;;
 294 ;;; We suppress printing of messages identical to the previous, but
 295 ;;; record the number of times that the message is repeated.
 296 (defun print-compiler-message (format-string format-args)
 297
 298   (declare (type simple-string format-string))
 299   (declare (type list format-args))
 300
 301   (let ((stream *error-output*)
 302         (context (find-error-context format-args)))
 303     (cond
 304      (context
 305       (let ((file (compiler-error-context-file-name context))
 306             (in (compiler-error-context-context context))
 307             (form (compiler-error-context-original-source context))
 308             (enclosing (compiler-error-context-enclosing-source context))
 309             (source (compiler-error-context-source context))
 310             (last *last-error-context*))
 311
 312         (unless (and last
 313                      (equal file (compiler-error-context-file-name last)))
 314           (when (pathnamep file)
 315             (note-message-repeats)
 316             (setq last nil)
 317             (format stream "~2&; file: ~A~%" (namestring file))))
 318
 319         (unless (and last
 320                      (equal in (compiler-error-context-context last)))
 321           (note-message-repeats)
 322           (setq last nil)
 323           (format stream "~&")
 324           (pprint-logical-block (stream nil :per-line-prefix "; ")
 325             (format stream "in:~{~<~%    ~4:;~{ ~S~}~>~^ =>~}" in))
 326           (format stream "~%"))
 327
 328
 329         (unless (and last
 330                      (string= form
 331                               (compiler-error-context-original-source last)))
 332           (note-message-repeats)
 333           (setq last nil)
 334           (format stream "~&")
 335           (pprint-logical-block (stream nil :per-line-prefix "; ")
 336             (format stream "  ~A" form))
 337           (format stream "~&"))
 338
 339         (unless (and last
 340                      (equal enclosing
 341                             (compiler-error-context-enclosing-source last)))
 342           (when enclosing
 343             (note-message-repeats)
 344             (setq last nil)
 345             (format stream "~&; --> ~{~<~%; --> ~1:;~A~> ~}~%" enclosing)))
 346
 347         (unless (and last
 348                      (equal source (compiler-error-context-source last)))
 349           (setq *last-format-string* nil)
 350           (when source
 351             (note-message-repeats)
 352             (dolist (src source)
 353               (format stream "~&")
 354               (write-string "; ==>" stream)
 355               (format stream "~&")
 356               (pprint-logical-block (stream nil :per-line-prefix "; ")
 357                 (write-string src stream)))))))
 358      (t
 359        (format stream "~&")
 360       (note-message-repeats)
 361       (setq *last-format-string* nil)
 362        (format stream "~&")))
 363
 364     (setq *last-error-context* context)
 365
 366     (unless (and (equal format-string *last-format-string*)
 367                  (tree-equal format-args *last-format-args*))
 368       (note-message-repeats nil)
 369       (setq *last-format-string* format-string)
 370       (setq *last-format-args* format-args)
 371       (let ((*print-level*  *compiler-error-print-level*)
 372             (*print-length* *compiler-error-print-length*)
 373             (*print-lines*  *compiler-error-print-lines*))
 374         (format stream "~&")
 375         (pprint-logical-block (stream nil :per-line-prefix "; ")
 376           (format stream "~&~?" format-string format-args))
 377         (format stream "~&"))))
 378
 379   (incf *last-message-count*)
 380   (values))
 381
 382 (defun print-compiler-condition (condition)
 383   (declare (type condition condition))
 384   (let (;; These different classes of conditions have different
 385         ;; effects on the return codes of COMPILE-FILE, so it's nice
 386         ;; for users to be able to pick them out by lexical search
 387         ;; through the output.
 388         (what (etypecase condition
 389                 (style-warning 'style-warning)
 390                 (warning 'warning)
 391                 (error 'error))))
 392     (multiple-value-bind (format-string format-args)
 393         (if (typep condition 'simple-condition)
 394             (values (simple-condition-format-control condition)
 395                     (simple-condition-format-arguments condition))
 396             (values "~A"
 397                     (list (with-output-to-string (s)
 398                             (princ condition s)))))
 399       (print-compiler-message (format nil
 400                                       "caught ~S:~%  ~A"
 401                                       what
 402                                       format-string)
 403                               format-args)))
 404   (values))
 405
 406 ;;; COMPILER-NOTE is vaguely like COMPILER-ERROR and the other
 407 ;;; condition-signalling functions, but it just writes some output
 408 ;;; instead of signalling. (In CMU CL, it did signal a condition, but
 409 ;;; this didn't seem to work all that well; it was weird to have
 410 ;;; COMPILE-FILE return with WARNINGS-P set when the only problem was
 411 ;;; that the compiler couldn't figure out how to compile something as
 412 ;;; efficiently as it liked.)
 413 (defun compiler-note (format-string &rest format-args)
 414   (unless (if *compiler-error-context*
 415               (policy *compiler-error-context* (= inhibit-warnings 3))
 416               (policy *lexenv* (= inhibit-warnings 3)))
 417     (incf *compiler-note-count*)
 418     (print-compiler-message (format nil "note: ~A" format-string)
 419                             format-args))
 420   (values))
 421
 422 ;;; Issue a note when we might or might not be in the compiler.
 423 (defun maybe-compiler-note (&rest rest)
 424   (if (boundp '*lexenv*) ; if we're in the compiler
 425       (apply #'compiler-note rest)
 426       (let ((stream *error-output*))
 427         (pprint-logical-block (stream nil :per-line-prefix ";")
 428
 429           (format stream " note: ~3I~_")
 430           (pprint-logical-block (stream nil)
 431             (apply #'format stream rest)))
 432         (fresh-line stream)))) ; (outside logical block, no per-line-prefix)
 433
 434 ;;; The politically correct way to print out progress messages and
 435 ;;; such like. We clear the current error context so that we know that
 436 ;;; it needs to be reprinted, and we also FORCE-OUTPUT so that the
 437 ;;; message gets seen right away.
 438 (declaim (ftype (function (string &rest t) (values)) compiler-mumble))
 439 (defun compiler-mumble (format-string &rest format-args)
 440   (note-message-repeats)
 441   (setq *last-error-context* nil)
 442   (apply #'format *error-output* format-string format-args)
 443   (force-output *error-output*)
 444   (values))
 445
 446 ;;; Return a string that somehow names the code in COMPONENT. We use
 447 ;;; the source path for the bind node for an arbitrary entry point to
 448 ;;; find the source context, then return that as a string.
 449 (declaim (ftype (function (component) simple-string) find-component-name))
 450 (defun find-component-name (component)
 451   (let ((ep (first (block-succ (component-head component)))))
 452     (aver ep) ; else no entry points??
 453     (multiple-value-bind (form context)
 454         (find-original-source
 455          (node-source-path (continuation-next (block-start ep))))
 456       (declare (ignore form))
 457       (let ((*print-level* 2)
 458             (*print-pretty* nil))
 459         (format nil "~{~{~S~^ ~}~^ => ~}" context)))))
 460 \f
 461 ;;;; condition system interface
 462
 463 ;;; Keep track of how many times each kind of condition happens.
 464 (defvar *compiler-error-count*)
 465 (defvar *compiler-warning-count*)
 466 (defvar *compiler-style-warning-count*)
 467 (defvar *compiler-note-count*)
 468
 469 ;;; Keep track of whether any surrounding COMPILE or COMPILE-FILE call
 470 ;;; should return WARNINGS-P or FAILURE-P.
 471 (defvar *failure-p*)
 472 (defvar *warnings-p*)
 473
 474 ;;; condition handlers established by the compiler. We re-signal the
 475 ;;; condition, then if it isn't handled, we increment our warning
 476 ;;; counter and print the error message.
 477 (defun compiler-error-handler (condition)
 478   (signal condition)
 479   (incf *compiler-error-count*)
 480   (setf *warnings-p* t
 481         *failure-p* t)
 482   (print-compiler-condition condition)
 483   (continue condition))
 484 (defun compiler-warning-handler (condition)
 485   (signal condition)
 486   (incf *compiler-warning-count*)
 487   (setf *warnings-p* t
 488         *failure-p* t)
 489   (print-compiler-condition condition)
 490   (muffle-warning condition))
 491 (defun compiler-style-warning-handler (condition)
 492   (signal condition)
 493   (incf *compiler-style-warning-count*)
 494   (setf *warnings-p* t)
 495   (print-compiler-condition condition)
 496   (muffle-warning condition))
 497 \f
 498 ;;;; undefined warnings
 499
 500 (defvar *undefined-warning-limit* 3
 501   #!+sb-doc
 502   "If non-null, then an upper limit on the number of unknown function or type
 503   warnings that the compiler will print for any given name in a single
 504   compilation. This prevents excessive amounts of output when the real
 505   problem is a missing definition (as opposed to a typo in the use.)")
 506
 507 ;;; Make an entry in the *UNDEFINED-WARNINGS* describing a reference
 508 ;;; to NAME of the specified KIND. If we have exceeded the warning
 509 ;;; limit, then just increment the count, otherwise note the current
 510 ;;; error context.
 511 ;;;
 512 ;;; Undefined types are noted by a condition handler in
 513 ;;; WITH-COMPILATION-UNIT, which can potentially be invoked outside
 514 ;;; the compiler, hence the BOUNDP check.
 515 (defun note-undefined-reference (name kind)
 516   (unless (and
 517            ;; Check for boundness so we don't blow up if we're called
 518            ;; when IR1 conversion isn't going on.
 519            (boundp '*lexenv*)
 520            ;; FIXME: I'm pretty sure the INHIBIT-WARNINGS test below
 521            ;; isn't a good idea; we should have INHIBIT-WARNINGS
 522            ;; affect compiler notes, not STYLE-WARNINGs. And I'm not
 523            ;; sure what the BOUNDP '*LEXENV* test above is for; it's
 524            ;; likely a good idea, but it probably deserves an
 525            ;; explanatory comment.
 526            (policy *lexenv* (= inhibit-warnings 3)))
 527     (let* ((found (dolist (warning *undefined-warnings* nil)
 528                     (when (and (equal (undefined-warning-name warning) name)
 529                                (eq (undefined-warning-kind warning) kind))
 530                       (return warning))))
 531            (res (or found
 532                     (make-undefined-warning :name name :kind kind))))
 533       (unless found (push res *undefined-warnings*))
 534       (when (or (not *undefined-warning-limit*)
 535                 (< (undefined-warning-count res) *undefined-warning-limit*))
 536         (push (find-error-context (list name))
 537               (undefined-warning-warnings res)))
 538       (incf (undefined-warning-count res))))
 539   (values))