src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (let* ((start (make-continuation))
  41            (block (continuation-starts-block start))
  42            (cont (make-continuation))
  43            (*lexenv* (if cleanup
  44                          (make-lexenv :cleanup cleanup)
  45                          *lexenv*)))
  46       (change-block-successor block1 block2 block)
  47       (link-blocks block block2)
  48       (ir1-convert start cont form)
  49       (setf (block-last block) (continuation-use cont))
  50       block)))
  51 \f
  52 ;;;; continuation use hacking
  53
  54 ;;; Return a list of all the nodes which use Cont.
  55 (declaim (ftype (function (continuation) list) find-uses))
  56 (defun find-uses (cont)
  57   (ecase (continuation-kind cont)
  58     ((:block-start :deleted-block-start)
  59      (block-start-uses (continuation-block cont)))
  60     (:inside-block (list (continuation-use cont)))
  61     (:unused nil)
  62     (:deleted nil)))
  63
  64 ;;; Update continuation use information so that NODE is no longer a
  65 ;;; use of its CONT. If the old continuation doesn't start its block,
  66 ;;; then we don't update the BLOCK-START-USES, since it will be
  67 ;;; deleted when we are done.
  68 ;;;
  69 ;;; Note: if you call this function, you may have to do a
  70 ;;; REOPTIMIZE-CONTINUATION to inform IR1 optimization that something
  71 ;;; has changed.
  72 (declaim (ftype (function (node) (values)) delete-continuation-use))
  73 (defun delete-continuation-use (node)
  74   (let* ((cont (node-cont node))
  75          (block (continuation-block cont)))
  76     (ecase (continuation-kind cont)
  77       (:deleted)
  78       ((:block-start :deleted-block-start)
  79        (let ((uses (delete node (block-start-uses block))))
  80          (setf (block-start-uses block) uses)
  81          (setf (continuation-use cont)
  82                (if (cdr uses) nil (car uses)))))
  83       (:inside-block
  84        (setf (continuation-kind cont) :unused)
  85        (setf (continuation-block cont) nil)
  86        (setf (continuation-use cont) nil)
  87        (setf (continuation-next cont) nil)))
  88     (setf (node-cont node) nil))
  89   (values))
  90
  91 ;;; Update continuation use information so that NODE uses CONT. If
  92 ;;; CONT is :UNUSED, then we set its block to NODE's NODE-BLOCK (which
  93 ;;; must be set.)
  94 ;;;
  95 ;;; Note: if you call this function, you may have to do a
  96 ;;; REOPTIMIZE-CONTINUATION to inform IR1 optimization that something
  97 ;;; has changed.
  98 (declaim (ftype (function (node continuation) (values)) add-continuation-use))
  99 (defun add-continuation-use (node cont)
 100   (aver (not (node-cont node)))
 101   (let ((block (continuation-block cont)))
 102     (ecase (continuation-kind cont)
 103       (:deleted)
 104       (:unused
 105        (aver (not block))
 106        (let ((block (node-block node)))
 107          (aver block)
 108          (setf (continuation-block cont) block))
 109        (setf (continuation-kind cont) :inside-block)
 110        (setf (continuation-use cont) node))
 111       ((:block-start :deleted-block-start)
 112        (let ((uses (cons node (block-start-uses block))))
 113          (setf (block-start-uses block) uses)
 114          (setf (continuation-use cont)
 115                (if (cdr uses) nil (car uses)))))))
 116   (setf (node-cont node) cont)
 117   (values))
 118
 119 ;;; Return true if CONT is the NODE-CONT for NODE and CONT is
 120 ;;; transferred to immediately after the evaluation of NODE.
 121 (defun immediately-used-p (cont node)
 122   (declare (type continuation cont) (type node node))
 123   (and (eq (node-cont node) cont)
 124        (not (eq (continuation-kind cont) :deleted))
 125        (let ((cblock (continuation-block cont))
 126              (nblock (node-block node)))
 127          (or (eq cblock nblock)
 128              (let ((succ (block-succ nblock)))
 129                (and (= (length succ) 1)
 130                     (eq (first succ) cblock)))))))
 131 \f
 132 ;;;; continuation substitution
 133
 134 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 135 ;;; NIL. When we are done, we call FLUSH-DEST on OLD to clear its DEST
 136 ;;; and to note potential optimization opportunities.
 137 (defun substitute-continuation (new old)
 138   (declare (type continuation old new))
 139   (aver (not (continuation-dest new)))
 140   (let ((dest (continuation-dest old)))
 141     (etypecase dest
 142       ((or ref bind))
 143       (cif (setf (if-test dest) new))
 144       (cset (setf (set-value dest) new))
 145       (creturn (setf (return-result dest) new))
 146       (exit (setf (exit-value dest) new))
 147       (basic-combination
 148        (if (eq old (basic-combination-fun dest))
 149            (setf (basic-combination-fun dest) new)
 150            (setf (basic-combination-args dest)
 151                  (nsubst new old (basic-combination-args dest))))))
 152
 153     (flush-dest old)
 154     (setf (continuation-dest new) dest))
 155   (values))
 156
 157 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 158 ;;; arbitary number of uses. If NEW will end up with more than one
 159 ;;; use, then we must arrange for it to start a block if it doesn't
 160 ;;; already.
 161 (defun substitute-continuation-uses (new old)
 162   (declare (type continuation old new))
 163   (unless (and (eq (continuation-kind new) :unused)
 164                (eq (continuation-kind old) :inside-block))
 165     (ensure-block-start new))
 166
 167   (do-uses (node old)
 168     (delete-continuation-use node)
 169     (add-continuation-use node new))
 170   (dolist (lexenv-use (continuation-lexenv-uses old))
 171     (setf (cadr lexenv-use) new))
 172
 173   (reoptimize-continuation new)
 174   (values))
 175 \f
 176 ;;;; block starting/creation
 177
 178 ;;; Return the block that CONT is the start of, making a block if
 179 ;;; necessary. This function is called by IR1 translators which may
 180 ;;; cause a continuation to be used more than once. Every continuation
 181 ;;; which may be used more than once must start a block by the time
 182 ;;; that anyone does a USE-CONTINUATION on it.
 183 ;;;
 184 ;;; We also throw the block into the next/prev list for the
 185 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 186 ;;; made.
 187 (defun continuation-starts-block (cont)
 188   (declare (type continuation cont))
 189   (ecase (continuation-kind cont)
 190     (:unused
 191      (aver (not (continuation-block cont)))
 192      (let* ((head (component-head *current-component*))
 193             (next (block-next head))
 194             (new-block (make-block cont)))
 195        (setf (block-next new-block) next
 196              (block-prev new-block) head
 197              (block-prev next) new-block
 198              (block-next head) new-block
 199              (continuation-block cont) new-block
 200              (continuation-use cont) nil
 201              (continuation-kind cont) :block-start)
 202        new-block))
 203     (:block-start
 204      (continuation-block cont))))
 205
 206 ;;; Ensure that CONT is the start of a block (or deleted) so that
 207 ;;; the use set can be freely manipulated.
 208 ;;; -- If the continuation is :UNUSED or is :INSIDE-BLOCK and the
 209 ;;;    CONT of LAST in its block, then we make it the start of a new
 210 ;;;    deleted block.
 211 ;;; -- If the continuation is :INSIDE-BLOCK inside a block, then we
 212 ;;;    split the block using Node-Ends-Block, which makes the
 213 ;;;    continuation be a :BLOCK-START.
 214 (defun ensure-block-start (cont)
 215   (declare (type continuation cont))
 216   (let ((kind (continuation-kind cont)))
 217     (ecase kind
 218       ((:deleted :block-start :deleted-block-start))
 219       ((:unused :inside-block)
 220        (let ((block (continuation-block cont)))
 221          (cond ((or (eq kind :unused)
 222                     (eq (node-cont (block-last block)) cont))
 223                 (setf (continuation-block cont)
 224                       (make-block-key :start cont
 225                                       :component nil
 226                                       :start-uses (find-uses cont)))
 227                 (setf (continuation-kind cont) :deleted-block-start))
 228                (t
 229                 (node-ends-block (continuation-use cont))))))))
 230   (values))
 231 \f
 232 ;;;; miscellaneous shorthand functions
 233
 234 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 235 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 236 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 237 ;;; deleted, and then return its home.
 238 (defun node-home-lambda (node)
 239   (declare (type node node))
 240   (do ((fun (lexenv-lambda (node-lexenv node))
 241             (lexenv-lambda (lambda-call-lexenv fun))))
 242       ((not (eq (functional-kind fun) :deleted))
 243        (lambda-home fun))
 244     (when (eq (lambda-home fun) fun)
 245       (return fun))))
 246
 247 (defun node-block (node)
 248   (declare (type node node))
 249   (the cblock (continuation-block (node-prev node))))
 250 (defun node-component (node)
 251   (declare (type node node))
 252   (block-component (node-block node)))
 253 (defun node-physenv (node)
 254   (declare (type node node))
 255   (the physenv (lambda-physenv (node-home-lambda node))))
 256
 257 (defun lambda-block (clambda)
 258   (declare (type clambda clambda))
 259   (node-block (lambda-bind clambda)))
 260 (defun lambda-component (clambda)
 261   (block-component (lambda-block clambda)))
 262
 263 ;;; Return the enclosing cleanup for environment of the first or last
 264 ;;; node in BLOCK.
 265 (defun block-start-cleanup (block)
 266   (declare (type cblock block))
 267   (node-enclosing-cleanup (continuation-next (block-start block))))
 268 (defun block-end-cleanup (block)
 269   (declare (type cblock block))
 270   (node-enclosing-cleanup (block-last block)))
 271
 272 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 273 ;;; if there is none.
 274 ;;;
 275 ;;; There can legitimately be no home lambda in dead code early in the
 276 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 277 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 278 ;;; where the block is just a placeholder during parsing and doesn't
 279 ;;; actually correspond to code which will be written anywhere.
 280 (defun block-home-lambda-or-null (block)
 281   (declare (type cblock block))
 282   (if (node-p (block-last block))
 283       ;; This is the old CMU CL way of doing it.
 284       (node-home-lambda (block-last block))
 285       ;; Now that SBCL uses this operation more aggressively than CMU
 286       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 287       ;;   1. It can fail in a few cases even when a meaningful home
 288       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 289       ;;      an IF.
 290       ;;   2. It can fail when converting a form which is born orphaned
 291       ;;      so that it never had a meaningful home lambda, e.g. a form
 292       ;;      which follows a RETURN-FROM or GO form.
 293       (let ((pred-list (block-pred block)))
 294         ;; To deal with case 1, we reason that
 295         ;; previous-in-target-execution-order blocks should be in the
 296         ;; same lambda, and that they seem in practice to be
 297         ;; previous-in-compilation-order blocks too, so we look back
 298         ;; to find one which is sufficiently initialized to tell us
 299         ;; what the home lambda is.
 300         (if pred-list
 301             ;; We could get fancy about this, flooding through the
 302             ;; graph of all the previous blocks, but in practice it
 303             ;; seems to work just to grab the first previous block and
 304             ;; use it.
 305             (node-home-lambda (block-last (first pred-list)))
 306             ;; In case 2, we end up with an empty PRED-LIST and
 307             ;; have to punt: There's no home lambda.
 308             nil))))
 309
 310 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 311 (defun block-home-lambda (block)
 312   (the clambda
 313     (block-home-lambda-or-null block)))
 314
 315 ;;; Return the IR1 physical environment for BLOCK.
 316 (defun block-physenv (block)
 317   (declare (type cblock block))
 318   (lambda-physenv (block-home-lambda block)))
 319
 320 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 321 ;;; of its original source's top level form in its compilation unit.
 322 (defun source-path-tlf-number (path)
 323   (declare (list path))
 324   (car (last path)))
 325
 326 ;;; Return the (reversed) list for the PATH in the original source
 327 ;;; (with the Top Level Form number last).
 328 (defun source-path-original-source (path)
 329   (declare (list path) (inline member))
 330   (cddr (member 'original-source-start path :test #'eq)))
 331
 332 ;;; Return the Form Number of PATH's original source inside the Top
 333 ;;; Level Form that contains it. This is determined by the order that
 334 ;;; we walk the subforms of the top level source form.
 335 (defun source-path-form-number (path)
 336   (declare (list path) (inline member))
 337   (cadr (member 'original-source-start path :test #'eq)))
 338
 339 ;;; Return a list of all the enclosing forms not in the original
 340 ;;; source that converted to get to this form, with the immediate
 341 ;;; source for node at the start of the list.
 342 (defun source-path-forms (path)
 343   (subseq path 0 (position 'original-source-start path)))
 344
 345 ;;; Return the innermost source form for NODE.
 346 (defun node-source-form (node)
 347   (declare (type node node))
 348   (let* ((path (node-source-path node))
 349          (forms (source-path-forms path)))
 350     (if forms
 351         (first forms)
 352         (values (find-original-source path)))))
 353
 354 ;;; Return NODE-SOURCE-FORM, T if continuation has a single use,
 355 ;;; otherwise NIL, NIL.
 356 (defun continuation-source (cont)
 357   (let ((use (continuation-use cont)))
 358     (if use
 359         (values (node-source-form use) t)
 360         (values nil nil))))
 361
 362 ;;; Return the LAMBDA that is CONT's home, or NIL if there is none.
 363 (defun continuation-home-lambda-or-null (cont)
 364   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 365   ;; implementation might not be quite right, or might be uglier than
 366   ;; necessary. It appears that the original Python never found a need
 367   ;; to do this operation. The obvious things based on
 368   ;; NODE-HOME-LAMBDA of CONTINUATION-USE usually work; then if that
 369   ;; fails, BLOCK-HOME-LAMBDA of CONTINUATION-BLOCK works, given that
 370   ;; we generalize it enough to grovel harder when the simple CMU CL
 371   ;; approach fails, and furthermore realize that in some exceptional
 372   ;; cases it might return NIL. -- WHN 2001-12-04
 373   (cond ((continuation-use cont)
 374          (node-home-lambda (continuation-use cont)))
 375         ((continuation-block cont)
 376          (block-home-lambda-or-null (continuation-block cont)))
 377         (t
 378          (bug "confused about home lambda for ~S"))))
 379
 380 ;;; Return the LAMBDA that is CONT's home.
 381 (defun continuation-home-lambda (cont)
 382   (the clambda
 383     (continuation-home-lambda-or-null cont)))
 384 \f
 385 ;;; Return a new LEXENV just like DEFAULT except for the specified
 386 ;;; slot values. Values for the alist slots are NCONCed to the
 387 ;;; beginning of the current value, rather than replacing it entirely.
 388 (defun make-lexenv (&key (default *lexenv*)
 389                          funs vars blocks tags type-restrictions options
 390                          (lambda (lexenv-lambda default))
 391                          (cleanup (lexenv-cleanup default))
 392                          (policy (lexenv-policy default)))
 393   (macrolet ((frob (var slot)
 394                `(let ((old (,slot default)))
 395                   (if ,var
 396                       (nconc ,var old)
 397                       old))))
 398     (internal-make-lexenv
 399      (frob funs lexenv-funs)
 400      (frob vars lexenv-vars)
 401      (frob blocks lexenv-blocks)
 402      (frob tags lexenv-tags)
 403      (frob type-restrictions lexenv-type-restrictions)
 404      lambda cleanup policy
 405      (frob options lexenv-options))))
 406 \f
 407 ;;;; flow/DFO/component hackery
 408
 409 ;;; Join BLOCK1 and BLOCK2.
 410 (defun link-blocks (block1 block2)
 411   (declare (type cblock block1 block2))
 412   (setf (block-succ block1)
 413         (if (block-succ block1)
 414             (%link-blocks block1 block2)
 415             (list block2)))
 416   (push block1 (block-pred block2))
 417   (values))
 418 (defun %link-blocks (block1 block2)
 419   (declare (type cblock block1 block2) (inline member))
 420   (let ((succ1 (block-succ block1)))
 421     (aver (not (member block2 succ1 :test #'eq)))
 422     (cons block2 succ1)))
 423
 424 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 425 ;;; this leaves a successor with a single predecessor that ends in an
 426 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 427 ;;; now be able to be propagated to the successor.
 428 (defun unlink-blocks (block1 block2)
 429   (declare (type cblock block1 block2))
 430   (let ((succ1 (block-succ block1)))
 431     (if (eq block2 (car succ1))
 432         (setf (block-succ block1) (cdr succ1))
 433         (do ((succ (cdr succ1) (cdr succ))
 434              (prev succ1 succ))
 435             ((eq (car succ) block2)
 436              (setf (cdr prev) (cdr succ)))
 437           (aver succ))))
 438
 439   (let ((new-pred (delq block1 (block-pred block2))))
 440     (setf (block-pred block2) new-pred)
 441     (when (and new-pred (null (rest new-pred)))
 442       (let ((pred-block (first new-pred)))
 443         (when (if-p (block-last pred-block))
 444           (setf (block-test-modified pred-block) t)))))
 445   (values))
 446
 447 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 448 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 449 ;;; consequent/alternative blocks to point to NEW. We also set
 450 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 451 ;;; the new successor.
 452 (defun change-block-successor (block old new)
 453   (declare (type cblock new old block) (inline member))
 454   (unlink-blocks block old)
 455   (let ((last (block-last block))
 456         (comp (block-component block)))
 457     (setf (component-reanalyze comp) t)
 458     (typecase last
 459       (cif
 460        (setf (block-test-modified block) t)
 461        (let* ((succ-left (block-succ block))
 462               (new (if (and (eq new (component-tail comp))
 463                             succ-left)
 464                        (first succ-left)
 465                        new)))
 466          (unless (member new succ-left :test #'eq)
 467            (link-blocks block new))
 468          (macrolet ((frob (slot)
 469                       `(when (eq (,slot last) old)
 470                          (setf (,slot last) new))))
 471            (frob if-consequent)
 472            (frob if-alternative))))
 473       (t
 474        (unless (member new (block-succ block) :test #'eq)
 475          (link-blocks block new)))))
 476
 477   (values))
 478
 479 ;;; Unlink a block from the next/prev chain. We also null out the
 480 ;;; COMPONENT.
 481 (declaim (ftype (function (cblock) (values)) remove-from-dfo))
 482 (defun remove-from-dfo (block)
 483   (let ((next (block-next block))
 484         (prev (block-prev block)))
 485     (setf (block-component block) nil)
 486     (setf (block-next prev) next)
 487     (setf (block-prev next) prev))
 488   (values))
 489
 490 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 491 ;;; COMPONENT to be the same as for AFTER.
 492 (defun add-to-dfo (block after)
 493   (declare (type cblock block after))
 494   (let ((next (block-next after))
 495         (comp (block-component after)))
 496     (aver (not (eq (component-kind comp) :deleted)))
 497     (setf (block-component block) comp)
 498     (setf (block-next after) block)
 499     (setf (block-prev block) after)
 500     (setf (block-next block) next)
 501     (setf (block-prev next) block))
 502   (values))
 503
 504 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 505 ;;; the head and tail which are set to T.
 506 (declaim (ftype (function (component) (values)) clear-flags))
 507 (defun clear-flags (component)
 508   (let ((head (component-head component))
 509         (tail (component-tail component)))
 510     (setf (block-flag head) t)
 511     (setf (block-flag tail) t)
 512     (do-blocks (block component)
 513       (setf (block-flag block) nil)))
 514   (values))
 515
 516 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 517 ;;; true in the head and tail blocks.
 518 (declaim (ftype (function nil component) make-empty-component))
 519 (defun make-empty-component ()
 520   (let* ((head (make-block-key :start nil :component nil))
 521          (tail (make-block-key :start nil :component nil))
 522          (res (make-component :head head :tail tail)))
 523     (setf (block-flag head) t)
 524     (setf (block-flag tail) t)
 525     (setf (block-component head) res)
 526     (setf (block-component tail) res)
 527     (setf (block-next head) tail)
 528     (setf (block-prev tail) head)
 529     res))
 530
 531 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 532 ;;; The new block is added to the DFO immediately following NODE's block.
 533 (defun node-ends-block (node)
 534   (declare (type node node))
 535   (let* ((block (node-block node))
 536          (start (node-cont node))
 537          (last (block-last block))
 538          (last-cont (node-cont last)))
 539     (unless (eq last node)
 540       (aver (and (eq (continuation-kind start) :inside-block)
 541                    (not (block-delete-p block))))
 542       (let* ((succ (block-succ block))
 543              (new-block
 544               (make-block-key :start start
 545                               :component (block-component block)
 546                               :start-uses (list (continuation-use start))
 547                               :succ succ :last last)))
 548         (setf (continuation-kind start) :block-start)
 549         (dolist (b succ)
 550           (setf (block-pred b)
 551                 (cons new-block (remove block (block-pred b)))))
 552         (setf (block-succ block) ())
 553         (setf (block-last block) node)
 554         (link-blocks block new-block)
 555         (add-to-dfo new-block block)
 556         (setf (component-reanalyze (block-component block)) t)
 557
 558         (do ((cont start (node-cont (continuation-next cont))))
 559             ((eq cont last-cont)
 560              (when (eq (continuation-kind last-cont) :inside-block)
 561                (setf (continuation-block last-cont) new-block)))
 562           (setf (continuation-block cont) new-block))
 563
 564         (setf (block-type-asserted block) t)
 565         (setf (block-test-modified block) t))))
 566
 567   (values))
 568 \f
 569 ;;;; deleting stuff
 570
 571 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 572 (defun delete-lambda-var (leaf)
 573   (declare (type lambda-var leaf))
 574
 575   ;; Iterate over all local calls flushing the corresponding argument,
 576   ;; allowing the computation of the argument to be deleted. We also
 577   ;; mark the LET for reoptimization, since it may be that we have
 578   ;; deleted its last variable.
 579   (let* ((fun (lambda-var-home leaf))
 580          (n (position leaf (lambda-vars fun))))
 581     (dolist (ref (leaf-refs fun))
 582       (let* ((cont (node-cont ref))
 583              (dest (continuation-dest cont)))
 584         (when (and (combination-p dest)
 585                    (eq (basic-combination-fun dest) cont)
 586                    (eq (basic-combination-kind dest) :local))
 587           (let* ((args (basic-combination-args dest))
 588                  (arg (elt args n)))
 589             (reoptimize-continuation arg)
 590             (flush-dest arg)
 591             (setf (elt args n) nil))))))
 592
 593   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 594   ;; too much difficulty, since we can efficiently implement
 595   ;; write-only variables. We iterate over the SETs, marking their
 596   ;; blocks for dead code flushing, since we can delete SETs whose
 597   ;; value is unused.
 598   (dolist (set (lambda-var-sets leaf))
 599     (setf (block-flush-p (node-block set)) t))
 600
 601   (values))
 602
 603 ;;; Note that something interesting has happened to VAR.
 604 (defun reoptimize-lambda-var (var)
 605   (declare (type lambda-var var))
 606   (let ((fun (lambda-var-home var)))
 607     ;; We only deal with LET variables, marking the corresponding
 608     ;; initial value arg as needing to be reoptimized.
 609     (when (and (eq (functional-kind fun) :let)
 610                (leaf-refs var))
 611       (do ((args (basic-combination-args
 612                   (continuation-dest
 613                    (node-cont
 614                     (first (leaf-refs fun)))))
 615                  (cdr args))
 616            (vars (lambda-vars fun) (cdr vars)))
 617           ((eq (car vars) var)
 618            (reoptimize-continuation (car args))))))
 619   (values))
 620
 621 ;;; Delete a function that has no references. This need only be called
 622 ;;; on functions that never had any references, since otherwise
 623 ;;; DELETE-REF will handle the deletion.
 624 (defun delete-functional (fun)
 625   (aver (and (null (leaf-refs fun))
 626              (not (functional-entry-fun fun))))
 627   (etypecase fun
 628     (optional-dispatch (delete-optional-dispatch fun))
 629     (clambda (delete-lambda fun)))
 630   (values))
 631
 632 ;;; Deal with deleting the last reference to a CLAMBDA. Since there is
 633 ;;; only one way into a CLAMBDA, deleting the last reference to a
 634 ;;; CLAMBDA ensures that there is no way to reach any of the code in
 635 ;;; it. So we just set the FUNCTIONAL-KIND for FUN and its LETs to
 636 ;;; :DELETED, causing IR1 optimization to delete blocks in that
 637 ;;; CLAMBDA.
 638 (defun delete-lambda (clambda)
 639   (declare (type clambda clambda))
 640   (let ((original-kind (functional-kind clambda))
 641         (bind (lambda-bind clambda)))
 642     (aver (not (member original-kind '(:deleted :optional :toplevel))))
 643     (aver (not (functional-has-external-references-p clambda)))
 644     (setf (functional-kind clambda) :deleted)
 645     (setf (lambda-bind clambda) nil)
 646     (dolist (let (lambda-lets clambda))
 647       (setf (lambda-bind let) nil)
 648       (setf (functional-kind let) :deleted))
 649
 650     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 651     ;; that we're using the old value of the KIND slot, not the
 652     ;; current slot value, which has now been set to :DELETED.)
 653     (if (member original-kind '(:let :mv-let :assignment))
 654         (let ((home (lambda-home clambda)))
 655           (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 656         ;; If the function isn't a LET, we unlink the function head
 657         ;; and tail from the component head and tail to indicate that
 658         ;; the code is unreachable. We also delete the function from
 659         ;; COMPONENT-LAMBDAS (it won't be there before local call
 660         ;; analysis, but no matter.) If the lambda was never
 661         ;; referenced, we give a note.
 662         (let* ((bind-block (node-block bind))
 663                (component (block-component bind-block))
 664                (return (lambda-return clambda)))
 665           (aver (null (leaf-refs clambda)))
 666           (unless (leaf-ever-used clambda)
 667             (let ((*compiler-error-context* bind))
 668               (compiler-note "deleting unused function~:[.~;~:*~%  ~S~]"
 669                              (leaf-debug-name clambda))))
 670           (unlink-blocks (component-head component) bind-block)
 671           (when return
 672             (unlink-blocks (node-block return) (component-tail component)))
 673           (setf (component-reanalyze component) t)
 674           (let ((tails (lambda-tail-set clambda)))
 675             (setf (tail-set-funs tails)
 676                   (delete clambda (tail-set-funs tails)))
 677             (setf (lambda-tail-set clambda) nil))
 678           (setf (component-lambdas component)
 679                 (delete clambda (component-lambdas component)))))
 680
 681     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 682     ;; ENTRY-FUN so that people will know that it is not an entry
 683     ;; point anymore.
 684     (when (eq original-kind :external)
 685       (let ((fun (functional-entry-fun clambda)))
 686         (setf (functional-entry-fun fun) nil)
 687         (when (optional-dispatch-p fun)
 688           (delete-optional-dispatch fun)))))
 689
 690   (values))
 691
 692 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 693 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 694 ;;; is used both before and after local call analysis. Afterward, all
 695 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 696 ;;; to the XEP, leaving it with no references at all. So we look at
 697 ;;; the XEP to see whether an optional-dispatch is still really being
 698 ;;; used. But before local call analysis, there are no XEPs, and all
 699 ;;; references are direct.
 700 ;;;
 701 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 702 ;;; entry-points, making them be normal lambdas, and then deleting the
 703 ;;; ones with no references. This deletes any e-p lambdas that were
 704 ;;; either never referenced, or couldn't be deleted when the last
 705 ;;; reference was deleted (due to their :OPTIONAL kind.)
 706 ;;;
 707 ;;; Note that the last optional entry point may alias the main entry,
 708 ;;; so when we process the main entry, its KIND may have been changed
 709 ;;; to NIL or even converted to a LETlike value.
 710 (defun delete-optional-dispatch (leaf)
 711   (declare (type optional-dispatch leaf))
 712   (let ((entry (functional-entry-fun leaf)))
 713     (unless (and entry (leaf-refs entry))
 714       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 715       (setf (functional-kind leaf) :deleted)
 716
 717       (flet ((frob (fun)
 718                (unless (eq (functional-kind fun) :deleted)
 719                  (aver (eq (functional-kind fun) :optional))
 720                  (setf (functional-kind fun) nil)
 721                  (let ((refs (leaf-refs fun)))
 722                    (cond ((null refs)
 723                           (delete-lambda fun))
 724                          ((null (rest refs))
 725                           (or (maybe-let-convert fun)
 726                               (maybe-convert-to-assignment fun)))
 727                          (t
 728                           (maybe-convert-to-assignment fun)))))))
 729
 730         (dolist (ep (optional-dispatch-entry-points leaf))
 731           (frob ep))
 732         (when (optional-dispatch-more-entry leaf)
 733           (frob (optional-dispatch-more-entry leaf)))
 734         (let ((main (optional-dispatch-main-entry leaf)))
 735           (when (eq (functional-kind main) :optional)
 736             (frob main))))))
 737
 738   (values))
 739
 740 ;;; Do stuff to delete the semantic attachments of a REF node. When
 741 ;;; this leaves zero or one reference, we do a type dispatch off of
 742 ;;; the leaf to determine if a special action is appropriate.
 743 (defun delete-ref (ref)
 744   (declare (type ref ref))
 745   (let* ((leaf (ref-leaf ref))
 746          (refs (delete ref (leaf-refs leaf))))
 747     (setf (leaf-refs leaf) refs)
 748
 749     (cond ((null refs)
 750            (typecase leaf
 751              (lambda-var
 752               (delete-lambda-var leaf))
 753              (clambda
 754               (ecase (functional-kind leaf)
 755                 ((nil :let :mv-let :assignment :escape :cleanup)
 756                  (aver (null (functional-entry-fun leaf)))
 757                  (delete-lambda leaf))
 758                 (:external
 759                  (delete-lambda leaf))
 760                 ((:deleted :optional))))
 761              (optional-dispatch
 762               (unless (eq (functional-kind leaf) :deleted)
 763                 (delete-optional-dispatch leaf)))))
 764           ((null (rest refs))
 765            (typecase leaf
 766              (clambda (or (maybe-let-convert leaf)
 767                           (maybe-convert-to-assignment leaf)))
 768              (lambda-var (reoptimize-lambda-var leaf))))
 769           (t
 770            (typecase leaf
 771              (clambda (maybe-convert-to-assignment leaf))))))
 772
 773   (values))
 774
 775 ;;; This function is called by people who delete nodes; it provides a
 776 ;;; way to indicate that the value of a continuation is no longer
 777 ;;; used. We null out the CONTINUATION-DEST, set FLUSH-P in the blocks
 778 ;;; containing uses of CONT and set COMPONENT-REOPTIMIZE. If the PREV
 779 ;;; of the use is deleted, then we blow off reoptimization.
 780 ;;;
 781 ;;; If the continuation is :DELETED, then we don't do anything, since
 782 ;;; all semantics have already been flushed. :DELETED-BLOCK-START
 783 ;;; start continuations are treated just like :BLOCK-START; it is
 784 ;;; possible that the continuation may be given a new dest (e.g. by
 785 ;;; SUBSTITUTE-CONTINUATION), so we don't want to delete it.
 786 (defun flush-dest (cont)
 787   (declare (type continuation cont))
 788
 789   (unless (eq (continuation-kind cont) :deleted)
 790     (aver (continuation-dest cont))
 791     (setf (continuation-dest cont) nil)
 792     (do-uses (use cont)
 793       (let ((prev (node-prev use)))
 794         (unless (eq (continuation-kind prev) :deleted)
 795           (let ((block (continuation-block prev)))
 796             (setf (component-reoptimize (block-component block)) t)
 797             (setf (block-attributep (block-flags block) flush-p type-asserted)
 798                   t))))))
 799
 800   (setf (continuation-%type-check cont) nil)
 801
 802   (values))
 803
 804 ;;; Do a graph walk backward from BLOCK, marking all predecessor
 805 ;;; blocks with the DELETE-P flag.
 806 (defun mark-for-deletion (block)
 807   (declare (type cblock block))
 808   (unless (block-delete-p block)
 809     (setf (block-delete-p block) t)
 810     (setf (component-reanalyze (block-component block)) t)
 811     (dolist (pred (block-pred block))
 812       (mark-for-deletion pred)))
 813   (values))
 814
 815 ;;; Delete CONT, eliminating both control and value semantics. We set
 816 ;;; FLUSH-P and COMPONENT-REOPTIMIZE similarly to in FLUSH-DEST. Here
 817 ;;; we must get the component from the use block, since the
 818 ;;; continuation may be a :DELETED-BLOCK-START.
 819 ;;;
 820 ;;; If CONT has DEST, then it must be the case that the DEST is
 821 ;;; unreachable, since we can't compute the value desired. In this
 822 ;;; case, we call MARK-FOR-DELETION to cause the DEST block and its
 823 ;;; predecessors to tell people to ignore them, and to cause them to
 824 ;;; be deleted eventually.
 825 (defun delete-continuation (cont)
 826   (declare (type continuation cont))
 827   (aver (not (eq (continuation-kind cont) :deleted)))
 828
 829   (do-uses (use cont)
 830     (let ((prev (node-prev use)))
 831       (unless (eq (continuation-kind prev) :deleted)
 832         (let ((block (continuation-block prev)))
 833           (setf (block-attributep (block-flags block) flush-p type-asserted) t)
 834           (setf (component-reoptimize (block-component block)) t)))))
 835
 836   (let ((dest (continuation-dest cont)))
 837     (when dest
 838       (let ((prev (node-prev dest)))
 839         (when (and prev
 840                    (not (eq (continuation-kind prev) :deleted)))
 841           (let ((block (continuation-block prev)))
 842             (unless (block-delete-p block)
 843               (mark-for-deletion block)))))))
 844
 845   (setf (continuation-kind cont) :deleted)
 846   (setf (continuation-dest cont) nil)
 847   (setf (continuation-next cont) nil)
 848   (setf (continuation-asserted-type cont) *empty-type*)
 849   (setf (continuation-%derived-type cont) *empty-type*)
 850   (setf (continuation-use cont) nil)
 851   (setf (continuation-block cont) nil)
 852   (setf (continuation-reoptimize cont) nil)
 853   (setf (continuation-%type-check cont) nil)
 854   (setf (continuation-info cont) nil)
 855
 856   (values))
 857
 858 ;;; This function does what is necessary to eliminate the code in it
 859 ;;; from the IR1 representation. This involves unlinking it from its
 860 ;;; predecessors and successors and deleting various node-specific
 861 ;;; semantic information.
 862 ;;;
 863 ;;; We mark the START as has having no next and remove the last node
 864 ;;; from its CONT's uses. We also flush the DEST for all continuations
 865 ;;; whose values are received by nodes in the block.
 866 (defun delete-block (block)
 867   (declare (type cblock block))
 868   (aver (block-component block)) ; else block is already deleted!
 869   (note-block-deletion block)
 870   (setf (block-delete-p block) t)
 871
 872   (let* ((last (block-last block))
 873          (cont (node-cont last)))
 874     (delete-continuation-use last)
 875     (if (eq (continuation-kind cont) :unused)
 876         (delete-continuation cont)
 877         (reoptimize-continuation cont)))
 878
 879   (dolist (b (block-pred block))
 880     (unlink-blocks b block)
 881     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
 882     ;; broken when successors were deleted without setting the
 883     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
 884     ;; doesn't happen again.
 885     (aver (not (and (null (block-succ b))
 886                     (not (block-delete-p b))
 887                     (not (eq b (component-head (block-component b))))))))
 888   (dolist (b (block-succ block))
 889     (unlink-blocks block b))
 890
 891   (do-nodes (node cont block)
 892     (typecase node
 893       (ref (delete-ref node))
 894       (cif
 895        (flush-dest (if-test node)))
 896       ;; The next two cases serve to maintain the invariant that a LET
 897       ;; always has a well-formed COMBINATION, REF and BIND. We delete
 898       ;; the lambda whenever we delete any of these, but we must be
 899       ;; careful that this LET has not already been partially deleted.
 900       (basic-combination
 901        (when (and (eq (basic-combination-kind node) :local)
 902                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
 903                   (continuation-use (basic-combination-fun node)))
 904          (let ((fun (combination-lambda node)))
 905            ;; If our REF was the second-to-last ref, and has been
 906            ;; deleted, then FUN may be a LET for some other
 907            ;; combination.
 908            (when (and (functional-letlike-p fun)
 909                       (eq (let-combination fun) node))
 910              (delete-lambda fun))))
 911        (flush-dest (basic-combination-fun node))
 912        (dolist (arg (basic-combination-args node))
 913          (when arg (flush-dest arg))))
 914       (bind
 915        (let ((lambda (bind-lambda node)))
 916          (unless (eq (functional-kind lambda) :deleted)
 917            (aver (functional-somewhat-letlike-p lambda))
 918            (delete-lambda lambda))))
 919       (exit
 920        (let ((value (exit-value node))
 921              (entry (exit-entry node)))
 922          (when value
 923            (flush-dest value))
 924          (when entry
 925            (setf (entry-exits entry)
 926                  (delete node (entry-exits entry))))))
 927       (creturn
 928        (flush-dest (return-result node))
 929        (delete-return node))
 930       (cset
 931        (flush-dest (set-value node))
 932        (let ((var (set-var node)))
 933          (setf (basic-var-sets var)
 934                (delete node (basic-var-sets var))))))
 935
 936     (delete-continuation (node-prev node)))
 937
 938   (remove-from-dfo block)
 939   (values))
 940
 941 ;;; Do stuff to indicate that the return node Node is being deleted.
 942 ;;; We set the RETURN to NIL.
 943 (defun delete-return (node)
 944   (declare (type creturn node))
 945   (let ((fun (return-lambda node)))
 946     (aver (lambda-return fun))
 947     (setf (lambda-return fun) nil))
 948   (values))
 949
 950 ;;; If any of the VARS in FUN was never referenced and was not
 951 ;;; declared IGNORE, then complain.
 952 (defun note-unreferenced-vars (fun)
 953   (declare (type clambda fun))
 954   (dolist (var (lambda-vars fun))
 955     (unless (or (leaf-ever-used var)
 956                 (lambda-var-ignorep var))
 957       (let ((*compiler-error-context* (lambda-bind fun)))
 958         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
 959           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
 960           ;; requires this to be no more than a STYLE-WARNING.
 961           (compiler-style-warn "The variable ~S is defined but never used."
 962                                (leaf-debug-name var)))
 963         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
 964   (values))
 965
 966 (defvar *deletion-ignored-objects* '(t nil))
 967
 968 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
 969 ;;; our recursion so that we don't get lost in circular structures. We
 970 ;;; ignore the car of forms if they are a symbol (to prevent confusing
 971 ;;; function referencess with variables), and we also ignore anything
 972 ;;; inside ' or #'.
 973 (defun present-in-form (obj form depth)
 974   (declare (type (integer 0 20) depth))
 975   (cond ((= depth 20) nil)
 976         ((eq obj form) t)
 977         ((atom form) nil)
 978         (t
 979          (let ((first (car form))
 980                (depth (1+ depth)))
 981            (if (member first '(quote function))
 982                nil
 983                (or (and (not (symbolp first))
 984                         (present-in-form obj first depth))
 985                    (do ((l (cdr form) (cdr l))
 986                         (n 0 (1+ n)))
 987                        ((or (atom l) (> n 100))
 988                         nil)
 989                      (declare (fixnum n))
 990                      (when (present-in-form obj (car l) depth)
 991                        (return t)))))))))
 992
 993 ;;; This function is called on a block immediately before we delete
 994 ;;; it. We check to see whether any of the code about to die appeared
 995 ;;; in the original source, and emit a note if so.
 996 ;;;
 997 ;;; If the block was in a lambda is now deleted, then we ignore the
 998 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
 999 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1000 ;;; reasonable for a function to not return, and there is a different
1001 ;;; note for that case anyway.
1002 ;;;
1003 ;;; If the actual source is an atom, then we use a bunch of heuristics
1004 ;;; to guess whether this reference really appeared in the original
1005 ;;; source:
1006 ;;; -- If a symbol, it must be interned and not a keyword.
1007 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1008 ;;;    or a character.)
1009 ;;; -- The atom must be "present" in the original source form, and
1010 ;;;    present in all intervening actual source forms.
1011 (defun note-block-deletion (block)
1012   (let ((home (block-home-lambda block)))
1013     (unless (eq (functional-kind home) :deleted)
1014       (do-nodes (node cont block)
1015         (let* ((path (node-source-path node))
1016                (first (first path)))
1017           (when (or (eq first 'original-source-start)
1018                     (and (atom first)
1019                          (or (not (symbolp first))
1020                              (let ((pkg (symbol-package first)))
1021                                (and pkg
1022                                     (not (eq pkg (symbol-package :end))))))
1023                          (not (member first *deletion-ignored-objects*))
1024                          (not (typep first '(or fixnum character)))
1025                          (every (lambda (x)
1026                                   (present-in-form first x 0))
1027                                 (source-path-forms path))
1028                          (present-in-form first (find-original-source path)
1029                                           0)))
1030             (unless (return-p node)
1031               (let ((*compiler-error-context* node))
1032                 (compiler-note "deleting unreachable code")))
1033             (return))))))
1034   (values))
1035
1036 ;;; Delete a node from a block, deleting the block if there are no
1037 ;;; nodes left. We remove the node from the uses of its CONT, but we
1038 ;;; don't deal with cleaning up any type-specific semantic
1039 ;;; attachments. If the CONT is :UNUSED after deleting this use, then
1040 ;;; we delete CONT. (Note :UNUSED is not the same as no uses. A
1041 ;;; continuation will only become :UNUSED if it was :INSIDE-BLOCK
1042 ;;; before.)
1043 ;;;
1044 ;;; If the node is the last node, there must be exactly one successor.
1045 ;;; We link all of our precedessors to the successor and unlink the
1046 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1047 ;;; left, and the block is a successor of itself, then we replace the
1048 ;;; only node with a degenerate exit node. This provides a way to
1049 ;;; represent the bodyless infinite loop, given the prohibition on
1050 ;;; empty blocks in IR1.
1051 (defun unlink-node (node)
1052   (declare (type node node))
1053   (let* ((cont (node-cont node))
1054          (next (continuation-next cont))
1055          (prev (node-prev node))
1056          (block (continuation-block prev))
1057          (prev-kind (continuation-kind prev))
1058          (last (block-last block)))
1059
1060     (unless (eq (continuation-kind cont) :deleted)
1061       (delete-continuation-use node)
1062       (when (eq (continuation-kind cont) :unused)
1063         (aver (not (continuation-dest cont)))
1064         (delete-continuation cont)))
1065
1066     (setf (block-type-asserted block) t)
1067     (setf (block-test-modified block) t)
1068
1069     (cond ((or (eq prev-kind :inside-block)
1070                (and (eq prev-kind :block-start)
1071                     (not (eq node last))))
1072            (cond ((eq node last)
1073                   (setf (block-last block) (continuation-use prev))
1074                   (setf (continuation-next prev) nil))
1075                  (t
1076                   (setf (continuation-next prev) next)
1077                   (setf (node-prev next) prev)))
1078            (setf (node-prev node) nil)
1079            nil)
1080           (t
1081            (aver (eq prev-kind :block-start))
1082            (aver (eq node last))
1083            (let* ((succ (block-succ block))
1084                   (next (first succ)))
1085              (aver (and succ (null (cdr succ))))
1086              (cond
1087               ((member block succ)
1088                (with-ir1-environment-from-node node
1089                  (let ((exit (make-exit))
1090                        (dummy (make-continuation)))
1091                    (setf (continuation-next prev) nil)
1092                    (link-node-to-previous-continuation exit prev)
1093                    (add-continuation-use exit dummy)
1094                    (setf (block-last block) exit)))
1095                (setf (node-prev node) nil)
1096                nil)
1097               (t
1098                (aver (eq (block-start-cleanup block)
1099                          (block-end-cleanup block)))
1100                (unlink-blocks block next)
1101                (dolist (pred (block-pred block))
1102                  (change-block-successor pred block next))
1103                (remove-from-dfo block)
1104                (cond ((continuation-dest prev)
1105                       (setf (continuation-next prev) nil)
1106                       (setf (continuation-kind prev) :deleted-block-start))
1107                      (t
1108                       (delete-continuation prev)))
1109                (setf (node-prev node) nil)
1110                t)))))))
1111
1112 ;;; Return true if NODE has been deleted, false if it is still a valid
1113 ;;; part of IR1.
1114 (defun node-deleted (node)
1115   (declare (type node node))
1116   (let ((prev (node-prev node)))
1117     (not (and prev
1118               (not (eq (continuation-kind prev) :deleted))
1119               (let ((block (continuation-block prev)))
1120                 (and (block-component block)
1121                      (not (block-delete-p block))))))))
1122
1123 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1124 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1125 ;;; triggered by deletion.
1126 (defun delete-component (component)
1127   (declare (type component component))
1128   (aver (null (component-new-functionals component)))
1129   (setf (component-kind component) :deleted)
1130   (do-blocks (block component)
1131     (setf (block-delete-p block) t))
1132   (dolist (fun (component-lambdas component))
1133     (setf (functional-kind fun) nil)
1134     (setf (functional-entry-fun fun) nil)
1135     (setf (leaf-refs fun) nil)
1136     (delete-functional fun))
1137   (do-blocks (block component)
1138     (delete-block block))
1139   (values))
1140
1141 ;;; Convert code of the form
1142 ;;;   (FOO ... (FUN ...) ...)
1143 ;;; to
1144 ;;;   (FOO ...    ...    ...).
1145 ;;; In other words, replace the function combination FUN by its
1146 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1147 ;;; to blow out of whatever transform called this. Note, as the number
1148 ;;; of arguments changes, the transform must be prepared to return a
1149 ;;; lambda with a new lambda-list with the correct number of
1150 ;;; arguments.
1151 (defun extract-fun-args (cont fun num-args)
1152   #!+sb-doc
1153   "If CONT is a call to FUN with NUM-ARGS args, change those arguments
1154    to feed directly to the continuation-dest of CONT, which must be
1155    a combination."
1156   (declare (type continuation cont)
1157            (type symbol fun)
1158            (type index num-args))
1159   (let ((outside (continuation-dest cont))
1160         (inside (continuation-use cont)))
1161     (aver (combination-p outside))
1162     (unless (combination-p inside)
1163       (give-up-ir1-transform))
1164     (let ((inside-fun (combination-fun inside)))
1165       (unless (eq (continuation-fun-name inside-fun) fun)
1166         (give-up-ir1-transform))
1167       (let ((inside-args (combination-args inside)))
1168         (unless (= (length inside-args) num-args)
1169           (give-up-ir1-transform))
1170         (let* ((outside-args (combination-args outside))
1171                (arg-position (position cont outside-args))
1172                (before-args (subseq outside-args 0 arg-position))
1173                (after-args (subseq outside-args (1+ arg-position))))
1174           (dolist (arg inside-args)
1175             (setf (continuation-dest arg) outside))
1176           (setf (combination-args inside) nil)
1177           (setf (combination-args outside)
1178                 (append before-args inside-args after-args))
1179           (change-ref-leaf (continuation-use inside-fun)
1180                            (find-free-fun 'list "???"))
1181           (setf (combination-kind inside) :full)
1182           (setf (node-derived-type inside) *wild-type*)
1183           (flush-dest cont)
1184           (setf (continuation-asserted-type cont) *wild-type*)
1185           (values))))))
1186 \f
1187 ;;;; leaf hackery
1188
1189 ;;; Change the LEAF that a REF refers to.
1190 (defun change-ref-leaf (ref leaf)
1191   (declare (type ref ref) (type leaf leaf))
1192   (unless (eq (ref-leaf ref) leaf)
1193     (push ref (leaf-refs leaf))
1194     (delete-ref ref)
1195     (setf (ref-leaf ref) leaf)
1196     (let ((ltype (leaf-type leaf)))
1197       (if (fun-type-p ltype)
1198           (setf (node-derived-type ref) ltype)
1199           (derive-node-type ref ltype)))
1200     (reoptimize-continuation (node-cont ref)))
1201   (values))
1202
1203 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1204 (defun substitute-leaf (new-leaf old-leaf)
1205   (declare (type leaf new-leaf old-leaf))
1206   (dolist (ref (leaf-refs old-leaf))
1207     (change-ref-leaf ref new-leaf))
1208   (values))
1209
1210 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1211 ;;; whether to substitute
1212 (defun substitute-leaf-if (test new-leaf old-leaf)
1213   (declare (type leaf new-leaf old-leaf) (type function test))
1214   (dolist (ref (leaf-refs old-leaf))
1215     (when (funcall test ref)
1216       (change-ref-leaf ref new-leaf)))
1217   (values))
1218
1219 ;;; Return a LEAF which represents the specified constant object. If
1220 ;;; the object is not in *CONSTANTS*, then we create a new constant
1221 ;;; LEAF and enter it.
1222 (defun find-constant (object)
1223   (if (typep object
1224              ;; FIXME: What is the significance of this test? ("things
1225              ;; that are worth uniquifying"?)
1226              '(or symbol number character instance))
1227       (or (gethash object *constants*)
1228           (setf (gethash object *constants*)
1229                 (make-constant :value object
1230                                :%source-name '.anonymous.
1231                                :type (ctype-of object)
1232                                :where-from :defined)))
1233       (make-constant :value object
1234                      :%source-name '.anonymous.
1235                      :type (ctype-of object)
1236                      :where-from :defined)))
1237 \f
1238 ;;; If there is a non-local exit noted in ENTRY's environment that
1239 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1240 (defun find-nlx-info (entry cont)
1241   (declare (type entry entry) (type continuation cont))
1242   (let ((entry-cleanup (entry-cleanup entry)))
1243     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1244       (when (and (eq (nlx-info-continuation nlx) cont)
1245                  (eq (nlx-info-cleanup nlx) entry-cleanup))
1246         (return nlx)))))
1247 \f
1248 ;;;; functional hackery
1249
1250 (declaim (ftype (function (functional) clambda) main-entry))
1251 (defun main-entry (functional)
1252   (etypecase functional
1253     (clambda functional)
1254     (optional-dispatch
1255      (optional-dispatch-main-entry functional))))
1256
1257 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1258 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1259 ;;; optional with null default and no SUPPLIED-P. There must be a
1260 ;;; &REST arg with no references.
1261 (declaim (ftype (function (functional) boolean) looks-like-an-mv-bind))
1262 (defun looks-like-an-mv-bind (functional)
1263   (and (optional-dispatch-p functional)
1264        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1265            ((null arg) nil)
1266          (let ((info (lambda-var-arg-info (car arg))))
1267            (unless info (return nil))
1268            (case (arg-info-kind info)
1269              (:optional
1270               (when (or (arg-info-supplied-p info) (arg-info-default info))
1271                 (return nil)))
1272              (:rest
1273               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1274              (t
1275               (return nil)))))))
1276
1277 ;;; Return true if function is an external entry point. This is true
1278 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1279 ;;; (:TOPLEVEL kind.)
1280 (defun xep-p (fun)
1281   (declare (type functional fun))
1282   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1283
1284 ;;; If CONT's only use is a non-notinline global function reference,
1285 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1286 ;;; is true, then we don't care if the leaf is NOTINLINE.
1287 (defun continuation-fun-name (cont &optional notinline-ok)
1288   (declare (type continuation cont))
1289   (let ((use (continuation-use cont)))
1290     (if (ref-p use)
1291         (let ((leaf (ref-leaf use)))
1292           (if (and (global-var-p leaf)
1293                    (eq (global-var-kind leaf) :global-function)
1294                    (or (not (defined-fun-p leaf))
1295                        (not (eq (defined-fun-inlinep leaf) :notinline))
1296                        notinline-ok))
1297               (leaf-source-name leaf)
1298               nil))
1299         nil)))
1300
1301 ;;; Return the source name of a combination. (This is an idiom
1302 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1303 (defun combination-fun-source-name (combination)
1304   (let ((ref (continuation-use (combination-fun combination))))
1305     (leaf-source-name (ref-leaf ref))))
1306
1307 ;;; Return the COMBINATION node that is the call to the LET FUN.
1308 (defun let-combination (fun)
1309   (declare (type clambda fun))
1310   (aver (functional-letlike-p fun))
1311   (continuation-dest (node-cont (first (leaf-refs fun)))))
1312
1313 ;;; Return the initial value continuation for a LET variable, or NIL
1314 ;;; if there is none.
1315 (defun let-var-initial-value (var)
1316   (declare (type lambda-var var))
1317   (let ((fun (lambda-var-home var)))
1318     (elt (combination-args (let-combination fun))
1319          (position-or-lose var (lambda-vars fun)))))
1320
1321 ;;; Return the LAMBDA that is called by the local CALL.
1322 (defun combination-lambda (call)
1323   (declare (type basic-combination call))
1324   (aver (eq (basic-combination-kind call) :local))
1325   (ref-leaf (continuation-use (basic-combination-fun call))))
1326
1327 (defvar *inline-expansion-limit* 200
1328   #!+sb-doc
1329   "an upper limit on the number of inline function calls that will be expanded
1330    in any given code object (single function or block compilation)")
1331
1332 ;;; Check whether NODE's component has exceeded its inline expansion
1333 ;;; limit, and warn if so, returning NIL.
1334 (defun inline-expansion-ok (node)
1335   (let ((expanded (incf (component-inline-expansions
1336                          (block-component
1337                           (node-block node))))))
1338     (cond ((> expanded *inline-expansion-limit*) nil)
1339           ((= expanded *inline-expansion-limit*)
1340            ;; FIXME: If the objective is to stop the recursive
1341            ;; expansion of inline functions, wouldn't it be more
1342            ;; correct to look back through surrounding expansions
1343            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1344            ;; possibly stored elsewhere too) and suppress expansion
1345            ;; and print this warning when the function being proposed
1346            ;; for inline expansion is found there? (I don't like the
1347            ;; arbitrary numerical limit in principle, and I think
1348            ;; it'll be a nuisance in practice if we ever want the
1349            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1350            ;; arbitrarily huge blocks of code. -- WHN)
1351            (let ((*compiler-error-context* node))
1352              (compiler-note "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1353                              probably trying to~%  ~
1354                              inline a recursive function."
1355                             *inline-expansion-limit*))
1356            nil)
1357           (t t))))
1358 \f
1359 ;;;; careful call
1360
1361 ;;; Apply a function to some arguments, returning a list of the values
1362 ;;; resulting of the evaluation. If an error is signalled during the
1363 ;;; application, then we produce a warning message using WARN-FUN and
1364 ;;; return NIL as our second value to indicate this. NODE is used as
1365 ;;; the error context for any error message, and CONTEXT is a string
1366 ;;; that is spliced into the warning.
1367 (declaim (ftype (function ((or symbol function) list node function string)
1368                           (values list boolean))
1369                 careful-call))
1370 (defun careful-call (function args node warn-fun context)
1371   (values
1372    (multiple-value-list
1373     (handler-case (apply function args)
1374       (error (condition)
1375         (let ((*compiler-error-context* node))
1376           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1377           (return-from careful-call (values nil nil))))))
1378    t))
1379 \f
1380 ;;;; utilities used at run-time for parsing &KEY args in IR1
1381
1382 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1383 ;;; the continuation for the value of the &KEY argument KEY in the
1384 ;;; list of continuations ARGS. It returns the continuation if the
1385 ;;; keyword is present, or NIL otherwise. The legality and
1386 ;;; constantness of the keywords should already have been checked.
1387 (declaim (ftype (function (list keyword) (or continuation null))
1388                 find-keyword-continuation))
1389 (defun find-keyword-continuation (args key)
1390   (do ((arg args (cddr arg)))
1391       ((null arg) nil)
1392     (when (eq (continuation-value (first arg)) key)
1393       (return (second arg)))))
1394
1395 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1396 ;;; verify that alternating continuations in ARGS are constant and
1397 ;;; that there is an even number of args.
1398 (declaim (ftype (function (list) boolean) check-key-args-constant))
1399 (defun check-key-args-constant (args)
1400   (do ((arg args (cddr arg)))
1401       ((null arg) t)
1402     (unless (and (rest arg)
1403                  (constant-continuation-p (first arg)))
1404       (return nil))))
1405
1406 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1407 ;;; verify that the list of continuations ARGS is a well-formed &KEY
1408 ;;; arglist and that only keywords present in the list KEYS are
1409 ;;; supplied.
1410 (declaim (ftype (function (list list) boolean) check-transform-keys))
1411 (defun check-transform-keys (args keys)
1412   (and (check-key-args-constant args)
1413        (do ((arg args (cddr arg)))
1414            ((null arg) t)
1415          (unless (member (continuation-value (first arg)) keys)
1416            (return nil)))))
1417 \f
1418 ;;;; miscellaneous
1419
1420 ;;; Called by the expansion of the EVENT macro.
1421 (declaim (ftype (function (event-info (or node null)) *) %event))
1422 (defun %event (info node)
1423   (incf (event-info-count info))
1424   (when (and (>= (event-info-level info) *event-note-threshold*)
1425              (policy (or node *lexenv*)
1426                      (= inhibit-warnings 0)))
1427     (let ((*compiler-error-context* node))
1428       (compiler-note (event-info-description info))))
1429
1430   (let ((action (event-info-action info)))
1431     (when action (funcall action node))))