src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; may be moved with impunity. Has no side effects except possibly
  65   ;; consing, and is affected only by its arguments.
  66   movable
  67   ;; The function is a true predicate likely to be open-coded. Convert
  68   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  69   ;; specified to DEFKNOWN, since this is implementation dependent,
  70   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  71   ;; option.
  72   predicate
  73   ;; Inhibit any warning for compiling a recursive definition.
  74   ;; (Normally the compiler warns when compiling a recursive
  75   ;; definition for a known function, since it might be a botched
  76   ;; interpreter stub.)
  77   recursive
  78   ;; The function does explicit argument type checking, so the
  79   ;; declared type should not be asserted when a definition is
  80   ;; compiled.
  81   explicit-check)
  82
  83 (defstruct (fun-info #-sb-xc-host (:pure t))
  84   ;; boolean attributes of this function.
  85   (attributes (missing-arg) :type attributes)
  86   ;; TRANSFORM structures describing transforms for this function
  87   (transforms () :type list)
  88   ;; a function which computes the derived type for a call to this
  89   ;; function by examining the arguments. This is null when there is
  90   ;; no special method for this function.
  91   (derive-type nil :type (or function null))
  92   ;; a function that does various unspecified code transformations by
  93   ;; directly hacking the IR. Returns true if further optimizations of
  94   ;; the call shouldn't be attempted.
  95   ;;
  96   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
  97   ;; further optimiz'ns) is backwards from the return convention for
  98   ;; transforms. -- WHN 19990917
  99   (optimizer nil :type (or function null))
 100   ;; If true, a special-case LTN annotation method that is used in
 101   ;; place of the standard type/policy template selection. It may use
 102   ;; arbitrary code to choose a template, decide to do a full call, or
 103   ;; conspire with the IR2-CONVERT method to do almost anything. The
 104   ;; COMBINATION node is passed as the argument.
 105   (ltn-annotate nil :type (or function null))
 106   ;; If true, the special-case IR2 conversion method for this
 107   ;; function. This deals with funny functions, and anything else that
 108   ;; can't be handled using the template mechanism. The Combination
 109   ;; node and the IR2-BLOCK are passed as arguments.
 110   (ir2-convert nil :type (or function null))
 111   ;; all the templates that could be used to translate this function
 112   ;; into IR2, sorted by increasing cost.
 113   (templates nil :type list)
 114   ;; If non-null, then this function is a unary type predicate for
 115   ;; this type.
 116   (predicate-type nil :type (or ctype null)))
 117
 118 (defprinter (fun-info)
 119   (transforms :test transforms)
 120   (derive-type :test derive-type)
 121   (optimizer :test optimizer)
 122   (ltn-annotate :test ltn-annotate)
 123   (ir2-convert :test ir2-convert)
 124   (templates :test templates)
 125   (predicate-type :test predicate-type))
 126 \f
 127 ;;;; interfaces to defining macros
 128
 129 ;;; an IR1 transform
 130 (defstruct (transform (:copier nil))
 131   ;; the function type which enables this transform.
 132   ;;
 133   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 134   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 135   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 136   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 137   ;; FUN-TYPE.)
 138   (type (missing-arg) :type ctype)
 139   ;; the transformation function. Takes the COMBINATION node and
 140   ;; returns a lambda expression, or throws out.
 141   (function (missing-arg) :type function)
 142   ;; string used in efficiency notes
 143   (note (missing-arg) :type string)
 144   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 145   (important nil :type (member t nil)))
 146
 147 (defprinter (transform) type note important)
 148
 149 ;;; Grab the FUN-INFO and enter the function, replacing any old
 150 ;;; one with the same type and note.
 151 (declaim (ftype (function (t list function &optional (or string null)
 152                              (member t nil))
 153                           *)
 154                 %deftransform))
 155 (defun %deftransform (name type fun &optional note important)
 156   (let* ((ctype (specifier-type type))
 157          (note (or note "optimize"))
 158          (info (fun-info-or-lose name))
 159          (old (find-if (lambda (x)
 160                          (and (type= (transform-type x) ctype)
 161                               (string-equal (transform-note x) note)
 162                               (eq (transform-important x) important)))
 163                        (fun-info-transforms info))))
 164     (if old
 165         (setf (transform-function old) fun
 166               (transform-note old) note)
 167         (push (make-transform :type ctype :function fun :note note
 168                               :important important)
 169               (fun-info-transforms info)))
 170     name))
 171
 172 ;;; Make a FUN-INFO structure with the specified type, attributes
 173 ;;; and optimizers.
 174 (declaim (ftype (function (list list attributes &key
 175                                 (:derive-type (or function null))
 176                                 (:optimizer (or function null)))
 177                           *)
 178                 %defknown))
 179 (defun %defknown (names type attributes &key derive-type optimizer)
 180   (let ((ctype (specifier-type type))
 181         (info (make-fun-info :attributes attributes
 182                              :derive-type derive-type
 183                              :optimizer optimizer))
 184         (target-env *info-environment*))
 185     (dolist (name names)
 186       (let ((old-fun-info (info :function :info name)))
 187         (when old-fun-info
 188           ;; This is handled as an error because it's generally a bad
 189           ;; thing to blow away all the old optimization stuff. It's
 190           ;; also a potential source of sneaky bugs:
 191           ;;    DEFKNOWN FOO
 192           ;;    DEFTRANSFORM FOO
 193           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 194           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 195           ;; However, it's continuable because it might be useful to do
 196           ;; it when testing new optimization stuff interactively.
 197           (cerror "Go ahead, overwrite it."
 198                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 199                   old-fun-info name)))
 200       (setf (info :function :type name target-env) ctype)
 201       (setf (info :function :where-from name target-env) :declared)
 202       (setf (info :function :kind name target-env) :function)
 203       (setf (info :function :info name target-env) info)))
 204   names)
 205
 206 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 207 ;;; used by callers who want to modify the info, and the info may be
 208 ;;; shared, we copy it. We don't have to copy the lists, since each
 209 ;;; function that has generators or transforms has already been
 210 ;;; through here.
 211 (declaim (ftype (function (t) fun-info) fun-info-or-lose))
 212 (defun fun-info-or-lose (name)
 213   (let (;; FIXME: Do we need this rebinding here? It's a literal
 214         ;; translation of the old CMU CL rebinding to
 215         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 216         ;; and it's not obvious whether the rebinding to itself is
 217         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 218         (*info-environment* *info-environment*))
 219     (let ((old (info :function :info name)))
 220       (unless old (error "~S is not a known function." name))
 221       (setf (info :function :info name) (copy-fun-info old)))))
 222 \f
 223 ;;;; generic type inference methods
 224
 225 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 226 ;;; only be done when the result value is that argument.
 227 (defun result-type-first-arg (call)
 228   (declare (type combination call))
 229   (let ((cont (first (combination-args call))))
 230     (when cont (continuation-type cont))))
 231 (defun result-type-last-arg (call)
 232   (declare (type combination call))
 233   (let ((cont (car (last (combination-args call)))))
 234     (when cont (continuation-type cont))))
 235
 236 ;;; Derive the result type according to the float contagion rules, but
 237 ;;; always return a float. This is used for irrational functions that
 238 ;;; preserve realness of their arguments.
 239 (defun result-type-float-contagion (call)
 240   (declare (type combination call))
 241   (reduce #'numeric-contagion (combination-args call)
 242           :key #'continuation-type
 243           :initial-value (specifier-type 'single-float)))
 244
 245 ;;; Return a closure usable as a derive-type method for accessing the
 246 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 247 ;;; vector, result is a vector with the same element type.
 248 (defun sequence-result-nth-arg (n)
 249   (lambda (call)
 250     (declare (type combination call))
 251     (let ((cont (nth (1- n) (combination-args call))))
 252       (when cont
 253         (let ((type (continuation-type cont)))
 254           (if (array-type-p type)
 255               (specifier-type
 256                `(vector ,(type-specifier (array-type-element-type type))))
 257               (let ((ltype (specifier-type 'list)))
 258                 (when (csubtypep type ltype)
 259                   ltype))))))))
 260
 261 ;;; Derive the type to be the type specifier which is the N'th arg.
 262 (defun result-type-specifier-nth-arg (n)
 263   (lambda (call)
 264     (declare (type combination call))
 265     (let ((cont (nth (1- n) (combination-args call))))
 266       (when (and cont (constant-continuation-p cont))
 267         (careful-specifier-type (continuation-value cont))))))
 268
 269 (/show0 "knownfun.lisp end of file")