src/compiler/ir1tran-lambda.lisp

   1 ;;;; This file contains code which does the translation of lambda
   2 ;;;; forms from Lisp code to the first intermediate representation
   3 ;;;; (IR1).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;;; LAMBDA hackery
  17
  18 ;;;; Note: Take a look at the compiler-overview.tex section on "Hairy
  19 ;;;; function representation" before you seriously mess with this
  20 ;;;; stuff.
  21
  22 ;;; Verify that the NAME is a legal name for a variable and return a
  23 ;;; VAR structure for it, filling in info if it is globally special.
  24 ;;; If it is losing, we punt with a COMPILER-ERROR. NAMES-SO-FAR is a
  25 ;;; list of names which have previously been bound. If the NAME is in
  26 ;;; this list, then we error out.
  27 (declaim (ftype (sfunction (t list) lambda-var) varify-lambda-arg))
  28 (defun varify-lambda-arg (name names-so-far)
  29   (declare (inline member))
  30   (unless (symbolp name)
  31     (compiler-error "The lambda variable ~S is not a symbol." name))
  32   (when (member name names-so-far :test #'eq)
  33     (compiler-error "The variable ~S occurs more than once in the lambda list."
  34                     name))
  35   (let ((kind (info :variable :kind name)))
  36     (when (or (keywordp name) (eq kind :constant))
  37       (compiler-error "The name of the lambda variable ~S is already in use to name a constant."
  38                       name))
  39     (cond ((eq kind :special)
  40            (let ((specvar (find-free-var name)))
  41              (make-lambda-var :%source-name name
  42                               :type (leaf-type specvar)
  43                               :where-from (leaf-where-from specvar)
  44                               :specvar specvar)))
  45           (t
  46            (make-lambda-var :%source-name name)))))
  47
  48 ;;; Make the default keyword for a &KEY arg, checking that the keyword
  49 ;;; isn't already used by one of the VARS.
  50 (declaim (ftype (sfunction (symbol list t) symbol) make-keyword-for-arg))
  51 (defun make-keyword-for-arg (symbol vars keywordify)
  52   (let ((key (if (and keywordify (not (keywordp symbol)))
  53                  (keywordicate symbol)
  54                  symbol)))
  55     (dolist (var vars)
  56       (let ((info (lambda-var-arg-info var)))
  57         (when (and info
  58                    (eq (arg-info-kind info) :keyword)
  59                    (eq (arg-info-key info) key))
  60           (compiler-error
  61            "The keyword ~S appears more than once in the lambda list."
  62            key))))
  63     key))
  64
  65 ;;; Parse a lambda list into a list of VAR structures, stripping off
  66 ;;; any &AUX bindings. Each arg name is checked for legality, and
  67 ;;; duplicate names are checked for. If an arg is globally special,
  68 ;;; the var is marked as :SPECIAL instead of :LEXICAL. &KEY,
  69 ;;; &OPTIONAL and &REST args are annotated with an ARG-INFO structure
  70 ;;; which contains the extra information. If we hit something losing,
  71 ;;; we bug out with COMPILER-ERROR. These values are returned:
  72 ;;;  1. a list of the var structures for each top level argument;
  73 ;;;  2. a flag indicating whether &KEY was specified;
  74 ;;;  3. a flag indicating whether other &KEY args are allowed;
  75 ;;;  4. a list of the &AUX variables; and
  76 ;;;  5. a list of the &AUX values.
  77 (declaim (ftype (sfunction (list) (values list boolean boolean list list))
  78                 make-lambda-vars))
  79 (defun make-lambda-vars (list)
  80   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
  81                         morep more-context more-count)
  82       (parse-lambda-list list)
  83     (declare (ignore auxp)) ; since we just iterate over AUX regardless
  84     (collect ((vars)
  85               (names-so-far)
  86               (aux-vars)
  87               (aux-vals))
  88       (flet (;; PARSE-DEFAULT deals with defaults and supplied-p args
  89              ;; for optionals and keywords args.
  90              (parse-default (spec info)
  91                (when (consp (cdr spec))
  92                  (setf (arg-info-default info) (second spec))
  93                  (when (consp (cddr spec))
  94                    (let* ((supplied-p (third spec))
  95                           (supplied-var (varify-lambda-arg supplied-p
  96                                                            (names-so-far))))
  97                      (setf (arg-info-supplied-p info) supplied-var)
  98                      (names-so-far supplied-p)
  99                      (when (> (length (the list spec)) 3)
 100                        (compiler-error
 101                         "The list ~S is too long to be an arg specifier."
 102                         spec)))))))
 103
 104         (dolist (name required)
 105           (let ((var (varify-lambda-arg name (names-so-far))))
 106             (vars var)
 107             (names-so-far name)))
 108
 109         (dolist (spec optional)
 110           (if (atom spec)
 111               (let ((var (varify-lambda-arg spec (names-so-far))))
 112                 (setf (lambda-var-arg-info var)
 113                       (make-arg-info :kind :optional))
 114                 (vars var)
 115                 (names-so-far spec))
 116               (let* ((name (first spec))
 117                      (var (varify-lambda-arg name (names-so-far)))
 118                      (info (make-arg-info :kind :optional)))
 119                 (setf (lambda-var-arg-info var) info)
 120                 (vars var)
 121                 (names-so-far name)
 122                 (parse-default spec info))))
 123
 124         (when restp
 125           (let ((var (varify-lambda-arg rest (names-so-far))))
 126             (setf (lambda-var-arg-info var) (make-arg-info :kind :rest))
 127             (vars var)
 128             (names-so-far rest)))
 129
 130         (when morep
 131           (let ((var (varify-lambda-arg more-context (names-so-far))))
 132             (setf (lambda-var-arg-info var)
 133                   (make-arg-info :kind :more-context))
 134             (vars var)
 135             (names-so-far more-context))
 136           (let ((var (varify-lambda-arg more-count (names-so-far))))
 137             (setf (lambda-var-arg-info var)
 138                   (make-arg-info :kind :more-count))
 139             (vars var)
 140             (names-so-far more-count)))
 141
 142         (dolist (spec keys)
 143           (cond
 144            ((atom spec)
 145             (let ((var (varify-lambda-arg spec (names-so-far))))
 146               (setf (lambda-var-arg-info var)
 147                     (make-arg-info :kind :keyword
 148                                    :key (make-keyword-for-arg spec
 149                                                               (vars)
 150                                                               t)))
 151               (vars var)
 152               (names-so-far spec)))
 153            ((atom (first spec))
 154             (let* ((name (first spec))
 155                    (var (varify-lambda-arg name (names-so-far)))
 156                    (info (make-arg-info
 157                           :kind :keyword
 158                           :key (make-keyword-for-arg name (vars) t))))
 159               (setf (lambda-var-arg-info var) info)
 160               (vars var)
 161               (names-so-far name)
 162               (parse-default spec info)))
 163            (t
 164             (let ((head (first spec)))
 165               (unless (proper-list-of-length-p head 2)
 166                 (error "malformed &KEY argument specifier: ~S" spec))
 167               (let* ((name (second head))
 168                      (var (varify-lambda-arg name (names-so-far)))
 169                      (info (make-arg-info
 170                             :kind :keyword
 171                             :key (make-keyword-for-arg (first head)
 172                                                        (vars)
 173                                                        nil))))
 174                 (setf (lambda-var-arg-info var) info)
 175                 (vars var)
 176                 (names-so-far name)
 177                 (parse-default spec info))))))
 178
 179         (dolist (spec aux)
 180           (cond ((atom spec)
 181                  (let ((var (varify-lambda-arg spec nil)))
 182                    (aux-vars var)
 183                    (aux-vals nil)
 184                    (names-so-far spec)))
 185                 (t
 186                  (unless (proper-list-of-length-p spec 1 2)
 187                    (compiler-error "malformed &AUX binding specifier: ~S"
 188                                    spec))
 189                  (let* ((name (first spec))
 190                         (var (varify-lambda-arg name nil)))
 191                    (aux-vars var)
 192                    (aux-vals (second spec))
 193                    (names-so-far name)))))
 194
 195         (values (vars) keyp allowp (aux-vars) (aux-vals))))))
 196
 197 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that we
 198 ;;; sequentially bind each AUX-VAR to the corresponding AUX-VAL before
 199 ;;; converting the body. If there are no bindings, just convert the
 200 ;;; body, otherwise do one binding and recurse on the rest.
 201 ;;;
 202 ;;; FIXME: This could and probably should be converted to use
 203 ;;; SOURCE-NAME and DEBUG-NAME. But I (WHN) don't use &AUX bindings,
 204 ;;; so I'm not motivated. Patches will be accepted...
 205 (defun ir1-convert-aux-bindings (start next result body aux-vars aux-vals)
 206   (declare (type ctran start next) (type (or lvar null) result)
 207            (list body aux-vars aux-vals))
 208   (if (null aux-vars)
 209       (ir1-convert-progn-body start next result body)
 210       (let ((ctran (make-ctran))
 211             (fun-lvar (make-lvar))
 212             (fun (ir1-convert-lambda-body body
 213                                           (list (first aux-vars))
 214                                           :aux-vars (rest aux-vars)
 215                                           :aux-vals (rest aux-vals)
 216                                           :debug-name (debug-namify
 217                                                        "&AUX bindings ~S"
 218                                                        aux-vars))))
 219         (reference-leaf start ctran fun-lvar fun)
 220         (ir1-convert-combination-args fun-lvar ctran next result
 221                                       (list (first aux-vals)))))
 222   (values))
 223
 224 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that code to bind
 225 ;;; the SPECVAR for each SVAR to the value of the variable is wrapped
 226 ;;; around the body. If there are no special bindings, we just convert
 227 ;;; the body, otherwise we do one special binding and recurse on the
 228 ;;; rest.
 229 ;;;
 230 ;;; We make a cleanup and introduce it into the lexical
 231 ;;; environment. If there are multiple special bindings, the cleanup
 232 ;;; for the blocks will end up being the innermost one. We force NEXT
 233 ;;; to start a block outside of this cleanup, causing cleanup code to
 234 ;;; be emitted when the scope is exited.
 235 (defun ir1-convert-special-bindings
 236     (start next result body aux-vars aux-vals svars)
 237   (declare (type ctran start next) (type (or lvar null) result)
 238            (list body aux-vars aux-vals svars))
 239   (cond
 240    ((null svars)
 241     (ir1-convert-aux-bindings start next result body aux-vars aux-vals))
 242    (t
 243     (ctran-starts-block next)
 244     (let ((cleanup (make-cleanup :kind :special-bind))
 245           (var (first svars))
 246           (bind-ctran (make-ctran))
 247           (cleanup-ctran (make-ctran)))
 248       (ir1-convert start bind-ctran nil
 249                    `(%special-bind ',(lambda-var-specvar var) ,var))
 250       (setf (cleanup-mess-up cleanup) (ctran-use bind-ctran))
 251       (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 252         (ir1-convert bind-ctran cleanup-ctran nil '(%cleanup-point))
 253         (ir1-convert-special-bindings cleanup-ctran next result
 254                                       body aux-vars aux-vals
 255                                       (rest svars))))))
 256   (values))
 257
 258 ;;; FIXME: this is the interface of the CMUCL WITH-DYNAMIC-EXTENT
 259 ;;; macro.  It is slightly confusing, in that START and BODY-START are
 260 ;;; already-existing CTRANs (and FIXME: probably deserve a ONCE-ONLY),
 261 ;;; whereas NEXT is a variable naming a CTRAN in the body.  -- CSR,
 262 ;;; 2004-03-30.
 263 (defmacro with-dynamic-extent ((start body-start next kind) &body body)
 264   (with-unique-names (cleanup next-ctran)
 265     `(progn
 266       (ctran-starts-block ,body-start)
 267       (let ((,cleanup (make-cleanup :kind :dynamic-extent))
 268             (,next-ctran (make-ctran))
 269             (,next (make-ctran)))
 270         (ir1-convert ,start ,next-ctran nil '(%dynamic-extent-start))
 271         (setf (cleanup-mess-up ,cleanup) (ctran-use ,next-ctran))
 272         (let ((*lexenv* (make-lexenv :cleanup ,cleanup)))
 273           (ir1-convert ,next-ctran ,next nil '(%cleanup-point))
 274           (locally ,@body))))))
 275
 276 ;;; Create a lambda node out of some code, returning the result. The
 277 ;;; bindings are specified by the list of VAR structures VARS. We deal
 278 ;;; with adding the names to the LEXENV-VARS for the conversion. The
 279 ;;; result is added to the NEW-FUNCTIONALS in the *CURRENT-COMPONENT*
 280 ;;; and linked to the component head and tail.
 281 ;;;
 282 ;;; We detect special bindings here, replacing the original VAR in the
 283 ;;; lambda list with a temporary variable. We then pass a list of the
 284 ;;; special vars to IR1-CONVERT-SPECIAL-BINDINGS, which actually emits
 285 ;;; the special binding code.
 286 ;;;
 287 ;;; We ignore any ARG-INFO in the VARS, trusting that someone else is
 288 ;;; dealing with &NONSENSE, except for &REST vars with DYNAMIC-EXTENT.
 289 ;;;
 290 ;;; AUX-VARS is a list of VAR structures for variables that are to be
 291 ;;; sequentially bound. Each AUX-VAL is a form that is to be evaluated
 292 ;;; to get the initial value for the corresponding AUX-VAR.
 293 (defun ir1-convert-lambda-body (body
 294                                 vars
 295                                 &key
 296                                 aux-vars
 297                                 aux-vals
 298                                 (source-name '.anonymous.)
 299                                 debug-name
 300                                 (note-lexical-bindings t))
 301   (declare (list body vars aux-vars aux-vals))
 302
 303   ;; We're about to try to put new blocks into *CURRENT-COMPONENT*.
 304   (aver-live-component *current-component*)
 305
 306   (let* ((bind (make-bind))
 307          (lambda (make-lambda :vars vars
 308                   :bind bind
 309                   :%source-name source-name
 310                   :%debug-name debug-name))
 311          (result-ctran (make-ctran))
 312          (result-lvar (make-lvar))
 313          (dx-rest nil))
 314
 315     (awhen (lexenv-lambda *lexenv*)
 316       (push lambda (lambda-children it))
 317       (setf (lambda-parent lambda) it))
 318
 319     ;; just to check: This function should fail internal assertions if
 320     ;; we didn't set up a valid debug name above.
 321     ;;
 322     ;; (In SBCL we try to make everything have a debug name, since we
 323     ;; lack the omniscient perspective the original implementors used
 324     ;; to decide which things didn't need one.)
 325     (functional-debug-name lambda)
 326
 327     (setf (lambda-home lambda) lambda)
 328     (collect ((svars)
 329               (new-venv nil cons))
 330
 331       (dolist (var vars)
 332         ;; As far as I can see, LAMBDA-VAR-HOME should never have
 333         ;; been set before. Let's make sure. -- WHN 2001-09-29
 334         (aver (not (lambda-var-home var)))
 335         (setf (lambda-var-home var) lambda)
 336         (let ((specvar (lambda-var-specvar var)))
 337           (cond (specvar
 338                  (svars var)
 339                  (new-venv (cons (leaf-source-name specvar) specvar)))
 340                 (t
 341                  (when note-lexical-bindings
 342                    (note-lexical-binding (leaf-source-name var)))
 343                  (new-venv (cons (leaf-source-name var) var)))))
 344         (let ((info (lambda-var-arg-info var)))
 345           (when (and info
 346                      (eq (arg-info-kind info) :rest)
 347                      (leaf-dynamic-extent var))
 348             (setq dx-rest t))))
 349
 350       (let ((*lexenv* (make-lexenv :vars (new-venv)
 351                                    :lambda lambda
 352                                    :cleanup nil)))
 353         (setf (bind-lambda bind) lambda)
 354         (setf (node-lexenv bind) *lexenv*)
 355
 356         (let ((block (ctran-starts-block result-ctran)))
 357           (let ((return (make-return :result result-lvar :lambda lambda))
 358                 (tail-set (make-tail-set :funs (list lambda))))
 359             (setf (lambda-tail-set lambda) tail-set)
 360             (setf (lambda-return lambda) return)
 361             (setf (lvar-dest result-lvar) return)
 362             (link-node-to-previous-ctran return result-ctran)
 363             (setf (block-last block) return))
 364           (link-blocks block (component-tail *current-component*)))
 365
 366         (with-component-last-block (*current-component*
 367                                     (ctran-block result-ctran))
 368           (let ((prebind-ctran (make-ctran))
 369                 (postbind-ctran (make-ctran)))
 370             (ctran-starts-block prebind-ctran)
 371             (link-node-to-previous-ctran bind prebind-ctran)
 372             (use-ctran bind postbind-ctran)
 373             (if dx-rest
 374                 (with-dynamic-extent (postbind-ctran result-ctran dx :rest)
 375                   (ir1-convert-special-bindings dx result-ctran result-lvar
 376                                                 body aux-vars aux-vals
 377                                                 (svars)))
 378                 (ir1-convert-special-bindings postbind-ctran result-ctran
 379                                               result-lvar body
 380                                               aux-vars aux-vals (svars)))))))
 381
 382     (link-blocks (component-head *current-component*) (node-block bind))
 383     (push lambda (component-new-functionals *current-component*))
 384
 385     lambda))
 386
 387 ;;; Entry point CLAMBDAs have a special kind
 388 (defun register-entry-point (entry dispatcher)
 389   (declare (type clambda entry)
 390            (type optional-dispatch dispatcher))
 391   (setf (functional-kind entry) :optional)
 392   (setf (leaf-ever-used entry) t)
 393   (setf (lambda-optional-dispatch entry) dispatcher)
 394   entry)
 395
 396 ;;; Create the actual entry-point function for an optional entry
 397 ;;; point. The lambda binds copies of each of the VARS, then calls FUN
 398 ;;; with the argument VALS and the DEFAULTS. Presumably the VALS refer
 399 ;;; to the VARS by name. The VALS are passed in the reverse order.
 400 ;;;
 401 ;;; If any of the copies of the vars are referenced more than once,
 402 ;;; then we mark the corresponding var as EVER-USED to inhibit
 403 ;;; "defined but not read" warnings for arguments that are only used
 404 ;;; by default forms.
 405 (defun convert-optional-entry (fun vars vals defaults)
 406   (declare (type clambda fun) (list vars vals defaults))
 407   (let* ((fvars (reverse vars))
 408          (arg-vars (mapcar (lambda (var)
 409                              (make-lambda-var
 410                               :%source-name (leaf-source-name var)
 411                               :type (leaf-type var)
 412                               :where-from (leaf-where-from var)
 413                               :specvar (lambda-var-specvar var)))
 414                            fvars))
 415          (fun (collect ((default-bindings)
 416                         (default-vals))
 417                 (dolist (default defaults)
 418                   (if (constantp default)
 419                       (default-vals default)
 420                       (let ((var (gensym)))
 421                         (default-bindings `(,var ,default))
 422                         (default-vals var))))
 423                 (ir1-convert-lambda-body `((let (,@(default-bindings))
 424                                              (%funcall ,fun
 425                                                        ,@(reverse vals)
 426                                                        ,@(default-vals))))
 427                                          arg-vars
 428                                          :debug-name
 429                                          (debug-namify "&OPTIONAL processor ~D"
 430                                                        (random 100))
 431                                          :note-lexical-bindings nil))))
 432     (mapc (lambda (var arg-var)
 433             (when (cdr (leaf-refs arg-var))
 434               (setf (leaf-ever-used var) t)))
 435           fvars arg-vars)
 436     fun))
 437
 438 ;;; This function deals with supplied-p vars in optional arguments. If
 439 ;;; the there is no supplied-p arg, then we just call
 440 ;;; IR1-CONVERT-HAIRY-ARGS on the remaining arguments, and generate a
 441 ;;; optional entry that calls the result. If there is a supplied-p
 442 ;;; var, then we add it into the default vars and throw a T into the
 443 ;;; entry values. The resulting entry point function is returned.
 444 (defun generate-optional-default-entry (res default-vars default-vals
 445                                         entry-vars entry-vals
 446                                         vars supplied-p-p body
 447                                         aux-vars aux-vals
 448                                         source-name debug-name
 449                                         force)
 450   (declare (type optional-dispatch res)
 451            (list default-vars default-vals entry-vars entry-vals vars body
 452                  aux-vars aux-vals))
 453   (let* ((arg (first vars))
 454          (arg-name (leaf-source-name arg))
 455          (info (lambda-var-arg-info arg))
 456          (default (arg-info-default info))
 457          (supplied-p (arg-info-supplied-p info))
 458          (force (or force
 459                     (not (sb!xc:constantp (arg-info-default info)))))
 460          (ep (if supplied-p
 461                  (ir1-convert-hairy-args
 462                   res
 463                   (list* supplied-p arg default-vars)
 464                   (list* (leaf-source-name supplied-p) arg-name default-vals)
 465                   (cons arg entry-vars)
 466                   (list* t arg-name entry-vals)
 467                   (rest vars) t body aux-vars aux-vals
 468                   source-name debug-name
 469                   force)
 470                  (ir1-convert-hairy-args
 471                   res
 472                   (cons arg default-vars)
 473                   (cons arg-name default-vals)
 474                   (cons arg entry-vars)
 475                   (cons arg-name entry-vals)
 476                   (rest vars) supplied-p-p body aux-vars aux-vals
 477                   source-name debug-name
 478                   force))))
 479
 480     ;; We want to delay converting the entry, but there exist
 481     ;; problems: hidden references should not be established to
 482     ;; lambdas of kind NIL should not have (otherwise the compiler
 483     ;; might let-convert or delete them) and to variables.
 484     (if (or force
 485             supplied-p-p ; this entry will be of kind NIL
 486             (and (lambda-p ep) (eq (lambda-kind ep) nil)))
 487         (convert-optional-entry ep
 488                                 default-vars default-vals
 489                                 (if supplied-p
 490                                     (list default nil)
 491                                     (list default)))
 492         (delay
 493          (register-entry-point
 494            (convert-optional-entry (force ep)
 495                                    default-vars default-vals
 496                                    (if supplied-p
 497                                        (list default nil)
 498                                        (list default)))
 499            res)))))
 500
 501 ;;; Create the MORE-ENTRY function for the OPTIONAL-DISPATCH RES.
 502 ;;; ENTRY-VARS and ENTRY-VALS describe the fixed arguments. REST is
 503 ;;; the var for any &REST arg. KEYS is a list of the &KEY arg vars.
 504 ;;;
 505 ;;; The most interesting thing that we do is parse keywords. We create
 506 ;;; a bunch of temporary variables to hold the result of the parse,
 507 ;;; and then loop over the supplied arguments, setting the appropriate
 508 ;;; temps for the supplied keyword. Note that it is significant that
 509 ;;; we iterate over the keywords in reverse order --- this implements
 510 ;;; the CL requirement that (when a keyword appears more than once)
 511 ;;; the first value is used.
 512 ;;;
 513 ;;; If there is no supplied-p var, then we initialize the temp to the
 514 ;;; default and just pass the temp into the main entry. Since
 515 ;;; non-constant &KEY args are forcibly given a supplied-p var, we
 516 ;;; know that the default is constant, and thus safe to evaluate out
 517 ;;; of order.
 518 ;;;
 519 ;;; If there is a supplied-p var, then we create temps for both the
 520 ;;; value and the supplied-p, and pass them into the main entry,
 521 ;;; letting it worry about defaulting.
 522 ;;;
 523 ;;; We deal with :ALLOW-OTHER-KEYS by delaying unknown keyword errors
 524 ;;; until we have scanned all the keywords.
 525 (defun convert-more-entry (res entry-vars entry-vals rest morep keys)
 526   (declare (type optional-dispatch res) (list entry-vars entry-vals keys))
 527   (collect ((arg-vars)
 528             (arg-vals (reverse entry-vals))
 529             (temps)
 530             (body))
 531
 532     (dolist (var (reverse entry-vars))
 533       (arg-vars (make-lambda-var :%source-name (leaf-source-name var)
 534                                  :type (leaf-type var)
 535                                  :where-from (leaf-where-from var))))
 536
 537     (let* ((n-context (gensym "N-CONTEXT-"))
 538            (context-temp (make-lambda-var :%source-name n-context))
 539            (n-count (gensym "N-COUNT-"))
 540            (count-temp (make-lambda-var :%source-name n-count
 541                                         :type (specifier-type 'index))))
 542
 543       (arg-vars context-temp count-temp)
 544
 545       (when rest
 546         (arg-vals `(%listify-rest-args
 547                     ,n-context ,n-count ,(leaf-dynamic-extent rest))))
 548       (when morep
 549         (arg-vals n-context)
 550         (arg-vals n-count))
 551
 552       (when (optional-dispatch-keyp res)
 553         (let ((n-index (gensym "N-INDEX-"))
 554               (n-key (gensym "N-KEY-"))
 555               (n-value-temp (gensym "N-VALUE-TEMP-"))
 556               (n-allowp (gensym "N-ALLOWP-"))
 557               (n-losep (gensym "N-LOSEP-"))
 558               (allowp (or (optional-dispatch-allowp res)
 559                           (policy *lexenv* (zerop safety))))
 560               (found-allow-p nil))
 561
 562           (temps `(,n-index (1- ,n-count)) n-key n-value-temp)
 563           (body `(declare (fixnum ,n-index) (ignorable ,n-key ,n-value-temp)))
 564
 565           (collect ((tests))
 566             (dolist (key keys)
 567               (let* ((info (lambda-var-arg-info key))
 568                      (default (arg-info-default info))
 569                      (keyword (arg-info-key info))
 570                      (supplied-p (arg-info-supplied-p info))
 571                      (n-value (gensym "N-VALUE-"))
 572                      (clause (cond (supplied-p
 573                                     (let ((n-supplied (gensym "N-SUPPLIED-")))
 574                                       (temps n-supplied)
 575                                       (arg-vals n-value n-supplied)
 576                                       `((eq ,n-key ',keyword)
 577                                         (setq ,n-supplied t)
 578                                         (setq ,n-value ,n-value-temp))))
 579                                    (t
 580                                     (arg-vals n-value)
 581                                     `((eq ,n-key ',keyword)
 582                                       (setq ,n-value ,n-value-temp))))))
 583                 (when (and (not allowp) (eq keyword :allow-other-keys))
 584                   (setq found-allow-p t)
 585                   (setq clause
 586                         (append clause `((setq ,n-allowp ,n-value-temp)))))
 587
 588                 (temps `(,n-value ,default))
 589                 (tests clause)))
 590
 591             (unless allowp
 592               (temps n-allowp n-losep)
 593               (unless found-allow-p
 594                 (tests `((eq ,n-key :allow-other-keys)
 595                          (setq ,n-allowp ,n-value-temp))))
 596               (tests `(t
 597                        (setq ,n-losep ,n-key))))
 598
 599             (body
 600              `(when (oddp ,n-count)
 601                 (%odd-key-args-error)))
 602
 603             (body
 604              `(locally
 605                 (declare (optimize (safety 0)))
 606                 (loop
 607                   (when (minusp ,n-index) (return))
 608                   (setf ,n-value-temp (%more-arg ,n-context ,n-index))
 609                   (decf ,n-index)
 610                   (setq ,n-key (%more-arg ,n-context ,n-index))
 611                   (decf ,n-index)
 612                   (cond ,@(tests)))))
 613
 614             (unless allowp
 615               (body `(when (and ,n-losep (not ,n-allowp))
 616                        (%unknown-key-arg-error ,n-losep)))))))
 617
 618       (let ((ep (ir1-convert-lambda-body
 619                  `((let ,(temps)
 620                      ,@(body)
 621                      (%funcall ,(optional-dispatch-main-entry res)
 622                                ,@(arg-vals))))
 623                  (arg-vars)
 624                  :debug-name (debug-namify "~S processing" '&more)
 625                  :note-lexical-bindings nil)))
 626         (setf (optional-dispatch-more-entry res)
 627               (register-entry-point ep res)))))
 628
 629   (values))
 630
 631 ;;; This is called by IR1-CONVERT-HAIRY-ARGS when we run into a &REST
 632 ;;; or &KEY arg. The arguments are similar to that function, but we
 633 ;;; split off any &REST arg and pass it in separately. REST is the
 634 ;;; &REST arg var, or NIL if there is no &REST arg. KEYS is a list of
 635 ;;; the &KEY argument vars.
 636 ;;;
 637 ;;; When there are &KEY arguments, we introduce temporary gensym
 638 ;;; variables to hold the values while keyword defaulting is in
 639 ;;; progress to get the required sequential binding semantics.
 640 ;;;
 641 ;;; This gets interesting mainly when there are &KEY arguments with
 642 ;;; supplied-p vars or non-constant defaults. In either case, pass in
 643 ;;; a supplied-p var. If the default is non-constant, we introduce an
 644 ;;; IF in the main entry that tests the supplied-p var and decides
 645 ;;; whether to evaluate the default or not. In this case, the real
 646 ;;; incoming value is NIL, so we must union NULL with the declared
 647 ;;; type when computing the type for the main entry's argument.
 648 (defun ir1-convert-more (res default-vars default-vals entry-vars entry-vals
 649                              rest more-context more-count keys supplied-p-p
 650                              body aux-vars aux-vals
 651                              source-name debug-name)
 652   (declare (type optional-dispatch res)
 653            (list default-vars default-vals entry-vars entry-vals keys body
 654                  aux-vars aux-vals))
 655   (collect ((main-vars (reverse default-vars))
 656             (main-vals default-vals cons)
 657             (bind-vars)
 658             (bind-vals))
 659     (when rest
 660       (main-vars rest)
 661       (main-vals '()))
 662     (when more-context
 663       (main-vars more-context)
 664       (main-vals nil)
 665       (main-vars more-count)
 666       (main-vals 0))
 667
 668     (dolist (key keys)
 669       (let* ((info (lambda-var-arg-info key))
 670              (default (arg-info-default info))
 671              (hairy-default (not (sb!xc:constantp default)))
 672              (supplied-p (arg-info-supplied-p info))
 673              (n-val (make-symbol (format nil
 674                                          "~A-DEFAULTING-TEMP"
 675                                          (leaf-source-name key))))
 676              (key-type (leaf-type key))
 677              (val-temp (make-lambda-var
 678                         :%source-name n-val
 679                         :type (if hairy-default
 680                                   (type-union key-type (specifier-type 'null))
 681                                   key-type))))
 682         (main-vars val-temp)
 683         (bind-vars key)
 684         (cond ((or hairy-default supplied-p)
 685                (let* ((n-supplied (gensym "N-SUPPLIED-"))
 686                       (supplied-temp (make-lambda-var
 687                                       :%source-name n-supplied)))
 688                  (unless supplied-p
 689                    (setf (arg-info-supplied-p info) supplied-temp))
 690                  (when hairy-default
 691                    (setf (arg-info-default info) nil))
 692                  (main-vars supplied-temp)
 693                  (cond (hairy-default
 694                         (main-vals nil nil)
 695                         (bind-vals `(if ,n-supplied ,n-val ,default)))
 696                        (t
 697                         (main-vals default nil)
 698                         (bind-vals n-val)))
 699                  (when supplied-p
 700                    (bind-vars supplied-p)
 701                    (bind-vals n-supplied))))
 702               (t
 703                (main-vals (arg-info-default info))
 704                (bind-vals n-val)))))
 705
 706     (let* ((main-entry (ir1-convert-lambda-body
 707                         body (main-vars)
 708                         :aux-vars (append (bind-vars) aux-vars)
 709                         :aux-vals (append (bind-vals) aux-vals)
 710                         :debug-name (debug-namify "varargs entry for ~A"
 711                                                   (as-debug-name source-name
 712                                                                  debug-name))))
 713            (last-entry (convert-optional-entry main-entry default-vars
 714                                                (main-vals) ())))
 715       (setf (optional-dispatch-main-entry res)
 716             (register-entry-point main-entry res))
 717       (convert-more-entry res entry-vars entry-vals rest more-context keys)
 718
 719       (push (register-entry-point
 720              (if supplied-p-p
 721                 (convert-optional-entry last-entry entry-vars entry-vals ())
 722                 last-entry)
 723              res)
 724             (optional-dispatch-entry-points res))
 725       last-entry)))
 726
 727 ;;; This function generates the entry point functions for the
 728 ;;; OPTIONAL-DISPATCH RES. We accomplish this by recursion on the list
 729 ;;; of arguments, analyzing the arglist on the way down and generating
 730 ;;; entry points on the way up.
 731 ;;;
 732 ;;; DEFAULT-VARS is a reversed list of all the argument vars processed
 733 ;;; so far, including supplied-p vars. DEFAULT-VALS is a list of the
 734 ;;; names of the DEFAULT-VARS.
 735 ;;;
 736 ;;; ENTRY-VARS is a reversed list of processed argument vars,
 737 ;;; excluding supplied-p vars. ENTRY-VALS is a list things that can be
 738 ;;; evaluated to get the values for all the vars from the ENTRY-VARS.
 739 ;;; It has the var name for each required or optional arg, and has T
 740 ;;; for each supplied-p arg.
 741 ;;;
 742 ;;; VARS is a list of the LAMBDA-VAR structures for arguments that
 743 ;;; haven't been processed yet. SUPPLIED-P-P is true if a supplied-p
 744 ;;; argument has already been processed; only in this case are the
 745 ;;; DEFAULT-XXX and ENTRY-XXX different.
 746 ;;;
 747 ;;; The result at each point is a lambda which should be called by the
 748 ;;; above level to default the remaining arguments and evaluate the
 749 ;;; body. We cause the body to be evaluated by converting it and
 750 ;;; returning it as the result when the recursion bottoms out.
 751 ;;;
 752 ;;; Each level in the recursion also adds its entry point function to
 753 ;;; the result OPTIONAL-DISPATCH. For most arguments, the defaulting
 754 ;;; function and the entry point function will be the same, but when
 755 ;;; SUPPLIED-P args are present they may be different.
 756 ;;;
 757 ;;; When we run into a &REST or &KEY arg, we punt out to
 758 ;;; IR1-CONVERT-MORE, which finishes for us in this case.
 759 (defun ir1-convert-hairy-args (res default-vars default-vals
 760                                entry-vars entry-vals
 761                                vars supplied-p-p body aux-vars
 762                                aux-vals
 763                                source-name debug-name
 764                                force)
 765   (declare (type optional-dispatch res)
 766            (list default-vars default-vals entry-vars entry-vals vars body
 767                  aux-vars aux-vals))
 768   (cond ((not vars)
 769          (if (optional-dispatch-keyp res)
 770              ;; Handle &KEY with no keys...
 771              (ir1-convert-more res default-vars default-vals
 772                                entry-vars entry-vals
 773                                nil nil nil vars supplied-p-p body aux-vars
 774                                aux-vals source-name debug-name)
 775              (let ((fun (ir1-convert-lambda-body
 776                          body (reverse default-vars)
 777                          :aux-vars aux-vars
 778                          :aux-vals aux-vals
 779                          :debug-name (debug-namify
 780                                       "hairy arg processor for ~A"
 781                                       (as-debug-name source-name
 782                                                      debug-name)))))
 783                (setf (optional-dispatch-main-entry res) fun)
 784                (register-entry-point fun res)
 785                (push (if supplied-p-p
 786                          (register-entry-point
 787                           (convert-optional-entry fun entry-vars entry-vals ())
 788                           res)
 789                           fun)
 790                      (optional-dispatch-entry-points res))
 791                fun)))
 792         ((not (lambda-var-arg-info (first vars)))
 793          (let* ((arg (first vars))
 794                 (nvars (cons arg default-vars))
 795                 (nvals (cons (leaf-source-name arg) default-vals)))
 796            (ir1-convert-hairy-args res nvars nvals nvars nvals
 797                                    (rest vars) nil body aux-vars aux-vals
 798                                    source-name debug-name
 799                                    nil)))
 800         (t
 801          (let* ((arg (first vars))
 802                 (info (lambda-var-arg-info arg))
 803                 (kind (arg-info-kind info)))
 804            (ecase kind
 805              (:optional
 806               (let ((ep (generate-optional-default-entry
 807                          res default-vars default-vals
 808                          entry-vars entry-vals vars supplied-p-p body
 809                          aux-vars aux-vals
 810                          source-name debug-name
 811                          force)))
 812                 ;; See GENERATE-OPTIONAL-DEFAULT-ENTRY.
 813                 (push (if (lambda-p ep)
 814                           (register-entry-point
 815                            (if supplied-p-p
 816                                (convert-optional-entry ep entry-vars entry-vals ())
 817                                ep)
 818                            res)
 819                           (progn (aver (not supplied-p-p))
 820                                  ep))
 821                       (optional-dispatch-entry-points res))
 822                 ep))
 823              (:rest
 824               (ir1-convert-more res default-vars default-vals
 825                                 entry-vars entry-vals
 826                                 arg nil nil (rest vars) supplied-p-p body
 827                                 aux-vars aux-vals
 828                                 source-name debug-name))
 829              (:more-context
 830               (ir1-convert-more res default-vars default-vals
 831                                 entry-vars entry-vals
 832                                 nil arg (second vars) (cddr vars) supplied-p-p
 833                                 body aux-vars aux-vals
 834                                 source-name debug-name))
 835              (:keyword
 836               (ir1-convert-more res default-vars default-vals
 837                                 entry-vars entry-vals
 838                                 nil nil nil vars supplied-p-p body aux-vars
 839                                 aux-vals source-name debug-name)))))))
 840
 841 ;;; This function deals with the case where we have to make an
 842 ;;; OPTIONAL-DISPATCH to represent a LAMBDA. We cons up the result and
 843 ;;; call IR1-CONVERT-HAIRY-ARGS to do the work. When it is done, we
 844 ;;; figure out the MIN-ARGS and MAX-ARGS.
 845 (defun ir1-convert-hairy-lambda (body vars keyp allowp aux-vars aux-vals
 846                                       &key
 847                                       (source-name '.anonymous.)
 848                                       (debug-name (debug-namify
 849                                                    "OPTIONAL-DISPATCH ~S"
 850                                                    vars)))
 851   (declare (list body vars aux-vars aux-vals))
 852   (let ((res (make-optional-dispatch :arglist vars
 853                                      :allowp allowp
 854                                      :keyp keyp
 855                                      :%source-name source-name
 856                                      :%debug-name debug-name
 857                                      :plist `(:ir1-environment
 858                                               (,*lexenv*
 859                                                ,*current-path*))))
 860         (min (or (position-if #'lambda-var-arg-info vars) (length vars))))
 861     (aver-live-component *current-component*)
 862     (push res (component-new-functionals *current-component*))
 863     (ir1-convert-hairy-args res () () () () vars nil body aux-vars aux-vals
 864                             source-name debug-name nil)
 865     (setf (optional-dispatch-min-args res) min)
 866     (setf (optional-dispatch-max-args res)
 867           (+ (1- (length (optional-dispatch-entry-points res))) min))
 868
 869     res))
 870
 871 ;;; Convert a LAMBDA form into a LAMBDA leaf or an OPTIONAL-DISPATCH leaf.
 872 (defun ir1-convert-lambda (form &key (source-name '.anonymous.)
 873                            debug-name
 874                            allow-debug-catch-tag)
 875
 876   (unless (consp form)
 877     (compiler-error "A ~S was found when expecting a lambda expression:~%  ~S"
 878                     (type-of form)
 879                     form))
 880   (unless (eq (car form) 'lambda)
 881     (compiler-error "~S was expected but ~S was found:~%  ~S"
 882                     'lambda
 883                     (car form)
 884                     form))
 885   (unless (and (consp (cdr form)) (listp (cadr form)))
 886     (compiler-error
 887      "The lambda expression has a missing or non-list lambda list:~%  ~S"
 888      form))
 889
 890   (let ((*allow-debug-catch-tag* (and *allow-debug-catch-tag* allow-debug-catch-tag)))
 891     (multiple-value-bind (vars keyp allow-other-keys aux-vars aux-vals)
 892         (make-lambda-vars (cadr form))
 893       (multiple-value-bind (forms decls) (parse-body (cddr form))
 894         (binding* (((*lexenv* result-type)
 895                     (process-decls decls (append aux-vars vars) nil))
 896                    (forms (if (and *allow-debug-catch-tag*
 897                                    (policy *lexenv* (>= insert-debug-catch 2)))
 898                               `((catch (make-symbol "SB-DEBUG-CATCH-TAG")
 899                                   ,@forms))
 900                               forms))
 901                    (forms (if (eq result-type *wild-type*)
 902                               forms
 903                               `((the ,result-type (progn ,@forms)))))
 904                    (res (if (or (find-if #'lambda-var-arg-info vars) keyp)
 905                             (ir1-convert-hairy-lambda forms vars keyp
 906                                                       allow-other-keys
 907                                                       aux-vars aux-vals
 908                                                       :source-name source-name
 909                                                       :debug-name debug-name)
 910                             (ir1-convert-lambda-body forms vars
 911                                                      :aux-vars aux-vars
 912                                                      :aux-vals aux-vals
 913                                                      :source-name source-name
 914                                                      :debug-name debug-name))))
 915           (setf (functional-inline-expansion res) form)
 916           (setf (functional-arg-documentation res) (cadr form))
 917           res)))))
 918
 919 ;;; helper for LAMBDA-like things, to massage them into a form
 920 ;;; suitable for IR1-CONVERT-LAMBDA.
 921 ;;;
 922 ;;; KLUDGE: We cons up a &REST list here, maybe for no particularly
 923 ;;; good reason.  It's probably lost in the noise of all the other
 924 ;;; consing, but it's still inelegant.  And we force our called
 925 ;;; functions to do full runtime keyword parsing, ugh.  -- CSR,
 926 ;;; 2003-01-25
 927 (defun ir1-convert-lambdalike (thing &rest args
 928                                &key (source-name '.anonymous.)
 929                                debug-name allow-debug-catch-tag)
 930   (declare (ignorable source-name debug-name allow-debug-catch-tag))
 931   (ecase (car thing)
 932     ((lambda) (apply #'ir1-convert-lambda thing args))
 933     ((instance-lambda)
 934      (let ((res (apply #'ir1-convert-lambda
 935                        `(lambda ,@(cdr thing)) args)))
 936        (setf (getf (functional-plist res) :fin-function) t)
 937        res))
 938     ((named-lambda)
 939      (let ((name (cadr thing)))
 940        (if (legal-fun-name-p name)
 941            (let ((defined-fun-res (get-defined-fun name))
 942                  (res (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 943                              :source-name name
 944                              :debug-name nil
 945                              args)))
 946              (assert-global-function-definition-type name res)
 947              (setf (defined-fun-functional defined-fun-res)
 948                    res)
 949              (unless (eq (defined-fun-inlinep defined-fun-res) :notinline)
 950                (substitute-leaf-if
 951                 (lambda (ref)
 952                   (policy ref (> recognize-self-calls 0)))
 953                 res defined-fun-res))
 954              res)
 955            (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 956                   :debug-name name args))))
 957     ((lambda-with-lexenv) (apply #'ir1-convert-inline-lambda thing args))))
 958 \f
 959 ;;;; defining global functions
 960
 961 ;;; Convert FUN as a lambda in the null environment, but use the
 962 ;;; current compilation policy. Note that FUN may be a
 963 ;;; LAMBDA-WITH-LEXENV, so we may have to augment the environment to
 964 ;;; reflect the state at the definition site.
 965 (defun ir1-convert-inline-lambda (fun &key
 966                                       (source-name '.anonymous.)
 967                                       debug-name
 968                                       allow-debug-catch-tag)
 969   (destructuring-bind (decls macros symbol-macros &rest body)
 970                       (if (eq (car fun) 'lambda-with-lexenv)
 971                           (cdr fun)
 972                           `(() () () . ,(cdr fun)))
 973     (let ((*lexenv* (make-lexenv
 974                      :default (process-decls decls nil nil
 975                                              (make-null-lexenv))
 976                      :vars (copy-list symbol-macros)
 977                      :funs (mapcar (lambda (x)
 978                                      `(,(car x) .
 979                                        (macro . ,(coerce (cdr x) 'function))))
 980                                    macros)
 981                      :policy (lexenv-policy *lexenv*))))
 982       (ir1-convert-lambda `(lambda ,@body)
 983                           :source-name source-name
 984                           :debug-name debug-name
 985                           :allow-debug-catch-tag nil))))
 986
 987 ;;; Get a DEFINED-FUN object for a function we are about to define. If
 988 ;;; the function has been forward referenced, then substitute for the
 989 ;;; previous references.
 990 (defun get-defined-fun (name)
 991   (proclaim-as-fun-name name)
 992   (let ((found (find-free-fun name "shouldn't happen! (defined-fun)")))
 993     (note-name-defined name :function)
 994     (cond ((not (defined-fun-p found))
 995            (aver (not (info :function :inlinep name)))
 996            (let* ((where-from (leaf-where-from found))
 997                   (res (make-defined-fun
 998                         :%source-name name
 999                         :where-from (if (eq where-from :declared)
1000                                         :declared :defined)
1001                         :type (leaf-type found))))
1002              (substitute-leaf res found)
1003              (setf (gethash name *free-funs*) res)))
1004           ;; If *FREE-FUNS* has a previously converted definition
1005           ;; for this name, then blow it away and try again.
1006           ((defined-fun-functional found)
1007            (remhash name *free-funs*)
1008            (get-defined-fun name))
1009           (t found))))
1010
1011 ;;; Check a new global function definition for consistency with
1012 ;;; previous declaration or definition, and assert argument/result
1013 ;;; types if appropriate. This assertion is suppressed by the
1014 ;;; EXPLICIT-CHECK attribute, which is specified on functions that
1015 ;;; check their argument types as a consequence of type dispatching.
1016 ;;; This avoids redundant checks such as NUMBERP on the args to +, etc.
1017 (defun assert-new-definition (var fun)
1018   (let ((type (leaf-type var))
1019         (for-real (eq (leaf-where-from var) :declared))
1020         (info (info :function :info (leaf-source-name var))))
1021     (assert-definition-type
1022      fun type
1023      ;; KLUDGE: Common Lisp is such a dynamic language that in general
1024      ;; all we can do here in general is issue a STYLE-WARNING. It
1025      ;; would be nice to issue a full WARNING in the special case of
1026      ;; of type mismatches within a compilation unit (as in section
1027      ;; 3.2.2.3 of the spec) but at least as of sbcl-0.6.11, we don't
1028      ;; keep track of whether the mismatched data came from the same
1029      ;; compilation unit, so we can't do that. -- WHN 2001-02-11
1030      :lossage-fun #'compiler-style-warn
1031      :unwinnage-fun (cond (info #'compiler-style-warn)
1032                           (for-real #'compiler-notify)
1033                           (t nil))
1034      :really-assert
1035      (and for-real
1036           (not (and info
1037                     (ir1-attributep (fun-info-attributes info)
1038                                     explicit-check))))
1039      :where (if for-real
1040                 "previous declaration"
1041                 "previous definition"))))
1042
1043 ;;; Convert a lambda doing all the basic stuff we would do if we were
1044 ;;; converting a DEFUN. In the old CMU CL system, this was used both
1045 ;;; by the %DEFUN translator and for global inline expansion, but
1046 ;;; since sbcl-0.pre7.something %DEFUN does things differently.
1047 ;;; FIXME: And now it's probably worth rethinking whether this
1048 ;;; function is a good idea.
1049 ;;;
1050 ;;; Unless a :INLINE function, we temporarily clobber the inline
1051 ;;; expansion. This prevents recursive inline expansion of
1052 ;;; opportunistic pseudo-inlines.
1053 (defun ir1-convert-lambda-for-defun (lambda var expansion converter)
1054   (declare (cons lambda) (function converter) (type defined-fun var))
1055   (let ((var-expansion (defined-fun-inline-expansion var)))
1056     (unless (eq (defined-fun-inlinep var) :inline)
1057       (setf (defined-fun-inline-expansion var) nil))
1058     (let* ((name (leaf-source-name var))
1059            (fun (funcall converter lambda
1060                          :source-name name))
1061            (fun-info (info :function :info name)))
1062       (setf (functional-inlinep fun) (defined-fun-inlinep var))
1063       (assert-new-definition var fun)
1064       (setf (defined-fun-inline-expansion var) var-expansion)
1065       ;; If definitely not an interpreter stub, then substitute for
1066       ;; any old references.
1067       (unless (or (eq (defined-fun-inlinep var) :notinline)
1068                   (not *block-compile*)
1069                   (and fun-info
1070                        (or (fun-info-transforms fun-info)
1071                            (fun-info-templates fun-info)
1072                            (fun-info-ir2-convert fun-info))))
1073         (substitute-leaf fun var)
1074         ;; If in a simple environment, then we can allow backward
1075         ;; references to this function from following top level forms.
1076         (when expansion (setf (defined-fun-functional var) fun)))
1077       fun)))
1078
1079 ;;; the even-at-compile-time part of DEFUN
1080 ;;;
1081 ;;; The INLINE-EXPANSION is a LAMBDA-WITH-LEXENV, or NIL if there is
1082 ;;; no inline expansion.
1083 (defun %compiler-defun (name lambda-with-lexenv)
1084
1085   (let ((defined-fun nil)) ; will be set below if we're in the compiler
1086
1087     (when (boundp '*lexenv*) ; when in the compiler
1088       (when sb!xc:*compile-print*
1089         (compiler-mumble "~&; recognizing DEFUN ~S~%" name))
1090       (remhash name *free-funs*)
1091       (setf defined-fun (get-defined-fun name)))
1092
1093     (become-defined-fun-name name)
1094
1095     (cond (lambda-with-lexenv
1096            (setf (info :function :inline-expansion-designator name)
1097                  lambda-with-lexenv)
1098            (when defined-fun
1099              (setf (defined-fun-inline-expansion defined-fun)
1100                    lambda-with-lexenv)))
1101           (t
1102            (clear-info :function :inline-expansion-designator name)))
1103
1104     ;; old CMU CL comment:
1105     ;;   If there is a type from a previous definition, blast it,
1106     ;;   since it is obsolete.
1107     (when (and defined-fun
1108                (eq (leaf-where-from defined-fun) :defined))
1109       (setf (leaf-type defined-fun)
1110             ;; FIXME: If this is a block compilation thing, shouldn't
1111             ;; we be setting the type to the full derived type for the
1112             ;; definition, instead of this most general function type?
1113             (specifier-type 'function))))
1114
1115   (values))
1116
1117 \f
1118 ;;; Entry point utilities
1119
1120 ;;; Return a function for the Nth entry point.
1121 (defun optional-dispatch-entry-point-fun (dispatcher n)
1122   (declare (type optional-dispatch dispatcher)
1123            (type unsigned-byte n))
1124   (let* ((env (getf (optional-dispatch-plist dispatcher) :ir1-environment))
1125          (*lexenv* (first env))
1126          (*current-path* (second env)))
1127     (force (nth n (optional-dispatch-entry-points dispatcher)))))