src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (defun principal-lvar-use (lvar)
  66   (labels ((plu (lvar)
  67              (declare (type lvar lvar))
  68              (let ((use (lvar-uses lvar)))
  69                (if (cast-p use)
  70                    (plu (cast-value use))
  71                    use))))
  72     (plu lvar)))
  73
  74 ;;; Update lvar use information so that NODE is no longer a use of its
  75 ;;; LVAR.
  76 ;;;
  77 ;;; Note: if you call this function, you may have to do a
  78 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  79 ;;; changed.
  80 (declaim (ftype (sfunction (node) (values))
  81                 delete-lvar-use
  82                 %delete-lvar-use))
  83 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  84 ;;; be given a new use.
  85 (defun %delete-lvar-use (node)
  86   (let ((lvar (node-lvar node)))
  87     (when lvar
  88       (if (listp (lvar-uses lvar))
  89           (let ((new-uses (delq node (lvar-uses lvar))))
  90             (setf (lvar-uses lvar)
  91                   (if (singleton-p new-uses)
  92                       (first new-uses)
  93                       new-uses)))
  94           (setf (lvar-uses lvar) nil))
  95       (setf (node-lvar node) nil)))
  96   (values))
  97 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
  98 ;;; its DEST's block, which must be unreachable.
  99 (defun delete-lvar-use (node)
 100   (let ((lvar (node-lvar node)))
 101     (when lvar
 102       (%delete-lvar-use node)
 103       (if (null (lvar-uses lvar))
 104           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 105                      (() (not (node-deleted dest)) :exit-if-null)
 106                      (block (node-block dest)))
 107             (mark-for-deletion block))
 108           (reoptimize-lvar lvar))))
 109   (values))
 110
 111 ;;; Update lvar use information so that NODE uses LVAR.
 112 ;;;
 113 ;;; Note: if you call this function, you may have to do a
 114 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 115 ;;; changed.
 116 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 117 (defun add-lvar-use (node lvar)
 118   (aver (not (node-lvar node)))
 119   (when lvar
 120     (let ((uses (lvar-uses lvar)))
 121       (setf (lvar-uses lvar)
 122             (cond ((null uses)
 123                    node)
 124                   ((listp uses)
 125                    (cons node uses))
 126                   (t
 127                    (list node uses))))
 128       (setf (node-lvar node) lvar)))
 129
 130   (values))
 131
 132 ;;; Return true if LVAR destination is executed immediately after
 133 ;;; NODE. Cleanups are ignored.
 134 (defun immediately-used-p (lvar node)
 135   (declare (type lvar lvar) (type node node))
 136   (aver (eq (node-lvar node) lvar))
 137   (let ((dest (lvar-dest lvar)))
 138     (acond ((node-next node)
 139             (eq (ctran-next it) dest))
 140            (t (eq (block-start (first (block-succ (node-block node))))
 141                   (node-prev dest))))))
 142 \f
 143 ;;;; lvar substitution
 144
 145 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 146 ;;; NIL. We do not flush OLD's DEST.
 147 (defun substitute-lvar (new old)
 148   (declare (type lvar old new))
 149   (aver (not (lvar-dest new)))
 150   (let ((dest (lvar-dest old)))
 151     (etypecase dest
 152       ((or ref bind))
 153       (cif (setf (if-test dest) new))
 154       (cset (setf (set-value dest) new))
 155       (creturn (setf (return-result dest) new))
 156       (exit (setf (exit-value dest) new))
 157       (basic-combination
 158        (if (eq old (basic-combination-fun dest))
 159            (setf (basic-combination-fun dest) new)
 160            (setf (basic-combination-args dest)
 161                  (nsubst new old (basic-combination-args dest)))))
 162       (cast (setf (cast-value dest) new)))
 163
 164     (setf (lvar-dest old) nil)
 165     (setf (lvar-dest new) dest)
 166     (flush-lvar-externally-checkable-type new))
 167   (values))
 168
 169 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 170 ;;; arbitary number of uses. NEW is supposed to be "later" than OLD.
 171 (defun substitute-lvar-uses (new old propagate-dx)
 172   (declare (type lvar old)
 173            (type (or lvar null) new)
 174            (type boolean propagate-dx))
 175
 176   (cond (new
 177          (do-uses (node old)
 178            (%delete-lvar-use node)
 179            (add-lvar-use node new))
 180          (reoptimize-lvar new)
 181          (awhen (and propagate-dx (lvar-dynamic-extent old))
 182            (setf (lvar-dynamic-extent old) nil)
 183            (unless (lvar-dynamic-extent new)
 184              (setf (lvar-dynamic-extent new) it)
 185              (setf (cleanup-info it) (substitute new old (cleanup-info it)))))
 186          (when (lvar-dynamic-extent new)
 187            (do-uses (node new)
 188              (node-ends-block node))))
 189         (t (flush-dest old)))
 190
 191   (values))
 192 \f
 193 ;;;; block starting/creation
 194
 195 ;;; Return the block that CTRAN is the start of, making a block if
 196 ;;; necessary. This function is called by IR1 translators which may
 197 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 198 ;;; used more than once must start a block by the time that anyone
 199 ;;; does a USE-CTRAN on it.
 200 ;;;
 201 ;;; We also throw the block into the next/prev list for the
 202 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 203 ;;; made.
 204 (defun ctran-starts-block (ctran)
 205   (declare (type ctran ctran))
 206   (ecase (ctran-kind ctran)
 207     (:unused
 208      (aver (not (ctran-block ctran)))
 209      (let* ((next (component-last-block *current-component*))
 210             (prev (block-prev next))
 211             (new-block (make-block ctran)))
 212        (setf (block-next new-block) next
 213              (block-prev new-block) prev
 214              (block-prev next) new-block
 215              (block-next prev) new-block
 216              (ctran-block ctran) new-block
 217              (ctran-kind ctran) :block-start)
 218        (aver (not (ctran-use ctran)))
 219        new-block))
 220     (:block-start
 221      (ctran-block ctran))))
 222
 223 ;;; Ensure that CTRAN is the start of a block so that the use set can
 224 ;;; be freely manipulated.
 225 (defun ensure-block-start (ctran)
 226   (declare (type ctran ctran))
 227   (let ((kind (ctran-kind ctran)))
 228     (ecase kind
 229       ((:block-start))
 230       ((:unused)
 231        (setf (ctran-block ctran)
 232              (make-block-key :start ctran))
 233        (setf (ctran-kind ctran) :block-start))
 234       ((:inside-block)
 235        (node-ends-block (ctran-use ctran)))))
 236   (values))
 237
 238 ;;; CTRAN must be the last ctran in an incomplete block; finish the
 239 ;;; block and start a new one if necessary.
 240 (defun start-block (ctran)
 241   (declare (type ctran ctran))
 242   (aver (not (ctran-next ctran)))
 243   (ecase (ctran-kind ctran)
 244     (:inside-block
 245      (let ((block (ctran-block ctran))
 246            (node (ctran-use ctran)))
 247        (aver (not (block-last block)))
 248        (aver node)
 249        (setf (block-last block) node)
 250        (setf (node-next node) nil)
 251        (setf (ctran-use ctran) nil)
 252        (setf (ctran-kind ctran) :unused)
 253        (setf (ctran-block ctran) nil)
 254        (link-blocks block (ctran-starts-block ctran))))
 255     (:block-start)))
 256 \f
 257 ;;;;
 258
 259 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 260 ;;; call. First argument must be 'DUMMY, which will be replaced with
 261 ;;; LVAR. In case of an ordinary call the function should not have
 262 ;;; return type NIL. We create a new "filtered" lvar.
 263 ;;;
 264 ;;; TODO: remove preconditions.
 265 (defun filter-lvar (lvar form)
 266   (declare (type lvar lvar) (type list form))
 267   (let* ((dest (lvar-dest lvar))
 268          (ctran (node-prev dest)))
 269     (with-ir1-environment-from-node dest
 270
 271       (ensure-block-start ctran)
 272       (let* ((old-block (ctran-block ctran))
 273              (new-start (make-ctran))
 274              (filtered-lvar (make-lvar))
 275              (new-block (ctran-starts-block new-start)))
 276
 277         ;; Splice in the new block before DEST, giving the new block
 278         ;; all of DEST's predecessors.
 279         (dolist (block (block-pred old-block))
 280           (change-block-successor block old-block new-block))
 281
 282         (ir1-convert new-start ctran filtered-lvar form)
 283
 284         ;; KLUDGE: Comments at the head of this function in CMU CL
 285         ;; said that somewhere in here we
 286         ;;   Set the new block's start and end cleanups to the *start*
 287         ;;   cleanup of PREV's block. This overrides the incorrect
 288         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 289         ;; Unfortunately I can't find any code which corresponds to this.
 290         ;; Perhaps it was a stale comment? Or perhaps I just don't
 291         ;; understand.. -- WHN 19990521
 292
 293         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 294         ;; no LET conversion has been done yet.) The [mv-]combination
 295         ;; code from the call in the form will be the use of the new
 296         ;; check lvar. We substitute for the first argument of
 297         ;; this node.
 298         (let* ((node (lvar-use filtered-lvar))
 299                (args (basic-combination-args node))
 300                (victim (first args)))
 301           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 302                     'dummy))
 303
 304           (substitute-lvar filtered-lvar lvar)
 305           (substitute-lvar lvar victim)
 306           (flush-dest victim))
 307
 308         ;; Invoking local call analysis converts this call to a LET.
 309         (locall-analyze-component *current-component*))))
 310   (values))
 311
 312 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 313 (defun delete-filter (node lvar value)
 314   (aver (eq (lvar-dest value) node))
 315   (aver (eq (node-lvar node) lvar))
 316   (cond (lvar (collect ((merges))
 317                 (when (return-p (lvar-dest lvar))
 318                   (do-uses (use value)
 319                     (when (and (basic-combination-p use)
 320                                (eq (basic-combination-kind use) :local))
 321                       (merges use))))
 322                 (substitute-lvar-uses lvar value
 323                                       (and lvar (eq (lvar-uses lvar) node)))
 324                 (%delete-lvar-use node)
 325                 (prog1
 326                     (unlink-node node)
 327                   (dolist (merge (merges))
 328                     (merge-tail-sets merge)))))
 329         (t (flush-dest value)
 330            (unlink-node node))))
 331
 332 ;;; Make a CAST and insert it into IR1 before node NEXT.
 333 (defun insert-cast-before (next lvar type policy)
 334   (declare (type node next) (type lvar lvar) (type ctype type))
 335   (with-ir1-environment-from-node next
 336     (let* ((ctran (node-prev next))
 337            (cast (make-cast lvar type policy))
 338            (internal-ctran (make-ctran)))
 339       (setf (ctran-next ctran) cast
 340             (node-prev cast) ctran)
 341       (use-ctran cast internal-ctran)
 342       (link-node-to-previous-ctran next internal-ctran)
 343       (setf (lvar-dest lvar) cast)
 344       (reoptimize-lvar lvar)
 345       (when (return-p next)
 346         (node-ends-block cast))
 347       (setf (block-attributep (block-flags (node-block cast))
 348                               type-check type-asserted)
 349             t)
 350       cast)))
 351 \f
 352 ;;;; miscellaneous shorthand functions
 353
 354 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 355 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 356 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 357 ;;; deleted, and then return its home.
 358 (defun node-home-lambda (node)
 359   (declare (type node node))
 360   (do ((fun (lexenv-lambda (node-lexenv node))
 361             (lexenv-lambda (lambda-call-lexenv fun))))
 362       ((not (memq (functional-kind fun) '(:deleted :zombie)))
 363        (lambda-home fun))
 364     (when (eq (lambda-home fun) fun)
 365       (return fun))))
 366
 367 #!-sb-fluid (declaim (inline node-block))
 368 (defun node-block (node)
 369   (ctran-block (node-prev node)))
 370 (declaim (ftype (sfunction (node) component) node-component))
 371 (defun node-component (node)
 372   (block-component (node-block node)))
 373 (declaim (ftype (sfunction (node) physenv) node-physenv))
 374 (defun node-physenv (node)
 375   (lambda-physenv (node-home-lambda node)))
 376 #!-sb-fluid (declaim (inline node-dest))
 377 (defun node-dest (node)
 378   (awhen (node-lvar node) (lvar-dest it)))
 379
 380 #!-sb-fluid (declaim (inline node-stack-allocate-p))
 381 (defun node-stack-allocate-p (node)
 382   (awhen (node-lvar node)
 383     (lvar-dynamic-extent it)))
 384
 385 (declaim (inline block-to-be-deleted-p))
 386 (defun block-to-be-deleted-p (block)
 387   (or (block-delete-p block)
 388       (eq (functional-kind (block-home-lambda block)) :deleted)))
 389
 390 ;;; Checks whether NODE is in a block to be deleted
 391 (declaim (inline node-to-be-deleted-p))
 392 (defun node-to-be-deleted-p (node)
 393   (block-to-be-deleted-p (node-block node)))
 394
 395 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 396 (defun lambda-block (clambda)
 397   (node-block (lambda-bind clambda)))
 398 (declaim (ftype (sfunction (clambda) component) lambda-component))
 399 (defun lambda-component (clambda)
 400   (block-component (lambda-block clambda)))
 401
 402 (declaim (ftype (sfunction (cblock) node) block-start-node))
 403 (defun block-start-node (block)
 404   (ctran-next (block-start block)))
 405
 406 ;;; Return the enclosing cleanup for environment of the first or last
 407 ;;; node in BLOCK.
 408 (defun block-start-cleanup (block)
 409   (node-enclosing-cleanup (block-start-node block)))
 410 (defun block-end-cleanup (block)
 411   (node-enclosing-cleanup (block-last block)))
 412
 413 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 414 ;;; if there is none.
 415 ;;;
 416 ;;; There can legitimately be no home lambda in dead code early in the
 417 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 418 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 419 ;;; where the block is just a placeholder during parsing and doesn't
 420 ;;; actually correspond to code which will be written anywhere.
 421 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 422 (defun block-home-lambda-or-null (block)
 423   (if (node-p (block-last block))
 424       ;; This is the old CMU CL way of doing it.
 425       (node-home-lambda (block-last block))
 426       ;; Now that SBCL uses this operation more aggressively than CMU
 427       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 428       ;;   1. It can fail in a few cases even when a meaningful home
 429       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 430       ;;      an IF.
 431       ;;   2. It can fail when converting a form which is born orphaned
 432       ;;      so that it never had a meaningful home lambda, e.g. a form
 433       ;;      which follows a RETURN-FROM or GO form.
 434       (let ((pred-list (block-pred block)))
 435         ;; To deal with case 1, we reason that
 436         ;; previous-in-target-execution-order blocks should be in the
 437         ;; same lambda, and that they seem in practice to be
 438         ;; previous-in-compilation-order blocks too, so we look back
 439         ;; to find one which is sufficiently initialized to tell us
 440         ;; what the home lambda is.
 441         (if pred-list
 442             ;; We could get fancy about this, flooding through the
 443             ;; graph of all the previous blocks, but in practice it
 444             ;; seems to work just to grab the first previous block and
 445             ;; use it.
 446             (node-home-lambda (block-last (first pred-list)))
 447             ;; In case 2, we end up with an empty PRED-LIST and
 448             ;; have to punt: There's no home lambda.
 449             nil))))
 450
 451 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 452 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 453 (defun block-home-lambda (block)
 454   (block-home-lambda-or-null block))
 455
 456 ;;; Return the IR1 physical environment for BLOCK.
 457 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 458 (defun block-physenv (block)
 459   (lambda-physenv (block-home-lambda block)))
 460
 461 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 462 ;;; of its original source's top level form in its compilation unit.
 463 (defun source-path-tlf-number (path)
 464   (declare (list path))
 465   (car (last path)))
 466
 467 ;;; Return the (reversed) list for the PATH in the original source
 468 ;;; (with the Top Level Form number last).
 469 (defun source-path-original-source (path)
 470   (declare (list path) (inline member))
 471   (cddr (member 'original-source-start path :test #'eq)))
 472
 473 ;;; Return the Form Number of PATH's original source inside the Top
 474 ;;; Level Form that contains it. This is determined by the order that
 475 ;;; we walk the subforms of the top level source form.
 476 (defun source-path-form-number (path)
 477   (declare (list path) (inline member))
 478   (cadr (member 'original-source-start path :test #'eq)))
 479
 480 ;;; Return a list of all the enclosing forms not in the original
 481 ;;; source that converted to get to this form, with the immediate
 482 ;;; source for node at the start of the list.
 483 (defun source-path-forms (path)
 484   (subseq path 0 (position 'original-source-start path)))
 485
 486 ;;; Return the innermost source form for NODE.
 487 (defun node-source-form (node)
 488   (declare (type node node))
 489   (let* ((path (node-source-path node))
 490          (forms (source-path-forms path)))
 491     (if forms
 492         (first forms)
 493         (values (find-original-source path)))))
 494
 495 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 496 ;;; NIL, NIL.
 497 (defun lvar-source (lvar)
 498   (let ((use (lvar-uses lvar)))
 499     (if (listp use)
 500         (values nil nil)
 501         (values (node-source-form use) t))))
 502
 503 ;;; Return the unique node, delivering a value to LVAR.
 504 #!-sb-fluid (declaim (inline lvar-use))
 505 (defun lvar-use (lvar)
 506   (the (not list) (lvar-uses lvar)))
 507
 508 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 509 (defun lvar-has-single-use-p (lvar)
 510   (typep (lvar-uses lvar) '(not list)))
 511
 512 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 513 (declaim (ftype (sfunction (ctran) (or clambda null))
 514                 ctran-home-lambda-or-null))
 515 (defun ctran-home-lambda-or-null (ctran)
 516   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 517   ;; implementation might not be quite right, or might be uglier than
 518   ;; necessary. It appears that the original Python never found a need
 519   ;; to do this operation. The obvious things based on
 520   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 521   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 522   ;; generalize it enough to grovel harder when the simple CMU CL
 523   ;; approach fails, and furthermore realize that in some exceptional
 524   ;; cases it might return NIL. -- WHN 2001-12-04
 525   (cond ((ctran-use ctran)
 526          (node-home-lambda (ctran-use ctran)))
 527         ((ctran-block ctran)
 528          (block-home-lambda-or-null (ctran-block ctran)))
 529         (t
 530          (bug "confused about home lambda for ~S" ctran))))
 531
 532 ;;; Return the LAMBDA that is CTRAN's home.
 533 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 534 (defun ctran-home-lambda (ctran)
 535   (ctran-home-lambda-or-null ctran))
 536
 537 (declaim (inline cast-single-value-p))
 538 (defun cast-single-value-p (cast)
 539   (not (values-type-p (cast-asserted-type cast))))
 540
 541 #!-sb-fluid (declaim (inline lvar-single-value-p))
 542 (defun lvar-single-value-p (lvar)
 543   (or (not lvar)
 544       (let ((dest (lvar-dest lvar)))
 545         (typecase dest
 546           ((or creturn exit)
 547            nil)
 548           (mv-combination
 549            (eq (basic-combination-fun dest) lvar))
 550           (cast
 551            (locally
 552                (declare (notinline lvar-single-value-p))
 553              (and (cast-single-value-p dest)
 554                   (lvar-single-value-p (node-lvar dest)))))
 555           (t
 556            t)))))
 557
 558 (defun principal-lvar-end (lvar)
 559   (loop for prev = lvar then (node-lvar dest)
 560         for dest = (and prev (lvar-dest prev))
 561         while (cast-p dest)
 562         finally (return (values dest prev))))
 563
 564 (defun principal-lvar-single-valuify (lvar)
 565   (loop for prev = lvar then (node-lvar dest)
 566         for dest = (and prev (lvar-dest prev))
 567         while (cast-p dest)
 568         do (setf (node-derived-type dest)
 569                  (make-short-values-type (list (single-value-type
 570                                                 (node-derived-type dest)))))
 571         (reoptimize-lvar prev)))
 572 \f
 573 ;;; Return a new LEXENV just like DEFAULT except for the specified
 574 ;;; slot values. Values for the alist slots are NCONCed to the
 575 ;;; beginning of the current value, rather than replacing it entirely.
 576 (defun make-lexenv (&key (default *lexenv*)
 577                          funs vars blocks tags
 578                          type-restrictions
 579                          (lambda (lexenv-lambda default))
 580                          (cleanup (lexenv-cleanup default))
 581                          (handled-conditions (lexenv-handled-conditions default))
 582                          (disabled-package-locks
 583                           (lexenv-disabled-package-locks default))
 584                          (policy (lexenv-policy default)))
 585   (macrolet ((frob (var slot)
 586                `(let ((old (,slot default)))
 587                   (if ,var
 588                       (nconc ,var old)
 589                       old))))
 590     (internal-make-lexenv
 591      (frob funs lexenv-funs)
 592      (frob vars lexenv-vars)
 593      (frob blocks lexenv-blocks)
 594      (frob tags lexenv-tags)
 595      (frob type-restrictions lexenv-type-restrictions)
 596      lambda cleanup handled-conditions
 597      disabled-package-locks policy)))
 598
 599 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 600 ;;; macroexpander
 601 (defun make-restricted-lexenv (lexenv)
 602   (flet ((fun-good-p (fun)
 603            (destructuring-bind (name . thing) fun
 604              (declare (ignore name))
 605              (etypecase thing
 606                (functional nil)
 607                (global-var t)
 608                (cons (aver (eq (car thing) 'macro))
 609                      t))))
 610          (var-good-p (var)
 611            (destructuring-bind (name . thing) var
 612              (declare (ignore name))
 613              (etypecase thing
 614                (leaf nil)
 615                (cons (aver (eq (car thing) 'macro))
 616                      t)
 617                (heap-alien-info nil)))))
 618     (internal-make-lexenv
 619      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 620      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 621      nil
 622      nil
 623      (lexenv-type-restrictions lexenv) ; XXX
 624      nil
 625      nil
 626      (lexenv-handled-conditions lexenv)
 627      (lexenv-disabled-package-locks lexenv)
 628      (lexenv-policy lexenv))))
 629 \f
 630 ;;;; flow/DFO/component hackery
 631
 632 ;;; Join BLOCK1 and BLOCK2.
 633 (defun link-blocks (block1 block2)
 634   (declare (type cblock block1 block2))
 635   (setf (block-succ block1)
 636         (if (block-succ block1)
 637             (%link-blocks block1 block2)
 638             (list block2)))
 639   (push block1 (block-pred block2))
 640   (values))
 641 (defun %link-blocks (block1 block2)
 642   (declare (type cblock block1 block2))
 643   (let ((succ1 (block-succ block1)))
 644     (aver (not (memq block2 succ1)))
 645     (cons block2 succ1)))
 646
 647 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 648 ;;; this leaves a successor with a single predecessor that ends in an
 649 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 650 ;;; now be able to be propagated to the successor.
 651 (defun unlink-blocks (block1 block2)
 652   (declare (type cblock block1 block2))
 653   (let ((succ1 (block-succ block1)))
 654     (if (eq block2 (car succ1))
 655         (setf (block-succ block1) (cdr succ1))
 656         (do ((succ (cdr succ1) (cdr succ))
 657              (prev succ1 succ))
 658             ((eq (car succ) block2)
 659              (setf (cdr prev) (cdr succ)))
 660           (aver succ))))
 661
 662   (let ((new-pred (delq block1 (block-pred block2))))
 663     (setf (block-pred block2) new-pred)
 664     (when (singleton-p new-pred)
 665       (let ((pred-block (first new-pred)))
 666         (when (if-p (block-last pred-block))
 667           (setf (block-test-modified pred-block) t)))))
 668   (values))
 669
 670 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 671 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 672 ;;; consequent/alternative blocks to point to NEW. We also set
 673 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 674 ;;; the new successor.
 675 (defun change-block-successor (block old new)
 676   (declare (type cblock new old block))
 677   (unlink-blocks block old)
 678   (let ((last (block-last block))
 679         (comp (block-component block)))
 680     (setf (component-reanalyze comp) t)
 681     (typecase last
 682       (cif
 683        (setf (block-test-modified block) t)
 684        (let* ((succ-left (block-succ block))
 685               (new (if (and (eq new (component-tail comp))
 686                             succ-left)
 687                        (first succ-left)
 688                        new)))
 689          (unless (memq new succ-left)
 690            (link-blocks block new))
 691          (macrolet ((frob (slot)
 692                       `(when (eq (,slot last) old)
 693                          (setf (,slot last) new))))
 694            (frob if-consequent)
 695            (frob if-alternative)
 696            (when (eq (if-consequent last)
 697                      (if-alternative last))
 698              (reoptimize-component (block-component block) :maybe)))))
 699       (t
 700        (unless (memq new (block-succ block))
 701          (link-blocks block new)))))
 702
 703   (values))
 704
 705 ;;; Unlink a block from the next/prev chain. We also null out the
 706 ;;; COMPONENT.
 707 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 708 (defun remove-from-dfo (block)
 709   (let ((next (block-next block))
 710         (prev (block-prev block)))
 711     (setf (block-component block) nil)
 712     (setf (block-next prev) next)
 713     (setf (block-prev next) prev))
 714   (values))
 715
 716 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 717 ;;; COMPONENT to be the same as for AFTER.
 718 (defun add-to-dfo (block after)
 719   (declare (type cblock block after))
 720   (let ((next (block-next after))
 721         (comp (block-component after)))
 722     (aver (not (eq (component-kind comp) :deleted)))
 723     (setf (block-component block) comp)
 724     (setf (block-next after) block)
 725     (setf (block-prev block) after)
 726     (setf (block-next block) next)
 727     (setf (block-prev next) block))
 728   (values))
 729
 730 ;;; List all NLX-INFOs which BLOCK can exit to.
 731 ;;;
 732 ;;; We hope that no cleanup actions are performed in the middle of
 733 ;;; BLOCK, so it is enough to look only at cleanups in the block
 734 ;;; end. The tricky thing is a special cleanup block; all its nodes
 735 ;;; have the same cleanup info, corresponding to the start, so the
 736 ;;; same approach returns safe result.
 737 (defun map-block-nlxes (fun block &optional dx-cleanup-fun)
 738   (loop for cleanup = (block-end-cleanup block)
 739         then (node-enclosing-cleanup (cleanup-mess-up cleanup))
 740         while cleanup
 741         do (let ((mess-up (cleanup-mess-up cleanup)))
 742              (case (cleanup-kind cleanup)
 743                ((:block :tagbody)
 744                 (aver (entry-p mess-up))
 745                 (loop for exit in (entry-exits mess-up)
 746                       for nlx-info = (exit-nlx-info exit)
 747                       do (funcall fun nlx-info)))
 748                ((:catch :unwind-protect)
 749                 (aver (combination-p mess-up))
 750                 (let* ((arg-lvar (first (basic-combination-args mess-up)))
 751                        (nlx-info (constant-value (ref-leaf (lvar-use arg-lvar)))))
 752                 (funcall fun nlx-info)))
 753                ((:dynamic-extent)
 754                 (when dx-cleanup-fun
 755                   (funcall dx-cleanup-fun cleanup)))))))
 756
 757 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 758 ;;; the head and tail which are set to T.
 759 (declaim (ftype (sfunction (component) (values)) clear-flags))
 760 (defun clear-flags (component)
 761   (let ((head (component-head component))
 762         (tail (component-tail component)))
 763     (setf (block-flag head) t)
 764     (setf (block-flag tail) t)
 765     (do-blocks (block component)
 766       (setf (block-flag block) nil)))
 767   (values))
 768
 769 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 770 ;;; true in the head and tail blocks.
 771 (declaim (ftype (sfunction () component) make-empty-component))
 772 (defun make-empty-component ()
 773   (let* ((head (make-block-key :start nil :component nil))
 774          (tail (make-block-key :start nil :component nil))
 775          (res (make-component head tail)))
 776     (setf (block-flag head) t)
 777     (setf (block-flag tail) t)
 778     (setf (block-component head) res)
 779     (setf (block-component tail) res)
 780     (setf (block-next head) tail)
 781     (setf (block-prev tail) head)
 782     res))
 783
 784 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 785 ;;; The new block is added to the DFO immediately following NODE's block.
 786 (defun node-ends-block (node)
 787   (declare (type node node))
 788   (let* ((block (node-block node))
 789          (start (node-next node))
 790          (last (block-last block)))
 791     (unless (eq last node)
 792       (aver (and (eq (ctran-kind start) :inside-block)
 793                  (not (block-delete-p block))))
 794       (let* ((succ (block-succ block))
 795              (new-block
 796               (make-block-key :start start
 797                               :component (block-component block)
 798                               :succ succ :last last)))
 799         (setf (ctran-kind start) :block-start)
 800         (setf (ctran-use start) nil)
 801         (setf (block-last block) node)
 802         (setf (node-next node) nil)
 803         (dolist (b succ)
 804           (setf (block-pred b)
 805                 (cons new-block (remove block (block-pred b)))))
 806         (setf (block-succ block) ())
 807         (link-blocks block new-block)
 808         (add-to-dfo new-block block)
 809         (setf (component-reanalyze (block-component block)) t)
 810
 811         (do ((ctran start (node-next (ctran-next ctran))))
 812             ((not ctran))
 813           (setf (ctran-block ctran) new-block))
 814
 815         (setf (block-type-asserted block) t)
 816         (setf (block-test-modified block) t))))
 817   (values))
 818 \f
 819 ;;;; deleting stuff
 820
 821 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 822 (defun delete-lambda-var (leaf)
 823   (declare (type lambda-var leaf))
 824
 825   ;; Iterate over all local calls flushing the corresponding argument,
 826   ;; allowing the computation of the argument to be deleted. We also
 827   ;; mark the LET for reoptimization, since it may be that we have
 828   ;; deleted its last variable.
 829   (let* ((fun (lambda-var-home leaf))
 830          (n (position leaf (lambda-vars fun))))
 831     (dolist (ref (leaf-refs fun))
 832       (let* ((lvar (node-lvar ref))
 833              (dest (and lvar (lvar-dest lvar))))
 834         (when (and (combination-p dest)
 835                    (eq (basic-combination-fun dest) lvar)
 836                    (eq (basic-combination-kind dest) :local))
 837           (let* ((args (basic-combination-args dest))
 838                  (arg (elt args n)))
 839             (reoptimize-lvar arg)
 840             (flush-dest arg)
 841             (setf (elt args n) nil))))))
 842
 843   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 844   ;; too much difficulty, since we can efficiently implement
 845   ;; write-only variables. We iterate over the SETs, marking their
 846   ;; blocks for dead code flushing, since we can delete SETs whose
 847   ;; value is unused.
 848   (dolist (set (lambda-var-sets leaf))
 849     (setf (block-flush-p (node-block set)) t))
 850
 851   (values))
 852
 853 ;;; Note that something interesting has happened to VAR.
 854 (defun reoptimize-lambda-var (var)
 855   (declare (type lambda-var var))
 856   (let ((fun (lambda-var-home var)))
 857     ;; We only deal with LET variables, marking the corresponding
 858     ;; initial value arg as needing to be reoptimized.
 859     (when (and (eq (functional-kind fun) :let)
 860                (leaf-refs var))
 861       (do ((args (basic-combination-args
 862                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 863                  (cdr args))
 864            (vars (lambda-vars fun) (cdr vars)))
 865           ((eq (car vars) var)
 866            (reoptimize-lvar (car args))))))
 867   (values))
 868
 869 ;;; Delete a function that has no references. This need only be called
 870 ;;; on functions that never had any references, since otherwise
 871 ;;; DELETE-REF will handle the deletion.
 872 (defun delete-functional (fun)
 873   (aver (and (null (leaf-refs fun))
 874              (not (functional-entry-fun fun))))
 875   (etypecase fun
 876     (optional-dispatch (delete-optional-dispatch fun))
 877     (clambda (delete-lambda fun)))
 878   (values))
 879
 880 ;;; Deal with deleting the last reference to a CLAMBDA, which means
 881 ;;; that the lambda is unreachable, so that its body may be
 882 ;;; deleted. We set FUNCTIONAL-KIND to :DELETED and rely on
 883 ;;; IR1-OPTIMIZE to delete its blocks.
 884 (defun delete-lambda (clambda)
 885   (declare (type clambda clambda))
 886   (let ((original-kind (functional-kind clambda))
 887         (bind (lambda-bind clambda)))
 888     (aver (not (member original-kind '(:deleted :toplevel))))
 889     (aver (not (functional-has-external-references-p clambda)))
 890     (aver (or (eq original-kind :zombie) bind))
 891     (setf (functional-kind clambda) :deleted)
 892     (setf (lambda-bind clambda) nil)
 893
 894     (labels ((delete-children (lambda)
 895                (dolist (child (lambda-children lambda))
 896                  (cond ((eq (functional-kind child) :deleted)
 897                         (delete-children child))
 898                        (t
 899                         (delete-lambda child))))
 900                (setf (lambda-children lambda) nil)
 901                (setf (lambda-parent lambda) nil)))
 902       (delete-children clambda))
 903
 904     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 905     ;; that we're using the old value of the KIND slot, not the
 906     ;; current slot value, which has now been set to :DELETED.)
 907     (case original-kind
 908       (:zombie)
 909       ((:let :mv-let :assignment)
 910        (let ((bind-block (node-block bind)))
 911          (mark-for-deletion bind-block))
 912        (let ((home (lambda-home clambda)))
 913          (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 914        ;; KLUDGE: In presence of NLEs we cannot always understand that
 915        ;; LET's BIND dominates its body [for a LET "its" body is not
 916        ;; quite its]; let's delete too dangerous for IR2 stuff. --
 917        ;; APD, 2004-01-01
 918        (dolist (var (lambda-vars clambda))
 919          (flet ((delete-node (node)
 920                   (mark-for-deletion (node-block node))))
 921          (mapc #'delete-node (leaf-refs var))
 922          (mapc #'delete-node (lambda-var-sets var)))))
 923       (t
 924        ;; Function has no reachable references.
 925        (dolist (ref (lambda-refs clambda))
 926          (mark-for-deletion (node-block ref)))
 927        ;; If the function isn't a LET, we unlink the function head
 928        ;; and tail from the component head and tail to indicate that
 929        ;; the code is unreachable. We also delete the function from
 930        ;; COMPONENT-LAMBDAS (it won't be there before local call
 931        ;; analysis, but no matter.) If the lambda was never
 932        ;; referenced, we give a note.
 933        (let* ((bind-block (node-block bind))
 934               (component (block-component bind-block))
 935               (return (lambda-return clambda))
 936               (return-block (and return (node-block return))))
 937          (unless (leaf-ever-used clambda)
 938            (let ((*compiler-error-context* bind))
 939              (compiler-notify 'code-deletion-note
 940                               :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 941                               :format-arguments (list (leaf-debug-name clambda)))))
 942          (unless (block-delete-p bind-block)
 943            (unlink-blocks (component-head component) bind-block))
 944          (when (and return-block (not (block-delete-p return-block)))
 945            (mark-for-deletion return-block)
 946            (unlink-blocks return-block (component-tail component)))
 947          (setf (component-reanalyze component) t)
 948          (let ((tails (lambda-tail-set clambda)))
 949            (setf (tail-set-funs tails)
 950                  (delete clambda (tail-set-funs tails)))
 951            (setf (lambda-tail-set clambda) nil))
 952          (setf (component-lambdas component)
 953                (delq clambda (component-lambdas component))))))
 954
 955     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 956     ;; ENTRY-FUN so that people will know that it is not an entry
 957     ;; point anymore.
 958     (when (eq original-kind :external)
 959       (let ((fun (functional-entry-fun clambda)))
 960         (setf (functional-entry-fun fun) nil)
 961         (when (optional-dispatch-p fun)
 962           (delete-optional-dispatch fun)))))
 963
 964   (values))
 965
 966 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 967 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 968 ;;; is used both before and after local call analysis. Afterward, all
 969 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 970 ;;; to the XEP, leaving it with no references at all. So we look at
 971 ;;; the XEP to see whether an optional-dispatch is still really being
 972 ;;; used. But before local call analysis, there are no XEPs, and all
 973 ;;; references are direct.
 974 ;;;
 975 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 976 ;;; entry-points, making them be normal lambdas, and then deleting the
 977 ;;; ones with no references. This deletes any e-p lambdas that were
 978 ;;; either never referenced, or couldn't be deleted when the last
 979 ;;; reference was deleted (due to their :OPTIONAL kind.)
 980 ;;;
 981 ;;; Note that the last optional entry point may alias the main entry,
 982 ;;; so when we process the main entry, its KIND may have been changed
 983 ;;; to NIL or even converted to a LETlike value.
 984 (defun delete-optional-dispatch (leaf)
 985   (declare (type optional-dispatch leaf))
 986   (let ((entry (functional-entry-fun leaf)))
 987     (unless (and entry (leaf-refs entry))
 988       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 989       (setf (functional-kind leaf) :deleted)
 990
 991       (flet ((frob (fun)
 992                (unless (eq (functional-kind fun) :deleted)
 993                  (aver (eq (functional-kind fun) :optional))
 994                  (setf (functional-kind fun) nil)
 995                  (let ((refs (leaf-refs fun)))
 996                    (cond ((null refs)
 997                           (delete-lambda fun))
 998                          ((null (rest refs))
 999                           (or (maybe-let-convert fun)
1000                               (maybe-convert-to-assignment fun)))
1001                          (t
1002                           (maybe-convert-to-assignment fun)))))))
1003
1004         (dolist (ep (optional-dispatch-entry-points leaf))
1005           (when (promise-ready-p ep)
1006             (frob (force ep))))
1007         (when (optional-dispatch-more-entry leaf)
1008           (frob (optional-dispatch-more-entry leaf)))
1009         (let ((main (optional-dispatch-main-entry leaf)))
1010           (when entry
1011             (setf (functional-entry-fun entry) main)
1012             (setf (functional-entry-fun main) entry))
1013           (when (eq (functional-kind main) :optional)
1014             (frob main))))))
1015
1016   (values))
1017
1018 ;;; Do stuff to delete the semantic attachments of a REF node. When
1019 ;;; this leaves zero or one reference, we do a type dispatch off of
1020 ;;; the leaf to determine if a special action is appropriate.
1021 (defun delete-ref (ref)
1022   (declare (type ref ref))
1023   (let* ((leaf (ref-leaf ref))
1024          (refs (delq ref (leaf-refs leaf))))
1025     (setf (leaf-refs leaf) refs)
1026
1027     (cond ((null refs)
1028            (typecase leaf
1029              (lambda-var
1030               (delete-lambda-var leaf))
1031              (clambda
1032               (ecase (functional-kind leaf)
1033                 ((nil :let :mv-let :assignment :escape :cleanup)
1034                  (aver (null (functional-entry-fun leaf)))
1035                  (delete-lambda leaf))
1036                 (:external
1037                  (delete-lambda leaf))
1038                 ((:deleted :zombie :optional))))
1039              (optional-dispatch
1040               (unless (eq (functional-kind leaf) :deleted)
1041                 (delete-optional-dispatch leaf)))))
1042           ((null (rest refs))
1043            (typecase leaf
1044              (clambda (or (maybe-let-convert leaf)
1045                           (maybe-convert-to-assignment leaf)))
1046              (lambda-var (reoptimize-lambda-var leaf))))
1047           (t
1048            (typecase leaf
1049              (clambda (maybe-convert-to-assignment leaf))))))
1050
1051   (values))
1052
1053 ;;; This function is called by people who delete nodes; it provides a
1054 ;;; way to indicate that the value of a lvar is no longer used. We
1055 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
1056 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
1057 (defun flush-dest (lvar)
1058   (declare (type (or lvar null) lvar))
1059   (unless (null lvar)
1060     (setf (lvar-dest lvar) nil)
1061     (flush-lvar-externally-checkable-type lvar)
1062     (do-uses (use lvar)
1063       (let ((prev (node-prev use)))
1064         (let ((block (ctran-block prev)))
1065           (reoptimize-component (block-component block) t)
1066           (setf (block-attributep (block-flags block)
1067                                   flush-p type-asserted type-check)
1068                 t)))
1069       (setf (node-lvar use) nil))
1070     (setf (lvar-uses lvar) nil))
1071   (values))
1072
1073 (defun delete-dest (lvar)
1074   (when lvar
1075     (let* ((dest (lvar-dest lvar))
1076            (prev (node-prev dest)))
1077       (let ((block (ctran-block prev)))
1078         (unless (block-delete-p block)
1079           (mark-for-deletion block))))))
1080
1081 ;;; Queue the block for deletion
1082 (defun delete-block-lazily (block)
1083   (declare (type cblock block))
1084   (unless (block-delete-p block)
1085     (setf (block-delete-p block) t)
1086     (push block (component-delete-blocks (block-component block)))))
1087
1088 ;;; Do a graph walk backward from BLOCK, marking all predecessor
1089 ;;; blocks with the DELETE-P flag.
1090 (defun mark-for-deletion (block)
1091   (declare (type cblock block))
1092   (let* ((component (block-component block))
1093          (head (component-head component)))
1094     (labels ((helper (block)
1095                (delete-block-lazily block)
1096                (dolist (pred (block-pred block))
1097                  (unless (or (block-delete-p pred)
1098                              (eq pred head))
1099                    (helper pred)))))
1100       (unless (block-delete-p block)
1101         (helper block)
1102         (setf (component-reanalyze component) t))))
1103   (values))
1104
1105 ;;; This function does what is necessary to eliminate the code in it
1106 ;;; from the IR1 representation. This involves unlinking it from its
1107 ;;; predecessors and successors and deleting various node-specific
1108 ;;; semantic information. BLOCK must be already removed from
1109 ;;; COMPONENT-DELETE-BLOCKS.
1110 (defun delete-block (block &optional silent)
1111   (declare (type cblock block))
1112   (aver (block-component block))      ; else block is already deleted!
1113   #!+high-security (aver (not (memq block (component-delete-blocks (block-component block)))))
1114   (unless silent
1115     (note-block-deletion block))
1116   (setf (block-delete-p block) t)
1117
1118   (dolist (b (block-pred block))
1119     (unlink-blocks b block)
1120     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
1121     ;; broken when successors were deleted without setting the
1122     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
1123     ;; doesn't happen again.
1124     (aver (not (and (null (block-succ b))
1125                     (not (block-delete-p b))
1126                     (not (eq b (component-head (block-component b))))))))
1127   (dolist (b (block-succ block))
1128     (unlink-blocks block b))
1129
1130   (do-nodes-carefully (node block)
1131     (when (valued-node-p node)
1132       (delete-lvar-use node))
1133     (etypecase node
1134       (ref (delete-ref node))
1135       (cif (flush-dest (if-test node)))
1136       ;; The next two cases serve to maintain the invariant that a LET
1137       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1138       ;; the lambda whenever we delete any of these, but we must be
1139       ;; careful that this LET has not already been partially deleted.
1140       (basic-combination
1141        (when (and (eq (basic-combination-kind node) :local)
1142                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1143                   (lvar-uses (basic-combination-fun node)))
1144          (let ((fun (combination-lambda node)))
1145            ;; If our REF was the second-to-last ref, and has been
1146            ;; deleted, then FUN may be a LET for some other
1147            ;; combination.
1148            (when (and (functional-letlike-p fun)
1149                       (eq (let-combination fun) node))
1150              (delete-lambda fun))))
1151        (flush-dest (basic-combination-fun node))
1152        (dolist (arg (basic-combination-args node))
1153          (when arg (flush-dest arg))))
1154       (bind
1155        (let ((lambda (bind-lambda node)))
1156          (unless (eq (functional-kind lambda) :deleted)
1157            (delete-lambda lambda))))
1158       (exit
1159        (let ((value (exit-value node))
1160              (entry (exit-entry node)))
1161          (when value
1162            (flush-dest value))
1163          (when entry
1164            (setf (entry-exits entry)
1165                  (delq node (entry-exits entry))))))
1166       (entry
1167        (dolist (exit (entry-exits node))
1168          (mark-for-deletion (node-block exit)))
1169        (let ((home (node-home-lambda node)))
1170          (setf (lambda-entries home) (delq node (lambda-entries home)))))
1171       (creturn
1172        (flush-dest (return-result node))
1173        (delete-return node))
1174       (cset
1175        (flush-dest (set-value node))
1176        (let ((var (set-var node)))
1177          (setf (basic-var-sets var)
1178                (delete node (basic-var-sets var)))))
1179       (cast
1180        (flush-dest (cast-value node)))))
1181
1182   (remove-from-dfo block)
1183   (values))
1184
1185 ;;; Do stuff to indicate that the return node NODE is being deleted.
1186 (defun delete-return (node)
1187   (declare (type creturn node))
1188   (let* ((fun (return-lambda node))
1189          (tail-set (lambda-tail-set fun)))
1190     (aver (lambda-return fun))
1191     (setf (lambda-return fun) nil)
1192     (when (and tail-set (not (find-if #'lambda-return
1193                                       (tail-set-funs tail-set))))
1194       (setf (tail-set-type tail-set) *empty-type*)))
1195   (values))
1196
1197 ;;; If any of the VARS in FUN was never referenced and was not
1198 ;;; declared IGNORE, then complain.
1199 (defun note-unreferenced-vars (fun)
1200   (declare (type clambda fun))
1201   (dolist (var (lambda-vars fun))
1202     (unless (or (leaf-ever-used var)
1203                 (lambda-var-ignorep var))
1204       (let ((*compiler-error-context* (lambda-bind fun)))
1205         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1206           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1207           ;; requires this to be no more than a STYLE-WARNING.
1208           #-sb-xc-host
1209           (compiler-style-warn "The variable ~S is defined but never used."
1210                                (leaf-debug-name var))
1211           ;; There's no reason to accept this kind of equivocation
1212           ;; when compiling our own code, though.
1213           #+sb-xc-host
1214           (warn "The variable ~S is defined but never used."
1215                 (leaf-debug-name var)))
1216         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1217   (values))
1218
1219 (defvar *deletion-ignored-objects* '(t nil))
1220
1221 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1222 ;;; our recursion so that we don't get lost in circular structures. We
1223 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1224 ;;; function referencess with variables), and we also ignore anything
1225 ;;; inside ' or #'.
1226 (defun present-in-form (obj form depth)
1227   (declare (type (integer 0 20) depth))
1228   (cond ((= depth 20) nil)
1229         ((eq obj form) t)
1230         ((atom form) nil)
1231         (t
1232          (let ((first (car form))
1233                (depth (1+ depth)))
1234            (if (member first '(quote function))
1235                nil
1236                (or (and (not (symbolp first))
1237                         (present-in-form obj first depth))
1238                    (do ((l (cdr form) (cdr l))
1239                         (n 0 (1+ n)))
1240                        ((or (atom l) (> n 100))
1241                         nil)
1242                      (declare (fixnum n))
1243                      (when (present-in-form obj (car l) depth)
1244                        (return t)))))))))
1245
1246 ;;; This function is called on a block immediately before we delete
1247 ;;; it. We check to see whether any of the code about to die appeared
1248 ;;; in the original source, and emit a note if so.
1249 ;;;
1250 ;;; If the block was in a lambda is now deleted, then we ignore the
1251 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1252 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1253 ;;; reasonable for a function to not return, and there is a different
1254 ;;; note for that case anyway.
1255 ;;;
1256 ;;; If the actual source is an atom, then we use a bunch of heuristics
1257 ;;; to guess whether this reference really appeared in the original
1258 ;;; source:
1259 ;;; -- If a symbol, it must be interned and not a keyword.
1260 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1261 ;;;    or a character.)
1262 ;;; -- The atom must be "present" in the original source form, and
1263 ;;;    present in all intervening actual source forms.
1264 (defun note-block-deletion (block)
1265   (let ((home (block-home-lambda block)))
1266     (unless (eq (functional-kind home) :deleted)
1267       (do-nodes (node nil block)
1268         (let* ((path (node-source-path node))
1269                (first (first path)))
1270           (when (or (eq first 'original-source-start)
1271                     (and (atom first)
1272                          (or (not (symbolp first))
1273                              (let ((pkg (symbol-package first)))
1274                                (and pkg
1275                                     (not (eq pkg (symbol-package :end))))))
1276                          (not (member first *deletion-ignored-objects*))
1277                          (not (typep first '(or fixnum character)))
1278                          (every (lambda (x)
1279                                   (present-in-form first x 0))
1280                                 (source-path-forms path))
1281                          (present-in-form first (find-original-source path)
1282                                           0)))
1283             (unless (return-p node)
1284               (let ((*compiler-error-context* node))
1285                 (compiler-notify 'code-deletion-note
1286                                  :format-control "deleting unreachable code"
1287                                  :format-arguments nil)))
1288             (return))))))
1289   (values))
1290
1291 ;;; Delete a node from a block, deleting the block if there are no
1292 ;;; nodes left. We remove the node from the uses of its LVAR.
1293 ;;;
1294 ;;; If the node is the last node, there must be exactly one successor.
1295 ;;; We link all of our precedessors to the successor and unlink the
1296 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1297 ;;; left, and the block is a successor of itself, then we replace the
1298 ;;; only node with a degenerate exit node. This provides a way to
1299 ;;; represent the bodyless infinite loop, given the prohibition on
1300 ;;; empty blocks in IR1.
1301 (defun unlink-node (node)
1302   (declare (type node node))
1303   (when (valued-node-p node)
1304     (delete-lvar-use node))
1305
1306   (let* ((ctran (node-next node))
1307          (next (and ctran (ctran-next ctran)))
1308          (prev (node-prev node))
1309          (block (ctran-block prev))
1310          (prev-kind (ctran-kind prev))
1311          (last (block-last block)))
1312
1313     (setf (block-type-asserted block) t)
1314     (setf (block-test-modified block) t)
1315
1316     (cond ((or (eq prev-kind :inside-block)
1317                (and (eq prev-kind :block-start)
1318                     (not (eq node last))))
1319            (cond ((eq node last)
1320                   (setf (block-last block) (ctran-use prev))
1321                   (setf (node-next (ctran-use prev)) nil))
1322                  (t
1323                   (setf (ctran-next prev) next)
1324                   (setf (node-prev next) prev)
1325                   (when (if-p next) ; AOP wanted
1326                     (reoptimize-lvar (if-test next)))))
1327            (setf (node-prev node) nil)
1328            nil)
1329           (t
1330            (aver (eq prev-kind :block-start))
1331            (aver (eq node last))
1332            (let* ((succ (block-succ block))
1333                   (next (first succ)))
1334              (aver (singleton-p succ))
1335              (cond
1336               ((eq block (first succ))
1337                (with-ir1-environment-from-node node
1338                  (let ((exit (make-exit)))
1339                    (setf (ctran-next prev) nil)
1340                    (link-node-to-previous-ctran exit prev)
1341                    (setf (block-last block) exit)))
1342                (setf (node-prev node) nil)
1343                nil)
1344               (t
1345                (aver (eq (block-start-cleanup block)
1346                          (block-end-cleanup block)))
1347                (unlink-blocks block next)
1348                (dolist (pred (block-pred block))
1349                  (change-block-successor pred block next))
1350                (when (block-delete-p block)
1351                  (let ((component (block-component block)))
1352                    (setf (component-delete-blocks component)
1353                          (delq block (component-delete-blocks component)))))
1354                (remove-from-dfo block)
1355                (setf (block-delete-p block) t)
1356                (setf (node-prev node) nil)
1357                t)))))))
1358
1359 ;;; Return true if CTRAN has been deleted, false if it is still a valid
1360 ;;; part of IR1.
1361 (defun ctran-deleted-p (ctran)
1362   (declare (type ctran ctran))
1363   (let ((block (ctran-block ctran)))
1364     (or (not (block-component block))
1365         (block-delete-p block))))
1366
1367 ;;; Return true if NODE has been deleted, false if it is still a valid
1368 ;;; part of IR1.
1369 (defun node-deleted (node)
1370   (declare (type node node))
1371   (let ((prev (node-prev node)))
1372     (or (not prev)
1373         (ctran-deleted-p prev))))
1374
1375 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1376 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1377 ;;; triggered by deletion.
1378 (defun delete-component (component)
1379   (declare (type component component))
1380   (aver (null (component-new-functionals component)))
1381   (setf (component-kind component) :deleted)
1382   (do-blocks (block component)
1383     (delete-block-lazily block))
1384   (dolist (fun (component-lambdas component))
1385     (unless (eq (functional-kind fun) :deleted)
1386       (setf (functional-kind fun) nil)
1387       (setf (functional-entry-fun fun) nil)
1388       (setf (leaf-refs fun) nil)
1389       (delete-functional fun)))
1390   (clean-component component)
1391   (values))
1392
1393 ;;; Remove all pending blocks to be deleted. Return the nearest live
1394 ;;; block after or equal to BLOCK.
1395 (defun clean-component (component &optional block)
1396   (loop while (component-delete-blocks component)
1397         ;; actual deletion of a block may queue new blocks
1398         do (let ((current (pop (component-delete-blocks component))))
1399              (when (eq block current)
1400                (setq block (block-next block)))
1401              (delete-block current)))
1402   block)
1403
1404 ;;; Convert code of the form
1405 ;;;   (FOO ... (FUN ...) ...)
1406 ;;; to
1407 ;;;   (FOO ...    ...    ...).
1408 ;;; In other words, replace the function combination FUN by its
1409 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1410 ;;; to blow out of whatever transform called this. Note, as the number
1411 ;;; of arguments changes, the transform must be prepared to return a
1412 ;;; lambda with a new lambda-list with the correct number of
1413 ;;; arguments.
1414 (defun extract-fun-args (lvar fun num-args)
1415   #!+sb-doc
1416   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1417    to feed directly to the LVAR-DEST of LVAR, which must be a
1418    combination."
1419   (declare (type lvar lvar)
1420            (type symbol fun)
1421            (type index num-args))
1422   (let ((outside (lvar-dest lvar))
1423         (inside (lvar-uses lvar)))
1424     (aver (combination-p outside))
1425     (unless (combination-p inside)
1426       (give-up-ir1-transform))
1427     (let ((inside-fun (combination-fun inside)))
1428       (unless (eq (lvar-fun-name inside-fun) fun)
1429         (give-up-ir1-transform))
1430       (let ((inside-args (combination-args inside)))
1431         (unless (= (length inside-args) num-args)
1432           (give-up-ir1-transform))
1433         (let* ((outside-args (combination-args outside))
1434                (arg-position (position lvar outside-args))
1435                (before-args (subseq outside-args 0 arg-position))
1436                (after-args (subseq outside-args (1+ arg-position))))
1437           (dolist (arg inside-args)
1438             (setf (lvar-dest arg) outside)
1439             (flush-lvar-externally-checkable-type arg))
1440           (setf (combination-args inside) nil)
1441           (setf (combination-args outside)
1442                 (append before-args inside-args after-args))
1443           (change-ref-leaf (lvar-uses inside-fun)
1444                            (find-free-fun 'list "???"))
1445           (setf (combination-fun-info inside) (info :function :info 'list)
1446                 (combination-kind inside) :known)
1447           (setf (node-derived-type inside) *wild-type*)
1448           (flush-dest lvar)
1449           (values))))))
1450
1451 (defun flush-combination (combination)
1452   (declare (type combination combination))
1453   (flush-dest (combination-fun combination))
1454   (dolist (arg (combination-args combination))
1455     (flush-dest arg))
1456   (unlink-node combination)
1457   (values))
1458
1459 \f
1460 ;;;; leaf hackery
1461
1462 ;;; Change the LEAF that a REF refers to.
1463 (defun change-ref-leaf (ref leaf)
1464   (declare (type ref ref) (type leaf leaf))
1465   (unless (eq (ref-leaf ref) leaf)
1466     (push ref (leaf-refs leaf))
1467     (delete-ref ref)
1468     (setf (ref-leaf ref) leaf)
1469     (setf (leaf-ever-used leaf) t)
1470     (let* ((ltype (leaf-type leaf))
1471            (vltype (make-single-value-type ltype)))
1472       (if (let* ((lvar (node-lvar ref))
1473                  (dest (and lvar (lvar-dest lvar))))
1474             (and (basic-combination-p dest)
1475                  (eq lvar (basic-combination-fun dest))
1476                  (csubtypep ltype (specifier-type 'function))))
1477           (setf (node-derived-type ref) vltype)
1478           (derive-node-type ref vltype)))
1479     (reoptimize-lvar (node-lvar ref)))
1480   (values))
1481
1482 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1483 (defun substitute-leaf (new-leaf old-leaf)
1484   (declare (type leaf new-leaf old-leaf))
1485   (dolist (ref (leaf-refs old-leaf))
1486     (change-ref-leaf ref new-leaf))
1487   (values))
1488
1489 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1490 ;;; whether to substitute
1491 (defun substitute-leaf-if (test new-leaf old-leaf)
1492   (declare (type leaf new-leaf old-leaf) (type function test))
1493   (dolist (ref (leaf-refs old-leaf))
1494     (when (funcall test ref)
1495       (change-ref-leaf ref new-leaf)))
1496   (values))
1497
1498 ;;; Return a LEAF which represents the specified constant object. If
1499 ;;; the object is not in *CONSTANTS*, then we create a new constant
1500 ;;; LEAF and enter it.
1501 (defun find-constant (object)
1502   (if (typep object
1503              ;; FIXME: What is the significance of this test? ("things
1504              ;; that are worth uniquifying"?)
1505              '(or symbol number character instance))
1506       (or (gethash object *constants*)
1507           (setf (gethash object *constants*)
1508                 (make-constant :value object
1509                                :%source-name '.anonymous.
1510                                :type (ctype-of object)
1511                                :where-from :defined)))
1512       (make-constant :value object
1513                      :%source-name '.anonymous.
1514                      :type (ctype-of object)
1515                      :where-from :defined)))
1516 \f
1517 ;;; Return true if VAR would have to be closed over if environment
1518 ;;; analysis ran now (i.e. if there are any uses that have a different
1519 ;;; home lambda than VAR's home.)
1520 (defun closure-var-p (var)
1521   (declare (type lambda-var var))
1522   (let ((home (lambda-var-home var)))
1523     (cond ((eq (functional-kind home) :deleted)
1524            nil)
1525           (t (let ((home (lambda-home home)))
1526                (flet ((frob (l)
1527                         (find home l
1528                               :key #'node-home-lambda
1529                               :test #'neq)))
1530                  (or (frob (leaf-refs var))
1531                      (frob (basic-var-sets var)))))))))
1532
1533 ;;; If there is a non-local exit noted in ENTRY's environment that
1534 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1535 (defun find-nlx-info (exit)
1536   (declare (type exit exit))
1537   (let* ((entry (exit-entry exit))
1538          (cleanup (entry-cleanup entry))
1539         (block (first (block-succ (node-block exit)))))
1540     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1541       (when (and (eq (nlx-info-block nlx) block)
1542                  (eq (nlx-info-cleanup nlx) cleanup))
1543         (return nlx)))))
1544
1545 (defun nlx-info-lvar (nlx)
1546   (declare (type nlx-info nlx))
1547   (node-lvar (block-last (nlx-info-target nlx))))
1548 \f
1549 ;;;; functional hackery
1550
1551 (declaim (ftype (sfunction (functional) clambda) main-entry))
1552 (defun main-entry (functional)
1553   (etypecase functional
1554     (clambda functional)
1555     (optional-dispatch
1556      (optional-dispatch-main-entry functional))))
1557
1558 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1559 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1560 ;;; optional with null default and no SUPPLIED-P. There must be a
1561 ;;; &REST arg with no references.
1562 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1563 (defun looks-like-an-mv-bind (functional)
1564   (and (optional-dispatch-p functional)
1565        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1566            ((null arg) nil)
1567          (let ((info (lambda-var-arg-info (car arg))))
1568            (unless info (return nil))
1569            (case (arg-info-kind info)
1570              (:optional
1571               (when (or (arg-info-supplied-p info) (arg-info-default info))
1572                 (return nil)))
1573              (:rest
1574               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1575              (t
1576               (return nil)))))))
1577
1578 ;;; Return true if function is an external entry point. This is true
1579 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1580 ;;; (:TOPLEVEL kind.)
1581 (defun xep-p (fun)
1582   (declare (type functional fun))
1583   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1584
1585 ;;; If LVAR's only use is a non-notinline global function reference,
1586 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1587 ;;; is true, then we don't care if the leaf is NOTINLINE.
1588 (defun lvar-fun-name (lvar &optional notinline-ok)
1589   (declare (type lvar lvar))
1590   (let ((use (lvar-uses lvar)))
1591     (if (ref-p use)
1592         (let ((leaf (ref-leaf use)))
1593           (if (and (global-var-p leaf)
1594                    (eq (global-var-kind leaf) :global-function)
1595                    (or (not (defined-fun-p leaf))
1596                        (not (eq (defined-fun-inlinep leaf) :notinline))
1597                        notinline-ok))
1598               (leaf-source-name leaf)
1599               nil))
1600         nil)))
1601
1602 ;;; Return the source name of a combination. (This is an idiom
1603 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1604 (defun combination-fun-source-name (combination)
1605   (let ((ref (lvar-uses (combination-fun combination))))
1606     (leaf-source-name (ref-leaf ref))))
1607
1608 ;;; Return the COMBINATION node that is the call to the LET FUN.
1609 (defun let-combination (fun)
1610   (declare (type clambda fun))
1611   (aver (functional-letlike-p fun))
1612   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1613
1614 ;;; Return the initial value lvar for a LET variable, or NIL if there
1615 ;;; is none.
1616 (defun let-var-initial-value (var)
1617   (declare (type lambda-var var))
1618   (let ((fun (lambda-var-home var)))
1619     (elt (combination-args (let-combination fun))
1620          (position-or-lose var (lambda-vars fun)))))
1621
1622 ;;; Return the LAMBDA that is called by the local CALL.
1623 (defun combination-lambda (call)
1624   (declare (type basic-combination call))
1625   (aver (eq (basic-combination-kind call) :local))
1626   (ref-leaf (lvar-uses (basic-combination-fun call))))
1627
1628 (defvar *inline-expansion-limit* 200
1629   #!+sb-doc
1630   "an upper limit on the number of inline function calls that will be expanded
1631    in any given code object (single function or block compilation)")
1632
1633 ;;; Check whether NODE's component has exceeded its inline expansion
1634 ;;; limit, and warn if so, returning NIL.
1635 (defun inline-expansion-ok (node)
1636   (let ((expanded (incf (component-inline-expansions
1637                          (block-component
1638                           (node-block node))))))
1639     (cond ((> expanded *inline-expansion-limit*) nil)
1640           ((= expanded *inline-expansion-limit*)
1641            ;; FIXME: If the objective is to stop the recursive
1642            ;; expansion of inline functions, wouldn't it be more
1643            ;; correct to look back through surrounding expansions
1644            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1645            ;; possibly stored elsewhere too) and suppress expansion
1646            ;; and print this warning when the function being proposed
1647            ;; for inline expansion is found there? (I don't like the
1648            ;; arbitrary numerical limit in principle, and I think
1649            ;; it'll be a nuisance in practice if we ever want the
1650            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1651            ;; arbitrarily huge blocks of code. -- WHN)
1652            (let ((*compiler-error-context* node))
1653              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1654                                probably trying to~%  ~
1655                                inline a recursive function."
1656                               *inline-expansion-limit*))
1657            nil)
1658           (t t))))
1659
1660 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1661 (defun assure-functional-live-p (functional)
1662   (declare (type functional functional))
1663   (when (and (or
1664               ;; looks LET-converted
1665               (functional-somewhat-letlike-p functional)
1666               ;; It's possible for a LET-converted function to end up
1667               ;; deleted later. In that case, for the purposes of this
1668               ;; analysis, it is LET-converted: LET-converted functionals
1669               ;; are too badly trashed to expand them inline, and deleted
1670               ;; LET-converted functionals are even worse.
1671               (memq (functional-kind functional) '(:deleted :zombie))))
1672     (throw 'locall-already-let-converted functional)))
1673
1674 (defun call-full-like-p (call)
1675   (declare (type combination call))
1676   (let ((kind (basic-combination-kind call)))
1677     (or (eq kind :full)
1678         (and (eq kind :known)
1679              (let ((info (basic-combination-fun-info call)))
1680                (and
1681                 (not (fun-info-ir2-convert info))
1682                 (dolist (template (fun-info-templates info) t)
1683                   (when (eq (template-ltn-policy template) :fast-safe)
1684                     (multiple-value-bind (val win)
1685                        (valid-fun-use call (template-type template))
1686                       (when (or val (not win)) (return nil)))))))))))
1687 \f
1688 ;;;; careful call
1689
1690 ;;; Apply a function to some arguments, returning a list of the values
1691 ;;; resulting of the evaluation. If an error is signalled during the
1692 ;;; application, then we produce a warning message using WARN-FUN and
1693 ;;; return NIL as our second value to indicate this. NODE is used as
1694 ;;; the error context for any error message, and CONTEXT is a string
1695 ;;; that is spliced into the warning.
1696 (declaim (ftype (sfunction ((or symbol function) list node function string)
1697                           (values list boolean))
1698                 careful-call))
1699 (defun careful-call (function args node warn-fun context)
1700   (values
1701    (multiple-value-list
1702     (handler-case (apply function args)
1703       (error (condition)
1704         (let ((*compiler-error-context* node))
1705           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1706           (return-from careful-call (values nil nil))))))
1707    t))
1708
1709 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1710 ;;; specifiers.
1711 (macrolet
1712     ((deffrob (basic careful compiler transform)
1713        `(progn
1714           (defun ,careful (specifier)
1715             (handler-case (,basic specifier)
1716               (sb!kernel::arg-count-error (condition)
1717                 (values nil (list (format nil "~A" condition))))
1718               (simple-error (condition)
1719                 (values nil (list* (simple-condition-format-control condition)
1720                                    (simple-condition-format-arguments condition))))))
1721           (defun ,compiler (specifier)
1722             (multiple-value-bind (type error-args) (,careful specifier)
1723               (or type
1724                   (apply #'compiler-error error-args))))
1725           (defun ,transform (specifier)
1726             (multiple-value-bind (type error-args) (,careful specifier)
1727               (or type
1728                   (apply #'give-up-ir1-transform
1729                          error-args)))))))
1730   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1731   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1732
1733 \f
1734 ;;;; utilities used at run-time for parsing &KEY args in IR1
1735
1736 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1737 ;;; the lvar for the value of the &KEY argument KEY in the list of
1738 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1739 ;;; otherwise. The legality and constantness of the keywords should
1740 ;;; already have been checked.
1741 (declaim (ftype (sfunction (list keyword) (or lvar null))
1742                 find-keyword-lvar))
1743 (defun find-keyword-lvar (args key)
1744   (do ((arg args (cddr arg)))
1745       ((null arg) nil)
1746     (when (eq (lvar-value (first arg)) key)
1747       (return (second arg)))))
1748
1749 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1750 ;;; verify that alternating lvars in ARGS are constant and that there
1751 ;;; is an even number of args.
1752 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1753 (defun check-key-args-constant (args)
1754   (do ((arg args (cddr arg)))
1755       ((null arg) t)
1756     (unless (and (rest arg)
1757                  (constant-lvar-p (first arg)))
1758       (return nil))))
1759
1760 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1761 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1762 ;;; and that only keywords present in the list KEYS are supplied.
1763 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1764 (defun check-transform-keys (args keys)
1765   (and (check-key-args-constant args)
1766        (do ((arg args (cddr arg)))
1767            ((null arg) t)
1768          (unless (member (lvar-value (first arg)) keys)
1769            (return nil)))))
1770 \f
1771 ;;;; miscellaneous
1772
1773 ;;; Called by the expansion of the EVENT macro.
1774 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1775 (defun %event (info node)
1776   (incf (event-info-count info))
1777   (when (and (>= (event-info-level info) *event-note-threshold*)
1778              (policy (or node *lexenv*)
1779                      (= inhibit-warnings 0)))
1780     (let ((*compiler-error-context* node))
1781       (compiler-notify (event-info-description info))))
1782
1783   (let ((action (event-info-action info)))
1784     (when action (funcall action node))))
1785
1786 ;;;
1787 (defun make-cast (value type policy)
1788   (declare (type lvar value)
1789            (type ctype type)
1790            (type policy policy))
1791   (%make-cast :asserted-type type
1792               :type-to-check (maybe-weaken-check type policy)
1793               :value value
1794               :derived-type (coerce-to-values type)))
1795
1796 (defun cast-type-check (cast)
1797   (declare (type cast cast))
1798   (when (cast-reoptimize cast)
1799     (ir1-optimize-cast cast t))
1800   (cast-%type-check cast))
1801
1802 (defun note-single-valuified-lvar (lvar)
1803   (declare (type (or lvar null) lvar))
1804   (when lvar
1805     (let ((use (lvar-uses lvar)))
1806       (cond ((ref-p use)
1807              (let ((leaf (ref-leaf use)))
1808                (when (and (lambda-var-p leaf)
1809                           (null (rest (leaf-refs leaf))))
1810                  (reoptimize-lambda-var leaf))))
1811             ((or (listp use) (combination-p use))
1812              (do-uses (node lvar)
1813                (setf (node-reoptimize node) t)
1814                (setf (block-reoptimize (node-block node)) t)
1815                (reoptimize-component (node-component node) :maybe)))))))