src/compiler/ir2tran.lisp

   1 ;;;; This file contains the virtual-machine-independent parts of the
   2 ;;;; code which does the actual translation of nodes to VOPs.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!C")
  14 \f
  15 ;;;; moves and type checks
  16
  17 ;;; Move X to Y unless they are EQ.
  18 (defun emit-move (node block x y)
  19   (declare (type node node) (type ir2-block block) (type tn x y))
  20   (unless (eq x y)
  21     (vop move node block x y))
  22   (values))
  23
  24 ;;; If there is any CHECK-xxx template for TYPE, then return it,
  25 ;;; otherwise return NIL.
  26 (defun type-check-template (type)
  27   (declare (type ctype type))
  28   (multiple-value-bind (check-ptype exact) (primitive-type type)
  29     (if exact
  30         (primitive-type-check check-ptype)
  31         (let ((name (hairy-type-check-template-name type)))
  32           (if name
  33               (template-or-lose name)
  34               nil)))))
  35
  36 ;;; Emit code in BLOCK to check that VALUE is of the specified TYPE,
  37 ;;; yielding the checked result in RESULT. VALUE and result may be of
  38 ;;; any primitive type. There must be CHECK-xxx VOP for TYPE. Any
  39 ;;; other type checks should have been converted to an explicit type
  40 ;;; test.
  41 (defun emit-type-check (node block value result type)
  42   (declare (type tn value result) (type node node) (type ir2-block block)
  43            (type ctype type))
  44   (emit-move-template node block (type-check-template type) value result)
  45   (values))
  46
  47 ;;; Allocate an indirect value cell. Maybe do some clever stack
  48 ;;; allocation someday.
  49 ;;;
  50 ;;; FIXME: DO-MAKE-VALUE-CELL is a bad name, since it doesn't make
  51 ;;; clear what's the distinction between it and the MAKE-VALUE-CELL
  52 ;;; VOP, and since the DO- further connotes iteration, which has
  53 ;;; nothing to do with this. Clearer, more systematic names, anyone?
  54 (defevent make-value-cell-event "Allocate heap value cell for lexical var.")
  55 (defun do-make-value-cell (node block value res)
  56   (event make-value-cell-event node)
  57   (vop make-value-cell node block value res))
  58 \f
  59 ;;;; leaf reference
  60
  61 ;;; Return the TN that holds the value of THING in the environment ENV.
  62 (declaim (ftype (function ((or nlx-info lambda-var) physenv) tn)
  63                 find-in-physenv))
  64 (defun find-in-physenv (thing physenv)
  65   (or (cdr (assoc thing (ir2-physenv-closure (physenv-info physenv))))
  66       (etypecase thing
  67         (lambda-var
  68          ;; I think that a failure of this assertion means that we're
  69          ;; trying to access a variable which was improperly closed
  70          ;; over. The PHYSENV describes a physical environment. Every
  71          ;; variable that a form refers to should either be in its
  72          ;; physical environment directly, or grabbed from a
  73          ;; surrounding physical environment when it was closed over.
  74          ;; The ASSOC expression above finds closed-over variables, so
  75          ;; if we fell through the ASSOC expression, it wasn't closed
  76          ;; over. Therefore, it must be in our physical environment
  77          ;; directly. If instead it is in some other physical
  78          ;; environment, then it's bogus for us to reference it here
  79          ;; without it being closed over. -- WHN 2001-09-29
  80          (aver (eq physenv (lambda-physenv (lambda-var-home thing))))
  81          (leaf-info thing))
  82         (nlx-info
  83          (aver (eq physenv (block-physenv (nlx-info-target thing))))
  84          (ir2-nlx-info-home (nlx-info-info thing))))
  85       (bug "~@<~2I~_~S ~_not found in ~_~S~:>" thing physenv)))
  86
  87 ;;; If LEAF already has a constant TN, return that, otherwise make a
  88 ;;; TN for it.
  89 (defun constant-tn (leaf)
  90   (declare (type constant leaf))
  91   (or (leaf-info leaf)
  92       (setf (leaf-info leaf)
  93             (make-constant-tn leaf))))
  94
  95 ;;; Return a TN that represents the value of LEAF, or NIL if LEAF
  96 ;;; isn't directly represented by a TN. ENV is the environment that
  97 ;;; the reference is done in.
  98 (defun leaf-tn (leaf env)
  99   (declare (type leaf leaf) (type physenv env))
 100   (typecase leaf
 101     (lambda-var
 102      (unless (lambda-var-indirect leaf)
 103        (find-in-physenv leaf env)))
 104     (constant (constant-tn leaf))
 105     (t nil)))
 106
 107 ;;; This is used to conveniently get a handle on a constant TN during
 108 ;;; IR2 conversion. It returns a constant TN representing the Lisp
 109 ;;; object VALUE.
 110 (defun emit-constant (value)
 111   (constant-tn (find-constant value)))
 112
 113 ;;; Convert a REF node. The reference must not be delayed.
 114 (defun ir2-convert-ref (node block)
 115   (declare (type ref node) (type ir2-block block))
 116   (let* ((lvar (node-lvar node))
 117          (leaf (ref-leaf node))
 118          (locs (lvar-result-tns
 119                 lvar (list (primitive-type (leaf-type leaf)))))
 120          (res (first locs)))
 121     (etypecase leaf
 122       (lambda-var
 123        (let ((tn (find-in-physenv leaf (node-physenv node))))
 124          (if (lambda-var-indirect leaf)
 125              (vop value-cell-ref node block tn res)
 126              (emit-move node block tn res))))
 127       (constant
 128        (if (legal-immediate-constant-p leaf)
 129            (emit-move node block (constant-tn leaf) res)
 130            (let* ((name (leaf-source-name leaf))
 131                   (name-tn (emit-constant name)))
 132              (if (policy node (zerop safety))
 133                  (vop fast-symbol-value node block name-tn res)
 134                  (vop symbol-value node block name-tn res)))))
 135       (functional
 136        (ir2-convert-closure node block leaf res))
 137       (global-var
 138        (let ((unsafe (policy node (zerop safety)))
 139              (name (leaf-source-name leaf)))
 140          (ecase (global-var-kind leaf)
 141            ((:special :global)
 142             (aver (symbolp name))
 143             (let ((name-tn (emit-constant name)))
 144               (if unsafe
 145                   (vop fast-symbol-value node block name-tn res)
 146                   (vop symbol-value node block name-tn res))))
 147            (:global-function
 148             (let ((fdefn-tn (make-load-time-constant-tn :fdefinition name)))
 149               (if unsafe
 150                   (vop fdefn-fun node block fdefn-tn res)
 151                   (vop safe-fdefn-fun node block fdefn-tn res))))))))
 152     (move-lvar-result node block locs lvar))
 153   (values))
 154
 155 ;;; some sanity checks for a CLAMBDA passed to IR2-CONVERT-CLOSURE
 156 (defun assertions-on-ir2-converted-clambda (clambda)
 157   ;; This assertion was sort of an experiment. It would be nice and
 158   ;; sane and easier to understand things if it were *always* true,
 159   ;; but experimentally I observe that it's only *almost* always
 160   ;; true. -- WHN 2001-01-02
 161   #+nil
 162   (aver (eql (lambda-component clambda)
 163              (block-component (ir2-block-block ir2-block))))
 164   ;; Check for some weirdness which came up in bug
 165   ;; 138, 2002-01-02.
 166   ;;
 167   ;; The MAKE-LOAD-TIME-CONSTANT-TN call above puts an :ENTRY record
 168   ;; into the IR2-COMPONENT-CONSTANTS table. The dump-a-COMPONENT
 169   ;; code
 170   ;;   * treats every HANDLEless :ENTRY record into a
 171   ;;     patch, and
 172   ;;   * expects every patch to correspond to an
 173   ;;     IR2-COMPONENT-ENTRIES record.
 174   ;; The IR2-COMPONENT-ENTRIES records are set by ENTRY-ANALYZE
 175   ;; walking over COMPONENT-LAMBDAS. Bug 138b arose because there
 176   ;; was a HANDLEless :ENTRY record which didn't correspond to an
 177   ;; IR2-COMPONENT-ENTRIES record. That problem is hard to debug
 178   ;; when it's caught at dump time, so this assertion tries to catch
 179   ;; it here.
 180   (aver (member clambda
 181                 (component-lambdas (lambda-component clambda))))
 182   ;; another bug-138-related issue: COMPONENT-NEW-FUNCTIONALS is
 183   ;; used as a queue for stuff pending to do in IR1, and now that
 184   ;; we're doing IR2 it should've been completely flushed (but
 185   ;; wasn't).
 186   (aver (null (component-new-functionals (lambda-component clambda))))
 187   (values))
 188
 189 ;;; Emit code to load a function object implementing FUNCTIONAL into
 190 ;;; RES. This gets interesting when the referenced function is a
 191 ;;; closure: we must make the closure and move the closed-over values
 192 ;;; into it.
 193 ;;;
 194 ;;; FUNCTIONAL is either a :TOPLEVEL-XEP functional or the XEP lambda
 195 ;;; for the called function, since local call analysis converts all
 196 ;;; closure references. If a :TOPLEVEL-XEP, we know it is not a
 197 ;;; closure.
 198 ;;;
 199 ;;; If a closed-over LAMBDA-VAR has no refs (is deleted), then we
 200 ;;; don't initialize that slot. This can happen with closures over
 201 ;;; top level variables, where optimization of the closure deleted the
 202 ;;; variable. Since we committed to the closure format when we
 203 ;;; pre-analyzed the top level code, we just leave an empty slot.
 204 (defun ir2-convert-closure (ref ir2-block functional res)
 205   (declare (type ref ref)
 206            (type ir2-block ir2-block)
 207            (type functional functional)
 208            (type tn res))
 209   (aver (not (eql (functional-kind functional) :deleted)))
 210   (unless (leaf-info functional)
 211     (setf (leaf-info functional)
 212           (make-entry-info :name (functional-debug-name functional))))
 213   (let ((entry (make-load-time-constant-tn :entry functional))
 214         (closure (etypecase functional
 215                    (clambda
 216                     (assertions-on-ir2-converted-clambda functional)
 217                     (physenv-closure (get-lambda-physenv functional)))
 218                    (functional
 219                     (aver (eq (functional-kind functional) :toplevel-xep))
 220                     nil))))
 221
 222     (cond (closure
 223            (let ((this-env (node-physenv ref)))
 224              (vop make-closure ref ir2-block entry (length closure) res)
 225              (loop for what in closure and n from 0 do
 226                (unless (and (lambda-var-p what)
 227                             (null (leaf-refs what)))
 228                  (vop closure-init ref ir2-block
 229                       res
 230                       (find-in-physenv what this-env)
 231                       n)))))
 232           (t
 233            (emit-move ref ir2-block entry res))))
 234   (values))
 235
 236 ;;; Convert a SET node. If the NODE's LVAR is annotated, then we also
 237 ;;; deliver the value to that lvar. If the var is a lexical variable
 238 ;;; with no refs, then we don't actually set anything, since the
 239 ;;; variable has been deleted.
 240 (defun ir2-convert-set (node block)
 241   (declare (type cset node) (type ir2-block block))
 242   (let* ((lvar (node-lvar node))
 243          (leaf (set-var node))
 244          (val (lvar-tn node block (set-value node)))
 245          (locs (if lvar
 246                    (lvar-result-tns
 247                     lvar (list (primitive-type (leaf-type leaf))))
 248                    nil)))
 249     (etypecase leaf
 250       (lambda-var
 251        (when (leaf-refs leaf)
 252          (let ((tn (find-in-physenv leaf (node-physenv node))))
 253            (if (lambda-var-indirect leaf)
 254                (vop value-cell-set node block tn val)
 255                (emit-move node block val tn)))))
 256       (global-var
 257        (ecase (global-var-kind leaf)
 258          ((:special :global)
 259           (aver (symbolp (leaf-source-name leaf)))
 260           (vop set node block (emit-constant (leaf-source-name leaf)) val)))))
 261     (when locs
 262       (emit-move node block val (first locs))
 263       (move-lvar-result node block locs lvar)))
 264   (values))
 265 \f
 266 ;;;; utilities for receiving fixed values
 267
 268 ;;; Return a TN that can be referenced to get the value of LVAR. LVAR
 269 ;;; must be LTN-ANNOTATED either as a delayed leaf ref or as a fixed,
 270 ;;; single-value lvar.
 271 ;;;
 272 ;;; The primitive-type of the result will always be the same as the
 273 ;;; IR2-LVAR-PRIMITIVE-TYPE, ensuring that VOPs are always called with
 274 ;;; TNs that satisfy the operand primitive-type restriction. We may
 275 ;;; have to make a temporary of the desired type and move the actual
 276 ;;; lvar TN into it. This happens when we delete a type check in
 277 ;;; unsafe code or when we locally know something about the type of an
 278 ;;; argument variable.
 279 (defun lvar-tn (node block lvar)
 280   (declare (type node node) (type ir2-block block) (type lvar lvar))
 281   (let* ((2lvar (lvar-info lvar))
 282          (lvar-tn
 283           (ecase (ir2-lvar-kind 2lvar)
 284             (:delayed
 285              (let ((ref (lvar-uses lvar)))
 286                (leaf-tn (ref-leaf ref) (node-physenv ref))))
 287             (:fixed
 288              (aver (= (length (ir2-lvar-locs 2lvar)) 1))
 289              (first (ir2-lvar-locs 2lvar)))))
 290          (ptype (ir2-lvar-primitive-type 2lvar)))
 291
 292     (cond ((eq (tn-primitive-type lvar-tn) ptype) lvar-tn)
 293           (t
 294            (let ((temp (make-normal-tn ptype)))
 295              (emit-move node block lvar-tn temp)
 296              temp)))))
 297
 298 ;;; This is similar to LVAR-TN, but hacks multiple values. We return
 299 ;;; TNs holding the values of LVAR with PTYPES as their primitive
 300 ;;; types. LVAR must be annotated for the same number of fixed values
 301 ;;; are there are PTYPES.
 302 ;;;
 303 ;;; If the lvar has a type check, check the values into temps and
 304 ;;; return the temps. When we have more values than assertions, we
 305 ;;; move the extra values with no check.
 306 (defun lvar-tns (node block lvar ptypes)
 307   (declare (type node node) (type ir2-block block)
 308            (type lvar lvar) (list ptypes))
 309   (let* ((locs (ir2-lvar-locs (lvar-info lvar)))
 310          (nlocs (length locs)))
 311     (aver (= nlocs (length ptypes)))
 312
 313     (mapcar (lambda (from to-type)
 314               (if (eq (tn-primitive-type from) to-type)
 315                   from
 316                   (let ((temp (make-normal-tn to-type)))
 317                     (emit-move node block from temp)
 318                     temp)))
 319             locs
 320             ptypes)))
 321 \f
 322 ;;;; utilities for delivering values to lvars
 323
 324 ;;; Return a list of TNs with the specifier TYPES that can be used as
 325 ;;; result TNs to evaluate an expression into LVAR. This is used
 326 ;;; together with MOVE-LVAR-RESULT to deliver fixed values to
 327 ;;; an lvar.
 328 ;;;
 329 ;;; If the lvar isn't annotated (meaning the values are discarded) or
 330 ;;; is unknown-values, the then we make temporaries for each supplied
 331 ;;; value, providing a place to compute the result in until we decide
 332 ;;; what to do with it (if anything.)
 333 ;;;
 334 ;;; If the lvar is fixed-values, and wants the same number of values
 335 ;;; as the user wants to deliver, then we just return the
 336 ;;; IR2-LVAR-LOCS. Otherwise we make a new list padded as necessary by
 337 ;;; discarded TNs. We always return a TN of the specified type, using
 338 ;;; the lvar locs only when they are of the correct type.
 339 (defun lvar-result-tns (lvar types)
 340   (declare (type (or lvar null) lvar) (type list types))
 341   (if (not lvar)
 342       (mapcar #'make-normal-tn types)
 343       (let ((2lvar (lvar-info lvar)))
 344         (ecase (ir2-lvar-kind 2lvar)
 345           (:fixed
 346            (let* ((locs (ir2-lvar-locs 2lvar))
 347                   (nlocs (length locs))
 348                   (ntypes (length types)))
 349              (if (and (= nlocs ntypes)
 350                       (do ((loc locs (cdr loc))
 351                            (type types (cdr type)))
 352                           ((null loc) t)
 353                         (unless (eq (tn-primitive-type (car loc)) (car type))
 354                           (return nil))))
 355                  locs
 356                  (mapcar (lambda (loc type)
 357                            (if (eq (tn-primitive-type loc) type)
 358                                loc
 359                                (make-normal-tn type)))
 360                          (if (< nlocs ntypes)
 361                              (append locs
 362                                      (mapcar #'make-normal-tn
 363                                              (subseq types nlocs)))
 364                              locs)
 365                          types))))
 366           (:unknown
 367            (mapcar #'make-normal-tn types))))))
 368
 369 ;;; Make the first N standard value TNs, returning them in a list.
 370 (defun make-standard-value-tns (n)
 371   (declare (type unsigned-byte n))
 372   (collect ((res))
 373     (dotimes (i n)
 374       (res (standard-arg-location i)))
 375     (res)))
 376
 377 ;;; Return a list of TNs wired to the standard value passing
 378 ;;; conventions that can be used to receive values according to the
 379 ;;; unknown-values convention. This is used with together
 380 ;;; MOVE-LVAR-RESULT for delivering unknown values to a fixed values
 381 ;;; lvar.
 382 ;;;
 383 ;;; If the lvar isn't annotated, then we treat as 0-values, returning
 384 ;;; an empty list of temporaries.
 385 ;;;
 386 ;;; If the lvar is annotated, then it must be :FIXED.
 387 (defun standard-result-tns (lvar)
 388   (declare (type (or lvar null) lvar))
 389   (if lvar
 390       (let ((2lvar (lvar-info lvar)))
 391         (ecase (ir2-lvar-kind 2lvar)
 392           (:fixed
 393            (make-standard-value-tns (length (ir2-lvar-locs 2lvar))))))
 394       nil))
 395
 396 ;;; Just move each SRC TN into the corresponding DEST TN, defaulting
 397 ;;; any unsupplied source values to NIL. We let EMIT-MOVE worry about
 398 ;;; doing the appropriate coercions.
 399 (defun move-results-coerced (node block src dest)
 400   (declare (type node node) (type ir2-block block) (list src dest))
 401   (let ((nsrc (length src))
 402         (ndest (length dest)))
 403     (mapc (lambda (from to)
 404             (unless (eq from to)
 405               (emit-move node block from to)))
 406           (if (> ndest nsrc)
 407               (append src (make-list (- ndest nsrc)
 408                                      :initial-element (emit-constant nil)))
 409               src)
 410           dest))
 411   (values))
 412
 413 ;;; Move each SRC TN into the corresponding DEST TN, checking types
 414 ;;; and defaulting any unsupplied source values to NIL
 415 (defun move-results-checked (node block src dest types)
 416   (declare (type node node) (type ir2-block block) (list src dest types))
 417   (let ((nsrc (length src))
 418         (ndest (length dest))
 419         (ntypes (length types)))
 420     (mapc (lambda (from to type)
 421             (if type
 422                 (emit-type-check node block from to type)
 423                 (emit-move node block from to)))
 424           (if (> ndest nsrc)
 425               (append src (make-list (- ndest nsrc)
 426                                      :initial-element (emit-constant nil)))
 427               src)
 428           dest
 429           (if (> ndest ntypes)
 430               (append types (make-list (- ndest ntypes)))
 431               types)))
 432   (values))
 433
 434 ;;; If necessary, emit coercion code needed to deliver the RESULTS to
 435 ;;; the specified lvar. NODE and BLOCK provide context for emitting
 436 ;;; code. Although usually obtained from STANDARD-RESULT-TNs or
 437 ;;; LVAR-RESULT-TNs, RESULTS my be a list of any type or
 438 ;;; number of TNs.
 439 ;;;
 440 ;;; If the lvar is fixed values, then move the results into the lvar
 441 ;;; locations. If the lvar is unknown values, then do the moves into
 442 ;;; the standard value locations, and use PUSH-VALUES to put the
 443 ;;; values on the stack.
 444 (defun move-lvar-result (node block results lvar)
 445   (declare (type node node) (type ir2-block block)
 446            (list results) (type (or lvar null) lvar))
 447   (when lvar
 448     (let ((2lvar (lvar-info lvar)))
 449       (ecase (ir2-lvar-kind 2lvar)
 450         (:fixed
 451          (let ((locs (ir2-lvar-locs 2lvar)))
 452            (unless (eq locs results)
 453              (move-results-coerced node block results locs))))
 454         (:unknown
 455          (let* ((nvals (length results))
 456                 (locs (make-standard-value-tns nvals)))
 457            (move-results-coerced node block results locs)
 458            (vop* push-values node block
 459                  ((reference-tn-list locs nil))
 460                  ((reference-tn-list (ir2-lvar-locs 2lvar) t))
 461                  nvals))))))
 462   (values))
 463
 464 ;;; CAST
 465 (defun ir2-convert-cast (node block)
 466   (declare (type cast node)
 467            (type ir2-block block))
 468   (binding* ((lvar (node-lvar node) :exit-if-null)
 469              (2lvar (lvar-info lvar))
 470              (value (cast-value node))
 471              (2value (lvar-info value)))
 472     (cond ((eq (ir2-lvar-kind 2lvar) :unused))
 473           ((eq (ir2-lvar-kind 2lvar) :unknown)
 474            (aver (eq (ir2-lvar-kind 2value) :unknown))
 475            (aver (not (cast-type-check node)))
 476            (move-results-coerced node block
 477                                  (ir2-lvar-locs 2value)
 478                                  (ir2-lvar-locs 2lvar)))
 479           ((eq (ir2-lvar-kind 2lvar) :fixed)
 480            (aver (eq (ir2-lvar-kind 2value) :fixed))
 481            (if (cast-type-check node)
 482                (move-results-checked node block
 483                                      (ir2-lvar-locs 2value)
 484                                      (ir2-lvar-locs 2lvar)
 485                                      (multiple-value-bind (check types)
 486                                          (cast-check-types node nil)
 487                                        (aver (eq check :simple))
 488                                        types))
 489                (move-results-coerced node block
 490                                      (ir2-lvar-locs 2value)
 491                                      (ir2-lvar-locs 2lvar))))
 492           (t (bug "CAST cannot be :DELAYED.")))))
 493 \f
 494 ;;;; template conversion
 495
 496 ;;; Build a TN-REFS list that represents access to the values of the
 497 ;;; specified list of lvars ARGS for TEMPLATE. Any :CONSTANT arguments
 498 ;;; are returned in the second value as a list rather than being
 499 ;;; accessed as a normal argument. NODE and BLOCK provide the context
 500 ;;; for emitting any necessary type-checking code.
 501 (defun reference-args (node block args template)
 502   (declare (type node node) (type ir2-block block) (list args)
 503            (type template template))
 504   (collect ((info-args))
 505     (let ((last nil)
 506           (first nil))
 507       (do ((args args (cdr args))
 508            (types (template-arg-types template) (cdr types)))
 509           ((null args))
 510         (let ((type (first types))
 511               (arg (first args)))
 512           (if (and (consp type) (eq (car type) ':constant))
 513               (info-args (lvar-value arg))
 514               (let ((ref (reference-tn (lvar-tn node block arg) nil)))
 515                 (if last
 516                     (setf (tn-ref-across last) ref)
 517                     (setf first ref))
 518                 (setq last ref)))))
 519
 520       (values (the (or tn-ref null) first) (info-args)))))
 521
 522 ;;; Convert a conditional template. We try to exploit any
 523 ;;; drop-through, but emit an unconditional branch afterward if we
 524 ;;; fail. NOT-P is true if the sense of the TEMPLATE's test should be
 525 ;;; negated.
 526 (defun ir2-convert-conditional (node block template args info-args if not-p)
 527   (declare (type node node) (type ir2-block block)
 528            (type template template) (type (or tn-ref null) args)
 529            (list info-args) (type cif if) (type boolean not-p))
 530   (aver (= (template-info-arg-count template) (+ (length info-args) 2)))
 531   (let ((consequent (if-consequent if))
 532         (alternative (if-alternative if)))
 533     (cond ((drop-thru-p if consequent)
 534            (emit-template node block template args nil
 535                           (list* (block-label alternative) (not not-p)
 536                                  info-args)))
 537           (t
 538            (emit-template node block template args nil
 539                           (list* (block-label consequent) not-p info-args))
 540            (unless (drop-thru-p if alternative)
 541              (vop branch node block (block-label alternative)))))))
 542
 543 ;;; Convert an IF that isn't the DEST of a conditional template.
 544 (defun ir2-convert-if (node block)
 545   (declare (type ir2-block block) (type cif node))
 546   (let* ((test (if-test node))
 547          (test-ref (reference-tn (lvar-tn node block test) nil))
 548          (nil-ref (reference-tn (emit-constant nil) nil)))
 549     (setf (tn-ref-across test-ref) nil-ref)
 550     (ir2-convert-conditional node block (template-or-lose 'if-eq)
 551                              test-ref () node t)))
 552
 553 ;;; Return a list of primitive-types that we can pass to
 554 ;;; LVAR-RESULT-TNS describing the result types we want for a
 555 ;;; template call. We duplicate here the determination of output type
 556 ;;; that was done in initially selecting the template, so we know that
 557 ;;; the types we find are allowed by the template output type
 558 ;;; restrictions.
 559 (defun find-template-result-types (call template rtypes)
 560   (declare (type combination call)
 561            (type template template) (list rtypes))
 562   (declare (ignore template))
 563   (let* ((dtype (node-derived-type call))
 564          (type dtype)
 565          (types (mapcar #'primitive-type
 566                         (if (values-type-p type)
 567                             (append (values-type-required type)
 568                                     (values-type-optional type))
 569                             (list type)))))
 570     (let ((nvals (length rtypes))
 571           (ntypes (length types)))
 572       (cond ((< ntypes nvals)
 573              (append types
 574                      (make-list (- nvals ntypes)
 575                                 :initial-element *backend-t-primitive-type*)))
 576             ((> ntypes nvals)
 577              (subseq types 0 nvals))
 578             (t
 579              types)))))
 580
 581 ;;; Return a list of TNs usable in a CALL to TEMPLATE delivering
 582 ;;; values to LVAR. As an efficiency hack, we pick off the common case
 583 ;;; where the LVAR is fixed values and has locations that satisfy the
 584 ;;; result restrictions. This can fail when there is a type check or a
 585 ;;; values count mismatch.
 586 (defun make-template-result-tns (call lvar template rtypes)
 587   (declare (type combination call) (type (or lvar null) lvar)
 588            (type template template) (list rtypes))
 589   (let ((2lvar (when lvar (lvar-info lvar))))
 590     (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :fixed))
 591         (let ((locs (ir2-lvar-locs 2lvar)))
 592           (if (and (= (length rtypes) (length locs))
 593                    (do ((loc locs (cdr loc))
 594                         (rtype rtypes (cdr rtype)))
 595                        ((null loc) t)
 596                      (unless (operand-restriction-ok
 597                               (car rtype)
 598                               (tn-primitive-type (car loc))
 599                               :t-ok nil)
 600                        (return nil))))
 601               locs
 602               (lvar-result-tns
 603                lvar
 604                (find-template-result-types call template rtypes))))
 605         (lvar-result-tns
 606          lvar
 607          (find-template-result-types call template rtypes)))))
 608
 609 ;;; Get the operands into TNs, make TN-REFs for them, and then call
 610 ;;; the template emit function.
 611 (defun ir2-convert-template (call block)
 612   (declare (type combination call) (type ir2-block block))
 613   (let* ((template (combination-info call))
 614          (lvar (node-lvar call))
 615          (rtypes (template-result-types template)))
 616     (multiple-value-bind (args info-args)
 617         (reference-args call block (combination-args call) template)
 618       (aver (not (template-more-results-type template)))
 619       (if (eq rtypes :conditional)
 620           (ir2-convert-conditional call block template args info-args
 621                                    (lvar-dest lvar) nil)
 622           (let* ((results (make-template-result-tns call lvar template rtypes))
 623                  (r-refs (reference-tn-list results t)))
 624             (aver (= (length info-args)
 625                      (template-info-arg-count template)))
 626             #!+stack-grows-downward-not-upward
 627             (when (and lvar (lvar-dynamic-extent lvar))
 628               (vop current-stack-pointer call block
 629                    (ir2-lvar-stack-pointer (lvar-info lvar))))
 630             (if info-args
 631                 (emit-template call block template args r-refs info-args)
 632                 (emit-template call block template args r-refs))
 633             (move-lvar-result call block results lvar)))))
 634   (values))
 635
 636 ;;; We don't have to do much because operand count checking is done by
 637 ;;; IR1 conversion. The only difference between this and the function
 638 ;;; case of IR2-CONVERT-TEMPLATE is that there can be codegen-info
 639 ;;; arguments.
 640 (defoptimizer (%%primitive ir2-convert) ((template info &rest args) call block)
 641   (let* ((template (lvar-value template))
 642          (info (lvar-value info))
 643          (lvar (node-lvar call))
 644          (rtypes (template-result-types template))
 645          (results (make-template-result-tns call lvar template rtypes))
 646          (r-refs (reference-tn-list results t)))
 647     (multiple-value-bind (args info-args)
 648         (reference-args call block (cddr (combination-args call)) template)
 649       (aver (not (template-more-results-type template)))
 650       (aver (not (eq rtypes :conditional)))
 651       (aver (null info-args))
 652
 653       (if info
 654           (emit-template call block template args r-refs info)
 655           (emit-template call block template args r-refs))
 656
 657       (move-lvar-result call block results lvar)))
 658   (values))
 659 \f
 660 ;;;; local call
 661
 662 ;;; Convert a LET by moving the argument values into the variables.
 663 ;;; Since a LET doesn't have any passing locations, we move the
 664 ;;; arguments directly into the variables. We must also allocate any
 665 ;;; indirect value cells, since there is no function prologue to do
 666 ;;; this.
 667 (defun ir2-convert-let (node block fun)
 668   (declare (type combination node) (type ir2-block block) (type clambda fun))
 669   (mapc (lambda (var arg)
 670           (when arg
 671             (let ((src (lvar-tn node block arg))
 672                   (dest (leaf-info var)))
 673               (if (lambda-var-indirect var)
 674                   (do-make-value-cell node block src dest)
 675                   (emit-move node block src dest)))))
 676         (lambda-vars fun) (basic-combination-args node))
 677   (values))
 678
 679 ;;; Emit any necessary moves into assignment temps for a local call to
 680 ;;; FUN. We return two lists of TNs: TNs holding the actual argument
 681 ;;; values, and (possibly EQ) TNs that are the actual destination of
 682 ;;; the arguments. When necessary, we allocate temporaries for
 683 ;;; arguments to preserve parallel assignment semantics. These lists
 684 ;;; exclude unused arguments and include implicit environment
 685 ;;; arguments, i.e. they exactly correspond to the arguments passed.
 686 ;;;
 687 ;;; OLD-FP is the TN currently holding the value we want to pass as
 688 ;;; OLD-FP. If null, then the call is to the same environment (an
 689 ;;; :ASSIGNMENT), so we only move the arguments, and leave the
 690 ;;; environment alone.
 691 (defun emit-psetq-moves (node block fun old-fp)
 692   (declare (type combination node) (type ir2-block block) (type clambda fun)
 693            (type (or tn null) old-fp))
 694   (let ((actuals (mapcar (lambda (x)
 695                            (when x
 696                              (lvar-tn node block x)))
 697                          (combination-args node))))
 698     (collect ((temps)
 699               (locs))
 700       (dolist (var (lambda-vars fun))
 701         (let ((actual (pop actuals))
 702               (loc (leaf-info var)))
 703           (when actual
 704             (cond
 705              ((lambda-var-indirect var)
 706               (let ((temp
 707                      (make-normal-tn *backend-t-primitive-type*)))
 708                 (do-make-value-cell node block actual temp)
 709                 (temps temp)))
 710              ((member actual (locs))
 711               (let ((temp (make-normal-tn (tn-primitive-type loc))))
 712                 (emit-move node block actual temp)
 713                 (temps temp)))
 714              (t
 715               (temps actual)))
 716             (locs loc))))
 717
 718       (when old-fp
 719         (let ((this-1env (node-physenv node))
 720               (called-env (physenv-info (lambda-physenv fun))))
 721           (dolist (thing (ir2-physenv-closure called-env))
 722             (temps (find-in-physenv (car thing) this-1env))
 723             (locs (cdr thing)))
 724           (temps old-fp)
 725           (locs (ir2-physenv-old-fp called-env))))
 726
 727       (values (temps) (locs)))))
 728
 729 ;;; A tail-recursive local call is done by emitting moves of stuff
 730 ;;; into the appropriate passing locations. After setting up the args
 731 ;;; and environment, we just move our return-pc into the called
 732 ;;; function's passing location.
 733 (defun ir2-convert-tail-local-call (node block fun)
 734   (declare (type combination node) (type ir2-block block) (type clambda fun))
 735   (let ((this-env (physenv-info (node-physenv node))))
 736     (multiple-value-bind (temps locs)
 737         (emit-psetq-moves node block fun (ir2-physenv-old-fp this-env))
 738
 739       (mapc (lambda (temp loc)
 740               (emit-move node block temp loc))
 741             temps locs))
 742
 743     (emit-move node block
 744                (ir2-physenv-return-pc this-env)
 745                (ir2-physenv-return-pc-pass
 746                 (physenv-info
 747                  (lambda-physenv fun)))))
 748
 749   (values))
 750
 751 ;;; Convert an :ASSIGNMENT call. This is just like a tail local call,
 752 ;;; except that the caller and callee environment are the same, so we
 753 ;;; don't need to mess with the environment locations, return PC, etc.
 754 (defun ir2-convert-assignment (node block fun)
 755   (declare (type combination node) (type ir2-block block) (type clambda fun))
 756     (multiple-value-bind (temps locs) (emit-psetq-moves node block fun nil)
 757
 758       (mapc (lambda (temp loc)
 759               (emit-move node block temp loc))
 760             temps locs))
 761   (values))
 762
 763 ;;; Do stuff to set up the arguments to a non-tail local call
 764 ;;; (including implicit environment args.) We allocate a frame
 765 ;;; (returning the FP and NFP), and also compute the TN-REFS list for
 766 ;;; the values to pass and the list of passing location TNs.
 767 (defun ir2-convert-local-call-args (node block fun)
 768   (declare (type combination node) (type ir2-block block) (type clambda fun))
 769   (let ((fp (make-stack-pointer-tn))
 770         (nfp (make-number-stack-pointer-tn))
 771         (old-fp (make-stack-pointer-tn)))
 772     (multiple-value-bind (temps locs)
 773         (emit-psetq-moves node block fun old-fp)
 774       (vop current-fp node block old-fp)
 775       (vop allocate-frame node block
 776            (physenv-info (lambda-physenv fun))
 777            fp nfp)
 778       (values fp nfp temps (mapcar #'make-alias-tn locs)))))
 779
 780 ;;; Handle a non-TR known-values local call. We emit the call, then
 781 ;;; move the results to the lvar's destination.
 782 (defun ir2-convert-local-known-call (node block fun returns lvar start)
 783   (declare (type node node) (type ir2-block block) (type clambda fun)
 784            (type return-info returns) (type (or lvar null) lvar)
 785            (type label start))
 786   (multiple-value-bind (fp nfp temps arg-locs)
 787       (ir2-convert-local-call-args node block fun)
 788     (let ((locs (return-info-locations returns)))
 789       (vop* known-call-local node block
 790             (fp nfp (reference-tn-list temps nil))
 791             ((reference-tn-list locs t))
 792             arg-locs (physenv-info (lambda-physenv fun)) start)
 793       (move-lvar-result node block locs lvar)))
 794   (values))
 795
 796 ;;; Handle a non-TR unknown-values local call. We do different things
 797 ;;; depending on what kind of values the lvar wants.
 798 ;;;
 799 ;;; If LVAR is :UNKNOWN, then we use the "multiple-" variant, directly
 800 ;;; specifying the lvar's LOCS as the VOP results so that we don't
 801 ;;; have to do anything after the call.
 802 ;;;
 803 ;;; Otherwise, we use STANDARD-RESULT-TNS to get wired result TNs, and
 804 ;;; then call MOVE-LVAR-RESULT to do any necessary type checks or
 805 ;;; coercions.
 806 (defun ir2-convert-local-unknown-call (node block fun lvar start)
 807   (declare (type node node) (type ir2-block block) (type clambda fun)
 808            (type (or lvar null) lvar) (type label start))
 809   (multiple-value-bind (fp nfp temps arg-locs)
 810       (ir2-convert-local-call-args node block fun)
 811     (let ((2lvar (and lvar (lvar-info lvar)))
 812           (env (physenv-info (lambda-physenv fun)))
 813           (temp-refs (reference-tn-list temps nil)))
 814       (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :unknown))
 815           (vop* multiple-call-local node block (fp nfp temp-refs)
 816                 ((reference-tn-list (ir2-lvar-locs 2lvar) t))
 817                 arg-locs env start)
 818           (let ((locs (standard-result-tns lvar)))
 819             (vop* call-local node block
 820                   (fp nfp temp-refs)
 821                   ((reference-tn-list locs t))
 822                   arg-locs env start (length locs))
 823             (move-lvar-result node block locs lvar)))))
 824   (values))
 825
 826 ;;; Dispatch to the appropriate function, depending on whether we have
 827 ;;; a let, tail or normal call. If the function doesn't return, call
 828 ;;; it using the unknown-value convention. We could compile it as a
 829 ;;; tail call, but that might seem confusing in the debugger.
 830 (defun ir2-convert-local-call (node block)
 831   (declare (type combination node) (type ir2-block block))
 832   (let* ((fun (ref-leaf (lvar-uses (basic-combination-fun node))))
 833          (kind (functional-kind fun)))
 834     (cond ((eq kind :let)
 835            (ir2-convert-let node block fun))
 836           ((eq kind :assignment)
 837            (ir2-convert-assignment node block fun))
 838           ((node-tail-p node)
 839            (ir2-convert-tail-local-call node block fun))
 840           (t
 841            (let ((start (block-label (lambda-block fun)))
 842                  (returns (tail-set-info (lambda-tail-set fun)))
 843                  (lvar (node-lvar node)))
 844              (ecase (if returns
 845                         (return-info-kind returns)
 846                         :unknown)
 847                (:unknown
 848                 (ir2-convert-local-unknown-call node block fun lvar start))
 849                (:fixed
 850                 (ir2-convert-local-known-call node block fun returns
 851                                               lvar start)))))))
 852   (values))
 853 \f
 854 ;;;; full call
 855
 856 ;;; Given a function lvar FUN, return (VALUES TN-TO-CALL NAMED-P),
 857 ;;; where TN-TO-CALL is a TN holding the thing that we call NAMED-P is
 858 ;;; true if the thing is named (false if it is a function).
 859 ;;;
 860 ;;; There are two interesting non-named cases:
 861 ;;;   -- We know it's a function. No check needed: return the
 862 ;;;      lvar LOC.
 863 ;;;   -- We don't know what it is.
 864 (defun fun-lvar-tn (node block lvar)
 865   (declare (ignore node block))
 866   (declare (type lvar lvar))
 867   (let ((2lvar (lvar-info lvar)))
 868     (if (eq (ir2-lvar-kind 2lvar) :delayed)
 869         (let ((name (lvar-fun-name lvar t)))
 870           (aver name)
 871           (values (make-load-time-constant-tn :fdefinition name) t))
 872         (let* ((locs (ir2-lvar-locs 2lvar))
 873                (loc (first locs))
 874                (function-ptype (primitive-type-or-lose 'function)))
 875           (aver (and (eq (ir2-lvar-kind 2lvar) :fixed)
 876                      (= (length locs) 1)))
 877           (aver (eq (tn-primitive-type loc) function-ptype))
 878           (values loc nil)))))
 879
 880 ;;; Set up the args to NODE in the current frame, and return a TN-REF
 881 ;;; list for the passing locations.
 882 (defun move-tail-full-call-args (node block)
 883   (declare (type combination node) (type ir2-block block))
 884   (let ((args (basic-combination-args node))
 885         (last nil)
 886         (first nil))
 887     (dotimes (num (length args))
 888       (let ((loc (standard-arg-location num)))
 889         (emit-move node block (lvar-tn node block (elt args num)) loc)
 890         (let ((ref (reference-tn loc nil)))
 891           (if last
 892               (setf (tn-ref-across last) ref)
 893               (setf first ref))
 894           (setq last ref))))
 895       first))
 896
 897 ;;; Move the arguments into the passing locations and do a (possibly
 898 ;;; named) tail call.
 899 (defun ir2-convert-tail-full-call (node block)
 900   (declare (type combination node) (type ir2-block block))
 901   (let* ((env (physenv-info (node-physenv node)))
 902          (args (basic-combination-args node))
 903          (nargs (length args))
 904          (pass-refs (move-tail-full-call-args node block))
 905          (old-fp (ir2-physenv-old-fp env))
 906          (return-pc (ir2-physenv-return-pc env)))
 907
 908     (multiple-value-bind (fun-tn named)
 909         (fun-lvar-tn node block (basic-combination-fun node))
 910       (if named
 911           (vop* tail-call-named node block
 912                 (fun-tn old-fp return-pc pass-refs)
 913                 (nil)
 914                 nargs)
 915           (vop* tail-call node block
 916                 (fun-tn old-fp return-pc pass-refs)
 917                 (nil)
 918                 nargs))))
 919
 920   (values))
 921
 922 ;;; like IR2-CONVERT-LOCAL-CALL-ARGS, only different
 923 (defun ir2-convert-full-call-args (node block)
 924   (declare (type combination node) (type ir2-block block))
 925   (let* ((args (basic-combination-args node))
 926          (fp (make-stack-pointer-tn))
 927          (nargs (length args)))
 928     (vop allocate-full-call-frame node block nargs fp)
 929     (collect ((locs))
 930       (let ((last nil)
 931             (first nil))
 932         (dotimes (num nargs)
 933           (locs (standard-arg-location num))
 934           (let ((ref (reference-tn (lvar-tn node block (elt args num))
 935                                    nil)))
 936             (if last
 937                 (setf (tn-ref-across last) ref)
 938                 (setf first ref))
 939             (setq last ref)))
 940
 941         (values fp first (locs) nargs)))))
 942
 943 ;;; Do full call when a fixed number of values are desired. We make
 944 ;;; STANDARD-RESULT-TNS for our lvar, then deliver the result using
 945 ;;; MOVE-LVAR-RESULT. We do named or normal call, as appropriate.
 946 (defun ir2-convert-fixed-full-call (node block)
 947   (declare (type combination node) (type ir2-block block))
 948   (multiple-value-bind (fp args arg-locs nargs)
 949       (ir2-convert-full-call-args node block)
 950     (let* ((lvar (node-lvar node))
 951            (locs (standard-result-tns lvar))
 952            (loc-refs (reference-tn-list locs t))
 953            (nvals (length locs)))
 954       (multiple-value-bind (fun-tn named)
 955           (fun-lvar-tn node block (basic-combination-fun node))
 956         (if named
 957             (vop* call-named node block (fp fun-tn args) (loc-refs)
 958                   arg-locs nargs nvals)
 959             (vop* call node block (fp fun-tn args) (loc-refs)
 960                   arg-locs nargs nvals))
 961         (move-lvar-result node block locs lvar))))
 962   (values))
 963
 964 ;;; Do full call when unknown values are desired.
 965 (defun ir2-convert-multiple-full-call (node block)
 966   (declare (type combination node) (type ir2-block block))
 967   (multiple-value-bind (fp args arg-locs nargs)
 968       (ir2-convert-full-call-args node block)
 969     (let* ((lvar (node-lvar node))
 970            (locs (ir2-lvar-locs (lvar-info lvar)))
 971            (loc-refs (reference-tn-list locs t)))
 972       (multiple-value-bind (fun-tn named)
 973           (fun-lvar-tn node block (basic-combination-fun node))
 974         (if named
 975             (vop* multiple-call-named node block (fp fun-tn args) (loc-refs)
 976                   arg-locs nargs)
 977             (vop* multiple-call node block (fp fun-tn args) (loc-refs)
 978                   arg-locs nargs)))))
 979   (values))
 980
 981 ;;; stuff to check in PONDER-FULL-CALL
 982 ;;;
 983 ;;; There are some things which are intended always to be optimized
 984 ;;; away by DEFTRANSFORMs and such, and so never compiled into full
 985 ;;; calls. This has been a source of bugs so many times that it seems
 986 ;;; worth listing some of them here so that we can check the list
 987 ;;; whenever we compile a full call.
 988 ;;;
 989 ;;; FIXME: It might be better to represent this property by setting a
 990 ;;; flag in DEFKNOWN, instead of representing it by membership in this
 991 ;;; list.
 992 (defvar *always-optimized-away*
 993   '(;; This should always be DEFTRANSFORMed away, but wasn't in a bug
 994     ;; reported to cmucl-imp 2000-06-20.
 995     %instance-ref
 996     ;; These should always turn into VOPs, but wasn't in a bug which
 997     ;; appeared when LTN-POLICY stuff was being tweaked in
 998     ;; sbcl-0.6.9.16. in sbcl-0.6.0
 999     data-vector-set
1000     data-vector-ref))
1001
1002 ;;; more stuff to check in PONDER-FULL-CALL
1003 ;;;
1004 ;;; These came in handy when troubleshooting cold boot after making
1005 ;;; major changes in the package structure: various transforms and
1006 ;;; VOPs and stuff got attached to the wrong symbol, so that
1007 ;;; references to the right symbol were bogusly translated as full
1008 ;;; calls instead of primitives, sending the system off into infinite
1009 ;;; space. Having a report on all full calls generated makes it easier
1010 ;;; to figure out what form caused the problem this time.
1011 #!+sb-show (defvar *show-full-called-fnames-p* nil)
1012 #!+sb-show (defvar *full-called-fnames* (make-hash-table :test 'equal))
1013
1014 ;;; Do some checks (and store some notes relevant for future checks)
1015 ;;; on a full call:
1016 ;;;   * Is this a full call to something we have reason to know should
1017 ;;;     never be full called? (Except as of sbcl-0.7.18 or so, we no
1018 ;;;     longer try to ensure this behavior when *FAILURE-P* has already
1019 ;;;     been detected.)
1020 ;;;   * Is this a full call to (SETF FOO) which might conflict with
1021 ;;;     a DEFSETF or some such thing elsewhere in the program?
1022 (defun ponder-full-call (node)
1023   (let* ((lvar (basic-combination-fun node))
1024          (fname (lvar-fun-name lvar t)))
1025     (declare (type (or symbol cons) fname))
1026
1027     #!+sb-show (unless (gethash fname *full-called-fnames*)
1028                  (setf (gethash fname *full-called-fnames*) t))
1029     #!+sb-show (when *show-full-called-fnames-p*
1030                  (/show "converting full call to named function" fname)
1031                  (/show (basic-combination-args node))
1032                  (/show (policy node speed) (policy node safety))
1033                  (/show (policy node compilation-speed))
1034                  (let ((arg-types (mapcar (lambda (lvar)
1035                                             (when lvar
1036                                               (type-specifier
1037                                                (lvar-type lvar))))
1038                                           (basic-combination-args node))))
1039                    (/show arg-types)))
1040
1041     ;; When illegal code is compiled, all sorts of perverse paths
1042     ;; through the compiler can be taken, and it's much harder -- and
1043     ;; probably pointless -- to guarantee that always-optimized-away
1044     ;; functions are actually optimized away. Thus, we skip the check
1045     ;; in that case.
1046     (unless *failure-p*
1047       (when (memq fname *always-optimized-away*)
1048         (/show (policy node speed) (policy node safety))
1049         (/show (policy node compilation-speed))
1050         (bug "full call to ~S" fname)))
1051
1052     (when (consp fname)
1053       (aver (legal-fun-name-p fname))
1054       (destructuring-bind (setfoid &rest stem) fname
1055         (when (eq setfoid 'setf)
1056           (setf (gethash (car stem) *setf-assumed-fboundp*) t))))))
1057
1058 ;;; If the call is in a tail recursive position and the return
1059 ;;; convention is standard, then do a tail full call. If one or fewer
1060 ;;; values are desired, then use a single-value call, otherwise use a
1061 ;;; multiple-values call.
1062 (defun ir2-convert-full-call (node block)
1063   (declare (type combination node) (type ir2-block block))
1064   (ponder-full-call node)
1065   (cond ((node-tail-p node)
1066          (ir2-convert-tail-full-call node block))
1067         ((let ((lvar (node-lvar node)))
1068            (and lvar
1069                 (eq (ir2-lvar-kind (lvar-info lvar)) :unknown)))
1070          (ir2-convert-multiple-full-call node block))
1071         (t
1072          (ir2-convert-fixed-full-call node block)))
1073   (values))
1074 \f
1075 ;;;; entering functions
1076
1077 ;;; Do all the stuff that needs to be done on XEP entry:
1078 ;;; -- Create frame.
1079 ;;; -- Copy any more arg.
1080 ;;; -- Set up the environment, accessing any closure variables.
1081 ;;; -- Move args from the standard passing locations to their internal
1082 ;;;    locations.
1083 (defun init-xep-environment (node block fun)
1084   (declare (type bind node) (type ir2-block block) (type clambda fun))
1085   (let ((start-label (entry-info-offset (leaf-info fun)))
1086         (env (physenv-info (node-physenv node))))
1087     (let ((ef (functional-entry-fun fun)))
1088       (cond ((and (optional-dispatch-p ef) (optional-dispatch-more-entry ef))
1089              ;; Special case the xep-allocate-frame + copy-more-arg case.
1090              (vop xep-allocate-frame node block start-label t)
1091              (vop copy-more-arg node block (optional-dispatch-max-args ef)))
1092             (t
1093              ;; No more args, so normal entry.
1094              (vop xep-allocate-frame node block start-label nil)))
1095       (if (ir2-physenv-closure env)
1096           (let ((closure (make-normal-tn *backend-t-primitive-type*)))
1097             (vop setup-closure-environment node block start-label closure)
1098             (when (getf (functional-plist ef) :fin-function)
1099               (vop funcallable-instance-lexenv node block closure closure))
1100             (let ((n -1))
1101               (dolist (loc (ir2-physenv-closure env))
1102                 (vop closure-ref node block closure (incf n) (cdr loc)))))
1103           (vop setup-environment node block start-label)))
1104
1105     (unless (eq (functional-kind fun) :toplevel)
1106       (let ((vars (lambda-vars fun))
1107             (n 0))
1108         (when (leaf-refs (first vars))
1109           (emit-move node block (make-arg-count-location)
1110                      (leaf-info (first vars))))
1111         (dolist (arg (rest vars))
1112           (when (leaf-refs arg)
1113             (let ((pass (standard-arg-location n))
1114                   (home (leaf-info arg)))
1115               (if (lambda-var-indirect arg)
1116                   (do-make-value-cell node block pass home)
1117                   (emit-move node block pass home))))
1118           (incf n))))
1119
1120     (emit-move node block (make-old-fp-passing-location t)
1121                (ir2-physenv-old-fp env)))
1122
1123   (values))
1124
1125 ;;; Emit function prolog code. This is only called on bind nodes for
1126 ;;; functions that allocate environments. All semantics of let calls
1127 ;;; are handled by IR2-CONVERT-LET.
1128 ;;;
1129 ;;; If not an XEP, all we do is move the return PC from its passing
1130 ;;; location, since in a local call, the caller allocates the frame
1131 ;;; and sets up the arguments.
1132 (defun ir2-convert-bind (node block)
1133   (declare (type bind node) (type ir2-block block))
1134   (let* ((fun (bind-lambda node))
1135          (env (physenv-info (lambda-physenv fun))))
1136     (aver (member (functional-kind fun)
1137                   '(nil :external :optional :toplevel :cleanup)))
1138
1139     (when (xep-p fun)
1140       (init-xep-environment node block fun)
1141       #!+sb-dyncount
1142       (when *collect-dynamic-statistics*
1143         (vop count-me node block *dynamic-counts-tn*
1144              (block-number (ir2-block-block block)))))
1145
1146     (emit-move node
1147                block
1148                (ir2-physenv-return-pc-pass env)
1149                (ir2-physenv-return-pc env))
1150
1151     (let ((lab (gen-label)))
1152       (setf (ir2-physenv-environment-start env) lab)
1153       (vop note-environment-start node block lab)))
1154
1155   (values))
1156 \f
1157 ;;;; function return
1158
1159 ;;; Do stuff to return from a function with the specified values and
1160 ;;; convention. If the return convention is :FIXED and we aren't
1161 ;;; returning from an XEP, then we do a known return (letting
1162 ;;; representation selection insert the correct move-arg VOPs.)
1163 ;;; Otherwise, we use the unknown-values convention. If there is a
1164 ;;; fixed number of return values, then use RETURN, otherwise use
1165 ;;; RETURN-MULTIPLE.
1166 (defun ir2-convert-return (node block)
1167   (declare (type creturn node) (type ir2-block block))
1168   (let* ((lvar (return-result node))
1169          (2lvar (lvar-info lvar))
1170          (lvar-kind (ir2-lvar-kind 2lvar))
1171          (fun (return-lambda node))
1172          (env (physenv-info (lambda-physenv fun)))
1173          (old-fp (ir2-physenv-old-fp env))
1174          (return-pc (ir2-physenv-return-pc env))
1175          (returns (tail-set-info (lambda-tail-set fun))))
1176     (cond
1177      ((and (eq (return-info-kind returns) :fixed)
1178            (not (xep-p fun)))
1179       (let ((locs (lvar-tns node block lvar
1180                                     (return-info-types returns))))
1181         (vop* known-return node block
1182               (old-fp return-pc (reference-tn-list locs nil))
1183               (nil)
1184               (return-info-locations returns))))
1185      ((eq lvar-kind :fixed)
1186       (let* ((types (mapcar #'tn-primitive-type (ir2-lvar-locs 2lvar)))
1187              (lvar-locs (lvar-tns node block lvar types))
1188              (nvals (length lvar-locs))
1189              (locs (make-standard-value-tns nvals)))
1190         (mapc (lambda (val loc)
1191                 (emit-move node block val loc))
1192               lvar-locs
1193               locs)
1194         (if (= nvals 1)
1195             (vop return-single node block old-fp return-pc (car locs))
1196             (vop* return node block
1197                   (old-fp return-pc (reference-tn-list locs nil))
1198                   (nil)
1199                   nvals))))
1200      (t
1201       (aver (eq lvar-kind :unknown))
1202       (vop* return-multiple node block
1203             (old-fp return-pc
1204                     (reference-tn-list (ir2-lvar-locs 2lvar) nil))
1205             (nil)))))
1206
1207   (values))
1208 \f
1209 ;;;; debugger hooks
1210
1211 ;;; This is used by the debugger to find the top function on the
1212 ;;; stack. It returns the OLD-FP and RETURN-PC for the current
1213 ;;; function as multiple values.
1214 (defoptimizer (sb!kernel:%caller-frame-and-pc ir2-convert) (() node block)
1215   (let ((ir2-physenv (physenv-info (node-physenv node))))
1216     (move-lvar-result node block
1217                       (list (ir2-physenv-old-fp ir2-physenv)
1218                             (ir2-physenv-return-pc ir2-physenv))
1219                       (node-lvar node))))
1220 \f
1221 ;;;; multiple values
1222
1223 ;;; This is almost identical to IR2-CONVERT-LET. Since LTN annotates
1224 ;;; the lvar for the correct number of values (with the lvar user
1225 ;;; responsible for defaulting), we can just pick them up from the
1226 ;;; lvar.
1227 (defun ir2-convert-mv-bind (node block)
1228   (declare (type mv-combination node) (type ir2-block block))
1229   (let* ((lvar (first (basic-combination-args node)))
1230          (fun (ref-leaf (lvar-uses (basic-combination-fun node))))
1231          (vars (lambda-vars fun)))
1232     (aver (eq (functional-kind fun) :mv-let))
1233     (mapc (lambda (src var)
1234             (when (leaf-refs var)
1235               (let ((dest (leaf-info var)))
1236                 (if (lambda-var-indirect var)
1237                     (do-make-value-cell node block src dest)
1238                     (emit-move node block src dest)))))
1239           (lvar-tns node block lvar
1240                             (mapcar (lambda (x)
1241                                       (primitive-type (leaf-type x)))
1242                                     vars))
1243           vars))
1244   (values))
1245
1246 ;;; Emit the appropriate fixed value, unknown value or tail variant of
1247 ;;; CALL-VARIABLE. Note that we only need to pass the values start for
1248 ;;; the first argument: all the other argument lvar TNs are
1249 ;;; ignored. This is because we require all of the values globs to be
1250 ;;; contiguous and on stack top.
1251 (defun ir2-convert-mv-call (node block)
1252   (declare (type mv-combination node) (type ir2-block block))
1253   (aver (basic-combination-args node))
1254   (let* ((start-lvar (lvar-info (first (basic-combination-args node))))
1255          (start (first (ir2-lvar-locs start-lvar)))
1256          (tails (and (node-tail-p node)
1257                      (lambda-tail-set (node-home-lambda node))))
1258          (lvar (node-lvar node))
1259          (2lvar (and lvar (lvar-info lvar))))
1260     (multiple-value-bind (fun named)
1261         (fun-lvar-tn node block (basic-combination-fun node))
1262       (aver (and (not named)
1263                  (eq (ir2-lvar-kind start-lvar) :unknown)))
1264       (cond
1265        (tails
1266         (let ((env (physenv-info (node-physenv node))))
1267           (vop tail-call-variable node block start fun
1268                (ir2-physenv-old-fp env)
1269                (ir2-physenv-return-pc env))))
1270        ((and 2lvar
1271              (eq (ir2-lvar-kind 2lvar) :unknown))
1272         (vop* multiple-call-variable node block (start fun nil)
1273               ((reference-tn-list (ir2-lvar-locs 2lvar) t))))
1274        (t
1275         (let ((locs (standard-result-tns lvar)))
1276           (vop* call-variable node block (start fun nil)
1277                 ((reference-tn-list locs t)) (length locs))
1278           (move-lvar-result node block locs lvar)))))))
1279
1280 ;;; Reset the stack pointer to the start of the specified
1281 ;;; unknown-values lvar (discarding it and all values globs on top of
1282 ;;; it.)
1283 (defoptimizer (%pop-values ir2-convert) ((%lvar) node block)
1284   (let* ((lvar (lvar-value %lvar))
1285          (2lvar (lvar-info lvar)))
1286     (cond ((eq (ir2-lvar-kind 2lvar) :unknown)
1287            (vop reset-stack-pointer node block
1288                 (first (ir2-lvar-locs 2lvar))))
1289           ((lvar-dynamic-extent lvar)
1290            #!+stack-grows-downward-not-upward
1291            (vop reset-stack-pointer node block
1292                 (ir2-lvar-stack-pointer 2lvar))
1293            #!-stack-grows-downward-not-upward
1294            (vop %%pop-dx node block
1295                 (first (ir2-lvar-locs 2lvar))))
1296           (t (bug "Trying to pop a not stack-allocated LVAR ~S."
1297                   lvar)))))
1298
1299 (defoptimizer (%nip-values ir2-convert) ((last-nipped last-preserved
1300                                                       &rest moved)
1301                                          node block)
1302   (let* ( ;; pointer immediately after the nipped block
1303          (after (lvar-value last-nipped))
1304          (2after (lvar-info after))
1305          ;; pointer to the first nipped word
1306          (first (lvar-value last-preserved))
1307          (2first (lvar-info first))
1308
1309          (moved-tns (loop for lvar-ref in moved
1310                           for lvar = (lvar-value lvar-ref)
1311                           for 2lvar = (lvar-info lvar)
1312                                         ;when 2lvar
1313                           collect (first (ir2-lvar-locs 2lvar)))))
1314     (aver (or (eq (ir2-lvar-kind 2after) :unknown)
1315               (lvar-dynamic-extent after)))
1316     (aver (eq (ir2-lvar-kind 2first) :unknown))
1317     (when *check-consistency*
1318       ;; we cannot move stack-allocated DX objects
1319       (dolist (moved-lvar moved)
1320         (aver (eq (ir2-lvar-kind (lvar-info (lvar-value moved-lvar)))
1321                   :unknown))))
1322     (flet ((nip-aligned (nipped)
1323              (vop* %%nip-values node block
1324                    (nipped
1325                     (first (ir2-lvar-locs 2first))
1326                     (reference-tn-list moved-tns nil))
1327                    ((reference-tn-list moved-tns t))))
1328            #!-stack-grows-downward-not-upward
1329            (nip-unaligned (nipped)
1330              (vop* %%nip-dx node block
1331                    (nipped
1332                     (first (ir2-lvar-locs 2first))
1333                     (reference-tn-list moved-tns nil))
1334                    ((reference-tn-list moved-tns t)))))
1335       (cond ((eq (ir2-lvar-kind 2after) :unknown)
1336              (nip-aligned (first (ir2-lvar-locs 2after))))
1337             ((lvar-dynamic-extent after)
1338              #!+stack-grows-downward-not-upward
1339              (nip-aligned (ir2-lvar-stack-pointer 2after))
1340              #!-stack-grows-downward-not-upward
1341              (nip-unaligned (ir2-lvar-stack-pointer 2after)))
1342             (t
1343              (bug "Trying to nip a not stack-allocated LVAR ~S." after))))))
1344
1345 ;;; Deliver the values TNs to LVAR using MOVE-LVAR-RESULT.
1346 (defoptimizer (values ir2-convert) ((&rest values) node block)
1347   (let ((tns (mapcar (lambda (x)
1348                        (lvar-tn node block x))
1349                      values)))
1350     (move-lvar-result node block tns (node-lvar node))))
1351
1352 ;;; In the normal case where unknown values are desired, we use the
1353 ;;; VALUES-LIST VOP. In the relatively unimportant case of VALUES-LIST
1354 ;;; for a fixed number of values, we punt by doing a full call to the
1355 ;;; VALUES-LIST function. This gets the full call VOP to deal with
1356 ;;; defaulting any unsupplied values. It seems unworthwhile to
1357 ;;; optimize this case.
1358 (defoptimizer (values-list ir2-convert) ((list) node block)
1359   (let* ((lvar (node-lvar node))
1360          (2lvar (and lvar (lvar-info lvar))))
1361     (cond ((and 2lvar
1362                 (eq (ir2-lvar-kind 2lvar) :unknown))
1363            (let ((locs (ir2-lvar-locs 2lvar)))
1364              (vop* values-list node block
1365                    ((lvar-tn node block list) nil)
1366                    ((reference-tn-list locs t)))))
1367           (t (aver (or (not 2lvar) ; i.e. we want to check the argument
1368                        (eq (ir2-lvar-kind 2lvar) :fixed)))
1369              (ir2-convert-full-call node block)))))
1370
1371 (defoptimizer (%more-arg-values ir2-convert) ((context start count) node block)
1372   (binding* ((lvar (node-lvar node) :exit-if-null)
1373              (2lvar (lvar-info lvar)))
1374     (ecase (ir2-lvar-kind 2lvar)
1375       (:fixed (ir2-convert-full-call node block))
1376       (:unknown
1377        (let ((locs (ir2-lvar-locs 2lvar)))
1378          (vop* %more-arg-values node block
1379                ((lvar-tn node block context)
1380                 (lvar-tn node block start)
1381                 (lvar-tn node block count)
1382                 nil)
1383                ((reference-tn-list locs t))))))))
1384 \f
1385 ;;;; special binding
1386
1387 ;;; This is trivial, given our assumption of a shallow-binding
1388 ;;; implementation.
1389 (defoptimizer (%special-bind ir2-convert) ((var value) node block)
1390   (let ((name (leaf-source-name (lvar-value var))))
1391     (vop bind node block (lvar-tn node block value)
1392          (emit-constant name))))
1393 (defoptimizer (%special-unbind ir2-convert) ((var) node block)
1394   (vop unbind node block))
1395
1396 ;;; ### It's not clear that this really belongs in this file, or
1397 ;;; should really be done this way, but this is the least violation of
1398 ;;; abstraction in the current setup. We don't want to wire
1399 ;;; shallow-binding assumptions into IR1tran.
1400 (def-ir1-translator progv
1401     ((vars vals &body body) start next result)
1402   (ir1-convert
1403    start next result
1404    (with-unique-names (bind unbind)
1405      (once-only ((n-save-bs '(%primitive current-binding-pointer)))
1406        `(unwind-protect
1407              (progn
1408                (labels ((,unbind (vars)
1409                           (declare (optimize (speed 2) (debug 0)))
1410                           (dolist (var vars)
1411                             (%primitive bind nil var)
1412                             (makunbound var)))
1413                         (,bind (vars vals)
1414                           (declare (optimize (speed 2) (debug 0)))
1415                           (cond ((null vars))
1416                                 ((null vals) (,unbind vars))
1417                                 (t (%primitive bind
1418                                                (car vals)
1419                                                (car vars))
1420                                    (,bind (cdr vars) (cdr vals))))))
1421                  (,bind ,vars ,vals))
1422                nil
1423                ,@body)
1424           (%primitive unbind-to-here ,n-save-bs))))))
1425 \f
1426 ;;;; non-local exit
1427
1428 ;;; Convert a non-local lexical exit. First find the NLX-INFO in our
1429 ;;; environment. Note that this is never called on the escape exits
1430 ;;; for CATCH and UNWIND-PROTECT, since the escape functions aren't
1431 ;;; IR2 converted.
1432 (defun ir2-convert-exit (node block)
1433   (declare (type exit node) (type ir2-block block))
1434   (let ((loc (find-in-physenv (find-nlx-info node)
1435                               (node-physenv node)))
1436         (temp (make-stack-pointer-tn))
1437         (value (exit-value node)))
1438     (vop value-cell-ref node block loc temp)
1439     (if value
1440         (let ((locs (ir2-lvar-locs (lvar-info value))))
1441           (vop unwind node block temp (first locs) (second locs)))
1442         (let ((0-tn (emit-constant 0)))
1443           (vop unwind node block temp 0-tn 0-tn))))
1444
1445   (values))
1446
1447 ;;; %CLEANUP-POINT doesn't do anything except prevent the body from
1448 ;;; being entirely deleted.
1449 (defoptimizer (%cleanup-point ir2-convert) (() node block) node block)
1450
1451 ;;; This function invalidates a lexical exit on exiting from the
1452 ;;; dynamic extent. This is done by storing 0 into the indirect value
1453 ;;; cell that holds the closed unwind block.
1454 (defoptimizer (%lexical-exit-breakup ir2-convert) ((info) node block)
1455   (vop value-cell-set node block
1456        (find-in-physenv (lvar-value info) (node-physenv node))
1457        (emit-constant 0)))
1458
1459 ;;; We have to do a spurious move of no values to the result lvar so
1460 ;;; that lifetime analysis won't get confused.
1461 (defun ir2-convert-throw (node block)
1462   (declare (type mv-combination node) (type ir2-block block))
1463   (let ((args (basic-combination-args node)))
1464     (check-catch-tag-type (first args))
1465     (vop* throw node block
1466           ((lvar-tn node block (first args))
1467            (reference-tn-list
1468             (ir2-lvar-locs (lvar-info (second args)))
1469             nil))
1470           (nil)))
1471   (move-lvar-result node block () (node-lvar node))
1472   (values))
1473
1474 ;;; Emit code to set up a non-local exit. INFO is the NLX-INFO for the
1475 ;;; exit, and TAG is the lvar for the catch tag (if any.) We get at
1476 ;;; the target PC by passing in the label to the vop. The vop is
1477 ;;; responsible for building a return-PC object.
1478 (defun emit-nlx-start (node block info tag)
1479   (declare (type node node) (type ir2-block block) (type nlx-info info)
1480            (type (or lvar null) tag))
1481   (let* ((2info (nlx-info-info info))
1482          (kind (cleanup-kind (nlx-info-cleanup info)))
1483          (block-tn (physenv-live-tn
1484                     (make-normal-tn (primitive-type-or-lose 'catch-block))
1485                     (node-physenv node)))
1486          (res (make-stack-pointer-tn))
1487          (target-label (ir2-nlx-info-target 2info)))
1488
1489     (vop current-binding-pointer node block
1490          (car (ir2-nlx-info-dynamic-state 2info)))
1491     (vop* save-dynamic-state node block
1492           (nil)
1493           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) t)))
1494     (vop current-stack-pointer node block (ir2-nlx-info-save-sp 2info))
1495
1496     (ecase kind
1497       (:catch
1498        (vop make-catch-block node block block-tn
1499             (lvar-tn node block tag) target-label res))
1500       ((:unwind-protect :block :tagbody)
1501        (vop make-unwind-block node block block-tn target-label res)))
1502
1503     (ecase kind
1504       ((:block :tagbody)
1505        (do-make-value-cell node block res (ir2-nlx-info-home 2info)))
1506       (:unwind-protect
1507        (vop set-unwind-protect node block block-tn))
1508       (:catch)))
1509
1510   (values))
1511
1512 ;;; Scan each of ENTRY's exits, setting up the exit for each lexical exit.
1513 (defun ir2-convert-entry (node block)
1514   (declare (type entry node) (type ir2-block block))
1515   (dolist (exit (entry-exits node))
1516     (let ((info (find-nlx-info exit)))
1517       (when (and info
1518                  (member (cleanup-kind (nlx-info-cleanup info))
1519                          '(:block :tagbody)))
1520         (emit-nlx-start node block info nil))))
1521   (values))
1522
1523 ;;; Set up the unwind block for these guys.
1524 (defoptimizer (%catch ir2-convert) ((info-lvar tag) node block)
1525   (check-catch-tag-type tag)
1526   (emit-nlx-start node block (lvar-value info-lvar) tag))
1527 (defoptimizer (%unwind-protect ir2-convert) ((info-lvar cleanup) node block)
1528   (emit-nlx-start node block (lvar-value info-lvar) nil))
1529
1530 ;;; Emit the entry code for a non-local exit. We receive values and
1531 ;;; restore dynamic state.
1532 ;;;
1533 ;;; In the case of a lexical exit or CATCH, we look at the exit lvar's
1534 ;;; kind to determine which flavor of entry VOP to emit. If unknown
1535 ;;; values, emit the xxx-MULTIPLE variant to the lvar locs. If fixed
1536 ;;; values, make the appropriate number of temps in the standard
1537 ;;; values locations and use the other variant, delivering the temps
1538 ;;; to the lvar using MOVE-LVAR-RESULT.
1539 ;;;
1540 ;;; In the UNWIND-PROTECT case, we deliver the first register
1541 ;;; argument, the argument count and the argument pointer to our lvar
1542 ;;; as multiple values. These values are the block exited to and the
1543 ;;; values start and count.
1544 ;;;
1545 ;;; After receiving values, we restore dynamic state. Except in the
1546 ;;; UNWIND-PROTECT case, the values receiving restores the stack
1547 ;;; pointer. In an UNWIND-PROTECT cleanup, we want to leave the stack
1548 ;;; pointer alone, since the thrown values are still out there.
1549 (defoptimizer (%nlx-entry ir2-convert) ((info-lvar) node block)
1550   (let* ((info (lvar-value info-lvar))
1551          (lvar (nlx-info-lvar info))
1552          (2info (nlx-info-info info))
1553          (top-loc (ir2-nlx-info-save-sp 2info))
1554          (start-loc (make-nlx-entry-arg-start-location))
1555          (count-loc (make-arg-count-location))
1556          (target (ir2-nlx-info-target 2info)))
1557
1558     (ecase (cleanup-kind (nlx-info-cleanup info))
1559       ((:catch :block :tagbody)
1560        (let ((2lvar (and lvar (lvar-info lvar))))
1561          (if (and 2lvar (eq (ir2-lvar-kind 2lvar) :unknown))
1562              (vop* nlx-entry-multiple node block
1563                    (top-loc start-loc count-loc nil)
1564                    ((reference-tn-list (ir2-lvar-locs 2lvar) t))
1565                    target)
1566              (let ((locs (standard-result-tns lvar)))
1567                (vop* nlx-entry node block
1568                      (top-loc start-loc count-loc nil)
1569                      ((reference-tn-list locs t))
1570                      target
1571                      (length locs))
1572                (move-lvar-result node block locs lvar)))))
1573       (:unwind-protect
1574        (let ((block-loc (standard-arg-location 0)))
1575          (vop uwp-entry node block target block-loc start-loc count-loc)
1576          (move-lvar-result
1577           node block
1578           (list block-loc start-loc count-loc)
1579           lvar))))
1580
1581     #!+sb-dyncount
1582     (when *collect-dynamic-statistics*
1583       (vop count-me node block *dynamic-counts-tn*
1584            (block-number (ir2-block-block block))))
1585
1586     (vop* restore-dynamic-state node block
1587           ((reference-tn-list (cdr (ir2-nlx-info-dynamic-state 2info)) nil))
1588           (nil))
1589     (vop unbind-to-here node block
1590          (car (ir2-nlx-info-dynamic-state 2info)))))
1591 \f
1592 ;;;; n-argument functions
1593
1594 (macrolet ((def (name)
1595              `(defoptimizer (,name ir2-convert) ((&rest args) node block)
1596                 (let* ((refs (move-tail-full-call-args node block))
1597                        (lvar (node-lvar node))
1598                        (res (lvar-result-tns
1599                              lvar
1600                              (list (primitive-type (specifier-type 'list))))))
1601                   #!+stack-grows-downward-not-upward
1602                   (when (and lvar (lvar-dynamic-extent lvar))
1603                     (vop current-stack-pointer node block
1604                          (ir2-lvar-stack-pointer (lvar-info lvar))))
1605                   (vop* ,name node block (refs) ((first res) nil)
1606                         (length args))
1607                   (move-lvar-result node block res lvar)))))
1608   (def list)
1609   (def list*))
1610
1611 \f
1612 ;;; Convert the code in a component into VOPs.
1613 (defun ir2-convert (component)
1614   (declare (type component component))
1615   (let (#!+sb-dyncount
1616         (*dynamic-counts-tn*
1617          (when *collect-dynamic-statistics*
1618            (let* ((blocks
1619                    (block-number (block-next (component-head component))))
1620                   (counts (make-array blocks
1621                                       :element-type '(unsigned-byte 32)
1622                                       :initial-element 0))
1623                   (info (make-dyncount-info
1624                          :for (component-name component)
1625                          :costs (make-array blocks
1626                                             :element-type '(unsigned-byte 32)
1627                                             :initial-element 0)
1628                          :counts counts)))
1629              (setf (ir2-component-dyncount-info (component-info component))
1630                    info)
1631              (emit-constant info)
1632              (emit-constant counts)))))
1633     (let ((num 0))
1634       (declare (type index num))
1635       (do-ir2-blocks (2block component)
1636         (let ((block (ir2-block-block 2block)))
1637           (when (block-start block)
1638             (setf (block-number block) num)
1639             #!+sb-dyncount
1640             (when *collect-dynamic-statistics*
1641               (let ((first-node (block-start-node block)))
1642                 (unless (or (and (bind-p first-node)
1643                                  (xep-p (bind-lambda first-node)))
1644                             (eq (lvar-fun-name
1645                                  (node-lvar first-node))
1646                                 '%nlx-entry))
1647                   (vop count-me
1648                        first-node
1649                        2block
1650                        #!+sb-dyncount *dynamic-counts-tn* #!-sb-dyncount nil
1651                        num))))
1652             (ir2-convert-block block)
1653             (incf num))))))
1654   (values))
1655
1656 ;;; If necessary, emit a terminal unconditional branch to go to the
1657 ;;; successor block. If the successor is the component tail, then
1658 ;;; there isn't really any successor, but if the end is an unknown,
1659 ;;; non-tail call, then we emit an error trap just in case the
1660 ;;; function really does return.
1661 (defun finish-ir2-block (block)
1662   (declare (type cblock block))
1663   (let* ((2block (block-info block))
1664          (last (block-last block))
1665          (succ (block-succ block)))
1666     (unless (if-p last)
1667       (aver (singleton-p succ))
1668       (let ((target (first succ)))
1669         (cond ((eq target (component-tail (block-component block)))
1670                (when (and (basic-combination-p last)
1671                           (eq (basic-combination-kind last) :full))
1672                  (let* ((fun (basic-combination-fun last))
1673                         (use (lvar-uses fun))
1674                         (name (and (ref-p use)
1675                                    (leaf-has-source-name-p (ref-leaf use))
1676                                    (leaf-source-name (ref-leaf use)))))
1677                    (unless (or (node-tail-p last)
1678                                (info :function :info name)
1679                                (policy last (zerop safety)))
1680                      (vop nil-fun-returned-error last 2block
1681                           (if name
1682                               (emit-constant name)
1683                               (multiple-value-bind (tn named)
1684                                   (fun-lvar-tn last 2block fun)
1685                                 (aver (not named))
1686                                 tn)))))))
1687               ((not (eq (ir2-block-next 2block) (block-info target)))
1688                (vop branch last 2block (block-label target)))))))
1689
1690   (values))
1691
1692 ;;; Convert the code in a block into VOPs.
1693 (defun ir2-convert-block (block)
1694   (declare (type cblock block))
1695   (let ((2block (block-info block)))
1696     (do-nodes (node lvar block)
1697       (etypecase node
1698         (ref
1699          (when lvar
1700            (let ((2lvar (lvar-info lvar)))
1701              ;; function REF in a local call is not annotated
1702              (when (and 2lvar (not (eq (ir2-lvar-kind 2lvar) :delayed)))
1703                (ir2-convert-ref node 2block)))))
1704         (combination
1705          (let ((kind (basic-combination-kind node)))
1706            (ecase kind
1707              (:local
1708               (ir2-convert-local-call node 2block))
1709              (:full
1710               (ir2-convert-full-call node 2block))
1711              (:known
1712               (let* ((info (basic-combination-fun-info node))
1713                      (fun (fun-info-ir2-convert info)))
1714                 (cond (fun
1715                        (funcall fun node 2block))
1716                       ((eq (basic-combination-info node) :full)
1717                        (ir2-convert-full-call node 2block))
1718                       (t
1719                        (ir2-convert-template node 2block))))))))
1720         (cif
1721          (when (lvar-info (if-test node))
1722            (ir2-convert-if node 2block)))
1723         (bind
1724          (let ((fun (bind-lambda node)))
1725            (when (eq (lambda-home fun) fun)
1726              (ir2-convert-bind node 2block))))
1727         (creturn
1728          (ir2-convert-return node 2block))
1729         (cset
1730          (ir2-convert-set node 2block))
1731         (cast
1732          (ir2-convert-cast node 2block))
1733         (mv-combination
1734          (cond
1735            ((eq (basic-combination-kind node) :local)
1736             (ir2-convert-mv-bind node 2block))
1737            ((eq (lvar-fun-name (basic-combination-fun node))
1738                 '%throw)
1739             (ir2-convert-throw node 2block))
1740            (t
1741             (ir2-convert-mv-call node 2block))))
1742         (exit
1743          (when (exit-entry node)
1744            (ir2-convert-exit node 2block)))
1745         (entry
1746          (ir2-convert-entry node 2block)))))
1747
1748   (finish-ir2-block block)
1749
1750   (values))