src/compiler/ir1tran.lisp

   1 ;;;; This file contains code which does the translation from Lisp code
   2 ;;;; to the first intermediate representation (IR1).
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14
  15 (declaim (special *compiler-error-bailout*))
  16
  17 ;;; *SOURCE-PATHS* is a hashtable from source code forms to the path
  18 ;;; taken through the source to reach the form. This provides a way to
  19 ;;; keep track of the location of original source forms, even when
  20 ;;; macroexpansions and other arbitary permutations of the code
  21 ;;; happen. This table is initialized by calling FIND-SOURCE-PATHS on
  22 ;;; the original source.
  23 (declaim (hash-table *source-paths*))
  24 (defvar *source-paths*)
  25
  26 ;;; *CURRENT-COMPONENT* is the COMPONENT structure which we link
  27 ;;; blocks into as we generate them. This just serves to glue the
  28 ;;; emitted blocks together until local call analysis and flow graph
  29 ;;; canonicalization figure out what is really going on. We need to
  30 ;;; keep track of all the blocks generated so that we can delete them
  31 ;;; if they turn out to be unreachable.
  32 ;;;
  33 ;;; FIXME: It's confusing having one variable named *CURRENT-COMPONENT*
  34 ;;; and another named *COMPONENT-BEING-COMPILED*. (In CMU CL they
  35 ;;; were called *CURRENT-COMPONENT* and *COMPILE-COMPONENT* respectively,
  36 ;;; which was also confusing.)
  37 (declaim (type (or component null) *current-component*))
  38 (defvar *current-component*)
  39
  40 ;;; *CURRENT-PATH* is the source path of the form we are currently
  41 ;;; translating. See NODE-SOURCE-PATH in the NODE structure.
  42 (declaim (list *current-path*))
  43 (defvar *current-path*)
  44
  45 (defvar *derive-function-types* nil
  46   "Should the compiler assume that function types will never change,
  47   so that it can use type information inferred from current definitions
  48   to optimize code which uses those definitions? Setting this true
  49   gives non-ANSI, early-CMU-CL behavior. It can be useful for improving
  50   the efficiency of stable code.")
  51
  52 (defvar *fun-names-in-this-file* nil)
  53
  54 ;;; *ALLOW-DEBUG-CATCH-TAG* controls whether we should allow the
  55 ;;; insertion a (CATCH ...) around code to allow the debugger RETURN
  56 ;;; command to function.
  57 (defvar *allow-debug-catch-tag* t)
  58 \f
  59 ;;;; namespace management utilities
  60
  61 (defun fun-lexically-notinline-p (name)
  62   (let ((fun (lexenv-find name funs :test #'equal)))
  63     ;; a declaration will trump a proclamation
  64     (if (and fun (defined-fun-p fun))
  65         (eq (defined-fun-inlinep fun) :notinline)
  66         (eq (info :function :inlinep name) :notinline))))
  67
  68 ;;; Return a GLOBAL-VAR structure usable for referencing the global
  69 ;;; function NAME.
  70 (defun find-free-really-fun (name)
  71   (unless (info :function :kind name)
  72     (setf (info :function :kind name) :function)
  73     (setf (info :function :where-from name) :assumed))
  74
  75   (let ((where (info :function :where-from name)))
  76     (when (and (eq where :assumed)
  77                ;; In the ordinary target Lisp, it's silly to report
  78                ;; undefinedness when the function is defined in the
  79                ;; running Lisp. But at cross-compile time, the current
  80                ;; definedness of a function is irrelevant to the
  81                ;; definedness at runtime, which is what matters.
  82                #-sb-xc-host (not (fboundp name)))
  83       (note-undefined-reference name :function))
  84     (make-global-var
  85      :kind :global-function
  86      :%source-name name
  87      :type (if (or *derive-function-types*
  88                    (eq where :declared)
  89                    (and (member name *fun-names-in-this-file* :test #'equal)
  90                         (not (fun-lexically-notinline-p name))))
  91                (info :function :type name)
  92                (specifier-type 'function))
  93      :where-from where)))
  94
  95 ;;; Has the *FREE-FUNS* entry FREE-FUN become invalid?
  96 ;;;
  97 ;;; In CMU CL, the answer was implicitly always true, so this
  98 ;;; predicate didn't exist.
  99 ;;;
 100 ;;; This predicate was added to fix bug 138 in SBCL. In some obscure
 101 ;;; circumstances, it was possible for a *FREE-FUNS* entry to contain a
 102 ;;; DEFINED-FUN whose DEFINED-FUN-FUNCTIONAL object contained IR1
 103 ;;; stuff (NODEs, BLOCKs...) referring to an already compiled (aka
 104 ;;; "dead") component. When this IR1 stuff was reused in a new
 105 ;;; component, under further obscure circumstances it could be used by
 106 ;;; WITH-IR1-ENVIRONMENT-FROM-NODE to generate a binding for
 107 ;;; *CURRENT-COMPONENT*. At that point things got all confused, since
 108 ;;; IR1 conversion was sending code to a component which had already
 109 ;;; been compiled and would never be compiled again.
 110 (defun invalid-free-fun-p (free-fun)
 111   ;; There might be other reasons that *FREE-FUN* entries could
 112   ;; become invalid, but the only one we've been bitten by so far
 113   ;; (sbcl-0.pre7.118) is this one:
 114   (and (defined-fun-p free-fun)
 115        (let ((functional (defined-fun-functional free-fun)))
 116          (or (and functional
 117                   (eql (functional-kind functional) :deleted))
 118              (and (lambda-p functional)
 119                   (or
 120                    ;; (The main reason for this first test is to bail
 121                    ;; out early in cases where the LAMBDA-COMPONENT
 122                    ;; call in the second test would fail because links
 123                    ;; it needs are uninitialized or invalid.)
 124                    ;;
 125                    ;; If the BIND node for this LAMBDA is null, then
 126                    ;; according to the slot comments, the LAMBDA has
 127                    ;; been deleted or its call has been deleted. In
 128                    ;; that case, it seems rather questionable to reuse
 129                    ;; it, and certainly it shouldn't be necessary to
 130                    ;; reuse it, so we cheerfully declare it invalid.
 131                    (null (lambda-bind functional))
 132                    ;; If this IR1 stuff belongs to a dead component,
 133                    ;; then we can't reuse it without getting into
 134                    ;; bizarre confusion.
 135                    (eql (component-info (lambda-component functional))
 136                         :dead)))))))
 137
 138 ;;; If NAME already has a valid entry in *FREE-FUNS*, then return
 139 ;;; the value. Otherwise, make a new GLOBAL-VAR using information from
 140 ;;; the global environment and enter it in *FREE-FUNS*. If NAME
 141 ;;; names a macro or special form, then we error out using the
 142 ;;; supplied context which indicates what we were trying to do that
 143 ;;; demanded a function.
 144 (declaim (ftype (sfunction (t string) global-var) find-free-fun))
 145 (defun find-free-fun (name context)
 146   (or (let ((old-free-fun (gethash name *free-funs*)))
 147         (and (not (invalid-free-fun-p old-free-fun))
 148              old-free-fun))
 149       (ecase (info :function :kind name)
 150         ;; FIXME: The :MACRO and :SPECIAL-FORM cases could be merged.
 151         (:macro
 152          (compiler-error "The macro name ~S was found ~A." name context))
 153         (:special-form
 154          (compiler-error "The special form name ~S was found ~A."
 155                          name
 156                          context))
 157         ((:function nil)
 158          (check-fun-name name)
 159          (note-if-setf-fun-and-macro name)
 160          (let ((expansion (fun-name-inline-expansion name))
 161                (inlinep (info :function :inlinep name)))
 162            (setf (gethash name *free-funs*)
 163                  (if (or expansion inlinep)
 164                      (make-defined-fun
 165                       :%source-name name
 166                       :inline-expansion expansion
 167                       :inlinep inlinep
 168                       :where-from (info :function :where-from name)
 169                       :type (if (eq inlinep :notinline)
 170                                 (specifier-type 'function)
 171                                 (info :function :type name)))
 172                      (find-free-really-fun name))))))))
 173
 174 ;;; Return the LEAF structure for the lexically apparent function
 175 ;;; definition of NAME.
 176 (declaim (ftype (sfunction (t string) leaf) find-lexically-apparent-fun))
 177 (defun find-lexically-apparent-fun (name context)
 178   (let ((var (lexenv-find name funs :test #'equal)))
 179     (cond (var
 180            (unless (leaf-p var)
 181              (aver (and (consp var) (eq (car var) 'macro)))
 182              (compiler-error "found macro name ~S ~A" name context))
 183            var)
 184           (t
 185            (find-free-fun name context)))))
 186
 187 ;;; Return the LEAF node for a global variable reference to NAME. If
 188 ;;; NAME is already entered in *FREE-VARS*, then we just return the
 189 ;;; corresponding value. Otherwise, we make a new leaf using
 190 ;;; information from the global environment and enter it in
 191 ;;; *FREE-VARS*. If the variable is unknown, then we emit a warning.
 192 (declaim (ftype (sfunction (t) (or leaf cons heap-alien-info)) find-free-var))
 193 (defun find-free-var (name)
 194   (unless (symbolp name)
 195     (compiler-error "Variable name is not a symbol: ~S." name))
 196   (or (gethash name *free-vars*)
 197       (let ((kind (info :variable :kind name))
 198             (type (info :variable :type name))
 199             (where-from (info :variable :where-from name)))
 200         (when (and (eq where-from :assumed) (eq kind :global))
 201           (note-undefined-reference name :variable))
 202         (setf (gethash name *free-vars*)
 203               (case kind
 204                 (:alien
 205                  (info :variable :alien-info name))
 206                 ;; FIXME: The return value in this case should really be
 207                 ;; of type SB!C::LEAF.  I don't feel too badly about it,
 208                 ;; because the MACRO idiom is scattered throughout this
 209                 ;; file, but it should be cleaned up so we're not
 210                 ;; throwing random conses around.  --njf 2002-03-23
 211                 (:macro
 212                  (let ((expansion (info :variable :macro-expansion name))
 213                        (type (type-specifier (info :variable :type name))))
 214                    `(MACRO . (the ,type ,expansion))))
 215                 (:constant
 216                  (let ((value (info :variable :constant-value name)))
 217                    (make-constant :value value
 218                                   :%source-name name
 219                                   :type (ctype-of value)
 220                                   :where-from where-from)))
 221                 (t
 222                  (make-global-var :kind kind
 223                                   :%source-name name
 224                                   :type type
 225                                   :where-from where-from)))))))
 226 \f
 227 ;;; Grovel over CONSTANT checking for any sub-parts that need to be
 228 ;;; processed with MAKE-LOAD-FORM. We have to be careful, because
 229 ;;; CONSTANT might be circular. We also check that the constant (and
 230 ;;; any subparts) are dumpable at all.
 231 (eval-when (:compile-toplevel :load-toplevel :execute)
 232   ;; The EVAL-WHEN is necessary for #.(1+ LIST-TO-HASH-TABLE-THRESHOLD)
 233   ;; below. -- AL 20010227
 234   (def!constant list-to-hash-table-threshold 32))
 235 (defun maybe-emit-make-load-forms (constant)
 236   (let ((things-processed nil)
 237         (count 0))
 238     ;; FIXME: Does this LIST-or-HASH-TABLE messiness give much benefit?
 239     (declare (type (or list hash-table) things-processed)
 240              (type (integer 0 #.(1+ list-to-hash-table-threshold)) count)
 241              (inline member))
 242     (labels ((grovel (value)
 243                ;; Unless VALUE is an object which which obviously
 244                ;; can't contain other objects
 245                (unless (typep value
 246                               '(or #-sb-xc-host unboxed-array
 247                                    symbol
 248                                    number
 249                                    character
 250                                    string))
 251                  (etypecase things-processed
 252                    (list
 253                     (when (member value things-processed :test #'eq)
 254                       (return-from grovel nil))
 255                     (push value things-processed)
 256                     (incf count)
 257                     (when (> count list-to-hash-table-threshold)
 258                       (let ((things things-processed))
 259                         (setf things-processed
 260                               (make-hash-table :test 'eq))
 261                         (dolist (thing things)
 262                           (setf (gethash thing things-processed) t)))))
 263                    (hash-table
 264                     (when (gethash value things-processed)
 265                       (return-from grovel nil))
 266                     (setf (gethash value things-processed) t)))
 267                  (typecase value
 268                    (cons
 269                     (grovel (car value))
 270                     (grovel (cdr value)))
 271                    (simple-vector
 272                     (dotimes (i (length value))
 273                       (grovel (svref value i))))
 274                    ((vector t)
 275                     (dotimes (i (length value))
 276                       (grovel (aref value i))))
 277                    ((simple-array t)
 278                     ;; Even though the (ARRAY T) branch does the exact
 279                     ;; same thing as this branch we do this separately
 280                     ;; so that the compiler can use faster versions of
 281                     ;; array-total-size and row-major-aref.
 282                     (dotimes (i (array-total-size value))
 283                       (grovel (row-major-aref value i))))
 284                    ((array t)
 285                     (dotimes (i (array-total-size value))
 286                       (grovel (row-major-aref value i))))
 287                    (;; In the target SBCL, we can dump any instance,
 288                     ;; but in the cross-compilation host,
 289                     ;; %INSTANCE-FOO functions don't work on general
 290                     ;; instances, only on STRUCTURE!OBJECTs.
 291                     #+sb-xc-host structure!object
 292                     #-sb-xc-host instance
 293                     (when (emit-make-load-form value)
 294                       (dotimes (i (%instance-length value))
 295                         (grovel (%instance-ref value i)))))
 296                    (t
 297                     (compiler-error
 298                      "Objects of type ~S can't be dumped into fasl files."
 299                      (type-of value)))))))
 300       (grovel constant)))
 301   (values))
 302 \f
 303 ;;;; some flow-graph hacking utilities
 304
 305 ;;; This function sets up the back link between the node and the
 306 ;;; ctran which continues at it.
 307 (defun link-node-to-previous-ctran (node ctran)
 308   (declare (type node node) (type ctran ctran))
 309   (aver (not (ctran-next ctran)))
 310   (setf (ctran-next ctran) node)
 311   (setf (node-prev node) ctran))
 312
 313 ;;; This function is used to set the ctran for a node, and thus
 314 ;;; determine what is evaluated next. If the ctran has no block, then
 315 ;;; we make it be in the block that the node is in. If the ctran heads
 316 ;;; its block, we end our block and link it to that block.
 317 #!-sb-fluid (declaim (inline use-ctran))
 318 (defun use-ctran (node ctran)
 319   (declare (type node node) (type ctran ctran))
 320   (if (eq (ctran-kind ctran) :unused)
 321       (let ((node-block (ctran-block (node-prev node))))
 322         (setf (ctran-block ctran) node-block)
 323         (setf (ctran-kind ctran) :inside-block)
 324         (setf (ctran-use ctran) node)
 325         (setf (node-next node) ctran))
 326       (%use-ctran node ctran)))
 327 (defun %use-ctran (node ctran)
 328   (declare (type node node) (type ctran ctran) (inline member))
 329   (let ((block (ctran-block ctran))
 330         (node-block (ctran-block (node-prev node))))
 331     (aver (eq (ctran-kind ctran) :block-start))
 332     (when (block-last node-block)
 333       (error "~S has already ended." node-block))
 334     (setf (block-last node-block) node)
 335     (when (block-succ node-block)
 336       (error "~S already has successors." node-block))
 337     (setf (block-succ node-block) (list block))
 338     (when (memq node-block (block-pred block))
 339       (error "~S is already a predecessor of ~S." node-block block))
 340     (push node-block (block-pred block))))
 341
 342 ;;; This function is used to set the ctran for a node, and thus
 343 ;;; determine what receives the value.
 344 (defun use-lvar (node lvar)
 345   (declare (type valued-node node) (type (or lvar null) lvar))
 346   (aver (not (node-lvar node)))
 347   (when lvar
 348     (setf (node-lvar node) lvar)
 349     (cond ((null (lvar-uses lvar))
 350            (setf (lvar-uses lvar) node))
 351           ((listp (lvar-uses lvar))
 352            (aver (not (memq node (lvar-uses lvar))))
 353            (push node (lvar-uses lvar)))
 354           (t
 355            (aver (neq node (lvar-uses lvar)))
 356            (setf (lvar-uses lvar) (list node (lvar-uses lvar)))))
 357     (reoptimize-lvar lvar)))
 358
 359 #!-sb-fluid(declaim (inline use-continuation))
 360 (defun use-continuation (node ctran lvar)
 361   (use-ctran node ctran)
 362   (use-lvar node lvar))
 363 \f
 364 ;;;; exported functions
 365
 366 ;;; This function takes a form and the top level form number for that
 367 ;;; form, and returns a lambda representing the translation of that
 368 ;;; form in the current global environment. The returned lambda is a
 369 ;;; top level lambda that can be called to cause evaluation of the
 370 ;;; forms. This lambda is in the initial component. If FOR-VALUE is T,
 371 ;;; then the value of the form is returned from the function,
 372 ;;; otherwise NIL is returned.
 373 ;;;
 374 ;;; This function may have arbitrary effects on the global environment
 375 ;;; due to processing of EVAL-WHENs. All syntax error checking is
 376 ;;; done, with erroneous forms being replaced by a proxy which signals
 377 ;;; an error if it is evaluated. Warnings about possibly inconsistent
 378 ;;; or illegal changes to the global environment will also be given.
 379 ;;;
 380 ;;; We make the initial component and convert the form in a PROGN (and
 381 ;;; an optional NIL tacked on the end.) We then return the lambda. We
 382 ;;; bind all of our state variables here, rather than relying on the
 383 ;;; global value (if any) so that IR1 conversion will be reentrant.
 384 ;;; This is necessary for EVAL-WHEN processing, etc.
 385 ;;;
 386 ;;; The hashtables used to hold global namespace info must be
 387 ;;; reallocated elsewhere. Note also that *LEXENV* is not bound, so
 388 ;;; that local macro definitions can be introduced by enclosing code.
 389 (defun ir1-toplevel (form path for-value)
 390   (declare (list path))
 391   (let* ((*current-path* path)
 392          (component (make-empty-component))
 393          (*current-component* component))
 394     (setf (component-name component) "initial component")
 395     (setf (component-kind component) :initial)
 396     (let* ((forms (if for-value `(,form) `(,form nil)))
 397            (res (ir1-convert-lambda-body
 398                  forms ()
 399                  :debug-name (debug-namify "top level form " form))))
 400       (setf (functional-entry-fun res) res
 401             (functional-arg-documentation res) ()
 402             (functional-kind res) :toplevel)
 403       res)))
 404
 405 ;;; *CURRENT-FORM-NUMBER* is used in FIND-SOURCE-PATHS to compute the
 406 ;;; form number to associate with a source path. This should be bound
 407 ;;; to an initial value of 0 before the processing of each truly
 408 ;;; top level form.
 409 (declaim (type index *current-form-number*))
 410 (defvar *current-form-number*)
 411
 412 ;;; This function is called on freshly read forms to record the
 413 ;;; initial location of each form (and subform.) Form is the form to
 414 ;;; find the paths in, and TLF-NUM is the top level form number of the
 415 ;;; truly top level form.
 416 ;;;
 417 ;;; This gets a bit interesting when the source code is circular. This
 418 ;;; can (reasonably?) happen in the case of circular list constants.
 419 (defun find-source-paths (form tlf-num)
 420   (declare (type index tlf-num))
 421   (let ((*current-form-number* 0))
 422     (sub-find-source-paths form (list tlf-num)))
 423   (values))
 424 (defun sub-find-source-paths (form path)
 425   (unless (gethash form *source-paths*)
 426     (setf (gethash form *source-paths*)
 427           (list* 'original-source-start *current-form-number* path))
 428     (incf *current-form-number*)
 429     (let ((pos 0)
 430           (subform form)
 431           (trail form))
 432       (declare (fixnum pos))
 433       (macrolet ((frob ()
 434                    '(progn
 435                       (when (atom subform) (return))
 436                       (let ((fm (car subform)))
 437                         (when (consp fm)
 438                           (sub-find-source-paths fm (cons pos path)))
 439                         (incf pos))
 440                       (setq subform (cdr subform))
 441                       (when (eq subform trail) (return)))))
 442         (loop
 443           (frob)
 444           (frob)
 445           (setq trail (cdr trail)))))))
 446 \f
 447 ;;;; IR1-CONVERT, macroexpansion and special form dispatching
 448
 449 (declaim (ftype (sfunction (ctran ctran (or lvar null) t) (values))
 450                 ir1-convert))
 451 (macrolet (;; Bind *COMPILER-ERROR-BAILOUT* to a function that throws
 452            ;; out of the body and converts a condition signalling form
 453            ;; instead. The source form is converted to a string since it
 454            ;; may contain arbitrary non-externalizable objects.
 455            (ir1-error-bailout ((start next result form) &body body)
 456              (with-unique-names (skip condition)
 457                `(block ,skip
 458                  (let ((,condition (catch 'ir1-error-abort
 459                                      (let ((*compiler-error-bailout*
 460                                             (lambda (&optional e)
 461                                               (throw 'ir1-error-abort e))))
 462                                        ,@body
 463                                        (return-from ,skip nil)))))
 464                    (ir1-convert ,start ,next ,result
 465                                 (make-compiler-error-form ,condition ,form)))))))
 466
 467   ;; Translate FORM into IR1. The code is inserted as the NEXT of the
 468   ;; CTRAN START. RESULT is the LVAR which receives the value of the
 469   ;; FORM to be translated. The translators call this function
 470   ;; recursively to translate their subnodes.
 471   ;;
 472   ;; As a special hack to make life easier in the compiler, a LEAF
 473   ;; IR1-converts into a reference to that LEAF structure. This allows
 474   ;; the creation using backquote of forms that contain leaf
 475   ;; references, without having to introduce dummy names into the
 476   ;; namespace.
 477   (defun ir1-convert (start next result form)
 478     (ir1-error-bailout (start next result form)
 479       (let ((*current-path* (or (gethash form *source-paths*)
 480                                 (cons form *current-path*))))
 481         (if (atom form)
 482             (cond ((and (symbolp form) (not (keywordp form)))
 483                    (ir1-convert-var start next result form))
 484                   ((leaf-p form)
 485                    (reference-leaf start next result form))
 486                   (t
 487                    (reference-constant start next result form)))
 488             (let ((opname (car form)))
 489               (cond ((or (symbolp opname) (leaf-p opname))
 490                      (let ((lexical-def (if (leaf-p opname)
 491                                             opname
 492                                             (lexenv-find opname funs))))
 493                        (typecase lexical-def
 494                          (null
 495                           (ir1-convert-global-functoid start next result
 496                                                        form))
 497                          (functional
 498                           (ir1-convert-local-combination start next result
 499                                                          form
 500                                                          lexical-def))
 501                          (global-var
 502                           (ir1-convert-srctran start next result
 503                                                lexical-def form))
 504                          (t
 505                           (aver (and (consp lexical-def)
 506                                      (eq (car lexical-def) 'macro)))
 507                           (ir1-convert start next result
 508                                        (careful-expand-macro (cdr lexical-def)
 509                                                              form))))))
 510                     ((or (atom opname) (not (eq (car opname) 'lambda)))
 511                      (compiler-error "illegal function call"))
 512                     (t
 513                      ;; implicitly (LAMBDA ..) because the LAMBDA
 514                      ;; expression is the CAR of an executed form
 515                      (ir1-convert-combination start next result
 516                                               form
 517                                               (ir1-convert-lambda
 518                                                opname
 519                                                :debug-name (debug-namify
 520                                                             "LAMBDA CAR "
 521                                                             opname)
 522                                                :allow-debug-catch-tag t))))))))
 523     (values))
 524
 525   ;; Generate a reference to a manifest constant, creating a new leaf
 526   ;; if necessary. If we are producing a fasl file, make sure that
 527   ;; MAKE-LOAD-FORM gets used on any parts of the constant that it
 528   ;; needs to be.
 529   (defun reference-constant (start next result value)
 530     (declare (type ctran start next)
 531              (type (or lvar null) result)
 532              (inline find-constant))
 533     (ir1-error-bailout (start next result value)
 534      (when (producing-fasl-file)
 535        (maybe-emit-make-load-forms value))
 536      (let* ((leaf (find-constant value))
 537             (res (make-ref leaf)))
 538        (push res (leaf-refs leaf))
 539        (link-node-to-previous-ctran res start)
 540        (use-continuation res next result)))
 541     (values)))
 542
 543 ;;; Add FUNCTIONAL to the COMPONENT-REANALYZE-FUNCTIONALS, unless it's
 544 ;;; some trivial type for which reanalysis is a trivial no-op, or
 545 ;;; unless it doesn't belong in this component at all.
 546 ;;;
 547 ;;; FUNCTIONAL is returned.
 548 (defun maybe-reanalyze-functional (functional)
 549
 550   (aver (not (eql (functional-kind functional) :deleted))) ; bug 148
 551   (aver-live-component *current-component*)
 552
 553   ;; When FUNCTIONAL is of a type for which reanalysis isn't a trivial
 554   ;; no-op
 555   (when (typep functional '(or optional-dispatch clambda))
 556
 557     ;; When FUNCTIONAL knows its component
 558     (when (lambda-p functional)
 559       (aver (eql (lambda-component functional) *current-component*)))
 560
 561     (pushnew functional
 562              (component-reanalyze-functionals *current-component*)))
 563
 564   functional)
 565
 566 ;;; Generate a REF node for LEAF, frobbing the LEAF structure as
 567 ;;; needed. If LEAF represents a defined function which has already
 568 ;;; been converted, and is not :NOTINLINE, then reference the
 569 ;;; functional instead.
 570 (defun reference-leaf (start next result leaf)
 571   (declare (type ctran start next) (type (or lvar null) result) (type leaf leaf))
 572   (when (functional-p leaf)
 573     (assure-functional-live-p leaf))
 574   (let* ((type (lexenv-find leaf type-restrictions))
 575          (leaf (or (and (defined-fun-p leaf)
 576                         (not (eq (defined-fun-inlinep leaf)
 577                                  :notinline))
 578                         (let ((functional (defined-fun-functional leaf)))
 579                           (when (and functional
 580                                      (not (functional-kind functional)))
 581                             (maybe-reanalyze-functional functional))))
 582                    (when (and (lambda-p leaf)
 583                               (memq (functional-kind leaf)
 584                                     '(nil :optional)))
 585                      (maybe-reanalyze-functional leaf))
 586                    leaf))
 587          (ref (make-ref leaf)))
 588     (push ref (leaf-refs leaf))
 589     (setf (leaf-ever-used leaf) t)
 590     (link-node-to-previous-ctran ref start)
 591     (cond (type (let* ((ref-ctran (make-ctran))
 592                        (ref-lvar (make-lvar))
 593                        (cast (make-cast ref-lvar
 594                                         (make-single-value-type type)
 595                                         (lexenv-policy *lexenv*))))
 596                   (setf (lvar-dest ref-lvar) cast)
 597                   (use-continuation ref ref-ctran ref-lvar)
 598                   (link-node-to-previous-ctran cast ref-ctran)
 599                   (use-continuation cast next result)))
 600           (t (use-continuation ref next result)))))
 601
 602 ;;; Convert a reference to a symbolic constant or variable. If the
 603 ;;; symbol is entered in the LEXENV-VARS we use that definition,
 604 ;;; otherwise we find the current global definition. This is also
 605 ;;; where we pick off symbol macro and alien variable references.
 606 (defun ir1-convert-var (start next result name)
 607   (declare (type ctran start next) (type (or lvar null) result) (symbol name))
 608   (let ((var (or (lexenv-find name vars) (find-free-var name))))
 609     (etypecase var
 610       (leaf
 611        (when (lambda-var-p var)
 612          (let ((home (ctran-home-lambda-or-null start)))
 613            (when home
 614              (pushnew var (lambda-calls-or-closes home))))
 615          (when (lambda-var-ignorep var)
 616            ;; (ANSI's specification for the IGNORE declaration requires
 617            ;; that this be a STYLE-WARNING, not a full WARNING.)
 618            #-sb-xc-host
 619            (compiler-style-warn "reading an ignored variable: ~S" name)
 620            ;; there's no need for us to accept ANSI's lameness when
 621            ;; processing our own code, though.
 622            #+sb-xc-host
 623            (warn "reading an ignored variable: ~S" name)))
 624        (reference-leaf start next result var))
 625       (cons
 626        (aver (eq (car var) 'MACRO))
 627        ;; FIXME: [Free] type declarations. -- APD, 2002-01-26
 628        (ir1-convert start next result (cdr var)))
 629       (heap-alien-info
 630        (ir1-convert start next result `(%heap-alien ',var)))))
 631   (values))
 632
 633 ;;; Convert anything that looks like a special form, global function
 634 ;;; or compiler-macro call.
 635 (defun ir1-convert-global-functoid (start next result form)
 636   (declare (type ctran start next) (type (or lvar null) result) (list form))
 637   (let* ((fun-name (first form))
 638          (translator (info :function :ir1-convert fun-name))
 639          (cmacro-fun (sb!xc:compiler-macro-function fun-name *lexenv*)))
 640     (cond (translator
 641            (when cmacro-fun
 642              (compiler-warn "ignoring compiler macro for special form"))
 643            (funcall translator start next result form))
 644           ((and cmacro-fun
 645                 ;; gotcha: If you look up the DEFINE-COMPILER-MACRO
 646                 ;; macro in the ANSI spec, you might think that
 647                 ;; suppressing compiler-macro expansion when NOTINLINE
 648                 ;; is some pre-ANSI hack. However, if you look up the
 649                 ;; NOTINLINE declaration, you'll find that ANSI
 650                 ;; requires this behavior after all.
 651                 (not (eq (info :function :inlinep fun-name) :notinline)))
 652            (let ((res (careful-expand-macro cmacro-fun form)))
 653              (if (eq res form)
 654                  (ir1-convert-global-functoid-no-cmacro
 655                   start next result form fun-name)
 656                  (ir1-convert start next result res))))
 657           (t
 658            (ir1-convert-global-functoid-no-cmacro start next result
 659                                                   form fun-name)))))
 660
 661 ;;; Handle the case of where the call was not a compiler macro, or was
 662 ;;; a compiler macro and passed.
 663 (defun ir1-convert-global-functoid-no-cmacro (start next result form fun)
 664   (declare (type ctran start next) (type (or lvar null) result)
 665            (list form))
 666   ;; FIXME: Couldn't all the INFO calls here be converted into
 667   ;; standard CL functions, like MACRO-FUNCTION or something?
 668   ;; And what happens with lexically-defined (MACROLET) macros
 669   ;; here, anyway?
 670   (ecase (info :function :kind fun)
 671     (:macro
 672      (ir1-convert start next result
 673                   (careful-expand-macro (info :function :macro-function fun)
 674                                         form)))
 675     ((nil :function)
 676      (ir1-convert-srctran start next result
 677                           (find-free-fun fun "shouldn't happen! (no-cmacro)")
 678                           form))))
 679
 680 (defun muffle-warning-or-die ()
 681   (muffle-warning)
 682   (bug "no MUFFLE-WARNING restart"))
 683
 684 ;;; Expand FORM using the macro whose MACRO-FUNCTION is FUN, trapping
 685 ;;; errors which occur during the macroexpansion.
 686 (defun careful-expand-macro (fun form)
 687   (let (;; a hint I (WHN) wish I'd known earlier
 688         (hint "(hint: For more precise location, try *BREAK-ON-SIGNALS*.)"))
 689     (flet (;; Return a string to use as a prefix in error reporting,
 690            ;; telling something about which form caused the problem.
 691            (wherestring ()
 692              (let ((*print-pretty* nil)
 693                    ;; We rely on the printer to abbreviate FORM.
 694                    (*print-length* 3)
 695                    (*print-level* 1))
 696                (format
 697                 nil
 698                 #-sb-xc-host "(in macroexpansion of ~S)"
 699                 ;; longer message to avoid ambiguity "Was it the xc host
 700                 ;; or the cross-compiler which encountered the problem?"
 701                 #+sb-xc-host "(in cross-compiler macroexpansion of ~S)"
 702                 form))))
 703       (handler-bind ((style-warning (lambda (c)
 704                                       (compiler-style-warn
 705                                        "~@<~A~:@_~A~@:_~A~:>"
 706                                        (wherestring) hint c)
 707                                       (muffle-warning-or-die)))
 708                      ;; KLUDGE: CMU CL in its wisdom (version 2.4.6 for
 709                      ;; Debian Linux, anyway) raises a CL:WARNING
 710                      ;; condition (not a CL:STYLE-WARNING) for undefined
 711                      ;; symbols when converting interpreted functions,
 712                      ;; causing COMPILE-FILE to think the file has a real
 713                      ;; problem, causing COMPILE-FILE to return FAILURE-P
 714                      ;; set (not just WARNINGS-P set). Since undefined
 715                      ;; symbol warnings are often harmless forward
 716                      ;; references, and since it'd be inordinately painful
 717                      ;; to try to eliminate all such forward references,
 718                      ;; these warnings are basically unavoidable. Thus, we
 719                      ;; need to coerce the system to work through them,
 720                      ;; and this code does so, by crudely suppressing all
 721                      ;; warnings in cross-compilation macroexpansion. --
 722                      ;; WHN 19990412
 723                      #+(and cmu sb-xc-host)
 724                      (warning (lambda (c)
 725                                 (compiler-notify
 726                                  "~@<~A~:@_~
 727                                   ~A~:@_~
 728                                   ~@<(KLUDGE: That was a non-STYLE WARNING. ~
 729                                   Ordinarily that would cause compilation to ~
 730                                   fail. However, since we're running under ~
 731                                   CMU CL, and since CMU CL emits non-STYLE ~
 732                                   warnings for safe, hard-to-fix things (e.g. ~
 733                                   references to not-yet-defined functions) ~
 734                                   we're going to have to ignore it and ~
 735                                   proceed anyway. Hopefully we're not ~
 736                                   ignoring anything  horrible here..)~:@>~:>"
 737                                  (wherestring)
 738                                  c)
 739                                 (muffle-warning-or-die)))
 740                      #-(and cmu sb-xc-host)
 741                      (warning (lambda (c)
 742                                 (warn "~@<~A~:@_~A~@:_~A~:>"
 743                                       (wherestring) hint c)
 744                                 (muffle-warning-or-die)))
 745                      (error (lambda (c)
 746                               (compiler-error "~@<~A~:@_~A~@:_~A~:>"
 747                                               (wherestring) hint c))))
 748         (funcall sb!xc:*macroexpand-hook* fun form *lexenv*)))))
 749 \f
 750 ;;;; conversion utilities
 751
 752 ;;; Convert a bunch of forms, discarding all the values except the
 753 ;;; last. If there aren't any forms, then translate a NIL.
 754 (declaim (ftype (sfunction (ctran ctran (or lvar null) list) (values))
 755                 ir1-convert-progn-body))
 756 (defun ir1-convert-progn-body (start next result body)
 757   (if (endp body)
 758       (reference-constant start next result nil)
 759       (let ((this-start start)
 760             (forms body))
 761         (loop
 762           (let ((form (car forms)))
 763             (when (endp (cdr forms))
 764               (ir1-convert this-start next result form)
 765               (return))
 766             (let ((this-ctran (make-ctran)))
 767               (ir1-convert this-start this-ctran nil form)
 768               (setq this-start this-ctran
 769                     forms (cdr forms)))))))
 770   (values))
 771 \f
 772 ;;;; converting combinations
 773
 774 ;;; Convert a function call where the function FUN is a LEAF. FORM is
 775 ;;; the source for the call. We return the COMBINATION node so that
 776 ;;; the caller can poke at it if it wants to.
 777 (declaim (ftype (sfunction (ctran ctran (or lvar null) list leaf) combination)
 778                 ir1-convert-combination))
 779 (defun ir1-convert-combination (start next result form fun)
 780   (let ((ctran (make-ctran))
 781         (fun-lvar (make-lvar)))
 782     (ir1-convert start ctran fun-lvar `(the (or function symbol) ,fun))
 783     (ir1-convert-combination-args fun-lvar ctran next result (cdr form))))
 784
 785 ;;; Convert the arguments to a call and make the COMBINATION
 786 ;;; node. FUN-LVAR yields the function to call. ARGS is the list of
 787 ;;; arguments for the call, which defaults to the cdr of source. We
 788 ;;; return the COMBINATION node.
 789 (defun ir1-convert-combination-args (fun-lvar start next result args)
 790   (declare (type ctran start next)
 791            (type lvar fun-lvar)
 792            (type (or lvar null) result)
 793            (list args))
 794   (let ((node (make-combination fun-lvar)))
 795     (setf (lvar-dest fun-lvar) node)
 796     (collect ((arg-lvars))
 797       (let ((this-start start))
 798         (dolist (arg args)
 799           (let ((this-ctran (make-ctran))
 800                 (this-lvar (make-lvar node)))
 801             (ir1-convert this-start this-ctran this-lvar arg)
 802             (setq this-start this-ctran)
 803             (arg-lvars this-lvar)))
 804         (link-node-to-previous-ctran node this-start)
 805         (use-continuation node next result)
 806         (setf (combination-args node) (arg-lvars))))
 807     node))
 808
 809 ;;; Convert a call to a global function. If not :NOTINLINE, then we do
 810 ;;; source transforms and try out any inline expansion. If there is no
 811 ;;; expansion, but is :INLINE, then give an efficiency note (unless a
 812 ;;; known function which will quite possibly be open-coded.) Next, we
 813 ;;; go to ok-combination conversion.
 814 (defun ir1-convert-srctran (start next result var form)
 815   (declare (type ctran start next) (type (or lvar null) result)
 816            (type global-var var))
 817   (let ((inlinep (when (defined-fun-p var)
 818                    (defined-fun-inlinep var))))
 819     (if (eq inlinep :notinline)
 820         (ir1-convert-combination start next result form var)
 821         (let ((transform (info :function
 822                                :source-transform
 823                                (leaf-source-name var))))
 824           (if transform
 825               (multiple-value-bind (transformed pass) (funcall transform form)
 826                 (if pass
 827                     (ir1-convert-maybe-predicate start next result form var)
 828                     (ir1-convert start next result transformed)))
 829               (ir1-convert-maybe-predicate start next result form var))))))
 830
 831 ;;; If the function has the PREDICATE attribute, and the RESULT's DEST
 832 ;;; isn't an IF, then we convert (IF <form> T NIL), ensuring that a
 833 ;;; predicate always appears in a conditional context.
 834 ;;;
 835 ;;; If the function isn't a predicate, then we call
 836 ;;; IR1-CONVERT-COMBINATION-CHECKING-TYPE.
 837 (defun ir1-convert-maybe-predicate (start next result form var)
 838   (declare (type ctran start next)
 839            (type (or lvar null) result)
 840            (list form)
 841            (type global-var var))
 842   (let ((info (info :function :info (leaf-source-name var))))
 843     (if (and info
 844              (ir1-attributep (fun-info-attributes info) predicate)
 845              (not (if-p (and result (lvar-dest result)))))
 846         (ir1-convert start next result `(if ,form t nil))
 847         (ir1-convert-combination-checking-type start next result form var))))
 848
 849 ;;; Actually really convert a global function call that we are allowed
 850 ;;; to early-bind.
 851 ;;;
 852 ;;; If we know the function type of the function, then we check the
 853 ;;; call for syntactic legality with respect to the declared function
 854 ;;; type. If it is impossible to determine whether the call is correct
 855 ;;; due to non-constant keywords, then we give up, marking the call as
 856 ;;; :FULL to inhibit further error messages. We return true when the
 857 ;;; call is legal.
 858 ;;;
 859 ;;; If the call is legal, we also propagate type assertions from the
 860 ;;; function type to the arg and result lvars. We do this now so that
 861 ;;; IR1 optimize doesn't have to redundantly do the check later so
 862 ;;; that it can do the type propagation.
 863 (defun ir1-convert-combination-checking-type (start next result form var)
 864   (declare (type ctran start next) (type (or lvar null) result)
 865            (list form)
 866            (type leaf var))
 867   (let* ((node (ir1-convert-combination start next result form var))
 868          (fun-lvar (basic-combination-fun node))
 869          (type (leaf-type var)))
 870     (when (validate-call-type node type t)
 871       (setf (lvar-%derived-type fun-lvar)
 872             (make-single-value-type type))
 873       (setf (lvar-reoptimize fun-lvar) nil)))
 874   (values))
 875
 876 ;;; Convert a call to a local function, or if the function has already
 877 ;;; been LET converted, then throw FUNCTIONAL to
 878 ;;; LOCALL-ALREADY-LET-CONVERTED. The THROW should only happen when we
 879 ;;; are converting inline expansions for local functions during
 880 ;;; optimization.
 881 (defun ir1-convert-local-combination (start next result form functional)
 882   (assure-functional-live-p functional)
 883   (ir1-convert-combination start next result
 884                            form
 885                            (maybe-reanalyze-functional functional)))
 886 \f
 887 ;;;; PROCESS-DECLS
 888
 889 ;;; Given a list of LAMBDA-VARs and a variable name, return the
 890 ;;; LAMBDA-VAR for that name, or NIL if it isn't found. We return the
 891 ;;; *last* variable with that name, since LET* bindings may be
 892 ;;; duplicated, and declarations always apply to the last.
 893 (declaim (ftype (sfunction (list symbol) (or lambda-var list))
 894                 find-in-bindings))
 895 (defun find-in-bindings (vars name)
 896   (let ((found nil))
 897     (dolist (var vars)
 898       (cond ((leaf-p var)
 899              (when (eq (leaf-source-name var) name)
 900                (setq found var))
 901              (let ((info (lambda-var-arg-info var)))
 902                (when info
 903                  (let ((supplied-p (arg-info-supplied-p info)))
 904                    (when (and supplied-p
 905                               (eq (leaf-source-name supplied-p) name))
 906                      (setq found supplied-p))))))
 907             ((and (consp var) (eq (car var) name))
 908              (setf found (cdr var)))))
 909     found))
 910
 911 ;;; Called by PROCESS-DECLS to deal with a variable type declaration.
 912 ;;; If a LAMBDA-VAR being bound, we intersect the type with the var's
 913 ;;; type, otherwise we add a type restriction on the var. If a symbol
 914 ;;; macro, we just wrap a THE around the expansion.
 915 (defun process-type-decl (decl res vars)
 916   (declare (list decl vars) (type lexenv res))
 917   (let ((type (compiler-specifier-type (first decl))))
 918     (collect ((restr nil cons)
 919              (new-vars nil cons))
 920       (dolist (var-name (rest decl))
 921         (when (boundp var-name)
 922           (compiler-assert-symbol-home-package-unlocked var-name
 923                                                         "declaring the type of ~A"))
 924         (let* ((bound-var (find-in-bindings vars var-name))
 925                (var (or bound-var
 926                         (lexenv-find var-name vars)
 927                         (find-free-var var-name))))
 928           (etypecase var
 929             (leaf
 930              (flet
 931                  ((process-var (var bound-var)
 932                     (let* ((old-type (or (lexenv-find var type-restrictions)
 933                                          (leaf-type var)))
 934                            (int (if (or (fun-type-p type)
 935                                         (fun-type-p old-type))
 936                                     type
 937                                     (type-approx-intersection2
 938                                      old-type type))))
 939                       (cond ((eq int *empty-type*)
 940                              (unless (policy *lexenv* (= inhibit-warnings 3))
 941                                (warn
 942                                 'type-warning
 943                                 :format-control
 944                                 "The type declarations ~S and ~S for ~S conflict."
 945                                 :format-arguments
 946                                 (list
 947                                  (type-specifier old-type)
 948                                  (type-specifier type)
 949                                  var-name))))
 950                             (bound-var (setf (leaf-type bound-var) int))
 951                             (t
 952                              (restr (cons var int)))))))
 953                (process-var var bound-var)
 954                (awhen (and (lambda-var-p var)
 955                            (lambda-var-specvar var))
 956                       (process-var it nil))))
 957             (cons
 958              ;; FIXME: non-ANSI weirdness
 959              (aver (eq (car var) 'MACRO))
 960              (new-vars `(,var-name . (MACRO . (the ,(first decl)
 961                                                 ,(cdr var))))))
 962             (heap-alien-info
 963              (compiler-error
 964               "~S is an alien variable, so its type can't be declared."
 965               var-name)))))
 966
 967       (if (or (restr) (new-vars))
 968           (make-lexenv :default res
 969                        :type-restrictions (restr)
 970                        :vars (new-vars))
 971           res))))
 972
 973 ;;; This is somewhat similar to PROCESS-TYPE-DECL, but handles
 974 ;;; declarations for function variables. In addition to allowing
 975 ;;; declarations for functions being bound, we must also deal with
 976 ;;; declarations that constrain the type of lexically apparent
 977 ;;; functions.
 978 (defun process-ftype-decl (spec res names fvars)
 979   (declare (type list names fvars)
 980            (type lexenv res))
 981   (let ((type (compiler-specifier-type spec)))
 982     (collect ((res nil cons))
 983       (dolist (name names)
 984         (when (fboundp name)
 985           (compiler-assert-symbol-home-package-unlocked name
 986                                                         "declaring the ftype of ~A"))
 987         (let ((found (find name fvars
 988                            :key #'leaf-source-name
 989                            :test #'equal)))
 990           (cond
 991            (found
 992             (setf (leaf-type found) type)
 993             (assert-definition-type found type
 994                                     :unwinnage-fun #'compiler-notify
 995                                     :where "FTYPE declaration"))
 996            (t
 997             (res (cons (find-lexically-apparent-fun
 998                         name "in a function type declaration")
 999                        type))))))
1000       (if (res)
1001           (make-lexenv :default res :type-restrictions (res))
1002           res))))
1003
1004 ;;; Process a special declaration, returning a new LEXENV. A non-bound
1005 ;;; special declaration is instantiated by throwing a special variable
1006 ;;; into the variables.
1007 (defun process-special-decl (spec res vars)
1008   (declare (list spec vars) (type lexenv res))
1009   (collect ((new-venv nil cons))
1010     (dolist (name (cdr spec))
1011       (compiler-assert-symbol-home-package-unlocked name "declaring ~A special")
1012       (let ((var (find-in-bindings vars name)))
1013         (etypecase var
1014           (cons
1015            (aver (eq (car var) 'MACRO))
1016            (compiler-error
1017             "~S is a symbol-macro and thus can't be declared special."
1018             name))
1019           (lambda-var
1020            (when (lambda-var-ignorep var)
1021              ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1022              ;; requires that this be a STYLE-WARNING, not a full WARNING.
1023              (compiler-style-warn
1024               "The ignored variable ~S is being declared special."
1025               name))
1026            (setf (lambda-var-specvar var)
1027                  (specvar-for-binding name)))
1028           (null
1029            (unless (assoc name (new-venv) :test #'eq)
1030              (new-venv (cons name (specvar-for-binding name))))))))
1031     (if (new-venv)
1032         (make-lexenv :default res :vars (new-venv))
1033         res)))
1034
1035 ;;; Return a DEFINED-FUN which copies a GLOBAL-VAR but for its INLINEP
1036 ;;; (and TYPE if notinline).
1037 (defun make-new-inlinep (var inlinep)
1038   (declare (type global-var var) (type inlinep inlinep))
1039   (let ((res (make-defined-fun
1040               :%source-name (leaf-source-name var)
1041               :where-from (leaf-where-from var)
1042               :type (if (and (eq inlinep :notinline)
1043                              (not (eq (leaf-where-from var) :declared)))
1044                         (specifier-type 'function)
1045                         (leaf-type var))
1046               :inlinep inlinep)))
1047     (when (defined-fun-p var)
1048       (setf (defined-fun-inline-expansion res)
1049             (defined-fun-inline-expansion var))
1050       (setf (defined-fun-functional res)
1051             (defined-fun-functional var)))
1052     res))
1053
1054 ;;; Parse an inline/notinline declaration. If it's a local function we're
1055 ;;; defining, set its INLINEP. If a global function, add a new FENV entry.
1056 (defun process-inline-decl (spec res fvars)
1057   (let ((sense (cdr (assoc (first spec) *inlinep-translations* :test #'eq)))
1058         (new-fenv ()))
1059     (dolist (name (rest spec))
1060       (let ((fvar (find name fvars
1061                         :key #'leaf-source-name
1062                         :test #'equal)))
1063         (if fvar
1064             (setf (functional-inlinep fvar) sense)
1065             (let ((found
1066                    (find-lexically-apparent-fun
1067                     name "in an inline or notinline declaration")))
1068               (etypecase found
1069                 (functional
1070                  (when (policy *lexenv* (>= speed inhibit-warnings))
1071                    (compiler-notify "ignoring ~A declaration not at ~
1072                                      definition of local function:~%  ~S"
1073                                     sense name)))
1074                 (global-var
1075                  (push (cons name (make-new-inlinep found sense))
1076                        new-fenv)))))))
1077
1078     (if new-fenv
1079         (make-lexenv :default res :funs new-fenv)
1080         res)))
1081
1082 ;;; like FIND-IN-BINDINGS, but looks for #'FOO in the FVARS
1083 (defun find-in-bindings-or-fbindings (name vars fvars)
1084   (declare (list vars fvars))
1085   (if (consp name)
1086       (destructuring-bind (wot fn-name) name
1087         (unless (eq wot 'function)
1088           (compiler-error "The function or variable name ~S is unrecognizable."
1089                           name))
1090         (find fn-name fvars :key #'leaf-source-name :test #'equal))
1091       (find-in-bindings vars name)))
1092
1093 ;;; Process an ignore/ignorable declaration, checking for various losing
1094 ;;; conditions.
1095 (defun process-ignore-decl (spec vars fvars)
1096   (declare (list spec vars fvars))
1097   (dolist (name (rest spec))
1098     (let ((var (find-in-bindings-or-fbindings name vars fvars)))
1099       (cond
1100        ((not var)
1101         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1102         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1103         (compiler-style-warn "declaring unknown variable ~S to be ignored"
1104                              name))
1105        ;; FIXME: This special case looks like non-ANSI weirdness.
1106        ((and (consp var) (eq (car var) 'macro))
1107         ;; Just ignore the IGNORE decl.
1108         )
1109        ((functional-p var)
1110         (setf (leaf-ever-used var) t))
1111        ((and (lambda-var-specvar var) (eq (first spec) 'ignore))
1112         ;; ANSI's definition for "Declaration IGNORE, IGNORABLE"
1113         ;; requires that this be a STYLE-WARNING, not a full WARNING.
1114         (compiler-style-warn "declaring special variable ~S to be ignored"
1115                              name))
1116        ((eq (first spec) 'ignorable)
1117         (setf (leaf-ever-used var) t))
1118        (t
1119         (setf (lambda-var-ignorep var) t)))))
1120   (values))
1121
1122 (defun process-dx-decl (names vars)
1123   (flet ((maybe-notify (control &rest args)
1124            (when (policy *lexenv* (> speed inhibit-warnings))
1125              (apply #'compiler-notify control args))))
1126     (if (policy *lexenv* (= stack-allocate-dynamic-extent 3))
1127         (dolist (name names)
1128           (cond
1129             ((symbolp name)
1130              (let* ((bound-var (find-in-bindings vars name))
1131                     (var (or bound-var
1132                              (lexenv-find name vars)
1133                              (find-free-var name))))
1134                (etypecase var
1135                  (leaf
1136                   (if bound-var
1137                       (setf (leaf-dynamic-extent var) t)
1138                       (maybe-notify
1139                        "ignoring DYNAMIC-EXTENT declaration for free ~S"
1140                        name)))
1141                  (cons
1142                   (compiler-error "DYNAMIC-EXTENT on symbol-macro: ~S" name))
1143                  (heap-alien-info
1144                   (compiler-error "DYNAMIC-EXTENT on heap-alien-info: ~S"
1145                                   name)))))
1146             ((and (consp name)
1147                   (eq (car name) 'function)
1148                   (null (cddr name))
1149                   (valid-function-name-p (cadr name)))
1150              (maybe-notify "ignoring DYNAMIC-EXTENT declaration for ~S" name))
1151             (t (compiler-error "DYNAMIC-EXTENT on a weird thing: ~S" name))))
1152       (maybe-notify "ignoring DYNAMIC-EXTENT declarations for ~S" names))))
1153
1154 ;;; FIXME: This is non-ANSI, so the default should be T, or it should
1155 ;;; go away, I think.
1156 (defvar *suppress-values-declaration* nil
1157   #!+sb-doc
1158   "If true, processing of the VALUES declaration is inhibited.")
1159
1160 ;;; Process a single declaration spec, augmenting the specified LEXENV
1161 ;;; RES. Return RES and result type. VARS and FVARS are as described
1162 ;;; PROCESS-DECLS.
1163 (defun process-1-decl (raw-spec res vars fvars)
1164   (declare (type list raw-spec vars fvars))
1165   (declare (type lexenv res))
1166   (let ((spec (canonized-decl-spec raw-spec))
1167         (result-type *wild-type*))
1168     (values
1169      (case (first spec)
1170        (special (process-special-decl spec res vars))
1171        (ftype
1172         (unless (cdr spec)
1173           (compiler-error "no type specified in FTYPE declaration: ~S" spec))
1174         (process-ftype-decl (second spec) res (cddr spec) fvars))
1175        ((inline notinline maybe-inline)
1176         (process-inline-decl spec res fvars))
1177        ((ignore ignorable)
1178         (process-ignore-decl spec vars fvars)
1179         res)
1180        (optimize
1181         (make-lexenv
1182          :default res
1183          :policy (process-optimize-decl spec (lexenv-policy res))))
1184        (muffle-conditions
1185         (make-lexenv
1186          :default res
1187          :handled-conditions (process-muffle-conditions-decl
1188                               spec (lexenv-handled-conditions res))))
1189        (unmuffle-conditions
1190         (make-lexenv
1191          :default res
1192          :handled-conditions (process-unmuffle-conditions-decl
1193                               spec (lexenv-handled-conditions res))))
1194        (type
1195         (process-type-decl (cdr spec) res vars))
1196        (values
1197         (unless *suppress-values-declaration*
1198           (let ((types (cdr spec)))
1199             (setq result-type
1200                   (compiler-values-specifier-type
1201                    (if (singleton-p types)
1202                        (car types)
1203                        `(values ,@types)))))
1204           res))
1205        (dynamic-extent
1206         (process-dx-decl (cdr spec) vars)
1207         res)
1208        ((disable-package-locks enable-package-locks)
1209         (make-lexenv
1210          :default res
1211          :disabled-package-locks (process-package-lock-decl
1212                                   spec (lexenv-disabled-package-locks res))))
1213        (t
1214         (unless (info :declaration :recognized (first spec))
1215           (compiler-warn "unrecognized declaration ~S" raw-spec))
1216         res))
1217      result-type)))
1218
1219 ;;; Use a list of DECLARE forms to annotate the lists of LAMBDA-VAR
1220 ;;; and FUNCTIONAL structures which are being bound. In addition to
1221 ;;; filling in slots in the leaf structures, we return a new LEXENV,
1222 ;;; which reflects pervasive special and function type declarations,
1223 ;;; (NOT)INLINE declarations and OPTIMIZE declarations, and type of
1224 ;;; VALUES declarations.
1225 ;;;
1226 ;;; This is also called in main.lisp when PROCESS-FORM handles a use
1227 ;;; of LOCALLY.
1228 (defun process-decls (decls vars fvars &optional (env *lexenv*))
1229   (declare (list decls vars fvars))
1230   (let ((result-type *wild-type*))
1231     (dolist (decl decls)
1232       (dolist (spec (rest decl))
1233         (unless (consp spec)
1234           (compiler-error "malformed declaration specifier ~S in ~S" spec decl))
1235         (multiple-value-bind (new-env new-result-type)
1236             (process-1-decl spec env vars fvars)
1237           (setq env new-env)
1238           (unless (eq new-result-type *wild-type*)
1239             (setq result-type
1240                   (values-type-intersection result-type new-result-type))))))
1241     (values env result-type)))
1242
1243 (defun %processing-decls (decls vars fvars ctran lvar fun)
1244   (multiple-value-bind (*lexenv* result-type)
1245       (process-decls decls vars fvars)
1246     (cond ((eq result-type *wild-type*)
1247            (funcall fun ctran lvar))
1248           (t
1249            (let ((value-ctran (make-ctran))
1250                  (value-lvar (make-lvar)))
1251              (multiple-value-prog1
1252                  (funcall fun value-ctran value-lvar)
1253                (let ((cast (make-cast value-lvar result-type
1254                                       (lexenv-policy *lexenv*))))
1255                  (link-node-to-previous-ctran cast value-ctran)
1256                  (setf (lvar-dest value-lvar) cast)
1257                  (use-continuation cast ctran lvar))))))))
1258 (defmacro processing-decls ((decls vars fvars ctran lvar) &body forms)
1259   (check-type ctran symbol)
1260   (check-type lvar symbol)
1261   `(%processing-decls ,decls ,vars ,fvars ,ctran ,lvar
1262                       (lambda (,ctran ,lvar) ,@forms)))
1263
1264 ;;; Return the SPECVAR for NAME to use when we see a local SPECIAL
1265 ;;; declaration. If there is a global variable of that name, then
1266 ;;; check that it isn't a constant and return it. Otherwise, create an
1267 ;;; anonymous GLOBAL-VAR.
1268 (defun specvar-for-binding (name)
1269   (cond ((not (eq (info :variable :where-from name) :assumed))
1270          (let ((found (find-free-var name)))
1271            (when (heap-alien-info-p found)
1272              (compiler-error
1273               "~S is an alien variable and so can't be declared special."
1274               name))
1275            (unless (global-var-p found)
1276              (compiler-error
1277               "~S is a constant and so can't be declared special."
1278               name))
1279            found))
1280         (t
1281          (make-global-var :kind :special
1282                           :%source-name name
1283                           :where-from :declared))))