src/compiler/ir1tran-lambda.lisp

   1 ;;;; This file contains code which does the translation of lambda
   2 ;;;; forms from Lisp code to the first intermediate representation
   3 ;;;; (IR1).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;;; LAMBDA hackery
  17
  18 ;;;; Note: Take a look at the compiler-overview.tex section on "Hairy
  19 ;;;; function representation" before you seriously mess with this
  20 ;;;; stuff.
  21
  22 ;;; Verify that the NAME is a legal name for a variable and return a
  23 ;;; VAR structure for it, filling in info if it is globally special.
  24 ;;; If it is losing, we punt with a COMPILER-ERROR. NAMES-SO-FAR is a
  25 ;;; list of names which have previously been bound. If the NAME is in
  26 ;;; this list, then we error out.
  27 (declaim (ftype (sfunction (t list) lambda-var) varify-lambda-arg))
  28 (defun varify-lambda-arg (name names-so-far)
  29   (declare (inline member))
  30   (unless (symbolp name)
  31     (compiler-error "The lambda variable ~S is not a symbol." name))
  32   (when (member name names-so-far :test #'eq)
  33     (compiler-error "The variable ~S occurs more than once in the lambda list."
  34                     name))
  35   (let ((kind (info :variable :kind name)))
  36     (when (or (keywordp name) (eq kind :constant))
  37       (compiler-error "The name of the lambda variable ~S is already in use to name a constant."
  38                       name))
  39     (cond ((eq kind :special)
  40            (let ((specvar (find-free-var name)))
  41              (make-lambda-var :%source-name name
  42                               :type (leaf-type specvar)
  43                               :where-from (leaf-where-from specvar)
  44                               :specvar specvar)))
  45           (t
  46            (make-lambda-var :%source-name name)))))
  47
  48 ;;; Make the default keyword for a &KEY arg, checking that the keyword
  49 ;;; isn't already used by one of the VARS.
  50 (declaim (ftype (sfunction (symbol list t) symbol) make-keyword-for-arg))
  51 (defun make-keyword-for-arg (symbol vars keywordify)
  52   (let ((key (if (and keywordify (not (keywordp symbol)))
  53                  (keywordicate symbol)
  54                  symbol)))
  55     (dolist (var vars)
  56       (let ((info (lambda-var-arg-info var)))
  57         (when (and info
  58                    (eq (arg-info-kind info) :keyword)
  59                    (eq (arg-info-key info) key))
  60           (compiler-error
  61            "The keyword ~S appears more than once in the lambda list."
  62            key))))
  63     key))
  64
  65 ;;; Parse a lambda list into a list of VAR structures, stripping off
  66 ;;; any &AUX bindings. Each arg name is checked for legality, and
  67 ;;; duplicate names are checked for. If an arg is globally special,
  68 ;;; the var is marked as :SPECIAL instead of :LEXICAL. &KEY,
  69 ;;; &OPTIONAL and &REST args are annotated with an ARG-INFO structure
  70 ;;; which contains the extra information. If we hit something losing,
  71 ;;; we bug out with COMPILER-ERROR. These values are returned:
  72 ;;;  1. a list of the var structures for each top level argument;
  73 ;;;  2. a flag indicating whether &KEY was specified;
  74 ;;;  3. a flag indicating whether other &KEY args are allowed;
  75 ;;;  4. a list of the &AUX variables; and
  76 ;;;  5. a list of the &AUX values.
  77 (declaim (ftype (sfunction (list) (values list boolean boolean list list))
  78                 make-lambda-vars))
  79 (defun make-lambda-vars (list)
  80   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
  81                         morep more-context more-count)
  82       (parse-lambda-list list)
  83     (declare (ignore auxp)) ; since we just iterate over AUX regardless
  84     (collect ((vars)
  85               (names-so-far)
  86               (aux-vars)
  87               (aux-vals))
  88       (flet (;; PARSE-DEFAULT deals with defaults and supplied-p args
  89              ;; for optionals and keywords args.
  90              (parse-default (spec info)
  91                (when (consp (cdr spec))
  92                  (setf (arg-info-default info) (second spec))
  93                  (when (consp (cddr spec))
  94                    (let* ((supplied-p (third spec))
  95                           (supplied-var (varify-lambda-arg supplied-p
  96                                                            (names-so-far))))
  97                      (setf (arg-info-supplied-p info) supplied-var)
  98                      (names-so-far supplied-p)
  99                      (when (> (length (the list spec)) 3)
 100                        (compiler-error
 101                         "The list ~S is too long to be an arg specifier."
 102                         spec)))))))
 103
 104         (dolist (name required)
 105           (let ((var (varify-lambda-arg name (names-so-far))))
 106             (vars var)
 107             (names-so-far name)))
 108
 109         (dolist (spec optional)
 110           (if (atom spec)
 111               (let ((var (varify-lambda-arg spec (names-so-far))))
 112                 (setf (lambda-var-arg-info var)
 113                       (make-arg-info :kind :optional))
 114                 (vars var)
 115                 (names-so-far spec))
 116               (let* ((name (first spec))
 117                      (var (varify-lambda-arg name (names-so-far)))
 118                      (info (make-arg-info :kind :optional)))
 119                 (setf (lambda-var-arg-info var) info)
 120                 (vars var)
 121                 (names-so-far name)
 122                 (parse-default spec info))))
 123
 124         (when restp
 125           (let ((var (varify-lambda-arg rest (names-so-far))))
 126             (setf (lambda-var-arg-info var) (make-arg-info :kind :rest))
 127             (vars var)
 128             (names-so-far rest)))
 129
 130         (when morep
 131           (let ((var (varify-lambda-arg more-context (names-so-far))))
 132             (setf (lambda-var-arg-info var)
 133                   (make-arg-info :kind :more-context))
 134             (vars var)
 135             (names-so-far more-context))
 136           (let ((var (varify-lambda-arg more-count (names-so-far))))
 137             (setf (lambda-var-arg-info var)
 138                   (make-arg-info :kind :more-count))
 139             (vars var)
 140             (names-so-far more-count)))
 141
 142         (dolist (spec keys)
 143           (cond
 144            ((atom spec)
 145             (let ((var (varify-lambda-arg spec (names-so-far))))
 146               (setf (lambda-var-arg-info var)
 147                     (make-arg-info :kind :keyword
 148                                    :key (make-keyword-for-arg spec
 149                                                               (vars)
 150                                                               t)))
 151               (vars var)
 152               (names-so-far spec)))
 153            ((atom (first spec))
 154             (let* ((name (first spec))
 155                    (var (varify-lambda-arg name (names-so-far)))
 156                    (info (make-arg-info
 157                           :kind :keyword
 158                           :key (make-keyword-for-arg name (vars) t))))
 159               (setf (lambda-var-arg-info var) info)
 160               (vars var)
 161               (names-so-far name)
 162               (parse-default spec info)))
 163            (t
 164             (let ((head (first spec)))
 165               (unless (proper-list-of-length-p head 2)
 166                 (error "malformed &KEY argument specifier: ~S" spec))
 167               (let* ((name (second head))
 168                      (var (varify-lambda-arg name (names-so-far)))
 169                      (info (make-arg-info
 170                             :kind :keyword
 171                             :key (make-keyword-for-arg (first head)
 172                                                        (vars)
 173                                                        nil))))
 174                 (setf (lambda-var-arg-info var) info)
 175                 (vars var)
 176                 (names-so-far name)
 177                 (parse-default spec info))))))
 178
 179         (dolist (spec aux)
 180           (cond ((atom spec)
 181                  (let ((var (varify-lambda-arg spec nil)))
 182                    (aux-vars var)
 183                    (aux-vals nil)
 184                    (names-so-far spec)))
 185                 (t
 186                  (unless (proper-list-of-length-p spec 1 2)
 187                    (compiler-error "malformed &AUX binding specifier: ~S"
 188                                    spec))
 189                  (let* ((name (first spec))
 190                         (var (varify-lambda-arg name nil)))
 191                    (aux-vars var)
 192                    (aux-vals (second spec))
 193                    (names-so-far name)))))
 194
 195         (values (vars) keyp allowp (aux-vars) (aux-vals))))))
 196
 197 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that we
 198 ;;; sequentially bind each AUX-VAR to the corresponding AUX-VAL before
 199 ;;; converting the body. If there are no bindings, just convert the
 200 ;;; body, otherwise do one binding and recurse on the rest.
 201 ;;;
 202 ;;; FIXME: This could and probably should be converted to use
 203 ;;; SOURCE-NAME and DEBUG-NAME. But I (WHN) don't use &AUX bindings,
 204 ;;; so I'm not motivated. Patches will be accepted...
 205 (defun ir1-convert-aux-bindings (start cont body aux-vars aux-vals)
 206   (declare (type continuation start cont) (list body aux-vars aux-vals))
 207   (if (null aux-vars)
 208       (ir1-convert-progn-body start cont body)
 209       (let ((fun-cont (make-continuation))
 210             (fun (ir1-convert-lambda-body body
 211                                           (list (first aux-vars))
 212                                           :aux-vars (rest aux-vars)
 213                                           :aux-vals (rest aux-vals)
 214                                           :debug-name (debug-namify
 215                                                        "&AUX bindings ~S"
 216                                                        aux-vars))))
 217         (reference-leaf start fun-cont fun)
 218         (ir1-convert-combination-args fun-cont cont
 219                                       (list (first aux-vals)))))
 220   (values))
 221
 222 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that code to bind
 223 ;;; the SPECVAR for each SVAR to the value of the variable is wrapped
 224 ;;; around the body. If there are no special bindings, we just convert
 225 ;;; the body, otherwise we do one special binding and recurse on the
 226 ;;; rest.
 227 ;;;
 228 ;;; We make a cleanup and introduce it into the lexical environment.
 229 ;;; If there are multiple special bindings, the cleanup for the blocks
 230 ;;; will end up being the innermost one. We force CONT to start a
 231 ;;; block outside of this cleanup, causing cleanup code to be emitted
 232 ;;; when the scope is exited.
 233 (defun ir1-convert-special-bindings (start cont body aux-vars aux-vals svars)
 234   (declare (type continuation start cont)
 235            (list body aux-vars aux-vals svars))
 236   (cond
 237    ((null svars)
 238     (ir1-convert-aux-bindings start cont body aux-vars aux-vals))
 239    (t
 240     (continuation-starts-block cont)
 241     (let ((cleanup (make-cleanup :kind :special-bind))
 242           (var (first svars))
 243           (next-cont (make-continuation))
 244           (nnext-cont (make-continuation)))
 245       (ir1-convert start next-cont
 246                    `(%special-bind ',(lambda-var-specvar var) ,var))
 247       (setf (cleanup-mess-up cleanup) (continuation-use next-cont))
 248       (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 249         (ir1-convert next-cont nnext-cont '(%cleanup-point))
 250         (ir1-convert-special-bindings nnext-cont cont body aux-vars aux-vals
 251                                       (rest svars))))))
 252   (values))
 253
 254 ;;; Create a lambda node out of some code, returning the result. The
 255 ;;; bindings are specified by the list of VAR structures VARS. We deal
 256 ;;; with adding the names to the LEXENV-VARS for the conversion. The
 257 ;;; result is added to the NEW-FUNCTIONALS in the *CURRENT-COMPONENT*
 258 ;;; and linked to the component head and tail.
 259 ;;;
 260 ;;; We detect special bindings here, replacing the original VAR in the
 261 ;;; lambda list with a temporary variable. We then pass a list of the
 262 ;;; special vars to IR1-CONVERT-SPECIAL-BINDINGS, which actually emits
 263 ;;; the special binding code.
 264 ;;;
 265 ;;; We ignore any ARG-INFO in the VARS, trusting that someone else is
 266 ;;; dealing with &nonsense.
 267 ;;;
 268 ;;; AUX-VARS is a list of VAR structures for variables that are to be
 269 ;;; sequentially bound. Each AUX-VAL is a form that is to be evaluated
 270 ;;; to get the initial value for the corresponding AUX-VAR.
 271 (defun ir1-convert-lambda-body (body
 272                                 vars
 273                                 &key
 274                                 aux-vars
 275                                 aux-vals
 276                                 result
 277                                 (source-name '.anonymous.)
 278                                 debug-name
 279                                 (note-lexical-bindings t))
 280   (declare (list body vars aux-vars aux-vals)
 281            (type (or continuation null) result))
 282
 283   ;; We're about to try to put new blocks into *CURRENT-COMPONENT*.
 284   (aver-live-component *current-component*)
 285
 286   (let* ((bind (make-bind))
 287          (lambda (make-lambda :vars vars
 288                               :bind bind
 289                               :%source-name source-name
 290                               :%debug-name debug-name))
 291          (result (or result (make-continuation))))
 292
 293     (continuation-starts-block result)
 294
 295     ;; just to check: This function should fail internal assertions if
 296     ;; we didn't set up a valid debug name above.
 297     ;;
 298     ;; (In SBCL we try to make everything have a debug name, since we
 299     ;; lack the omniscient perspective the original implementors used
 300     ;; to decide which things didn't need one.)
 301     (functional-debug-name lambda)
 302
 303     (setf (lambda-home lambda) lambda)
 304     (collect ((svars)
 305               (new-venv nil cons))
 306
 307       (dolist (var vars)
 308         ;; As far as I can see, LAMBDA-VAR-HOME should never have
 309         ;; been set before. Let's make sure. -- WHN 2001-09-29
 310         (aver (null (lambda-var-home var)))
 311         (setf (lambda-var-home var) lambda)
 312         (let ((specvar (lambda-var-specvar var)))
 313           (cond (specvar
 314                  (svars var)
 315                  (new-venv (cons (leaf-source-name specvar) specvar)))
 316                 (t
 317                  (when note-lexical-bindings
 318                    (note-lexical-binding (leaf-source-name var)))
 319                  (new-venv (cons (leaf-source-name var) var))))))
 320
 321       (let ((*lexenv* (make-lexenv :vars (new-venv)
 322                                    :lambda lambda
 323                                    :cleanup nil)))
 324         (setf (bind-lambda bind) lambda)
 325         (setf (node-lexenv bind) *lexenv*)
 326
 327         (let ((cont1 (make-continuation))
 328               (cont2 (make-continuation)))
 329           (continuation-starts-block cont1)
 330           (link-node-to-previous-continuation bind cont1)
 331           (use-continuation bind cont2)
 332           (ir1-convert-special-bindings cont2 result body
 333                                         aux-vars aux-vals (svars)))
 334
 335         (let ((block (continuation-block result)))
 336           (when block
 337             (let ((return (make-return :result result :lambda lambda))
 338                   (tail-set (make-tail-set :funs (list lambda)))
 339                   (dummy (make-continuation)))
 340               (setf (lambda-tail-set lambda) tail-set)
 341               (setf (lambda-return lambda) return)
 342               (setf (continuation-dest result) return)
 343               (flush-continuation-externally-checkable-type result)
 344               (setf (block-last block) return)
 345               (link-node-to-previous-continuation return result)
 346               (use-continuation return dummy))
 347             (link-blocks block (component-tail *current-component*))))))
 348
 349     (link-blocks (component-head *current-component*) (node-block bind))
 350     (push lambda (component-new-functionals *current-component*))
 351
 352     lambda))
 353
 354 ;;; Entry point CLAMBDAs have a special kind
 355 (defun register-entry-point (entry dispatcher)
 356   (declare (type clambda entry)
 357            (type optional-dispatch dispatcher))
 358   (setf (functional-kind entry) :optional)
 359   (setf (leaf-ever-used entry) t)
 360   (setf (lambda-optional-dispatch entry)
 361         dispatcher)
 362   entry)
 363
 364 ;;; Create the actual entry-point function for an optional entry
 365 ;;; point. The lambda binds copies of each of the VARS, then calls FUN
 366 ;;; with the argument VALS and the DEFAULTS. Presumably the VALS refer
 367 ;;; to the VARS by name. The VALS are passed in the reverse order.
 368 ;;;
 369 ;;; If any of the copies of the vars are referenced more than once,
 370 ;;; then we mark the corresponding var as EVER-USED to inhibit
 371 ;;; "defined but not read" warnings for arguments that are only used
 372 ;;; by default forms.
 373 (defun convert-optional-entry (fun vars vals defaults)
 374   (declare (type clambda fun) (list vars vals defaults))
 375   (let* ((fvars (reverse vars))
 376          (arg-vars (mapcar (lambda (var)
 377                              (make-lambda-var
 378                               :%source-name (leaf-source-name var)
 379                               :type (leaf-type var)
 380                               :where-from (leaf-where-from var)
 381                               :specvar (lambda-var-specvar var)))
 382                            fvars))
 383          (fun (collect ((default-bindings)
 384                         (default-vals))
 385                 (dolist (default defaults)
 386                   (if (constantp default)
 387                       (default-vals default)
 388                       (let ((var (gensym)))
 389                         (default-bindings `(,var ,default))
 390                         (default-vals var))))
 391                 (ir1-convert-lambda-body `((let (,@(default-bindings))
 392                                              (%funcall ,fun
 393                                                        ,@(reverse vals)
 394                                                        ,@(default-vals))))
 395                                          arg-vars
 396                                          :debug-name
 397                                          (debug-namify "&OPTIONAL processor ~D"
 398                                                        (random 100))
 399                                          :note-lexical-bindings nil))))
 400     (mapc (lambda (var arg-var)
 401             (when (cdr (leaf-refs arg-var))
 402               (setf (leaf-ever-used var) t)))
 403           fvars arg-vars)
 404     fun))
 405
 406 ;;; This function deals with supplied-p vars in optional arguments. If
 407 ;;; the there is no supplied-p arg, then we just call
 408 ;;; IR1-CONVERT-HAIRY-ARGS on the remaining arguments, and generate a
 409 ;;; optional entry that calls the result. If there is a supplied-p
 410 ;;; var, then we add it into the default vars and throw a T into the
 411 ;;; entry values. The resulting entry point function is returned.
 412 (defun generate-optional-default-entry (res default-vars default-vals
 413                                         entry-vars entry-vals
 414                                         vars supplied-p-p body
 415                                         aux-vars aux-vals cont
 416                                         source-name debug-name
 417                                         force)
 418   (declare (type optional-dispatch res)
 419            (list default-vars default-vals entry-vars entry-vals vars body
 420                  aux-vars aux-vals)
 421            (type (or continuation null) cont))
 422   (let* ((arg (first vars))
 423          (arg-name (leaf-source-name arg))
 424          (info (lambda-var-arg-info arg))
 425          (default (arg-info-default info))
 426          (supplied-p (arg-info-supplied-p info))
 427          (force (or force
 428                     (not (sb!xc:constantp (arg-info-default info)))))
 429          (ep (if supplied-p
 430                  (ir1-convert-hairy-args
 431                   res
 432                   (list* supplied-p arg default-vars)
 433                   (list* (leaf-source-name supplied-p) arg-name default-vals)
 434                   (cons arg entry-vars)
 435                   (list* t arg-name entry-vals)
 436                   (rest vars) t body aux-vars aux-vals cont
 437                   source-name debug-name
 438                   force)
 439                  (ir1-convert-hairy-args
 440                   res
 441                   (cons arg default-vars)
 442                   (cons arg-name default-vals)
 443                   (cons arg entry-vars)
 444                   (cons arg-name entry-vals)
 445                   (rest vars) supplied-p-p body aux-vars aux-vals cont
 446                   source-name debug-name
 447                   force))))
 448
 449     ;; We want to delay converting the entry, but there exist
 450     ;; problems: hidden references should not be established to
 451     ;; lambdas of kind NIL should not have (otherwise the compiler
 452     ;; might let-convert or delete them) and to variables.
 453     (if (or force
 454             supplied-p-p ; this entry will be of kind NIL
 455             (and (lambda-p ep) (eq (lambda-kind ep) nil)))
 456         (convert-optional-entry ep
 457                                 default-vars default-vals
 458                                 (if supplied-p
 459                                     (list default nil)
 460                                     (list default)))
 461         (delay
 462          (register-entry-point
 463            (convert-optional-entry (force ep)
 464                                    default-vars default-vals
 465                                    (if supplied-p
 466                                        (list default nil)
 467                                        (list default)))
 468            res)))))
 469
 470 ;;; Create the MORE-ENTRY function for the OPTIONAL-DISPATCH RES.
 471 ;;; ENTRY-VARS and ENTRY-VALS describe the fixed arguments. REST is
 472 ;;; the var for any &REST arg. KEYS is a list of the &KEY arg vars.
 473 ;;;
 474 ;;; The most interesting thing that we do is parse keywords. We create
 475 ;;; a bunch of temporary variables to hold the result of the parse,
 476 ;;; and then loop over the supplied arguments, setting the appropriate
 477 ;;; temps for the supplied keyword. Note that it is significant that
 478 ;;; we iterate over the keywords in reverse order --- this implements
 479 ;;; the CL requirement that (when a keyword appears more than once)
 480 ;;; the first value is used.
 481 ;;;
 482 ;;; If there is no supplied-p var, then we initialize the temp to the
 483 ;;; default and just pass the temp into the main entry. Since
 484 ;;; non-constant &KEY args are forcibly given a supplied-p var, we
 485 ;;; know that the default is constant, and thus safe to evaluate out
 486 ;;; of order.
 487 ;;;
 488 ;;; If there is a supplied-p var, then we create temps for both the
 489 ;;; value and the supplied-p, and pass them into the main entry,
 490 ;;; letting it worry about defaulting.
 491 ;;;
 492 ;;; We deal with :ALLOW-OTHER-KEYS by delaying unknown keyword errors
 493 ;;; until we have scanned all the keywords.
 494 (defun convert-more-entry (res entry-vars entry-vals rest morep keys)
 495   (declare (type optional-dispatch res) (list entry-vars entry-vals keys))
 496   (collect ((arg-vars)
 497             (arg-vals (reverse entry-vals))
 498             (temps)
 499             (body))
 500
 501     (dolist (var (reverse entry-vars))
 502       (arg-vars (make-lambda-var :%source-name (leaf-source-name var)
 503                                  :type (leaf-type var)
 504                                  :where-from (leaf-where-from var))))
 505
 506     (let* ((n-context (gensym "N-CONTEXT-"))
 507            (context-temp (make-lambda-var :%source-name n-context))
 508            (n-count (gensym "N-COUNT-"))
 509            (count-temp (make-lambda-var :%source-name n-count
 510                                         :type (specifier-type 'index))))
 511
 512       (arg-vars context-temp count-temp)
 513
 514       (when rest
 515         (arg-vals `(%listify-rest-args ,n-context ,n-count)))
 516       (when morep
 517         (arg-vals n-context)
 518         (arg-vals n-count))
 519
 520       (when (optional-dispatch-keyp res)
 521         (let ((n-index (gensym "N-INDEX-"))
 522               (n-key (gensym "N-KEY-"))
 523               (n-value-temp (gensym "N-VALUE-TEMP-"))
 524               (n-allowp (gensym "N-ALLOWP-"))
 525               (n-losep (gensym "N-LOSEP-"))
 526               (allowp (or (optional-dispatch-allowp res)
 527                           (policy *lexenv* (zerop safety))))
 528               (found-allow-p nil))
 529
 530           (temps `(,n-index (1- ,n-count)) n-key n-value-temp)
 531           (body `(declare (fixnum ,n-index) (ignorable ,n-key ,n-value-temp)))
 532
 533           (collect ((tests))
 534             (dolist (key keys)
 535               (let* ((info (lambda-var-arg-info key))
 536                      (default (arg-info-default info))
 537                      (keyword (arg-info-key info))
 538                      (supplied-p (arg-info-supplied-p info))
 539                      (n-value (gensym "N-VALUE-"))
 540                      (clause (cond (supplied-p
 541                                     (let ((n-supplied (gensym "N-SUPPLIED-")))
 542                                       (temps n-supplied)
 543                                       (arg-vals n-value n-supplied)
 544                                       `((eq ,n-key ',keyword)
 545                                         (setq ,n-supplied t)
 546                                         (setq ,n-value ,n-value-temp))))
 547                                    (t
 548                                     (arg-vals n-value)
 549                                     `((eq ,n-key ',keyword)
 550                                       (setq ,n-value ,n-value-temp))))))
 551                 (when (and (not allowp) (eq keyword :allow-other-keys))
 552                   (setq found-allow-p t)
 553                   (setq clause
 554                         (append clause `((setq ,n-allowp ,n-value-temp)))))
 555
 556                 (temps `(,n-value ,default))
 557                 (tests clause)))
 558
 559             (unless allowp
 560               (temps n-allowp n-losep)
 561               (unless found-allow-p
 562                 (tests `((eq ,n-key :allow-other-keys)
 563                          (setq ,n-allowp ,n-value-temp))))
 564               (tests `(t
 565                        (setq ,n-losep ,n-key))))
 566
 567             (body
 568              `(when (oddp ,n-count)
 569                 (%odd-key-args-error)))
 570
 571             (body
 572              `(locally
 573                 (declare (optimize (safety 0)))
 574                 (loop
 575                   (when (minusp ,n-index) (return))
 576                   (setf ,n-value-temp (%more-arg ,n-context ,n-index))
 577                   (decf ,n-index)
 578                   (setq ,n-key (%more-arg ,n-context ,n-index))
 579                   (decf ,n-index)
 580                   (cond ,@(tests)))))
 581
 582             (unless allowp
 583               (body `(when (and ,n-losep (not ,n-allowp))
 584                        (%unknown-key-arg-error ,n-losep)))))))
 585
 586       (let ((ep (ir1-convert-lambda-body
 587                  `((let ,(temps)
 588                      ,@(body)
 589                      (%funcall ,(optional-dispatch-main-entry res)
 590                                ,@(arg-vals))))
 591                  (arg-vars)
 592                  :debug-name (debug-namify "~S processing" '&more)
 593                  :note-lexical-bindings nil)))
 594         (setf (optional-dispatch-more-entry res)
 595               (register-entry-point ep res)))))
 596
 597   (values))
 598
 599 ;;; This is called by IR1-CONVERT-HAIRY-ARGS when we run into a &REST
 600 ;;; or &KEY arg. The arguments are similar to that function, but we
 601 ;;; split off any &REST arg and pass it in separately. REST is the
 602 ;;; &REST arg var, or NIL if there is no &REST arg. KEYS is a list of
 603 ;;; the &KEY argument vars.
 604 ;;;
 605 ;;; When there are &KEY arguments, we introduce temporary gensym
 606 ;;; variables to hold the values while keyword defaulting is in
 607 ;;; progress to get the required sequential binding semantics.
 608 ;;;
 609 ;;; This gets interesting mainly when there are &KEY arguments with
 610 ;;; supplied-p vars or non-constant defaults. In either case, pass in
 611 ;;; a supplied-p var. If the default is non-constant, we introduce an
 612 ;;; IF in the main entry that tests the supplied-p var and decides
 613 ;;; whether to evaluate the default or not. In this case, the real
 614 ;;; incoming value is NIL, so we must union NULL with the declared
 615 ;;; type when computing the type for the main entry's argument.
 616 (defun ir1-convert-more (res default-vars default-vals entry-vars entry-vals
 617                              rest more-context more-count keys supplied-p-p
 618                              body aux-vars aux-vals cont
 619                              source-name debug-name)
 620   (declare (type optional-dispatch res)
 621            (list default-vars default-vals entry-vars entry-vals keys body
 622                  aux-vars aux-vals)
 623            (type (or continuation null) cont))
 624   (collect ((main-vars (reverse default-vars))
 625             (main-vals default-vals cons)
 626             (bind-vars)
 627             (bind-vals))
 628     (when rest
 629       (main-vars rest)
 630       (main-vals '()))
 631     (when more-context
 632       (main-vars more-context)
 633       (main-vals nil)
 634       (main-vars more-count)
 635       (main-vals 0))
 636
 637     (dolist (key keys)
 638       (let* ((info (lambda-var-arg-info key))
 639              (default (arg-info-default info))
 640              (hairy-default (not (sb!xc:constantp default)))
 641              (supplied-p (arg-info-supplied-p info))
 642              (n-val (make-symbol (format nil
 643                                          "~A-DEFAULTING-TEMP"
 644                                          (leaf-source-name key))))
 645              (key-type (leaf-type key))
 646              (val-temp (make-lambda-var
 647                         :%source-name n-val
 648                         :type (if hairy-default
 649                                   (type-union key-type (specifier-type 'null))
 650                                   key-type))))
 651         (main-vars val-temp)
 652         (bind-vars key)
 653         (cond ((or hairy-default supplied-p)
 654                (let* ((n-supplied (gensym "N-SUPPLIED-"))
 655                       (supplied-temp (make-lambda-var
 656                                       :%source-name n-supplied)))
 657                  (unless supplied-p
 658                    (setf (arg-info-supplied-p info) supplied-temp))
 659                  (when hairy-default
 660                    (setf (arg-info-default info) nil))
 661                  (main-vars supplied-temp)
 662                  (cond (hairy-default
 663                         (main-vals nil nil)
 664                         (bind-vals `(if ,n-supplied ,n-val ,default)))
 665                        (t
 666                         (main-vals default nil)
 667                         (bind-vals n-val)))
 668                  (when supplied-p
 669                    (bind-vars supplied-p)
 670                    (bind-vals n-supplied))))
 671               (t
 672                (main-vals (arg-info-default info))
 673                (bind-vals n-val)))))
 674
 675     (let* ((main-entry (ir1-convert-lambda-body
 676                         body (main-vars)
 677                         :aux-vars (append (bind-vars) aux-vars)
 678                         :aux-vals (append (bind-vals) aux-vals)
 679                         :result cont
 680                         :debug-name (debug-namify "varargs entry for ~A"
 681                                                   (as-debug-name source-name
 682                                                                  debug-name))))
 683            (last-entry (convert-optional-entry main-entry default-vars
 684                                                (main-vals) ())))
 685       (setf (optional-dispatch-main-entry res)
 686             (register-entry-point main-entry res))
 687       (convert-more-entry res entry-vars entry-vals rest more-context keys)
 688
 689       (push (register-entry-point
 690              (if supplied-p-p
 691                 (convert-optional-entry last-entry entry-vars entry-vals ())
 692                 last-entry)
 693              res)
 694             (optional-dispatch-entry-points res))
 695       last-entry)))
 696
 697 ;;; This function generates the entry point functions for the
 698 ;;; OPTIONAL-DISPATCH RES. We accomplish this by recursion on the list
 699 ;;; of arguments, analyzing the arglist on the way down and generating
 700 ;;; entry points on the way up.
 701 ;;;
 702 ;;; DEFAULT-VARS is a reversed list of all the argument vars processed
 703 ;;; so far, including supplied-p vars. DEFAULT-VALS is a list of the
 704 ;;; names of the DEFAULT-VARS.
 705 ;;;
 706 ;;; ENTRY-VARS is a reversed list of processed argument vars,
 707 ;;; excluding supplied-p vars. ENTRY-VALS is a list things that can be
 708 ;;; evaluated to get the values for all the vars from the ENTRY-VARS.
 709 ;;; It has the var name for each required or optional arg, and has T
 710 ;;; for each supplied-p arg.
 711 ;;;
 712 ;;; VARS is a list of the LAMBDA-VAR structures for arguments that
 713 ;;; haven't been processed yet. SUPPLIED-P-P is true if a supplied-p
 714 ;;; argument has already been processed; only in this case are the
 715 ;;; DEFAULT-XXX and ENTRY-XXX different.
 716 ;;;
 717 ;;; The result at each point is a lambda which should be called by the
 718 ;;; above level to default the remaining arguments and evaluate the
 719 ;;; body. We cause the body to be evaluated by converting it and
 720 ;;; returning it as the result when the recursion bottoms out.
 721 ;;;
 722 ;;; Each level in the recursion also adds its entry point function to
 723 ;;; the result OPTIONAL-DISPATCH. For most arguments, the defaulting
 724 ;;; function and the entry point function will be the same, but when
 725 ;;; SUPPLIED-P args are present they may be different.
 726 ;;;
 727 ;;; When we run into a &REST or &KEY arg, we punt out to
 728 ;;; IR1-CONVERT-MORE, which finishes for us in this case.
 729 (defun ir1-convert-hairy-args (res default-vars default-vals
 730                                entry-vars entry-vals
 731                                vars supplied-p-p body aux-vars
 732                                aux-vals cont
 733                                source-name debug-name
 734                                force)
 735   (declare (type optional-dispatch res)
 736            (list default-vars default-vals entry-vars entry-vals vars body
 737                  aux-vars aux-vals)
 738            (type (or continuation null) cont))
 739   (cond ((not vars)
 740          (if (optional-dispatch-keyp res)
 741              ;; Handle &KEY with no keys...
 742              (ir1-convert-more res default-vars default-vals
 743                                entry-vars entry-vals
 744                                nil nil nil vars supplied-p-p body aux-vars
 745                                aux-vals cont source-name debug-name)
 746              (let ((fun (ir1-convert-lambda-body
 747                          body (reverse default-vars)
 748                          :aux-vars aux-vars
 749                          :aux-vals aux-vals
 750                          :result cont
 751                          :debug-name (debug-namify
 752                                       "hairy arg processor for ~A"
 753                                       (as-debug-name source-name
 754                                                      debug-name)))))
 755                (setf (optional-dispatch-main-entry res) fun)
 756                (register-entry-point fun res)
 757                (push (if supplied-p-p
 758                          (register-entry-point
 759                           (convert-optional-entry fun entry-vars entry-vals ())
 760                           res)
 761                           fun)
 762                      (optional-dispatch-entry-points res))
 763                fun)))
 764         ((not (lambda-var-arg-info (first vars)))
 765          (let* ((arg (first vars))
 766                 (nvars (cons arg default-vars))
 767                 (nvals (cons (leaf-source-name arg) default-vals)))
 768            (ir1-convert-hairy-args res nvars nvals nvars nvals
 769                                    (rest vars) nil body aux-vars aux-vals
 770                                    cont
 771                                    source-name debug-name
 772                                    nil)))
 773         (t
 774          (let* ((arg (first vars))
 775                 (info (lambda-var-arg-info arg))
 776                 (kind (arg-info-kind info)))
 777            (ecase kind
 778              (:optional
 779               (let ((ep (generate-optional-default-entry
 780                          res default-vars default-vals
 781                          entry-vars entry-vals vars supplied-p-p body
 782                          aux-vars aux-vals cont
 783                          source-name debug-name
 784                          force)))
 785                 ;; See GENERATE-OPTIONAL-DEFAULT-ENTRY.
 786                 (push (if (lambda-p ep)
 787                           (register-entry-point
 788                            (if supplied-p-p
 789                                (convert-optional-entry ep entry-vars entry-vals ())
 790                                ep)
 791                            res)
 792                           (progn (aver (not supplied-p-p))
 793                                  ep))
 794                       (optional-dispatch-entry-points res))
 795                 ep))
 796              (:rest
 797               (ir1-convert-more res default-vars default-vals
 798                                 entry-vars entry-vals
 799                                 arg nil nil (rest vars) supplied-p-p body
 800                                 aux-vars aux-vals cont
 801                                 source-name debug-name))
 802              (:more-context
 803               (ir1-convert-more res default-vars default-vals
 804                                 entry-vars entry-vals
 805                                 nil arg (second vars) (cddr vars) supplied-p-p
 806                                 body aux-vars aux-vals cont
 807                                 source-name debug-name))
 808              (:keyword
 809               (ir1-convert-more res default-vars default-vals
 810                                 entry-vars entry-vals
 811                                 nil nil nil vars supplied-p-p body aux-vars
 812                                 aux-vals cont source-name debug-name)))))))
 813
 814 ;;; This function deals with the case where we have to make an
 815 ;;; OPTIONAL-DISPATCH to represent a LAMBDA. We cons up the result and
 816 ;;; call IR1-CONVERT-HAIRY-ARGS to do the work. When it is done, we
 817 ;;; figure out the MIN-ARGS and MAX-ARGS.
 818 (defun ir1-convert-hairy-lambda (body vars keyp allowp aux-vars aux-vals cont
 819                                       &key
 820                                       (source-name '.anonymous.)
 821                                       (debug-name (debug-namify
 822                                                    "OPTIONAL-DISPATCH ~S"
 823                                                    vars)))
 824   (declare (list body vars aux-vars aux-vals) (type continuation cont))
 825   (let ((res (make-optional-dispatch :arglist vars
 826                                      :allowp allowp
 827                                      :keyp keyp
 828                                      :%source-name source-name
 829                                      :%debug-name debug-name
 830                                      :plist `(:ir1-environment
 831                                               (,*lexenv*
 832                                                ,*current-path*))))
 833         (min (or (position-if #'lambda-var-arg-info vars) (length vars))))
 834     (aver-live-component *current-component*)
 835     (push res (component-new-functionals *current-component*))
 836     (ir1-convert-hairy-args res () () () () vars nil body aux-vars aux-vals
 837                             cont source-name debug-name nil)
 838     (setf (optional-dispatch-min-args res) min)
 839     (setf (optional-dispatch-max-args res)
 840           (+ (1- (length (optional-dispatch-entry-points res))) min))
 841
 842     res))
 843
 844 ;;; Convert a LAMBDA form into a LAMBDA leaf or an OPTIONAL-DISPATCH leaf.
 845 (defun ir1-convert-lambda (form &key (source-name '.anonymous.)
 846                                      debug-name
 847                                      allow-debug-catch-tag)
 848
 849   (unless (consp form)
 850     (compiler-error "A ~S was found when expecting a lambda expression:~%  ~S"
 851                     (type-of form)
 852                     form))
 853   (unless (eq (car form) 'lambda)
 854     (compiler-error "~S was expected but ~S was found:~%  ~S"
 855                     'lambda
 856                     (car form)
 857                     form))
 858   (unless (and (consp (cdr form)) (listp (cadr form)))
 859     (compiler-error
 860      "The lambda expression has a missing or non-list lambda list:~%  ~S"
 861      form))
 862
 863   (let ((*allow-debug-catch-tag* (and *allow-debug-catch-tag* allow-debug-catch-tag)))
 864     (multiple-value-bind (vars keyp allow-other-keys aux-vars aux-vals)
 865         (make-lambda-vars (cadr form))
 866       (multiple-value-bind (forms decls) (parse-body (cddr form))
 867         (let* ((result-cont (make-continuation))
 868                (*lexenv* (process-decls decls
 869                                         (append aux-vars vars)
 870                                         nil result-cont))
 871                (forms (if (and *allow-debug-catch-tag*
 872                                (policy *lexenv* (= insert-debug-catch 3)))
 873                           `((catch (make-symbol "SB-DEBUG-CATCH-TAG")
 874                               ,@forms))
 875                           forms))
 876                (res (if (or (find-if #'lambda-var-arg-info vars) keyp)
 877                         (ir1-convert-hairy-lambda forms vars keyp
 878                                                   allow-other-keys
 879                                                   aux-vars aux-vals result-cont
 880                                                   :source-name source-name
 881                                                   :debug-name debug-name)
 882                         (ir1-convert-lambda-body forms vars
 883                                                  :aux-vars aux-vars
 884                                                  :aux-vals aux-vals
 885                                                  :result result-cont
 886                                                  :source-name source-name
 887                                                  :debug-name debug-name))))
 888           (setf (functional-inline-expansion res) form)
 889           (setf (functional-arg-documentation res) (cadr form))
 890           res)))))
 891
 892 ;;; helper for LAMBDA-like things, to massage them into a form
 893 ;;; suitable for IR1-CONVERT-LAMBDA.
 894 ;;;
 895 ;;; KLUDGE: We cons up a &REST list here, maybe for no particularly
 896 ;;; good reason.  It's probably lost in the noise of all the other
 897 ;;; consing, but it's still inelegant.  And we force our called
 898 ;;; functions to do full runtime keyword parsing, ugh.  -- CSR,
 899 ;;; 2003-01-25
 900 (defun ir1-convert-lambdalike (thing &rest args
 901                                &key (source-name '.anonymous.)
 902                                debug-name allow-debug-catch-tag)
 903   (declare (ignorable source-name debug-name allow-debug-catch-tag))
 904   (ecase (car thing)
 905     ((lambda) (apply #'ir1-convert-lambda thing args))
 906     ((instance-lambda)
 907      (let ((res (apply #'ir1-convert-lambda
 908                        `(lambda ,@(cdr thing)) args)))
 909        (setf (getf (functional-plist res) :fin-function) t)
 910        res))
 911     ((named-lambda)
 912      (let ((name (cadr thing)))
 913        (if (legal-fun-name-p name)
 914            (let ((res (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 915                              :source-name name
 916                              :debug-name nil
 917                              args)))
 918              (assert-global-function-definition-type name res)
 919              res)
 920            (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 921                   :debug-name name args))))
 922     ((lambda-with-lexenv) (apply #'ir1-convert-inline-lambda thing args))))
 923 \f
 924 ;;;; defining global functions
 925
 926 ;;; Convert FUN as a lambda in the null environment, but use the
 927 ;;; current compilation policy. Note that FUN may be a
 928 ;;; LAMBDA-WITH-LEXENV, so we may have to augment the environment to
 929 ;;; reflect the state at the definition site.
 930 (defun ir1-convert-inline-lambda (fun &key
 931                                       (source-name '.anonymous.)
 932                                       debug-name
 933                                       allow-debug-catch-tag)
 934   (destructuring-bind (decls macros symbol-macros &rest body)
 935                       (if (eq (car fun) 'lambda-with-lexenv)
 936                           (cdr fun)
 937                           `(() () () . ,(cdr fun)))
 938     (let ((*lexenv* (make-lexenv
 939                      :default (process-decls decls nil nil
 940                                              (make-continuation)
 941                                              (make-null-lexenv))
 942                      :vars (copy-list symbol-macros)
 943                      :funs (mapcar (lambda (x)
 944                                      `(,(car x) .
 945                                        (macro . ,(coerce (cdr x) 'function))))
 946                                    macros)
 947                      :policy (lexenv-policy *lexenv*))))
 948       (ir1-convert-lambda `(lambda ,@body)
 949                           :source-name source-name
 950                           :debug-name debug-name
 951                           :allow-debug-catch-tag nil))))
 952
 953 ;;; Get a DEFINED-FUN object for a function we are about to define. If
 954 ;;; the function has been forward referenced, then substitute for the
 955 ;;; previous references.
 956 (defun get-defined-fun (name)
 957   (proclaim-as-fun-name name)
 958   (let ((found (find-free-fun name "shouldn't happen! (defined-fun)")))
 959     (note-name-defined name :function)
 960     (cond ((not (defined-fun-p found))
 961            (aver (not (info :function :inlinep name)))
 962            (let* ((where-from (leaf-where-from found))
 963                   (res (make-defined-fun
 964                         :%source-name name
 965                         :where-from (if (eq where-from :declared)
 966                                         :declared :defined)
 967                         :type (leaf-type found))))
 968              (substitute-leaf res found)
 969              (setf (gethash name *free-funs*) res)))
 970           ;; If *FREE-FUNS* has a previously converted definition
 971           ;; for this name, then blow it away and try again.
 972           ((defined-fun-functional found)
 973            (remhash name *free-funs*)
 974            (get-defined-fun name))
 975           (t found))))
 976
 977 ;;; Check a new global function definition for consistency with
 978 ;;; previous declaration or definition, and assert argument/result
 979 ;;; types if appropriate. This assertion is suppressed by the
 980 ;;; EXPLICIT-CHECK attribute, which is specified on functions that
 981 ;;; check their argument types as a consequence of type dispatching.
 982 ;;; This avoids redundant checks such as NUMBERP on the args to +, etc.
 983 (defun assert-new-definition (var fun)
 984   (let ((type (leaf-type var))
 985         (for-real (eq (leaf-where-from var) :declared))
 986         (info (info :function :info (leaf-source-name var))))
 987     (assert-definition-type
 988      fun type
 989      ;; KLUDGE: Common Lisp is such a dynamic language that in general
 990      ;; all we can do here in general is issue a STYLE-WARNING. It
 991      ;; would be nice to issue a full WARNING in the special case of
 992      ;; of type mismatches within a compilation unit (as in section
 993      ;; 3.2.2.3 of the spec) but at least as of sbcl-0.6.11, we don't
 994      ;; keep track of whether the mismatched data came from the same
 995      ;; compilation unit, so we can't do that. -- WHN 2001-02-11
 996      :lossage-fun #'compiler-style-warn
 997      :unwinnage-fun (cond (info #'compiler-style-warn)
 998                           (for-real #'compiler-notify)
 999                           (t nil))
1000      :really-assert
1001      (and for-real
1002           (not (and info
1003                     (ir1-attributep (fun-info-attributes info)
1004                                     explicit-check))))
1005      :where (if for-real
1006                 "previous declaration"
1007                 "previous definition"))))
1008
1009 ;;; Convert a lambda doing all the basic stuff we would do if we were
1010 ;;; converting a DEFUN. In the old CMU CL system, this was used both
1011 ;;; by the %DEFUN translator and for global inline expansion, but
1012 ;;; since sbcl-0.pre7.something %DEFUN does things differently.
1013 ;;; FIXME: And now it's probably worth rethinking whether this
1014 ;;; function is a good idea.
1015 ;;;
1016 ;;; Unless a :INLINE function, we temporarily clobber the inline
1017 ;;; expansion. This prevents recursive inline expansion of
1018 ;;; opportunistic pseudo-inlines.
1019 (defun ir1-convert-lambda-for-defun (lambda var expansion converter)
1020   (declare (cons lambda) (function converter) (type defined-fun var))
1021   (let ((var-expansion (defined-fun-inline-expansion var)))
1022     (unless (eq (defined-fun-inlinep var) :inline)
1023       (setf (defined-fun-inline-expansion var) nil))
1024     (let* ((name (leaf-source-name var))
1025            (fun (funcall converter lambda
1026                          :source-name name))
1027            (fun-info (info :function :info name)))
1028       (setf (functional-inlinep fun) (defined-fun-inlinep var))
1029       (assert-new-definition var fun)
1030       (setf (defined-fun-inline-expansion var) var-expansion)
1031       ;; If definitely not an interpreter stub, then substitute for
1032       ;; any old references.
1033       (unless (or (eq (defined-fun-inlinep var) :notinline)
1034                   (not *block-compile*)
1035                   (and fun-info
1036                        (or (fun-info-transforms fun-info)
1037                            (fun-info-templates fun-info)
1038                            (fun-info-ir2-convert fun-info))))
1039         (substitute-leaf fun var)
1040         ;; If in a simple environment, then we can allow backward
1041         ;; references to this function from following top level forms.
1042         (when expansion (setf (defined-fun-functional var) fun)))
1043       fun)))
1044
1045 ;;; the even-at-compile-time part of DEFUN
1046 ;;;
1047 ;;; The INLINE-EXPANSION is a LAMBDA-WITH-LEXENV, or NIL if there is
1048 ;;; no inline expansion.
1049 (defun %compiler-defun (name lambda-with-lexenv)
1050
1051   (let ((defined-fun nil)) ; will be set below if we're in the compiler
1052
1053     (when (boundp '*lexenv*) ; when in the compiler
1054       (when sb!xc:*compile-print*
1055         (compiler-mumble "~&; recognizing DEFUN ~S~%" name))
1056       (remhash name *free-funs*)
1057       (setf defined-fun (get-defined-fun name)))
1058
1059     (become-defined-fun-name name)
1060
1061     (cond (lambda-with-lexenv
1062            (setf (info :function :inline-expansion-designator name)
1063                  lambda-with-lexenv)
1064            (when defined-fun
1065              (setf (defined-fun-inline-expansion defined-fun)
1066                    lambda-with-lexenv)))
1067           (t
1068            (clear-info :function :inline-expansion-designator name)))
1069
1070     ;; old CMU CL comment:
1071     ;;   If there is a type from a previous definition, blast it,
1072     ;;   since it is obsolete.
1073     (when (and defined-fun
1074                (eq (leaf-where-from defined-fun) :defined))
1075       (setf (leaf-type defined-fun)
1076             ;; FIXME: If this is a block compilation thing, shouldn't
1077             ;; we be setting the type to the full derived type for the
1078             ;; definition, instead of this most general function type?
1079             (specifier-type 'function))))
1080
1081   (values))
1082
1083 \f
1084 ;;; Entry point utilities
1085
1086 ;;; Return a function for the Nth entry point.
1087 (defun optional-dispatch-entry-point-fun (dispatcher n)
1088   (declare (type optional-dispatch dispatcher)
1089            (type unsigned-byte n))
1090   (let* ((env (getf (optional-dispatch-plist dispatcher) :ir1-environment))
1091          (*lexenv* (first env))
1092          (*current-path* (second env)))
1093     (force (nth n (optional-dispatch-entry-points dispatcher)))))