src/compiler/ir2tran.lisp

   1 ;;;; This file contains the virtual-machine-independent parts of the
   2 ;;;; code which does the actual translation of nodes to VOPs.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; moves and type checks
  16
  17 ;;; Move X to Y unless they are EQ.
  18 (defun emit-move (node block x y)
  19   (declare (type node node) (type ir2-block block) (type tn x y))
  20   (unless (eq x y)
  21     (vop move node block x y))
  22   (values))
  23
  24 ;;; If there is any CHECK-xxx template for TYPE, then return it,
  25 ;;; otherwise return NIL.
  26 (defun type-check-template (type)
  27   (declare (type ctype type))
  28   (multiple-value-bind (check-ptype exact) (primitive-type type)
  29     (if exact
  30         (primitive-type-check check-ptype)
  31         (let ((name (hairy-type-check-template-name type)))
  32           (if name
  33               (template-or-lose name)
  34               nil)))))
  35
  36 ;;; Emit code in BLOCK to check that VALUE is of the specified TYPE,
  37 ;;; yielding the checked result in RESULT. VALUE and result may be of
  38 ;;; any primitive type. There must be CHECK-xxx VOP for TYPE. Any
  39 ;;; other type checks should have been converted to an explicit type
  40 ;;; test.
  41 (defun emit-type-check (node block value result type)
  42   (declare (type tn value result) (type node node) (type ir2-block block)
  43            (type ctype type))
  44   (emit-move-template node block (type-check-template type) value result)
  45   (values))
  46
  47 ;;; Allocate an indirect value cell. Maybe do some clever stack
  48 ;;; allocation someday.
  49 (defevent make-value-cell "Allocate heap value cell for lexical var.")
  50 (defun do-make-value-cell (node block value res)
  51   (event make-value-cell node)
  52   (vop make-value-cell node block value res))
  53 \f
  54 ;;;; leaf reference
  55
  56 ;;; Return the TN that holds the value of THING in the environment ENV.
  57 (defun find-in-environment (thing env)
  58   (declare (type (or nlx-info lambda-var) thing) (type environment env)
  59            (values tn))
  60   (or (cdr (assoc thing (ir2-environment-environment (environment-info env))))
  61       (etypecase thing
  62         (lambda-var
  63          ;; I think that a failure of this assertion means that we're
  64          ;; trying to access a variable which was improperly closed
  65          ;; over. An ENVIRONMENT structure is a physical environment.
  66          ;; Every variable that a form refers to should either be in
  67          ;; its physical environment directly, or grabbed from a
  68          ;; surrounding physical environment when it was closed over.
  69          ;; The ASSOC expression above finds closed-over variables, so
  70          ;; if we fell through the ASSOC expression, it wasn't closed
  71          ;; over. Therefore, it must be in our physical environment
  72          ;; directly. If instead it is in some other physical
  73          ;; environment, then it's bogus for us to reference it here
  74          ;; without it being closed over. -- WHN 2001-09-29
  75          (aver (eq env (lambda-environment (lambda-var-home thing))))
  76          (leaf-info thing))
  77         (nlx-info
  78          (aver (eq env (block-environment (nlx-info-target thing))))
  79          (ir2-nlx-info-home (nlx-info-info thing))))))
  80
  81 ;;; If LEAF already has a constant TN, return that, otherwise make a
  82 ;;; TN for it.
  83 (defun constant-tn (leaf)
  84   (declare (type constant leaf))
  85   (or (leaf-info leaf)
  86       (setf (leaf-info leaf)
  87             (make-constant-tn leaf))))
  88
  89 ;;; Return a TN that represents the value of LEAF, or NIL if LEAF
  90 ;;; isn't directly represented by a TN. ENV is the environment that
  91 ;;; the reference is done in.
  92 (defun leaf-tn (leaf env)
  93   (declare (type leaf leaf) (type environment env))
  94   (typecase leaf
  95     (lambda-var
  96      (unless (lambda-var-indirect leaf)
  97        (find-in-environment leaf env)))
  98     (constant (constant-tn leaf))
  99     (t nil)))
 100
 101 ;;; This is used to conveniently get a handle on a constant TN during
 102 ;;; IR2 conversion. It returns a constant TN representing the Lisp
 103 ;;; object VALUE.
 104 (defun emit-constant (value)
 105   (constant-tn (find-constant value)))
 106
 107 ;;; Convert a REF node. The reference must not be delayed.
 108 (defun ir2-convert-ref (node block)
 109   (declare (type ref node) (type ir2-block block))
 110   (let* ((cont (node-cont node))
 111          (leaf (ref-leaf node))
 112          (name (leaf-name leaf))
 113          (locs (continuation-result-tns
 114                 cont (list (primitive-type (leaf-type leaf)))))
 115          (res (first locs)))
 116     (etypecase leaf
 117       (lambda-var
 118        (let ((tn (find-in-environment leaf (node-environment node))))
 119          (if (lambda-var-indirect leaf)
 120              (vop value-cell-ref node block tn res)
 121              (emit-move node block tn res))))
 122       (constant
 123        (if (legal-immediate-constant-p leaf)
 124            (emit-move node block (constant-tn leaf) res)
 125            (let ((name-tn (emit-constant name)))
 126              (if (policy node (zerop safety))
 127                  (vop fast-symbol-value node block name-tn res)
 128                  (vop symbol-value node block name-tn res)))))
 129       (functional
 130        (ir2-convert-closure node block leaf res))
 131       (global-var
 132        (let ((unsafe (policy node (zerop safety))))
 133          (ecase (global-var-kind leaf)
 134            ((:special :global :constant)
 135             (aver (symbolp name))
 136             (let ((name-tn (emit-constant name)))
 137               (if unsafe
 138                   (vop fast-symbol-value node block name-tn res)
 139                   (vop symbol-value node block name-tn res))))
 140            (:global-function
 141             (let ((fdefn-tn (make-load-time-constant-tn :fdefinition name)))
 142               (if unsafe
 143                   (vop fdefn-function node block fdefn-tn res)
 144                   (vop safe-fdefn-function node block fdefn-tn res))))))))
 145     (move-continuation-result node block locs cont))
 146   (values))
 147
 148 ;;; Emit code to load a function object representing LEAF into RES.
 149 ;;; This gets interesting when the referenced function is a closure:
 150 ;;; we must make the closure and move the closed over values into it.
 151 ;;;
 152 ;;; LEAF is either a :TOP-LEVEL-XEP functional or the XEP lambda for
 153 ;;; the called function, since local call analysis converts all
 154 ;;; closure references. If a TL-XEP, we know it is not a closure.
 155 ;;;
 156 ;;; If a closed-over lambda-var has no refs (is deleted), then we
 157 ;;; don't initialize that slot. This can happen with closures over
 158 ;;; top-level variables, where optimization of the closure deleted the
 159 ;;; variable. Since we committed to the closure format when we
 160 ;;; pre-analyzed the top-level code, we just leave an empty slot.
 161 #!-gengc
 162 (defun ir2-convert-closure (node block leaf res)
 163   (declare (type ref node) (type ir2-block block)
 164            (type functional leaf) (type tn res))
 165   (unless (leaf-info leaf)
 166     (setf (leaf-info leaf) (make-entry-info)))
 167   (let ((entry (make-load-time-constant-tn :entry leaf))
 168         (closure (etypecase leaf
 169                    (clambda
 170                     (environment-closure (get-lambda-environment leaf)))
 171                    (functional
 172                     (aver (eq (functional-kind leaf) :top-level-xep))
 173                     nil))))
 174     (cond (closure
 175            (let ((this-env (node-environment node)))
 176              (vop make-closure node block entry (length closure) res)
 177              (loop for what in closure and n from 0 do
 178                (unless (and (lambda-var-p what)
 179                             (null (leaf-refs what)))
 180                  (vop closure-init node block
 181                       res
 182                       (find-in-environment what this-env)
 183                       n)))))
 184           (t
 185            (emit-move node block entry res))))
 186   (values))
 187
 188 ;;; Convert a SET node. If the node's CONT is annotated, then we also
 189 ;;; deliver the value to that continuation. If the var is a lexical
 190 ;;; variable with no refs, then we don't actually set anything, since
 191 ;;; the variable has been deleted.
 192 (defun ir2-convert-set (node block)
 193   (declare (type cset node) (type ir2-block block))
 194   (let* ((cont (node-cont node))
 195          (leaf (set-var node))
 196          (val (continuation-tn node block (set-value node)))
 197          (locs (if (continuation-info cont)
 198                    (continuation-result-tns
 199                     cont (list (primitive-type (leaf-type leaf))))
 200                    nil)))
 201     (etypecase leaf
 202       (lambda-var
 203        (when (leaf-refs leaf)
 204          (let ((tn (find-in-environment leaf (node-environment node))))
 205            (if (lambda-var-indirect leaf)
 206                (vop value-cell-set node block tn val)
 207                (emit-move node block val tn)))))
 208       (global-var
 209        (ecase (global-var-kind leaf)
 210          ((:special :global)
 211           (aver (symbolp (leaf-name leaf)))
 212           (vop set node block (emit-constant (leaf-name leaf)) val)))))
 213     (when locs
 214       (emit-move node block val (first locs))
 215       (move-continuation-result node block locs cont)))
 216   (values))
 217 \f
 218 ;;;; utilities for receiving fixed values
 219
 220 ;;; Return a TN that can be referenced to get the value of CONT. CONT
 221 ;;; must be LTN-Annotated either as a delayed leaf ref or as a fixed,
 222 ;;; single-value continuation. If a type check is called for, do it.
 223 ;;;
 224 ;;; The primitive-type of the result will always be the same as the
 225 ;;; IR2-CONTINUATION-PRIMITIVE-TYPE, ensuring that VOPs are always
 226 ;;; called with TNs that satisfy the operand primitive-type
 227 ;;; restriction. We may have to make a temporary of the desired type
 228 ;;; and move the actual continuation TN into it. This happens when we
 229 ;;; delete a type check in unsafe code or when we locally know
 230 ;;; something about the type of an argument variable.
 231 (defun continuation-tn (node block cont)
 232   (declare (type node node) (type ir2-block block) (type continuation cont))
 233   (let* ((2cont (continuation-info cont))
 234          (cont-tn
 235           (ecase (ir2-continuation-kind 2cont)
 236             (:delayed
 237              (let ((ref (continuation-use cont)))
 238                (leaf-tn (ref-leaf ref) (node-environment ref))))
 239             (:fixed
 240              (aver (= (length (ir2-continuation-locs 2cont)) 1))
 241              (first (ir2-continuation-locs 2cont)))))
 242          (ptype (ir2-continuation-primitive-type 2cont)))
 243
 244     (cond ((and (eq (continuation-type-check cont) t)
 245                 (multiple-value-bind (check types)
 246                     (continuation-check-types cont)
 247                   (aver (eq check :simple))
 248                   ;; If the proven type is a subtype of the possibly
 249                   ;; weakened type check then it's always true and is
 250                   ;; flushed.
 251                   (unless (values-subtypep (continuation-proven-type cont)
 252                                            (first types))
 253                     (let ((temp (make-normal-tn ptype)))
 254                       (emit-type-check node block cont-tn temp
 255                                        (first types))
 256                       temp)))))
 257           ((eq (tn-primitive-type cont-tn) ptype) cont-tn)
 258           (t
 259            (let ((temp (make-normal-tn ptype)))
 260              (emit-move node block cont-tn temp)
 261              temp)))))
 262
 263 ;;; This is similar to CONTINUATION-TN, but hacks multiple values. We
 264 ;;; return continuations holding the values of CONT with PTYPES as
 265 ;;; their primitive types. CONT must be annotated for the same number
 266 ;;; of fixed values are there are PTYPES.
 267 ;;;
 268 ;;; If the continuation has a type check, check the values into temps
 269 ;;; and return the temps. When we have more values than assertions, we
 270 ;;; move the extra values with no check.
 271 (defun continuation-tns (node block cont ptypes)
 272   (declare (type node node) (type ir2-block block)
 273            (type continuation cont) (list ptypes))
 274   (let* ((locs (ir2-continuation-locs (continuation-info cont)))
 275          (nlocs (length locs)))
 276     (aver (= nlocs (length ptypes)))
 277     (if (eq (continuation-type-check cont) t)
 278         (multiple-value-bind (check types) (continuation-check-types cont)
 279           (aver (eq check :simple))
 280           (let ((ntypes (length types)))
 281             (mapcar #'(lambda (from to-type assertion)
 282                         (let ((temp (make-normal-tn to-type)))
 283                           (if assertion
 284                               (emit-type-check node block from temp assertion)
 285                               (emit-move node block from temp))
 286                           temp))
 287                     locs ptypes
 288                     (if (< ntypes nlocs)
 289                         (append types (make-list (- nlocs ntypes)
 290                                                  :initial-element nil))
 291                         types))))
 292         (mapcar #'(lambda (from to-type)
 293                     (if (eq (tn-primitive-type from) to-type)
 294                         from
 295                         (let ((temp (make-normal-tn to-type)))
 296                           (emit-move node block from temp)
 297                           temp)))
 298                 locs
 299                 ptypes))))
 300 \f
 301 ;;;; utilities for delivering values to continuations
 302
 303 ;;; Return a list of TNs with the specifier TYPES that can be used as
 304 ;;; result TNs to evaluate an expression into the continuation CONT.
 305 ;;; This is used together with MOVE-CONTINUATION-RESULT to deliver
 306 ;;; fixed values to a continuation.
 307 ;;;
 308 ;;; If the continuation isn't annotated (meaning the values are
 309 ;;; discarded) or is unknown-values, the then we make temporaries for
 310 ;;; each supplied value, providing a place to compute the result in
 311 ;;; until we decide what to do with it (if anything.)
 312 ;;;
 313 ;;; If the continuation is fixed-values, and wants the same number of
 314 ;;; values as the user wants to deliver, then we just return the
 315 ;;; IR2-CONTINUATION-LOCS. Otherwise we make a new list padded as
 316 ;;; necessary by discarded TNs. We always return a TN of the specified
 317 ;;; type, using the continuation locs only when they are of the
 318 ;;; correct type.
 319 (defun continuation-result-tns (cont types)
 320   (declare (type continuation cont) (type list types))
 321   (let ((2cont (continuation-info cont)))
 322     (if (not 2cont)
 323         (mapcar #'make-normal-tn types)
 324         (ecase (ir2-continuation-kind 2cont)
 325           (:fixed
 326            (let* ((locs (ir2-continuation-locs 2cont))
 327                   (nlocs (length locs))
 328                   (ntypes (length types)))
 329              (if (and (= nlocs ntypes)
 330                       (do ((loc locs (cdr loc))
 331                            (type types (cdr type)))
 332                           ((null loc) t)
 333                         (unless (eq (tn-primitive-type (car loc)) (car type))
 334                           (return nil))))
 335                  locs
 336                  (mapcar #'(lambda (loc type)
 337                              (if (eq (tn-primitive-type loc) type)
 338                                  loc
 339                                  (make-normal-tn type)))
 340                          (if (< nlocs ntypes)
 341                              (append locs
 342                                      (mapcar #'make-normal-tn
 343                                              (subseq types nlocs)))
 344                              locs)
 345                          types))))
 346           (:unknown
 347            (mapcar #'make-normal-tn types))))))
 348
 349 ;;; Make the first N standard value TNs, returning them in a list.
 350 (defun make-standard-value-tns (n)
 351   (declare (type unsigned-byte n))
 352   (collect ((res))
 353     (dotimes (i n)
 354       (res (standard-argument-location i)))
 355     (res)))
 356
 357 ;;; Return a list of TNs wired to the standard value passing
 358 ;;; conventions that can be used to receive values according to the
 359 ;;; unknown-values convention. This is used with together
 360 ;;; MOVE-CONTINUATION-RESULT for delivering unknown values to a fixed
 361 ;;; values continuation.
 362 ;;;
 363 ;;; If the continuation isn't annotated, then we treat as 0-values,
 364 ;;; returning an empty list of temporaries.
 365 ;;;
 366 ;;; If the continuation is annotated, then it must be :FIXED.
 367 (defun standard-result-tns (cont)
 368   (declare (type continuation cont))
 369   (let ((2cont (continuation-info cont)))
 370     (if 2cont
 371         (ecase (ir2-continuation-kind 2cont)
 372           (:fixed
 373            (make-standard-value-tns (length (ir2-continuation-locs 2cont)))))
 374         ())))
 375
 376 ;;; Just move each SRC TN into the corresponding DEST TN, defaulting
 377 ;;; any unsupplied source values to NIL. We let EMIT-MOVE worry about
 378 ;;; doing the appropriate coercions.
 379 (defun move-results-coerced (node block src dest)
 380   (declare (type node node) (type ir2-block block) (list src dest))
 381   (let ((nsrc (length src))
 382         (ndest (length dest)))
 383     (mapc #'(lambda (from to)
 384               (unless (eq from to)
 385                 (emit-move node block from to)))
 386           (if (> ndest nsrc)
 387               (append src (make-list (- ndest nsrc)
 388                                      :initial-element (emit-constant nil)))
 389               src)
 390           dest))
 391   (values))
 392
 393 ;;; If necessary, emit coercion code needed to deliver the Results to
 394 ;;; the specified continuation. NODE and BLOCK provide context for
 395 ;;; emitting code. Although usually obtained from STANDARD-RESULT-TNs
 396 ;;; or CONTINUATION-RESULT-TNs, RESULTS my be a list of any type or
 397 ;;; number of TNs.
 398 ;;;
 399 ;;; If the continuation is fixed values, then move the results into
 400 ;;; the continuation locations. If the continuation is unknown values,
 401 ;;; then do the moves into the standard value locations, and use
 402 ;;; PUSH-VALUES to put the values on the stack.
 403 (defun move-continuation-result (node block results cont)
 404   (declare (type node node) (type ir2-block block)
 405            (list results) (type continuation cont))
 406   (let* ((2cont (continuation-info cont)))
 407     (when 2cont
 408       (ecase (ir2-continuation-kind 2cont)
 409         (:fixed
 410          (let ((locs (ir2-continuation-locs 2cont)))
 411            (unless (eq locs results)
 412              (move-results-coerced node block results locs))))
 413         (:unknown
 414          (let* ((nvals (length results))
 415                 (locs (make-standard-value-tns nvals)))
 416            (move-results-coerced node block results locs)
 417            (vop* push-values node block
 418                  ((reference-tn-list locs nil))
 419                  ((reference-tn-list (ir2-continuation-locs 2cont) t))
 420                  nvals))))))
 421   (values))
 422 \f
 423 ;;;; template conversion
 424
 425 ;;; Build a TN-Refs list that represents access to the values of the
 426 ;;; specified list of continuations ARGS for TEMPLATE. Any :CONSTANT
 427 ;;; arguments are returned in the second value as a list rather than
 428 ;;; being accessed as a normal argument. NODE and BLOCK provide the
 429 ;;; context for emitting any necessary type-checking code.
 430 (defun reference-arguments (node block args template)
 431   (declare (type node node) (type ir2-block block) (list args)
 432            (type template template))
 433   (collect ((info-args))
 434     (let ((last nil)
 435           (first nil))
 436       (do ((args args (cdr args))
 437            (types (template-arg-types template) (cdr types)))
 438           ((null args))
 439         (let ((type (first types))
 440               (arg (first args)))
 441           (if (and (consp type) (eq (car type) ':constant))
 442               (info-args (continuation-value arg))
 443               (let ((ref (reference-tn (continuation-tn node block arg) nil)))
 444                 (if last
 445                     (setf (tn-ref-across last) ref)
 446                     (setf first ref))
 447                 (setq last ref)))))
 448
 449       (values (the (or tn-ref null) first) (info-args)))))
 450
 451 ;;; Convert a conditional template. We try to exploit any
 452 ;;; drop-through, but emit an unconditional branch afterward if we
 453 ;;; fail. NOT-P is true if the sense of the TEMPLATE's test should be
 454 ;;; negated.
 455 (defun ir2-convert-conditional (node block template args info-args if not-p)
 456   (declare (type node node) (type ir2-block block)
 457            (type template template) (type (or tn-ref null) args)
 458            (list info-args) (type cif if) (type boolean not-p))
 459   (aver (= (template-info-arg-count template) (+ (length info-args) 2)))
 460   (let ((consequent (if-consequent if))
 461         (alternative (if-alternative if)))
 462     (cond ((drop-thru-p if consequent)
 463            (emit-template node block template args nil
 464                           (list* (block-label alternative) (not not-p)
 465                                  info-args)))
 466           (t
 467            (emit-template node block template args nil
 468                           (list* (block-label consequent) not-p info-args))
 469            (unless (drop-thru-p if alternative)
 470              (vop branch node block (block-label alternative)))))))
 471
 472 ;;; Convert an IF that isn't the DEST of a conditional template.
 473 (defun ir2-convert-if (node block)
 474   (declare (type ir2-block block) (type cif node))
 475   (let* ((test (if-test node))
 476          (test-ref (reference-tn (continuation-tn node block test) nil))
 477          (nil-ref (reference-tn (emit-constant nil) nil)))
 478     (setf (tn-ref-across test-ref) nil-ref)
 479     (ir2-convert-conditional node block (template-or-lose 'if-eq)
 480                              test-ref () node t)))
 481
 482 ;;; Return a list of primitive-types that we can pass to
 483 ;;; CONTINUATION-RESULT-TNS describing the result types we want for a
 484 ;;; template call. We duplicate here the determination of output type
 485 ;;; that was done in initially selecting the template, so we know that
 486 ;;; the types we find are allowed by the template output type
 487 ;;; restrictions.
 488 (defun find-template-result-types (call cont template rtypes)
 489   (declare (type combination call) (type continuation cont)
 490            (type template template) (list rtypes))
 491   (let* ((dtype (node-derived-type call))
 492          (type (if (and (or (eq (template-ltn-policy template) :safe)
 493                             (policy call (= safety 0)))
 494                         (continuation-type-check cont))
 495                    (values-type-intersection
 496                     dtype
 497                     (continuation-asserted-type cont))
 498                    dtype))
 499          (types (mapcar #'primitive-type
 500                         (if (values-type-p type)
 501                             (append (values-type-required type)
 502                                     (values-type-optional type))
 503                             (list type)))))
 504     (let ((nvals (length rtypes))
 505           (ntypes (length types)))
 506       (cond ((< ntypes nvals)
 507              (append types
 508                      (make-list (- nvals ntypes)
 509                                 :initial-element *backend-t-primitive-type*)))
 510             ((> ntypes nvals)
 511              (subseq types 0 nvals))
 512             (t
 513              types)))))
 514
 515 ;;; Return a list of TNs usable in a CALL to TEMPLATE delivering
 516 ;;; values to CONT. As an efficiency hack, we pick off the common case
 517 ;;; where the continuation is fixed values and has locations that
 518 ;;; satisfy the result restrictions. This can fail when there is a
 519 ;;; type check or a values count mismatch.
 520 (defun make-template-result-tns (call cont template rtypes)
 521   (declare (type combination call) (type continuation cont)
 522            (type template template) (list rtypes))
 523   (let ((2cont (continuation-info cont)))
 524     (if (and 2cont (eq (ir2-continuation-kind 2cont) :fixed))
 525         (let ((locs (ir2-continuation-locs 2cont)))
 526           (if (and (= (length rtypes) (length locs))
 527                    (do ((loc locs (cdr loc))
 528                         (rtype rtypes (cdr rtype)))
 529                        ((null loc) t)
 530                      (unless (operand-restriction-ok
 531                               (car rtype)
 532                               (tn-primitive-type (car loc))
 533                               :t-ok nil)
 534                        (return nil))))
 535               locs
 536               (continuation-result-tns
 537                cont
 538                (find-template-result-types call cont template rtypes))))
 539         (continuation-result-tns
 540          cont
 541          (find-template-result-types call cont template rtypes)))))
 542
 543 ;;; Get the operands into TNs, make TN-Refs for them, and then call
 544 ;;; the template emit function.
 545 (defun ir2-convert-template (call block)
 546   (declare (type combination call) (type ir2-block block))
 547   (let* ((template (combination-info call))
 548          (cont (node-cont call))
 549          (rtypes (template-result-types template)))
 550     (multiple-value-bind (args info-args)
 551         (reference-arguments call block (combination-args call) template)
 552       (aver (not (template-more-results-type template)))
 553       (if (eq rtypes :conditional)
 554           (ir2-convert-conditional call block template args info-args
 555                                    (continuation-dest cont) nil)
 556           (let* ((results (make-template-result-tns call cont template rtypes))
 557                  (r-refs (reference-tn-list results t)))
 558             (aver (= (length info-args)
 559                      (template-info-arg-count template)))
 560             (if info-args
 561                 (emit-template call block template args r-refs info-args)
 562                 (emit-template call block template args r-refs))
 563             (move-continuation-result call block results cont)))))
 564   (values))
 565
 566 ;;; We don't have to do much because operand count checking is done by
 567 ;;; IR1 conversion. The only difference between this and the function
 568 ;;; case of IR2-CONVERT-TEMPLATE is that there can be codegen-info
 569 ;;; arguments.
 570 (defoptimizer (%%primitive ir2-convert) ((template info &rest args) call block)
 571   (let* ((template (continuation-value template))
 572          (info (continuation-value info))
 573          (cont (node-cont call))
 574          (rtypes (template-result-types template))
 575          (results (make-template-result-tns call cont template rtypes))
 576          (r-refs (reference-tn-list results t)))
 577     (multiple-value-bind (args info-args)
 578         (reference-arguments call block (cddr (combination-args call))
 579                              template)
 580       (aver (not (template-more-results-type template)))
 581       (aver (not (eq rtypes :conditional)))
 582       (aver (null info-args))
 583
 584       (if info
 585           (emit-template call block template args r-refs info)
 586           (emit-template call block template args r-refs))
 587
 588       (move-continuation-result call block results cont)))
 589   (values))
 590 \f
 591 ;;;; local call
 592
 593 ;;; Convert a LET by moving the argument values into the variables.
 594 ;;; Since a LET doesn't have any passing locations, we move the
 595 ;;; arguments directly into the variables. We must also allocate any
 596 ;;; indirect value cells, since there is no function prologue to do
 597 ;;; this.
 598 (defun ir2-convert-let (node block fun)
 599   (declare (type combination node) (type ir2-block block) (type clambda fun))
 600   (mapc #'(lambda (var arg)
 601             (when arg
 602               (let ((src (continuation-tn node block arg))
 603                     (dest (leaf-info var)))
 604                 (if (lambda-var-indirect var)
 605                     (do-make-value-cell node block src dest)
 606                     (emit-move node block src dest)))))
 607         (lambda-vars fun) (basic-combination-args node))
 608   (values))
 609
 610 ;;; Emit any necessary moves into assignment temps for a local call to
 611 ;;; FUN. We return two lists of TNs: TNs holding the actual argument
 612 ;;; values, and (possibly EQ) TNs that are the actual destination of
 613 ;;; the arguments. When necessary, we allocate temporaries for
 614 ;;; arguments to preserve parallel assignment semantics. These lists
 615 ;;; exclude unused arguments and include implicit environment
 616 ;;; arguments, i.e. they exactly correspond to the arguments passed.
 617 ;;;
 618 ;;; OLD-FP is the TN currently holding the value we want to pass as
 619 ;;; OLD-FP. If null, then the call is to the same environment (an
 620 ;;; :ASSIGNMENT), so we only move the arguments, and leave the
 621 ;;; environment alone.
 622 (defun emit-psetq-moves (node block fun old-fp)
 623   (declare (type combination node) (type ir2-block block) (type clambda fun)
 624            (type (or tn null) old-fp))
 625   (let* ((called-env (environment-info (lambda-environment fun)))
 626          (this-1env (node-environment node))
 627          (actuals (mapcar #'(lambda (x)
 628                              (when x
 629                                (continuation-tn node block x)))
 630                          (combination-args node))))
 631     (collect ((temps)
 632               (locs))
 633       (dolist (var (lambda-vars fun))
 634         (let ((actual (pop actuals))
 635               (loc (leaf-info var)))
 636           (when actual
 637             (cond
 638              ((lambda-var-indirect var)
 639               (let ((temp
 640                      (make-normal-tn *backend-t-primitive-type*)))
 641                 (do-make-value-cell node block actual temp)
 642                 (temps temp)))
 643              ((member actual (locs))
 644               (let ((temp (make-normal-tn (tn-primitive-type loc))))
 645                 (emit-move node block actual temp)
 646                 (temps temp)))
 647              (t
 648               (temps actual)))
 649             (locs loc))))
 650
 651       (when old-fp
 652         (dolist (thing (ir2-environment-environment called-env))
 653           (temps (find-in-environment (car thing) this-1env))
 654           (locs (cdr thing)))
 655
 656         (temps old-fp)
 657         (locs (ir2-environment-old-fp called-env)))
 658
 659       (values (temps) (locs)))))
 660
 661 ;;; A tail-recursive local call is done by emitting moves of stuff
 662 ;;; into the appropriate passing locations. After setting up the args
 663 ;;; and environment, we just move our return-pc into the called
 664 ;;; function's passing location.
 665 (defun ir2-convert-tail-local-call (node block fun)
 666   (declare (type combination node) (type ir2-block block) (type clambda fun))
 667   (let ((this-env (environment-info (node-environment node))))
 668     (multiple-value-bind (temps locs)
 669         (emit-psetq-moves node block fun (ir2-environment-old-fp this-env))
 670
 671       (mapc #'(lambda (temp loc)
 672                 (emit-move node block temp loc))
 673             temps locs))
 674
 675     (emit-move node block
 676                (ir2-environment-return-pc this-env)
 677                (ir2-environment-return-pc-pass
 678                 (environment-info
 679                  (lambda-environment fun)))))
 680
 681   (values))
 682
 683 ;;; Convert an :ASSIGNMENT call. This is just like a tail local call,
 684 ;;; except that the caller and callee environment are the same, so we
 685 ;;; don't need to mess with the environment locations, return PC, etc.
 686 (defun ir2-convert-assignment (node block fun)
 687   (declare (type combination node) (type ir2-block block) (type clambda fun))
 688     (multiple-value-bind (temps locs) (emit-psetq-moves node block fun nil)
 689
 690       (mapc #'(lambda (temp loc)
 691                 (emit-move node block temp loc))
 692             temps locs))
 693   (values))
 694
 695 ;;; Do stuff to set up the arguments to a non-tail local call
 696 ;;; (including implicit environment args.) We allocate a frame
 697 ;;; (returning the FP and NFP), and also compute the TN-REFS list for
 698 ;;; the values to pass and the list of passing location TNs.
 699 (defun ir2-convert-local-call-args (node block fun)
 700   (declare (type combination node) (type ir2-block block) (type clambda fun))
 701   (let ((fp (make-stack-pointer-tn))
 702         (nfp (make-number-stack-pointer-tn))
 703         (old-fp (make-stack-pointer-tn)))
 704     (multiple-value-bind (temps locs)
 705         (emit-psetq-moves node block fun old-fp)
 706       (vop current-fp node block old-fp)
 707       (vop allocate-frame node block
 708            (environment-info (lambda-environment fun))
 709            fp nfp)
 710       (values fp nfp temps (mapcar #'make-alias-tn locs)))))
 711
 712 ;;; Handle a non-TR known-values local call. We emit the call, then
 713 ;;; move the results to the continuation's destination.
 714 (defun ir2-convert-local-known-call (node block fun returns cont start)
 715   (declare (type node node) (type ir2-block block) (type clambda fun)
 716            (type return-info returns) (type continuation cont)
 717            (type label start))
 718   (multiple-value-bind (fp nfp temps arg-locs)
 719       (ir2-convert-local-call-args node block fun)
 720     (let ((locs (return-info-locations returns)))
 721       (vop* known-call-local node block
 722             (fp nfp (reference-tn-list temps nil))
 723             ((reference-tn-list locs t))
 724             arg-locs (environment-info (lambda-environment fun)) start)
 725       (move-continuation-result node block locs cont)))
 726   (values))
 727
 728 ;;; Handle a non-TR unknown-values local call. We do different things
 729 ;;; depending on what kind of values the continuation wants.
 730 ;;;
 731 ;;; If CONT is :UNKNOWN, then we use the "multiple-" variant, directly
 732 ;;; specifying the continuation's LOCS as the VOP results so that we
 733 ;;; don't have to do anything after the call.
 734 ;;;
 735 ;;; Otherwise, we use STANDARD-RESULT-TNS to get wired result TNs, and
 736 ;;; then call MOVE-CONTINUATION-RESULT to do any necessary type checks
 737 ;;; or coercions.
 738 (defun ir2-convert-local-unknown-call (node block fun cont start)
 739   (declare (type node node) (type ir2-block block) (type clambda fun)
 740            (type continuation cont) (type label start))
 741   (multiple-value-bind (fp nfp temps arg-locs)
 742       (ir2-convert-local-call-args node block fun)
 743     (let ((2cont (continuation-info cont))
 744           (env (environment-info (lambda-environment fun)))
 745           (temp-refs (reference-tn-list temps nil)))
 746       (if (and 2cont (eq (ir2-continuation-kind 2cont) :unknown))
 747           (vop* multiple-call-local node block (fp nfp temp-refs)
 748                 ((reference-tn-list (ir2-continuation-locs 2cont) t))
 749                 arg-locs env start)
 750           (let ((locs (standard-result-tns cont)))
 751             (vop* call-local node block
 752                   (fp nfp temp-refs)
 753                   ((reference-tn-list locs t))
 754                   arg-locs env start (length locs))
 755             (move-continuation-result node block locs cont)))))
 756   (values))
 757
 758 ;;; Dispatch to the appropriate function, depending on whether we have
 759 ;;; a let, tail or normal call. If the function doesn't return, call
 760 ;;; it using the unknown-value convention. We could compile it as a
 761 ;;; tail call, but that might seem confusing in the debugger.
 762 (defun ir2-convert-local-call (node block)
 763   (declare (type combination node) (type ir2-block block))
 764   (let* ((fun (ref-leaf (continuation-use (basic-combination-fun node))))
 765          (kind (functional-kind fun)))
 766     (cond ((eq kind :let)
 767            (ir2-convert-let node block fun))
 768           ((eq kind :assignment)
 769            (ir2-convert-assignment node block fun))
 770           ((node-tail-p node)
 771            (ir2-convert-tail-local-call node block fun))
 772           (t
 773            (let ((start (block-label (node-block (lambda-bind fun))))
 774                  (returns (tail-set-info (lambda-tail-set fun)))
 775                  (cont (node-cont node)))
 776              (ecase (if returns
 777                         (return-info-kind returns)
 778                         :unknown)
 779                (:unknown
 780                 (ir2-convert-local-unknown-call node block fun cont start))
 781                (:fixed
 782                 (ir2-convert-local-known-call node block fun returns
 783                                               cont start)))))))
 784   (values))
 785 \f
 786 ;;;; full call
 787
 788 ;;; Given a function continuation Fun, return as values a TN holding
 789 ;;; the thing that we call and true if the thing is named (false if it
 790 ;;; is a function). There are two interesting non-named cases:
 791 ;;; -- Known to be a function, no check needed: return the continuation loc.
 792 ;;; -- Not known what it is.
 793 (defun function-continuation-tn (node block cont)
 794   (declare (type continuation cont))
 795   (let ((2cont (continuation-info cont)))
 796     (if (eq (ir2-continuation-kind 2cont) :delayed)
 797         (let ((name (continuation-function-name cont t)))
 798           (aver name)
 799           (values (make-load-time-constant-tn :fdefinition name) t))
 800         (let* ((locs (ir2-continuation-locs 2cont))
 801                (loc (first locs))
 802                (check (continuation-type-check cont))
 803                (function-ptype (primitive-type-or-lose 'function)))
 804           (aver (and (eq (ir2-continuation-kind 2cont) :fixed)
 805                      (= (length locs) 1)))
 806           (cond ((eq (tn-primitive-type loc) function-ptype)
 807                  (aver (not (eq check t)))
 808                  (values loc nil))
 809                 (t
 810                  (let ((temp (make-normal-tn function-ptype)))
 811                    (aver (and (eq (ir2-continuation-primitive-type 2cont)
 812                                   function-ptype)
 813                               (eq check t)))
 814                    (emit-type-check node block loc temp
 815                                     (specifier-type 'function))
 816                    (values temp nil))))))))
 817
 818 ;;; Set up the args to Node in the current frame, and return a tn-ref
 819 ;;; list for the passing locations.
 820 (defun move-tail-full-call-args (node block)
 821   (declare (type combination node) (type ir2-block block))
 822   (let ((args (basic-combination-args node))
 823         (last nil)
 824         (first nil))
 825     (dotimes (num (length args))
 826       (let ((loc (standard-argument-location num)))
 827         (emit-move node block (continuation-tn node block (elt args num)) loc)
 828         (let ((ref (reference-tn loc nil)))
 829           (if last
 830               (setf (tn-ref-across last) ref)
 831               (setf first ref))
 832           (setq last ref))))
 833       first))
 834
 835 ;;; Move the arguments into the passing locations and do a (possibly
 836 ;;; named) tail call.
 837 (defun ir2-convert-tail-full-call (node block)
 838   (declare (type combination node) (type ir2-block block))
 839   (let* ((env (environment-info (node-environment node)))
 840          (args (basic-combination-args node))
 841          (nargs (length args))
 842          (pass-refs (move-tail-full-call-args node block))
 843          (old-fp (ir2-environment-old-fp env))
 844          (return-pc (ir2-environment-return-pc env)))
 845
 846     (multiple-value-bind (fun-tn named)
 847         (function-continuation-tn node block (basic-combination-fun node))
 848       (if named
 849           (vop* tail-call-named node block
 850                 (fun-tn old-fp return-pc pass-refs)
 851                 (nil)
 852                 nargs)
 853           (vop* tail-call node block
 854                 (fun-tn old-fp return-pc pass-refs)
 855                 (nil)
 856                 nargs))))
 857
 858   (values))
 859
 860 ;;; like IR2-CONVERT-LOCAL-CALL-ARGS, only different
 861 (defun ir2-convert-full-call-args (node block)
 862   (declare (type combination node) (type ir2-block block))
 863   (let* ((args (basic-combination-args node))
 864          (fp (make-stack-pointer-tn))
 865          (nargs (length args)))
 866     (vop allocate-full-call-frame node block nargs fp)
 867     (collect ((locs))
 868       (let ((last nil)
 869             (first nil))
 870         (dotimes (num nargs)
 871           (locs (standard-argument-location num))
 872           (let ((ref (reference-tn (continuation-tn node block (elt args num))
 873                                    nil)))
 874             (if last
 875                 (setf (tn-ref-across last) ref)
 876                 (setf first ref))
 877             (setq last ref)))
 878
 879         (values fp first (locs) nargs)))))
 880
 881 ;;; Do full call when a fixed number of values are desired. We make
 882 ;;; STANDARD-RESULT-TNS for our continuation, then deliver the result
 883 ;;; using MOVE-CONTINUATION-RESULT. We do named or normal call, as
 884 ;;; appropriate.
 885 (defun ir2-convert-fixed-full-call (node block)
 886   (declare (type combination node) (type ir2-block block))
 887   (multiple-value-bind (fp args arg-locs nargs)
 888       (ir2-convert-full-call-args node block)
 889     (let* ((cont (node-cont node))
 890            (locs (standard-result-tns cont))
 891            (loc-refs (reference-tn-list locs t))
 892            (nvals (length locs)))
 893       (multiple-value-bind (fun-tn named)
 894           (function-continuation-tn node block (basic-combination-fun node))
 895         (if named
 896             (vop* call-named node block (fp fun-tn args) (loc-refs)
 897                   arg-locs nargs nvals)
 898             (vop* call node block (fp fun-tn args) (loc-refs)
 899                   arg-locs nargs nvals))
 900         (move-continuation-result node block locs cont))))
 901   (values))
 902
 903 ;;; Do full call when unknown values are desired.
 904 (defun ir2-convert-multiple-full-call (node block)
 905   (declare (type combination node) (type ir2-block block))
 906   (multiple-value-bind (fp args arg-locs nargs)
 907       (ir2-convert-full-call-args node block)
 908     (let* ((cont (node-cont node))
 909            (locs (ir2-continuation-locs (continuation-info cont)))
 910            (loc-refs (reference-tn-list locs t)))
 911       (multiple-value-bind (fun-tn named)
 912           (function-continuation-tn node block (basic-combination-fun node))
 913         (if named
 914             (vop* multiple-call-named node block (fp fun-tn args) (loc-refs)
 915                   arg-locs nargs)
 916             (vop* multiple-call node block (fp fun-tn args) (loc-refs)
 917                   arg-locs nargs)))))
 918   (values))
 919
 920 ;;; stuff to check in CHECK-FULL-CALL
 921 ;;;
 922 ;;; There are some things which are intended always to be optimized
 923 ;;; away by DEFTRANSFORMs and such, and so never compiled into full
 924 ;;; calls. This has been a source of bugs so many times that it seems
 925 ;;; worth listing some of them here so that we can check the list
 926 ;;; whenever we compile a full call.
 927 ;;;
 928 ;;; FIXME: It might be better to represent this property by setting a
 929 ;;; flag in DEFKNOWN, instead of representing it by membership in this
 930 ;;; list.
 931 (defvar *always-optimized-away*
 932   '(;; This should always be DEFTRANSFORMed away, but wasn't in a bug
 933     ;; reported to cmucl-imp@cons.org 2000-06-20.
 934     %instance-ref
 935     ;; These should always turn into VOPs, but wasn't in a bug which
 936     ;; appeared when LTN-POLICY stuff was being tweaked in
 937     ;; sbcl-0.6.9.16. in sbcl-0.6.0
 938     data-vector-set
 939     data-vector-ref))
 940
 941 ;;; more stuff to check in CHECK-FULL-CALL
 942 ;;;
 943 ;;; These came in handy when troubleshooting cold boot after making
 944 ;;; major changes in the package structure: various transforms and
 945 ;;; VOPs and stuff got attached to the wrong symbol, so that
 946 ;;; references to the right symbol were bogusly translated as full
 947 ;;; calls instead of primitives, sending the system off into infinite
 948 ;;; space. Having a report on all full calls generated makes it easier
 949 ;;; to figure out what form caused the problem this time.
 950 #!+sb-show (defvar *show-full-called-fnames-p* nil)
 951 #!+sb-show (defvar *full-called-fnames* (make-hash-table :test 'equal))
 952
 953 ;;; Do some checks on a full call:
 954 ;;;   * Is this a full call to something we have reason to know should
 955 ;;;     never be full called?
 956 ;;;   * Is this a full call to (SETF FOO) which might conflict with
 957 ;;;     a DEFSETF or some such thing elsewhere in the program?
 958 (defun check-full-call (node)
 959   (let* ((cont (basic-combination-fun node))
 960          (fname (continuation-function-name cont t)))
 961     (declare (type (or symbol cons) fname))
 962
 963     #!+sb-show (unless (gethash fname *full-called-fnames*)
 964                  (setf (gethash fname *full-called-fnames*) t))
 965     #!+sb-show (when *show-full-called-fnames-p*
 966                  (/show "converting full call to named function" fname)
 967                  (/show (basic-combination-args node))
 968                  (/show (policy node speed) (policy node safety))
 969                  (/show (policy node compilation-speed))
 970                  (let ((arg-types (mapcar (lambda (maybe-continuation)
 971                                             (when maybe-continuation
 972                                               (type-specifier
 973                                                (continuation-type
 974                                                 maybe-continuation))))
 975                                           (basic-combination-args node))))
 976                    (/show arg-types)))
 977
 978     (when (memq fname *always-optimized-away*)
 979       (/show (policy node speed) (policy node safety))
 980       (/show (policy node compilation-speed))
 981       (error "internal error: full call to ~S" fname))
 982
 983     (when (consp fname)
 984       (destructuring-bind (setf stem) fname
 985         (aver (eq setf 'setf))
 986         (setf (gethash stem *setf-assumed-fboundp*) t)))))
 987
 988 ;;; If the call is in a tail recursive position and the return
 989 ;;; convention is standard, then do a tail full call. If one or fewer
 990 ;;; values are desired, then use a single-value call, otherwise use a
 991 ;;; multiple-values call.
 992 (defun ir2-convert-full-call (node block)
 993   (declare (type combination node) (type ir2-block block))
 994   (check-full-call node)
 995   (let ((2cont (continuation-info (node-cont node))))
 996     (cond ((node-tail-p node)
 997            (ir2-convert-tail-full-call node block))
 998           ((and 2cont
 999                 (eq (ir2-continuation-kind 2cont) :unknown))
1000            (ir2-convert-multiple-full-call node block))
1001           (t
1002            (ir2-convert-fixed-full-call node block))))
1003   (values))
1004 \f
1005 ;;;; entering functions
1006
1007 ;;; Do all the stuff that needs to be done on XEP entry:
1008 ;;; -- Create frame.
1009 ;;; -- Copy any more arg.
1010 ;;; -- Set up the environment, accessing any closure variables.
1011 ;;; -- Move args from the standard passing locations to their internal
1012 ;;;    locations.
1013 (defun init-xep-environment (node block fun)
1014   (declare (type bind node) (type ir2-block block) (type clambda fun))
1015   (let ((start-label (entry-info-offset (leaf-info fun)))
1016         (env (environment-info (node-environment node))))
1017     (let ((ef (functional-entry-function fun)))
1018       (cond ((and (optional-dispatch-p ef) (optional-dispatch-more-entry ef))
1019              ;; Special case the xep-allocate-frame + copy-more-arg case.
1020              (vop xep-allocate-frame node block start-label t)
1021              (vop copy-more-arg node block (optional-dispatch-max-args ef)))
1022             (t
1023              ;; No more args, so normal entry.
1024              (vop xep-allocate-frame node block start-label nil)))
1025       (if (ir2-environment-environment env)
1026           (let ((closure (make-normal-tn *backend-t-primitive-type*)))
1027             (vop setup-closure-environment node block start-label closure)
1028             (when (getf (functional-plist ef) :fin-function)
1029               (vop funcallable-instance-lexenv node block closure closure))
1030             (let ((n -1))
1031               (dolist (loc (ir2-environment-environment env))
1032                 (vop closure-ref node block closure (incf n) (cdr loc)))))
1033           (vop setup-environment node block start-label)))
1034
1035     (unless (eq (functional-kind fun) :top-level)
1036       (let ((vars (lambda-vars fun))
1037             (n 0))
1038         (when (leaf-refs (first vars))
1039           (emit-move node block (make-argument-count-location)
1040                      (leaf-info (first vars))))
1041         (dolist (arg (rest vars))
1042           (when (leaf-refs arg)
1043             (let ((pass (standard-argument-location n))
1044                   (home (leaf-info arg)))
1045               (if (lambda-var-indirect arg)
1046                   (do-make-value-cell node block pass home)
1047                   (emit-move node block pass home))))
1048           (incf n))))
1049
1050     (emit-move node block (make-old-fp-passing-location t)
1051                (ir2-environment-old-fp env)))
1052
1053   (values))
1054
1055 ;;; Emit function prolog code. This is only called on bind nodes for
1056 ;;; functions that allocate environments. All semantics of let calls
1057 ;;; are handled by IR2-Convert-Let.
1058 ;;;
1059 ;;; If not an XEP, all we do is move the return PC from its passing
1060 ;;; location, since in a local call, the caller allocates the frame
1061 ;;; and sets up the arguments.
1062 (defun ir2-convert-bind (node block)
1063   (declare (type bind node) (type ir2-block block))
1064   (let* ((fun (bind-lambda node))
1065          (env (environment-info (lambda-environment fun))))
1066     (aver (member (functional-kind fun)
1067                   '(nil :external :optional :top-level :cleanup)))
1068
1069     (when (external-entry-point-p fun)
1070       (init-xep-environment node block fun)
1071       #!+sb-dyncount
1072       (when *collect-dynamic-statistics*
1073         (vop count-me node block *dynamic-counts-tn*
1074              (block-number (ir2-block-block block)))))
1075
1076     (emit-move node
1077                block
1078                (ir2-environment-return-pc-pass env)
1079                (ir2-environment-return-pc env))
1080
1081     (let ((lab (gen-label)))
1082       (setf (ir2-environment-environment-start env) lab)
1083       (vop note-environment-start node block lab)))
1084
1085   (values))
1086 \f
1087 ;;;; function return
1088
1089 ;;; Do stuff to return from a function with the specified values and
1090 ;;; convention. If the return convention is :FIXED and we aren't
1091 ;;; returning from an XEP, then we do a known return (letting
1092 ;;; representation selection insert the correct move-arg VOPs.)
1093 ;;; Otherwise, we use the unknown-values convention. If there is a
1094 ;;; fixed number of return values, then use RETURN, otherwise use
1095 ;;; RETURN-MULTIPLE.
1096 (defun ir2-convert-return (node block)
1097   (declare (type creturn node) (type ir2-block block))
1098   (let* ((cont (return-result node))
1099          (2cont (continuation-info cont))
1100          (cont-kind (ir2-continuation-kind 2cont))
1101          (fun (return-lambda node))
1102          (env (environment-info (lambda-environment fun)))
1103          (old-fp (ir2-environment-old-fp env))
1104          (return-pc (ir2-environment-return-pc env))
1105          (returns (tail-set-info (lambda-tail-set fun))))
1106     (cond
1107      ((and (eq (return-info-kind returns) :fixed)
1108            (not (external-entry-point-p fun)))
1109       (let ((locs (continuation-tns node block cont
1110                                     (return-info-types returns))))
1111         (vop* known-return node block
1112               (old-fp return-pc (reference-tn-list locs nil))
1113               (nil)
1114               (return-info-locations returns))))
1115      ((eq cont-kind :fixed)
1116       (let* ((types (mapcar #'tn-primitive-type (ir2-continuation-locs 2cont)))
1117              (cont-locs (continuation-tns node block cont types))
1118              (nvals (length cont-locs))
1119              (locs (make-standard-value-tns nvals)))
1120         (mapc #'(lambda (val loc)
1121                   (emit-move node block val loc))
1122               cont-locs
1123               locs)
1124         (if (= nvals 1)
1125             (vop return-single node block old-fp return-pc (car locs))
1126             (vop* return node block
1127                   (old-fp return-pc (reference-tn-list locs nil))
1128                   (nil)
1129                   nvals))))
1130      (t
1131       (aver (eq cont-kind :unknown))
1132       (vop* return-multiple node block
1133             (old-fp return-pc
1134                     (reference-tn-list (ir2-continuation-locs 2cont) nil))
1135             (nil)))))
1136
1137   (values))
1138 \f
1139 ;;;; debugger hooks
1140
1141 ;;; This is used by the debugger to find the top function on the
1142 ;;; stack. It returns the OLD-FP and RETURN-PC for the current
1143 ;;; function as multiple values.
1144 (defoptimizer (sb!kernel:%caller-frame-and-pc ir2-convert) (() node block)
1145   (let ((env (environment-info (node-environment node))))
1146     (move-continuation-result node block
1147                               (list (ir2-environment-old-fp env)
1148                                     (ir2-environment-return-pc env))
1149                               (node-cont node))))
1150 \f
1151 ;;;; multiple values
1152
1153 ;;; This is almost identical to IR2-Convert-Let. Since LTN annotates
1154 ;;; the continuation for the correct number of values (with the
1155 ;;; continuation user responsible for defaulting), we can just pick
1156 ;;; them up from the continuation.
1157 (defun ir2-convert-mv-bind (node block)
1158   (declare (type mv-combination node) (type ir2-block block))
1159   (let* ((cont (first (basic-combination-args node)))
1160          (fun (ref-leaf (continuation-use (basic-combination-fun node))))
1161          (vars (lambda-vars fun)))
1162     (aver (eq (functional-kind fun) :mv-let))
1163     (mapc #'(lambda (src var)
1164               (when (leaf-refs var)
1165                 (let ((dest (leaf-info var)))
1166                   (if (lambda-var-indirect var)
1167                       (do-make-value-cell node block src dest)
1168                       (emit-move node block src dest)))))
1169           (continuation-tns node block cont
1170                             (mapcar #'(lambda (x)
1171                                         (primitive-type (leaf-type x)))
1172                                     vars))
1173           vars))
1174   (values))
1175
1176 ;;; Emit the appropriate fixed value, unknown value or tail variant of
1177 ;;; CALL-VARIABLE. Note that we only need to pass the values start for
1178 ;;; the first argument: all the other argument continuation TNs are
1179 ;;; ignored. This is because we require all of the values globs to be
1180 ;;; contiguous and on stack top.
1181 (defun ir2-convert-mv-call (node block)
1182   (declare (type mv-combination node) (type ir2-block block))
1183   (aver (basic-combination-args node))
1184   (let* ((start-cont (continuation-info (first (basic-combination-args node))))
1185          (start (first (ir2-continuation-locs start-cont)))
1186          (tails (and (node-tail-p node)
1187                      (lambda-tail-set (node-home-lambda node))))
1188          (cont (node-cont node))
1189          (2cont (continuation-info cont)))
1190     (multiple-value-bind (fun named)
1191         (function-continuation-tn node block (basic-combination-fun node))
1192       (aver (and (not named)
1193                  (eq (ir2-continuation-kind start-cont) :unknown)))
1194       (cond
1195        (tails
1196         (let ((env (environment-info (node-environment node))))
1197           (vop tail-call-variable node block start fun
1198                (ir2-environment-old-fp env)
1199                (ir2-environment-return-pc env))))
1200        ((and 2cont
1201              (eq (ir2-continuation-kind 2cont) :unknown))
1202         (vop* multiple-call-variable node block (start fun nil)
1203               ((reference-tn-list (ir2-continuation-locs 2cont) t))))
1204        (t
1205         (let ((locs (standard-result-tns cont)))
1206           (vop* call-variable node block (start fun nil)
1207                 ((reference-tn-list locs t)) (length locs))
1208           (move-continuation-result node block locs cont)))))))
1209
1210 ;;; Reset the stack pointer to the start of the specified
1211 ;;; unknown-values continuation (discarding it and all values globs on
1212 ;;; top of it.)
1213 (defoptimizer (%pop-values ir2-convert) ((continuation) node block)
1214   (let ((2cont (continuation-info (continuation-value continuation))))
1215     (aver (eq (ir2-continuation-kind 2cont) :unknown))
1216     (vop reset-stack-pointer node block
1217          (first (ir2-continuation-locs 2cont)))))
1218
1219 ;;; Deliver the values TNs to CONT using MOVE-CONTINUATION-RESULT.
1220 (defoptimizer (values ir2-convert) ((&rest values) node block)
1221   (let ((tns (mapcar #'(lambda (x)
1222                          (continuation-tn node block x))
1223                      values)))
1224     (move-continuation-result node block tns (node-cont node))))
1225
1226 ;;; In the normal case where unknown values are desired, we use the
1227 ;;; VALUES-LIST VOP. In the relatively unimportant case of VALUES-LIST
1228 ;;; for a fixed number of values, we punt by doing a full call to the
1229 ;;; VALUES-LIST function. This gets the full call VOP to deal with
1230 ;;; defaulting any unsupplied values. It seems unworthwhile to
1231 ;;; optimize this case.
1232 (defoptimizer (values-list ir2-convert) ((list) node block)
1233   (let* ((cont (node-cont node))
1234          (2cont (continuation-info cont)))
1235     (when 2cont
1236       (ecase (ir2-continuation-kind 2cont)
1237         (:fixed (ir2-convert-full-call node block))
1238         (:unknown
1239          (let ((locs (ir2-continuation-locs 2cont)))
1240            (vop* values-list node block
1241                  ((continuation-tn node block list) nil)
1242                  ((reference-tn-list locs t)))))))))
1243
1244 (defoptimizer (%more-arg-values ir2-convert) ((context start count) node block)
1245   (let* ((cont (node-cont node))
1246          (2cont (continuation-info cont)))
1247     (when 2cont
1248       (ecase (ir2-continuation-kind 2cont)
1249         (:fixed (ir2-convert-full-call node block))
1250         (:unknown
1251          (let ((locs (ir2-continuation-locs 2cont)))
1252            (vop* %more-arg-values node block
1253                  ((continuation-tn node block context)
1254                   (continuation-tn node block start)
1255                   (continuation-tn node block count)
1256                   nil)
1257                  ((reference-tn-list locs t)))))))))
1258 \f
1259 ;;;; special binding
1260
1261 ;;; This is trivial, given our assumption of a shallow-binding
1262 ;;; implementation.
1263 (defoptimizer (%special-bind ir2-convert) ((var value) node block)
1264   (let ((name (leaf-name (continuation-value var))))
1265     (vop bind node block (continuation-tn node block value)
1266          (emit-constant name))))
1267 (defoptimizer (%special-unbind ir2-convert) ((var) node block)
1268   (vop unbind node block))
1269
1270 ;;; ### It's not clear that this really belongs in this file, or
1271 ;;; should really be done this way, but this is the least violation of
1272 ;;; abstraction in the current setup. We don't want to wire
1273 ;;; shallow-binding assumptions into IR1tran.
1274 (def-ir1-translator progv ((vars vals &body body) start cont)
1275   (ir1-convert
1276    start cont
1277    (if (byte-compiling)
1278        `(%progv ,vars ,vals #'(lambda () ,@body))
1279        (once-only ((n-save-bs '(%primitive current-binding-pointer)))
1280          `(unwind-protect
1281               (progn
1282                 (mapc #'(lambda (var val)
1283                           (%primitive bind val var))
1284                       ,vars
1285                       ,vals)
1286                 ,@body)
1287             (%primitive unbind-to-here ,n-save-bs))))))
1288 \f
1289 ;;;; non-local exit
1290
1291 ;;; Convert a non-local lexical exit. First find the NLX-Info in our
1292 ;;; environment. Note that this is never called on the escape exits
1293 ;;; for CATCH and UNWIND-PROTECT, since the escape functions aren't
1294 ;;; IR2 converted.
1295 (defun ir2-convert-exit (node block)
1296   (declare (type exit node) (type ir2-block block))
1297   (let ((loc (find-in-environment (find-nlx-info (exit-entry node)
1298                                                  (node-cont node))
1299                                   (node-environment node)))
1300         (temp (make-stack-pointer-tn))
1301         (value (exit-value node)))
1302     (vop value-cell-ref node block loc temp)
1303     (if value
1304         (let ((locs (ir2-continuation-locs (continuation-info value))))
1305           (vop unwind node block temp (first locs) (second locs)))
1306         (let ((0-tn (emit-constant 0)))
1307           (vop unwind node block temp 0-tn 0-tn))))
1308
1309   (values))
1310
1311 ;;; %CLEANUP-POINT doesn't do anything except prevent the body from
1312 ;;; being entirely deleted.
1313 (defoptimizer (%cleanup-point ir2-convert) (() node block) node block)
1314
1315 ;;; This function invalidates a lexical exit on exiting from the
1316 ;;; dynamic extent. This is done by storing 0 into the indirect value
1317 ;;; cell that holds the closed unwind block.
1318 (defoptimizer (%lexical-exit-breakup ir2-convert) ((info) node block)
1319   (vop value-cell-set node block
1320        (find-in-environment (continuation-value info) (node-environment node))
1321        (emit-constant 0)))
1322
1323 ;;; We have to do a spurious move of no values to the result
1324 ;;; continuation so that lifetime analysis won't get confused.
1325 (defun ir2-convert-throw (node block)
1326   (declare (type mv-combination node) (type ir2-block block))
1327   (let ((args (basic-combination-args node)))
1328     (vop* throw node block
1329           ((continuation-tn node block (first args))
1330            (reference-tn-list
1331             (ir2-continuation-locs (continuation-info (second args)))
1332             nil))
1333           (nil)))
1334
1335   (move-continuation-result node block () (node-cont node))
1336   (values))
1337
1338 ;;; Emit code to set up a non-local exit. INFO is the NLX-Info for the
1339 ;;; exit, and TAG is the continuation for the catch tag (if any.) We
1340 ;;; get at the target PC by passing in the label to the vop. The vop
1341 ;;; is responsible for building a return-PC object.
1342 (defun emit-nlx-start (node block info tag)
1343   (declare (type node node) (type ir2-block block) (type nlx-info info)
1344            (type (or continuation null) tag))
1345   (let* ((2info (nlx-info-info info))
1346          (kind (cleanup-kind (nlx-info-cleanup info)))
1347          (block-tn (environment-live-tn
1348                     (make-normal-tn (primitive-type-or-lose 'catch-block))
1349                     (node-environment node)))
1350          (res (make-stack-pointer-tn))
1351          (target-label (ir2-nlx-info-target 2info)))
1352
1353     (vop current-binding-pointer node block
1354          (car (ir2-nlx-info-dynamic-state 2info)))
1355     (vop* save-dynamic-state node block
1356           (nil)
1357           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) t)))
1358     (vop current-stack-pointer node block (ir2-nlx-info-save-sp 2info))
1359
1360     (ecase kind
1361       (:catch
1362        (vop make-catch-block node block block-tn
1363             (continuation-tn node block tag) target-label res))
1364       ((:unwind-protect :block :tagbody)
1365        (vop make-unwind-block node block block-tn target-label res)))
1366
1367     (ecase kind
1368       ((:block :tagbody)
1369        (do-make-value-cell node block res (ir2-nlx-info-home 2info)))
1370       (:unwind-protect
1371        (vop set-unwind-protect node block block-tn))
1372       (:catch)))
1373
1374   (values))
1375
1376 ;;; Scan each of ENTRY's exits, setting up the exit for each lexical exit.
1377 (defun ir2-convert-entry (node block)
1378   (declare (type entry node) (type ir2-block block))
1379   (dolist (exit (entry-exits node))
1380     (let ((info (find-nlx-info node (node-cont exit))))
1381       (when (and info
1382                  (member (cleanup-kind (nlx-info-cleanup info))
1383                          '(:block :tagbody)))
1384         (emit-nlx-start node block info nil))))
1385   (values))
1386
1387 ;;; Set up the unwind block for these guys.
1388 (defoptimizer (%catch ir2-convert) ((info-cont tag) node block)
1389   (emit-nlx-start node block (continuation-value info-cont) tag))
1390 (defoptimizer (%unwind-protect ir2-convert) ((info-cont cleanup) node block)
1391   (emit-nlx-start node block (continuation-value info-cont) nil))
1392
1393 ;;; Emit the entry code for a non-local exit. We receive values and
1394 ;;; restore dynamic state.
1395 ;;;
1396 ;;; In the case of a lexical exit or CATCH, we look at the exit
1397 ;;; continuation's kind to determine which flavor of entry VOP to
1398 ;;; emit. If unknown values, emit the xxx-MULTIPLE variant to the
1399 ;;; continuation locs. If fixed values, make the appropriate number of
1400 ;;; temps in the standard values locations and use the other variant,
1401 ;;; delivering the temps to the continuation using
1402 ;;; MOVE-CONTINUATION-RESULT.
1403 ;;;
1404 ;;; In the UNWIND-PROTECT case, we deliver the first register
1405 ;;; argument, the argument count and the argument pointer to our
1406 ;;; continuation as multiple values. These values are the block exited
1407 ;;; to and the values start and count.
1408 ;;;
1409 ;;; After receiving values, we restore dynamic state. Except in the
1410 ;;; UNWIND-PROTECT case, the values receiving restores the stack
1411 ;;; pointer. In an UNWIND-PROTECT cleanup, we want to leave the stack
1412 ;;; pointer alone, since the thrown values are still out there.
1413 (defoptimizer (%nlx-entry ir2-convert) ((info-cont) node block)
1414   (let* ((info (continuation-value info-cont))
1415          (cont (nlx-info-continuation info))
1416          (2cont (continuation-info cont))
1417          (2info (nlx-info-info info))
1418          (top-loc (ir2-nlx-info-save-sp 2info))
1419          (start-loc (make-nlx-entry-argument-start-location))
1420          (count-loc (make-argument-count-location))
1421          (target (ir2-nlx-info-target 2info)))
1422
1423     (ecase (cleanup-kind (nlx-info-cleanup info))
1424       ((:catch :block :tagbody)
1425        (if (and 2cont (eq (ir2-continuation-kind 2cont) :unknown))
1426            (vop* nlx-entry-multiple node block
1427                  (top-loc start-loc count-loc nil)
1428                  ((reference-tn-list (ir2-continuation-locs 2cont) t))
1429                  target)
1430            (let ((locs (standard-result-tns cont)))
1431              (vop* nlx-entry node block
1432                    (top-loc start-loc count-loc nil)
1433                    ((reference-tn-list locs t))
1434                    target
1435                    (length locs))
1436              (move-continuation-result node block locs cont))))
1437       (:unwind-protect
1438        (let ((block-loc (standard-argument-location 0)))
1439          (vop uwp-entry node block target block-loc start-loc count-loc)
1440          (move-continuation-result
1441           node block
1442           (list block-loc start-loc count-loc)
1443           cont))))
1444
1445     #!+sb-dyncount
1446     (when *collect-dynamic-statistics*
1447       (vop count-me node block *dynamic-counts-tn*
1448            (block-number (ir2-block-block block))))
1449
1450     (vop* restore-dynamic-state node block
1451           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) nil))
1452           (nil))
1453     (vop unbind-to-here node block
1454          (car (ir2-nlx-info-dynamic-state 2info)))))
1455 \f
1456 ;;;; n-argument functions
1457
1458 (macrolet ((def-frob (name)
1459              `(defoptimizer (,name ir2-convert) ((&rest args) node block)
1460                 (let* ((refs (move-tail-full-call-args node block))
1461                        (cont (node-cont node))
1462                        (res (continuation-result-tns
1463                              cont
1464                              (list (primitive-type (specifier-type 'list))))))
1465                   (vop* ,name node block (refs) ((first res) nil)
1466                         (length args))
1467                   (move-continuation-result node block res cont)))))
1468   (def-frob list)
1469   (def-frob list*))
1470 \f
1471 ;;;; structure accessors
1472 ;;;;
1473 ;;;; These guys have to bizarrely determine the slot offset by looking
1474 ;;;; at the called function.
1475
1476 (defoptimizer (%slot-accessor ir2-convert) ((str) node block)
1477   (let* ((cont (node-cont node))
1478          (res (continuation-result-tns cont
1479                                        (list *backend-t-primitive-type*))))
1480     (vop instance-ref node block
1481          (continuation-tn node block str)
1482          (dsd-index
1483           (slot-accessor-slot
1484            (ref-leaf
1485             (continuation-use
1486              (combination-fun node)))))
1487          (first res))
1488     (move-continuation-result node block res cont)))
1489
1490 (defoptimizer (%slot-setter ir2-convert) ((value str) node block)
1491   (let ((val (continuation-tn node block value)))
1492     (vop instance-set node block
1493          (continuation-tn node block str)
1494          val
1495          (dsd-index
1496           (slot-accessor-slot
1497            (ref-leaf
1498             (continuation-use
1499              (combination-fun node))))))
1500
1501     (move-continuation-result node block (list val) (node-cont node))))
1502 \f
1503 ;;; Convert the code in a component into VOPs.
1504 (defun ir2-convert (component)
1505   (declare (type component component))
1506   (let (#!+sb-dyncount
1507         (*dynamic-counts-tn*
1508          (when *collect-dynamic-statistics*
1509            (let* ((blocks
1510                    (block-number (block-next (component-head component))))
1511                   (counts (make-array blocks
1512                                       :element-type '(unsigned-byte 32)
1513                                       :initial-element 0))
1514                   (info (make-dyncount-info
1515                          :for (component-name component)
1516                          :costs (make-array blocks
1517                                             :element-type '(unsigned-byte 32)
1518                                             :initial-element 0)
1519                          :counts counts)))
1520              (setf (ir2-component-dyncount-info (component-info component))
1521                    info)
1522              (emit-constant info)
1523              (emit-constant counts)))))
1524     (let ((num 0))
1525       (declare (type index num))
1526       (do-ir2-blocks (2block component)
1527         (let ((block (ir2-block-block 2block)))
1528           (when (block-start block)
1529             (setf (block-number block) num)
1530             #!+sb-dyncount
1531             (when *collect-dynamic-statistics*
1532               (let ((first-node (continuation-next (block-start block))))
1533                 (unless (or (and (bind-p first-node)
1534                                  (external-entry-point-p
1535                                   (bind-lambda first-node)))
1536                             (eq (continuation-function-name
1537                                  (node-cont first-node))
1538                                 '%nlx-entry))
1539                   (vop count-me
1540                        first-node
1541                        2block
1542                        #!+sb-dyncount *dynamic-counts-tn* #!-sb-dyncount nil
1543                        num))))
1544             (ir2-convert-block block)
1545             (incf num))))))
1546   (values))
1547
1548 ;;; If necessary, emit a terminal unconditional branch to go to the
1549 ;;; successor block. If the successor is the component tail, then
1550 ;;; there isn't really any successor, but if the end is an unknown,
1551 ;;; non-tail call, then we emit an error trap just in case the
1552 ;;; function really does return.
1553 (defun finish-ir2-block (block)
1554   (declare (type cblock block))
1555   (let* ((2block (block-info block))
1556          (last (block-last block))
1557          (succ (block-succ block)))
1558     (unless (if-p last)
1559       (aver (and succ (null (rest succ))))
1560       (let ((target (first succ)))
1561         (cond ((eq target (component-tail (block-component block)))
1562                (when (and (basic-combination-p last)
1563                           (eq (basic-combination-kind last) :full))
1564                  (let* ((fun (basic-combination-fun last))
1565                         (use (continuation-use fun))
1566                         (name (and (ref-p use) (leaf-name (ref-leaf use)))))
1567                    (unless (or (node-tail-p last)
1568                                (info :function :info name)
1569                                (policy last (zerop safety)))
1570                      (vop nil-function-returned-error last 2block
1571                           (if name
1572                               (emit-constant name)
1573                               (multiple-value-bind (tn named)
1574                                   (function-continuation-tn last 2block fun)
1575                                 (aver (not named))
1576                                 tn)))))))
1577               ((not (eq (ir2-block-next 2block) (block-info target)))
1578                (vop branch last 2block (block-label target)))))))
1579
1580   (values))
1581
1582 ;;; Convert the code in a block into VOPs.
1583 (defun ir2-convert-block (block)
1584   (declare (type cblock block))
1585   (let ((2block (block-info block)))
1586     (do-nodes (node cont block)
1587       (etypecase node
1588         (ref
1589          (let ((2cont (continuation-info cont)))
1590            (when (and 2cont
1591                       (not (eq (ir2-continuation-kind 2cont) :delayed)))
1592              (ir2-convert-ref node 2block))))
1593         (combination
1594          (let ((kind (basic-combination-kind node)))
1595            (case kind
1596              (:local
1597               (ir2-convert-local-call node 2block))
1598              (:full
1599               (ir2-convert-full-call node 2block))
1600              (t
1601               (let ((fun (function-info-ir2-convert kind)))
1602                 (cond (fun
1603                        (funcall fun node 2block))
1604                       ((eq (basic-combination-info node) :full)
1605                        (ir2-convert-full-call node 2block))
1606                       (t
1607                        (ir2-convert-template node 2block))))))))
1608         (cif
1609          (when (continuation-info (if-test node))
1610            (ir2-convert-if node 2block)))
1611         (bind
1612          (let ((fun (bind-lambda node)))
1613            (when (eq (lambda-home fun) fun)
1614              (ir2-convert-bind node 2block))))
1615         (creturn
1616          (ir2-convert-return node 2block))
1617         (cset
1618          (ir2-convert-set node 2block))
1619         (mv-combination
1620          (cond
1621           ((eq (basic-combination-kind node) :local)
1622            (ir2-convert-mv-bind node 2block))
1623           ((eq (continuation-function-name (basic-combination-fun node))
1624                '%throw)
1625            (ir2-convert-throw node 2block))
1626           (t
1627            (ir2-convert-mv-call node 2block))))
1628         (exit
1629          (when (exit-entry node)
1630            (ir2-convert-exit node 2block)))
1631         (entry
1632          (ir2-convert-entry node 2block)))))
1633
1634   (finish-ir2-block block)
1635
1636   (values))