src/compiler/ir1report.lisp

   1 ;;;; machinery for reporting errors/warnings/notes/whatnot from
   2 ;;;; the compiler
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; compiler error context determination
  16
  17 (declaim (special *current-path*))
  18
  19 ;;; We bind print level and length when printing out messages so that
  20 ;;; we don't dump huge amounts of garbage.
  21 ;;;
  22 ;;; FIXME: It's not possible to get the defaults right for everyone.
  23 ;;; So: Should these variables be in the SB-EXT package? Or should we
  24 ;;; just get rid of them completely and just use the bare
  25 ;;; CL:*PRINT-FOO* variables instead?
  26 (declaim (type (or unsigned-byte null)
  27                *compiler-error-print-level*
  28                *compiler-error-print-length*
  29                *compiler-error-print-lines*))
  30 (defvar *compiler-error-print-level* 5
  31   #!+sb-doc
  32   "the value for *PRINT-LEVEL* when printing compiler error messages")
  33 (defvar *compiler-error-print-length* 10
  34   #!+sb-doc
  35   "the value for *PRINT-LENGTH* when printing compiler error messages")
  36 (defvar *compiler-error-print-lines* 12
  37   #!+sb-doc
  38   "the value for *PRINT-LINES* when printing compiler error messages")
  39
  40 (defvar *enclosing-source-cutoff* 1
  41   #!+sb-doc
  42   "The maximum number of enclosing non-original source forms (i.e. from
  43   macroexpansion) that we print in full. For additional enclosing forms, we
  44   print only the CAR.")
  45 (declaim (type unsigned-byte *enclosing-source-cutoff*))
  46
  47 ;;; We separate the determination of compiler error contexts from the
  48 ;;; actual signalling of those errors by objectifying the error
  49 ;;; context. This allows postponement of the determination of how (and
  50 ;;; if) to signal the error.
  51 ;;;
  52 ;;; We take care not to reference any of the IR1 so that pending
  53 ;;; potential error messages won't prevent the IR1 from being GC'd. To
  54 ;;; this end, we convert source forms to strings so that source forms
  55 ;;; that contain IR1 references (e.g. %DEFUN) don't hold onto the IR.
  56 (defstruct (compiler-error-context
  57             #-no-ansi-print-object
  58             (:print-object (lambda (x stream)
  59                              (print-unreadable-object (x stream :type t))))
  60             (:copier nil))
  61   ;; a list of the stringified CARs of the enclosing non-original source forms
  62   ;; exceeding the *enclosing-source-cutoff*
  63   (enclosing-source nil :type list)
  64   ;; a list of stringified enclosing non-original source forms
  65   (source nil :type list)
  66   ;; the stringified form in the original source that expanded into SOURCE
  67   (original-source (missing-arg) :type simple-string)
  68   ;; a list of prefixes of "interesting" forms that enclose original-source
  69   (context nil :type list)
  70   ;; the FILE-INFO-NAME for the relevant FILE-INFO
  71   (file-name (missing-arg) :type (or pathname (member :lisp :stream)))
  72   ;; the file position at which the top level form starts, if applicable
  73   (file-position nil :type (or index null))
  74   ;; the original source part of the source path
  75   (original-source-path nil :type list))
  76
  77 ;;; If true, this is the node which is used as context in compiler warning
  78 ;;; messages.
  79 (declaim (type (or null compiler-error-context node) *compiler-error-context*))
  80 (defvar *compiler-error-context* nil)
  81
  82 ;;; a hashtable mapping macro names to source context parsers. Each parser
  83 ;;; function returns the source-context list for that form.
  84 (defvar *source-context-methods* (make-hash-table))
  85
  86 ;;; documentation originally from cmu-user.tex:
  87 ;;;   This macro defines how to extract an abbreviated source context from
  88 ;;;   the \var{name}d form when it appears in the compiler input.
  89 ;;;   \var{lambda-list} is a \code{defmacro} style lambda-list used to
  90 ;;;   parse the arguments. The \var{body} should return a list of
  91 ;;;   subforms that can be printed on about one line. There are
  92 ;;;   predefined methods for \code{defstruct}, \code{defmethod}, etc. If
  93 ;;;   no method is defined, then the first two subforms are returned.
  94 ;;;   Note that this facility implicitly determines the string name
  95 ;;;   associated with anonymous functions.
  96 ;;; So even though SBCL itself only uses this macro within this file,
  97 ;;; it's a reasonable thing to put in SB-EXT in case some dedicated
  98 ;;; user wants to do some heavy tweaking to make SBCL give more
  99 ;;; informative output about his code.
 100 (defmacro define-source-context (name lambda-list &body body)
 101   #!+sb-doc
 102   "DEFINE-SOURCE-CONTEXT Name Lambda-List Form*
 103    This macro defines how to extract an abbreviated source context from the
 104    Named form when it appears in the compiler input. Lambda-List is a DEFMACRO
 105    style lambda-list used to parse the arguments. The Body should return a
 106    list of subforms suitable for a \"~{~S ~}\" format string."
 107   (let ((n-whole (gensym)))
 108     `(setf (gethash ',name *source-context-methods*)
 109            (lambda (,n-whole)
 110              (destructuring-bind ,lambda-list ,n-whole ,@body)))))
 111
 112 (defmacro def-source-context (&rest rest)
 113   (deprecation-warning 'def-source-context 'define-source-context)
 114   `(define-source-context ,@rest))
 115
 116 (define-source-context defstruct (name-or-options &rest slots)
 117   (declare (ignore slots))
 118   `(defstruct ,(if (consp name-or-options)
 119                    (car name-or-options)
 120                    name-or-options)))
 121
 122 (define-source-context function (thing)
 123   (if (and (consp thing) (eq (first thing) 'lambda) (consp (rest thing)))
 124       `(lambda ,(second thing))
 125       `(function ,thing)))
 126
 127 ;;; Return the first two elements of FORM if FORM is a list. Take the
 128 ;;; CAR of the second form if appropriate.
 129 (defun source-form-context (form)
 130   (cond ((atom form) nil)
 131         ((>= (length form) 2)
 132          (funcall (gethash (first form) *source-context-methods*
 133                            (lambda (x)
 134                              (declare (ignore x))
 135                              (list (first form) (second form))))
 136                   (rest form)))
 137         (t
 138          form)))
 139
 140 ;;; Given a source path, return the original source form and a
 141 ;;; description of the interesting aspects of the context in which it
 142 ;;; appeared. The context is a list of lists, one sublist per context
 143 ;;; form. The sublist is a list of some of the initial subforms of the
 144 ;;; context form.
 145 ;;;
 146 ;;; For now, we use the first two subforms of each interesting form. A
 147 ;;; form is interesting if the first element is a symbol beginning
 148 ;;; with "DEF" and it is not the source form. If there is no
 149 ;;; DEF-mumble, then we use the outermost containing form. If the
 150 ;;; second subform is a list, then in some cases we return the CAR of
 151 ;;; that form rather than the whole form (i.e. don't show DEFSTRUCT
 152 ;;; options, etc.)
 153 (defun find-original-source (path)
 154   (declare (list path))
 155   (let* ((rpath (reverse (source-path-original-source path)))
 156          (tlf (first rpath))
 157          (root (find-source-root tlf *source-info*)))
 158     (collect ((context))
 159       (let ((form root)
 160             (current (rest rpath)))
 161         (loop
 162           (when (atom form)
 163             (aver (null current))
 164             (return))
 165           (let ((head (first form)))
 166             (when (symbolp head)
 167               (let ((name (symbol-name head)))
 168                 (when (and (>= (length name) 3) (string= name "DEF" :end1 3))
 169                   (context (source-form-context form))))))
 170           (when (null current) (return))
 171           (setq form (nth (pop current) form)))
 172
 173         (cond ((context)
 174                (values form (context)))
 175               ((and path root)
 176                (let ((c (source-form-context root)))
 177                  (values form (if c (list c) nil))))
 178               (t
 179                (values '(unable to locate source)
 180                        '((some strange place)))))))))
 181
 182 ;;; Convert a source form to a string, suitably formatted for use in
 183 ;;; compiler warnings.
 184 (defun stringify-form (form &optional (pretty t))
 185   (with-standard-io-syntax
 186    (let ((*print-readably* nil)
 187          (*print-pretty* pretty)
 188          (*print-level* *compiler-error-print-level*)
 189          (*print-length* *compiler-error-print-length*)
 190          (*print-lines* *compiler-error-print-lines*))
 191      (if pretty
 192          (format nil "~<~@;  ~S~:>" (list form))
 193          (prin1-to-string form)))))
 194
 195 ;;; shorthand for a repeated idiom in creating debug names
 196 ;;;
 197 ;;; the problem, part I: We want to create debug names that look like
 198 ;;; "&MORE processor for <something>" where <something> might be
 199 ;;; either a source-name value (typically a symbol) or a non-symbol
 200 ;;; debug-name value (typically a string). It's awkward to handle this
 201 ;;; with FORMAT because we'd like to splice a source-name value using
 202 ;;; "~S" (to get package qualifiers) but a debug-name value using "~A"
 203 ;;; (to avoid irrelevant quotes at string splice boundaries).
 204 ;;;
 205 ;;; the problem, part II: The <something> is represented as a pair
 206 ;;; of values, SOURCE-NAME and DEBUG-NAME, where SOURCE-NAME is used
 207 ;;; if it's not .ANONYMOUS. (This is parallel to the way that ordinarily
 208 ;;; we don't use a value if it's NIL, instead defaulting it. But we
 209 ;;; can't safely/comfortably use NIL for that in this context, since
 210 ;;; the app programmer can use NIL as a name, so we use the private
 211 ;;; symbol .ANONYMOUS. instead.)
 212 ;;;
 213 ;;; the solution: Use this function to convert whatever it is to a
 214 ;;; string, which FORMAT can then splice using "~A".
 215 (defun as-debug-name (source-name debug-name)
 216   (if (eql source-name '.anonymous.)
 217       debug-name
 218       (debug-namify "~S" source-name)))
 219
 220 ;;; Return a COMPILER-ERROR-CONTEXT structure describing the current
 221 ;;; error context, or NIL if we can't figure anything out. ARGS is a
 222 ;;; list of things that are going to be printed out in the error
 223 ;;; message, and can thus be blown off when they appear in the source
 224 ;;; context.
 225 (defun find-error-context (args)
 226   (let ((context *compiler-error-context*))
 227     (if (compiler-error-context-p context)
 228         context
 229         (let ((path (or (and (boundp '*current-path*) *current-path*)
 230                         (if context
 231                             (node-source-path context)
 232                             nil))))
 233           (when (and *source-info* path)
 234             (multiple-value-bind (form src-context) (find-original-source path)
 235               (collect ((full nil cons)
 236                         (short nil cons))
 237                 (let ((forms (source-path-forms path))
 238                       (n 0))
 239                   (dolist (src (if (member (first forms) args)
 240                                    (rest forms)
 241                                    forms))
 242                     (if (>= n *enclosing-source-cutoff*)
 243                         (short (stringify-form (if (consp src)
 244                                                    (car src)
 245                                                    src)
 246                                                nil))
 247                         (full (stringify-form src)))
 248                     (incf n)))
 249
 250                 (let* ((tlf (source-path-tlf-number path))
 251                        (file-info (source-info-file-info *source-info*)))
 252                   (make-compiler-error-context
 253                    :enclosing-source (short)
 254                    :source (full)
 255                    :original-source (stringify-form form)
 256                    :context src-context
 257                    :file-name (file-info-name file-info)
 258                    :file-position
 259                    (multiple-value-bind (ignore pos)
 260                        (find-source-root tlf *source-info*)
 261                      (declare (ignore ignore))
 262                      pos)
 263                    :original-source-path
 264                    (source-path-original-source path))))))))))
 265 \f
 266 ;;;; printing error messages
 267
 268 ;;; We save the context information that we printed out most recently
 269 ;;; so that we don't print it out redundantly.
 270
 271 ;;; The last COMPILER-ERROR-CONTEXT that we printed.
 272 (defvar *last-error-context* nil)
 273 (declaim (type (or compiler-error-context null) *last-error-context*))
 274
 275 ;;; The format string and args for the last error we printed.
 276 (defvar *last-format-string* nil)
 277 (defvar *last-format-args* nil)
 278 (declaim (type (or string null) *last-format-string*))
 279 (declaim (type list *last-format-args*))
 280
 281 ;;; The number of times that the last error message has been emitted,
 282 ;;; so that we can compress duplicate error messages.
 283 (defvar *last-message-count* 0)
 284 (declaim (type index *last-message-count*))
 285
 286 ;;; If the last message was given more than once, then print out an
 287 ;;; indication of how many times it was repeated. We reset the message
 288 ;;; count when we are done.
 289 (defun note-message-repeats (&optional (terpri t))
 290   (cond ((= *last-message-count* 1)
 291          (when terpri (terpri *error-output*)))
 292         ((> *last-message-count* 1)
 293           (format *error-output* "~&; [Last message occurs ~W times.]~2%"
 294                  *last-message-count*)))
 295   (setq *last-message-count* 0))
 296
 297 ;;; Print out the message, with appropriate context if we can find it.
 298 ;;; If the context is different from the context of the last message
 299 ;;; we printed, then we print the context. If the original source is
 300 ;;; different from the source we are working on, then we print the
 301 ;;; current source in addition to the original source.
 302 ;;;
 303 ;;; We suppress printing of messages identical to the previous, but
 304 ;;; record the number of times that the message is repeated.
 305 (defun print-compiler-message (format-string format-args)
 306
 307   (declare (type simple-string format-string))
 308   (declare (type list format-args))
 309
 310   (let ((stream *error-output*)
 311         (context (find-error-context format-args)))
 312     (cond
 313      (context
 314       (let ((file (compiler-error-context-file-name context))
 315             (in (compiler-error-context-context context))
 316             (form (compiler-error-context-original-source context))
 317             (enclosing (compiler-error-context-enclosing-source context))
 318             (source (compiler-error-context-source context))
 319             (last *last-error-context*))
 320
 321         (unless (and last
 322                      (equal file (compiler-error-context-file-name last)))
 323           (when (pathnamep file)
 324             (note-message-repeats)
 325             (setq last nil)
 326             (format stream "~2&; file: ~A~%" (namestring file))))
 327
 328         (unless (and last
 329                      (equal in (compiler-error-context-context last)))
 330           (note-message-repeats)
 331           (setq last nil)
 332           (format stream "~&")
 333           (pprint-logical-block (stream nil :per-line-prefix "; ")
 334             (format stream "in:~{~<~%    ~4:;~{ ~S~}~>~^ =>~}" in))
 335           (format stream "~%"))
 336
 337
 338         (unless (and last
 339                      (string= form
 340                               (compiler-error-context-original-source last)))
 341           (note-message-repeats)
 342           (setq last nil)
 343           (format stream "~&")
 344           (pprint-logical-block (stream nil :per-line-prefix "; ")
 345             (format stream "  ~A" form))
 346           (format stream "~&"))
 347
 348         (unless (and last
 349                      (equal enclosing
 350                             (compiler-error-context-enclosing-source last)))
 351           (when enclosing
 352             (note-message-repeats)
 353             (setq last nil)
 354             (format stream "~&; --> ~{~<~%; --> ~1:;~A~> ~}~%" enclosing)))
 355
 356         (unless (and last
 357                      (equal source (compiler-error-context-source last)))
 358           (setq *last-format-string* nil)
 359           (when source
 360             (note-message-repeats)
 361             (dolist (src source)
 362               (format stream "~&")
 363               (write-string "; ==>" stream)
 364               (format stream "~&")
 365               (pprint-logical-block (stream nil :per-line-prefix "; ")
 366                 (write-string src stream)))))))
 367      (t
 368        (format stream "~&")
 369       (note-message-repeats)
 370       (setq *last-format-string* nil)
 371        (format stream "~&")))
 372
 373     (setq *last-error-context* context)
 374
 375     (unless (and (equal format-string *last-format-string*)
 376                  (tree-equal format-args *last-format-args*))
 377       (note-message-repeats nil)
 378       (setq *last-format-string* format-string)
 379       (setq *last-format-args* format-args)
 380       (let ((*print-level*  *compiler-error-print-level*)
 381             (*print-length* *compiler-error-print-length*)
 382             (*print-lines*  *compiler-error-print-lines*))
 383         (format stream "~&")
 384         (pprint-logical-block (stream nil :per-line-prefix "; ")
 385           (format stream "~&~?" format-string format-args))
 386         (format stream "~&"))))
 387
 388   (incf *last-message-count*)
 389   (values))
 390
 391 (defun print-compiler-condition (condition)
 392   (declare (type condition condition))
 393   (let (;; These different classes of conditions have different
 394         ;; effects on the return codes of COMPILE-FILE, so it's nice
 395         ;; for users to be able to pick them out by lexical search
 396         ;; through the output.
 397         (what (etypecase condition
 398                 (style-warning 'style-warning)
 399                 (warning 'warning)
 400                 (error 'error))))
 401     (multiple-value-bind (format-string format-args)
 402         (if (typep condition 'simple-condition)
 403             (values (simple-condition-format-control condition)
 404                     (simple-condition-format-arguments condition))
 405             (values "~A"
 406                     (list (with-output-to-string (s)
 407                             (princ condition s)))))
 408       (print-compiler-message (format nil
 409                                       "caught ~S:~%  ~A"
 410                                       what
 411                                       format-string)
 412                               format-args)))
 413   (values))
 414
 415 ;;; COMPILER-NOTE is vaguely like COMPILER-ERROR and the other
 416 ;;; condition-signalling functions, but it just writes some output
 417 ;;; instead of signalling. (In CMU CL, it did signal a condition, but
 418 ;;; this didn't seem to work all that well; it was weird to have
 419 ;;; COMPILE-FILE return with WARNINGS-P set when the only problem was
 420 ;;; that the compiler couldn't figure out how to compile something as
 421 ;;; efficiently as it liked.)
 422 (defun compiler-note (format-string &rest format-args)
 423   (unless (if *compiler-error-context*
 424               (policy *compiler-error-context* (= inhibit-warnings 3))
 425               (policy *lexenv* (= inhibit-warnings 3)))
 426     (incf *compiler-note-count*)
 427     (print-compiler-message (format nil "note: ~A" format-string)
 428                             format-args))
 429   (values))
 430
 431 ;;; Issue a note when we might or might not be in the compiler.
 432 (defun maybe-compiler-note (&rest rest)
 433   (if (boundp '*lexenv*) ; if we're in the compiler
 434       (apply #'compiler-note rest)
 435       (let ((stream *error-output*))
 436         (pprint-logical-block (stream nil :per-line-prefix ";")
 437
 438           (format stream " note: ~3I~_")
 439           (pprint-logical-block (stream nil)
 440             (apply #'format stream rest)))
 441         (fresh-line stream)))) ; (outside logical block, no per-line-prefix)
 442
 443 ;;; The politically correct way to print out progress messages and
 444 ;;; such like. We clear the current error context so that we know that
 445 ;;; it needs to be reprinted, and we also FORCE-OUTPUT so that the
 446 ;;; message gets seen right away.
 447 (declaim (ftype (function (string &rest t) (values)) compiler-mumble))
 448 (defun compiler-mumble (format-string &rest format-args)
 449   (note-message-repeats)
 450   (setq *last-error-context* nil)
 451   (apply #'format *error-output* format-string format-args)
 452   (force-output *error-output*)
 453   (values))
 454
 455 ;;; Return a string that somehow names the code in COMPONENT. We use
 456 ;;; the source path for the bind node for an arbitrary entry point to
 457 ;;; find the source context, then return that as a string.
 458 (declaim (ftype (function (component) simple-string) find-component-name))
 459 (defun find-component-name (component)
 460   (let ((ep (first (block-succ (component-head component)))))
 461     (aver ep) ; else no entry points??
 462     (multiple-value-bind (form context)
 463         (find-original-source
 464          (node-source-path (continuation-next (block-start ep))))
 465       (declare (ignore form))
 466       (let ((*print-level* 2)
 467             (*print-pretty* nil))
 468         (format nil "~{~{~S~^ ~}~^ => ~}" context)))))
 469 \f
 470 ;;;; condition system interface
 471
 472 ;;; Keep track of how many times each kind of condition happens.
 473 (defvar *compiler-error-count*)
 474 (defvar *compiler-warning-count*)
 475 (defvar *compiler-style-warning-count*)
 476 (defvar *compiler-note-count*)
 477
 478 ;;; Keep track of whether any surrounding COMPILE or COMPILE-FILE call
 479 ;;; should return WARNINGS-P or FAILURE-P.
 480 (defvar *failure-p*)
 481 (defvar *warnings-p*)
 482
 483 ;;; condition handlers established by the compiler. We re-signal the
 484 ;;; condition, then if it isn't handled, we increment our warning
 485 ;;; counter and print the error message.
 486 (defun compiler-error-handler (condition)
 487   (signal condition)
 488   (incf *compiler-error-count*)
 489   (setf *warnings-p* t
 490         *failure-p* t)
 491   (print-compiler-condition condition)
 492   (continue condition))
 493 (defun compiler-warning-handler (condition)
 494   (signal condition)
 495   (incf *compiler-warning-count*)
 496   (setf *warnings-p* t
 497         *failure-p* t)
 498   (print-compiler-condition condition)
 499   (muffle-warning condition))
 500 (defun compiler-style-warning-handler (condition)
 501   (signal condition)
 502   (incf *compiler-style-warning-count*)
 503   (setf *warnings-p* t)
 504   (print-compiler-condition condition)
 505   (muffle-warning condition))
 506 \f
 507 ;;;; undefined warnings
 508
 509 (defvar *undefined-warning-limit* 3
 510   #!+sb-doc
 511   "If non-null, then an upper limit on the number of unknown function or type
 512   warnings that the compiler will print for any given name in a single
 513   compilation. This prevents excessive amounts of output when the real
 514   problem is a missing definition (as opposed to a typo in the use.)")
 515
 516 ;;; Make an entry in the *UNDEFINED-WARNINGS* describing a reference
 517 ;;; to NAME of the specified KIND. If we have exceeded the warning
 518 ;;; limit, then just increment the count, otherwise note the current
 519 ;;; error context.
 520 ;;;
 521 ;;; Undefined types are noted by a condition handler in
 522 ;;; WITH-COMPILATION-UNIT, which can potentially be invoked outside
 523 ;;; the compiler, hence the BOUNDP check.
 524 (defun note-undefined-reference (name kind)
 525   (unless (and
 526            ;; Check for boundness so we don't blow up if we're called
 527            ;; when IR1 conversion isn't going on.
 528            (boundp '*lexenv*)
 529            ;; FIXME: I'm pretty sure the INHIBIT-WARNINGS test below
 530            ;; isn't a good idea; we should have INHIBIT-WARNINGS
 531            ;; affect compiler notes, not STYLE-WARNINGs. And I'm not
 532            ;; sure what the BOUNDP '*LEXENV* test above is for; it's
 533            ;; likely a good idea, but it probably deserves an
 534            ;; explanatory comment.
 535            (policy *lexenv* (= inhibit-warnings 3)))
 536     (let* ((found (dolist (warning *undefined-warnings* nil)
 537                     (when (and (equal (undefined-warning-name warning) name)
 538                                (eq (undefined-warning-kind warning) kind))
 539                       (return warning))))
 540            (res (or found
 541                     (make-undefined-warning :name name :kind kind))))
 542       (unless found (push res *undefined-warnings*))
 543       (when (or (not *undefined-warning-limit*)
 544                 (< (undefined-warning-count res) *undefined-warning-limit*))
 545         (push (find-error-context (list name))
 546               (undefined-warning-warnings res)))
 547       (incf (undefined-warning-count res))))
 548   (values))