src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-continuation))
  43              (block (continuation-starts-block start))
  44              (cont (make-continuation))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start cont form)
  51         (setf (block-last block) (continuation-use cont))
  52         block))))
  53 \f
  54 ;;;; continuation use hacking
  55
  56 ;;; Return a list of all the nodes which use Cont.
  57 (declaim (ftype (sfunction (continuation) list) find-uses))
  58 (defun find-uses (cont)
  59   (ecase (continuation-kind cont)
  60     ((:block-start :deleted-block-start)
  61      (block-start-uses (continuation-block cont)))
  62     (:inside-block (list (continuation-use cont)))
  63     (:unused nil)
  64     (:deleted nil)))
  65
  66 (defun principal-continuation-use (cont)
  67   (let ((use (continuation-use cont)))
  68     (if (cast-p use)
  69         (principal-continuation-use (cast-value use))
  70         use)))
  71
  72 ;;; Update continuation use information so that NODE is no longer a
  73 ;;; use of its CONT. If the old continuation doesn't start its block,
  74 ;;; then we don't update the BLOCK-START-USES, since it will be
  75 ;;; deleted when we are done.
  76 ;;;
  77 ;;; Note: if you call this function, you may have to do a
  78 ;;; REOPTIMIZE-CONTINUATION to inform IR1 optimization that something
  79 ;;; has changed.
  80 (declaim (ftype (sfunction (node) (values)) delete-continuation-use))
  81 (defun delete-continuation-use (node)
  82   (let* ((cont (node-cont node))
  83          (block (continuation-block cont)))
  84     (ecase (continuation-kind cont)
  85       (:deleted)
  86       ((:block-start :deleted-block-start)
  87        (let ((uses (delete node (block-start-uses block))))
  88          (setf (block-start-uses block) uses)
  89          (setf (continuation-use cont)
  90                (if (cdr uses) nil (car uses)))))
  91       (:inside-block
  92        (setf (continuation-kind cont) :unused)
  93        (setf (continuation-block cont) nil)
  94        (setf (continuation-use cont) nil)
  95        (setf (continuation-next cont) nil)))
  96     (setf (node-cont node) nil))
  97   (values))
  98
  99 ;;; Update continuation use information so that NODE uses CONT. If
 100 ;;; CONT is :UNUSED, then we set its block to NODE's NODE-BLOCK (which
 101 ;;; must be set.)
 102 ;;;
 103 ;;; Note: if you call this function, you may have to do a
 104 ;;; REOPTIMIZE-CONTINUATION to inform IR1 optimization that something
 105 ;;; has changed.
 106 (declaim (ftype (sfunction (node continuation) (values)) add-continuation-use))
 107 (defun add-continuation-use (node cont)
 108   (aver (not (node-cont node)))
 109   (let ((block (continuation-block cont)))
 110     (ecase (continuation-kind cont)
 111       (:deleted)
 112       (:unused
 113        (aver (not block))
 114        (let ((block (node-block node)))
 115          (aver block)
 116          (setf (continuation-block cont) block))
 117        (setf (continuation-kind cont) :inside-block)
 118        (setf (continuation-use cont) node))
 119       ((:block-start :deleted-block-start)
 120        (let ((uses (cons node (block-start-uses block))))
 121          (setf (block-start-uses block) uses)
 122          (setf (continuation-use cont)
 123                (if (cdr uses) nil (car uses)))
 124          (let ((block (node-block node)))
 125            (unless (block-last block)
 126              (setf (block-last block) node)))))))
 127   (setf (node-cont node) cont)
 128   (values))
 129
 130 ;;; Return true if CONT is the NODE-CONT for NODE and CONT is
 131 ;;; transferred to immediately after the evaluation of NODE.
 132 (defun immediately-used-p (cont node)
 133   (declare (type continuation cont) (type node node))
 134   (and (eq (node-cont node) cont)
 135        (not (eq (continuation-kind cont) :deleted))
 136        (eq (continuation-dest cont)
 137            (continuation-next cont))
 138        (let ((cblock (continuation-block cont))
 139              (nblock (node-block node)))
 140          (or (eq cblock nblock)
 141              (let ((succ (block-succ nblock)))
 142                (and (= (length succ) 1)
 143                     (eq (first succ) cblock)))))))
 144 \f
 145 ;;;; continuation substitution
 146
 147 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 148 ;;; NIL. When we are done, we call FLUSH-DEST on OLD to clear its DEST
 149 ;;; and to note potential optimization opportunities.
 150 (defun substitute-continuation (new old)
 151   (declare (type continuation old new))
 152   (aver (not (continuation-dest new)))
 153   (let ((dest (continuation-dest old)))
 154     (etypecase dest
 155       ((or ref bind))
 156       (cif (setf (if-test dest) new))
 157       (cset (setf (set-value dest) new))
 158       (creturn (setf (return-result dest) new))
 159       (exit (setf (exit-value dest) new))
 160       (basic-combination
 161        (if (eq old (basic-combination-fun dest))
 162            (setf (basic-combination-fun dest) new)
 163            (setf (basic-combination-args dest)
 164                  (nsubst new old (basic-combination-args dest)))))
 165       (cast (setf (cast-value dest) new))
 166       (null))
 167
 168     (when dest (flush-dest old))
 169     (setf (continuation-dest new) dest)
 170     (flush-continuation-externally-checkable-type new))
 171   (values))
 172
 173 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 174 ;;; arbitary number of uses. If NEW will end up with more than one
 175 ;;; use, then we must arrange for it to start a block if it doesn't
 176 ;;; already.
 177 (defun substitute-continuation-uses (new old)
 178   (declare (type continuation old new))
 179   (unless (and (eq (continuation-kind new) :unused)
 180                (eq (continuation-kind old) :inside-block))
 181     (ensure-block-start new))
 182
 183   (do-uses (node old)
 184     (delete-continuation-use node)
 185     (add-continuation-use node new))
 186   (dolist (lexenv-use (continuation-lexenv-uses old)) ; FIXME - APD
 187     (setf (cadr lexenv-use) new))
 188
 189   (reoptimize-continuation new)
 190   (values))
 191 \f
 192 ;;;; block starting/creation
 193
 194 ;;; Return the block that CONT is the start of, making a block if
 195 ;;; necessary. This function is called by IR1 translators which may
 196 ;;; cause a continuation to be used more than once. Every continuation
 197 ;;; which may be used more than once must start a block by the time
 198 ;;; that anyone does a USE-CONTINUATION on it.
 199 ;;;
 200 ;;; We also throw the block into the next/prev list for the
 201 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 202 ;;; made.
 203 (defun continuation-starts-block (cont)
 204   (declare (type continuation cont))
 205   (ecase (continuation-kind cont)
 206     (:unused
 207      (aver (not (continuation-block cont)))
 208      (let* ((next (component-last-block *current-component*))
 209             (prev (block-prev next))
 210             (new-block (make-block cont)))
 211        (setf (block-next new-block) next
 212              (block-prev new-block) prev
 213              (block-prev next) new-block
 214              (block-next prev) new-block
 215              (continuation-block cont) new-block
 216              (continuation-use cont) nil
 217              (continuation-kind cont) :block-start)
 218        new-block))
 219     (:block-start
 220      (continuation-block cont))))
 221
 222 ;;; Ensure that CONT is the start of a block (or deleted) so that
 223 ;;; the use set can be freely manipulated.
 224 ;;; -- If the continuation is :UNUSED or is :INSIDE-BLOCK and the
 225 ;;;    CONT of LAST in its block, then we make it the start of a new
 226 ;;;    deleted block.
 227 ;;; -- If the continuation is :INSIDE-BLOCK inside a block, then we
 228 ;;;    split the block using NODE-ENDS-BLOCK, which makes the
 229 ;;;    continuation be a :BLOCK-START.
 230 (defun ensure-block-start (cont)
 231   (declare (type continuation cont))
 232   (let ((kind (continuation-kind cont)))
 233     (ecase kind
 234       ((:deleted :block-start :deleted-block-start))
 235       ((:unused :inside-block)
 236        (let ((block (continuation-block cont)))
 237          (cond ((or (eq kind :unused)
 238                     (eq (node-cont (block-last block)) cont))
 239                 (setf (continuation-block cont)
 240                       (make-block-key :start cont
 241                                       :component nil
 242                                       :start-uses (find-uses cont)))
 243                 (setf (continuation-kind cont) :deleted-block-start))
 244                (t
 245                 (node-ends-block (continuation-use cont))))))))
 246   (values))
 247 \f
 248 ;;;;
 249
 250 ;;; Filter values of CONT with a destination through FORM, which must
 251 ;;; be an ordinary/mv call. First argument must be 'DUMMY, which will
 252 ;;; be replaced with CONT. In case of an ordinary call the function
 253 ;;; should not have return type NIL.
 254 ;;;
 255 ;;; TODO: remove preconditions.
 256 (defun filter-continuation (cont form)
 257   (declare (type continuation cont) (type list form))
 258   (let ((dest (continuation-dest cont)))
 259     (declare (type node dest))
 260     (with-ir1-environment-from-node dest
 261
 262       ;; Ensuring that CONT starts a block lets us freely manipulate its uses.
 263       (ensure-block-start cont)
 264
 265       ;; Make a new continuation and move CONT's uses to it.
 266       (let ((new-start (make-continuation))
 267             (prev (node-prev dest)))
 268         (continuation-starts-block new-start)
 269         (substitute-continuation-uses new-start cont)
 270
 271         ;; Make the DEST node start its block so that we can splice in
 272         ;; the LAMBDA code.
 273         (when (continuation-use prev)
 274           (node-ends-block (continuation-use prev)))
 275
 276         (let* ((prev-block (continuation-block prev))
 277                (new-block (continuation-block new-start))
 278                (dummy (make-continuation)))
 279
 280           ;; Splice in the new block before DEST, giving the new block
 281           ;; all of DEST's predecessors.
 282           (dolist (block (block-pred prev-block))
 283             (change-block-successor block prev-block new-block))
 284
 285           ;; Convert the lambda form, using the new block start as
 286           ;; START and a dummy continuation as CONT.
 287           (ir1-convert new-start dummy form)
 288
 289           ;; TODO: Why should this be true? -- WHN 19990601
 290           ;;
 291           ;; It is somehow related to the precondition of non-NIL
 292           ;; return type of the function. -- APD 2003-3-24
 293           (aver (eq (continuation-block dummy) new-block))
 294
 295           ;; KLUDGE: Comments at the head of this function in CMU CL
 296           ;; said that somewhere in here we
 297           ;;   Set the new block's start and end cleanups to the *start*
 298           ;;   cleanup of PREV's block. This overrides the incorrect
 299           ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 300           ;; Unfortunately I can't find any code which corresponds to this.
 301           ;; Perhaps it was a stale comment? Or perhaps I just don't
 302           ;; understand.. -- WHN 19990521
 303
 304           (let ((node (continuation-use dummy)))
 305             (setf (block-last new-block) node)
 306             ;; Change the use to a use of CONT. (We need to use the
 307             ;; dummy continuation to get the control transfer right,
 308             ;; because we want to go to PREV's block, not CONT's.)
 309             (delete-continuation-use node)
 310             (add-continuation-use node cont))
 311           ;; Link the new block to PREV's block.
 312           (link-blocks new-block prev-block))
 313
 314         ;; Replace 'DUMMY with the new continuation. (We can find
 315         ;; 'DUMMY because no LET conversion has been done yet.) The
 316         ;; [mv-]combination code from the call in the form will be the
 317         ;; use of the new check continuation. We substitute for the
 318         ;; first argument of this node.
 319         (let* ((node (continuation-use cont))
 320                (args (basic-combination-args node))
 321                (victim (first args)))
 322           (aver (eq (constant-value (ref-leaf (continuation-use victim)))
 323                     'dummy))
 324           (substitute-continuation new-start victim)))
 325
 326       ;; Invoking local call analysis converts this call to a LET.
 327       (locall-analyze-component *current-component*)
 328
 329       (values))))
 330
 331 ;;; Deleting a filter may result in some calls becoming tail.
 332 (defun delete-filter (node cont value)
 333   (collect ((merges))
 334     (prog2
 335         (when (return-p (continuation-dest cont))
 336           (do-uses (use value)
 337             (when (and (basic-combination-p use)
 338                        (eq (basic-combination-kind use) :local))
 339               (merges use))))
 340         (cond ((and (eq (continuation-kind cont) :inside-block)
 341                     (eq (continuation-kind value) :inside-block))
 342                (setf (continuation-dest value) nil)
 343                (substitute-continuation value cont)
 344                (prog1 (unlink-node node)
 345                  (setq cont value)))
 346               (t (ensure-block-start value)
 347                  (ensure-block-start cont)
 348                  (substitute-continuation-uses cont value)
 349                  (prog1 (unlink-node node)
 350                    (setf (continuation-dest value) nil))))
 351       (dolist (merge (merges))
 352         (merge-tail-sets merge)))))
 353 \f
 354 ;;;; miscellaneous shorthand functions
 355
 356 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 357 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 358 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 359 ;;; deleted, and then return its home.
 360 (defun node-home-lambda (node)
 361   (declare (type node node))
 362   (do ((fun (lexenv-lambda (node-lexenv node))
 363             (lexenv-lambda (lambda-call-lexenv fun))))
 364       ((not (eq (functional-kind fun) :deleted))
 365        (lambda-home fun))
 366     (when (eq (lambda-home fun) fun)
 367       (return fun))))
 368
 369 (declaim (ftype (sfunction (node) cblock) node-block))
 370 (defun node-block (node)
 371   (continuation-block (node-prev node)))
 372 (declaim (ftype (sfunction (node) component) node-component))
 373 (defun node-component (node)
 374   (block-component (node-block node)))
 375 (declaim (ftype (sfunction (node) physenv) node-physenv))
 376 (defun node-physenv (node)
 377   (lambda-physenv (node-home-lambda node)))
 378
 379 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 380 (defun lambda-block (clambda)
 381   (node-block (lambda-bind clambda)))
 382 (declaim (ftype (sfunction (clambda) component) lambda-component))
 383 (defun lambda-component (clambda)
 384   (block-component (lambda-block clambda)))
 385
 386 ;;; Return the enclosing cleanup for environment of the first or last
 387 ;;; node in BLOCK.
 388 (defun block-start-cleanup (block)
 389   (declare (type cblock block))
 390   (node-enclosing-cleanup (continuation-next (block-start block))))
 391 (defun block-end-cleanup (block)
 392   (declare (type cblock block))
 393   (node-enclosing-cleanup (block-last block)))
 394
 395 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 396 ;;; if there is none.
 397 ;;;
 398 ;;; There can legitimately be no home lambda in dead code early in the
 399 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 400 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 401 ;;; where the block is just a placeholder during parsing and doesn't
 402 ;;; actually correspond to code which will be written anywhere.
 403 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 404 (defun block-home-lambda-or-null (block)
 405   (if (node-p (block-last block))
 406       ;; This is the old CMU CL way of doing it.
 407       (node-home-lambda (block-last block))
 408       ;; Now that SBCL uses this operation more aggressively than CMU
 409       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 410       ;;   1. It can fail in a few cases even when a meaningful home
 411       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 412       ;;      an IF.
 413       ;;   2. It can fail when converting a form which is born orphaned
 414       ;;      so that it never had a meaningful home lambda, e.g. a form
 415       ;;      which follows a RETURN-FROM or GO form.
 416       (let ((pred-list (block-pred block)))
 417         ;; To deal with case 1, we reason that
 418         ;; previous-in-target-execution-order blocks should be in the
 419         ;; same lambda, and that they seem in practice to be
 420         ;; previous-in-compilation-order blocks too, so we look back
 421         ;; to find one which is sufficiently initialized to tell us
 422         ;; what the home lambda is.
 423         (if pred-list
 424             ;; We could get fancy about this, flooding through the
 425             ;; graph of all the previous blocks, but in practice it
 426             ;; seems to work just to grab the first previous block and
 427             ;; use it.
 428             (node-home-lambda (block-last (first pred-list)))
 429             ;; In case 2, we end up with an empty PRED-LIST and
 430             ;; have to punt: There's no home lambda.
 431             nil))))
 432
 433 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 434 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 435 (defun block-home-lambda (block)
 436   (block-home-lambda-or-null block))
 437
 438 ;;; Return the IR1 physical environment for BLOCK.
 439 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 440 (defun block-physenv (block)
 441   (lambda-physenv (block-home-lambda block)))
 442
 443 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 444 ;;; of its original source's top level form in its compilation unit.
 445 (defun source-path-tlf-number (path)
 446   (declare (list path))
 447   (car (last path)))
 448
 449 ;;; Return the (reversed) list for the PATH in the original source
 450 ;;; (with the Top Level Form number last).
 451 (defun source-path-original-source (path)
 452   (declare (list path) (inline member))
 453   (cddr (member 'original-source-start path :test #'eq)))
 454
 455 ;;; Return the Form Number of PATH's original source inside the Top
 456 ;;; Level Form that contains it. This is determined by the order that
 457 ;;; we walk the subforms of the top level source form.
 458 (defun source-path-form-number (path)
 459   (declare (list path) (inline member))
 460   (cadr (member 'original-source-start path :test #'eq)))
 461
 462 ;;; Return a list of all the enclosing forms not in the original
 463 ;;; source that converted to get to this form, with the immediate
 464 ;;; source for node at the start of the list.
 465 (defun source-path-forms (path)
 466   (subseq path 0 (position 'original-source-start path)))
 467
 468 ;;; Return the innermost source form for NODE.
 469 (defun node-source-form (node)
 470   (declare (type node node))
 471   (let* ((path (node-source-path node))
 472          (forms (source-path-forms path)))
 473     (if forms
 474         (first forms)
 475         (values (find-original-source path)))))
 476
 477 ;;; Return NODE-SOURCE-FORM, T if continuation has a single use,
 478 ;;; otherwise NIL, NIL.
 479 (defun continuation-source (cont)
 480   (let ((use (continuation-use cont)))
 481     (if use
 482         (values (node-source-form use) t)
 483         (values nil nil))))
 484
 485 ;;; Return the LAMBDA that is CONT's home, or NIL if there is none.
 486 (declaim (ftype (sfunction (continuation) (or clambda null))
 487                 continuation-home-lambda-or-null))
 488 (defun continuation-home-lambda-or-null (cont)
 489   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 490   ;; implementation might not be quite right, or might be uglier than
 491   ;; necessary. It appears that the original Python never found a need
 492   ;; to do this operation. The obvious things based on
 493   ;; NODE-HOME-LAMBDA of CONTINUATION-USE usually work; then if that
 494   ;; fails, BLOCK-HOME-LAMBDA of CONTINUATION-BLOCK works, given that
 495   ;; we generalize it enough to grovel harder when the simple CMU CL
 496   ;; approach fails, and furthermore realize that in some exceptional
 497   ;; cases it might return NIL. -- WHN 2001-12-04
 498   (cond ((continuation-use cont)
 499          (node-home-lambda (continuation-use cont)))
 500         ((continuation-block cont)
 501          (block-home-lambda-or-null (continuation-block cont)))
 502         (t
 503          (bug "confused about home lambda for ~S"))))
 504
 505 ;;; Return the LAMBDA that is CONT's home.
 506 (declaim (ftype (sfunction (continuation) clambda)
 507                 continuation-home-lambda))
 508 (defun continuation-home-lambda (cont)
 509   (continuation-home-lambda-or-null cont))
 510
 511 #!-sb-fluid (declaim (inline continuation-single-value-p))
 512 (defun continuation-single-value-p (cont)
 513   (let ((dest (continuation-dest cont)))
 514     (typecase dest
 515       ((or creturn exit)
 516        nil)
 517       (mv-combination
 518        (eq (basic-combination-fun dest) cont))
 519       (cast
 520        (locally
 521            (declare (notinline continuation-single-value-p))
 522          (and (not (values-type-p (cast-asserted-type dest)))
 523               (continuation-single-value-p (node-cont dest)))))
 524       (t
 525        t))))
 526
 527 (defun principal-continuation-end (cont)
 528   (loop for prev = cont then (node-cont dest)
 529         for dest = (continuation-dest prev)
 530         while (cast-p dest)
 531         finally (return (values dest prev))))
 532
 533 (defun principal-continuation-single-valuify (cont)
 534   (loop for prev = cont then (node-cont dest)
 535      for dest = (continuation-dest prev)
 536      while (cast-p dest)
 537      do (setf (node-derived-type dest)
 538               (make-short-values-type (list (single-value-type
 539                                              (node-derived-type dest)))))
 540      (reoptimize-continuation prev)))
 541 \f
 542 ;;; Return a new LEXENV just like DEFAULT except for the specified
 543 ;;; slot values. Values for the alist slots are NCONCed to the
 544 ;;; beginning of the current value, rather than replacing it entirely.
 545 (defun make-lexenv (&key (default *lexenv*)
 546                          funs vars blocks tags
 547                          type-restrictions weakend-type-restrictions
 548                          (lambda (lexenv-lambda default))
 549                          (cleanup (lexenv-cleanup default))
 550                          (policy (lexenv-policy default)))
 551   (macrolet ((frob (var slot)
 552                `(let ((old (,slot default)))
 553                   (if ,var
 554                       (nconc ,var old)
 555                       old))))
 556     (internal-make-lexenv
 557      (frob funs lexenv-funs)
 558      (frob vars lexenv-vars)
 559      (frob blocks lexenv-blocks)
 560      (frob tags lexenv-tags)
 561      (frob type-restrictions lexenv-type-restrictions)
 562      (frob weakend-type-restrictions lexenv-weakend-type-restrictions)
 563      lambda cleanup policy)))
 564
 565 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 566 ;;; macroexpander
 567 (defun make-restricted-lexenv (lexenv)
 568   (flet ((fun-good-p (fun)
 569            (destructuring-bind (name . thing) fun
 570              (declare (ignore name))
 571              (etypecase thing
 572                (functional nil)
 573                (global-var t)
 574                (cons (aver (eq (car thing) 'macro))
 575                      t))))
 576          (var-good-p (var)
 577            (destructuring-bind (name . thing) var
 578              (declare (ignore name))
 579              (etypecase thing
 580                (leaf nil)
 581                (cons (aver (eq (car thing) 'macro))
 582                      t)
 583                (heap-alien-info nil)))))
 584     (internal-make-lexenv
 585      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 586      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 587      nil
 588      nil
 589      (lexenv-type-restrictions lexenv) ; XXX
 590      (lexenv-weakend-type-restrictions lexenv)
 591      nil
 592      nil
 593      (lexenv-policy lexenv))))
 594 \f
 595 ;;;; flow/DFO/component hackery
 596
 597 ;;; Join BLOCK1 and BLOCK2.
 598 (defun link-blocks (block1 block2)
 599   (declare (type cblock block1 block2))
 600   (setf (block-succ block1)
 601         (if (block-succ block1)
 602             (%link-blocks block1 block2)
 603             (list block2)))
 604   (push block1 (block-pred block2))
 605   (values))
 606 (defun %link-blocks (block1 block2)
 607   (declare (type cblock block1 block2) (inline member))
 608   (let ((succ1 (block-succ block1)))
 609     (aver (not (member block2 succ1 :test #'eq)))
 610     (cons block2 succ1)))
 611
 612 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 613 ;;; this leaves a successor with a single predecessor that ends in an
 614 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 615 ;;; now be able to be propagated to the successor.
 616 (defun unlink-blocks (block1 block2)
 617   (declare (type cblock block1 block2))
 618   (let ((succ1 (block-succ block1)))
 619     (if (eq block2 (car succ1))
 620         (setf (block-succ block1) (cdr succ1))
 621         (do ((succ (cdr succ1) (cdr succ))
 622              (prev succ1 succ))
 623             ((eq (car succ) block2)
 624              (setf (cdr prev) (cdr succ)))
 625           (aver succ))))
 626
 627   (let ((new-pred (delq block1 (block-pred block2))))
 628     (setf (block-pred block2) new-pred)
 629     (when (singleton-p new-pred)
 630       (let ((pred-block (first new-pred)))
 631         (when (if-p (block-last pred-block))
 632           (setf (block-test-modified pred-block) t)))))
 633   (values))
 634
 635 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 636 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 637 ;;; consequent/alternative blocks to point to NEW. We also set
 638 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 639 ;;; the new successor.
 640 (defun change-block-successor (block old new)
 641   (declare (type cblock new old block) (inline member))
 642   (unlink-blocks block old)
 643   (let ((last (block-last block))
 644         (comp (block-component block)))
 645     (setf (component-reanalyze comp) t)
 646     (typecase last
 647       (cif
 648        (setf (block-test-modified block) t)
 649        (let* ((succ-left (block-succ block))
 650               (new (if (and (eq new (component-tail comp))
 651                             succ-left)
 652                        (first succ-left)
 653                        new)))
 654          (unless (member new succ-left :test #'eq)
 655            (link-blocks block new))
 656          (macrolet ((frob (slot)
 657                       `(when (eq (,slot last) old)
 658                          (setf (,slot last) new))))
 659            (frob if-consequent)
 660            (frob if-alternative)
 661            (when (eq (if-consequent last)
 662                      (if-alternative last))
 663              (setf (component-reoptimize (block-component block)) t)))))
 664       (t
 665        (unless (member new (block-succ block) :test #'eq)
 666          (link-blocks block new)))))
 667
 668   (values))
 669
 670 ;;; Unlink a block from the next/prev chain. We also null out the
 671 ;;; COMPONENT.
 672 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 673 (defun remove-from-dfo (block)
 674   (let ((next (block-next block))
 675         (prev (block-prev block)))
 676     (setf (block-component block) nil)
 677     (setf (block-next prev) next)
 678     (setf (block-prev next) prev))
 679   (values))
 680
 681 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 682 ;;; COMPONENT to be the same as for AFTER.
 683 (defun add-to-dfo (block after)
 684   (declare (type cblock block after))
 685   (let ((next (block-next after))
 686         (comp (block-component after)))
 687     (aver (not (eq (component-kind comp) :deleted)))
 688     (setf (block-component block) comp)
 689     (setf (block-next after) block)
 690     (setf (block-prev block) after)
 691     (setf (block-next block) next)
 692     (setf (block-prev next) block))
 693   (values))
 694
 695 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 696 ;;; the head and tail which are set to T.
 697 (declaim (ftype (sfunction (component) (values)) clear-flags))
 698 (defun clear-flags (component)
 699   (let ((head (component-head component))
 700         (tail (component-tail component)))
 701     (setf (block-flag head) t)
 702     (setf (block-flag tail) t)
 703     (do-blocks (block component)
 704       (setf (block-flag block) nil)))
 705   (values))
 706
 707 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 708 ;;; true in the head and tail blocks.
 709 (declaim (ftype (sfunction () component) make-empty-component))
 710 (defun make-empty-component ()
 711   (let* ((head (make-block-key :start nil :component nil))
 712          (tail (make-block-key :start nil :component nil))
 713          (res (make-component head tail)))
 714     (setf (block-flag head) t)
 715     (setf (block-flag tail) t)
 716     (setf (block-component head) res)
 717     (setf (block-component tail) res)
 718     (setf (block-next head) tail)
 719     (setf (block-prev tail) head)
 720     res))
 721
 722 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 723 ;;; The new block is added to the DFO immediately following NODE's block.
 724 (defun node-ends-block (node)
 725   (declare (type node node))
 726   (let* ((block (node-block node))
 727          (start (node-cont node))
 728          (last (block-last block))
 729          (last-cont (node-cont last)))
 730     (unless (eq last node)
 731       (aver (and (eq (continuation-kind start) :inside-block)
 732                    (not (block-delete-p block))))
 733       (let* ((succ (block-succ block))
 734              (new-block
 735               (make-block-key :start start
 736                               :component (block-component block)
 737                               :start-uses (list (continuation-use start))
 738                               :succ succ :last last)))
 739         (setf (continuation-kind start) :block-start)
 740         (dolist (b succ)
 741           (setf (block-pred b)
 742                 (cons new-block (remove block (block-pred b)))))
 743         (setf (block-succ block) ())
 744         (setf (block-last block) node)
 745         (link-blocks block new-block)
 746         (add-to-dfo new-block block)
 747         (setf (component-reanalyze (block-component block)) t)
 748
 749         (do ((cont start (node-cont (continuation-next cont))))
 750             ((eq cont last-cont)
 751              (when (eq (continuation-kind last-cont) :inside-block)
 752                (setf (continuation-block last-cont) new-block)))
 753           (setf (continuation-block cont) new-block))
 754
 755         (setf (block-type-asserted block) t)
 756         (setf (block-test-modified block) t))))
 757
 758   (values))
 759 \f
 760 ;;;; deleting stuff
 761
 762 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 763 (defun delete-lambda-var (leaf)
 764   (declare (type lambda-var leaf))
 765
 766   ;; Iterate over all local calls flushing the corresponding argument,
 767   ;; allowing the computation of the argument to be deleted. We also
 768   ;; mark the LET for reoptimization, since it may be that we have
 769   ;; deleted its last variable.
 770   (let* ((fun (lambda-var-home leaf))
 771          (n (position leaf (lambda-vars fun))))
 772     (dolist (ref (leaf-refs fun))
 773       (let* ((cont (node-cont ref))
 774              (dest (continuation-dest cont)))
 775         (when (and (combination-p dest)
 776                    (eq (basic-combination-fun dest) cont)
 777                    (eq (basic-combination-kind dest) :local))
 778           (let* ((args (basic-combination-args dest))
 779                  (arg (elt args n)))
 780             (reoptimize-continuation arg)
 781             (flush-dest arg)
 782             (setf (elt args n) nil))))))
 783
 784   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 785   ;; too much difficulty, since we can efficiently implement
 786   ;; write-only variables. We iterate over the SETs, marking their
 787   ;; blocks for dead code flushing, since we can delete SETs whose
 788   ;; value is unused.
 789   (dolist (set (lambda-var-sets leaf))
 790     (setf (block-flush-p (node-block set)) t))
 791
 792   (values))
 793
 794 ;;; Note that something interesting has happened to VAR.
 795 (defun reoptimize-lambda-var (var)
 796   (declare (type lambda-var var))
 797   (let ((fun (lambda-var-home var)))
 798     ;; We only deal with LET variables, marking the corresponding
 799     ;; initial value arg as needing to be reoptimized.
 800     (when (and (eq (functional-kind fun) :let)
 801                (leaf-refs var))
 802       (do ((args (basic-combination-args
 803                   (continuation-dest
 804                    (node-cont
 805                     (first (leaf-refs fun)))))
 806                  (cdr args))
 807            (vars (lambda-vars fun) (cdr vars)))
 808           ((eq (car vars) var)
 809            (reoptimize-continuation (car args))))))
 810   (values))
 811
 812 ;;; Delete a function that has no references. This need only be called
 813 ;;; on functions that never had any references, since otherwise
 814 ;;; DELETE-REF will handle the deletion.
 815 (defun delete-functional (fun)
 816   (aver (and (null (leaf-refs fun))
 817              (not (functional-entry-fun fun))))
 818   (etypecase fun
 819     (optional-dispatch (delete-optional-dispatch fun))
 820     (clambda (delete-lambda fun)))
 821   (values))
 822
 823 ;;; Deal with deleting the last reference to a CLAMBDA. Since there is
 824 ;;; only one way into a CLAMBDA, deleting the last reference to a
 825 ;;; CLAMBDA ensures that there is no way to reach any of the code in
 826 ;;; it. So we just set the FUNCTIONAL-KIND for FUN and its LETs to
 827 ;;; :DELETED, causing IR1 optimization to delete blocks in that
 828 ;;; CLAMBDA.
 829 (defun delete-lambda (clambda)
 830   (declare (type clambda clambda))
 831   (let ((original-kind (functional-kind clambda))
 832         (bind (lambda-bind clambda)))
 833     (aver (not (member original-kind '(:deleted :optional :toplevel))))
 834     (aver (not (functional-has-external-references-p clambda)))
 835     (setf (functional-kind clambda) :deleted)
 836     (setf (lambda-bind clambda) nil)
 837     (dolist (let (lambda-lets clambda))
 838       (setf (lambda-bind let) nil)
 839       (setf (functional-kind let) :deleted))
 840
 841     ;; LET may be deleted if its BIND is unreachable. Autonomous
 842     ;; function may be deleted if it has no reachable references.
 843     (unless (member original-kind '(:let :mv-let :assignment))
 844       (dolist (ref (lambda-refs clambda))
 845         (mark-for-deletion (node-block ref))))
 846
 847     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 848     ;; that we're using the old value of the KIND slot, not the
 849     ;; current slot value, which has now been set to :DELETED.)
 850     (if (member original-kind '(:let :mv-let :assignment))
 851         (let ((home (lambda-home clambda)))
 852           (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 853         ;; If the function isn't a LET, we unlink the function head
 854         ;; and tail from the component head and tail to indicate that
 855         ;; the code is unreachable. We also delete the function from
 856         ;; COMPONENT-LAMBDAS (it won't be there before local call
 857         ;; analysis, but no matter.) If the lambda was never
 858         ;; referenced, we give a note.
 859         (let* ((bind-block (node-block bind))
 860                (component (block-component bind-block))
 861                (return (lambda-return clambda))
 862                (return-block (and return (node-block return))))
 863           (unless (leaf-ever-used clambda)
 864             (let ((*compiler-error-context* bind))
 865               (compiler-notify "deleting unused function~:[.~;~:*~%  ~S~]"
 866                                (leaf-debug-name clambda))))
 867           (unless (block-delete-p bind-block)
 868             (unlink-blocks (component-head component) bind-block))
 869           (when (and return-block (not (block-delete-p return-block)))
 870             (mark-for-deletion return-block)
 871             (unlink-blocks return-block (component-tail component)))
 872           (setf (component-reanalyze component) t)
 873           (let ((tails (lambda-tail-set clambda)))
 874             (setf (tail-set-funs tails)
 875                   (delete clambda (tail-set-funs tails)))
 876             (setf (lambda-tail-set clambda) nil))
 877           (setf (component-lambdas component)
 878                 (delete clambda (component-lambdas component)))))
 879
 880     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 881     ;; ENTRY-FUN so that people will know that it is not an entry
 882     ;; point anymore.
 883     (when (eq original-kind :external)
 884       (let ((fun (functional-entry-fun clambda)))
 885         (setf (functional-entry-fun fun) nil)
 886         (when (optional-dispatch-p fun)
 887           (delete-optional-dispatch fun)))))
 888
 889   (values))
 890
 891 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 892 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 893 ;;; is used both before and after local call analysis. Afterward, all
 894 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 895 ;;; to the XEP, leaving it with no references at all. So we look at
 896 ;;; the XEP to see whether an optional-dispatch is still really being
 897 ;;; used. But before local call analysis, there are no XEPs, and all
 898 ;;; references are direct.
 899 ;;;
 900 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 901 ;;; entry-points, making them be normal lambdas, and then deleting the
 902 ;;; ones with no references. This deletes any e-p lambdas that were
 903 ;;; either never referenced, or couldn't be deleted when the last
 904 ;;; reference was deleted (due to their :OPTIONAL kind.)
 905 ;;;
 906 ;;; Note that the last optional entry point may alias the main entry,
 907 ;;; so when we process the main entry, its KIND may have been changed
 908 ;;; to NIL or even converted to a LETlike value.
 909 (defun delete-optional-dispatch (leaf)
 910   (declare (type optional-dispatch leaf))
 911   (let ((entry (functional-entry-fun leaf)))
 912     (unless (and entry (leaf-refs entry))
 913       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 914       (setf (functional-kind leaf) :deleted)
 915
 916       (flet ((frob (fun)
 917                (unless (eq (functional-kind fun) :deleted)
 918                  (aver (eq (functional-kind fun) :optional))
 919                  (setf (functional-kind fun) nil)
 920                  (let ((refs (leaf-refs fun)))
 921                    (cond ((null refs)
 922                           (delete-lambda fun))
 923                          ((null (rest refs))
 924                           (or (maybe-let-convert fun)
 925                               (maybe-convert-to-assignment fun)))
 926                          (t
 927                           (maybe-convert-to-assignment fun)))))))
 928
 929         (dolist (ep (optional-dispatch-entry-points leaf))
 930           (when (promise-ready-p ep)
 931             (frob (force ep))))
 932         (when (optional-dispatch-more-entry leaf)
 933           (frob (optional-dispatch-more-entry leaf)))
 934         (let ((main (optional-dispatch-main-entry leaf)))
 935           (when (eq (functional-kind main) :optional)
 936             (frob main))))))
 937
 938   (values))
 939
 940 ;;; Do stuff to delete the semantic attachments of a REF node. When
 941 ;;; this leaves zero or one reference, we do a type dispatch off of
 942 ;;; the leaf to determine if a special action is appropriate.
 943 (defun delete-ref (ref)
 944   (declare (type ref ref))
 945   (let* ((leaf (ref-leaf ref))
 946          (refs (delete ref (leaf-refs leaf))))
 947     (setf (leaf-refs leaf) refs)
 948
 949     (cond ((null refs)
 950            (typecase leaf
 951              (lambda-var
 952               (delete-lambda-var leaf))
 953              (clambda
 954               (ecase (functional-kind leaf)
 955                 ((nil :let :mv-let :assignment :escape :cleanup)
 956                  (aver (null (functional-entry-fun leaf)))
 957                  (delete-lambda leaf))
 958                 (:external
 959                  (delete-lambda leaf))
 960                 ((:deleted :optional))))
 961              (optional-dispatch
 962               (unless (eq (functional-kind leaf) :deleted)
 963                 (delete-optional-dispatch leaf)))))
 964           ((null (rest refs))
 965            (typecase leaf
 966              (clambda (or (maybe-let-convert leaf)
 967                           (maybe-convert-to-assignment leaf)))
 968              (lambda-var (reoptimize-lambda-var leaf))))
 969           (t
 970            (typecase leaf
 971              (clambda (maybe-convert-to-assignment leaf))))))
 972
 973   (values))
 974
 975 ;;; This function is called by people who delete nodes; it provides a
 976 ;;; way to indicate that the value of a continuation is no longer
 977 ;;; used. We null out the CONTINUATION-DEST, set FLUSH-P in the blocks
 978 ;;; containing uses of CONT and set COMPONENT-REOPTIMIZE. If the PREV
 979 ;;; of the use is deleted, then we blow off reoptimization.
 980 ;;;
 981 ;;; If the continuation is :DELETED, then we don't do anything, since
 982 ;;; all semantics have already been flushed. :DELETED-BLOCK-START
 983 ;;; start continuations are treated just like :BLOCK-START; it is
 984 ;;; possible that the continuation may be given a new dest (e.g. by
 985 ;;; SUBSTITUTE-CONTINUATION), so we don't want to delete it.
 986 (defun flush-dest (cont)
 987   (declare (type continuation cont))
 988
 989   (unless (eq (continuation-kind cont) :deleted)
 990     (aver (continuation-dest cont))
 991     (setf (continuation-dest cont) nil)
 992     (flush-continuation-externally-checkable-type cont)
 993     (do-uses (use cont)
 994       (let ((prev (node-prev use)))
 995         (unless (eq (continuation-kind prev) :deleted)
 996           (let ((block (continuation-block prev)))
 997             (setf (component-reoptimize (block-component block)) t)
 998             (setf (block-attributep (block-flags block) flush-p type-asserted)
 999                   t))))))
1000
1001   (values))
1002
1003 (defun delete-dest (cont)
1004   (let ((dest (continuation-dest cont)))
1005     (when dest
1006       (let ((prev (node-prev dest)))
1007         (when (and prev
1008                    (not (eq (continuation-kind prev) :deleted)))
1009           (let ((block (continuation-block prev)))
1010             (unless (block-delete-p block)
1011               (mark-for-deletion block))))))))
1012
1013 ;;; Do a graph walk backward from BLOCK, marking all predecessor
1014 ;;; blocks with the DELETE-P flag.
1015 (defun mark-for-deletion (block)
1016   (declare (type cblock block))
1017   (let* ((component (block-component block))
1018          (head (component-head component)))
1019     (labels ((helper (block)
1020                (setf (block-delete-p block) t)
1021                (dolist (pred (block-pred block))
1022                  (unless (or (block-delete-p pred)
1023                              (eq pred head))
1024                    (helper pred)))))
1025       (unless (block-delete-p block)
1026         (helper block)
1027         (setf (component-reanalyze component) t))))
1028   (values))
1029
1030 ;;; Delete CONT, eliminating both control and value semantics. We set
1031 ;;; FLUSH-P and COMPONENT-REOPTIMIZE similarly to in FLUSH-DEST. Here
1032 ;;; we must get the component from the use block, since the
1033 ;;; continuation may be a :DELETED-BLOCK-START.
1034 ;;;
1035 ;;; If CONT has DEST, then it must be the case that the DEST is
1036 ;;; unreachable, since we can't compute the value desired. In this
1037 ;;; case, we call MARK-FOR-DELETION to cause the DEST block and its
1038 ;;; predecessors to tell people to ignore them, and to cause them to
1039 ;;; be deleted eventually.
1040 (defun delete-continuation (cont)
1041   (declare (type continuation cont))
1042   (aver (not (eq (continuation-kind cont) :deleted)))
1043
1044   (do-uses (use cont)
1045     (let ((prev (node-prev use)))
1046       (unless (eq (continuation-kind prev) :deleted)
1047         (let ((block (continuation-block prev)))
1048           (setf (block-attributep (block-flags block) flush-p type-asserted) t)
1049           (setf (component-reoptimize (block-component block)) t)))))
1050
1051   (delete-dest cont)
1052
1053   (setf (continuation-kind cont) :deleted)
1054   (setf (continuation-dest cont) nil)
1055   (flush-continuation-externally-checkable-type cont)
1056   (setf (continuation-next cont) nil)
1057   (setf (continuation-%derived-type cont) *empty-type*)
1058   (setf (continuation-use cont) nil)
1059   (setf (continuation-block cont) nil)
1060   (setf (continuation-reoptimize cont) nil)
1061   (setf (continuation-info cont) nil)
1062
1063   (values))
1064
1065 ;;; This function does what is necessary to eliminate the code in it
1066 ;;; from the IR1 representation. This involves unlinking it from its
1067 ;;; predecessors and successors and deleting various node-specific
1068 ;;; semantic information.
1069 ;;;
1070 ;;; We mark the START as has having no next and remove the last node
1071 ;;; from its CONT's uses. We also flush the DEST for all continuations
1072 ;;; whose values are received by nodes in the block.
1073 (defun delete-block (block &optional silent)
1074   (declare (type cblock block))
1075   (aver (block-component block))      ; else block is already deleted!
1076   (unless silent
1077     (note-block-deletion block))
1078   (setf (block-delete-p block) t)
1079
1080   (let ((last (block-last block)))
1081     (when last
1082       (let ((cont (node-cont last)))
1083         (delete-continuation-use last)
1084         (if (eq (continuation-kind cont) :unused)
1085             (delete-continuation cont)
1086             (reoptimize-continuation cont)))))
1087
1088   (dolist (b (block-pred block))
1089     (unlink-blocks b block)
1090     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
1091     ;; broken when successors were deleted without setting the
1092     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
1093     ;; doesn't happen again.
1094     (aver (not (and (null (block-succ b))
1095                     (not (block-delete-p b))
1096                     (not (eq b (component-head (block-component b))))))))
1097   (dolist (b (block-succ block))
1098     (unlink-blocks block b))
1099
1100   (do-nodes-carefully (node cont block)
1101     (typecase node
1102       (ref (delete-ref node))
1103       (cif
1104        (flush-dest (if-test node)))
1105       ;; The next two cases serve to maintain the invariant that a LET
1106       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1107       ;; the lambda whenever we delete any of these, but we must be
1108       ;; careful that this LET has not already been partially deleted.
1109       (basic-combination
1110        (when (and (eq (basic-combination-kind node) :local)
1111                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1112                   (continuation-use (basic-combination-fun node)))
1113          (let ((fun (combination-lambda node)))
1114            ;; If our REF was the second-to-last ref, and has been
1115            ;; deleted, then FUN may be a LET for some other
1116            ;; combination.
1117            (when (and (functional-letlike-p fun)
1118                       (eq (let-combination fun) node))
1119              (delete-lambda fun))))
1120        (flush-dest (basic-combination-fun node))
1121        (dolist (arg (basic-combination-args node))
1122          (when arg (flush-dest arg))))
1123       (bind
1124        (let ((lambda (bind-lambda node)))
1125          (unless (eq (functional-kind lambda) :deleted)
1126            (delete-lambda lambda))))
1127       (exit
1128        (let ((value (exit-value node))
1129              (entry (exit-entry node)))
1130          (when value
1131            (flush-dest value))
1132          (when entry
1133            (setf (entry-exits entry)
1134                  (delete node (entry-exits entry))))))
1135       (creturn
1136        (flush-dest (return-result node))
1137        (delete-return node))
1138       (cset
1139        (flush-dest (set-value node))
1140        (let ((var (set-var node)))
1141          (setf (basic-var-sets var)
1142                (delete node (basic-var-sets var)))))
1143       (cast
1144        (flush-dest (cast-value node))))
1145
1146        (delete-continuation (node-prev node)))
1147
1148   (remove-from-dfo block)
1149   (values))
1150
1151 ;;; Do stuff to indicate that the return node NODE is being deleted.
1152 (defun delete-return (node)
1153   (declare (type creturn node))
1154   (let* ((fun (return-lambda node))
1155          (tail-set (lambda-tail-set fun)))
1156     (aver (lambda-return fun))
1157     (setf (lambda-return fun) nil)
1158     (when (and tail-set (not (find-if #'lambda-return
1159                                       (tail-set-funs tail-set))))
1160       (setf (tail-set-type tail-set) *empty-type*)))
1161   (values))
1162
1163 ;;; If any of the VARS in FUN was never referenced and was not
1164 ;;; declared IGNORE, then complain.
1165 (defun note-unreferenced-vars (fun)
1166   (declare (type clambda fun))
1167   (dolist (var (lambda-vars fun))
1168     (unless (or (leaf-ever-used var)
1169                 (lambda-var-ignorep var))
1170       (let ((*compiler-error-context* (lambda-bind fun)))
1171         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1172           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1173           ;; requires this to be no more than a STYLE-WARNING.
1174           (compiler-style-warn "The variable ~S is defined but never used."
1175                                (leaf-debug-name var)))
1176         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1177   (values))
1178
1179 (defvar *deletion-ignored-objects* '(t nil))
1180
1181 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1182 ;;; our recursion so that we don't get lost in circular structures. We
1183 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1184 ;;; function referencess with variables), and we also ignore anything
1185 ;;; inside ' or #'.
1186 (defun present-in-form (obj form depth)
1187   (declare (type (integer 0 20) depth))
1188   (cond ((= depth 20) nil)
1189         ((eq obj form) t)
1190         ((atom form) nil)
1191         (t
1192          (let ((first (car form))
1193                (depth (1+ depth)))
1194            (if (member first '(quote function))
1195                nil
1196                (or (and (not (symbolp first))
1197                         (present-in-form obj first depth))
1198                    (do ((l (cdr form) (cdr l))
1199                         (n 0 (1+ n)))
1200                        ((or (atom l) (> n 100))
1201                         nil)
1202                      (declare (fixnum n))
1203                      (when (present-in-form obj (car l) depth)
1204                        (return t)))))))))
1205
1206 ;;; This function is called on a block immediately before we delete
1207 ;;; it. We check to see whether any of the code about to die appeared
1208 ;;; in the original source, and emit a note if so.
1209 ;;;
1210 ;;; If the block was in a lambda is now deleted, then we ignore the
1211 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1212 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1213 ;;; reasonable for a function to not return, and there is a different
1214 ;;; note for that case anyway.
1215 ;;;
1216 ;;; If the actual source is an atom, then we use a bunch of heuristics
1217 ;;; to guess whether this reference really appeared in the original
1218 ;;; source:
1219 ;;; -- If a symbol, it must be interned and not a keyword.
1220 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1221 ;;;    or a character.)
1222 ;;; -- The atom must be "present" in the original source form, and
1223 ;;;    present in all intervening actual source forms.
1224 (defun note-block-deletion (block)
1225   (let ((home (block-home-lambda block)))
1226     (unless (eq (functional-kind home) :deleted)
1227       (do-nodes (node cont block)
1228         (let* ((path (node-source-path node))
1229                (first (first path)))
1230           (when (or (eq first 'original-source-start)
1231                     (and (atom first)
1232                          (or (not (symbolp first))
1233                              (let ((pkg (symbol-package first)))
1234                                (and pkg
1235                                     (not (eq pkg (symbol-package :end))))))
1236                          (not (member first *deletion-ignored-objects*))
1237                          (not (typep first '(or fixnum character)))
1238                          (every (lambda (x)
1239                                   (present-in-form first x 0))
1240                                 (source-path-forms path))
1241                          (present-in-form first (find-original-source path)
1242                                           0)))
1243             (unless (return-p node)
1244               (let ((*compiler-error-context* node))
1245                 (compiler-notify "deleting unreachable code")))
1246             (return))))))
1247   (values))
1248
1249 ;;; Delete a node from a block, deleting the block if there are no
1250 ;;; nodes left. We remove the node from the uses of its CONT, but we
1251 ;;; don't deal with cleaning up any type-specific semantic
1252 ;;; attachments. If the CONT is :UNUSED after deleting this use, then
1253 ;;; we delete CONT. (Note :UNUSED is not the same as no uses. A
1254 ;;; continuation will only become :UNUSED if it was :INSIDE-BLOCK
1255 ;;; before.)
1256 ;;;
1257 ;;; If the node is the last node, there must be exactly one successor.
1258 ;;; We link all of our precedessors to the successor and unlink the
1259 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1260 ;;; left, and the block is a successor of itself, then we replace the
1261 ;;; only node with a degenerate exit node. This provides a way to
1262 ;;; represent the bodyless infinite loop, given the prohibition on
1263 ;;; empty blocks in IR1.
1264 (defun unlink-node (node)
1265   (declare (type node node))
1266   (let* ((cont (node-cont node))
1267          (next (continuation-next cont))
1268          (prev (node-prev node))
1269          (block (continuation-block prev))
1270          (prev-kind (continuation-kind prev))
1271          (last (block-last block)))
1272
1273     (unless (eq (continuation-kind cont) :deleted)
1274       (delete-continuation-use node)
1275       (when (eq (continuation-kind cont) :unused)
1276         (aver (not (continuation-dest cont)))
1277         (delete-continuation cont)))
1278
1279     (setf (block-type-asserted block) t)
1280     (setf (block-test-modified block) t)
1281
1282     (cond ((or (eq prev-kind :inside-block)
1283                (and (eq prev-kind :block-start)
1284                     (not (eq node last))))
1285            (cond ((eq node last)
1286                   (setf (block-last block) (continuation-use prev))
1287                   (setf (continuation-next prev) nil))
1288                  (t
1289                   (setf (continuation-next prev) next)
1290                   (setf (node-prev next) prev)
1291                   (when (and (if-p next) ; AOP wanted
1292                              (eq prev (if-test next)))
1293                     (reoptimize-continuation prev))))
1294            (setf (node-prev node) nil)
1295            nil)
1296           (t
1297            (aver (eq prev-kind :block-start))
1298            (aver (eq node last))
1299            (let* ((succ (block-succ block))
1300                   (next (first succ)))
1301              (aver (singleton-p succ))
1302              (cond
1303               ((member block succ)
1304                (with-ir1-environment-from-node node
1305                  (let ((exit (make-exit))
1306                        (dummy (make-continuation)))
1307                    (setf (continuation-next prev) nil)
1308                    (link-node-to-previous-continuation exit prev)
1309                    (add-continuation-use exit dummy)
1310                    (setf (block-last block) exit)))
1311                (setf (node-prev node) nil)
1312                nil)
1313               (t
1314                (aver (eq (block-start-cleanup block)
1315                          (block-end-cleanup block)))
1316                (unlink-blocks block next)
1317                (dolist (pred (block-pred block))
1318                  (change-block-successor pred block next))
1319                (remove-from-dfo block)
1320                (cond ((continuation-dest prev)
1321                       (setf (continuation-next prev) nil)
1322                       (setf (continuation-kind prev) :deleted-block-start))
1323                      (t
1324                       (delete-continuation prev)))
1325                (setf (node-prev node) nil)
1326                t)))))))
1327
1328 ;;; Return true if NODE has been deleted, false if it is still a valid
1329 ;;; part of IR1.
1330 (defun node-deleted (node)
1331   (declare (type node node))
1332   (let ((prev (node-prev node)))
1333     (not (and prev
1334               (not (eq (continuation-kind prev) :deleted))
1335               (let ((block (continuation-block prev)))
1336                 (and (block-component block)
1337                      (not (block-delete-p block))))))))
1338
1339 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1340 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1341 ;;; triggered by deletion.
1342 (defun delete-component (component)
1343   (declare (type component component))
1344   (aver (null (component-new-functionals component)))
1345   (setf (component-kind component) :deleted)
1346   (do-blocks (block component)
1347     (setf (block-delete-p block) t))
1348   (dolist (fun (component-lambdas component))
1349     (setf (functional-kind fun) nil)
1350     (setf (functional-entry-fun fun) nil)
1351     (setf (leaf-refs fun) nil)
1352     (delete-functional fun))
1353   (do-blocks (block component)
1354     (delete-block block))
1355   (values))
1356
1357 ;;; Convert code of the form
1358 ;;;   (FOO ... (FUN ...) ...)
1359 ;;; to
1360 ;;;   (FOO ...    ...    ...).
1361 ;;; In other words, replace the function combination FUN by its
1362 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1363 ;;; to blow out of whatever transform called this. Note, as the number
1364 ;;; of arguments changes, the transform must be prepared to return a
1365 ;;; lambda with a new lambda-list with the correct number of
1366 ;;; arguments.
1367 (defun extract-fun-args (cont fun num-args)
1368   #!+sb-doc
1369   "If CONT is a call to FUN with NUM-ARGS args, change those arguments
1370    to feed directly to the continuation-dest of CONT, which must be
1371    a combination."
1372   (declare (type continuation cont)
1373            (type symbol fun)
1374            (type index num-args))
1375   (let ((outside (continuation-dest cont))
1376         (inside (continuation-use cont)))
1377     (aver (combination-p outside))
1378     (unless (combination-p inside)
1379       (give-up-ir1-transform))
1380     (let ((inside-fun (combination-fun inside)))
1381       (unless (eq (continuation-fun-name inside-fun) fun)
1382         (give-up-ir1-transform))
1383       (let ((inside-args (combination-args inside)))
1384         (unless (= (length inside-args) num-args)
1385           (give-up-ir1-transform))
1386         (let* ((outside-args (combination-args outside))
1387                (arg-position (position cont outside-args))
1388                (before-args (subseq outside-args 0 arg-position))
1389                (after-args (subseq outside-args (1+ arg-position))))
1390           (dolist (arg inside-args)
1391             (setf (continuation-dest arg) outside)
1392             (flush-continuation-externally-checkable-type arg))
1393           (setf (combination-args inside) nil)
1394           (setf (combination-args outside)
1395                 (append before-args inside-args after-args))
1396           (change-ref-leaf (continuation-use inside-fun)
1397                            (find-free-fun 'list "???"))
1398           (setf (combination-kind inside)
1399                 (info :function :info 'list))
1400           (setf (node-derived-type inside) *wild-type*)
1401           (flush-dest cont)
1402           (values))))))
1403
1404 (defun flush-combination (combination)
1405   (declare (type combination combination))
1406   (flush-dest (combination-fun combination))
1407   (dolist (arg (combination-args combination))
1408     (flush-dest arg))
1409   (unlink-node combination)
1410   (values))
1411
1412 \f
1413 ;;;; leaf hackery
1414
1415 ;;; Change the LEAF that a REF refers to.
1416 (defun change-ref-leaf (ref leaf)
1417   (declare (type ref ref) (type leaf leaf))
1418   (unless (eq (ref-leaf ref) leaf)
1419     (push ref (leaf-refs leaf))
1420     (delete-ref ref)
1421     (setf (ref-leaf ref) leaf)
1422     (setf (leaf-ever-used leaf) t)
1423     (let* ((ltype (leaf-type leaf))
1424            (vltype (make-single-value-type ltype)))
1425       (if (let* ((cont (node-cont ref))
1426                  (dest (continuation-dest cont)))
1427             (and (basic-combination-p dest)
1428                  (eq cont (basic-combination-fun dest))
1429                  (csubtypep ltype (specifier-type 'function))))
1430           (setf (node-derived-type ref) vltype)
1431           (derive-node-type ref vltype)))
1432     (reoptimize-continuation (node-cont ref)))
1433   (values))
1434
1435 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1436 (defun substitute-leaf (new-leaf old-leaf)
1437   (declare (type leaf new-leaf old-leaf))
1438   (dolist (ref (leaf-refs old-leaf))
1439     (change-ref-leaf ref new-leaf))
1440   (values))
1441
1442 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1443 ;;; whether to substitute
1444 (defun substitute-leaf-if (test new-leaf old-leaf)
1445   (declare (type leaf new-leaf old-leaf) (type function test))
1446   (dolist (ref (leaf-refs old-leaf))
1447     (when (funcall test ref)
1448       (change-ref-leaf ref new-leaf)))
1449   (values))
1450
1451 ;;; Return a LEAF which represents the specified constant object. If
1452 ;;; the object is not in *CONSTANTS*, then we create a new constant
1453 ;;; LEAF and enter it.
1454 (defun find-constant (object)
1455   (if (typep object
1456              ;; FIXME: What is the significance of this test? ("things
1457              ;; that are worth uniquifying"?)
1458              '(or symbol number character instance))
1459       (or (gethash object *constants*)
1460           (setf (gethash object *constants*)
1461                 (make-constant :value object
1462                                :%source-name '.anonymous.
1463                                :type (ctype-of object)
1464                                :where-from :defined)))
1465       (make-constant :value object
1466                      :%source-name '.anonymous.
1467                      :type (ctype-of object)
1468                      :where-from :defined)))
1469 \f
1470 ;;; Return true if VAR would have to be closed over if environment
1471 ;;; analysis ran now (i.e. if there are any uses that have a different
1472 ;;; home lambda than VAR's home.)
1473 (defun closure-var-p (var)
1474   (declare (type lambda-var var))
1475   (let ((home (lambda-var-home var)))
1476     (cond ((eq (functional-kind home) :deleted)
1477            nil)
1478           (t (let ((home (lambda-home home)))
1479                (flet ((frob (l)
1480                         (find home l :key #'node-home-lambda
1481                               :test-not #'eq)))
1482                  (or (frob (leaf-refs var))
1483                      (frob (basic-var-sets var)))))))))
1484
1485 ;;; If there is a non-local exit noted in ENTRY's environment that
1486 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1487 (defun find-nlx-info (entry cont)
1488   (declare (type entry entry) (type continuation cont))
1489   (let ((entry-cleanup (entry-cleanup entry)))
1490     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1491       (when (and (eq (nlx-info-continuation nlx) cont)
1492                  (eq (nlx-info-cleanup nlx) entry-cleanup))
1493         (return nlx)))))
1494 \f
1495 ;;;; functional hackery
1496
1497 (declaim (ftype (sfunction (functional) clambda) main-entry))
1498 (defun main-entry (functional)
1499   (etypecase functional
1500     (clambda functional)
1501     (optional-dispatch
1502      (optional-dispatch-main-entry functional))))
1503
1504 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1505 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1506 ;;; optional with null default and no SUPPLIED-P. There must be a
1507 ;;; &REST arg with no references.
1508 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1509 (defun looks-like-an-mv-bind (functional)
1510   (and (optional-dispatch-p functional)
1511        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1512            ((null arg) nil)
1513          (let ((info (lambda-var-arg-info (car arg))))
1514            (unless info (return nil))
1515            (case (arg-info-kind info)
1516              (:optional
1517               (when (or (arg-info-supplied-p info) (arg-info-default info))
1518                 (return nil)))
1519              (:rest
1520               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1521              (t
1522               (return nil)))))))
1523
1524 ;;; Return true if function is an external entry point. This is true
1525 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1526 ;;; (:TOPLEVEL kind.)
1527 (defun xep-p (fun)
1528   (declare (type functional fun))
1529   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1530
1531 ;;; If CONT's only use is a non-notinline global function reference,
1532 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1533 ;;; is true, then we don't care if the leaf is NOTINLINE.
1534 (defun continuation-fun-name (cont &optional notinline-ok)
1535   (declare (type continuation cont))
1536   (let ((use (continuation-use cont)))
1537     (if (ref-p use)
1538         (let ((leaf (ref-leaf use)))
1539           (if (and (global-var-p leaf)
1540                    (eq (global-var-kind leaf) :global-function)
1541                    (or (not (defined-fun-p leaf))
1542                        (not (eq (defined-fun-inlinep leaf) :notinline))
1543                        notinline-ok))
1544               (leaf-source-name leaf)
1545               nil))
1546         nil)))
1547
1548 ;;; Return the source name of a combination. (This is an idiom
1549 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1550 (defun combination-fun-source-name (combination)
1551   (let ((ref (continuation-use (combination-fun combination))))
1552     (leaf-source-name (ref-leaf ref))))
1553
1554 ;;; Return the COMBINATION node that is the call to the LET FUN.
1555 (defun let-combination (fun)
1556   (declare (type clambda fun))
1557   (aver (functional-letlike-p fun))
1558   (continuation-dest (node-cont (first (leaf-refs fun)))))
1559
1560 ;;; Return the initial value continuation for a LET variable, or NIL
1561 ;;; if there is none.
1562 (defun let-var-initial-value (var)
1563   (declare (type lambda-var var))
1564   (let ((fun (lambda-var-home var)))
1565     (elt (combination-args (let-combination fun))
1566          (position-or-lose var (lambda-vars fun)))))
1567
1568 ;;; Return the LAMBDA that is called by the local CALL.
1569 (defun combination-lambda (call)
1570   (declare (type basic-combination call))
1571   (aver (eq (basic-combination-kind call) :local))
1572   (ref-leaf (continuation-use (basic-combination-fun call))))
1573
1574 (defvar *inline-expansion-limit* 200
1575   #!+sb-doc
1576   "an upper limit on the number of inline function calls that will be expanded
1577    in any given code object (single function or block compilation)")
1578
1579 ;;; Check whether NODE's component has exceeded its inline expansion
1580 ;;; limit, and warn if so, returning NIL.
1581 (defun inline-expansion-ok (node)
1582   (let ((expanded (incf (component-inline-expansions
1583                          (block-component
1584                           (node-block node))))))
1585     (cond ((> expanded *inline-expansion-limit*) nil)
1586           ((= expanded *inline-expansion-limit*)
1587            ;; FIXME: If the objective is to stop the recursive
1588            ;; expansion of inline functions, wouldn't it be more
1589            ;; correct to look back through surrounding expansions
1590            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1591            ;; possibly stored elsewhere too) and suppress expansion
1592            ;; and print this warning when the function being proposed
1593            ;; for inline expansion is found there? (I don't like the
1594            ;; arbitrary numerical limit in principle, and I think
1595            ;; it'll be a nuisance in practice if we ever want the
1596            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1597            ;; arbitrarily huge blocks of code. -- WHN)
1598            (let ((*compiler-error-context* node))
1599              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1600                                probably trying to~%  ~
1601                                inline a recursive function."
1602                               *inline-expansion-limit*))
1603            nil)
1604           (t t))))
1605
1606 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1607 (defun assure-functional-live-p (functional)
1608   (declare (type functional functional))
1609   (when (and (or
1610               ;; looks LET-converted
1611               (functional-somewhat-letlike-p functional)
1612               ;; It's possible for a LET-converted function to end up
1613               ;; deleted later. In that case, for the purposes of this
1614               ;; analysis, it is LET-converted: LET-converted functionals
1615               ;; are too badly trashed to expand them inline, and deleted
1616               ;; LET-converted functionals are even worse.
1617               (eql (functional-kind functional) :deleted)))
1618     (throw 'locall-already-let-converted functional)))
1619 \f
1620 ;;;; careful call
1621
1622 ;;; Apply a function to some arguments, returning a list of the values
1623 ;;; resulting of the evaluation. If an error is signalled during the
1624 ;;; application, then we produce a warning message using WARN-FUN and
1625 ;;; return NIL as our second value to indicate this. NODE is used as
1626 ;;; the error context for any error message, and CONTEXT is a string
1627 ;;; that is spliced into the warning.
1628 (declaim (ftype (sfunction ((or symbol function) list node function string)
1629                           (values list boolean))
1630                 careful-call))
1631 (defun careful-call (function args node warn-fun context)
1632   (values
1633    (multiple-value-list
1634     (handler-case (apply function args)
1635       (error (condition)
1636         (let ((*compiler-error-context* node))
1637           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1638           (return-from careful-call (values nil nil))))))
1639    t))
1640
1641 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1642 ;;; specifiers.
1643 (macrolet
1644     ((deffrob (basic careful compiler transform)
1645        `(progn
1646           (defun ,careful (specifier)
1647             (handler-case (,basic specifier)
1648               (sb!kernel::arg-count-error (condition)
1649                 (values nil (list (format nil "~A" condition))))
1650               (simple-error (condition)
1651                 (values nil (list* (simple-condition-format-control condition)
1652                                    (simple-condition-format-arguments condition))))))
1653           (defun ,compiler (specifier)
1654             (multiple-value-bind (type error-args) (,careful specifier)
1655               (or type
1656                   (apply #'compiler-error error-args))))
1657           (defun ,transform (specifier)
1658             (multiple-value-bind (type error-args) (,careful specifier)
1659               (or type
1660                   (apply #'give-up-ir1-transform
1661                          error-args)))))))
1662   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1663   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1664
1665 \f
1666 ;;;; utilities used at run-time for parsing &KEY args in IR1
1667
1668 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1669 ;;; the continuation for the value of the &KEY argument KEY in the
1670 ;;; list of continuations ARGS. It returns the continuation if the
1671 ;;; keyword is present, or NIL otherwise. The legality and
1672 ;;; constantness of the keywords should already have been checked.
1673 (declaim (ftype (sfunction (list keyword) (or continuation null))
1674                 find-keyword-continuation))
1675 (defun find-keyword-continuation (args key)
1676   (do ((arg args (cddr arg)))
1677       ((null arg) nil)
1678     (when (eq (continuation-value (first arg)) key)
1679       (return (second arg)))))
1680
1681 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1682 ;;; verify that alternating continuations in ARGS are constant and
1683 ;;; that there is an even number of args.
1684 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1685 (defun check-key-args-constant (args)
1686   (do ((arg args (cddr arg)))
1687       ((null arg) t)
1688     (unless (and (rest arg)
1689                  (constant-continuation-p (first arg)))
1690       (return nil))))
1691
1692 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1693 ;;; verify that the list of continuations ARGS is a well-formed &KEY
1694 ;;; arglist and that only keywords present in the list KEYS are
1695 ;;; supplied.
1696 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1697 (defun check-transform-keys (args keys)
1698   (and (check-key-args-constant args)
1699        (do ((arg args (cddr arg)))
1700            ((null arg) t)
1701          (unless (member (continuation-value (first arg)) keys)
1702            (return nil)))))
1703 \f
1704 ;;;; miscellaneous
1705
1706 ;;; Called by the expansion of the EVENT macro.
1707 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1708 (defun %event (info node)
1709   (incf (event-info-count info))
1710   (when (and (>= (event-info-level info) *event-note-threshold*)
1711              (policy (or node *lexenv*)
1712                      (= inhibit-warnings 0)))
1713     (let ((*compiler-error-context* node))
1714       (compiler-notify (event-info-description info))))
1715
1716   (let ((action (event-info-action info)))
1717     (when action (funcall action node))))
1718
1719 ;;;
1720 (defun make-cast (value type policy)
1721   (declare (type continuation value)
1722            (type ctype type)
1723            (type policy policy))
1724   (%make-cast :asserted-type type
1725               :type-to-check (maybe-weaken-check type policy)
1726               :value value
1727               :derived-type (coerce-to-values type)))
1728
1729 (defun cast-type-check (cast)
1730   (declare (type cast cast))
1731   (when (cast-reoptimize cast)
1732     (ir1-optimize-cast cast t))
1733   (cast-%type-check cast))
1734
1735 (defun note-single-valuified-continuation (cont)
1736   (declare (type continuation cont))
1737   (let ((use (continuation-use cont)))
1738     (cond ((ref-p use)
1739            (let ((leaf (ref-leaf use)))
1740              (when (and (lambda-var-p leaf)
1741                         (null (rest (leaf-refs leaf))))
1742                (reoptimize-lambda-var leaf))))
1743           ((or (null use) (combination-p use))
1744            (dolist (node (find-uses cont))
1745              (setf (node-reoptimize node) t)
1746              (setf (block-reoptimize (node-block node)) t)
1747              (setf (component-reoptimize (node-component node)) t))))))