src/compiler/ir2tran.lisp

   1 ;;;; This file contains the virtual-machine-independent parts of the
   2 ;;;; code which does the actual translation of nodes to VOPs.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; moves and type checks
  16
  17 ;;; Move X to Y unless they are EQ.
  18 (defun emit-move (node block x y)
  19   (declare (type node node) (type ir2-block block) (type tn x y))
  20   (unless (eq x y)
  21     (vop move node block x y))
  22   (values))
  23
  24 ;;; If there is any CHECK-xxx template for TYPE, then return it,
  25 ;;; otherwise return NIL.
  26 (defun type-check-template (type)
  27   (declare (type ctype type))
  28   (multiple-value-bind (check-ptype exact) (primitive-type type)
  29     (if exact
  30         (primitive-type-check check-ptype)
  31         (let ((name (hairy-type-check-template-name type)))
  32           (if name
  33               (template-or-lose name)
  34               nil)))))
  35
  36 ;;; Emit code in BLOCK to check that VALUE is of the specified TYPE,
  37 ;;; yielding the checked result in RESULT. VALUE and result may be of
  38 ;;; any primitive type. There must be CHECK-xxx VOP for TYPE. Any
  39 ;;; other type checks should have been converted to an explicit type
  40 ;;; test.
  41 (defun emit-type-check (node block value result type)
  42   (declare (type tn value result) (type node node) (type ir2-block block)
  43            (type ctype type))
  44   (emit-move-template node block (type-check-template type) value result)
  45   (values))
  46
  47 ;;; Allocate an indirect value cell. Maybe do some clever stack
  48 ;;; allocation someday.
  49 ;;;
  50 ;;; FIXME: DO-MAKE-VALUE-CELL is a bad name, since it doesn't make
  51 ;;; clear what's the distinction between it and the MAKE-VALUE-CELL
  52 ;;; VOP, and since the DO- further connotes iteration, which has
  53 ;;; nothing to do with this. Clearer, more systematic names, anyone?
  54 (defevent make-value-cell-event "Allocate heap value cell for lexical var.")
  55 (defun do-make-value-cell (node block value res)
  56   (event make-value-cell-event node)
  57   (vop make-value-cell node block value res))
  58 \f
  59 ;;;; leaf reference
  60
  61 ;;; Return the TN that holds the value of THING in the environment ENV.
  62 (declaim (ftype (function ((or nlx-info lambda-var clambda) physenv) tn)
  63                 find-in-physenv))
  64 (defun find-in-physenv (thing physenv)
  65   (or (cdr (assoc thing (ir2-physenv-closure (physenv-info physenv))))
  66       (etypecase thing
  67         (lambda-var
  68          ;; I think that a failure of this assertion means that we're
  69          ;; trying to access a variable which was improperly closed
  70          ;; over. The PHYSENV describes a physical environment. Every
  71          ;; variable that a form refers to should either be in its
  72          ;; physical environment directly, or grabbed from a
  73          ;; surrounding physical environment when it was closed over.
  74          ;; The ASSOC expression above finds closed-over variables, so
  75          ;; if we fell through the ASSOC expression, it wasn't closed
  76          ;; over. Therefore, it must be in our physical environment
  77          ;; directly. If instead it is in some other physical
  78          ;; environment, then it's bogus for us to reference it here
  79          ;; without it being closed over. -- WHN 2001-09-29
  80          (aver (eq physenv (lambda-physenv (lambda-var-home thing))))
  81          (leaf-info thing))
  82         (nlx-info
  83          (aver (eq physenv (block-physenv (nlx-info-target thing))))
  84          (ir2-nlx-info-home (nlx-info-info thing)))
  85         (clambda
  86          (aver (xep-p thing))
  87          (entry-info-closure-tn (lambda-info thing))))
  88       (bug "~@<~2I~_~S ~_not found in ~_~S~:>" thing physenv)))
  89
  90 ;;; If LEAF already has a constant TN, return that, otherwise make a
  91 ;;; TN for it.
  92 (defun constant-tn (leaf)
  93   (declare (type constant leaf))
  94   (or (leaf-info leaf)
  95       (setf (leaf-info leaf)
  96             (make-constant-tn leaf))))
  97
  98 ;;; Return a TN that represents the value of LEAF, or NIL if LEAF
  99 ;;; isn't directly represented by a TN. ENV is the environment that
 100 ;;; the reference is done in.
 101 (defun leaf-tn (leaf env)
 102   (declare (type leaf leaf) (type physenv env))
 103   (typecase leaf
 104     (lambda-var
 105      (unless (lambda-var-indirect leaf)
 106        (find-in-physenv leaf env)))
 107     (constant (constant-tn leaf))
 108     (t nil)))
 109
 110 ;;; This is used to conveniently get a handle on a constant TN during
 111 ;;; IR2 conversion. It returns a constant TN representing the Lisp
 112 ;;; object VALUE.
 113 (defun emit-constant (value)
 114   (constant-tn (find-constant value)))
 115
 116 ;;; Convert a REF node. The reference must not be delayed.
 117 (defun ir2-convert-ref (node block)
 118   (declare (type ref node) (type ir2-block block))
 119   (let* ((lvar (node-lvar node))
 120          (leaf (ref-leaf node))
 121          (locs (lvar-result-tns
 122                 lvar (list (primitive-type (leaf-type leaf)))))
 123          (res (first locs)))
 124     (etypecase leaf
 125       (lambda-var
 126        (let ((tn (find-in-physenv leaf (node-physenv node))))
 127          (if (lambda-var-indirect leaf)
 128              (vop value-cell-ref node block tn res)
 129              (emit-move node block tn res))))
 130       (constant
 131        (if (legal-immediate-constant-p leaf)
 132            (emit-move node block (constant-tn leaf) res)
 133            (let* ((name (leaf-source-name leaf))
 134                   (name-tn (emit-constant name)))
 135              (if (policy node (zerop safety))
 136                  (vop fast-symbol-value node block name-tn res)
 137                  (vop symbol-value node block name-tn res)))))
 138       (functional
 139        (ir2-convert-closure node block leaf res))
 140       (global-var
 141        (let ((unsafe (policy node (zerop safety)))
 142              (name (leaf-source-name leaf)))
 143          (ecase (global-var-kind leaf)
 144            ((:special :global)
 145             (aver (symbolp name))
 146             (let ((name-tn (emit-constant name)))
 147               (if unsafe
 148                   (vop fast-symbol-value node block name-tn res)
 149                   (vop symbol-value node block name-tn res))))
 150            (:global-function
 151             (let ((fdefn-tn (make-load-time-constant-tn :fdefinition name)))
 152               (if unsafe
 153                   (vop fdefn-fun node block fdefn-tn res)
 154                   (vop safe-fdefn-fun node block fdefn-tn res))))))))
 155     (move-lvar-result node block locs lvar))
 156   (values))
 157
 158 ;;; some sanity checks for a CLAMBDA passed to IR2-CONVERT-CLOSURE
 159 (defun assertions-on-ir2-converted-clambda (clambda)
 160   ;; This assertion was sort of an experiment. It would be nice and
 161   ;; sane and easier to understand things if it were *always* true,
 162   ;; but experimentally I observe that it's only *almost* always
 163   ;; true. -- WHN 2001-01-02
 164   #+nil
 165   (aver (eql (lambda-component clambda)
 166              (block-component (ir2-block-block ir2-block))))
 167   ;; Check for some weirdness which came up in bug
 168   ;; 138, 2002-01-02.
 169   ;;
 170   ;; The MAKE-LOAD-TIME-CONSTANT-TN call above puts an :ENTRY record
 171   ;; into the IR2-COMPONENT-CONSTANTS table. The dump-a-COMPONENT
 172   ;; code
 173   ;;   * treats every HANDLEless :ENTRY record into a
 174   ;;     patch, and
 175   ;;   * expects every patch to correspond to an
 176   ;;     IR2-COMPONENT-ENTRIES record.
 177   ;; The IR2-COMPONENT-ENTRIES records are set by ENTRY-ANALYZE
 178   ;; walking over COMPONENT-LAMBDAS. Bug 138b arose because there
 179   ;; was a HANDLEless :ENTRY record which didn't correspond to an
 180   ;; IR2-COMPONENT-ENTRIES record. That problem is hard to debug
 181   ;; when it's caught at dump time, so this assertion tries to catch
 182   ;; it here.
 183   (aver (member clambda
 184                 (component-lambdas (lambda-component clambda))))
 185   ;; another bug-138-related issue: COMPONENT-NEW-FUNCTIONALS is
 186   ;; used as a queue for stuff pending to do in IR1, and now that
 187   ;; we're doing IR2 it should've been completely flushed (but
 188   ;; wasn't).
 189   (aver (null (component-new-functionals (lambda-component clambda))))
 190   (values))
 191
 192 ;;; Emit code to load a function object implementing FUNCTIONAL into
 193 ;;; RES. This gets interesting when the referenced function is a
 194 ;;; closure: we must make the closure and move the closed-over values
 195 ;;; into it.
 196 ;;;
 197 ;;; FUNCTIONAL is either a :TOPLEVEL-XEP functional or the XEP lambda
 198 ;;; for the called function, since local call analysis converts all
 199 ;;; closure references. If a :TOPLEVEL-XEP, we know it is not a
 200 ;;; closure.
 201 ;;;
 202 ;;; If a closed-over LAMBDA-VAR has no refs (is deleted), then we
 203 ;;; don't initialize that slot. This can happen with closures over
 204 ;;; top level variables, where optimization of the closure deleted the
 205 ;;; variable. Since we committed to the closure format when we
 206 ;;; pre-analyzed the top level code, we just leave an empty slot.
 207 (defun ir2-convert-closure (ref ir2-block functional res)
 208   (declare (type ref ref)
 209            (type ir2-block ir2-block)
 210            (type functional functional)
 211            (type tn res))
 212   (aver (not (eql (functional-kind functional) :deleted)))
 213   (unless (leaf-info functional)
 214     (setf (leaf-info functional)
 215           (make-entry-info :name (functional-debug-name functional))))
 216   (let ((closure (etypecase functional
 217                    (clambda
 218                     (assertions-on-ir2-converted-clambda functional)
 219                     (physenv-closure (get-lambda-physenv functional)))
 220                    (functional
 221                     (aver (eq (functional-kind functional) :toplevel-xep))
 222                     nil))))
 223
 224     (cond (closure
 225            (let* ((physenv (node-physenv ref))
 226                   (tn (find-in-physenv functional physenv)))
 227              (emit-move ref ir2-block tn res)))
 228           (t
 229            (let ((entry (make-load-time-constant-tn :entry functional)))
 230              (emit-move ref ir2-block entry res)))))
 231   (values))
 232
 233 (defoptimizer (%allocate-closures ltn-annotate) ((leaves) node ltn-policy)
 234   ltn-policy ; a hack to effectively (DECLARE (IGNORE LTN-POLICY))
 235   (when (lvar-dynamic-extent leaves)
 236     (let ((info (make-ir2-lvar *backend-t-primitive-type*)))
 237       (setf (ir2-lvar-kind info) :delayed)
 238       (setf (lvar-info leaves) info)
 239       (setf (ir2-lvar-stack-pointer info)
 240             (make-stack-pointer-tn)))))
 241
 242 (defoptimizer (%allocate-closures ir2-convert) ((leaves) call 2block)
 243   (let ((dx-p (lvar-dynamic-extent leaves)))
 244     (collect ((delayed))
 245       (when dx-p
 246         (vop current-stack-pointer call 2block
 247              (ir2-lvar-stack-pointer (lvar-info leaves))))
 248       (dolist (leaf (lvar-value leaves))
 249         (binding* ((xep (functional-entry-fun leaf) :exit-if-null)
 250                    (nil (aver (xep-p xep)))
 251                    (entry-info (lambda-info xep) :exit-if-null)
 252                    (tn (entry-info-closure-tn entry-info) :exit-if-null)
 253                    (closure (physenv-closure (get-lambda-physenv xep)))
 254                    (entry (make-load-time-constant-tn :entry xep)))
 255           (let ((this-env (node-physenv call))
 256                 (leaf-dx-p (and dx-p (leaf-dynamic-extent leaf))))
 257             (vop make-closure call 2block entry (length closure)
 258                  leaf-dx-p tn)
 259             (loop for what in closure and n from 0 do
 260                   (unless (and (lambda-var-p what)
 261                                (null (leaf-refs what)))
 262                     ;; In LABELS a closure may refer to another closure
 263                     ;; in the same group, so we must be sure that we
 264                     ;; store a closure only after its creation.
 265                     ;;
 266                     ;; TODO: Here is a simple solution: we postpone
 267                     ;; putting of all closures after all creations
 268                     ;; (though it may require more registers).
 269                     (if (lambda-p what)
 270                         (delayed (list tn (find-in-physenv what this-env) n))
 271                         (vop closure-init call 2block
 272                              tn
 273                              (find-in-physenv what this-env)
 274                              n)))))))
 275       (loop for (tn what n) in (delayed)
 276             do (vop closure-init call 2block
 277                     tn what n))))
 278   (values))
 279
 280 ;;; Convert a SET node. If the NODE's LVAR is annotated, then we also
 281 ;;; deliver the value to that lvar. If the var is a lexical variable
 282 ;;; with no refs, then we don't actually set anything, since the
 283 ;;; variable has been deleted.
 284 (defun ir2-convert-set (node block)
 285   (declare (type cset node) (type ir2-block block))
 286   (let* ((lvar (node-lvar node))
 287          (leaf (set-var node))
 288          (val (lvar-tn node block (set-value node)))
 289          (locs (if lvar
 290                    (lvar-result-tns
 291                     lvar (list (primitive-type (leaf-type leaf))))
 292                    nil)))
 293     (etypecase leaf
 294       (lambda-var
 295        (when (leaf-refs leaf)
 296          (let ((tn (find-in-physenv leaf (node-physenv node))))
 297            (if (lambda-var-indirect leaf)
 298                (vop value-cell-set node block tn val)
 299                (emit-move node block val tn)))))
 300       (global-var
 301        (ecase (global-var-kind leaf)
 302          ((:special :global)
 303           (aver (symbolp (leaf-source-name leaf)))
 304           (vop set node block (emit-constant (leaf-source-name leaf)) val)))))
 305     (when locs
 306       (emit-move node block val (first locs))
 307       (move-lvar-result node block locs lvar)))
 308   (values))
 309 \f
 310 ;;;; utilities for receiving fixed values
 311
 312 ;;; Return a TN that can be referenced to get the value of LVAR. LVAR
 313 ;;; must be LTN-ANNOTATED either as a delayed leaf ref or as a fixed,
 314 ;;; single-value lvar.
 315 ;;;
 316 ;;; The primitive-type of the result will always be the same as the
 317 ;;; IR2-LVAR-PRIMITIVE-TYPE, ensuring that VOPs are always called with
 318 ;;; TNs that satisfy the operand primitive-type restriction. We may
 319 ;;; have to make a temporary of the desired type and move the actual
 320 ;;; lvar TN into it. This happens when we delete a type check in
 321 ;;; unsafe code or when we locally know something about the type of an
 322 ;;; argument variable.
 323 (defun lvar-tn (node block lvar)
 324   (declare (type node node) (type ir2-block block) (type lvar lvar))
 325   (let* ((2lvar (lvar-info lvar))
 326          (lvar-tn
 327           (ecase (ir2-lvar-kind 2lvar)
 328             (:delayed
 329              (let ((ref (lvar-uses lvar)))
 330                (leaf-tn (ref-leaf ref) (node-physenv ref))))
 331             (:fixed
 332              (aver (= (length (ir2-lvar-locs 2lvar)) 1))
 333              (first (ir2-lvar-locs 2lvar)))))
 334          (ptype (ir2-lvar-primitive-type 2lvar)))
 335
 336     (cond ((eq (tn-primitive-type lvar-tn) ptype) lvar-tn)
 337           (t
 338            (let ((temp (make-normal-tn ptype)))
 339              (emit-move node block lvar-tn temp)
 340              temp)))))
 341
 342 ;;; This is similar to LVAR-TN, but hacks multiple values. We return
 343 ;;; TNs holding the values of LVAR with PTYPES as their primitive
 344 ;;; types. LVAR must be annotated for the same number of fixed values
 345 ;;; are there are PTYPES.
 346 ;;;
 347 ;;; If the lvar has a type check, check the values into temps and
 348 ;;; return the temps. When we have more values than assertions, we
 349 ;;; move the extra values with no check.
 350 (defun lvar-tns (node block lvar ptypes)
 351   (declare (type node node) (type ir2-block block)
 352            (type lvar lvar) (list ptypes))
 353   (let* ((locs (ir2-lvar-locs (lvar-info lvar)))
 354          (nlocs (length locs)))
 355     (aver (= nlocs (length ptypes)))
 356
 357     (mapcar (lambda (from to-type)
 358               (if (eq (tn-primitive-type from) to-type)
 359                   from
 360                   (let ((temp (make-normal-tn to-type)))
 361                     (emit-move node block from temp)
 362                     temp)))
 363             locs
 364             ptypes)))
 365 \f
 366 ;;;; utilities for delivering values to lvars
 367
 368 ;;; Return a list of TNs with the specifier TYPES that can be used as
 369 ;;; result TNs to evaluate an expression into LVAR. This is used
 370 ;;; together with MOVE-LVAR-RESULT to deliver fixed values to
 371 ;;; an lvar.
 372 ;;;
 373 ;;; If the lvar isn't annotated (meaning the values are discarded) or
 374 ;;; is unknown-values, the then we make temporaries for each supplied
 375 ;;; value, providing a place to compute the result in until we decide
 376 ;;; what to do with it (if anything.)
 377 ;;;
 378 ;;; If the lvar is fixed-values, and wants the same number of values
 379 ;;; as the user wants to deliver, then we just return the
 380 ;;; IR2-LVAR-LOCS. Otherwise we make a new list padded as necessary by
 381 ;;; discarded TNs. We always return a TN of the specified type, using
 382 ;;; the lvar locs only when they are of the correct type.
 383 (defun lvar-result-tns (lvar types)
 384   (declare (type (or lvar null) lvar) (type list types))
 385   (if (not lvar)
 386       (mapcar #'make-normal-tn types)
 387       (let ((2lvar (lvar-info lvar)))
 388         (ecase (ir2-lvar-kind 2lvar)
 389           (:fixed
 390            (let* ((locs (ir2-lvar-locs 2lvar))
 391                   (nlocs (length locs))
 392                   (ntypes (length types)))
 393              (if (and (= nlocs ntypes)
 394                       (do ((loc locs (cdr loc))
 395                            (type types (cdr type)))
 396                           ((null loc) t)
 397                         (unless (eq (tn-primitive-type (car loc)) (car type))
 398                           (return nil))))
 399                  locs
 400                  (mapcar (lambda (loc type)
 401                            (if (eq (tn-primitive-type loc) type)
 402                                loc
 403                                (make-normal-tn type)))
 404                          (if (< nlocs ntypes)
 405                              (append locs
 406                                      (mapcar #'make-normal-tn
 407                                              (subseq types nlocs)))
 408                              locs)
 409                          types))))
 410           (:unknown
 411            (mapcar #'make-normal-tn types))))))
 412
 413 ;;; Make the first N standard value TNs, returning them in a list.
 414 (defun make-standard-value-tns (n)
 415   (declare (type unsigned-byte n))
 416   (collect ((res))
 417     (dotimes (i n)
 418       (res (standard-arg-location i)))
 419     (res)))
 420
 421 ;;; Return a list of TNs wired to the standard value passing
 422 ;;; conventions that can be used to receive values according to the
 423 ;;; unknown-values convention. This is used with together
 424 ;;; MOVE-LVAR-RESULT for delivering unknown values to a fixed values
 425 ;;; lvar.
 426 ;;;
 427 ;;; If the lvar isn't annotated, then we treat as 0-values, returning
 428 ;;; an empty list of temporaries.
 429 ;;;
 430 ;;; If the lvar is annotated, then it must be :FIXED.
 431 (defun standard-result-tns (lvar)
 432   (declare (type (or lvar null) lvar))
 433   (if lvar
 434       (let ((2lvar (lvar-info lvar)))
 435         (ecase (ir2-lvar-kind 2lvar)
 436           (:fixed
 437            (make-standard-value-tns (length (ir2-lvar-locs 2lvar))))))
 438       nil))
 439
 440 ;;; Just move each SRC TN into the corresponding DEST TN, defaulting
 441 ;;; any unsupplied source values to NIL. We let EMIT-MOVE worry about
 442 ;;; doing the appropriate coercions.
 443 (defun move-results-coerced (node block src dest)
 444   (declare (type node node) (type ir2-block block) (list src dest))
 445   (let ((nsrc (length src))
 446         (ndest (length dest)))
 447     (mapc (lambda (from to)
 448             (unless (eq from to)
 449               (emit-move node block from to)))
 450           (if (> ndest nsrc)
 451               (append src (make-list (- ndest nsrc)
 452                                      :initial-element (emit-constant nil)))
 453               src)
 454           dest))
 455   (values))
 456
 457 ;;; Move each SRC TN into the corresponding DEST TN, checking types
 458 ;;; and defaulting any unsupplied source values to NIL
 459 (defun move-results-checked (node block src dest types)
 460   (declare (type node node) (type ir2-block block) (list src dest types))
 461   (let ((nsrc (length src))
 462         (ndest (length dest))
 463         (ntypes (length types)))
 464     (mapc (lambda (from to type)
 465             (if type
 466                 (emit-type-check node block from to type)
 467                 (emit-move node block from to)))
 468           (if (> ndest nsrc)
 469               (append src (make-list (- ndest nsrc)
 470                                      :initial-element (emit-constant nil)))
 471               src)
 472           dest
 473           (if (> ndest ntypes)
 474               (append types (make-list (- ndest ntypes)))
 475               types)))
 476   (values))
 477
 478 ;;; If necessary, emit coercion code needed to deliver the RESULTS to
 479 ;;; the specified lvar. NODE and BLOCK provide context for emitting
 480 ;;; code. Although usually obtained from STANDARD-RESULT-TNs or
 481 ;;; LVAR-RESULT-TNs, RESULTS my be a list of any type or
 482 ;;; number of TNs.
 483 ;;;
 484 ;;; If the lvar is fixed values, then move the results into the lvar
 485 ;;; locations. If the lvar is unknown values, then do the moves into
 486 ;;; the standard value locations, and use PUSH-VALUES to put the
 487 ;;; values on the stack.
 488 (defun move-lvar-result (node block results lvar)
 489   (declare (type node node) (type ir2-block block)
 490            (list results) (type (or lvar null) lvar))
 491   (when lvar
 492     (let ((2lvar (lvar-info lvar)))
 493       (ecase (ir2-lvar-kind 2lvar)
 494         (:fixed
 495          (let ((locs (ir2-lvar-locs 2lvar)))
 496            (unless (eq locs results)
 497              (move-results-coerced node block results locs))))
 498         (:unknown
 499          (let* ((nvals (length results))
 500                 (locs (make-standard-value-tns nvals)))
 501            (move-results-coerced node block results locs)
 502            (vop* push-values node block
 503                  ((reference-tn-list locs nil))
 504                  ((reference-tn-list (ir2-lvar-locs 2lvar) t))
 505                  nvals))))))
 506   (values))
 507
 508 ;;; CAST
 509 (defun ir2-convert-cast (node block)
 510   (declare (type cast node)
 511            (type ir2-block block))
 512   (binding* ((lvar (node-lvar node) :exit-if-null)
 513              (2lvar (lvar-info lvar))
 514              (value (cast-value node))
 515              (2value (lvar-info value)))
 516     (cond ((eq (ir2-lvar-kind 2lvar) :unused))
 517           ((eq (ir2-lvar-kind 2lvar) :unknown)
 518            (aver (eq (ir2-lvar-kind 2value) :unknown))
 519            (aver (not (cast-type-check node)))
 520            (move-results-coerced node block
 521                                  (ir2-lvar-locs 2value)
 522                                  (ir2-lvar-locs 2lvar)))
 523           ((eq (ir2-lvar-kind 2lvar) :fixed)
 524            (aver (eq (ir2-lvar-kind 2value) :fixed))
 525            (if (cast-type-check node)
 526                (move-results-checked node block
 527                                      (ir2-lvar-locs 2value)
 528                                      (ir2-lvar-locs 2lvar)
 529                                      (multiple-value-bind (check types)
 530                                          (cast-check-types node nil)
 531                                        (aver (eq check :simple))
 532                                        types))
 533                (move-results-coerced node block
 534                                      (ir2-lvar-locs 2value)
 535                                      (ir2-lvar-locs 2lvar))))
 536           (t (bug "CAST cannot be :DELAYED.")))))
 537 \f
 538 ;;;; template conversion
 539
 540 ;;; Build a TN-REFS list that represents access to the values of the
 541 ;;; specified list of lvars ARGS for TEMPLATE. Any :CONSTANT arguments
 542 ;;; are returned in the second value as a list rather than being
 543 ;;; accessed as a normal argument. NODE and BLOCK provide the context
 544 ;;; for emitting any necessary type-checking code.
 545 (defun reference-args (node block args template)
 546   (declare (type node node) (type ir2-block block) (list args)
 547            (type template template))
 548   (collect ((info-args))
 549     (let ((last nil)
 550           (first nil))
 551       (do ((args args (cdr args))
 552            (types (template-arg-types template) (cdr types)))
 553           ((null args))
 554         (let ((type (first types))
 555               (arg (first args)))
 556           (if (and (consp type) (eq (car type) ':constant))
 557               (info-args (lvar-value arg))
 558               (let ((ref (reference-tn (lvar-tn node block arg) nil)))
 559                 (if last
 560                     (setf (tn-ref-across last) ref)
 561                     (setf first ref))
 562                 (setq last ref)))))
 563
 564       (values (the (or tn-ref null) first) (info-args)))))
 565
 566 ;;; Convert a conditional template. We try to exploit any
 567 ;;; drop-through, but emit an unconditional branch afterward if we
 568 ;;; fail. NOT-P is true if the sense of the TEMPLATE's test should be
 569 ;;; negated.
 570 (defun ir2-convert-conditional (node block template args info-args if not-p)
 571   (declare (type node node) (type ir2-block block)
 572            (type template template) (type (or tn-ref null) args)
 573            (list info-args) (type cif if) (type boolean not-p))
 574   (aver (= (template-info-arg-count template) (+ (length info-args) 2)))
 575   (let ((consequent (if-consequent if))
 576         (alternative (if-alternative if)))
 577     (cond ((drop-thru-p if consequent)
 578            (emit-template node block template args nil
 579                           (list* (block-label alternative) (not not-p)
 580                                  info-args)))
 581           (t
 582            (emit-template node block template args nil
 583                           (list* (block-label consequent) not-p info-args))
 584            (unless (drop-thru-p if alternative)
 585              (vop branch node block (block-label alternative)))))))
 586
 587 ;;; Convert an IF that isn't the DEST of a conditional template.
 588 (defun ir2-convert-if (node block)
 589   (declare (type ir2-block block) (type cif node))
 590   (let* ((test (if-test node))
 591          (test-ref (reference-tn (lvar-tn node block test) nil))
 592          (nil-ref (reference-tn (emit-constant nil) nil)))
 593     (setf (tn-ref-across test-ref) nil-ref)
 594     (ir2-convert-conditional node block (template-or-lose 'if-eq)
 595                              test-ref () node t)))
 596
 597 ;;; Return a list of primitive-types that we can pass to
 598 ;;; LVAR-RESULT-TNS describing the result types we want for a
 599 ;;; template call. We duplicate here the determination of output type
 600 ;;; that was done in initially selecting the template, so we know that
 601 ;;; the types we find are allowed by the template output type
 602 ;;; restrictions.
 603 (defun find-template-result-types (call template rtypes)
 604   (declare (type combination call)
 605            (type template template) (list rtypes))
 606   (declare (ignore template))
 607   (let* ((dtype (node-derived-type call))
 608          (type dtype)
 609          (types (mapcar #'primitive-type
 610                         (if (values-type-p type)
 611                             (append (values-type-required type)
 612                                     (values-type-optional type))
 613                             (list type)))))
 614     (let ((nvals (length rtypes))
 615           (ntypes (length types)))
 616       (cond ((< ntypes nvals)
 617              (append types
 618                      (make-list (- nvals ntypes)
 619                                 :initial-element *backend-t-primitive-type*)))
 620             ((> ntypes nvals)
 621              (subseq types 0 nvals))
 622             (t
 623              types)))))
 624
 625 ;;; Return a list of TNs usable in a CALL to TEMPLATE delivering
 626 ;;; values to LVAR. As an efficiency hack, we pick off the common case
 627 ;;; where the LVAR is fixed values and has locations that satisfy the
 628 ;;; result restrictions. This can fail when there is a type check or a
 629 ;;; values count mismatch.
 630 (defun make-template-result-tns (call lvar template rtypes)
 631   (declare (type combination call) (type (or lvar null) lvar)
 632            (type template template) (list rtypes))
 633   (let ((2lvar (when lvar (lvar-info lvar))))
 634     (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :fixed))
 635         (let ((locs (ir2-lvar-locs 2lvar)))
 636           (if (and (= (length rtypes) (length locs))
 637                    (do ((loc locs (cdr loc))
 638                         (rtype rtypes (cdr rtype)))
 639                        ((null loc) t)
 640                      (unless (operand-restriction-ok
 641                               (car rtype)
 642                               (tn-primitive-type (car loc))
 643                               :t-ok nil)
 644                        (return nil))))
 645               locs
 646               (lvar-result-tns
 647                lvar
 648                (find-template-result-types call template rtypes))))
 649         (lvar-result-tns
 650          lvar
 651          (find-template-result-types call template rtypes)))))
 652
 653 ;;; Get the operands into TNs, make TN-REFs for them, and then call
 654 ;;; the template emit function.
 655 (defun ir2-convert-template (call block)
 656   (declare (type combination call) (type ir2-block block))
 657   (let* ((template (combination-info call))
 658          (lvar (node-lvar call))
 659          (rtypes (template-result-types template)))
 660     (multiple-value-bind (args info-args)
 661         (reference-args call block (combination-args call) template)
 662       (aver (not (template-more-results-type template)))
 663       (if (eq rtypes :conditional)
 664           (ir2-convert-conditional call block template args info-args
 665                                    (lvar-dest lvar) nil)
 666           (let* ((results (make-template-result-tns call lvar template rtypes))
 667                  (r-refs (reference-tn-list results t)))
 668             (aver (= (length info-args)
 669                      (template-info-arg-count template)))
 670             (when (and lvar (lvar-dynamic-extent lvar))
 671               (vop current-stack-pointer call block
 672                    (ir2-lvar-stack-pointer (lvar-info lvar))))
 673             (if info-args
 674                 (emit-template call block template args r-refs info-args)
 675                 (emit-template call block template args r-refs))
 676             (move-lvar-result call block results lvar)))))
 677   (values))
 678
 679 ;;; We don't have to do much because operand count checking is done by
 680 ;;; IR1 conversion. The only difference between this and the function
 681 ;;; case of IR2-CONVERT-TEMPLATE is that there can be codegen-info
 682 ;;; arguments.
 683 (defoptimizer (%%primitive ir2-convert) ((template info &rest args) call block)
 684   (let* ((template (lvar-value template))
 685          (info (lvar-value info))
 686          (lvar (node-lvar call))
 687          (rtypes (template-result-types template))
 688          (results (make-template-result-tns call lvar template rtypes))
 689          (r-refs (reference-tn-list results t)))
 690     (multiple-value-bind (args info-args)
 691         (reference-args call block (cddr (combination-args call)) template)
 692       (aver (not (template-more-results-type template)))
 693       (aver (not (eq rtypes :conditional)))
 694       (aver (null info-args))
 695
 696       (if info
 697           (emit-template call block template args r-refs info)
 698           (emit-template call block template args r-refs))
 699
 700       (move-lvar-result call block results lvar)))
 701   (values))
 702 \f
 703 ;;;; local call
 704
 705 ;;; Convert a LET by moving the argument values into the variables.
 706 ;;; Since a LET doesn't have any passing locations, we move the
 707 ;;; arguments directly into the variables. We must also allocate any
 708 ;;; indirect value cells, since there is no function prologue to do
 709 ;;; this.
 710 (defun ir2-convert-let (node block fun)
 711   (declare (type combination node) (type ir2-block block) (type clambda fun))
 712   (mapc (lambda (var arg)
 713           (when arg
 714             (let ((src (lvar-tn node block arg))
 715                   (dest (leaf-info var)))
 716               (if (lambda-var-indirect var)
 717                   (do-make-value-cell node block src dest)
 718                   (emit-move node block src dest)))))
 719         (lambda-vars fun) (basic-combination-args node))
 720   (values))
 721
 722 ;;; Emit any necessary moves into assignment temps for a local call to
 723 ;;; FUN. We return two lists of TNs: TNs holding the actual argument
 724 ;;; values, and (possibly EQ) TNs that are the actual destination of
 725 ;;; the arguments. When necessary, we allocate temporaries for
 726 ;;; arguments to preserve parallel assignment semantics. These lists
 727 ;;; exclude unused arguments and include implicit environment
 728 ;;; arguments, i.e. they exactly correspond to the arguments passed.
 729 ;;;
 730 ;;; OLD-FP is the TN currently holding the value we want to pass as
 731 ;;; OLD-FP. If null, then the call is to the same environment (an
 732 ;;; :ASSIGNMENT), so we only move the arguments, and leave the
 733 ;;; environment alone.
 734 (defun emit-psetq-moves (node block fun old-fp)
 735   (declare (type combination node) (type ir2-block block) (type clambda fun)
 736            (type (or tn null) old-fp))
 737   (let ((actuals (mapcar (lambda (x)
 738                            (when x
 739                              (lvar-tn node block x)))
 740                          (combination-args node))))
 741     (collect ((temps)
 742               (locs))
 743       (dolist (var (lambda-vars fun))
 744         (let ((actual (pop actuals))
 745               (loc (leaf-info var)))
 746           (when actual
 747             (cond
 748              ((lambda-var-indirect var)
 749               (let ((temp
 750                      (make-normal-tn *backend-t-primitive-type*)))
 751                 (do-make-value-cell node block actual temp)
 752                 (temps temp)))
 753              ((member actual (locs))
 754               (let ((temp (make-normal-tn (tn-primitive-type loc))))
 755                 (emit-move node block actual temp)
 756                 (temps temp)))
 757              (t
 758               (temps actual)))
 759             (locs loc))))
 760
 761       (when old-fp
 762         (let ((this-1env (node-physenv node))
 763               (called-env (physenv-info (lambda-physenv fun))))
 764           (dolist (thing (ir2-physenv-closure called-env))
 765             (temps (find-in-physenv (car thing) this-1env))
 766             (locs (cdr thing)))
 767           (temps old-fp)
 768           (locs (ir2-physenv-old-fp called-env))))
 769
 770       (values (temps) (locs)))))
 771
 772 ;;; A tail-recursive local call is done by emitting moves of stuff
 773 ;;; into the appropriate passing locations. After setting up the args
 774 ;;; and environment, we just move our return-pc into the called
 775 ;;; function's passing location.
 776 (defun ir2-convert-tail-local-call (node block fun)
 777   (declare (type combination node) (type ir2-block block) (type clambda fun))
 778   (let ((this-env (physenv-info (node-physenv node))))
 779     (multiple-value-bind (temps locs)
 780         (emit-psetq-moves node block fun (ir2-physenv-old-fp this-env))
 781
 782       (mapc (lambda (temp loc)
 783               (emit-move node block temp loc))
 784             temps locs))
 785
 786     (emit-move node block
 787                (ir2-physenv-return-pc this-env)
 788                (ir2-physenv-return-pc-pass
 789                 (physenv-info
 790                  (lambda-physenv fun)))))
 791
 792   (values))
 793
 794 ;;; Convert an :ASSIGNMENT call. This is just like a tail local call,
 795 ;;; except that the caller and callee environment are the same, so we
 796 ;;; don't need to mess with the environment locations, return PC, etc.
 797 (defun ir2-convert-assignment (node block fun)
 798   (declare (type combination node) (type ir2-block block) (type clambda fun))
 799     (multiple-value-bind (temps locs) (emit-psetq-moves node block fun nil)
 800
 801       (mapc (lambda (temp loc)
 802               (emit-move node block temp loc))
 803             temps locs))
 804   (values))
 805
 806 ;;; Do stuff to set up the arguments to a non-tail local call
 807 ;;; (including implicit environment args.) We allocate a frame
 808 ;;; (returning the FP and NFP), and also compute the TN-REFS list for
 809 ;;; the values to pass and the list of passing location TNs.
 810 (defun ir2-convert-local-call-args (node block fun)
 811   (declare (type combination node) (type ir2-block block) (type clambda fun))
 812   (let ((fp (make-stack-pointer-tn))
 813         (nfp (make-number-stack-pointer-tn))
 814         (old-fp (make-stack-pointer-tn)))
 815     (multiple-value-bind (temps locs)
 816         (emit-psetq-moves node block fun old-fp)
 817       (vop current-fp node block old-fp)
 818       (vop allocate-frame node block
 819            (physenv-info (lambda-physenv fun))
 820            fp nfp)
 821       (values fp nfp temps (mapcar #'make-alias-tn locs)))))
 822
 823 ;;; Handle a non-TR known-values local call. We emit the call, then
 824 ;;; move the results to the lvar's destination.
 825 (defun ir2-convert-local-known-call (node block fun returns lvar start)
 826   (declare (type node node) (type ir2-block block) (type clambda fun)
 827            (type return-info returns) (type (or lvar null) lvar)
 828            (type label start))
 829   (multiple-value-bind (fp nfp temps arg-locs)
 830       (ir2-convert-local-call-args node block fun)
 831     (let ((locs (return-info-locations returns)))
 832       (vop* known-call-local node block
 833             (fp nfp (reference-tn-list temps nil))
 834             ((reference-tn-list locs t))
 835             arg-locs (physenv-info (lambda-physenv fun)) start)
 836       (move-lvar-result node block locs lvar)))
 837   (values))
 838
 839 ;;; Handle a non-TR unknown-values local call. We do different things
 840 ;;; depending on what kind of values the lvar wants.
 841 ;;;
 842 ;;; If LVAR is :UNKNOWN, then we use the "multiple-" variant, directly
 843 ;;; specifying the lvar's LOCS as the VOP results so that we don't
 844 ;;; have to do anything after the call.
 845 ;;;
 846 ;;; Otherwise, we use STANDARD-RESULT-TNS to get wired result TNs, and
 847 ;;; then call MOVE-LVAR-RESULT to do any necessary type checks or
 848 ;;; coercions.
 849 (defun ir2-convert-local-unknown-call (node block fun lvar start)
 850   (declare (type node node) (type ir2-block block) (type clambda fun)
 851            (type (or lvar null) lvar) (type label start))
 852   (multiple-value-bind (fp nfp temps arg-locs)
 853       (ir2-convert-local-call-args node block fun)
 854     (let ((2lvar (and lvar (lvar-info lvar)))
 855           (env (physenv-info (lambda-physenv fun)))
 856           (temp-refs (reference-tn-list temps nil)))
 857       (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :unknown))
 858           (vop* multiple-call-local node block (fp nfp temp-refs)
 859                 ((reference-tn-list (ir2-lvar-locs 2lvar) t))
 860                 arg-locs env start)
 861           (let ((locs (standard-result-tns lvar)))
 862             (vop* call-local node block
 863                   (fp nfp temp-refs)
 864                   ((reference-tn-list locs t))
 865                   arg-locs env start (length locs))
 866             (move-lvar-result node block locs lvar)))))
 867   (values))
 868
 869 ;;; Dispatch to the appropriate function, depending on whether we have
 870 ;;; a let, tail or normal call. If the function doesn't return, call
 871 ;;; it using the unknown-value convention. We could compile it as a
 872 ;;; tail call, but that might seem confusing in the debugger.
 873 (defun ir2-convert-local-call (node block)
 874   (declare (type combination node) (type ir2-block block))
 875   (let* ((fun (ref-leaf (lvar-uses (basic-combination-fun node))))
 876          (kind (functional-kind fun)))
 877     (cond ((eq kind :let)
 878            (ir2-convert-let node block fun))
 879           ((eq kind :assignment)
 880            (ir2-convert-assignment node block fun))
 881           ((node-tail-p node)
 882            (ir2-convert-tail-local-call node block fun))
 883           (t
 884            (let ((start (block-label (lambda-block fun)))
 885                  (returns (tail-set-info (lambda-tail-set fun)))
 886                  (lvar (node-lvar node)))
 887              (ecase (if returns
 888                         (return-info-kind returns)
 889                         :unknown)
 890                (:unknown
 891                 (ir2-convert-local-unknown-call node block fun lvar start))
 892                (:fixed
 893                 (ir2-convert-local-known-call node block fun returns
 894                                               lvar start)))))))
 895   (values))
 896 \f
 897 ;;;; full call
 898
 899 ;;; Given a function lvar FUN, return (VALUES TN-TO-CALL NAMED-P),
 900 ;;; where TN-TO-CALL is a TN holding the thing that we call NAMED-P is
 901 ;;; true if the thing is named (false if it is a function).
 902 ;;;
 903 ;;; There are two interesting non-named cases:
 904 ;;;   -- We know it's a function. No check needed: return the
 905 ;;;      lvar LOC.
 906 ;;;   -- We don't know what it is.
 907 (defun fun-lvar-tn (node block lvar)
 908   (declare (ignore node block))
 909   (declare (type lvar lvar))
 910   (let ((2lvar (lvar-info lvar)))
 911     (if (eq (ir2-lvar-kind 2lvar) :delayed)
 912         (let ((name (lvar-fun-name lvar t)))
 913           (aver name)
 914           (values (make-load-time-constant-tn :fdefinition name) t))
 915         (let* ((locs (ir2-lvar-locs 2lvar))
 916                (loc (first locs))
 917                (function-ptype (primitive-type-or-lose 'function)))
 918           (aver (and (eq (ir2-lvar-kind 2lvar) :fixed)
 919                      (= (length locs) 1)))
 920           (aver (eq (tn-primitive-type loc) function-ptype))
 921           (values loc nil)))))
 922
 923 ;;; Set up the args to NODE in the current frame, and return a TN-REF
 924 ;;; list for the passing locations.
 925 (defun move-tail-full-call-args (node block)
 926   (declare (type combination node) (type ir2-block block))
 927   (let ((args (basic-combination-args node))
 928         (last nil)
 929         (first nil))
 930     (dotimes (num (length args))
 931       (let ((loc (standard-arg-location num)))
 932         (emit-move node block (lvar-tn node block (elt args num)) loc)
 933         (let ((ref (reference-tn loc nil)))
 934           (if last
 935               (setf (tn-ref-across last) ref)
 936               (setf first ref))
 937           (setq last ref))))
 938       first))
 939
 940 ;;; Move the arguments into the passing locations and do a (possibly
 941 ;;; named) tail call.
 942 (defun ir2-convert-tail-full-call (node block)
 943   (declare (type combination node) (type ir2-block block))
 944   (let* ((env (physenv-info (node-physenv node)))
 945          (args (basic-combination-args node))
 946          (nargs (length args))
 947          (pass-refs (move-tail-full-call-args node block))
 948          (old-fp (ir2-physenv-old-fp env))
 949          (return-pc (ir2-physenv-return-pc env)))
 950
 951     (multiple-value-bind (fun-tn named)
 952         (fun-lvar-tn node block (basic-combination-fun node))
 953       (if named
 954           (vop* tail-call-named node block
 955                 (fun-tn old-fp return-pc pass-refs)
 956                 (nil)
 957                 nargs)
 958           (vop* tail-call node block
 959                 (fun-tn old-fp return-pc pass-refs)
 960                 (nil)
 961                 nargs))))
 962
 963   (values))
 964
 965 ;;; like IR2-CONVERT-LOCAL-CALL-ARGS, only different
 966 (defun ir2-convert-full-call-args (node block)
 967   (declare (type combination node) (type ir2-block block))
 968   (let* ((args (basic-combination-args node))
 969          (fp (make-stack-pointer-tn))
 970          (nargs (length args)))
 971     (vop allocate-full-call-frame node block nargs fp)
 972     (collect ((locs))
 973       (let ((last nil)
 974             (first nil))
 975         (dotimes (num nargs)
 976           (locs (standard-arg-location num))
 977           (let ((ref (reference-tn (lvar-tn node block (elt args num))
 978                                    nil)))
 979             (if last
 980                 (setf (tn-ref-across last) ref)
 981                 (setf first ref))
 982             (setq last ref)))
 983
 984         (values fp first (locs) nargs)))))
 985
 986 ;;; Do full call when a fixed number of values are desired. We make
 987 ;;; STANDARD-RESULT-TNS for our lvar, then deliver the result using
 988 ;;; MOVE-LVAR-RESULT. We do named or normal call, as appropriate.
 989 (defun ir2-convert-fixed-full-call (node block)
 990   (declare (type combination node) (type ir2-block block))
 991   (multiple-value-bind (fp args arg-locs nargs)
 992       (ir2-convert-full-call-args node block)
 993     (let* ((lvar (node-lvar node))
 994            (locs (standard-result-tns lvar))
 995            (loc-refs (reference-tn-list locs t))
 996            (nvals (length locs)))
 997       (multiple-value-bind (fun-tn named)
 998           (fun-lvar-tn node block (basic-combination-fun node))
 999         (if named
1000             (vop* call-named node block (fp fun-tn args) (loc-refs)
1001                   arg-locs nargs nvals)
1002             (vop* call node block (fp fun-tn args) (loc-refs)
1003                   arg-locs nargs nvals))
1004         (move-lvar-result node block locs lvar))))
1005   (values))
1006
1007 ;;; Do full call when unknown values are desired.
1008 (defun ir2-convert-multiple-full-call (node block)
1009   (declare (type combination node) (type ir2-block block))
1010   (multiple-value-bind (fp args arg-locs nargs)
1011       (ir2-convert-full-call-args node block)
1012     (let* ((lvar (node-lvar node))
1013            (locs (ir2-lvar-locs (lvar-info lvar)))
1014            (loc-refs (reference-tn-list locs t)))
1015       (multiple-value-bind (fun-tn named)
1016           (fun-lvar-tn node block (basic-combination-fun node))
1017         (if named
1018             (vop* multiple-call-named node block (fp fun-tn args) (loc-refs)
1019                   arg-locs nargs)
1020             (vop* multiple-call node block (fp fun-tn args) (loc-refs)
1021                   arg-locs nargs)))))
1022   (values))
1023
1024 ;;; stuff to check in PONDER-FULL-CALL
1025 ;;;
1026 ;;; These came in handy when troubleshooting cold boot after making
1027 ;;; major changes in the package structure: various transforms and
1028 ;;; VOPs and stuff got attached to the wrong symbol, so that
1029 ;;; references to the right symbol were bogusly translated as full
1030 ;;; calls instead of primitives, sending the system off into infinite
1031 ;;; space. Having a report on all full calls generated makes it easier
1032 ;;; to figure out what form caused the problem this time.
1033 #!+sb-show (defvar *show-full-called-fnames-p* nil)
1034 #!+sb-show (defvar *full-called-fnames* (make-hash-table :test 'equal))
1035
1036 ;;; Do some checks (and store some notes relevant for future checks)
1037 ;;; on a full call:
1038 ;;;   * Is this a full call to something we have reason to know should
1039 ;;;     never be full called? (Except as of sbcl-0.7.18 or so, we no
1040 ;;;     longer try to ensure this behavior when *FAILURE-P* has already
1041 ;;;     been detected.)
1042 ;;;   * Is this a full call to (SETF FOO) which might conflict with
1043 ;;;     a DEFSETF or some such thing elsewhere in the program?
1044 (defun ponder-full-call (node)
1045   (let* ((lvar (basic-combination-fun node))
1046          (fname (lvar-fun-name lvar t)))
1047     (declare (type (or symbol cons) fname))
1048
1049     #!+sb-show (unless (gethash fname *full-called-fnames*)
1050                  (setf (gethash fname *full-called-fnames*) t))
1051     #!+sb-show (when *show-full-called-fnames-p*
1052                  (/show "converting full call to named function" fname)
1053                  (/show (basic-combination-args node))
1054                  (/show (policy node speed) (policy node safety))
1055                  (/show (policy node compilation-speed))
1056                  (let ((arg-types (mapcar (lambda (lvar)
1057                                             (when lvar
1058                                               (type-specifier
1059                                                (lvar-type lvar))))
1060                                           (basic-combination-args node))))
1061                    (/show arg-types)))
1062
1063     ;; When illegal code is compiled, all sorts of perverse paths
1064     ;; through the compiler can be taken, and it's much harder -- and
1065     ;; probably pointless -- to guarantee that always-optimized-away
1066     ;; functions are actually optimized away. Thus, we skip the check
1067     ;; in that case.
1068     (unless *failure-p*
1069       ;; check to see if we know anything about the function
1070       (let ((info (info :function :info fname)))
1071         ;; if we know something, check to see if the full call was valid
1072         (when (and info (ir1-attributep (fun-info-attributes info)
1073                                         always-translatable))
1074           (/show (policy node speed) (policy node safety))
1075           (/show (policy node compilation-speed))
1076           (bug "full call to ~S" fname))))
1077
1078     (when (consp fname)
1079       (aver (legal-fun-name-p fname))
1080       (destructuring-bind (setfoid &rest stem) fname
1081         (when (eq setfoid 'setf)
1082           (setf (gethash (car stem) *setf-assumed-fboundp*) t))))))
1083
1084 ;;; If the call is in a tail recursive position and the return
1085 ;;; convention is standard, then do a tail full call. If one or fewer
1086 ;;; values are desired, then use a single-value call, otherwise use a
1087 ;;; multiple-values call.
1088 (defun ir2-convert-full-call (node block)
1089   (declare (type combination node) (type ir2-block block))
1090   (ponder-full-call node)
1091   (cond ((node-tail-p node)
1092          (ir2-convert-tail-full-call node block))
1093         ((let ((lvar (node-lvar node)))
1094            (and lvar
1095                 (eq (ir2-lvar-kind (lvar-info lvar)) :unknown)))
1096          (ir2-convert-multiple-full-call node block))
1097         (t
1098          (ir2-convert-fixed-full-call node block)))
1099   (values))
1100 \f
1101 ;;;; entering functions
1102
1103 ;;; Do all the stuff that needs to be done on XEP entry:
1104 ;;; -- Create frame.
1105 ;;; -- Copy any more arg.
1106 ;;; -- Set up the environment, accessing any closure variables.
1107 ;;; -- Move args from the standard passing locations to their internal
1108 ;;;    locations.
1109 (defun init-xep-environment (node block fun)
1110   (declare (type bind node) (type ir2-block block) (type clambda fun))
1111   (let ((start-label (entry-info-offset (leaf-info fun)))
1112         (env (physenv-info (node-physenv node))))
1113     (let ((ef (functional-entry-fun fun)))
1114       (cond ((and (optional-dispatch-p ef) (optional-dispatch-more-entry ef))
1115              ;; Special case the xep-allocate-frame + copy-more-arg case.
1116              (vop xep-allocate-frame node block start-label t)
1117              (vop copy-more-arg node block (optional-dispatch-max-args ef)))
1118             (t
1119              ;; No more args, so normal entry.
1120              (vop xep-allocate-frame node block start-label nil)))
1121       (if (ir2-physenv-closure env)
1122           (let ((closure (make-normal-tn *backend-t-primitive-type*)))
1123             (vop setup-closure-environment node block start-label closure)
1124             ;; KLUDGE: see the comment around the definition of
1125             ;; CLOSURE objects in src/compiler/objdef.lisp
1126             (vop funcallable-instance-lexenv node block closure closure)
1127             (let ((n -1))
1128               (dolist (loc (ir2-physenv-closure env))
1129                 (vop closure-ref node block closure (incf n) (cdr loc)))))
1130           (vop setup-environment node block start-label)))
1131
1132     (unless (eq (functional-kind fun) :toplevel)
1133       (let ((vars (lambda-vars fun))
1134             (n 0))
1135         (when (leaf-refs (first vars))
1136           (emit-move node block (make-arg-count-location)
1137                      (leaf-info (first vars))))
1138         (dolist (arg (rest vars))
1139           (when (leaf-refs arg)
1140             (let ((pass (standard-arg-location n))
1141                   (home (leaf-info arg)))
1142               (if (lambda-var-indirect arg)
1143                   (do-make-value-cell node block pass home)
1144                   (emit-move node block pass home))))
1145           (incf n))))
1146
1147     (emit-move node block (make-old-fp-passing-location t)
1148                (ir2-physenv-old-fp env)))
1149
1150   (values))
1151
1152 ;;; Emit function prolog code. This is only called on bind nodes for
1153 ;;; functions that allocate environments. All semantics of let calls
1154 ;;; are handled by IR2-CONVERT-LET.
1155 ;;;
1156 ;;; If not an XEP, all we do is move the return PC from its passing
1157 ;;; location, since in a local call, the caller allocates the frame
1158 ;;; and sets up the arguments.
1159 (defun ir2-convert-bind (node block)
1160   (declare (type bind node) (type ir2-block block))
1161   (let* ((fun (bind-lambda node))
1162          (env (physenv-info (lambda-physenv fun))))
1163     (aver (member (functional-kind fun)
1164                   '(nil :external :optional :toplevel :cleanup)))
1165
1166     (when (xep-p fun)
1167       (init-xep-environment node block fun)
1168       #!+sb-dyncount
1169       (when *collect-dynamic-statistics*
1170         (vop count-me node block *dynamic-counts-tn*
1171              (block-number (ir2-block-block block)))))
1172
1173     (emit-move node
1174                block
1175                (ir2-physenv-return-pc-pass env)
1176                (ir2-physenv-return-pc env))
1177
1178     (let ((lab (gen-label)))
1179       (setf (ir2-physenv-environment-start env) lab)
1180       (vop note-environment-start node block lab)))
1181
1182   (values))
1183 \f
1184 ;;;; function return
1185
1186 ;;; Do stuff to return from a function with the specified values and
1187 ;;; convention. If the return convention is :FIXED and we aren't
1188 ;;; returning from an XEP, then we do a known return (letting
1189 ;;; representation selection insert the correct move-arg VOPs.)
1190 ;;; Otherwise, we use the unknown-values convention. If there is a
1191 ;;; fixed number of return values, then use RETURN, otherwise use
1192 ;;; RETURN-MULTIPLE.
1193 (defun ir2-convert-return (node block)
1194   (declare (type creturn node) (type ir2-block block))
1195   (let* ((lvar (return-result node))
1196          (2lvar (lvar-info lvar))
1197          (lvar-kind (ir2-lvar-kind 2lvar))
1198          (fun (return-lambda node))
1199          (env (physenv-info (lambda-physenv fun)))
1200          (old-fp (ir2-physenv-old-fp env))
1201          (return-pc (ir2-physenv-return-pc env))
1202          (returns (tail-set-info (lambda-tail-set fun))))
1203     (cond
1204      ((and (eq (return-info-kind returns) :fixed)
1205            (not (xep-p fun)))
1206       (let ((locs (lvar-tns node block lvar
1207                                     (return-info-types returns))))
1208         (vop* known-return node block
1209               (old-fp return-pc (reference-tn-list locs nil))
1210               (nil)
1211               (return-info-locations returns))))
1212      ((eq lvar-kind :fixed)
1213       (let* ((types (mapcar #'tn-primitive-type (ir2-lvar-locs 2lvar)))
1214              (lvar-locs (lvar-tns node block lvar types))
1215              (nvals (length lvar-locs))
1216              (locs (make-standard-value-tns nvals)))
1217         (mapc (lambda (val loc)
1218                 (emit-move node block val loc))
1219               lvar-locs
1220               locs)
1221         (if (= nvals 1)
1222             (vop return-single node block old-fp return-pc (car locs))
1223             (vop* return node block
1224                   (old-fp return-pc (reference-tn-list locs nil))
1225                   (nil)
1226                   nvals))))
1227      (t
1228       (aver (eq lvar-kind :unknown))
1229       (vop* return-multiple node block
1230             (old-fp return-pc
1231                     (reference-tn-list (ir2-lvar-locs 2lvar) nil))
1232             (nil)))))
1233
1234   (values))
1235 \f
1236 ;;;; debugger hooks
1237
1238 ;;; This is used by the debugger to find the top function on the
1239 ;;; stack. It returns the OLD-FP and RETURN-PC for the current
1240 ;;; function as multiple values.
1241 (defoptimizer (sb!kernel:%caller-frame-and-pc ir2-convert) (() node block)
1242   (let ((ir2-physenv (physenv-info (node-physenv node))))
1243     (move-lvar-result node block
1244                       (list (ir2-physenv-old-fp ir2-physenv)
1245                             (ir2-physenv-return-pc ir2-physenv))
1246                       (node-lvar node))))
1247 \f
1248 ;;;; multiple values
1249
1250 ;;; This is almost identical to IR2-CONVERT-LET. Since LTN annotates
1251 ;;; the lvar for the correct number of values (with the lvar user
1252 ;;; responsible for defaulting), we can just pick them up from the
1253 ;;; lvar.
1254 (defun ir2-convert-mv-bind (node block)
1255   (declare (type mv-combination node) (type ir2-block block))
1256   (let* ((lvar (first (basic-combination-args node)))
1257          (fun (ref-leaf (lvar-uses (basic-combination-fun node))))
1258          (vars (lambda-vars fun)))
1259     (aver (eq (functional-kind fun) :mv-let))
1260     (mapc (lambda (src var)
1261             (when (leaf-refs var)
1262               (let ((dest (leaf-info var)))
1263                 (if (lambda-var-indirect var)
1264                     (do-make-value-cell node block src dest)
1265                     (emit-move node block src dest)))))
1266           (lvar-tns node block lvar
1267                             (mapcar (lambda (x)
1268                                       (primitive-type (leaf-type x)))
1269                                     vars))
1270           vars))
1271   (values))
1272
1273 ;;; Emit the appropriate fixed value, unknown value or tail variant of
1274 ;;; CALL-VARIABLE. Note that we only need to pass the values start for
1275 ;;; the first argument: all the other argument lvar TNs are
1276 ;;; ignored. This is because we require all of the values globs to be
1277 ;;; contiguous and on stack top.
1278 (defun ir2-convert-mv-call (node block)
1279   (declare (type mv-combination node) (type ir2-block block))
1280   (aver (basic-combination-args node))
1281   (let* ((start-lvar (lvar-info (first (basic-combination-args node))))
1282          (start (first (ir2-lvar-locs start-lvar)))
1283          (tails (and (node-tail-p node)
1284                      (lambda-tail-set (node-home-lambda node))))
1285          (lvar (node-lvar node))
1286          (2lvar (and lvar (lvar-info lvar))))
1287     (multiple-value-bind (fun named)
1288         (fun-lvar-tn node block (basic-combination-fun node))
1289       (aver (and (not named)
1290                  (eq (ir2-lvar-kind start-lvar) :unknown)))
1291       (cond
1292        (tails
1293         (let ((env (physenv-info (node-physenv node))))
1294           (vop tail-call-variable node block start fun
1295                (ir2-physenv-old-fp env)
1296                (ir2-physenv-return-pc env))))
1297        ((and 2lvar
1298              (eq (ir2-lvar-kind 2lvar) :unknown))
1299         (vop* multiple-call-variable node block (start fun nil)
1300               ((reference-tn-list (ir2-lvar-locs 2lvar) t))))
1301        (t
1302         (let ((locs (standard-result-tns lvar)))
1303           (vop* call-variable node block (start fun nil)
1304                 ((reference-tn-list locs t)) (length locs))
1305           (move-lvar-result node block locs lvar)))))))
1306
1307 ;;; Reset the stack pointer to the start of the specified
1308 ;;; unknown-values lvar (discarding it and all values globs on top of
1309 ;;; it.)
1310 (defoptimizer (%pop-values ir2-convert) ((%lvar) node block)
1311   (let* ((lvar (lvar-value %lvar))
1312          (2lvar (lvar-info lvar)))
1313     (cond ((eq (ir2-lvar-kind 2lvar) :unknown)
1314            (vop reset-stack-pointer node block
1315                 (first (ir2-lvar-locs 2lvar))))
1316           ((lvar-dynamic-extent lvar)
1317            (vop reset-stack-pointer node block
1318                 (ir2-lvar-stack-pointer 2lvar)))
1319           (t (bug "Trying to pop a not stack-allocated LVAR ~S."
1320                   lvar)))))
1321
1322 (defoptimizer (%nip-values ir2-convert) ((last-nipped last-preserved
1323                                                       &rest moved)
1324                                          node block)
1325   (let* ( ;; pointer immediately after the nipped block
1326          (after (lvar-value last-nipped))
1327          (2after (lvar-info after))
1328          ;; pointer to the first nipped word
1329          (first (lvar-value last-preserved))
1330          (2first (lvar-info first))
1331
1332          (moved-tns (loop for lvar-ref in moved
1333                           for lvar = (lvar-value lvar-ref)
1334                           for 2lvar = (lvar-info lvar)
1335                                         ;when 2lvar
1336                           collect (first (ir2-lvar-locs 2lvar)))))
1337     (aver (or (eq (ir2-lvar-kind 2after) :unknown)
1338               (lvar-dynamic-extent after)))
1339     (aver (eq (ir2-lvar-kind 2first) :unknown))
1340     (when *check-consistency*
1341       ;; we cannot move stack-allocated DX objects
1342       (dolist (moved-lvar moved)
1343         (aver (eq (ir2-lvar-kind (lvar-info (lvar-value moved-lvar)))
1344                   :unknown))))
1345     (flet ((nip-aligned (nipped)
1346              (vop* %%nip-values node block
1347                    (nipped
1348                     (first (ir2-lvar-locs 2first))
1349                     (reference-tn-list moved-tns nil))
1350                    ((reference-tn-list moved-tns t)))))
1351       (cond ((eq (ir2-lvar-kind 2after) :unknown)
1352              (nip-aligned (first (ir2-lvar-locs 2after))))
1353             ((lvar-dynamic-extent after)
1354              (nip-aligned (ir2-lvar-stack-pointer 2after)))
1355             (t
1356              (bug "Trying to nip a not stack-allocated LVAR ~S." after))))))
1357
1358 ;;; Deliver the values TNs to LVAR using MOVE-LVAR-RESULT.
1359 (defoptimizer (values ir2-convert) ((&rest values) node block)
1360   (let ((tns (mapcar (lambda (x)
1361                        (lvar-tn node block x))
1362                      values)))
1363     (move-lvar-result node block tns (node-lvar node))))
1364
1365 ;;; In the normal case where unknown values are desired, we use the
1366 ;;; VALUES-LIST VOP. In the relatively unimportant case of VALUES-LIST
1367 ;;; for a fixed number of values, we punt by doing a full call to the
1368 ;;; VALUES-LIST function. This gets the full call VOP to deal with
1369 ;;; defaulting any unsupplied values. It seems unworthwhile to
1370 ;;; optimize this case.
1371 (defoptimizer (values-list ir2-convert) ((list) node block)
1372   (let* ((lvar (node-lvar node))
1373          (2lvar (and lvar (lvar-info lvar))))
1374     (cond ((and 2lvar
1375                 (eq (ir2-lvar-kind 2lvar) :unknown))
1376            (let ((locs (ir2-lvar-locs 2lvar)))
1377              (vop* values-list node block
1378                    ((lvar-tn node block list) nil)
1379                    ((reference-tn-list locs t)))))
1380           (t (aver (or (not 2lvar) ; i.e. we want to check the argument
1381                        (eq (ir2-lvar-kind 2lvar) :fixed)))
1382              (ir2-convert-full-call node block)))))
1383
1384 (defoptimizer (%more-arg-values ir2-convert) ((context start count) node block)
1385   (binding* ((lvar (node-lvar node) :exit-if-null)
1386              (2lvar (lvar-info lvar)))
1387     (ecase (ir2-lvar-kind 2lvar)
1388       (:fixed (ir2-convert-full-call node block))
1389       (:unknown
1390        (let ((locs (ir2-lvar-locs 2lvar)))
1391          (vop* %more-arg-values node block
1392                ((lvar-tn node block context)
1393                 (lvar-tn node block start)
1394                 (lvar-tn node block count)
1395                 nil)
1396                ((reference-tn-list locs t))))))))
1397 \f
1398 ;;;; special binding
1399
1400 ;;; This is trivial, given our assumption of a shallow-binding
1401 ;;; implementation.
1402 (defoptimizer (%special-bind ir2-convert) ((var value) node block)
1403   (let ((name (leaf-source-name (lvar-value var))))
1404     (vop bind node block (lvar-tn node block value)
1405          (emit-constant name))))
1406 (defoptimizer (%special-unbind ir2-convert) ((var) node block)
1407   (vop unbind node block))
1408
1409 ;;; ### It's not clear that this really belongs in this file, or
1410 ;;; should really be done this way, but this is the least violation of
1411 ;;; abstraction in the current setup. We don't want to wire
1412 ;;; shallow-binding assumptions into IR1tran.
1413 (def-ir1-translator progv
1414     ((vars vals &body body) start next result)
1415   (ir1-convert
1416    start next result
1417    (with-unique-names (bind unbind)
1418      (once-only ((n-save-bs '(%primitive current-binding-pointer)))
1419        `(unwind-protect
1420              (progn
1421                (labels ((,unbind (vars)
1422                           (declare (optimize (speed 2) (debug 0)))
1423                           (dolist (var vars)
1424                             (%primitive bind nil var)
1425                             (makunbound var)))
1426                         (,bind (vars vals)
1427                           (declare (optimize (speed 2) (debug 0)))
1428                           (cond ((null vars))
1429                                 ((null vals) (,unbind vars))
1430                                 (t (%primitive bind
1431                                                (car vals)
1432                                                (car vars))
1433                                    (,bind (cdr vars) (cdr vals))))))
1434                  (,bind ,vars ,vals))
1435                nil
1436                ,@body)
1437           (%primitive unbind-to-here ,n-save-bs))))))
1438 \f
1439 ;;;; non-local exit
1440
1441 ;;; Convert a non-local lexical exit. First find the NLX-INFO in our
1442 ;;; environment. Note that this is never called on the escape exits
1443 ;;; for CATCH and UNWIND-PROTECT, since the escape functions aren't
1444 ;;; IR2 converted.
1445 (defun ir2-convert-exit (node block)
1446   (declare (type exit node) (type ir2-block block))
1447   (let* ((nlx (exit-nlx-info node))
1448          (loc (find-in-physenv nlx (node-physenv node)))
1449          (temp (make-stack-pointer-tn))
1450          (value (exit-value node)))
1451     (if (nlx-info-safe-p nlx)
1452         (vop value-cell-ref node block loc temp)
1453         (emit-move node block loc temp))
1454     (if value
1455         (let ((locs (ir2-lvar-locs (lvar-info value))))
1456           (vop unwind node block temp (first locs) (second locs)))
1457         (let ((0-tn (emit-constant 0)))
1458           (vop unwind node block temp 0-tn 0-tn))))
1459
1460   (values))
1461
1462 ;;; %CLEANUP-POINT doesn't do anything except prevent the body from
1463 ;;; being entirely deleted.
1464 (defoptimizer (%cleanup-point ir2-convert) (() node block) node block)
1465
1466 ;;; This function invalidates a lexical exit on exiting from the
1467 ;;; dynamic extent. This is done by storing 0 into the indirect value
1468 ;;; cell that holds the closed unwind block.
1469 (defoptimizer (%lexical-exit-breakup ir2-convert) ((info) node block)
1470   (let ((nlx (lvar-value info)))
1471     (when (nlx-info-safe-p nlx)
1472       (vop value-cell-set node block
1473            (find-in-physenv nlx (node-physenv node))
1474            (emit-constant 0)))))
1475
1476 ;;; We have to do a spurious move of no values to the result lvar so
1477 ;;; that lifetime analysis won't get confused.
1478 (defun ir2-convert-throw (node block)
1479   (declare (type mv-combination node) (type ir2-block block))
1480   (let ((args (basic-combination-args node)))
1481     (check-catch-tag-type (first args))
1482     (vop* throw node block
1483           ((lvar-tn node block (first args))
1484            (reference-tn-list
1485             (ir2-lvar-locs (lvar-info (second args)))
1486             nil))
1487           (nil)))
1488   (move-lvar-result node block () (node-lvar node))
1489   (values))
1490
1491 ;;; Emit code to set up a non-local exit. INFO is the NLX-INFO for the
1492 ;;; exit, and TAG is the lvar for the catch tag (if any.) We get at
1493 ;;; the target PC by passing in the label to the vop. The vop is
1494 ;;; responsible for building a return-PC object.
1495 (defun emit-nlx-start (node block info tag)
1496   (declare (type node node) (type ir2-block block) (type nlx-info info)
1497            (type (or lvar null) tag))
1498   (let* ((2info (nlx-info-info info))
1499          (kind (cleanup-kind (nlx-info-cleanup info)))
1500          (block-tn (physenv-live-tn
1501                     (make-normal-tn (primitive-type-or-lose 'catch-block))
1502                     (node-physenv node)))
1503          (res (make-stack-pointer-tn))
1504          (target-label (ir2-nlx-info-target 2info)))
1505
1506     (vop current-binding-pointer node block
1507          (car (ir2-nlx-info-dynamic-state 2info)))
1508     (vop* save-dynamic-state node block
1509           (nil)
1510           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) t)))
1511     (vop current-stack-pointer node block (ir2-nlx-info-save-sp 2info))
1512
1513     (ecase kind
1514       (:catch
1515        (vop make-catch-block node block block-tn
1516             (lvar-tn node block tag) target-label res))
1517       ((:unwind-protect :block :tagbody)
1518        (vop make-unwind-block node block block-tn target-label res)))
1519
1520     (ecase kind
1521       ((:block :tagbody)
1522        (if (nlx-info-safe-p info)
1523            (do-make-value-cell node block res (ir2-nlx-info-home 2info))
1524            (emit-move node block res (ir2-nlx-info-home 2info))))
1525       (:unwind-protect
1526        (vop set-unwind-protect node block block-tn))
1527       (:catch)))
1528
1529   (values))
1530
1531 ;;; Scan each of ENTRY's exits, setting up the exit for each lexical exit.
1532 (defun ir2-convert-entry (node block)
1533   (declare (type entry node) (type ir2-block block))
1534   (let ((nlxes '()))
1535     (dolist (exit (entry-exits node))
1536       (let ((info (exit-nlx-info exit)))
1537         (when (and info
1538                    (not (memq info nlxes))
1539                    (member (cleanup-kind (nlx-info-cleanup info))
1540                            '(:block :tagbody)))
1541           (push info nlxes)
1542           (emit-nlx-start node block info nil)))))
1543   (values))
1544
1545 ;;; Set up the unwind block for these guys.
1546 (defoptimizer (%catch ir2-convert) ((info-lvar tag) node block)
1547   (check-catch-tag-type tag)
1548   (emit-nlx-start node block (lvar-value info-lvar) tag))
1549 (defoptimizer (%unwind-protect ir2-convert) ((info-lvar cleanup) node block)
1550   (emit-nlx-start node block (lvar-value info-lvar) nil))
1551
1552 ;;; Emit the entry code for a non-local exit. We receive values and
1553 ;;; restore dynamic state.
1554 ;;;
1555 ;;; In the case of a lexical exit or CATCH, we look at the exit lvar's
1556 ;;; kind to determine which flavor of entry VOP to emit. If unknown
1557 ;;; values, emit the xxx-MULTIPLE variant to the lvar locs. If fixed
1558 ;;; values, make the appropriate number of temps in the standard
1559 ;;; values locations and use the other variant, delivering the temps
1560 ;;; to the lvar using MOVE-LVAR-RESULT.
1561 ;;;
1562 ;;; In the UNWIND-PROTECT case, we deliver the first register
1563 ;;; argument, the argument count and the argument pointer to our lvar
1564 ;;; as multiple values. These values are the block exited to and the
1565 ;;; values start and count.
1566 ;;;
1567 ;;; After receiving values, we restore dynamic state. Except in the
1568 ;;; UNWIND-PROTECT case, the values receiving restores the stack
1569 ;;; pointer. In an UNWIND-PROTECT cleanup, we want to leave the stack
1570 ;;; pointer alone, since the thrown values are still out there.
1571 (defoptimizer (%nlx-entry ir2-convert) ((info-lvar) node block)
1572   (let* ((info (lvar-value info-lvar))
1573          (lvar (node-lvar node))
1574          (2info (nlx-info-info info))
1575          (top-loc (ir2-nlx-info-save-sp 2info))
1576          (start-loc (make-nlx-entry-arg-start-location))
1577          (count-loc (make-arg-count-location))
1578          (target (ir2-nlx-info-target 2info)))
1579
1580     (ecase (cleanup-kind (nlx-info-cleanup info))
1581       ((:catch :block :tagbody)
1582        (let ((2lvar (and lvar (lvar-info lvar))))
1583          (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :unknown))
1584              (vop* nlx-entry-multiple node block
1585                    (top-loc start-loc count-loc nil)
1586                    ((reference-tn-list (ir2-lvar-locs 2lvar) t))
1587                    target)
1588              (let ((locs (standard-result-tns lvar)))
1589                (vop* nlx-entry node block
1590                      (top-loc start-loc count-loc nil)
1591                      ((reference-tn-list locs t))
1592                      target
1593                      (length locs))
1594                (move-lvar-result node block locs lvar)))))
1595       (:unwind-protect
1596        (let ((block-loc (standard-arg-location 0)))
1597          (vop uwp-entry node block target block-loc start-loc count-loc)
1598          (move-lvar-result
1599           node block
1600           (list block-loc start-loc count-loc)
1601           lvar))))
1602
1603     #!+sb-dyncount
1604     (when *collect-dynamic-statistics*
1605       (vop count-me node block *dynamic-counts-tn*
1606            (block-number (ir2-block-block block))))
1607
1608     (vop* restore-dynamic-state node block
1609           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) nil))
1610           (nil))
1611     (vop unbind-to-here node block
1612          (car (ir2-nlx-info-dynamic-state 2info)))))
1613 \f
1614 ;;;; n-argument functions
1615
1616 (macrolet ((def (name)
1617              `(defoptimizer (,name ir2-convert) ((&rest args) node block)
1618                 (let* ((refs (move-tail-full-call-args node block))
1619                        (lvar (node-lvar node))
1620                        (res (lvar-result-tns
1621                              lvar
1622                              (list (primitive-type (specifier-type 'list))))))
1623                   (when (and lvar (lvar-dynamic-extent lvar))
1624                     (vop current-stack-pointer node block
1625                          (ir2-lvar-stack-pointer (lvar-info lvar))))
1626                   (vop* ,name node block (refs) ((first res) nil)
1627                         (length args))
1628                   (move-lvar-result node block res lvar)))))
1629   (def list)
1630   (def list*))
1631
1632 \f
1633 ;;; Convert the code in a component into VOPs.
1634 (defun ir2-convert (component)
1635   (declare (type component component))
1636   (let (#!+sb-dyncount
1637         (*dynamic-counts-tn*
1638          (when *collect-dynamic-statistics*
1639            (let* ((blocks
1640                    (block-number (block-next (component-head component))))
1641                   (counts (make-array blocks
1642                                       :element-type '(unsigned-byte 32)
1643                                       :initial-element 0))
1644                   (info (make-dyncount-info
1645                          :for (component-name component)
1646                          :costs (make-array blocks
1647                                             :element-type '(unsigned-byte 32)
1648                                             :initial-element 0)
1649                          :counts counts)))
1650              (setf (ir2-component-dyncount-info (component-info component))
1651                    info)
1652              (emit-constant info)
1653              (emit-constant counts)))))
1654     (let ((num 0))
1655       (declare (type index num))
1656       (do-ir2-blocks (2block component)
1657         (let ((block (ir2-block-block 2block)))
1658           (when (block-start block)
1659             (setf (block-number block) num)
1660             #!+sb-dyncount
1661             (when *collect-dynamic-statistics*
1662               (let ((first-node (block-start-node block)))
1663                 (unless (or (and (bind-p first-node)
1664                                  (xep-p (bind-lambda first-node)))
1665                             (eq (lvar-fun-name
1666                                  (node-lvar first-node))
1667                                 '%nlx-entry))
1668                   (vop count-me
1669                        first-node
1670                        2block
1671                        #!+sb-dyncount *dynamic-counts-tn* #!-sb-dyncount nil
1672                        num))))
1673             (ir2-convert-block block)
1674             (incf num))))))
1675   (values))
1676
1677 ;;; If necessary, emit a terminal unconditional branch to go to the
1678 ;;; successor block. If the successor is the component tail, then
1679 ;;; there isn't really any successor, but if the end is an unknown,
1680 ;;; non-tail call, then we emit an error trap just in case the
1681 ;;; function really does return.
1682 (defun finish-ir2-block (block)
1683   (declare (type cblock block))
1684   (let* ((2block (block-info block))
1685          (last (block-last block))
1686          (succ (block-succ block)))
1687     (unless (if-p last)
1688       (aver (singleton-p succ))
1689       (let ((target (first succ)))
1690         (cond ((eq target (component-tail (block-component block)))
1691                (when (and (basic-combination-p last)
1692                           (eq (basic-combination-kind last) :full))
1693                  (let* ((fun (basic-combination-fun last))
1694                         (use (lvar-uses fun))
1695                         (name (and (ref-p use)
1696                                    (leaf-has-source-name-p (ref-leaf use))
1697                                    (leaf-source-name (ref-leaf use)))))
1698                    (unless (or (node-tail-p last)
1699                                (info :function :info name)
1700                                (policy last (zerop safety)))
1701                      (vop nil-fun-returned-error last 2block
1702                           (if name
1703                               (emit-constant name)
1704                               (multiple-value-bind (tn named)
1705                                   (fun-lvar-tn last 2block fun)
1706                                 (aver (not named))
1707                                 tn)))))))
1708               ((not (eq (ir2-block-next 2block) (block-info target)))
1709                (vop branch last 2block (block-label target)))))))
1710
1711   (values))
1712
1713 ;;; Convert the code in a block into VOPs.
1714 (defun ir2-convert-block (block)
1715   (declare (type cblock block))
1716   (let ((2block (block-info block)))
1717     (do-nodes (node lvar block)
1718       (etypecase node
1719         (ref
1720          (when lvar
1721            (let ((2lvar (lvar-info lvar)))
1722              ;; function REF in a local call is not annotated
1723              (when (and 2lvar (not (eq (ir2-lvar-kind 2lvar) :delayed)))
1724                (ir2-convert-ref node 2block)))))
1725         (combination
1726          (let ((kind (basic-combination-kind node)))
1727            (ecase kind
1728              (:local
1729               (ir2-convert-local-call node 2block))
1730              (:full
1731               (ir2-convert-full-call node 2block))
1732              (:known
1733               (let* ((info (basic-combination-fun-info node))
1734                      (fun (fun-info-ir2-convert info)))
1735                 (cond (fun
1736                        (funcall fun node 2block))
1737                       ((eq (basic-combination-info node) :full)
1738                        (ir2-convert-full-call node 2block))
1739                       (t
1740                        (ir2-convert-template node 2block))))))))
1741         (cif
1742          (when (lvar-info (if-test node))
1743            (ir2-convert-if node 2block)))
1744         (bind
1745          (let ((fun (bind-lambda node)))
1746            (when (eq (lambda-home fun) fun)
1747              (ir2-convert-bind node 2block))))
1748         (creturn
1749          (ir2-convert-return node 2block))
1750         (cset
1751          (ir2-convert-set node 2block))
1752         (cast
1753          (ir2-convert-cast node 2block))
1754         (mv-combination
1755          (cond
1756            ((eq (basic-combination-kind node) :local)
1757             (ir2-convert-mv-bind node 2block))
1758            ((eq (lvar-fun-name (basic-combination-fun node))
1759                 '%throw)
1760             (ir2-convert-throw node 2block))
1761            (t
1762             (ir2-convert-mv-call node 2block))))
1763         (exit
1764          (when (exit-entry node)
1765            (ir2-convert-exit node 2block)))
1766         (entry
1767          (ir2-convert-entry node 2block)))))
1768
1769   (finish-ir2-block block)
1770
1771   (values))