src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; return value is important, and ignoring it is probably a mistake.
  65   ;; Unlike the other attributes, this is used only for style
  66   ;; warnings and has no effect on optimization.
  67   important-result
  68   ;; may be moved with impunity. Has no side effects except possibly
  69   ;; consing, and is affected only by its arguments.
  70   ;;
  71   ;; Since it is not used now, its distribution in fndb.lisp is
  72   ;; mere random; use with caution.
  73   movable
  74   ;; The function is a true predicate likely to be open-coded. Convert
  75   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  76   ;; specified to DEFKNOWN, since this is implementation dependent,
  77   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  78   ;; option.
  79   predicate
  80   ;; Inhibit any warning for compiling a recursive definition.
  81   ;; (Normally the compiler warns when compiling a recursive
  82   ;; definition for a known function, since it might be a botched
  83   ;; interpreter stub.)
  84   recursive
  85   ;; The function does explicit argument type checking, so the
  86   ;; declared type should not be asserted when a definition is
  87   ;; compiled.
  88   explicit-check)
  89
  90 (defstruct (fun-info #-sb-xc-host (:pure t))
  91   ;; boolean attributes of this function.
  92   (attributes (missing-arg) :type attributes)
  93   ;; TRANSFORM structures describing transforms for this function
  94   (transforms () :type list)
  95   ;; a function which computes the derived type for a call to this
  96   ;; function by examining the arguments. This is null when there is
  97   ;; no special method for this function.
  98   (derive-type nil :type (or function null))
  99   ;; a function that does various unspecified code transformations by
 100   ;; directly hacking the IR. Returns true if further optimizations of
 101   ;; the call shouldn't be attempted.
 102   ;;
 103   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 104   ;; further optimiz'ns) is backwards from the return convention for
 105   ;; transforms. -- WHN 19990917
 106   (optimizer nil :type (or function null))
 107   ;; a function computing the constant or literal arguments which are
 108   ;; destructively modified by the call.
 109   (destroyed-constant-args nil :type (or function null))
 110   ;; If true, a special-case LTN annotation method that is used in
 111   ;; place of the standard type/policy template selection. It may use
 112   ;; arbitrary code to choose a template, decide to do a full call, or
 113   ;; conspire with the IR2-CONVERT method to do almost anything. The
 114   ;; COMBINATION node is passed as the argument.
 115   (ltn-annotate nil :type (or function null))
 116   ;; If true, the special-case IR2 conversion method for this
 117   ;; function. This deals with funny functions, and anything else that
 118   ;; can't be handled using the template mechanism. The COMBINATION
 119   ;; node and the IR2-BLOCK are passed as arguments.
 120   (ir2-convert nil :type (or function null))
 121   ;; If true, the function can stack-allocate the result. The
 122   ;; COMBINATION node is passed as an argument.
 123   (stack-allocate-result nil :type (or function null))
 124   ;; all the templates that could be used to translate this function
 125   ;; into IR2, sorted by increasing cost.
 126   (templates nil :type list)
 127   ;; If non-null, then this function is a unary type predicate for
 128   ;; this type.
 129   (predicate-type nil :type (or ctype null)))
 130
 131 (defprinter (fun-info)
 132   (attributes :test (not (zerop attributes))
 133               :prin1 (decode-ir1-attributes attributes))
 134   (transforms :test transforms)
 135   (derive-type :test derive-type)
 136   (optimizer :test optimizer)
 137   (ltn-annotate :test ltn-annotate)
 138   (ir2-convert :test ir2-convert)
 139   (templates :test templates)
 140   (predicate-type :test predicate-type))
 141 \f
 142 ;;;; interfaces to defining macros
 143
 144 ;;; an IR1 transform
 145 (defstruct (transform (:copier nil))
 146   ;; the function type which enables this transform.
 147   ;;
 148   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 149   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 150   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 151   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 152   ;; FUN-TYPE.)
 153   (type (missing-arg) :type ctype)
 154   ;; the transformation function. Takes the COMBINATION node and
 155   ;; returns a lambda expression, or throws out.
 156   (function (missing-arg) :type function)
 157   ;; string used in efficiency notes
 158   (note (missing-arg) :type string)
 159   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 160   (important nil :type (member t nil)))
 161
 162 (defprinter (transform) type note important)
 163
 164 ;;; Grab the FUN-INFO and enter the function, replacing any old
 165 ;;; one with the same type and note.
 166 (declaim (ftype (function (t list function &optional (or string null)
 167                              (member t nil))
 168                           *)
 169                 %deftransform))
 170 (defun %deftransform (name type fun &optional note important)
 171   (let* ((ctype (specifier-type type))
 172          (note (or note "optimize"))
 173          (info (fun-info-or-lose name))
 174          (old (find-if (lambda (x)
 175                          (and (type= (transform-type x) ctype)
 176                               (string-equal (transform-note x) note)
 177                               (eq (transform-important x) important)))
 178                        (fun-info-transforms info))))
 179     (cond (old
 180            (style-warn "Overwriting ~S" old)
 181            (setf (transform-function old) fun
 182                  (transform-note old) note))
 183           (t
 184            (push (make-transform :type ctype :function fun :note note
 185                                  :important important)
 186                  (fun-info-transforms info))))
 187     name))
 188
 189 ;;; Make a FUN-INFO structure with the specified type, attributes
 190 ;;; and optimizers.
 191 (declaim (ftype (function (list list attributes &key
 192                                 (:derive-type (or function null))
 193                                 (:optimizer (or function null))
 194                                 (:destroyed-constant-args (or function null)))
 195                           *)
 196                 %defknown))
 197 (defun %defknown (names type attributes &key derive-type optimizer destroyed-constant-args)
 198   (let ((ctype (specifier-type type))
 199         (info (make-fun-info :attributes attributes
 200                              :derive-type derive-type
 201                              :optimizer optimizer
 202                              :destroyed-constant-args destroyed-constant-args))
 203         (target-env *info-environment*))
 204     (dolist (name names)
 205       (let ((old-fun-info (info :function :info name)))
 206         (when old-fun-info
 207           ;; This is handled as an error because it's generally a bad
 208           ;; thing to blow away all the old optimization stuff. It's
 209           ;; also a potential source of sneaky bugs:
 210           ;;    DEFKNOWN FOO
 211           ;;    DEFTRANSFORM FOO
 212           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 213           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 214           ;; However, it's continuable because it might be useful to do
 215           ;; it when testing new optimization stuff interactively.
 216           (cerror "Go ahead, overwrite it."
 217                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 218                   old-fun-info name)))
 219       (setf (info :function :type name target-env) ctype)
 220       (setf (info :function :where-from name target-env) :declared)
 221       (setf (info :function :kind name target-env) :function)
 222       (setf (info :function :info name target-env) info)))
 223   names)
 224
 225 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 226 ;;; used by callers who want to modify the info, and the info may be
 227 ;;; shared, we copy it. We don't have to copy the lists, since each
 228 ;;; function that has generators or transforms has already been
 229 ;;; through here.
 230 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 231 (defun fun-info-or-lose (name)
 232   (let (;; FIXME: Do we need this rebinding here? It's a literal
 233         ;; translation of the old CMU CL rebinding to
 234         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 235         ;; and it's not obvious whether the rebinding to itself is
 236         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 237         (*info-environment* *info-environment*))
 238     (let ((old (info :function :info name)))
 239       (unless old (error "~S is not a known function." name))
 240       (setf (info :function :info name) (copy-fun-info old)))))
 241 \f
 242 ;;;; generic type inference methods
 243
 244 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 245 ;;; only be done when the result value is that argument.
 246 (defun result-type-first-arg (call)
 247   (declare (type combination call))
 248   (let ((lvar (first (combination-args call))))
 249     (when lvar (lvar-type lvar))))
 250 (defun result-type-last-arg (call)
 251   (declare (type combination call))
 252   (let ((lvar (car (last (combination-args call)))))
 253     (when lvar (lvar-type lvar))))
 254
 255 ;;; Derive the result type according to the float contagion rules, but
 256 ;;; always return a float. This is used for irrational functions that
 257 ;;; preserve realness of their arguments.
 258 (defun result-type-float-contagion (call)
 259   (declare (type combination call))
 260   (reduce #'numeric-contagion (combination-args call)
 261           :key #'lvar-type
 262           :initial-value (specifier-type 'single-float)))
 263
 264 ;;; Return a closure usable as a derive-type method for accessing the
 265 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 266 ;;; vector, result is a vector with the same element type.
 267 (defun sequence-result-nth-arg (n)
 268   (lambda (call)
 269     (declare (type combination call))
 270     (let ((lvar (nth (1- n) (combination-args call))))
 271       (when lvar
 272         (let ((type (lvar-type lvar)))
 273           (if (array-type-p type)
 274               (specifier-type
 275                `(vector ,(type-specifier (array-type-element-type type))))
 276               (let ((ltype (specifier-type 'list)))
 277                 (when (csubtypep type ltype)
 278                   ltype))))))))
 279
 280 ;;; Derive the type to be the type specifier which is the Nth arg.
 281 (defun result-type-specifier-nth-arg (n)
 282   (lambda (call)
 283     (declare (type combination call))
 284     (let ((lvar (nth (1- n) (combination-args call))))
 285       (when (and lvar (constant-lvar-p lvar))
 286         (careful-specifier-type (lvar-value lvar))))))
 287
 288 ;;; Derive the type to be the type specifier which is the Nth arg,
 289 ;;; with the additional restriptions noted in the CLHS for STRING and
 290 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 291 ;;; (under the page for MAKE-SEQUENCE).
 292 (defun creation-result-type-specifier-nth-arg (n)
 293   (lambda (call)
 294     (declare (type combination call))
 295     (let ((lvar (nth (1- n) (combination-args call))))
 296       (when (and lvar (constant-lvar-p lvar))
 297         (let* ((specifier (lvar-value lvar))
 298                (lspecifier (if (atom specifier) (list specifier) specifier)))
 299           (cond
 300             ((eq (car lspecifier) 'string)
 301              (destructuring-bind (string &rest size)
 302                  lspecifier
 303                (declare (ignore string))
 304                (careful-specifier-type
 305                 `(vector character ,@(when size size)))))
 306             ((eq (car lspecifier) 'simple-string)
 307              (destructuring-bind (simple-string &rest size)
 308                  lspecifier
 309                (declare (ignore simple-string))
 310                (careful-specifier-type
 311                 `(simple-array character ,@(if size (list size) '((*)))))))
 312             (t
 313              (let ((ctype (careful-specifier-type specifier)))
 314                (if (and (array-type-p ctype)
 315                         (eq (array-type-specialized-element-type ctype)
 316                             *wild-type*))
 317                    ;; I don't think I'm allowed to modify what I get
 318                    ;; back from SPECIFIER-TYPE; it is, after all,
 319                    ;; cached.  Better copy it, then.
 320                    (let ((real-ctype (copy-structure ctype)))
 321                      (setf (array-type-element-type real-ctype)
 322                            *universal-type*
 323                            (array-type-specialized-element-type real-ctype)
 324                            *universal-type*)
 325                      real-ctype)
 326                    ctype)))))))))
 327
 328 (defun remove-non-constants-and-nils (fun)
 329   (lambda (list)
 330     (remove-if-not #'lvar-value
 331                    (remove-if-not #'constant-lvar-p (funcall fun list)))))
 332
 333 ;;; FIXME: bad name (first because it uses 1-based indexing; second
 334 ;;; because it doesn't get the nth constant arguments)
 335 (defun nth-constant-args (&rest indices)
 336   (lambda (list)
 337     (let (result)
 338       (do ((i 1 (1+ i))
 339            (list list (cdr list))
 340            (indices indices))
 341           ((null indices) (nreverse result))
 342         (when (= i (car indices))
 343           (when (constant-lvar-p (car list))
 344             (push (car list) result))
 345           (setf indices (cdr indices)))))))
 346
 347 ;;; FIXME: a number of the sequence functions not only do not destroy
 348 ;;; their argument if it is empty, but also leave it alone if :start
 349 ;;; and :end bound a null sequence, or if :count is 0.  This test is a
 350 ;;; bit complicated to implement, verging on the impossible, but for
 351 ;;; extra points (fill #\1 "abc" :start 0 :end 0) should not cause a
 352 ;;; warning.
 353 (defun nth-constant-nonempty-sequence-args (&rest indices)
 354   (lambda (list)
 355     (let (result)
 356       (do ((i 1 (1+ i))
 357            (list list (cdr list))
 358            (indices indices))
 359           ((null indices) (nreverse result))
 360         (when (= i (car indices))
 361           (when (constant-lvar-p (car list))
 362             (let ((value (lvar-value (car list))))
 363               (unless (or (typep value 'null)
 364                           (typep value '(vector * 0)))
 365                 (push (car list) result))))
 366           (setf indices (cdr indices)))))))
 367
 368 (/show0 "knownfun.lisp end of file")