src/compiler/ir1tran-lambda.lisp

   1 ;;;; This file contains code which does the translation of lambda
   2 ;;;; forms from Lisp code to the first intermediate representation
   3 ;;;; (IR1).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;;; LAMBDA hackery
  17
  18 ;;;; Note: Take a look at the compiler-overview.tex section on "Hairy
  19 ;;;; function representation" before you seriously mess with this
  20 ;;;; stuff.
  21
  22 ;;; Verify that the NAME is a legal name for a variable and return a
  23 ;;; VAR structure for it, filling in info if it is globally special.
  24 ;;; If it is losing, we punt with a COMPILER-ERROR. NAMES-SO-FAR is a
  25 ;;; list of names which have previously been bound. If the NAME is in
  26 ;;; this list, then we error out.
  27 (declaim (ftype (sfunction (t list) lambda-var) varify-lambda-arg))
  28 (defun varify-lambda-arg (name names-so-far)
  29   (declare (inline member))
  30   (unless (symbolp name)
  31     (compiler-error "The lambda variable ~S is not a symbol." name))
  32   (when (member name names-so-far :test #'eq)
  33     (compiler-error "The variable ~S occurs more than once in the lambda list."
  34                     name))
  35   (let ((kind (info :variable :kind name)))
  36     (when (or (keywordp name) (eq kind :constant))
  37       (compiler-error "The name of the lambda variable ~S is already in use to name a constant."
  38                       name))
  39     (cond ((eq kind :special)
  40            (let ((specvar (find-free-var name)))
  41              (make-lambda-var :%source-name name
  42                               :type (leaf-type specvar)
  43                               :where-from (leaf-where-from specvar)
  44                               :specvar specvar)))
  45           (t
  46            (make-lambda-var :%source-name name)))))
  47
  48 ;;; Make the default keyword for a &KEY arg, checking that the keyword
  49 ;;; isn't already used by one of the VARS.
  50 (declaim (ftype (sfunction (symbol list t) symbol) make-keyword-for-arg))
  51 (defun make-keyword-for-arg (symbol vars keywordify)
  52   (let ((key (if (and keywordify (not (keywordp symbol)))
  53                  (keywordicate symbol)
  54                  symbol)))
  55     (dolist (var vars)
  56       (let ((info (lambda-var-arg-info var)))
  57         (when (and info
  58                    (eq (arg-info-kind info) :keyword)
  59                    (eq (arg-info-key info) key))
  60           (compiler-error
  61            "The keyword ~S appears more than once in the lambda list."
  62            key))))
  63     key))
  64
  65 ;;; Parse a lambda list into a list of VAR structures, stripping off
  66 ;;; any &AUX bindings. Each arg name is checked for legality, and
  67 ;;; duplicate names are checked for. If an arg is globally special,
  68 ;;; the var is marked as :SPECIAL instead of :LEXICAL. &KEY,
  69 ;;; &OPTIONAL and &REST args are annotated with an ARG-INFO structure
  70 ;;; which contains the extra information. If we hit something losing,
  71 ;;; we bug out with COMPILER-ERROR. These values are returned:
  72 ;;;  1. a list of the var structures for each top level argument;
  73 ;;;  2. a flag indicating whether &KEY was specified;
  74 ;;;  3. a flag indicating whether other &KEY args are allowed;
  75 ;;;  4. a list of the &AUX variables; and
  76 ;;;  5. a list of the &AUX values.
  77 (declaim (ftype (sfunction (list) (values list boolean boolean list list))
  78                 make-lambda-vars))
  79 (defun make-lambda-vars (list)
  80   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
  81                         morep more-context more-count)
  82       (parse-lambda-list list)
  83     (declare (ignore auxp)) ; since we just iterate over AUX regardless
  84     (collect ((vars)
  85               (names-so-far)
  86               (aux-vars)
  87               (aux-vals))
  88       (flet (;; PARSE-DEFAULT deals with defaults and supplied-p args
  89              ;; for optionals and keywords args.
  90              (parse-default (spec info)
  91                (when (consp (cdr spec))
  92                  (setf (arg-info-default info) (second spec))
  93                  (when (consp (cddr spec))
  94                    (let* ((supplied-p (third spec))
  95                           (supplied-var (varify-lambda-arg supplied-p
  96                                                            (names-so-far))))
  97                      (setf (arg-info-supplied-p info) supplied-var)
  98                      (names-so-far supplied-p)
  99                      (when (> (length (the list spec)) 3)
 100                        (compiler-error
 101                         "The list ~S is too long to be an arg specifier."
 102                         spec)))))))
 103
 104         (dolist (name required)
 105           (let ((var (varify-lambda-arg name (names-so-far))))
 106             (vars var)
 107             (names-so-far name)))
 108
 109         (dolist (spec optional)
 110           (if (atom spec)
 111               (let ((var (varify-lambda-arg spec (names-so-far))))
 112                 (setf (lambda-var-arg-info var)
 113                       (make-arg-info :kind :optional))
 114                 (vars var)
 115                 (names-so-far spec))
 116               (let* ((name (first spec))
 117                      (var (varify-lambda-arg name (names-so-far)))
 118                      (info (make-arg-info :kind :optional)))
 119                 (setf (lambda-var-arg-info var) info)
 120                 (vars var)
 121                 (names-so-far name)
 122                 (parse-default spec info))))
 123
 124         (when restp
 125           (let ((var (varify-lambda-arg rest (names-so-far))))
 126             (setf (lambda-var-arg-info var) (make-arg-info :kind :rest))
 127             (vars var)
 128             (names-so-far rest)))
 129
 130         (when morep
 131           (let ((var (varify-lambda-arg more-context (names-so-far))))
 132             (setf (lambda-var-arg-info var)
 133                   (make-arg-info :kind :more-context))
 134             (vars var)
 135             (names-so-far more-context))
 136           (let ((var (varify-lambda-arg more-count (names-so-far))))
 137             (setf (lambda-var-arg-info var)
 138                   (make-arg-info :kind :more-count))
 139             (vars var)
 140             (names-so-far more-count)))
 141
 142         (dolist (spec keys)
 143           (cond
 144            ((atom spec)
 145             (let ((var (varify-lambda-arg spec (names-so-far))))
 146               (setf (lambda-var-arg-info var)
 147                     (make-arg-info :kind :keyword
 148                                    :key (make-keyword-for-arg spec
 149                                                               (vars)
 150                                                               t)))
 151               (vars var)
 152               (names-so-far spec)))
 153            ((atom (first spec))
 154             (let* ((name (first spec))
 155                    (var (varify-lambda-arg name (names-so-far)))
 156                    (info (make-arg-info
 157                           :kind :keyword
 158                           :key (make-keyword-for-arg name (vars) t))))
 159               (setf (lambda-var-arg-info var) info)
 160               (vars var)
 161               (names-so-far name)
 162               (parse-default spec info)))
 163            (t
 164             (let ((head (first spec)))
 165               (unless (proper-list-of-length-p head 2)
 166                 (error "malformed &KEY argument specifier: ~S" spec))
 167               (let* ((name (second head))
 168                      (var (varify-lambda-arg name (names-so-far)))
 169                      (info (make-arg-info
 170                             :kind :keyword
 171                             :key (make-keyword-for-arg (first head)
 172                                                        (vars)
 173                                                        nil))))
 174                 (setf (lambda-var-arg-info var) info)
 175                 (vars var)
 176                 (names-so-far name)
 177                 (parse-default spec info))))))
 178
 179         (dolist (spec aux)
 180           (cond ((atom spec)
 181                  (let ((var (varify-lambda-arg spec nil)))
 182                    (aux-vars var)
 183                    (aux-vals nil)
 184                    (names-so-far spec)))
 185                 (t
 186                  (unless (proper-list-of-length-p spec 1 2)
 187                    (compiler-error "malformed &AUX binding specifier: ~S"
 188                                    spec))
 189                  (let* ((name (first spec))
 190                         (var (varify-lambda-arg name nil)))
 191                    (aux-vars var)
 192                    (aux-vals (second spec))
 193                    (names-so-far name)))))
 194
 195         (values (vars) keyp allowp (aux-vars) (aux-vals))))))
 196
 197 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that we
 198 ;;; sequentially bind each AUX-VAR to the corresponding AUX-VAL before
 199 ;;; converting the body. If there are no bindings, just convert the
 200 ;;; body, otherwise do one binding and recurse on the rest.
 201 ;;;
 202 ;;; FIXME: This could and probably should be converted to use
 203 ;;; SOURCE-NAME and DEBUG-NAME. But I (WHN) don't use &AUX bindings,
 204 ;;; so I'm not motivated. Patches will be accepted...
 205 (defun ir1-convert-aux-bindings (start next result body aux-vars aux-vals
 206                                  post-binding-lexenv)
 207   (declare (type ctran start next) (type (or lvar null) result)
 208            (list body aux-vars aux-vals))
 209   (if (null aux-vars)
 210       (let ((*lexenv* (make-lexenv :vars (copy-list post-binding-lexenv))))
 211         (ir1-convert-progn-body start next result body))
 212       (let ((ctran (make-ctran))
 213             (fun-lvar (make-lvar))
 214             (fun (ir1-convert-lambda-body body
 215                                           (list (first aux-vars))
 216                                           :aux-vars (rest aux-vars)
 217                                           :aux-vals (rest aux-vals)
 218                                           :post-binding-lexenv post-binding-lexenv
 219                                           :debug-name (debug-name
 220                                                        '&aux-bindings
 221                                                        aux-vars))))
 222         (reference-leaf start ctran fun-lvar fun)
 223         (ir1-convert-combination-args fun-lvar ctran next result
 224                                       (list (first aux-vals)))))
 225   (values))
 226
 227 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that code to bind
 228 ;;; the SPECVAR for each SVAR to the value of the variable is wrapped
 229 ;;; around the body. If there are no special bindings, we just convert
 230 ;;; the body, otherwise we do one special binding and recurse on the
 231 ;;; rest.
 232 ;;;
 233 ;;; We make a cleanup and introduce it into the lexical
 234 ;;; environment. If there are multiple special bindings, the cleanup
 235 ;;; for the blocks will end up being the innermost one. We force NEXT
 236 ;;; to start a block outside of this cleanup, causing cleanup code to
 237 ;;; be emitted when the scope is exited.
 238 (defun ir1-convert-special-bindings
 239     (start next result body aux-vars aux-vals svars post-binding-lexenv)
 240   (declare (type ctran start next) (type (or lvar null) result)
 241            (list body aux-vars aux-vals svars))
 242   (cond
 243    ((null svars)
 244     (ir1-convert-aux-bindings start next result body aux-vars aux-vals
 245                               post-binding-lexenv))
 246    (t
 247     (ctran-starts-block next)
 248     (let ((cleanup (make-cleanup :kind :special-bind))
 249           (var (first svars))
 250           (bind-ctran (make-ctran))
 251           (cleanup-ctran (make-ctran)))
 252       (ir1-convert start bind-ctran nil
 253                    `(%special-bind ',(lambda-var-specvar var) ,var))
 254       (setf (cleanup-mess-up cleanup) (ctran-use bind-ctran))
 255       (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 256         (ir1-convert bind-ctran cleanup-ctran nil '(%cleanup-point))
 257         (ir1-convert-special-bindings cleanup-ctran next result
 258                                       body aux-vars aux-vals
 259                                       (rest svars)
 260                                       post-binding-lexenv)))))
 261   (values))
 262
 263 ;;; Create a lambda node out of some code, returning the result. The
 264 ;;; bindings are specified by the list of VAR structures VARS. We deal
 265 ;;; with adding the names to the LEXENV-VARS for the conversion. The
 266 ;;; result is added to the NEW-FUNCTIONALS in the *CURRENT-COMPONENT*
 267 ;;; and linked to the component head and tail.
 268 ;;;
 269 ;;; We detect special bindings here, replacing the original VAR in the
 270 ;;; lambda list with a temporary variable. We then pass a list of the
 271 ;;; special vars to IR1-CONVERT-SPECIAL-BINDINGS, which actually emits
 272 ;;; the special binding code.
 273 ;;;
 274 ;;; We ignore any ARG-INFO in the VARS, trusting that someone else is
 275 ;;; dealing with &NONSENSE, except for &REST vars with DYNAMIC-EXTENT.
 276 ;;;
 277 ;;; AUX-VARS is a list of VAR structures for variables that are to be
 278 ;;; sequentially bound. Each AUX-VAL is a form that is to be evaluated
 279 ;;; to get the initial value for the corresponding AUX-VAR.
 280 (defun ir1-convert-lambda-body (body
 281                                 vars
 282                                 &key
 283                                 aux-vars
 284                                 aux-vals
 285                                 (source-name '.anonymous.)
 286                                 debug-name
 287                                 (note-lexical-bindings t)
 288                                 post-binding-lexenv)
 289   (declare (list body vars aux-vars aux-vals))
 290
 291   ;; We're about to try to put new blocks into *CURRENT-COMPONENT*.
 292   (aver-live-component *current-component*)
 293
 294   (let* ((bind (make-bind))
 295          (lambda (make-lambda :vars vars
 296                   :bind bind
 297                   :%source-name source-name
 298                   :%debug-name debug-name))
 299          (result-ctran (make-ctran))
 300          (result-lvar (make-lvar)))
 301
 302     (awhen (lexenv-lambda *lexenv*)
 303       (push lambda (lambda-children it))
 304       (setf (lambda-parent lambda) it))
 305
 306     ;; just to check: This function should fail internal assertions if
 307     ;; we didn't set up a valid debug name above.
 308     ;;
 309     ;; (In SBCL we try to make everything have a debug name, since we
 310     ;; lack the omniscient perspective the original implementors used
 311     ;; to decide which things didn't need one.)
 312     (functional-debug-name lambda)
 313
 314     (setf (lambda-home lambda) lambda)
 315     (collect ((svars)
 316               (new-venv nil cons))
 317
 318       (dolist (var vars)
 319         ;; As far as I can see, LAMBDA-VAR-HOME should never have
 320         ;; been set before. Let's make sure. -- WHN 2001-09-29
 321         (aver (not (lambda-var-home var)))
 322         (setf (lambda-var-home var) lambda)
 323         (let ((specvar (lambda-var-specvar var)))
 324           (cond (specvar
 325                  (svars var)
 326                  (new-venv (cons (leaf-source-name specvar) specvar)))
 327                 (t
 328                  (when note-lexical-bindings
 329                    (note-lexical-binding (leaf-source-name var)))
 330                  (new-venv (cons (leaf-source-name var) var))))))
 331
 332       (let ((*lexenv* (make-lexenv :vars (new-venv)
 333                                    :lambda lambda
 334                                    :cleanup nil)))
 335         (setf (bind-lambda bind) lambda)
 336         (setf (node-lexenv bind) *lexenv*)
 337
 338         (let ((block (ctran-starts-block result-ctran)))
 339           (let ((return (make-return :result result-lvar :lambda lambda))
 340                 (tail-set (make-tail-set :funs (list lambda))))
 341             (setf (lambda-tail-set lambda) tail-set)
 342             (setf (lambda-return lambda) return)
 343             (setf (lvar-dest result-lvar) return)
 344             (link-node-to-previous-ctran return result-ctran)
 345             (setf (block-last block) return))
 346           (link-blocks block (component-tail *current-component*)))
 347
 348         (with-component-last-block (*current-component*
 349                                     (ctran-block result-ctran))
 350           (let ((prebind-ctran (make-ctran))
 351                 (postbind-ctran (make-ctran)))
 352             (ctran-starts-block prebind-ctran)
 353             (link-node-to-previous-ctran bind prebind-ctran)
 354             (use-ctran bind postbind-ctran)
 355             (ir1-convert-special-bindings postbind-ctran result-ctran
 356                                           result-lvar body
 357                                           aux-vars aux-vals (svars)
 358                                           post-binding-lexenv)))))
 359
 360     (link-blocks (component-head *current-component*) (node-block bind))
 361     (push lambda (component-new-functionals *current-component*))
 362
 363     lambda))
 364
 365 ;;; Entry point CLAMBDAs have a special kind
 366 (defun register-entry-point (entry dispatcher)
 367   (declare (type clambda entry)
 368            (type optional-dispatch dispatcher))
 369   (setf (functional-kind entry) :optional)
 370   (setf (leaf-ever-used entry) t)
 371   (setf (lambda-optional-dispatch entry) dispatcher)
 372   entry)
 373
 374 ;;; Create the actual entry-point function for an optional entry
 375 ;;; point. The lambda binds copies of each of the VARS, then calls FUN
 376 ;;; with the argument VALS and the DEFAULTS. Presumably the VALS refer
 377 ;;; to the VARS by name. The VALS are passed in the reverse order.
 378 ;;;
 379 ;;; If any of the copies of the vars are referenced more than once,
 380 ;;; then we mark the corresponding var as EVER-USED to inhibit
 381 ;;; "defined but not read" warnings for arguments that are only used
 382 ;;; by default forms.
 383 (defun convert-optional-entry (fun vars vals defaults name)
 384   (declare (type clambda fun) (list vars vals defaults))
 385   (let* ((fvars (reverse vars))
 386          (arg-vars (mapcar (lambda (var)
 387                              (make-lambda-var
 388                               :%source-name (leaf-source-name var)
 389                               :type (leaf-type var)
 390                               :where-from (leaf-where-from var)
 391                               :specvar (lambda-var-specvar var)))
 392                            fvars))
 393          (fun (collect ((default-bindings)
 394                         (default-vals))
 395                 (dolist (default defaults)
 396                   (if (constantp default)
 397                       (default-vals default)
 398                       (let ((var (gensym)))
 399                         (default-bindings `(,var ,default))
 400                         (default-vals var))))
 401                 (ir1-convert-lambda-body `((let (,@(default-bindings))
 402                                              (%funcall ,fun
 403                                                        ,@(reverse vals)
 404                                                        ,@(default-vals))))
 405                                          arg-vars
 406                                          ;; FIXME: Would be nice to
 407                                          ;; share these names instead
 408                                          ;; of consing up several
 409                                          ;; identical ones. Oh well.
 410                                          :debug-name (debug-name
 411                                                       '&optional-processor
 412                                                       name)
 413                                          :note-lexical-bindings nil))))
 414     (mapc (lambda (var arg-var)
 415             (when (cdr (leaf-refs arg-var))
 416               (setf (leaf-ever-used var) t)))
 417           fvars arg-vars)
 418     fun))
 419
 420 ;;; This function deals with supplied-p vars in optional arguments. If
 421 ;;; the there is no supplied-p arg, then we just call
 422 ;;; IR1-CONVERT-HAIRY-ARGS on the remaining arguments, and generate a
 423 ;;; optional entry that calls the result. If there is a supplied-p
 424 ;;; var, then we add it into the default vars and throw a T into the
 425 ;;; entry values. The resulting entry point function is returned.
 426 (defun generate-optional-default-entry (res default-vars default-vals
 427                                         entry-vars entry-vals
 428                                         vars supplied-p-p body
 429                                         aux-vars aux-vals
 430                                         source-name debug-name
 431                                         force post-binding-lexenv)
 432   (declare (type optional-dispatch res)
 433            (list default-vars default-vals entry-vars entry-vals vars body
 434                  aux-vars aux-vals))
 435   (let* ((arg (first vars))
 436          (arg-name (leaf-source-name arg))
 437          (info (lambda-var-arg-info arg))
 438          (default (arg-info-default info))
 439          (supplied-p (arg-info-supplied-p info))
 440          (force (or force
 441                     (not (sb!xc:constantp (arg-info-default info)))))
 442          (ep (if supplied-p
 443                  (ir1-convert-hairy-args
 444                   res
 445                   (list* supplied-p arg default-vars)
 446                   (list* (leaf-source-name supplied-p) arg-name default-vals)
 447                   (cons arg entry-vars)
 448                   (list* t arg-name entry-vals)
 449                   (rest vars) t body aux-vars aux-vals
 450                   source-name debug-name
 451                   force post-binding-lexenv)
 452                  (ir1-convert-hairy-args
 453                   res
 454                   (cons arg default-vars)
 455                   (cons arg-name default-vals)
 456                   (cons arg entry-vars)
 457                   (cons arg-name entry-vals)
 458                   (rest vars) supplied-p-p body aux-vars aux-vals
 459                   source-name debug-name
 460                   force post-binding-lexenv))))
 461
 462     ;; We want to delay converting the entry, but there exist
 463     ;; problems: hidden references should not be established to
 464     ;; lambdas of kind NIL should not have (otherwise the compiler
 465     ;; might let-convert or delete them) and to variables.
 466     (let ((name (or debug-name source-name))
 467           (defaults (if supplied-p (list default nil) (list default))))
 468       (if (or force
 469               supplied-p-p ; this entry will be of kind NIL
 470               (and (lambda-p ep) (eq (lambda-kind ep) nil)))
 471           (convert-optional-entry ep
 472                                   default-vars default-vals
 473                                   defaults
 474                                   name)
 475           (delay
 476            (register-entry-point
 477             (convert-optional-entry (force ep)
 478                                     default-vars default-vals
 479                                     defaults
 480                                     name)
 481             res))))))
 482
 483 ;;; Create the MORE-ENTRY function for the OPTIONAL-DISPATCH RES.
 484 ;;; ENTRY-VARS and ENTRY-VALS describe the fixed arguments. REST is
 485 ;;; the var for any &REST arg. KEYS is a list of the &KEY arg vars.
 486 ;;;
 487 ;;; The most interesting thing that we do is parse keywords. We create
 488 ;;; a bunch of temporary variables to hold the result of the parse,
 489 ;;; and then loop over the supplied arguments, setting the appropriate
 490 ;;; temps for the supplied keyword. Note that it is significant that
 491 ;;; we iterate over the keywords in reverse order --- this implements
 492 ;;; the CL requirement that (when a keyword appears more than once)
 493 ;;; the first value is used.
 494 ;;;
 495 ;;; If there is no supplied-p var, then we initialize the temp to the
 496 ;;; default and just pass the temp into the main entry. Since
 497 ;;; non-constant &KEY args are forcibly given a supplied-p var, we
 498 ;;; know that the default is constant, and thus safe to evaluate out
 499 ;;; of order.
 500 ;;;
 501 ;;; If there is a supplied-p var, then we create temps for both the
 502 ;;; value and the supplied-p, and pass them into the main entry,
 503 ;;; letting it worry about defaulting.
 504 ;;;
 505 ;;; We deal with :ALLOW-OTHER-KEYS by delaying unknown keyword errors
 506 ;;; until we have scanned all the keywords.
 507 (defun convert-more-entry (res entry-vars entry-vals rest morep keys name)
 508   (declare (type optional-dispatch res) (list entry-vars entry-vals keys))
 509   (collect ((arg-vars)
 510             (arg-vals (reverse entry-vals))
 511             (temps)
 512             (body))
 513
 514     (dolist (var (reverse entry-vars))
 515       (arg-vars (make-lambda-var :%source-name (leaf-source-name var)
 516                                  :type (leaf-type var)
 517                                  :where-from (leaf-where-from var))))
 518
 519     (let* ((*allow-instrumenting* nil)
 520            (n-context (gensym "N-CONTEXT-"))
 521            (context-temp (make-lambda-var :%source-name n-context))
 522            (n-count (gensym "N-COUNT-"))
 523            (count-temp (make-lambda-var :%source-name n-count
 524                                         :type (specifier-type 'index))))
 525
 526       (arg-vars context-temp count-temp)
 527
 528       (when rest
 529         (arg-vals `(%listify-rest-args
 530                     ,n-context ,n-count)))
 531       (when morep
 532         (arg-vals n-context)
 533         (arg-vals n-count))
 534
 535       (when (optional-dispatch-keyp res)
 536         (let ((n-index (gensym "N-INDEX-"))
 537               (n-key (gensym "N-KEY-"))
 538               (n-value-temp (gensym "N-VALUE-TEMP-"))
 539               (n-allowp (gensym "N-ALLOWP-"))
 540               (n-losep (gensym "N-LOSEP-"))
 541               (allowp (or (optional-dispatch-allowp res)
 542                           (policy *lexenv* (zerop safety))))
 543               (found-allow-p nil))
 544
 545           (temps `(,n-index (1- ,n-count)) n-key n-value-temp)
 546           (body `(declare (fixnum ,n-index) (ignorable ,n-key ,n-value-temp)))
 547
 548           (collect ((tests))
 549             (dolist (key keys)
 550               (let* ((info (lambda-var-arg-info key))
 551                      (default (arg-info-default info))
 552                      (keyword (arg-info-key info))
 553                      (supplied-p (arg-info-supplied-p info))
 554                      (n-value (gensym "N-VALUE-"))
 555                      (clause (cond (supplied-p
 556                                     (let ((n-supplied (gensym "N-SUPPLIED-")))
 557                                       (temps n-supplied)
 558                                       (arg-vals n-value n-supplied)
 559                                       `((eq ,n-key ',keyword)
 560                                         (setq ,n-supplied t)
 561                                         (setq ,n-value ,n-value-temp))))
 562                                    (t
 563                                     (arg-vals n-value)
 564                                     `((eq ,n-key ',keyword)
 565                                       (setq ,n-value ,n-value-temp))))))
 566                 (when (and (not allowp) (eq keyword :allow-other-keys))
 567                   (setq found-allow-p t)
 568                   (setq clause
 569                         (append clause `((setq ,n-allowp ,n-value-temp)))))
 570
 571                 (temps `(,n-value ,default))
 572                 (tests clause)))
 573
 574             (unless allowp
 575               (temps n-allowp n-losep)
 576               (unless found-allow-p
 577                 (tests `((eq ,n-key :allow-other-keys)
 578                          (setq ,n-allowp ,n-value-temp))))
 579               (tests `(t
 580                        (setq ,n-losep (list ,n-key)))))
 581
 582             (body
 583              `(when (oddp ,n-count)
 584                 (%odd-key-args-error)))
 585
 586             (body
 587              `(locally
 588                 (declare (optimize (safety 0)))
 589                 (loop
 590                   (when (minusp ,n-index) (return))
 591                   (setf ,n-value-temp (%more-arg ,n-context ,n-index))
 592                   (decf ,n-index)
 593                   (setq ,n-key (%more-arg ,n-context ,n-index))
 594                   (decf ,n-index)
 595                   (cond ,@(tests)))))
 596
 597             (unless allowp
 598               (body `(when (and ,n-losep (not ,n-allowp))
 599                        (%unknown-key-arg-error (car ,n-losep))))))))
 600
 601       (let ((ep (ir1-convert-lambda-body
 602                  `((let ,(temps)
 603                      ,@(body)
 604                      (%funcall ,(optional-dispatch-main-entry res)
 605                                ,@(arg-vals))))
 606                  (arg-vars)
 607                  :debug-name (debug-name '&more-processor name)
 608                  :note-lexical-bindings nil)))
 609         (setf (optional-dispatch-more-entry res)
 610               (register-entry-point ep res)))))
 611
 612   (values))
 613
 614 ;;; This is called by IR1-CONVERT-HAIRY-ARGS when we run into a &REST
 615 ;;; or &KEY arg. The arguments are similar to that function, but we
 616 ;;; split off any &REST arg and pass it in separately. REST is the
 617 ;;; &REST arg var, or NIL if there is no &REST arg. KEYS is a list of
 618 ;;; the &KEY argument vars.
 619 ;;;
 620 ;;; When there are &KEY arguments, we introduce temporary gensym
 621 ;;; variables to hold the values while keyword defaulting is in
 622 ;;; progress to get the required sequential binding semantics.
 623 ;;;
 624 ;;; This gets interesting mainly when there are &KEY arguments with
 625 ;;; supplied-p vars or non-constant defaults. In either case, pass in
 626 ;;; a supplied-p var. If the default is non-constant, we introduce an
 627 ;;; IF in the main entry that tests the supplied-p var and decides
 628 ;;; whether to evaluate the default or not. In this case, the real
 629 ;;; incoming value is NIL, so we must union NULL with the declared
 630 ;;; type when computing the type for the main entry's argument.
 631 (defun ir1-convert-more (res default-vars default-vals entry-vars entry-vals
 632                              rest more-context more-count keys supplied-p-p
 633                              body aux-vars aux-vals
 634                              source-name debug-name post-binding-lexenv)
 635   (declare (type optional-dispatch res)
 636            (list default-vars default-vals entry-vars entry-vals keys body
 637                  aux-vars aux-vals))
 638   (collect ((main-vars (reverse default-vars))
 639             (main-vals default-vals cons)
 640             (bind-vars)
 641             (bind-vals))
 642     (when rest
 643       (main-vars rest)
 644       (main-vals '()))
 645     (when more-context
 646       (main-vars more-context)
 647       (main-vals nil)
 648       (main-vars more-count)
 649       (main-vals 0))
 650
 651     (dolist (key keys)
 652       (let* ((info (lambda-var-arg-info key))
 653              (default (arg-info-default info))
 654              (hairy-default (not (sb!xc:constantp default)))
 655              (supplied-p (arg-info-supplied-p info))
 656              (n-val (make-symbol (format nil
 657                                          "~A-DEFAULTING-TEMP"
 658                                          (leaf-source-name key))))
 659              (key-type (leaf-type key))
 660              (val-temp (make-lambda-var
 661                         :%source-name n-val
 662                         :type (if hairy-default
 663                                   (type-union key-type (specifier-type 'null))
 664                                   key-type))))
 665         (main-vars val-temp)
 666         (bind-vars key)
 667         (cond ((or hairy-default supplied-p)
 668                (let* ((n-supplied (gensym "N-SUPPLIED-"))
 669                       (supplied-temp (make-lambda-var
 670                                       :%source-name n-supplied)))
 671                  (unless supplied-p
 672                    (setf (arg-info-supplied-p info) supplied-temp))
 673                  (when hairy-default
 674                    (setf (arg-info-default info) nil))
 675                  (main-vars supplied-temp)
 676                  (cond (hairy-default
 677                         (main-vals nil nil)
 678                         (bind-vals `(if ,n-supplied ,n-val ,default)))
 679                        (t
 680                         (main-vals default nil)
 681                         (bind-vals n-val)))
 682                  (when supplied-p
 683                    (bind-vars supplied-p)
 684                    (bind-vals n-supplied))))
 685               (t
 686                (main-vals (arg-info-default info))
 687                (bind-vals n-val)))))
 688
 689     (let* ((name (or debug-name source-name))
 690            (main-entry (ir1-convert-lambda-body
 691                         body (main-vars)
 692                         :aux-vars (append (bind-vars) aux-vars)
 693                         :aux-vals (append (bind-vals) aux-vals)
 694                         :post-binding-lexenv post-binding-lexenv
 695                         :debug-name (debug-name 'varargs-entry name)))
 696            (last-entry (convert-optional-entry main-entry default-vars
 697                                                (main-vals) () name)))
 698       (setf (optional-dispatch-main-entry res)
 699             (register-entry-point main-entry res))
 700       (convert-more-entry res entry-vars entry-vals rest more-context keys
 701                           name)
 702
 703       (push (register-entry-point
 704              (if supplied-p-p
 705                 (convert-optional-entry last-entry entry-vars entry-vals
 706                                         () name)
 707                 last-entry)
 708              res)
 709             (optional-dispatch-entry-points res))
 710       last-entry)))
 711
 712 ;;; This function generates the entry point functions for the
 713 ;;; OPTIONAL-DISPATCH RES. We accomplish this by recursion on the list
 714 ;;; of arguments, analyzing the arglist on the way down and generating
 715 ;;; entry points on the way up.
 716 ;;;
 717 ;;; DEFAULT-VARS is a reversed list of all the argument vars processed
 718 ;;; so far, including supplied-p vars. DEFAULT-VALS is a list of the
 719 ;;; names of the DEFAULT-VARS.
 720 ;;;
 721 ;;; ENTRY-VARS is a reversed list of processed argument vars,
 722 ;;; excluding supplied-p vars. ENTRY-VALS is a list things that can be
 723 ;;; evaluated to get the values for all the vars from the ENTRY-VARS.
 724 ;;; It has the var name for each required or optional arg, and has T
 725 ;;; for each supplied-p arg.
 726 ;;;
 727 ;;; VARS is a list of the LAMBDA-VAR structures for arguments that
 728 ;;; haven't been processed yet. SUPPLIED-P-P is true if a supplied-p
 729 ;;; argument has already been processed; only in this case are the
 730 ;;; DEFAULT-XXX and ENTRY-XXX different.
 731 ;;;
 732 ;;; The result at each point is a lambda which should be called by the
 733 ;;; above level to default the remaining arguments and evaluate the
 734 ;;; body. We cause the body to be evaluated by converting it and
 735 ;;; returning it as the result when the recursion bottoms out.
 736 ;;;
 737 ;;; Each level in the recursion also adds its entry point function to
 738 ;;; the result OPTIONAL-DISPATCH. For most arguments, the defaulting
 739 ;;; function and the entry point function will be the same, but when
 740 ;;; SUPPLIED-P args are present they may be different.
 741 ;;;
 742 ;;; When we run into a &REST or &KEY arg, we punt out to
 743 ;;; IR1-CONVERT-MORE, which finishes for us in this case.
 744 (defun ir1-convert-hairy-args (res default-vars default-vals
 745                                entry-vars entry-vals
 746                                vars supplied-p-p body aux-vars
 747                                aux-vals
 748                                source-name debug-name
 749                                force post-binding-lexenv)
 750   (declare (type optional-dispatch res)
 751            (list default-vars default-vals entry-vars entry-vals vars body
 752                  aux-vars aux-vals))
 753   (cond ((not vars)
 754          (if (optional-dispatch-keyp res)
 755              ;; Handle &KEY with no keys...
 756              (ir1-convert-more res default-vars default-vals
 757                                entry-vars entry-vals
 758                                nil nil nil vars supplied-p-p body aux-vars
 759                                aux-vals source-name debug-name
 760                                post-binding-lexenv)
 761              (let* ((name (or debug-name source-name))
 762                     (fun (ir1-convert-lambda-body
 763                          body (reverse default-vars)
 764                          :aux-vars aux-vars
 765                          :aux-vals aux-vals
 766                          :post-binding-lexenv post-binding-lexenv
 767                          :debug-name (debug-name 'hairy-arg-processor name))))
 768
 769                (setf (optional-dispatch-main-entry res) fun)
 770                (register-entry-point fun res)
 771                (push (if supplied-p-p
 772                          (register-entry-point
 773                           (convert-optional-entry fun entry-vars entry-vals ()
 774                                                   name)
 775                           res)
 776                           fun)
 777                      (optional-dispatch-entry-points res))
 778                fun)))
 779         ((not (lambda-var-arg-info (first vars)))
 780          (let* ((arg (first vars))
 781                 (nvars (cons arg default-vars))
 782                 (nvals (cons (leaf-source-name arg) default-vals)))
 783            (ir1-convert-hairy-args res nvars nvals nvars nvals
 784                                    (rest vars) nil body aux-vars aux-vals
 785                                    source-name debug-name
 786                                    nil post-binding-lexenv)))
 787         (t
 788          (let* ((arg (first vars))
 789                 (info (lambda-var-arg-info arg))
 790                 (kind (arg-info-kind info)))
 791            (ecase kind
 792              (:optional
 793               (let ((ep (generate-optional-default-entry
 794                          res default-vars default-vals
 795                          entry-vars entry-vals vars supplied-p-p body
 796                          aux-vars aux-vals
 797                          source-name debug-name
 798                          force post-binding-lexenv)))
 799                 ;; See GENERATE-OPTIONAL-DEFAULT-ENTRY.
 800                 (push (if (lambda-p ep)
 801                           (register-entry-point
 802                            (if supplied-p-p
 803                                (convert-optional-entry
 804                                 ep entry-vars entry-vals nil
 805                                 (or debug-name source-name))
 806                                ep)
 807                            res)
 808                           (progn (aver (not supplied-p-p))
 809                                  ep))
 810                       (optional-dispatch-entry-points res))
 811                 ep))
 812              (:rest
 813               (ir1-convert-more res default-vars default-vals
 814                                 entry-vars entry-vals
 815                                 arg nil nil (rest vars) supplied-p-p body
 816                                 aux-vars aux-vals
 817                                 source-name debug-name
 818                                 post-binding-lexenv))
 819              (:more-context
 820               (ir1-convert-more res default-vars default-vals
 821                                 entry-vars entry-vals
 822                                 nil arg (second vars) (cddr vars) supplied-p-p
 823                                 body aux-vars aux-vals
 824                                 source-name debug-name
 825                                 post-binding-lexenv))
 826              (:keyword
 827               (ir1-convert-more res default-vars default-vals
 828                                 entry-vars entry-vals
 829                                 nil nil nil vars supplied-p-p body aux-vars
 830                                 aux-vals source-name debug-name
 831                                 post-binding-lexenv)))))))
 832
 833 ;;; This function deals with the case where we have to make an
 834 ;;; OPTIONAL-DISPATCH to represent a LAMBDA. We cons up the result and
 835 ;;; call IR1-CONVERT-HAIRY-ARGS to do the work. When it is done, we
 836 ;;; figure out the MIN-ARGS and MAX-ARGS.
 837 (defun ir1-convert-hairy-lambda (body vars keyp allowp aux-vars aux-vals
 838                                       &key
 839                                       post-binding-lexenv
 840                                       (source-name '.anonymous.)
 841                                       (debug-name
 842                                        (debug-name '&optional-dispatch vars)))
 843   (declare (list body vars aux-vars aux-vals))
 844   (let ((res (make-optional-dispatch :arglist vars
 845                                      :allowp allowp
 846                                      :keyp keyp
 847                                      :%source-name source-name
 848                                      :%debug-name debug-name
 849                                      :plist `(:ir1-environment
 850                                               (,*lexenv*
 851                                                ,*current-path*))))
 852         (min (or (position-if #'lambda-var-arg-info vars) (length vars))))
 853     (aver-live-component *current-component*)
 854     (push res (component-new-functionals *current-component*))
 855     (ir1-convert-hairy-args res () () () () vars nil body aux-vars aux-vals
 856                             source-name debug-name nil post-binding-lexenv)
 857     (setf (optional-dispatch-min-args res) min)
 858     (setf (optional-dispatch-max-args res)
 859           (+ (1- (length (optional-dispatch-entry-points res))) min))
 860
 861     res))
 862
 863 ;;; Convert a LAMBDA form into a LAMBDA leaf or an OPTIONAL-DISPATCH leaf.
 864 (defun ir1-convert-lambda (form &key (source-name '.anonymous.)
 865                            debug-name)
 866   (unless (consp form)
 867     (compiler-error "A ~S was found when expecting a lambda expression:~%  ~S"
 868                     (type-of form)
 869                     form))
 870   (unless (eq (car form) 'lambda)
 871     (compiler-error "~S was expected but ~S was found:~%  ~S"
 872                     'lambda
 873                     (car form)
 874                     form))
 875   (unless (and (consp (cdr form)) (listp (cadr form)))
 876     (compiler-error
 877      "The lambda expression has a missing or non-list lambda list:~%  ~S"
 878      form))
 879
 880   (multiple-value-bind (vars keyp allow-other-keys aux-vars aux-vals)
 881       (make-lambda-vars (cadr form))
 882     (multiple-value-bind (forms decls) (parse-body (cddr form))
 883       (binding* (((*lexenv* result-type post-binding-lexenv)
 884                   (process-decls decls (append aux-vars vars) nil
 885                                  :binding-form-p t))
 886                  (forms (if (and *allow-instrumenting*
 887                                  (policy *lexenv* (>= insert-debug-catch 2)))
 888                             `((catch (locally
 889                                          (declare (optimize (insert-step-conditions 0)))
 890                                        ;; Using MAKE-SYMBOL would lead
 891                                        ;; to recursive disaster.
 892                                        (%make-symbol "SB-DEBUG-CATCH-TAG"))
 893                                 ,@forms))
 894                             forms))
 895                  (forms (if (eq result-type *wild-type*)
 896                             forms
 897                             `((the ,result-type (progn ,@forms)))))
 898                  (res (if (or (find-if #'lambda-var-arg-info vars) keyp)
 899                           (ir1-convert-hairy-lambda forms vars keyp
 900                                                     allow-other-keys
 901                                                     aux-vars aux-vals
 902                                                     :post-binding-lexenv post-binding-lexenv
 903                                                     :source-name source-name
 904                                                     :debug-name debug-name)
 905                           (ir1-convert-lambda-body forms vars
 906                                                    :aux-vars aux-vars
 907                                                    :aux-vals aux-vals
 908                                                    :post-binding-lexenv post-binding-lexenv
 909                                                    :source-name source-name
 910                                                    :debug-name debug-name))))
 911         (setf (functional-inline-expansion res) form)
 912         (setf (functional-arg-documentation res) (cadr form))
 913         res))))
 914
 915 ;;; helper for LAMBDA-like things, to massage them into a form
 916 ;;; suitable for IR1-CONVERT-LAMBDA.
 917 (defun ir1-convert-lambdalike (thing
 918                                &key
 919                                (source-name '.anonymous.)
 920                                debug-name)
 921   (ecase (car thing)
 922     ((lambda)
 923      (ir1-convert-lambda thing
 924                          :source-name source-name
 925                          :debug-name debug-name))
 926     ((instance-lambda)
 927      (deprecation-warning 'instance-lambda 'lambda)
 928      (ir1-convert-lambda `(lambda ,@(cdr thing))
 929                          :source-name source-name
 930                          :debug-name debug-name))
 931     ((named-lambda)
 932      (let ((name (cadr thing))
 933            (lambda-expression `(lambda ,@(cddr thing))))
 934        (if (legal-fun-name-p name)
 935            (let ((defined-fun-res (get-defined-fun name))
 936                  (res (ir1-convert-lambda lambda-expression
 937                                           :source-name name)))
 938              (assert-global-function-definition-type name res)
 939              (setf (defined-fun-functional defined-fun-res) res)
 940              (unless (eq (defined-fun-inlinep defined-fun-res) :notinline)
 941                (substitute-leaf-if
 942                 (lambda (ref)
 943                   (policy ref (> recognize-self-calls 0)))
 944                 res defined-fun-res))
 945              res)
 946            (ir1-convert-lambda lambda-expression :debug-name name))))
 947     ((lambda-with-lexenv)
 948      (ir1-convert-inline-lambda thing
 949                                 :source-name source-name
 950                                 :debug-name debug-name))))
 951 \f
 952 ;;;; defining global functions
 953
 954 ;;; Convert FUN as a lambda in the null environment, but use the
 955 ;;; current compilation policy. Note that FUN may be a
 956 ;;; LAMBDA-WITH-LEXENV, so we may have to augment the environment to
 957 ;;; reflect the state at the definition site.
 958 (defun ir1-convert-inline-lambda (fun &key
 959                                       (source-name '.anonymous.)
 960                                       debug-name)
 961   (destructuring-bind (decls macros symbol-macros &rest body)
 962                       (if (eq (car fun) 'lambda-with-lexenv)
 963                           (cdr fun)
 964                           `(() () () . ,(cdr fun)))
 965     (let ((*lexenv* (make-lexenv
 966                      :default (process-decls decls nil nil
 967                                              :lexenv (make-null-lexenv))
 968                      :vars (copy-list symbol-macros)
 969                      :funs (mapcar (lambda (x)
 970                                      `(,(car x) .
 971                                        (macro . ,(coerce (cdr x) 'function))))
 972                                    macros)
 973                      :policy (lexenv-policy *lexenv*))))
 974       (ir1-convert-lambda `(lambda ,@body)
 975                           :source-name source-name
 976                           :debug-name debug-name))))
 977
 978 ;;; Get a DEFINED-FUN object for a function we are about to define. If
 979 ;;; the function has been forward referenced, then substitute for the
 980 ;;; previous references.
 981 (defun get-defined-fun (name)
 982   (proclaim-as-fun-name name)
 983   (let ((found (find-free-fun name "shouldn't happen! (defined-fun)")))
 984     (note-name-defined name :function)
 985     (cond ((not (defined-fun-p found))
 986            (aver (not (info :function :inlinep name)))
 987            (let* ((where-from (leaf-where-from found))
 988                   (res (make-defined-fun
 989                         :%source-name name
 990                         :where-from (if (eq where-from :declared)
 991                                         :declared :defined)
 992                         :type (leaf-type found))))
 993              (substitute-leaf res found)
 994              (setf (gethash name *free-funs*) res)))
 995           ;; If *FREE-FUNS* has a previously converted definition
 996           ;; for this name, then blow it away and try again.
 997           ((defined-fun-functional found)
 998            (remhash name *free-funs*)
 999            (get-defined-fun name))
1000           (t found))))
1001
1002 ;;; Check a new global function definition for consistency with
1003 ;;; previous declaration or definition, and assert argument/result
1004 ;;; types if appropriate. This assertion is suppressed by the
1005 ;;; EXPLICIT-CHECK attribute, which is specified on functions that
1006 ;;; check their argument types as a consequence of type dispatching.
1007 ;;; This avoids redundant checks such as NUMBERP on the args to +, etc.
1008 (defun assert-new-definition (var fun)
1009   (let ((type (leaf-type var))
1010         (for-real (eq (leaf-where-from var) :declared))
1011         (info (info :function :info (leaf-source-name var))))
1012     (assert-definition-type
1013      fun type
1014      ;; KLUDGE: Common Lisp is such a dynamic language that in general
1015      ;; all we can do here in general is issue a STYLE-WARNING. It
1016      ;; would be nice to issue a full WARNING in the special case of
1017      ;; of type mismatches within a compilation unit (as in section
1018      ;; 3.2.2.3 of the spec) but at least as of sbcl-0.6.11, we don't
1019      ;; keep track of whether the mismatched data came from the same
1020      ;; compilation unit, so we can't do that. -- WHN 2001-02-11
1021      :lossage-fun #'compiler-style-warn
1022      :unwinnage-fun (cond (info #'compiler-style-warn)
1023                           (for-real #'compiler-notify)
1024                           (t nil))
1025      :really-assert
1026      (and for-real
1027           (not (and info
1028                     (ir1-attributep (fun-info-attributes info)
1029                                     explicit-check))))
1030      :where (if for-real
1031                 "previous declaration"
1032                 "previous definition"))))
1033
1034 ;;; Convert a lambda doing all the basic stuff we would do if we were
1035 ;;; converting a DEFUN. In the old CMU CL system, this was used both
1036 ;;; by the %DEFUN translator and for global inline expansion, but
1037 ;;; since sbcl-0.pre7.something %DEFUN does things differently.
1038 ;;; FIXME: And now it's probably worth rethinking whether this
1039 ;;; function is a good idea.
1040 ;;;
1041 ;;; Unless a :INLINE function, we temporarily clobber the inline
1042 ;;; expansion. This prevents recursive inline expansion of
1043 ;;; opportunistic pseudo-inlines.
1044 (defun ir1-convert-lambda-for-defun (lambda var expansion converter)
1045   (declare (cons lambda) (function converter) (type defined-fun var))
1046   (let ((var-expansion (defined-fun-inline-expansion var)))
1047     (unless (eq (defined-fun-inlinep var) :inline)
1048       (setf (defined-fun-inline-expansion var) nil))
1049     (let* ((name (leaf-source-name var))
1050            (fun (funcall converter lambda
1051                          :source-name name))
1052            (fun-info (info :function :info name)))
1053       (setf (functional-inlinep fun) (defined-fun-inlinep var))
1054       (assert-new-definition var fun)
1055       (setf (defined-fun-inline-expansion var) var-expansion)
1056       ;; If definitely not an interpreter stub, then substitute for
1057       ;; any old references.
1058       (unless (or (eq (defined-fun-inlinep var) :notinline)
1059                   (not *block-compile*)
1060                   (and fun-info
1061                        (or (fun-info-transforms fun-info)
1062                            (fun-info-templates fun-info)
1063                            (fun-info-ir2-convert fun-info))))
1064         (substitute-leaf fun var)
1065         ;; If in a simple environment, then we can allow backward
1066         ;; references to this function from following top level forms.
1067         (when expansion (setf (defined-fun-functional var) fun)))
1068       fun)))
1069
1070 ;;; the even-at-compile-time part of DEFUN
1071 ;;;
1072 ;;; The INLINE-EXPANSION is a LAMBDA-WITH-LEXENV, or NIL if there is
1073 ;;; no inline expansion.
1074 (defun %compiler-defun (name lambda-with-lexenv compile-toplevel)
1075   (let ((defined-fun nil)) ; will be set below if we're in the compiler
1076     (when compile-toplevel
1077       ;; better be in the compiler
1078       (aver (boundp '*lexenv*))
1079       (remhash name *free-funs*)
1080       (setf defined-fun (get-defined-fun name))
1081       (aver (fasl-output-p *compile-object*))
1082       (if (member name *fun-names-in-this-file* :test #'equal)
1083           (warn 'duplicate-definition :name name)
1084           (push name *fun-names-in-this-file*)))
1085
1086     (become-defined-fun-name name)
1087
1088     (cond (lambda-with-lexenv
1089            (setf (info :function :inline-expansion-designator name)
1090                  lambda-with-lexenv)
1091            (when defined-fun
1092              (setf (defined-fun-inline-expansion defined-fun)
1093                    lambda-with-lexenv)))
1094           (t
1095            (clear-info :function :inline-expansion-designator name)))
1096
1097     ;; old CMU CL comment:
1098     ;;   If there is a type from a previous definition, blast it,
1099     ;;   since it is obsolete.
1100     (when (and defined-fun
1101                (eq (leaf-where-from defined-fun) :defined))
1102       (setf (leaf-type defined-fun)
1103             ;; FIXME: If this is a block compilation thing, shouldn't
1104             ;; we be setting the type to the full derived type for the
1105             ;; definition, instead of this most general function type?
1106             (specifier-type 'function))))
1107
1108   (values))
1109
1110 \f
1111 ;;; Entry point utilities
1112
1113 ;;; Return a function for the Nth entry point.
1114 (defun optional-dispatch-entry-point-fun (dispatcher n)
1115   (declare (type optional-dispatch dispatcher)
1116            (type unsigned-byte n))
1117   (let* ((env (getf (optional-dispatch-plist dispatcher) :ir1-environment))
1118          (*lexenv* (first env))
1119          (*current-path* (second env)))
1120     (force (nth n (optional-dispatch-entry-points dispatcher)))))