src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (defun principal-lvar-use (lvar)
  66   (let ((use (lvar-uses lvar)))
  67     (if (cast-p use)
  68         (principal-lvar-use (cast-value use))
  69         use)))
  70
  71 ;;; Update lvar use information so that NODE is no longer a use of its
  72 ;;; LVAR.
  73 ;;;
  74 ;;; Note: if you call this function, you may have to do a
  75 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  76 ;;; changed.
  77 (declaim (ftype (sfunction (node) (values))
  78                 delete-lvar-use
  79                 %delete-lvar-use))
  80 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  81 ;;; be given a new use.
  82 (defun %delete-lvar-use (node)
  83   (let ((lvar (node-lvar node)))
  84     (when lvar
  85       (if (listp (lvar-uses lvar))
  86           (let ((new-uses (delq node (lvar-uses lvar))))
  87             (setf (lvar-uses lvar)
  88                   (if (singleton-p new-uses)
  89                       (first new-uses)
  90                       new-uses)))
  91           (setf (lvar-uses lvar) nil))
  92       (setf (node-lvar node) nil)))
  93   (values))
  94 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
  95 ;;; its DEST's block, which must be unreachable.
  96 (defun delete-lvar-use (node)
  97   (let ((lvar (node-lvar node)))
  98     (when lvar
  99       (%delete-lvar-use node)
 100       (if (null (lvar-uses lvar))
 101           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 102                      (() (not (node-deleted dest)) :exit-if-null)
 103                      (block (node-block dest)))
 104             (mark-for-deletion block))
 105           (reoptimize-lvar lvar))))
 106   (values))
 107
 108 ;;; Update lvar use information so that NODE uses LVAR.
 109 ;;;
 110 ;;; Note: if you call this function, you may have to do a
 111 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 112 ;;; changed.
 113 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 114 (defun add-lvar-use (node lvar)
 115   (aver (not (node-lvar node)))
 116   (when lvar
 117     (let ((uses (lvar-uses lvar)))
 118       (setf (lvar-uses lvar)
 119             (cond ((null uses)
 120                    node)
 121                   ((listp uses)
 122                    (cons node uses))
 123                   (t
 124                    (list node uses))))
 125       (setf (node-lvar node) lvar)))
 126
 127   (values))
 128
 129 ;;; Return true if LVAR destination is executed immediately after
 130 ;;; NODE. Cleanups are ignored.
 131 (defun immediately-used-p (lvar node)
 132   (declare (type lvar lvar) (type node node))
 133   (aver (eq (node-lvar node) lvar))
 134   (let ((dest (lvar-dest lvar)))
 135     (acond ((node-next node)
 136             (eq (ctran-next it) dest))
 137            (t (eq (block-start (first (block-succ (node-block node))))
 138                   (node-prev dest))))))
 139 \f
 140 ;;;; lvar substitution
 141
 142 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 143 ;;; NIL. We do not flush OLD's DEST.
 144 (defun substitute-lvar (new old)
 145   (declare (type lvar old new))
 146   (aver (not (lvar-dest new)))
 147   (let ((dest (lvar-dest old)))
 148     (etypecase dest
 149       ((or ref bind))
 150       (cif (setf (if-test dest) new))
 151       (cset (setf (set-value dest) new))
 152       (creturn (setf (return-result dest) new))
 153       (exit (setf (exit-value dest) new))
 154       (basic-combination
 155        (if (eq old (basic-combination-fun dest))
 156            (setf (basic-combination-fun dest) new)
 157            (setf (basic-combination-args dest)
 158                  (nsubst new old (basic-combination-args dest)))))
 159       (cast (setf (cast-value dest) new)))
 160
 161     (setf (lvar-dest old) nil)
 162     (setf (lvar-dest new) dest)
 163     (flush-lvar-externally-checkable-type new))
 164   (values))
 165
 166 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 167 ;;; arbitary number of uses.
 168 (defun substitute-lvar-uses (new old)
 169   (declare (type lvar old)
 170            (type (or lvar null) new))
 171
 172   (cond (new (do-uses (node old)
 173                (%delete-lvar-use node)
 174                (add-lvar-use node new))
 175              (reoptimize-lvar new))
 176         (t (flush-dest old)))
 177   (values))
 178 \f
 179 ;;;; block starting/creation
 180
 181 ;;; Return the block that CTRAN is the start of, making a block if
 182 ;;; necessary. This function is called by IR1 translators which may
 183 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 184 ;;; used more than once must start a block by the time that anyone
 185 ;;; does a USE-CTRAN on it.
 186 ;;;
 187 ;;; We also throw the block into the next/prev list for the
 188 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 189 ;;; made.
 190 (defun ctran-starts-block (ctran)
 191   (declare (type ctran ctran))
 192   (ecase (ctran-kind ctran)
 193     (:unused
 194      (aver (not (ctran-block ctran)))
 195      (let* ((next (component-last-block *current-component*))
 196             (prev (block-prev next))
 197             (new-block (make-block ctran)))
 198        (setf (block-next new-block) next
 199              (block-prev new-block) prev
 200              (block-prev next) new-block
 201              (block-next prev) new-block
 202              (ctran-block ctran) new-block
 203              (ctran-kind ctran) :block-start)
 204        (aver (not (ctran-use ctran)))
 205        new-block))
 206     (:block-start
 207      (ctran-block ctran))))
 208
 209 ;;; Ensure that CTRAN is the start of a block so that the use set can
 210 ;;; be freely manipulated.
 211 (defun ensure-block-start (ctran)
 212   (declare (type ctran ctran))
 213   (let ((kind (ctran-kind ctran)))
 214     (ecase kind
 215       ((:block-start))
 216       ((:unused)
 217        (setf (ctran-block ctran)
 218              (make-block-key :start ctran))
 219        (setf (ctran-kind ctran) :block-start))
 220       ((:inside-block)
 221        (node-ends-block (ctran-use ctran)))))
 222   (values))
 223
 224 ;;; CTRAN must be the last ctran in an incomplete block; finish the
 225 ;;; block and start a new one if necessary.
 226 (defun start-block (ctran)
 227   (declare (type ctran ctran))
 228   (aver (not (ctran-next ctran)))
 229   (ecase (ctran-kind ctran)
 230     (:inside-block
 231      (let ((block (ctran-block ctran))
 232            (node (ctran-use ctran)))
 233        (aver (not (block-last block)))
 234        (aver node)
 235        (setf (block-last block) node)
 236        (setf (node-next node) nil)
 237        (setf (ctran-use ctran) nil)
 238        (setf (ctran-kind ctran) :unused)
 239        (setf (ctran-block ctran) nil)
 240        (link-blocks block (ctran-starts-block ctran))))
 241     (:block-start)))
 242 \f
 243 ;;;;
 244
 245 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 246 ;;; call. First argument must be 'DUMMY, which will be replaced with
 247 ;;; LVAR. In case of an ordinary call the function should not have
 248 ;;; return type NIL. We create a new "filtered" lvar.
 249 ;;;
 250 ;;; TODO: remove preconditions.
 251 (defun filter-lvar (lvar form)
 252   (declare (type lvar lvar) (type list form))
 253   (let* ((dest (lvar-dest lvar))
 254          (ctran (node-prev dest)))
 255     (with-ir1-environment-from-node dest
 256
 257       (ensure-block-start ctran)
 258       (let* ((old-block (ctran-block ctran))
 259              (new-start (make-ctran))
 260              (filtered-lvar (make-lvar))
 261              (new-block (ctran-starts-block new-start)))
 262
 263         ;; Splice in the new block before DEST, giving the new block
 264         ;; all of DEST's predecessors.
 265         (dolist (block (block-pred old-block))
 266           (change-block-successor block old-block new-block))
 267
 268         (ir1-convert new-start ctran filtered-lvar form)
 269
 270         ;; KLUDGE: Comments at the head of this function in CMU CL
 271         ;; said that somewhere in here we
 272         ;;   Set the new block's start and end cleanups to the *start*
 273         ;;   cleanup of PREV's block. This overrides the incorrect
 274         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 275         ;; Unfortunately I can't find any code which corresponds to this.
 276         ;; Perhaps it was a stale comment? Or perhaps I just don't
 277         ;; understand.. -- WHN 19990521
 278
 279         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 280         ;; no LET conversion has been done yet.) The [mv-]combination
 281         ;; code from the call in the form will be the use of the new
 282         ;; check lvar. We substitute for the first argument of
 283         ;; this node.
 284         (let* ((node (lvar-use filtered-lvar))
 285                (args (basic-combination-args node))
 286                (victim (first args)))
 287           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 288                     'dummy))
 289
 290           (substitute-lvar filtered-lvar lvar)
 291           (substitute-lvar lvar victim)
 292           (flush-dest victim))
 293
 294         ;; Invoking local call analysis converts this call to a LET.
 295         (locall-analyze-component *current-component*))))
 296   (values))
 297
 298 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 299 (defun delete-filter (node lvar value)
 300   (aver (eq (lvar-dest value) node))
 301   (aver (eq (node-lvar node) lvar))
 302   (cond (lvar (collect ((merges))
 303                 (when (return-p (lvar-dest lvar))
 304                   (do-uses (use value)
 305                     (when (and (basic-combination-p use)
 306                                (eq (basic-combination-kind use) :local))
 307                       (merges use))))
 308                 (%delete-lvar-use node)
 309                 (substitute-lvar-uses lvar value)
 310                 (prog1
 311                     (unlink-node node)
 312                   (dolist (merge (merges))
 313                     (merge-tail-sets merge)))))
 314         (t (flush-dest value)
 315            (unlink-node node))))
 316 \f
 317 ;;;; miscellaneous shorthand functions
 318
 319 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 320 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 321 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 322 ;;; deleted, and then return its home.
 323 (defun node-home-lambda (node)
 324   (declare (type node node))
 325   (do ((fun (lexenv-lambda (node-lexenv node))
 326             (lexenv-lambda (lambda-call-lexenv fun))))
 327       ((not (memq (functional-kind fun) '(:deleted :zombie)))
 328        (lambda-home fun))
 329     (when (eq (lambda-home fun) fun)
 330       (return fun))))
 331
 332 #!-sb-fluid (declaim (inline node-block))
 333 (defun node-block (node)
 334   (ctran-block (node-prev node)))
 335 (declaim (ftype (sfunction (node) component) node-component))
 336 (defun node-component (node)
 337   (block-component (node-block node)))
 338 (declaim (ftype (sfunction (node) physenv) node-physenv))
 339 (defun node-physenv (node)
 340   (lambda-physenv (node-home-lambda node)))
 341 #!-sb-fluid (declaim (inline node-dest))
 342 (defun node-dest (node)
 343   (awhen (node-lvar node) (lvar-dest it)))
 344
 345 (declaim (inline block-to-be-deleted-p))
 346 (defun block-to-be-deleted-p (block)
 347   (or (block-delete-p block)
 348       (eq (functional-kind (block-home-lambda block)) :deleted)))
 349
 350 ;;; Checks whether NODE is in a block to be deleted
 351 (declaim (inline node-to-be-deleted-p))
 352 (defun node-to-be-deleted-p (node)
 353   (block-to-be-deleted-p (node-block node)))
 354
 355 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 356 (defun lambda-block (clambda)
 357   (node-block (lambda-bind clambda)))
 358 (declaim (ftype (sfunction (clambda) component) lambda-component))
 359 (defun lambda-component (clambda)
 360   (block-component (lambda-block clambda)))
 361
 362 (declaim (ftype (sfunction (cblock) node) block-start-node))
 363 (defun block-start-node (block)
 364   (ctran-next (block-start block)))
 365
 366 ;;; Return the enclosing cleanup for environment of the first or last
 367 ;;; node in BLOCK.
 368 (defun block-start-cleanup (block)
 369   (node-enclosing-cleanup (block-start-node block)))
 370 (defun block-end-cleanup (block)
 371   (node-enclosing-cleanup (block-last block)))
 372
 373 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 374 ;;; if there is none.
 375 ;;;
 376 ;;; There can legitimately be no home lambda in dead code early in the
 377 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 378 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 379 ;;; where the block is just a placeholder during parsing and doesn't
 380 ;;; actually correspond to code which will be written anywhere.
 381 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 382 (defun block-home-lambda-or-null (block)
 383   (if (node-p (block-last block))
 384       ;; This is the old CMU CL way of doing it.
 385       (node-home-lambda (block-last block))
 386       ;; Now that SBCL uses this operation more aggressively than CMU
 387       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 388       ;;   1. It can fail in a few cases even when a meaningful home
 389       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 390       ;;      an IF.
 391       ;;   2. It can fail when converting a form which is born orphaned
 392       ;;      so that it never had a meaningful home lambda, e.g. a form
 393       ;;      which follows a RETURN-FROM or GO form.
 394       (let ((pred-list (block-pred block)))
 395         ;; To deal with case 1, we reason that
 396         ;; previous-in-target-execution-order blocks should be in the
 397         ;; same lambda, and that they seem in practice to be
 398         ;; previous-in-compilation-order blocks too, so we look back
 399         ;; to find one which is sufficiently initialized to tell us
 400         ;; what the home lambda is.
 401         (if pred-list
 402             ;; We could get fancy about this, flooding through the
 403             ;; graph of all the previous blocks, but in practice it
 404             ;; seems to work just to grab the first previous block and
 405             ;; use it.
 406             (node-home-lambda (block-last (first pred-list)))
 407             ;; In case 2, we end up with an empty PRED-LIST and
 408             ;; have to punt: There's no home lambda.
 409             nil))))
 410
 411 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 412 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 413 (defun block-home-lambda (block)
 414   (block-home-lambda-or-null block))
 415
 416 ;;; Return the IR1 physical environment for BLOCK.
 417 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 418 (defun block-physenv (block)
 419   (lambda-physenv (block-home-lambda block)))
 420
 421 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 422 ;;; of its original source's top level form in its compilation unit.
 423 (defun source-path-tlf-number (path)
 424   (declare (list path))
 425   (car (last path)))
 426
 427 ;;; Return the (reversed) list for the PATH in the original source
 428 ;;; (with the Top Level Form number last).
 429 (defun source-path-original-source (path)
 430   (declare (list path) (inline member))
 431   (cddr (member 'original-source-start path :test #'eq)))
 432
 433 ;;; Return the Form Number of PATH's original source inside the Top
 434 ;;; Level Form that contains it. This is determined by the order that
 435 ;;; we walk the subforms of the top level source form.
 436 (defun source-path-form-number (path)
 437   (declare (list path) (inline member))
 438   (cadr (member 'original-source-start path :test #'eq)))
 439
 440 ;;; Return a list of all the enclosing forms not in the original
 441 ;;; source that converted to get to this form, with the immediate
 442 ;;; source for node at the start of the list.
 443 (defun source-path-forms (path)
 444   (subseq path 0 (position 'original-source-start path)))
 445
 446 ;;; Return the innermost source form for NODE.
 447 (defun node-source-form (node)
 448   (declare (type node node))
 449   (let* ((path (node-source-path node))
 450          (forms (source-path-forms path)))
 451     (if forms
 452         (first forms)
 453         (values (find-original-source path)))))
 454
 455 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 456 ;;; NIL, NIL.
 457 (defun lvar-source (lvar)
 458   (let ((use (lvar-uses lvar)))
 459     (if (listp use)
 460         (values nil nil)
 461         (values (node-source-form use) t))))
 462
 463 ;;; Return the unique node, delivering a value to LVAR.
 464 #!-sb-fluid (declaim (inline lvar-use))
 465 (defun lvar-use (lvar)
 466   (the (not list) (lvar-uses lvar)))
 467
 468 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 469 (defun lvar-has-single-use-p (lvar)
 470   (typep (lvar-uses lvar) '(not list)))
 471
 472 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 473 (declaim (ftype (sfunction (ctran) (or clambda null))
 474                 ctran-home-lambda-or-null))
 475 (defun ctran-home-lambda-or-null (ctran)
 476   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 477   ;; implementation might not be quite right, or might be uglier than
 478   ;; necessary. It appears that the original Python never found a need
 479   ;; to do this operation. The obvious things based on
 480   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 481   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 482   ;; generalize it enough to grovel harder when the simple CMU CL
 483   ;; approach fails, and furthermore realize that in some exceptional
 484   ;; cases it might return NIL. -- WHN 2001-12-04
 485   (cond ((ctran-use ctran)
 486          (node-home-lambda (ctran-use ctran)))
 487         ((ctran-block ctran)
 488          (block-home-lambda-or-null (ctran-block ctran)))
 489         (t
 490          (bug "confused about home lambda for ~S" ctran))))
 491
 492 ;;; Return the LAMBDA that is CTRAN's home.
 493 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 494 (defun ctran-home-lambda (ctran)
 495   (ctran-home-lambda-or-null ctran))
 496
 497 (declaim (inline cast-single-value-p))
 498 (defun cast-single-value-p (cast)
 499   (not (values-type-p (cast-asserted-type cast))))
 500
 501 #!-sb-fluid (declaim (inline lvar-single-value-p))
 502 (defun lvar-single-value-p (lvar)
 503   (or (not lvar)
 504       (let ((dest (lvar-dest lvar)))
 505         (typecase dest
 506           ((or creturn exit)
 507            nil)
 508           (mv-combination
 509            (eq (basic-combination-fun dest) lvar))
 510           (cast
 511            (locally
 512                (declare (notinline lvar-single-value-p))
 513              (and (cast-single-value-p dest)
 514                   (lvar-single-value-p (node-lvar dest)))))
 515           (t
 516            t)))))
 517
 518 (defun principal-lvar-end (lvar)
 519   (loop for prev = lvar then (node-lvar dest)
 520         for dest = (and prev (lvar-dest prev))
 521         while (cast-p dest)
 522         finally (return (values dest prev))))
 523
 524 (defun principal-lvar-single-valuify (lvar)
 525   (loop for prev = lvar then (node-lvar dest)
 526         for dest = (and prev (lvar-dest prev))
 527         while (cast-p dest)
 528         do (setf (node-derived-type dest)
 529                  (make-short-values-type (list (single-value-type
 530                                                 (node-derived-type dest)))))
 531         (reoptimize-lvar prev)))
 532 \f
 533 ;;; Return a new LEXENV just like DEFAULT except for the specified
 534 ;;; slot values. Values for the alist slots are NCONCed to the
 535 ;;; beginning of the current value, rather than replacing it entirely.
 536 (defun make-lexenv (&key (default *lexenv*)
 537                          funs vars blocks tags
 538                          type-restrictions
 539                          (lambda (lexenv-lambda default))
 540                          (cleanup (lexenv-cleanup default))
 541                          (handled-conditions (lexenv-handled-conditions default))
 542                          (policy (lexenv-policy default)))
 543   (macrolet ((frob (var slot)
 544                `(let ((old (,slot default)))
 545                   (if ,var
 546                       (nconc ,var old)
 547                       old))))
 548     (internal-make-lexenv
 549      (frob funs lexenv-funs)
 550      (frob vars lexenv-vars)
 551      (frob blocks lexenv-blocks)
 552      (frob tags lexenv-tags)
 553      (frob type-restrictions lexenv-type-restrictions)
 554      lambda cleanup handled-conditions policy)))
 555
 556 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 557 ;;; macroexpander
 558 (defun make-restricted-lexenv (lexenv)
 559   (flet ((fun-good-p (fun)
 560            (destructuring-bind (name . thing) fun
 561              (declare (ignore name))
 562              (etypecase thing
 563                (functional nil)
 564                (global-var t)
 565                (cons (aver (eq (car thing) 'macro))
 566                      t))))
 567          (var-good-p (var)
 568            (destructuring-bind (name . thing) var
 569              (declare (ignore name))
 570              (etypecase thing
 571                (leaf nil)
 572                (cons (aver (eq (car thing) 'macro))
 573                      t)
 574                (heap-alien-info nil)))))
 575     (internal-make-lexenv
 576      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 577      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 578      nil
 579      nil
 580      (lexenv-type-restrictions lexenv) ; XXX
 581      nil
 582      nil
 583      (lexenv-handled-conditions lexenv)
 584      (lexenv-policy lexenv))))
 585 \f
 586 ;;;; flow/DFO/component hackery
 587
 588 ;;; Join BLOCK1 and BLOCK2.
 589 (defun link-blocks (block1 block2)
 590   (declare (type cblock block1 block2))
 591   (setf (block-succ block1)
 592         (if (block-succ block1)
 593             (%link-blocks block1 block2)
 594             (list block2)))
 595   (push block1 (block-pred block2))
 596   (values))
 597 (defun %link-blocks (block1 block2)
 598   (declare (type cblock block1 block2))
 599   (let ((succ1 (block-succ block1)))
 600     (aver (not (memq block2 succ1)))
 601     (cons block2 succ1)))
 602
 603 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 604 ;;; this leaves a successor with a single predecessor that ends in an
 605 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 606 ;;; now be able to be propagated to the successor.
 607 (defun unlink-blocks (block1 block2)
 608   (declare (type cblock block1 block2))
 609   (let ((succ1 (block-succ block1)))
 610     (if (eq block2 (car succ1))
 611         (setf (block-succ block1) (cdr succ1))
 612         (do ((succ (cdr succ1) (cdr succ))
 613              (prev succ1 succ))
 614             ((eq (car succ) block2)
 615              (setf (cdr prev) (cdr succ)))
 616           (aver succ))))
 617
 618   (let ((new-pred (delq block1 (block-pred block2))))
 619     (setf (block-pred block2) new-pred)
 620     (when (singleton-p new-pred)
 621       (let ((pred-block (first new-pred)))
 622         (when (if-p (block-last pred-block))
 623           (setf (block-test-modified pred-block) t)))))
 624   (values))
 625
 626 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 627 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 628 ;;; consequent/alternative blocks to point to NEW. We also set
 629 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 630 ;;; the new successor.
 631 (defun change-block-successor (block old new)
 632   (declare (type cblock new old block))
 633   (unlink-blocks block old)
 634   (let ((last (block-last block))
 635         (comp (block-component block)))
 636     (setf (component-reanalyze comp) t)
 637     (typecase last
 638       (cif
 639        (setf (block-test-modified block) t)
 640        (let* ((succ-left (block-succ block))
 641               (new (if (and (eq new (component-tail comp))
 642                             succ-left)
 643                        (first succ-left)
 644                        new)))
 645          (unless (memq new succ-left)
 646            (link-blocks block new))
 647          (macrolet ((frob (slot)
 648                       `(when (eq (,slot last) old)
 649                          (setf (,slot last) new))))
 650            (frob if-consequent)
 651            (frob if-alternative)
 652            (when (eq (if-consequent last)
 653                      (if-alternative last))
 654              (setf (component-reoptimize (block-component block)) t)))))
 655       (t
 656        (unless (memq new (block-succ block))
 657          (link-blocks block new)))))
 658
 659   (values))
 660
 661 ;;; Unlink a block from the next/prev chain. We also null out the
 662 ;;; COMPONENT.
 663 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 664 (defun remove-from-dfo (block)
 665   (let ((next (block-next block))
 666         (prev (block-prev block)))
 667     (setf (block-component block) nil)
 668     (setf (block-next prev) next)
 669     (setf (block-prev next) prev))
 670   (values))
 671
 672 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 673 ;;; COMPONENT to be the same as for AFTER.
 674 (defun add-to-dfo (block after)
 675   (declare (type cblock block after))
 676   (let ((next (block-next after))
 677         (comp (block-component after)))
 678     (aver (not (eq (component-kind comp) :deleted)))
 679     (setf (block-component block) comp)
 680     (setf (block-next after) block)
 681     (setf (block-prev block) after)
 682     (setf (block-next block) next)
 683     (setf (block-prev next) block))
 684   (values))
 685
 686 ;;; List all NLX-INFOs which BLOCK can exit to.
 687 ;;;
 688 ;;; We hope that no cleanup actions are performed in the middle of
 689 ;;; BLOCK, so it is enough to look only at cleanups in the block
 690 ;;; end. The tricky thing is a special cleanup block; all its nodes
 691 ;;; have the same cleanup info, corresponding to the start, so the
 692 ;;; same approach returns safe result.
 693 (defun map-block-nlxes (fun block)
 694   (loop for cleanup = (block-end-cleanup block)
 695         then (node-enclosing-cleanup (cleanup-mess-up cleanup))
 696         while cleanup
 697         do (let ((mess-up (cleanup-mess-up cleanup)))
 698              (case (cleanup-kind cleanup)
 699                ((:block :tagbody)
 700                 (aver (entry-p mess-up))
 701                 (loop for exit in (entry-exits mess-up)
 702                       for nlx-info = (find-nlx-info exit)
 703                       do (funcall fun nlx-info)))
 704                ((:catch :unwind-protect)
 705                 (aver (combination-p mess-up))
 706                 (let* ((arg-lvar (first (basic-combination-args mess-up)))
 707                        (nlx-info (constant-value (ref-leaf (lvar-use arg-lvar)))))
 708                 (funcall fun nlx-info)))))))
 709
 710 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 711 ;;; the head and tail which are set to T.
 712 (declaim (ftype (sfunction (component) (values)) clear-flags))
 713 (defun clear-flags (component)
 714   (let ((head (component-head component))
 715         (tail (component-tail component)))
 716     (setf (block-flag head) t)
 717     (setf (block-flag tail) t)
 718     (do-blocks (block component)
 719       (setf (block-flag block) nil)))
 720   (values))
 721
 722 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 723 ;;; true in the head and tail blocks.
 724 (declaim (ftype (sfunction () component) make-empty-component))
 725 (defun make-empty-component ()
 726   (let* ((head (make-block-key :start nil :component nil))
 727          (tail (make-block-key :start nil :component nil))
 728          (res (make-component head tail)))
 729     (setf (block-flag head) t)
 730     (setf (block-flag tail) t)
 731     (setf (block-component head) res)
 732     (setf (block-component tail) res)
 733     (setf (block-next head) tail)
 734     (setf (block-prev tail) head)
 735     res))
 736
 737 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 738 ;;; The new block is added to the DFO immediately following NODE's block.
 739 (defun node-ends-block (node)
 740   (declare (type node node))
 741   (let* ((block (node-block node))
 742          (start (node-next node))
 743          (last (block-last block)))
 744     (unless (eq last node)
 745       (aver (and (eq (ctran-kind start) :inside-block)
 746                  (not (block-delete-p block))))
 747       (let* ((succ (block-succ block))
 748              (new-block
 749               (make-block-key :start start
 750                               :component (block-component block)
 751                               :succ succ :last last)))
 752         (setf (ctran-kind start) :block-start)
 753         (setf (ctran-use start) nil)
 754         (setf (block-last block) node)
 755         (setf (node-next node) nil)
 756         (dolist (b succ)
 757           (setf (block-pred b)
 758                 (cons new-block (remove block (block-pred b)))))
 759         (setf (block-succ block) ())
 760         (link-blocks block new-block)
 761         (add-to-dfo new-block block)
 762         (setf (component-reanalyze (block-component block)) t)
 763
 764         (do ((ctran start (node-next (ctran-next ctran))))
 765             ((not ctran))
 766           (setf (ctran-block ctran) new-block))
 767
 768         (setf (block-type-asserted block) t)
 769         (setf (block-test-modified block) t))))
 770   (values))
 771 \f
 772 ;;;; deleting stuff
 773
 774 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 775 (defun delete-lambda-var (leaf)
 776   (declare (type lambda-var leaf))
 777
 778   ;; Iterate over all local calls flushing the corresponding argument,
 779   ;; allowing the computation of the argument to be deleted. We also
 780   ;; mark the LET for reoptimization, since it may be that we have
 781   ;; deleted its last variable.
 782   (let* ((fun (lambda-var-home leaf))
 783          (n (position leaf (lambda-vars fun))))
 784     (dolist (ref (leaf-refs fun))
 785       (let* ((lvar (node-lvar ref))
 786              (dest (and lvar (lvar-dest lvar))))
 787         (when (and (combination-p dest)
 788                    (eq (basic-combination-fun dest) lvar)
 789                    (eq (basic-combination-kind dest) :local))
 790           (let* ((args (basic-combination-args dest))
 791                  (arg (elt args n)))
 792             (reoptimize-lvar arg)
 793             (flush-dest arg)
 794             (setf (elt args n) nil))))))
 795
 796   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 797   ;; too much difficulty, since we can efficiently implement
 798   ;; write-only variables. We iterate over the SETs, marking their
 799   ;; blocks for dead code flushing, since we can delete SETs whose
 800   ;; value is unused.
 801   (dolist (set (lambda-var-sets leaf))
 802     (setf (block-flush-p (node-block set)) t))
 803
 804   (values))
 805
 806 ;;; Note that something interesting has happened to VAR.
 807 (defun reoptimize-lambda-var (var)
 808   (declare (type lambda-var var))
 809   (let ((fun (lambda-var-home var)))
 810     ;; We only deal with LET variables, marking the corresponding
 811     ;; initial value arg as needing to be reoptimized.
 812     (when (and (eq (functional-kind fun) :let)
 813                (leaf-refs var))
 814       (do ((args (basic-combination-args
 815                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 816                  (cdr args))
 817            (vars (lambda-vars fun) (cdr vars)))
 818           ((eq (car vars) var)
 819            (reoptimize-lvar (car args))))))
 820   (values))
 821
 822 ;;; Delete a function that has no references. This need only be called
 823 ;;; on functions that never had any references, since otherwise
 824 ;;; DELETE-REF will handle the deletion.
 825 (defun delete-functional (fun)
 826   (aver (and (null (leaf-refs fun))
 827              (not (functional-entry-fun fun))))
 828   (etypecase fun
 829     (optional-dispatch (delete-optional-dispatch fun))
 830     (clambda (delete-lambda fun)))
 831   (values))
 832
 833 ;;; Deal with deleting the last reference to a CLAMBDA, which means
 834 ;;; that the lambda is unreachable, so that its body may be
 835 ;;; deleted. We set FUNCTIONAL-KIND to :DELETED and rely on
 836 ;;; IR1-OPTIMIZE to delete its blocks.
 837 (defun delete-lambda (clambda)
 838   (declare (type clambda clambda))
 839   (let ((original-kind (functional-kind clambda))
 840         (bind (lambda-bind clambda)))
 841     (aver (not (member original-kind '(:deleted :toplevel))))
 842     (aver (not (functional-has-external-references-p clambda)))
 843     (aver (or (eq original-kind :zombie) bind))
 844     (setf (functional-kind clambda) :deleted)
 845     (setf (lambda-bind clambda) nil)
 846
 847     (labels ((delete-children (lambda)
 848                (dolist (child (lambda-children lambda))
 849                  (cond ((eq (functional-kind child) :deleted)
 850                         (delete-children child))
 851                        (t
 852                         (delete-lambda child))))
 853                (setf (lambda-children lambda) nil)
 854                (setf (lambda-parent lambda) nil)))
 855       (delete-children clambda))
 856
 857     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 858     ;; that we're using the old value of the KIND slot, not the
 859     ;; current slot value, which has now been set to :DELETED.)
 860     (case original-kind
 861       (:zombie)
 862       ((:let :mv-let :assignment)
 863        (let ((bind-block (node-block bind)))
 864          (mark-for-deletion bind-block))
 865        (let ((home (lambda-home clambda)))
 866          (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 867        ;; KLUDGE: In presence of NLEs we cannot always understand that
 868        ;; LET's BIND dominates its body [for a LET "its" body is not
 869        ;; quite its]; let's delete too dangerous for IR2 stuff. --
 870        ;; APD, 2004-01-01
 871        (dolist (var (lambda-vars clambda))
 872          (flet ((delete-node (node)
 873                   (mark-for-deletion (node-block node))))
 874          (mapc #'delete-node (leaf-refs var))
 875          (mapc #'delete-node (lambda-var-sets var)))))
 876       (t
 877        ;; Function has no reachable references.
 878        (dolist (ref (lambda-refs clambda))
 879          (mark-for-deletion (node-block ref)))
 880        ;; If the function isn't a LET, we unlink the function head
 881        ;; and tail from the component head and tail to indicate that
 882        ;; the code is unreachable. We also delete the function from
 883        ;; COMPONENT-LAMBDAS (it won't be there before local call
 884        ;; analysis, but no matter.) If the lambda was never
 885        ;; referenced, we give a note.
 886        (let* ((bind-block (node-block bind))
 887               (component (block-component bind-block))
 888               (return (lambda-return clambda))
 889               (return-block (and return (node-block return))))
 890          (unless (leaf-ever-used clambda)
 891            (let ((*compiler-error-context* bind))
 892              (compiler-notify 'code-deletion-note
 893                               :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 894                               :format-arguments (list (leaf-debug-name clambda)))))
 895          (unless (block-delete-p bind-block)
 896            (unlink-blocks (component-head component) bind-block))
 897          (when (and return-block (not (block-delete-p return-block)))
 898            (mark-for-deletion return-block)
 899            (unlink-blocks return-block (component-tail component)))
 900          (setf (component-reanalyze component) t)
 901          (let ((tails (lambda-tail-set clambda)))
 902            (setf (tail-set-funs tails)
 903                  (delete clambda (tail-set-funs tails)))
 904            (setf (lambda-tail-set clambda) nil))
 905          (setf (component-lambdas component)
 906                (delq clambda (component-lambdas component))))))
 907
 908     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 909     ;; ENTRY-FUN so that people will know that it is not an entry
 910     ;; point anymore.
 911     (when (eq original-kind :external)
 912       (let ((fun (functional-entry-fun clambda)))
 913         (setf (functional-entry-fun fun) nil)
 914         (when (optional-dispatch-p fun)
 915           (delete-optional-dispatch fun)))))
 916
 917   (values))
 918
 919 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 920 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 921 ;;; is used both before and after local call analysis. Afterward, all
 922 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 923 ;;; to the XEP, leaving it with no references at all. So we look at
 924 ;;; the XEP to see whether an optional-dispatch is still really being
 925 ;;; used. But before local call analysis, there are no XEPs, and all
 926 ;;; references are direct.
 927 ;;;
 928 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 929 ;;; entry-points, making them be normal lambdas, and then deleting the
 930 ;;; ones with no references. This deletes any e-p lambdas that were
 931 ;;; either never referenced, or couldn't be deleted when the last
 932 ;;; reference was deleted (due to their :OPTIONAL kind.)
 933 ;;;
 934 ;;; Note that the last optional entry point may alias the main entry,
 935 ;;; so when we process the main entry, its KIND may have been changed
 936 ;;; to NIL or even converted to a LETlike value.
 937 (defun delete-optional-dispatch (leaf)
 938   (declare (type optional-dispatch leaf))
 939   (let ((entry (functional-entry-fun leaf)))
 940     (unless (and entry (leaf-refs entry))
 941       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 942       (setf (functional-kind leaf) :deleted)
 943
 944       (flet ((frob (fun)
 945                (unless (eq (functional-kind fun) :deleted)
 946                  (aver (eq (functional-kind fun) :optional))
 947                  (setf (functional-kind fun) nil)
 948                  (let ((refs (leaf-refs fun)))
 949                    (cond ((null refs)
 950                           (delete-lambda fun))
 951                          ((null (rest refs))
 952                           (or (maybe-let-convert fun)
 953                               (maybe-convert-to-assignment fun)))
 954                          (t
 955                           (maybe-convert-to-assignment fun)))))))
 956
 957         (dolist (ep (optional-dispatch-entry-points leaf))
 958           (when (promise-ready-p ep)
 959             (frob (force ep))))
 960         (when (optional-dispatch-more-entry leaf)
 961           (frob (optional-dispatch-more-entry leaf)))
 962         (let ((main (optional-dispatch-main-entry leaf)))
 963           (when (eq (functional-kind main) :optional)
 964             (frob main))))))
 965
 966   (values))
 967
 968 ;;; Do stuff to delete the semantic attachments of a REF node. When
 969 ;;; this leaves zero or one reference, we do a type dispatch off of
 970 ;;; the leaf to determine if a special action is appropriate.
 971 (defun delete-ref (ref)
 972   (declare (type ref ref))
 973   (let* ((leaf (ref-leaf ref))
 974          (refs (delq ref (leaf-refs leaf))))
 975     (setf (leaf-refs leaf) refs)
 976
 977     (cond ((null refs)
 978            (typecase leaf
 979              (lambda-var
 980               (delete-lambda-var leaf))
 981              (clambda
 982               (ecase (functional-kind leaf)
 983                 ((nil :let :mv-let :assignment :escape :cleanup)
 984                  (aver (null (functional-entry-fun leaf)))
 985                  (delete-lambda leaf))
 986                 (:external
 987                  (delete-lambda leaf))
 988                 ((:deleted :zombie :optional))))
 989              (optional-dispatch
 990               (unless (eq (functional-kind leaf) :deleted)
 991                 (delete-optional-dispatch leaf)))))
 992           ((null (rest refs))
 993            (typecase leaf
 994              (clambda (or (maybe-let-convert leaf)
 995                           (maybe-convert-to-assignment leaf)))
 996              (lambda-var (reoptimize-lambda-var leaf))))
 997           (t
 998            (typecase leaf
 999              (clambda (maybe-convert-to-assignment leaf))))))
1000
1001   (values))
1002
1003 ;;; This function is called by people who delete nodes; it provides a
1004 ;;; way to indicate that the value of a lvar is no longer used. We
1005 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
1006 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
1007 (defun flush-dest (lvar)
1008   (declare (type (or lvar null) lvar))
1009   (unless (null lvar)
1010     (setf (lvar-dest lvar) nil)
1011     (flush-lvar-externally-checkable-type lvar)
1012     (do-uses (use lvar)
1013       (let ((prev (node-prev use)))
1014         (let ((block (ctran-block prev)))
1015           (setf (component-reoptimize (block-component block)) t)
1016           (setf (block-attributep (block-flags block)
1017                                   flush-p type-asserted type-check)
1018                 t)))
1019       (setf (node-lvar use) nil))
1020     (setf (lvar-uses lvar) nil))
1021   (values))
1022
1023 (defun delete-dest (lvar)
1024   (when lvar
1025     (let* ((dest (lvar-dest lvar))
1026            (prev (node-prev dest)))
1027       (let ((block (ctran-block prev)))
1028         (unless (block-delete-p block)
1029           (mark-for-deletion block))))))
1030
1031 ;;; Queue the block for deletion
1032 (defun delete-block-lazily (block)
1033   (declare (type cblock block))
1034   (unless (block-delete-p block)
1035     (setf (block-delete-p block) t)
1036     (push block (component-delete-blocks (block-component block)))))
1037
1038 ;;; Do a graph walk backward from BLOCK, marking all predecessor
1039 ;;; blocks with the DELETE-P flag.
1040 (defun mark-for-deletion (block)
1041   (declare (type cblock block))
1042   (let* ((component (block-component block))
1043          (head (component-head component)))
1044     (labels ((helper (block)
1045                (delete-block-lazily block)
1046                (dolist (pred (block-pred block))
1047                  (unless (or (block-delete-p pred)
1048                              (eq pred head))
1049                    (helper pred)))))
1050       (unless (block-delete-p block)
1051         (helper block)
1052         (setf (component-reanalyze component) t))))
1053   (values))
1054
1055 ;;; This function does what is necessary to eliminate the code in it
1056 ;;; from the IR1 representation. This involves unlinking it from its
1057 ;;; predecessors and successors and deleting various node-specific
1058 ;;; semantic information. BLOCK must be already removed from
1059 ;;; COMPONENT-DELETE-BLOCKS.
1060 (defun delete-block (block &optional silent)
1061   (declare (type cblock block))
1062   (aver (block-component block))      ; else block is already deleted!
1063   #!+high-security (aver (not (memq block (component-delete-blocks (block-component block)))))
1064   (unless silent
1065     (note-block-deletion block))
1066   (setf (block-delete-p block) t)
1067
1068   (dolist (b (block-pred block))
1069     (unlink-blocks b block)
1070     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
1071     ;; broken when successors were deleted without setting the
1072     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
1073     ;; doesn't happen again.
1074     (aver (not (and (null (block-succ b))
1075                     (not (block-delete-p b))
1076                     (not (eq b (component-head (block-component b))))))))
1077   (dolist (b (block-succ block))
1078     (unlink-blocks block b))
1079
1080   (do-nodes-carefully (node block)
1081     (when (valued-node-p node)
1082       (delete-lvar-use node))
1083     (etypecase node
1084       (ref (delete-ref node))
1085       (cif (flush-dest (if-test node)))
1086       ;; The next two cases serve to maintain the invariant that a LET
1087       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1088       ;; the lambda whenever we delete any of these, but we must be
1089       ;; careful that this LET has not already been partially deleted.
1090       (basic-combination
1091        (when (and (eq (basic-combination-kind node) :local)
1092                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1093                   (lvar-uses (basic-combination-fun node)))
1094          (let ((fun (combination-lambda node)))
1095            ;; If our REF was the second-to-last ref, and has been
1096            ;; deleted, then FUN may be a LET for some other
1097            ;; combination.
1098            (when (and (functional-letlike-p fun)
1099                       (eq (let-combination fun) node))
1100              (delete-lambda fun))))
1101        (flush-dest (basic-combination-fun node))
1102        (dolist (arg (basic-combination-args node))
1103          (when arg (flush-dest arg))))
1104       (bind
1105        (let ((lambda (bind-lambda node)))
1106          (unless (eq (functional-kind lambda) :deleted)
1107            (delete-lambda lambda))))
1108       (exit
1109        (let ((value (exit-value node))
1110              (entry (exit-entry node)))
1111          (when value
1112            (flush-dest value))
1113          (when entry
1114            (setf (entry-exits entry)
1115                  (delq node (entry-exits entry))))))
1116       (entry
1117        (dolist (exit (entry-exits node))
1118          (mark-for-deletion (node-block exit)))
1119        (let ((home (node-home-lambda node)))
1120          (setf (lambda-entries home) (delq node (lambda-entries home)))))
1121       (creturn
1122        (flush-dest (return-result node))
1123        (delete-return node))
1124       (cset
1125        (flush-dest (set-value node))
1126        (let ((var (set-var node)))
1127          (setf (basic-var-sets var)
1128                (delete node (basic-var-sets var)))))
1129       (cast
1130        (flush-dest (cast-value node)))))
1131
1132   (remove-from-dfo block)
1133   (values))
1134
1135 ;;; Do stuff to indicate that the return node NODE is being deleted.
1136 (defun delete-return (node)
1137   (declare (type creturn node))
1138   (let* ((fun (return-lambda node))
1139          (tail-set (lambda-tail-set fun)))
1140     (aver (lambda-return fun))
1141     (setf (lambda-return fun) nil)
1142     (when (and tail-set (not (find-if #'lambda-return
1143                                       (tail-set-funs tail-set))))
1144       (setf (tail-set-type tail-set) *empty-type*)))
1145   (values))
1146
1147 ;;; If any of the VARS in FUN was never referenced and was not
1148 ;;; declared IGNORE, then complain.
1149 (defun note-unreferenced-vars (fun)
1150   (declare (type clambda fun))
1151   (dolist (var (lambda-vars fun))
1152     (unless (or (leaf-ever-used var)
1153                 (lambda-var-ignorep var))
1154       (let ((*compiler-error-context* (lambda-bind fun)))
1155         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1156           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1157           ;; requires this to be no more than a STYLE-WARNING.
1158           #-sb-xc-host
1159           (compiler-style-warn "The variable ~S is defined but never used."
1160                                (leaf-debug-name var))
1161           ;; There's no reason to accept this kind of equivocation
1162           ;; when compiling our own code, though.
1163           #+sb-xc-host
1164           (warn "The variable ~S is defined but never used."
1165                 (leaf-debug-name var)))
1166         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1167   (values))
1168
1169 (defvar *deletion-ignored-objects* '(t nil))
1170
1171 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1172 ;;; our recursion so that we don't get lost in circular structures. We
1173 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1174 ;;; function referencess with variables), and we also ignore anything
1175 ;;; inside ' or #'.
1176 (defun present-in-form (obj form depth)
1177   (declare (type (integer 0 20) depth))
1178   (cond ((= depth 20) nil)
1179         ((eq obj form) t)
1180         ((atom form) nil)
1181         (t
1182          (let ((first (car form))
1183                (depth (1+ depth)))
1184            (if (member first '(quote function))
1185                nil
1186                (or (and (not (symbolp first))
1187                         (present-in-form obj first depth))
1188                    (do ((l (cdr form) (cdr l))
1189                         (n 0 (1+ n)))
1190                        ((or (atom l) (> n 100))
1191                         nil)
1192                      (declare (fixnum n))
1193                      (when (present-in-form obj (car l) depth)
1194                        (return t)))))))))
1195
1196 ;;; This function is called on a block immediately before we delete
1197 ;;; it. We check to see whether any of the code about to die appeared
1198 ;;; in the original source, and emit a note if so.
1199 ;;;
1200 ;;; If the block was in a lambda is now deleted, then we ignore the
1201 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1202 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1203 ;;; reasonable for a function to not return, and there is a different
1204 ;;; note for that case anyway.
1205 ;;;
1206 ;;; If the actual source is an atom, then we use a bunch of heuristics
1207 ;;; to guess whether this reference really appeared in the original
1208 ;;; source:
1209 ;;; -- If a symbol, it must be interned and not a keyword.
1210 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1211 ;;;    or a character.)
1212 ;;; -- The atom must be "present" in the original source form, and
1213 ;;;    present in all intervening actual source forms.
1214 (defun note-block-deletion (block)
1215   (let ((home (block-home-lambda block)))
1216     (unless (eq (functional-kind home) :deleted)
1217       (do-nodes (node nil block)
1218         (let* ((path (node-source-path node))
1219                (first (first path)))
1220           (when (or (eq first 'original-source-start)
1221                     (and (atom first)
1222                          (or (not (symbolp first))
1223                              (let ((pkg (symbol-package first)))
1224                                (and pkg
1225                                     (not (eq pkg (symbol-package :end))))))
1226                          (not (member first *deletion-ignored-objects*))
1227                          (not (typep first '(or fixnum character)))
1228                          (every (lambda (x)
1229                                   (present-in-form first x 0))
1230                                 (source-path-forms path))
1231                          (present-in-form first (find-original-source path)
1232                                           0)))
1233             (unless (return-p node)
1234               (let ((*compiler-error-context* node))
1235                 (compiler-notify 'code-deletion-note
1236                                  :format-control "deleting unreachable code"
1237                                  :format-arguments nil)))
1238             (return))))))
1239   (values))
1240
1241 ;;; Delete a node from a block, deleting the block if there are no
1242 ;;; nodes left. We remove the node from the uses of its LVAR.
1243 ;;;
1244 ;;; If the node is the last node, there must be exactly one successor.
1245 ;;; We link all of our precedessors to the successor and unlink the
1246 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1247 ;;; left, and the block is a successor of itself, then we replace the
1248 ;;; only node with a degenerate exit node. This provides a way to
1249 ;;; represent the bodyless infinite loop, given the prohibition on
1250 ;;; empty blocks in IR1.
1251 (defun unlink-node (node)
1252   (declare (type node node))
1253   (when (valued-node-p node)
1254     (delete-lvar-use node))
1255
1256   (let* ((ctran (node-next node))
1257          (next (and ctran (ctran-next ctran)))
1258          (prev (node-prev node))
1259          (block (ctran-block prev))
1260          (prev-kind (ctran-kind prev))
1261          (last (block-last block)))
1262
1263     (setf (block-type-asserted block) t)
1264     (setf (block-test-modified block) t)
1265
1266     (cond ((or (eq prev-kind :inside-block)
1267                (and (eq prev-kind :block-start)
1268                     (not (eq node last))))
1269            (cond ((eq node last)
1270                   (setf (block-last block) (ctran-use prev))
1271                   (setf (node-next (ctran-use prev)) nil))
1272                  (t
1273                   (setf (ctran-next prev) next)
1274                   (setf (node-prev next) prev)
1275                   (when (if-p next) ; AOP wanted
1276                     (reoptimize-lvar (if-test next)))))
1277            (setf (node-prev node) nil)
1278            nil)
1279           (t
1280            (aver (eq prev-kind :block-start))
1281            (aver (eq node last))
1282            (let* ((succ (block-succ block))
1283                   (next (first succ)))
1284              (aver (singleton-p succ))
1285              (cond
1286               ((eq block (first succ))
1287                (with-ir1-environment-from-node node
1288                  (let ((exit (make-exit)))
1289                    (setf (ctran-next prev) nil)
1290                    (link-node-to-previous-ctran exit prev)
1291                    (setf (block-last block) exit)))
1292                (setf (node-prev node) nil)
1293                nil)
1294               (t
1295                (aver (eq (block-start-cleanup block)
1296                          (block-end-cleanup block)))
1297                (unlink-blocks block next)
1298                (dolist (pred (block-pred block))
1299                  (change-block-successor pred block next))
1300                (when (block-delete-p block)
1301                  (let ((component (block-component block)))
1302                    (setf (component-delete-blocks component)
1303                          (delq block (component-delete-blocks component)))))
1304                (remove-from-dfo block)
1305                (setf (block-delete-p block) t)
1306                (setf (node-prev node) nil)
1307                t)))))))
1308
1309 ;;; Return true if NODE has been deleted, false if it is still a valid
1310 ;;; part of IR1.
1311 (defun node-deleted (node)
1312   (declare (type node node))
1313   (let ((prev (node-prev node)))
1314     (not (and prev
1315               (let ((block (ctran-block prev)))
1316                 (and (block-component block)
1317                      (not (block-delete-p block))))))))
1318
1319 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1320 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1321 ;;; triggered by deletion.
1322 (defun delete-component (component)
1323   (declare (type component component))
1324   (aver (null (component-new-functionals component)))
1325   (setf (component-kind component) :deleted)
1326   (do-blocks (block component)
1327     (delete-block-lazily block))
1328   (dolist (fun (component-lambdas component))
1329     (unless (eq (functional-kind fun) :deleted)
1330       (setf (functional-kind fun) nil)
1331       (setf (functional-entry-fun fun) nil)
1332       (setf (leaf-refs fun) nil)
1333       (delete-functional fun)))
1334   (clean-component component)
1335   (values))
1336
1337 ;;; Remove all pending blocks to be deleted. Return the nearest live
1338 ;;; block after or equal to BLOCK.
1339 (defun clean-component (component &optional block)
1340   (loop while (component-delete-blocks component)
1341         ;; actual deletion of a block may queue new blocks
1342         do (let ((current (pop (component-delete-blocks component))))
1343              (when (eq block current)
1344                (setq block (block-next block)))
1345              (delete-block current)))
1346   block)
1347
1348 ;;; Convert code of the form
1349 ;;;   (FOO ... (FUN ...) ...)
1350 ;;; to
1351 ;;;   (FOO ...    ...    ...).
1352 ;;; In other words, replace the function combination FUN by its
1353 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1354 ;;; to blow out of whatever transform called this. Note, as the number
1355 ;;; of arguments changes, the transform must be prepared to return a
1356 ;;; lambda with a new lambda-list with the correct number of
1357 ;;; arguments.
1358 (defun extract-fun-args (lvar fun num-args)
1359   #!+sb-doc
1360   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1361    to feed directly to the LVAR-DEST of LVAR, which must be a
1362    combination."
1363   (declare (type lvar lvar)
1364            (type symbol fun)
1365            (type index num-args))
1366   (let ((outside (lvar-dest lvar))
1367         (inside (lvar-uses lvar)))
1368     (aver (combination-p outside))
1369     (unless (combination-p inside)
1370       (give-up-ir1-transform))
1371     (let ((inside-fun (combination-fun inside)))
1372       (unless (eq (lvar-fun-name inside-fun) fun)
1373         (give-up-ir1-transform))
1374       (let ((inside-args (combination-args inside)))
1375         (unless (= (length inside-args) num-args)
1376           (give-up-ir1-transform))
1377         (let* ((outside-args (combination-args outside))
1378                (arg-position (position lvar outside-args))
1379                (before-args (subseq outside-args 0 arg-position))
1380                (after-args (subseq outside-args (1+ arg-position))))
1381           (dolist (arg inside-args)
1382             (setf (lvar-dest arg) outside)
1383             (flush-lvar-externally-checkable-type arg))
1384           (setf (combination-args inside) nil)
1385           (setf (combination-args outside)
1386                 (append before-args inside-args after-args))
1387           (change-ref-leaf (lvar-uses inside-fun)
1388                            (find-free-fun 'list "???"))
1389           (setf (combination-fun-info inside) (info :function :info 'list)
1390                 (combination-kind inside) :known)
1391           (setf (node-derived-type inside) *wild-type*)
1392           (flush-dest lvar)
1393           (values))))))
1394
1395 (defun flush-combination (combination)
1396   (declare (type combination combination))
1397   (flush-dest (combination-fun combination))
1398   (dolist (arg (combination-args combination))
1399     (flush-dest arg))
1400   (unlink-node combination)
1401   (values))
1402
1403 \f
1404 ;;;; leaf hackery
1405
1406 ;;; Change the LEAF that a REF refers to.
1407 (defun change-ref-leaf (ref leaf)
1408   (declare (type ref ref) (type leaf leaf))
1409   (unless (eq (ref-leaf ref) leaf)
1410     (push ref (leaf-refs leaf))
1411     (delete-ref ref)
1412     (setf (ref-leaf ref) leaf)
1413     (setf (leaf-ever-used leaf) t)
1414     (let* ((ltype (leaf-type leaf))
1415            (vltype (make-single-value-type ltype)))
1416       (if (let* ((lvar (node-lvar ref))
1417                  (dest (and lvar (lvar-dest lvar))))
1418             (and (basic-combination-p dest)
1419                  (eq lvar (basic-combination-fun dest))
1420                  (csubtypep ltype (specifier-type 'function))))
1421           (setf (node-derived-type ref) vltype)
1422           (derive-node-type ref vltype)))
1423     (reoptimize-lvar (node-lvar ref)))
1424   (values))
1425
1426 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1427 (defun substitute-leaf (new-leaf old-leaf)
1428   (declare (type leaf new-leaf old-leaf))
1429   (dolist (ref (leaf-refs old-leaf))
1430     (change-ref-leaf ref new-leaf))
1431   (values))
1432
1433 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1434 ;;; whether to substitute
1435 (defun substitute-leaf-if (test new-leaf old-leaf)
1436   (declare (type leaf new-leaf old-leaf) (type function test))
1437   (dolist (ref (leaf-refs old-leaf))
1438     (when (funcall test ref)
1439       (change-ref-leaf ref new-leaf)))
1440   (values))
1441
1442 ;;; Return a LEAF which represents the specified constant object. If
1443 ;;; the object is not in *CONSTANTS*, then we create a new constant
1444 ;;; LEAF and enter it.
1445 (defun find-constant (object)
1446   (if (typep object
1447              ;; FIXME: What is the significance of this test? ("things
1448              ;; that are worth uniquifying"?)
1449              '(or symbol number character instance))
1450       (or (gethash object *constants*)
1451           (setf (gethash object *constants*)
1452                 (make-constant :value object
1453                                :%source-name '.anonymous.
1454                                :type (ctype-of object)
1455                                :where-from :defined)))
1456       (make-constant :value object
1457                      :%source-name '.anonymous.
1458                      :type (ctype-of object)
1459                      :where-from :defined)))
1460 \f
1461 ;;; Return true if VAR would have to be closed over if environment
1462 ;;; analysis ran now (i.e. if there are any uses that have a different
1463 ;;; home lambda than VAR's home.)
1464 (defun closure-var-p (var)
1465   (declare (type lambda-var var))
1466   (let ((home (lambda-var-home var)))
1467     (cond ((eq (functional-kind home) :deleted)
1468            nil)
1469           (t (let ((home (lambda-home home)))
1470                (flet ((frob (l)
1471                         (find home l
1472                               :key #'node-home-lambda
1473                               :test #'neq)))
1474                  (or (frob (leaf-refs var))
1475                      (frob (basic-var-sets var)))))))))
1476
1477 ;;; If there is a non-local exit noted in ENTRY's environment that
1478 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1479 (defun find-nlx-info (exit)
1480   (declare (type exit exit))
1481   (let ((entry (exit-entry exit)))
1482     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1483       (when (eq (nlx-info-exit nlx) exit)
1484         (return nlx)))))
1485 \f
1486 ;;;; functional hackery
1487
1488 (declaim (ftype (sfunction (functional) clambda) main-entry))
1489 (defun main-entry (functional)
1490   (etypecase functional
1491     (clambda functional)
1492     (optional-dispatch
1493      (optional-dispatch-main-entry functional))))
1494
1495 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1496 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1497 ;;; optional with null default and no SUPPLIED-P. There must be a
1498 ;;; &REST arg with no references.
1499 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1500 (defun looks-like-an-mv-bind (functional)
1501   (and (optional-dispatch-p functional)
1502        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1503            ((null arg) nil)
1504          (let ((info (lambda-var-arg-info (car arg))))
1505            (unless info (return nil))
1506            (case (arg-info-kind info)
1507              (:optional
1508               (when (or (arg-info-supplied-p info) (arg-info-default info))
1509                 (return nil)))
1510              (:rest
1511               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1512              (t
1513               (return nil)))))))
1514
1515 ;;; Return true if function is an external entry point. This is true
1516 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1517 ;;; (:TOPLEVEL kind.)
1518 (defun xep-p (fun)
1519   (declare (type functional fun))
1520   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1521
1522 ;;; If LVAR's only use is a non-notinline global function reference,
1523 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1524 ;;; is true, then we don't care if the leaf is NOTINLINE.
1525 (defun lvar-fun-name (lvar &optional notinline-ok)
1526   (declare (type lvar lvar))
1527   (let ((use (lvar-uses lvar)))
1528     (if (ref-p use)
1529         (let ((leaf (ref-leaf use)))
1530           (if (and (global-var-p leaf)
1531                    (eq (global-var-kind leaf) :global-function)
1532                    (or (not (defined-fun-p leaf))
1533                        (not (eq (defined-fun-inlinep leaf) :notinline))
1534                        notinline-ok))
1535               (leaf-source-name leaf)
1536               nil))
1537         nil)))
1538
1539 ;;; Return the source name of a combination. (This is an idiom
1540 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1541 (defun combination-fun-source-name (combination)
1542   (let ((ref (lvar-uses (combination-fun combination))))
1543     (leaf-source-name (ref-leaf ref))))
1544
1545 ;;; Return the COMBINATION node that is the call to the LET FUN.
1546 (defun let-combination (fun)
1547   (declare (type clambda fun))
1548   (aver (functional-letlike-p fun))
1549   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1550
1551 ;;; Return the initial value lvar for a LET variable, or NIL if there
1552 ;;; is none.
1553 (defun let-var-initial-value (var)
1554   (declare (type lambda-var var))
1555   (let ((fun (lambda-var-home var)))
1556     (elt (combination-args (let-combination fun))
1557          (position-or-lose var (lambda-vars fun)))))
1558
1559 ;;; Return the LAMBDA that is called by the local CALL.
1560 (defun combination-lambda (call)
1561   (declare (type basic-combination call))
1562   (aver (eq (basic-combination-kind call) :local))
1563   (ref-leaf (lvar-uses (basic-combination-fun call))))
1564
1565 (defvar *inline-expansion-limit* 200
1566   #!+sb-doc
1567   "an upper limit on the number of inline function calls that will be expanded
1568    in any given code object (single function or block compilation)")
1569
1570 ;;; Check whether NODE's component has exceeded its inline expansion
1571 ;;; limit, and warn if so, returning NIL.
1572 (defun inline-expansion-ok (node)
1573   (let ((expanded (incf (component-inline-expansions
1574                          (block-component
1575                           (node-block node))))))
1576     (cond ((> expanded *inline-expansion-limit*) nil)
1577           ((= expanded *inline-expansion-limit*)
1578            ;; FIXME: If the objective is to stop the recursive
1579            ;; expansion of inline functions, wouldn't it be more
1580            ;; correct to look back through surrounding expansions
1581            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1582            ;; possibly stored elsewhere too) and suppress expansion
1583            ;; and print this warning when the function being proposed
1584            ;; for inline expansion is found there? (I don't like the
1585            ;; arbitrary numerical limit in principle, and I think
1586            ;; it'll be a nuisance in practice if we ever want the
1587            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1588            ;; arbitrarily huge blocks of code. -- WHN)
1589            (let ((*compiler-error-context* node))
1590              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1591                                probably trying to~%  ~
1592                                inline a recursive function."
1593                               *inline-expansion-limit*))
1594            nil)
1595           (t t))))
1596
1597 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1598 (defun assure-functional-live-p (functional)
1599   (declare (type functional functional))
1600   (when (and (or
1601               ;; looks LET-converted
1602               (functional-somewhat-letlike-p functional)
1603               ;; It's possible for a LET-converted function to end up
1604               ;; deleted later. In that case, for the purposes of this
1605               ;; analysis, it is LET-converted: LET-converted functionals
1606               ;; are too badly trashed to expand them inline, and deleted
1607               ;; LET-converted functionals are even worse.
1608               (memq (functional-kind functional) '(:deleted :zombie))))
1609     (throw 'locall-already-let-converted functional)))
1610
1611 (defun call-full-like-p (call)
1612   (declare (type combination call))
1613   (let ((kind (basic-combination-kind call)))
1614     (or (eq kind :full)
1615         (and (eq kind :known)
1616              (let ((info (basic-combination-fun-info call)))
1617                (and
1618                 (not (fun-info-ir2-convert info))
1619                 (dolist (template (fun-info-templates info) t)
1620                   (when (eq (template-ltn-policy template) :fast-safe)
1621                     (multiple-value-bind (val win)
1622                        (valid-fun-use call (template-type template))
1623                       (when (or val (not win)) (return nil)))))))))))
1624 \f
1625 ;;;; careful call
1626
1627 ;;; Apply a function to some arguments, returning a list of the values
1628 ;;; resulting of the evaluation. If an error is signalled during the
1629 ;;; application, then we produce a warning message using WARN-FUN and
1630 ;;; return NIL as our second value to indicate this. NODE is used as
1631 ;;; the error context for any error message, and CONTEXT is a string
1632 ;;; that is spliced into the warning.
1633 (declaim (ftype (sfunction ((or symbol function) list node function string)
1634                           (values list boolean))
1635                 careful-call))
1636 (defun careful-call (function args node warn-fun context)
1637   (values
1638    (multiple-value-list
1639     (handler-case (apply function args)
1640       (error (condition)
1641         (let ((*compiler-error-context* node))
1642           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1643           (return-from careful-call (values nil nil))))))
1644    t))
1645
1646 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1647 ;;; specifiers.
1648 (macrolet
1649     ((deffrob (basic careful compiler transform)
1650        `(progn
1651           (defun ,careful (specifier)
1652             (handler-case (,basic specifier)
1653               (sb!kernel::arg-count-error (condition)
1654                 (values nil (list (format nil "~A" condition))))
1655               (simple-error (condition)
1656                 (values nil (list* (simple-condition-format-control condition)
1657                                    (simple-condition-format-arguments condition))))))
1658           (defun ,compiler (specifier)
1659             (multiple-value-bind (type error-args) (,careful specifier)
1660               (or type
1661                   (apply #'compiler-error error-args))))
1662           (defun ,transform (specifier)
1663             (multiple-value-bind (type error-args) (,careful specifier)
1664               (or type
1665                   (apply #'give-up-ir1-transform
1666                          error-args)))))))
1667   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1668   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1669
1670 \f
1671 ;;;; utilities used at run-time for parsing &KEY args in IR1
1672
1673 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1674 ;;; the lvar for the value of the &KEY argument KEY in the list of
1675 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1676 ;;; otherwise. The legality and constantness of the keywords should
1677 ;;; already have been checked.
1678 (declaim (ftype (sfunction (list keyword) (or lvar null))
1679                 find-keyword-lvar))
1680 (defun find-keyword-lvar (args key)
1681   (do ((arg args (cddr arg)))
1682       ((null arg) nil)
1683     (when (eq (lvar-value (first arg)) key)
1684       (return (second arg)))))
1685
1686 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1687 ;;; verify that alternating lvars in ARGS are constant and that there
1688 ;;; is an even number of args.
1689 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1690 (defun check-key-args-constant (args)
1691   (do ((arg args (cddr arg)))
1692       ((null arg) t)
1693     (unless (and (rest arg)
1694                  (constant-lvar-p (first arg)))
1695       (return nil))))
1696
1697 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1698 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1699 ;;; and that only keywords present in the list KEYS are supplied.
1700 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1701 (defun check-transform-keys (args keys)
1702   (and (check-key-args-constant args)
1703        (do ((arg args (cddr arg)))
1704            ((null arg) t)
1705          (unless (member (lvar-value (first arg)) keys)
1706            (return nil)))))
1707 \f
1708 ;;;; miscellaneous
1709
1710 ;;; Called by the expansion of the EVENT macro.
1711 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1712 (defun %event (info node)
1713   (incf (event-info-count info))
1714   (when (and (>= (event-info-level info) *event-note-threshold*)
1715              (policy (or node *lexenv*)
1716                      (= inhibit-warnings 0)))
1717     (let ((*compiler-error-context* node))
1718       (compiler-notify (event-info-description info))))
1719
1720   (let ((action (event-info-action info)))
1721     (when action (funcall action node))))
1722
1723 ;;;
1724 (defun make-cast (value type policy)
1725   (declare (type lvar value)
1726            (type ctype type)
1727            (type policy policy))
1728   (%make-cast :asserted-type type
1729               :type-to-check (maybe-weaken-check type policy)
1730               :value value
1731               :derived-type (coerce-to-values type)))
1732
1733 (defun cast-type-check (cast)
1734   (declare (type cast cast))
1735   (when (cast-reoptimize cast)
1736     (ir1-optimize-cast cast t))
1737   (cast-%type-check cast))
1738
1739 (defun note-single-valuified-lvar (lvar)
1740   (declare (type (or lvar null) lvar))
1741   (when lvar
1742     (let ((use (lvar-uses lvar)))
1743       (cond ((ref-p use)
1744              (let ((leaf (ref-leaf use)))
1745                (when (and (lambda-var-p leaf)
1746                           (null (rest (leaf-refs leaf))))
1747                  (reoptimize-lambda-var leaf))))
1748             ((or (listp use) (combination-p use))
1749              (do-uses (node lvar)
1750                (setf (node-reoptimize node) t)
1751                (setf (block-reoptimize (node-block node)) t)
1752                (setf (component-reoptimize (node-component node)) t)))))))