src/compiler/ir1tran-lambda.lisp

   1 ;;;; This file contains code which does the translation of lambda
   2 ;;;; forms from Lisp code to the first intermediate representation
   3 ;;;; (IR1).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;;; LAMBDA hackery
  17
  18 ;;;; Note: Take a look at the compiler-overview.tex section on "Hairy
  19 ;;;; function representation" before you seriously mess with this
  20 ;;;; stuff.
  21
  22 ;;; Verify that the NAME is a legal name for a variable and return a
  23 ;;; VAR structure for it, filling in info if it is globally special.
  24 ;;; If it is losing, we punt with a COMPILER-ERROR. NAMES-SO-FAR is a
  25 ;;; list of names which have previously been bound. If the NAME is in
  26 ;;; this list, then we error out.
  27 (declaim (ftype (sfunction (t list) lambda-var) varify-lambda-arg))
  28 (defun varify-lambda-arg (name names-so-far)
  29   (declare (inline member))
  30   (unless (symbolp name)
  31     (compiler-error "The lambda variable ~S is not a symbol." name))
  32   (when (member name names-so-far :test #'eq)
  33     (compiler-error "The variable ~S occurs more than once in the lambda list."
  34                     name))
  35   (let ((kind (info :variable :kind name)))
  36     (when (or (keywordp name) (eq kind :constant))
  37       (compiler-error "The name of the lambda variable ~S is already in use to name a constant."
  38                       name))
  39     (cond ((eq kind :special)
  40            (let ((specvar (find-free-var name)))
  41              (make-lambda-var :%source-name name
  42                               :type (leaf-type specvar)
  43                               :where-from (leaf-where-from specvar)
  44                               :specvar specvar)))
  45           (t
  46            (make-lambda-var :%source-name name)))))
  47
  48 ;;; Make the default keyword for a &KEY arg, checking that the keyword
  49 ;;; isn't already used by one of the VARS.
  50 (declaim (ftype (sfunction (symbol list t) symbol) make-keyword-for-arg))
  51 (defun make-keyword-for-arg (symbol vars keywordify)
  52   (let ((key (if (and keywordify (not (keywordp symbol)))
  53                  (keywordicate symbol)
  54                  symbol)))
  55     (dolist (var vars)
  56       (let ((info (lambda-var-arg-info var)))
  57         (when (and info
  58                    (eq (arg-info-kind info) :keyword)
  59                    (eq (arg-info-key info) key))
  60           (compiler-error
  61            "The keyword ~S appears more than once in the lambda list."
  62            key))))
  63     key))
  64
  65 ;;; Parse a lambda list into a list of VAR structures, stripping off
  66 ;;; any &AUX bindings. Each arg name is checked for legality, and
  67 ;;; duplicate names are checked for. If an arg is globally special,
  68 ;;; the var is marked as :SPECIAL instead of :LEXICAL. &KEY,
  69 ;;; &OPTIONAL and &REST args are annotated with an ARG-INFO structure
  70 ;;; which contains the extra information. If we hit something losing,
  71 ;;; we bug out with COMPILER-ERROR. These values are returned:
  72 ;;;  1. a list of the var structures for each top level argument;
  73 ;;;  2. a flag indicating whether &KEY was specified;
  74 ;;;  3. a flag indicating whether other &KEY args are allowed;
  75 ;;;  4. a list of the &AUX variables; and
  76 ;;;  5. a list of the &AUX values.
  77 (declaim (ftype (sfunction (list) (values list boolean boolean list list))
  78                 make-lambda-vars))
  79 (defun make-lambda-vars (list)
  80   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
  81                         morep more-context more-count)
  82       (parse-lambda-list list)
  83     (declare (ignore auxp)) ; since we just iterate over AUX regardless
  84     (collect ((vars)
  85               (names-so-far)
  86               (aux-vars)
  87               (aux-vals))
  88       (flet (;; PARSE-DEFAULT deals with defaults and supplied-p args
  89              ;; for optionals and keywords args.
  90              (parse-default (spec info)
  91                (when (consp (cdr spec))
  92                  (setf (arg-info-default info) (second spec))
  93                  (when (consp (cddr spec))
  94                    (let* ((supplied-p (third spec))
  95                           (supplied-var (varify-lambda-arg supplied-p
  96                                                            (names-so-far))))
  97                      (setf (arg-info-supplied-p info) supplied-var)
  98                      (names-so-far supplied-p)
  99                      (when (> (length (the list spec)) 3)
 100                        (compiler-error
 101                         "The list ~S is too long to be an arg specifier."
 102                         spec)))))))
 103
 104         (dolist (name required)
 105           (let ((var (varify-lambda-arg name (names-so-far))))
 106             (vars var)
 107             (names-so-far name)))
 108
 109         (dolist (spec optional)
 110           (if (atom spec)
 111               (let ((var (varify-lambda-arg spec (names-so-far))))
 112                 (setf (lambda-var-arg-info var)
 113                       (make-arg-info :kind :optional))
 114                 (vars var)
 115                 (names-so-far spec))
 116               (let* ((name (first spec))
 117                      (var (varify-lambda-arg name (names-so-far)))
 118                      (info (make-arg-info :kind :optional)))
 119                 (setf (lambda-var-arg-info var) info)
 120                 (vars var)
 121                 (names-so-far name)
 122                 (parse-default spec info))))
 123
 124         (when restp
 125           (let ((var (varify-lambda-arg rest (names-so-far))))
 126             (setf (lambda-var-arg-info var) (make-arg-info :kind :rest))
 127             (vars var)
 128             (names-so-far rest)))
 129
 130         (when morep
 131           (let ((var (varify-lambda-arg more-context (names-so-far))))
 132             (setf (lambda-var-arg-info var)
 133                   (make-arg-info :kind :more-context))
 134             (vars var)
 135             (names-so-far more-context))
 136           (let ((var (varify-lambda-arg more-count (names-so-far))))
 137             (setf (lambda-var-arg-info var)
 138                   (make-arg-info :kind :more-count))
 139             (vars var)
 140             (names-so-far more-count)))
 141
 142         (dolist (spec keys)
 143           (cond
 144            ((atom spec)
 145             (let ((var (varify-lambda-arg spec (names-so-far))))
 146               (setf (lambda-var-arg-info var)
 147                     (make-arg-info :kind :keyword
 148                                    :key (make-keyword-for-arg spec
 149                                                               (vars)
 150                                                               t)))
 151               (vars var)
 152               (names-so-far spec)))
 153            ((atom (first spec))
 154             (let* ((name (first spec))
 155                    (var (varify-lambda-arg name (names-so-far)))
 156                    (info (make-arg-info
 157                           :kind :keyword
 158                           :key (make-keyword-for-arg name (vars) t))))
 159               (setf (lambda-var-arg-info var) info)
 160               (vars var)
 161               (names-so-far name)
 162               (parse-default spec info)))
 163            (t
 164             (let ((head (first spec)))
 165               (unless (proper-list-of-length-p head 2)
 166                 (error "malformed &KEY argument specifier: ~S" spec))
 167               (let* ((name (second head))
 168                      (var (varify-lambda-arg name (names-so-far)))
 169                      (info (make-arg-info
 170                             :kind :keyword
 171                             :key (make-keyword-for-arg (first head)
 172                                                        (vars)
 173                                                        nil))))
 174                 (setf (lambda-var-arg-info var) info)
 175                 (vars var)
 176                 (names-so-far name)
 177                 (parse-default spec info))))))
 178
 179         (dolist (spec aux)
 180           (cond ((atom spec)
 181                  (let ((var (varify-lambda-arg spec nil)))
 182                    (aux-vars var)
 183                    (aux-vals nil)
 184                    (names-so-far spec)))
 185                 (t
 186                  (unless (proper-list-of-length-p spec 1 2)
 187                    (compiler-error "malformed &AUX binding specifier: ~S"
 188                                    spec))
 189                  (let* ((name (first spec))
 190                         (var (varify-lambda-arg name nil)))
 191                    (aux-vars var)
 192                    (aux-vals (second spec))
 193                    (names-so-far name)))))
 194
 195         (values (vars) keyp allowp (aux-vars) (aux-vals))))))
 196
 197 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that we
 198 ;;; sequentially bind each AUX-VAR to the corresponding AUX-VAL before
 199 ;;; converting the body. If there are no bindings, just convert the
 200 ;;; body, otherwise do one binding and recurse on the rest.
 201 ;;;
 202 ;;; FIXME: This could and probably should be converted to use
 203 ;;; SOURCE-NAME and DEBUG-NAME. But I (WHN) don't use &AUX bindings,
 204 ;;; so I'm not motivated. Patches will be accepted...
 205 (defun ir1-convert-aux-bindings (start cont body aux-vars aux-vals)
 206   (declare (type continuation start cont) (list body aux-vars aux-vals))
 207   (if (null aux-vars)
 208       (ir1-convert-progn-body start cont body)
 209       (let ((fun-cont (make-continuation))
 210             (fun (ir1-convert-lambda-body body
 211                                           (list (first aux-vars))
 212                                           :aux-vars (rest aux-vars)
 213                                           :aux-vals (rest aux-vals)
 214                                           :debug-name (debug-namify
 215                                                        "&AUX bindings ~S"
 216                                                        aux-vars))))
 217         (reference-leaf start fun-cont fun)
 218         (ir1-convert-combination-args fun-cont cont
 219                                       (list (first aux-vals)))))
 220   (values))
 221
 222 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that code to bind
 223 ;;; the SPECVAR for each SVAR to the value of the variable is wrapped
 224 ;;; around the body. If there are no special bindings, we just convert
 225 ;;; the body, otherwise we do one special binding and recurse on the
 226 ;;; rest.
 227 ;;;
 228 ;;; We make a cleanup and introduce it into the lexical environment.
 229 ;;; If there are multiple special bindings, the cleanup for the blocks
 230 ;;; will end up being the innermost one. We force CONT to start a
 231 ;;; block outside of this cleanup, causing cleanup code to be emitted
 232 ;;; when the scope is exited.
 233 (defun ir1-convert-special-bindings (start cont body aux-vars aux-vals svars)
 234   (declare (type continuation start cont)
 235            (list body aux-vars aux-vals svars))
 236   (cond
 237    ((null svars)
 238     (ir1-convert-aux-bindings start cont body aux-vars aux-vals))
 239    (t
 240     (continuation-starts-block cont)
 241     (let ((cleanup (make-cleanup :kind :special-bind))
 242           (var (first svars))
 243           (next-cont (make-continuation))
 244           (nnext-cont (make-continuation)))
 245       (ir1-convert start next-cont
 246                    `(%special-bind ',(lambda-var-specvar var) ,var))
 247       (setf (cleanup-mess-up cleanup) (continuation-use next-cont))
 248       (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 249         (ir1-convert next-cont nnext-cont '(%cleanup-point))
 250         (ir1-convert-special-bindings nnext-cont cont body aux-vars aux-vals
 251                                       (rest svars))))))
 252   (values))
 253
 254 ;;; Create a lambda node out of some code, returning the result. The
 255 ;;; bindings are specified by the list of VAR structures VARS. We deal
 256 ;;; with adding the names to the LEXENV-VARS for the conversion. The
 257 ;;; result is added to the NEW-FUNCTIONALS in the *CURRENT-COMPONENT*
 258 ;;; and linked to the component head and tail.
 259 ;;;
 260 ;;; We detect special bindings here, replacing the original VAR in the
 261 ;;; lambda list with a temporary variable. We then pass a list of the
 262 ;;; special vars to IR1-CONVERT-SPECIAL-BINDINGS, which actually emits
 263 ;;; the special binding code.
 264 ;;;
 265 ;;; We ignore any ARG-INFO in the VARS, trusting that someone else is
 266 ;;; dealing with &nonsense.
 267 ;;;
 268 ;;; AUX-VARS is a list of VAR structures for variables that are to be
 269 ;;; sequentially bound. Each AUX-VAL is a form that is to be evaluated
 270 ;;; to get the initial value for the corresponding AUX-VAR.
 271 (defun ir1-convert-lambda-body (body
 272                                 vars
 273                                 &key
 274                                 aux-vars
 275                                 aux-vals
 276                                 (source-name '.anonymous.)
 277                                 debug-name
 278                                 (note-lexical-bindings t))
 279   (declare (list body vars aux-vars aux-vals))
 280
 281   ;; We're about to try to put new blocks into *CURRENT-COMPONENT*.
 282   (aver-live-component *current-component*)
 283
 284   (let* ((bind (make-bind))
 285          (lambda (make-lambda :vars vars
 286                   :bind bind
 287                   :%source-name source-name
 288                   :%debug-name debug-name))
 289          (result (make-continuation)))
 290
 291     ;; just to check: This function should fail internal assertions if
 292     ;; we didn't set up a valid debug name above.
 293     ;;
 294     ;; (In SBCL we try to make everything have a debug name, since we
 295     ;; lack the omniscient perspective the original implementors used
 296     ;; to decide which things didn't need one.)
 297     (functional-debug-name lambda)
 298
 299     (setf (lambda-home lambda) lambda)
 300     (collect ((svars)
 301               (new-venv nil cons))
 302
 303       (dolist (var vars)
 304         ;; As far as I can see, LAMBDA-VAR-HOME should never have
 305         ;; been set before. Let's make sure. -- WHN 2001-09-29
 306         (aver (not (lambda-var-home var)))
 307         (setf (lambda-var-home var) lambda)
 308         (let ((specvar (lambda-var-specvar var)))
 309           (cond (specvar
 310                  (svars var)
 311                  (new-venv (cons (leaf-source-name specvar) specvar)))
 312                 (t
 313                  (when note-lexical-bindings
 314                    (note-lexical-binding (leaf-source-name var)))
 315                  (new-venv (cons (leaf-source-name var) var))))))
 316
 317       (let ((*lexenv* (make-lexenv :vars (new-venv)
 318                                    :lambda lambda
 319                                    :cleanup nil)))
 320         (setf (bind-lambda bind) lambda)
 321         (setf (node-lexenv bind) *lexenv*)
 322
 323         (let ((block (continuation-starts-block result)))
 324           (let ((return (make-return :result result :lambda lambda))
 325                 (tail-set (make-tail-set :funs (list lambda)))
 326                 (dummy (make-continuation)))
 327             (setf (lambda-tail-set lambda) tail-set)
 328             (setf (lambda-return lambda) return)
 329             (setf (continuation-dest result) return)
 330             (setf (block-last block) return)
 331             (link-node-to-previous-continuation return result)
 332             (use-continuation return dummy))
 333           (link-blocks block (component-tail *current-component*)))
 334
 335         (with-component-last-block (*current-component*
 336                                     (continuation-block result))
 337           (let ((cont1 (make-continuation))
 338                 (cont2 (make-continuation)))
 339             (continuation-starts-block cont1)
 340             (link-node-to-previous-continuation bind cont1)
 341             (use-continuation bind cont2)
 342             (ir1-convert-special-bindings cont2 result body
 343                                           aux-vars aux-vals (svars))))))
 344
 345     (link-blocks (component-head *current-component*) (node-block bind))
 346     (push lambda (component-new-functionals *current-component*))
 347
 348     lambda))
 349
 350 ;;; Entry point CLAMBDAs have a special kind
 351 (defun register-entry-point (entry dispatcher)
 352   (declare (type clambda entry)
 353            (type optional-dispatch dispatcher))
 354   (setf (functional-kind entry) :optional)
 355   (setf (leaf-ever-used entry) t)
 356   (setf (lambda-optional-dispatch entry)
 357         dispatcher)
 358   entry)
 359
 360 ;;; Create the actual entry-point function for an optional entry
 361 ;;; point. The lambda binds copies of each of the VARS, then calls FUN
 362 ;;; with the argument VALS and the DEFAULTS. Presumably the VALS refer
 363 ;;; to the VARS by name. The VALS are passed in the reverse order.
 364 ;;;
 365 ;;; If any of the copies of the vars are referenced more than once,
 366 ;;; then we mark the corresponding var as EVER-USED to inhibit
 367 ;;; "defined but not read" warnings for arguments that are only used
 368 ;;; by default forms.
 369 (defun convert-optional-entry (fun vars vals defaults)
 370   (declare (type clambda fun) (list vars vals defaults))
 371   (let* ((fvars (reverse vars))
 372          (arg-vars (mapcar (lambda (var)
 373                              (make-lambda-var
 374                               :%source-name (leaf-source-name var)
 375                               :type (leaf-type var)
 376                               :where-from (leaf-where-from var)
 377                               :specvar (lambda-var-specvar var)))
 378                            fvars))
 379          (fun (collect ((default-bindings)
 380                         (default-vals))
 381                 (dolist (default defaults)
 382                   (if (constantp default)
 383                       (default-vals default)
 384                       (let ((var (gensym)))
 385                         (default-bindings `(,var ,default))
 386                         (default-vals var))))
 387                 (ir1-convert-lambda-body `((let (,@(default-bindings))
 388                                              (%funcall ,fun
 389                                                        ,@(reverse vals)
 390                                                        ,@(default-vals))))
 391                                          arg-vars
 392                                          :debug-name
 393                                          (debug-namify "&OPTIONAL processor ~D"
 394                                                        (random 100))
 395                                          :note-lexical-bindings nil))))
 396     (mapc (lambda (var arg-var)
 397             (when (cdr (leaf-refs arg-var))
 398               (setf (leaf-ever-used var) t)))
 399           fvars arg-vars)
 400     fun))
 401
 402 ;;; This function deals with supplied-p vars in optional arguments. If
 403 ;;; the there is no supplied-p arg, then we just call
 404 ;;; IR1-CONVERT-HAIRY-ARGS on the remaining arguments, and generate a
 405 ;;; optional entry that calls the result. If there is a supplied-p
 406 ;;; var, then we add it into the default vars and throw a T into the
 407 ;;; entry values. The resulting entry point function is returned.
 408 (defun generate-optional-default-entry (res default-vars default-vals
 409                                         entry-vars entry-vals
 410                                         vars supplied-p-p body
 411                                         aux-vars aux-vals
 412                                         source-name debug-name
 413                                         force)
 414   (declare (type optional-dispatch res)
 415            (list default-vars default-vals entry-vars entry-vals vars body
 416                  aux-vars aux-vals))
 417   (let* ((arg (first vars))
 418          (arg-name (leaf-source-name arg))
 419          (info (lambda-var-arg-info arg))
 420          (default (arg-info-default info))
 421          (supplied-p (arg-info-supplied-p info))
 422          (force (or force
 423                     (not (sb!xc:constantp (arg-info-default info)))))
 424          (ep (if supplied-p
 425                  (ir1-convert-hairy-args
 426                   res
 427                   (list* supplied-p arg default-vars)
 428                   (list* (leaf-source-name supplied-p) arg-name default-vals)
 429                   (cons arg entry-vars)
 430                   (list* t arg-name entry-vals)
 431                   (rest vars) t body aux-vars aux-vals
 432                   source-name debug-name
 433                   force)
 434                  (ir1-convert-hairy-args
 435                   res
 436                   (cons arg default-vars)
 437                   (cons arg-name default-vals)
 438                   (cons arg entry-vars)
 439                   (cons arg-name entry-vals)
 440                   (rest vars) supplied-p-p body aux-vars aux-vals
 441                   source-name debug-name
 442                   force))))
 443
 444     ;; We want to delay converting the entry, but there exist
 445     ;; problems: hidden references should not be established to
 446     ;; lambdas of kind NIL should not have (otherwise the compiler
 447     ;; might let-convert or delete them) and to variables.
 448     (if (or force
 449             supplied-p-p ; this entry will be of kind NIL
 450             (and (lambda-p ep) (eq (lambda-kind ep) nil)))
 451         (convert-optional-entry ep
 452                                 default-vars default-vals
 453                                 (if supplied-p
 454                                     (list default nil)
 455                                     (list default)))
 456         (delay
 457          (register-entry-point
 458            (convert-optional-entry (force ep)
 459                                    default-vars default-vals
 460                                    (if supplied-p
 461                                        (list default nil)
 462                                        (list default)))
 463            res)))))
 464
 465 ;;; Create the MORE-ENTRY function for the OPTIONAL-DISPATCH RES.
 466 ;;; ENTRY-VARS and ENTRY-VALS describe the fixed arguments. REST is
 467 ;;; the var for any &REST arg. KEYS is a list of the &KEY arg vars.
 468 ;;;
 469 ;;; The most interesting thing that we do is parse keywords. We create
 470 ;;; a bunch of temporary variables to hold the result of the parse,
 471 ;;; and then loop over the supplied arguments, setting the appropriate
 472 ;;; temps for the supplied keyword. Note that it is significant that
 473 ;;; we iterate over the keywords in reverse order --- this implements
 474 ;;; the CL requirement that (when a keyword appears more than once)
 475 ;;; the first value is used.
 476 ;;;
 477 ;;; If there is no supplied-p var, then we initialize the temp to the
 478 ;;; default and just pass the temp into the main entry. Since
 479 ;;; non-constant &KEY args are forcibly given a supplied-p var, we
 480 ;;; know that the default is constant, and thus safe to evaluate out
 481 ;;; of order.
 482 ;;;
 483 ;;; If there is a supplied-p var, then we create temps for both the
 484 ;;; value and the supplied-p, and pass them into the main entry,
 485 ;;; letting it worry about defaulting.
 486 ;;;
 487 ;;; We deal with :ALLOW-OTHER-KEYS by delaying unknown keyword errors
 488 ;;; until we have scanned all the keywords.
 489 (defun convert-more-entry (res entry-vars entry-vals rest morep keys)
 490   (declare (type optional-dispatch res) (list entry-vars entry-vals keys))
 491   (collect ((arg-vars)
 492             (arg-vals (reverse entry-vals))
 493             (temps)
 494             (body))
 495
 496     (dolist (var (reverse entry-vars))
 497       (arg-vars (make-lambda-var :%source-name (leaf-source-name var)
 498                                  :type (leaf-type var)
 499                                  :where-from (leaf-where-from var))))
 500
 501     (let* ((n-context (gensym "N-CONTEXT-"))
 502            (context-temp (make-lambda-var :%source-name n-context))
 503            (n-count (gensym "N-COUNT-"))
 504            (count-temp (make-lambda-var :%source-name n-count
 505                                         :type (specifier-type 'index))))
 506
 507       (arg-vars context-temp count-temp)
 508
 509       (when rest
 510         (arg-vals `(%listify-rest-args ,n-context ,n-count)))
 511       (when morep
 512         (arg-vals n-context)
 513         (arg-vals n-count))
 514
 515       (when (optional-dispatch-keyp res)
 516         (let ((n-index (gensym "N-INDEX-"))
 517               (n-key (gensym "N-KEY-"))
 518               (n-value-temp (gensym "N-VALUE-TEMP-"))
 519               (n-allowp (gensym "N-ALLOWP-"))
 520               (n-losep (gensym "N-LOSEP-"))
 521               (allowp (or (optional-dispatch-allowp res)
 522                           (policy *lexenv* (zerop safety))))
 523               (found-allow-p nil))
 524
 525           (temps `(,n-index (1- ,n-count)) n-key n-value-temp)
 526           (body `(declare (fixnum ,n-index) (ignorable ,n-key ,n-value-temp)))
 527
 528           (collect ((tests))
 529             (dolist (key keys)
 530               (let* ((info (lambda-var-arg-info key))
 531                      (default (arg-info-default info))
 532                      (keyword (arg-info-key info))
 533                      (supplied-p (arg-info-supplied-p info))
 534                      (n-value (gensym "N-VALUE-"))
 535                      (clause (cond (supplied-p
 536                                     (let ((n-supplied (gensym "N-SUPPLIED-")))
 537                                       (temps n-supplied)
 538                                       (arg-vals n-value n-supplied)
 539                                       `((eq ,n-key ',keyword)
 540                                         (setq ,n-supplied t)
 541                                         (setq ,n-value ,n-value-temp))))
 542                                    (t
 543                                     (arg-vals n-value)
 544                                     `((eq ,n-key ',keyword)
 545                                       (setq ,n-value ,n-value-temp))))))
 546                 (when (and (not allowp) (eq keyword :allow-other-keys))
 547                   (setq found-allow-p t)
 548                   (setq clause
 549                         (append clause `((setq ,n-allowp ,n-value-temp)))))
 550
 551                 (temps `(,n-value ,default))
 552                 (tests clause)))
 553
 554             (unless allowp
 555               (temps n-allowp n-losep)
 556               (unless found-allow-p
 557                 (tests `((eq ,n-key :allow-other-keys)
 558                          (setq ,n-allowp ,n-value-temp))))
 559               (tests `(t
 560                        (setq ,n-losep ,n-key))))
 561
 562             (body
 563              `(when (oddp ,n-count)
 564                 (%odd-key-args-error)))
 565
 566             (body
 567              `(locally
 568                 (declare (optimize (safety 0)))
 569                 (loop
 570                   (when (minusp ,n-index) (return))
 571                   (setf ,n-value-temp (%more-arg ,n-context ,n-index))
 572                   (decf ,n-index)
 573                   (setq ,n-key (%more-arg ,n-context ,n-index))
 574                   (decf ,n-index)
 575                   (cond ,@(tests)))))
 576
 577             (unless allowp
 578               (body `(when (and ,n-losep (not ,n-allowp))
 579                        (%unknown-key-arg-error ,n-losep)))))))
 580
 581       (let ((ep (ir1-convert-lambda-body
 582                  `((let ,(temps)
 583                      ,@(body)
 584                      (%funcall ,(optional-dispatch-main-entry res)
 585                                ,@(arg-vals))))
 586                  (arg-vars)
 587                  :debug-name (debug-namify "~S processing" '&more)
 588                  :note-lexical-bindings nil)))
 589         (setf (optional-dispatch-more-entry res)
 590               (register-entry-point ep res)))))
 591
 592   (values))
 593
 594 ;;; This is called by IR1-CONVERT-HAIRY-ARGS when we run into a &REST
 595 ;;; or &KEY arg. The arguments are similar to that function, but we
 596 ;;; split off any &REST arg and pass it in separately. REST is the
 597 ;;; &REST arg var, or NIL if there is no &REST arg. KEYS is a list of
 598 ;;; the &KEY argument vars.
 599 ;;;
 600 ;;; When there are &KEY arguments, we introduce temporary gensym
 601 ;;; variables to hold the values while keyword defaulting is in
 602 ;;; progress to get the required sequential binding semantics.
 603 ;;;
 604 ;;; This gets interesting mainly when there are &KEY arguments with
 605 ;;; supplied-p vars or non-constant defaults. In either case, pass in
 606 ;;; a supplied-p var. If the default is non-constant, we introduce an
 607 ;;; IF in the main entry that tests the supplied-p var and decides
 608 ;;; whether to evaluate the default or not. In this case, the real
 609 ;;; incoming value is NIL, so we must union NULL with the declared
 610 ;;; type when computing the type for the main entry's argument.
 611 (defun ir1-convert-more (res default-vars default-vals entry-vars entry-vals
 612                              rest more-context more-count keys supplied-p-p
 613                              body aux-vars aux-vals
 614                              source-name debug-name)
 615   (declare (type optional-dispatch res)
 616            (list default-vars default-vals entry-vars entry-vals keys body
 617                  aux-vars aux-vals))
 618   (collect ((main-vars (reverse default-vars))
 619             (main-vals default-vals cons)
 620             (bind-vars)
 621             (bind-vals))
 622     (when rest
 623       (main-vars rest)
 624       (main-vals '()))
 625     (when more-context
 626       (main-vars more-context)
 627       (main-vals nil)
 628       (main-vars more-count)
 629       (main-vals 0))
 630
 631     (dolist (key keys)
 632       (let* ((info (lambda-var-arg-info key))
 633              (default (arg-info-default info))
 634              (hairy-default (not (sb!xc:constantp default)))
 635              (supplied-p (arg-info-supplied-p info))
 636              (n-val (make-symbol (format nil
 637                                          "~A-DEFAULTING-TEMP"
 638                                          (leaf-source-name key))))
 639              (key-type (leaf-type key))
 640              (val-temp (make-lambda-var
 641                         :%source-name n-val
 642                         :type (if hairy-default
 643                                   (type-union key-type (specifier-type 'null))
 644                                   key-type))))
 645         (main-vars val-temp)
 646         (bind-vars key)
 647         (cond ((or hairy-default supplied-p)
 648                (let* ((n-supplied (gensym "N-SUPPLIED-"))
 649                       (supplied-temp (make-lambda-var
 650                                       :%source-name n-supplied)))
 651                  (unless supplied-p
 652                    (setf (arg-info-supplied-p info) supplied-temp))
 653                  (when hairy-default
 654                    (setf (arg-info-default info) nil))
 655                  (main-vars supplied-temp)
 656                  (cond (hairy-default
 657                         (main-vals nil nil)
 658                         (bind-vals `(if ,n-supplied ,n-val ,default)))
 659                        (t
 660                         (main-vals default nil)
 661                         (bind-vals n-val)))
 662                  (when supplied-p
 663                    (bind-vars supplied-p)
 664                    (bind-vals n-supplied))))
 665               (t
 666                (main-vals (arg-info-default info))
 667                (bind-vals n-val)))))
 668
 669     (let* ((main-entry (ir1-convert-lambda-body
 670                         body (main-vars)
 671                         :aux-vars (append (bind-vars) aux-vars)
 672                         :aux-vals (append (bind-vals) aux-vals)
 673                         :debug-name (debug-namify "varargs entry for ~A"
 674                                                   (as-debug-name source-name
 675                                                                  debug-name))))
 676            (last-entry (convert-optional-entry main-entry default-vars
 677                                                (main-vals) ())))
 678       (setf (optional-dispatch-main-entry res)
 679             (register-entry-point main-entry res))
 680       (convert-more-entry res entry-vars entry-vals rest more-context keys)
 681
 682       (push (register-entry-point
 683              (if supplied-p-p
 684                 (convert-optional-entry last-entry entry-vars entry-vals ())
 685                 last-entry)
 686              res)
 687             (optional-dispatch-entry-points res))
 688       last-entry)))
 689
 690 ;;; This function generates the entry point functions for the
 691 ;;; OPTIONAL-DISPATCH RES. We accomplish this by recursion on the list
 692 ;;; of arguments, analyzing the arglist on the way down and generating
 693 ;;; entry points on the way up.
 694 ;;;
 695 ;;; DEFAULT-VARS is a reversed list of all the argument vars processed
 696 ;;; so far, including supplied-p vars. DEFAULT-VALS is a list of the
 697 ;;; names of the DEFAULT-VARS.
 698 ;;;
 699 ;;; ENTRY-VARS is a reversed list of processed argument vars,
 700 ;;; excluding supplied-p vars. ENTRY-VALS is a list things that can be
 701 ;;; evaluated to get the values for all the vars from the ENTRY-VARS.
 702 ;;; It has the var name for each required or optional arg, and has T
 703 ;;; for each supplied-p arg.
 704 ;;;
 705 ;;; VARS is a list of the LAMBDA-VAR structures for arguments that
 706 ;;; haven't been processed yet. SUPPLIED-P-P is true if a supplied-p
 707 ;;; argument has already been processed; only in this case are the
 708 ;;; DEFAULT-XXX and ENTRY-XXX different.
 709 ;;;
 710 ;;; The result at each point is a lambda which should be called by the
 711 ;;; above level to default the remaining arguments and evaluate the
 712 ;;; body. We cause the body to be evaluated by converting it and
 713 ;;; returning it as the result when the recursion bottoms out.
 714 ;;;
 715 ;;; Each level in the recursion also adds its entry point function to
 716 ;;; the result OPTIONAL-DISPATCH. For most arguments, the defaulting
 717 ;;; function and the entry point function will be the same, but when
 718 ;;; SUPPLIED-P args are present they may be different.
 719 ;;;
 720 ;;; When we run into a &REST or &KEY arg, we punt out to
 721 ;;; IR1-CONVERT-MORE, which finishes for us in this case.
 722 (defun ir1-convert-hairy-args (res default-vars default-vals
 723                                entry-vars entry-vals
 724                                vars supplied-p-p body aux-vars
 725                                aux-vals
 726                                source-name debug-name
 727                                force)
 728   (declare (type optional-dispatch res)
 729            (list default-vars default-vals entry-vars entry-vals vars body
 730                  aux-vars aux-vals))
 731   (cond ((not vars)
 732          (if (optional-dispatch-keyp res)
 733              ;; Handle &KEY with no keys...
 734              (ir1-convert-more res default-vars default-vals
 735                                entry-vars entry-vals
 736                                nil nil nil vars supplied-p-p body aux-vars
 737                                aux-vals source-name debug-name)
 738              (let ((fun (ir1-convert-lambda-body
 739                          body (reverse default-vars)
 740                          :aux-vars aux-vars
 741                          :aux-vals aux-vals
 742                          :debug-name (debug-namify
 743                                       "hairy arg processor for ~A"
 744                                       (as-debug-name source-name
 745                                                      debug-name)))))
 746                (setf (optional-dispatch-main-entry res) fun)
 747                (register-entry-point fun res)
 748                (push (if supplied-p-p
 749                          (register-entry-point
 750                           (convert-optional-entry fun entry-vars entry-vals ())
 751                           res)
 752                           fun)
 753                      (optional-dispatch-entry-points res))
 754                fun)))
 755         ((not (lambda-var-arg-info (first vars)))
 756          (let* ((arg (first vars))
 757                 (nvars (cons arg default-vars))
 758                 (nvals (cons (leaf-source-name arg) default-vals)))
 759            (ir1-convert-hairy-args res nvars nvals nvars nvals
 760                                    (rest vars) nil body aux-vars aux-vals
 761                                    source-name debug-name
 762                                    nil)))
 763         (t
 764          (let* ((arg (first vars))
 765                 (info (lambda-var-arg-info arg))
 766                 (kind (arg-info-kind info)))
 767            (ecase kind
 768              (:optional
 769               (let ((ep (generate-optional-default-entry
 770                          res default-vars default-vals
 771                          entry-vars entry-vals vars supplied-p-p body
 772                          aux-vars aux-vals
 773                          source-name debug-name
 774                          force)))
 775                 ;; See GENERATE-OPTIONAL-DEFAULT-ENTRY.
 776                 (push (if (lambda-p ep)
 777                           (register-entry-point
 778                            (if supplied-p-p
 779                                (convert-optional-entry ep entry-vars entry-vals ())
 780                                ep)
 781                            res)
 782                           (progn (aver (not supplied-p-p))
 783                                  ep))
 784                       (optional-dispatch-entry-points res))
 785                 ep))
 786              (:rest
 787               (ir1-convert-more res default-vars default-vals
 788                                 entry-vars entry-vals
 789                                 arg nil nil (rest vars) supplied-p-p body
 790                                 aux-vars aux-vals
 791                                 source-name debug-name))
 792              (:more-context
 793               (ir1-convert-more res default-vars default-vals
 794                                 entry-vars entry-vals
 795                                 nil arg (second vars) (cddr vars) supplied-p-p
 796                                 body aux-vars aux-vals
 797                                 source-name debug-name))
 798              (:keyword
 799               (ir1-convert-more res default-vars default-vals
 800                                 entry-vars entry-vals
 801                                 nil nil nil vars supplied-p-p body aux-vars
 802                                 aux-vals source-name debug-name)))))))
 803
 804 ;;; This function deals with the case where we have to make an
 805 ;;; OPTIONAL-DISPATCH to represent a LAMBDA. We cons up the result and
 806 ;;; call IR1-CONVERT-HAIRY-ARGS to do the work. When it is done, we
 807 ;;; figure out the MIN-ARGS and MAX-ARGS.
 808 (defun ir1-convert-hairy-lambda (body vars keyp allowp aux-vars aux-vals
 809                                       &key
 810                                       (source-name '.anonymous.)
 811                                       (debug-name (debug-namify
 812                                                    "OPTIONAL-DISPATCH ~S"
 813                                                    vars)))
 814   (declare (list body vars aux-vars aux-vals))
 815   (let ((res (make-optional-dispatch :arglist vars
 816                                      :allowp allowp
 817                                      :keyp keyp
 818                                      :%source-name source-name
 819                                      :%debug-name debug-name
 820                                      :plist `(:ir1-environment
 821                                               (,*lexenv*
 822                                                ,*current-path*))))
 823         (min (or (position-if #'lambda-var-arg-info vars) (length vars))))
 824     (aver-live-component *current-component*)
 825     (push res (component-new-functionals *current-component*))
 826     (ir1-convert-hairy-args res () () () () vars nil body aux-vars aux-vals
 827                             source-name debug-name nil)
 828     (setf (optional-dispatch-min-args res) min)
 829     (setf (optional-dispatch-max-args res)
 830           (+ (1- (length (optional-dispatch-entry-points res))) min))
 831
 832     res))
 833
 834 ;;; Convert a LAMBDA form into a LAMBDA leaf or an OPTIONAL-DISPATCH leaf.
 835 (defun ir1-convert-lambda (form &key (source-name '.anonymous.)
 836                            debug-name
 837                            allow-debug-catch-tag)
 838
 839   (unless (consp form)
 840     (compiler-error "A ~S was found when expecting a lambda expression:~%  ~S"
 841                     (type-of form)
 842                     form))
 843   (unless (eq (car form) 'lambda)
 844     (compiler-error "~S was expected but ~S was found:~%  ~S"
 845                     'lambda
 846                     (car form)
 847                     form))
 848   (unless (and (consp (cdr form)) (listp (cadr form)))
 849     (compiler-error
 850      "The lambda expression has a missing or non-list lambda list:~%  ~S"
 851      form))
 852
 853   (let ((*allow-debug-catch-tag* (and *allow-debug-catch-tag* allow-debug-catch-tag)))
 854     (multiple-value-bind (vars keyp allow-other-keys aux-vars aux-vals)
 855         (make-lambda-vars (cadr form))
 856       (multiple-value-bind (forms decls) (parse-body (cddr form))
 857         (binding* (((*lexenv* result-type)
 858                     (process-decls decls (append aux-vars vars) nil))
 859                    (forms (if (and *allow-debug-catch-tag*
 860                                    (policy *lexenv* (>= insert-debug-catch 2)))
 861                               `((catch (make-symbol "SB-DEBUG-CATCH-TAG")
 862                                   ,@forms))
 863                               forms))
 864                    (forms (if (eq result-type *wild-type*)
 865                               forms
 866                               `((the ,result-type (progn ,@forms)))))
 867                    (res (if (or (find-if #'lambda-var-arg-info vars) keyp)
 868                             (ir1-convert-hairy-lambda forms vars keyp
 869                                                       allow-other-keys
 870                                                       aux-vars aux-vals
 871                                                       :source-name source-name
 872                                                       :debug-name debug-name)
 873                             (ir1-convert-lambda-body forms vars
 874                                                      :aux-vars aux-vars
 875                                                      :aux-vals aux-vals
 876                                                      :source-name source-name
 877                                                      :debug-name debug-name))))
 878           (setf (functional-inline-expansion res) form)
 879           (setf (functional-arg-documentation res) (cadr form))
 880           res)))))
 881
 882 ;;; helper for LAMBDA-like things, to massage them into a form
 883 ;;; suitable for IR1-CONVERT-LAMBDA.
 884 ;;;
 885 ;;; KLUDGE: We cons up a &REST list here, maybe for no particularly
 886 ;;; good reason.  It's probably lost in the noise of all the other
 887 ;;; consing, but it's still inelegant.  And we force our called
 888 ;;; functions to do full runtime keyword parsing, ugh.  -- CSR,
 889 ;;; 2003-01-25
 890 (defun ir1-convert-lambdalike (thing &rest args
 891                                &key (source-name '.anonymous.)
 892                                debug-name allow-debug-catch-tag)
 893   (declare (ignorable source-name debug-name allow-debug-catch-tag))
 894   (ecase (car thing)
 895     ((lambda) (apply #'ir1-convert-lambda thing args))
 896     ((instance-lambda)
 897      (let ((res (apply #'ir1-convert-lambda
 898                        `(lambda ,@(cdr thing)) args)))
 899        (setf (getf (functional-plist res) :fin-function) t)
 900        res))
 901     ((named-lambda)
 902      (let ((name (cadr thing)))
 903        (if (legal-fun-name-p name)
 904            (let ((defined-fun-res (get-defined-fun name))
 905                  (res (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 906                              :source-name name
 907                              :debug-name nil
 908                              args)))
 909              (assert-global-function-definition-type name res)
 910              (setf (defined-fun-functional defined-fun-res)
 911                    res)
 912              (unless (eq (defined-fun-inlinep defined-fun-res) :notinline)
 913                (substitute-leaf-if
 914                 (lambda (ref)
 915                   (policy ref (> recognize-self-calls 0)))
 916                 res defined-fun-res))
 917              res)
 918            (apply #'ir1-convert-lambda `(lambda ,@(cddr thing))
 919                   :debug-name name args))))
 920     ((lambda-with-lexenv) (apply #'ir1-convert-inline-lambda thing args))))
 921 \f
 922 ;;;; defining global functions
 923
 924 ;;; Convert FUN as a lambda in the null environment, but use the
 925 ;;; current compilation policy. Note that FUN may be a
 926 ;;; LAMBDA-WITH-LEXENV, so we may have to augment the environment to
 927 ;;; reflect the state at the definition site.
 928 (defun ir1-convert-inline-lambda (fun &key
 929                                       (source-name '.anonymous.)
 930                                       debug-name
 931                                       allow-debug-catch-tag)
 932   (destructuring-bind (decls macros symbol-macros &rest body)
 933                       (if (eq (car fun) 'lambda-with-lexenv)
 934                           (cdr fun)
 935                           `(() () () . ,(cdr fun)))
 936     (let ((*lexenv* (make-lexenv
 937                      :default (process-decls decls nil nil
 938                                              (make-null-lexenv))
 939                      :vars (copy-list symbol-macros)
 940                      :funs (mapcar (lambda (x)
 941                                      `(,(car x) .
 942                                        (macro . ,(coerce (cdr x) 'function))))
 943                                    macros)
 944                      :policy (lexenv-policy *lexenv*))))
 945       (ir1-convert-lambda `(lambda ,@body)
 946                           :source-name source-name
 947                           :debug-name debug-name
 948                           :allow-debug-catch-tag nil))))
 949
 950 ;;; Get a DEFINED-FUN object for a function we are about to define. If
 951 ;;; the function has been forward referenced, then substitute for the
 952 ;;; previous references.
 953 (defun get-defined-fun (name)
 954   (proclaim-as-fun-name name)
 955   (let ((found (find-free-fun name "shouldn't happen! (defined-fun)")))
 956     (note-name-defined name :function)
 957     (cond ((not (defined-fun-p found))
 958            (aver (not (info :function :inlinep name)))
 959            (let* ((where-from (leaf-where-from found))
 960                   (res (make-defined-fun
 961                         :%source-name name
 962                         :where-from (if (eq where-from :declared)
 963                                         :declared :defined)
 964                         :type (leaf-type found))))
 965              (substitute-leaf res found)
 966              (setf (gethash name *free-funs*) res)))
 967           ;; If *FREE-FUNS* has a previously converted definition
 968           ;; for this name, then blow it away and try again.
 969           ((defined-fun-functional found)
 970            (remhash name *free-funs*)
 971            (get-defined-fun name))
 972           (t found))))
 973
 974 ;;; Check a new global function definition for consistency with
 975 ;;; previous declaration or definition, and assert argument/result
 976 ;;; types if appropriate. This assertion is suppressed by the
 977 ;;; EXPLICIT-CHECK attribute, which is specified on functions that
 978 ;;; check their argument types as a consequence of type dispatching.
 979 ;;; This avoids redundant checks such as NUMBERP on the args to +, etc.
 980 (defun assert-new-definition (var fun)
 981   (let ((type (leaf-type var))
 982         (for-real (eq (leaf-where-from var) :declared))
 983         (info (info :function :info (leaf-source-name var))))
 984     (assert-definition-type
 985      fun type
 986      ;; KLUDGE: Common Lisp is such a dynamic language that in general
 987      ;; all we can do here in general is issue a STYLE-WARNING. It
 988      ;; would be nice to issue a full WARNING in the special case of
 989      ;; of type mismatches within a compilation unit (as in section
 990      ;; 3.2.2.3 of the spec) but at least as of sbcl-0.6.11, we don't
 991      ;; keep track of whether the mismatched data came from the same
 992      ;; compilation unit, so we can't do that. -- WHN 2001-02-11
 993      :lossage-fun #'compiler-style-warn
 994      :unwinnage-fun (cond (info #'compiler-style-warn)
 995                           (for-real #'compiler-notify)
 996                           (t nil))
 997      :really-assert
 998      (and for-real
 999           (not (and info
1000                     (ir1-attributep (fun-info-attributes info)
1001                                     explicit-check))))
1002      :where (if for-real
1003                 "previous declaration"
1004                 "previous definition"))))
1005
1006 ;;; Convert a lambda doing all the basic stuff we would do if we were
1007 ;;; converting a DEFUN. In the old CMU CL system, this was used both
1008 ;;; by the %DEFUN translator and for global inline expansion, but
1009 ;;; since sbcl-0.pre7.something %DEFUN does things differently.
1010 ;;; FIXME: And now it's probably worth rethinking whether this
1011 ;;; function is a good idea.
1012 ;;;
1013 ;;; Unless a :INLINE function, we temporarily clobber the inline
1014 ;;; expansion. This prevents recursive inline expansion of
1015 ;;; opportunistic pseudo-inlines.
1016 (defun ir1-convert-lambda-for-defun (lambda var expansion converter)
1017   (declare (cons lambda) (function converter) (type defined-fun var))
1018   (let ((var-expansion (defined-fun-inline-expansion var)))
1019     (unless (eq (defined-fun-inlinep var) :inline)
1020       (setf (defined-fun-inline-expansion var) nil))
1021     (let* ((name (leaf-source-name var))
1022            (fun (funcall converter lambda
1023                          :source-name name))
1024            (fun-info (info :function :info name)))
1025       (setf (functional-inlinep fun) (defined-fun-inlinep var))
1026       (assert-new-definition var fun)
1027       (setf (defined-fun-inline-expansion var) var-expansion)
1028       ;; If definitely not an interpreter stub, then substitute for
1029       ;; any old references.
1030       (unless (or (eq (defined-fun-inlinep var) :notinline)
1031                   (not *block-compile*)
1032                   (and fun-info
1033                        (or (fun-info-transforms fun-info)
1034                            (fun-info-templates fun-info)
1035                            (fun-info-ir2-convert fun-info))))
1036         (substitute-leaf fun var)
1037         ;; If in a simple environment, then we can allow backward
1038         ;; references to this function from following top level forms.
1039         (when expansion (setf (defined-fun-functional var) fun)))
1040       fun)))
1041
1042 ;;; the even-at-compile-time part of DEFUN
1043 ;;;
1044 ;;; The INLINE-EXPANSION is a LAMBDA-WITH-LEXENV, or NIL if there is
1045 ;;; no inline expansion.
1046 (defun %compiler-defun (name lambda-with-lexenv)
1047
1048   (let ((defined-fun nil)) ; will be set below if we're in the compiler
1049
1050     (when (boundp '*lexenv*) ; when in the compiler
1051       (when sb!xc:*compile-print*
1052         (compiler-mumble "~&; recognizing DEFUN ~S~%" name))
1053       (remhash name *free-funs*)
1054       (setf defined-fun (get-defined-fun name)))
1055
1056     (become-defined-fun-name name)
1057
1058     (cond (lambda-with-lexenv
1059            (setf (info :function :inline-expansion-designator name)
1060                  lambda-with-lexenv)
1061            (when defined-fun
1062              (setf (defined-fun-inline-expansion defined-fun)
1063                    lambda-with-lexenv)))
1064           (t
1065            (clear-info :function :inline-expansion-designator name)))
1066
1067     ;; old CMU CL comment:
1068     ;;   If there is a type from a previous definition, blast it,
1069     ;;   since it is obsolete.
1070     (when (and defined-fun
1071                (eq (leaf-where-from defined-fun) :defined))
1072       (setf (leaf-type defined-fun)
1073             ;; FIXME: If this is a block compilation thing, shouldn't
1074             ;; we be setting the type to the full derived type for the
1075             ;; definition, instead of this most general function type?
1076             (specifier-type 'function))))
1077
1078   (values))
1079
1080 \f
1081 ;;; Entry point utilities
1082
1083 ;;; Return a function for the Nth entry point.
1084 (defun optional-dispatch-entry-point-fun (dispatcher n)
1085   (declare (type optional-dispatch dispatcher)
1086            (type unsigned-byte n))
1087   (let* ((env (getf (optional-dispatch-plist dispatcher) :ir1-environment))
1088          (*lexenv* (first env))
1089          (*current-path* (second env)))
1090     (force (nth n (optional-dispatch-entry-points dispatcher)))))