src/compiler/knownfun.lisp

   1 ;;;; This file contains stuff for maintaining a database of special
   2 ;;;; information about functions known to the compiler. This includes
   3 ;;;; semantic information such as side effects and type inference
   4 ;;;; functions as well as transforms and IR2 translators.
   5
   6 ;;;; This software is part of the SBCL system. See the README file for
   7 ;;;; more information.
   8 ;;;;
   9 ;;;; This software is derived from the CMU CL system, which was
  10 ;;;; written at Carnegie Mellon University and released into the
  11 ;;;; public domain. The software is in the public domain and is
  12 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  13 ;;;; files for more information.
  14
  15 (in-package "SB!C")
  16
  17 (/show0 "knownfun.lisp 17")
  18
  19 ;;; IR1 boolean function attributes
  20 ;;;
  21 ;;; There are a number of boolean attributes of known functions which
  22 ;;; we like to have in IR1. This information is mostly side effect
  23 ;;; information of a sort, but it is different from the kind of
  24 ;;; information we want in IR2. We aren't interested in a fine
  25 ;;; breakdown of side effects, since we do very little code motion on
  26 ;;; IR1. We are interested in some deeper semantic properties such as
  27 ;;; whether it is safe to pass stack closures to.
  28 (!def-boolean-attribute ir1
  29   ;; may call functions that are passed as arguments. In order to
  30   ;; determine what other effects are present, we must find the
  31   ;; effects of all arguments that may be functions.
  32   call
  33   ;; may incorporate function or number arguments into the result or
  34   ;; somehow pass them upward. Note that this applies to any argument
  35   ;; that *might* be a function or number, not just the arguments that
  36   ;; always are.
  37   unsafe
  38   ;; may fail to return during correct execution. Errors are O.K.
  39   unwind
  40   ;; the (default) worst case. Includes all the other bad things, plus
  41   ;; any other possible bad thing. If this is present, the above bad
  42   ;; attributes will be explicitly present as well.
  43   any
  44   ;; may be constant-folded. The function has no side effects, but may
  45   ;; be affected by side effects on the arguments. e.g. SVREF, MAPC.
  46   ;; Functions that side-effect their arguments are not considered to
  47   ;; be foldable. Although it would be "legal" to constant fold them
  48   ;; (since it "is an error" to modify a constant), we choose not to
  49   ;; mark these functions as foldable in this database.
  50   foldable
  51   ;; may be eliminated if value is unused. The function has no side
  52   ;; effects except possibly cons. If a function might signal errors,
  53   ;; then it is not flushable even if it is movable, foldable or
  54   ;; unsafely-flushable. Implies UNSAFELY-FLUSHABLE. (In safe code
  55   ;; type checking of arguments is always performed by the caller, so
  56   ;; a function which SHOULD signal an error if arguments are not of
  57   ;; declared types may be FLUSHABLE.)
  58   flushable
  59   ;; unsafe call may be eliminated if value is unused. The function
  60   ;; has no side effects except possibly cons and signalling an error
  61   ;; in the safe code. If a function MUST signal errors, then it is
  62   ;; not unsafely-flushable even if it is movable or foldable.
  63   unsafely-flushable
  64   ;; return value is important, and ignoring it is probably a mistake.
  65   ;; Unlike the other attributes, this is used only for style
  66   ;; warnings and has no effect on optimization.
  67   important-result
  68   ;; may be moved with impunity. Has no side effects except possibly
  69   ;; consing, and is affected only by its arguments.
  70   ;;
  71   ;; Since it is not used now, its distribution in fndb.lisp is
  72   ;; mere random; use with caution.
  73   movable
  74   ;; The function is a true predicate likely to be open-coded. Convert
  75   ;; any non-conditional uses into (IF <pred> T NIL). Not usually
  76   ;; specified to DEFKNOWN, since this is implementation dependent,
  77   ;; and is usually automatically set by the DEFINE-VOP :CONDITIONAL
  78   ;; option.
  79   predicate
  80   ;; Inhibit any warning for compiling a recursive definition.
  81   ;; (Normally the compiler warns when compiling a recursive
  82   ;; definition for a known function, since it might be a botched
  83   ;; interpreter stub.)
  84   recursive
  85   ;; The function does explicit argument type checking, so the
  86   ;; declared type should not be asserted when a definition is
  87   ;; compiled.
  88   explicit-check
  89   ;; The function should always be translated by a VOP (i.e. it should
  90   ;; should never be converted into a full call).  This is used strictly
  91   ;; as a consistency checking mechanism inside the compiler during IR2
  92   ;; transformation.
  93   always-translatable)
  94
  95 (defstruct (fun-info #-sb-xc-host (:pure t))
  96   ;; boolean attributes of this function.
  97   (attributes (missing-arg) :type attributes)
  98   ;; TRANSFORM structures describing transforms for this function
  99   (transforms () :type list)
 100   ;; a function which computes the derived type for a call to this
 101   ;; function by examining the arguments. This is null when there is
 102   ;; no special method for this function.
 103   (derive-type nil :type (or function null))
 104   ;; a function that does various unspecified code transformations by
 105   ;; directly hacking the IR. Returns true if further optimizations of
 106   ;; the call shouldn't be attempted.
 107   ;;
 108   ;; KLUDGE: This return convention (non-NIL if you shouldn't do
 109   ;; further optimiz'ns) is backwards from the return convention for
 110   ;; transforms. -- WHN 19990917
 111   (optimizer nil :type (or function null))
 112   ;; a function computing the constant or literal arguments which are
 113   ;; destructively modified by the call.
 114   (destroyed-constant-args nil :type (or function null))
 115   ;; If true, a special-case LTN annotation method that is used in
 116   ;; place of the standard type/policy template selection. It may use
 117   ;; arbitrary code to choose a template, decide to do a full call, or
 118   ;; conspire with the IR2-CONVERT method to do almost anything. The
 119   ;; COMBINATION node is passed as the argument.
 120   (ltn-annotate nil :type (or function null))
 121   ;; If true, the special-case IR2 conversion method for this
 122   ;; function. This deals with funny functions, and anything else that
 123   ;; can't be handled using the template mechanism. The COMBINATION
 124   ;; node and the IR2-BLOCK are passed as arguments.
 125   (ir2-convert nil :type (or function null))
 126   ;; If true, the function can stack-allocate the result. The
 127   ;; COMBINATION node is passed as an argument.
 128   (stack-allocate-result nil :type (or function null))
 129   ;; all the templates that could be used to translate this function
 130   ;; into IR2, sorted by increasing cost.
 131   (templates nil :type list)
 132   ;; If non-null, then this function is a unary type predicate for
 133   ;; this type.
 134   (predicate-type nil :type (or ctype null))
 135   ;; If non-null, the index of the argument which becomes the result
 136   ;; of the function.
 137   (result-arg nil :type (or index null)))
 138
 139 (defprinter (fun-info)
 140   (attributes :test (not (zerop attributes))
 141               :prin1 (decode-ir1-attributes attributes))
 142   (transforms :test transforms)
 143   (derive-type :test derive-type)
 144   (optimizer :test optimizer)
 145   (ltn-annotate :test ltn-annotate)
 146   (ir2-convert :test ir2-convert)
 147   (templates :test templates)
 148   (predicate-type :test predicate-type))
 149 \f
 150 ;;;; interfaces to defining macros
 151
 152 ;;; an IR1 transform
 153 (defstruct (transform (:copier nil))
 154   ;; the function type which enables this transform.
 155   ;;
 156   ;; (Note that declaring this :TYPE FUN-TYPE probably wouldn't
 157   ;; work because some function types, like (SPECIFIER-TYPE 'FUNCTION0
 158   ;; itself, are represented as BUILT-IN-TYPE, and at least as of
 159   ;; sbcl-0.pre7.54 or so, that's inconsistent with being a
 160   ;; FUN-TYPE.)
 161   (type (missing-arg) :type ctype)
 162   ;; the transformation function. Takes the COMBINATION node and
 163   ;; returns a lambda expression, or throws out.
 164   (function (missing-arg) :type function)
 165   ;; string used in efficiency notes
 166   (note (missing-arg) :type string)
 167   ;; T if we should emit a failure note even if SPEED=INHIBIT-WARNINGS.
 168   (important nil :type (member t nil)))
 169
 170 (defprinter (transform) type note important)
 171
 172 ;;; Grab the FUN-INFO and enter the function, replacing any old
 173 ;;; one with the same type and note.
 174 (declaim (ftype (function (t list function &optional (or string null)
 175                              (member t nil))
 176                           *)
 177                 %deftransform))
 178 (defun %deftransform (name type fun &optional note important)
 179   (let* ((ctype (specifier-type type))
 180          (note (or note "optimize"))
 181          (info (fun-info-or-lose name))
 182          (old (find-if (lambda (x)
 183                          (and (type= (transform-type x) ctype)
 184                               (string-equal (transform-note x) note)
 185                               (eq (transform-important x) important)))
 186                        (fun-info-transforms info))))
 187     (cond (old
 188            (style-warn 'sb!kernel:redefinition-with-deftransform
 189                        :transform old)
 190            (setf (transform-function old) fun
 191                  (transform-note old) note))
 192           (t
 193            (push (make-transform :type ctype :function fun :note note
 194                                  :important important)
 195                  (fun-info-transforms info))))
 196     name))
 197
 198 ;;; Make a FUN-INFO structure with the specified type, attributes
 199 ;;; and optimizers.
 200 (declaim (ftype (function (list list attributes &key
 201                                 (:derive-type (or function null))
 202                                 (:optimizer (or function null))
 203                                 (:destroyed-constant-args (or function null))
 204                                 (:result-arg (or index null)))
 205                           *)
 206                 %defknown))
 207 (defun %defknown (names type attributes &key derive-type optimizer destroyed-constant-args result-arg)
 208   (let ((ctype (specifier-type type))
 209         (info (make-fun-info :attributes attributes
 210                              :derive-type derive-type
 211                              :optimizer optimizer
 212                              :destroyed-constant-args destroyed-constant-args
 213                              :result-arg result-arg))
 214         (target-env *info-environment*))
 215     (dolist (name names)
 216       (let ((old-fun-info (info :function :info name)))
 217         (when old-fun-info
 218           ;; This is handled as an error because it's generally a bad
 219           ;; thing to blow away all the old optimization stuff. It's
 220           ;; also a potential source of sneaky bugs:
 221           ;;    DEFKNOWN FOO
 222           ;;    DEFTRANSFORM FOO
 223           ;;    DEFKNOWN FOO ; possibly hidden inside some macroexpansion
 224           ;;    ; Now the DEFTRANSFORM doesn't exist in the target Lisp.
 225           ;; However, it's continuable because it might be useful to do
 226           ;; it when testing new optimization stuff interactively.
 227           (cerror "Go ahead, overwrite it."
 228                   "~@<overwriting old FUN-INFO ~2I~_~S ~I~_for ~S~:>"
 229                   old-fun-info name)))
 230       (setf (info :function :type name target-env) ctype)
 231       (setf (info :function :where-from name target-env) :declared)
 232       (setf (info :function :kind name target-env) :function)
 233       (setf (info :function :info name target-env) info)))
 234   names)
 235
 236 ;;; Return the FUN-INFO for NAME or die trying. Since this is
 237 ;;; used by callers who want to modify the info, and the info may be
 238 ;;; shared, we copy it. We don't have to copy the lists, since each
 239 ;;; function that has generators or transforms has already been
 240 ;;; through here.
 241 (declaim (ftype (sfunction (t) fun-info) fun-info-or-lose))
 242 (defun fun-info-or-lose (name)
 243   (let (;; FIXME: Do we need this rebinding here? It's a literal
 244         ;; translation of the old CMU CL rebinding to
 245         ;; (OR *BACKEND-INFO-ENVIRONMENT* *INFO-ENVIRONMENT*),
 246         ;; and it's not obvious whether the rebinding to itself is
 247         ;; needed that SBCL doesn't need *BACKEND-INFO-ENVIRONMENT*.
 248         (*info-environment* *info-environment*))
 249     (let ((old (info :function :info name)))
 250       (unless old (error "~S is not a known function." name))
 251       (setf (info :function :info name) (copy-fun-info old)))))
 252 \f
 253 ;;;; generic type inference methods
 254
 255 ;;; Derive the type to be the type of the xxx'th arg. This can normally
 256 ;;; only be done when the result value is that argument.
 257 (defun result-type-first-arg (call)
 258   (declare (type combination call))
 259   (let ((lvar (first (combination-args call))))
 260     (when lvar (lvar-type lvar))))
 261 (defun result-type-last-arg (call)
 262   (declare (type combination call))
 263   (let ((lvar (car (last (combination-args call)))))
 264     (when lvar (lvar-type lvar))))
 265
 266 ;;; Derive the result type according to the float contagion rules, but
 267 ;;; always return a float. This is used for irrational functions that
 268 ;;; preserve realness of their arguments.
 269 (defun result-type-float-contagion (call)
 270   (declare (type combination call))
 271   (reduce #'numeric-contagion (combination-args call)
 272           :key #'lvar-type
 273           :initial-value (specifier-type 'single-float)))
 274
 275 ;;; Return a closure usable as a derive-type method for accessing the
 276 ;;; N'th argument. If arg is a list, result is a list. If arg is a
 277 ;;; vector, result is a vector with the same element type.
 278 (defun sequence-result-nth-arg (n)
 279   (lambda (call)
 280     (declare (type combination call))
 281     (let ((lvar (nth (1- n) (combination-args call))))
 282       (when lvar
 283         (let ((type (lvar-type lvar)))
 284           (if (array-type-p type)
 285               (specifier-type
 286                `(vector ,(type-specifier (array-type-element-type type))))
 287               (let ((ltype (specifier-type 'list)))
 288                 (when (csubtypep type ltype)
 289                   ltype))))))))
 290
 291 ;;; Derive the type to be the type specifier which is the Nth arg.
 292 (defun result-type-specifier-nth-arg (n)
 293   (lambda (call)
 294     (declare (type combination call))
 295     (let ((lvar (nth (1- n) (combination-args call))))
 296       (when (and lvar (constant-lvar-p lvar))
 297         (careful-specifier-type (lvar-value lvar))))))
 298
 299 ;;; Derive the type to be the type specifier which is the Nth arg,
 300 ;;; with the additional restriptions noted in the CLHS for STRING and
 301 ;;; SIMPLE-STRING, defined to specialize on CHARACTER, and for VECTOR
 302 ;;; (under the page for MAKE-SEQUENCE).
 303 (defun creation-result-type-specifier-nth-arg (n)
 304   (lambda (call)
 305     (declare (type combination call))
 306     (let ((lvar (nth (1- n) (combination-args call))))
 307       (when (and lvar (constant-lvar-p lvar))
 308         (let* ((specifier (lvar-value lvar))
 309                (lspecifier (if (atom specifier) (list specifier) specifier)))
 310           (cond
 311             ((eq (car lspecifier) 'string)
 312              (destructuring-bind (string &rest size)
 313                  lspecifier
 314                (declare (ignore string))
 315                (careful-specifier-type
 316                 `(vector character ,@(when size size)))))
 317             ((eq (car lspecifier) 'simple-string)
 318              (destructuring-bind (simple-string &rest size)
 319                  lspecifier
 320                (declare (ignore simple-string))
 321                (careful-specifier-type
 322                 `(simple-array character ,@(if size (list size) '((*)))))))
 323             (t
 324              (let ((ctype (careful-specifier-type specifier)))
 325                (if (and (array-type-p ctype)
 326                         (eq (array-type-specialized-element-type ctype)
 327                             *wild-type*))
 328                    ;; I don't think I'm allowed to modify what I get
 329                    ;; back from SPECIFIER-TYPE; it is, after all,
 330                    ;; cached.  Better copy it, then.
 331                    (let ((real-ctype (copy-structure ctype)))
 332                      (setf (array-type-element-type real-ctype)
 333                            *universal-type*
 334                            (array-type-specialized-element-type real-ctype)
 335                            *universal-type*)
 336                      real-ctype)
 337                    ctype)))))))))
 338
 339 (defun remove-non-constants-and-nils (fun)
 340   (lambda (list)
 341     (remove-if-not #'lvar-value
 342                    (remove-if-not #'constant-lvar-p (funcall fun list)))))
 343
 344 ;;; FIXME: bad name (first because it uses 1-based indexing; second
 345 ;;; because it doesn't get the nth constant arguments)
 346 (defun nth-constant-args (&rest indices)
 347   (lambda (list)
 348     (let (result)
 349       (do ((i 1 (1+ i))
 350            (list list (cdr list))
 351            (indices indices))
 352           ((null indices) (nreverse result))
 353         (when (= i (car indices))
 354           (when (constant-lvar-p (car list))
 355             (push (car list) result))
 356           (setf indices (cdr indices)))))))
 357
 358 ;;; FIXME: a number of the sequence functions not only do not destroy
 359 ;;; their argument if it is empty, but also leave it alone if :start
 360 ;;; and :end bound a null sequence, or if :count is 0.  This test is a
 361 ;;; bit complicated to implement, verging on the impossible, but for
 362 ;;; extra points (fill #\1 "abc" :start 0 :end 0) should not cause a
 363 ;;; warning.
 364 (defun nth-constant-nonempty-sequence-args (&rest indices)
 365   (lambda (list)
 366     (let (result)
 367       (do ((i 1 (1+ i))
 368            (list list (cdr list))
 369            (indices indices))
 370           ((null indices) (nreverse result))
 371         (when (= i (car indices))
 372           (when (constant-lvar-p (car list))
 373             (let ((value (lvar-value (car list))))
 374               (unless (or (typep value 'null)
 375                           (typep value '(vector * 0)))
 376                 (push (car list) result))))
 377           (setf indices (cdr indices)))))))
 378
 379 (/show0 "knownfun.lisp end of file")