src/compiler/ir1util.lisp

   1 ;;;; This file contains miscellaneous utilities used for manipulating
   2 ;;;; the IR1 representation.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; cleanup hackery
  16
  17 ;;; Return the innermost cleanup enclosing NODE, or NIL if there is
  18 ;;; none in its function. If NODE has no cleanup, but is in a LET,
  19 ;;; then we must still check the environment that the call is in.
  20 (defun node-enclosing-cleanup (node)
  21   (declare (type node node))
  22   (do ((lexenv (node-lexenv node)
  23                (lambda-call-lexenv (lexenv-lambda lexenv))))
  24       ((null lexenv) nil)
  25     (let ((cup (lexenv-cleanup lexenv)))
  26       (when cup (return cup)))))
  27
  28 ;;; Convert the FORM in a block inserted between BLOCK1 and BLOCK2 as
  29 ;;; an implicit MV-PROG1. The inserted block is returned. NODE is used
  30 ;;; for IR1 context when converting the form. Note that the block is
  31 ;;; not assigned a number, and is linked into the DFO at the
  32 ;;; beginning. We indicate that we have trashed the DFO by setting
  33 ;;; COMPONENT-REANALYZE. If CLEANUP is supplied, then convert with
  34 ;;; that cleanup.
  35 (defun insert-cleanup-code (block1 block2 node form &optional cleanup)
  36   (declare (type cblock block1 block2) (type node node)
  37            (type (or cleanup null) cleanup))
  38   (setf (component-reanalyze (block-component block1)) t)
  39   (with-ir1-environment-from-node node
  40     (with-component-last-block (*current-component*
  41                                 (block-next (component-head *current-component*)))
  42       (let* ((start (make-ctran))
  43              (block (ctran-starts-block start))
  44              (next (make-ctran))
  45              (*lexenv* (if cleanup
  46                            (make-lexenv :cleanup cleanup)
  47                            *lexenv*)))
  48         (change-block-successor block1 block2 block)
  49         (link-blocks block block2)
  50         (ir1-convert start next nil form)
  51         (setf (block-last block) (ctran-use next))
  52         (setf (node-next (block-last block)) nil)
  53         block))))
  54 \f
  55 ;;;; lvar use hacking
  56
  57 ;;; Return a list of all the nodes which use LVAR.
  58 (declaim (ftype (sfunction (lvar) list) find-uses))
  59 (defun find-uses (lvar)
  60   (let ((uses (lvar-uses lvar)))
  61     (if (listp uses)
  62         uses
  63         (list uses))))
  64
  65 (defun principal-lvar-use (lvar)
  66   (let ((use (lvar-uses lvar)))
  67     (if (cast-p use)
  68         (principal-lvar-use (cast-value use))
  69         use)))
  70
  71 ;;; Update lvar use information so that NODE is no longer a use of its
  72 ;;; LVAR.
  73 ;;;
  74 ;;; Note: if you call this function, you may have to do a
  75 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
  76 ;;; changed.
  77 (declaim (ftype (sfunction (node) (values))
  78                 delete-lvar-use
  79                 %delete-lvar-use))
  80 ;;; Just delete NODE from its LVAR uses; LVAR is preserved so it may
  81 ;;; be given a new use.
  82 (defun %delete-lvar-use (node)
  83   (let* ((lvar (node-lvar node)))
  84     (when lvar
  85       (if (listp (lvar-uses lvar))
  86           (let ((new-uses (delq node (lvar-uses lvar))))
  87             (setf (lvar-uses lvar)
  88                   (if (singleton-p new-uses)
  89                       (first new-uses)
  90                       new-uses)))
  91           (setf (lvar-uses lvar) nil))
  92       (setf (node-lvar node) nil)))
  93   (values))
  94 ;;; Delete NODE from its LVAR uses; if LVAR has no other uses, delete
  95 ;;; its DEST's block, which must be unreachable.
  96 (defun delete-lvar-use (node)
  97   (let ((lvar (node-lvar node)))
  98     (when lvar
  99       (%delete-lvar-use node)
 100       (if (null (lvar-uses lvar))
 101           (binding* ((dest (lvar-dest lvar) :exit-if-null)
 102                      (() (not (node-deleted dest)) :exit-if-null)
 103                      (block (node-block dest)))
 104             (mark-for-deletion block))
 105           (reoptimize-lvar lvar))))
 106   (values))
 107
 108 ;;; Update lvar use information so that NODE uses LVAR.
 109 ;;;
 110 ;;; Note: if you call this function, you may have to do a
 111 ;;; REOPTIMIZE-LVAR to inform IR1 optimization that something has
 112 ;;; changed.
 113 (declaim (ftype (sfunction (node (or lvar null)) (values)) add-lvar-use))
 114 (defun add-lvar-use (node lvar)
 115   (aver (not (node-lvar node)))
 116   (when lvar
 117     (let ((uses (lvar-uses lvar)))
 118       (setf (lvar-uses lvar)
 119             (cond ((null uses)
 120                    node)
 121                   ((listp uses)
 122                    (cons node uses))
 123                   (t
 124                    (list node uses))))
 125       (setf (node-lvar node) lvar)))
 126
 127   (values))
 128
 129 ;;; Return true if LVAR destination is executed immediately after
 130 ;;; NODE. Cleanups are ignored.
 131 (defun immediately-used-p (lvar node)
 132   (declare (type lvar lvar) (type node node))
 133   (aver (eq (node-lvar node) lvar))
 134   (let ((dest (lvar-dest lvar)))
 135     (acond ((node-next node)
 136             (eq (ctran-next it) dest))
 137            (t (eq (block-start (first (block-succ (node-block node))))
 138                   (node-prev dest))))))
 139 \f
 140 ;;;; lvar substitution
 141
 142 ;;; In OLD's DEST, replace OLD with NEW. NEW's DEST must initially be
 143 ;;; NIL. We do not flush OLD's DEST.
 144 (defun substitute-lvar (new old)
 145   (declare (type lvar old new))
 146   (aver (not (lvar-dest new)))
 147   (let ((dest (lvar-dest old)))
 148     (etypecase dest
 149       ((or ref bind))
 150       (cif (setf (if-test dest) new))
 151       (cset (setf (set-value dest) new))
 152       (creturn (setf (return-result dest) new))
 153       (exit (setf (exit-value dest) new))
 154       (basic-combination
 155        (if (eq old (basic-combination-fun dest))
 156            (setf (basic-combination-fun dest) new)
 157            (setf (basic-combination-args dest)
 158                  (nsubst new old (basic-combination-args dest)))))
 159       (cast (setf (cast-value dest) new)))
 160
 161     (setf (lvar-dest old) nil)
 162     (setf (lvar-dest new) dest)
 163     (flush-lvar-externally-checkable-type new))
 164   (values))
 165
 166 ;;; Replace all uses of OLD with uses of NEW, where NEW has an
 167 ;;; arbitary number of uses.
 168 (defun substitute-lvar-uses (new old)
 169   (declare (type lvar old)
 170            (type (or lvar null) new))
 171
 172   (do-uses (node old)
 173     (%delete-lvar-use node)
 174     (when new
 175       (add-lvar-use node new)))
 176
 177   (when new (reoptimize-lvar new))
 178   (values))
 179 \f
 180 ;;;; block starting/creation
 181
 182 ;;; Return the block that CTRAN is the start of, making a block if
 183 ;;; necessary. This function is called by IR1 translators which may
 184 ;;; cause a CTRAN to be used more than once. Every CTRAN which may be
 185 ;;; used more than once must start a block by the time that anyone
 186 ;;; does a USE-CTRAN on it.
 187 ;;;
 188 ;;; We also throw the block into the next/prev list for the
 189 ;;; *CURRENT-COMPONENT* so that we keep track of which blocks we have
 190 ;;; made.
 191 (defun ctran-starts-block (ctran)
 192   (declare (type ctran ctran))
 193   (ecase (ctran-kind ctran)
 194     (:unused
 195      (aver (not (ctran-block ctran)))
 196      (let* ((next (component-last-block *current-component*))
 197             (prev (block-prev next))
 198             (new-block (make-block ctran)))
 199        (setf (block-next new-block) next
 200              (block-prev new-block) prev
 201              (block-prev next) new-block
 202              (block-next prev) new-block
 203              (ctran-block ctran) new-block
 204              (ctran-kind ctran) :block-start)
 205        (aver (not (ctran-use ctran)))
 206        new-block))
 207     (:block-start
 208      (ctran-block ctran))))
 209
 210 ;;; Ensure that CTRAN is the start of a block so that the use set can
 211 ;;; be freely manipulated.
 212 (defun ensure-block-start (ctran)
 213   (declare (type ctran ctran))
 214   (let ((kind (ctran-kind ctran)))
 215     (ecase kind
 216       ((:block-start))
 217       ((:unused)
 218        (setf (ctran-block ctran)
 219              (make-block-key :start ctran))
 220        (setf (ctran-kind ctran) :block-start))
 221       ((:inside-block)
 222        (node-ends-block (ctran-use ctran)))))
 223   (values))
 224 \f
 225 ;;;;
 226
 227 ;;; Filter values of LVAR through FORM, which must be an ordinary/mv
 228 ;;; call. First argument must be 'DUMMY, which will be replaced with
 229 ;;; LVAR. In case of an ordinary call the function should not have
 230 ;;; return type NIL. We create a new "filtered" lvar.
 231 ;;;
 232 ;;; TODO: remove preconditions.
 233 (defun filter-lvar (lvar form)
 234   (declare (type lvar lvar) (type list form))
 235   (let* ((dest (lvar-dest lvar))
 236          (ctran (node-prev dest)))
 237     (with-ir1-environment-from-node dest
 238
 239       (ensure-block-start ctran)
 240       (let* ((old-block (ctran-block ctran))
 241              (new-start (make-ctran))
 242              (filtered-lvar (make-lvar))
 243              (new-block (ctran-starts-block new-start)))
 244
 245         ;; Splice in the new block before DEST, giving the new block
 246         ;; all of DEST's predecessors.
 247         (dolist (block (block-pred old-block))
 248           (change-block-successor block old-block new-block))
 249
 250         (ir1-convert new-start ctran filtered-lvar form)
 251
 252         ;; KLUDGE: Comments at the head of this function in CMU CL
 253         ;; said that somewhere in here we
 254         ;;   Set the new block's start and end cleanups to the *start*
 255         ;;   cleanup of PREV's block. This overrides the incorrect
 256         ;;   default from WITH-IR1-ENVIRONMENT-FROM-NODE.
 257         ;; Unfortunately I can't find any code which corresponds to this.
 258         ;; Perhaps it was a stale comment? Or perhaps I just don't
 259         ;; understand.. -- WHN 19990521
 260
 261         ;; Replace 'DUMMY with the LVAR. (We can find 'DUMMY because
 262         ;; no LET conversion has been done yet.) The [mv-]combination
 263         ;; code from the call in the form will be the use of the new
 264         ;; check lvar. We substitute for the first argument of
 265         ;; this node.
 266         (let* ((node (lvar-use filtered-lvar))
 267                (args (basic-combination-args node))
 268                (victim (first args)))
 269           (aver (eq (constant-value (ref-leaf (lvar-use victim)))
 270                     'dummy))
 271
 272           (substitute-lvar filtered-lvar lvar)
 273           (substitute-lvar lvar victim)
 274           (flush-dest victim))
 275
 276         ;; Invoking local call analysis converts this call to a LET.
 277         (locall-analyze-component *current-component*))))
 278   (values))
 279
 280 ;;; Delete NODE and VALUE. It may result in some calls becoming tail.
 281 (defun delete-filter (node lvar value)
 282   (aver (eq (lvar-dest value) node))
 283   (aver (eq (node-lvar node) lvar))
 284   (cond (lvar (collect ((merges))
 285                 (when (return-p (lvar-dest lvar))
 286                   (do-uses (use value)
 287                     (when (and (basic-combination-p use)
 288                                (eq (basic-combination-kind use) :local))
 289                       (merges use))))
 290                 (%delete-lvar-use node)
 291                 (substitute-lvar-uses lvar value)
 292                 (prog1
 293                     (unlink-node node)
 294                   (dolist (merge (merges))
 295                     (merge-tail-sets merge)))))
 296         (t (flush-dest value)
 297            (unlink-node node))))
 298 \f
 299 ;;;; miscellaneous shorthand functions
 300
 301 ;;; Return the home (i.e. enclosing non-LET) CLAMBDA for NODE. Since
 302 ;;; the LEXENV-LAMBDA may be deleted, we must chain up the
 303 ;;; LAMBDA-CALL-LEXENV thread until we find a CLAMBDA that isn't
 304 ;;; deleted, and then return its home.
 305 (defun node-home-lambda (node)
 306   (declare (type node node))
 307   (do ((fun (lexenv-lambda (node-lexenv node))
 308             (lexenv-lambda (lambda-call-lexenv fun))))
 309       ((not (eq (functional-kind fun) :deleted))
 310        (lambda-home fun))
 311     (when (eq (lambda-home fun) fun)
 312       (return fun))))
 313
 314 #!-sb-fluid (declaim (inline node-block))
 315 (defun node-block (node)
 316   (ctran-block (node-prev node)))
 317 (declaim (ftype (sfunction (node) component) node-component))
 318 (defun node-component (node)
 319   (block-component (node-block node)))
 320 (declaim (ftype (sfunction (node) physenv) node-physenv))
 321 (defun node-physenv (node)
 322   (lambda-physenv (node-home-lambda node)))
 323 #!-sb-fluid (declaim (inline node-dest))
 324 (defun node-dest (node)
 325   (awhen (node-lvar node) (lvar-dest it)))
 326
 327 (declaim (ftype (sfunction (clambda) cblock) lambda-block))
 328 (defun lambda-block (clambda)
 329   (node-block (lambda-bind clambda)))
 330 (declaim (ftype (sfunction (clambda) component) lambda-component))
 331 (defun lambda-component (clambda)
 332   (block-component (lambda-block clambda)))
 333
 334 (declaim (ftype (sfunction (cblock) node) block-start-node))
 335 (defun block-start-node (block)
 336   (ctran-next (block-start block)))
 337
 338 ;;; Return the enclosing cleanup for environment of the first or last
 339 ;;; node in BLOCK.
 340 (defun block-start-cleanup (block)
 341   (node-enclosing-cleanup (block-start-node block)))
 342 (defun block-end-cleanup (block)
 343   (node-enclosing-cleanup (block-last block)))
 344
 345 ;;; Return the non-LET LAMBDA that holds BLOCK's code, or NIL
 346 ;;; if there is none.
 347 ;;;
 348 ;;; There can legitimately be no home lambda in dead code early in the
 349 ;;; IR1 conversion process, e.g. when IR1-converting the SETQ form in
 350 ;;;   (BLOCK B (RETURN-FROM B) (SETQ X 3))
 351 ;;; where the block is just a placeholder during parsing and doesn't
 352 ;;; actually correspond to code which will be written anywhere.
 353 (declaim (ftype (sfunction (cblock) (or clambda null)) block-home-lambda-or-null))
 354 (defun block-home-lambda-or-null (block)
 355   (if (node-p (block-last block))
 356       ;; This is the old CMU CL way of doing it.
 357       (node-home-lambda (block-last block))
 358       ;; Now that SBCL uses this operation more aggressively than CMU
 359       ;; CL did, the old CMU CL way of doing it can fail in two ways.
 360       ;;   1. It can fail in a few cases even when a meaningful home
 361       ;;      lambda exists, e.g. in IR1-CONVERT of one of the legs of
 362       ;;      an IF.
 363       ;;   2. It can fail when converting a form which is born orphaned
 364       ;;      so that it never had a meaningful home lambda, e.g. a form
 365       ;;      which follows a RETURN-FROM or GO form.
 366       (let ((pred-list (block-pred block)))
 367         ;; To deal with case 1, we reason that
 368         ;; previous-in-target-execution-order blocks should be in the
 369         ;; same lambda, and that they seem in practice to be
 370         ;; previous-in-compilation-order blocks too, so we look back
 371         ;; to find one which is sufficiently initialized to tell us
 372         ;; what the home lambda is.
 373         (if pred-list
 374             ;; We could get fancy about this, flooding through the
 375             ;; graph of all the previous blocks, but in practice it
 376             ;; seems to work just to grab the first previous block and
 377             ;; use it.
 378             (node-home-lambda (block-last (first pred-list)))
 379             ;; In case 2, we end up with an empty PRED-LIST and
 380             ;; have to punt: There's no home lambda.
 381             nil))))
 382
 383 ;;; Return the non-LET LAMBDA that holds BLOCK's code.
 384 (declaim (ftype (sfunction (cblock) clambda) block-home-lambda))
 385 (defun block-home-lambda (block)
 386   (block-home-lambda-or-null block))
 387
 388 ;;; Return the IR1 physical environment for BLOCK.
 389 (declaim (ftype (sfunction (cblock) physenv) block-physenv))
 390 (defun block-physenv (block)
 391   (lambda-physenv (block-home-lambda block)))
 392
 393 ;;; Return the Top Level Form number of PATH, i.e. the ordinal number
 394 ;;; of its original source's top level form in its compilation unit.
 395 (defun source-path-tlf-number (path)
 396   (declare (list path))
 397   (car (last path)))
 398
 399 ;;; Return the (reversed) list for the PATH in the original source
 400 ;;; (with the Top Level Form number last).
 401 (defun source-path-original-source (path)
 402   (declare (list path) (inline member))
 403   (cddr (member 'original-source-start path :test #'eq)))
 404
 405 ;;; Return the Form Number of PATH's original source inside the Top
 406 ;;; Level Form that contains it. This is determined by the order that
 407 ;;; we walk the subforms of the top level source form.
 408 (defun source-path-form-number (path)
 409   (declare (list path) (inline member))
 410   (cadr (member 'original-source-start path :test #'eq)))
 411
 412 ;;; Return a list of all the enclosing forms not in the original
 413 ;;; source that converted to get to this form, with the immediate
 414 ;;; source for node at the start of the list.
 415 (defun source-path-forms (path)
 416   (subseq path 0 (position 'original-source-start path)))
 417
 418 ;;; Return the innermost source form for NODE.
 419 (defun node-source-form (node)
 420   (declare (type node node))
 421   (let* ((path (node-source-path node))
 422          (forms (source-path-forms path)))
 423     (if forms
 424         (first forms)
 425         (values (find-original-source path)))))
 426
 427 ;;; Return NODE-SOURCE-FORM, T if lvar has a single use, otherwise
 428 ;;; NIL, NIL.
 429 (defun lvar-source (lvar)
 430   (let ((use (lvar-uses lvar)))
 431     (if (listp use)
 432         (values nil nil)
 433         (values (node-source-form use) t))))
 434
 435 ;;; Return the unique node, delivering a value to LVAR.
 436 #!-sb-fluid (declaim (inline lvar-use))
 437 (defun lvar-use (lvar)
 438   (the (not list) (lvar-uses lvar)))
 439
 440 #!-sb-fluid (declaim (inline lvar-has-single-use-p))
 441 (defun lvar-has-single-use-p (lvar)
 442   (typep (lvar-uses lvar) '(not list)))
 443
 444 ;;; Return the LAMBDA that is CTRAN's home, or NIL if there is none.
 445 (declaim (ftype (sfunction (ctran) (or clambda null))
 446                 ctran-home-lambda-or-null))
 447 (defun ctran-home-lambda-or-null (ctran)
 448   ;; KLUDGE: This function is a post-CMU-CL hack by WHN, and this
 449   ;; implementation might not be quite right, or might be uglier than
 450   ;; necessary. It appears that the original Python never found a need
 451   ;; to do this operation. The obvious things based on
 452   ;; NODE-HOME-LAMBDA of CTRAN-USE usually work; then if that fails,
 453   ;; BLOCK-HOME-LAMBDA of CTRAN-BLOCK works, given that we
 454   ;; generalize it enough to grovel harder when the simple CMU CL
 455   ;; approach fails, and furthermore realize that in some exceptional
 456   ;; cases it might return NIL. -- WHN 2001-12-04
 457   (cond ((ctran-use ctran)
 458          (node-home-lambda (ctran-use ctran)))
 459         ((ctran-block ctran)
 460          (block-home-lambda-or-null (ctran-block ctran)))
 461         (t
 462          (bug "confused about home lambda for ~S" ctran))))
 463
 464 ;;; Return the LAMBDA that is CTRAN's home.
 465 (declaim (ftype (sfunction (ctran) clambda) ctran-home-lambda))
 466 (defun ctran-home-lambda (ctran)
 467   (ctran-home-lambda-or-null ctran))
 468
 469 #!-sb-fluid (declaim (inline lvar-single-value-p))
 470 (defun lvar-single-value-p (lvar)
 471   (or (not lvar)
 472       (let ((dest (lvar-dest lvar)))
 473         (typecase dest
 474           ((or creturn exit)
 475            nil)
 476           (mv-combination
 477            (eq (basic-combination-fun dest) lvar))
 478           (cast
 479            (locally
 480                (declare (notinline lvar-single-value-p))
 481              (and (not (values-type-p (cast-asserted-type dest)))
 482                   (lvar-single-value-p (node-lvar dest)))))
 483           (t
 484            t)))))
 485
 486 (defun principal-lvar-end (lvar)
 487   (loop for prev = lvar then (node-lvar dest)
 488         for dest = (and prev (lvar-dest prev))
 489         while (cast-p dest)
 490         finally (return (values dest prev))))
 491
 492 (defun principal-lvar-single-valuify (lvar)
 493   (loop for prev = lvar then (node-lvar dest)
 494         for dest = (and prev (lvar-dest prev))
 495         while (cast-p dest)
 496         do (setf (node-derived-type dest)
 497                  (make-short-values-type (list (single-value-type
 498                                                 (node-derived-type dest)))))
 499         (reoptimize-lvar prev)))
 500 \f
 501 ;;; Return a new LEXENV just like DEFAULT except for the specified
 502 ;;; slot values. Values for the alist slots are NCONCed to the
 503 ;;; beginning of the current value, rather than replacing it entirely.
 504 (defun make-lexenv (&key (default *lexenv*)
 505                          funs vars blocks tags
 506                          type-restrictions
 507                          (lambda (lexenv-lambda default))
 508                          (cleanup (lexenv-cleanup default))
 509                          (policy (lexenv-policy default)))
 510   (macrolet ((frob (var slot)
 511                `(let ((old (,slot default)))
 512                   (if ,var
 513                       (nconc ,var old)
 514                       old))))
 515     (internal-make-lexenv
 516      (frob funs lexenv-funs)
 517      (frob vars lexenv-vars)
 518      (frob blocks lexenv-blocks)
 519      (frob tags lexenv-tags)
 520      (frob type-restrictions lexenv-type-restrictions)
 521      lambda cleanup policy)))
 522
 523 ;;; Makes a LEXENV, suitable for using in a MACROLET introduced
 524 ;;; macroexpander
 525 (defun make-restricted-lexenv (lexenv)
 526   (flet ((fun-good-p (fun)
 527            (destructuring-bind (name . thing) fun
 528              (declare (ignore name))
 529              (etypecase thing
 530                (functional nil)
 531                (global-var t)
 532                (cons (aver (eq (car thing) 'macro))
 533                      t))))
 534          (var-good-p (var)
 535            (destructuring-bind (name . thing) var
 536              (declare (ignore name))
 537              (etypecase thing
 538                (leaf nil)
 539                (cons (aver (eq (car thing) 'macro))
 540                      t)
 541                (heap-alien-info nil)))))
 542     (internal-make-lexenv
 543      (remove-if-not #'fun-good-p (lexenv-funs lexenv))
 544      (remove-if-not #'var-good-p (lexenv-vars lexenv))
 545      nil
 546      nil
 547      (lexenv-type-restrictions lexenv) ; XXX
 548      nil
 549      nil
 550      (lexenv-policy lexenv))))
 551 \f
 552 ;;;; flow/DFO/component hackery
 553
 554 ;;; Join BLOCK1 and BLOCK2.
 555 (defun link-blocks (block1 block2)
 556   (declare (type cblock block1 block2))
 557   (setf (block-succ block1)
 558         (if (block-succ block1)
 559             (%link-blocks block1 block2)
 560             (list block2)))
 561   (push block1 (block-pred block2))
 562   (values))
 563 (defun %link-blocks (block1 block2)
 564   (declare (type cblock block1 block2))
 565   (let ((succ1 (block-succ block1)))
 566     (aver (not (memq block2 succ1)))
 567     (cons block2 succ1)))
 568
 569 ;;; This is like LINK-BLOCKS, but we separate BLOCK1 and BLOCK2. If
 570 ;;; this leaves a successor with a single predecessor that ends in an
 571 ;;; IF, then set BLOCK-TEST-MODIFIED so that any test constraint will
 572 ;;; now be able to be propagated to the successor.
 573 (defun unlink-blocks (block1 block2)
 574   (declare (type cblock block1 block2))
 575   (let ((succ1 (block-succ block1)))
 576     (if (eq block2 (car succ1))
 577         (setf (block-succ block1) (cdr succ1))
 578         (do ((succ (cdr succ1) (cdr succ))
 579              (prev succ1 succ))
 580             ((eq (car succ) block2)
 581              (setf (cdr prev) (cdr succ)))
 582           (aver succ))))
 583
 584   (let ((new-pred (delq block1 (block-pred block2))))
 585     (setf (block-pred block2) new-pred)
 586     (when (singleton-p new-pred)
 587       (let ((pred-block (first new-pred)))
 588         (when (if-p (block-last pred-block))
 589           (setf (block-test-modified pred-block) t)))))
 590   (values))
 591
 592 ;;; Swing the succ/pred link between BLOCK and OLD to be between BLOCK
 593 ;;; and NEW. If BLOCK ends in an IF, then we have to fix up the
 594 ;;; consequent/alternative blocks to point to NEW. We also set
 595 ;;; BLOCK-TEST-MODIFIED so that any test constraint will be applied to
 596 ;;; the new successor.
 597 (defun change-block-successor (block old new)
 598   (declare (type cblock new old block))
 599   (unlink-blocks block old)
 600   (let ((last (block-last block))
 601         (comp (block-component block)))
 602     (setf (component-reanalyze comp) t)
 603     (typecase last
 604       (cif
 605        (setf (block-test-modified block) t)
 606        (let* ((succ-left (block-succ block))
 607               (new (if (and (eq new (component-tail comp))
 608                             succ-left)
 609                        (first succ-left)
 610                        new)))
 611          (unless (memq new succ-left)
 612            (link-blocks block new))
 613          (macrolet ((frob (slot)
 614                       `(when (eq (,slot last) old)
 615                          (setf (,slot last) new))))
 616            (frob if-consequent)
 617            (frob if-alternative)
 618            (when (eq (if-consequent last)
 619                      (if-alternative last))
 620              (setf (component-reoptimize (block-component block)) t)))))
 621       (t
 622        (unless (memq new (block-succ block))
 623          (link-blocks block new)))))
 624
 625   (values))
 626
 627 ;;; Unlink a block from the next/prev chain. We also null out the
 628 ;;; COMPONENT.
 629 (declaim (ftype (sfunction (cblock) (values)) remove-from-dfo))
 630 (defun remove-from-dfo (block)
 631   (let ((next (block-next block))
 632         (prev (block-prev block)))
 633     (setf (block-component block) nil)
 634     (setf (block-next prev) next)
 635     (setf (block-prev next) prev))
 636   (values))
 637
 638 ;;; Add BLOCK to the next/prev chain following AFTER. We also set the
 639 ;;; COMPONENT to be the same as for AFTER.
 640 (defun add-to-dfo (block after)
 641   (declare (type cblock block after))
 642   (let ((next (block-next after))
 643         (comp (block-component after)))
 644     (aver (not (eq (component-kind comp) :deleted)))
 645     (setf (block-component block) comp)
 646     (setf (block-next after) block)
 647     (setf (block-prev block) after)
 648     (setf (block-next block) next)
 649     (setf (block-prev next) block))
 650   (values))
 651
 652 ;;; Set the FLAG for all the blocks in COMPONENT to NIL, except for
 653 ;;; the head and tail which are set to T.
 654 (declaim (ftype (sfunction (component) (values)) clear-flags))
 655 (defun clear-flags (component)
 656   (let ((head (component-head component))
 657         (tail (component-tail component)))
 658     (setf (block-flag head) t)
 659     (setf (block-flag tail) t)
 660     (do-blocks (block component)
 661       (setf (block-flag block) nil)))
 662   (values))
 663
 664 ;;; Make a component with no blocks in it. The BLOCK-FLAG is initially
 665 ;;; true in the head and tail blocks.
 666 (declaim (ftype (sfunction () component) make-empty-component))
 667 (defun make-empty-component ()
 668   (let* ((head (make-block-key :start nil :component nil))
 669          (tail (make-block-key :start nil :component nil))
 670          (res (make-component head tail)))
 671     (setf (block-flag head) t)
 672     (setf (block-flag tail) t)
 673     (setf (block-component head) res)
 674     (setf (block-component tail) res)
 675     (setf (block-next head) tail)
 676     (setf (block-prev tail) head)
 677     res))
 678
 679 ;;; Make NODE the LAST node in its block, splitting the block if necessary.
 680 ;;; The new block is added to the DFO immediately following NODE's block.
 681 (defun node-ends-block (node)
 682   (declare (type node node))
 683   (let* ((block (node-block node))
 684          (start (node-next node))
 685          (last (block-last block)))
 686     (unless (eq last node)
 687       (aver (and (eq (ctran-kind start) :inside-block)
 688                  (not (block-delete-p block))))
 689       (let* ((succ (block-succ block))
 690              (new-block
 691               (make-block-key :start start
 692                               :component (block-component block)
 693                               :succ succ :last last)))
 694         (setf (ctran-kind start) :block-start)
 695         (setf (ctran-use start) nil)
 696         (setf (block-last block) node)
 697         (setf (node-next node) nil)
 698         (dolist (b succ)
 699           (setf (block-pred b)
 700                 (cons new-block (remove block (block-pred b)))))
 701         (setf (block-succ block) ())
 702         (link-blocks block new-block)
 703         (add-to-dfo new-block block)
 704         (setf (component-reanalyze (block-component block)) t)
 705
 706         (do ((ctran start (node-next (ctran-next ctran))))
 707             ((not ctran))
 708           (setf (ctran-block ctran) new-block))
 709
 710         (setf (block-type-asserted block) t)
 711         (setf (block-test-modified block) t))))
 712   (values))
 713 \f
 714 ;;;; deleting stuff
 715
 716 ;;; Deal with deleting the last (read) reference to a LAMBDA-VAR.
 717 (defun delete-lambda-var (leaf)
 718   (declare (type lambda-var leaf))
 719
 720   ;; Iterate over all local calls flushing the corresponding argument,
 721   ;; allowing the computation of the argument to be deleted. We also
 722   ;; mark the LET for reoptimization, since it may be that we have
 723   ;; deleted its last variable.
 724   (let* ((fun (lambda-var-home leaf))
 725          (n (position leaf (lambda-vars fun))))
 726     (dolist (ref (leaf-refs fun))
 727       (let* ((lvar (node-lvar ref))
 728              (dest (and lvar (lvar-dest lvar))))
 729         (when (and (combination-p dest)
 730                    (eq (basic-combination-fun dest) lvar)
 731                    (eq (basic-combination-kind dest) :local))
 732           (let* ((args (basic-combination-args dest))
 733                  (arg (elt args n)))
 734             (reoptimize-lvar arg)
 735             (flush-dest arg)
 736             (setf (elt args n) nil))))))
 737
 738   ;; The LAMBDA-VAR may still have some SETs, but this doesn't cause
 739   ;; too much difficulty, since we can efficiently implement
 740   ;; write-only variables. We iterate over the SETs, marking their
 741   ;; blocks for dead code flushing, since we can delete SETs whose
 742   ;; value is unused.
 743   (dolist (set (lambda-var-sets leaf))
 744     (setf (block-flush-p (node-block set)) t))
 745
 746   (values))
 747
 748 ;;; Note that something interesting has happened to VAR.
 749 (defun reoptimize-lambda-var (var)
 750   (declare (type lambda-var var))
 751   (let ((fun (lambda-var-home var)))
 752     ;; We only deal with LET variables, marking the corresponding
 753     ;; initial value arg as needing to be reoptimized.
 754     (when (and (eq (functional-kind fun) :let)
 755                (leaf-refs var))
 756       (do ((args (basic-combination-args
 757                   (lvar-dest (node-lvar (first (leaf-refs fun)))))
 758                  (cdr args))
 759            (vars (lambda-vars fun) (cdr vars)))
 760           ((eq (car vars) var)
 761            (reoptimize-lvar (car args))))))
 762   (values))
 763
 764 ;;; Delete a function that has no references. This need only be called
 765 ;;; on functions that never had any references, since otherwise
 766 ;;; DELETE-REF will handle the deletion.
 767 (defun delete-functional (fun)
 768   (aver (and (null (leaf-refs fun))
 769              (not (functional-entry-fun fun))))
 770   (etypecase fun
 771     (optional-dispatch (delete-optional-dispatch fun))
 772     (clambda (delete-lambda fun)))
 773   (values))
 774
 775 ;;; Deal with deleting the last reference to a CLAMBDA. Since there is
 776 ;;; only one way into a CLAMBDA, deleting the last reference to a
 777 ;;; CLAMBDA ensures that there is no way to reach any of the code in
 778 ;;; it. So we just set the FUNCTIONAL-KIND for FUN and its LETs to
 779 ;;; :DELETED, causing IR1 optimization to delete blocks in that
 780 ;;; CLAMBDA.
 781 (defun delete-lambda (clambda)
 782   (declare (type clambda clambda))
 783   (let ((original-kind (functional-kind clambda))
 784         (bind (lambda-bind clambda)))
 785     (aver (not (member original-kind '(:deleted :optional :toplevel))))
 786     (aver (not (functional-has-external-references-p clambda)))
 787     (setf (functional-kind clambda) :deleted)
 788     (setf (lambda-bind clambda) nil)
 789     (dolist (let (lambda-lets clambda))
 790       (setf (lambda-bind let) nil)
 791       (setf (functional-kind let) :deleted))
 792
 793     ;; LET may be deleted if its BIND is unreachable. Autonomous
 794     ;; function may be deleted if it has no reachable references.
 795     (unless (member original-kind '(:let :mv-let :assignment))
 796       (dolist (ref (lambda-refs clambda))
 797         (mark-for-deletion (node-block ref))))
 798
 799     ;; (The IF test is (FUNCTIONAL-SOMEWHAT-LETLIKE-P CLAMBDA), except
 800     ;; that we're using the old value of the KIND slot, not the
 801     ;; current slot value, which has now been set to :DELETED.)
 802     (if (member original-kind '(:let :mv-let :assignment))
 803         (let ((home (lambda-home clambda)))
 804           (setf (lambda-lets home) (delete clambda (lambda-lets home))))
 805         ;; If the function isn't a LET, we unlink the function head
 806         ;; and tail from the component head and tail to indicate that
 807         ;; the code is unreachable. We also delete the function from
 808         ;; COMPONENT-LAMBDAS (it won't be there before local call
 809         ;; analysis, but no matter.) If the lambda was never
 810         ;; referenced, we give a note.
 811         (let* ((bind-block (node-block bind))
 812                (component (block-component bind-block))
 813                (return (lambda-return clambda))
 814                (return-block (and return (node-block return))))
 815           (unless (leaf-ever-used clambda)
 816             (let ((*compiler-error-context* bind))
 817               (compiler-notify 'code-deletion-note
 818                                :format-control "deleting unused function~:[.~;~:*~%  ~S~]"
 819                                :format-arguments (list (leaf-debug-name clambda)))))
 820           (unless (block-delete-p bind-block)
 821             (unlink-blocks (component-head component) bind-block))
 822           (when (and return-block (not (block-delete-p return-block)))
 823             (mark-for-deletion return-block)
 824             (unlink-blocks return-block (component-tail component)))
 825           (setf (component-reanalyze component) t)
 826           (let ((tails (lambda-tail-set clambda)))
 827             (setf (tail-set-funs tails)
 828                   (delete clambda (tail-set-funs tails)))
 829             (setf (lambda-tail-set clambda) nil))
 830           (setf (component-lambdas component)
 831                 (delete clambda (component-lambdas component)))))
 832
 833     ;; If the lambda is an XEP, then we null out the ENTRY-FUN in its
 834     ;; ENTRY-FUN so that people will know that it is not an entry
 835     ;; point anymore.
 836     (when (eq original-kind :external)
 837       (let ((fun (functional-entry-fun clambda)))
 838         (setf (functional-entry-fun fun) nil)
 839         (when (optional-dispatch-p fun)
 840           (delete-optional-dispatch fun)))))
 841
 842   (values))
 843
 844 ;;; Deal with deleting the last reference to an OPTIONAL-DISPATCH. We
 845 ;;; have to be a bit more careful than with lambdas, since DELETE-REF
 846 ;;; is used both before and after local call analysis. Afterward, all
 847 ;;; references to still-existing OPTIONAL-DISPATCHes have been moved
 848 ;;; to the XEP, leaving it with no references at all. So we look at
 849 ;;; the XEP to see whether an optional-dispatch is still really being
 850 ;;; used. But before local call analysis, there are no XEPs, and all
 851 ;;; references are direct.
 852 ;;;
 853 ;;; When we do delete the OPTIONAL-DISPATCH, we grovel all of its
 854 ;;; entry-points, making them be normal lambdas, and then deleting the
 855 ;;; ones with no references. This deletes any e-p lambdas that were
 856 ;;; either never referenced, or couldn't be deleted when the last
 857 ;;; reference was deleted (due to their :OPTIONAL kind.)
 858 ;;;
 859 ;;; Note that the last optional entry point may alias the main entry,
 860 ;;; so when we process the main entry, its KIND may have been changed
 861 ;;; to NIL or even converted to a LETlike value.
 862 (defun delete-optional-dispatch (leaf)
 863   (declare (type optional-dispatch leaf))
 864   (let ((entry (functional-entry-fun leaf)))
 865     (unless (and entry (leaf-refs entry))
 866       (aver (or (not entry) (eq (functional-kind entry) :deleted)))
 867       (setf (functional-kind leaf) :deleted)
 868
 869       (flet ((frob (fun)
 870                (unless (eq (functional-kind fun) :deleted)
 871                  (aver (eq (functional-kind fun) :optional))
 872                  (setf (functional-kind fun) nil)
 873                  (let ((refs (leaf-refs fun)))
 874                    (cond ((null refs)
 875                           (delete-lambda fun))
 876                          ((null (rest refs))
 877                           (or (maybe-let-convert fun)
 878                               (maybe-convert-to-assignment fun)))
 879                          (t
 880                           (maybe-convert-to-assignment fun)))))))
 881
 882         (dolist (ep (optional-dispatch-entry-points leaf))
 883           (when (promise-ready-p ep)
 884             (frob (force ep))))
 885         (when (optional-dispatch-more-entry leaf)
 886           (frob (optional-dispatch-more-entry leaf)))
 887         (let ((main (optional-dispatch-main-entry leaf)))
 888           (when (eq (functional-kind main) :optional)
 889             (frob main))))))
 890
 891   (values))
 892
 893 ;;; Do stuff to delete the semantic attachments of a REF node. When
 894 ;;; this leaves zero or one reference, we do a type dispatch off of
 895 ;;; the leaf to determine if a special action is appropriate.
 896 (defun delete-ref (ref)
 897   (declare (type ref ref))
 898   (let* ((leaf (ref-leaf ref))
 899          (refs (delq ref (leaf-refs leaf))))
 900     (setf (leaf-refs leaf) refs)
 901
 902     (cond ((null refs)
 903            (typecase leaf
 904              (lambda-var
 905               (delete-lambda-var leaf))
 906              (clambda
 907               (ecase (functional-kind leaf)
 908                 ((nil :let :mv-let :assignment :escape :cleanup)
 909                  (aver (null (functional-entry-fun leaf)))
 910                  (delete-lambda leaf))
 911                 (:external
 912                  (delete-lambda leaf))
 913                 ((:deleted :optional))))
 914              (optional-dispatch
 915               (unless (eq (functional-kind leaf) :deleted)
 916                 (delete-optional-dispatch leaf)))))
 917           ((null (rest refs))
 918            (typecase leaf
 919              (clambda (or (maybe-let-convert leaf)
 920                           (maybe-convert-to-assignment leaf)))
 921              (lambda-var (reoptimize-lambda-var leaf))))
 922           (t
 923            (typecase leaf
 924              (clambda (maybe-convert-to-assignment leaf))))))
 925
 926   (values))
 927
 928 ;;; This function is called by people who delete nodes; it provides a
 929 ;;; way to indicate that the value of a lvar is no longer used. We
 930 ;;; null out the LVAR-DEST, set FLUSH-P in the blocks containing uses
 931 ;;; of LVAR and set COMPONENT-REOPTIMIZE.
 932 (defun flush-dest (lvar)
 933   (declare (type (or lvar null) lvar))
 934   (unless (null lvar)
 935     (setf (lvar-dest lvar) nil)
 936     (flush-lvar-externally-checkable-type lvar)
 937     (do-uses (use lvar)
 938       (let ((prev (node-prev use)))
 939         (let ((block (ctran-block prev)))
 940           (setf (component-reoptimize (block-component block)) t)
 941           (setf (block-attributep (block-flags block) flush-p type-asserted)
 942                 t)))
 943       (setf (node-lvar use) nil))
 944     (setf (lvar-uses lvar) nil))
 945   (values))
 946
 947 (defun delete-dest (lvar)
 948   (when lvar
 949     (let* ((dest (lvar-dest lvar))
 950            (prev (node-prev dest)))
 951       (let ((block (ctran-block prev)))
 952         (unless (block-delete-p block)
 953           (mark-for-deletion block))))))
 954
 955 ;;; Do a graph walk backward from BLOCK, marking all predecessor
 956 ;;; blocks with the DELETE-P flag.
 957 (defun mark-for-deletion (block)
 958   (declare (type cblock block))
 959   (let* ((component (block-component block))
 960          (head (component-head component)))
 961     (labels ((helper (block)
 962                (setf (block-delete-p block) t)
 963                (dolist (pred (block-pred block))
 964                  (unless (or (block-delete-p pred)
 965                              (eq pred head))
 966                    (helper pred)))))
 967       (unless (block-delete-p block)
 968         (helper block)
 969         (setf (component-reanalyze component) t))))
 970   (values))
 971
 972 ;;; This function does what is necessary to eliminate the code in it
 973 ;;; from the IR1 representation. This involves unlinking it from its
 974 ;;; predecessors and successors and deleting various node-specific
 975 ;;; semantic information.
 976 (defun delete-block (block &optional silent)
 977   (declare (type cblock block))
 978   (aver (block-component block))      ; else block is already deleted!
 979   (unless silent
 980     (note-block-deletion block))
 981   (setf (block-delete-p block) t)
 982
 983   (dolist (b (block-pred block))
 984     (unlink-blocks b block)
 985     ;; In bug 147 the almost-all-blocks-have-a-successor invariant was
 986     ;; broken when successors were deleted without setting the
 987     ;; BLOCK-DELETE-P flags of their predececessors. Make sure that
 988     ;; doesn't happen again.
 989     (aver (not (and (null (block-succ b))
 990                     (not (block-delete-p b))
 991                     (not (eq b (component-head (block-component b))))))))
 992   (dolist (b (block-succ block))
 993     (unlink-blocks block b))
 994
 995   (do-nodes-carefully (node block)
 996     (when (valued-node-p node)
 997       (delete-lvar-use node))
 998     (typecase node
 999       (ref (delete-ref node))
1000       (cif (flush-dest (if-test node)))
1001       ;; The next two cases serve to maintain the invariant that a LET
1002       ;; always has a well-formed COMBINATION, REF and BIND. We delete
1003       ;; the lambda whenever we delete any of these, but we must be
1004       ;; careful that this LET has not already been partially deleted.
1005       (basic-combination
1006        (when (and (eq (basic-combination-kind node) :local)
1007                   ;; Guards COMBINATION-LAMBDA agains the REF being deleted.
1008                   (lvar-uses (basic-combination-fun node)))
1009          (let ((fun (combination-lambda node)))
1010            ;; If our REF was the second-to-last ref, and has been
1011            ;; deleted, then FUN may be a LET for some other
1012            ;; combination.
1013            (when (and (functional-letlike-p fun)
1014                       (eq (let-combination fun) node))
1015              (delete-lambda fun))))
1016        (flush-dest (basic-combination-fun node))
1017        (dolist (arg (basic-combination-args node))
1018          (when arg (flush-dest arg))))
1019       (bind
1020        (let ((lambda (bind-lambda node)))
1021          (unless (eq (functional-kind lambda) :deleted)
1022            (delete-lambda lambda))))
1023       (exit
1024        (let ((value (exit-value node))
1025              (entry (exit-entry node)))
1026          (when value
1027            (flush-dest value))
1028          (when entry
1029            (setf (entry-exits entry)
1030                  (delq node (entry-exits entry))))))
1031       (creturn
1032        (flush-dest (return-result node))
1033        (delete-return node))
1034       (cset
1035        (flush-dest (set-value node))
1036        (let ((var (set-var node)))
1037          (setf (basic-var-sets var)
1038                (delete node (basic-var-sets var)))))
1039       (cast
1040        (flush-dest (cast-value node)))))
1041
1042   (remove-from-dfo block)
1043   (values))
1044
1045 ;;; Do stuff to indicate that the return node NODE is being deleted.
1046 (defun delete-return (node)
1047   (declare (type creturn node))
1048   (let* ((fun (return-lambda node))
1049          (tail-set (lambda-tail-set fun)))
1050     (aver (lambda-return fun))
1051     (setf (lambda-return fun) nil)
1052     (when (and tail-set (not (find-if #'lambda-return
1053                                       (tail-set-funs tail-set))))
1054       (setf (tail-set-type tail-set) *empty-type*)))
1055   (values))
1056
1057 ;;; If any of the VARS in FUN was never referenced and was not
1058 ;;; declared IGNORE, then complain.
1059 (defun note-unreferenced-vars (fun)
1060   (declare (type clambda fun))
1061   (dolist (var (lambda-vars fun))
1062     (unless (or (leaf-ever-used var)
1063                 (lambda-var-ignorep var))
1064       (let ((*compiler-error-context* (lambda-bind fun)))
1065         (unless (policy *compiler-error-context* (= inhibit-warnings 3))
1066           ;; ANSI section "3.2.5 Exceptional Situations in the Compiler"
1067           ;; requires this to be no more than a STYLE-WARNING.
1068           (compiler-style-warn "The variable ~S is defined but never used."
1069                                (leaf-debug-name var)))
1070         (setf (leaf-ever-used var) t)))) ; to avoid repeated warnings? -- WHN
1071   (values))
1072
1073 (defvar *deletion-ignored-objects* '(t nil))
1074
1075 ;;; Return true if we can find OBJ in FORM, NIL otherwise. We bound
1076 ;;; our recursion so that we don't get lost in circular structures. We
1077 ;;; ignore the car of forms if they are a symbol (to prevent confusing
1078 ;;; function referencess with variables), and we also ignore anything
1079 ;;; inside ' or #'.
1080 (defun present-in-form (obj form depth)
1081   (declare (type (integer 0 20) depth))
1082   (cond ((= depth 20) nil)
1083         ((eq obj form) t)
1084         ((atom form) nil)
1085         (t
1086          (let ((first (car form))
1087                (depth (1+ depth)))
1088            (if (member first '(quote function))
1089                nil
1090                (or (and (not (symbolp first))
1091                         (present-in-form obj first depth))
1092                    (do ((l (cdr form) (cdr l))
1093                         (n 0 (1+ n)))
1094                        ((or (atom l) (> n 100))
1095                         nil)
1096                      (declare (fixnum n))
1097                      (when (present-in-form obj (car l) depth)
1098                        (return t)))))))))
1099
1100 ;;; This function is called on a block immediately before we delete
1101 ;;; it. We check to see whether any of the code about to die appeared
1102 ;;; in the original source, and emit a note if so.
1103 ;;;
1104 ;;; If the block was in a lambda is now deleted, then we ignore the
1105 ;;; whole block, since this case is picked off in DELETE-LAMBDA. We
1106 ;;; also ignore the deletion of CRETURN nodes, since it is somewhat
1107 ;;; reasonable for a function to not return, and there is a different
1108 ;;; note for that case anyway.
1109 ;;;
1110 ;;; If the actual source is an atom, then we use a bunch of heuristics
1111 ;;; to guess whether this reference really appeared in the original
1112 ;;; source:
1113 ;;; -- If a symbol, it must be interned and not a keyword.
1114 ;;; -- It must not be an easily introduced constant (T or NIL, a fixnum
1115 ;;;    or a character.)
1116 ;;; -- The atom must be "present" in the original source form, and
1117 ;;;    present in all intervening actual source forms.
1118 (defun note-block-deletion (block)
1119   (let ((home (block-home-lambda block)))
1120     (unless (eq (functional-kind home) :deleted)
1121       (do-nodes (node nil block)
1122         (let* ((path (node-source-path node))
1123                (first (first path)))
1124           (when (or (eq first 'original-source-start)
1125                     (and (atom first)
1126                          (or (not (symbolp first))
1127                              (let ((pkg (symbol-package first)))
1128                                (and pkg
1129                                     (not (eq pkg (symbol-package :end))))))
1130                          (not (member first *deletion-ignored-objects*))
1131                          (not (typep first '(or fixnum character)))
1132                          (every (lambda (x)
1133                                   (present-in-form first x 0))
1134                                 (source-path-forms path))
1135                          (present-in-form first (find-original-source path)
1136                                           0)))
1137             (unless (return-p node)
1138               (let ((*compiler-error-context* node))
1139                 (compiler-notify 'code-deletion-note
1140                                  :format-control "deleting unreachable code"
1141                                  :format-arguments nil)))
1142             (return))))))
1143   (values))
1144
1145 ;;; Delete a node from a block, deleting the block if there are no
1146 ;;; nodes left. We remove the node from the uses of its LVAR.
1147 ;;;
1148 ;;; If the node is the last node, there must be exactly one successor.
1149 ;;; We link all of our precedessors to the successor and unlink the
1150 ;;; block. In this case, we return T, otherwise NIL. If no nodes are
1151 ;;; left, and the block is a successor of itself, then we replace the
1152 ;;; only node with a degenerate exit node. This provides a way to
1153 ;;; represent the bodyless infinite loop, given the prohibition on
1154 ;;; empty blocks in IR1.
1155 (defun unlink-node (node)
1156   (declare (type node node))
1157   (when (valued-node-p node)
1158     (delete-lvar-use node))
1159
1160   (let* ((ctran (node-next node))
1161          (next (and ctran (ctran-next ctran)))
1162          (prev (node-prev node))
1163          (block (ctran-block prev))
1164          (prev-kind (ctran-kind prev))
1165          (last (block-last block)))
1166
1167     (setf (block-type-asserted block) t)
1168     (setf (block-test-modified block) t)
1169
1170     (cond ((or (eq prev-kind :inside-block)
1171                (and (eq prev-kind :block-start)
1172                     (not (eq node last))))
1173            (cond ((eq node last)
1174                   (setf (block-last block) (ctran-use prev))
1175                   (setf (node-next (ctran-use prev)) nil))
1176                  (t
1177                   (setf (ctran-next prev) next)
1178                   (setf (node-prev next) prev)
1179                   (when (if-p next) ; AOP wanted
1180                     (reoptimize-lvar (if-test next)))))
1181            (setf (node-prev node) nil)
1182            nil)
1183           (t
1184            (aver (eq prev-kind :block-start))
1185            (aver (eq node last))
1186            (let* ((succ (block-succ block))
1187                   (next (first succ)))
1188              (aver (singleton-p succ))
1189              (cond
1190               ((eq block (first succ))
1191                (with-ir1-environment-from-node node
1192                  (let ((exit (make-exit)))
1193                    (setf (ctran-next prev) nil)
1194                    (link-node-to-previous-ctran exit prev)
1195                    (setf (block-last block) exit)))
1196                (setf (node-prev node) nil)
1197                nil)
1198               (t
1199                (aver (eq (block-start-cleanup block)
1200                          (block-end-cleanup block)))
1201                (unlink-blocks block next)
1202                (dolist (pred (block-pred block))
1203                  (change-block-successor pred block next))
1204                (remove-from-dfo block)
1205                (setf (block-delete-p block) t)
1206                (setf (node-prev node) nil)
1207                t)))))))
1208
1209 ;;; Return true if NODE has been deleted, false if it is still a valid
1210 ;;; part of IR1.
1211 (defun node-deleted (node)
1212   (declare (type node node))
1213   (let ((prev (node-prev node)))
1214     (not (and prev
1215               (let ((block (ctran-block prev)))
1216                 (and (block-component block)
1217                      (not (block-delete-p block))))))))
1218
1219 ;;; Delete all the blocks and functions in COMPONENT. We scan first
1220 ;;; marking the blocks as DELETE-P to prevent weird stuff from being
1221 ;;; triggered by deletion.
1222 (defun delete-component (component)
1223   (declare (type component component))
1224   (aver (null (component-new-functionals component)))
1225   (setf (component-kind component) :deleted)
1226   (do-blocks (block component)
1227     (setf (block-delete-p block) t))
1228   (dolist (fun (component-lambdas component))
1229     (setf (functional-kind fun) nil)
1230     (setf (functional-entry-fun fun) nil)
1231     (setf (leaf-refs fun) nil)
1232     (delete-functional fun))
1233   (do-blocks (block component)
1234     (delete-block block))
1235   (values))
1236
1237 ;;; Convert code of the form
1238 ;;;   (FOO ... (FUN ...) ...)
1239 ;;; to
1240 ;;;   (FOO ...    ...    ...).
1241 ;;; In other words, replace the function combination FUN by its
1242 ;;; arguments. If there are any problems with doing this, use GIVE-UP
1243 ;;; to blow out of whatever transform called this. Note, as the number
1244 ;;; of arguments changes, the transform must be prepared to return a
1245 ;;; lambda with a new lambda-list with the correct number of
1246 ;;; arguments.
1247 (defun extract-fun-args (lvar fun num-args)
1248   #!+sb-doc
1249   "If LVAR is a call to FUN with NUM-ARGS args, change those arguments
1250    to feed directly to the LVAR-DEST of LVAR, which must be a
1251    combination."
1252   (declare (type lvar lvar)
1253            (type symbol fun)
1254            (type index num-args))
1255   (let ((outside (lvar-dest lvar))
1256         (inside (lvar-uses lvar)))
1257     (aver (combination-p outside))
1258     (unless (combination-p inside)
1259       (give-up-ir1-transform))
1260     (let ((inside-fun (combination-fun inside)))
1261       (unless (eq (lvar-fun-name inside-fun) fun)
1262         (give-up-ir1-transform))
1263       (let ((inside-args (combination-args inside)))
1264         (unless (= (length inside-args) num-args)
1265           (give-up-ir1-transform))
1266         (let* ((outside-args (combination-args outside))
1267                (arg-position (position lvar outside-args))
1268                (before-args (subseq outside-args 0 arg-position))
1269                (after-args (subseq outside-args (1+ arg-position))))
1270           (dolist (arg inside-args)
1271             (setf (lvar-dest arg) outside)
1272             (flush-lvar-externally-checkable-type arg))
1273           (setf (combination-args inside) nil)
1274           (setf (combination-args outside)
1275                 (append before-args inside-args after-args))
1276           (change-ref-leaf (lvar-uses inside-fun)
1277                            (find-free-fun 'list "???"))
1278           (setf (combination-kind inside)
1279                 (info :function :info 'list))
1280           (setf (node-derived-type inside) *wild-type*)
1281           (flush-dest lvar)
1282           (values))))))
1283
1284 (defun flush-combination (combination)
1285   (declare (type combination combination))
1286   (flush-dest (combination-fun combination))
1287   (dolist (arg (combination-args combination))
1288     (flush-dest arg))
1289   (unlink-node combination)
1290   (values))
1291
1292 \f
1293 ;;;; leaf hackery
1294
1295 ;;; Change the LEAF that a REF refers to.
1296 (defun change-ref-leaf (ref leaf)
1297   (declare (type ref ref) (type leaf leaf))
1298   (unless (eq (ref-leaf ref) leaf)
1299     (push ref (leaf-refs leaf))
1300     (delete-ref ref)
1301     (setf (ref-leaf ref) leaf)
1302     (setf (leaf-ever-used leaf) t)
1303     (let* ((ltype (leaf-type leaf))
1304            (vltype (make-single-value-type ltype)))
1305       (if (let* ((lvar (node-lvar ref))
1306                  (dest (and lvar (lvar-dest lvar))))
1307             (and (basic-combination-p dest)
1308                  (eq lvar (basic-combination-fun dest))
1309                  (csubtypep ltype (specifier-type 'function))))
1310           (setf (node-derived-type ref) vltype)
1311           (derive-node-type ref vltype)))
1312     (reoptimize-lvar (node-lvar ref)))
1313   (values))
1314
1315 ;;; Change all REFS for OLD-LEAF to NEW-LEAF.
1316 (defun substitute-leaf (new-leaf old-leaf)
1317   (declare (type leaf new-leaf old-leaf))
1318   (dolist (ref (leaf-refs old-leaf))
1319     (change-ref-leaf ref new-leaf))
1320   (values))
1321
1322 ;;; like SUBSITUTE-LEAF, only there is a predicate on the REF to tell
1323 ;;; whether to substitute
1324 (defun substitute-leaf-if (test new-leaf old-leaf)
1325   (declare (type leaf new-leaf old-leaf) (type function test))
1326   (dolist (ref (leaf-refs old-leaf))
1327     (when (funcall test ref)
1328       (change-ref-leaf ref new-leaf)))
1329   (values))
1330
1331 ;;; Return a LEAF which represents the specified constant object. If
1332 ;;; the object is not in *CONSTANTS*, then we create a new constant
1333 ;;; LEAF and enter it.
1334 (defun find-constant (object)
1335   (if (typep object
1336              ;; FIXME: What is the significance of this test? ("things
1337              ;; that are worth uniquifying"?)
1338              '(or symbol number character instance))
1339       (or (gethash object *constants*)
1340           (setf (gethash object *constants*)
1341                 (make-constant :value object
1342                                :%source-name '.anonymous.
1343                                :type (ctype-of object)
1344                                :where-from :defined)))
1345       (make-constant :value object
1346                      :%source-name '.anonymous.
1347                      :type (ctype-of object)
1348                      :where-from :defined)))
1349 \f
1350 ;;; Return true if VAR would have to be closed over if environment
1351 ;;; analysis ran now (i.e. if there are any uses that have a different
1352 ;;; home lambda than VAR's home.)
1353 (defun closure-var-p (var)
1354   (declare (type lambda-var var))
1355   (let ((home (lambda-var-home var)))
1356     (cond ((eq (functional-kind home) :deleted)
1357            nil)
1358           (t (let ((home (lambda-home home)))
1359                (flet ((frob (l)
1360                         (find home l
1361                               :key #'node-home-lambda
1362                               :test-not #'eq)))
1363                  (or (frob (leaf-refs var))
1364                      (frob (basic-var-sets var)))))))))
1365
1366 ;;; If there is a non-local exit noted in ENTRY's environment that
1367 ;;; exits to CONT in that entry, then return it, otherwise return NIL.
1368 (defun find-nlx-info (exit)
1369   (declare (type exit exit))
1370   (let* ((entry (exit-entry exit))
1371          (entry-cleanup (entry-cleanup entry)))
1372     (dolist (nlx (physenv-nlx-info (node-physenv entry)) nil)
1373       (when (eq (nlx-info-exit nlx) exit)
1374         (return nlx)))))
1375 \f
1376 ;;;; functional hackery
1377
1378 (declaim (ftype (sfunction (functional) clambda) main-entry))
1379 (defun main-entry (functional)
1380   (etypecase functional
1381     (clambda functional)
1382     (optional-dispatch
1383      (optional-dispatch-main-entry functional))))
1384
1385 ;;; RETURN true if FUNCTIONAL is a thing that can be treated like
1386 ;;; MV-BIND when it appears in an MV-CALL. All fixed arguments must be
1387 ;;; optional with null default and no SUPPLIED-P. There must be a
1388 ;;; &REST arg with no references.
1389 (declaim (ftype (sfunction (functional) boolean) looks-like-an-mv-bind))
1390 (defun looks-like-an-mv-bind (functional)
1391   (and (optional-dispatch-p functional)
1392        (do ((arg (optional-dispatch-arglist functional) (cdr arg)))
1393            ((null arg) nil)
1394          (let ((info (lambda-var-arg-info (car arg))))
1395            (unless info (return nil))
1396            (case (arg-info-kind info)
1397              (:optional
1398               (when (or (arg-info-supplied-p info) (arg-info-default info))
1399                 (return nil)))
1400              (:rest
1401               (return (and (null (cdr arg)) (null (leaf-refs (car arg))))))
1402              (t
1403               (return nil)))))))
1404
1405 ;;; Return true if function is an external entry point. This is true
1406 ;;; of normal XEPs (:EXTERNAL kind) and also of top level lambdas
1407 ;;; (:TOPLEVEL kind.)
1408 (defun xep-p (fun)
1409   (declare (type functional fun))
1410   (not (null (member (functional-kind fun) '(:external :toplevel)))))
1411
1412 ;;; If LVAR's only use is a non-notinline global function reference,
1413 ;;; then return the referenced symbol, otherwise NIL. If NOTINLINE-OK
1414 ;;; is true, then we don't care if the leaf is NOTINLINE.
1415 (defun lvar-fun-name (lvar &optional notinline-ok)
1416   (declare (type lvar lvar))
1417   (let ((use (lvar-uses lvar)))
1418     (if (ref-p use)
1419         (let ((leaf (ref-leaf use)))
1420           (if (and (global-var-p leaf)
1421                    (eq (global-var-kind leaf) :global-function)
1422                    (or (not (defined-fun-p leaf))
1423                        (not (eq (defined-fun-inlinep leaf) :notinline))
1424                        notinline-ok))
1425               (leaf-source-name leaf)
1426               nil))
1427         nil)))
1428
1429 ;;; Return the source name of a combination. (This is an idiom
1430 ;;; which was used in CMU CL. I gather it always works. -- WHN)
1431 (defun combination-fun-source-name (combination)
1432   (let ((ref (lvar-uses (combination-fun combination))))
1433     (leaf-source-name (ref-leaf ref))))
1434
1435 ;;; Return the COMBINATION node that is the call to the LET FUN.
1436 (defun let-combination (fun)
1437   (declare (type clambda fun))
1438   (aver (functional-letlike-p fun))
1439   (lvar-dest (node-lvar (first (leaf-refs fun)))))
1440
1441 ;;; Return the initial value lvar for a LET variable, or NIL if there
1442 ;;; is none.
1443 (defun let-var-initial-value (var)
1444   (declare (type lambda-var var))
1445   (let ((fun (lambda-var-home var)))
1446     (elt (combination-args (let-combination fun))
1447          (position-or-lose var (lambda-vars fun)))))
1448
1449 ;;; Return the LAMBDA that is called by the local CALL.
1450 (defun combination-lambda (call)
1451   (declare (type basic-combination call))
1452   (aver (eq (basic-combination-kind call) :local))
1453   (ref-leaf (lvar-uses (basic-combination-fun call))))
1454
1455 (defvar *inline-expansion-limit* 200
1456   #!+sb-doc
1457   "an upper limit on the number of inline function calls that will be expanded
1458    in any given code object (single function or block compilation)")
1459
1460 ;;; Check whether NODE's component has exceeded its inline expansion
1461 ;;; limit, and warn if so, returning NIL.
1462 (defun inline-expansion-ok (node)
1463   (let ((expanded (incf (component-inline-expansions
1464                          (block-component
1465                           (node-block node))))))
1466     (cond ((> expanded *inline-expansion-limit*) nil)
1467           ((= expanded *inline-expansion-limit*)
1468            ;; FIXME: If the objective is to stop the recursive
1469            ;; expansion of inline functions, wouldn't it be more
1470            ;; correct to look back through surrounding expansions
1471            ;; (which are, I think, stored in the *CURRENT-PATH*, and
1472            ;; possibly stored elsewhere too) and suppress expansion
1473            ;; and print this warning when the function being proposed
1474            ;; for inline expansion is found there? (I don't like the
1475            ;; arbitrary numerical limit in principle, and I think
1476            ;; it'll be a nuisance in practice if we ever want the
1477            ;; compiler to be able to use WITH-COMPILATION-UNIT on
1478            ;; arbitrarily huge blocks of code. -- WHN)
1479            (let ((*compiler-error-context* node))
1480              (compiler-notify "*INLINE-EXPANSION-LIMIT* (~W) was exceeded, ~
1481                                probably trying to~%  ~
1482                                inline a recursive function."
1483                               *inline-expansion-limit*))
1484            nil)
1485           (t t))))
1486
1487 ;;; Make sure that FUNCTIONAL is not let-converted or deleted.
1488 (defun assure-functional-live-p (functional)
1489   (declare (type functional functional))
1490   (when (and (or
1491               ;; looks LET-converted
1492               (functional-somewhat-letlike-p functional)
1493               ;; It's possible for a LET-converted function to end up
1494               ;; deleted later. In that case, for the purposes of this
1495               ;; analysis, it is LET-converted: LET-converted functionals
1496               ;; are too badly trashed to expand them inline, and deleted
1497               ;; LET-converted functionals are even worse.
1498               (eql (functional-kind functional) :deleted)))
1499     (throw 'locall-already-let-converted functional)))
1500 \f
1501 ;;;; careful call
1502
1503 ;;; Apply a function to some arguments, returning a list of the values
1504 ;;; resulting of the evaluation. If an error is signalled during the
1505 ;;; application, then we produce a warning message using WARN-FUN and
1506 ;;; return NIL as our second value to indicate this. NODE is used as
1507 ;;; the error context for any error message, and CONTEXT is a string
1508 ;;; that is spliced into the warning.
1509 (declaim (ftype (sfunction ((or symbol function) list node function string)
1510                           (values list boolean))
1511                 careful-call))
1512 (defun careful-call (function args node warn-fun context)
1513   (values
1514    (multiple-value-list
1515     (handler-case (apply function args)
1516       (error (condition)
1517         (let ((*compiler-error-context* node))
1518           (funcall warn-fun "Lisp error during ~A:~%~A" context condition)
1519           (return-from careful-call (values nil nil))))))
1520    t))
1521
1522 ;;; Variations of SPECIFIER-TYPE for parsing possibly wrong
1523 ;;; specifiers.
1524 (macrolet
1525     ((deffrob (basic careful compiler transform)
1526        `(progn
1527           (defun ,careful (specifier)
1528             (handler-case (,basic specifier)
1529               (sb!kernel::arg-count-error (condition)
1530                 (values nil (list (format nil "~A" condition))))
1531               (simple-error (condition)
1532                 (values nil (list* (simple-condition-format-control condition)
1533                                    (simple-condition-format-arguments condition))))))
1534           (defun ,compiler (specifier)
1535             (multiple-value-bind (type error-args) (,careful specifier)
1536               (or type
1537                   (apply #'compiler-error error-args))))
1538           (defun ,transform (specifier)
1539             (multiple-value-bind (type error-args) (,careful specifier)
1540               (or type
1541                   (apply #'give-up-ir1-transform
1542                          error-args)))))))
1543   (deffrob specifier-type careful-specifier-type compiler-specifier-type ir1-transform-specifier-type)
1544   (deffrob values-specifier-type careful-values-specifier-type compiler-values-specifier-type ir1-transform-values-specifier-type))
1545
1546 \f
1547 ;;;; utilities used at run-time for parsing &KEY args in IR1
1548
1549 ;;; This function is used by the result of PARSE-DEFTRANSFORM to find
1550 ;;; the lvar for the value of the &KEY argument KEY in the list of
1551 ;;; lvars ARGS. It returns the lvar if the keyword is present, or NIL
1552 ;;; otherwise. The legality and constantness of the keywords should
1553 ;;; already have been checked.
1554 (declaim (ftype (sfunction (list keyword) (or lvar null))
1555                 find-keyword-lvar))
1556 (defun find-keyword-lvar (args key)
1557   (do ((arg args (cddr arg)))
1558       ((null arg) nil)
1559     (when (eq (lvar-value (first arg)) key)
1560       (return (second arg)))))
1561
1562 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1563 ;;; verify that alternating lvars in ARGS are constant and that there
1564 ;;; is an even number of args.
1565 (declaim (ftype (sfunction (list) boolean) check-key-args-constant))
1566 (defun check-key-args-constant (args)
1567   (do ((arg args (cddr arg)))
1568       ((null arg) t)
1569     (unless (and (rest arg)
1570                  (constant-lvar-p (first arg)))
1571       (return nil))))
1572
1573 ;;; This function is used by the result of PARSE-DEFTRANSFORM to
1574 ;;; verify that the list of lvars ARGS is a well-formed &KEY arglist
1575 ;;; and that only keywords present in the list KEYS are supplied.
1576 (declaim (ftype (sfunction (list list) boolean) check-transform-keys))
1577 (defun check-transform-keys (args keys)
1578   (and (check-key-args-constant args)
1579        (do ((arg args (cddr arg)))
1580            ((null arg) t)
1581          (unless (member (lvar-value (first arg)) keys)
1582            (return nil)))))
1583 \f
1584 ;;;; miscellaneous
1585
1586 ;;; Called by the expansion of the EVENT macro.
1587 (declaim (ftype (sfunction (event-info (or node null)) *) %event))
1588 (defun %event (info node)
1589   (incf (event-info-count info))
1590   (when (and (>= (event-info-level info) *event-note-threshold*)
1591              (policy (or node *lexenv*)
1592                      (= inhibit-warnings 0)))
1593     (let ((*compiler-error-context* node))
1594       (compiler-notify (event-info-description info))))
1595
1596   (let ((action (event-info-action info)))
1597     (when action (funcall action node))))
1598
1599 ;;;
1600 (defun make-cast (value type policy)
1601   (declare (type lvar value)
1602            (type ctype type)
1603            (type policy policy))
1604   (%make-cast :asserted-type type
1605               :type-to-check (maybe-weaken-check type policy)
1606               :value value
1607               :derived-type (coerce-to-values type)))
1608
1609 (defun cast-type-check (cast)
1610   (declare (type cast cast))
1611   (when (cast-reoptimize cast)
1612     (ir1-optimize-cast cast t))
1613   (cast-%type-check cast))
1614
1615 (defun note-single-valuified-lvar (lvar)
1616   (declare (type (or lvar null) lvar))
1617   (when lvar
1618     (let ((use (lvar-uses lvar)))
1619       (cond ((ref-p use)
1620              (let ((leaf (ref-leaf use)))
1621                (when (and (lambda-var-p leaf)
1622                           (null (rest (leaf-refs leaf))))
1623                  (reoptimize-lambda-var leaf))))
1624             ((or (listp use) (combination-p use))
1625              (do-uses (node lvar)
1626                (setf (node-reoptimize node) t)
1627                (setf (block-reoptimize (node-block node)) t)
1628                (setf (component-reoptimize (node-component node)) t)))))))