0.8.14.13: Step SBCL, step!
[sbcl.git] / src / compiler / ir1tran.lisp
1 ;;;; This file contains code which does the translation from Lisp code
2 ;;;; to the first intermediate representation (IR1).
3
4 ;;;; This software is part of the SBCL system. See the README file for
5 ;;;; more information.
6 ;;;;
7 ;;;; This software is derived from the CMU CL system, which was
8 ;;;; written at Carnegie Mellon University and released into the
9 ;;;; public domain. The software is in the public domain and is
10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
11 ;;;; files for more information.
12
13 (in-package "SB!C")
14
15 (declaim (special *compiler-error-bailout*))
16
17 ;;; *SOURCE-PATHS* is a hashtable from source code forms to the path
18 ;;; taken through the source to reach the form. This provides a way to
19 ;;; keep track of the location of original source forms, even when
20 ;;; macroexpansions and other arbitary permutations of the code
21 ;;; happen. This table is initialized by calling FIND-SOURCE-PATHS on
22 ;;; the original source.
23 (declaim (hash-table *source-paths*))
24 (defvar *source-paths*)
25
26 ;;; *CURRENT-COMPONENT* is the COMPONENT structure which we link
27 ;;; blocks into as we generate them. This just serves to glue the
28 ;;; emitted blocks together until local call analysis and flow graph
29 ;;; canonicalization figure out what is really going on. We need to
30 ;;; keep track of all the blocks generated so that we can delete them
31 ;;; if they turn out to be unreachable.
32 ;;;
33 ;;; FIXME: It's confusing having one variable named *CURRENT-COMPONENT*
34 ;;; and another named *COMPONENT-BEING-COMPILED*. (In CMU CL they
35 ;;; were called *CURRENT-COMPONENT* and *COMPILE-COMPONENT* respectively,
36 ;;; which was also confusing.)
37 (declaim (type (or component null) *current-component*))
38 (defvar *current-component*)
39
40 ;;; *CURRENT-PATH* is the source path of the form we are currently
41 ;;; translating. See NODE-SOURCE-PATH in the NODE structure.
42 (declaim (list *current-path*))
43 (defvar *current-path*)
44
45 (defvar *derive-function-types* nil
46   "Should the compiler assume that function types will never change,
47   so that it can use type information inferred from current definitions
48   to optimize code which uses those definitions? Setting this true
49   gives non-ANSI, early-CMU-CL behavior. It can be useful for improving
50   the efficiency of stable code.")
51
52 (defvar *fun-names-in-this-file* nil)
53
54 ;;; *ALLOW-DEBUG-CATCH-TAG* controls whether we should allow the
55 ;;; insertion a (CATCH ...) around code to allow the debugger RETURN
56 ;;; command to function.
57 (defvar *allow-debug-catch-tag* t)
58 \f
59 ;;;; namespace management utilities
60
61 (defun fun-lexically-notinline-p (name)
62   (let ((fun (lexenv-find name funs :test #'equal)))
63     ;; a declaration will trump a proclamation
64     (if (and fun (defined-fun-p fun))
65         (eq (defined-fun-inlinep fun) :notinline)
66         (eq (info :function :inlinep name) :notinline))))
67
68 ;;; Return a GLOBAL-VAR structure usable for referencing the global
69 ;;; function NAME.
70 (defun find-free-really-fun (name)
71   (unless (info :function :kind name)
72     (setf (info :function :kind name) :function)
73     (setf (info :function :where-from name) :assumed))
74
75   (let ((where (info :function :where-from name)))
76     (when (and (eq where :assumed)
77                ;; In the ordinary target Lisp, it's silly to report
78                ;; undefinedness when the function is defined in the
79                ;; running Lisp. But at cross-compile time, the current
80                ;; definedness of a function is irrelevant to the
81                ;; definedness at runtime, which is what matters.
82                #-sb-xc-host (not (fboundp name)))
83       (note-undefined-reference name :function))
84     (make-global-var
85      :kind :global-function
86      :%source-name name
87      :type (if (or *derive-function-types*
88                    (eq where :declared)
89                    (and (member name *fun-names-in-this-file* :test #'equal)
90                         (not (fun-lexically-notinline-p name))))
91                (info :function :type name)
92                (specifier-type 'function))
93      :where-from where)))
94
95 ;;; Has the *FREE-FUNS* entry FREE-FUN become invalid?
96 ;;;
97 ;;; In CMU CL, the answer was implicitly always true, so this 
98 ;;; predicate didn't exist.
99 ;;;
100 ;;; This predicate was added to fix bug 138 in SBCL. In some obscure
101 ;;; circumstances, it was possible for a *FREE-FUNS* entry to contain a
102 ;;; DEFINED-FUN whose DEFINED-FUN-FUNCTIONAL object contained IR1
103 ;;; stuff (NODEs, BLOCKs...) referring to an already compiled (aka
104 ;;; "dead") component. When this IR1 stuff was reused in a new
105 ;;; component, under further obscure circumstances it could be used by
106 ;;; WITH-IR1-ENVIRONMENT-FROM-NODE to generate a binding for
107 ;;; *CURRENT-COMPONENT*. At that point things got all confused, since
108 ;;; IR1 conversion was sending code to a component which had already
109 ;;; been compiled and would never be compiled again.
110 (defun invalid-free-fun-p (free-fun)
111   ;; There might be other reasons that *FREE-FUN* entries could
112   ;; become invalid, but the only one we've been bitten by so far
113   ;; (sbcl-0.pre7.118) is this one:
114   (and (defined-fun-p free-fun)
115        (let ((functional (defined-fun-functional free-fun)))
116          (or (and functional
117                   (eql (functional-kind functional) :deleted))
118              (and (lambda-p functional)
119                   (or
120                    ;; (The main reason for this first test is to bail
121                    ;; out early in cases where the LAMBDA-COMPONENT
122                    ;; call in the second test would fail because links
123                    ;; it needs are uninitialized or invalid.)
124                    ;;
125                    ;; If the BIND node for this LAMBDA is null, then
126                    ;; according to the slot comments, the LAMBDA has
127                    ;; been deleted or its call has been deleted. In
128                    ;; that case, it seems rather questionable to reuse
129                    ;; it, and certainly it shouldn't be necessary to
130                    ;; reuse it, so we cheerfully declare it invalid.
131                    (null (lambda-bind functional))
132                    ;; If this IR1 stuff belongs to a dead component,
133                    ;; then we can't reuse it without getting into
134                    ;; bizarre confusion.
135                    (eql (component-info (lambda-component functional))
136                         :dead)))))))
137
138 ;;; If NAME already has a valid entry in *FREE-FUNS*, then return
139 ;;; the value. Otherwise, make a new GLOBAL-VAR using information from
140 ;;; the global environment and enter it in *FREE-FUNS*. If NAME
141 ;;; names a macro or special form, then we error out using the
142 ;;; supplied context which indicates what we were trying to do that
143 ;;; demanded a function.
144 (declaim (ftype (sfunction (t string) global-var) find-free-fun))
145 (defun find-free-fun (name context)
146   (or (let ((old-free-fun (gethash name *free-funs*)))
147         (and (not (invalid-free-fun-p old-free-fun))
148              old-free-fun))
149       (ecase (info :function :kind name)
150         ;; FIXME: The :MACRO and :SPECIAL-FORM cases could be merged.
151         (:macro
152          (compiler-error "The macro name ~S was found ~A." name context))
153         (:special-form
154          (compiler-error "The special form name ~S was found ~A."
155                          name
156                          context))
157         ((:function nil)
158          (check-fun-name name)
159          (note-if-setf-fun-and-macro name)
160          (let ((expansion (fun-name-inline-expansion name))
161                (inlinep (info :function :inlinep name)))
162            (setf (gethash name *free-funs*)
163                  (if (or expansion inlinep)
164                      (make-defined-fun
165                       :%source-name name
166                       :inline-expansion expansion
167                       :inlinep inlinep
168                       :where-from (info :function :where-from name)
169                       :type (if (eq inlinep :notinline)
170                                 (specifier-type 'function)
171                                 (info :function :type name)))
172                      (find-free-really-fun name))))))))
173
174 ;;; Return the LEAF structure for the lexically apparent function
175 ;;; definition of NAME.
176 (declaim (ftype (sfunction (t string) leaf) find-lexically-apparent-fun))
177 (defun find-lexically-apparent-fun (name context)
178   (let ((var (lexenv-find name funs :test #'equal)))
179     (cond (var
180            (unless (leaf-p var)
181              (aver (and (consp var) (eq (car var) 'macro)))
182              (compiler-error "found macro name ~S ~A" name context))
183            var)
184           (t
185            (find-free-fun name context)))))
186
187 ;;; Return the LEAF node for a global variable reference to NAME. If
188 ;;; NAME is already entered in *FREE-VARS*, then we just return the
189 ;;; corresponding value. Otherwise, we make a new leaf using
190 ;;; information from the global environment and enter it in
191 ;;; *FREE-VARS*. If the variable is unknown, then we emit a warning.
192 (declaim (ftype (sfunction (t) (or leaf cons heap-alien-info)) find-free-var))
193 (defun find-free-var (name)
194   (unless (symbolp name)
195     (compiler-error "Variable name is not a symbol: ~S." name))
196   (or (gethash name *free-vars*)
197       (let ((kind (info :variable :kind name))
198             (type (info :variable :type name))
199             (where-from (info :variable :where-from name)))
200         (when (and (eq where-from :assumed) (eq kind :global))
201           (note-undefined-reference name :variable))
202         (setf (gethash name *free-vars*)
203               (case kind
204                 (:alien
205                  (info :variable :alien-info name))
206                 ;; FIXME: The return value in this case should really be
207                 ;; of type SB!C::LEAF.  I don't feel too badly about it,
208                 ;; because the MACRO idiom is scattered throughout this
209                 ;; file, but it should be cleaned up so we're not
210                 ;; throwing random conses around.  --njf 2002-03-23
211                 (:macro
212                  (let ((expansion (info :variable :macro-expansion name))
213                        (type (type-specifier (info :variable :type name))))
214                    `(MACRO . (the ,type ,expansion))))
215                 (:constant
216                  (let ((value (info :variable :constant-value name)))
217                    (make-constant :value value
218                                   :%source-name name
219                                   :type (ctype-of value)
220                                   :where-from where-from)))
221                 (t
222                  (make-global-var :kind kind
223                                   :%source-name name
224                                   :type type
225                                   :where-from where-from)))))))
226 \f
227 ;;; Grovel over CONSTANT checking for any sub-parts that need to be
228 ;;; processed with MAKE-LOAD-FORM. We have to be careful, because
229 ;;; CONSTANT might be circular. We also check that the constant (and
230 ;;; any subparts) are dumpable at all.
231 (eval-when (:compile-toplevel :load-toplevel :execute)
232   ;; The EVAL-WHEN is necessary for #.(1+ LIST-TO-HASH-TABLE-THRESHOLD)
233   ;; below. -- AL 20010227
234   (def!constant list-to-hash-table-threshold 32))
235 (defun maybe-emit-make-load-forms (constant)
236   (let ((things-processed nil)
237         (count 0))
238     ;; FIXME: Does this LIST-or-HASH-TABLE messiness give much benefit?
239     (declare (type (or list hash-table) things-processed)
240              (type (integer 0 #.(1+ list-to-hash-table-threshold)) count)
241              (inline member))
242     (labels ((grovel (value)
243                ;; Unless VALUE is an object which which obviously
244                ;; can't contain other objects
245                (unless (typep value
246                               '(or #-sb-xc-host unboxed-array
247                                    symbol
248                                    number
249                                    character
250                                    string))
251                  (etypecase things-processed
252                    (list
253                     (when (member value things-processed :test #'eq)
254                       (return-from grovel nil))
255                     (push value things-processed)
256                     (incf count)
257                     (when (> count list-to-hash-table-threshold)
258                       (let ((things things-processed))
259                         (setf things-processed
260                               (make-hash-table :test 'eq))
261                         (dolist (thing things)
262                           (setf (gethash thing things-processed) t)))))
263                    (hash-table
264                     (when (gethash value things-processed)
265                       (return-from grovel nil))
266                     (setf (gethash value things-processed) t)))
267                  (typecase value
268                    (cons
269                     (grovel (car value))
270                     (grovel (cdr value)))
271                    (simple-vector
272                     (dotimes (i (length value))
273                       (grovel (svref value i))))
274                    ((vector t)
275                     (dotimes (i (length value))
276                       (grovel (aref value i))))
277                    ((simple-array t)
278                     ;; Even though the (ARRAY T) branch does the exact
279                     ;; same thing as this branch we do this separately
280                     ;; so that the compiler can use faster versions of
281                     ;; array-total-size and row-major-aref.
282                     (dotimes (i (array-total-size value))
283                       (grovel (row-major-aref value i))))
284                    ((array t)
285                     (dotimes (i (array-total-size value))
286                       (grovel (row-major-aref value i))))
287                    (;; In the target SBCL, we can dump any instance,
288                     ;; but in the cross-compilation host,
289                     ;; %INSTANCE-FOO functions don't work on general
290                     ;; instances, only on STRUCTURE!OBJECTs.
291                     #+sb-xc-host structure!object
292                     #-sb-xc-host instance
293                     (when (emit-make-load-form value)
294                       (dotimes (i (%instance-length value))
295                         (grovel (%instance-ref value i)))))
296                    (t
297                     (compiler-error
298                      "Objects of type ~S can't be dumped into fasl files."
299                      (type-of value)))))))
300       (grovel constant)))
301   (values))
302 \f
303 ;;;; some flow-graph hacking utilities
304
305 ;;; This function sets up the back link between the node and the
306 ;;; ctran which continues at it.
307 (defun link-node-to-previous-ctran (node ctran)
308   (declare (type node node) (type ctran ctran))
309   (aver (not (ctran-next ctran)))
310   (setf (ctran-next ctran) node)
311   (setf (node-prev node) ctran))
312
313 ;;; This function is used to set the ctran for a node, and thus
314 ;;; determine what is evaluated next. If the ctran has no block, then
315 ;;; we make it be in the block that the node is in. If the ctran heads
316 ;;; its block, we end our block and link it to that block.
317 #!-sb-fluid (declaim (inline use-ctran))
318 (defun use-ctran (node ctran)
319   (declare (type node node) (type ctran ctran))
320   (if (eq (ctran-kind ctran) :unused)
321       (let ((node-block (ctran-block (node-prev node))))
322         (setf (ctran-block ctran) node-block)
323         (setf (ctran-kind ctran) :inside-block)
324         (setf (ctran-use ctran) node)
325         (setf (node-next node) ctran))
326       (%use-ctran node ctran)))
327 (defun %use-ctran (node ctran)
328   (declare (type node node) (type ctran ctran) (inline member))
329   (let ((block (ctran-block ctran))
330         (node-block (ctran-block (node-prev node))))
331     (aver (eq (ctran-kind ctran) :block-start))
332     (when (block-last node-block)
333       (error "~S has already ended." node-block))
334     (setf (block-last node-block) node)
335     (when (block-succ node-block)
336       (error "~S already has successors." node-block))
337     (setf (block-succ node-block) (list block))
338     (when (memq node-block (block-pred block))
339       (error "~S is already a predecessor of ~S." node-block block))
340     (push node-block (block-pred block))))
341
342 ;;; This function is used to set the ctran for a node, and thus
343 ;;; determine what receives the value.
344 (defun use-lvar (node lvar)
345   (declare (type valued-node node) (type (or lvar null) lvar))
346   (aver (not (node-lvar node)))
347   (when lvar
348     (setf (node-lvar node) lvar)
349     (cond ((null (lvar-uses lvar))
350            (setf (lvar-uses lvar) node))
351           ((listp (lvar-uses lvar))
352            (aver (not (memq node (lvar-uses lvar))))
353            (push node (lvar-uses lvar)))
354           (t
355            (aver (neq node (lvar-uses lvar)))
356            (setf (lvar-uses lvar) (list node (lvar-uses lvar)))))
357     (reoptimize-lvar lvar)))
358
359 #!-sb-fluid(declaim (inline use-continuation))
360 (defun use-continuation (node ctran lvar)
361   (use-ctran node ctran)
362   (use-lvar node lvar))
363 \f
364 ;;;; exported functions
365
366 ;;; This function takes a form and the top level form number for that
367 ;;; form, and returns a lambda representing the translation of that
368 ;;; form in the current global environment. The returned lambda is a
369 ;;; top level lambda that can be called to cause evaluation of the
370 ;;; forms. This lambda is in the initial component. If FOR-VALUE is T,
371 ;;; then the value of the form is returned from the function,
372 ;;; otherwise NIL is returned.
373 ;;;
374 ;;; This function may have arbitrary effects on the global environment
375 ;;; due to processing of EVAL-WHENs. All syntax error checking is
376 ;;; done, with erroneous forms being replaced by a proxy which signals
377 ;;; an error if it is evaluated. Warnings about possibly inconsistent
378 ;;; or illegal changes to the global environment will also be given.
379 ;;;
380 ;;; We make the initial component and convert the form in a PROGN (and
381 ;;; an optional NIL tacked on the end.) We then return the lambda. We
382 ;;; bind all of our state variables here, rather than relying on the
383 ;;; global value (if any) so that IR1 conversion will be reentrant.
384 ;;; This is necessary for EVAL-WHEN processing, etc.
385 ;;;
386 ;;; The hashtables used to hold global namespace info must be
387 ;;; reallocated elsewhere. Note also that *LEXENV* is not bound, so
388 ;;; that local macro definitions can be introduced by enclosing code.
389 (defun ir1-toplevel (form path for-value)
390   (declare (list path))
391   (let* ((*current-path* path)
392          (component (make-empty-component))
393          (*current-component* component))
394     (setf (component-name component) "initial component")
395     (setf (component-kind component) :initial)
396     (let* ((forms (if for-value `(,form) `(,form nil)))
397            (res (ir1-convert-lambda-body
398                  forms ()
399                  :debug-name (debug-namify "top level form " form))))
400       (setf (functional-entry-fun res) res
401             (functional-arg-documentation res) ()
402             (functional-kind res) :toplevel)
403       res)))
404
405 ;;; *CURRENT-FORM-NUMBER* is used in FIND-SOURCE-PATHS to compute the
406 ;;; form number to associate with a source path. This should be bound
407 ;;; to an initial value of 0 before the processing of each truly
408 ;;; top level form.
409 (declaim (type index *current-form-number*))
410 (defvar *current-form-number*)
411
412 ;;; This function is called on freshly read forms to record the
413 ;;; initial location of each form (and subform.) Form is the form to
414 ;;; find the paths in, and TLF-NUM is the top level form number of the
415 ;;; truly top level form.
416 ;;;
417 ;;; This gets a bit interesting when the source code is circular. This
418 ;;; can (reasonably?) happen in the case of circular list constants.
419 (defun find-source-paths (form tlf-num)
420   (declare (type index tlf-num))
421   (let ((*current-form-number* 0))
422     (sub-find-source-paths form (list tlf-num)))
423   (values))
424 (defun sub-find-source-paths (form path)
425   (unless (gethash form *source-paths*)
426     (setf (gethash form *source-paths*)
427           (list* 'original-source-start *current-form-number* path))
428     (incf *current-form-number*)
429     (let ((pos 0)
430           (subform form)
431           (trail form))
432       (declare (fixnum pos))
433       (macrolet ((frob ()
434                    '(progn
435                       (when (atom subform) (return))
436                       (let ((fm (car subform)))
437                         (when (consp fm)
438                           (sub-find-source-paths fm (cons pos path)))
439                         (incf pos))
440                       (setq subform (cdr subform))
441                       (when (eq subform trail) (return)))))
442         (loop
443           (frob)
444           (frob)
445           (setq trail (cdr trail)))))))
446 \f
447 ;;;; IR1-CONVERT, macroexpansion and special form dispatching
448
449 (declaim (ftype (sfunction (ctran ctran (or lvar null) t) (values))
450                 ir1-convert))
451 (macrolet (;; Bind *COMPILER-ERROR-BAILOUT* to a function that throws
452            ;; out of the body and converts a condition signalling form
453            ;; instead. The source form is converted to a string since it
454            ;; may contain arbitrary non-externalizable objects.
455            (ir1-error-bailout ((start next result form) &body body)
456              (with-unique-names (skip condition)
457                `(block ,skip
458                  (let ((,condition (catch 'ir1-error-abort
459                                      (let ((*compiler-error-bailout*
460                                             (lambda (&optional e)
461                                               (throw 'ir1-error-abort e))))
462                                        ,@body
463                                        (return-from ,skip nil)))))
464                    (ir1-convert ,start ,next ,result
465                                 (make-compiler-error-form ,condition ,form)))))))
466
467   ;; Translate FORM into IR1. The code is inserted as the NEXT of the
468   ;; CTRAN START. RESULT is the LVAR which receives the value of the
469   ;; FORM to be translated. The translators call this function
470   ;; recursively to translate their subnodes.
471   ;;
472   ;; As a special hack to make life easier in the compiler, a LEAF
473   ;; IR1-converts into a reference to that LEAF structure. This allows
474   ;; the creation using backquote of forms that contain leaf
475   ;; references, without having to introduce dummy names into the
476   ;; namespace.
477   (defun ir1-convert (start next result form)
478     (ir1-error-bailout (start next result form)
479       (let ((*current-path* (or (gethash form *source-paths*)
480                                 (cons form *current-path*))))
481         (if (step-form-p form)
482             (ir1-convert-step start next result form)
483         (if (atom form)
484             (cond ((and (symbolp form) (not (keywordp form)))
485                    (ir1-convert-var start next result form))
486                   ((leaf-p form)
487                    (reference-leaf start next result form))
488                   (t
489                    (reference-constant start next result form)))
490             (let ((opname (car form)))
491               (cond ((or (symbolp opname) (leaf-p opname))
492                      (let ((lexical-def (if (leaf-p opname)
493                                             opname
494                                             (lexenv-find opname funs))))
495                        (typecase lexical-def
496                          (null
497                           (ir1-convert-global-functoid start next result
498                                                        form))
499                          (functional
500                           (ir1-convert-local-combination start next result
501                                                          form
502                                                          lexical-def))
503                          (global-var
504                           (ir1-convert-srctran start next result
505                                                lexical-def form))
506                          (t
507                           (aver (and (consp lexical-def)
508                                      (eq (car lexical-def) 'macro)))
509                           (ir1-convert start next result
510                                        (careful-expand-macro (cdr lexical-def)
511                                                              form))))))
512                     ((or (atom opname) (not (eq (car opname) 'lambda)))
513                      (compiler-error "illegal function call"))
514                     (t
515                      ;; implicitly (LAMBDA ..) because the LAMBDA
516                      ;; expression is the CAR of an executed form
517                      (ir1-convert-combination start next result
518                                               form
519                                               (ir1-convert-lambda
520                                                opname
521                                                :debug-name (debug-namify
522                                                             "LAMBDA CAR "
523                                                             opname)
524                                                :allow-debug-catch-tag t)))))))))
525     (values))
526
527   ;; Generate a reference to a manifest constant, creating a new leaf
528   ;; if necessary. If we are producing a fasl file, make sure that
529   ;; MAKE-LOAD-FORM gets used on any parts of the constant that it
530   ;; needs to be.
531   (defun reference-constant (start next result value)
532     (declare (type ctran start next)
533              (type (or lvar null) result)
534              (inline find-constant))
535     (ir1-error-bailout (start next result value)
536      (when (producing-fasl-file)
537        (maybe-emit-make-load-forms value))
538      (let* ((leaf (find-constant value))
539             (res (make-ref leaf)))
540        (push res (leaf-refs leaf))
541        (link-node-to-previous-ctran res start)
542        (use-continuation res next result)))
543     (values)))
544
545 ;;; Add FUNCTIONAL to the COMPONENT-REANALYZE-FUNCTIONALS, unless it's
546 ;;; some trivial type for which reanalysis is a trivial no-op, or
547 ;;; unless it doesn't belong in this component at all.
548 ;;;
549 ;;; FUNCTIONAL is returned.
550 (defun maybe-reanalyze-functional (functional)
551
552   (aver (not (eql (functional-kind functional) :deleted))) ; bug 148
553   (aver-live-component *current-component*)
554
555   ;; When FUNCTIONAL is of a type for which reanalysis isn't a trivial
556   ;; no-op
557   (when (typep functional '(or optional-dispatch clambda))
558
559     ;; When FUNCTIONAL knows its component
560     (when (lambda-p functional)
561       (aver (eql (lambda-component functional) *current-component*)))
562
563     (pushnew functional
564              (component-reanalyze-functionals *current-component*)))
565
566   functional)
567
568 ;;; Generate a REF node for LEAF, frobbing the LEAF structure as
569 ;;; needed. If LEAF represents a defined function which has already
570 ;;; been converted, and is not :NOTINLINE, then reference the
571 ;;; functional instead.
572 (defun reference-leaf (start next result leaf)
573   (declare (type ctran start next) (type (or lvar null) result) (type leaf leaf))
574   (when (functional-p leaf)
575     (assure-functional-live-p leaf))
576   (let* ((type (lexenv-find leaf type-restrictions))
577          (leaf (or (and (defined-fun-p leaf)
578                         (not (eq (defined-fun-inlinep leaf)
579                                  :notinline))
580                         (let ((functional (defined-fun-functional leaf)))
581                           (when (and functional
582                                      (not (functional-kind functional)))
583                             (maybe-reanalyze-functional functional))))
584                    (when (and (lambda-p leaf)
585                               (memq (functional-kind leaf)
586                                     '(nil :optional)))
587                      (maybe-reanalyze-functional leaf))
588                    leaf))
589          (ref (make-ref leaf)))
590     (push ref (leaf-refs leaf))
591     (setf (leaf-ever-used leaf) t)
592     (link-node-to-previous-ctran ref start)
593     (cond (type (let* ((ref-ctran (make-ctran))
594                        (ref-lvar (make-lvar))
595                        (cast (make-cast ref-lvar
596                                         (make-single-value-type type)
597                                         (lexenv-policy *lexenv*))))
598                   (setf (lvar-dest ref-lvar) cast)
599                   (use-continuation ref ref-ctran ref-lvar)
600                   (link-node-to-previous-ctran cast ref-ctran)
601                   (use-continuation cast next result)))
602           (t (use-continuation ref next result)))))
603
604 ;;; Convert a reference to a symbolic constant or variable. If the
605 ;;; symbol is entered in the LEXENV-VARS we use that definition,
606 ;;; otherwise we find the current global definition. This is also
607 ;;; where we pick off symbol macro and alien variable references.
608 (defun ir1-convert-var (start next result name)
609   (declare (type ctran start next) (type (or lvar null) result) (symbol name))
610   (let ((var (or (lexenv-find name vars) (find-free-var name))))
611     (etypecase var
612       (leaf
613        (when (lambda-var-p var)
614          (let ((home (ctran-home-lambda-or-null start)))
615            (when home
616              (pushnew var (lambda-calls-or-closes home))))
617          (when (lambda-var-ignorep var)
618            ;; (ANSI's specification for the IGNORE declaration requires
619            ;; that this be a STYLE-WARNING, not a full WARNING.)
620            #-sb-xc-host
621            (compiler-style-warn "reading an ignored variable: ~S" name)
622            ;; there's no need for us to accept ANSI's lameness when
623            ;; processing our own code, though.
624            #+sb-xc-host
625            (warn "reading an ignored variable: ~S" name)))
626        (reference-leaf start next result var))
627       (cons
628        (aver (eq (car var) 'MACRO))
629        ;; FIXME: [Free] type declarations. -- APD, 2002-01-26
630        (ir1-convert start next result (cdr var)))
631       (heap-alien-info
632        (ir1-convert start next result `(%heap-alien ',var)))))
633   (values))
634
635 ;;; Convert anything that looks like a special form, global function
636 ;;; or compiler-macro call.
637 (defun ir1-convert-global-functoid (start next result form)
638   (declare (type ctran start next) (type (or lvar null) result) (list form))
639   (let* ((fun-name (first form))
640          (translator (info :function :ir1-convert fun-name))
641          (cmacro-fun (sb!xc:compiler-macro-function fun-name *lexenv*)))
642     (cond (translator
643            (when cmacro-fun
644              (compiler-warn "ignoring compiler macro for special form"))
645            (funcall translator start next result form))
646           ((and cmacro-fun
647                 ;; gotcha: If you look up the DEFINE-COMPILER-MACRO
648                 ;; macro in the ANSI spec, you might think that
649                 ;; suppressing compiler-macro expansion when NOTINLINE
650                 ;; is some pre-ANSI hack. However, if you look up the
651                 ;; NOTINLINE declaration, you'll find that ANSI
652                 ;; requires this behavior after all.
653                 (not (eq (info :function :inlinep fun-name) :notinline)))
654            (let ((res (careful-expand-macro cmacro-fun form)))
655              (if (eq res form)
656                  (ir1-convert-global-functoid-no-cmacro
657                   start next result form fun-name)
658                  (ir1-convert start next result res))))
659           (t
660            (ir1-convert-global-functoid-no-cmacro start next result
661                                                   form fun-name)))))
662
663 ;;; Handle the case of where the call was not a compiler macro, or was
664 ;;; a compiler macro and passed.
665 (defun ir1-convert-global-functoid-no-cmacro (start next result form fun)
666   (declare (type ctran start next) (type (or lvar null) result)
667            (list form))
668   ;; FIXME: Couldn't all the INFO calls here be converted into
669   ;; standard CL functions, like MACRO-FUNCTION or something?
670   ;; And what happens with lexically-defined (MACROLET) macros
671   ;; here, anyway?
672   (ecase (info :function :kind fun)
673     (:macro
674      (ir1-convert start next result
675                   (careful-expand-macro (info :function :macro-function fun)
676                                         form)))
677     ((nil :function)
678      (ir1-convert-srctran start next result
679                           (find-free-fun fun "shouldn't happen! (no-cmacro)")
680                           form))))
681
682 (defun muffle-warning-or-die ()
683   (muffle-warning)
684   (bug "no MUFFLE-WARNING restart"))
685
686 ;;; Expand FORM using the macro whose MACRO-FUNCTION is FUN, trapping
687 ;;; errors which occur during the macroexpansion.
688 (defun careful-expand-macro (fun form)
689   (let (;; a hint I (WHN) wish I'd known earlier
690         (hint "(hint: For more precise location, try *BREAK-ON-SIGNALS*.)"))
691     (flet (;; Return a string to use as a prefix in error reporting,
692            ;; telling something about which form caused the problem.
693            (wherestring ()
694              (let ((*print-pretty* nil)
695                    ;; We rely on the printer to abbreviate FORM. 
696                    (*print-length* 3)
697                    (*print-level* 1))
698                (format
699                 nil
700                 #-sb-xc-host "(in macroexpansion of ~S)"
701                 ;; longer message to avoid ambiguity "Was it the xc host
702                 ;; or the cross-compiler which encountered the problem?"
703                 #+sb-xc-host "(in cross-compiler macroexpansion of ~S)"
704                 form))))
705       (handler-bind ((style-warning (lambda (c)
706                                       (compiler-style-warn
707                                        "~@<~A~:@_~A~@:_~A~:>"
708                                        (wherestring) hint c)
709                                       (muffle-warning-or-die)))
710                      ;; KLUDGE: CMU CL in its wisdom (version 2.4.6 for
711                      ;; Debian Linux, anyway) raises a CL:WARNING
712                      ;; condition (not a CL:STYLE-WARNING) for undefined
713                      ;; symbols when converting interpreted functions,
714                      ;; causing COMPILE-FILE to think the file has a real
715                      ;; problem, causing COMPILE-FILE to return FAILURE-P
716                      ;; set (not just WARNINGS-P set). Since undefined
717                      ;; symbol warnings are often harmless forward
718                      ;; references, and since it'd be inordinately painful
719                      ;; to try to eliminate all such forward references,
720                      ;; these warnings are basically unavoidable. Thus, we
721                      ;; need to coerce the system to work through them,
722                      ;; and this code does so, by crudely suppressing all
723                      ;; warnings in cross-compilation macroexpansion. --
724                      ;; WHN 19990412
725                      #+(and cmu sb-xc-host)
726                      (warning (lambda (c)
727                                 (compiler-notify
728                                  "~@<~A~:@_~
729                                   ~A~:@_~
730                                   ~@<(KLUDGE: That was a non-STYLE WARNING. ~
731                                   Ordinarily that would cause compilation to ~
732                                   fail. However, since we're running under ~
733                                   CMU CL, and since CMU CL emits non-STYLE ~
734                                   warnings for safe, hard-to-fix things (e.g. ~
735                                   references to not-yet-defined functions) ~
736                                   we're going to have to ignore it and ~
737                                   proceed anyway. Hopefully we're not ~
738                                   ignoring anything  horrible here..)~:@>~:>"
739                                  (wherestring)
740                                  c)
741                                 (muffle-warning-or-die)))
742                      #-(and cmu sb-xc-host)
743                      (warning (lambda (c)
744                                 (warn "~@<~A~:@_~A~@:_~A~:>"
745                                       (wherestring) hint c)
746                                 (muffle-warning-or-die)))
747                      (error (lambda (c)
748                               (compiler-error "~@<~A~:@_~A~@:_~A~:>"
749                                               (wherestring) hint c))))
750         (funcall sb!xc:*macroexpand-hook* fun form *lexenv*)))))
751 \f
752 ;;;; conversion utilities
753
754 ;;; Convert a bunch of forms, discarding all the values except the
755 ;;; last. If there aren't any forms, then translate a NIL.
756 (declaim (ftype (sfunction (ctran ctran (or lvar null) list) (values))
757                 ir1-convert-progn-body))
758 (defun ir1-convert-progn-body (start next result body)
759   (if (endp body)
760       (reference-constant start next result nil)
761       (let ((this-start start)
762             (forms body))
763         (loop
764           (let ((form (car forms)))
765             (when (endp (cdr forms))
766               (ir1-convert this-start next result form)
767               (return))
768             (let ((this-ctran (make-ctran)))
769               (ir1-convert this-start this-ctran nil form)
770               (setq this-start this-ctran
771                     forms (cdr forms)))))))
772   (values))
773 \f
774 ;;;; converting combinations
775
776 ;;; Convert a function call where the function FUN is a LEAF. FORM is
777 ;;; the source for the call. We return the COMBINATION node so that
778 ;;; the caller can poke at it if it wants to.
779 (declaim (ftype (sfunction (ctran ctran (or lvar null) list leaf) combination)
780                 ir1-convert-combination))
781 (defun ir1-convert-combination (start next result form fun)
782   (let ((ctran (make-ctran))
783         (fun-lvar (make-lvar)))
784     (ir1-convert start ctran fun-lvar `(the (or function symbol) ,fun))
785     (ir1-convert-combination-args fun-lvar ctran next result (cdr form))))
786
787 ;;; Convert the arguments to a call and make the COMBINATION
788 ;;; node. FUN-LVAR yields the function to call. ARGS is the list of
789 ;;; arguments for the call, which defaults to the cdr of source. We
790 ;;; return the COMBINATION node.
791 (defun ir1-convert-combination-args (fun-lvar start next result args)
792   (declare (type ctran start next)
793            (type lvar fun-lvar)
794            (type (or lvar null) result)
795            (list args))
796   (let ((node (make-combination fun-lvar)))
797     (setf (lvar-dest fun-lvar) node)
798     (collect ((arg-lvars))
799       (let ((this-start start))
800         (dolist (arg args)
801           (let ((this-ctran (make-ctran))
802                 (this-lvar (make-lvar node)))
803             (ir1-convert this-start this-ctran this-lvar arg)
804             (setq this-start this-ctran)
805             (arg-lvars this-lvar)))
806         (link-node-to-previous-ctran node this-start)
807         (use-continuation node next result)
808         (setf (combination-args node) (arg-lvars))))
809     node))
810
811 ;;; Convert a call to a global function. If not :NOTINLINE, then we do
812 ;;; source transforms and try out any inline expansion. If there is no
813 ;;; expansion, but is :INLINE, then give an efficiency note (unless a
814 ;;; known function which will quite possibly be open-coded.) Next, we
815 ;;; go to ok-combination conversion.
816 (defun ir1-convert-srctran (start next result var form)
817   (declare (type ctran start next) (type (or lvar null) result)
818            (type global-var var))
819   (let ((inlinep (when (defined-fun-p var)
820                    (defined-fun-inlinep var))))
821     (if (eq inlinep :notinline)
822         (ir1-convert-combination start next result form var)
823         (let ((transform (info :function
824                                :source-transform
825                                (leaf-source-name var))))
826           (if transform
827               (multiple-value-bind (transformed pass) (funcall transform form)
828                 (if pass
829                     (ir1-convert-maybe-predicate start next result form var)
830                     (ir1-convert start next result transformed)))
831               (ir1-convert-maybe-predicate start next result form var))))))
832
833 ;;; If the function has the PREDICATE attribute, and the RESULT's DEST
834 ;;; isn't an IF, then we convert (IF <form> T NIL), ensuring that a
835 ;;; predicate always appears in a conditional context.
836 ;;;
837 ;;; If the function isn't a predicate, then we call
838 ;;; IR1-CONVERT-COMBINATION-CHECKING-TYPE.
839 (defun ir1-convert-maybe-predicate (start next result form var)
840   (declare (type ctran start next)
841            (type (or lvar null) result)
842            (list form)
843            (type global-var var))
844   (let ((info (info :function :info (leaf-source-name var))))
845     (if (and info
846              (ir1-attributep (fun-info-attributes info) predicate)
847              (not (if-p (and result (lvar-dest result)))))
848         (ir1-convert start next result `(if ,form t nil))
849         (ir1-convert-combination-checking-type start next result form var))))
850
851 ;;; Actually really convert a global function call that we are allowed
852 ;;; to early-bind.
853 ;;;
854 ;;; If we know the function type of the function, then we check the
855 ;;; call for syntactic legality with respect to the declared function
856 ;;; type. If it is impossible to determine whether the call is correct
857 ;;; due to non-constant keywords, then we give up, marking the call as
858 ;;; :FULL to inhibit further error messages. We return true when the
859 ;;; call is legal.
860 ;;;
861 ;;; If the call is legal, we also propagate type assertions from the
862 ;;; function type to the arg and result lvars. We do this now so that
863 ;;; IR1 optimize doesn't have to redundantly do the check later so
864 ;;; that it can do the type propagation.
865 (defun ir1-convert-combination-checking-type (start next result form var)
866   (declare (type ctran start next) (type (or lvar null) result)
867            (list form)
868            (type leaf var))
869   (let* ((node (ir1-convert-combination start next result form var))
870          (fun-lvar (basic-combination-fun node))
871          (type (leaf-type var)))
872     (when (validate-call-type node type t)
873       (setf (lvar-%derived-type fun-lvar)
874             (make-single-value-type type))
875       (setf (lvar-reoptimize fun-lvar) nil)))
876   (values))
877
878 ;;; Convert a call to a local function, or if the function has already
879 ;;; been LET converted, then throw FUNCTIONAL to
880 ;;; LOCALL-ALREADY-LET-CONVERTED. The THROW should only happen when we
881 ;;; are converting inline expansions for local functions during
882 ;;; optimization.
883 (defun ir1-convert-local-combination (start next result form functional)
884   (assure-functional-live-p functional)
885   (ir1-convert-combination start next result
886                            form
887                            (maybe-reanalyze-functional functional)))
888 \f
889 ;;;; PROCESS-DECLS
890
891 ;;; Given a list of LAMBDA-VARs and a variable name, return the
892 ;;; LAMBDA-VAR for that name, or NIL if it isn't found. We return the
893 ;;; *last* variable with that name, since LET* bindings may be
894 ;;; duplicated, and declarations always apply to the last.
895 (declaim (ftype (sfunction (list symbol) (or lambda-var list))
896                 find-in-bindings))
897 (defun find-in-bindings (vars name)
898   (let ((found nil))
899     (dolist (var vars)
900       (cond ((leaf-p var)
901              (when (eq (leaf-source-name var) name)
902                (setq found var))
903              (let ((info (lambda-var-arg-info var)))
904                (when info
905                  (let ((supplied-p (arg-info-supplied-p info)))
906                    (when (and supplied-p
907                               (eq (leaf-source-name supplied-p) name))
908                      (setq found supplied-p))))))
909             ((and (consp var) (eq (car var) name))
910              (setf found (cdr var)))))
911     found))
912
913 ;;; Called by PROCESS-DECLS to deal with a variable type declaration.
914 ;;; If a LAMBDA-VAR being bound, we intersect the type with the var's
915 ;;; type, otherwise we add a type restriction on the var. If a symbol
916 ;;; macro, we just wrap a THE around the expansion.
917 (defun process-type-decl (decl res vars)
918   (declare (list decl vars) (type lexenv res))
919   (let ((type (compiler-specifier-type (first decl))))
920     (collect ((restr nil cons)
921              (new-vars nil cons))
922       (dolist (var-name (rest decl))
923         (when (boundp var-name)
924           (compiler-assert-symbol-home-package-unlocked var-name
925                                                         "declaring the type of ~A"))
926         (let* ((bound-var (find-in-bindings vars var-name))
927                (var (or bound-var
928                         (lexenv-find var-name vars)
929                         (find-free-var var-name))))
930           (etypecase var
931             (leaf
932              (flet 
933                  ((process-var (var bound-var)
934                     (let* ((old-type (or (lexenv-find var type-restrictions)
935                                          (leaf-type var)))
936                            (int (if (or (fun-type-p type)
937                                         (fun-type-p old-type))
938                                     type
939                                     (type-approx-intersection2 
940                                      old-type type))))
941                       (cond ((eq int *empty-type*)
942                              (unless (policy *lexenv* (= inhibit-warnings 3))
943                                (warn
944                                 'type-warning
945                                 :format-control
946                                 "The type declarations ~S and ~S for ~S conflict."
947                                 :format-arguments
948                                 (list
949                                  (type-specifier old-type) 
950                                  (type-specifier type)
951                                  var-name))))
952                             (bound-var (setf (leaf-type bound-var) int))
953                             (t
954                              (restr (cons var int)))))))
955                (process-var var bound-var)
956                (awhen (and (lambda-var-p var)
957                            (lambda-var-specvar var))
958                       (process-var it nil))))
959             (cons
960              ;; FIXME: non-ANSI weirdness
961              (aver (eq (car var) 'MACRO))
962              (new-vars `(,var-name . (MACRO . (the ,(first decl)
963                                                 ,(cdr var))))))
964             (heap-alien-info
965              (compiler-error
966               "~S is an alien variable, so its type can't be declared."
967               var-name)))))
968
969       (if (or (restr) (new-vars))
970           (make-lexenv :default res
971                        :type-restrictions (restr)
972                        :vars (new-vars))
973           res))))
974
975 ;;; This is somewhat similar to PROCESS-TYPE-DECL, but handles
976 ;;; declarations for function variables. In addition to allowing
977 ;;; declarations for functions being bound, we must also deal with
978 ;;; declarations that constrain the type of lexically apparent
979 ;;; functions.
980 (defun process-ftype-decl (spec res names fvars)
981   (declare (type list names fvars)
982            (type lexenv res))
983   (let ((type (compiler-specifier-type spec)))
984     (collect ((res nil cons))
985       (dolist (name names)
986         (when (fboundp name)
987           (compiler-assert-symbol-home-package-unlocked name
988                                                         "declaring the ftype of ~A"))
989         (let ((found (find name fvars
990                            :key #'leaf-source-name
991                            :test #'equal)))
992           (cond
993            (found
994             (setf (leaf-type found) type)
995             (assert-definition-type found type
996                                     :unwinnage-fun #'compiler-notify
997                                     :where "FTYPE declaration"))
998            (t
999             (res (cons (find-lexically-apparent-fun
1000                         name "in a function type declaration")
1001                        type))))))
1002       (if (res)
1003           (make-lexenv :default res :type-restrictions (res))
1004           res))))
1005
1006 ;;; Process a special declaration, returning a new LEXENV. A non-bound
1007 ;;; special declaration is instantiated by throwing a special variable
1008 ;;; into the variables.
1009 (defun process-special-decl (spec res vars)
1010   (declare (list spec vars) (type lexenv res))
1011   (collect ((new-venv nil cons))
1012     (dolist (name (cdr spec))
1013       (compiler-assert-symbol-home-package-unlocked name "declaring ~A special")
1014       (let ((var (find-in-bindings vars name)))
1015         (etypecase var
1016           (cons
1017            (aver (eq (car var) 'MACRO))
1018            (compiler-error
1019             "~S is a symbol-macro and thus can't be declared special."
1020             name))
1021           (lambda-var
1022            (when (lambda-var-ignorep var)
1023              ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1024              ;; requires that this be a STYLE-WARNING, not a full WARNING.
1025              (compiler-style-warn
1026               "The ignored variable ~S is being declared special."
1027               name))
1028            (setf (lambda-var-specvar var)
1029                  (specvar-for-binding name)))
1030           (null
1031            (unless (assoc name (new-venv) :test #'eq)
1032              (new-venv (cons name (specvar-for-binding name))))))))
1033     (if (new-venv)
1034         (make-lexenv :default res :vars (new-venv))
1035         res)))
1036
1037 ;;; Return a DEFINED-FUN which copies a GLOBAL-VAR but for its INLINEP
1038 ;;; (and TYPE if notinline).
1039 (defun make-new-inlinep (var inlinep)
1040   (declare (type global-var var) (type inlinep inlinep))
1041   (let ((res (make-defined-fun
1042               :%source-name (leaf-source-name var)
1043               :where-from (leaf-where-from var)
1044               :type (if (and (eq inlinep :notinline)
1045                              (not (eq (leaf-where-from var) :declared)))
1046                         (specifier-type 'function)
1047                         (leaf-type var))
1048               :inlinep inlinep)))
1049     (when (defined-fun-p var)
1050       (setf (defined-fun-inline-expansion res)
1051             (defined-fun-inline-expansion var))
1052       (setf (defined-fun-functional res)
1053             (defined-fun-functional var)))
1054     res))
1055
1056 ;;; Parse an inline/notinline declaration. If it's a local function we're
1057 ;;; defining, set its INLINEP. If a global function, add a new FENV entry.
1058 (defun process-inline-decl (spec res fvars)
1059   (let ((sense (cdr (assoc (first spec) *inlinep-translations* :test #'eq)))
1060         (new-fenv ()))
1061     (dolist (name (rest spec))
1062       (let ((fvar (find name fvars
1063                         :key #'leaf-source-name
1064                         :test #'equal)))
1065         (if fvar
1066             (setf (functional-inlinep fvar) sense)
1067             (let ((found
1068                    (find-lexically-apparent-fun
1069                     name "in an inline or notinline declaration")))
1070               (etypecase found
1071                 (functional
1072                  (when (policy *lexenv* (>= speed inhibit-warnings))
1073                    (compiler-notify "ignoring ~A declaration not at ~
1074                                      definition of local function:~%  ~S"
1075                                     sense name)))
1076                 (global-var
1077                  (push (cons name (make-new-inlinep found sense))
1078                        new-fenv)))))))
1079
1080     (if new-fenv
1081         (make-lexenv :default res :funs new-fenv)
1082         res)))
1083
1084 ;;; like FIND-IN-BINDINGS, but looks for #'FOO in the FVARS
1085 (defun find-in-bindings-or-fbindings (name vars fvars)
1086   (declare (list vars fvars))
1087   (if (consp name)
1088       (destructuring-bind (wot fn-name) name
1089         (unless (eq wot 'function)
1090           (compiler-error "The function or variable name ~S is unrecognizable."
1091                           name))
1092         (find fn-name fvars :key #'leaf-source-name :test #'equal))
1093       (find-in-bindings vars name)))
1094
1095 ;;; Process an ignore/ignorable declaration, checking for various losing
1096 ;;; conditions.
1097 (defun process-ignore-decl (spec vars fvars)
1098   (declare (list spec vars fvars))
1099   (dolist (name (rest spec))
1100     (let ((var (find-in-bindings-or-fbindings name vars fvars)))
1101       (cond
1102        ((not var)
1103         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1104         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1105         (compiler-style-warn "declaring unknown variable ~S to be ignored"
1106                              name))
1107        ;; FIXME: This special case looks like non-ANSI weirdness.
1108        ((and (consp var) (eq (car var) 'macro))
1109         ;; Just ignore the IGNORE decl.
1110         )
1111        ((functional-p var)
1112         (setf (leaf-ever-used var) t))
1113        ((and (lambda-var-specvar var) (eq (first spec) 'ignore))
1114         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1115         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1116         (compiler-style-warn "declaring special variable ~S to be ignored"
1117                              name))
1118        ((eq (first spec) 'ignorable)
1119         (setf (leaf-ever-used var) t))
1120        (t
1121         (setf (lambda-var-ignorep var) t)))))
1122   (values))
1123
1124 (defun process-dx-decl (names vars)
1125   (flet ((maybe-notify (control &rest args)
1126            (when (policy *lexenv* (> speed inhibit-warnings))
1127              (apply #'compiler-notify control args))))
1128     (if (policy *lexenv* (= stack-allocate-dynamic-extent 3))
1129         (dolist (name names)
1130           (cond
1131             ((symbolp name)
1132              (let* ((bound-var (find-in-bindings vars name))
1133                     (var (or bound-var
1134                              (lexenv-find name vars)
1135                              (find-free-var name))))
1136                (etypecase var
1137                  (leaf
1138                   (if bound-var
1139                       (setf (leaf-dynamic-extent var) t)
1140                       (maybe-notify
1141                        "ignoring DYNAMIC-EXTENT declaration for free ~S"
1142                        name)))
1143                  (cons
1144                   (compiler-error "DYNAMIC-EXTENT on symbol-macro: ~S" name))
1145                  (heap-alien-info
1146                   (compiler-error "DYNAMIC-EXTENT on heap-alien-info: ~S"
1147                                   name)))))
1148             ((and (consp name)
1149                   (eq (car name) 'function)
1150                   (null (cddr name))
1151                   (valid-function-name-p (cadr name)))
1152              (maybe-notify "ignoring DYNAMIC-EXTENT declaration for ~S" name))
1153             (t (compiler-error "DYNAMIC-EXTENT on a weird thing: ~S" name))))
1154       (maybe-notify "ignoring DYNAMIC-EXTENT declarations for ~S" names))))
1155
1156 ;;; FIXME: This is non-ANSI, so the default should be T, or it should
1157 ;;; go away, I think.
1158 (defvar *suppress-values-declaration* nil
1159   #!+sb-doc
1160   "If true, processing of the VALUES declaration is inhibited.")
1161
1162 ;;; Process a single declaration spec, augmenting the specified LEXENV
1163 ;;; RES. Return RES and result type. VARS and FVARS are as described
1164 ;;; PROCESS-DECLS.
1165 (defun process-1-decl (raw-spec res vars fvars)
1166   (declare (type list raw-spec vars fvars))
1167   (declare (type lexenv res))
1168   (let ((spec (canonized-decl-spec raw-spec))
1169         (result-type *wild-type*))
1170     (values
1171      (case (first spec)
1172        (special (process-special-decl spec res vars))
1173        (ftype
1174         (unless (cdr spec)
1175           (compiler-error "no type specified in FTYPE declaration: ~S" spec))
1176         (process-ftype-decl (second spec) res (cddr spec) fvars))
1177        ((inline notinline maybe-inline)
1178         (process-inline-decl spec res fvars))
1179        ((ignore ignorable)
1180         (process-ignore-decl spec vars fvars)
1181         res)
1182        (optimize
1183         (make-lexenv
1184          :default res
1185          :policy (process-optimize-decl spec (lexenv-policy res))))
1186        (muffle-conditions
1187         (make-lexenv
1188          :default res
1189          :handled-conditions (process-muffle-conditions-decl
1190                               spec (lexenv-handled-conditions res))))
1191        (unmuffle-conditions
1192         (make-lexenv
1193          :default res
1194          :handled-conditions (process-unmuffle-conditions-decl
1195                               spec (lexenv-handled-conditions res))))
1196        (type
1197         (process-type-decl (cdr spec) res vars))
1198        (values
1199         (unless *suppress-values-declaration*
1200           (let ((types (cdr spec)))
1201             (setq result-type
1202                   (compiler-values-specifier-type
1203                    (if (singleton-p types)
1204                        (car types)
1205                        `(values ,@types)))))
1206           res))
1207        (dynamic-extent
1208         (process-dx-decl (cdr spec) vars)
1209         res)
1210        ((disable-package-locks enable-package-locks)
1211         (make-lexenv
1212          :default res
1213          :disabled-package-locks (process-package-lock-decl 
1214                                   spec (lexenv-disabled-package-locks res))))
1215        (t
1216         (unless (info :declaration :recognized (first spec))
1217           (compiler-warn "unrecognized declaration ~S" raw-spec))
1218         res))
1219      result-type)))
1220
1221 ;;; Use a list of DECLARE forms to annotate the lists of LAMBDA-VAR
1222 ;;; and FUNCTIONAL structures which are being bound. In addition to
1223 ;;; filling in slots in the leaf structures, we return a new LEXENV,
1224 ;;; which reflects pervasive special and function type declarations,
1225 ;;; (NOT)INLINE declarations and OPTIMIZE declarations, and type of
1226 ;;; VALUES declarations.
1227 ;;;
1228 ;;; This is also called in main.lisp when PROCESS-FORM handles a use
1229 ;;; of LOCALLY.
1230 (defun process-decls (decls vars fvars &optional (env *lexenv*))
1231   (declare (list decls vars fvars))
1232   (let ((result-type *wild-type*))
1233     (dolist (decl decls)
1234       (dolist (spec (rest decl))
1235         (unless (consp spec)
1236           (compiler-error "malformed declaration specifier ~S in ~S" spec decl))
1237         (multiple-value-bind (new-env new-result-type)
1238             (process-1-decl spec env vars fvars)
1239           (setq env new-env)
1240           (unless (eq new-result-type *wild-type*)
1241             (setq result-type
1242                   (values-type-intersection result-type new-result-type))))))
1243     (values env result-type)))
1244
1245 (defun %processing-decls (decls vars fvars ctran lvar fun)
1246   (multiple-value-bind (*lexenv* result-type)
1247       (process-decls decls vars fvars)
1248     (cond ((eq result-type *wild-type*)
1249            (funcall fun ctran lvar))
1250           (t
1251            (let ((value-ctran (make-ctran))
1252                  (value-lvar (make-lvar)))
1253              (multiple-value-prog1
1254                  (funcall fun value-ctran value-lvar)
1255                (let ((cast (make-cast value-lvar result-type
1256                                       (lexenv-policy *lexenv*))))
1257                  (link-node-to-previous-ctran cast value-ctran)
1258                  (setf (lvar-dest value-lvar) cast)
1259                  (use-continuation cast ctran lvar))))))))
1260 (defmacro processing-decls ((decls vars fvars ctran lvar) &body forms)
1261   (check-type ctran symbol)
1262   (check-type lvar symbol)
1263   `(%processing-decls ,decls ,vars ,fvars ,ctran ,lvar
1264                       (lambda (,ctran ,lvar) ,@forms)))
1265
1266 ;;; Return the SPECVAR for NAME to use when we see a local SPECIAL
1267 ;;; declaration. If there is a global variable of that name, then
1268 ;;; check that it isn't a constant and return it. Otherwise, create an
1269 ;;; anonymous GLOBAL-VAR.
1270 (defun specvar-for-binding (name)
1271   (cond ((not (eq (info :variable :where-from name) :assumed))
1272          (let ((found (find-free-var name)))
1273            (when (heap-alien-info-p found)
1274              (compiler-error
1275               "~S is an alien variable and so can't be declared special."
1276               name))
1277            (unless (global-var-p found)
1278              (compiler-error
1279               "~S is a constant and so can't be declared special."
1280               name))
1281            found))
1282         (t
1283          (make-global-var :kind :special
1284                           :%source-name name
1285                           :where-from :declared))))