src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (defun principal-lvar-use (lvar)
  66   (let ((use (lvar-uses lvar)))
  67     (if (cast-p use)
  68         (principal-lvar-use (cast-value use))
  69         use)))
  70
  71 ;;; Update lvar use information so that NODE is no longer a use of its
  72 ;;; LVAR.
  73 ;;;
  74 ;;; Note: if you call this function, you may have to do a
  75 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  76 ;;; changed.
  77 (declaim (ftype (sfunction (node) (values))
  78                 delete-lvar-use
  79                 %delete-lvar-use))
  80 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  81 ;;; be given a new use.
  82 (defun %delete-lvar-use (node)
  83   (let ((lvar (node-lvar node)))
  84     (when lvar
  85       (if (listp (lvar-uses lvar))
  86           (let ((new-uses (delq node (lvar-uses lvar))))
  87             (setf (lvar-uses lvar)
  88                   (if (singleton-p new-uses)
  89                       (first new-uses)
  90                       new-uses)))
  91           (setf (lvar-uses lvar) nil))
  92       (setf (node-lvar node) nil)))
  93   (values))
  94 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
  95 ;;; its DEST's block, which must be unreachable.
  96 (defun delete-lvar-use (node)
  97   (let ((lvar (node-lvar node)))
  98     (when lvar
  99       (%delete-lvar-use node)
 100       (if (null (lvar-uses lvar))
 101           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 102                      (() (not (node-deleted dest)) :exit-if-null)
 103                      (block (node-block dest)))
 104             (mark-for-deletion block))
 105           (reoptimize-lvar lvar))))
 106   (values))
 107
 108 ;;; Update lvar use information so that NODE uses LVAR.
 109 ;;;
 110 ;;; Note: if you call this function, you may have to do a
 111 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 112 ;;; changed.
 113 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 114 (defun add-lvar-use (node lvar)
 115   (aver (not (node-lvar node)))
 116   (when lvar
 117     (let ((uses (lvar-uses lvar)))
 118       (setf (lvar-uses lvar)
 119             (cond ((null uses)
 120                    node)
 121                   ((listp uses)
 122                    (cons node uses))
 123                   (t
 124                    (list node uses))))
 125       (setf (node-lvar node) lvar)))
 126
 127   (values))
 128
 129 ;;; Return true if LVAR destination is executed immediately after
 130 ;;; NODE. Cleanups are ignored.
 131 (defun immediately-used-p (lvar node)
 132   (declare (type lvar lvar) (type node node))
 133   (aver (eq (node-lvar node) lvar))
 134   (let ((dest (lvar-dest lvar)))
 135     (acond ((node-next node)
 136             (eq (ctran-next it) dest))
 137            (t (eq (block-start (first (block-succ (node-block node))))
 138                   (node-prev dest))))))
 139 \f
 140 ;;;; lvar substitution
 141
 142 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 143 ;;; NIL. We do not flush OLD's DEST.
 144 (defun substitute-lvar (new old)
 145   (declare (type lvar old new))
 146   (aver (not (lvar-dest new)))
 147   (let ((dest (lvar-dest old)))
 148     (etypecase dest
 149       ((or ref bind))
 150       (cif (setf (if-test dest) new))
 151       (cset (setf (set-value dest) new))
 152       (creturn (setf (return-result dest) new))
 153       (exit (setf (exit-value dest) new))
 154       (basic-combination
 155        (if (eq old (basic-combination-fun dest))
 156            (setf (basic-combination-fun dest) new)
 157            (setf (basic-combination-args dest)
 158                  (nsubst new old (basic-combination-args dest)))))
 159       (cast (setf (cast-value dest) new)))
 160
 161     (setf (lvar-dest old) nil)
 162     (setf (lvar-dest new) dest)
 163     (flush-lvar-externally-checkable-type new))
 164   (values))
 165
 166 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 167 ;;; arbitary number of uses.
 168 (defun substitute-lvar-uses (new old)
 169   (declare (type lvar old)
 170            (type (or lvar null) new))
 171
 172   (cond (new (do-uses (node old)
 173                (%delete-lvar-use node)
 174                (add-lvar-use node new))
 175              (reoptimize-lvar new))
 176         (t (flush-dest old)))
 177   (values))
 178 \f
 179 ;;;; block starting/creation
 180
 181 ;;; Return the block that CTRAN is the start of, making a block if
 182 ;;; necessary. This function is called by IR1 translators which may
 183 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 184 ;;; used more than once must start a block by the time that anyone
 185 ;;; does a USE-CTRAN on it.
 186 ;;;
 187 ;;; We also throw the block into the next/prev list for the
 188 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 189 ;;; made.
 190 (defun ctran-starts-block (ctran)
 191   (declare (type ctran ctran))
 192   (ecase (ctran-kind ctran)
 193     (:unused
 194      (aver (not (ctran-block ctran)))
 195      (let* ((next (component-last-block *current-component*))
 196             (prev (block-prev next))
 197             (new-block (make-block ctran)))
 198        (setf (block-next new-block) next
 199              (block-prev new-block) prev
 200              (block-prev next) new-block
 201              (block-next prev) new-block
 202              (ctran-block ctran) new-block
 203              (ctran-kind ctran) :block-start)
 204        (aver (not (ctran-use ctran)))
 205        new-block))
 206     (:block-start
 207      (ctran-block ctran))))
 208
 209 ;;; Ensure that CTRAN is the start of a block so that the use set can
 210 ;;; be freely manipulated.
 211 (defun ensure-block-start (ctran)
 212   (declare (type ctran ctran))
 213   (let ((kind (ctran-kind ctran)))
 214     (ecase kind
 215       ((:block-start))
 216       ((:unused)
 217        (setf (ctran-block ctran)
 218              (make-block-key :start ctran))
 219        (setf (ctran-kind ctran) :block-start))
 220       ((:inside-block)
 221        (node-ends-block (ctran-use ctran)))))
 222   (values))
 223
 224 ;;; CTRAN must be the last ctran in an incomplete block; finish the
 225 ;;; block and start a new one if necessary.
 226 (defun start-block (ctran)
 227   (declare (type ctran ctran))
 228   (aver (not (ctran-next ctran)))
 229   (ecase (ctran-kind ctran)
 230     (:inside-block
 231      (let ((block (ctran-block ctran))
 232            (node (ctran-use ctran)))
 233        (aver (not (block-last block)))
 234        (aver node)
 235        (setf (block-last block) node)
 236        (setf (node-next node) nil)
 237        (setf (ctran-use ctran) nil)
 238        (setf (ctran-kind ctran) :unused)
 239        (setf (ctran-block ctran) nil)
 240        (link-blocks block (ctran-starts-block ctran))))
 241     (:block-start)))
 242 \f
 243 ;;;;
 244
 245 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 246 ;;; call. First argument must be 'DUMMY, which will be replaced with
 247 ;;; LVAR. In case of an ordinary call the function should not have
 248 ;;; return type NIL. We create a new "filtered" lvar.
 249 ;;;
 250 ;;; TODO: remove preconditions.
 251 (defun filter-lvar (lvar form)
 252   (declare (type lvar lvar) (type list form))
 253   (let* ((dest (lvar-dest lvar))
 254          (ctran (node-prev dest)))
 255     (with-ir1-environment-from-node dest
 256
 257       (ensure-block-start ctran)
 258       (let* ((old-block (ctran-block ctran))
 259              (new-start (make-ctran))
 260              (filtered-lvar (make-lvar))
 261              (new-block (ctran-starts-block new-start)))
 262
 263         ;; Splice in the new block before DEST, giving the new block
 264         ;; all of DEST's predecessors.
 265         (dolist (block (block-pred old-block))
 266           (change-block-successor block old-block new-block))
 267
 268         (ir1-convert new-start ctran filtered-lvar form)
 269
 270         ;; KLUDGE: Comments at the head of this function in CMU CL
 271         ;; said that somewhere in here we
 272         ;;   Set the new block's start and end cleanups to the *start*
 273         ;;   cleanup of PREV's block. This overrides the incorrect
 274         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 275         ;; Unfortunately I can't find any code which corresponds to this.
 276         ;; Perhaps it was a stale comment? Or perhaps I just don't
 277         ;; understand.. -- WHN 19990521
 278
 279         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 280         ;; no LET conversion has been done yet.) The [mv-]combination
 281         ;; code from the call in the form will be the use of the new
 282         ;; check lvar. We substitute for the first argument of
 283         ;; this node.
 284         (let* ((node (lvar-use filtered-lvar))
 285                (args (basic-combination-args node))
 286                (victim (first args)))
 287           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 288                     'dummy))
 289
 290           (substitute-lvar filtered-lvar lvar)
 291           (substitute-lvar lvar victim)
 292           (flush-dest victim))
 293
 294         ;; Invoking local call analysis converts this call to a LET.
 295         (locall-analyze-component *current-component*))))
 296   (values))
 297
 298 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 299 (defun delete-filter (node lvar value)
 300   (aver (eq (lvar-dest value) node))
 301   (aver (eq (node-lvar node) lvar))
 302   (cond (lvar (collect ((merges))
 303                 (when (return-p (lvar-dest lvar))
 304                   (do-uses (use value)
 305                     (when (and (basic-combination-p use)
 306                                (eq (basic-combination-kind use) :local))
 307                       (merges use))))
 308                 (%delete-lvar-use node)
 309                 (substitute-lvar-uses lvar value)
 310                 (prog1
 311                     (unlink-node node)
 312                   (dolist (merge (merges))
 313                     (merge-tail-sets merge)))))
 314         (t (flush-dest value)
 315            (unlink-node node))))
 316 \f
 317 ;;;; miscellaneous shorthand functions
 318
 319 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 320 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 321 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 322 ;;; deleted, and then return its home.
 323 (defun node-home-lambda (node)
 324   (declare (type node node))
 325   (do ((fun (lexenv-lambda (node-lexenv node))
 326             (lexenv-lambda (lambda-call-lexenv fun))))
 327       ((not (memq (functional-kind fun) '(:deleted :zombie)))
 328        (lambda-home fun))
 329     (when (eq (lambda-home fun) fun)
 330       (return fun))))
 331
 332 #!-sb-fluid (declaim (inline node-block))
 333 (defun node-block (node)
 334   (ctran-block (node-prev node)))
 335 (declaim (ftype (sfunction (node) component) node-component))
 336 (defun node-component (node)
 337   (block-component (node-block node)))
 338 (declaim (ftype (sfunction (node) physenv) node-physenv))
 339 (defun node-physenv (node)
 340   (lambda-physenv (node-home-lambda node)))
 341 #!-sb-fluid (declaim (inline node-dest))
 342 (defun node-dest (node)
 343   (awhen (node-lvar node) (lvar-dest it)))
 344
 345 (declaim (inline block-to-be-deleted-p))
 346 (defun block-to-be-deleted-p (block)
 347   (or (block-delete-p block)
 348       (eq (functional-kind (block-home-lambda block)) :deleted)))
 349
 350 ;;; Checks whether NODE is in a block to be deleted
 351 (declaim (inline node-to-be-deleted-p))
 352 (defun node-to-be-deleted-p (node)
 353   (block-to-be-deleted-p (node-block node)))
 354
 355 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 356 (defun lambda-block (clambda)
 357   (node-block (lambda-bind clambda)))
 358 (declaim (ftype (sfunction (clambda) component) lambda-component))
 359 (defun lambda-component (clambda)
 360   (block-component (lambda-block clambda)))
 361
 362 (declaim (ftype (sfunction (cblock) node) block-start-node))
 363 (defun block-start-node (block)
 364   (ctran-next (block-start block)))
 365
 366 ;;; Return the enclosing cleanup for environment of the first or last
 367 ;;; node in BLOCK.
 368 (defun block-start-cleanup (block)
 369   (node-enclosing-cleanup (block-start-node block)))
 370 (defun block-end-cleanup (block)
 371   (node-enclosing-cleanup (block-last block)))
 372
 373 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 374 ;;; if there is none.
 375 ;;;
 376 ;;; There can legitimately be no home lambda in dead code early in the
 377 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 378 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 379 ;;; where the block is just a placeholder during parsing and doesn't
 380 ;;; actually correspond to code which will be written anywhere.
 381 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 382 (defun block-home-lambda-or-null (block)
 383   (if (node-p (block-last block))
 384       ;; This is the old CMU CL way of doing it.
 385       (node-home-lambda (block-last block))
 386       ;; Now that SBCL uses this operation more aggressively than CMU
 387       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 388       ;;   1. It can fail in a few cases even when a meaningful home
 389       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 390       ;;      an IF.
 391       ;;   2. It can fail when converting a form which is born orphaned
 392       ;;      so that it never had a meaningful home lambda, e.g. a form
 393       ;;      which follows a RETURN-FROM or GO form.
 394       (let ((pred-list (block-pred block)))
 395         ;; To deal with case 1, we reason that
 396         ;; previous-in-target-execution-order blocks should be in the
 397         ;; same lambda, and that they seem in practice to be
 398         ;; previous-in-compilation-order blocks too, so we look back
 399         ;; to find one which is sufficiently initialized to tell us
 400         ;; what the home lambda is.
 401         (if pred-list
 402             ;; We could get fancy about this, flooding through the
 403             ;; graph of all the previous blocks, but in practice it
 404             ;; seems to work just to grab the first previous block and
 405             ;; use it.
 406             (node-home-lambda (block-last (first pred-list)))
 407             ;; In case 2, we end up with an empty PRED-LIST and
 408             ;; have to punt: There's no home lambda.
 409             nil))))
 410
 411 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 412 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 413 (defun block-home-lambda (block)
 414   (block-home-lambda-or-null block))
 415
 416 ;;; Return the IR1 physical environment for BLOCK.
 417 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 418 (defun block-physenv (block)
 419   (lambda-physenv (block-home-lambda block)))
 420
 421 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 422 ;;; of its original source's top level form in its compilation unit.
 423 (defun source-path-tlf-number (path)
 424   (declare (list path))
 425   (car (last path)))
 426
 427 ;;; Return the (reversed) list for the PATH in the original source
 428 ;;; (with the Top Level Form number last).
 429 (defun source-path-original-source (path)
 430   (declare (list path) (inline member))
 431   (cddr (member 'original-source-start path :test #'eq)))
 432
 433 ;;; Return the Form Number of PATH's original source inside the Top
 434 ;;; Level Form that contains it. This is determined by the order that
 435 ;;; we walk the subforms of the top level source form.
 436 (defun source-path-form-number (path)
 437   (declare (list path) (inline member))
 438   (cadr (member 'original-source-start path :test #'eq)))
 439
 440 ;;; Return a list of all the enclosing forms not in the original
 441 ;;; source that converted to get to this form, with the immediate
 442 ;;; source for node at the start of the list.
 443 (defun source-path-forms (path)
 444   (subseq path 0 (position 'original-source-start path)))
 445
 446 ;;; Return the innermost source form for NODE.
 447 (defun node-source-form (node)
 448   (declare (type node node))
 449   (let* ((path (node-source-path node))
 450          (forms (source-path-forms path)))
 451     (if forms
 452         (first forms)
 453         (values (find-original-source path)))))
 454
 455 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 456 ;;; NIL, NIL.
 457 (defun lvar-source (lvar)
 458   (let ((use (lvar-uses lvar)))
 459     (if (listp use)
 460         (values nil nil)
 461         (values (node-source-form use) t))))
 462
 463 ;;; Return the unique node, delivering a value to LVAR.
 464 #!-sb-fluid (declaim (inline lvar-use))
 465 (defun lvar-use (lvar)
 466   (the (not list) (lvar-uses lvar)))
 467
 468 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 469 (defun lvar-has-single-use-p (lvar)
 470   (typep (lvar-uses lvar) '(not list)))
 471
 472 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 473 (declaim (ftype (sfunction (ctran) (or clambda null))
 474                 ctran-home-lambda-or-null))
 475 (defun ctran-home-lambda-or-null (ctran)
 476   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 477   ;; implementation might not be quite right, or might be uglier than
 478   ;; necessary. It appears that the original Python never found a need
 479   ;; to do this operation. The obvious things based on
 480   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 481   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 482   ;; generalize it enough to grovel harder when the simple CMU CL
 483   ;; approach fails, and furthermore realize that in some exceptional
 484   ;; cases it might return NIL. -- WHN 2001-12-04
 485   (cond ((ctran-use ctran)
 486          (node-home-lambda (ctran-use ctran)))
 487         ((ctran-block ctran)
 488          (block-home-lambda-or-null (ctran-block ctran)))
 489         (t
 490          (bug "confused about home lambda for ~S" ctran))))
 491
 492 ;;; Return the LAMBDA that is CTRAN's home.
 493 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 494 (defun ctran-home-lambda (ctran)
 495   (ctran-home-lambda-or-null ctran))
 496
 497 (declaim (inline cast-single-value-p))
 498 (defun cast-single-value-p (cast)
 499   (not (values-type-p (cast-asserted-type cast))))
 500
 501 #!-sb-fluid (declaim (inline lvar-single-value-p))
 502 (defun lvar-single-value-p (lvar)
 503   (or (not lvar)
 504       (let ((dest (lvar-dest lvar)))
 505         (typecase dest
 506           ((or creturn exit)
 507            nil)
 508           (mv-combination
 509            (eq (basic-combination-fun dest) lvar))
 510           (cast
 511            (locally
 512                (declare (notinline lvar-single-value-p))
 513              (and (cast-single-value-p dest)
 514                   (lvar-single-value-p (node-lvar dest)))))
 515           (t
 516            t)))))
 517
 518 (defun principal-lvar-end (lvar)
 519   (loop for prev = lvar then (node-lvar dest)
 520         for dest = (and prev (lvar-dest prev))
 521         while (cast-p dest)
 522         finally (return (values dest prev))))
 523
 524 (defun principal-lvar-single-valuify (lvar)
 525   (loop for prev = lvar then (node-lvar dest)
 526         for dest = (and prev (lvar-dest prev))
 527         while (cast-p dest)
 528         do (setf (node-derived-type dest)
 529                  (make-short-values-type (list (single-value-type
 530                                                 (node-derived-type dest)))))
 531         (reoptimize-lvar prev)))
 532 \f
 533 ;;; Return a new LEXENV just like DEFAULT except for the specified
 534 ;;; slot values. Values for the alist slots are NCONCed to the
 535 ;;; beginning of the current value, rather than replacing it entirely.
 536 (defun make-lexenv (&key (default *lexenv*)
 537                          funs vars blocks tags
 538                          type-restrictions
 539                          (lambda (lexenv-lambda default))
 540                          (cleanup (lexenv-cleanup default))
 541                          (policy (lexenv-policy default)))
 542   (macrolet ((frob (var slot)
 543                `(let ((old (,slot default)))
 544                   (if ,var
 545                       (nconc ,var old)
 546                       old))))
 547     (internal-make-lexenv
 548      (frob funs lexenv-funs)
 549      (frob vars lexenv-vars)
 550      (frob blocks lexenv-blocks)
 551      (frob tags lexenv-tags)
 552      (frob type-restrictions lexenv-type-restrictions)
 553      lambda cleanup policy)))
 554
 555 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 556 ;;; macroexpander
 557 (defun make-restricted-lexenv (lexenv)
 558   (flet ((fun-good-p (fun)
 559            (destructuring-bind (name . thing) fun
 560              (declare (ignore name))
 561              (etypecase thing
 562                (functional nil)
 563                (global-var t)
 564                (cons (aver (eq (car thing) 'macro))
 565                      t))))
 566          (var-good-p (var)
 567            (destructuring-bind (name . thing) var
 568              (declare (ignore name))
 569              (etypecase thing
 570                (leaf nil)
 571                (cons (aver (eq (car thing) 'macro))
 572                      t)
 573                (heap-alien-info nil)))))
 574     (internal-make-lexenv
 575      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 576      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 577      nil
 578      nil
 579      (lexenv-type-restrictions lexenv) ; XXX
 580      nil
 581      nil
 582      (lexenv-policy lexenv))))
 583 \f
 584 ;;;; flow/DFO/component hackery
 585
 586 ;;; Join BLOCK1 and BLOCK2.
 587 (defun link-blocks (block1 block2)
 588   (declare (type cblock block1 block2))
 589   (setf (block-succ block1)
 590         (if (block-succ block1)
 591             (%link-blocks block1 block2)
 592             (list block2)))
 593   (push block1 (block-pred block2))
 594   (values))
 595 (defun %link-blocks (block1 block2)
 596   (declare (type cblock block1 block2))
 597   (let ((succ1 (block-succ block1)))
 598     (aver (not (memq block2 succ1)))
 599     (cons block2 succ1)))
 600
 601 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 602 ;;; this leaves a successor with a single predecessor that ends in an
 603 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 604 ;;; now be able to be propagated to the successor.
 605 (defun unlink-blocks (block1 block2)
 606   (declare (type cblock block1 block2))
 607   (let ((succ1 (block-succ block1)))
 608     (if (eq block2 (car succ1))
 609         (setf (block-succ block1) (cdr succ1))
 610         (do ((succ (cdr succ1) (cdr succ))
 611              (prev succ1 succ))
 612             ((eq (car succ) block2)
 613              (setf (cdr prev) (cdr succ)))
 614           (aver succ))))
 615
 616   (let ((new-pred (delq block1 (block-pred block2))))
 617     (setf (block-pred block2) new-pred)
 618     (when (singleton-p new-pred)
 619       (let ((pred-block (first new-pred)))
 620         (when (if-p (block-last pred-block))
 621           (setf (block-test-modified pred-block) t)))))
 622   (values))
 623
 624 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 625 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 626 ;;; consequent/alternative blocks to point to NEW. We also set
 627 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 628 ;;; the new successor.
 629 (defun change-block-successor (block old new)
 630   (declare (type cblock new old block))
 631   (unlink-blocks block old)
 632   (let ((last (block-last block))
 633         (comp (block-component block)))
 634     (setf (component-reanalyze comp) t)
 635     (typecase last
 636       (cif
 637        (setf (block-test-modified block) t)
 638        (let* ((succ-left (block-succ block))
 639               (new (if (and (eq new (component-tail comp))
 640                             succ-left)
 641                        (first succ-left)
 642                        new)))
 643          (unless (memq new succ-left)
 644            (link-blocks block new))
 645          (macrolet ((frob (slot)
 646                       `(when (eq (,slot last) old)
 647                          (setf (,slot last) new))))
 648            (frob if-consequent)
 649            (frob if-alternative)
 650            (when (eq (if-consequent last)
 651                      (if-alternative last))
 652              (setf (component-reoptimize (block-component block)) t)))))
 653       (t
 654        (unless (memq new (block-succ block))
 655          (link-blocks block new)))))
 656
 657   (values))
 658
 659 ;;; Unlink a block from the next/prev chain. We also null out the
 660 ;;; COMPONENT.
 661 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 662 (defun remove-from-dfo (block)
 663   (let ((next (block-next block))
 664         (prev (block-prev block)))
 665     (setf (block-component block) nil)
 666     (setf (block-next prev) next)
 667     (setf (block-prev next) prev))
 668   (values))
 669
 670 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 671 ;;; COMPONENT to be the same as for AFTER.
 672 (defun add-to-dfo (block after)
 673   (declare (type cblock block after))
 674   (let ((next (block-next after))
 675         (comp (block-component after)))
 676     (aver (not (eq (component-kind comp) :deleted)))
 677     (setf (block-component block) comp)
 678     (setf (block-next after) block)
 679     (setf (block-prev block) after)
 680     (setf (block-next block) next)
 681     (setf (block-prev next) block))
 682   (values))
 683
 684 ;;; List all NLX-INFOs which BLOCK can exit to.
 685 ;;;
 686 ;;; We hope that no cleanup actions are performed in the middle of
 687 ;;; BLOCK, so it is enough to look only at cleanups in the block
 688 ;;; end. The tricky thing is a special cleanup block; all its nodes
 689 ;;; have the same cleanup info, corresponding to the start, so the
 690 ;;; same approach returns safe result.
 691 (defun map-block-nlxes (fun block)
 692   (loop for cleanup = (block-end-cleanup block)
 693         then (node-enclosing-cleanup (cleanup-mess-up cleanup))
 694         while cleanup
 695         do (let ((mess-up (cleanup-mess-up cleanup)))
 696              (case (cleanup-kind cleanup)
 697                ((:block :tagbody)
 698                 (aver (entry-p mess-up))
 699                 (loop for exit in (entry-exits mess-up)
 700                       for nlx-info = (find-nlx-info exit)
 701                       do (funcall fun nlx-info)))
 702                ((:catch :unwind-protect)
 703                 (aver (combination-p mess-up))
 704                 (let* ((arg-lvar (first (basic-combination-args mess-up)))
 705                        (nlx-info (constant-value (ref-leaf (lvar-use arg-lvar)))))
 706                 (funcall fun nlx-info)))))))
 707
 708 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 709 ;;; the head and tail which are set to T.
 710 (declaim (ftype (sfunction (component) (values)) clear-flags))
 711 (defun clear-flags (component)
 712   (let ((head (component-head component))
 713         (tail (component-tail component)))
 714     (setf (block-flag head) t)
 715     (setf (block-flag tail) t)
 716     (do-blocks (block component)
 717       (setf (block-flag block) nil)))
 718   (values))
 719
 720 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 721 ;;; true in the head and tail blocks.
 722 (declaim (ftype (sfunction () component) make-empty-component))
 723 (defun make-empty-component ()
 724   (let* ((head (make-block-key :start nil :component nil))
 725          (tail (make-block-key :start nil :component nil))
 726          (res (make-component head tail)))
 727     (setf (block-flag head) t)
 728     (setf (block-flag tail) t)
 729     (setf (block-component head) res)
 730     (setf (block-component tail) res)
 731     (setf (block-next head) tail)
 732     (setf (block-prev tail) head)
 733     res))
 734
 735 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 736 ;;; The new block is added to the DFO immediately following NODE's block.
 737 (defun node-ends-block (node)
 738   (declare (type node node))
 739   (let* ((block (node-block node))
 740          (start (node-next node))
 741          (last (block-last block)))
 742     (unless (eq last node)
 743       (aver (and (eq (ctran-kind start) :inside-block)
 744                  (not (block-delete-p block))))
 745       (let* ((succ (block-succ block))
 746              (new-block
 747               (make-block-key :start start
 748                               :component (block-component block)
 749                               :succ succ :last last)))
 750         (setf (ctran-kind start) :block-start)
 751         (setf (ctran-use start) nil)
 752         (setf (block-last block) node)
 753         (setf (node-next node) nil)
 754         (dolist (b succ)
 755           (setf (block-pred b)
 756                 (cons new-block (remove block (block-pred b)))))
 757         (setf (block-succ block) ())
 758         (link-blocks block new-block)
 759         (add-to-dfo new-block block)
 760         (setf (component-reanalyze (block-component block)) t)
 761
 762         (do ((ctran start (node-next (ctran-next ctran))))
 763             ((not ctran))
 764           (setf (ctran-block ctran) new-block))
 765
 766         (setf (block-type-asserted block) t)
 767         (setf (block-test-modified block) t))))
 768   (values))
 769 \f
 770 ;;;; deleting stuff
 771
 772 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 773 (defun delete-lambda-var (leaf)
 774   (declare (type lambda-var leaf))
 775
 776   ;; Iterate over all local calls flushing the corresponding argument,
 777   ;; allowing the computation of the argument to be deleted. We also
 778   ;; mark the LET for reoptimization, since it may be that we have
 779   ;; deleted its last variable.
 780   (let* ((fun (lambda-var-home leaf))
 781          (n (position leaf (lambda-vars fun))))
 782     (dolist (ref (leaf-refs fun))
 783       (let* ((lvar (node-lvar ref))
 784              (dest (and lvar (lvar-dest lvar))))
 785         (when (and (combination-p dest)
 786                    (eq (basic-combination-fun dest) lvar)
 787                    (eq (basic-combination-kind dest) :local))
 788           (let* ((args (basic-combination-args dest))
 789                  (arg (elt args n)))
 790             (reoptimize-lvar arg)
 791             (flush-dest arg)
 792             (setf (elt args n) nil))))))
 793
 794   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 795   ;; too much difficulty, since we can efficiently implement
 796   ;; write-only variables. We iterate over the SETs, marking their
 797   ;; blocks for dead code flushing, since we can delete SETs whose
 798   ;; value is unused.
 799   (dolist (set (lambda-var-sets leaf))
 800     (setf (block-flush-p (node-block set)) t))
 801
 802   (values))
 803
 804 ;;; Note that something interesting has happened to VAR.
 805 (defun reoptimize-lambda-var (var)
 806   (declare (type lambda-var var))
 807   (let ((fun (lambda-var-home var)))
 808     ;; We only deal with LET variables, marking the corresponding
 809     ;; initial value arg as needing to be reoptimized.
 810     (when (and (eq (functional-kind fun) :let)
 811                (leaf-refs var))
 812       (do ((args (basic-combination-args
 813                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 814                  (cdr args))
 815            (vars (lambda-vars fun) (cdr vars)))
 816           ((eq (car vars) var)
 817            (reoptimize-lvar (car args))))))
 818   (values))
 819
 820 ;;; Delete a function that has no references. This need only be called
 821 ;;; on functions that never had any references, since otherwise
 822 ;;; DELETE-REF will handle the deletion.
 823 (defun delete-functional (fun)
 824   (aver (and (null (leaf-refs fun))
 825              (not (functional-entry-fun fun))))
 826   (etypecase fun
 827     (optional-dispatch (delete-optional-dispatch fun))
 828     (clambda (delete-lambda fun)))
 829   (values))
 830
 831 ;;; Deal with deleting the last reference to a CLAMBDA, which means
 832 ;;; that the lambda is unreachable, so that its body may be
 833 ;;; deleted. We set FUNCTIONAL-KIND to :DELETED and rely on
 834 ;;; IR1-OPTIMIZE to delete its blocks.
 835 (defun delete-lambda (clambda)
 836   (declare (type clambda clambda))
 837   (let ((original-kind (functional-kind clambda))
 838         (bind (lambda-bind clambda)))
 839     (aver (not (member original-kind '(:deleted :toplevel))))
 840     (aver (not (functional-has-external-references-p clambda)))
 841     (aver (or (eq original-kind :zombie) bind))
 842     (setf (functional-kind clambda) :deleted)
 843     (setf (lambda-bind clambda) nil)
 844
 845     (labels ((delete-children (lambda)
 846                (dolist (child (lambda-children lambda))
 847                  (cond ((eq (functional-kind child) :deleted)
 848                         (delete-children child))
 849                        (t
 850                         (delete-lambda child))))
 851                (setf (lambda-children lambda) nil)
 852                (setf (lambda-parent lambda) nil)))
 853       (delete-children clambda))
 854
 855     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 856     ;; that we're using the old value of the KIND slot, not the
 857     ;; current slot value, which has now been set to :DELETED.)
 858     (case original-kind
 859       (:zombie)
 860       ((:let :mv-let :assignment)
 861        (let ((bind-block (node-block bind)))
 862          (mark-for-deletion bind-block))
 863        (let ((home (lambda-home clambda)))
 864          (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 865        ;; KLUDGE: In presence of NLEs we cannot always understand that
 866        ;; LET's BIND dominates its body [for a LET "its" body is not
 867        ;; quite its]; let's delete too dangerous for IR2 stuff. --
 868        ;; APD, 2004-01-01
 869        (dolist (var (lambda-vars clambda))
 870          (flet ((delete-node (node)
 871                   (mark-for-deletion (node-block node))))
 872          (mapc #'delete-node (leaf-refs var))
 873          (mapc #'delete-node (lambda-var-sets var)))))
 874       (t
 875        ;; Function has no reachable references.
 876        (dolist (ref (lambda-refs clambda))
 877          (mark-for-deletion (node-block ref)))
 878        ;; If the function isn't a LET, we unlink the function head
 879        ;; and tail from the component head and tail to indicate that
 880        ;; the code is unreachable. We also delete the function from
 881        ;; COMPONENT-LAMBDAS (it won't be there before local call
 882        ;; analysis, but no matter.) If the lambda was never
 883        ;; referenced, we give a note.
 884        (let* ((bind-block (node-block bind))
 885               (component (block-component bind-block))
 886               (return (lambda-return clambda))
 887               (return-block (and return (node-block return))))
 888          (unless (leaf-ever-used clambda)
 889            (let ((*compiler-error-context* bind))
 890              (compiler-notify 'code-deletion-note
 891                               :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 892                               :format-arguments (list (leaf-debug-name clambda)))))
 893          (unless (block-delete-p bind-block)
 894            (unlink-blocks (component-head component) bind-block))
 895          (when (and return-block (not (block-delete-p return-block)))
 896            (mark-for-deletion return-block)
 897            (unlink-blocks return-block (component-tail component)))
 898          (setf (component-reanalyze component) t)
 899          (let ((tails (lambda-tail-set clambda)))
 900            (setf (tail-set-funs tails)
 901                  (delete clambda (tail-set-funs tails)))
 902            (setf (lambda-tail-set clambda) nil))
 903          (setf (component-lambdas component)
 904                (delq clambda (component-lambdas component))))))
 905
 906     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 907     ;; ENTRY-FUN so that people will know that it is not an entry
 908     ;; point anymore.
 909     (when (eq original-kind :external)
 910       (let ((fun (functional-entry-fun clambda)))
 911         (setf (functional-entry-fun fun) nil)
 912         (when (optional-dispatch-p fun)
 913           (delete-optional-dispatch fun)))))
 914
 915   (values))
 916
 917 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 918 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 919 ;;; is used both before and after local call analysis. Afterward, all
 920 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 921 ;;; to the XEP, leaving it with no references at all. So we look at
 922 ;;; the XEP to see whether an optional-dispatch is still really being
 923 ;;; used. But before local call analysis, there are no XEPs, and all
 924 ;;; references are direct.
 925 ;;;
 926 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 927 ;;; entry-points, making them be normal lambdas, and then deleting the
 928 ;;; ones with no references. This deletes any e-p lambdas that were
 929 ;;; either never referenced, or couldn't be deleted when the last
 930 ;;; reference was deleted (due to their :OPTIONAL kind.)
 931 ;;;
 932 ;;; Note that the last optional entry point may alias the main entry,
 933 ;;; so when we process the main entry, its KIND may have been changed
 934 ;;; to NIL or even converted to a LETlike value.
 935 (defun delete-optional-dispatch (leaf)
 936   (declare (type optional-dispatch leaf))
 937   (let ((entry (functional-entry-fun leaf)))
 938     (unless (and entry (leaf-refs entry))
 939       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 940       (setf (functional-kind leaf) :deleted)
 941
 942       (flet ((frob (fun)
 943                (unless (eq (functional-kind fun) :deleted)
 944                  (aver (eq (functional-kind fun) :optional))
 945                  (setf (functional-kind fun) nil)
 946                  (let ((refs (leaf-refs fun)))
 947                    (cond ((null refs)
 948                           (delete-lambda fun))
 949                          ((null (rest refs))
 950                           (or (maybe-let-convert fun)
 951                               (maybe-convert-to-assignment fun)))
 952                          (t
 953                           (maybe-convert-to-assignment fun)))))))
 954
 955         (dolist (ep (optional-dispatch-entry-points leaf))
 956           (when (promise-ready-p ep)
 957             (frob (force ep))))
 958         (when (optional-dispatch-more-entry leaf)
 959           (frob (optional-dispatch-more-entry leaf)))
 960         (let ((main (optional-dispatch-main-entry leaf)))
 961           (when (eq (functional-kind main) :optional)
 962             (frob main))))))
 963
 964   (values))
 965
 966 ;;; Do stuff to delete the semantic attachments of a REF node. When
 967 ;;; this leaves zero or one reference, we do a type dispatch off of
 968 ;;; the leaf to determine if a special action is appropriate.
 969 (defun delete-ref (ref)
 970   (declare (type ref ref))
 971   (let* ((leaf (ref-leaf ref))
 972          (refs (delq ref (leaf-refs leaf))))
 973     (setf (leaf-refs leaf) refs)
 974
 975     (cond ((null refs)
 976            (typecase leaf
 977              (lambda-var
 978               (delete-lambda-var leaf))
 979              (clambda
 980               (ecase (functional-kind leaf)
 981                 ((nil :let :mv-let :assignment :escape :cleanup)
 982                  (aver (null (functional-entry-fun leaf)))
 983                  (delete-lambda leaf))
 984                 (:external
 985                  (delete-lambda leaf))
 986                 ((:deleted :zombie :optional))))
 987              (optional-dispatch
 988               (unless (eq (functional-kind leaf) :deleted)
 989                 (delete-optional-dispatch leaf)))))
 990           ((null (rest refs))
 991            (typecase leaf
 992              (clambda (or (maybe-let-convert leaf)
 993                           (maybe-convert-to-assignment leaf)))
 994              (lambda-var (reoptimize-lambda-var leaf))))
 995           (t
 996            (typecase leaf
 997              (clambda (maybe-convert-to-assignment leaf))))))
 998
 999   (values))
1000
1001 ;;; This function is called by people who delete nodes; it provides a
1002 ;;; way to indicate that the value of a lvar is no longer used. We
1003 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
1004 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
1005 (defun flush-dest (lvar)
1006   (declare (type (or lvar null) lvar))
1007   (unless (null lvar)
1008     (setf (lvar-dest lvar) nil)
1009     (flush-lvar-externally-checkable-type lvar)
1010     (do-uses (use lvar)
1011       (let ((prev (node-prev use)))
1012         (let ((block (ctran-block prev)))
1013           (setf (component-reoptimize (block-component block)) t)
1014           (setf (block-attributep (block-flags block)
1015                                   flush-p type-asserted type-check)
1016                 t)))
1017       (setf (node-lvar use) nil))
1018     (setf (lvar-uses lvar) nil))
1019   (values))
1020
1021 (defun delete-dest (lvar)
1022   (when lvar
1023     (let* ((dest (lvar-dest lvar))
1024            (prev (node-prev dest)))
1025       (let ((block (ctran-block prev)))
1026         (unless (block-delete-p block)
1027           (mark-for-deletion block))))))
1028
1029 ;;; Queue the block for deletion
1030 (defun delete-block-lazily (block)
1031   (declare (type cblock block))
1032   (unless (block-delete-p block)
1033     (setf (block-delete-p block) t)
1034     (push block (component-delete-blocks (block-component block)))))
1035
1036 ;;; Do a graph walk backward from BLOCK, marking all predecessor
1037 ;;; blocks with the DELETE-P flag.
1038 (defun mark-for-deletion (block)
1039   (declare (type cblock block))
1040   (let* ((component (block-component block))
1041          (head (component-head component)))
1042     (labels ((helper (block)
1043                (delete-block-lazily block)
1044                (dolist (pred (block-pred block))
1045                  (unless (or (block-delete-p pred)
1046                              (eq pred head))
1047                    (helper pred)))))
1048       (unless (block-delete-p block)
1049         (helper block)
1050         (setf (component-reanalyze component) t))))
1051   (values))
1052
1053 ;;; This function does what is necessary to eliminate the code in it
1054 ;;; from the IR1 representation. This involves unlinking it from its
1055 ;;; predecessors and successors and deleting various node-specific
1056 ;;; semantic information. BLOCK must be already removed from
1057 ;;; COMPONENT-DELETE-BLOCKS.
1058 (defun delete-block (block &optional silent)
1059   (declare (type cblock block))
1060   (aver (block-component block))      ; else block is already deleted!
1061   #!+high-security (aver (not (memq block (component-delete-blocks (block-component block)))))
1062   (unless silent
1063     (note-block-deletion block))
1064   (setf (block-delete-p block) t)
1065
1066   (dolist (b (block-pred block))
1067     (unlink-blocks b block)
1068     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
1069     ;; broken when successors were deleted without setting the
1070     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
1071     ;; doesn't happen again.
1072     (aver (not (and (null (block-succ b))
1073                     (not (block-delete-p b))
1074                     (not (eq b (component-head (block-component b))))))))
1075   (dolist (b (block-succ block))
1076     (unlink-blocks block b))
1077
1078   (do-nodes-carefully (node block)
1079     (when (valued-node-p node)
1080       (delete-lvar-use node))
1081     (etypecase node
1082       (ref (delete-ref node))
1083       (cif (flush-dest (if-test node)))
1084       ;; The next two cases serve to maintain the invariant that a LET
1085       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1086       ;; the lambda whenever we delete any of these, but we must be
1087       ;; careful that this LET has not already been partially deleted.
1088       (basic-combination
1089        (when (and (eq (basic-combination-kind node) :local)
1090                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1091                   (lvar-uses (basic-combination-fun node)))
1092          (let ((fun (combination-lambda node)))
1093            ;; If our REF was the second-to-last ref, and has been
1094            ;; deleted, then FUN may be a LET for some other
1095            ;; combination.
1096            (when (and (functional-letlike-p fun)
1097                       (eq (let-combination fun) node))
1098              (delete-lambda fun))))
1099        (flush-dest (basic-combination-fun node))
1100        (dolist (arg (basic-combination-args node))
1101          (when arg (flush-dest arg))))
1102       (bind
1103        (let ((lambda (bind-lambda node)))
1104          (unless (eq (functional-kind lambda) :deleted)
1105            (delete-lambda lambda))))
1106       (exit
1107        (let ((value (exit-value node))
1108              (entry (exit-entry node)))
1109          (when value
1110            (flush-dest value))
1111          (when entry
1112            (setf (entry-exits entry)
1113                  (delq node (entry-exits entry))))))
1114       (entry
1115        (dolist (exit (entry-exits node))
1116          (mark-for-deletion (node-block exit)))
1117        (let ((home (node-home-lambda node)))
1118          (setf (lambda-entries home) (delq node (lambda-entries home)))))
1119       (creturn
1120        (flush-dest (return-result node))
1121        (delete-return node))
1122       (cset
1123        (flush-dest (set-value node))
1124        (let ((var (set-var node)))
1125          (setf (basic-var-sets var)
1126                (delete node (basic-var-sets var)))))
1127       (cast
1128        (flush-dest (cast-value node)))))
1129
1130   (remove-from-dfo block)
1131   (values))
1132
1133 ;;; Do stuff to indicate that the return node NODE is being deleted.
1134 (defun delete-return (node)
1135   (declare (type creturn node))
1136   (let* ((fun (return-lambda node))
1137          (tail-set (lambda-tail-set fun)))
1138     (aver (lambda-return fun))
1139     (setf (lambda-return fun) nil)
1140     (when (and tail-set (not (find-if #'lambda-return
1141                                       (tail-set-funs tail-set))))
1142       (setf (tail-set-type tail-set) *empty-type*)))
1143   (values))
1144
1145 ;;; If any of the VARS in FUN was never referenced and was not
1146 ;;; declared IGNORE, then complain.
1147 (defun note-unreferenced-vars (fun)
1148   (declare (type clambda fun))
1149   (dolist (var (lambda-vars fun))
1150     (unless (or (leaf-ever-used var)
1151                 (lambda-var-ignorep var))
1152       (let ((*compiler-error-context* (lambda-bind fun)))
1153         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1154           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1155           ;; requires this to be no more than a STYLE-WARNING.
1156           #-sb-xc-host
1157           (compiler-style-warn "The variable ~S is defined but never used."
1158                                (leaf-debug-name var))
1159           ;; There's no reason to accept this kind of equivocation
1160           ;; when compiling our own code, though.
1161           #+sb-xc-host
1162           (compiler-warn "The variable ~S is defined but never used."
1163                          (leaf-debug-name var)))
1164         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1165   (values))
1166
1167 (defvar *deletion-ignored-objects* '(t nil))
1168
1169 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1170 ;;; our recursion so that we don't get lost in circular structures. We
1171 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1172 ;;; function referencess with variables), and we also ignore anything
1173 ;;; inside ' or #'.
1174 (defun present-in-form (obj form depth)
1175   (declare (type (integer 0 20) depth))
1176   (cond ((= depth 20) nil)
1177         ((eq obj form) t)
1178         ((atom form) nil)
1179         (t
1180          (let ((first (car form))
1181                (depth (1+ depth)))
1182            (if (member first '(quote function))
1183                nil
1184                (or (and (not (symbolp first))
1185                         (present-in-form obj first depth))
1186                    (do ((l (cdr form) (cdr l))
1187                         (n 0 (1+ n)))
1188                        ((or (atom l) (> n 100))
1189                         nil)
1190                      (declare (fixnum n))
1191                      (when (present-in-form obj (car l) depth)
1192                        (return t)))))))))
1193
1194 ;;; This function is called on a block immediately before we delete
1195 ;;; it. We check to see whether any of the code about to die appeared
1196 ;;; in the original source, and emit a note if so.
1197 ;;;
1198 ;;; If the block was in a lambda is now deleted, then we ignore the
1199 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1200 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1201 ;;; reasonable for a function to not return, and there is a different
1202 ;;; note for that case anyway.
1203 ;;;
1204 ;;; If the actual source is an atom, then we use a bunch of heuristics
1205 ;;; to guess whether this reference really appeared in the original
1206 ;;; source:
1207 ;;; -- If a symbol, it must be interned and not a keyword.
1208 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1209 ;;;    or a character.)
1210 ;;; -- The atom must be "present" in the original source form, and
1211 ;;;    present in all intervening actual source forms.
1212 (defun note-block-deletion (block)
1213   (let ((home (block-home-lambda block)))
1214     (unless (eq (functional-kind home) :deleted)
1215       (do-nodes (node nil block)
1216         (let* ((path (node-source-path node))
1217                (first (first path)))
1218           (when (or (eq first 'original-source-start)
1219                     (and (atom first)
1220                          (or (not (symbolp first))
1221                              (let ((pkg (symbol-package first)))
1222                                (and pkg
1223                                     (not (eq pkg (symbol-package :end))))))
1224                          (not (member first *deletion-ignored-objects*))
1225                          (not (typep first '(or fixnum character)))
1226                          (every (lambda (x)
1227                                   (present-in-form first x 0))
1228                                 (source-path-forms path))
1229                          (present-in-form first (find-original-source path)
1230                                           0)))
1231             (unless (return-p node)
1232               (let ((*compiler-error-context* node))
1233                 (compiler-notify 'code-deletion-note
1234                                  :format-control "deleting unreachable code"
1235                                  :format-arguments nil)))
1236             (return))))))
1237   (values))
1238
1239 ;;; Delete a node from a block, deleting the block if there are no
1240 ;;; nodes left. We remove the node from the uses of its LVAR.
1241 ;;;
1242 ;;; If the node is the last node, there must be exactly one successor.
1243 ;;; We link all of our precedessors to the successor and unlink the
1244 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1245 ;;; left, and the block is a successor of itself, then we replace the
1246 ;;; only node with a degenerate exit node. This provides a way to
1247 ;;; represent the bodyless infinite loop, given the prohibition on
1248 ;;; empty blocks in IR1.
1249 (defun unlink-node (node)
1250   (declare (type node node))
1251   (when (valued-node-p node)
1252     (delete-lvar-use node))
1253
1254   (let* ((ctran (node-next node))
1255          (next (and ctran (ctran-next ctran)))
1256          (prev (node-prev node))
1257          (block (ctran-block prev))
1258          (prev-kind (ctran-kind prev))
1259          (last (block-last block)))
1260
1261     (setf (block-type-asserted block) t)
1262     (setf (block-test-modified block) t)
1263
1264     (cond ((or (eq prev-kind :inside-block)
1265                (and (eq prev-kind :block-start)
1266                     (not (eq node last))))
1267            (cond ((eq node last)
1268                   (setf (block-last block) (ctran-use prev))
1269                   (setf (node-next (ctran-use prev)) nil))
1270                  (t
1271                   (setf (ctran-next prev) next)
1272                   (setf (node-prev next) prev)
1273                   (when (if-p next) ; AOP wanted
1274                     (reoptimize-lvar (if-test next)))))
1275            (setf (node-prev node) nil)
1276            nil)
1277           (t
1278            (aver (eq prev-kind :block-start))
1279            (aver (eq node last))
1280            (let* ((succ (block-succ block))
1281                   (next (first succ)))
1282              (aver (singleton-p succ))
1283              (cond
1284               ((eq block (first succ))
1285                (with-ir1-environment-from-node node
1286                  (let ((exit (make-exit)))
1287                    (setf (ctran-next prev) nil)
1288                    (link-node-to-previous-ctran exit prev)
1289                    (setf (block-last block) exit)))
1290                (setf (node-prev node) nil)
1291                nil)
1292               (t
1293                (aver (eq (block-start-cleanup block)
1294                          (block-end-cleanup block)))
1295                (unlink-blocks block next)
1296                (dolist (pred (block-pred block))
1297                  (change-block-successor pred block next))
1298                (when (block-delete-p block)
1299                  (let ((component (block-component block)))
1300                    (setf (component-delete-blocks component)
1301                          (delq block (component-delete-blocks component)))))
1302                (remove-from-dfo block)
1303                (setf (block-delete-p block) t)
1304                (setf (node-prev node) nil)
1305                t)))))))
1306
1307 ;;; Return true if NODE has been deleted, false if it is still a valid
1308 ;;; part of IR1.
1309 (defun node-deleted (node)
1310   (declare (type node node))
1311   (let ((prev (node-prev node)))
1312     (not (and prev
1313               (let ((block (ctran-block prev)))
1314                 (and (block-component block)
1315                      (not (block-delete-p block))))))))
1316
1317 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1318 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1319 ;;; triggered by deletion.
1320 (defun delete-component (component)
1321   (declare (type component component))
1322   (aver (null (component-new-functionals component)))
1323   (setf (component-kind component) :deleted)
1324   (do-blocks (block component)
1325     (delete-block-lazily block))
1326   (dolist (fun (component-lambdas component))
1327     (unless (eq (functional-kind fun) :deleted)
1328       (setf (functional-kind fun) nil)
1329       (setf (functional-entry-fun fun) nil)
1330       (setf (leaf-refs fun) nil)
1331       (delete-functional fun)))
1332   (clean-component component)
1333   (values))
1334
1335 ;;; Remove all pending blocks to be deleted. Return the nearest live
1336 ;;; block after or equal to BLOCK.
1337 (defun clean-component (component &optional block)
1338   (loop while (component-delete-blocks component)
1339         ;; actual deletion of a block may queue new blocks
1340         do (let ((current (pop (component-delete-blocks component))))
1341              (when (eq block current)
1342                (setq block (block-next block)))
1343              (delete-block current)))
1344   block)
1345
1346 ;;; Convert code of the form
1347 ;;;   (FOO ... (FUN ...) ...)
1348 ;;; to
1349 ;;;   (FOO ...    ...    ...).
1350 ;;; In other words, replace the function combination FUN by its
1351 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1352 ;;; to blow out of whatever transform called this. Note, as the number
1353 ;;; of arguments changes, the transform must be prepared to return a
1354 ;;; lambda with a new lambda-list with the correct number of
1355 ;;; arguments.
1356 (defun extract-fun-args (lvar fun num-args)
1357   #!+sb-doc
1358   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1359    to feed directly to the LVAR-DEST of LVAR, which must be a
1360    combination."
1361   (declare (type lvar lvar)
1362            (type symbol fun)
1363            (type index num-args))
1364   (let ((outside (lvar-dest lvar))
1365         (inside (lvar-uses lvar)))
1366     (aver (combination-p outside))
1367     (unless (combination-p inside)
1368       (give-up-ir1-transform))
1369     (let ((inside-fun (combination-fun inside)))
1370       (unless (eq (lvar-fun-name inside-fun) fun)
1371         (give-up-ir1-transform))
1372       (let ((inside-args (combination-args inside)))
1373         (unless (= (length inside-args) num-args)
1374           (give-up-ir1-transform))
1375         (let* ((outside-args (combination-args outside))
1376                (arg-position (position lvar outside-args))
1377                (before-args (subseq outside-args 0 arg-position))
1378                (after-args (subseq outside-args (1+ arg-position))))
1379           (dolist (arg inside-args)
1380             (setf (lvar-dest arg) outside)
1381             (flush-lvar-externally-checkable-type arg))
1382           (setf (combination-args inside) nil)
1383           (setf (combination-args outside)
1384                 (append before-args inside-args after-args))
1385           (change-ref-leaf (lvar-uses inside-fun)
1386                            (find-free-fun 'list "???"))
1387           (setf (combination-fun-info inside) (info :function :info 'list)
1388                 (combination-kind inside) :known)
1389           (setf (node-derived-type inside) *wild-type*)
1390           (flush-dest lvar)
1391           (values))))))
1392
1393 (defun flush-combination (combination)
1394   (declare (type combination combination))
1395   (flush-dest (combination-fun combination))
1396   (dolist (arg (combination-args combination))
1397     (flush-dest arg))
1398   (unlink-node combination)
1399   (values))
1400
1401 \f
1402 ;;;; leaf hackery
1403
1404 ;;; Change the LEAF that a REF refers to.
1405 (defun change-ref-leaf (ref leaf)
1406   (declare (type ref ref) (type leaf leaf))
1407   (unless (eq (ref-leaf ref) leaf)
1408     (push ref (leaf-refs leaf))
1409     (delete-ref ref)
1410     (setf (ref-leaf ref) leaf)
1411     (setf (leaf-ever-used leaf) t)
1412     (let* ((ltype (leaf-type leaf))
1413            (vltype (make-single-value-type ltype)))
1414       (if (let* ((lvar (node-lvar ref))
1415                  (dest (and lvar (lvar-dest lvar))))
1416             (and (basic-combination-p dest)
1417                  (eq lvar (basic-combination-fun dest))
1418                  (csubtypep ltype (specifier-type 'function))))
1419           (setf (node-derived-type ref) vltype)
1420           (derive-node-type ref vltype)))
1421     (reoptimize-lvar (node-lvar ref)))
1422   (values))
1423
1424 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1425 (defun substitute-leaf (new-leaf old-leaf)
1426   (declare (type leaf new-leaf old-leaf))
1427   (dolist (ref (leaf-refs old-leaf))
1428     (change-ref-leaf ref new-leaf))
1429   (values))
1430
1431 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1432 ;;; whether to substitute
1433 (defun substitute-leaf-if (test new-leaf old-leaf)
1434   (declare (type leaf new-leaf old-leaf) (type function test))
1435   (dolist (ref (leaf-refs old-leaf))
1436     (when (funcall test ref)
1437       (change-ref-leaf ref new-leaf)))
1438   (values))
1439
1440 ;;; Return a LEAF which represents the specified constant object. If
1441 ;;; the object is not in *CONSTANTS*, then we create a new constant
1442 ;;; LEAF and enter it.
1443 (defun find-constant (object)
1444   (if (typep object
1445              ;; FIXME: What is the significance of this test? ("things
1446              ;; that are worth uniquifying"?)
1447              '(or symbol number character instance))
1448       (or (gethash object *constants*)
1449           (setf (gethash object *constants*)
1450                 (make-constant :value object
1451                                :%source-name '.anonymous.
1452                                :type (ctype-of object)
1453                                :where-from :defined)))
1454       (make-constant :value object
1455                      :%source-name '.anonymous.
1456                      :type (ctype-of object)
1457                      :where-from :defined)))
1458 \f
1459 ;;; Return true if VAR would have to be closed over if environment
1460 ;;; analysis ran now (i.e. if there are any uses that have a different
1461 ;;; home lambda than VAR's home.)
1462 (defun closure-var-p (var)
1463   (declare (type lambda-var var))
1464   (let ((home (lambda-var-home var)))
1465     (cond ((eq (functional-kind home) :deleted)
1466            nil)
1467           (t (let ((home (lambda-home home)))
1468                (flet ((frob (l)
1469                         (find home l
1470                               :key #'node-home-lambda
1471                               :test #'neq)))
1472                  (or (frob (leaf-refs var))
1473                      (frob (basic-var-sets var)))))))))
1474
1475 ;;; If there is a non-local exit noted in ENTRY's environment that
1476 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1477 (defun find-nlx-info (exit)
1478   (declare (type exit exit))
1479   (let ((entry (exit-entry exit)))
1480     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1481       (when (eq (nlx-info-exit nlx) exit)
1482         (return nlx)))))
1483 \f
1484 ;;;; functional hackery
1485
1486 (declaim (ftype (sfunction (functional) clambda) main-entry))
1487 (defun main-entry (functional)
1488   (etypecase functional
1489     (clambda functional)
1490     (optional-dispatch
1491      (optional-dispatch-main-entry functional))))
1492
1493 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1494 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1495 ;;; optional with null default and no SUPPLIED-P. There must be a
1496 ;;; &REST arg with no references.
1497 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1498 (defun looks-like-an-mv-bind (functional)
1499   (and (optional-dispatch-p functional)
1500        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1501            ((null arg) nil)
1502          (let ((info (lambda-var-arg-info (car arg))))
1503            (unless info (return nil))
1504            (case (arg-info-kind info)
1505              (:optional
1506               (when (or (arg-info-supplied-p info) (arg-info-default info))
1507                 (return nil)))
1508              (:rest
1509               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1510              (t
1511               (return nil)))))))
1512
1513 ;;; Return true if function is an external entry point. This is true
1514 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1515 ;;; (:TOPLEVEL kind.)
1516 (defun xep-p (fun)
1517   (declare (type functional fun))
1518   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1519
1520 ;;; If LVAR's only use is a non-notinline global function reference,
1521 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1522 ;;; is true, then we don't care if the leaf is NOTINLINE.
1523 (defun lvar-fun-name (lvar &optional notinline-ok)
1524   (declare (type lvar lvar))
1525   (let ((use (lvar-uses lvar)))
1526     (if (ref-p use)
1527         (let ((leaf (ref-leaf use)))
1528           (if (and (global-var-p leaf)
1529                    (eq (global-var-kind leaf) :global-function)
1530                    (or (not (defined-fun-p leaf))
1531                        (not (eq (defined-fun-inlinep leaf) :notinline))
1532                        notinline-ok))
1533               (leaf-source-name leaf)
1534               nil))
1535         nil)))
1536
1537 ;;; Return the source name of a combination. (This is an idiom
1538 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1539 (defun combination-fun-source-name (combination)
1540   (let ((ref (lvar-uses (combination-fun combination))))
1541     (leaf-source-name (ref-leaf ref))))
1542
1543 ;;; Return the COMBINATION node that is the call to the LET FUN.
1544 (defun let-combination (fun)
1545   (declare (type clambda fun))
1546   (aver (functional-letlike-p fun))
1547   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1548
1549 ;;; Return the initial value lvar for a LET variable, or NIL if there
1550 ;;; is none.
1551 (defun let-var-initial-value (var)
1552   (declare (type lambda-var var))
1553   (let ((fun (lambda-var-home var)))
1554     (elt (combination-args (let-combination fun))
1555          (position-or-lose var (lambda-vars fun)))))
1556
1557 ;;; Return the LAMBDA that is called by the local CALL.
1558 (defun combination-lambda (call)
1559   (declare (type basic-combination call))
1560   (aver (eq (basic-combination-kind call) :local))
1561   (ref-leaf (lvar-uses (basic-combination-fun call))))
1562
1563 (defvar *inline-expansion-limit* 200
1564   #!+sb-doc
1565   "an upper limit on the number of inline function calls that will be expanded
1566    in any given code object (single function or block compilation)")
1567
1568 ;;; Check whether NODE's component has exceeded its inline expansion
1569 ;;; limit, and warn if so, returning NIL.
1570 (defun inline-expansion-ok (node)
1571   (let ((expanded (incf (component-inline-expansions
1572                          (block-component
1573                           (node-block node))))))
1574     (cond ((> expanded *inline-expansion-limit*) nil)
1575           ((= expanded *inline-expansion-limit*)
1576            ;; FIXME: If the objective is to stop the recursive
1577            ;; expansion of inline functions, wouldn't it be more
1578            ;; correct to look back through surrounding expansions
1579            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1580            ;; possibly stored elsewhere too) and suppress expansion
1581            ;; and print this warning when the function being proposed
1582            ;; for inline expansion is found there? (I don't like the
1583            ;; arbitrary numerical limit in principle, and I think
1584            ;; it'll be a nuisance in practice if we ever want the
1585            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1586            ;; arbitrarily huge blocks of code. -- WHN)
1587            (let ((*compiler-error-context* node))
1588              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1589                                probably trying to~%  ~
1590                                inline a recursive function."
1591                               *inline-expansion-limit*))
1592            nil)
1593           (t t))))
1594
1595 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1596 (defun assure-functional-live-p (functional)
1597   (declare (type functional functional))
1598   (when (and (or
1599               ;; looks LET-converted
1600               (functional-somewhat-letlike-p functional)
1601               ;; It's possible for a LET-converted function to end up
1602               ;; deleted later. In that case, for the purposes of this
1603               ;; analysis, it is LET-converted: LET-converted functionals
1604               ;; are too badly trashed to expand them inline, and deleted
1605               ;; LET-converted functionals are even worse.
1606               (memq (functional-kind functional) '(:deleted :zombie))))
1607     (throw 'locall-already-let-converted functional)))
1608
1609 (defun call-full-like-p (call)
1610   (declare (type combination call))
1611   (let ((kind (basic-combination-kind call)))
1612     (or (eq kind :full)
1613         (and (eq kind :known)
1614              (let ((info (basic-combination-fun-info call)))
1615                (and
1616                 (not (fun-info-ir2-convert info))
1617                 (dolist (template (fun-info-templates info) t)
1618                   (when (eq (template-ltn-policy template) :fast-safe)
1619                     (multiple-value-bind (val win)
1620                        (valid-fun-use call (template-type template))
1621                       (when (or val (not win)) (return nil)))))))))))
1622 \f
1623 ;;;; careful call
1624
1625 ;;; Apply a function to some arguments, returning a list of the values
1626 ;;; resulting of the evaluation. If an error is signalled during the
1627 ;;; application, then we produce a warning message using WARN-FUN and
1628 ;;; return NIL as our second value to indicate this. NODE is used as
1629 ;;; the error context for any error message, and CONTEXT is a string
1630 ;;; that is spliced into the warning.
1631 (declaim (ftype (sfunction ((or symbol function) list node function string)
1632                           (values list boolean))
1633                 careful-call))
1634 (defun careful-call (function args node warn-fun context)
1635   (values
1636    (multiple-value-list
1637     (handler-case (apply function args)
1638       (error (condition)
1639         (let ((*compiler-error-context* node))
1640           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1641           (return-from careful-call (values nil nil))))))
1642    t))
1643
1644 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1645 ;;; specifiers.
1646 (macrolet
1647     ((deffrob (basic careful compiler transform)
1648        `(progn
1649           (defun ,careful (specifier)
1650             (handler-case (,basic specifier)
1651               (sb!kernel::arg-count-error (condition)
1652                 (values nil (list (format nil "~A" condition))))
1653               (simple-error (condition)
1654                 (values nil (list* (simple-condition-format-control condition)
1655                                    (simple-condition-format-arguments condition))))))
1656           (defun ,compiler (specifier)
1657             (multiple-value-bind (type error-args) (,careful specifier)
1658               (or type
1659                   (apply #'compiler-error error-args))))
1660           (defun ,transform (specifier)
1661             (multiple-value-bind (type error-args) (,careful specifier)
1662               (or type
1663                   (apply #'give-up-ir1-transform
1664                          error-args)))))))
1665   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1666   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1667
1668 \f
1669 ;;;; utilities used at run-time for parsing &KEY args in IR1
1670
1671 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1672 ;;; the lvar for the value of the &KEY argument KEY in the list of
1673 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1674 ;;; otherwise. The legality and constantness of the keywords should
1675 ;;; already have been checked.
1676 (declaim (ftype (sfunction (list keyword) (or lvar null))
1677                 find-keyword-lvar))
1678 (defun find-keyword-lvar (args key)
1679   (do ((arg args (cddr arg)))
1680       ((null arg) nil)
1681     (when (eq (lvar-value (first arg)) key)
1682       (return (second arg)))))
1683
1684 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1685 ;;; verify that alternating lvars in ARGS are constant and that there
1686 ;;; is an even number of args.
1687 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1688 (defun check-key-args-constant (args)
1689   (do ((arg args (cddr arg)))
1690       ((null arg) t)
1691     (unless (and (rest arg)
1692                  (constant-lvar-p (first arg)))
1693       (return nil))))
1694
1695 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1696 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1697 ;;; and that only keywords present in the list KEYS are supplied.
1698 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1699 (defun check-transform-keys (args keys)
1700   (and (check-key-args-constant args)
1701        (do ((arg args (cddr arg)))
1702            ((null arg) t)
1703          (unless (member (lvar-value (first arg)) keys)
1704            (return nil)))))
1705 \f
1706 ;;;; miscellaneous
1707
1708 ;;; Called by the expansion of the EVENT macro.
1709 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1710 (defun %event (info node)
1711   (incf (event-info-count info))
1712   (when (and (>= (event-info-level info) *event-note-threshold*)
1713              (policy (or node *lexenv*)
1714                      (= inhibit-warnings 0)))
1715     (let ((*compiler-error-context* node))
1716       (compiler-notify (event-info-description info))))
1717
1718   (let ((action (event-info-action info)))
1719     (when action (funcall action node))))
1720
1721 ;;;
1722 (defun make-cast (value type policy)
1723   (declare (type lvar value)
1724            (type ctype type)
1725            (type policy policy))
1726   (%make-cast :asserted-type type
1727               :type-to-check (maybe-weaken-check type policy)
1728               :value value
1729               :derived-type (coerce-to-values type)))
1730
1731 (defun cast-type-check (cast)
1732   (declare (type cast cast))
1733   (when (cast-reoptimize cast)
1734     (ir1-optimize-cast cast t))
1735   (cast-%type-check cast))
1736
1737 (defun note-single-valuified-lvar (lvar)
1738   (declare (type (or lvar null) lvar))
1739   (when lvar
1740     (let ((use (lvar-uses lvar)))
1741       (cond ((ref-p use)
1742              (let ((leaf (ref-leaf use)))
1743                (when (and (lambda-var-p leaf)
1744                           (null (rest (leaf-refs leaf))))
1745                  (reoptimize-lambda-var leaf))))
1746             ((or (listp use) (combination-p use))
1747              (do-uses (node lvar)
1748                (setf (node-reoptimize node) t)
1749                (setf (block-reoptimize (node-block node)) t)
1750                (setf (component-reoptimize (node-component node)) t)))))))