src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (defun principal-lvar-use (lvar)
  66   (let ((use (lvar-uses lvar)))
  67     (if (cast-p use)
  68         (principal-lvar-use (cast-value use))
  69         use)))
  70
  71 ;;; Update lvar use information so that NODE is no longer a use of its
  72 ;;; LVAR.
  73 ;;;
  74 ;;; Note: if you call this function, you may have to do a
  75 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  76 ;;; changed.
  77 (declaim (ftype (sfunction (node) (values))
  78                 delete-lvar-use
  79                 %delete-lvar-use))
  80 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  81 ;;; be given a new use.
  82 (defun %delete-lvar-use (node)
  83   (let* ((lvar (node-lvar node)))
  84     (when lvar
  85       (if (listp (lvar-uses lvar))
  86           (let ((new-uses (delq node (lvar-uses lvar))))
  87             (setf (lvar-uses lvar)
  88                   (if (singleton-p new-uses)
  89                       (first new-uses)
  90                       new-uses)))
  91           (setf (lvar-uses lvar) nil))
  92       (setf (node-lvar node) nil)))
  93   (values))
  94 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
  95 ;;; its DEST's block, which must be unreachable.
  96 (defun delete-lvar-use (node)
  97   (let ((lvar (node-lvar node)))
  98     (when lvar
  99       (%delete-lvar-use node)
 100       (if (null (lvar-uses lvar))
 101           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 102                      (() (not (node-deleted dest)) :exit-if-null)
 103                      (block (node-block dest)))
 104             (mark-for-deletion block))
 105           (reoptimize-lvar lvar))))
 106   (values))
 107
 108 ;;; Update lvar use information so that NODE uses LVAR.
 109 ;;;
 110 ;;; Note: if you call this function, you may have to do a
 111 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 112 ;;; changed.
 113 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 114 (defun add-lvar-use (node lvar)
 115   (aver (not (node-lvar node)))
 116   (when lvar
 117     (let ((uses (lvar-uses lvar)))
 118       (setf (lvar-uses lvar)
 119             (cond ((null uses)
 120                    node)
 121                   ((listp uses)
 122                    (cons node uses))
 123                   (t
 124                    (list node uses))))
 125       (setf (node-lvar node) lvar)))
 126
 127   (values))
 128
 129 ;;; Return true if LVAR destination is executed immediately after
 130 ;;; NODE. Cleanups are ignored.
 131 (defun immediately-used-p (lvar node)
 132   (declare (type lvar lvar) (type node node))
 133   (aver (eq (node-lvar node) lvar))
 134   (let ((dest (lvar-dest lvar)))
 135     (acond ((node-next node)
 136             (eq (ctran-next it) dest))
 137            (t (eq (block-start (first (block-succ (node-block node))))
 138                   (node-prev dest))))))
 139 \f
 140 ;;;; lvar substitution
 141
 142 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 143 ;;; NIL. We do not flush OLD's DEST.
 144 (defun substitute-lvar (new old)
 145   (declare (type lvar old new))
 146   (aver (not (lvar-dest new)))
 147   (let ((dest (lvar-dest old)))
 148     (etypecase dest
 149       ((or ref bind))
 150       (cif (setf (if-test dest) new))
 151       (cset (setf (set-value dest) new))
 152       (creturn (setf (return-result dest) new))
 153       (exit (setf (exit-value dest) new))
 154       (basic-combination
 155        (if (eq old (basic-combination-fun dest))
 156            (setf (basic-combination-fun dest) new)
 157            (setf (basic-combination-args dest)
 158                  (nsubst new old (basic-combination-args dest)))))
 159       (cast (setf (cast-value dest) new)))
 160
 161     (setf (lvar-dest old) nil)
 162     (setf (lvar-dest new) dest)
 163     (flush-lvar-externally-checkable-type new))
 164   (values))
 165
 166 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 167 ;;; arbitary number of uses.
 168 (defun substitute-lvar-uses (new old)
 169   (declare (type lvar old)
 170            (type (or lvar null) new))
 171
 172   (do-uses (node old)
 173     (%delete-lvar-use node)
 174     (when new
 175       (add-lvar-use node new)))
 176
 177   (when new (reoptimize-lvar new))
 178   (values))
 179 \f
 180 ;;;; block starting/creation
 181
 182 ;;; Return the block that CTRAN is the start of, making a block if
 183 ;;; necessary. This function is called by IR1 translators which may
 184 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 185 ;;; used more than once must start a block by the time that anyone
 186 ;;; does a USE-CTRAN on it.
 187 ;;;
 188 ;;; We also throw the block into the next/prev list for the
 189 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 190 ;;; made.
 191 (defun ctran-starts-block (ctran)
 192   (declare (type ctran ctran))
 193   (ecase (ctran-kind ctran)
 194     (:unused
 195      (aver (not (ctran-block ctran)))
 196      (let* ((next (component-last-block *current-component*))
 197             (prev (block-prev next))
 198             (new-block (make-block ctran)))
 199        (setf (block-next new-block) next
 200              (block-prev new-block) prev
 201              (block-prev next) new-block
 202              (block-next prev) new-block
 203              (ctran-block ctran) new-block
 204              (ctran-kind ctran) :block-start)
 205        (aver (not (ctran-use ctran)))
 206        new-block))
 207     (:block-start
 208      (ctran-block ctran))))
 209
 210 ;;; Ensure that CTRAN is the start of a block so that the use set can
 211 ;;; be freely manipulated.
 212 (defun ensure-block-start (ctran)
 213   (declare (type ctran ctran))
 214   (let ((kind (ctran-kind ctran)))
 215     (ecase kind
 216       ((:block-start))
 217       ((:unused)
 218        (setf (ctran-block ctran)
 219              (make-block-key :start ctran))
 220        (setf (ctran-kind ctran) :block-start))
 221       ((:inside-block)
 222        (node-ends-block (ctran-use ctran)))))
 223   (values))
 224 \f
 225 ;;;;
 226
 227 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 228 ;;; call. First argument must be 'DUMMY, which will be replaced with
 229 ;;; LVAR. In case of an ordinary call the function should not have
 230 ;;; return type NIL. We create a new "filtered" lvar.
 231 ;;;
 232 ;;; TODO: remove preconditions.
 233 (defun filter-lvar (lvar form)
 234   (declare (type lvar lvar) (type list form))
 235   (let* ((dest (lvar-dest lvar))
 236          (ctran (node-prev dest)))
 237     (with-ir1-environment-from-node dest
 238
 239       (ensure-block-start ctran)
 240       (let* ((old-block (ctran-block ctran))
 241              (new-start (make-ctran))
 242              (filtered-lvar (make-lvar))
 243              (new-block (ctran-starts-block new-start)))
 244
 245         ;; Splice in the new block before DEST, giving the new block
 246         ;; all of DEST's predecessors.
 247         (dolist (block (block-pred old-block))
 248           (change-block-successor block old-block new-block))
 249
 250         (ir1-convert new-start ctran filtered-lvar form)
 251
 252         ;; KLUDGE: Comments at the head of this function in CMU CL
 253         ;; said that somewhere in here we
 254         ;;   Set the new block's start and end cleanups to the *start*
 255         ;;   cleanup of PREV's block. This overrides the incorrect
 256         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 257         ;; Unfortunately I can't find any code which corresponds to this.
 258         ;; Perhaps it was a stale comment? Or perhaps I just don't
 259         ;; understand.. -- WHN 19990521
 260
 261         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 262         ;; no LET conversion has been done yet.) The [mv-]combination
 263         ;; code from the call in the form will be the use of the new
 264         ;; check lvar. We substitute for the first argument of
 265         ;; this node.
 266         (let* ((node (lvar-use filtered-lvar))
 267                (args (basic-combination-args node))
 268                (victim (first args)))
 269           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 270                     'dummy))
 271
 272           (substitute-lvar filtered-lvar lvar)
 273           (substitute-lvar lvar victim)
 274           (flush-dest victim))
 275
 276         ;; Invoking local call analysis converts this call to a LET.
 277         (locall-analyze-component *current-component*))))
 278   (values))
 279
 280 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 281 (defun delete-filter (node lvar value)
 282   (aver (eq (lvar-dest value) node))
 283   (aver (eq (node-lvar node) lvar))
 284   (cond (lvar (collect ((merges))
 285                 (when (return-p (lvar-dest lvar))
 286                   (do-uses (use value)
 287                     (when (and (basic-combination-p use)
 288                                (eq (basic-combination-kind use) :local))
 289                       (merges use))))
 290                 (%delete-lvar-use node)
 291                 (substitute-lvar-uses lvar value)
 292                 (prog1
 293                     (unlink-node node)
 294                   (dolist (merge (merges))
 295                     (merge-tail-sets merge)))))
 296         (t (flush-dest value)
 297            (unlink-node node))))
 298 \f
 299 ;;;; miscellaneous shorthand functions
 300
 301 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 302 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 303 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 304 ;;; deleted, and then return its home.
 305 (defun node-home-lambda (node)
 306   (declare (type node node))
 307   (do ((fun (lexenv-lambda (node-lexenv node))
 308             (lexenv-lambda (lambda-call-lexenv fun))))
 309       ((not (eq (functional-kind fun) :deleted))
 310        (lambda-home fun))
 311     (when (eq (lambda-home fun) fun)
 312       (return fun))))
 313
 314 #!-sb-fluid (declaim (inline node-block))
 315 (defun node-block (node)
 316   (ctran-block (node-prev node)))
 317 (declaim (ftype (sfunction (node) component) node-component))
 318 (defun node-component (node)
 319   (block-component (node-block node)))
 320 (declaim (ftype (sfunction (node) physenv) node-physenv))
 321 (defun node-physenv (node)
 322   (lambda-physenv (node-home-lambda node)))
 323 #!-sb-fluid (declaim (inline node-dest))
 324 (defun node-dest (node)
 325   (awhen (node-lvar node) (lvar-dest it)))
 326
 327 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 328 (defun lambda-block (clambda)
 329   (node-block (lambda-bind clambda)))
 330 (declaim (ftype (sfunction (clambda) component) lambda-component))
 331 (defun lambda-component (clambda)
 332   (block-component (lambda-block clambda)))
 333
 334 (declaim (ftype (sfunction (cblock) node) block-start-node))
 335 (defun block-start-node (block)
 336   (ctran-next (block-start block)))
 337
 338 ;;; Return the enclosing cleanup for environment of the first or last
 339 ;;; node in BLOCK.
 340 (defun block-start-cleanup (block)
 341   (node-enclosing-cleanup (block-start-node block)))
 342 (defun block-end-cleanup (block)
 343   (node-enclosing-cleanup (block-last block)))
 344
 345 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 346 ;;; if there is none.
 347 ;;;
 348 ;;; There can legitimately be no home lambda in dead code early in the
 349 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 350 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 351 ;;; where the block is just a placeholder during parsing and doesn't
 352 ;;; actually correspond to code which will be written anywhere.
 353 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 354 (defun block-home-lambda-or-null (block)
 355   (if (node-p (block-last block))
 356       ;; This is the old CMU CL way of doing it.
 357       (node-home-lambda (block-last block))
 358       ;; Now that SBCL uses this operation more aggressively than CMU
 359       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 360       ;;   1. It can fail in a few cases even when a meaningful home
 361       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 362       ;;      an IF.
 363       ;;   2. It can fail when converting a form which is born orphaned
 364       ;;      so that it never had a meaningful home lambda, e.g. a form
 365       ;;      which follows a RETURN-FROM or GO form.
 366       (let ((pred-list (block-pred block)))
 367         ;; To deal with case 1, we reason that
 368         ;; previous-in-target-execution-order blocks should be in the
 369         ;; same lambda, and that they seem in practice to be
 370         ;; previous-in-compilation-order blocks too, so we look back
 371         ;; to find one which is sufficiently initialized to tell us
 372         ;; what the home lambda is.
 373         (if pred-list
 374             ;; We could get fancy about this, flooding through the
 375             ;; graph of all the previous blocks, but in practice it
 376             ;; seems to work just to grab the first previous block and
 377             ;; use it.
 378             (node-home-lambda (block-last (first pred-list)))
 379             ;; In case 2, we end up with an empty PRED-LIST and
 380             ;; have to punt: There's no home lambda.
 381             nil))))
 382
 383 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 384 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 385 (defun block-home-lambda (block)
 386   (block-home-lambda-or-null block))
 387
 388 ;;; Return the IR1 physical environment for BLOCK.
 389 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 390 (defun block-physenv (block)
 391   (lambda-physenv (block-home-lambda block)))
 392
 393 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 394 ;;; of its original source's top level form in its compilation unit.
 395 (defun source-path-tlf-number (path)
 396   (declare (list path))
 397   (car (last path)))
 398
 399 ;;; Return the (reversed) list for the PATH in the original source
 400 ;;; (with the Top Level Form number last).
 401 (defun source-path-original-source (path)
 402   (declare (list path) (inline member))
 403   (cddr (member 'original-source-start path :test #'eq)))
 404
 405 ;;; Return the Form Number of PATH's original source inside the Top
 406 ;;; Level Form that contains it. This is determined by the order that
 407 ;;; we walk the subforms of the top level source form.
 408 (defun source-path-form-number (path)
 409   (declare (list path) (inline member))
 410   (cadr (member 'original-source-start path :test #'eq)))
 411
 412 ;;; Return a list of all the enclosing forms not in the original
 413 ;;; source that converted to get to this form, with the immediate
 414 ;;; source for node at the start of the list.
 415 (defun source-path-forms (path)
 416   (subseq path 0 (position 'original-source-start path)))
 417
 418 ;;; Return the innermost source form for NODE.
 419 (defun node-source-form (node)
 420   (declare (type node node))
 421   (let* ((path (node-source-path node))
 422          (forms (source-path-forms path)))
 423     (if forms
 424         (first forms)
 425         (values (find-original-source path)))))
 426
 427 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 428 ;;; NIL, NIL.
 429 (defun lvar-source (lvar)
 430   (let ((use (lvar-uses lvar)))
 431     (if (listp use)
 432         (values nil nil)
 433         (values (node-source-form use) t))))
 434
 435 ;;; Return the unique node, delivering a value to LVAR.
 436 #!-sb-fluid (declaim (inline lvar-use))
 437 (defun lvar-use (lvar)
 438   (the (not list) (lvar-uses lvar)))
 439
 440 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 441 (defun lvar-has-single-use-p (lvar)
 442   (typep (lvar-uses lvar) '(not list)))
 443
 444 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 445 (declaim (ftype (sfunction (ctran) (or clambda null))
 446                 ctran-home-lambda-or-null))
 447 (defun ctran-home-lambda-or-null (ctran)
 448   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 449   ;; implementation might not be quite right, or might be uglier than
 450   ;; necessary. It appears that the original Python never found a need
 451   ;; to do this operation. The obvious things based on
 452   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 453   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 454   ;; generalize it enough to grovel harder when the simple CMU CL
 455   ;; approach fails, and furthermore realize that in some exceptional
 456   ;; cases it might return NIL. -- WHN 2001-12-04
 457   (cond ((ctran-use ctran)
 458          (node-home-lambda (ctran-use ctran)))
 459         ((ctran-block ctran)
 460          (block-home-lambda-or-null (ctran-block ctran)))
 461         (t
 462          (bug "confused about home lambda for ~S" ctran))))
 463
 464 ;;; Return the LAMBDA that is CTRAN's home.
 465 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 466 (defun ctran-home-lambda (ctran)
 467   (ctran-home-lambda-or-null ctran))
 468
 469 #!-sb-fluid (declaim (inline lvar-single-value-p))
 470 (defun lvar-single-value-p (lvar)
 471   (or (not lvar)
 472       (let ((dest (lvar-dest lvar)))
 473         (typecase dest
 474           ((or creturn exit)
 475            nil)
 476           (mv-combination
 477            (eq (basic-combination-fun dest) lvar))
 478           (cast
 479            (locally
 480                (declare (notinline lvar-single-value-p))
 481              (and (not (values-type-p (cast-asserted-type dest)))
 482                   (lvar-single-value-p (node-lvar dest)))))
 483           (t
 484            t)))))
 485
 486 (defun principal-lvar-end (lvar)
 487   (loop for prev = lvar then (node-lvar dest)
 488         for dest = (and prev (lvar-dest prev))
 489         while (cast-p dest)
 490         finally (return (values dest prev))))
 491
 492 (defun principal-lvar-single-valuify (lvar)
 493   (loop for prev = lvar then (node-lvar dest)
 494         for dest = (and prev (lvar-dest prev))
 495         while (cast-p dest)
 496         do (setf (node-derived-type dest)
 497                  (make-short-values-type (list (single-value-type
 498                                                 (node-derived-type dest)))))
 499         (reoptimize-lvar prev)))
 500 \f
 501 ;;; Return a new LEXENV just like DEFAULT except for the specified
 502 ;;; slot values. Values for the alist slots are NCONCed to the
 503 ;;; beginning of the current value, rather than replacing it entirely.
 504 (defun make-lexenv (&key (default *lexenv*)
 505                          funs vars blocks tags
 506                          type-restrictions
 507                          (lambda (lexenv-lambda default))
 508                          (cleanup (lexenv-cleanup default))
 509                          (policy (lexenv-policy default)))
 510   (macrolet ((frob (var slot)
 511                `(let ((old (,slot default)))
 512                   (if ,var
 513                       (nconc ,var old)
 514                       old))))
 515     (internal-make-lexenv
 516      (frob funs lexenv-funs)
 517      (frob vars lexenv-vars)
 518      (frob blocks lexenv-blocks)
 519      (frob tags lexenv-tags)
 520      (frob type-restrictions lexenv-type-restrictions)
 521      lambda cleanup policy)))
 522
 523 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 524 ;;; macroexpander
 525 (defun make-restricted-lexenv (lexenv)
 526   (flet ((fun-good-p (fun)
 527            (destructuring-bind (name . thing) fun
 528              (declare (ignore name))
 529              (etypecase thing
 530                (functional nil)
 531                (global-var t)
 532                (cons (aver (eq (car thing) 'macro))
 533                      t))))
 534          (var-good-p (var)
 535            (destructuring-bind (name . thing) var
 536              (declare (ignore name))
 537              (etypecase thing
 538                (leaf nil)
 539                (cons (aver (eq (car thing) 'macro))
 540                      t)
 541                (heap-alien-info nil)))))
 542     (internal-make-lexenv
 543      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 544      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 545      nil
 546      nil
 547      (lexenv-type-restrictions lexenv) ; XXX
 548      nil
 549      nil
 550      (lexenv-policy lexenv))))
 551 \f
 552 ;;;; flow/DFO/component hackery
 553
 554 ;;; Join BLOCK1 and BLOCK2.
 555 (defun link-blocks (block1 block2)
 556   (declare (type cblock block1 block2))
 557   (setf (block-succ block1)
 558         (if (block-succ block1)
 559             (%link-blocks block1 block2)
 560             (list block2)))
 561   (push block1 (block-pred block2))
 562   (values))
 563 (defun %link-blocks (block1 block2)
 564   (declare (type cblock block1 block2))
 565   (let ((succ1 (block-succ block1)))
 566     (aver (not (memq block2 succ1)))
 567     (cons block2 succ1)))
 568
 569 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 570 ;;; this leaves a successor with a single predecessor that ends in an
 571 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 572 ;;; now be able to be propagated to the successor.
 573 (defun unlink-blocks (block1 block2)
 574   (declare (type cblock block1 block2))
 575   (let ((succ1 (block-succ block1)))
 576     (if (eq block2 (car succ1))
 577         (setf (block-succ block1) (cdr succ1))
 578         (do ((succ (cdr succ1) (cdr succ))
 579              (prev succ1 succ))
 580             ((eq (car succ) block2)
 581              (setf (cdr prev) (cdr succ)))
 582           (aver succ))))
 583
 584   (let ((new-pred (delq block1 (block-pred block2))))
 585     (setf (block-pred block2) new-pred)
 586     (when (singleton-p new-pred)
 587       (let ((pred-block (first new-pred)))
 588         (when (if-p (block-last pred-block))
 589           (setf (block-test-modified pred-block) t)))))
 590   (values))
 591
 592 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 593 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 594 ;;; consequent/alternative blocks to point to NEW. We also set
 595 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 596 ;;; the new successor.
 597 (defun change-block-successor (block old new)
 598   (declare (type cblock new old block))
 599   (unlink-blocks block old)
 600   (let ((last (block-last block))
 601         (comp (block-component block)))
 602     (setf (component-reanalyze comp) t)
 603     (typecase last
 604       (cif
 605        (setf (block-test-modified block) t)
 606        (let* ((succ-left (block-succ block))
 607               (new (if (and (eq new (component-tail comp))
 608                             succ-left)
 609                        (first succ-left)
 610                        new)))
 611          (unless (memq new succ-left)
 612            (link-blocks block new))
 613          (macrolet ((frob (slot)
 614                       `(when (eq (,slot last) old)
 615                          (setf (,slot last) new))))
 616            (frob if-consequent)
 617            (frob if-alternative)
 618            (when (eq (if-consequent last)
 619                      (if-alternative last))
 620              (setf (component-reoptimize (block-component block)) t)))))
 621       (t
 622        (unless (memq new (block-succ block))
 623          (link-blocks block new)))))
 624
 625   (values))
 626
 627 ;;; Unlink a block from the next/prev chain. We also null out the
 628 ;;; COMPONENT.
 629 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 630 (defun remove-from-dfo (block)
 631   (let ((next (block-next block))
 632         (prev (block-prev block)))
 633     (setf (block-component block) nil)
 634     (setf (block-next prev) next)
 635     (setf (block-prev next) prev))
 636   (values))
 637
 638 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 639 ;;; COMPONENT to be the same as for AFTER.
 640 (defun add-to-dfo (block after)
 641   (declare (type cblock block after))
 642   (let ((next (block-next after))
 643         (comp (block-component after)))
 644     (aver (not (eq (component-kind comp) :deleted)))
 645     (setf (block-component block) comp)
 646     (setf (block-next after) block)
 647     (setf (block-prev block) after)
 648     (setf (block-next block) next)
 649     (setf (block-prev next) block))
 650   (values))
 651
 652 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 653 ;;; the head and tail which are set to T.
 654 (declaim (ftype (sfunction (component) (values)) clear-flags))
 655 (defun clear-flags (component)
 656   (let ((head (component-head component))
 657         (tail (component-tail component)))
 658     (setf (block-flag head) t)
 659     (setf (block-flag tail) t)
 660     (do-blocks (block component)
 661       (setf (block-flag block) nil)))
 662   (values))
 663
 664 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 665 ;;; true in the head and tail blocks.
 666 (declaim (ftype (sfunction () component) make-empty-component))
 667 (defun make-empty-component ()
 668   (let* ((head (make-block-key :start nil :component nil))
 669          (tail (make-block-key :start nil :component nil))
 670          (res (make-component head tail)))
 671     (setf (block-flag head) t)
 672     (setf (block-flag tail) t)
 673     (setf (block-component head) res)
 674     (setf (block-component tail) res)
 675     (setf (block-next head) tail)
 676     (setf (block-prev tail) head)
 677     res))
 678
 679 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 680 ;;; The new block is added to the DFO immediately following NODE's block.
 681 (defun node-ends-block (node)
 682   (declare (type node node))
 683   (let* ((block (node-block node))
 684          (start (node-next node))
 685          (last (block-last block)))
 686     (unless (eq last node)
 687       (aver (and (eq (ctran-kind start) :inside-block)
 688                  (not (block-delete-p block))))
 689       (let* ((succ (block-succ block))
 690              (new-block
 691               (make-block-key :start start
 692                               :component (block-component block)
 693                               :succ succ :last last)))
 694         (setf (ctran-kind start) :block-start)
 695         (setf (ctran-use start) nil)
 696         (setf (block-last block) node)
 697         (setf (node-next node) nil)
 698         (dolist (b succ)
 699           (setf (block-pred b)
 700                 (cons new-block (remove block (block-pred b)))))
 701         (setf (block-succ block) ())
 702         (link-blocks block new-block)
 703         (add-to-dfo new-block block)
 704         (setf (component-reanalyze (block-component block)) t)
 705
 706         (do ((ctran start (node-next (ctran-next ctran))))
 707             ((not ctran))
 708           (setf (ctran-block ctran) new-block))
 709
 710         (setf (block-type-asserted block) t)
 711         (setf (block-test-modified block) t))))
 712   (values))
 713 \f
 714 ;;;; deleting stuff
 715
 716 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 717 (defun delete-lambda-var (leaf)
 718   (declare (type lambda-var leaf))
 719
 720   ;; Iterate over all local calls flushing the corresponding argument,
 721   ;; allowing the computation of the argument to be deleted. We also
 722   ;; mark the LET for reoptimization, since it may be that we have
 723   ;; deleted its last variable.
 724   (let* ((fun (lambda-var-home leaf))
 725          (n (position leaf (lambda-vars fun))))
 726     (dolist (ref (leaf-refs fun))
 727       (let* ((lvar (node-lvar ref))
 728              (dest (and lvar (lvar-dest lvar))))
 729         (when (and (combination-p dest)
 730                    (eq (basic-combination-fun dest) lvar)
 731                    (eq (basic-combination-kind dest) :local))
 732           (let* ((args (basic-combination-args dest))
 733                  (arg (elt args n)))
 734             (reoptimize-lvar arg)
 735             (flush-dest arg)
 736             (setf (elt args n) nil))))))
 737
 738   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 739   ;; too much difficulty, since we can efficiently implement
 740   ;; write-only variables. We iterate over the SETs, marking their
 741   ;; blocks for dead code flushing, since we can delete SETs whose
 742   ;; value is unused.
 743   (dolist (set (lambda-var-sets leaf))
 744     (setf (block-flush-p (node-block set)) t))
 745
 746   (values))
 747
 748 ;;; Note that something interesting has happened to VAR.
 749 (defun reoptimize-lambda-var (var)
 750   (declare (type lambda-var var))
 751   (let ((fun (lambda-var-home var)))
 752     ;; We only deal with LET variables, marking the corresponding
 753     ;; initial value arg as needing to be reoptimized.
 754     (when (and (eq (functional-kind fun) :let)
 755                (leaf-refs var))
 756       (do ((args (basic-combination-args
 757                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 758                  (cdr args))
 759            (vars (lambda-vars fun) (cdr vars)))
 760           ((eq (car vars) var)
 761            (reoptimize-lvar (car args))))))
 762   (values))
 763
 764 ;;; Delete a function that has no references. This need only be called
 765 ;;; on functions that never had any references, since otherwise
 766 ;;; DELETE-REF will handle the deletion.
 767 (defun delete-functional (fun)
 768   (aver (and (null (leaf-refs fun))
 769              (not (functional-entry-fun fun))))
 770   (etypecase fun
 771     (optional-dispatch (delete-optional-dispatch fun))
 772     (clambda (delete-lambda fun)))
 773   (values))
 774
 775 ;;; Deal with deleting the last reference to a CLAMBDA. It is called
 776 ;;; in two situations: when the lambda is unreachable (so that its
 777 ;;; body may be deleted), and when it is an effectless LET (in this
 778 ;;; case its body is reachable and is not completely "its"). We set
 779 ;;; FUNCTIONAL-KIND to :DELETED and rely on IR1-OPTIMIZE to delete its
 780 ;;; blocks.
 781 (defun delete-lambda (clambda)
 782   (declare (type clambda clambda))
 783   (let ((original-kind (functional-kind clambda))
 784         (bind (lambda-bind clambda)))
 785     (aver (not (member original-kind '(:deleted :toplevel))))
 786     (aver (not (functional-has-external-references-p clambda)))
 787     (setf (functional-kind clambda) :deleted)
 788     (setf (lambda-bind clambda) nil)
 789
 790     (when bind              ; CLAMBDA is deleted due to unreachability
 791       (labels ((delete-children (lambda)
 792                  (dolist (child (lambda-children lambda))
 793                    (cond ((eq (functional-kind child) :deleted)
 794                           (delete-children child))
 795                          (t
 796                           (delete-lambda child))))
 797                  (setf (lambda-children lambda) nil)
 798                  (setf (lambda-parent lambda) nil)))
 799         (delete-children clambda)))
 800     (dolist (let (lambda-lets clambda))
 801       (setf (lambda-bind let) nil)
 802       (setf (functional-kind let) :deleted))
 803
 804     ;; LET may be deleted if its BIND is unreachable. Autonomous
 805     ;; function may be deleted if it has no reachable references.
 806     (unless (member original-kind '(:let :mv-let :assignment))
 807       (dolist (ref (lambda-refs clambda))
 808         (mark-for-deletion (node-block ref))))
 809
 810     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 811     ;; that we're using the old value of the KIND slot, not the
 812     ;; current slot value, which has now been set to :DELETED.)
 813     (if (member original-kind '(:let :mv-let :assignment))
 814         (let ((home (lambda-home clambda)))
 815           (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 816         ;; If the function isn't a LET, we unlink the function head
 817         ;; and tail from the component head and tail to indicate that
 818         ;; the code is unreachable. We also delete the function from
 819         ;; COMPONENT-LAMBDAS (it won't be there before local call
 820         ;; analysis, but no matter.) If the lambda was never
 821         ;; referenced, we give a note.
 822         (let* ((bind-block (node-block bind))
 823                (component (block-component bind-block))
 824                (return (lambda-return clambda))
 825                (return-block (and return (node-block return))))
 826           (unless (leaf-ever-used clambda)
 827             (let ((*compiler-error-context* bind))
 828               (compiler-notify 'code-deletion-note
 829                                :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 830                                :format-arguments (list (leaf-debug-name clambda)))))
 831           (unless (block-delete-p bind-block)
 832             (unlink-blocks (component-head component) bind-block))
 833           (when (and return-block (not (block-delete-p return-block)))
 834             (mark-for-deletion return-block)
 835             (unlink-blocks return-block (component-tail component)))
 836           (setf (component-reanalyze component) t)
 837           (let ((tails (lambda-tail-set clambda)))
 838             (setf (tail-set-funs tails)
 839                   (delete clambda (tail-set-funs tails)))
 840             (setf (lambda-tail-set clambda) nil))
 841           (setf (component-lambdas component)
 842                 (delq clambda (component-lambdas component)))))
 843
 844     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 845     ;; ENTRY-FUN so that people will know that it is not an entry
 846     ;; point anymore.
 847     (when (eq original-kind :external)
 848       (let ((fun (functional-entry-fun clambda)))
 849         (setf (functional-entry-fun fun) nil)
 850         (when (optional-dispatch-p fun)
 851           (delete-optional-dispatch fun)))))
 852
 853   (values))
 854
 855 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 856 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 857 ;;; is used both before and after local call analysis. Afterward, all
 858 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 859 ;;; to the XEP, leaving it with no references at all. So we look at
 860 ;;; the XEP to see whether an optional-dispatch is still really being
 861 ;;; used. But before local call analysis, there are no XEPs, and all
 862 ;;; references are direct.
 863 ;;;
 864 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 865 ;;; entry-points, making them be normal lambdas, and then deleting the
 866 ;;; ones with no references. This deletes any e-p lambdas that were
 867 ;;; either never referenced, or couldn't be deleted when the last
 868 ;;; reference was deleted (due to their :OPTIONAL kind.)
 869 ;;;
 870 ;;; Note that the last optional entry point may alias the main entry,
 871 ;;; so when we process the main entry, its KIND may have been changed
 872 ;;; to NIL or even converted to a LETlike value.
 873 (defun delete-optional-dispatch (leaf)
 874   (declare (type optional-dispatch leaf))
 875   (let ((entry (functional-entry-fun leaf)))
 876     (unless (and entry (leaf-refs entry))
 877       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 878       (setf (functional-kind leaf) :deleted)
 879
 880       (flet ((frob (fun)
 881                (unless (eq (functional-kind fun) :deleted)
 882                  (aver (eq (functional-kind fun) :optional))
 883                  (setf (functional-kind fun) nil)
 884                  (let ((refs (leaf-refs fun)))
 885                    (cond ((null refs)
 886                           (delete-lambda fun))
 887                          ((null (rest refs))
 888                           (or (maybe-let-convert fun)
 889                               (maybe-convert-to-assignment fun)))
 890                          (t
 891                           (maybe-convert-to-assignment fun)))))))
 892
 893         (dolist (ep (optional-dispatch-entry-points leaf))
 894           (when (promise-ready-p ep)
 895             (frob (force ep))))
 896         (when (optional-dispatch-more-entry leaf)
 897           (frob (optional-dispatch-more-entry leaf)))
 898         (let ((main (optional-dispatch-main-entry leaf)))
 899           (when (eq (functional-kind main) :optional)
 900             (frob main))))))
 901
 902   (values))
 903
 904 ;;; Do stuff to delete the semantic attachments of a REF node. When
 905 ;;; this leaves zero or one reference, we do a type dispatch off of
 906 ;;; the leaf to determine if a special action is appropriate.
 907 (defun delete-ref (ref)
 908   (declare (type ref ref))
 909   (let* ((leaf (ref-leaf ref))
 910          (refs (delq ref (leaf-refs leaf))))
 911     (setf (leaf-refs leaf) refs)
 912
 913     (cond ((null refs)
 914            (typecase leaf
 915              (lambda-var
 916               (delete-lambda-var leaf))
 917              (clambda
 918               (ecase (functional-kind leaf)
 919                 ((nil :let :mv-let :assignment :escape :cleanup)
 920                  (aver (null (functional-entry-fun leaf)))
 921                  (delete-lambda leaf))
 922                 (:external
 923                  (delete-lambda leaf))
 924                 ((:deleted :optional))))
 925              (optional-dispatch
 926               (unless (eq (functional-kind leaf) :deleted)
 927                 (delete-optional-dispatch leaf)))))
 928           ((null (rest refs))
 929            (typecase leaf
 930              (clambda (or (maybe-let-convert leaf)
 931                           (maybe-convert-to-assignment leaf)))
 932              (lambda-var (reoptimize-lambda-var leaf))))
 933           (t
 934            (typecase leaf
 935              (clambda (maybe-convert-to-assignment leaf))))))
 936
 937   (values))
 938
 939 ;;; This function is called by people who delete nodes; it provides a
 940 ;;; way to indicate that the value of a lvar is no longer used. We
 941 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
 942 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
 943 (defun flush-dest (lvar)
 944   (declare (type (or lvar null) lvar))
 945   (unless (null lvar)
 946     (setf (lvar-dest lvar) nil)
 947     (flush-lvar-externally-checkable-type lvar)
 948     (do-uses (use lvar)
 949       (let ((prev (node-prev use)))
 950         (let ((block (ctran-block prev)))
 951           (setf (component-reoptimize (block-component block)) t)
 952           (setf (block-attributep (block-flags block) flush-p type-asserted)
 953                 t)))
 954       (setf (node-lvar use) nil))
 955     (setf (lvar-uses lvar) nil))
 956   (values))
 957
 958 (defun delete-dest (lvar)
 959   (when lvar
 960     (let* ((dest (lvar-dest lvar))
 961            (prev (node-prev dest)))
 962       (let ((block (ctran-block prev)))
 963         (unless (block-delete-p block)
 964           (mark-for-deletion block))))))
 965
 966 ;;; Do a graph walk backward from BLOCK, marking all predecessor
 967 ;;; blocks with the DELETE-P flag.
 968 (defun mark-for-deletion (block)
 969   (declare (type cblock block))
 970   (let* ((component (block-component block))
 971          (head (component-head component)))
 972     (labels ((helper (block)
 973                (setf (block-delete-p block) t)
 974                (dolist (pred (block-pred block))
 975                  (unless (or (block-delete-p pred)
 976                              (eq pred head))
 977                    (helper pred)))))
 978       (unless (block-delete-p block)
 979         (helper block)
 980         (setf (component-reanalyze component) t))))
 981   (values))
 982
 983 ;;; This function does what is necessary to eliminate the code in it
 984 ;;; from the IR1 representation. This involves unlinking it from its
 985 ;;; predecessors and successors and deleting various node-specific
 986 ;;; semantic information.
 987 (defun delete-block (block &optional silent)
 988   (declare (type cblock block))
 989   (aver (block-component block))      ; else block is already deleted!
 990   (unless silent
 991     (note-block-deletion block))
 992   (setf (block-delete-p block) t)
 993
 994   (dolist (b (block-pred block))
 995     (unlink-blocks b block)
 996     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
 997     ;; broken when successors were deleted without setting the
 998     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
 999     ;; doesn't happen again.
1000     (aver (not (and (null (block-succ b))
1001                     (not (block-delete-p b))
1002                     (not (eq b (component-head (block-component b))))))))
1003   (dolist (b (block-succ block))
1004     (unlink-blocks block b))
1005
1006   (do-nodes-carefully (node block)
1007     (when (valued-node-p node)
1008       (delete-lvar-use node))
1009     (etypecase node
1010       (ref (delete-ref node))
1011       (cif (flush-dest (if-test node)))
1012       ;; The next two cases serve to maintain the invariant that a LET
1013       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1014       ;; the lambda whenever we delete any of these, but we must be
1015       ;; careful that this LET has not already been partially deleted.
1016       (basic-combination
1017        (when (and (eq (basic-combination-kind node) :local)
1018                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1019                   (lvar-uses (basic-combination-fun node)))
1020          (let ((fun (combination-lambda node)))
1021            ;; If our REF was the second-to-last ref, and has been
1022            ;; deleted, then FUN may be a LET for some other
1023            ;; combination.
1024            (when (and (functional-letlike-p fun)
1025                       (eq (let-combination fun) node))
1026              (delete-lambda fun))))
1027        (flush-dest (basic-combination-fun node))
1028        (dolist (arg (basic-combination-args node))
1029          (when arg (flush-dest arg))))
1030       (bind
1031        (let ((lambda (bind-lambda node)))
1032          (unless (eq (functional-kind lambda) :deleted)
1033            (delete-lambda lambda))))
1034       (exit
1035        (let ((value (exit-value node))
1036              (entry (exit-entry node)))
1037          (when value
1038            (flush-dest value))
1039          (when entry
1040            (setf (entry-exits entry)
1041                  (delq node (entry-exits entry))))))
1042       (entry
1043        (dolist (exit (entry-exits node))
1044          (mark-for-deletion (node-block exit)))
1045        (let ((home (node-home-lambda node)))
1046          (setf (lambda-entries home) (delq node (lambda-entries home)))))
1047       (creturn
1048        (flush-dest (return-result node))
1049        (delete-return node))
1050       (cset
1051        (flush-dest (set-value node))
1052        (let ((var (set-var node)))
1053          (setf (basic-var-sets var)
1054                (delete node (basic-var-sets var)))))
1055       (cast
1056        (flush-dest (cast-value node)))))
1057
1058   (remove-from-dfo block)
1059   (values))
1060
1061 ;;; Do stuff to indicate that the return node NODE is being deleted.
1062 (defun delete-return (node)
1063   (declare (type creturn node))
1064   (let* ((fun (return-lambda node))
1065          (tail-set (lambda-tail-set fun)))
1066     (aver (lambda-return fun))
1067     (setf (lambda-return fun) nil)
1068     (when (and tail-set (not (find-if #'lambda-return
1069                                       (tail-set-funs tail-set))))
1070       (setf (tail-set-type tail-set) *empty-type*)))
1071   (values))
1072
1073 ;;; If any of the VARS in FUN was never referenced and was not
1074 ;;; declared IGNORE, then complain.
1075 (defun note-unreferenced-vars (fun)
1076   (declare (type clambda fun))
1077   (dolist (var (lambda-vars fun))
1078     (unless (or (leaf-ever-used var)
1079                 (lambda-var-ignorep var))
1080       (let ((*compiler-error-context* (lambda-bind fun)))
1081         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1082           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1083           ;; requires this to be no more than a STYLE-WARNING.
1084           (compiler-style-warn "The variable ~S is defined but never used."
1085                                (leaf-debug-name var)))
1086         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1087   (values))
1088
1089 (defvar *deletion-ignored-objects* '(t nil))
1090
1091 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1092 ;;; our recursion so that we don't get lost in circular structures. We
1093 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1094 ;;; function referencess with variables), and we also ignore anything
1095 ;;; inside ' or #'.
1096 (defun present-in-form (obj form depth)
1097   (declare (type (integer 0 20) depth))
1098   (cond ((= depth 20) nil)
1099         ((eq obj form) t)
1100         ((atom form) nil)
1101         (t
1102          (let ((first (car form))
1103                (depth (1+ depth)))
1104            (if (member first '(quote function))
1105                nil
1106                (or (and (not (symbolp first))
1107                         (present-in-form obj first depth))
1108                    (do ((l (cdr form) (cdr l))
1109                         (n 0 (1+ n)))
1110                        ((or (atom l) (> n 100))
1111                         nil)
1112                      (declare (fixnum n))
1113                      (when (present-in-form obj (car l) depth)
1114                        (return t)))))))))
1115
1116 ;;; This function is called on a block immediately before we delete
1117 ;;; it. We check to see whether any of the code about to die appeared
1118 ;;; in the original source, and emit a note if so.
1119 ;;;
1120 ;;; If the block was in a lambda is now deleted, then we ignore the
1121 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1122 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1123 ;;; reasonable for a function to not return, and there is a different
1124 ;;; note for that case anyway.
1125 ;;;
1126 ;;; If the actual source is an atom, then we use a bunch of heuristics
1127 ;;; to guess whether this reference really appeared in the original
1128 ;;; source:
1129 ;;; -- If a symbol, it must be interned and not a keyword.
1130 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1131 ;;;    or a character.)
1132 ;;; -- The atom must be "present" in the original source form, and
1133 ;;;    present in all intervening actual source forms.
1134 (defun note-block-deletion (block)
1135   (let ((home (block-home-lambda block)))
1136     (unless (eq (functional-kind home) :deleted)
1137       (do-nodes (node nil block)
1138         (let* ((path (node-source-path node))
1139                (first (first path)))
1140           (when (or (eq first 'original-source-start)
1141                     (and (atom first)
1142                          (or (not (symbolp first))
1143                              (let ((pkg (symbol-package first)))
1144                                (and pkg
1145                                     (not (eq pkg (symbol-package :end))))))
1146                          (not (member first *deletion-ignored-objects*))
1147                          (not (typep first '(or fixnum character)))
1148                          (every (lambda (x)
1149                                   (present-in-form first x 0))
1150                                 (source-path-forms path))
1151                          (present-in-form first (find-original-source path)
1152                                           0)))
1153             (unless (return-p node)
1154               (let ((*compiler-error-context* node))
1155                 (compiler-notify 'code-deletion-note
1156                                  :format-control "deleting unreachable code"
1157                                  :format-arguments nil)))
1158             (return))))))
1159   (values))
1160
1161 ;;; Delete a node from a block, deleting the block if there are no
1162 ;;; nodes left. We remove the node from the uses of its LVAR.
1163 ;;;
1164 ;;; If the node is the last node, there must be exactly one successor.
1165 ;;; We link all of our precedessors to the successor and unlink the
1166 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1167 ;;; left, and the block is a successor of itself, then we replace the
1168 ;;; only node with a degenerate exit node. This provides a way to
1169 ;;; represent the bodyless infinite loop, given the prohibition on
1170 ;;; empty blocks in IR1.
1171 (defun unlink-node (node)
1172   (declare (type node node))
1173   (when (valued-node-p node)
1174     (delete-lvar-use node))
1175
1176   (let* ((ctran (node-next node))
1177          (next (and ctran (ctran-next ctran)))
1178          (prev (node-prev node))
1179          (block (ctran-block prev))
1180          (prev-kind (ctran-kind prev))
1181          (last (block-last block)))
1182
1183     (setf (block-type-asserted block) t)
1184     (setf (block-test-modified block) t)
1185
1186     (cond ((or (eq prev-kind :inside-block)
1187                (and (eq prev-kind :block-start)
1188                     (not (eq node last))))
1189            (cond ((eq node last)
1190                   (setf (block-last block) (ctran-use prev))
1191                   (setf (node-next (ctran-use prev)) nil))
1192                  (t
1193                   (setf (ctran-next prev) next)
1194                   (setf (node-prev next) prev)
1195                   (when (if-p next) ; AOP wanted
1196                     (reoptimize-lvar (if-test next)))))
1197            (setf (node-prev node) nil)
1198            nil)
1199           (t
1200            (aver (eq prev-kind :block-start))
1201            (aver (eq node last))
1202            (let* ((succ (block-succ block))
1203                   (next (first succ)))
1204              (aver (singleton-p succ))
1205              (cond
1206               ((eq block (first succ))
1207                (with-ir1-environment-from-node node
1208                  (let ((exit (make-exit)))
1209                    (setf (ctran-next prev) nil)
1210                    (link-node-to-previous-ctran exit prev)
1211                    (setf (block-last block) exit)))
1212                (setf (node-prev node) nil)
1213                nil)
1214               (t
1215                (aver (eq (block-start-cleanup block)
1216                          (block-end-cleanup block)))
1217                (unlink-blocks block next)
1218                (dolist (pred (block-pred block))
1219                  (change-block-successor pred block next))
1220                (remove-from-dfo block)
1221                (setf (block-delete-p block) t)
1222                (setf (node-prev node) nil)
1223                t)))))))
1224
1225 ;;; Return true if NODE has been deleted, false if it is still a valid
1226 ;;; part of IR1.
1227 (defun node-deleted (node)
1228   (declare (type node node))
1229   (let ((prev (node-prev node)))
1230     (not (and prev
1231               (let ((block (ctran-block prev)))
1232                 (and (block-component block)
1233                      (not (block-delete-p block))))))))
1234
1235 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1236 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1237 ;;; triggered by deletion.
1238 (defun delete-component (component)
1239   (declare (type component component))
1240   (aver (null (component-new-functionals component)))
1241   (setf (component-kind component) :deleted)
1242   (do-blocks (block component)
1243     (setf (block-delete-p block) t))
1244   (dolist (fun (component-lambdas component))
1245     (unless (eq (functional-kind fun) :deleted)
1246       (setf (functional-kind fun) nil)
1247       (setf (functional-entry-fun fun) nil)
1248       (setf (leaf-refs fun) nil)
1249       (delete-functional fun)))
1250   (do-blocks (block component)
1251     (delete-block block))
1252   (values))
1253
1254 ;;; Convert code of the form
1255 ;;;   (FOO ... (FUN ...) ...)
1256 ;;; to
1257 ;;;   (FOO ...    ...    ...).
1258 ;;; In other words, replace the function combination FUN by its
1259 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1260 ;;; to blow out of whatever transform called this. Note, as the number
1261 ;;; of arguments changes, the transform must be prepared to return a
1262 ;;; lambda with a new lambda-list with the correct number of
1263 ;;; arguments.
1264 (defun extract-fun-args (lvar fun num-args)
1265   #!+sb-doc
1266   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1267    to feed directly to the LVAR-DEST of LVAR, which must be a
1268    combination."
1269   (declare (type lvar lvar)
1270            (type symbol fun)
1271            (type index num-args))
1272   (let ((outside (lvar-dest lvar))
1273         (inside (lvar-uses lvar)))
1274     (aver (combination-p outside))
1275     (unless (combination-p inside)
1276       (give-up-ir1-transform))
1277     (let ((inside-fun (combination-fun inside)))
1278       (unless (eq (lvar-fun-name inside-fun) fun)
1279         (give-up-ir1-transform))
1280       (let ((inside-args (combination-args inside)))
1281         (unless (= (length inside-args) num-args)
1282           (give-up-ir1-transform))
1283         (let* ((outside-args (combination-args outside))
1284                (arg-position (position lvar outside-args))
1285                (before-args (subseq outside-args 0 arg-position))
1286                (after-args (subseq outside-args (1+ arg-position))))
1287           (dolist (arg inside-args)
1288             (setf (lvar-dest arg) outside)
1289             (flush-lvar-externally-checkable-type arg))
1290           (setf (combination-args inside) nil)
1291           (setf (combination-args outside)
1292                 (append before-args inside-args after-args))
1293           (change-ref-leaf (lvar-uses inside-fun)
1294                            (find-free-fun 'list "???"))
1295           (setf (combination-kind inside)
1296                 (info :function :info 'list))
1297           (setf (node-derived-type inside) *wild-type*)
1298           (flush-dest lvar)
1299           (values))))))
1300
1301 (defun flush-combination (combination)
1302   (declare (type combination combination))
1303   (flush-dest (combination-fun combination))
1304   (dolist (arg (combination-args combination))
1305     (flush-dest arg))
1306   (unlink-node combination)
1307   (values))
1308
1309 \f
1310 ;;;; leaf hackery
1311
1312 ;;; Change the LEAF that a REF refers to.
1313 (defun change-ref-leaf (ref leaf)
1314   (declare (type ref ref) (type leaf leaf))
1315   (unless (eq (ref-leaf ref) leaf)
1316     (push ref (leaf-refs leaf))
1317     (delete-ref ref)
1318     (setf (ref-leaf ref) leaf)
1319     (setf (leaf-ever-used leaf) t)
1320     (let* ((ltype (leaf-type leaf))
1321            (vltype (make-single-value-type ltype)))
1322       (if (let* ((lvar (node-lvar ref))
1323                  (dest (and lvar (lvar-dest lvar))))
1324             (and (basic-combination-p dest)
1325                  (eq lvar (basic-combination-fun dest))
1326                  (csubtypep ltype (specifier-type 'function))))
1327           (setf (node-derived-type ref) vltype)
1328           (derive-node-type ref vltype)))
1329     (reoptimize-lvar (node-lvar ref)))
1330   (values))
1331
1332 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1333 (defun substitute-leaf (new-leaf old-leaf)
1334   (declare (type leaf new-leaf old-leaf))
1335   (dolist (ref (leaf-refs old-leaf))
1336     (change-ref-leaf ref new-leaf))
1337   (values))
1338
1339 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1340 ;;; whether to substitute
1341 (defun substitute-leaf-if (test new-leaf old-leaf)
1342   (declare (type leaf new-leaf old-leaf) (type function test))
1343   (dolist (ref (leaf-refs old-leaf))
1344     (when (funcall test ref)
1345       (change-ref-leaf ref new-leaf)))
1346   (values))
1347
1348 ;;; Return a LEAF which represents the specified constant object. If
1349 ;;; the object is not in *CONSTANTS*, then we create a new constant
1350 ;;; LEAF and enter it.
1351 (defun find-constant (object)
1352   (if (typep object
1353              ;; FIXME: What is the significance of this test? ("things
1354              ;; that are worth uniquifying"?)
1355              '(or symbol number character instance))
1356       (or (gethash object *constants*)
1357           (setf (gethash object *constants*)
1358                 (make-constant :value object
1359                                :%source-name '.anonymous.
1360                                :type (ctype-of object)
1361                                :where-from :defined)))
1362       (make-constant :value object
1363                      :%source-name '.anonymous.
1364                      :type (ctype-of object)
1365                      :where-from :defined)))
1366 \f
1367 ;;; Return true if VAR would have to be closed over if environment
1368 ;;; analysis ran now (i.e. if there are any uses that have a different
1369 ;;; home lambda than VAR's home.)
1370 (defun closure-var-p (var)
1371   (declare (type lambda-var var))
1372   (let ((home (lambda-var-home var)))
1373     (cond ((eq (functional-kind home) :deleted)
1374            nil)
1375           (t (let ((home (lambda-home home)))
1376                (flet ((frob (l)
1377                         (find home l
1378                               :key #'node-home-lambda
1379                               :test-not #'eq)))
1380                  (or (frob (leaf-refs var))
1381                      (frob (basic-var-sets var)))))))))
1382
1383 ;;; If there is a non-local exit noted in ENTRY's environment that
1384 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1385 (defun find-nlx-info (exit)
1386   (declare (type exit exit))
1387   (let* ((entry (exit-entry exit))
1388          (entry-cleanup (entry-cleanup entry)))
1389     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1390       (when (eq (nlx-info-exit nlx) exit)
1391         (return nlx)))))
1392 \f
1393 ;;;; functional hackery
1394
1395 (declaim (ftype (sfunction (functional) clambda) main-entry))
1396 (defun main-entry (functional)
1397   (etypecase functional
1398     (clambda functional)
1399     (optional-dispatch
1400      (optional-dispatch-main-entry functional))))
1401
1402 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1403 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1404 ;;; optional with null default and no SUPPLIED-P. There must be a
1405 ;;; &REST arg with no references.
1406 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1407 (defun looks-like-an-mv-bind (functional)
1408   (and (optional-dispatch-p functional)
1409        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1410            ((null arg) nil)
1411          (let ((info (lambda-var-arg-info (car arg))))
1412            (unless info (return nil))
1413            (case (arg-info-kind info)
1414              (:optional
1415               (when (or (arg-info-supplied-p info) (arg-info-default info))
1416                 (return nil)))
1417              (:rest
1418               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1419              (t
1420               (return nil)))))))
1421
1422 ;;; Return true if function is an external entry point. This is true
1423 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1424 ;;; (:TOPLEVEL kind.)
1425 (defun xep-p (fun)
1426   (declare (type functional fun))
1427   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1428
1429 ;;; If LVAR's only use is a non-notinline global function reference,
1430 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1431 ;;; is true, then we don't care if the leaf is NOTINLINE.
1432 (defun lvar-fun-name (lvar &optional notinline-ok)
1433   (declare (type lvar lvar))
1434   (let ((use (lvar-uses lvar)))
1435     (if (ref-p use)
1436         (let ((leaf (ref-leaf use)))
1437           (if (and (global-var-p leaf)
1438                    (eq (global-var-kind leaf) :global-function)
1439                    (or (not (defined-fun-p leaf))
1440                        (not (eq (defined-fun-inlinep leaf) :notinline))
1441                        notinline-ok))
1442               (leaf-source-name leaf)
1443               nil))
1444         nil)))
1445
1446 ;;; Return the source name of a combination. (This is an idiom
1447 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1448 (defun combination-fun-source-name (combination)
1449   (let ((ref (lvar-uses (combination-fun combination))))
1450     (leaf-source-name (ref-leaf ref))))
1451
1452 ;;; Return the COMBINATION node that is the call to the LET FUN.
1453 (defun let-combination (fun)
1454   (declare (type clambda fun))
1455   (aver (functional-letlike-p fun))
1456   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1457
1458 ;;; Return the initial value lvar for a LET variable, or NIL if there
1459 ;;; is none.
1460 (defun let-var-initial-value (var)
1461   (declare (type lambda-var var))
1462   (let ((fun (lambda-var-home var)))
1463     (elt (combination-args (let-combination fun))
1464          (position-or-lose var (lambda-vars fun)))))
1465
1466 ;;; Return the LAMBDA that is called by the local CALL.
1467 (defun combination-lambda (call)
1468   (declare (type basic-combination call))
1469   (aver (eq (basic-combination-kind call) :local))
1470   (ref-leaf (lvar-uses (basic-combination-fun call))))
1471
1472 (defvar *inline-expansion-limit* 200
1473   #!+sb-doc
1474   "an upper limit on the number of inline function calls that will be expanded
1475    in any given code object (single function or block compilation)")
1476
1477 ;;; Check whether NODE's component has exceeded its inline expansion
1478 ;;; limit, and warn if so, returning NIL.
1479 (defun inline-expansion-ok (node)
1480   (let ((expanded (incf (component-inline-expansions
1481                          (block-component
1482                           (node-block node))))))
1483     (cond ((> expanded *inline-expansion-limit*) nil)
1484           ((= expanded *inline-expansion-limit*)
1485            ;; FIXME: If the objective is to stop the recursive
1486            ;; expansion of inline functions, wouldn't it be more
1487            ;; correct to look back through surrounding expansions
1488            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1489            ;; possibly stored elsewhere too) and suppress expansion
1490            ;; and print this warning when the function being proposed
1491            ;; for inline expansion is found there? (I don't like the
1492            ;; arbitrary numerical limit in principle, and I think
1493            ;; it'll be a nuisance in practice if we ever want the
1494            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1495            ;; arbitrarily huge blocks of code. -- WHN)
1496            (let ((*compiler-error-context* node))
1497              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1498                                probably trying to~%  ~
1499                                inline a recursive function."
1500                               *inline-expansion-limit*))
1501            nil)
1502           (t t))))
1503
1504 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1505 (defun assure-functional-live-p (functional)
1506   (declare (type functional functional))
1507   (when (and (or
1508               ;; looks LET-converted
1509               (functional-somewhat-letlike-p functional)
1510               ;; It's possible for a LET-converted function to end up
1511               ;; deleted later. In that case, for the purposes of this
1512               ;; analysis, it is LET-converted: LET-converted functionals
1513               ;; are too badly trashed to expand them inline, and deleted
1514               ;; LET-converted functionals are even worse.
1515               (eql (functional-kind functional) :deleted)))
1516     (throw 'locall-already-let-converted functional)))
1517
1518 (defun call-full-like-p (call)
1519   (declare (type combination call))
1520   (let ((kind (basic-combination-kind call)))
1521     (or (eq kind :full)
1522         (and (fun-info-p kind)
1523              (not (fun-info-ir2-convert kind))
1524              (dolist (template (fun-info-templates kind) t)
1525                (when (eq (template-ltn-policy template) :fast-safe)
1526                  (multiple-value-bind (val win)
1527                      (valid-fun-use call (template-type template))
1528                    (when (or val (not win)) (return nil)))))))))
1529 \f
1530 ;;;; careful call
1531
1532 ;;; Apply a function to some arguments, returning a list of the values
1533 ;;; resulting of the evaluation. If an error is signalled during the
1534 ;;; application, then we produce a warning message using WARN-FUN and
1535 ;;; return NIL as our second value to indicate this. NODE is used as
1536 ;;; the error context for any error message, and CONTEXT is a string
1537 ;;; that is spliced into the warning.
1538 (declaim (ftype (sfunction ((or symbol function) list node function string)
1539                           (values list boolean))
1540                 careful-call))
1541 (defun careful-call (function args node warn-fun context)
1542   (values
1543    (multiple-value-list
1544     (handler-case (apply function args)
1545       (error (condition)
1546         (let ((*compiler-error-context* node))
1547           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1548           (return-from careful-call (values nil nil))))))
1549    t))
1550
1551 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1552 ;;; specifiers.
1553 (macrolet
1554     ((deffrob (basic careful compiler transform)
1555        `(progn
1556           (defun ,careful (specifier)
1557             (handler-case (,basic specifier)
1558               (sb!kernel::arg-count-error (condition)
1559                 (values nil (list (format nil "~A" condition))))
1560               (simple-error (condition)
1561                 (values nil (list* (simple-condition-format-control condition)
1562                                    (simple-condition-format-arguments condition))))))
1563           (defun ,compiler (specifier)
1564             (multiple-value-bind (type error-args) (,careful specifier)
1565               (or type
1566                   (apply #'compiler-error error-args))))
1567           (defun ,transform (specifier)
1568             (multiple-value-bind (type error-args) (,careful specifier)
1569               (or type
1570                   (apply #'give-up-ir1-transform
1571                          error-args)))))))
1572   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1573   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1574
1575 \f
1576 ;;;; utilities used at run-time for parsing &KEY args in IR1
1577
1578 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1579 ;;; the lvar for the value of the &KEY argument KEY in the list of
1580 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1581 ;;; otherwise. The legality and constantness of the keywords should
1582 ;;; already have been checked.
1583 (declaim (ftype (sfunction (list keyword) (or lvar null))
1584                 find-keyword-lvar))
1585 (defun find-keyword-lvar (args key)
1586   (do ((arg args (cddr arg)))
1587       ((null arg) nil)
1588     (when (eq (lvar-value (first arg)) key)
1589       (return (second arg)))))
1590
1591 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1592 ;;; verify that alternating lvars in ARGS are constant and that there
1593 ;;; is an even number of args.
1594 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1595 (defun check-key-args-constant (args)
1596   (do ((arg args (cddr arg)))
1597       ((null arg) t)
1598     (unless (and (rest arg)
1599                  (constant-lvar-p (first arg)))
1600       (return nil))))
1601
1602 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1603 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1604 ;;; and that only keywords present in the list KEYS are supplied.
1605 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1606 (defun check-transform-keys (args keys)
1607   (and (check-key-args-constant args)
1608        (do ((arg args (cddr arg)))
1609            ((null arg) t)
1610          (unless (member (lvar-value (first arg)) keys)
1611            (return nil)))))
1612 \f
1613 ;;;; miscellaneous
1614
1615 ;;; Called by the expansion of the EVENT macro.
1616 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1617 (defun %event (info node)
1618   (incf (event-info-count info))
1619   (when (and (>= (event-info-level info) *event-note-threshold*)
1620              (policy (or node *lexenv*)
1621                      (= inhibit-warnings 0)))
1622     (let ((*compiler-error-context* node))
1623       (compiler-notify (event-info-description info))))
1624
1625   (let ((action (event-info-action info)))
1626     (when action (funcall action node))))
1627
1628 ;;;
1629 (defun make-cast (value type policy)
1630   (declare (type lvar value)
1631            (type ctype type)
1632            (type policy policy))
1633   (%make-cast :asserted-type type
1634               :type-to-check (maybe-weaken-check type policy)
1635               :value value
1636               :derived-type (coerce-to-values type)))
1637
1638 (defun cast-type-check (cast)
1639   (declare (type cast cast))
1640   (when (cast-reoptimize cast)
1641     (ir1-optimize-cast cast t))
1642   (cast-%type-check cast))
1643
1644 (defun note-single-valuified-lvar (lvar)
1645   (declare (type (or lvar null) lvar))
1646   (when lvar
1647     (let ((use (lvar-uses lvar)))
1648       (cond ((ref-p use)
1649              (let ((leaf (ref-leaf use)))
1650                (when (and (lambda-var-p leaf)
1651                           (null (rest (leaf-refs leaf))))
1652                  (reoptimize-lambda-var leaf))))
1653             ((or (listp use) (combination-p use))
1654              (do-uses (node lvar)
1655                (setf (node-reoptimize node) t)
1656                (setf (block-reoptimize (node-block node)) t)
1657                (setf (component-reoptimize (node-component node)) t)))))))