src/compiler/ir1tran.lisp

   1 ;;;; This file contains code which does the translation from Lisp code
   2 ;;;; to the first intermediate representation (IR1).
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (declaim (special *compiler-error-bailout*))
  16
  17 ;;; *SOURCE-PATHS* is a hashtable from source code forms to the path
  18 ;;; taken through the source to reach the form. This provides a way to
  19 ;;; keep track of the location of original source forms, even when
  20 ;;; macroexpansions and other arbitary permutations of the code
  21 ;;; happen. This table is initialized by calling FIND-SOURCE-PATHS on
  22 ;;; the original source.
  23 (declaim (hash-table *source-paths*))
  24 (defvar *source-paths*)
  25
  26 ;;; *CURRENT-COMPONENT* is the COMPONENT structure which we link
  27 ;;; blocks into as we generate them. This just serves to glue the
  28 ;;; emitted blocks together until local call analysis and flow graph
  29 ;;; canonicalization figure out what is really going on. We need to
  30 ;;; keep track of all the blocks generated so that we can delete them
  31 ;;; if they turn out to be unreachable.
  32 ;;;
  33 ;;; FIXME: It's confusing having one variable named *CURRENT-COMPONENT*
  34 ;;; and another named *COMPONENT-BEING-COMPILED*. (In CMU CL they
  35 ;;; were called *CURRENT-COMPONENT* and *COMPILE-COMPONENT* respectively,
  36 ;;; which was also confusing.)
  37 (declaim (type (or component null) *current-component*))
  38 (defvar *current-component*)
  39
  40 ;;; *CURRENT-PATH* is the source path of the form we are currently
  41 ;;; translating. See NODE-SOURCE-PATH in the NODE structure.
  42 (declaim (list *current-path*))
  43 (defvar *current-path*)
  44
  45 (defvar *derive-function-types* nil
  46   "Should the compiler assume that function types will never change,
  47   so that it can use type information inferred from current definitions
  48   to optimize code which uses those definitions? Setting this true
  49   gives non-ANSI, early-CMU-CL behavior. It can be useful for improving
  50   the efficiency of stable code.")
  51
  52 (defvar *fun-names-in-this-file* nil)
  53
  54 ;;; *ALLOW-DEBUG-CATCH-TAG* controls whether we should allow the
  55 ;;; insertion a (CATCH ...) around code to allow the debugger RETURN
  56 ;;; command to function.
  57 (defvar *allow-debug-catch-tag* t)
  58 \f
  59 ;;;; namespace management utilities
  60
  61 (defun fun-lexically-notinline-p (name)
  62   (let ((fun (lexenv-find name funs :test #'equal)))
  63     ;; a declaration will trump a proclamation
  64     (if (and fun (defined-fun-p fun))
  65         (eq (defined-fun-inlinep fun) :notinline)
  66         (eq (info :function :inlinep name) :notinline))))
  67
  68 ;;; Return a GLOBAL-VAR structure usable for referencing the global
  69 ;;; function NAME.
  70 (defun find-free-really-fun (name)
  71   (unless (info :function :kind name)
  72     (setf (info :function :kind name) :function)
  73     (setf (info :function :where-from name) :assumed))
  74
  75   (let ((where (info :function :where-from name)))
  76     (when (and (eq where :assumed)
  77                ;; In the ordinary target Lisp, it's silly to report
  78                ;; undefinedness when the function is defined in the
  79                ;; running Lisp. But at cross-compile time, the current
  80                ;; definedness of a function is irrelevant to the
  81                ;; definedness at runtime, which is what matters.
  82                #-sb-xc-host (not (fboundp name)))
  83       (note-undefined-reference name :function))
  84     (make-global-var
  85      :kind :global-function
  86      :%source-name name
  87      :type (if (or *derive-function-types*
  88                    (eq where :declared)
  89                    (and (member name *fun-names-in-this-file* :test #'equal)
  90                         (not (fun-lexically-notinline-p name))))
  91                (info :function :type name)
  92                (specifier-type 'function))
  93      :where-from where)))
  94
  95 ;;; Has the *FREE-FUNS* entry FREE-FUN become invalid?
  96 ;;;
  97 ;;; In CMU CL, the answer was implicitly always true, so this
  98 ;;; predicate didn't exist.
  99 ;;;
 100 ;;; This predicate was added to fix bug 138 in SBCL. In some obscure
 101 ;;; circumstances, it was possible for a *FREE-FUNS* entry to contain a
 102 ;;; DEFINED-FUN whose DEFINED-FUN-FUNCTIONAL object contained IR1
 103 ;;; stuff (NODEs, BLOCKs...) referring to an already compiled (aka
 104 ;;; "dead") component. When this IR1 stuff was reused in a new
 105 ;;; component, under further obscure circumstances it could be used by
 106 ;;; WITH-IR1-ENVIRONMENT-FROM-NODE to generate a binding for
 107 ;;; *CURRENT-COMPONENT*. At that point things got all confused, since
 108 ;;; IR1 conversion was sending code to a component which had already
 109 ;;; been compiled and would never be compiled again.
 110 (defun invalid-free-fun-p (free-fun)
 111   ;; There might be other reasons that *FREE-FUN* entries could
 112   ;; become invalid, but the only one we've been bitten by so far
 113   ;; (sbcl-0.pre7.118) is this one:
 114   (and (defined-fun-p free-fun)
 115        (let ((functional (defined-fun-functional free-fun)))
 116          (or (and functional
 117                   (eql (functional-kind functional) :deleted))
 118              (and (lambda-p functional)
 119                   (or
 120                    ;; (The main reason for this first test is to bail
 121                    ;; out early in cases where the LAMBDA-COMPONENT
 122                    ;; call in the second test would fail because links
 123                    ;; it needs are uninitialized or invalid.)
 124                    ;;
 125                    ;; If the BIND node for this LAMBDA is null, then
 126                    ;; according to the slot comments, the LAMBDA has
 127                    ;; been deleted or its call has been deleted. In
 128                    ;; that case, it seems rather questionable to reuse
 129                    ;; it, and certainly it shouldn't be necessary to
 130                    ;; reuse it, so we cheerfully declare it invalid.
 131                    (null (lambda-bind functional))
 132                    ;; If this IR1 stuff belongs to a dead component,
 133                    ;; then we can't reuse it without getting into
 134                    ;; bizarre confusion.
 135                    (eql (component-info (lambda-component functional))
 136                         :dead)))))))
 137
 138 ;;; If NAME already has a valid entry in *FREE-FUNS*, then return
 139 ;;; the value. Otherwise, make a new GLOBAL-VAR using information from
 140 ;;; the global environment and enter it in *FREE-FUNS*. If NAME
 141 ;;; names a macro or special form, then we error out using the
 142 ;;; supplied context which indicates what we were trying to do that
 143 ;;; demanded a function.
 144 (declaim (ftype (sfunction (t string) global-var) find-free-fun))
 145 (defun find-free-fun (name context)
 146   (or (let ((old-free-fun (gethash name *free-funs*)))
 147         (and (not (invalid-free-fun-p old-free-fun))
 148              old-free-fun))
 149       (ecase (info :function :kind name)
 150         ;; FIXME: The :MACRO and :SPECIAL-FORM cases could be merged.
 151         (:macro
 152          (compiler-error "The macro name ~S was found ~A." name context))
 153         (:special-form
 154          (compiler-error "The special form name ~S was found ~A."
 155                          name
 156                          context))
 157         ((:function nil)
 158          (check-fun-name name)
 159          (note-if-setf-fun-and-macro name)
 160          (let ((expansion (fun-name-inline-expansion name))
 161                (inlinep (info :function :inlinep name)))
 162            (setf (gethash name *free-funs*)
 163                  (if (or expansion inlinep)
 164                      (make-defined-fun
 165                       :%source-name name
 166                       :inline-expansion expansion
 167                       :inlinep inlinep
 168                       :where-from (info :function :where-from name)
 169                       :type (if (eq inlinep :notinline)
 170                                 (specifier-type 'function)
 171                                 (info :function :type name)))
 172                      (find-free-really-fun name))))))))
 173
 174 ;;; Return the LEAF structure for the lexically apparent function
 175 ;;; definition of NAME.
 176 (declaim (ftype (sfunction (t string) leaf) find-lexically-apparent-fun))
 177 (defun find-lexically-apparent-fun (name context)
 178   (let ((var (lexenv-find name funs :test #'equal)))
 179     (cond (var
 180            (unless (leaf-p var)
 181              (aver (and (consp var) (eq (car var) 'macro)))
 182              (compiler-error "found macro name ~S ~A" name context))
 183            var)
 184           (t
 185            (find-free-fun name context)))))
 186
 187 ;;; Return the LEAF node for a global variable reference to NAME. If
 188 ;;; NAME is already entered in *FREE-VARS*, then we just return the
 189 ;;; corresponding value. Otherwise, we make a new leaf using
 190 ;;; information from the global environment and enter it in
 191 ;;; *FREE-VARS*. If the variable is unknown, then we emit a warning.
 192 (declaim (ftype (sfunction (t) (or leaf cons heap-alien-info)) find-free-var))
 193 (defun find-free-var (name)
 194   (unless (symbolp name)
 195     (compiler-error "Variable name is not a symbol: ~S." name))
 196   (or (gethash name *free-vars*)
 197       (let ((kind (info :variable :kind name))
 198             (type (info :variable :type name))
 199             (where-from (info :variable :where-from name)))
 200         (when (and (eq where-from :assumed) (eq kind :global))
 201           (note-undefined-reference name :variable))
 202         (setf (gethash name *free-vars*)
 203               (case kind
 204                 (:alien
 205                  (info :variable :alien-info name))
 206                 ;; FIXME: The return value in this case should really be
 207                 ;; of type SB!C::LEAF.  I don't feel too badly about it,
 208                 ;; because the MACRO idiom is scattered throughout this
 209                 ;; file, but it should be cleaned up so we're not
 210                 ;; throwing random conses around.  --njf 2002-03-23
 211                 (:macro
 212                  (let ((expansion (info :variable :macro-expansion name))
 213                        (type (type-specifier (info :variable :type name))))
 214                    `(MACRO . (the ,type ,expansion))))
 215                 (:constant
 216                  (let ((value (info :variable :constant-value name)))
 217                    (make-constant :value value
 218                                   :%source-name name
 219                                   :type (ctype-of value)
 220                                   :where-from where-from)))
 221                 (t
 222                  (make-global-var :kind kind
 223                                   :%source-name name
 224                                   :type type
 225                                   :where-from where-from)))))))
 226 \f
 227 ;;; Grovel over CONSTANT checking for any sub-parts that need to be
 228 ;;; processed with MAKE-LOAD-FORM. We have to be careful, because
 229 ;;; CONSTANT might be circular. We also check that the constant (and
 230 ;;; any subparts) are dumpable at all.
 231 (eval-when (:compile-toplevel :load-toplevel :execute)
 232   ;; The EVAL-WHEN is necessary for #.(1+ LIST-TO-HASH-TABLE-THRESHOLD)
 233   ;; below. -- AL 20010227
 234   (def!constant list-to-hash-table-threshold 32))
 235 (defun maybe-emit-make-load-forms (constant)
 236   (let ((things-processed nil)
 237         (count 0))
 238     ;; FIXME: Does this LIST-or-HASH-TABLE messiness give much benefit?
 239     (declare (type (or list hash-table) things-processed)
 240              (type (integer 0 #.(1+ list-to-hash-table-threshold)) count)
 241              (inline member))
 242     (labels ((grovel (value)
 243                ;; Unless VALUE is an object which which obviously
 244                ;; can't contain other objects
 245                (unless (typep value
 246                               '(or #-sb-xc-host unboxed-array
 247                                    symbol
 248                                    number
 249                                    character
 250                                    string))
 251                  (etypecase things-processed
 252                    (list
 253                     (when (member value things-processed :test #'eq)
 254                       (return-from grovel nil))
 255                     (push value things-processed)
 256                     (incf count)
 257                     (when (> count list-to-hash-table-threshold)
 258                       (let ((things things-processed))
 259                         (setf things-processed
 260                               (make-hash-table :test 'eq))
 261                         (dolist (thing things)
 262                           (setf (gethash thing things-processed) t)))))
 263                    (hash-table
 264                     (when (gethash value things-processed)
 265                       (return-from grovel nil))
 266                     (setf (gethash value things-processed) t)))
 267                  (typecase value
 268                    (cons
 269                     (grovel (car value))
 270                     (grovel (cdr value)))
 271                    (simple-vector
 272                     (dotimes (i (length value))
 273                       (grovel (svref value i))))
 274                    ((vector t)
 275                     (dotimes (i (length value))
 276                       (grovel (aref value i))))
 277                    ((simple-array t)
 278                     ;; Even though the (ARRAY T) branch does the exact
 279                     ;; same thing as this branch we do this separately
 280                     ;; so that the compiler can use faster versions of
 281                     ;; array-total-size and row-major-aref.
 282                     (dotimes (i (array-total-size value))
 283                       (grovel (row-major-aref value i))))
 284                    ((array t)
 285                     (dotimes (i (array-total-size value))
 286                       (grovel (row-major-aref value i))))
 287                    (;; In the target SBCL, we can dump any instance,
 288                     ;; but in the cross-compilation host,
 289                     ;; %INSTANCE-FOO functions don't work on general
 290                     ;; instances, only on STRUCTURE!OBJECTs.
 291                     #+sb-xc-host structure!object
 292                     #-sb-xc-host instance
 293                     (when (emit-make-load-form value)
 294                       (dotimes (i (%instance-length value))
 295                         (grovel (%instance-ref value i)))))
 296                    (t
 297                     (compiler-error
 298                      "Objects of type ~S can't be dumped into fasl files."
 299                      (type-of value)))))))
 300       (grovel constant)))
 301   (values))
 302 \f
 303 ;;;; some flow-graph hacking utilities
 304
 305 ;;; This function sets up the back link between the node and the
 306 ;;; ctran which continues at it.
 307 (defun link-node-to-previous-ctran (node ctran)
 308   (declare (type node node) (type ctran ctran))
 309   (aver (not (ctran-next ctran)))
 310   (setf (ctran-next ctran) node)
 311   (setf (node-prev node) ctran))
 312
 313 ;;; This function is used to set the ctran for a node, and thus
 314 ;;; determine what is evaluated next. If the ctran has no block, then
 315 ;;; we make it be in the block that the node is in. If the ctran heads
 316 ;;; its block, we end our block and link it to that block.
 317 #!-sb-fluid (declaim (inline use-ctran))
 318 (defun use-ctran (node ctran)
 319   (declare (type node node) (type ctran ctran))
 320   (if (eq (ctran-kind ctran) :unused)
 321       (let ((node-block (ctran-block (node-prev node))))
 322         (setf (ctran-block ctran) node-block)
 323         (setf (ctran-kind ctran) :inside-block)
 324         (setf (ctran-use ctran) node)
 325         (setf (node-next node) ctran))
 326       (%use-ctran node ctran)))
 327 (defun %use-ctran (node ctran)
 328   (declare (type node node) (type ctran ctran) (inline member))
 329   (let ((block (ctran-block ctran))
 330         (node-block (ctran-block (node-prev node))))
 331     (aver (eq (ctran-kind ctran) :block-start))
 332     (when (block-last node-block)
 333       (error "~S has already ended." node-block))
 334     (setf (block-last node-block) node)
 335     (when (block-succ node-block)
 336       (error "~S already has successors." node-block))
 337     (setf (block-succ node-block) (list block))
 338     (when (memq node-block (block-pred block))
 339       (error "~S is already a predecessor of ~S." node-block block))
 340     (push node-block (block-pred block))))
 341
 342 ;;; This function is used to set the ctran for a node, and thus
 343 ;;; determine what receives the value.
 344 (defun use-lvar (node lvar)
 345   (declare (type valued-node node) (type (or lvar null) lvar))
 346   (aver (not (node-lvar node)))
 347   (when lvar
 348     (setf (node-lvar node) lvar)
 349     (cond ((null (lvar-uses lvar))
 350            (setf (lvar-uses lvar) node))
 351           ((listp (lvar-uses lvar))
 352            (aver (not (memq node (lvar-uses lvar))))
 353            (push node (lvar-uses lvar)))
 354           (t
 355            (aver (neq node (lvar-uses lvar)))
 356            (setf (lvar-uses lvar) (list node (lvar-uses lvar)))))
 357     (reoptimize-lvar lvar)))
 358
 359 #!-sb-fluid(declaim (inline use-continuation))
 360 (defun use-continuation (node ctran lvar)
 361   (use-ctran node ctran)
 362   (use-lvar node lvar))
 363 \f
 364 ;;;; exported functions
 365
 366 ;;; This function takes a form and the top level form number for that
 367 ;;; form, and returns a lambda representing the translation of that
 368 ;;; form in the current global environment. The returned lambda is a
 369 ;;; top level lambda that can be called to cause evaluation of the
 370 ;;; forms. This lambda is in the initial component. If FOR-VALUE is T,
 371 ;;; then the value of the form is returned from the function,
 372 ;;; otherwise NIL is returned.
 373 ;;;
 374 ;;; This function may have arbitrary effects on the global environment
 375 ;;; due to processing of EVAL-WHENs. All syntax error checking is
 376 ;;; done, with erroneous forms being replaced by a proxy which signals
 377 ;;; an error if it is evaluated. Warnings about possibly inconsistent
 378 ;;; or illegal changes to the global environment will also be given.
 379 ;;;
 380 ;;; We make the initial component and convert the form in a PROGN (and
 381 ;;; an optional NIL tacked on the end.) We then return the lambda. We
 382 ;;; bind all of our state variables here, rather than relying on the
 383 ;;; global value (if any) so that IR1 conversion will be reentrant.
 384 ;;; This is necessary for EVAL-WHEN processing, etc.
 385 ;;;
 386 ;;; The hashtables used to hold global namespace info must be
 387 ;;; reallocated elsewhere. Note also that *LEXENV* is not bound, so
 388 ;;; that local macro definitions can be introduced by enclosing code.
 389 (defun ir1-toplevel (form path for-value)
 390   (declare (list path))
 391   (let* ((*current-path* path)
 392          (component (make-empty-component))
 393          (*current-component* component))
 394     (setf (component-name component) "initial component")
 395     (setf (component-kind component) :initial)
 396     (let* ((forms (if for-value `(,form) `(,form nil)))
 397            (res (ir1-convert-lambda-body
 398                  forms ()
 399                  :debug-name (debug-namify "top level form ~S" form))))
 400       (setf (functional-entry-fun res) res
 401             (functional-arg-documentation res) ()
 402             (functional-kind res) :toplevel)
 403       res)))
 404
 405 ;;; *CURRENT-FORM-NUMBER* is used in FIND-SOURCE-PATHS to compute the
 406 ;;; form number to associate with a source path. This should be bound
 407 ;;; to an initial value of 0 before the processing of each truly
 408 ;;; top level form.
 409 (declaim (type index *current-form-number*))
 410 (defvar *current-form-number*)
 411
 412 ;;; This function is called on freshly read forms to record the
 413 ;;; initial location of each form (and subform.) Form is the form to
 414 ;;; find the paths in, and TLF-NUM is the top level form number of the
 415 ;;; truly top level form.
 416 ;;;
 417 ;;; This gets a bit interesting when the source code is circular. This
 418 ;;; can (reasonably?) happen in the case of circular list constants.
 419 (defun find-source-paths (form tlf-num)
 420   (declare (type index tlf-num))
 421   (let ((*current-form-number* 0))
 422     (sub-find-source-paths form (list tlf-num)))
 423   (values))
 424 (defun sub-find-source-paths (form path)
 425   (unless (gethash form *source-paths*)
 426     (setf (gethash form *source-paths*)
 427           (list* 'original-source-start *current-form-number* path))
 428     (incf *current-form-number*)
 429     (let ((pos 0)
 430           (subform form)
 431           (trail form))
 432       (declare (fixnum pos))
 433       (macrolet ((frob ()
 434                    '(progn
 435                       (when (atom subform) (return))
 436                       (let ((fm (car subform)))
 437                         (when (consp fm)
 438                           (sub-find-source-paths fm (cons pos path)))
 439                         (incf pos))
 440                       (setq subform (cdr subform))
 441                       (when (eq subform trail) (return)))))
 442         (loop
 443           (frob)
 444           (frob)
 445           (setq trail (cdr trail)))))))
 446 \f
 447 ;;;; IR1-CONVERT, macroexpansion and special form dispatching
 448
 449 (declaim (ftype (sfunction (ctran ctran (or lvar null) t) (values))
 450                 ir1-convert))
 451 (macrolet (;; Bind *COMPILER-ERROR-BAILOUT* to a function that throws
 452            ;; out of the body and converts a proxy form instead.
 453            (ir1-error-bailout ((start next result
 454                                 form
 455                                 &optional
 456                                 (proxy ``(error 'simple-program-error
 457                                           :format-control "execution of a form compiled with errors:~% ~S"
 458                                           :format-arguments (list ',,form))))
 459                                &body body)
 460                               (with-unique-names (skip)
 461                                 `(block ,skip
 462                                    (catch 'ir1-error-abort
 463                                      (let ((*compiler-error-bailout*
 464                                             (lambda ()
 465                                               (throw 'ir1-error-abort nil))))
 466                                        ,@body
 467                                        (return-from ,skip nil)))
 468                                    (ir1-convert ,start ,next ,result ,proxy)))))
 469
 470   ;; Translate FORM into IR1. The code is inserted as the NEXT of the
 471   ;; CTRAN START. RESULT is the LVAR which receives the value of the
 472   ;; FORM to be translated. The translators call this function
 473   ;; recursively to translate their subnodes.
 474   ;;
 475   ;; As a special hack to make life easier in the compiler, a LEAF
 476   ;; IR1-converts into a reference to that LEAF structure. This allows
 477   ;; the creation using backquote of forms that contain leaf
 478   ;; references, without having to introduce dummy names into the
 479   ;; namespace.
 480   (defun ir1-convert (start next result form)
 481     (ir1-error-bailout (start next result form)
 482       (let ((*current-path* (or (gethash form *source-paths*)
 483                                 (cons form *current-path*))))
 484         (if (atom form)
 485             (cond ((and (symbolp form) (not (keywordp form)))
 486                    (ir1-convert-var start next result form))
 487                   ((leaf-p form)
 488                    (reference-leaf start next result form))
 489                   (t
 490                    (reference-constant start next result form)))
 491             (let ((opname (car form)))
 492               (cond ((or (symbolp opname) (leaf-p opname))
 493                      (let ((lexical-def (if (leaf-p opname)
 494                                             opname
 495                                             (lexenv-find opname funs))))
 496                        (typecase lexical-def
 497                          (null
 498                           (ir1-convert-global-functoid start next result
 499                                                        form))
 500                          (functional
 501                           (ir1-convert-local-combination start next result
 502                                                          form
 503                                                          lexical-def))
 504                          (global-var
 505                           (ir1-convert-srctran start next result
 506                                                lexical-def form))
 507                          (t
 508                           (aver (and (consp lexical-def)
 509                                      (eq (car lexical-def) 'macro)))
 510                           (ir1-convert start next result
 511                                        (careful-expand-macro (cdr lexical-def)
 512                                                              form))))))
 513                     ((or (atom opname) (not (eq (car opname) 'lambda)))
 514                      (compiler-error "illegal function call"))
 515                     (t
 516                      ;; implicitly (LAMBDA ..) because the LAMBDA
 517                      ;; expression is the CAR of an executed form
 518                      (ir1-convert-combination start next result
 519                                               form
 520                                               (ir1-convert-lambda
 521                                                opname
 522                                                :debug-name (debug-namify
 523                                                             "LAMBDA CAR ~S"
 524                                                             opname)
 525                                                :allow-debug-catch-tag t))))))))
 526     (values))
 527
 528   ;; Generate a reference to a manifest constant, creating a new leaf
 529   ;; if necessary. If we are producing a fasl file, make sure that
 530   ;; MAKE-LOAD-FORM gets used on any parts of the constant that it
 531   ;; needs to be.
 532   (defun reference-constant (start next result value)
 533     (declare (type ctran start next)
 534              (type (or lvar null) result)
 535              (inline find-constant))
 536     (ir1-error-bailout
 537      (start next result value '(error "attempt to reference undumpable constant"))
 538      (when (producing-fasl-file)
 539        (maybe-emit-make-load-forms value))
 540      (let* ((leaf (find-constant value))
 541             (res (make-ref leaf)))
 542        (push res (leaf-refs leaf))
 543        (link-node-to-previous-ctran res start)
 544        (use-continuation res next result)))
 545     (values)))
 546
 547 ;;; Add FUNCTIONAL to the COMPONENT-REANALYZE-FUNCTIONALS, unless it's
 548 ;;; some trivial type for which reanalysis is a trivial no-op, or
 549 ;;; unless it doesn't belong in this component at all.
 550 ;;;
 551 ;;; FUNCTIONAL is returned.
 552 (defun maybe-reanalyze-functional (functional)
 553
 554   (aver (not (eql (functional-kind functional) :deleted))) ; bug 148
 555   (aver-live-component *current-component*)
 556
 557   ;; When FUNCTIONAL is of a type for which reanalysis isn't a trivial
 558   ;; no-op
 559   (when (typep functional '(or optional-dispatch clambda))
 560
 561     ;; When FUNCTIONAL knows its component
 562     (when (lambda-p functional)
 563       (aver (eql (lambda-component functional) *current-component*)))
 564
 565     (pushnew functional
 566              (component-reanalyze-functionals *current-component*)))
 567
 568   functional)
 569
 570 ;;; Generate a REF node for LEAF, frobbing the LEAF structure as
 571 ;;; needed. If LEAF represents a defined function which has already
 572 ;;; been converted, and is not :NOTINLINE, then reference the
 573 ;;; functional instead.
 574 (defun reference-leaf (start next result leaf)
 575   (declare (type ctran start next) (type (or lvar null) result) (type leaf leaf))
 576   (when (functional-p leaf)
 577     (assure-functional-live-p leaf))
 578   (let* ((type (lexenv-find leaf type-restrictions))
 579          (leaf (or (and (defined-fun-p leaf)
 580                         (not (eq (defined-fun-inlinep leaf)
 581                                  :notinline))
 582                         (let ((functional (defined-fun-functional leaf)))
 583                           (when (and functional
 584                                      (not (functional-kind functional)))
 585                             (maybe-reanalyze-functional functional))))
 586                    (when (and (lambda-p leaf)
 587                               (memq (functional-kind leaf)
 588                                     '(nil :optional)))
 589                      (maybe-reanalyze-functional leaf))
 590                    leaf))
 591          (ref (make-ref leaf)))
 592     (push ref (leaf-refs leaf))
 593     (setf (leaf-ever-used leaf) t)
 594     (link-node-to-previous-ctran ref start)
 595     (cond (type (let* ((ref-ctran (make-ctran))
 596                        (ref-lvar (make-lvar))
 597                        (cast (make-cast ref-lvar
 598                                         (make-single-value-type type)
 599                                         (lexenv-policy *lexenv*))))
 600                   (setf (lvar-dest ref-lvar) cast)
 601                   (use-continuation ref ref-ctran ref-lvar)
 602                   (link-node-to-previous-ctran cast ref-ctran)
 603                   (use-continuation cast next result)))
 604           (t (use-continuation ref next result)))))
 605
 606 ;;; Convert a reference to a symbolic constant or variable. If the
 607 ;;; symbol is entered in the LEXENV-VARS we use that definition,
 608 ;;; otherwise we find the current global definition. This is also
 609 ;;; where we pick off symbol macro and alien variable references.
 610 (defun ir1-convert-var (start next result name)
 611   (declare (type ctran start next) (type (or lvar null) result) (symbol name))
 612   (let ((var (or (lexenv-find name vars) (find-free-var name))))
 613     (etypecase var
 614       (leaf
 615        (when (lambda-var-p var)
 616          (let ((home (ctran-home-lambda-or-null start)))
 617            (when home
 618              (pushnew var (lambda-calls-or-closes home))))
 619          (when (lambda-var-ignorep var)
 620            ;; (ANSI's specification for the IGNORE declaration requires
 621            ;; that this be a STYLE-WARNING, not a full WARNING.)
 622            (compiler-style-warn "reading an ignored variable: ~S" name)))
 623        (reference-leaf start next result var))
 624       (cons
 625        (aver (eq (car var) 'MACRO))
 626        ;; FIXME: [Free] type declarations. -- APD, 2002-01-26
 627        (ir1-convert start next result (cdr var)))
 628       (heap-alien-info
 629        (ir1-convert start next result `(%heap-alien ',var)))))
 630   (values))
 631
 632 ;;; Convert anything that looks like a special form, global function
 633 ;;; or compiler-macro call.
 634 (defun ir1-convert-global-functoid (start next result form)
 635   (declare (type ctran start next) (type (or lvar null) result) (list form))
 636   (let* ((fun-name (first form))
 637          (translator (info :function :ir1-convert fun-name))
 638          (cmacro-fun (sb!xc:compiler-macro-function fun-name *lexenv*)))
 639     (cond (translator
 640            (when cmacro-fun
 641              (compiler-warn "ignoring compiler macro for special form"))
 642            (funcall translator start next result form))
 643           ((and cmacro-fun
 644                 ;; gotcha: If you look up the DEFINE-COMPILER-MACRO
 645                 ;; macro in the ANSI spec, you might think that
 646                 ;; suppressing compiler-macro expansion when NOTINLINE
 647                 ;; is some pre-ANSI hack. However, if you look up the
 648                 ;; NOTINLINE declaration, you'll find that ANSI
 649                 ;; requires this behavior after all.
 650                 (not (eq (info :function :inlinep fun-name) :notinline)))
 651            (let ((res (careful-expand-macro cmacro-fun form)))
 652              (if (eq res form)
 653                  (ir1-convert-global-functoid-no-cmacro
 654                   start next result form fun-name)
 655                  (ir1-convert start next result res))))
 656           (t
 657            (ir1-convert-global-functoid-no-cmacro start next result
 658                                                   form fun-name)))))
 659
 660 ;;; Handle the case of where the call was not a compiler macro, or was
 661 ;;; a compiler macro and passed.
 662 (defun ir1-convert-global-functoid-no-cmacro (start next result form fun)
 663   (declare (type ctran start next) (type (or lvar null) result)
 664            (list form))
 665   ;; FIXME: Couldn't all the INFO calls here be converted into
 666   ;; standard CL functions, like MACRO-FUNCTION or something?
 667   ;; And what happens with lexically-defined (MACROLET) macros
 668   ;; here, anyway?
 669   (ecase (info :function :kind fun)
 670     (:macro
 671      (ir1-convert start next result
 672                   (careful-expand-macro (info :function :macro-function fun)
 673                                         form)))
 674     ((nil :function)
 675      (ir1-convert-srctran start next result
 676                           (find-free-fun fun "shouldn't happen! (no-cmacro)")
 677                           form))))
 678
 679 (defun muffle-warning-or-die ()
 680   (muffle-warning)
 681   (bug "no MUFFLE-WARNING restart"))
 682
 683 ;;; Expand FORM using the macro whose MACRO-FUNCTION is FUN, trapping
 684 ;;; errors which occur during the macroexpansion.
 685 (defun careful-expand-macro (fun form)
 686   (let (;; a hint I (WHN) wish I'd known earlier
 687         (hint "(hint: For more precise location, try *BREAK-ON-SIGNALS*.)"))
 688     (flet (;; Return a string to use as a prefix in error reporting,
 689            ;; telling something about which form caused the problem.
 690            (wherestring ()
 691              (let ((*print-pretty* nil)
 692                    ;; We rely on the printer to abbreviate FORM.
 693                    (*print-length* 3)
 694                    (*print-level* 1))
 695                (format
 696                 nil
 697                 #-sb-xc-host "(in macroexpansion of ~S)"
 698                 ;; longer message to avoid ambiguity "Was it the xc host
 699                 ;; or the cross-compiler which encountered the problem?"
 700                 #+sb-xc-host "(in cross-compiler macroexpansion of ~S)"
 701                 form))))
 702       (handler-bind ((style-warning (lambda (c)
 703                                       (compiler-style-warn
 704                                        "~@<~A~:@_~A~@:_~A~:>"
 705                                        (wherestring) hint c)
 706                                       (muffle-warning-or-die)))
 707                      ;; KLUDGE: CMU CL in its wisdom (version 2.4.6 for
 708                      ;; Debian Linux, anyway) raises a CL:WARNING
 709                      ;; condition (not a CL:STYLE-WARNING) for undefined
 710                      ;; symbols when converting interpreted functions,
 711                      ;; causing COMPILE-FILE to think the file has a real
 712                      ;; problem, causing COMPILE-FILE to return FAILURE-P
 713                      ;; set (not just WARNINGS-P set). Since undefined
 714                      ;; symbol warnings are often harmless forward
 715                      ;; references, and since it'd be inordinately painful
 716                      ;; to try to eliminate all such forward references,
 717                      ;; these warnings are basically unavoidable. Thus, we
 718                      ;; need to coerce the system to work through them,
 719                      ;; and this code does so, by crudely suppressing all
 720                      ;; warnings in cross-compilation macroexpansion. --
 721                      ;; WHN 19990412
 722                      #+(and cmu sb-xc-host)
 723                      (warning (lambda (c)
 724                                 (compiler-notify
 725                                  "~@<~A~:@_~
 726                                   ~A~:@_~
 727                                   ~@<(KLUDGE: That was a non-STYLE WARNING. ~
 728                                   Ordinarily that would cause compilation to ~
 729                                   fail. However, since we're running under ~
 730                                   CMU CL, and since CMU CL emits non-STYLE ~
 731                                   warnings for safe, hard-to-fix things (e.g. ~
 732                                   references to not-yet-defined functions) ~
 733                                   we're going to have to ignore it and ~
 734                                   proceed anyway. Hopefully we're not ~
 735                                   ignoring anything  horrible here..)~:@>~:>"
 736                                  (wherestring)
 737                                  c)
 738                                 (muffle-warning-or-die)))
 739                      #-(and cmu sb-xc-host)
 740                      (warning (lambda (c)
 741                                 (compiler-warn "~@<~A~:@_~A~@:_~A~:>"
 742                                                (wherestring) hint c)
 743                                 (muffle-warning-or-die)))
 744                      (error (lambda (c)
 745                               (compiler-error "~@<~A~:@_~A~@:_~A~:>"
 746                                               (wherestring) hint c))))
 747         (funcall sb!xc:*macroexpand-hook* fun form *lexenv*)))))
 748 \f
 749 ;;;; conversion utilities
 750
 751 ;;; Convert a bunch of forms, discarding all the values except the
 752 ;;; last. If there aren't any forms, then translate a NIL.
 753 (declaim (ftype (sfunction (ctran ctran (or lvar null) list) (values))
 754                 ir1-convert-progn-body))
 755 (defun ir1-convert-progn-body (start next result body)
 756   (if (endp body)
 757       (reference-constant start next result nil)
 758       (let ((this-start start)
 759             (forms body))
 760         (loop
 761           (let ((form (car forms)))
 762             (when (endp (cdr forms))
 763               (ir1-convert this-start next result form)
 764               (return))
 765             (let ((this-ctran (make-ctran)))
 766               (ir1-convert this-start this-ctran nil form)
 767               (setq this-start this-ctran
 768                     forms (cdr forms)))))))
 769   (values))
 770 \f
 771 ;;;; converting combinations
 772
 773 ;;; Convert a function call where the function FUN is a LEAF. FORM is
 774 ;;; the source for the call. We return the COMBINATION node so that
 775 ;;; the caller can poke at it if it wants to.
 776 (declaim (ftype (sfunction (ctran ctran (or lvar null) list leaf) combination)
 777                 ir1-convert-combination))
 778 (defun ir1-convert-combination (start next result form fun)
 779   (let ((ctran (make-ctran))
 780         (fun-lvar (make-lvar)))
 781     (ir1-convert start ctran fun-lvar `(the (or function symbol) ,fun))
 782     (ir1-convert-combination-args fun-lvar ctran next result (cdr form))))
 783
 784 ;;; Convert the arguments to a call and make the COMBINATION
 785 ;;; node. FUN-LVAR yields the function to call. ARGS is the list of
 786 ;;; arguments for the call, which defaults to the cdr of source. We
 787 ;;; return the COMBINATION node.
 788 (defun ir1-convert-combination-args (fun-lvar start next result args)
 789   (declare (type ctran start next)
 790            (type lvar fun-lvar)
 791            (type (or lvar null) result)
 792            (list args))
 793   (let ((node (make-combination fun-lvar)))
 794     (setf (lvar-dest fun-lvar) node)
 795     (collect ((arg-lvars))
 796       (let ((this-start start))
 797         (dolist (arg args)
 798           (let ((this-ctran (make-ctran))
 799                 (this-lvar (make-lvar node)))
 800             (ir1-convert this-start this-ctran this-lvar arg)
 801             (setq this-start this-ctran)
 802             (arg-lvars this-lvar)))
 803         (link-node-to-previous-ctran node this-start)
 804         (use-continuation node next result)
 805         (setf (combination-args node) (arg-lvars))))
 806     node))
 807
 808 ;;; Convert a call to a global function. If not :NOTINLINE, then we do
 809 ;;; source transforms and try out any inline expansion. If there is no
 810 ;;; expansion, but is :INLINE, then give an efficiency note (unless a
 811 ;;; known function which will quite possibly be open-coded.) Next, we
 812 ;;; go to ok-combination conversion.
 813 (defun ir1-convert-srctran (start next result var form)
 814   (declare (type ctran start next) (type (or lvar null) result)
 815            (type global-var var))
 816   (let ((inlinep (when (defined-fun-p var)
 817                    (defined-fun-inlinep var))))
 818     (if (eq inlinep :notinline)
 819         (ir1-convert-combination start next result form var)
 820         (let ((transform (info :function
 821                                :source-transform
 822                                (leaf-source-name var))))
 823           (if transform
 824               (multiple-value-bind (transformed pass) (funcall transform form)
 825                 (if pass
 826                     (ir1-convert-maybe-predicate start next result form var)
 827                     (ir1-convert start next result transformed)))
 828               (ir1-convert-maybe-predicate start next result form var))))))
 829
 830 ;;; If the function has the PREDICATE attribute, and the RESULT's DEST
 831 ;;; isn't an IF, then we convert (IF <form> T NIL), ensuring that a
 832 ;;; predicate always appears in a conditional context.
 833 ;;;
 834 ;;; If the function isn't a predicate, then we call
 835 ;;; IR1-CONVERT-COMBINATION-CHECKING-TYPE.
 836 (defun ir1-convert-maybe-predicate (start next result form var)
 837   (declare (type ctran start next)
 838            (type (or lvar null) result)
 839            (list form)
 840            (type global-var var))
 841   (let ((info (info :function :info (leaf-source-name var))))
 842     (if (and info
 843              (ir1-attributep (fun-info-attributes info) predicate)
 844              (not (if-p (and result (lvar-dest result)))))
 845         (ir1-convert start next result `(if ,form t nil))
 846         (ir1-convert-combination-checking-type start next result form var))))
 847
 848 ;;; Actually really convert a global function call that we are allowed
 849 ;;; to early-bind.
 850 ;;;
 851 ;;; If we know the function type of the function, then we check the
 852 ;;; call for syntactic legality with respect to the declared function
 853 ;;; type. If it is impossible to determine whether the call is correct
 854 ;;; due to non-constant keywords, then we give up, marking the call as
 855 ;;; :FULL to inhibit further error messages. We return true when the
 856 ;;; call is legal.
 857 ;;;
 858 ;;; If the call is legal, we also propagate type assertions from the
 859 ;;; function type to the arg and result lvars. We do this now so that
 860 ;;; IR1 optimize doesn't have to redundantly do the check later so
 861 ;;; that it can do the type propagation.
 862 (defun ir1-convert-combination-checking-type (start next result form var)
 863   (declare (type ctran start next) (type (or lvar null) result)
 864            (list form)
 865            (type leaf var))
 866   (let* ((node (ir1-convert-combination start next result form var))
 867          (fun-lvar (basic-combination-fun node))
 868          (type (leaf-type var)))
 869     (when (validate-call-type node type t)
 870       (setf (lvar-%derived-type fun-lvar)
 871             (make-single-value-type type))
 872       (setf (lvar-reoptimize fun-lvar) nil)))
 873   (values))
 874
 875 ;;; Convert a call to a local function, or if the function has already
 876 ;;; been LET converted, then throw FUNCTIONAL to
 877 ;;; LOCALL-ALREADY-LET-CONVERTED. The THROW should only happen when we
 878 ;;; are converting inline expansions for local functions during
 879 ;;; optimization.
 880 (defun ir1-convert-local-combination (start next result form functional)
 881   (assure-functional-live-p functional)
 882   (ir1-convert-combination start next result
 883                            form
 884                            (maybe-reanalyze-functional functional)))
 885 \f
 886 ;;;; PROCESS-DECLS
 887
 888 ;;; Given a list of LAMBDA-VARs and a variable name, return the
 889 ;;; LAMBDA-VAR for that name, or NIL if it isn't found. We return the
 890 ;;; *last* variable with that name, since LET* bindings may be
 891 ;;; duplicated, and declarations always apply to the last.
 892 (declaim (ftype (sfunction (list symbol) (or lambda-var list))
 893                 find-in-bindings))
 894 (defun find-in-bindings (vars name)
 895   (let ((found nil))
 896     (dolist (var vars)
 897       (cond ((leaf-p var)
 898              (when (eq (leaf-source-name var) name)
 899                (setq found var))
 900              (let ((info (lambda-var-arg-info var)))
 901                (when info
 902                  (let ((supplied-p (arg-info-supplied-p info)))
 903                    (when (and supplied-p
 904                               (eq (leaf-source-name supplied-p) name))
 905                      (setq found supplied-p))))))
 906             ((and (consp var) (eq (car var) name))
 907              (setf found (cdr var)))))
 908     found))
 909
 910 ;;; Called by PROCESS-DECLS to deal with a variable type declaration.
 911 ;;; If a LAMBDA-VAR being bound, we intersect the type with the var's
 912 ;;; type, otherwise we add a type restriction on the var. If a symbol
 913 ;;; macro, we just wrap a THE around the expansion.
 914 (defun process-type-decl (decl res vars)
 915   (declare (list decl vars) (type lexenv res))
 916   (let ((type (compiler-specifier-type (first decl))))
 917     (collect ((restr nil cons)
 918              (new-vars nil cons))
 919       (dolist (var-name (rest decl))
 920         (let* ((bound-var (find-in-bindings vars var-name))
 921                (var (or bound-var
 922                         (lexenv-find var-name vars)
 923                         (find-free-var var-name))))
 924           (etypecase var
 925             (leaf
 926              (flet ((process-var (var bound-var)
 927                       (let* ((old-type (or (lexenv-find var type-restrictions)
 928                                            (leaf-type var)))
 929                              (int (if (or (fun-type-p type)
 930                                           (fun-type-p old-type))
 931                                       type
 932                                       (type-approx-intersection2 old-type type))))
 933                         (cond ((eq int *empty-type*)
 934                                (unless (policy *lexenv* (= inhibit-warnings 3))
 935                                  (compiler-warn
 936                                   "The type declarations ~S and ~S for ~S conflict."
 937                                   (type-specifier old-type) (type-specifier type)
 938                                   var-name)))
 939                               (bound-var (setf (leaf-type bound-var) int))
 940                               (t
 941                                (restr (cons var int)))))))
 942                (process-var var bound-var)
 943                (awhen (and (lambda-var-p var)
 944                            (lambda-var-specvar var))
 945                       (process-var it nil))))
 946             (cons
 947              ;; FIXME: non-ANSI weirdness
 948              (aver (eq (car var) 'MACRO))
 949              (new-vars `(,var-name . (MACRO . (the ,(first decl)
 950                                                 ,(cdr var))))))
 951             (heap-alien-info
 952              (compiler-error
 953               "~S is an alien variable, so its type can't be declared."
 954               var-name)))))
 955
 956       (if (or (restr) (new-vars))
 957           (make-lexenv :default res
 958                        :type-restrictions (restr)
 959                        :vars (new-vars))
 960           res))))
 961
 962 ;;; This is somewhat similar to PROCESS-TYPE-DECL, but handles
 963 ;;; declarations for function variables. In addition to allowing
 964 ;;; declarations for functions being bound, we must also deal with
 965 ;;; declarations that constrain the type of lexically apparent
 966 ;;; functions.
 967 (defun process-ftype-decl (spec res names fvars)
 968   (declare (type list names fvars)
 969            (type lexenv res))
 970   (let ((type (compiler-specifier-type spec)))
 971     (collect ((res nil cons))
 972       (dolist (name names)
 973         (let ((found (find name fvars
 974                            :key #'leaf-source-name
 975                            :test #'equal)))
 976           (cond
 977            (found
 978             (setf (leaf-type found) type)
 979             (assert-definition-type found type
 980                                     :unwinnage-fun #'compiler-notify
 981                                     :where "FTYPE declaration"))
 982            (t
 983             (res (cons (find-lexically-apparent-fun
 984                         name "in a function type declaration")
 985                        type))))))
 986       (if (res)
 987           (make-lexenv :default res :type-restrictions (res))
 988           res))))
 989
 990 ;;; Process a special declaration, returning a new LEXENV. A non-bound
 991 ;;; special declaration is instantiated by throwing a special variable
 992 ;;; into the variables.
 993 (defun process-special-decl (spec res vars)
 994   (declare (list spec vars) (type lexenv res))
 995   (collect ((new-venv nil cons))
 996     (dolist (name (cdr spec))
 997       (let ((var (find-in-bindings vars name)))
 998         (etypecase var
 999           (cons
1000            (aver (eq (car var) 'MACRO))
1001            (compiler-error
1002             "~S is a symbol-macro and thus can't be declared special."
1003             name))
1004           (lambda-var
1005            (when (lambda-var-ignorep var)
1006              ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1007              ;; requires that this be a STYLE-WARNING, not a full WARNING.
1008              (compiler-style-warn
1009               "The ignored variable ~S is being declared special."
1010               name))
1011            (setf (lambda-var-specvar var)
1012                  (specvar-for-binding name)))
1013           (null
1014            (unless (assoc name (new-venv) :test #'eq)
1015              (new-venv (cons name (specvar-for-binding name))))))))
1016     (if (new-venv)
1017         (make-lexenv :default res :vars (new-venv))
1018         res)))
1019
1020 ;;; Return a DEFINED-FUN which copies a GLOBAL-VAR but for its INLINEP
1021 ;;; (and TYPE if notinline).
1022 (defun make-new-inlinep (var inlinep)
1023   (declare (type global-var var) (type inlinep inlinep))
1024   (let ((res (make-defined-fun
1025               :%source-name (leaf-source-name var)
1026               :where-from (leaf-where-from var)
1027               :type (if (and (eq inlinep :notinline)
1028                              (not (eq (leaf-where-from var) :declared)))
1029                         (specifier-type 'function)
1030                         (leaf-type var))
1031               :inlinep inlinep)))
1032     (when (defined-fun-p var)
1033       (setf (defined-fun-inline-expansion res)
1034             (defined-fun-inline-expansion var))
1035       (setf (defined-fun-functional res)
1036             (defined-fun-functional var)))
1037     res))
1038
1039 ;;; Parse an inline/notinline declaration. If it's a local function we're
1040 ;;; defining, set its INLINEP. If a global function, add a new FENV entry.
1041 (defun process-inline-decl (spec res fvars)
1042   (let ((sense (cdr (assoc (first spec) *inlinep-translations* :test #'eq)))
1043         (new-fenv ()))
1044     (dolist (name (rest spec))
1045       (let ((fvar (find name fvars
1046                         :key #'leaf-source-name
1047                         :test #'equal)))
1048         (if fvar
1049             (setf (functional-inlinep fvar) sense)
1050             (let ((found
1051                    (find-lexically-apparent-fun
1052                     name "in an inline or notinline declaration")))
1053               (etypecase found
1054                 (functional
1055                  (when (policy *lexenv* (>= speed inhibit-warnings))
1056                    (compiler-notify "ignoring ~A declaration not at ~
1057                                      definition of local function:~%  ~S"
1058                                     sense name)))
1059                 (global-var
1060                  (push (cons name (make-new-inlinep found sense))
1061                        new-fenv)))))))
1062
1063     (if new-fenv
1064         (make-lexenv :default res :funs new-fenv)
1065         res)))
1066
1067 ;;; like FIND-IN-BINDINGS, but looks for #'FOO in the FVARS
1068 (defun find-in-bindings-or-fbindings (name vars fvars)
1069   (declare (list vars fvars))
1070   (if (consp name)
1071       (destructuring-bind (wot fn-name) name
1072         (unless (eq wot 'function)
1073           (compiler-error "The function or variable name ~S is unrecognizable."
1074                           name))
1075         (find fn-name fvars :key #'leaf-source-name :test #'equal))
1076       (find-in-bindings vars name)))
1077
1078 ;;; Process an ignore/ignorable declaration, checking for various losing
1079 ;;; conditions.
1080 (defun process-ignore-decl (spec vars fvars)
1081   (declare (list spec vars fvars))
1082   (dolist (name (rest spec))
1083     (let ((var (find-in-bindings-or-fbindings name vars fvars)))
1084       (cond
1085        ((not var)
1086         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1087         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1088         (compiler-style-warn "declaring unknown variable ~S to be ignored"
1089                              name))
1090        ;; FIXME: This special case looks like non-ANSI weirdness.
1091        ((and (consp var) (eq (car var) 'macro))
1092         ;; Just ignore the IGNORE decl.
1093         )
1094        ((functional-p var)
1095         (setf (leaf-ever-used var) t))
1096        ((and (lambda-var-specvar var) (eq (first spec) 'ignore))
1097         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1098         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1099         (compiler-style-warn "declaring special variable ~S to be ignored"
1100                              name))
1101        ((eq (first spec) 'ignorable)
1102         (setf (leaf-ever-used var) t))
1103        (t
1104         (setf (lambda-var-ignorep var) t)))))
1105   (values))
1106
1107 ;;; FIXME: This is non-ANSI, so the default should be T, or it should
1108 ;;; go away, I think.
1109 (defvar *suppress-values-declaration* nil
1110   #!+sb-doc
1111   "If true, processing of the VALUES declaration is inhibited.")
1112
1113 ;;; Process a single declaration spec, augmenting the specified LEXENV
1114 ;;; RES. Return RES and result type. VARS and FVARS are as described
1115 ;;; PROCESS-DECLS.
1116 (defun process-1-decl (raw-spec res vars fvars)
1117   (declare (type list raw-spec vars fvars))
1118   (declare (type lexenv res))
1119   (let ((spec (canonized-decl-spec raw-spec))
1120         (result-type *wild-type*))
1121     (values
1122      (case (first spec)
1123        (special (process-special-decl spec res vars))
1124        (ftype
1125         (unless (cdr spec)
1126           (compiler-error "no type specified in FTYPE declaration: ~S" spec))
1127         (process-ftype-decl (second spec) res (cddr spec) fvars))
1128        ((inline notinline maybe-inline)
1129         (process-inline-decl spec res fvars))
1130        ((ignore ignorable)
1131         (process-ignore-decl spec vars fvars)
1132         res)
1133        (optimize
1134         (make-lexenv
1135          :default res
1136          :policy (process-optimize-decl spec (lexenv-policy res))))
1137        (type
1138         (process-type-decl (cdr spec) res vars))
1139        (values
1140         (unless *suppress-values-declaration*
1141           (let ((types (cdr spec)))
1142             (setq result-type
1143                   (compiler-values-specifier-type
1144                    (if (singleton-p types)
1145                        (car types)
1146                        `(values ,@types)))))
1147           res))
1148        (dynamic-extent
1149         (when (policy *lexenv* (> speed inhibit-warnings))
1150           (compiler-notify
1151            "compiler limitation: ~
1152           ~%  There's no special support for DYNAMIC-EXTENT (so it's ignored)."))
1153         res)
1154        (t
1155         (unless (info :declaration :recognized (first spec))
1156           (compiler-warn "unrecognized declaration ~S" raw-spec))
1157         res))
1158      result-type)))
1159
1160 ;;; Use a list of DECLARE forms to annotate the lists of LAMBDA-VAR
1161 ;;; and FUNCTIONAL structures which are being bound. In addition to
1162 ;;; filling in slots in the leaf structures, we return a new LEXENV,
1163 ;;; which reflects pervasive special and function type declarations,
1164 ;;; (NOT)INLINE declarations and OPTIMIZE declarations, and type of
1165 ;;; VALUES declarations.
1166 ;;;
1167 ;;; This is also called in main.lisp when PROCESS-FORM handles a use
1168 ;;; of LOCALLY.
1169 (defun process-decls (decls vars fvars &optional (env *lexenv*))
1170   (declare (list decls vars fvars))
1171   (let ((result-type *wild-type*))
1172     (dolist (decl decls)
1173       (dolist (spec (rest decl))
1174         (unless (consp spec)
1175           (compiler-error "malformed declaration specifier ~S in ~S" spec decl))
1176         (multiple-value-bind (new-env new-result-type)
1177             (process-1-decl spec env vars fvars)
1178           (setq env new-env)
1179           (unless (eq new-result-type *wild-type*)
1180             (setq result-type
1181                   (values-type-intersection result-type new-result-type))))))
1182     (values env result-type)))
1183
1184 (defun %processing-decls (decls vars fvars ctran lvar fun)
1185   (multiple-value-bind (*lexenv* result-type)
1186       (process-decls decls vars fvars)
1187     (cond ((eq result-type *wild-type*)
1188            (funcall fun ctran lvar))
1189           (t
1190            (let ((value-ctran (make-ctran))
1191                  (value-lvar (make-lvar)))
1192              (multiple-value-prog1
1193                  (funcall fun value-ctran value-lvar)
1194                (let ((cast (make-cast value-lvar result-type
1195                                       (lexenv-policy *lexenv*))))
1196                  (link-node-to-previous-ctran cast value-ctran)
1197                  (setf (lvar-dest value-lvar) cast)
1198                  (use-continuation cast ctran lvar))))))))
1199 (defmacro processing-decls ((decls vars fvars ctran lvar) &body forms)
1200   (check-type ctran symbol)
1201   (check-type lvar symbol)
1202   `(%processing-decls ,decls ,vars ,fvars ,ctran ,lvar
1203                       (lambda (,ctran ,lvar) ,@forms)))
1204
1205 ;;; Return the SPECVAR for NAME to use when we see a local SPECIAL
1206 ;;; declaration. If there is a global variable of that name, then
1207 ;;; check that it isn't a constant and return it. Otherwise, create an
1208 ;;; anonymous GLOBAL-VAR.
1209 (defun specvar-for-binding (name)
1210   (cond ((not (eq (info :variable :where-from name) :assumed))
1211          (let ((found (find-free-var name)))
1212            (when (heap-alien-info-p found)
1213              (compiler-error
1214               "~S is an alien variable and so can't be declared special."
1215               name))
1216            (unless (global-var-p found)
1217              (compiler-error
1218               "~S is a constant and so can't be declared special."
1219               name))
1220            found))
1221         (t
1222          (make-global-var :kind :special
1223                           :%source-name name
1224                           :where-from :declared))))