src/compiler/ir1tran-lambda.lisp

   1 ;;;; This file contains code which does the translation of lambda
   2 ;;;; forms from Lisp code to the first intermediate representation
   3 ;;;; (IR1).
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!C")
  15
  16 ;;;; LAMBDA hackery
  17
  18 ;;;; Note: Take a look at the compiler-overview.tex section on "Hairy
  19 ;;;; function representation" before you seriously mess with this
  20 ;;;; stuff.
  21
  22 ;;; Verify that the NAME is a legal name for a variable and return a
  23 ;;; VAR structure for it, filling in info if it is globally special.
  24 ;;; If it is losing, we punt with a COMPILER-ERROR. NAMES-SO-FAR is a
  25 ;;; list of names which have previously been bound. If the NAME is in
  26 ;;; this list, then we error out.
  27 (declaim (ftype (sfunction (t list) lambda-var) varify-lambda-arg))
  28 (defun varify-lambda-arg (name names-so-far)
  29   (declare (inline member))
  30   (unless (symbolp name)
  31     (compiler-error "The lambda variable ~S is not a symbol." name))
  32   (when (member name names-so-far :test #'eq)
  33     (compiler-error "The variable ~S occurs more than once in the lambda list."
  34                     name))
  35   (let ((kind (info :variable :kind name)))
  36     (when (or (keywordp name) (eq kind :constant))
  37       (compiler-error "The name of the lambda variable ~S is already in use to name a constant."
  38                       name))
  39     (cond ((eq kind :special)
  40            (let ((specvar (find-free-var name)))
  41              (make-lambda-var :%source-name name
  42                               :type (leaf-type specvar)
  43                               :where-from (leaf-where-from specvar)
  44                               :specvar specvar)))
  45           (t
  46            (make-lambda-var :%source-name name)))))
  47
  48 ;;; Make the default keyword for a &KEY arg, checking that the keyword
  49 ;;; isn't already used by one of the VARS.
  50 (declaim (ftype (sfunction (symbol list t) symbol) make-keyword-for-arg))
  51 (defun make-keyword-for-arg (symbol vars keywordify)
  52   (let ((key (if (and keywordify (not (keywordp symbol)))
  53                  (keywordicate symbol)
  54                  symbol)))
  55     (dolist (var vars)
  56       (let ((info (lambda-var-arg-info var)))
  57         (when (and info
  58                    (eq (arg-info-kind info) :keyword)
  59                    (eq (arg-info-key info) key))
  60           (compiler-error
  61            "The keyword ~S appears more than once in the lambda list."
  62            key))))
  63     key))
  64
  65 ;;; Parse a lambda list into a list of VAR structures, stripping off
  66 ;;; any &AUX bindings. Each arg name is checked for legality, and
  67 ;;; duplicate names are checked for. If an arg is globally special,
  68 ;;; the var is marked as :SPECIAL instead of :LEXICAL. &KEY,
  69 ;;; &OPTIONAL and &REST args are annotated with an ARG-INFO structure
  70 ;;; which contains the extra information. If we hit something losing,
  71 ;;; we bug out with COMPILER-ERROR. These values are returned:
  72 ;;;  1. a list of the var structures for each top level argument;
  73 ;;;  2. a flag indicating whether &KEY was specified;
  74 ;;;  3. a flag indicating whether other &KEY args are allowed;
  75 ;;;  4. a list of the &AUX variables; and
  76 ;;;  5. a list of the &AUX values.
  77 (declaim (ftype (sfunction (list) (values list boolean boolean list list))
  78                 make-lambda-vars))
  79 (defun make-lambda-vars (list)
  80   (multiple-value-bind (required optional restp rest keyp keys allowp auxp aux
  81                         morep more-context more-count)
  82       (parse-lambda-list list)
  83     (declare (ignore auxp)) ; since we just iterate over AUX regardless
  84     (collect ((vars)
  85               (names-so-far)
  86               (aux-vars)
  87               (aux-vals))
  88       (flet (;; PARSE-DEFAULT deals with defaults and supplied-p args
  89              ;; for optionals and keywords args.
  90              (parse-default (spec info)
  91                (when (consp (cdr spec))
  92                  (setf (arg-info-default info) (second spec))
  93                  (when (consp (cddr spec))
  94                    (let* ((supplied-p (third spec))
  95                           (supplied-var (varify-lambda-arg supplied-p
  96                                                            (names-so-far))))
  97                      (setf (arg-info-supplied-p info) supplied-var)
  98                      (names-so-far supplied-p)
  99                      (when (> (length (the list spec)) 3)
 100                        (compiler-error
 101                         "The list ~S is too long to be an arg specifier."
 102                         spec)))))))
 103
 104         (dolist (name required)
 105           (let ((var (varify-lambda-arg name (names-so-far))))
 106             (vars var)
 107             (names-so-far name)))
 108
 109         (dolist (spec optional)
 110           (if (atom spec)
 111               (let ((var (varify-lambda-arg spec (names-so-far))))
 112                 (setf (lambda-var-arg-info var)
 113                       (make-arg-info :kind :optional))
 114                 (vars var)
 115                 (names-so-far spec))
 116               (let* ((name (first spec))
 117                      (var (varify-lambda-arg name (names-so-far)))
 118                      (info (make-arg-info :kind :optional)))
 119                 (setf (lambda-var-arg-info var) info)
 120                 (vars var)
 121                 (names-so-far name)
 122                 (parse-default spec info))))
 123
 124         (when restp
 125           (let ((var (varify-lambda-arg rest (names-so-far))))
 126             (setf (lambda-var-arg-info var) (make-arg-info :kind :rest))
 127             (vars var)
 128             (names-so-far rest)))
 129
 130         (when morep
 131           (let ((var (varify-lambda-arg more-context (names-so-far))))
 132             (setf (lambda-var-arg-info var)
 133                   (make-arg-info :kind :more-context))
 134             (vars var)
 135             (names-so-far more-context))
 136           (let ((var (varify-lambda-arg more-count (names-so-far))))
 137             (setf (lambda-var-arg-info var)
 138                   (make-arg-info :kind :more-count))
 139             (vars var)
 140             (names-so-far more-count)))
 141
 142         (dolist (spec keys)
 143           (cond
 144            ((atom spec)
 145             (let ((var (varify-lambda-arg spec (names-so-far))))
 146               (setf (lambda-var-arg-info var)
 147                     (make-arg-info :kind :keyword
 148                                    :key (make-keyword-for-arg spec
 149                                                               (vars)
 150                                                               t)))
 151               (vars var)
 152               (names-so-far spec)))
 153            ((atom (first spec))
 154             (let* ((name (first spec))
 155                    (var (varify-lambda-arg name (names-so-far)))
 156                    (info (make-arg-info
 157                           :kind :keyword
 158                           :key (make-keyword-for-arg name (vars) t))))
 159               (setf (lambda-var-arg-info var) info)
 160               (vars var)
 161               (names-so-far name)
 162               (parse-default spec info)))
 163            (t
 164             (let ((head (first spec)))
 165               (unless (proper-list-of-length-p head 2)
 166                 (error "malformed &KEY argument specifier: ~S" spec))
 167               (let* ((name (second head))
 168                      (var (varify-lambda-arg name (names-so-far)))
 169                      (info (make-arg-info
 170                             :kind :keyword
 171                             :key (make-keyword-for-arg (first head)
 172                                                        (vars)
 173                                                        nil))))
 174                 (setf (lambda-var-arg-info var) info)
 175                 (vars var)
 176                 (names-so-far name)
 177                 (parse-default spec info))))))
 178
 179         (dolist (spec aux)
 180           (cond ((atom spec)
 181                  (let ((var (varify-lambda-arg spec nil)))
 182                    (aux-vars var)
 183                    (aux-vals nil)
 184                    (names-so-far spec)))
 185                 (t
 186                  (unless (proper-list-of-length-p spec 1 2)
 187                    (compiler-error "malformed &AUX binding specifier: ~S"
 188                                    spec))
 189                  (let* ((name (first spec))
 190                         (var (varify-lambda-arg name nil)))
 191                    (aux-vars var)
 192                    (aux-vals (second spec))
 193                    (names-so-far name)))))
 194
 195         (values (vars) keyp allowp (aux-vars) (aux-vals))))))
 196
 197 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that we
 198 ;;; sequentially bind each AUX-VAR to the corresponding AUX-VAL before
 199 ;;; converting the body. If there are no bindings, just convert the
 200 ;;; body, otherwise do one binding and recurse on the rest.
 201 ;;;
 202 ;;; FIXME: This could and probably should be converted to use
 203 ;;; SOURCE-NAME and DEBUG-NAME. But I (WHN) don't use &AUX bindings,
 204 ;;; so I'm not motivated. Patches will be accepted...
 205 (defun ir1-convert-aux-bindings (start next result body aux-vars aux-vals)
 206   (declare (type ctran start next) (type (or lvar null) result)
 207            (list body aux-vars aux-vals))
 208   (if (null aux-vars)
 209       (ir1-convert-progn-body start next result body)
 210       (let ((ctran (make-ctran))
 211             (fun-lvar (make-lvar))
 212             (fun (ir1-convert-lambda-body body
 213                                           (list (first aux-vars))
 214                                           :aux-vars (rest aux-vars)
 215                                           :aux-vals (rest aux-vals)
 216                                           :debug-name (debug-name
 217                                                        '&aux-bindings
 218                                                        aux-vars))))
 219         (reference-leaf start ctran fun-lvar fun)
 220         (ir1-convert-combination-args fun-lvar ctran next result
 221                                       (list (first aux-vals)))))
 222   (values))
 223
 224 ;;; This is similar to IR1-CONVERT-PROGN-BODY except that code to bind
 225 ;;; the SPECVAR for each SVAR to the value of the variable is wrapped
 226 ;;; around the body. If there are no special bindings, we just convert
 227 ;;; the body, otherwise we do one special binding and recurse on the
 228 ;;; rest.
 229 ;;;
 230 ;;; We make a cleanup and introduce it into the lexical
 231 ;;; environment. If there are multiple special bindings, the cleanup
 232 ;;; for the blocks will end up being the innermost one. We force NEXT
 233 ;;; to start a block outside of this cleanup, causing cleanup code to
 234 ;;; be emitted when the scope is exited.
 235 (defun ir1-convert-special-bindings
 236     (start next result body aux-vars aux-vals svars)
 237   (declare (type ctran start next) (type (or lvar null) result)
 238            (list body aux-vars aux-vals svars))
 239   (cond
 240    ((null svars)
 241     (ir1-convert-aux-bindings start next result body aux-vars aux-vals))
 242    (t
 243     (ctran-starts-block next)
 244     (let ((cleanup (make-cleanup :kind :special-bind))
 245           (var (first svars))
 246           (bind-ctran (make-ctran))
 247           (cleanup-ctran (make-ctran)))
 248       (ir1-convert start bind-ctran nil
 249                    `(%special-bind ',(lambda-var-specvar var) ,var))
 250       (setf (cleanup-mess-up cleanup) (ctran-use bind-ctran))
 251       (let ((*lexenv* (make-lexenv :cleanup cleanup)))
 252         (ir1-convert bind-ctran cleanup-ctran nil '(%cleanup-point))
 253         (ir1-convert-special-bindings cleanup-ctran next result
 254                                       body aux-vars aux-vals
 255                                       (rest svars))))))
 256   (values))
 257
 258 ;;; Create a lambda node out of some code, returning the result. The
 259 ;;; bindings are specified by the list of VAR structures VARS. We deal
 260 ;;; with adding the names to the LEXENV-VARS for the conversion. The
 261 ;;; result is added to the NEW-FUNCTIONALS in the *CURRENT-COMPONENT*
 262 ;;; and linked to the component head and tail.
 263 ;;;
 264 ;;; We detect special bindings here, replacing the original VAR in the
 265 ;;; lambda list with a temporary variable. We then pass a list of the
 266 ;;; special vars to IR1-CONVERT-SPECIAL-BINDINGS, which actually emits
 267 ;;; the special binding code.
 268 ;;;
 269 ;;; We ignore any ARG-INFO in the VARS, trusting that someone else is
 270 ;;; dealing with &NONSENSE, except for &REST vars with DYNAMIC-EXTENT.
 271 ;;;
 272 ;;; AUX-VARS is a list of VAR structures for variables that are to be
 273 ;;; sequentially bound. Each AUX-VAL is a form that is to be evaluated
 274 ;;; to get the initial value for the corresponding AUX-VAR.
 275 (defun ir1-convert-lambda-body (body
 276                                 vars
 277                                 &key
 278                                 aux-vars
 279                                 aux-vals
 280                                 (source-name '.anonymous.)
 281                                 debug-name
 282                                 (note-lexical-bindings t))
 283   (declare (list body vars aux-vars aux-vals))
 284
 285   ;; We're about to try to put new blocks into *CURRENT-COMPONENT*.
 286   (aver-live-component *current-component*)
 287
 288   (let* ((bind (make-bind))
 289          (lambda (make-lambda :vars vars
 290                   :bind bind
 291                   :%source-name source-name
 292                   :%debug-name debug-name))
 293          (result-ctran (make-ctran))
 294          (result-lvar (make-lvar)))
 295
 296     (awhen (lexenv-lambda *lexenv*)
 297       (push lambda (lambda-children it))
 298       (setf (lambda-parent lambda) it))
 299
 300     ;; just to check: This function should fail internal assertions if
 301     ;; we didn't set up a valid debug name above.
 302     ;;
 303     ;; (In SBCL we try to make everything have a debug name, since we
 304     ;; lack the omniscient perspective the original implementors used
 305     ;; to decide which things didn't need one.)
 306     (functional-debug-name lambda)
 307
 308     (setf (lambda-home lambda) lambda)
 309     (collect ((svars)
 310               (new-venv nil cons))
 311
 312       (dolist (var vars)
 313         ;; As far as I can see, LAMBDA-VAR-HOME should never have
 314         ;; been set before. Let's make sure. -- WHN 2001-09-29
 315         (aver (not (lambda-var-home var)))
 316         (setf (lambda-var-home var) lambda)
 317         (let ((specvar (lambda-var-specvar var)))
 318           (cond (specvar
 319                  (svars var)
 320                  (new-venv (cons (leaf-source-name specvar) specvar)))
 321                 (t
 322                  (when note-lexical-bindings
 323                    (note-lexical-binding (leaf-source-name var)))
 324                  (new-venv (cons (leaf-source-name var) var))))))
 325
 326       (let ((*lexenv* (make-lexenv :vars (new-venv)
 327                                    :lambda lambda
 328                                    :cleanup nil)))
 329         (setf (bind-lambda bind) lambda)
 330         (setf (node-lexenv bind) *lexenv*)
 331
 332         (let ((block (ctran-starts-block result-ctran)))
 333           (let ((return (make-return :result result-lvar :lambda lambda))
 334                 (tail-set (make-tail-set :funs (list lambda))))
 335             (setf (lambda-tail-set lambda) tail-set)
 336             (setf (lambda-return lambda) return)
 337             (setf (lvar-dest result-lvar) return)
 338             (link-node-to-previous-ctran return result-ctran)
 339             (setf (block-last block) return))
 340           (link-blocks block (component-tail *current-component*)))
 341
 342         (with-component-last-block (*current-component*
 343                                     (ctran-block result-ctran))
 344           (let ((prebind-ctran (make-ctran))
 345                 (postbind-ctran (make-ctran)))
 346             (ctran-starts-block prebind-ctran)
 347             (link-node-to-previous-ctran bind prebind-ctran)
 348             (use-ctran bind postbind-ctran)
 349             (ir1-convert-special-bindings postbind-ctran result-ctran
 350                                           result-lvar body
 351                                           aux-vars aux-vals (svars))))))
 352
 353     (link-blocks (component-head *current-component*) (node-block bind))
 354     (push lambda (component-new-functionals *current-component*))
 355
 356     lambda))
 357
 358 ;;; Entry point CLAMBDAs have a special kind
 359 (defun register-entry-point (entry dispatcher)
 360   (declare (type clambda entry)
 361            (type optional-dispatch dispatcher))
 362   (setf (functional-kind entry) :optional)
 363   (setf (leaf-ever-used entry) t)
 364   (setf (lambda-optional-dispatch entry) dispatcher)
 365   entry)
 366
 367 ;;; Create the actual entry-point function for an optional entry
 368 ;;; point. The lambda binds copies of each of the VARS, then calls FUN
 369 ;;; with the argument VALS and the DEFAULTS. Presumably the VALS refer
 370 ;;; to the VARS by name. The VALS are passed in the reverse order.
 371 ;;;
 372 ;;; If any of the copies of the vars are referenced more than once,
 373 ;;; then we mark the corresponding var as EVER-USED to inhibit
 374 ;;; "defined but not read" warnings for arguments that are only used
 375 ;;; by default forms.
 376 (defun convert-optional-entry (fun vars vals defaults name)
 377   (declare (type clambda fun) (list vars vals defaults))
 378   (let* ((fvars (reverse vars))
 379          (arg-vars (mapcar (lambda (var)
 380                              (make-lambda-var
 381                               :%source-name (leaf-source-name var)
 382                               :type (leaf-type var)
 383                               :where-from (leaf-where-from var)
 384                               :specvar (lambda-var-specvar var)))
 385                            fvars))
 386          (fun (collect ((default-bindings)
 387                         (default-vals))
 388                 (dolist (default defaults)
 389                   (if (constantp default)
 390                       (default-vals default)
 391                       (let ((var (gensym)))
 392                         (default-bindings `(,var ,default))
 393                         (default-vals var))))
 394                 (ir1-convert-lambda-body `((let (,@(default-bindings))
 395                                              (%funcall ,fun
 396                                                        ,@(reverse vals)
 397                                                        ,@(default-vals))))
 398                                          arg-vars
 399                                          ;; FIXME: Would be nice to
 400                                          ;; share these names instead
 401                                          ;; of consing up several
 402                                          ;; identical ones. Oh well.
 403                                          :debug-name (debug-name
 404                                                       '&optional-processor
 405                                                       name)
 406                                          :note-lexical-bindings nil))))
 407     (mapc (lambda (var arg-var)
 408             (when (cdr (leaf-refs arg-var))
 409               (setf (leaf-ever-used var) t)))
 410           fvars arg-vars)
 411     fun))
 412
 413 ;;; This function deals with supplied-p vars in optional arguments. If
 414 ;;; the there is no supplied-p arg, then we just call
 415 ;;; IR1-CONVERT-HAIRY-ARGS on the remaining arguments, and generate a
 416 ;;; optional entry that calls the result. If there is a supplied-p
 417 ;;; var, then we add it into the default vars and throw a T into the
 418 ;;; entry values. The resulting entry point function is returned.
 419 (defun generate-optional-default-entry (res default-vars default-vals
 420                                         entry-vars entry-vals
 421                                         vars supplied-p-p body
 422                                         aux-vars aux-vals
 423                                         source-name debug-name
 424                                         force)
 425   (declare (type optional-dispatch res)
 426            (list default-vars default-vals entry-vars entry-vals vars body
 427                  aux-vars aux-vals))
 428   (let* ((arg (first vars))
 429          (arg-name (leaf-source-name arg))
 430          (info (lambda-var-arg-info arg))
 431          (default (arg-info-default info))
 432          (supplied-p (arg-info-supplied-p info))
 433          (force (or force
 434                     (not (sb!xc:constantp (arg-info-default info)))))
 435          (ep (if supplied-p
 436                  (ir1-convert-hairy-args
 437                   res
 438                   (list* supplied-p arg default-vars)
 439                   (list* (leaf-source-name supplied-p) arg-name default-vals)
 440                   (cons arg entry-vars)
 441                   (list* t arg-name entry-vals)
 442                   (rest vars) t body aux-vars aux-vals
 443                   source-name debug-name
 444                   force)
 445                  (ir1-convert-hairy-args
 446                   res
 447                   (cons arg default-vars)
 448                   (cons arg-name default-vals)
 449                   (cons arg entry-vars)
 450                   (cons arg-name entry-vals)
 451                   (rest vars) supplied-p-p body aux-vars aux-vals
 452                   source-name debug-name
 453                   force))))
 454
 455     ;; We want to delay converting the entry, but there exist
 456     ;; problems: hidden references should not be established to
 457     ;; lambdas of kind NIL should not have (otherwise the compiler
 458     ;; might let-convert or delete them) and to variables.
 459     (let ((name (or debug-name source-name))
 460           (defaults (if supplied-p (list default nil) (list default))))
 461       (if (or force
 462               supplied-p-p ; this entry will be of kind NIL
 463               (and (lambda-p ep) (eq (lambda-kind ep) nil)))
 464           (convert-optional-entry ep
 465                                   default-vars default-vals
 466                                   defaults
 467                                   name)
 468           (delay
 469            (register-entry-point
 470             (convert-optional-entry (force ep)
 471                                     default-vars default-vals
 472                                     defaults
 473                                     name)
 474             res))))))
 475
 476 ;;; Create the MORE-ENTRY function for the OPTIONAL-DISPATCH RES.
 477 ;;; ENTRY-VARS and ENTRY-VALS describe the fixed arguments. REST is
 478 ;;; the var for any &REST arg. KEYS is a list of the &KEY arg vars.
 479 ;;;
 480 ;;; The most interesting thing that we do is parse keywords. We create
 481 ;;; a bunch of temporary variables to hold the result of the parse,
 482 ;;; and then loop over the supplied arguments, setting the appropriate
 483 ;;; temps for the supplied keyword. Note that it is significant that
 484 ;;; we iterate over the keywords in reverse order --- this implements
 485 ;;; the CL requirement that (when a keyword appears more than once)
 486 ;;; the first value is used.
 487 ;;;
 488 ;;; If there is no supplied-p var, then we initialize the temp to the
 489 ;;; default and just pass the temp into the main entry. Since
 490 ;;; non-constant &KEY args are forcibly given a supplied-p var, we
 491 ;;; know that the default is constant, and thus safe to evaluate out
 492 ;;; of order.
 493 ;;;
 494 ;;; If there is a supplied-p var, then we create temps for both the
 495 ;;; value and the supplied-p, and pass them into the main entry,
 496 ;;; letting it worry about defaulting.
 497 ;;;
 498 ;;; We deal with :ALLOW-OTHER-KEYS by delaying unknown keyword errors
 499 ;;; until we have scanned all the keywords.
 500 (defun convert-more-entry (res entry-vars entry-vals rest morep keys name)
 501   (declare (type optional-dispatch res) (list entry-vars entry-vals keys))
 502   (collect ((arg-vars)
 503             (arg-vals (reverse entry-vals))
 504             (temps)
 505             (body))
 506
 507     (dolist (var (reverse entry-vars))
 508       (arg-vars (make-lambda-var :%source-name (leaf-source-name var)
 509                                  :type (leaf-type var)
 510                                  :where-from (leaf-where-from var))))
 511
 512     (let* ((*allow-instrumenting* nil)
 513            (n-context (gensym "N-CONTEXT-"))
 514            (context-temp (make-lambda-var :%source-name n-context))
 515            (n-count (gensym "N-COUNT-"))
 516            (count-temp (make-lambda-var :%source-name n-count
 517                                         :type (specifier-type 'index))))
 518
 519       (arg-vars context-temp count-temp)
 520
 521       (when rest
 522         (arg-vals `(%listify-rest-args
 523                     ,n-context ,n-count)))
 524       (when morep
 525         (arg-vals n-context)
 526         (arg-vals n-count))
 527
 528       (when (optional-dispatch-keyp res)
 529         (let ((n-index (gensym "N-INDEX-"))
 530               (n-key (gensym "N-KEY-"))
 531               (n-value-temp (gensym "N-VALUE-TEMP-"))
 532               (n-allowp (gensym "N-ALLOWP-"))
 533               (n-losep (gensym "N-LOSEP-"))
 534               (allowp (or (optional-dispatch-allowp res)
 535                           (policy *lexenv* (zerop safety))))
 536               (found-allow-p nil))
 537
 538           (temps `(,n-index (1- ,n-count)) n-key n-value-temp)
 539           (body `(declare (fixnum ,n-index) (ignorable ,n-key ,n-value-temp)))
 540
 541           (collect ((tests))
 542             (dolist (key keys)
 543               (let* ((info (lambda-var-arg-info key))
 544                      (default (arg-info-default info))
 545                      (keyword (arg-info-key info))
 546                      (supplied-p (arg-info-supplied-p info))
 547                      (n-value (gensym "N-VALUE-"))
 548                      (clause (cond (supplied-p
 549                                     (let ((n-supplied (gensym "N-SUPPLIED-")))
 550                                       (temps n-supplied)
 551                                       (arg-vals n-value n-supplied)
 552                                       `((eq ,n-key ',keyword)
 553                                         (setq ,n-supplied t)
 554                                         (setq ,n-value ,n-value-temp))))
 555                                    (t
 556                                     (arg-vals n-value)
 557                                     `((eq ,n-key ',keyword)
 558                                       (setq ,n-value ,n-value-temp))))))
 559                 (when (and (not allowp) (eq keyword :allow-other-keys))
 560                   (setq found-allow-p t)
 561                   (setq clause
 562                         (append clause `((setq ,n-allowp ,n-value-temp)))))
 563
 564                 (temps `(,n-value ,default))
 565                 (tests clause)))
 566
 567             (unless allowp
 568               (temps n-allowp n-losep)
 569               (unless found-allow-p
 570                 (tests `((eq ,n-key :allow-other-keys)
 571                          (setq ,n-allowp ,n-value-temp))))
 572               (tests `(t
 573                        (setq ,n-losep (list ,n-key)))))
 574
 575             (body
 576              `(when (oddp ,n-count)
 577                 (%odd-key-args-error)))
 578
 579             (body
 580              `(locally
 581                 (declare (optimize (safety 0)))
 582                 (loop
 583                   (when (minusp ,n-index) (return))
 584                   (setf ,n-value-temp (%more-arg ,n-context ,n-index))
 585                   (decf ,n-index)
 586                   (setq ,n-key (%more-arg ,n-context ,n-index))
 587                   (decf ,n-index)
 588                   (cond ,@(tests)))))
 589
 590             (unless allowp
 591               (body `(when (and ,n-losep (not ,n-allowp))
 592                        (%unknown-key-arg-error (car ,n-losep))))))))
 593
 594       (let ((ep (ir1-convert-lambda-body
 595                  `((let ,(temps)
 596                      ,@(body)
 597                      (%funcall ,(optional-dispatch-main-entry res)
 598                                ,@(arg-vals))))
 599                  (arg-vars)
 600                  :debug-name (debug-name '&more-processor name)
 601                  :note-lexical-bindings nil)))
 602         (setf (optional-dispatch-more-entry res)
 603               (register-entry-point ep res)))))
 604
 605   (values))
 606
 607 ;;; This is called by IR1-CONVERT-HAIRY-ARGS when we run into a &REST
 608 ;;; or &KEY arg. The arguments are similar to that function, but we
 609 ;;; split off any &REST arg and pass it in separately. REST is the
 610 ;;; &REST arg var, or NIL if there is no &REST arg. KEYS is a list of
 611 ;;; the &KEY argument vars.
 612 ;;;
 613 ;;; When there are &KEY arguments, we introduce temporary gensym
 614 ;;; variables to hold the values while keyword defaulting is in
 615 ;;; progress to get the required sequential binding semantics.
 616 ;;;
 617 ;;; This gets interesting mainly when there are &KEY arguments with
 618 ;;; supplied-p vars or non-constant defaults. In either case, pass in
 619 ;;; a supplied-p var. If the default is non-constant, we introduce an
 620 ;;; IF in the main entry that tests the supplied-p var and decides
 621 ;;; whether to evaluate the default or not. In this case, the real
 622 ;;; incoming value is NIL, so we must union NULL with the declared
 623 ;;; type when computing the type for the main entry's argument.
 624 (defun ir1-convert-more (res default-vars default-vals entry-vars entry-vals
 625                              rest more-context more-count keys supplied-p-p
 626                              body aux-vars aux-vals
 627                              source-name debug-name)
 628   (declare (type optional-dispatch res)
 629            (list default-vars default-vals entry-vars entry-vals keys body
 630                  aux-vars aux-vals))
 631   (collect ((main-vars (reverse default-vars))
 632             (main-vals default-vals cons)
 633             (bind-vars)
 634             (bind-vals))
 635     (when rest
 636       (main-vars rest)
 637       (main-vals '()))
 638     (when more-context
 639       (main-vars more-context)
 640       (main-vals nil)
 641       (main-vars more-count)
 642       (main-vals 0))
 643
 644     (dolist (key keys)
 645       (let* ((info (lambda-var-arg-info key))
 646              (default (arg-info-default info))
 647              (hairy-default (not (sb!xc:constantp default)))
 648              (supplied-p (arg-info-supplied-p info))
 649              (n-val (make-symbol (format nil
 650                                          "~A-DEFAULTING-TEMP"
 651                                          (leaf-source-name key))))
 652              (key-type (leaf-type key))
 653              (val-temp (make-lambda-var
 654                         :%source-name n-val
 655                         :type (if hairy-default
 656                                   (type-union key-type (specifier-type 'null))
 657                                   key-type))))
 658         (main-vars val-temp)
 659         (bind-vars key)
 660         (cond ((or hairy-default supplied-p)
 661                (let* ((n-supplied (gensym "N-SUPPLIED-"))
 662                       (supplied-temp (make-lambda-var
 663                                       :%source-name n-supplied)))
 664                  (unless supplied-p
 665                    (setf (arg-info-supplied-p info) supplied-temp))
 666                  (when hairy-default
 667                    (setf (arg-info-default info) nil))
 668                  (main-vars supplied-temp)
 669                  (cond (hairy-default
 670                         (main-vals nil nil)
 671                         (bind-vals `(if ,n-supplied ,n-val ,default)))
 672                        (t
 673                         (main-vals default nil)
 674                         (bind-vals n-val)))
 675                  (when supplied-p
 676                    (bind-vars supplied-p)
 677                    (bind-vals n-supplied))))
 678               (t
 679                (main-vals (arg-info-default info))
 680                (bind-vals n-val)))))
 681
 682     (let* ((name (or debug-name source-name))
 683            (main-entry (ir1-convert-lambda-body
 684                         body (main-vars)
 685                         :aux-vars (append (bind-vars) aux-vars)
 686                         :aux-vals (append (bind-vals) aux-vals)
 687                         :debug-name (debug-name 'varargs-entry name)))
 688            (last-entry (convert-optional-entry main-entry default-vars
 689                                                (main-vals) () name)))
 690       (setf (optional-dispatch-main-entry res)
 691             (register-entry-point main-entry res))
 692       (convert-more-entry res entry-vars entry-vals rest more-context keys
 693                           name)
 694
 695       (push (register-entry-point
 696              (if supplied-p-p
 697                 (convert-optional-entry last-entry entry-vars entry-vals
 698                                         () name)
 699                 last-entry)
 700              res)
 701             (optional-dispatch-entry-points res))
 702       last-entry)))
 703
 704 ;;; This function generates the entry point functions for the
 705 ;;; OPTIONAL-DISPATCH RES. We accomplish this by recursion on the list
 706 ;;; of arguments, analyzing the arglist on the way down and generating
 707 ;;; entry points on the way up.
 708 ;;;
 709 ;;; DEFAULT-VARS is a reversed list of all the argument vars processed
 710 ;;; so far, including supplied-p vars. DEFAULT-VALS is a list of the
 711 ;;; names of the DEFAULT-VARS.
 712 ;;;
 713 ;;; ENTRY-VARS is a reversed list of processed argument vars,
 714 ;;; excluding supplied-p vars. ENTRY-VALS is a list things that can be
 715 ;;; evaluated to get the values for all the vars from the ENTRY-VARS.
 716 ;;; It has the var name for each required or optional arg, and has T
 717 ;;; for each supplied-p arg.
 718 ;;;
 719 ;;; VARS is a list of the LAMBDA-VAR structures for arguments that
 720 ;;; haven't been processed yet. SUPPLIED-P-P is true if a supplied-p
 721 ;;; argument has already been processed; only in this case are the
 722 ;;; DEFAULT-XXX and ENTRY-XXX different.
 723 ;;;
 724 ;;; The result at each point is a lambda which should be called by the
 725 ;;; above level to default the remaining arguments and evaluate the
 726 ;;; body. We cause the body to be evaluated by converting it and
 727 ;;; returning it as the result when the recursion bottoms out.
 728 ;;;
 729 ;;; Each level in the recursion also adds its entry point function to
 730 ;;; the result OPTIONAL-DISPATCH. For most arguments, the defaulting
 731 ;;; function and the entry point function will be the same, but when
 732 ;;; SUPPLIED-P args are present they may be different.
 733 ;;;
 734 ;;; When we run into a &REST or &KEY arg, we punt out to
 735 ;;; IR1-CONVERT-MORE, which finishes for us in this case.
 736 (defun ir1-convert-hairy-args (res default-vars default-vals
 737                                entry-vars entry-vals
 738                                vars supplied-p-p body aux-vars
 739                                aux-vals
 740                                source-name debug-name
 741                                force)
 742   (declare (type optional-dispatch res)
 743            (list default-vars default-vals entry-vars entry-vals vars body
 744                  aux-vars aux-vals))
 745   (cond ((not vars)
 746          (if (optional-dispatch-keyp res)
 747              ;; Handle &KEY with no keys...
 748              (ir1-convert-more res default-vars default-vals
 749                                entry-vars entry-vals
 750                                nil nil nil vars supplied-p-p body aux-vars
 751                                aux-vals source-name debug-name)
 752              (let* ((name (or debug-name source-name))
 753                     (fun (ir1-convert-lambda-body
 754                          body (reverse default-vars)
 755                          :aux-vars aux-vars
 756                          :aux-vals aux-vals
 757                          :debug-name (debug-name 'hairy-arg-processor name))))
 758
 759                (setf (optional-dispatch-main-entry res) fun)
 760                (register-entry-point fun res)
 761                (push (if supplied-p-p
 762                          (register-entry-point
 763                           (convert-optional-entry fun entry-vars entry-vals ()
 764                                                   name)
 765                           res)
 766                           fun)
 767                      (optional-dispatch-entry-points res))
 768                fun)))
 769         ((not (lambda-var-arg-info (first vars)))
 770          (let* ((arg (first vars))
 771                 (nvars (cons arg default-vars))
 772                 (nvals (cons (leaf-source-name arg) default-vals)))
 773            (ir1-convert-hairy-args res nvars nvals nvars nvals
 774                                    (rest vars) nil body aux-vars aux-vals
 775                                    source-name debug-name
 776                                    nil)))
 777         (t
 778          (let* ((arg (first vars))
 779                 (info (lambda-var-arg-info arg))
 780                 (kind (arg-info-kind info)))
 781            (ecase kind
 782              (:optional
 783               (let ((ep (generate-optional-default-entry
 784                          res default-vars default-vals
 785                          entry-vars entry-vals vars supplied-p-p body
 786                          aux-vars aux-vals
 787                          source-name debug-name
 788                          force)))
 789                 ;; See GENERATE-OPTIONAL-DEFAULT-ENTRY.
 790                 (push (if (lambda-p ep)
 791                           (register-entry-point
 792                            (if supplied-p-p
 793                                (convert-optional-entry
 794                                 ep entry-vars entry-vals nil
 795                                 (or debug-name source-name))
 796                                ep)
 797                            res)
 798                           (progn (aver (not supplied-p-p))
 799                                  ep))
 800                       (optional-dispatch-entry-points res))
 801                 ep))
 802              (:rest
 803               (ir1-convert-more res default-vars default-vals
 804                                 entry-vars entry-vals
 805                                 arg nil nil (rest vars) supplied-p-p body
 806                                 aux-vars aux-vals
 807                                 source-name debug-name))
 808              (:more-context
 809               (ir1-convert-more res default-vars default-vals
 810                                 entry-vars entry-vals
 811                                 nil arg (second vars) (cddr vars) supplied-p-p
 812                                 body aux-vars aux-vals
 813                                 source-name debug-name))
 814              (:keyword
 815               (ir1-convert-more res default-vars default-vals
 816                                 entry-vars entry-vals
 817                                 nil nil nil vars supplied-p-p body aux-vars
 818                                 aux-vals source-name debug-name)))))))
 819
 820 ;;; This function deals with the case where we have to make an
 821 ;;; OPTIONAL-DISPATCH to represent a LAMBDA. We cons up the result and
 822 ;;; call IR1-CONVERT-HAIRY-ARGS to do the work. When it is done, we
 823 ;;; figure out the MIN-ARGS and MAX-ARGS.
 824 (defun ir1-convert-hairy-lambda (body vars keyp allowp aux-vars aux-vals
 825                                       &key
 826                                       (source-name '.anonymous.)
 827                                       (debug-name
 828                                        (debug-name '&optional-dispatch vars)))
 829   (declare (list body vars aux-vars aux-vals))
 830   (let ((res (make-optional-dispatch :arglist vars
 831                                      :allowp allowp
 832                                      :keyp keyp
 833                                      :%source-name source-name
 834                                      :%debug-name debug-name
 835                                      :plist `(:ir1-environment
 836                                               (,*lexenv*
 837                                                ,*current-path*))))
 838         (min (or (position-if #'lambda-var-arg-info vars) (length vars))))
 839     (aver-live-component *current-component*)
 840     (push res (component-new-functionals *current-component*))
 841     (ir1-convert-hairy-args res () () () () vars nil body aux-vars aux-vals
 842                             source-name debug-name nil)
 843     (setf (optional-dispatch-min-args res) min)
 844     (setf (optional-dispatch-max-args res)
 845           (+ (1- (length (optional-dispatch-entry-points res))) min))
 846
 847     res))
 848
 849 ;;; Convert a LAMBDA form into a LAMBDA leaf or an OPTIONAL-DISPATCH leaf.
 850 (defun ir1-convert-lambda (form &key (source-name '.anonymous.)
 851                            debug-name)
 852   (unless (consp form)
 853     (compiler-error "A ~S was found when expecting a lambda expression:~%  ~S"
 854                     (type-of form)
 855                     form))
 856   (unless (eq (car form) 'lambda)
 857     (compiler-error "~S was expected but ~S was found:~%  ~S"
 858                     'lambda
 859                     (car form)
 860                     form))
 861   (unless (and (consp (cdr form)) (listp (cadr form)))
 862     (compiler-error
 863      "The lambda expression has a missing or non-list lambda list:~%  ~S"
 864      form))
 865
 866   (multiple-value-bind (vars keyp allow-other-keys aux-vars aux-vals)
 867       (make-lambda-vars (cadr form))
 868     (multiple-value-bind (forms decls) (parse-body (cddr form))
 869       (binding* (((*lexenv* result-type)
 870                   (process-decls decls (append aux-vars vars) nil))
 871                  (forms (if (and *allow-instrumenting*
 872                                  (policy *lexenv* (>= insert-debug-catch 2)))
 873                             `((catch (locally
 874                                          (declare (optimize (insert-step-conditions 0)))
 875                                     (make-symbol "SB-DEBUG-CATCH-TAG"))
 876                                 ,@forms))
 877                             forms))
 878                  (forms (if (eq result-type *wild-type*)
 879                             forms
 880                             `((the ,result-type (progn ,@forms)))))
 881                  (res (if (or (find-if #'lambda-var-arg-info vars) keyp)
 882                           (ir1-convert-hairy-lambda forms vars keyp
 883                                                     allow-other-keys
 884                                                     aux-vars aux-vals
 885                                                     :source-name source-name
 886                                                     :debug-name debug-name)
 887                           (ir1-convert-lambda-body forms vars
 888                                                    :aux-vars aux-vars
 889                                                    :aux-vals aux-vals
 890                                                    :source-name source-name
 891                                                    :debug-name debug-name))))
 892         (setf (functional-inline-expansion res) form)
 893         (setf (functional-arg-documentation res) (cadr form))
 894         res))))
 895
 896 ;;; helper for LAMBDA-like things, to massage them into a form
 897 ;;; suitable for IR1-CONVERT-LAMBDA.
 898 (defun ir1-convert-lambdalike (thing
 899                                &key
 900                                (source-name '.anonymous.)
 901                                debug-name)
 902   (ecase (car thing)
 903     ((lambda)
 904      (ir1-convert-lambda thing
 905                          :source-name source-name
 906                          :debug-name debug-name))
 907     ((instance-lambda)
 908      (let ((res (ir1-convert-lambda `(lambda ,@(cdr thing))
 909                                     :source-name source-name
 910                                     :debug-name debug-name)))
 911        (setf (getf (functional-plist res) :fin-function) t)
 912        res))
 913     ((named-lambda)
 914      (let ((name (cadr thing))
 915            (lambda-expression `(lambda ,@(cddr thing))))
 916        (if (legal-fun-name-p name)
 917            (let ((defined-fun-res (get-defined-fun name))
 918                  (res (ir1-convert-lambda lambda-expression
 919                                           :source-name name)))
 920              (assert-global-function-definition-type name res)
 921              (setf (defined-fun-functional defined-fun-res) res)
 922              (unless (eq (defined-fun-inlinep defined-fun-res) :notinline)
 923                (substitute-leaf-if
 924                 (lambda (ref)
 925                   (policy ref (> recognize-self-calls 0)))
 926                 res defined-fun-res))
 927              res)
 928            (ir1-convert-lambda lambda-expression :debug-name name))))
 929     ((lambda-with-lexenv)
 930      (ir1-convert-inline-lambda thing
 931                                 :source-name source-name
 932                                 :debug-name debug-name))))
 933 \f
 934 ;;;; defining global functions
 935
 936 ;;; Convert FUN as a lambda in the null environment, but use the
 937 ;;; current compilation policy. Note that FUN may be a
 938 ;;; LAMBDA-WITH-LEXENV, so we may have to augment the environment to
 939 ;;; reflect the state at the definition site.
 940 (defun ir1-convert-inline-lambda (fun &key
 941                                       (source-name '.anonymous.)
 942                                       debug-name)
 943   (destructuring-bind (decls macros symbol-macros &rest body)
 944                       (if (eq (car fun) 'lambda-with-lexenv)
 945                           (cdr fun)
 946                           `(() () () . ,(cdr fun)))
 947     (let ((*lexenv* (make-lexenv
 948                      :default (process-decls decls nil nil
 949                                              (make-null-lexenv))
 950                      :vars (copy-list symbol-macros)
 951                      :funs (mapcar (lambda (x)
 952                                      `(,(car x) .
 953                                        (macro . ,(coerce (cdr x) 'function))))
 954                                    macros)
 955                      :policy (lexenv-policy *lexenv*))))
 956       (ir1-convert-lambda `(lambda ,@body)
 957                           :source-name source-name
 958                           :debug-name debug-name))))
 959
 960 ;;; Get a DEFINED-FUN object for a function we are about to define. If
 961 ;;; the function has been forward referenced, then substitute for the
 962 ;;; previous references.
 963 (defun get-defined-fun (name)
 964   (proclaim-as-fun-name name)
 965   (let ((found (find-free-fun name "shouldn't happen! (defined-fun)")))
 966     (note-name-defined name :function)
 967     (cond ((not (defined-fun-p found))
 968            (aver (not (info :function :inlinep name)))
 969            (let* ((where-from (leaf-where-from found))
 970                   (res (make-defined-fun
 971                         :%source-name name
 972                         :where-from (if (eq where-from :declared)
 973                                         :declared :defined)
 974                         :type (leaf-type found))))
 975              (substitute-leaf res found)
 976              (setf (gethash name *free-funs*) res)))
 977           ;; If *FREE-FUNS* has a previously converted definition
 978           ;; for this name, then blow it away and try again.
 979           ((defined-fun-functional found)
 980            (remhash name *free-funs*)
 981            (get-defined-fun name))
 982           (t found))))
 983
 984 ;;; Check a new global function definition for consistency with
 985 ;;; previous declaration or definition, and assert argument/result
 986 ;;; types if appropriate. This assertion is suppressed by the
 987 ;;; EXPLICIT-CHECK attribute, which is specified on functions that
 988 ;;; check their argument types as a consequence of type dispatching.
 989 ;;; This avoids redundant checks such as NUMBERP on the args to +, etc.
 990 (defun assert-new-definition (var fun)
 991   (let ((type (leaf-type var))
 992         (for-real (eq (leaf-where-from var) :declared))
 993         (info (info :function :info (leaf-source-name var))))
 994     (assert-definition-type
 995      fun type
 996      ;; KLUDGE: Common Lisp is such a dynamic language that in general
 997      ;; all we can do here in general is issue a STYLE-WARNING. It
 998      ;; would be nice to issue a full WARNING in the special case of
 999      ;; of type mismatches within a compilation unit (as in section
1000      ;; 3.2.2.3 of the spec) but at least as of sbcl-0.6.11, we don't
1001      ;; keep track of whether the mismatched data came from the same
1002      ;; compilation unit, so we can't do that. -- WHN 2001-02-11
1003      :lossage-fun #'compiler-style-warn
1004      :unwinnage-fun (cond (info #'compiler-style-warn)
1005                           (for-real #'compiler-notify)
1006                           (t nil))
1007      :really-assert
1008      (and for-real
1009           (not (and info
1010                     (ir1-attributep (fun-info-attributes info)
1011                                     explicit-check))))
1012      :where (if for-real
1013                 "previous declaration"
1014                 "previous definition"))))
1015
1016 ;;; Convert a lambda doing all the basic stuff we would do if we were
1017 ;;; converting a DEFUN. In the old CMU CL system, this was used both
1018 ;;; by the %DEFUN translator and for global inline expansion, but
1019 ;;; since sbcl-0.pre7.something %DEFUN does things differently.
1020 ;;; FIXME: And now it's probably worth rethinking whether this
1021 ;;; function is a good idea.
1022 ;;;
1023 ;;; Unless a :INLINE function, we temporarily clobber the inline
1024 ;;; expansion. This prevents recursive inline expansion of
1025 ;;; opportunistic pseudo-inlines.
1026 (defun ir1-convert-lambda-for-defun (lambda var expansion converter)
1027   (declare (cons lambda) (function converter) (type defined-fun var))
1028   (let ((var-expansion (defined-fun-inline-expansion var)))
1029     (unless (eq (defined-fun-inlinep var) :inline)
1030       (setf (defined-fun-inline-expansion var) nil))
1031     (let* ((name (leaf-source-name var))
1032            (fun (funcall converter lambda
1033                          :source-name name))
1034            (fun-info (info :function :info name)))
1035       (setf (functional-inlinep fun) (defined-fun-inlinep var))
1036       (assert-new-definition var fun)
1037       (setf (defined-fun-inline-expansion var) var-expansion)
1038       ;; If definitely not an interpreter stub, then substitute for
1039       ;; any old references.
1040       (unless (or (eq (defined-fun-inlinep var) :notinline)
1041                   (not *block-compile*)
1042                   (and fun-info
1043                        (or (fun-info-transforms fun-info)
1044                            (fun-info-templates fun-info)
1045                            (fun-info-ir2-convert fun-info))))
1046         (substitute-leaf fun var)
1047         ;; If in a simple environment, then we can allow backward
1048         ;; references to this function from following top level forms.
1049         (when expansion (setf (defined-fun-functional var) fun)))
1050       fun)))
1051
1052 ;;; the even-at-compile-time part of DEFUN
1053 ;;;
1054 ;;; The INLINE-EXPANSION is a LAMBDA-WITH-LEXENV, or NIL if there is
1055 ;;; no inline expansion.
1056 (defun %compiler-defun (name lambda-with-lexenv compile-toplevel)
1057   (let ((defined-fun nil)) ; will be set below if we're in the compiler
1058     (when compile-toplevel
1059       ;; better be in the compiler
1060       (aver (boundp '*lexenv*))
1061       (remhash name *free-funs*)
1062       (setf defined-fun (get-defined-fun name))
1063       (aver (fasl-output-p *compile-object*))
1064       (if (member name *fun-names-in-this-file* :test #'equal)
1065           (warn 'duplicate-definition :name name)
1066           (push name *fun-names-in-this-file*)))
1067
1068     (become-defined-fun-name name)
1069
1070     (cond (lambda-with-lexenv
1071            (setf (info :function :inline-expansion-designator name)
1072                  lambda-with-lexenv)
1073            (when defined-fun
1074              (setf (defined-fun-inline-expansion defined-fun)
1075                    lambda-with-lexenv)))
1076           (t
1077            (clear-info :function :inline-expansion-designator name)))
1078
1079     ;; old CMU CL comment:
1080     ;;   If there is a type from a previous definition, blast it,
1081     ;;   since it is obsolete.
1082     (when (and defined-fun
1083                (eq (leaf-where-from defined-fun) :defined))
1084       (setf (leaf-type defined-fun)
1085             ;; FIXME: If this is a block compilation thing, shouldn't
1086             ;; we be setting the type to the full derived type for the
1087             ;; definition, instead of this most general function type?
1088             (specifier-type 'function))))
1089
1090   (values))
1091
1092 \f
1093 ;;; Entry point utilities
1094
1095 ;;; Return a function for the Nth entry point.
1096 (defun optional-dispatch-entry-point-fun (dispatcher n)
1097   (declare (type optional-dispatch dispatcher)
1098            (type unsigned-byte n))
1099   (let* ((env (getf (optional-dispatch-plist dispatcher) :ir1-environment))
1100          (*lexenv* (first env))
1101          (*current-path* (second env)))
1102     (force (nth n (optional-dispatch-entry-points dispatcher)))))