src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; may be moved with impunity. Has no side effects except possibly
  65   ;; consing, and is affected only by its arguments.
  66   ;;
  67   ;; Since it is not used now, its distribution in fndb.lisp is
  68   ;; mere random; use with caution.
  69   movable
  70   ;; The function is a true predicate likely to be open-coded. Convert
  71   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  72   ;; specified to DEFKNOWN, since this is implementation dependent,
  73   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  74   ;; option.
  75   predicate
  76   ;; Inhibit any warning for compiling a recursive definition.
  77   ;; (Normally the compiler warns when compiling a recursive
  78   ;; definition for a known function, since it might be a botched
  79   ;; interpreter stub.)
  80   recursive
  81   ;; The function does explicit argument type checking, so the
  82   ;; declared type should not be asserted when a definition is
  83   ;; compiled.
  84   explicit-check)
  85
  86 (defstruct (fun-info #-sb-xc-host (:pure t))
  87   ;; boolean attributes of this function.
  88   (attributes (missing-arg) :type attributes)
  89   ;; TRANSFORM structures describing transforms for this function
  90   (transforms () :type list)
  91   ;; a function which computes the derived type for a call to this
  92   ;; function by examining the arguments. This is null when there is
  93   ;; no special method for this function.
  94   (derive-type nil :type (or function null))
  95   ;; a function that does various unspecified code transformations by
  96   ;; directly hacking the IR. Returns true if further optimizations of
  97   ;; the call shouldn't be attempted.
  98   ;;
  99   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 100   ;; further optimiz'ns) is backwards from the return convention for
 101   ;; transforms. -- WHN 19990917
 102   (optimizer nil :type (or function null))
 103   ;; If true, a special-case LTN annotation method that is used in
 104   ;; place of the standard type/policy template selection. It may use
 105   ;; arbitrary code to choose a template, decide to do a full call, or
 106   ;; conspire with the IR2-CONVERT method to do almost anything. The
 107   ;; COMBINATION node is passed as the argument.
 108   (ltn-annotate nil :type (or function null))
 109   ;; If true, the special-case IR2 conversion method for this
 110   ;; function. This deals with funny functions, and anything else that
 111   ;; can't be handled using the template mechanism. The Combination
 112   ;; node and the IR2-BLOCK are passed as arguments.
 113   (ir2-convert nil :type (or function null))
 114   ;; all the templates that could be used to translate this function
 115   ;; into IR2, sorted by increasing cost.
 116   (templates nil :type list)
 117   ;; If non-null, then this function is a unary type predicate for
 118   ;; this type.
 119   (predicate-type nil :type (or ctype null)))
 120
 121 (defprinter (fun-info)
 122   (attributes :test (not (zerop attributes))
 123               :prin1 (decode-ir1-attributes attributes))
 124   (transforms :test transforms)
 125   (derive-type :test derive-type)
 126   (optimizer :test optimizer)
 127   (ltn-annotate :test ltn-annotate)
 128   (ir2-convert :test ir2-convert)
 129   (templates :test templates)
 130   (predicate-type :test predicate-type))
 131 \f
 132 ;;;; interfaces to defining macros
 133
 134 ;;; an IR1 transform
 135 (defstruct (transform (:copier nil))
 136   ;; the function type which enables this transform.
 137   ;;
 138   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 139   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 140   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 141   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 142   ;; FUN-TYPE.)
 143   (type (missing-arg) :type ctype)
 144   ;; the transformation function. Takes the COMBINATION node and
 145   ;; returns a lambda expression, or throws out.
 146   (function (missing-arg) :type function)
 147   ;; string used in efficiency notes
 148   (note (missing-arg) :type string)
 149   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 150   (important nil :type (member t nil)))
 151
 152 (defprinter (transform) type note important)
 153
 154 ;;; Grab the FUN-INFO and enter the function, replacing any old
 155 ;;; one with the same type and note.
 156 (declaim (ftype (function (t list function &optional (or string null)
 157                              (member t nil))
 158                           *)
 159                 %deftransform))
 160 (defun %deftransform (name type fun &optional note important)
 161   (let* ((ctype (specifier-type type))
 162          (note (or note "optimize"))
 163          (info (fun-info-or-lose name))
 164          (old (find-if (lambda (x)
 165                          (and (type= (transform-type x) ctype)
 166                               (string-equal (transform-note x) note)
 167                               (eq (transform-important x) important)))
 168                        (fun-info-transforms info))))
 169     (cond (old
 170            (style-warn "Overwriting ~S" old)
 171            (setf (transform-function old) fun
 172                  (transform-note old) note))
 173           (t
 174            (push (make-transform :type ctype :function fun :note note
 175                                  :important important)
 176                  (fun-info-transforms info))))
 177     name))
 178
 179 ;;; Make a FUN-INFO structure with the specified type, attributes
 180 ;;; and optimizers.
 181 (declaim (ftype (function (list list attributes &key
 182                                 (:derive-type (or function null))
 183                                 (:optimizer (or function null)))
 184                           *)
 185                 %defknown))
 186 (defun %defknown (names type attributes &key derive-type optimizer)
 187   (let ((ctype (specifier-type type))
 188         (info (make-fun-info :attributes attributes
 189                              :derive-type derive-type
 190                              :optimizer optimizer))
 191         (target-env *info-environment*))
 192     (dolist (name names)
 193       (let ((old-fun-info (info :function :info name)))
 194         (when old-fun-info
 195           ;; This is handled as an error because it's generally a bad
 196           ;; thing to blow away all the old optimization stuff. It's
 197           ;; also a potential source of sneaky bugs:
 198           ;;    DEFKNOWN FOO
 199           ;;    DEFTRANSFORM FOO
 200           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 201           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 202           ;; However, it's continuable because it might be useful to do
 203           ;; it when testing new optimization stuff interactively.
 204           (cerror "Go ahead, overwrite it."
 205                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 206                   old-fun-info name)))
 207       (setf (info :function :type name target-env) ctype)
 208       (setf (info :function :where-from name target-env) :declared)
 209       (setf (info :function :kind name target-env) :function)
 210       (setf (info :function :info name target-env) info)))
 211   names)
 212
 213 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 214 ;;; used by callers who want to modify the info, and the info may be
 215 ;;; shared, we copy it. We don't have to copy the lists, since each
 216 ;;; function that has generators or transforms has already been
 217 ;;; through here.
 218 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 219 (defun fun-info-or-lose (name)
 220   (let (;; FIXME: Do we need this rebinding here? It's a literal
 221         ;; translation of the old CMU CL rebinding to
 222         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 223         ;; and it's not obvious whether the rebinding to itself is
 224         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 225         (*info-environment* *info-environment*))
 226     (let ((old (info :function :info name)))
 227       (unless old (error "~S is not a known function." name))
 228       (setf (info :function :info name) (copy-fun-info old)))))
 229 \f
 230 ;;;; generic type inference methods
 231
 232 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 233 ;;; only be done when the result value is that argument.
 234 (defun result-type-first-arg (call)
 235   (declare (type combination call))
 236   (let ((lvar (first (combination-args call))))
 237     (when lvar (lvar-type lvar))))
 238 (defun result-type-last-arg (call)
 239   (declare (type combination call))
 240   (let ((lvar (car (last (combination-args call)))))
 241     (when lvar (lvar-type lvar))))
 242
 243 ;;; Derive the result type according to the float contagion rules, but
 244 ;;; always return a float. This is used for irrational functions that
 245 ;;; preserve realness of their arguments.
 246 (defun result-type-float-contagion (call)
 247   (declare (type combination call))
 248   (reduce #'numeric-contagion (combination-args call)
 249           :key #'lvar-type
 250           :initial-value (specifier-type 'single-float)))
 251
 252 ;;; Return a closure usable as a derive-type method for accessing the
 253 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 254 ;;; vector, result is a vector with the same element type.
 255 (defun sequence-result-nth-arg (n)
 256   (lambda (call)
 257     (declare (type combination call))
 258     (let ((lvar (nth (1- n) (combination-args call))))
 259       (when lvar
 260         (let ((type (lvar-type lvar)))
 261           (if (array-type-p type)
 262               (specifier-type
 263                `(vector ,(type-specifier (array-type-element-type type))))
 264               (let ((ltype (specifier-type 'list)))
 265                 (when (csubtypep type ltype)
 266                   ltype))))))))
 267
 268 ;;; Derive the type to be the type specifier which is the Nth arg.
 269 (defun result-type-specifier-nth-arg (n)
 270   (lambda (call)
 271     (declare (type combination call))
 272     (let ((lvar (nth (1- n) (combination-args call))))
 273       (when (and lvar (constant-lvar-p lvar))
 274         (careful-specifier-type (lvar-value lvar))))))
 275
 276 ;;; Derive the type to be the type specifier which is the Nth arg,
 277 ;;; with the additional restriptions noted in the CLHS for STRING and
 278 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 279 ;;; (under the page for MAKE-SEQUENCE).
 280 (defun creation-result-type-specifier-nth-arg (n)
 281   (lambda (call)
 282     (declare (type combination call))
 283     (let ((lvar (nth (1- n) (combination-args call))))
 284       (when (and lvar (constant-lvar-p lvar))
 285         (let* ((specifier (lvar-value lvar))
 286                (lspecifier (if (atom specifier) (list specifier) specifier)))
 287           (cond
 288             ((eq (car lspecifier) 'string)
 289              (destructuring-bind (string &rest size)
 290                  lspecifier
 291                (declare (ignore string))
 292                (careful-specifier-type
 293                 `(vector character ,@(when size size)))))
 294             ((eq (car lspecifier) 'simple-string)
 295              (destructuring-bind (simple-string &rest size)
 296                  lspecifier
 297                (declare (ignore simple-string))
 298                (careful-specifier-type
 299                 `(simple-array character ,@(if size (list size) '((*)))))))
 300             (t
 301              (let ((ctype (careful-specifier-type specifier)))
 302                (if (and (array-type-p ctype)
 303                         (eq (array-type-specialized-element-type ctype)
 304                             *wild-type*))
 305                    ;; I don't think I'm allowed to modify what I get
 306                    ;; back from SPECIFIER-TYPE; it is, after all,
 307                    ;; cached.  Better copy it, then.
 308                    (let ((real-ctype (copy-structure ctype)))
 309                      (setf (array-type-element-type real-ctype)
 310                            *universal-type*
 311                            (array-type-specialized-element-type real-ctype)
 312                            *universal-type*)
 313                      real-ctype)
 314                    ctype)))))))))
 315
 316 (/show0 "knownfun.lisp end of file")