src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (declaim (ftype (sfunction (lvar) lvar) principal-lvar))
  66 (defun principal-lvar (lvar)
  67   (labels ((pl (lvar)
  68              (let ((use (lvar-uses lvar)))
  69                (if (cast-p use)
  70                    (pl (cast-value use))
  71                    lvar))))
  72     (pl lvar)))
  73
  74 (defun principal-lvar-use (lvar)
  75   (labels ((plu (lvar)
  76              (declare (type lvar lvar))
  77              (let ((use (lvar-uses lvar)))
  78                (if (cast-p use)
  79                    (plu (cast-value use))
  80                    use))))
  81     (plu lvar)))
  82
  83 ;;; Update lvar use information so that NODE is no longer a use of its
  84 ;;; LVAR.
  85 ;;;
  86 ;;; Note: if you call this function, you may have to do a
  87 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  88 ;;; changed.
  89 (declaim (ftype (sfunction (node) (values))
  90                 delete-lvar-use
  91                 %delete-lvar-use))
  92 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  93 ;;; be given a new use.
  94 (defun %delete-lvar-use (node)
  95   (let ((lvar (node-lvar node)))
  96     (when lvar
  97       (if (listp (lvar-uses lvar))
  98           (let ((new-uses (delq node (lvar-uses lvar))))
  99             (setf (lvar-uses lvar)
 100                   (if (singleton-p new-uses)
 101                       (first new-uses)
 102                       new-uses)))
 103           (setf (lvar-uses lvar) nil))
 104       (setf (node-lvar node) nil)))
 105   (values))
 106 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
 107 ;;; its DEST's block, which must be unreachable.
 108 (defun delete-lvar-use (node)
 109   (let ((lvar (node-lvar node)))
 110     (when lvar
 111       (%delete-lvar-use node)
 112       (if (null (lvar-uses lvar))
 113           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 114                      (() (not (node-deleted dest)) :exit-if-null)
 115                      (block (node-block dest)))
 116             (mark-for-deletion block))
 117           (reoptimize-lvar lvar))))
 118   (values))
 119
 120 ;;; Update lvar use information so that NODE uses LVAR.
 121 ;;;
 122 ;;; Note: if you call this function, you may have to do a
 123 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 124 ;;; changed.
 125 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 126 (defun add-lvar-use (node lvar)
 127   (aver (not (node-lvar node)))
 128   (when lvar
 129     (let ((uses (lvar-uses lvar)))
 130       (setf (lvar-uses lvar)
 131             (cond ((null uses)
 132                    node)
 133                   ((listp uses)
 134                    (cons node uses))
 135                   (t
 136                    (list node uses))))
 137       (setf (node-lvar node) lvar)))
 138
 139   (values))
 140
 141 ;;; Return true if LVAR destination is executed immediately after
 142 ;;; NODE. Cleanups are ignored.
 143 (defun immediately-used-p (lvar node)
 144   (declare (type lvar lvar) (type node node))
 145   (aver (eq (node-lvar node) lvar))
 146   (let ((dest (lvar-dest lvar)))
 147     (acond ((node-next node)
 148             (eq (ctran-next it) dest))
 149            (t (eq (block-start (first (block-succ (node-block node))))
 150                   (node-prev dest))))))
 151 \f
 152 ;;;; lvar substitution
 153
 154 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 155 ;;; NIL. We do not flush OLD's DEST.
 156 (defun substitute-lvar (new old)
 157   (declare (type lvar old new))
 158   (aver (not (lvar-dest new)))
 159   (let ((dest (lvar-dest old)))
 160     (etypecase dest
 161       ((or ref bind))
 162       (cif (setf (if-test dest) new))
 163       (cset (setf (set-value dest) new))
 164       (creturn (setf (return-result dest) new))
 165       (exit (setf (exit-value dest) new))
 166       (basic-combination
 167        (if (eq old (basic-combination-fun dest))
 168            (setf (basic-combination-fun dest) new)
 169            (setf (basic-combination-args dest)
 170                  (nsubst new old (basic-combination-args dest)))))
 171       (cast (setf (cast-value dest) new)))
 172
 173     (setf (lvar-dest old) nil)
 174     (setf (lvar-dest new) dest)
 175     (flush-lvar-externally-checkable-type new))
 176   (values))
 177
 178 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 179 ;;; arbitary number of uses. NEW is supposed to be "later" than OLD.
 180 (defun substitute-lvar-uses (new old propagate-dx)
 181   (declare (type lvar old)
 182            (type (or lvar null) new)
 183            (type boolean propagate-dx))
 184
 185   (cond (new
 186          (do-uses (node old)
 187            (%delete-lvar-use node)
 188            (add-lvar-use node new))
 189          (reoptimize-lvar new)
 190          (awhen (and propagate-dx (lvar-dynamic-extent old))
 191            (setf (lvar-dynamic-extent old) nil)
 192            (unless (lvar-dynamic-extent new)
 193              (setf (lvar-dynamic-extent new) it)
 194              (setf (cleanup-info it) (substitute new old (cleanup-info it)))))
 195          (when (lvar-dynamic-extent new)
 196            (do-uses (node new)
 197              (node-ends-block node))))
 198         (t (flush-dest old)))
 199
 200   (values))
 201 \f
 202 ;;;; block starting/creation
 203
 204 ;;; Return the block that CTRAN is the start of, making a block if
 205 ;;; necessary. This function is called by IR1 translators which may
 206 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 207 ;;; used more than once must start a block by the time that anyone
 208 ;;; does a USE-CTRAN on it.
 209 ;;;
 210 ;;; We also throw the block into the next/prev list for the
 211 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 212 ;;; made.
 213 (defun ctran-starts-block (ctran)
 214   (declare (type ctran ctran))
 215   (ecase (ctran-kind ctran)
 216     (:unused
 217      (aver (not (ctran-block ctran)))
 218      (let* ((next (component-last-block *current-component*))
 219             (prev (block-prev next))
 220             (new-block (make-block ctran)))
 221        (setf (block-next new-block) next
 222              (block-prev new-block) prev
 223              (block-prev next) new-block
 224              (block-next prev) new-block
 225              (ctran-block ctran) new-block
 226              (ctran-kind ctran) :block-start)
 227        (aver (not (ctran-use ctran)))
 228        new-block))
 229     (:block-start
 230      (ctran-block ctran))))
 231
 232 ;;; Ensure that CTRAN is the start of a block so that the use set can
 233 ;;; be freely manipulated.
 234 (defun ensure-block-start (ctran)
 235   (declare (type ctran ctran))
 236   (let ((kind (ctran-kind ctran)))
 237     (ecase kind
 238       ((:block-start))
 239       ((:unused)
 240        (setf (ctran-block ctran)
 241              (make-block-key :start ctran))
 242        (setf (ctran-kind ctran) :block-start))
 243       ((:inside-block)
 244        (node-ends-block (ctran-use ctran)))))
 245   (values))
 246
 247 ;;; CTRAN must be the last ctran in an incomplete block; finish the
 248 ;;; block and start a new one if necessary.
 249 (defun start-block (ctran)
 250   (declare (type ctran ctran))
 251   (aver (not (ctran-next ctran)))
 252   (ecase (ctran-kind ctran)
 253     (:inside-block
 254      (let ((block (ctran-block ctran))
 255            (node (ctran-use ctran)))
 256        (aver (not (block-last block)))
 257        (aver node)
 258        (setf (block-last block) node)
 259        (setf (node-next node) nil)
 260        (setf (ctran-use ctran) nil)
 261        (setf (ctran-kind ctran) :unused)
 262        (setf (ctran-block ctran) nil)
 263        (link-blocks block (ctran-starts-block ctran))))
 264     (:block-start)))
 265 \f
 266 ;;;;
 267
 268 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 269 ;;; call. First argument must be 'DUMMY, which will be replaced with
 270 ;;; LVAR. In case of an ordinary call the function should not have
 271 ;;; return type NIL. We create a new "filtered" lvar.
 272 ;;;
 273 ;;; TODO: remove preconditions.
 274 (defun filter-lvar (lvar form)
 275   (declare (type lvar lvar) (type list form))
 276   (let* ((dest (lvar-dest lvar))
 277          (ctran (node-prev dest)))
 278     (with-ir1-environment-from-node dest
 279
 280       (ensure-block-start ctran)
 281       (let* ((old-block (ctran-block ctran))
 282              (new-start (make-ctran))
 283              (filtered-lvar (make-lvar))
 284              (new-block (ctran-starts-block new-start)))
 285
 286         ;; Splice in the new block before DEST, giving the new block
 287         ;; all of DEST's predecessors.
 288         (dolist (block (block-pred old-block))
 289           (change-block-successor block old-block new-block))
 290
 291         (ir1-convert new-start ctran filtered-lvar form)
 292
 293         ;; KLUDGE: Comments at the head of this function in CMU CL
 294         ;; said that somewhere in here we
 295         ;;   Set the new block's start and end cleanups to the *start*
 296         ;;   cleanup of PREV's block. This overrides the incorrect
 297         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 298         ;; Unfortunately I can't find any code which corresponds to this.
 299         ;; Perhaps it was a stale comment? Or perhaps I just don't
 300         ;; understand.. -- WHN 19990521
 301
 302         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 303         ;; no LET conversion has been done yet.) The [mv-]combination
 304         ;; code from the call in the form will be the use of the new
 305         ;; check lvar. We substitute for the first argument of
 306         ;; this node.
 307         (let* ((node (lvar-use filtered-lvar))
 308                (args (basic-combination-args node))
 309                (victim (first args)))
 310           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 311                     'dummy))
 312
 313           (substitute-lvar filtered-lvar lvar)
 314           (substitute-lvar lvar victim)
 315           (flush-dest victim))
 316
 317         ;; Invoking local call analysis converts this call to a LET.
 318         (locall-analyze-component *current-component*))))
 319   (values))
 320
 321 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 322 (defun delete-filter (node lvar value)
 323   (aver (eq (lvar-dest value) node))
 324   (aver (eq (node-lvar node) lvar))
 325   (cond (lvar (collect ((merges))
 326                 (when (return-p (lvar-dest lvar))
 327                   (do-uses (use value)
 328                     (when (and (basic-combination-p use)
 329                                (eq (basic-combination-kind use) :local))
 330                       (merges use))))
 331                 (substitute-lvar-uses lvar value
 332                                       (and lvar (eq (lvar-uses lvar) node)))
 333                 (%delete-lvar-use node)
 334                 (prog1
 335                     (unlink-node node)
 336                   (dolist (merge (merges))
 337                     (merge-tail-sets merge)))))
 338         (t (flush-dest value)
 339            (unlink-node node))))
 340
 341 ;;; Make a CAST and insert it into IR1 before node NEXT.
 342 (defun insert-cast-before (next lvar type policy)
 343   (declare (type node next) (type lvar lvar) (type ctype type))
 344   (with-ir1-environment-from-node next
 345     (let* ((ctran (node-prev next))
 346            (cast (make-cast lvar type policy))
 347            (internal-ctran (make-ctran)))
 348       (setf (ctran-next ctran) cast
 349             (node-prev cast) ctran)
 350       (use-ctran cast internal-ctran)
 351       (link-node-to-previous-ctran next internal-ctran)
 352       (setf (lvar-dest lvar) cast)
 353       (reoptimize-lvar lvar)
 354       (when (return-p next)
 355         (node-ends-block cast))
 356       (setf (block-attributep (block-flags (node-block cast))
 357                               type-check type-asserted)
 358             t)
 359       cast)))
 360 \f
 361 ;;;; miscellaneous shorthand functions
 362
 363 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 364 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 365 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 366 ;;; deleted, and then return its home.
 367 (defun node-home-lambda (node)
 368   (declare (type node node))
 369   (do ((fun (lexenv-lambda (node-lexenv node))
 370             (lexenv-lambda (lambda-call-lexenv fun))))
 371       ((not (memq (functional-kind fun) '(:deleted :zombie)))
 372        (lambda-home fun))
 373     (when (eq (lambda-home fun) fun)
 374       (return fun))))
 375
 376 #!-sb-fluid (declaim (inline node-block))
 377 (defun node-block (node)
 378   (ctran-block (node-prev node)))
 379 (declaim (ftype (sfunction (node) component) node-component))
 380 (defun node-component (node)
 381   (block-component (node-block node)))
 382 (declaim (ftype (sfunction (node) physenv) node-physenv))
 383 (defun node-physenv (node)
 384   (lambda-physenv (node-home-lambda node)))
 385 #!-sb-fluid (declaim (inline node-dest))
 386 (defun node-dest (node)
 387   (awhen (node-lvar node) (lvar-dest it)))
 388
 389 #!-sb-fluid (declaim (inline node-stack-allocate-p))
 390 (defun node-stack-allocate-p (node)
 391   (awhen (node-lvar node)
 392     (lvar-dynamic-extent it)))
 393
 394 (declaim (ftype (sfunction (node (member nil t :truly) &optional (or null component))
 395                            boolean) use-good-for-dx-p))
 396 (declaim (ftype (sfunction (lvar (member nil t :truly) &optional (or null component))
 397                            boolean) lvar-good-for-dx-p))
 398 (defun use-good-for-dx-p (use dx &optional component)
 399   ;; FIXME: Can casts point to LVARs in other components?
 400   ;; RECHECK-DYNAMIC-EXTENT-LVARS assumes that they can't -- that is, that the
 401   ;; PRINCIPAL-LVAR is always in the same component as the original one. It
 402   ;; would be either good to have an explanation of why casts don't point
 403   ;; across components, or an explanation of when they do it. ...in the
 404   ;; meanwhile AVER that our assumption holds true.
 405   (aver (or (not component) (eq component (node-component use))))
 406   (or (and (combination-p use)
 407            (eq (combination-kind use) :known)
 408            (awhen (fun-info-stack-allocate-result (combination-fun-info use))
 409              (funcall it use dx))
 410            t)
 411       (and (cast-p use)
 412            (not (cast-type-check use))
 413            (lvar-good-for-dx-p (cast-value use) dx component)
 414            t)))
 415
 416 (defun lvar-good-for-dx-p (lvar dx &optional component)
 417   (let ((uses (lvar-uses lvar)))
 418     (if (listp uses)
 419         (every (lambda (use)
 420                  (use-good-for-dx-p use dx component))
 421                uses)
 422         (use-good-for-dx-p uses dx component))))
 423
 424 (declaim (inline block-to-be-deleted-p))
 425 (defun block-to-be-deleted-p (block)
 426   (or (block-delete-p block)
 427       (eq (functional-kind (block-home-lambda block)) :deleted)))
 428
 429 ;;; Checks whether NODE is in a block to be deleted
 430 (declaim (inline node-to-be-deleted-p))
 431 (defun node-to-be-deleted-p (node)
 432   (block-to-be-deleted-p (node-block node)))
 433
 434 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 435 (defun lambda-block (clambda)
 436   (node-block (lambda-bind clambda)))
 437 (declaim (ftype (sfunction (clambda) component) lambda-component))
 438 (defun lambda-component (clambda)
 439   (block-component (lambda-block clambda)))
 440
 441 (declaim (ftype (sfunction (cblock) node) block-start-node))
 442 (defun block-start-node (block)
 443   (ctran-next (block-start block)))
 444
 445 ;;; Return the enclosing cleanup for environment of the first or last
 446 ;;; node in BLOCK.
 447 (defun block-start-cleanup (block)
 448   (node-enclosing-cleanup (block-start-node block)))
 449 (defun block-end-cleanup (block)
 450   (node-enclosing-cleanup (block-last block)))
 451
 452 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 453 ;;; if there is none.
 454 ;;;
 455 ;;; There can legitimately be no home lambda in dead code early in the
 456 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 457 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 458 ;;; where the block is just a placeholder during parsing and doesn't
 459 ;;; actually correspond to code which will be written anywhere.
 460 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 461 (defun block-home-lambda-or-null (block)
 462   (if (node-p (block-last block))
 463       ;; This is the old CMU CL way of doing it.
 464       (node-home-lambda (block-last block))
 465       ;; Now that SBCL uses this operation more aggressively than CMU
 466       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 467       ;;   1. It can fail in a few cases even when a meaningful home
 468       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 469       ;;      an IF.
 470       ;;   2. It can fail when converting a form which is born orphaned
 471       ;;      so that it never had a meaningful home lambda, e.g. a form
 472       ;;      which follows a RETURN-FROM or GO form.
 473       (let ((pred-list (block-pred block)))
 474         ;; To deal with case 1, we reason that
 475         ;; previous-in-target-execution-order blocks should be in the
 476         ;; same lambda, and that they seem in practice to be
 477         ;; previous-in-compilation-order blocks too, so we look back
 478         ;; to find one which is sufficiently initialized to tell us
 479         ;; what the home lambda is.
 480         (if pred-list
 481             ;; We could get fancy about this, flooding through the
 482             ;; graph of all the previous blocks, but in practice it
 483             ;; seems to work just to grab the first previous block and
 484             ;; use it.
 485             (node-home-lambda (block-last (first pred-list)))
 486             ;; In case 2, we end up with an empty PRED-LIST and
 487             ;; have to punt: There's no home lambda.
 488             nil))))
 489
 490 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 491 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 492 (defun block-home-lambda (block)
 493   (block-home-lambda-or-null block))
 494
 495 ;;; Return the IR1 physical environment for BLOCK.
 496 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 497 (defun block-physenv (block)
 498   (lambda-physenv (block-home-lambda block)))
 499
 500 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 501 ;;; of its original source's top level form in its compilation unit.
 502 (defun source-path-tlf-number (path)
 503   (declare (list path))
 504   (car (last path)))
 505
 506 ;;; Return the (reversed) list for the PATH in the original source
 507 ;;; (with the Top Level Form number last).
 508 (defun source-path-original-source (path)
 509   (declare (list path) (inline member))
 510   (cddr (member 'original-source-start path :test #'eq)))
 511
 512 ;;; Return the Form Number of PATH's original source inside the Top
 513 ;;; Level Form that contains it. This is determined by the order that
 514 ;;; we walk the subforms of the top level source form.
 515 (defun source-path-form-number (path)
 516   (declare (list path) (inline member))
 517   (cadr (member 'original-source-start path :test #'eq)))
 518
 519 ;;; Return a list of all the enclosing forms not in the original
 520 ;;; source that converted to get to this form, with the immediate
 521 ;;; source for node at the start of the list.
 522 (defun source-path-forms (path)
 523   (subseq path 0 (position 'original-source-start path)))
 524
 525 ;;; Return the innermost source form for NODE.
 526 (defun node-source-form (node)
 527   (declare (type node node))
 528   (let* ((path (node-source-path node))
 529          (forms (source-path-forms path)))
 530     (if forms
 531         (first forms)
 532         (values (find-original-source path)))))
 533
 534 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 535 ;;; NIL, NIL.
 536 (defun lvar-source (lvar)
 537   (let ((use (lvar-uses lvar)))
 538     (if (listp use)
 539         (values nil nil)
 540         (values (node-source-form use) t))))
 541
 542 ;;; Return the unique node, delivering a value to LVAR.
 543 #!-sb-fluid (declaim (inline lvar-use))
 544 (defun lvar-use (lvar)
 545   (the (not list) (lvar-uses lvar)))
 546
 547 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 548 (defun lvar-has-single-use-p (lvar)
 549   (typep (lvar-uses lvar) '(not list)))
 550
 551 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 552 (declaim (ftype (sfunction (ctran) (or clambda null))
 553                 ctran-home-lambda-or-null))
 554 (defun ctran-home-lambda-or-null (ctran)
 555   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 556   ;; implementation might not be quite right, or might be uglier than
 557   ;; necessary. It appears that the original Python never found a need
 558   ;; to do this operation. The obvious things based on
 559   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 560   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 561   ;; generalize it enough to grovel harder when the simple CMU CL
 562   ;; approach fails, and furthermore realize that in some exceptional
 563   ;; cases it might return NIL. -- WHN 2001-12-04
 564   (cond ((ctran-use ctran)
 565          (node-home-lambda (ctran-use ctran)))
 566         ((ctran-block ctran)
 567          (block-home-lambda-or-null (ctran-block ctran)))
 568         (t
 569          (bug "confused about home lambda for ~S" ctran))))
 570
 571 ;;; Return the LAMBDA that is CTRAN's home.
 572 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 573 (defun ctran-home-lambda (ctran)
 574   (ctran-home-lambda-or-null ctran))
 575
 576 (declaim (inline cast-single-value-p))
 577 (defun cast-single-value-p (cast)
 578   (not (values-type-p (cast-asserted-type cast))))
 579
 580 #!-sb-fluid (declaim (inline lvar-single-value-p))
 581 (defun lvar-single-value-p (lvar)
 582   (or (not lvar)
 583       (let ((dest (lvar-dest lvar)))
 584         (typecase dest
 585           ((or creturn exit)
 586            nil)
 587           (mv-combination
 588            (eq (basic-combination-fun dest) lvar))
 589           (cast
 590            (locally
 591                (declare (notinline lvar-single-value-p))
 592              (and (cast-single-value-p dest)
 593                   (lvar-single-value-p (node-lvar dest)))))
 594           (t
 595            t)))))
 596
 597 (defun principal-lvar-end (lvar)
 598   (loop for prev = lvar then (node-lvar dest)
 599         for dest = (and prev (lvar-dest prev))
 600         while (cast-p dest)
 601         finally (return (values dest prev))))
 602
 603 (defun principal-lvar-single-valuify (lvar)
 604   (loop for prev = lvar then (node-lvar dest)
 605         for dest = (and prev (lvar-dest prev))
 606         while (cast-p dest)
 607         do (setf (node-derived-type dest)
 608                  (make-short-values-type (list (single-value-type
 609                                                 (node-derived-type dest)))))
 610         (reoptimize-lvar prev)))
 611 \f
 612 ;;; Return a new LEXENV just like DEFAULT except for the specified
 613 ;;; slot values. Values for the alist slots are NCONCed to the
 614 ;;; beginning of the current value, rather than replacing it entirely.
 615 (defun make-lexenv (&key (default *lexenv*)
 616                          funs vars blocks tags
 617                          type-restrictions
 618                          (lambda (lexenv-lambda default))
 619                          (cleanup (lexenv-cleanup default))
 620                          (handled-conditions (lexenv-handled-conditions default))
 621                          (disabled-package-locks
 622                           (lexenv-disabled-package-locks default))
 623                          (policy (lexenv-policy default)))
 624   (macrolet ((frob (var slot)
 625                `(let ((old (,slot default)))
 626                   (if ,var
 627                       (nconc ,var old)
 628                       old))))
 629     (internal-make-lexenv
 630      (frob funs lexenv-funs)
 631      (frob vars lexenv-vars)
 632      (frob blocks lexenv-blocks)
 633      (frob tags lexenv-tags)
 634      (frob type-restrictions lexenv-type-restrictions)
 635      lambda cleanup handled-conditions
 636      disabled-package-locks policy)))
 637
 638 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 639 ;;; macroexpander
 640 (defun make-restricted-lexenv (lexenv)
 641   (flet ((fun-good-p (fun)
 642            (destructuring-bind (name . thing) fun
 643              (declare (ignore name))
 644              (etypecase thing
 645                (functional nil)
 646                (global-var t)
 647                (cons (aver (eq (car thing) 'macro))
 648                      t))))
 649          (var-good-p (var)
 650            (destructuring-bind (name . thing) var
 651              (declare (ignore name))
 652              (etypecase thing
 653                ;; The evaluator will mark lexicals with :BOGUS when it
 654                ;; translates an interpreter lexenv to a compiler
 655                ;; lexenv.
 656                ((or leaf #!+sb-eval (member :bogus)) nil)
 657                (cons (aver (eq (car thing) 'macro))
 658                      t)
 659                (heap-alien-info nil)))))
 660     (internal-make-lexenv
 661      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 662      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 663      nil
 664      nil
 665      (lexenv-type-restrictions lexenv) ; XXX
 666      nil
 667      nil
 668      (lexenv-handled-conditions lexenv)
 669      (lexenv-disabled-package-locks lexenv)
 670      (lexenv-policy lexenv))))
 671 \f
 672 ;;;; flow/DFO/component hackery
 673
 674 ;;; Join BLOCK1 and BLOCK2.
 675 (defun link-blocks (block1 block2)
 676   (declare (type cblock block1 block2))
 677   (setf (block-succ block1)
 678         (if (block-succ block1)
 679             (%link-blocks block1 block2)
 680             (list block2)))
 681   (push block1 (block-pred block2))
 682   (values))
 683 (defun %link-blocks (block1 block2)
 684   (declare (type cblock block1 block2))
 685   (let ((succ1 (block-succ block1)))
 686     (aver (not (memq block2 succ1)))
 687     (cons block2 succ1)))
 688
 689 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 690 ;;; this leaves a successor with a single predecessor that ends in an
 691 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 692 ;;; now be able to be propagated to the successor.
 693 (defun unlink-blocks (block1 block2)
 694   (declare (type cblock block1 block2))
 695   (let ((succ1 (block-succ block1)))
 696     (if (eq block2 (car succ1))
 697         (setf (block-succ block1) (cdr succ1))
 698         (do ((succ (cdr succ1) (cdr succ))
 699              (prev succ1 succ))
 700             ((eq (car succ) block2)
 701              (setf (cdr prev) (cdr succ)))
 702           (aver succ))))
 703
 704   (let ((new-pred (delq block1 (block-pred block2))))
 705     (setf (block-pred block2) new-pred)
 706     (when (singleton-p new-pred)
 707       (let ((pred-block (first new-pred)))
 708         (when (if-p (block-last pred-block))
 709           (setf (block-test-modified pred-block) t)))))
 710   (values))
 711
 712 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 713 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 714 ;;; consequent/alternative blocks to point to NEW. We also set
 715 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 716 ;;; the new successor.
 717 (defun change-block-successor (block old new)
 718   (declare (type cblock new old block))
 719   (unlink-blocks block old)
 720   (let ((last (block-last block))
 721         (comp (block-component block)))
 722     (setf (component-reanalyze comp) t)
 723     (typecase last
 724       (cif
 725        (setf (block-test-modified block) t)
 726        (let* ((succ-left (block-succ block))
 727               (new (if (and (eq new (component-tail comp))
 728                             succ-left)
 729                        (first succ-left)
 730                        new)))
 731          (unless (memq new succ-left)
 732            (link-blocks block new))
 733          (macrolet ((frob (slot)
 734                       `(when (eq (,slot last) old)
 735                          (setf (,slot last) new))))
 736            (frob if-consequent)
 737            (frob if-alternative)
 738            (when (eq (if-consequent last)
 739                      (if-alternative last))
 740              (reoptimize-component (block-component block) :maybe)))))
 741       (t
 742        (unless (memq new (block-succ block))
 743          (link-blocks block new)))))
 744
 745   (values))
 746
 747 ;;; Unlink a block from the next/prev chain. We also null out the
 748 ;;; COMPONENT.
 749 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 750 (defun remove-from-dfo (block)
 751   (let ((next (block-next block))
 752         (prev (block-prev block)))
 753     (setf (block-component block) nil)
 754     (setf (block-next prev) next)
 755     (setf (block-prev next) prev))
 756   (values))
 757
 758 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 759 ;;; COMPONENT to be the same as for AFTER.
 760 (defun add-to-dfo (block after)
 761   (declare (type cblock block after))
 762   (let ((next (block-next after))
 763         (comp (block-component after)))
 764     (aver (not (eq (component-kind comp) :deleted)))
 765     (setf (block-component block) comp)
 766     (setf (block-next after) block)
 767     (setf (block-prev block) after)
 768     (setf (block-next block) next)
 769     (setf (block-prev next) block))
 770   (values))
 771
 772 ;;; List all NLX-INFOs which BLOCK can exit to.
 773 ;;;
 774 ;;; We hope that no cleanup actions are performed in the middle of
 775 ;;; BLOCK, so it is enough to look only at cleanups in the block
 776 ;;; end. The tricky thing is a special cleanup block; all its nodes
 777 ;;; have the same cleanup info, corresponding to the start, so the
 778 ;;; same approach returns safe result.
 779 (defun map-block-nlxes (fun block &optional dx-cleanup-fun)
 780   (loop for cleanup = (block-end-cleanup block)
 781         then (node-enclosing-cleanup (cleanup-mess-up cleanup))
 782         while cleanup
 783         do (let ((mess-up (cleanup-mess-up cleanup)))
 784              (case (cleanup-kind cleanup)
 785                ((:block :tagbody)
 786                 (aver (entry-p mess-up))
 787                 (loop for exit in (entry-exits mess-up)
 788                       for nlx-info = (exit-nlx-info exit)
 789                       do (funcall fun nlx-info)))
 790                ((:catch :unwind-protect)
 791                 (aver (combination-p mess-up))
 792                 (let* ((arg-lvar (first (basic-combination-args mess-up)))
 793                        (nlx-info (constant-value (ref-leaf (lvar-use arg-lvar)))))
 794                 (funcall fun nlx-info)))
 795                ((:dynamic-extent)
 796                 (when dx-cleanup-fun
 797                   (funcall dx-cleanup-fun cleanup)))))))
 798
 799 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 800 ;;; the head and tail which are set to T.
 801 (declaim (ftype (sfunction (component) (values)) clear-flags))
 802 (defun clear-flags (component)
 803   (let ((head (component-head component))
 804         (tail (component-tail component)))
 805     (setf (block-flag head) t)
 806     (setf (block-flag tail) t)
 807     (do-blocks (block component)
 808       (setf (block-flag block) nil)))
 809   (values))
 810
 811 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 812 ;;; true in the head and tail blocks.
 813 (declaim (ftype (sfunction () component) make-empty-component))
 814 (defun make-empty-component ()
 815   (let* ((head (make-block-key :start nil :component nil))
 816          (tail (make-block-key :start nil :component nil))
 817          (res (make-component head tail)))
 818     (setf (block-flag head) t)
 819     (setf (block-flag tail) t)
 820     (setf (block-component head) res)
 821     (setf (block-component tail) res)
 822     (setf (block-next head) tail)
 823     (setf (block-prev tail) head)
 824     res))
 825
 826 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 827 ;;; The new block is added to the DFO immediately following NODE's block.
 828 (defun node-ends-block (node)
 829   (declare (type node node))
 830   (let* ((block (node-block node))
 831          (start (node-next node))
 832          (last (block-last block)))
 833     (check-type last node)
 834     (unless (eq last node)
 835       (aver (and (eq (ctran-kind start) :inside-block)
 836                  (not (block-delete-p block))))
 837       (let* ((succ (block-succ block))
 838              (new-block
 839               (make-block-key :start start
 840                               :component (block-component block)
 841                               :succ succ :last last)))
 842         (setf (ctran-kind start) :block-start)
 843         (setf (ctran-use start) nil)
 844         (setf (block-last block) node)
 845         (setf (node-next node) nil)
 846         (dolist (b succ)
 847           (setf (block-pred b)
 848                 (cons new-block (remove block (block-pred b)))))
 849         (setf (block-succ block) ())
 850         (link-blocks block new-block)
 851         (add-to-dfo new-block block)
 852         (setf (component-reanalyze (block-component block)) t)
 853
 854         (do ((ctran start (node-next (ctran-next ctran))))
 855             ((not ctran))
 856           (setf (ctran-block ctran) new-block))
 857
 858         (setf (block-type-asserted block) t)
 859         (setf (block-test-modified block) t))))
 860   (values))
 861 \f
 862 ;;;; deleting stuff
 863
 864 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 865 (defun delete-lambda-var (leaf)
 866   (declare (type lambda-var leaf))
 867
 868   ;; Iterate over all local calls flushing the corresponding argument,
 869   ;; allowing the computation of the argument to be deleted. We also
 870   ;; mark the LET for reoptimization, since it may be that we have
 871   ;; deleted its last variable.
 872   (let* ((fun (lambda-var-home leaf))
 873          (n (position leaf (lambda-vars fun))))
 874     (dolist (ref (leaf-refs fun))
 875       (let* ((lvar (node-lvar ref))
 876              (dest (and lvar (lvar-dest lvar))))
 877         (when (and (combination-p dest)
 878                    (eq (basic-combination-fun dest) lvar)
 879                    (eq (basic-combination-kind dest) :local))
 880           (let* ((args (basic-combination-args dest))
 881                  (arg (elt args n)))
 882             (reoptimize-lvar arg)
 883             (flush-dest arg)
 884             (setf (elt args n) nil))))))
 885
 886   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 887   ;; too much difficulty, since we can efficiently implement
 888   ;; write-only variables. We iterate over the SETs, marking their
 889   ;; blocks for dead code flushing, since we can delete SETs whose
 890   ;; value is unused.
 891   (dolist (set (lambda-var-sets leaf))
 892     (setf (block-flush-p (node-block set)) t))
 893
 894   (values))
 895
 896 ;;; Note that something interesting has happened to VAR.
 897 (defun reoptimize-lambda-var (var)
 898   (declare (type lambda-var var))
 899   (let ((fun (lambda-var-home var)))
 900     ;; We only deal with LET variables, marking the corresponding
 901     ;; initial value arg as needing to be reoptimized.
 902     (when (and (eq (functional-kind fun) :let)
 903                (leaf-refs var))
 904       (do ((args (basic-combination-args
 905                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 906                  (cdr args))
 907            (vars (lambda-vars fun) (cdr vars)))
 908           ((eq (car vars) var)
 909            (reoptimize-lvar (car args))))))
 910   (values))
 911
 912 ;;; Delete a function that has no references. This need only be called
 913 ;;; on functions that never had any references, since otherwise
 914 ;;; DELETE-REF will handle the deletion.
 915 (defun delete-functional (fun)
 916   (aver (and (null (leaf-refs fun))
 917              (not (functional-entry-fun fun))))
 918   (etypecase fun
 919     (optional-dispatch (delete-optional-dispatch fun))
 920     (clambda (delete-lambda fun)))
 921   (values))
 922
 923 ;;; Deal with deleting the last reference to a CLAMBDA, which means
 924 ;;; that the lambda is unreachable, so that its body may be
 925 ;;; deleted. We set FUNCTIONAL-KIND to :DELETED and rely on
 926 ;;; IR1-OPTIMIZE to delete its blocks.
 927 (defun delete-lambda (clambda)
 928   (declare (type clambda clambda))
 929   (let ((original-kind (functional-kind clambda))
 930         (bind (lambda-bind clambda)))
 931     (aver (not (member original-kind '(:deleted :toplevel))))
 932     (aver (not (functional-has-external-references-p clambda)))
 933     (aver (or (eq original-kind :zombie) bind))
 934     (setf (functional-kind clambda) :deleted)
 935     (setf (lambda-bind clambda) nil)
 936
 937     (labels ((delete-children (lambda)
 938                (dolist (child (lambda-children lambda))
 939                  (cond ((eq (functional-kind child) :deleted)
 940                         (delete-children child))
 941                        (t
 942                         (delete-lambda child))))
 943                (setf (lambda-children lambda) nil)
 944                (setf (lambda-parent lambda) nil)))
 945       (delete-children clambda))
 946
 947     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 948     ;; that we're using the old value of the KIND slot, not the
 949     ;; current slot value, which has now been set to :DELETED.)
 950     (case original-kind
 951       (:zombie)
 952       ((:let :mv-let :assignment)
 953        (let ((bind-block (node-block bind)))
 954          (mark-for-deletion bind-block))
 955        (let ((home (lambda-home clambda)))
 956          (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 957        ;; KLUDGE: In presence of NLEs we cannot always understand that
 958        ;; LET's BIND dominates its body [for a LET "its" body is not
 959        ;; quite its]; let's delete too dangerous for IR2 stuff. --
 960        ;; APD, 2004-01-01
 961        (dolist (var (lambda-vars clambda))
 962          (flet ((delete-node (node)
 963                   (mark-for-deletion (node-block node))))
 964          (mapc #'delete-node (leaf-refs var))
 965          (mapc #'delete-node (lambda-var-sets var)))))
 966       (t
 967        ;; Function has no reachable references.
 968        (dolist (ref (lambda-refs clambda))
 969          (mark-for-deletion (node-block ref)))
 970        ;; If the function isn't a LET, we unlink the function head
 971        ;; and tail from the component head and tail to indicate that
 972        ;; the code is unreachable. We also delete the function from
 973        ;; COMPONENT-LAMBDAS (it won't be there before local call
 974        ;; analysis, but no matter.) If the lambda was never
 975        ;; referenced, we give a note.
 976        (let* ((bind-block (node-block bind))
 977               (component (block-component bind-block))
 978               (return (lambda-return clambda))
 979               (return-block (and return (node-block return))))
 980          (unless (leaf-ever-used clambda)
 981            (let ((*compiler-error-context* bind))
 982              (compiler-notify 'code-deletion-note
 983                               :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 984                               :format-arguments (list (leaf-debug-name clambda)))))
 985          (unless (block-delete-p bind-block)
 986            (unlink-blocks (component-head component) bind-block))
 987          (when (and return-block (not (block-delete-p return-block)))
 988            (mark-for-deletion return-block)
 989            (unlink-blocks return-block (component-tail component)))
 990          (setf (component-reanalyze component) t)
 991          (let ((tails (lambda-tail-set clambda)))
 992            (setf (tail-set-funs tails)
 993                  (delete clambda (tail-set-funs tails)))
 994            (setf (lambda-tail-set clambda) nil))
 995          (setf (component-lambdas component)
 996                (delq clambda (component-lambdas component))))))
 997
 998     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 999     ;; ENTRY-FUN so that people will know that it is not an entry
1000     ;; point anymore.
1001     (when (eq original-kind :external)
1002       (let ((fun (functional-entry-fun clambda)))
1003         (setf (functional-entry-fun fun) nil)
1004         (when (optional-dispatch-p fun)
1005           (delete-optional-dispatch fun)))))
1006
1007   (values))
1008
1009 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
1010 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
1011 ;;; is used both before and after local call analysis. Afterward, all
1012 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
1013 ;;; to the XEP, leaving it with no references at all. So we look at
1014 ;;; the XEP to see whether an optional-dispatch is still really being
1015 ;;; used. But before local call analysis, there are no XEPs, and all
1016 ;;; references are direct.
1017 ;;;
1018 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
1019 ;;; entry-points, making them be normal lambdas, and then deleting the
1020 ;;; ones with no references. This deletes any e-p lambdas that were
1021 ;;; either never referenced, or couldn't be deleted when the last
1022 ;;; reference was deleted (due to their :OPTIONAL kind.)
1023 ;;;
1024 ;;; Note that the last optional entry point may alias the main entry,
1025 ;;; so when we process the main entry, its KIND may have been changed
1026 ;;; to NIL or even converted to a LETlike value.
1027 (defun delete-optional-dispatch (leaf)
1028   (declare (type optional-dispatch leaf))
1029   (let ((entry (functional-entry-fun leaf)))
1030     (unless (and entry (leaf-refs entry))
1031       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
1032       (setf (functional-kind leaf) :deleted)
1033
1034       (flet ((frob (fun)
1035                (unless (eq (functional-kind fun) :deleted)
1036                  (aver (eq (functional-kind fun) :optional))
1037                  (setf (functional-kind fun) nil)
1038                  (let ((refs (leaf-refs fun)))
1039                    (cond ((null refs)
1040                           (delete-lambda fun))
1041                          ((null (rest refs))
1042                           (or (maybe-let-convert fun)
1043                               (maybe-convert-to-assignment fun)))
1044                          (t
1045                           (maybe-convert-to-assignment fun)))))))
1046
1047         (dolist (ep (optional-dispatch-entry-points leaf))
1048           (when (promise-ready-p ep)
1049             (frob (force ep))))
1050         (when (optional-dispatch-more-entry leaf)
1051           (frob (optional-dispatch-more-entry leaf)))
1052         (let ((main (optional-dispatch-main-entry leaf)))
1053           (when entry
1054             (setf (functional-entry-fun entry) main)
1055             (setf (functional-entry-fun main) entry))
1056           (when (eq (functional-kind main) :optional)
1057             (frob main))))))
1058
1059   (values))
1060
1061 (defun note-local-functional (fun)
1062   (declare (type functional fun))
1063   (when (and (leaf-has-source-name-p fun)
1064              (eq (leaf-source-name fun) (functional-debug-name fun)))
1065     (let ((name (leaf-source-name fun)))
1066       (let ((defined-fun (gethash name *free-funs*)))
1067         (when (and defined-fun
1068                    (defined-fun-p defined-fun)
1069                    (eq (defined-fun-functional defined-fun) fun))
1070           (remhash name *free-funs*))))))
1071
1072 ;;; Do stuff to delete the semantic attachments of a REF node. When
1073 ;;; this leaves zero or one reference, we do a type dispatch off of
1074 ;;; the leaf to determine if a special action is appropriate.
1075 (defun delete-ref (ref)
1076   (declare (type ref ref))
1077   (let* ((leaf (ref-leaf ref))
1078          (refs (delq ref (leaf-refs leaf))))
1079     (setf (leaf-refs leaf) refs)
1080
1081     (cond ((null refs)
1082            (typecase leaf
1083              (lambda-var
1084               (delete-lambda-var leaf))
1085              (clambda
1086               (ecase (functional-kind leaf)
1087                 ((nil :let :mv-let :assignment :escape :cleanup)
1088                  (aver (null (functional-entry-fun leaf)))
1089                  (delete-lambda leaf))
1090                 (:external
1091                  (delete-lambda leaf))
1092                 ((:deleted :zombie :optional))))
1093              (optional-dispatch
1094               (unless (eq (functional-kind leaf) :deleted)
1095                 (delete-optional-dispatch leaf)))))
1096           ((null (rest refs))
1097            (typecase leaf
1098              (clambda (or (maybe-let-convert leaf)
1099                           (maybe-convert-to-assignment leaf)))
1100              (lambda-var (reoptimize-lambda-var leaf))))
1101           (t
1102            (typecase leaf
1103              (clambda (maybe-convert-to-assignment leaf))))))
1104
1105   (values))
1106
1107 ;;; This function is called by people who delete nodes; it provides a
1108 ;;; way to indicate that the value of a lvar is no longer used. We
1109 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
1110 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
1111 (defun flush-dest (lvar)
1112   (declare (type (or lvar null) lvar))
1113   (unless (null lvar)
1114     (setf (lvar-dest lvar) nil)
1115     (flush-lvar-externally-checkable-type lvar)
1116     (do-uses (use lvar)
1117       (let ((prev (node-prev use)))
1118         (let ((block (ctran-block prev)))
1119           (reoptimize-component (block-component block) t)
1120           (setf (block-attributep (block-flags block)
1121                                   flush-p type-asserted type-check)
1122                 t)))
1123       (setf (node-lvar use) nil))
1124     (setf (lvar-uses lvar) nil))
1125   (values))
1126
1127 (defun delete-dest (lvar)
1128   (when lvar
1129     (let* ((dest (lvar-dest lvar))
1130            (prev (node-prev dest)))
1131       (let ((block (ctran-block prev)))
1132         (unless (block-delete-p block)
1133           (mark-for-deletion block))))))
1134
1135 ;;; Queue the block for deletion
1136 (defun delete-block-lazily (block)
1137   (declare (type cblock block))
1138   (unless (block-delete-p block)
1139     (setf (block-delete-p block) t)
1140     (push block (component-delete-blocks (block-component block)))))
1141
1142 ;;; Do a graph walk backward from BLOCK, marking all predecessor
1143 ;;; blocks with the DELETE-P flag.
1144 (defun mark-for-deletion (block)
1145   (declare (type cblock block))
1146   (let* ((component (block-component block))
1147          (head (component-head component)))
1148     (labels ((helper (block)
1149                (delete-block-lazily block)
1150                (dolist (pred (block-pred block))
1151                  (unless (or (block-delete-p pred)
1152                              (eq pred head))
1153                    (helper pred)))))
1154       (unless (block-delete-p block)
1155         (helper block)
1156         (setf (component-reanalyze component) t))))
1157   (values))
1158
1159 ;;; This function does what is necessary to eliminate the code in it
1160 ;;; from the IR1 representation. This involves unlinking it from its
1161 ;;; predecessors and successors and deleting various node-specific
1162 ;;; semantic information. BLOCK must be already removed from
1163 ;;; COMPONENT-DELETE-BLOCKS.
1164 (defun delete-block (block &optional silent)
1165   (declare (type cblock block))
1166   (aver (block-component block))      ; else block is already deleted!
1167   #!+high-security (aver (not (memq block (component-delete-blocks (block-component block)))))
1168   (unless silent
1169     (note-block-deletion block))
1170   (setf (block-delete-p block) t)
1171
1172   (dolist (b (block-pred block))
1173     (unlink-blocks b block)
1174     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
1175     ;; broken when successors were deleted without setting the
1176     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
1177     ;; doesn't happen again.
1178     (aver (not (and (null (block-succ b))
1179                     (not (block-delete-p b))
1180                     (not (eq b (component-head (block-component b))))))))
1181   (dolist (b (block-succ block))
1182     (unlink-blocks block b))
1183
1184   (do-nodes-carefully (node block)
1185     (when (valued-node-p node)
1186       (delete-lvar-use node))
1187     (etypecase node
1188       (ref (delete-ref node))
1189       (cif (flush-dest (if-test node)))
1190       ;; The next two cases serve to maintain the invariant that a LET
1191       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1192       ;; the lambda whenever we delete any of these, but we must be
1193       ;; careful that this LET has not already been partially deleted.
1194       (basic-combination
1195        (when (and (eq (basic-combination-kind node) :local)
1196                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1197                   (lvar-uses (basic-combination-fun node)))
1198          (let ((fun (combination-lambda node)))
1199            ;; If our REF was the second-to-last ref, and has been
1200            ;; deleted, then FUN may be a LET for some other
1201            ;; combination.
1202            (when (and (functional-letlike-p fun)
1203                       (eq (let-combination fun) node))
1204              (delete-lambda fun))))
1205        (flush-dest (basic-combination-fun node))
1206        (dolist (arg (basic-combination-args node))
1207          (when arg (flush-dest arg))))
1208       (bind
1209        (let ((lambda (bind-lambda node)))
1210          (unless (eq (functional-kind lambda) :deleted)
1211            (delete-lambda lambda))))
1212       (exit
1213        (let ((value (exit-value node))
1214              (entry (exit-entry node)))
1215          (when value
1216            (flush-dest value))
1217          (when entry
1218            (setf (entry-exits entry)
1219                  (delq node (entry-exits entry))))))
1220       (entry
1221        (dolist (exit (entry-exits node))
1222          (mark-for-deletion (node-block exit)))
1223        (let ((home (node-home-lambda node)))
1224          (setf (lambda-entries home) (delq node (lambda-entries home)))))
1225       (creturn
1226        (flush-dest (return-result node))
1227        (delete-return node))
1228       (cset
1229        (flush-dest (set-value node))
1230        (let ((var (set-var node)))
1231          (setf (basic-var-sets var)
1232                (delete node (basic-var-sets var)))))
1233       (cast
1234        (flush-dest (cast-value node)))))
1235
1236   (remove-from-dfo block)
1237   (values))
1238
1239 ;;; Do stuff to indicate that the return node NODE is being deleted.
1240 (defun delete-return (node)
1241   (declare (type creturn node))
1242   (let* ((fun (return-lambda node))
1243          (tail-set (lambda-tail-set fun)))
1244     (aver (lambda-return fun))
1245     (setf (lambda-return fun) nil)
1246     (when (and tail-set (not (find-if #'lambda-return
1247                                       (tail-set-funs tail-set))))
1248       (setf (tail-set-type tail-set) *empty-type*)))
1249   (values))
1250
1251 ;;; If any of the VARS in FUN was never referenced and was not
1252 ;;; declared IGNORE, then complain.
1253 (defun note-unreferenced-vars (fun)
1254   (declare (type clambda fun))
1255   (dolist (var (lambda-vars fun))
1256     (unless (or (leaf-ever-used var)
1257                 (lambda-var-ignorep var))
1258       (let ((*compiler-error-context* (lambda-bind fun)))
1259         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1260           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1261           ;; requires this to be no more than a STYLE-WARNING.
1262           #-sb-xc-host
1263           (compiler-style-warn "The variable ~S is defined but never used."
1264                                (leaf-debug-name var))
1265           ;; There's no reason to accept this kind of equivocation
1266           ;; when compiling our own code, though.
1267           #+sb-xc-host
1268           (warn "The variable ~S is defined but never used."
1269                 (leaf-debug-name var)))
1270         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1271   (values))
1272
1273 (defvar *deletion-ignored-objects* '(t nil))
1274
1275 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1276 ;;; our recursion so that we don't get lost in circular structures. We
1277 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1278 ;;; function referencess with variables), and we also ignore anything
1279 ;;; inside ' or #'.
1280 (defun present-in-form (obj form depth)
1281   (declare (type (integer 0 20) depth))
1282   (cond ((= depth 20) nil)
1283         ((eq obj form) t)
1284         ((atom form) nil)
1285         (t
1286          (let ((first (car form))
1287                (depth (1+ depth)))
1288            (if (member first '(quote function))
1289                nil
1290                (or (and (not (symbolp first))
1291                         (present-in-form obj first depth))
1292                    (do ((l (cdr form) (cdr l))
1293                         (n 0 (1+ n)))
1294                        ((or (atom l) (> n 100))
1295                         nil)
1296                      (declare (fixnum n))
1297                      (when (present-in-form obj (car l) depth)
1298                        (return t)))))))))
1299
1300 ;;; This function is called on a block immediately before we delete
1301 ;;; it. We check to see whether any of the code about to die appeared
1302 ;;; in the original source, and emit a note if so.
1303 ;;;
1304 ;;; If the block was in a lambda is now deleted, then we ignore the
1305 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1306 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1307 ;;; reasonable for a function to not return, and there is a different
1308 ;;; note for that case anyway.
1309 ;;;
1310 ;;; If the actual source is an atom, then we use a bunch of heuristics
1311 ;;; to guess whether this reference really appeared in the original
1312 ;;; source:
1313 ;;; -- If a symbol, it must be interned and not a keyword.
1314 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1315 ;;;    or a character.)
1316 ;;; -- The atom must be "present" in the original source form, and
1317 ;;;    present in all intervening actual source forms.
1318 (defun note-block-deletion (block)
1319   (let ((home (block-home-lambda block)))
1320     (unless (eq (functional-kind home) :deleted)
1321       (do-nodes (node nil block)
1322         (let* ((path (node-source-path node))
1323                (first (first path)))
1324           (when (or (eq first 'original-source-start)
1325                     (and (atom first)
1326                          (or (not (symbolp first))
1327                              (let ((pkg (symbol-package first)))
1328                                (and pkg
1329                                     (not (eq pkg (symbol-package :end))))))
1330                          (not (member first *deletion-ignored-objects*))
1331                          (not (typep first '(or fixnum character)))
1332                          (every (lambda (x)
1333                                   (present-in-form first x 0))
1334                                 (source-path-forms path))
1335                          (present-in-form first (find-original-source path)
1336                                           0)))
1337             (unless (return-p node)
1338               (let ((*compiler-error-context* node))
1339                 (compiler-notify 'code-deletion-note
1340                                  :format-control "deleting unreachable code"
1341                                  :format-arguments nil)))
1342             (return))))))
1343   (values))
1344
1345 ;;; Delete a node from a block, deleting the block if there are no
1346 ;;; nodes left. We remove the node from the uses of its LVAR.
1347 ;;;
1348 ;;; If the node is the last node, there must be exactly one successor.
1349 ;;; We link all of our precedessors to the successor and unlink the
1350 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1351 ;;; left, and the block is a successor of itself, then we replace the
1352 ;;; only node with a degenerate exit node. This provides a way to
1353 ;;; represent the bodyless infinite loop, given the prohibition on
1354 ;;; empty blocks in IR1.
1355 (defun unlink-node (node)
1356   (declare (type node node))
1357   (when (valued-node-p node)
1358     (delete-lvar-use node))
1359
1360   (let* ((ctran (node-next node))
1361          (next (and ctran (ctran-next ctran)))
1362          (prev (node-prev node))
1363          (block (ctran-block prev))
1364          (prev-kind (ctran-kind prev))
1365          (last (block-last block)))
1366
1367     (setf (block-type-asserted block) t)
1368     (setf (block-test-modified block) t)
1369
1370     (cond ((or (eq prev-kind :inside-block)
1371                (and (eq prev-kind :block-start)
1372                     (not (eq node last))))
1373            (cond ((eq node last)
1374                   (setf (block-last block) (ctran-use prev))
1375                   (setf (node-next (ctran-use prev)) nil))
1376                  (t
1377                   (setf (ctran-next prev) next)
1378                   (setf (node-prev next) prev)
1379                   (when (if-p next) ; AOP wanted
1380                     (reoptimize-lvar (if-test next)))))
1381            (setf (node-prev node) nil)
1382            nil)
1383           (t
1384            (aver (eq prev-kind :block-start))
1385            (aver (eq node last))
1386            (let* ((succ (block-succ block))
1387                   (next (first succ)))
1388              (aver (singleton-p succ))
1389              (cond
1390               ((eq block (first succ))
1391                (with-ir1-environment-from-node node
1392                  (let ((exit (make-exit)))
1393                    (setf (ctran-next prev) nil)
1394                    (link-node-to-previous-ctran exit prev)
1395                    (setf (block-last block) exit)))
1396                (setf (node-prev node) nil)
1397                nil)
1398               (t
1399                (aver (eq (block-start-cleanup block)
1400                          (block-end-cleanup block)))
1401                (unlink-blocks block next)
1402                (dolist (pred (block-pred block))
1403                  (change-block-successor pred block next))
1404                (when (block-delete-p block)
1405                  (let ((component (block-component block)))
1406                    (setf (component-delete-blocks component)
1407                          (delq block (component-delete-blocks component)))))
1408                (remove-from-dfo block)
1409                (setf (block-delete-p block) t)
1410                (setf (node-prev node) nil)
1411                t)))))))
1412
1413 ;;; Return true if CTRAN has been deleted, false if it is still a valid
1414 ;;; part of IR1.
1415 (defun ctran-deleted-p (ctran)
1416   (declare (type ctran ctran))
1417   (let ((block (ctran-block ctran)))
1418     (or (not (block-component block))
1419         (block-delete-p block))))
1420
1421 ;;; Return true if NODE has been deleted, false if it is still a valid
1422 ;;; part of IR1.
1423 (defun node-deleted (node)
1424   (declare (type node node))
1425   (let ((prev (node-prev node)))
1426     (or (not prev)
1427         (ctran-deleted-p prev))))
1428
1429 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1430 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1431 ;;; triggered by deletion.
1432 (defun delete-component (component)
1433   (declare (type component component))
1434   (aver (null (component-new-functionals component)))
1435   (setf (component-kind component) :deleted)
1436   (do-blocks (block component)
1437     (delete-block-lazily block))
1438   (dolist (fun (component-lambdas component))
1439     (unless (eq (functional-kind fun) :deleted)
1440       (setf (functional-kind fun) nil)
1441       (setf (functional-entry-fun fun) nil)
1442       (setf (leaf-refs fun) nil)
1443       (delete-functional fun)))
1444   (clean-component component)
1445   (values))
1446
1447 ;;; Remove all pending blocks to be deleted. Return the nearest live
1448 ;;; block after or equal to BLOCK.
1449 (defun clean-component (component &optional block)
1450   (loop while (component-delete-blocks component)
1451         ;; actual deletion of a block may queue new blocks
1452         do (let ((current (pop (component-delete-blocks component))))
1453              (when (eq block current)
1454                (setq block (block-next block)))
1455              (delete-block current)))
1456   block)
1457
1458 ;;; Convert code of the form
1459 ;;;   (FOO ... (FUN ...) ...)
1460 ;;; to
1461 ;;;   (FOO ...    ...    ...).
1462 ;;; In other words, replace the function combination FUN by its
1463 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1464 ;;; to blow out of whatever transform called this. Note, as the number
1465 ;;; of arguments changes, the transform must be prepared to return a
1466 ;;; lambda with a new lambda-list with the correct number of
1467 ;;; arguments.
1468 (defun splice-fun-args (lvar fun num-args)
1469   #!+sb-doc
1470   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1471    to feed directly to the LVAR-DEST of LVAR, which must be a
1472    combination."
1473   (declare (type lvar lvar)
1474            (type symbol fun)
1475            (type index num-args))
1476   (let ((outside (lvar-dest lvar))
1477         (inside (lvar-uses lvar)))
1478     (aver (combination-p outside))
1479     (unless (combination-p inside)
1480       (give-up-ir1-transform))
1481     (let ((inside-fun (combination-fun inside)))
1482       (unless (eq (lvar-fun-name inside-fun) fun)
1483         (give-up-ir1-transform))
1484       (let ((inside-args (combination-args inside)))
1485         (unless (= (length inside-args) num-args)
1486           (give-up-ir1-transform))
1487         (let* ((outside-args (combination-args outside))
1488                (arg-position (position lvar outside-args))
1489                (before-args (subseq outside-args 0 arg-position))
1490                (after-args (subseq outside-args (1+ arg-position))))
1491           (dolist (arg inside-args)
1492             (setf (lvar-dest arg) outside)
1493             (flush-lvar-externally-checkable-type arg))
1494           (setf (combination-args inside) nil)
1495           (setf (combination-args outside)
1496                 (append before-args inside-args after-args))
1497           (change-ref-leaf (lvar-uses inside-fun)
1498                            (find-free-fun 'list "???"))
1499           (setf (combination-fun-info inside) (info :function :info 'list)
1500                 (combination-kind inside) :known)
1501           (setf (node-derived-type inside) *wild-type*)
1502           (flush-dest lvar)
1503           (values))))))
1504
1505 (defun extract-fun-args (lvar fun num-args)
1506   (declare (type lvar lvar)
1507            (type (or symbol list) fun)
1508            (type index num-args))
1509   (let ((fun (if (listp fun) fun (list fun))))
1510     (let ((inside (lvar-uses lvar)))
1511       (unless (combination-p inside)
1512         (give-up-ir1-transform))
1513       (let ((inside-fun (combination-fun inside)))
1514         (unless (member (lvar-fun-name inside-fun) fun)
1515           (give-up-ir1-transform))
1516         (let ((inside-args (combination-args inside)))
1517           (unless (= (length inside-args) num-args)
1518             (give-up-ir1-transform))
1519           (values (lvar-fun-name inside-fun) inside-args))))))
1520
1521 (defun flush-combination (combination)
1522   (declare (type combination combination))
1523   (flush-dest (combination-fun combination))
1524   (dolist (arg (combination-args combination))
1525     (flush-dest arg))
1526   (unlink-node combination)
1527   (values))
1528
1529 \f
1530 ;;;; leaf hackery
1531
1532 ;;; Change the LEAF that a REF refers to.
1533 (defun change-ref-leaf (ref leaf)
1534   (declare (type ref ref) (type leaf leaf))
1535   (unless (eq (ref-leaf ref) leaf)
1536     (push ref (leaf-refs leaf))
1537     (delete-ref ref)
1538     (setf (ref-leaf ref) leaf)
1539     (setf (leaf-ever-used leaf) t)
1540     (let* ((ltype (leaf-type leaf))
1541            (vltype (make-single-value-type ltype)))
1542       (if (let* ((lvar (node-lvar ref))
1543                  (dest (and lvar (lvar-dest lvar))))
1544             (and (basic-combination-p dest)
1545                  (eq lvar (basic-combination-fun dest))
1546                  (csubtypep ltype (specifier-type 'function))))
1547           (setf (node-derived-type ref) vltype)
1548           (derive-node-type ref vltype)))
1549     (reoptimize-lvar (node-lvar ref)))
1550   (values))
1551
1552 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1553 (defun substitute-leaf (new-leaf old-leaf)
1554   (declare (type leaf new-leaf old-leaf))
1555   (dolist (ref (leaf-refs old-leaf))
1556     (change-ref-leaf ref new-leaf))
1557   (values))
1558
1559 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1560 ;;; whether to substitute
1561 (defun substitute-leaf-if (test new-leaf old-leaf)
1562   (declare (type leaf new-leaf old-leaf) (type function test))
1563   (dolist (ref (leaf-refs old-leaf))
1564     (when (funcall test ref)
1565       (change-ref-leaf ref new-leaf)))
1566   (values))
1567
1568 ;;; Return a LEAF which represents the specified constant object. If
1569 ;;; the object is not in *CONSTANTS*, then we create a new constant
1570 ;;; LEAF and enter it. If we are producing a fasl file, make sure that
1571 ;;; MAKE-LOAD-FORM gets used on any parts of the constant that it
1572 ;;; needs to be.
1573 ;;;
1574 ;;; We are allowed to coalesce things like EQUAL strings and bit-vectors
1575 ;;; when file-compiling, but not when using COMPILE.
1576 (defun find-constant (object &optional (name nil namep))
1577   (let ((faslp (producing-fasl-file)))
1578     (labels ((make-it ()
1579                (when faslp
1580                  (if namep
1581                      (maybe-emit-make-load-forms object name)
1582                      (maybe-emit-make-load-forms object)))
1583                (make-constant object))
1584              (core-coalesce-p (x)
1585                ;; True for things which retain their identity under EQUAL,
1586                ;; so we can safely share the same CONSTANT leaf between
1587                ;; multiple references.
1588                (or (typep x '(or symbol number character))
1589                    ;; Amusingly enough, we see CLAMBDAs --among other things--
1590                    ;; here, from compiling things like %ALLOCATE-CLOSUREs forms.
1591                    ;; No point in stuffing them in the hash-table.
1592                    (and (typep x 'instance)
1593                         (not (or (leaf-p x) (node-p x))))))
1594              (file-coalesce-p (x)
1595                ;; CLHS 3.2.4.2.2: We are also allowed to coalesce various
1596                ;; other things when file-compiling.
1597                (or (core-coalesce-p x)
1598                    (if (consp x)
1599                        (if (eq +code-coverage-unmarked+ (cdr x))
1600                            ;; These are already coalesced, and the CAR should
1601                            ;; always be OK, so no need to check.
1602                            t
1603                            (unless (maybe-cyclic-p x) ; safe for EQUAL?
1604                              (do ((y x (cdr y)))
1605                                  ((atom y) (file-coalesce-p y))
1606                                (unless (file-coalesce-p (car y))
1607                                  (return nil)))))
1608                        ;; We *could* coalesce base-strings as well, but we'd need
1609                        ;; a separate hash-table for that, since we are not allowed to
1610                        ;; coalesce base-strings with non-base-strings.
1611                        (typep x '(or (vector character) bit-vector)))))
1612              (coalescep (x)
1613                (if faslp (file-coalesce-p x) (core-coalesce-p x))))
1614       (if (and (boundp '*constants*) (coalescep object))
1615           (or (gethash object *constants*)
1616               (setf (gethash object *constants*)
1617                     (make-it)))
1618           (make-it)))))
1619 \f
1620 ;;; Return true if VAR would have to be closed over if environment
1621 ;;; analysis ran now (i.e. if there are any uses that have a different
1622 ;;; home lambda than VAR's home.)
1623 (defun closure-var-p (var)
1624   (declare (type lambda-var var))
1625   (let ((home (lambda-var-home var)))
1626     (cond ((eq (functional-kind home) :deleted)
1627            nil)
1628           (t (let ((home (lambda-home home)))
1629                (flet ((frob (l)
1630                         (find home l
1631                               :key #'node-home-lambda
1632                               :test #'neq)))
1633                  (or (frob (leaf-refs var))
1634                      (frob (basic-var-sets var)))))))))
1635
1636 ;;; If there is a non-local exit noted in ENTRY's environment that
1637 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1638 (defun find-nlx-info (exit)
1639   (declare (type exit exit))
1640   (let* ((entry (exit-entry exit))
1641          (cleanup (entry-cleanup entry))
1642         (block (first (block-succ (node-block exit)))))
1643     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1644       (when (and (eq (nlx-info-block nlx) block)
1645                  (eq (nlx-info-cleanup nlx) cleanup))
1646         (return nlx)))))
1647
1648 (defun nlx-info-lvar (nlx)
1649   (declare (type nlx-info nlx))
1650   (node-lvar (block-last (nlx-info-target nlx))))
1651 \f
1652 ;;;; functional hackery
1653
1654 (declaim (ftype (sfunction (functional) clambda) main-entry))
1655 (defun main-entry (functional)
1656   (etypecase functional
1657     (clambda functional)
1658     (optional-dispatch
1659      (optional-dispatch-main-entry functional))))
1660
1661 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1662 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1663 ;;; optional with null default and no SUPPLIED-P. There must be a
1664 ;;; &REST arg with no references.
1665 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1666 (defun looks-like-an-mv-bind (functional)
1667   (and (optional-dispatch-p functional)
1668        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1669            ((null arg) nil)
1670          (let ((info (lambda-var-arg-info (car arg))))
1671            (unless info (return nil))
1672            (case (arg-info-kind info)
1673              (:optional
1674               (when (or (arg-info-supplied-p info) (arg-info-default info))
1675                 (return nil)))
1676              (:rest
1677               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1678              (t
1679               (return nil)))))))
1680
1681 ;;; Return true if function is an external entry point. This is true
1682 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1683 ;;; (:TOPLEVEL kind.)
1684 (defun xep-p (fun)
1685   (declare (type functional fun))
1686   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1687
1688 ;;; If LVAR's only use is a non-notinline global function reference,
1689 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1690 ;;; is true, then we don't care if the leaf is NOTINLINE.
1691 (defun lvar-fun-name (lvar &optional notinline-ok)
1692   (declare (type lvar lvar))
1693   (let ((use (lvar-uses lvar)))
1694     (if (ref-p use)
1695         (let ((leaf (ref-leaf use)))
1696           (if (and (global-var-p leaf)
1697                    (eq (global-var-kind leaf) :global-function)
1698                    (or (not (defined-fun-p leaf))
1699                        (not (eq (defined-fun-inlinep leaf) :notinline))
1700                        notinline-ok))
1701               (leaf-source-name leaf)
1702               nil))
1703         nil)))
1704
1705 (defun lvar-fun-debug-name (lvar)
1706   (declare (type lvar lvar))
1707   (let ((uses (lvar-uses lvar)))
1708     (flet ((name1 (use)
1709              (leaf-debug-name (ref-leaf use))))
1710       (if (ref-p uses)
1711         (name1 uses)
1712         (mapcar #'name1 uses)))))
1713
1714 ;;; Return the source name of a combination. (This is an idiom
1715 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1716 (defun combination-fun-source-name (combination)
1717   (let ((ref (lvar-uses (combination-fun combination))))
1718     (leaf-source-name (ref-leaf ref))))
1719
1720 ;;; Return the COMBINATION node that is the call to the LET FUN.
1721 (defun let-combination (fun)
1722   (declare (type clambda fun))
1723   (aver (functional-letlike-p fun))
1724   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1725
1726 ;;; Return the initial value lvar for a LET variable, or NIL if there
1727 ;;; is none.
1728 (defun let-var-initial-value (var)
1729   (declare (type lambda-var var))
1730   (let ((fun (lambda-var-home var)))
1731     (elt (combination-args (let-combination fun))
1732          (position-or-lose var (lambda-vars fun)))))
1733
1734 ;;; Return the LAMBDA that is called by the local CALL.
1735 (defun combination-lambda (call)
1736   (declare (type basic-combination call))
1737   (aver (eq (basic-combination-kind call) :local))
1738   (ref-leaf (lvar-uses (basic-combination-fun call))))
1739
1740 (defvar *inline-expansion-limit* 200
1741   #!+sb-doc
1742   "an upper limit on the number of inline function calls that will be expanded
1743    in any given code object (single function or block compilation)")
1744
1745 ;;; Check whether NODE's component has exceeded its inline expansion
1746 ;;; limit, and warn if so, returning NIL.
1747 (defun inline-expansion-ok (node)
1748   (let ((expanded (incf (component-inline-expansions
1749                          (block-component
1750                           (node-block node))))))
1751     (cond ((> expanded *inline-expansion-limit*) nil)
1752           ((= expanded *inline-expansion-limit*)
1753            ;; FIXME: If the objective is to stop the recursive
1754            ;; expansion of inline functions, wouldn't it be more
1755            ;; correct to look back through surrounding expansions
1756            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1757            ;; possibly stored elsewhere too) and suppress expansion
1758            ;; and print this warning when the function being proposed
1759            ;; for inline expansion is found there? (I don't like the
1760            ;; arbitrary numerical limit in principle, and I think
1761            ;; it'll be a nuisance in practice if we ever want the
1762            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1763            ;; arbitrarily huge blocks of code. -- WHN)
1764            (let ((*compiler-error-context* node))
1765              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1766                                probably trying to~%  ~
1767                                inline a recursive function."
1768                               *inline-expansion-limit*))
1769            nil)
1770           (t t))))
1771
1772 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1773 (defun assure-functional-live-p (functional)
1774   (declare (type functional functional))
1775   (when (and (or
1776               ;; looks LET-converted
1777               (functional-somewhat-letlike-p functional)
1778               ;; It's possible for a LET-converted function to end up
1779               ;; deleted later. In that case, for the purposes of this
1780               ;; analysis, it is LET-converted: LET-converted functionals
1781               ;; are too badly trashed to expand them inline, and deleted
1782               ;; LET-converted functionals are even worse.
1783               (memq (functional-kind functional) '(:deleted :zombie))))
1784     (throw 'locall-already-let-converted functional)))
1785
1786 (defun call-full-like-p (call)
1787   (declare (type combination call))
1788   (let ((kind (basic-combination-kind call)))
1789     (or (eq kind :full)
1790         (and (eq kind :known)
1791              (let ((info (basic-combination-fun-info call)))
1792                (and
1793                 (not (fun-info-ir2-convert info))
1794                 (dolist (template (fun-info-templates info) t)
1795                   (when (eq (template-ltn-policy template) :fast-safe)
1796                     (multiple-value-bind (val win)
1797                        (valid-fun-use call (template-type template))
1798                       (when (or val (not win)) (return nil)))))))))))
1799 \f
1800 ;;;; careful call
1801
1802 ;;; Apply a function to some arguments, returning a list of the values
1803 ;;; resulting of the evaluation. If an error is signalled during the
1804 ;;; application, then we produce a warning message using WARN-FUN and
1805 ;;; return NIL as our second value to indicate this. NODE is used as
1806 ;;; the error context for any error message, and CONTEXT is a string
1807 ;;; that is spliced into the warning.
1808 (declaim (ftype (sfunction ((or symbol function) list node function string)
1809                           (values list boolean))
1810                 careful-call))
1811 (defun careful-call (function args node warn-fun context)
1812   (values
1813    (multiple-value-list
1814     (handler-case (apply function args)
1815       (error (condition)
1816         (let ((*compiler-error-context* node))
1817           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1818           (return-from careful-call (values nil nil))))))
1819    t))
1820
1821 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1822 ;;; specifiers.
1823 (macrolet
1824     ((deffrob (basic careful compiler transform)
1825        `(progn
1826           (defun ,careful (specifier)
1827             (handler-case (,basic specifier)
1828               (sb!kernel::arg-count-error (condition)
1829                 (values nil (list (format nil "~A" condition))))
1830               (simple-error (condition)
1831                 (values nil (list* (simple-condition-format-control condition)
1832                                    (simple-condition-format-arguments condition))))))
1833           (defun ,compiler (specifier)
1834             (multiple-value-bind (type error-args) (,careful specifier)
1835               (or type
1836                   (apply #'compiler-error error-args))))
1837           (defun ,transform (specifier)
1838             (multiple-value-bind (type error-args) (,careful specifier)
1839               (or type
1840                   (apply #'give-up-ir1-transform
1841                          error-args)))))))
1842   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1843   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1844
1845 \f
1846 ;;;; utilities used at run-time for parsing &KEY args in IR1
1847
1848 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1849 ;;; the lvar for the value of the &KEY argument KEY in the list of
1850 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1851 ;;; otherwise. The legality and constantness of the keywords should
1852 ;;; already have been checked.
1853 (declaim (ftype (sfunction (list keyword) (or lvar null))
1854                 find-keyword-lvar))
1855 (defun find-keyword-lvar (args key)
1856   (do ((arg args (cddr arg)))
1857       ((null arg) nil)
1858     (when (eq (lvar-value (first arg)) key)
1859       (return (second arg)))))
1860
1861 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1862 ;;; verify that alternating lvars in ARGS are constant and that there
1863 ;;; is an even number of args.
1864 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1865 (defun check-key-args-constant (args)
1866   (do ((arg args (cddr arg)))
1867       ((null arg) t)
1868     (unless (and (rest arg)
1869                  (constant-lvar-p (first arg)))
1870       (return nil))))
1871
1872 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1873 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1874 ;;; and that only keywords present in the list KEYS are supplied.
1875 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1876 (defun check-transform-keys (args keys)
1877   (and (check-key-args-constant args)
1878        (do ((arg args (cddr arg)))
1879            ((null arg) t)
1880          (unless (member (lvar-value (first arg)) keys)
1881            (return nil)))))
1882 \f
1883 ;;;; miscellaneous
1884
1885 ;;; Called by the expansion of the EVENT macro.
1886 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1887 (defun %event (info node)
1888   (incf (event-info-count info))
1889   (when (and (>= (event-info-level info) *event-note-threshold*)
1890              (policy (or node *lexenv*)
1891                      (= inhibit-warnings 0)))
1892     (let ((*compiler-error-context* node))
1893       (compiler-notify (event-info-description info))))
1894
1895   (let ((action (event-info-action info)))
1896     (when action (funcall action node))))
1897
1898 ;;;
1899 (defun make-cast (value type policy)
1900   (declare (type lvar value)
1901            (type ctype type)
1902            (type policy policy))
1903   (%make-cast :asserted-type type
1904               :type-to-check (maybe-weaken-check type policy)
1905               :value value
1906               :derived-type (coerce-to-values type)))
1907
1908 (defun cast-type-check (cast)
1909   (declare (type cast cast))
1910   (when (cast-reoptimize cast)
1911     (ir1-optimize-cast cast t))
1912   (cast-%type-check cast))
1913
1914 (defun note-single-valuified-lvar (lvar)
1915   (declare (type (or lvar null) lvar))
1916   (when lvar
1917     (let ((use (lvar-uses lvar)))
1918       (cond ((ref-p use)
1919              (let ((leaf (ref-leaf use)))
1920                (when (and (lambda-var-p leaf)
1921                           (null (rest (leaf-refs leaf))))
1922                  (reoptimize-lambda-var leaf))))
1923             ((or (listp use) (combination-p use))
1924              (do-uses (node lvar)
1925                (setf (node-reoptimize node) t)
1926                (setf (block-reoptimize (node-block node)) t)
1927                (reoptimize-component (node-component node) :maybe)))))))
1928
1929 ;;; True if LVAR is for 'NAME, or #'NAME (global, not local)
1930 (defun lvar-for-named-function (lvar name)
1931   (if (constant-lvar-p lvar)
1932       (eq name (lvar-value lvar))
1933       (let ((use (lvar-uses lvar)))
1934         (and (not (listp use))
1935              (ref-p use)
1936              (let ((leaf (ref-leaf use)))
1937                (and (global-var-p leaf)
1938                     (eq :global-function (global-var-kind leaf))
1939                     (eq name (leaf-source-name leaf))))))))