src/compiler/ir1report.lisp

   1 ;;;; machinery for reporting errors/warnings/notes/whatnot from
   2 ;;;; the compiler
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; compiler error context determination
  16
  17 (declaim (special *current-path*))
  18
  19 ;;; We bind print level and length when printing out messages so that
  20 ;;; we don't dump huge amounts of garbage.
  21 ;;;
  22 ;;; FIXME: It's not possible to get the defaults right for everyone.
  23 ;;; So: Should these variables be in the SB-EXT package? Or should we
  24 ;;; just get rid of them completely and just use the bare
  25 ;;; CL:*PRINT-FOO* variables instead?
  26 (declaim (type (or unsigned-byte null)
  27                *compiler-error-print-level*
  28                *compiler-error-print-length*
  29                *compiler-error-print-lines*))
  30 (defvar *compiler-error-print-level* 5
  31   #!+sb-doc
  32   "the value for *PRINT-LEVEL* when printing compiler error messages")
  33 (defvar *compiler-error-print-length* 10
  34   #!+sb-doc
  35   "the value for *PRINT-LENGTH* when printing compiler error messages")
  36 (defvar *compiler-error-print-lines* 12
  37   #!+sb-doc
  38   "the value for *PRINT-LINES* when printing compiler error messages")
  39
  40 (defvar *enclosing-source-cutoff* 1
  41   #!+sb-doc
  42   "The maximum number of enclosing non-original source forms (i.e. from
  43   macroexpansion) that we print in full. For additional enclosing forms, we
  44   print only the CAR.")
  45 (declaim (type unsigned-byte *enclosing-source-cutoff*))
  46
  47 ;;; We separate the determination of compiler error contexts from the
  48 ;;; actual signalling of those errors by objectifying the error
  49 ;;; context. This allows postponement of the determination of how (and
  50 ;;; if) to signal the error.
  51 ;;;
  52 ;;; We take care not to reference any of the IR1 so that pending
  53 ;;; potential error messages won't prevent the IR1 from being GC'd. To
  54 ;;; this end, we convert source forms to strings so that source forms
  55 ;;; that contain IR1 references (e.g. %DEFUN) don't hold onto the IR.
  56 (defstruct (compiler-error-context
  57             #-no-ansi-print-object
  58             (:print-object (lambda (x stream)
  59                              (print-unreadable-object (x stream :type t))))
  60             (:copier nil))
  61   ;; a list of the stringified CARs of the enclosing non-original source forms
  62   ;; exceeding the *enclosing-source-cutoff*
  63   (enclosing-source nil :type list)
  64   ;; a list of stringified enclosing non-original source forms
  65   (source nil :type list)
  66   ;; the stringified form in the original source that expanded into SOURCE
  67   (original-source (missing-arg) :type simple-string)
  68   ;; a list of prefixes of "interesting" forms that enclose original-source
  69   (context nil :type list)
  70   ;; the FILE-INFO-NAME for the relevant FILE-INFO
  71   (file-name (missing-arg) :type (or pathname (member :lisp :stream)))
  72   ;; the file position at which the top level form starts, if applicable
  73   (file-position nil :type (or index null))
  74   ;; the original source part of the source path
  75   (original-source-path nil :type list))
  76
  77 ;;; If true, this is the node which is used as context in compiler warning
  78 ;;; messages.
  79 (declaim (type (or null compiler-error-context node) *compiler-error-context*))
  80 (defvar *compiler-error-context* nil)
  81
  82 ;;; a hashtable mapping macro names to source context parsers. Each parser
  83 ;;; function returns the source-context list for that form.
  84 (defvar *source-context-methods* (make-hash-table))
  85
  86 ;;; documentation originally from cmu-user.tex:
  87 ;;;   This macro defines how to extract an abbreviated source context from
  88 ;;;   the \var{name}d form when it appears in the compiler input.
  89 ;;;   \var{lambda-list} is a \code{defmacro} style lambda-list used to
  90 ;;;   parse the arguments. The \var{body} should return a list of
  91 ;;;   subforms that can be printed on about one line. There are
  92 ;;;   predefined methods for \code{defstruct}, \code{defmethod}, etc. If
  93 ;;;   no method is defined, then the first two subforms are returned.
  94 ;;;   Note that this facility implicitly determines the string name
  95 ;;;   associated with anonymous functions.
  96 ;;; So even though SBCL itself only uses this macro within this file,
  97 ;;; it's a reasonable thing to put in SB-EXT in case some dedicated
  98 ;;; user wants to do some heavy tweaking to make SBCL give more
  99 ;;; informative output about his code.
 100 (defmacro define-source-context (name lambda-list &body body)
 101   #!+sb-doc
 102   "DEFINE-SOURCE-CONTEXT Name Lambda-List Form*
 103    This macro defines how to extract an abbreviated source context from the
 104    Named form when it appears in the compiler input. Lambda-List is a DEFMACRO
 105    style lambda-list used to parse the arguments. The Body should return a
 106    list of subforms suitable for a \"~{~S ~}\" format string."
 107   (let ((n-whole (gensym)))
 108     `(setf (gethash ',name *source-context-methods*)
 109            (lambda (,n-whole)
 110              (destructuring-bind ,lambda-list ,n-whole ,@body)))))
 111
 112 (defmacro def-source-context (&rest rest)
 113   (deprecation-warning 'def-source-context 'define-source-context)
 114   `(define-source-context ,@rest))
 115
 116 (define-source-context defstruct (name-or-options &rest slots)
 117   (declare (ignore slots))
 118   `(defstruct ,(if (consp name-or-options)
 119                    (car name-or-options)
 120                    name-or-options)))
 121
 122 (define-source-context function (thing)
 123   (if (and (consp thing) (eq (first thing) 'lambda) (consp (rest thing)))
 124       `(lambda ,(second thing))
 125       `(function ,thing)))
 126
 127 ;;; Return the first two elements of FORM if FORM is a list. Take the
 128 ;;; CAR of the second form if appropriate.
 129 (defun source-form-context (form)
 130   (cond ((atom form) nil)
 131         ((>= (length form) 2)
 132          (let* ((context-fun-default (lambda (x)
 133                                        (declare (ignore x))
 134                                        (list (first form) (second form))))
 135                 (context-fun (gethash (first form)
 136                                       *source-context-methods*
 137                                       context-fun-default)))
 138            (declare (type function context-fun))
 139            (funcall context-fun (rest form))))
 140         (t
 141          form)))
 142
 143 ;;; Given a source path, return the original source form and a
 144 ;;; description of the interesting aspects of the context in which it
 145 ;;; appeared. The context is a list of lists, one sublist per context
 146 ;;; form. The sublist is a list of some of the initial subforms of the
 147 ;;; context form.
 148 ;;;
 149 ;;; For now, we use the first two subforms of each interesting form. A
 150 ;;; form is interesting if the first element is a symbol beginning
 151 ;;; with "DEF" and it is not the source form. If there is no
 152 ;;; DEF-mumble, then we use the outermost containing form. If the
 153 ;;; second subform is a list, then in some cases we return the CAR of
 154 ;;; that form rather than the whole form (i.e. don't show DEFSTRUCT
 155 ;;; options, etc.)
 156 (defun find-original-source (path)
 157   (declare (list path))
 158   (let* ((rpath (reverse (source-path-original-source path)))
 159          (tlf (first rpath))
 160          (root (find-source-root tlf *source-info*)))
 161     (collect ((context))
 162       (let ((form root)
 163             (current (rest rpath)))
 164         (loop
 165           (when (atom form)
 166             (aver (null current))
 167             (return))
 168           (let ((head (first form)))
 169             (when (symbolp head)
 170               (let ((name (symbol-name head)))
 171                 (when (and (>= (length name) 3) (string= name "DEF" :end1 3))
 172                   (context (source-form-context form))))))
 173           (when (null current) (return))
 174           (setq form (nth (pop current) form)))
 175
 176         (cond ((context)
 177                (values form (context)))
 178               ((and path root)
 179                (let ((c (source-form-context root)))
 180                  (values form (if c (list c) nil))))
 181               (t
 182                (values '(unable to locate source)
 183                        '((some strange place)))))))))
 184
 185 ;;; Convert a source form to a string, suitably formatted for use in
 186 ;;; compiler warnings.
 187 (defun stringify-form (form &optional (pretty t))
 188   (with-standard-io-syntax
 189    (let ((*print-readably* nil)
 190          (*print-pretty* pretty)
 191          (*print-level* *compiler-error-print-level*)
 192          (*print-length* *compiler-error-print-length*)
 193          (*print-lines* *compiler-error-print-lines*))
 194      (if pretty
 195          (format nil "~<~@;  ~S~:>" (list form))
 196          (prin1-to-string form)))))
 197
 198 ;;; shorthand for a repeated idiom in creating debug names
 199 ;;;
 200 ;;; the problem, part I: We want to create debug names that look like
 201 ;;; "&MORE processor for <something>" where <something> might be
 202 ;;; either a source-name value (typically a symbol) or a non-symbol
 203 ;;; debug-name value (typically a string). It's awkward to handle this
 204 ;;; with FORMAT because we'd like to splice a source-name value using
 205 ;;; "~S" (to get package qualifiers) but a debug-name value using "~A"
 206 ;;; (to avoid irrelevant quotes at string splice boundaries).
 207 ;;;
 208 ;;; the problem, part II: The <something> is represented as a pair
 209 ;;; of values, SOURCE-NAME and DEBUG-NAME, where SOURCE-NAME is used
 210 ;;; if it's not .ANONYMOUS. (This is parallel to the way that ordinarily
 211 ;;; we don't use a value if it's NIL, instead defaulting it. But we
 212 ;;; can't safely/comfortably use NIL for that in this context, since
 213 ;;; the app programmer can use NIL as a name, so we use the private
 214 ;;; symbol .ANONYMOUS. instead.)
 215 ;;;
 216 ;;; the solution: Use this function to convert whatever it is to a
 217 ;;; string, which FORMAT can then splice using "~A".
 218 (defun as-debug-name (source-name debug-name)
 219   (if (eql source-name '.anonymous.)
 220       debug-name
 221       (debug-namify "~S" source-name)))
 222
 223 ;;; Return a COMPILER-ERROR-CONTEXT structure describing the current
 224 ;;; error context, or NIL if we can't figure anything out. ARGS is a
 225 ;;; list of things that are going to be printed out in the error
 226 ;;; message, and can thus be blown off when they appear in the source
 227 ;;; context.
 228 (defun find-error-context (args)
 229   (let ((context *compiler-error-context*))
 230     (if (compiler-error-context-p context)
 231         context
 232         (let ((path (or (and (boundp '*current-path*) *current-path*)
 233                         (if context
 234                             (node-source-path context)
 235                             nil))))
 236           (when (and *source-info* path)
 237             (multiple-value-bind (form src-context) (find-original-source path)
 238               (collect ((full nil cons)
 239                         (short nil cons))
 240                 (let ((forms (source-path-forms path))
 241                       (n 0))
 242                   (dolist (src (if (member (first forms) args)
 243                                    (rest forms)
 244                                    forms))
 245                     (if (>= n *enclosing-source-cutoff*)
 246                         (short (stringify-form (if (consp src)
 247                                                    (car src)
 248                                                    src)
 249                                                nil))
 250                         (full (stringify-form src)))
 251                     (incf n)))
 252
 253                 (let* ((tlf (source-path-tlf-number path))
 254                        (file-info (source-info-file-info *source-info*)))
 255                   (make-compiler-error-context
 256                    :enclosing-source (short)
 257                    :source (full)
 258                    :original-source (stringify-form form)
 259                    :context src-context
 260                    :file-name (file-info-name file-info)
 261                    :file-position
 262                    (multiple-value-bind (ignore pos)
 263                        (find-source-root tlf *source-info*)
 264                      (declare (ignore ignore))
 265                      pos)
 266                    :original-source-path
 267                    (source-path-original-source path))))))))))
 268 \f
 269 ;;;; printing error messages
 270
 271 ;;; We save the context information that we printed out most recently
 272 ;;; so that we don't print it out redundantly.
 273
 274 ;;; The last COMPILER-ERROR-CONTEXT that we printed.
 275 (defvar *last-error-context* nil)
 276 (declaim (type (or compiler-error-context null) *last-error-context*))
 277
 278 ;;; The format string and args for the last error we printed.
 279 (defvar *last-format-string* nil)
 280 (defvar *last-format-args* nil)
 281 (declaim (type (or string null) *last-format-string*))
 282 (declaim (type list *last-format-args*))
 283
 284 ;;; The number of times that the last error message has been emitted,
 285 ;;; so that we can compress duplicate error messages.
 286 (defvar *last-message-count* 0)
 287 (declaim (type index *last-message-count*))
 288
 289 ;;; If the last message was given more than once, then print out an
 290 ;;; indication of how many times it was repeated. We reset the message
 291 ;;; count when we are done.
 292 (defun note-message-repeats (&optional (terpri t))
 293   (cond ((= *last-message-count* 1)
 294          (when terpri (terpri *error-output*)))
 295         ((> *last-message-count* 1)
 296           (format *error-output* "~&; [Last message occurs ~W times.]~2%"
 297                  *last-message-count*)))
 298   (setq *last-message-count* 0))
 299
 300 ;;; Print out the message, with appropriate context if we can find it.
 301 ;;; If the context is different from the context of the last message
 302 ;;; we printed, then we print the context. If the original source is
 303 ;;; different from the source we are working on, then we print the
 304 ;;; current source in addition to the original source.
 305 ;;;
 306 ;;; We suppress printing of messages identical to the previous, but
 307 ;;; record the number of times that the message is repeated.
 308 (defun print-compiler-message (format-string format-args)
 309
 310   (declare (type simple-string format-string))
 311   (declare (type list format-args))
 312
 313   (let ((stream *error-output*)
 314         (context (find-error-context format-args)))
 315     (cond
 316      (context
 317       (let ((file (compiler-error-context-file-name context))
 318             (in (compiler-error-context-context context))
 319             (form (compiler-error-context-original-source context))
 320             (enclosing (compiler-error-context-enclosing-source context))
 321             (source (compiler-error-context-source context))
 322             (last *last-error-context*))
 323
 324         (unless (and last
 325                      (equal file (compiler-error-context-file-name last)))
 326           (when (pathnamep file)
 327             (note-message-repeats)
 328             (setq last nil)
 329             (format stream "~2&; file: ~A~%" (namestring file))))
 330
 331         (unless (and last
 332                      (equal in (compiler-error-context-context last)))
 333           (note-message-repeats)
 334           (setq last nil)
 335           (format stream "~&")
 336           (pprint-logical-block (stream nil :per-line-prefix "; ")
 337             (format stream "in:~{~<~%    ~4:;~{ ~S~}~>~^ =>~}" in))
 338           (format stream "~%"))
 339
 340
 341         (unless (and last
 342                      (string= form
 343                               (compiler-error-context-original-source last)))
 344           (note-message-repeats)
 345           (setq last nil)
 346           (format stream "~&")
 347           (pprint-logical-block (stream nil :per-line-prefix "; ")
 348             (format stream "  ~A" form))
 349           (format stream "~&"))
 350
 351         (unless (and last
 352                      (equal enclosing
 353                             (compiler-error-context-enclosing-source last)))
 354           (when enclosing
 355             (note-message-repeats)
 356             (setq last nil)
 357             (format stream "~&; --> ~{~<~%; --> ~1:;~A~> ~}~%" enclosing)))
 358
 359         (unless (and last
 360                      (equal source (compiler-error-context-source last)))
 361           (setq *last-format-string* nil)
 362           (when source
 363             (note-message-repeats)
 364             (dolist (src source)
 365               (format stream "~&")
 366               (write-string "; ==>" stream)
 367               (format stream "~&")
 368               (pprint-logical-block (stream nil :per-line-prefix "; ")
 369                 (write-string src stream)))))))
 370      (t
 371        (format stream "~&")
 372       (note-message-repeats)
 373       (setq *last-format-string* nil)
 374        (format stream "~&")))
 375
 376     (setq *last-error-context* context)
 377
 378     (unless (and (equal format-string *last-format-string*)
 379                  (tree-equal format-args *last-format-args*))
 380       (note-message-repeats nil)
 381       (setq *last-format-string* format-string)
 382       (setq *last-format-args* format-args)
 383       (let ((*print-level*  *compiler-error-print-level*)
 384             (*print-length* *compiler-error-print-length*)
 385             (*print-lines*  *compiler-error-print-lines*))
 386         (format stream "~&")
 387         (pprint-logical-block (stream nil :per-line-prefix "; ")
 388           (format stream "~&~?" format-string format-args))
 389         (format stream "~&"))))
 390
 391   (incf *last-message-count*)
 392   (values))
 393
 394 (defun print-compiler-condition (condition)
 395   (declare (type condition condition))
 396   (let (;; These different classes of conditions have different
 397         ;; effects on the return codes of COMPILE-FILE, so it's nice
 398         ;; for users to be able to pick them out by lexical search
 399         ;; through the output.
 400         (what (etypecase condition
 401                 (style-warning 'style-warning)
 402                 (warning 'warning)
 403                 (error 'error))))
 404     (multiple-value-bind (format-string format-args)
 405         (if (typep condition 'simple-condition)
 406             (values (simple-condition-format-control condition)
 407                     (simple-condition-format-arguments condition))
 408             (values "~A"
 409                     (list (with-output-to-string (s)
 410                             (princ condition s)))))
 411       (print-compiler-message (format nil
 412                                       "caught ~S:~%  ~A"
 413                                       what
 414                                       format-string)
 415                               format-args)))
 416   (values))
 417
 418 ;;; COMPILER-NOTE is vaguely like COMPILER-ERROR and the other
 419 ;;; condition-signalling functions, but it just writes some output
 420 ;;; instead of signalling. (In CMU CL, it did signal a condition, but
 421 ;;; this didn't seem to work all that well; it was weird to have
 422 ;;; COMPILE-FILE return with WARNINGS-P set when the only problem was
 423 ;;; that the compiler couldn't figure out how to compile something as
 424 ;;; efficiently as it liked.)
 425 (defun compiler-note (format-string &rest format-args)
 426   (unless (if *compiler-error-context*
 427               (policy *compiler-error-context* (= inhibit-warnings 3))
 428               (policy *lexenv* (= inhibit-warnings 3)))
 429     (incf *compiler-note-count*)
 430     (print-compiler-message (format nil "note: ~A" format-string)
 431                             format-args))
 432   (values))
 433
 434 ;;; Issue a note when we might or might not be in the compiler.
 435 (defun maybe-compiler-note (&rest rest)
 436   (if (boundp '*lexenv*) ; if we're in the compiler
 437       (apply #'compiler-note rest)
 438       (let ((stream *error-output*))
 439         (pprint-logical-block (stream nil :per-line-prefix ";")
 440
 441           (format stream " note: ~3I~_")
 442           (pprint-logical-block (stream nil)
 443             (apply #'format stream rest)))
 444         (fresh-line stream)))) ; (outside logical block, no per-line-prefix)
 445
 446 ;;; The politically correct way to print out progress messages and
 447 ;;; such like. We clear the current error context so that we know that
 448 ;;; it needs to be reprinted, and we also FORCE-OUTPUT so that the
 449 ;;; message gets seen right away.
 450 (declaim (ftype (function (string &rest t) (values)) compiler-mumble))
 451 (defun compiler-mumble (format-string &rest format-args)
 452   (note-message-repeats)
 453   (setq *last-error-context* nil)
 454   (apply #'format *error-output* format-string format-args)
 455   (force-output *error-output*)
 456   (values))
 457
 458 ;;; Return a string that somehow names the code in COMPONENT. We use
 459 ;;; the source path for the bind node for an arbitrary entry point to
 460 ;;; find the source context, then return that as a string.
 461 (declaim (ftype (function (component) simple-string) find-component-name))
 462 (defun find-component-name (component)
 463   (let ((ep (first (block-succ (component-head component)))))
 464     (aver ep) ; else no entry points??
 465     (multiple-value-bind (form context)
 466         (find-original-source
 467          (node-source-path (continuation-next (block-start ep))))
 468       (declare (ignore form))
 469       (let ((*print-level* 2)
 470             (*print-pretty* nil))
 471         (format nil "~{~{~S~^ ~}~^ => ~}" context)))))
 472 \f
 473 ;;;; condition system interface
 474
 475 ;;; Keep track of how many times each kind of condition happens.
 476 (defvar *compiler-error-count*)
 477 (defvar *compiler-warning-count*)
 478 (defvar *compiler-style-warning-count*)
 479 (defvar *compiler-note-count*)
 480
 481 ;;; Keep track of whether any surrounding COMPILE or COMPILE-FILE call
 482 ;;; should return WARNINGS-P or FAILURE-P.
 483 (defvar *failure-p*)
 484 (defvar *warnings-p*)
 485
 486 ;;; condition handlers established by the compiler. We re-signal the
 487 ;;; condition, then if it isn't handled, we increment our warning
 488 ;;; counter and print the error message.
 489 (defun compiler-error-handler (condition)
 490   (signal condition)
 491   (incf *compiler-error-count*)
 492   (setf *warnings-p* t
 493         *failure-p* t)
 494   (print-compiler-condition condition)
 495   (continue condition))
 496 (defun compiler-warning-handler (condition)
 497   (signal condition)
 498   (incf *compiler-warning-count*)
 499   (setf *warnings-p* t
 500         *failure-p* t)
 501   (print-compiler-condition condition)
 502   (muffle-warning condition))
 503 (defun compiler-style-warning-handler (condition)
 504   (signal condition)
 505   (incf *compiler-style-warning-count*)
 506   (setf *warnings-p* t)
 507   (print-compiler-condition condition)
 508   (muffle-warning condition))
 509 \f
 510 ;;;; undefined warnings
 511
 512 (defvar *undefined-warning-limit* 3
 513   #!+sb-doc
 514   "If non-null, then an upper limit on the number of unknown function or type
 515   warnings that the compiler will print for any given name in a single
 516   compilation. This prevents excessive amounts of output when the real
 517   problem is a missing definition (as opposed to a typo in the use.)")
 518
 519 ;;; Make an entry in the *UNDEFINED-WARNINGS* describing a reference
 520 ;;; to NAME of the specified KIND. If we have exceeded the warning
 521 ;;; limit, then just increment the count, otherwise note the current
 522 ;;; error context.
 523 ;;;
 524 ;;; Undefined types are noted by a condition handler in
 525 ;;; WITH-COMPILATION-UNIT, which can potentially be invoked outside
 526 ;;; the compiler, hence the BOUNDP check.
 527 (defun note-undefined-reference (name kind)
 528   (unless (and
 529            ;; Check for boundness so we don't blow up if we're called
 530            ;; when IR1 conversion isn't going on.
 531            (boundp '*lexenv*)
 532            ;; FIXME: I'm pretty sure the INHIBIT-WARNINGS test below
 533            ;; isn't a good idea; we should have INHIBIT-WARNINGS
 534            ;; affect compiler notes, not STYLE-WARNINGs. And I'm not
 535            ;; sure what the BOUNDP '*LEXENV* test above is for; it's
 536            ;; likely a good idea, but it probably deserves an
 537            ;; explanatory comment.
 538            (policy *lexenv* (= inhibit-warnings 3)))
 539     (let* ((found (dolist (warning *undefined-warnings* nil)
 540                     (when (and (equal (undefined-warning-name warning) name)
 541                                (eq (undefined-warning-kind warning) kind))
 542                       (return warning))))
 543            (res (or found
 544                     (make-undefined-warning :name name :kind kind))))
 545       (unless found (push res *undefined-warnings*))
 546       (when (or (not *undefined-warning-limit*)
 547                 (< (undefined-warning-count res) *undefined-warning-limit*))
 548         (push (find-error-context (list name))
 549               (undefined-warning-warnings res)))
 550       (incf (undefined-warning-count res))))
 551   (values))